OSDN Git Service

3cad882f947e8c36d56a660d0fab05cb610d5526
[pf3gnuchains/gcc-fork.git] / gcc / configure.ac
1 # configure.ac for GCC
2 # Process this file with autoconf to generate a configuration script.
3
4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
5 # Free Software Foundation, Inc.
6
7 #This file is part of GCC.
8
9 #GCC is free software; you can redistribute it and/or modify it under
10 #the terms of the GNU General Public License as published by the Free
11 #Software Foundation; either version 2, or (at your option) any later
12 #version.
13
14 #GCC is distributed in the hope that it will be useful, but WITHOUT
15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
17 #for more details.
18
19 #You should have received a copy of the GNU General Public License
20 #along with GCC; see the file COPYING.  If not, write to the Free
21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
22 #02111-1307, USA.
23
24 # --------------------------------
25 # Initialization and sanity checks
26 # --------------------------------
27
28 AC_PREREQ(2.59)
29 AC_INIT
30 AC_CONFIG_SRCDIR(tree.c)
31 AC_CONFIG_HEADER(auto-host.h:config.in)
32
33 #Set to 1 on a release branch
34 is_release=
35
36 # Determine the host, build, and target systems
37 AC_CANONICAL_BUILD
38 AC_CANONICAL_HOST
39 AC_CANONICAL_TARGET
40
41 # Determine the noncanonical target name, for directory use.
42 ACX_NONCANONICAL_TARGET
43
44 # Determine the target- and build-specific subdirectories
45 GCC_TOPLEV_SUBDIRS
46
47 # Set program_transform_name
48 AC_ARG_PROGRAM
49
50 # Check for bogus environment variables.
51 # Test if LIBRARY_PATH contains the notation for the current directory
52 # since this would lead to problems installing/building glibc.
53 # LIBRARY_PATH contains the current directory if one of the following
54 # is true:
55 # - one of the terminals (":" and ";") is the first or last sign
56 # - two terminals occur directly after each other
57 # - the path contains an element with a dot in it
58 AC_MSG_CHECKING(LIBRARY_PATH variable)
59 changequote(,)dnl
60 case ${LIBRARY_PATH} in
61   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
62     library_path_setting="contains current directory"
63     ;;
64   *)
65     library_path_setting="ok"
66     ;;
67 esac
68 changequote([,])dnl
69 AC_MSG_RESULT($library_path_setting)
70 if test "$library_path_setting" != "ok"; then
71 AC_MSG_ERROR([
72 *** LIBRARY_PATH shouldn't contain the current directory when
73 *** building gcc. Please change the environment variable
74 *** and run configure again.])
75 fi
76
77 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
78 # since this would lead to problems installing/building glibc.
79 # GCC_EXEC_PREFIX contains the current directory if one of the following
80 # is true:
81 # - one of the terminals (":" and ";") is the first or last sign
82 # - two terminals occur directly after each other
83 # - the path contains an element with a dot in it
84 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
85 changequote(,)dnl
86 case ${GCC_EXEC_PREFIX} in
87   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
88     gcc_exec_prefix_setting="contains current directory"
89     ;;
90   *)
91     gcc_exec_prefix_setting="ok"
92     ;;
93 esac
94 changequote([,])dnl
95 AC_MSG_RESULT($gcc_exec_prefix_setting)
96 if test "$gcc_exec_prefix_setting" != "ok"; then
97 AC_MSG_ERROR([
98 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
99 *** building gcc. Please change the environment variable
100 *** and run configure again.])
101 fi
102
103 TL_AC_GCC_VERSION([$srcdir/..])
104
105 # -----------
106 # Directories
107 # -----------
108
109 # Specify the local prefix
110 local_prefix=
111 AC_ARG_WITH(local-prefix,
112 [  --with-local-prefix=DIR specifies directory to put local include],
113 [case "${withval}" in
114 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
115 no)     ;;
116 *)      local_prefix=$with_local_prefix ;;
117 esac])
118
119 # Default local prefix if it is empty
120 if test x$local_prefix = x; then
121         local_prefix=/usr/local
122 fi
123
124 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
125 # passed in by the toplevel make and thus we'd get different behavior
126 # depending on where we built the sources.
127 gcc_gxx_include_dir=
128 # Specify the g++ header file directory
129 AC_ARG_WITH(gxx-include-dir,
130 [  --with-gxx-include-dir=DIR
131                           specifies directory to put g++ header files],
132 [case "${withval}" in
133 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
134 no)     ;;
135 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
136 esac])
137
138 if test x${gcc_gxx_include_dir} = x; then
139   if test x${enable_version_specific_runtime_libs} = xyes; then
140     gcc_gxx_include_dir='${libsubdir}/include/c++'
141   else
142     libstdcxx_incdir=c++/${gcc_version}
143 changequote(<<, >>)dnl
144     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
145 changequote([, ])dnl
146   fi
147 fi
148
149 AC_ARG_WITH(cpp_install_dir,
150 [  --with-cpp-install-dir=DIR
151                           install the user visible C preprocessor in DIR
152                           (relative to PREFIX) as well as PREFIX/bin],
153 [if test x$withval = xyes; then
154   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
155 elif test x$withval != xno; then
156   cpp_install_dir=$withval
157 fi])
158
159 # We would like to our source tree to be readonly.  However when releases or
160 # pre-releases are generated, the flex/bison generated files as well as the 
161 # various formats of manuals need to be included along with the rest of the
162 # sources.  Therefore we have --enable-generated-files-in-srcdir to do 
163 # just that.
164
165 AC_MSG_CHECKING([whether to place generated files in the source directory])
166   dnl generated-files-in-srcdir is disabled by default
167   AC_ARG_ENABLE(generated-files-in-srcdir, 
168 [  --enable-generated-files-in-srcdir
169                           put copies of generated files in source dir
170                           intended for creating source tarballs for users
171                           without texinfo bison or flex.],
172       generated_files_in_srcdir=$enableval,
173       generated_files_in_srcdir=no)
174
175 AC_MSG_RESULT($generated_files_in_srcdir)
176
177 if test "$generated_files_in_srcdir" = "yes"; then
178   GENINSRC=''
179 else
180   GENINSRC='#'
181 fi
182 AC_SUBST(GENINSRC)
183
184 # -------------------
185 # Find default linker
186 # -------------------
187
188 # With GNU ld
189 AC_ARG_WITH(gnu-ld,
190 [  --with-gnu-ld           arrange to work with GNU ld.],
191 gnu_ld_flag="$with_gnu_ld",
192 gnu_ld_flag=no)
193
194 # With pre-defined ld
195 AC_ARG_WITH(ld,
196 [  --with-ld               arrange to use the specified ld (full pathname)],
197 DEFAULT_LINKER="$with_ld")
198 if test x"${DEFAULT_LINKER+set}" = x"set"; then
199   if test ! -x "$DEFAULT_LINKER"; then
200     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
201   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
202     gnu_ld_flag=yes
203   fi
204   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
205         [Define to enable the use of a default linker.])
206 fi
207
208 AC_MSG_CHECKING([whether a default linker was specified])
209 if test x"${DEFAULT_LINKER+set}" = x"set"; then
210   if test x"$gnu_ld_flag" = x"no"; then
211     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
212   else
213     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
214   fi
215 else
216   AC_MSG_RESULT(no)
217 fi
218
219 # With demangler in GNU ld
220 AC_ARG_WITH(demangler-in-ld,
221 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
222 demangler_in_ld="$with_demangler_in_ld",
223 demangler_in_ld=no)
224
225 # ----------------------
226 # Find default assembler
227 # ----------------------
228
229 # With GNU as
230 AC_ARG_WITH(gnu-as,
231 [  --with-gnu-as           arrange to work with GNU as],
232 gas_flag="$with_gnu_as",
233 gas_flag=no)
234
235 AC_ARG_WITH(as,
236 [  --with-as               arrange to use the specified as (full pathname)],
237 DEFAULT_ASSEMBLER="$with_as")
238 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
239   if test ! -x "$DEFAULT_ASSEMBLER"; then
240     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
241   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
242     gas_flag=yes
243   fi
244   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
245         [Define to enable the use of a default assembler.])
246 fi
247
248 AC_MSG_CHECKING([whether a default assembler was specified])
249 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
250   if test x"$gas_flag" = x"no"; then
251     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
252   else
253     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
254   fi
255 else
256   AC_MSG_RESULT(no)
257 fi
258
259 # ---------------
260 # Find C compiler
261 # ---------------
262
263 # If a non-executable a.out is present (e.g. created by GNU as above even if
264 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
265 # file, even when creating an executable, so an execution test fails.
266 # Remove possible default executable files to avoid this.
267 #
268 # FIXME: This really belongs into AC_PROG_CC and can be removed once
269 # Autoconf includes it.
270 rm -f a.out a.exe b.out
271
272 # Find the native compiler
273 AC_PROG_CC
274 AM_PROG_CC_C_O
275 # autoconf is lame and doesn't give us any substitution variable for this.
276 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
277   NO_MINUS_C_MINUS_O=yes
278 else
279   OUTPUT_OPTION='-o $@'
280 fi
281 AC_SUBST(NO_MINUS_C_MINUS_O)
282 AC_SUBST(OUTPUT_OPTION)
283
284 # -------------------------
285 # Check C compiler features
286 # -------------------------
287
288 AC_PROG_CPP
289 AC_C_INLINE
290
291 gcc_AC_C_LONG_LONG
292
293 # sizeof(char) is 1 by definition.
294 AC_CHECK_SIZEOF(void *)
295 AC_CHECK_SIZEOF(short)
296 AC_CHECK_SIZEOF(int)
297 AC_CHECK_SIZEOF(long)
298 if test $ac_cv_c_long_long = yes; then
299   AC_CHECK_SIZEOF(long long)
300 fi
301 if test $ac_cv_c___int64 = yes; then
302   AC_CHECK_SIZEOF(__int64)
303 fi
304
305 # ---------------------
306 # Warnings and checking
307 # ---------------------
308
309 # Check $CC warning features (if it's GCC).
310 # We want to use -pedantic, but we don't want warnings about
311 # * 'long long'
312 # * variadic macros
313 # So, we only use -pedantic if we can disable those warnings.
314
315 AC_CACHE_CHECK(
316   [whether ${CC} accepts -Wno-long-long],
317   [ac_cv_prog_cc_w_no_long_long],
318   [save_CFLAGS="$CFLAGS"
319   CFLAGS="-Wno-long-long"
320   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
321                     [ac_cv_prog_cc_w_no_long_long=yes],
322                     [ac_cv_prog_cc_w_no_long_long=no])
323   CFLAGS="$save_CFLAGS"
324   ])
325
326 AC_CACHE_CHECK(
327   [whether ${CC} accepts -Wno-variadic-macros],
328   [ac_cv_prog_cc_w_no_variadic_macros],
329   [save_CFLAGS="$CFLAGS"
330   CFLAGS="-Wno-variadic-macros"
331   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
332                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
333                     [ac_cv_prog_cc_w_no_variadic_macros=no])
334   CFLAGS="$save_CFLAGS"
335   ])
336
337 strict1_warn=
338 if test $ac_cv_prog_cc_w_no_long_long = yes \
339    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
340   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
341 fi
342 AC_SUBST(strict1_warn)
343
344 # Add -Wold-style-definition if it's accepted
345 AC_CACHE_CHECK(
346   [whether ${CC} accepts -Wold-style-definition],
347   [ac_cv_prog_cc_w_old_style_definition],
348   [save_CFLAGS="$CFLAGS"
349   CFLAGS="-Wold-style-definition"
350   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
351                     [ac_cv_prog_cc_w_old_style_definition=yes],
352                     [ac_cv_prog_cc_w_old_style_definition=no])
353   CFLAGS="$save_CFLAGS"
354   ])
355 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
356   strict1_warn="${strict1_warn} -Wold-style-definition"
357 fi
358
359 # Enable -Werror, period.
360 AC_ARG_ENABLE(werror_always, 
361 [  --enable-werror-always         enable -Werror always], [],
362 [enable_werror_always=no])
363 if test x${enable_werror_always} = xyes ; then
364   strict1_warn="${strict1_warn} -Werror"
365   WERROR=-Werror
366 fi
367
368 # If the native compiler is GCC, we can enable warnings even in stage1.  
369 # That's useful for people building cross-compilers, or just running a
370 # quick `make'.
371 warn_cflags=
372 if test "x$GCC" = "xyes"; then
373   warn_cflags='$(GCC_WARN_CFLAGS)'
374 fi
375 AC_SUBST(warn_cflags)
376
377 # Enable -Werror in bootstrap stage2 and later.
378 AC_ARG_ENABLE(werror, 
379 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
380 [if test x$is_release = x ; then
381   # Default to "yes" on development branches.
382   enable_werror=yes
383 else
384   # Default to "no" on release branches.
385   enable_werror=no
386 fi])
387 if test x$enable_werror = xyes ; then
388   WERROR=-Werror
389 fi
390 AC_SUBST(WERROR)
391
392 # Enable expensive internal checks
393 AC_ARG_ENABLE(checking,
394 [  --enable-checking[=LIST]
395                           enable expensive run-time checks.  With LIST,
396                           enable only specific categories of checks.
397                           Categories are: assert,fold,gc,gcac,misc,
398                           rtlflag,rtl,tree,valgrind,release,yes,all;],
399 [ac_checking_flags="${enableval}"],[
400 # Determine the default checks.
401 if test x$is_release = x ; then
402   ac_checking_flags=yes
403 else
404   ac_checking_flags=release
405 fi])
406 ac_assert_checking=1
407 ac_checking=
408 ac_tree_checking=
409 ac_rtl_checking=
410 ac_rtlflag_checking=
411 ac_gc_checking=
412 ac_gc_always_collect=
413 ac_fold_checking=
414 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
415 for check in $ac_checking_flags
416 do
417         case $check in
418         yes)            ac_assert_checking=1 ; ac_checking=1 ;
419                         ac_tree_checking=1 ; ac_gc_checking=1 ;
420                         ac_rtlflag_checking=1 ;;
421         no)             ac_assert_checking= ; ac_checking= ;
422                         ac_tree_checking= ; ac_rtl_checking= ;
423                         ac_rtlflag_checking= ; ac_gc_checking= ;
424                         ac_gc_always_collect= ; ac_fold_checking= ;;
425         all)            ac_assert_checking=1 ; ac_checking=1 ;
426                         ac_tree_checking=1 ; ac_rtl_checking=1 ;
427                         ac_rtlflag_checking=1 ; ac_gc_checking=1 ;
428                         ac_gc_always_collect=1 ; ac_fold_checking=1 ;;
429         release)        ac_assert_checking=1 ;;
430         assert)         ac_assert_checking=1 ;;
431         fold)           ac_fold_checking=1 ;;
432         gc)             ac_gc_checking=1 ;;
433         gcac)           ac_gc_always_collect=1 ;;
434         misc)           ac_checking=1 ;;
435         rtlflag)        ac_rtlflag_checking=1 ;;
436         rtl)            ac_rtl_checking=1 ;;
437         tree)           ac_tree_checking=1 ;;
438         valgrind)       ac_checking_valgrind=1 ;;
439         *)      AC_MSG_ERROR(unknown check category $check) ;;
440         esac
441 done
442 IFS="$ac_save_IFS"
443
444 nocommon_flag=""
445 if test x$ac_checking != x ; then
446   AC_DEFINE(ENABLE_CHECKING, 1,
447 [Define if you want more run-time sanity checks.  This one gets a grab
448    bag of miscellaneous but relatively cheap checks.])
449   nocommon_flag=-fno-common
450 fi
451 AC_SUBST(nocommon_flag)
452 if test x$ac_assert_checking != x ; then
453   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
454 [Define if you want assertions enabled.  This is a cheap check.])
455 fi
456 if test x$ac_tree_checking != x ; then
457   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
458 [Define if you want all operations on trees (the basic data
459    structure of the front ends) to be checked for dynamic type safety
460    at runtime.  This is moderately expensive.  The tree browser debugging
461    routines will also be enabled by this option.
462    ])
463   TREEBROWSER=tree-browser.o
464 fi
465 AC_SUBST(TREEBROWSER)
466 if test x$ac_rtl_checking != x ; then
467   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
468 [Define if you want all operations on RTL (the basic data structure
469    of the optimizer and back end) to be checked for dynamic type safety
470    at runtime.  This is quite expensive.])
471 fi
472 if test x$ac_rtlflag_checking != x ; then
473   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
474 [Define if you want RTL flag accesses to be checked against the RTL
475    codes that are supported for each access macro.  This is relatively
476    cheap.])
477 fi
478 if test x$ac_gc_checking != x ; then
479   AC_DEFINE(ENABLE_GC_CHECKING, 1,
480 [Define if you want the garbage collector to do object poisoning and
481    other memory allocation checks.  This is quite expensive.])
482 fi
483 if test x$ac_gc_always_collect != x ; then
484   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
485 [Define if you want the garbage collector to operate in maximally
486    paranoid mode, validating the entire heap and collecting garbage at
487    every opportunity.  This is extremely expensive.])
488 fi
489 if test x$ac_fold_checking != x ; then
490   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
491 [Define if you want fold checked that it never destructs its argument.
492    This is quite expensive.])
493 fi
494 valgrind_path_defines=
495 valgrind_command=
496
497 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
498 dnl # an if statement.  This was the source of very frustrating bugs
499 dnl # in converting to autoconf 2.5x!
500 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
501
502 if test x$ac_checking_valgrind != x ; then
503   # It is certainly possible that there's valgrind but no valgrind.h.
504   # GCC relies on making annotations so we must have both.
505   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
506   AC_TRY_CPP(
507     [#include <valgrind/memcheck.h>
508 #ifndef VALGRIND_DISCARD
509 #error VALGRIND_DISCARD not defined
510 #endif],
511   [gcc_cv_header_valgrind_memcheck_h=yes],
512   [gcc_cv_header_valgrind_memcheck_h=no])
513   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
514   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
515   AC_TRY_CPP(
516     [#include <memcheck.h>
517 #ifndef VALGRIND_DISCARD
518 #error VALGRIND_DISCARD not defined
519 #endif],
520   [gcc_cv_header_memcheck_h=yes], 
521   gcc_cv_header_memcheck_h=no)
522   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
523   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
524         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
525   if test "x$valgrind_path" = "x" \
526     || (test $have_valgrind_h = no \
527         && test $gcc_cv_header_memcheck_h = no \
528         && test $gcc_cv_header_valgrind_memcheck_h = no); then
529         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
530   fi
531   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
532   valgrind_command="$valgrind_path -q"
533   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
534 [Define if you want to run subprograms and generated programs
535    through valgrind (a memory checker).  This is extremely expensive.])
536   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
537     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
538         [Define if valgrind's valgrind/memcheck.h header is installed.])
539   fi
540   if test $gcc_cv_header_memcheck_h = yes; then
541     AC_DEFINE(HAVE_MEMCHECK_H, 1,
542         [Define if valgrind's memcheck.h header is installed.])
543   fi
544 fi
545 AC_SUBST(valgrind_path_defines)
546 AC_SUBST(valgrind_command)
547
548 AC_ARG_ENABLE(mapped-location,
549 [  --enable-mapped-location   location_t is fileline integer cookie],,
550 enable_mapped_location=no)
551
552 if test "$enable_mapped_location" = yes ; then
553   AC_DEFINE(USE_MAPPED_LOCATION, 1,
554 [Define if location_t is fileline integer cookie.])
555 fi
556
557 # Enable code coverage collection
558 AC_ARG_ENABLE(coverage,
559 [  --enable-coverage[=LEVEL]
560                           enable compiler's code coverage collection.
561                           Use to measure compiler performance and locate
562                           unused parts of the compiler. With LEVEL, specify
563                           optimization. Values are opt, noopt,
564                           default is noopt],
565 [case "${enableval}" in
566   yes|noopt)
567     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
568     ;;
569   opt)
570     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
571     ;;
572   no)
573     # a.k.a. --disable-coverage
574     coverage_flags=""
575     ;;
576   *)
577     AC_MSG_ERROR(unknown coverage setting $enableval)
578     ;;
579 esac],
580 [coverage_flags=""])
581 AC_SUBST(coverage_flags)
582
583 AC_ARG_ENABLE(gather-detailed-mem-stats, 
584 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
585 [enable_gather_detailed_mem_stats=no])
586 if test x$enable_gather_detailed_mem_stats = xyes ; then
587   AC_DEFINE(GATHER_STATISTICS, 1,
588         [Define to enable detailed memory allocation stats gathering.])
589 fi
590
591 # -------------------------------
592 # Miscenalleous configure options
593 # -------------------------------
594
595 # With stabs
596 AC_ARG_WITH(stabs,
597 [  --with-stabs            arrange to use stabs instead of host debug format],
598 stabs="$with_stabs",
599 stabs=no)
600
601 # Determine whether or not multilibs are enabled.
602 AC_ARG_ENABLE(multilib,
603 [  --enable-multilib       enable library support for multiple ABIs],
604 [], [enable_multilib=yes])
605 AC_SUBST(enable_multilib)
606
607 # Enable __cxa_atexit for C++.
608 AC_ARG_ENABLE(__cxa_atexit,
609 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
610 [], [])
611
612 # Enable threads
613 # Pass with no value to take the default
614 # Pass with a value to specify a thread package
615 AC_ARG_ENABLE(threads,
616 [  --enable-threads        enable thread usage for target GCC
617   --enable-threads=LIB    use LIB thread package for target GCC],,
618 [enable_threads=''])
619
620 AC_ARG_ENABLE(objc-gc,
621 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
622                           the GNU Objective-C runtime],
623 if test x$enable_objc_gc = xno; then
624         objc_boehm_gc=''
625 else
626         objc_boehm_gc=1
627 fi,
628 objc_boehm_gc='')
629
630 AC_ARG_WITH(dwarf2,
631 [  --with-dwarf2           force the default debug format to be DWARF 2],
632 dwarf2="$with_dwarf2",
633 dwarf2=no)
634
635 AC_ARG_ENABLE(shared,
636 [  --disable-shared        don't provide a shared libgcc],
637 [
638   case $enable_shared in
639   yes | no) ;;
640   *)
641     enable_shared=no
642     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
643     for pkg in $enableval; do
644       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
645         enable_shared=yes
646       fi
647     done
648     IFS="$ac_save_ifs"
649     ;;
650   esac
651 ], [enable_shared=yes])
652 AC_SUBST(enable_shared)
653
654 AC_ARG_WITH(sysroot,
655 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
656 [
657  case ${with_sysroot} in
658  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
659  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
660  esac
661    
662  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
663  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
664
665  if test "x$exec_prefix" = xNONE; then
666   if test "x$prefix" = xNONE; then
667    test_prefix=/usr/local
668   else
669    test_prefix=$prefix
670   fi
671  else
672   test_prefix=$exec_prefix
673  fi
674  case ${TARGET_SYSTEM_ROOT} in
675  "${test_prefix}"|"${test_prefix}/"*|\
676  '${exec_prefix}'|'${exec_prefix}/'*)
677    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
678    TARGET_SYSTEM_ROOT_DEFINE="$t"
679    ;;
680  esac
681 ], [
682  TARGET_SYSTEM_ROOT=
683  TARGET_SYSTEM_ROOT_DEFINE=
684  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
685 ])
686 AC_SUBST(TARGET_SYSTEM_ROOT)
687 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
688 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
689
690 # Build with intermodule optimisations
691 AC_ARG_ENABLE(intermodule,
692 [  --enable-intermodule    build the compiler in one step],
693 [case ${enable_intermodule} in
694   yes) onestep="-onestep";;
695   *) onestep="";;
696 esac],
697 [onestep=""])
698 AC_SUBST(onestep)
699
700 # Sanity check enable_languages in case someone does not run the toplevel
701 # configure # script.
702 AC_ARG_ENABLE(languages,
703 [  --enable-languages=LIST specify which front-ends to build],
704 [case ,${enable_languages}, in
705        ,,|,yes,)
706                 # go safe -- we cannot be much sure without the toplevel
707                 # configure's
708                 # analysis of which target libs are present and usable
709                 enable_languages=c
710                 ;;
711          *,all,*)
712                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
713                 ;;
714         *,c,*)
715                 ;;
716         *)
717                 enable_languages=c,${enable_languages}
718                 ;;
719 esac],
720 [enable_languages=c])
721
722 subdirs=
723 for lang in ${srcdir}/*/config-lang.in
724 do
725         case $lang in
726         # The odd quoting in the next line works around
727         # an apparent bug in bash 1.12 on linux.
728 changequote(,)dnl
729         ${srcdir}/[*]/config-lang.in) ;;
730         *)
731           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
732           if test "x$lang_alias" = x
733           then
734                 echo "$lang doesn't set \$language." 1>&2
735                 exit 1
736           fi
737           case ",$enable_languages," in
738           *,$lang_alias,*)
739             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
740           esac
741           ;;
742 changequote([,])dnl
743         esac
744 done
745
746
747 # -------------------------
748 # Checks for other programs
749 # -------------------------
750
751 AC_PROG_MAKE_SET
752
753 # Find some useful tools
754 AC_PROG_AWK
755 # We need awk to create options.c and options.h.
756 # Bail out if it's missing.
757 case ${AWK} in
758   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
759 esac
760
761 gcc_AC_PROG_LN_S
762 ACX_PROG_LN($LN_S)
763 AC_PROG_RANLIB
764 case "${host}" in
765 *-*-darwin*)
766   # By default, the Darwin ranlib will not treat common symbols as
767   # definitions when  building the archive table of contents.  Other 
768   # ranlibs do that; pass an option to the Darwin ranlib that makes
769   # it behave similarly.
770   ranlib_flags="-c" 
771   ;;
772 *)
773   ranlib_flags=""
774 esac
775 AC_SUBST(ranlib_flags)
776      
777 gcc_AC_PROG_INSTALL
778
779 # See if cmp has --ignore-initial.
780 gcc_AC_PROG_CMP_IGNORE_INITIAL
781
782 # See if we have the mktemp command.
783 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
784
785 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
786
787 # See if makeinfo has been installed and is modern enough
788 # that we can use it.
789 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
790   [GNU texinfo.* \([0-9][0-9.]*\)],
791   [4.[2-9]*])
792 if test $gcc_cv_prog_makeinfo_modern = no; then
793   MAKEINFO="$MISSING makeinfo"
794   AC_MSG_WARN([
795 *** Makeinfo is missing or too old.
796 *** Info documentation will not be built.])
797   BUILD_INFO=
798 else
799   BUILD_INFO=info
800 fi
801 AC_SUBST(BUILD_INFO)
802
803 # Is pod2man recent enough to regenerate manpages?
804 AC_MSG_CHECKING([for recent Pod::Man])
805 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
806   AC_MSG_RESULT(yes)
807   GENERATED_MANPAGES=generated-manpages
808 else
809   AC_MSG_RESULT(no)
810   GENERATED_MANPAGES=
811 fi
812 AC_SUBST(GENERATED_MANPAGES)
813
814 # How about lex?
815 dnl Don't use AC_PROG_LEX; we insist on flex.
816 dnl LEXLIB is not useful in gcc.
817 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
818
819 # Bison?
820 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
821
822 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
823 # check for build == host before using them.
824
825 # NM
826 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
827   && test -d ../binutils ; then
828   NM='$(objdir)/../binutils/nm-new'
829 else
830   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
831 fi
832
833 # AR
834 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
835   && test -d ../binutils ; then
836   AR='$(objdir)/../binutils/ar'
837 else
838   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
839 fi
840
841
842 # --------------------
843 # Checks for C headers
844 # --------------------
845
846 AC_MSG_CHECKING(for GNU C library)
847 AC_CACHE_VAL(gcc_cv_glibc,
848 [AC_TRY_COMPILE(
849   [#include <features.h>],[
850 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
851 #error Not a GNU C library system
852 #endif], 
853   [gcc_cv_glibc=yes], 
854   gcc_cv_glibc=no)])
855 AC_MSG_RESULT($gcc_cv_glibc)
856 if test $gcc_cv_glibc = yes; then
857   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
858 fi
859
860 # Need to reject headers which give warnings, so that the -Werror bootstrap
861 # works later. *sigh*  This needs to come before all header checks.
862 AC_PROG_CPP_WERROR
863
864 AC_HEADER_STDC
865 AC_HEADER_TIME
866 ACX_HEADER_STRING
867 AC_HEADER_SYS_WAIT
868 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
869                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
870                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
871                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
872
873 # Check for thread headers.
874 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
875 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
876
877 # These tests can't be done till we know if we have limits.h.
878 gcc_AC_C_CHAR_BIT
879 AC_C_BIGENDIAN_CROSS
880
881 # --------
882 # UNSORTED
883 # --------
884
885 # Stage specific cflags for build.
886 stage1_cflags=
887 case $build in
888 vax-*-*)
889   if test x$GCC = xyes
890   then
891     stage1_cflags="-Wa,-J"
892   else
893     stage1_cflags="-J"
894   fi
895   ;;
896 powerpc-*-darwin*)
897   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
898   # sources; use -no-cpp-precomp to get to GNU cpp.
899   # Apple's GCC has bugs in designated initializer handling, so disable
900   # that too.
901   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
902   ;;
903 esac
904 AC_SUBST(stage1_cflags)
905
906 # These libraries may be used by collect2.
907 # We may need a special search path to get them linked.
908 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
909 [save_LIBS="$LIBS"
910 for libs in '' -lld -lmld \
911                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
912                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
913 do
914         LIBS="$libs"
915         AC_TRY_LINK_FUNC(ldopen,
916                 [gcc_cv_collect2_libs="$libs"; break])
917 done
918 LIBS="$save_LIBS"
919 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
920 case $gcc_cv_collect2_libs in
921         "none required")        ;;
922         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
923 esac
924 AC_SUBST(COLLECT2_LIBS)
925
926 # When building Ada code on Alpha, we need exc_resume which is usually in
927 # -lexc.  So test for it.
928 save_LIBS="$LIBS"
929 LIBS=
930 AC_SEARCH_LIBS(exc_resume, exc)
931 GNAT_LIBEXC="$LIBS"
932 LIBS="$save_LIBS"
933 AC_SUBST(GNAT_LIBEXC)
934
935 # Some systems put ldexp and frexp in libm instead of libc; assume
936 # they're both in the same place.  jcf-dump needs them.
937 save_LIBS="$LIBS"
938 LIBS=
939 AC_SEARCH_LIBS(ldexp, m)
940 LDEXP_LIB="$LIBS"
941 LIBS="$save_LIBS"
942 AC_SUBST(LDEXP_LIB)
943
944 # Use <inttypes.h> only if it exists,
945 # doesn't clash with <sys/types.h>, and declares intmax_t.
946 AC_MSG_CHECKING(for inttypes.h)
947 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
948 [AC_TRY_COMPILE(
949   [#include <sys/types.h>
950 #include <inttypes.h>],
951   [intmax_t i = -1;],
952   [gcc_cv_header_inttypes_h=yes],
953   gcc_cv_header_inttypes_h=no)])
954 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
955 if test $gcc_cv_header_inttypes_h = yes; then
956   AC_DEFINE(HAVE_INTTYPES_H, 1,
957         [Define if you have a working <inttypes.h> header file.])
958 fi
959
960 dnl Disabled until we have a complete test for buggy enum bitfields.
961 dnl gcc_AC_C_ENUM_BF_UNSIGNED
962
963 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
964         sysconf strsignal putc_unlocked fputc_unlocked fputs_unlocked \
965         fwrite_unlocked fprintf_unlocked getrusage nl_langinfo \
966         scandir alphasort gettimeofday mbstowcs wcswidth mmap mincore \
967         setlocale)
968
969 if test x$ac_cv_func_mbstowcs = xyes; then
970   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
971 [    AC_TRY_RUN([#include <stdlib.h>
972 int main()
973 {
974   mbstowcs(0, "", 0);
975   return 0;
976 }],
977     gcc_cv_func_mbstowcs_works=yes,
978     gcc_cv_func_mbstowcs_works=no,
979     gcc_cv_func_mbstowcs_works=yes)])
980   if test x$gcc_cv_func_mbstowcs_works = xyes; then
981     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
982   [Define this macro if mbstowcs does not crash when its
983    first argument is NULL.])
984   fi
985 fi
986
987 AC_CHECK_TYPE(ssize_t, int)
988
989 # Try to determine the array type of the second argument of getgroups
990 # for the target system (int or gid_t).
991 AC_TYPE_GETGROUPS
992 if test "${target}" = "${build}"; then
993   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
994 else
995   case "${target}" in
996         # This condition may need some tweaking.  It should include all
997         # targets where the array type of the second argument of getgroups
998         # is int and the type of gid_t is not equivalent to int.
999         *-*-sunos* | *-*-ultrix*)
1000                 TARGET_GETGROUPS_T=int
1001                 ;;
1002         *)
1003                 TARGET_GETGROUPS_T=gid_t
1004                 ;;
1005   esac
1006 fi
1007 AC_SUBST(TARGET_GETGROUPS_T)
1008
1009 gcc_AC_FUNC_PRINTF_PTR
1010 gcc_AC_FUNC_MMAP_BLACKLIST
1011
1012 case "${host}" in
1013 *-*-*vms*)
1014   # Under VMS, vfork works very differently than on Unix. The standard test 
1015   # won't work, and it isn't easily adaptable. It makes more sense to
1016   # just force it.
1017   ac_cv_func_vfork_works=yes
1018   ;;
1019 esac
1020 AC_FUNC_VFORK
1021
1022 AM_ICONV
1023 # Until we have in-tree GNU iconv:
1024 LIBICONV_DEP=
1025 AC_SUBST(LIBICONV_DEP)
1026
1027 AM_LC_MESSAGES
1028
1029 AM_LANGINFO_CODESET
1030
1031 # We will need to find libiberty.h and ansidecl.h
1032 saved_CFLAGS="$CFLAGS"
1033 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1034 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd \
1035         strsignal putc_unlocked fputs_unlocked fwrite_unlocked \
1036         fprintf_unlocked strstr errno snprintf vasprintf \
1037         malloc realloc calloc free basename getopt clock getpagesize, , ,[
1038 #include "ansidecl.h"
1039 #include "system.h"])
1040
1041 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1042 #include "ansidecl.h"
1043 #include "system.h"
1044 #ifdef HAVE_SYS_RESOURCE_H
1045 #include <sys/resource.h>
1046 #endif
1047 ])
1048
1049 AC_TRY_COMPILE([
1050 #include "ansidecl.h"
1051 #include "system.h"
1052 #ifdef HAVE_SYS_RESOURCE_H
1053 #include <sys/resource.h>
1054 #endif
1055 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1056 [Define to \`long' if <sys/resource.h> doesn't define.])])
1057
1058 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1059 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1060 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1061 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1062 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1063 #include "ansidecl.h"
1064 #include "system.h"
1065 #ifdef HAVE_LDFCN_H
1066 #undef FREAD
1067 #undef FWRITE
1068 #include <ldfcn.h>
1069 #endif
1070 ])
1071
1072 gcc_AC_CHECK_DECLS(times, , ,[
1073 #include "ansidecl.h"
1074 #include "system.h"
1075 #ifdef HAVE_SYS_TIMES_H
1076 #include <sys/times.h>
1077 #endif
1078 ])
1079
1080 # More time-related stuff.
1081 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1082 AC_TRY_COMPILE([
1083 #include "ansidecl.h"
1084 #include "system.h"
1085 #ifdef HAVE_SYS_TIMES_H
1086 #include <sys/times.h>
1087 #endif
1088 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1089 if test $ac_cv_struct_tms = yes; then
1090   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1091   [Define if <sys/times.h> defines struct tms.])
1092 fi
1093
1094 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1095 # revisit after autoconf 2.50.
1096 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1097 AC_TRY_COMPILE([
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1101 if test $gcc_cv_type_clock_t = yes; then
1102   AC_DEFINE(HAVE_CLOCK_T, 1,
1103   [Define if <time.h> defines clock_t.])
1104 fi
1105
1106 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1107 CFLAGS="$saved_CFLAGS"
1108
1109 gcc_AC_INITFINI_ARRAY
1110
1111 # mkdir takes a single argument on some systems. 
1112 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1113
1114 # File extensions
1115 manext='.1'
1116 objext='.o'
1117 AC_SUBST(manext)
1118 AC_SUBST(objext)
1119
1120 # With Setjmp/Longjmp based exception handling.
1121 AC_ARG_ENABLE(sjlj-exceptions,
1122 [  --enable-sjlj-exceptions
1123                           arrange to use setjmp/longjmp exception handling],
1124 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1125 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1126   [Define 0/1 to force the choice for exception handling model.])])
1127
1128 # For platforms with the unwind ABI which includes an unwind library,
1129 # libunwind, we can choose to use the system libunwind.
1130 AC_ARG_WITH(system-libunwind,
1131 [  --with-system-libunwind use installed libunwind])
1132
1133 # --------------------------------------------------------
1134 # Build, host, and target specific configuration fragments
1135 # --------------------------------------------------------
1136
1137 # Collect build-machine-specific information.
1138 . ${srcdir}/config.build
1139
1140 # Collect host-machine-specific information.
1141 . ${srcdir}/config.host
1142
1143 target_gtfiles=
1144
1145 # Collect target-machine-specific information.
1146 . ${srcdir}/config.gcc
1147
1148 extra_objs="${host_extra_objs} ${extra_objs}"
1149 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1150
1151 # Default the target-machine variables that were not explicitly set.
1152 if test x"$tm_file" = x
1153 then tm_file=$cpu_type/$cpu_type.h; fi
1154
1155 if test x"$extra_headers" = x
1156 then extra_headers=; fi
1157
1158 if test x$md_file = x
1159 then md_file=$cpu_type/$cpu_type.md; fi
1160
1161 if test x$out_file = x
1162 then out_file=$cpu_type/$cpu_type.c; fi
1163
1164 if test x"$tmake_file" = x
1165 then tmake_file=$cpu_type/t-$cpu_type
1166 fi
1167
1168 if test x"$dwarf2" = xyes
1169 then tm_file="$tm_file tm-dwarf2.h"
1170 fi
1171
1172 # Say what files are being used for the output code and MD file.
1173 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1174 echo "Using \`$srcdir/config/$md_file' as machine description file."
1175
1176 # If any of the xm_file variables contain nonexistent files, warn
1177 # about them and drop them.
1178
1179 bx=
1180 for x in $build_xm_file; do
1181   if    test -f $srcdir/config/$x
1182   then      bx="$bx $x"
1183   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1184   fi
1185 done
1186 build_xm_file="$bx"
1187
1188 hx=
1189 for x in $host_xm_file; do
1190   if    test -f $srcdir/config/$x
1191   then      hx="$hx $x"
1192   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1193   fi
1194 done
1195 host_xm_file="$hx"
1196
1197 tx=
1198 for x in $xm_file; do
1199   if    test -f $srcdir/config/$x
1200   then      tx="$tx $x"
1201   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1202   fi
1203 done
1204 xm_file="$tx"
1205
1206 count=a
1207 for f in $tm_file; do
1208         count=${count}x
1209 done
1210 if test $count = ax; then
1211         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1212 else
1213         echo "Using the following target machine macro files:"
1214         for f in $tm_file; do
1215                 echo "  $srcdir/config/$f"
1216         done
1217 fi
1218
1219 if test x$need_64bit_hwint = xyes; then
1220         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1221 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1222 fi
1223
1224 if test x$use_long_long_for_widest_fast_int = xyes; then
1225         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1226 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1227 efficiently supported by the host hardware.])
1228 fi
1229
1230 count=a
1231 for f in $host_xm_file; do
1232         count=${count}x
1233 done
1234 if test $count = a; then
1235         :
1236 elif test $count = ax; then
1237         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1238 else
1239         echo "Using the following host machine macro files:"
1240         for f in $host_xm_file; do
1241                 echo "  $srcdir/config/$f"
1242         done
1243 fi
1244 echo "Using ${out_host_hook_obj} for host machine hooks."
1245
1246 if test "$host_xm_file" != "$build_xm_file"; then
1247         count=a
1248         for f in $build_xm_file; do
1249                 count=${count}x
1250         done
1251         if test $count = a; then
1252                 :
1253         elif test $count = ax; then
1254                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1255         else
1256                 echo "Using the following build machine macro files:"
1257                 for f in $build_xm_file; do
1258                         echo "  $srcdir/config/$f"
1259                 done
1260         fi
1261 fi
1262
1263 # ---------
1264 # Threading
1265 # ---------
1266
1267 # Check if a valid thread package
1268 case ${enable_threads} in
1269   "" | no)
1270     # No threads
1271     target_thread_file='single'
1272     ;;
1273   yes)
1274     # default
1275     target_thread_file='single'
1276     ;;
1277   aix | dce | gnat | irix | posix | posix95 | rtems | \
1278   single | solaris | vxworks | win32 )
1279     target_thread_file=${enable_threads}
1280     ;;
1281   *)
1282     echo "${enable_threads} is an unknown thread package" 1>&2
1283     exit 1
1284     ;;
1285 esac
1286
1287 if test x${thread_file} = x; then
1288   # No thread file set by target-specific clauses in config.gcc,
1289   # so use file chosen by default logic above
1290   thread_file=${target_thread_file}
1291 fi
1292
1293 # Make gthr-default.h if we have a thread file.
1294 gthread_flags=
1295 if test $thread_file != single; then
1296   rm -f gthr-default.h
1297   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1298   gthread_flags=-DHAVE_GTHR_DEFAULT
1299 fi
1300 AC_SUBST(gthread_flags)
1301
1302 # --------
1303 # UNSORTED
1304 # --------
1305
1306 use_cxa_atexit=no
1307 if test x$enable___cxa_atexit = xyes || \
1308    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1309   if test x$host = x$target; then
1310     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1311         [echo "__cxa_atexit can't be enabled on this target"])
1312   else
1313     # We can't check for __cxa_atexit when building a cross, so assume
1314     # it is available 
1315     use_cxa_atexit=yes
1316   fi
1317   if test x$use_cxa_atexit = xyes; then
1318     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1319       [Define if you want to use __cxa_atexit, rather than atexit, to
1320       register C++ destructors for local statics and global objects.
1321       This is essential for fully standards-compliant handling of
1322       destructors, but requires __cxa_atexit in libc.])
1323   fi
1324 fi
1325
1326 # Look for a file containing extra machine modes.
1327 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1328   extra_modes_file='$(srcdir)'/config/${extra_modes}
1329   AC_SUBST(extra_modes_file)
1330   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1331   [Define to the name of a file containing a list of extra machine modes
1332    for this architecture.])
1333 fi
1334
1335 # auto-host.h is the file containing items generated by autoconf and is
1336 # the first file included by config.h.
1337 # If host=build, it is correct to have bconfig include auto-host.h
1338 # as well.  If host!=build, we are in error and need to do more 
1339 # work to find out the build config parameters.
1340 if test x$host = x$build
1341 then
1342         build_auto=auto-host.h
1343 else
1344         # We create a subdir, then run autoconf in the subdir.
1345         # To prevent recursion we set host and build for the new
1346         # invocation of configure to the build for this invocation
1347         # of configure. 
1348         tempdir=build.$$
1349         rm -rf $tempdir
1350         mkdir $tempdir
1351         cd $tempdir
1352         case ${srcdir} in
1353         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1354         *) realsrcdir=../${srcdir};;
1355         esac
1356         saved_CFLAGS="${CFLAGS}"
1357         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1358         ${realsrcdir}/configure \
1359                 --enable-languages=${enable_languages-all} \
1360                 --target=$target_alias --host=$build_alias --build=$build_alias
1361         CFLAGS="${saved_CFLAGS}"
1362
1363         # We just finished tests for the build machine, so rename
1364         # the file auto-build.h in the gcc directory.
1365         mv auto-host.h ../auto-build.h
1366         cd ..
1367         rm -rf $tempdir
1368         build_auto=auto-build.h
1369 fi
1370 AC_SUBST(build_subdir)
1371
1372 tm_file="${tm_file} defaults.h"
1373 tm_p_file="${tm_p_file} tm-preds.h"
1374 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1375 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1376 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1377 # put this back in temporarily.
1378 xm_file="ansidecl.h ${xm_file}"
1379
1380 # --------
1381 # UNSORTED
1382 # --------
1383
1384 changequote(,)dnl
1385 # Compile in configure arguments.
1386 if test -f configargs.h ; then
1387         # Being re-configured.
1388         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1389         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1390 else
1391         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1392 fi
1393
1394 # Double all backslashes and backslash all quotes to turn
1395 # gcc_config_arguments into a C string.
1396 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1397 $gcc_config_arguments
1398 EOF
1399 gcc_config_arguments_str=`cat conftest.out`
1400 rm -f conftest.out
1401
1402 cat > configargs.h <<EOF
1403 /* Generated automatically. */
1404 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1405 static const char thread_model[] = "$thread_file";
1406
1407 static const struct {
1408   const char *name, *value;
1409 } configure_default_options[] = $configure_default_options;
1410 EOF
1411 changequote([,])dnl
1412
1413 # Internationalization
1414 PACKAGE=gcc
1415 VERSION="$gcc_version"
1416 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE",
1417   [The name of this program for internationalization purposes.])
1418 AC_SUBST(PACKAGE)
1419 AC_SUBST(VERSION)
1420
1421 ZW_GNU_GETTEXT_SISTER_DIR
1422
1423 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1424 # -liconv on the link line twice.
1425 case "$LIBINTL" in *$LIBICONV*)
1426         LIBICONV= ;;
1427 esac
1428
1429 # Windows32 Registry support for specifying GCC installation paths.
1430 AC_ARG_ENABLE(win32-registry,
1431 [  --disable-win32-registry
1432                           disable lookup of installation paths in the
1433                           Registry on Windows hosts
1434   --enable-win32-registry enable registry lookup (default)
1435   --enable-win32-registry=KEY
1436                           use KEY instead of GCC version as the last portion
1437                           of the registry key],,)
1438 case $host_os in
1439         win32 | pe | cygwin* | mingw32* | uwin*)
1440 AC_MSG_CHECKING(whether windows registry support is requested)
1441 if test "x$enable_win32_registry" != xno; then
1442   AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1443 [Define to 1 if installation paths should be looked up in Windows32
1444    Registry. Ignored on non windows32 hosts.])
1445   AC_MSG_RESULT(yes)
1446   AC_SEARCH_LIBS(RegOpenKeyExA, advapi32)
1447 else
1448   AC_MSG_RESULT(no)
1449 fi
1450
1451 # Check if user specified a different registry key.
1452 case "x${enable_win32_registry}" in
1453 x | xyes)
1454   # default.
1455   gcc_cv_win32_registry_key="$VERSION"
1456   ;;
1457 xno)
1458   # no registry lookup.
1459   gcc_cv_win32_registry_key=''
1460   ;;
1461 *)
1462   # user-specified key.
1463   gcc_cv_win32_registry_key="$enable_win32_registry"
1464   ;;
1465 esac
1466
1467 if test "x$enable_win32_registry" != xno; then
1468   AC_MSG_CHECKING(registry key on windows hosts)
1469   AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$gcc_cv_win32_registry_key",
1470         [Define to be the last portion of registry key on windows hosts.])
1471   AC_MSG_RESULT($gcc_cv_win32_registry_key)
1472 fi
1473 ;;
1474 esac
1475
1476 # Get an absolute path to the GCC top-level source directory
1477 holddir=`${PWDCMD-pwd}`
1478 cd $srcdir
1479 topdir=`${PWDCMD-pwd}`
1480 cd $holddir
1481
1482 # Conditionalize the makefile for this host machine.
1483 xmake_file=
1484 for f in ${host_xmake_file}
1485 do
1486         if test -f ${srcdir}/config/$f
1487         then
1488                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1489         fi
1490 done
1491
1492 # Conditionalize the makefile for this target machine.
1493 tmake_file_=
1494 for f in ${tmake_file}
1495 do
1496         if test -f ${srcdir}/config/$f
1497         then
1498                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1499         fi
1500 done
1501 tmake_file="${tmake_file_}"
1502
1503 # If the host doesn't support symlinks, modify CC in
1504 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1505 # Otherwise, we can use "CC=$(CC)".
1506 rm -f symtest.tem
1507 case "$LN_S" in
1508         *-s*)
1509                 cc_set_by_configure="\$(CC)"
1510                 quoted_cc_set_by_configure="\$(CC)"
1511                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1512                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1513                 ;;
1514         *)
1515                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1516                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1517                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1518                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1519                 ;;
1520 esac
1521
1522 # This is a terrible hack which will go away some day.
1523 host_cc_for_libada=${CC}
1524 AC_SUBST(host_cc_for_libada)
1525
1526 out_object_file=`basename $out_file .c`.o
1527
1528 tm_file_list=
1529 tm_include_list=
1530 for f in $tm_file; do
1531   case $f in
1532     defaults.h )
1533        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1534        tm_include_list="${tm_include_list} $f"
1535        ;;
1536     * )
1537        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1538        tm_include_list="${tm_include_list} config/$f"
1539        ;;
1540   esac
1541 done
1542
1543 tm_p_file_list=
1544 tm_p_include_list=
1545 for f in $tm_p_file; do
1546   case $f in
1547     tm-preds.h )
1548        tm_p_file_list="${tm_p_file_list} $f"
1549        tm_p_include_list="${tm_p_include_list} $f"
1550        ;;
1551     * )
1552        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1553        tm_p_include_list="${tm_p_include_list} config/$f"
1554   esac
1555 done
1556
1557 xm_file_list=
1558 xm_include_list=
1559 for f in $xm_file; do
1560   case $f in
1561     ansidecl.h )
1562        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1563        xm_include_list="${xm_include_list} $f"
1564        ;;
1565     auto-host.h )
1566        xm_file_list="${xm_file_list} $f"
1567        xm_include_list="${xm_include_list} $f"
1568        ;;
1569     * )
1570        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1571        xm_include_list="${xm_include_list} config/$f"
1572        ;;
1573   esac
1574 done
1575
1576 host_xm_file_list=
1577 host_xm_include_list=
1578 for f in $host_xm_file; do
1579   case $f in
1580     ansidecl.h )
1581        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1582        host_xm_include_list="${host_xm_include_list} $f"
1583        ;;
1584     auto-host.h )
1585        host_xm_file_list="${host_xm_file_list} $f"
1586        host_xm_include_list="${host_xm_include_list} $f"
1587        ;;
1588     * )
1589        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1590        host_xm_include_list="${host_xm_include_list} config/$f"
1591        ;;
1592   esac
1593 done
1594
1595 build_xm_file_list=
1596 for f in $build_xm_file; do
1597   case $f in
1598     ansidecl.h )
1599        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1600        build_xm_include_list="${build_xm_include_list} $f"
1601        ;;
1602     auto-build.h | auto-host.h )
1603        build_xm_file_list="${build_xm_file_list} $f"
1604        build_xm_include_list="${build_xm_include_list} $f"
1605        ;;
1606     * )
1607        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1608        build_xm_include_list="${build_xm_include_list} config/$f"
1609        ;;
1610   esac
1611 done
1612
1613 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1614 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1615 CROSS=                                          AC_SUBST(CROSS)
1616 ALL=all.internal                                AC_SUBST(ALL)
1617 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1618 if test x$host != x$target
1619 then
1620         CROSS="-DCROSS_COMPILE"
1621         ALL=all.cross
1622         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1623         case "$host","$target" in
1624         # Darwin crosses can use the host system's libraries and headers,
1625         # because of the fat library support.  Of course, it must be the
1626         # same version of Darwin on both sides.  Allow the user to
1627         # just say --target=foo-darwin without a version number to mean
1628         # "the version on this system".
1629             *-*-darwin*,*-*-darwin*)
1630                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1631                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1632                 if test $hostos = $targetos -o $targetos = darwin ; then
1633                     CROSS=
1634                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1635                     with_headers=yes
1636                 fi
1637                 ;;
1638
1639             i?86-*-*,x86_64-*-* \
1640             | powerpc*-*-*,powerpc64*-*-*)
1641                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1642         esac
1643 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1644         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1645         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1646 fi
1647
1648 # If this is a cross-compiler that does not
1649 # have its own set of headers then define
1650 # inhibit_libc
1651
1652 # If this is using newlib, without having the headers available now,
1653 # then define inhibit_libc in LIBGCC2_CFLAGS.
1654 # This prevents libgcc2 from containing any code which requires libc
1655 # support.
1656 inhibit_libc=
1657 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1658        test x$with_newlib = xyes ; } &&
1659      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1660        inhibit_libc=-Dinhibit_libc
1661 fi
1662 AC_SUBST(inhibit_libc)
1663
1664 # When building gcc with a cross-compiler, we need to adjust things so
1665 # that the generator programs are still built with the native compiler.
1666 # Also, we cannot run fixincludes or fix-header.
1667
1668 # These are the normal (build=host) settings:
1669 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1670 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1671 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1672
1673 # Possibly disable fixproto, on a per-target basis.
1674 case ${use_fixproto} in
1675   no)
1676     STMP_FIXPROTO=
1677     ;;
1678   yes)
1679     STMP_FIXPROTO=stmp-fixproto
1680     ;;
1681 esac
1682 AC_SUBST(STMP_FIXPROTO)
1683
1684 # And these apply if build != host, or we are generating coverage data
1685 if test x$build != x$host || test "x$coverage_flags" != x
1686 then
1687     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1688
1689     if test "x$TARGET_SYSTEM_ROOT" = x; then
1690         if [ "x$STMP_FIXPROTO" != x ] ; then
1691           STMP_FIXPROTO=stmp-install-fixproto
1692         fi
1693     fi
1694 fi
1695
1696 # Expand extra_headers to include complete path.
1697 # This substitutes for lots of t-* files.
1698 extra_headers_list=
1699 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1700 for file in ${extra_headers} ; do
1701   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1702 done
1703
1704 # Define collect2 in Makefile.
1705 case $host_can_use_collect2 in
1706   no) collect2= ;;
1707   *) collect2='collect2$(exeext)' ;;
1708 esac
1709 AC_SUBST([collect2])
1710
1711 # Add a definition of USE_COLLECT2 if system wants one.
1712 case $use_collect2 in
1713   no) use_collect2= ;;
1714   "") ;;
1715   *) 
1716     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1717     xm_defines="${xm_defines} USE_COLLECT2"
1718     case $host_can_use_collect2 in
1719       no)
1720         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1721         ;;
1722     esac
1723     ;;
1724 esac
1725
1726 # ---------------------------
1727 # Assembler & linker features
1728 # ---------------------------
1729
1730 # Identify the assembler which will work hand-in-glove with the newly
1731 # built GCC, so that we can examine its features.  This is the assembler
1732 # which will be driven by the driver program.
1733 #
1734 # If build != host, and we aren't building gas in-tree, we identify a
1735 # build->target assembler and hope that it will have the same features
1736 # as the host->target assembler we'll be using.
1737 AC_MSG_CHECKING(what assembler to use)
1738 in_tree_gas=no
1739 gcc_cv_as=
1740 gcc_cv_gas_major_version=
1741 gcc_cv_gas_minor_version=
1742 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1743 if test -x "$DEFAULT_ASSEMBLER"; then
1744         gcc_cv_as="$DEFAULT_ASSEMBLER"
1745 elif test -x as$build_exeext; then
1746         # Build using assembler in the current directory.
1747         gcc_cv_as=./as$build_exeext
1748 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1749      && test -f ../gas/Makefile \
1750      && test x$build = x$host; then
1751   # Single tree build which includes gas.  We want to prefer it
1752   # over whatever linker top-level may have detected, since
1753   # we'll use what we're building after installation anyway.
1754   in_tree_gas=yes
1755   _gcc_COMPUTE_GAS_VERSION
1756   rm -f as$build_exeext
1757   $LN_S ../gas/as-new$build_exeext as$build_exeext 2>/dev/null
1758   in_tree_gas_is_elf=no
1759   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1760      || (grep 'obj_format = multi' ../gas/Makefile \
1761          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1762   then
1763     in_tree_gas_is_elf=yes
1764   fi
1765 m4_pattern_allow([AS_FOR_TARGET])dnl
1766 elif test -x "$AS_FOR_TARGET"; then
1767         gcc_cv_as="$AS_FOR_TARGET"
1768 elif test -x "$AS" && test x$host = x$target; then
1769         gcc_cv_as="$AS"
1770 fi
1771
1772 if test "x$gcc_cv_as" = x; then
1773         # Search the same directories that the installed compiler will
1774         # search.  Else we may find the wrong assembler and lose.  If we
1775         # do not find a suitable assembler binary, then try the user's
1776         # path.
1777         #
1778         # Also note we have to check MD_EXEC_PREFIX before checking the
1779         # user's path.  Unfortunately, there is no good way to get at the
1780         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1781         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1782         # to be fixed as part of the make/configure rewrite too.
1783
1784         if test "x$exec_prefix" = xNONE; then
1785                 if test "x$prefix" = xNONE; then
1786                         test_prefix=/usr/local
1787                 else
1788                         test_prefix=$prefix
1789                 fi
1790         else
1791                 test_prefix=$exec_prefix
1792         fi
1793
1794         # If the loop below does not find an assembler, then use whatever
1795         # one we can find in the users's path.  We are looking for a
1796         # ${build} -> ${target} assembler.
1797         if test "x$program_prefix" != xNONE; then
1798                 gcc_cv_as=${program_prefix}as$build_exeext
1799         elif test x$build != x$host && test x$build != x$target; then
1800                 gcc_cv_as=${target_noncanonical}-as$build_exeext
1801         else
1802                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$build_exeext
1803         fi
1804
1805         if test x$host = x$build; then
1806             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1807                        $test_prefix/libexec/gcc/$target_noncanonical \
1808                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1809                        /usr/lib/gcc/$target_noncanonical \
1810                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1811                        $test_prefix/$target_noncanonical/bin"
1812         else
1813             test_dirs=
1814         fi
1815
1816         if test x$build = x$target; then
1817             test_dirs="$test_dirs \
1818                    /usr/libexec \
1819                    /usr/ccs/gcc \
1820                    /usr/ccs/bin \
1821                    /udk/usr/ccs/bin \
1822                    /bsd43/usr/lib/cmplrs/cc \
1823                    /usr/cross64/usr/bin \
1824                    /usr/lib/cmplrs/cc \
1825                    /sysv/usr/lib/cmplrs/cc \
1826                    /svr4/usr/lib/cmplrs/cc \
1827                    /usr/bin"
1828         fi
1829
1830         for dir in $test_dirs; do
1831                 if test -x $dir/as$build_exeext; then
1832                         gcc_cv_as=$dir/as$build_exeext
1833                         break;
1834                 fi
1835         done
1836 fi
1837 case $in_tree_gas in
1838   yes)
1839     AC_MSG_RESULT("newly built gas")
1840     ;;
1841   no)
1842     AC_MSG_RESULT($gcc_cv_as)
1843     ;;
1844 esac
1845
1846 # Identify the linker which will work hand-in-glove with the newly
1847 # built GCC, so that we can examine its features.  This is the linker
1848 # which will be driven by the driver program.
1849 #
1850 # If build != host, and we aren't building gas in-tree, we identify a
1851 # build->target linker and hope that it will have the same features
1852 # as the host->target linker we'll be using.
1853 AC_MSG_CHECKING(what linker to use)
1854 in_tree_ld=no
1855 gcc_cv_ld=
1856 gcc_cv_gld_major_version=
1857 gcc_cv_gld_minor_version=
1858 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1859 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1860 if test -x "$DEFAULT_LINKER"; then
1861         gcc_cv_ld="$DEFAULT_LINKER"
1862 elif test -x collect-ld$build_exeext; then
1863         # Build using linker in the current directory.
1864         gcc_cv_ld=./collect-ld$build_exeext
1865 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1866      && test -f ../ld/Makefile \
1867      && test x$build = x$host; then
1868         # Single tree build which includes ld.  We want to prefer it
1869         # over whatever linker top-level may have detected, since
1870         # we'll use what we're building after installation anyway.
1871         in_tree_ld=yes
1872         in_tree_ld_is_elf=no
1873         if (grep 'EMUL = .*elf' ../ld/Makefile \
1874             || grep 'EMUL = .*linux' ../ld/Makefile \
1875             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1876           in_tree_ld_is_elf=yes
1877         fi
1878         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1879         do
1880 changequote(,)dnl
1881                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1882 changequote([,])dnl
1883                 if test x$gcc_cv_gld_version != x; then
1884                         break
1885                 fi
1886         done
1887 changequote(,)dnl
1888         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1889         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1890 changequote([,])dnl
1891         rm -f collect-ld$build_exeext
1892         $LN_S ../ld/ld-new$build_exeext collect-ld$build_exeext 2>/dev/null
1893 elif test -x "$LD_FOR_TARGET"; then
1894         gcc_cv_ld="$LD_FOR_TARGET"
1895 elif test -x "$LD" && test x$host = x$target; then
1896         gcc_cv_ld="$LD"
1897 fi
1898
1899 if test "x$gcc_cv_ld" = x; then
1900         # Search the same directories that the installed compiler will
1901         # search.  Else we may find the wrong linker and lose.  If we
1902         # do not find a suitable linker binary, then try the user's
1903         # path.
1904         #
1905         # Also note we have to check MD_EXEC_PREFIX before checking the
1906         # user's path.  Unfortunately, there is no good way to get at the
1907         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1908         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1909         # to be fixed as part of the make/configure rewrite too.
1910
1911         if test "x$exec_prefix" = xNONE; then
1912                 if test "x$prefix" = xNONE; then
1913                         test_prefix=/usr/local
1914                 else
1915                         test_prefix=$prefix
1916                 fi
1917         else
1918                 test_prefix=$exec_prefix
1919         fi
1920
1921         # If the loop below does not find a linker, then use whatever
1922         # one we can find in the users's path.  We are looking for a
1923         # ${build} -> ${target} linker.
1924         if test "x$program_prefix" != xNONE; then
1925                 gcc_cv_ld=${program_prefix}ld$build_exeext
1926         elif test x$build != x$host && test x$build != x$target; then
1927                 gcc_cv_ld=${target_noncanonical}-ld$build_exeext
1928         else
1929                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$build_exeext
1930         fi
1931
1932         if test x$host = x$build; then
1933             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1934                        $test_prefix/libexec/gcc/$target_noncanonical \
1935                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1936                        /usr/lib/gcc/$target_noncanonical \
1937                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1938                        $test_prefix/$target_noncanonical/bin"
1939         else
1940             test_dirs=
1941         fi
1942
1943         if test x$build = x$target; then
1944             test_dirs="$test_dirs \
1945                    /usr/libexec \
1946                    /usr/ccs/gcc \
1947                    /usr/ccs/bin \
1948                    /udk/usr/ccs/bin \
1949                    /bsd43/usr/lib/cmplrs/cc \
1950                    /usr/cross64/usr/bin \
1951                    /usr/lib/cmplrs/cc \
1952                    /sysv/usr/lib/cmplrs/cc \
1953                    /svr4/usr/lib/cmplrs/cc \
1954                    /usr/bin"
1955         fi
1956
1957         for dir in $test_dirs; do
1958                 if test -x $dir/ld$build_exeext; then
1959                         gcc_cv_ld=$dir/ld$build_exeext
1960                         break;
1961                 fi
1962         done
1963 fi
1964 case $in_tree_ld in
1965   yes)
1966     AC_MSG_RESULT("newly built ld")
1967     ;;
1968   no)
1969     AC_MSG_RESULT($gcc_cv_ld)
1970     ;;
1971 esac
1972
1973 # Figure out what nm we will be using.
1974 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1975 AC_MSG_CHECKING(what nm to use)
1976 in_tree_nm=no
1977 if test -x nm$build_exeext; then
1978         gcc_cv_nm=./nm$build_exeext
1979 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1980      && test -f ../binutils/Makefile; then
1981         # Single tree build which includes binutils.
1982         in_tree_nm=yes
1983         gcc_cv_nm=./nm$build_exeext
1984         rm -f nm$build_exeext
1985         $LN_S ../binutils/nm-new$build_exeext nm$build_exeext 2>/dev/null
1986 elif test "x$program_prefix" != xNONE; then
1987         gcc_cv_nm=${program_prefix}nm$build_exeext
1988 elif test x$build != x$host && test x$build != x$target; then
1989         gcc_cv_nm=${target_noncanonical}-nm$build_exeext
1990 else
1991         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$build_exeext
1992 fi
1993 case $in_tree_nm in
1994   yes) AC_MSG_RESULT("newly built nm") ;;
1995   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1996 esac
1997
1998 # Figure out what objdump we will be using.
1999 AC_MSG_CHECKING(what objdump to use)
2000 in_tree_objdump=no
2001 if test -x objdump$build_exeext; then
2002         gcc_cv_objdump=./objdump$build_exeext
2003 elif test -f $gcc_cv_binutils_srcdir/configure.in \
2004      && test -f ../binutils/Makefile; then
2005         # Single tree build which includes binutils.
2006         in_tree_objdump=yes
2007         gcc_cv_objdump=./objdump$build_exeext
2008         rm -f objdump$build_exeext
2009         $LN_S ../binutils/objdump$build_exeext objdump$build_exeext 2>/dev/null
2010 elif test "x$program_prefix" != xNONE; then
2011         gcc_cv_objdump=${program_prefix}objdump$build_exeext
2012 elif test x$build != x$host && test x$build != x$target; then
2013         gcc_cv_objdump=${target_noncanonical}-objdump$build_exeext
2014 else
2015         gcc_cv_objdump=`echo objdump | \
2016                 sed "${program_transform_name}"`$build_exeext
2017 fi
2018 case $in_tree_objdump in
2019   yes) AC_MSG_RESULT("newly built objdump") ;;
2020   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
2021 esac
2022
2023 # Figure out what assembler alignment features are present.
2024 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2025  [2,6,0],,
2026 [.balign 4
2027 .p2align 2],,
2028 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2029   [Define if your assembler supports .balign and .p2align.])])
2030
2031 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2032  [2,8,0],,
2033  [.p2align 4,,7],,
2034 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2035   [Define if your assembler supports specifying the maximum number
2036    of bytes to skip when using the GAS .p2align command.])])
2037
2038 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2039  [elf,2,9,0],,
2040  [conftest_label1: .word 0
2041 .subsection -1
2042 conftest_label2: .word 0
2043 .previous],
2044  [if test x$gcc_cv_nm != x; then
2045     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2046     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2047     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2048     then :
2049     else gcc_cv_as_subsection_m1=yes
2050     fi
2051     rm -f conftest.nm1 conftest.nm2
2052   fi],
2053  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2054   [Define if your assembler supports .subsection and .subsection -1 starts
2055    emitting at the beginning of your section.])])
2056
2057 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2058  [2,2,0],,
2059  [      .weak foobar],,
2060 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2061
2062 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2063  [2,15,91],,
2064  [      .SPACE $TEXT$
2065         .NSUBSPA $CODE$,COMDAT],,
2066 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2067
2068 # .hidden needs to be supported in both the assembler and the linker,
2069 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2070 # This is irritatingly difficult to feature test for; we have to check the
2071 # date string after the version number.  If we've got an in-tree
2072 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2073 # to be safe.
2074 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2075 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2076  [elf,2,13,0],,
2077 [       .hidden foobar
2078 foobar:])
2079
2080 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2081 [if test $in_tree_ld = yes ; then
2082   gcc_cv_ld_hidden=no
2083   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2084      && test $in_tree_ld_is_elf = yes; then
2085      gcc_cv_ld_hidden=yes
2086   fi
2087 else
2088   gcc_cv_ld_hidden=yes
2089   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2090   if echo "$ld_ver" | grep GNU > /dev/null; then
2091 changequote(,)dnl
2092     ld_vers=`echo $ld_ver | sed -n \
2093         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2094         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2095         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2096         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2097         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2098         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[        ].*$,\1,p'`
2099     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2100     if test 0"$ld_date" -lt 20020404; then
2101       if test -n "$ld_date"; then
2102         # If there was date string, but was earlier than 2002-04-04, fail
2103         gcc_cv_ld_hidden=no
2104       elif test -z "$ld_vers"; then
2105         # If there was no date string nor ld version number, something is wrong
2106         gcc_cv_ld_hidden=no
2107       else
2108         ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2109         ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2110         ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2111         test -z "$ld_vers_patch" && ld_vers_patch=0
2112         if test "$ld_vers_major" -lt 2; then
2113           gcc_cv_ld_hidden=no
2114         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2115           gcc_cv_ld_hidden="no"
2116         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2117           gcc_cv_ld_hidden=no
2118         fi
2119       fi
2120 changequote([,])dnl
2121     fi
2122   else
2123     case "${target}" in
2124       hppa64*-*-hpux* | ia64*-*-hpux*)
2125         gcc_cv_ld_hidden=yes
2126         ;;
2127       *)
2128         gcc_cv_ld_hidden=no
2129         ;;
2130     esac
2131   fi
2132 fi])
2133 libgcc_visibility=no
2134 AC_SUBST(libgcc_visibility)
2135 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2136   libgcc_visibility=yes
2137   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2138   [Define if your assembler and linker support .hidden.])
2139 fi
2140
2141 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2142 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2143   [elf,2,11,0],,
2144 [       .data
2145         .uleb128 L2 - L1
2146 L1:
2147         .uleb128 1280
2148         .sleb128 -1010
2149 L2:],
2150  [# GAS versions before 2.11 do not support uleb128,
2151   # despite appearing to.
2152   # ??? There exists an elf-specific test that will crash
2153   # the assembler.  Perhaps it's better to figure out whether
2154   # arbitrary sections are supported and try the test.
2155   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2156   if echo "$as_ver" | grep GNU > /dev/null; then
2157 changequote(,)dnl
2158     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2159     as_major=`echo $as_ver | sed 's/\..*//'`
2160     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2161 changequote([,])dnl
2162     if test $as_major -eq 2 && test $as_minor -lt 11
2163     then :
2164     else gcc_cv_as_leb128=yes
2165     fi
2166   fi],
2167   [AC_DEFINE(HAVE_AS_LEB128, 1,
2168     [Define if your assembler supports .sleb128 and .uleb128.])])
2169
2170 # GAS versions up to and including 2.11.0 may mis-optimize
2171 # .eh_frame data.
2172 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2173   [elf,2,12,0],,
2174 [       .text
2175 .LFB1:
2176         .4byte  0
2177 .L1:
2178         .4byte  0
2179 .LFE1:
2180         .section        .eh_frame,"aw",@progbits
2181 __FRAME_BEGIN__:
2182         .4byte  .LECIE1-.LSCIE1
2183 .LSCIE1:
2184         .4byte  0x0
2185         .byte   0x1
2186         .ascii "z\0"
2187         .byte   0x1
2188         .byte   0x78
2189         .byte   0x1a
2190         .byte   0x0
2191         .byte   0x4
2192         .4byte  1
2193         .p2align 1
2194 .LECIE1:
2195 .LSFDE1:
2196         .4byte  .LEFDE1-.LASFDE1
2197 .LASFDE1:
2198         .4byte  .LASFDE1-__FRAME_BEGIN__
2199         .4byte  .LFB1
2200         .4byte  .LFE1-.LFB1
2201         .byte   0x4
2202         .4byte  .LFE1-.LFB1
2203         .byte   0x4
2204         .4byte  .L1-.LFB1
2205 .LEFDE1:],
2206 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2207 cat > conftest.lit <<EOF
2208  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2209  0010 01000000 12000000 18000000 00000000  ................
2210  0020 08000000 04080000 0044               .........D      @&t@
2211 EOF
2212 cat > conftest.big <<EOF
2213  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2214  0010 00000001 00000012 00000018 00000000  ................
2215  0020 00000008 04000000 0844               .........D      @&t@
2216 EOF
2217   # If the assembler didn't choke, and we can objdump,
2218   # and we got the correct data, then succeed.
2219   if test x$gcc_cv_objdump != x \
2220   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2221      | tail -3 > conftest.got \
2222   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2223     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2224   then
2225     gcc_cv_as_eh_frame=yes
2226   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2227     gcc_cv_as_eh_frame=buggy
2228   else
2229     # Uh oh, what do we do now?
2230     gcc_cv_as_eh_frame=no
2231   fi])
2232
2233 if test $gcc_cv_as_eh_frame = buggy; then
2234   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2235   [Define if your assembler mis-optimizes .eh_frame data.])
2236 fi
2237
2238 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2239  [elf,2,12,0], [--fatal-warnings],
2240  [.section .rodata.str, "aMS", @progbits, 1])
2241 if test $gcc_cv_as_shf_merge = no; then
2242   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2243     [elf,2,12,0], [--fatal-warnings],
2244     [.section .rodata.str, "aMS", %progbits, 1])
2245 fi
2246 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2247   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2248 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2249
2250 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2251  [elf,2,15,91], [--fatal-warnings],
2252  [.section .text,"axG",@progbits,.foo,comdat])
2253 if test $gcc_cv_as_comdat_group = yes; then
2254   gcc_cv_as_comdat_group_percent=no
2255 else
2256  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2257    [elf,2,15,91], [--fatal-warnings],
2258    [.section .text,"axG",%progbits,.foo,comdat])
2259 fi
2260 AC_DEFINE_UNQUOTED(HAVE_GAS_COMDAT_GROUP,
2261   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2262 [Define 0/1 if your assembler supports COMDAT group.])
2263
2264 # Thread-local storage - the check is heavily parametrized.
2265 conftest_s=
2266 tls_first_major=
2267 tls_first_minor=
2268 tls_as_opt=
2269 case "$target" in
2270 changequote(,)dnl
2271   alpha*-*-*)
2272     conftest_s='
2273         .section ".tdata","awT",@progbits
2274 foo:    .long   25
2275         .text
2276         ldq     $27,__tls_get_addr($29)         !literal!1
2277         lda     $16,foo($29)                    !tlsgd!1
2278         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2279         ldq     $27,__tls_get_addr($29)         !literal!2
2280         lda     $16,foo($29)                    !tlsldm!2
2281         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2282         ldq     $1,foo($29)                     !gotdtprel
2283         ldah    $2,foo($29)                     !dtprelhi
2284         lda     $3,foo($2)                      !dtprello
2285         lda     $4,foo($29)                     !dtprel
2286         ldq     $1,foo($29)                     !gottprel
2287         ldah    $2,foo($29)                     !tprelhi
2288         lda     $3,foo($2)                      !tprello
2289         lda     $4,foo($29)                     !tprel'
2290         tls_first_major=2
2291         tls_first_minor=13
2292         tls_as_opt=--fatal-warnings
2293         ;;
2294   frv*-*-*)
2295     conftest_s='
2296         .section ".tdata","awT",@progbits
2297 x:      .long   25
2298         .text
2299         call    #gettlsoff(x)'
2300         tls_first_major=2
2301         tls_first_minor=14
2302         ;;
2303   i[34567]86-*-*)
2304     conftest_s='
2305         .section ".tdata","awT",@progbits
2306 foo:    .long   25
2307         .text
2308         movl    %gs:0, %eax
2309         leal    foo@TLSGD(,%ebx,1), %eax
2310         leal    foo@TLSLDM(%ebx), %eax
2311         leal    foo@DTPOFF(%eax), %edx
2312         movl    foo@GOTTPOFF(%ebx), %eax
2313         subl    foo@GOTTPOFF(%ebx), %eax
2314         addl    foo@GOTNTPOFF(%ebx), %eax
2315         movl    foo@INDNTPOFF, %eax
2316         movl    $foo@TPOFF, %eax
2317         subl    $foo@TPOFF, %eax
2318         leal    foo@NTPOFF(%ecx), %eax'
2319         tls_first_major=2
2320         tls_first_minor=14
2321         tls_as_opt=--fatal-warnings
2322         ;;
2323   x86_64-*-*)
2324     conftest_s='
2325         .section ".tdata","awT",@progbits
2326 foo:    .long   25
2327         .text
2328         movq    %fs:0, %rax
2329         leaq    foo@TLSGD(%rip), %rdi
2330         leaq    foo@TLSLD(%rip), %rdi
2331         leaq    foo@DTPOFF(%rax), %rdx
2332         movq    foo@GOTTPOFF(%rip), %rax
2333         movq    $foo@TPOFF, %rax'
2334         tls_first_major=2
2335         tls_first_minor=14
2336         tls_as_opt=--fatal-warnings
2337         ;;
2338   ia64-*-*)
2339     conftest_s='
2340         .section ".tdata","awT",@progbits
2341 foo:    data8   25
2342         .text
2343         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2344         addl    r17 = @ltoff(@dtprel(foo#)), gp
2345         addl    r18 = @ltoff(@tprel(foo#)), gp
2346         addl    r19 = @dtprel(foo#), gp
2347         adds    r21 = @dtprel(foo#), r13
2348         movl    r23 = @dtprel(foo#)
2349         addl    r20 = @tprel(foo#), gp
2350         adds    r22 = @tprel(foo#), r13
2351         movl    r24 = @tprel(foo#)'
2352         tls_first_major=2
2353         tls_first_minor=13
2354         tls_as_opt=--fatal-warnings
2355         ;;
2356   mips*-*-*)
2357     conftest_s='
2358         .section .tdata,"awT",@progbits
2359 x:
2360         .word 2
2361         .text
2362         addiu $4, $28, %tlsgd(x)
2363         addiu $4, $28, %tlsldm(x)
2364         lui $4, %dtprel_hi(x)
2365         addiu $4, $4, %dtprel_lo(x)
2366         lw $4, %gottprel(x)($28)
2367         lui $4, %tprel_hi(x)
2368         addiu $4, $4, %tprel_lo(x)'
2369         tls_first_major=2
2370         tls_first_minor=16
2371         tls_as_opt='-32 --fatal-warnings'
2372         ;;
2373   powerpc-*-*)
2374     conftest_s='
2375         .section ".tdata","awT",@progbits
2376         .align 2
2377 ld0:    .space 4
2378 ld1:    .space 4
2379 x1:     .space 4
2380 x2:     .space 4
2381 x3:     .space 4
2382         .text
2383         addi 3,31,ld0@got@tlsgd
2384         bl __tls_get_addr
2385         addi 3,31,x1@got@tlsld
2386         bl __tls_get_addr
2387         addi 9,3,x1@dtprel
2388         addis 9,3,x2@dtprel@ha
2389         addi 9,9,x2@dtprel@l
2390         lwz 9,x3@got@tprel(31)
2391         add 9,9,x@tls
2392         addi 9,2,x1@tprel
2393         addis 9,2,x2@tprel@ha
2394         addi 9,9,x2@tprel@l'
2395         tls_first_major=2
2396         tls_first_minor=14
2397         tls_as_opt="-a32 --fatal-warnings"
2398         ;;
2399   powerpc64-*-*)
2400     conftest_s='
2401         .section ".tdata","awT",@progbits
2402         .align 3
2403 ld0:    .space 8
2404 ld1:    .space 8
2405 x1:     .space 8
2406 x2:     .space 8
2407 x3:     .space 8
2408         .text
2409         addi 3,2,ld0@got@tlsgd
2410         bl .__tls_get_addr
2411         nop
2412         addi 3,2,ld1@toc
2413         bl .__tls_get_addr
2414         nop
2415         addi 3,2,x1@got@tlsld
2416         bl .__tls_get_addr
2417         nop
2418         addi 9,3,x1@dtprel
2419         bl .__tls_get_addr
2420         nop
2421         addis 9,3,x2@dtprel@ha
2422         addi 9,9,x2@dtprel@l
2423         bl .__tls_get_addr
2424         nop
2425         ld 9,x3@got@dtprel(2)
2426         add 9,9,3
2427         bl .__tls_get_addr
2428         nop'
2429         tls_first_major=2
2430         tls_first_minor=14
2431         tls_as_opt="-a64 --fatal-warnings"
2432         ;;
2433   s390-*-*)
2434     conftest_s='
2435         .section ".tdata","awT",@progbits
2436 foo:    .long   25
2437         .text
2438         .long   foo@TLSGD
2439         .long   foo@TLSLDM
2440         .long   foo@DTPOFF
2441         .long   foo@NTPOFF
2442         .long   foo@GOTNTPOFF
2443         .long   foo@INDNTPOFF
2444         l       %r1,foo@GOTNTPOFF(%r12)
2445         l       %r1,0(%r1):tls_load:foo
2446         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2447         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2448         tls_first_major=2
2449         tls_first_minor=14
2450         tls_as_opt="-m31 --fatal-warnings"
2451         ;;
2452   s390x-*-*)
2453     conftest_s='
2454         .section ".tdata","awT",@progbits
2455 foo:    .long   25
2456         .text
2457         .quad   foo@TLSGD
2458         .quad   foo@TLSLDM
2459         .quad   foo@DTPOFF
2460         .quad   foo@NTPOFF
2461         .quad   foo@GOTNTPOFF
2462         lg      %r1,foo@GOTNTPOFF(%r12)
2463         larl    %r1,foo@INDNTPOFF
2464         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2465         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2466         tls_first_major=2
2467         tls_first_minor=14
2468         tls_as_opt="-m64 -Aesame --fatal-warnings"
2469         ;;
2470   sh-*-* | sh[34]-*-*)
2471     conftest_s='
2472         .section ".tdata","awT",@progbits
2473 foo:    .long   25
2474         .text
2475         .long   foo@TLSGD
2476         .long   foo@TLSLDM
2477         .long   foo@DTPOFF
2478         .long   foo@GOTTPOFF
2479         .long   foo@TPOFF'
2480         tls_first_major=2
2481         tls_first_minor=13
2482         tls_as_opt=--fatal-warnings
2483         ;;
2484   sparc*-*-*)
2485     case "$target" in
2486       sparc*-sun-solaris2.*)
2487         on_solaris=yes
2488         ;;
2489       *)
2490         on_solaris=no
2491         ;;
2492     esac
2493     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2494       conftest_s='
2495         .section ".tdata",#alloc,#write,#tls
2496 foo:    .long   25
2497         .text
2498         sethi   %tgd_hi22(foo), %o0
2499         add     %o0, %tgd_lo10(foo), %o1
2500         add     %l7, %o1, %o0, %tgd_add(foo)
2501         call    __tls_get_addr, %tgd_call(foo)
2502         sethi   %tldm_hi22(foo), %l1
2503         add     %l1, %tldm_lo10(foo), %l2
2504         add     %l7, %l2, %o0, %tldm_add(foo)
2505         call    __tls_get_addr, %tldm_call(foo)
2506         sethi   %tldo_hix22(foo), %l3
2507         xor     %l3, %tldo_lox10(foo), %l4
2508         add     %o0, %l4, %l5, %tldo_add(foo)
2509         sethi   %tie_hi22(foo), %o3
2510         add     %o3, %tie_lo10(foo), %o3
2511         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2512         add     %g7, %o2, %o4, %tie_add(foo)
2513         sethi   %tle_hix22(foo), %l1
2514         xor     %l1, %tle_lox10(foo), %o5
2515         ld      [%g7 + %o5], %o1'
2516         tls_first_major=0
2517         tls_first_minor=0
2518     else
2519       conftest_s='
2520         .section ".tdata","awT",@progbits
2521 foo:    .long   25
2522         .text
2523         sethi   %tgd_hi22(foo), %o0
2524         add     %o0, %tgd_lo10(foo), %o1
2525         add     %l7, %o1, %o0, %tgd_add(foo)
2526         call    __tls_get_addr, %tgd_call(foo)
2527         sethi   %tldm_hi22(foo), %l1
2528         add     %l1, %tldm_lo10(foo), %l2
2529         add     %l7, %l2, %o0, %tldm_add(foo)
2530         call    __tls_get_addr, %tldm_call(foo)
2531         sethi   %tldo_hix22(foo), %l3
2532         xor     %l3, %tldo_lox10(foo), %l4
2533         add     %o0, %l4, %l5, %tldo_add(foo)
2534         sethi   %tie_hi22(foo), %o3
2535         add     %o3, %tie_lo10(foo), %o3
2536         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2537         add     %g7, %o2, %o4, %tie_add(foo)
2538         sethi   %tle_hix22(foo), %l1
2539         xor     %l1, %tle_lox10(foo), %o5
2540         ld      [%g7 + %o5], %o1'
2541         tls_first_major=2
2542         tls_first_minor=14
2543         tls_as_opt="-32 --fatal-warnings"
2544       fi
2545         ;;
2546 changequote([,])dnl
2547 esac
2548 if test -z "$tls_first_major"; then
2549   : # If we don't have a check, assume no support.
2550 else
2551   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2552   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2553   [AC_DEFINE(HAVE_AS_TLS, 1,
2554             [Define if your assembler supports thread-local storage.])])
2555 fi
2556
2557 # Target-specific assembler checks.
2558
2559 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2560 gcc_cv_ld_static_dynamic=no
2561 if test $in_tree_ld = yes ; then
2562   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2563     gcc_cv_ld_static_dynamic=yes
2564   fi
2565 elif test x$gcc_cv_ld != x; then
2566         # Check if linker supports -Bstatic/-Bdynamic option
2567         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2568           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2569                 gcc_cv_ld_static_dynamic=yes
2570         fi
2571 fi
2572 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2573         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2574 [Define if your linker supports -Bstatic/-Bdynamic option.])
2575 fi
2576 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2577
2578 if test x"$demangler_in_ld" = xyes; then
2579   AC_MSG_CHECKING(linker --demangle support)
2580   gcc_cv_ld_demangle=no
2581   if test $in_tree_ld = yes; then
2582     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2583       gcc_cv_ld_demangle=yes
2584     fi
2585   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2586     # Check if the GNU linker supports --demangle option
2587     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2588       gcc_cv_ld_demangle=yes
2589     fi
2590   fi
2591   if test x"$gcc_cv_ld_demangle" = xyes; then
2592     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2593 [Define if your linker supports --demangle option.])
2594   fi
2595   AC_MSG_RESULT($gcc_cv_ld_demangle)
2596 fi
2597
2598 case "$target" in
2599   # All TARGET_ABI_OSF targets.
2600   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2601     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2602         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2603 [       .set nomacro
2604         .text
2605         extbl   $3, $2, $3      !lituse_bytoff!1
2606         ldq     $2, a($29)      !literal!1
2607         ldq     $4, b($29)      !literal!2
2608         ldq_u   $3, 0($2)       !lituse_base!1
2609         ldq     $27, f($29)     !literal!5
2610         jsr     $26, ($27), f   !lituse_jsr!5
2611         ldah    $29, 0($26)     !gpdisp!3
2612         lda     $0, c($29)      !gprel
2613         ldah    $1, d($29)      !gprelhigh
2614         lda     $1, d($1)       !gprellow
2615         lda     $29, 0($29)     !gpdisp!3],,
2616     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2617   [Define if your assembler supports explicit relocations.])])
2618     ;;
2619
2620   cris-*-*)
2621     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2622       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2623       [-no-mul-bug-abort], [.text],,
2624       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2625                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2626     ;;
2627
2628   sparc*-*-*)
2629     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2630       [.register %g2, #scratch],,
2631       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2632                 [Define if your assembler supports .register.])])
2633
2634     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2635       [-relax], [.text],,
2636       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2637                 [Define if your assembler supports -relax option.])])
2638
2639     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2640       gcc_cv_as_sparc_ua_pcrel,,
2641       [-K PIC],
2642 [.text
2643 foo:
2644         nop
2645 .data
2646 .align 4
2647 .byte 0
2648 .uaword %r_disp32(foo)],
2649       [if test x$gcc_cv_ld != x \
2650        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2651          gcc_cv_as_sparc_ua_pcrel=yes
2652        fi
2653        rm -f conftest],
2654       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2655                 [Define if your assembler and linker support unaligned PC relative relocs.])
2656
2657       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2658         gcc_cv_as_sparc_ua_pcrel_hidden,,
2659         [-K PIC],
2660 [.data
2661 .align 4
2662 .byte 0x31
2663 .uaword %r_disp32(foo)
2664 .byte 0x32, 0x33, 0x34
2665 .global foo
2666 .hidden foo
2667 foo:
2668 .skip 4],
2669         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2670          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2671          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2672             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2673             if $gcc_cv_objdump -R conftest 2> /dev/null \
2674                | grep 'DISP32' > /dev/null 2>&1; then
2675                 :
2676             else
2677                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2678             fi
2679          fi
2680          rm -f conftest],
2681          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2682                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2683     ]) # unaligned pcrel relocs
2684
2685     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2686       gcc_cv_as_sparc_offsetable_lo10,,
2687       [-xarch=v9],
2688 [.text
2689         or %g1, %lo(ab) + 12, %g1
2690         or %g1, %lo(ab + 12), %g1],
2691       [if test x$gcc_cv_objdump != x \
2692        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2693           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2694          gcc_cv_as_sparc_offsetable_lo10=yes
2695        fi],
2696        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2697                  [Define if your assembler supports offsetable %lo().])])
2698     ;;
2699
2700 changequote(,)dnl
2701   i[34567]86-*-* | x86_64-*-*)
2702 changequote([,])dnl
2703     case $target_os in
2704       cygwin* | pe | mingw32*)
2705         # Used for DWARF 2 in PE
2706         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2707           gcc_cv_as_ix86_pe_secrel32,
2708           [2,15,91],,
2709 [.text
2710 foo:    nop
2711 .data
2712         .secrel32 foo],
2713           [if test x$gcc_cv_ld != x \
2714            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2715              gcc_cv_as_ix86_pe_secrel32=yes
2716            fi
2717            rm -f conftest],
2718           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2719             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2720         ;;
2721     esac
2722
2723     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2724        gcc_cv_as_ix86_filds_fists,
2725       [2,9,0],, [filds mem; fists mem],,
2726       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2727         [Define if your assembler uses the new HImode fild and fist notation.])])
2728
2729     gcc_GAS_CHECK_FEATURE([cmov syntax],
2730       gcc_cv_as_ix86_cmov_sun_syntax,,,
2731       [cmovl.l %edx, %eax],,
2732       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2733         [Define if your assembler supports the Sun syntax for cmov.])])
2734
2735     # This one is used unconditionally by i386.[ch]; it is to be defined
2736     # to 1 if the feature is present, 0 otherwise.
2737     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2738         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2739 [       .text
2740 .L0:
2741         nop
2742         .data
2743         .long .L0@GOTOFF])
2744     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2745       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2746       [Define true if the assembler supports '.long foo@GOTOFF'.])
2747     ;;
2748
2749   ia64*-*-*)
2750     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2751         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2752 [       .text
2753         addl r15 = @ltoffx(x#), gp
2754         ;;
2755         ld8.mov r16 = [[r15]], x#],,
2756     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2757           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2758
2759     ;;
2760
2761   powerpc*-*-*)
2762     case $target in
2763       *-*-aix*) conftest_s='    .csect .text[[PR]]
2764         mfcr 3,128';;
2765       *-*-darwin*)
2766         gcc_GAS_CHECK_FEATURE([.machine directive support],
2767           gcc_cv_as_machine_directive,,,
2768           [     .machine ppc7400])
2769         if test x$gcc_cv_as_machine_directive != xyes; then
2770           echo "*** This target requires an assembler supporting \".machine\"" >&2
2771           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2772           test x$build = x$target && exit 1
2773         fi
2774         conftest_s='    .text
2775         mfcr r3,128';;
2776       *) conftest_s='   .machine power4
2777         .text
2778         mfcr 3,128';;
2779     esac
2780
2781     gcc_GAS_CHECK_FEATURE([mfcr field support],
2782       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2783       [$conftest_s],,
2784       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2785           [Define if your assembler supports mfcr field.])])
2786     ;;
2787
2788   mips*-*-*)
2789     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2790       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2791 [       lw $4,%gp_rel(foo)($4)],,
2792       [if test x$target_cpu_default = x
2793        then target_cpu_default=MASK_EXPLICIT_RELOCS
2794        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2795        fi])
2796
2797     if test x$gas_flag = xyes \
2798        || test x"$host" != x"$build" \
2799        || test ! -x "$gcc_cv_as" \
2800        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2801       :
2802     else
2803       echo "*** This configuration requires the GNU assembler" >&2
2804       exit 1
2805     fi
2806     ;;
2807 esac
2808 # ??? Not all targets support dwarf2 debug_line, even within a version
2809 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2810 # info to the output file.  So, as supported targets are added to gas 2.11,
2811 # add some instruction here to (also) show we expect this might work.
2812 # ??? Once 2.11 is released, probably need to add first known working
2813 # version to the per-target configury.
2814 case "$target" in
2815   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2816   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2817   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2818     insn="nop"
2819     ;;
2820   ia64*-*-* | s390*-*-*)
2821     insn="nop 0"
2822     ;;
2823   mmix-*-*)
2824     insn="swym 0"
2825     ;;
2826 esac
2827 if test x"$insn" != x; then
2828  conftest_s="\
2829         .file 1 \"conftest.s\"
2830         .loc 1 3 0
2831         $insn"
2832  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2833   gcc_cv_as_dwarf2_debug_line,
2834   [elf,2,11,0],, [$conftest_s],
2835   [if test x$gcc_cv_objdump != x \
2836    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2837       | grep debug_line > /dev/null 2>&1; then
2838      gcc_cv_as_dwarf2_debug_line=yes
2839    fi])
2840
2841 # The .debug_line file table must be in the exact order that
2842 # we specified the files, since these indices are also used
2843 # by DW_AT_decl_file.  Approximate this test by testing if
2844 # the assembler bitches if the same index is assigned twice.
2845  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2846   gcc_cv_as_dwarf2_file_buggy,,,
2847 [       .file 1 "foo.s"
2848         .file 1 "bar.s"])
2849
2850  if test $gcc_cv_as_dwarf2_debug_line = yes \
2851  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2852         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2853   [Define if your assembler supports dwarf2 .file/.loc directives,
2854    and preserves file table indices exactly as given.])
2855  fi
2856
2857  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2858   gcc_cv_as_gdwarf2_flag,
2859   [elf,2,11,0], [--gdwarf2], [$insn],,
2860   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2861 [Define if your assembler supports the --gdwarf2 option.])])
2862
2863  gcc_GAS_CHECK_FEATURE([--gstabs option],
2864   gcc_cv_as_gstabs_flag,
2865   [elf,2,11,0], [--gstabs], [$insn],
2866   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2867    # and warns about it, but still exits successfully.  So check for
2868    # this.
2869    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2870    then :
2871    else gcc_cv_as_gstabs_flag=yes
2872    fi],
2873   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2874 [Define if your assembler supports the --gstabs option.])])
2875 fi
2876
2877 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2878 gcc_cv_ld_ro_rw_mix=unknown
2879 if test $in_tree_ld = yes ; then
2880   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2881      && test $in_tree_ld_is_elf = yes; then
2882     gcc_cv_ld_ro_rw_mix=read-write
2883   fi
2884 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2885   echo '.section myfoosect, "a"' > conftest1.s
2886   echo '.section myfoosect, "aw"' > conftest2.s
2887   echo '.byte 1' >> conftest2.s
2888   echo '.section myfoosect, "a"' > conftest3.s
2889   echo '.byte 0' >> conftest3.s
2890   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2891      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2892      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2893      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2894         conftest2.o conftest3.o > /dev/null 2>&1; then
2895     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2896                          | sed -e '/myfoosect/!d' -e N`
2897     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2898       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2899         gcc_cv_ld_ro_rw_mix=read-only
2900       else
2901         gcc_cv_ld_ro_rw_mix=read-write
2902       fi
2903     fi
2904   fi
2905 changequote(,)dnl
2906   rm -f conftest.* conftest[123].*
2907 changequote([,])dnl
2908 fi
2909 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2910         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2911   [Define if your linker links a mix of read-only
2912    and read-write sections into a read-write section.])
2913 fi
2914 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2915
2916 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2917 gcc_cv_ld_eh_frame_hdr=no
2918 if test $in_tree_ld = yes ; then
2919   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2920      && test $in_tree_ld_is_elf = yes; then
2921     gcc_cv_ld_eh_frame_hdr=yes
2922   fi
2923 elif test x$gcc_cv_ld != x; then
2924         # Check if linker supports --eh-frame-hdr option
2925         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2926                 gcc_cv_ld_eh_frame_hdr=yes
2927         fi
2928 fi
2929 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2930         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2931 [Define if your linker supports --eh-frame-hdr option.])
2932 fi
2933 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2934
2935 AC_MSG_CHECKING(linker position independent executable support)
2936 gcc_cv_ld_pie=no
2937 if test $in_tree_ld = yes ; then
2938   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2939      && test $in_tree_ld_is_elf = yes; then
2940     gcc_cv_ld_pie=yes
2941   fi
2942 elif test x$gcc_cv_ld != x; then
2943         # Check if linker supports -pie option
2944         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2945                 gcc_cv_ld_pie=yes
2946         fi
2947 fi
2948 if test x"$gcc_cv_ld_pie" = xyes; then
2949         AC_DEFINE(HAVE_LD_PIE, 1,
2950 [Define if your linker supports -pie option.])
2951 fi
2952 AC_MSG_RESULT($gcc_cv_ld_pie)
2953
2954 # --------
2955 # UNSORTED
2956 # --------
2957
2958 AC_CACHE_CHECK(linker --as-needed support,
2959 gcc_cv_ld_as_needed,
2960 [gcc_cv_ld_as_needed=no
2961 if test $in_tree_ld = yes ; then
2962   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2963      && test $in_tree_ld_is_elf = yes; then
2964     gcc_cv_ld_as_needed=yes
2965   fi
2966 elif test x$gcc_cv_ld != x; then
2967         # Check if linker supports --as-needed and --no-as-needed options
2968         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
2969                 gcc_cv_ld_as_needed=yes
2970         fi
2971 fi
2972 ])
2973 if test x"$gcc_cv_ld_as_needed" = xyes; then
2974         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
2975 [Define if your linker supports --as-needed and --no-as-needed options.])
2976 fi
2977
2978 case "$target" in
2979   powerpc64*-*-linux*)
2980     AC_CACHE_CHECK(linker support for omitting dot symbols,
2981     gcc_cv_ld_no_dot_syms,
2982     [gcc_cv_ld_no_dot_syms=no
2983     if test $in_tree_ld = yes ; then
2984       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
2985         gcc_cv_ld_no_dot_syms=yes
2986       fi
2987     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
2988       cat > conftest1.s <<EOF
2989         .text
2990         bl .foo
2991 EOF
2992       cat > conftest2.s <<EOF
2993         .section ".opd","aw"
2994         .align 3
2995         .globl foo
2996         .type foo,@function
2997 foo:
2998         .quad .LEfoo,.TOC.@tocbase,0
2999         .text
3000 .LEfoo:
3001         blr
3002         .size foo,.-.LEfoo
3003 EOF
3004       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3005          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3006          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3007         gcc_cv_ld_no_dot_syms=yes
3008       fi
3009       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3010     fi
3011     ])
3012     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3013       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3014     [Define if your PowerPC64 linker only needs function descriptor syms.])
3015     fi
3016     ;;
3017 esac
3018
3019 if test x$with_sysroot = x && test x$host = x$target \
3020    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
3021   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3022 [Define to PREFIX/include if cpp should also search that directory.])
3023 fi
3024
3025 # Find out what GC implementation we want, or may, use.
3026 AC_ARG_WITH(gc,
3027 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3028                           with the compiler],
3029 [case "$withval" in
3030   page)
3031     GGC=ggc-$withval
3032     ;;
3033   zone)
3034     GGC=ggc-$withval
3035     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3036     ;;
3037   *)
3038     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3039     ;;
3040 esac],
3041 [GGC=ggc-page])
3042 AC_SUBST(GGC)
3043 echo "Using $GGC for garbage collection."
3044
3045 # Use the system's zlib library.
3046 zlibdir=-L../zlib
3047 zlibinc="-I\$(srcdir)/../zlib"
3048 AC_ARG_WITH(system-zlib,
3049 [  --with-system-zlib      use installed libz],
3050 zlibdir=
3051 zlibinc=
3052 )
3053 AC_SUBST(zlibdir)
3054 AC_SUBST(zlibinc)
3055
3056 dnl Very limited version of automake's enable-maintainer-mode
3057
3058 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3059   dnl maintainer-mode is disabled by default
3060   AC_ARG_ENABLE(maintainer-mode,
3061 [  --enable-maintainer-mode
3062                           enable make rules and dependencies not useful
3063                           (and sometimes confusing) to the casual installer],
3064       maintainer_mode=$enableval,
3065       maintainer_mode=no)
3066
3067 AC_MSG_RESULT($maintainer_mode)
3068
3069 if test "$maintainer_mode" = "yes"; then
3070   MAINT=''
3071 else
3072   MAINT='#'
3073 fi
3074 AC_SUBST(MAINT)dnl
3075
3076 # --------------
3077 # Language hooks
3078 # --------------
3079
3080 # Make empty files to contain the specs and options for each language.
3081 # Then add #include lines to for a compiler that has specs and/or options.
3082
3083 lang_opt_files=
3084 lang_specs_files=
3085 lang_tree_files=
3086 for subdir in . $subdirs
3087 do
3088         if test -f $srcdir/$subdir/lang.opt; then
3089             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3090         fi
3091         if test -f $srcdir/$subdir/lang-specs.h; then
3092             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3093         fi
3094         if test -f $srcdir/$subdir/$subdir-tree.def; then
3095             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3096         fi
3097 done
3098
3099 # These (without "all_") are set in each config-lang.in.
3100 # `language' must be a single word so is spelled singularly.
3101 all_languages=
3102 all_boot_languages=
3103 all_compilers=
3104 all_stagestuff=
3105 all_outputs='Makefile gccbug mklibgcc libada-mk'
3106 # List of language makefile fragments.
3107 all_lang_makefrags=
3108 # List of language subdirectory makefiles.  Deprecated.
3109 all_lang_makefiles=
3110 # Files for gengtype
3111 all_gtfiles="$target_gtfiles"
3112 # Files for gengtype with language
3113 all_gtfiles_files_langs=
3114 all_gtfiles_files_files=
3115
3116 # Add the language fragments.
3117 # Languages are added via two mechanisms.  Some information must be
3118 # recorded in makefile variables, these are defined in config-lang.in.
3119 # We accumulate them and plug them into the main Makefile.
3120 # The other mechanism is a set of hooks for each of the main targets
3121 # like `clean', `install', etc.
3122
3123 language_hooks="Make-hooks"
3124
3125 for s in $subdirs
3126 do
3127                 language=
3128                 boot_language=
3129                 compilers=
3130                 stagestuff=
3131                 outputs=
3132                 gtfiles=
3133                 . ${srcdir}/$s/config-lang.in
3134                 if test "x$language" = x
3135                 then
3136                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3137                         exit 1
3138                 fi
3139                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3140                 if test -f ${srcdir}/$s/Makefile.in
3141                 then all_lang_makefiles="$s/Makefile"
3142                 fi
3143                 all_languages="$all_languages $language"
3144                 if test "x$boot_language" = xyes
3145                 then
3146                         all_boot_languages="$all_boot_languages $language"
3147                 fi
3148                 all_compilers="$all_compilers $compilers"
3149                 all_stagestuff="$all_stagestuff $stagestuff"
3150                 all_outputs="$all_outputs $outputs"
3151                 all_gtfiles="$all_gtfiles $gtfiles"
3152                 for f in $gtfiles
3153                 do
3154                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3155                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3156                 done
3157 done
3158
3159 # Pick up gtfiles for c
3160 gtfiles=
3161 s="c"
3162 . ${srcdir}/c-config-lang.in
3163 all_gtfiles="$all_gtfiles $gtfiles"
3164 for f in $gtfiles
3165 do
3166         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3167         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3168 done
3169
3170 check_languages=
3171 for language in $all_languages
3172 do
3173                 check_languages="$check_languages check-$language"
3174 done
3175
3176 # We link each language in with a set of hooks, reached indirectly via
3177 # lang.${target}.
3178
3179 rm -f Make-hooks
3180 touch Make-hooks
3181 target_list="all.build all.cross start.encap rest.encap tags \
3182         install-normal install-common install-man \
3183         uninstall info man srcextra srcman srcinfo \
3184         mostlyclean clean distclean maintainer-clean \
3185         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3186 for t in $target_list
3187 do
3188         x=
3189         for lang in $all_languages
3190         do
3191                         x="$x $lang.$t"
3192         done
3193         echo "lang.$t: $x" >> Make-hooks
3194 done
3195
3196 # --------
3197 # UNSORTED
3198 # --------
3199
3200 # Create .gdbinit.
3201
3202 echo "dir ." > .gdbinit
3203 echo "dir ${srcdir}" >> .gdbinit
3204 if test x$gdb_needs_out_file_path = xyes
3205 then
3206         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3207 fi
3208 if test "x$subdirs" != x; then
3209         for s in $subdirs
3210         do
3211                 echo "dir ${srcdir}/$s" >> .gdbinit
3212         done
3213 fi
3214 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3215
3216 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3217 # absolute path for gcc_tooldir based on inserting the number of up-directory
3218 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3219 # $(libsubdir)/@(unlibsubdir) based path.
3220 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3221 # make and thus we'd get different behavior depending on where we built the
3222 # sources.
3223 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3224     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3225 else
3226 changequote(<<, >>)dnl
3227 # An explanation of the sed strings:
3228 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3229 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3230 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3231 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3232 #
3233 # (*) Note this pattern overwrites the first character of the string
3234 # with a forward slash if one is not already present.  This is not a
3235 # problem because the exact names of the sub-directories concerned is
3236 # unimportant, just the number of them matters.
3237 #
3238 # The practical upshot of these patterns is like this:
3239 #
3240 #  prefix     exec_prefix        result
3241 #  ------     -----------        ------
3242 #   /foo        /foo/bar          ../
3243 #   /foo/       /foo/bar          ../
3244 #   /foo        /foo/bar/         ../
3245 #   /foo/       /foo/bar/         ../
3246 #   /foo        /foo/bar/ugg      ../../
3247 #
3248     dollar='$$'
3249     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3250 changequote([, ])dnl
3251 fi
3252 AC_SUBST(gcc_tooldir)
3253 AC_SUBST(dollar)
3254
3255 # Find a directory in which to install a shared libgcc.
3256
3257 AC_ARG_ENABLE(version-specific-runtime-libs,
3258 [  --enable-version-specific-runtime-libs
3259                           specify that runtime libraries should be
3260                           installed in a compiler-specific directory])
3261
3262 AC_ARG_WITH(slibdir,
3263 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3264 slibdir="$with_slibdir",
3265 if test "${enable_version_specific_runtime_libs+set}" = set; then
3266   slibdir='$(libsubdir)'
3267 elif test "$host" != "$target"; then
3268   slibdir='$(build_tooldir)/lib'
3269 else
3270   slibdir='$(libdir)'
3271 fi)
3272 AC_SUBST(slibdir)
3273
3274 objdir=`${PWDCMD-pwd}`
3275 AC_SUBST(objdir)
3276
3277 # Substitute configuration variables
3278 AC_SUBST(subdirs)
3279 AC_SUBST(srcdir)
3280 AC_SUBST(all_boot_languages)
3281 AC_SUBST(all_compilers)
3282 AC_SUBST(all_gtfiles)
3283 AC_SUBST(all_gtfiles_files_langs)
3284 AC_SUBST(all_gtfiles_files_files)
3285 AC_SUBST(all_lang_makefrags)
3286 AC_SUBST(all_lang_makefiles)
3287 AC_SUBST(all_languages)
3288 AC_SUBST(all_stagestuff)
3289 AC_SUBST(build_exeext)
3290 AC_SUBST(build_install_headers_dir)
3291 AC_SUBST(build_xm_file_list)
3292 AC_SUBST(build_xm_include_list)
3293 AC_SUBST(build_xm_defines)
3294 AC_SUBST(check_languages)
3295 AC_SUBST(cc_set_by_configure)
3296 AC_SUBST(quoted_cc_set_by_configure)
3297 AC_SUBST(cpp_install_dir)
3298 AC_SUBST(xmake_file)
3299 AC_SUBST(tmake_file)
3300 AC_SUBST(extra_gcc_objs)
3301 AC_SUBST(extra_headers_list)
3302 AC_SUBST(extra_objs)
3303 AC_SUBST(extra_parts)
3304 AC_SUBST(extra_passes)
3305 AC_SUBST(extra_programs)
3306 AC_SUBST(float_h_file)
3307 AC_SUBST(gcc_config_arguments)
3308 AC_SUBST(gcc_gxx_include_dir)
3309 AC_SUBST(libstdcxx_incdir)
3310 AC_SUBST(host_exeext)
3311 AC_SUBST(host_xm_file_list)
3312 AC_SUBST(host_xm_include_list)
3313 AC_SUBST(host_xm_defines)
3314 AC_SUBST(out_host_hook_obj)
3315 AC_SUBST(install)
3316 AC_SUBST(lang_opt_files)
3317 AC_SUBST(lang_specs_files)
3318 AC_SUBST(lang_tree_files)
3319 AC_SUBST(local_prefix)
3320 AC_SUBST(md_file)
3321 AC_SUBST(objc_boehm_gc)
3322 AC_SUBST(out_file)
3323 AC_SUBST(out_object_file)
3324 AC_SUBST(stage_prefix_set_by_configure)
3325 AC_SUBST(quoted_stage_prefix_set_by_configure)
3326 AC_SUBST(thread_file)
3327 AC_SUBST(tm_file_list)
3328 AC_SUBST(tm_include_list)
3329 AC_SUBST(tm_defines)
3330 AC_SUBST(tm_p_file_list)
3331 AC_SUBST(tm_p_include_list)
3332 AC_SUBST(xm_file_list)
3333 AC_SUBST(xm_include_list)
3334 AC_SUBST(xm_defines)
3335 AC_SUBST(c_target_objs)
3336 AC_SUBST(cxx_target_objs)
3337 AC_SUBST(target_cpu_default)
3338
3339 AC_SUBST_FILE(language_hooks)
3340
3341 TL_AC_GNU_MAKE_GCC_LIB_PATH
3342
3343 # Echo link setup.
3344 if test x${build} = x${host} ; then
3345   if test x${host} = x${target} ; then
3346     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3347   else
3348     echo "Links are now set up to build a cross-compiler" 1>&2
3349     echo " from ${host} to ${target}." 1>&2
3350   fi
3351 else
3352   if test x${host} = x${target} ; then
3353     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3354     echo " for ${target}." 1>&2
3355   else
3356     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3357     echo " from ${host} to ${target}." 1>&2
3358   fi
3359 fi
3360
3361 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3362 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3363
3364 # Configure the subdirectories
3365 # AC_CONFIG_SUBDIRS($subdirs)
3366
3367 # Create the Makefile
3368 # and configure language subdirectories
3369 AC_CONFIG_FILES($all_outputs)
3370
3371 AC_CONFIG_COMMANDS([default],
3372 [
3373 case ${CONFIG_HEADERS} in
3374   *auto-host.h:config.in*)
3375   echo > cstamp-h ;;
3376 esac
3377 # Make sure all the subdirs exist.
3378 for d in $subdirs doc build
3379 do
3380     test -d $d || mkdir $d
3381 done
3382 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3383 # bootstrapping and the installation procedure can still use
3384 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3385 # FLAGS_TO_PASS has been modified to solve the problem there.
3386 # This is virtually a duplicate of what happens in configure.lang; we do
3387 # an extra check to make sure this only happens if ln -s can be used.
3388 case "$LN_S" in
3389   *-s*)
3390     for d in ${subdirs} ; do
3391         STARTDIR=`${PWDCMD-pwd}`
3392         cd $d
3393         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3394         do
3395                 rm -f $t
3396                 $LN_S ../$t $t 2>/dev/null
3397         done
3398         cd $STARTDIR
3399     done
3400   ;;
3401 esac
3402 ], 
3403 [subdirs='$subdirs'])
3404 AC_OUTPUT