gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 ACX_PROG_GNAT([-I"$srcdir"/ada])
 280
 281 # autoconf is lame and doesn't give us any substitution variable for this.
 282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 283   NO_MINUS_C_MINUS_O=yes
 284 else
 285   OUTPUT_OPTION='-o $@'
 286 fi
 287 AC_SUBST(NO_MINUS_C_MINUS_O)
 288 AC_SUBST(OUTPUT_OPTION)
 289
 290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 291 # optimizations to be activated explicitly by the toplevel.
 292 case "$CC" in
 293   */prev-gcc/xgcc*) ;;
 294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 295 esac
 296 AC_SUBST(CFLAGS)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 # sizeof(char) is 1 by definition.
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(int)
 310 AC_CHECK_SIZEOF(long)
 311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 313
 314 # ---------------------
 315 # Warnings and checking
 316 # ---------------------
 317
 318 # Check $CC warning features (if it's GCC).
 319 # We want to use -pedantic, but we don't want warnings about
 320 # * 'long long'
 321 # * variadic macros
 322 # * overlong strings
 323 # So, we only use -pedantic if we can disable those warnings.
 324
 325 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 326                           -Wmissing-prototypes], [loose_warn])
 327 ACX_PROG_CC_WARNING_OPTS([-Wc++-compat], [cxx_compat_warn])
 328 ACX_PROG_CC_WARNING_OPTS([-Wold-style-definition \
 329                           -Wmissing-format-attribute], [strict_warn])
 330 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long -Wno-variadic-macros \
 331                                      -Wno-overlength-strings], [strict_warn])
 332 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 333
 334 # The above macros do nothing if the compiler is not GCC.  However, the
 335 # Makefile has more goo to add other flags, so this variabl is used to
 336 # enables warnings only for GCC.
 337 warn_cflags=
 338 if test "x$GCC" = "xyes"; then
 339   warn_cflags='$(GCC_WARN_CFLAGS)'
 340 fi
 341 AC_SUBST(warn_cflags)
 342
 343 # Enable expensive internal checks
 344 is_release=
 345 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 346   is_release=yes
 347 fi
 348
 349 AC_ARG_ENABLE(checking,
 350 [  --enable-checking[=LIST]
 351                           enable expensive run-time checks.  With LIST,
 352                           enable only specific categories of checks.
 353                           Categories are: yes,no,all,none,release.
 354                           Flags are: assert,df,fold,gc,gcac,misc,
 355                           rtlflag,rtl,runtime,tree,valgrind,types.],
 356 [ac_checking_flags="${enableval}"],[
 357 # Determine the default checks.
 358 if test x$is_release = x ; then
 359   ac_checking_flags=yes
 360 else
 361   ac_checking_flags=release
 362 fi])
 363 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 364 for check in release $ac_checking_flags
 365 do
 366         case $check in
 367         # these set all the flags to specific states
 368         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 369                         ac_fold_checking= ; ac_gc_checking=1 ;
 370                         ac_gc_always_collect= ; ac_rtl_checking= ;
 371                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 372                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 373                         ac_types_checking=1 ;;
 374         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 375                         ac_fold_checking= ; ac_gc_checking= ;
 376                         ac_gc_always_collect= ; ac_rtl_checking= ;
 377                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 378                         ac_tree_checking= ; ac_valgrind_checking= ;
 379                         ac_types_checking= ;;
 380         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 381                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 382                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 383                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 384                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 385                         ac_types_checking=1 ;;
 386         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 387                         ac_fold_checking= ; ac_gc_checking= ;
 388                         ac_gc_always_collect= ; ac_rtl_checking= ;
 389                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 390                         ac_tree_checking= ; ac_valgrind_checking= ;
 391                         ac_types_checking= ;;
 392         # these enable particular checks
 393         assert)         ac_assert_checking=1 ;;
 394         df)             ac_df_checking=1 ;;
 395         fold)           ac_fold_checking=1 ;;
 396         gc)             ac_gc_checking=1 ;;
 397         gcac)           ac_gc_always_collect=1 ;;
 398         misc)           ac_checking=1 ;;
 399         rtl)            ac_rtl_checking=1 ;;
 400         rtlflag)        ac_rtlflag_checking=1 ;;
 401         runtime)        ac_runtime_checking=1 ;;
 402         tree)           ac_tree_checking=1 ;;
 403         types)          ac_types_checking=1 ;;
 404         valgrind)       ac_valgrind_checking=1 ;;
 405         *)      AC_MSG_ERROR(unknown check category $check) ;;
 406         esac
 407 done
 408 IFS="$ac_save_IFS"
 409
 410 nocommon_flag=""
 411 if test x$ac_checking != x ; then
 412   AC_DEFINE(ENABLE_CHECKING, 1,
 413 [Define if you want more run-time sanity checks.  This one gets a grab
 414    bag of miscellaneous but relatively cheap checks.])
 415   nocommon_flag=-fno-common
 416 fi
 417 AC_SUBST(nocommon_flag)
 418 if test x$ac_df_checking != x ; then
 419   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 420 [Define if you want more run-time sanity checks for dataflow.])
 421 fi
 422 if test x$ac_assert_checking != x ; then
 423   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 424 [Define if you want assertions enabled.  This is a cheap check.])
 425 fi
 426 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 427 if test x$ac_runtime_checking != x ; then
 428   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 429 [Define if you want runtime assertions enabled.  This is a cheap check.])
 430 fi
 431 if test x$ac_tree_checking != x ; then
 432   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 433 [Define if you want all operations on trees (the basic data
 434    structure of the front ends) to be checked for dynamic type safety
 435    at runtime.  This is moderately expensive.  The tree browser debugging
 436    routines will also be enabled by this option.
 437    ])
 438   TREEBROWSER=tree-browser.o
 439 fi
 440 if test x$ac_types_checking != x ; then
 441   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 442 [Define if you want all gimple types to be verified after gimplifiation.
 443    This is cheap.
 444    ])
 445 fi
 446 AC_SUBST(TREEBROWSER)
 447 if test x$ac_rtl_checking != x ; then
 448   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 449 [Define if you want all operations on RTL (the basic data structure
 450    of the optimizer and back end) to be checked for dynamic type safety
 451    at runtime.  This is quite expensive.])
 452 fi
 453 if test x$ac_rtlflag_checking != x ; then
 454   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 455 [Define if you want RTL flag accesses to be checked against the RTL
 456    codes that are supported for each access macro.  This is relatively
 457    cheap.])
 458 fi
 459 if test x$ac_gc_checking != x ; then
 460   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 461 [Define if you want the garbage collector to do object poisoning and
 462    other memory allocation checks.  This is quite expensive.])
 463 fi
 464 if test x$ac_gc_always_collect != x ; then
 465   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 466 [Define if you want the garbage collector to operate in maximally
 467    paranoid mode, validating the entire heap and collecting garbage at
 468    every opportunity.  This is extremely expensive.])
 469 fi
 470 if test x$ac_fold_checking != x ; then
 471   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 472 [Define if you want fold checked that it never destructs its argument.
 473    This is quite expensive.])
 474 fi
 475 valgrind_path_defines=
 476 valgrind_command=
 477
 478 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 479 dnl # an if statement.  This was the source of very frustrating bugs
 480 dnl # in converting to autoconf 2.5x!
 481 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 482
 483 if test x$ac_valgrind_checking != x ; then
 484   # It is certainly possible that there's valgrind but no valgrind.h.
 485   # GCC relies on making annotations so we must have both.
 486   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 487   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 488     [[#include <valgrind/memcheck.h>
 489 #ifndef VALGRIND_DISCARD
 490 #error VALGRIND_DISCARD not defined
 491 #endif]])],
 492   [gcc_cv_header_valgrind_memcheck_h=yes],
 493   [gcc_cv_header_valgrind_memcheck_h=no])
 494   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 497     [[#include <memcheck.h>
 498 #ifndef VALGRIND_DISCARD
 499 #error VALGRIND_DISCARD not defined
 500 #endif]])],
 501   [gcc_cv_header_memcheck_h=yes],
 502   [gcc_cv_header_memcheck_h=no])
 503   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 504   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 505         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 506   if test "x$valgrind_path" = "x" \
 507     || (test $have_valgrind_h = no \
 508         && test $gcc_cv_header_memcheck_h = no \
 509         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 510         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 511   fi
 512   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 513   valgrind_command="$valgrind_path -q"
 514   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 515 [Define if you want to run subprograms and generated programs
 516    through valgrind (a memory checker).  This is extremely expensive.])
 517   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 518     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 519         [Define if valgrind's valgrind/memcheck.h header is installed.])
 520   fi
 521   if test $gcc_cv_header_memcheck_h = yes; then
 522     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 523         [Define if valgrind's memcheck.h header is installed.])
 524   fi
 525 fi
 526 AC_SUBST(valgrind_path_defines)
 527 AC_SUBST(valgrind_command)
 528
 529 # Enable code coverage collection
 530 AC_ARG_ENABLE(coverage,
 531 [  --enable-coverage[=LEVEL]
 532                           enable compiler's code coverage collection.
 533                           Use to measure compiler performance and locate
 534                           unused parts of the compiler. With LEVEL, specify
 535                           optimization. Values are opt, noopt,
 536                           default is noopt],
 537 [case "${enableval}" in
 538   yes|noopt)
 539     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 540     ;;
 541   opt)
 542     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 543     ;;
 544   no)
 545     # a.k.a. --disable-coverage
 546     coverage_flags=""
 547     ;;
 548   *)
 549     AC_MSG_ERROR(unknown coverage setting $enableval)
 550     ;;
 551 esac],
 552 [coverage_flags=""])
 553 AC_SUBST(coverage_flags)
 554
 555 AC_ARG_ENABLE(gather-detailed-mem-stats,
 556 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 557 [enable_gather_detailed_mem_stats=no])
 558 if test x$enable_gather_detailed_mem_stats = xyes ; then
 559   AC_DEFINE(GATHER_STATISTICS, 1,
 560         [Define to enable detailed memory allocation stats gathering.])
 561 fi
 562
 563 # -------------------------------
 564 # Miscenalleous configure options
 565 # -------------------------------
 566
 567 # With stabs
 568 AC_ARG_WITH(stabs,
 569 [  --with-stabs            arrange to use stabs instead of host debug format],
 570 stabs="$with_stabs",
 571 stabs=no)
 572
 573 # Determine whether or not multilibs are enabled.
 574 AC_ARG_ENABLE(multilib,
 575 [  --enable-multilib       enable library support for multiple ABIs],
 576 [], [enable_multilib=yes])
 577 AC_SUBST(enable_multilib)
 578
 579 # Enable __cxa_atexit for C++.
 580 AC_ARG_ENABLE(__cxa_atexit,
 581 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 582 [], [])
 583
 584 # Enable C extension for decimal float if target supports it.
 585 AC_ARG_ENABLE(decimal-float,
 586 [  --enable-decimal-float={no,yes,bid,dpd}
 587                         enable decimal float extension to C.  Selecting 'bid'
 588                         or 'dpd' choses which decimal floating point format
 589                         to use],
 590 [
 591   case $enable_decimal_float in
 592     yes | no | bid | dpd) ;;
 593     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 594 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 595   esac
 596 ],
 597 [
 598   case $target in
 599     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 600       enable_decimal_float=yes
 601       ;;
 602     *)
 603       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 604       enable_decimal_float=no
 605       ;;
 606   esac
 607 ])
 608
 609 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 610 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 611 [Define to 1 to enable decimal float extension to C.])
 612
 613 # x86's use BID format instead of DPD
 614 case x$enable_decimal_float in
 615   xyes)
 616     case $target in
 617       i?86*-*-linux* | x86_64*-*-linux*)
 618         enable_decimal_float=bid
 619         ;;
 620       *)
 621         enable_decimal_float=dpd
 622         ;;
 623     esac
 624     ;;
 625   xno)
 626     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 627     # dependency on libdecnumber.
 628     enable_decimal_float=dpd
 629     ;;
 630 esac
 631 AC_SUBST(enable_decimal_float)
 632
 633 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 634 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 635 [Define to 1 to specify that we are using the BID decimal floating
 636 point format instead of DPD])
 637
 638 # Enable C extension for fixed-point arithmetic.
 639 AC_ARG_ENABLE(fixed-point,
 640 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 641 [
 642 ],
 643 [
 644   case $target in
 645     mips*-*-*)
 646       case $host in
 647         mips*-sgi-irix*)
 648           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 649           enable_fixed_point=no
 650           ;;
 651         *)
 652           enable_fixed_point=yes
 653           ;;
 654       esac
 655       ;;
 656     *)
 657       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 658       enable_fixed_point=no
 659       ;;
 660   esac
 661 ])
 662 AC_SUBST(enable_fixed_point)
 663
 664 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 665 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 666 [Define to 1 to enable fixed-point arithmetic extension to C.])
 667
 668 # Enable threads
 669 # Pass with no value to take the default
 670 # Pass with a value to specify a thread package
 671 AC_ARG_ENABLE(threads,
 672 [  --enable-threads        enable thread usage for target GCC
 673   --enable-threads=LIB    use LIB thread package for target GCC],,
 674 [enable_threads=''])
 675
 676 AC_ARG_ENABLE(tls,
 677 [  --enable-tls            enable or disable generation of tls code
 678                           overriding the assembler check for tls support],
 679 [
 680   case $enable_tls in
 681     yes | no) ;;
 682     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 683 Valid choices are 'yes' and 'no'.]) ;;
 684   esac
 685 ], [enable_tls=''])
 686
 687 AC_ARG_ENABLE(objc-gc,
 688 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 689                           the GNU Objective-C runtime],
 690 if test x$enable_objc_gc = xno; then
 691         objc_boehm_gc=''
 692 else
 693         objc_boehm_gc=1
 694 fi,
 695 objc_boehm_gc='')
 696
 697 AC_ARG_WITH(dwarf2,
 698 [  --with-dwarf2           force the default debug format to be DWARF 2],
 699 dwarf2="$with_dwarf2",
 700 dwarf2=no)
 701
 702 AC_ARG_ENABLE(shared,
 703 [  --disable-shared        don't provide a shared libgcc],
 704 [
 705   case $enable_shared in
 706   yes | no) ;;
 707   *)
 708     enable_shared=no
 709     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 710     for pkg in $enableval; do
 711       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 712         enable_shared=yes
 713       fi
 714     done
 715     IFS="$ac_save_ifs"
 716     ;;
 717   esac
 718 ], [enable_shared=yes])
 719 AC_SUBST(enable_shared)
 720
 721 AC_ARG_WITH(build-sysroot,
 722   [  --with-build-sysroot=sysroot
 723                           use sysroot as the system root during the build])
 724
 725 AC_ARG_WITH(sysroot,
 726 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 727 [
 728  case ${with_sysroot} in
 729  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 730  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 731  esac
 732
 733  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 734  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 735
 736  if test "x$prefix" = xNONE; then
 737   test_prefix=/usr/local
 738  else
 739   test_prefix=$prefix
 740  fi
 741  if test "x$exec_prefix" = xNONE; then
 742   test_exec_prefix=$test_prefix
 743  else
 744   test_exec_prefix=$exec_prefix
 745  fi
 746  case ${TARGET_SYSTEM_ROOT} in
 747  "${test_prefix}"|"${test_prefix}/"*|\
 748  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 749  '${prefix}'|'${prefix}/'*|\
 750  '${exec_prefix}'|'${exec_prefix}/'*)
 751    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 752    TARGET_SYSTEM_ROOT_DEFINE="$t"
 753    ;;
 754  esac
 755 ], [
 756  TARGET_SYSTEM_ROOT=
 757  TARGET_SYSTEM_ROOT_DEFINE=
 758  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 759 ])
 760 AC_SUBST(TARGET_SYSTEM_ROOT)
 761 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 762 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 763
 764 # Build with intermodule optimisations
 765 AC_ARG_ENABLE(intermodule,
 766 [  --enable-intermodule    build the compiler in one step],
 767 [case ${enable_intermodule} in
 768   yes) onestep="-onestep";;
 769   *) onestep="";;
 770 esac],
 771 [onestep=""])
 772 AC_SUBST(onestep)
 773
 774 ACX_PKGVERSION([GCC])
 775 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 776
 777 # Sanity check enable_languages in case someone does not run the toplevel
 778 # configure # script.
 779 AC_ARG_ENABLE(languages,
 780 [  --enable-languages=LIST specify which front-ends to build],
 781 [case ,${enable_languages}, in
 782        ,,|,yes,)
 783                 # go safe -- we cannot be much sure without the toplevel
 784                 # configure's
 785                 # analysis of which target libs are present and usable
 786                 enable_languages=c
 787                 ;;
 788          *,all,*)
 789                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 790                 ;;
 791         *,c,*)
 792                 ;;
 793         *)
 794                 enable_languages=c,${enable_languages}
 795                 ;;
 796 esac],
 797 [enable_languages=c])
 798
 799 # Used by documentation targets
 800 AC_SUBST(datarootdir)
 801 AC_SUBST(docdir)
 802 AC_SUBST(htmldir)
 803
 804 # -------------------------
 805 # Checks for other programs
 806 # -------------------------
 807
 808 AC_PROG_MAKE_SET
 809
 810 # Find some useful tools
 811 AC_PROG_AWK
 812 # We need awk to create options.c and options.h.
 813 # Bail out if it's missing.
 814 case ${AWK} in
 815   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 816 esac
 817
 818 gcc_AC_PROG_LN_S
 819 ACX_PROG_LN($LN_S)
 820 AC_PROG_RANLIB
 821 case "${host}" in
 822 *-*-darwin*)
 823   # By default, the Darwin ranlib will not treat common symbols as
 824   # definitions when  building the archive table of contents.  Other
 825   # ranlibs do that; pass an option to the Darwin ranlib that makes
 826   # it behave similarly.
 827   ranlib_flags="-c"
 828   ;;
 829 *)
 830   ranlib_flags=""
 831 esac
 832 AC_SUBST(ranlib_flags)
 833
 834 gcc_AC_PROG_INSTALL
 835
 836 # See if cmp has --ignore-initial.
 837 gcc_AC_PROG_CMP_IGNORE_INITIAL
 838
 839 # See if we have the mktemp command.
 840 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 841
 842 # See if makeinfo has been installed and is modern enough
 843 # that we can use it.
 844 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 845   [GNU texinfo.* \([0-9][0-9.]*\)],
 846   [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 847 if test $gcc_cv_prog_makeinfo_modern = no; then
 848   AC_MSG_WARN([
 849 *** Makeinfo is missing or too old.
 850 *** Info documentation will not be built.])
 851   BUILD_INFO=
 852 else
 853   BUILD_INFO=info
 854 fi
 855 AC_SUBST(BUILD_INFO)
 856
 857 # Is pod2man recent enough to regenerate manpages?
 858 AC_MSG_CHECKING([for recent Pod::Man])
 859 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 860   AC_MSG_RESULT(yes)
 861   GENERATED_MANPAGES=generated-manpages
 862 else
 863   AC_MSG_RESULT(no)
 864   GENERATED_MANPAGES=
 865 fi
 866 AC_SUBST(GENERATED_MANPAGES)
 867
 868 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 869
 870 # How about lex?
 871 dnl Don't use AC_PROG_LEX; we insist on flex.
 872 dnl LEXLIB is not useful in gcc.
 873 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 874
 875 # Bison?
 876 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 877
 878 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 879 # check for build == host before using them.
 880
 881 # NM
 882 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 883   && test -d ../binutils ; then
 884   NM='$(objdir)/../binutils/nm-new'
 885 else
 886   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 887 fi
 888
 889 # AR
 890 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 891   && test -d ../binutils ; then
 892   AR='$(objdir)/../binutils/ar'
 893 else
 894   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 895 fi
 896
 897
 898 # --------------------
 899 # Checks for C headers
 900 # --------------------
 901
 902 # Need to reject headers which give warnings, so that the -Werror bootstrap
 903 # works later. *sigh*  This needs to come before all header checks.
 904 AC_PROG_CPP_WERROR
 905
 906 AC_HEADER_STDC
 907 AC_HEADER_TIME
 908 ACX_HEADER_STRING
 909 AC_HEADER_SYS_WAIT
 910 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 911                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 912                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 913                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 914
 915 # Check for thread headers.
 916 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 917 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 918
 919 # These tests can't be done till we know if we have limits.h.
 920 gcc_AC_C_CHAR_BIT
 921 AC_C_BIGENDIAN
 922
 923 # --------
 924 # UNSORTED
 925 # --------
 926
 927
 928 # These libraries may be used by collect2.
 929 # We may need a special search path to get them linked.
 930 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 931 [save_LIBS="$LIBS"
 932 for libs in '' -lld -lmld \
 933                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 934                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 935 do
 936         LIBS="$libs"
 937         AC_TRY_LINK_FUNC(ldopen,
 938                 [gcc_cv_collect2_libs="$libs"; break])
 939 done
 940 LIBS="$save_LIBS"
 941 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 942 case $gcc_cv_collect2_libs in
 943         "none required")        ;;
 944         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 945 esac
 946 AC_SUBST(COLLECT2_LIBS)
 947
 948 # When building Ada code on Alpha, we need exc_resume which is usually in
 949 # -lexc.  So test for it.
 950 save_LIBS="$LIBS"
 951 LIBS=
 952 AC_SEARCH_LIBS(exc_resume, exc)
 953 GNAT_LIBEXC="$LIBS"
 954 LIBS="$save_LIBS"
 955 AC_SUBST(GNAT_LIBEXC)
 956
 957 # Some systems put ldexp and frexp in libm instead of libc; assume
 958 # they're both in the same place.  jcf-dump needs them.
 959 save_LIBS="$LIBS"
 960 LIBS=
 961 AC_SEARCH_LIBS(ldexp, m)
 962 LDEXP_LIB="$LIBS"
 963 LIBS="$save_LIBS"
 964 AC_SUBST(LDEXP_LIB)
 965
 966 # Use <inttypes.h> only if it exists,
 967 # doesn't clash with <sys/types.h>, and declares intmax_t.
 968 AC_MSG_CHECKING(for inttypes.h)
 969 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 970 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 971 [[#include <sys/types.h>
 972 #include <inttypes.h>]],
 973   [[intmax_t i = -1;]])],
 974   [gcc_cv_header_inttypes_h=yes],
 975   [gcc_cv_header_inttypes_h=no])])
 976 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 977 if test $gcc_cv_header_inttypes_h = yes; then
 978   AC_DEFINE(HAVE_INTTYPES_H, 1,
 979         [Define if you have a working <inttypes.h> header file.])
 980 fi
 981
 982 dnl Disabled until we have a complete test for buggy enum bitfields.
 983 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 984
 985 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 986   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 987   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 988   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 989   putchar_unlocked putc_unlocked)
 990 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
 991         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 992         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 993         gcc_UNLOCKED_FUNCS)
 994
 995 if test x$ac_cv_func_mbstowcs = xyes; then
 996   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 997 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 998 int main()
 999 {
1000   mbstowcs(0, "", 0);
1001   return 0;
1002 }]])],
1003     [gcc_cv_func_mbstowcs_works=yes],
1004     [gcc_cv_func_mbstowcs_works=no],
1005     [gcc_cv_func_mbstowcs_works=yes])])
1006   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1007     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1008   [Define this macro if mbstowcs does not crash when its
1009    first argument is NULL.])
1010   fi
1011 fi
1012
1013 AC_CHECK_TYPE(ssize_t, int)
1014
1015 # Try to determine the array type of the second argument of getgroups
1016 # for the target system (int or gid_t).
1017 AC_TYPE_GETGROUPS
1018 if test "${target}" = "${build}"; then
1019   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1020 else
1021   case "${target}" in
1022         # This condition may need some tweaking.  It should include all
1023         # targets where the array type of the second argument of getgroups
1024         # is int and the type of gid_t is not equivalent to int.
1025         *-*-sunos* | *-*-ultrix*)
1026                 TARGET_GETGROUPS_T=int
1027                 ;;
1028         *)
1029                 TARGET_GETGROUPS_T=gid_t
1030                 ;;
1031   esac
1032 fi
1033 AC_SUBST(TARGET_GETGROUPS_T)
1034
1035 gcc_AC_FUNC_MMAP_BLACKLIST
1036
1037 case "${host}" in
1038 *-*-*vms*)
1039   # Under VMS, vfork works very differently than on Unix. The standard test
1040   # won't work, and it isn't easily adaptable. It makes more sense to
1041   # just force it.
1042   ac_cv_func_vfork_works=yes
1043   ;;
1044 esac
1045 AC_FUNC_FORK
1046
1047 AM_ICONV
1048 # Until we have in-tree GNU iconv:
1049 LIBICONV_DEP=
1050 AC_SUBST(LIBICONV_DEP)
1051
1052 AM_LC_MESSAGES
1053
1054 AM_LANGINFO_CODESET
1055
1056 # We will need to find libiberty.h and ansidecl.h
1057 saved_CFLAGS="$CFLAGS"
1058 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1059 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1060         strsignal strstr strverscmp \
1061         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1062         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1063 #include "ansidecl.h"
1064 #include "system.h"])
1065
1066 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1067 #include "ansidecl.h"
1068 #include "system.h"
1069 #ifdef HAVE_SYS_RESOURCE_H
1070 #include <sys/resource.h>
1071 #endif
1072 ])
1073
1074 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1075 #include "ansidecl.h"
1076 #include "system.h"
1077 #ifdef HAVE_SYS_RESOURCE_H
1078 #include <sys/resource.h>
1079 #endif
1080 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1081 [Define to \`long' if <sys/resource.h> doesn't define.])])
1082
1083 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1084 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1085 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1086 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1087 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #ifdef HAVE_LDFCN_H
1091 #undef FREAD
1092 #undef FWRITE
1093 #include <ldfcn.h>
1094 #endif
1095 ])
1096
1097 gcc_AC_CHECK_DECLS(times, , ,[
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 #ifdef HAVE_SYS_TIMES_H
1101 #include <sys/times.h>
1102 #endif
1103 ])
1104
1105 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1106 #include "ansidecl.h"
1107 #include "system.h"
1108 #include <signal.h>
1109 ])
1110
1111 # More time-related stuff.
1112 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1113 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1114 #include "ansidecl.h"
1115 #include "system.h"
1116 #ifdef HAVE_SYS_TIMES_H
1117 #include <sys/times.h>
1118 #endif
1119 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1120 if test $ac_cv_struct_tms = yes; then
1121   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1122   [Define if <sys/times.h> defines struct tms.])
1123 fi
1124
1125 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1126 # revisit after autoconf 2.50.
1127 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1128 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1129 #include "ansidecl.h"
1130 #include "system.h"
1131 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1132 if test $gcc_cv_type_clock_t = yes; then
1133   AC_DEFINE(HAVE_CLOCK_T, 1,
1134   [Define if <time.h> defines clock_t.])
1135 fi
1136
1137 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1138 CFLAGS="$saved_CFLAGS"
1139
1140 gcc_AC_INITFINI_ARRAY
1141
1142 # mkdir takes a single argument on some systems.
1143 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1144
1145 # File extensions
1146 manext='.1'
1147 objext='.o'
1148 AC_SUBST(manext)
1149 AC_SUBST(objext)
1150
1151 # With Setjmp/Longjmp based exception handling.
1152 AC_ARG_ENABLE(sjlj-exceptions,
1153 [  --enable-sjlj-exceptions
1154                           arrange to use setjmp/longjmp exception handling],
1155 [case $target in
1156   *-*-hpux10*)
1157     if test $enableval != yes; then
1158       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1159       enableval=yes
1160     fi
1161     ;;
1162 esac
1163 force_sjlj_exceptions=yes],
1164 [case $target in
1165   *-*-hpux10*)
1166     force_sjlj_exceptions=yes
1167     enableval=yes
1168     ;;
1169   *)
1170     force_sjlj_exceptions=no
1171     ;;
1172 esac])
1173 if test $force_sjlj_exceptions = yes; then
1174   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1175   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1176     [Define 0/1 to force the choice for exception handling model.])
1177 fi
1178
1179 # For platforms with the unwind ABI which includes an unwind library,
1180 # libunwind, we can choose to use the system libunwind.
1181 AC_ARG_WITH(system-libunwind,
1182 [  --with-system-libunwind use installed libunwind])
1183
1184 # config.gcc also contains tests of with_system_libunwind.
1185 if test x$with_system_libunwind = xyes; then
1186         AC_DEFINE(HAVE_GETIPINFO, 1,
1187 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1188 fi
1189
1190 # --------------------------------------------------------
1191 # Build, host, and target specific configuration fragments
1192 # --------------------------------------------------------
1193
1194 # Collect build-machine-specific information.
1195 . ${srcdir}/config.build
1196
1197 # Collect host-machine-specific information.
1198 . ${srcdir}/config.host
1199
1200 target_gtfiles=
1201
1202 # Collect target-machine-specific information.
1203 . ${srcdir}/config.gcc
1204
1205 extra_objs="${host_extra_objs} ${extra_objs}"
1206 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1207
1208 # Default the target-machine variables that were not explicitly set.
1209 if test x"$tm_file" = x
1210 then tm_file=$cpu_type/$cpu_type.h; fi
1211
1212 if test x"$extra_headers" = x
1213 then extra_headers=; fi
1214
1215 if test x$md_file = x
1216 then md_file=$cpu_type/$cpu_type.md; fi
1217
1218 if test x$out_file = x
1219 then out_file=$cpu_type/$cpu_type.c; fi
1220
1221 if test x"$tmake_file" = x
1222 then tmake_file=$cpu_type/t-$cpu_type
1223 fi
1224
1225 if test x"$dwarf2" = xyes
1226 then tm_file="$tm_file tm-dwarf2.h"
1227 fi
1228
1229 # Say what files are being used for the output code and MD file.
1230 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1231 echo "Using \`$srcdir/config/$md_file' as machine description file."
1232
1233 # If any of the xm_file variables contain nonexistent files, warn
1234 # about them and drop them.
1235
1236 bx=
1237 for x in $build_xm_file; do
1238   if    test -f $srcdir/config/$x
1239   then      bx="$bx $x"
1240   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1241   fi
1242 done
1243 build_xm_file="$bx"
1244
1245 hx=
1246 for x in $host_xm_file; do
1247   if    test -f $srcdir/config/$x
1248   then      hx="$hx $x"
1249   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1250   fi
1251 done
1252 host_xm_file="$hx"
1253
1254 tx=
1255 for x in $xm_file; do
1256   if    test -f $srcdir/config/$x
1257   then      tx="$tx $x"
1258   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1259   fi
1260 done
1261 xm_file="$tx"
1262
1263 count=a
1264 for f in $tm_file; do
1265         count=${count}x
1266 done
1267 if test $count = ax; then
1268         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1269 else
1270         echo "Using the following target machine macro files:"
1271         for f in $tm_file; do
1272                 echo "  $srcdir/config/$f"
1273         done
1274 fi
1275
1276 if test x$need_64bit_hwint = xyes; then
1277         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1278 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1279 fi
1280
1281 if test x$use_long_long_for_widest_fast_int = xyes; then
1282         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1283 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1284 efficiently supported by the host hardware.])
1285 fi
1286
1287 count=a
1288 for f in $host_xm_file; do
1289         count=${count}x
1290 done
1291 if test $count = a; then
1292         :
1293 elif test $count = ax; then
1294         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1295 else
1296         echo "Using the following host machine macro files:"
1297         for f in $host_xm_file; do
1298                 echo "  $srcdir/config/$f"
1299         done
1300 fi
1301 echo "Using ${out_host_hook_obj} for host machine hooks."
1302
1303 if test "$host_xm_file" != "$build_xm_file"; then
1304         count=a
1305         for f in $build_xm_file; do
1306                 count=${count}x
1307         done
1308         if test $count = a; then
1309                 :
1310         elif test $count = ax; then
1311                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1312         else
1313                 echo "Using the following build machine macro files:"
1314                 for f in $build_xm_file; do
1315                         echo "  $srcdir/config/$f"
1316                 done
1317         fi
1318 fi
1319
1320 case ${host} in
1321   powerpc*-*-darwin*)
1322     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1323       gcc_cv_mcontext_underscores,
1324       AC_COMPILE_IFELSE([
1325 #include <sys/cdefs.h>
1326 #include <sys/signal.h>
1327 #include <ucontext.h>
1328 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1329 ],
1330         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1331       if test $gcc_cv_mcontext_underscores = yes; then
1332         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1333           [mcontext_t fields start with __])
1334       fi
1335     ;;
1336 esac
1337
1338 # ---------
1339 # Threading
1340 # ---------
1341
1342 # Check if a valid thread package
1343 case ${enable_threads} in
1344   "" | no)
1345     # No threads
1346     target_thread_file='single'
1347     ;;
1348   yes)
1349     # default
1350     target_thread_file='single'
1351     ;;
1352   aix | dce | gnat | irix | posix | posix95 | rtems | \
1353   single | solaris | vxworks | win32 | mipssde)
1354     target_thread_file=${enable_threads}
1355     ;;
1356   *)
1357     echo "${enable_threads} is an unknown thread package" 1>&2
1358     exit 1
1359     ;;
1360 esac
1361
1362 if test x${thread_file} = x; then
1363   # No thread file set by target-specific clauses in config.gcc,
1364   # so use file chosen by default logic above
1365   thread_file=${target_thread_file}
1366 fi
1367
1368 # Make gthr-default.h if we have a thread file.
1369 gthread_flags=
1370 if test $thread_file != single; then
1371   rm -f gthr-default.h
1372   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1373   gthread_flags=-DHAVE_GTHR_DEFAULT
1374 fi
1375 AC_SUBST(gthread_flags)
1376
1377 # --------
1378 # UNSORTED
1379 # --------
1380
1381 use_cxa_atexit=no
1382 if test x$enable___cxa_atexit = xyes || \
1383    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1384   if test x$host = x$target; then
1385     case $host in
1386       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1387       # keyed to flag_use_cxa_atexit
1388       *-*-mingw32*)
1389         use_cxa_atexit=yes
1390         ;;
1391       *)
1392         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1393           [echo "__cxa_atexit can't be enabled on this target"])
1394         ;;
1395     esac
1396   else
1397     # We can't check for __cxa_atexit when building a cross, so assume
1398     # it is available
1399     use_cxa_atexit=yes
1400   fi
1401   if test x$use_cxa_atexit = xyes; then
1402     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1403       [Define if you want to use __cxa_atexit, rather than atexit, to
1404       register C++ destructors for local statics and global objects.
1405       This is essential for fully standards-compliant handling of
1406       destructors, but requires __cxa_atexit in libc.])
1407   fi
1408 fi
1409
1410 use_getipinfo=yes
1411 if test x$with_system_libunwind = xyes; then
1412    if test x$host = x$target; then
1413      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1414    fi
1415 fi
1416 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1417 if test x$use_getipinfo = xyes; then
1418    AC_DEFINE(HAVE_GETIPINFO, 1,
1419         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1420 else
1421    echo "The system unwind library does not support _Unwind_GetIPInfo."
1422 fi
1423
1424 # Look for a file containing extra machine modes.
1425 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1426   extra_modes_file='$(srcdir)'/config/${extra_modes}
1427   AC_SUBST(extra_modes_file)
1428   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1429   [Define to the name of a file containing a list of extra machine modes
1430    for this architecture.])
1431 fi
1432
1433 # Convert extra_options into a form suitable for Makefile use.
1434 extra_opt_files=
1435 for f in $extra_options; do
1436   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1437 done
1438 AC_SUBST(extra_opt_files)
1439
1440 # auto-host.h is the file containing items generated by autoconf and is
1441 # the first file included by config.h.
1442 # If host=build, it is correct to have bconfig include auto-host.h
1443 # as well.  If host!=build, we are in error and need to do more
1444 # work to find out the build config parameters.
1445 if test x$host = x$build
1446 then
1447         build_auto=auto-host.h
1448 else
1449         # We create a subdir, then run autoconf in the subdir.
1450         # To prevent recursion we set host and build for the new
1451         # invocation of configure to the build for this invocation
1452         # of configure.
1453         tempdir=build.$$
1454         rm -rf $tempdir
1455         mkdir $tempdir
1456         cd $tempdir
1457         case ${srcdir} in
1458         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1459         *) realsrcdir=../${srcdir};;
1460         esac
1461         saved_CFLAGS="${CFLAGS}"
1462         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1463         ${realsrcdir}/configure \
1464                 --enable-languages=${enable_languages-all} \
1465                 --target=$target_alias --host=$build_alias --build=$build_alias
1466         CFLAGS="${saved_CFLAGS}"
1467
1468         # We just finished tests for the build machine, so rename
1469         # the file auto-build.h in the gcc directory.
1470         mv auto-host.h ../auto-build.h
1471         cd ..
1472         rm -rf $tempdir
1473         build_auto=auto-build.h
1474 fi
1475 AC_SUBST(build_subdir)
1476
1477 tm_file="${tm_file} defaults.h"
1478 tm_p_file="${tm_p_file} tm-preds.h"
1479 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1480 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1481 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1482 # put this back in temporarily.
1483 xm_file="auto-host.h ansidecl.h ${xm_file}"
1484
1485 # --------
1486 # UNSORTED
1487 # --------
1488
1489 changequote(,)dnl
1490 # Compile in configure arguments.
1491 if test -f configargs.h ; then
1492         # Being re-configured.
1493         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1494         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1495 else
1496         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1497 fi
1498
1499 # Double all backslashes and backslash all quotes to turn
1500 # gcc_config_arguments into a C string.
1501 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1502 $gcc_config_arguments
1503 EOF
1504 gcc_config_arguments_str=`cat conftest.out`
1505 rm -f conftest.out
1506
1507 cat > configargs.h <<EOF
1508 /* Generated automatically. */
1509 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1510 static const char thread_model[] = "$thread_file";
1511
1512 static const struct {
1513   const char *name, *value;
1514 } configure_default_options[] = $configure_default_options;
1515 EOF
1516 changequote([,])dnl
1517
1518 # Internationalization
1519 ZW_GNU_GETTEXT_SISTER_DIR
1520
1521 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1522 # -liconv on the link line twice.
1523 case "$LIBINTL" in *$LIBICONV*)
1524         LIBICONV= ;;
1525 esac
1526
1527 AC_ARG_ENABLE(secureplt,
1528 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1529 [], [])
1530
1531 AC_ARG_ENABLE(cld,
1532 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1533 [enable_cld=no])
1534
1535 # Windows32 Registry support for specifying GCC installation paths.
1536 AC_ARG_ENABLE(win32-registry,
1537 [  --disable-win32-registry
1538                           disable lookup of installation paths in the
1539                           Registry on Windows hosts
1540   --enable-win32-registry enable registry lookup (default)
1541   --enable-win32-registry=KEY
1542                           use KEY instead of GCC version as the last portion
1543                           of the registry key],,)
1544
1545 case $host_os in
1546   win32 | pe | cygwin* | mingw32* | uwin*)
1547     if test "x$enable_win32_registry" != xno; then
1548       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1549     fi
1550
1551     if test "x$enable_win32_registry" != xno; then
1552       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1553   [Define to 1 if installation paths should be looked up in the Windows
1554    Registry. Ignored on non-Windows hosts.])
1555
1556       if test "x$enable_win32_registry" != xyes \
1557          && test "x$enable_win32_registry" != x; then
1558         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1559   [Define to be the last component of the Windows registry key under which
1560    to look for installation paths.  The full key used will be
1561    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1562    The default is the GCC version number.])
1563       fi
1564     fi
1565   ;;
1566 esac
1567
1568 # Get an absolute path to the GCC top-level source directory
1569 holddir=`${PWDCMD-pwd}`
1570 cd $srcdir
1571 topdir=`${PWDCMD-pwd}`
1572 cd $holddir
1573
1574 # Conditionalize the makefile for this host machine.
1575 xmake_file=
1576 for f in ${host_xmake_file}
1577 do
1578         if test -f ${srcdir}/config/$f
1579         then
1580                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1581         fi
1582 done
1583
1584 # Conditionalize the makefile for this target machine.
1585 tmake_file_=
1586 for f in ${tmake_file}
1587 do
1588         if test -f ${srcdir}/config/$f
1589         then
1590                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1591         fi
1592 done
1593 tmake_file="${tmake_file_}"
1594
1595 # This is a terrible hack which will go away some day.
1596 host_cc_for_libada=${CC}
1597 AC_SUBST(host_cc_for_libada)
1598
1599 out_object_file=`basename $out_file .c`.o
1600
1601 tm_file_list="options.h"
1602 tm_include_list="options.h"
1603 for f in $tm_file; do
1604   case $f in
1605     ./* )
1606        f=`echo $f | sed 's/^..//'`
1607        tm_file_list="${tm_file_list} $f"
1608        tm_include_list="${tm_include_list} $f"
1609        ;;
1610     defaults.h )
1611        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1612        tm_include_list="${tm_include_list} $f"
1613        ;;
1614     * )
1615        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1616        tm_include_list="${tm_include_list} config/$f"
1617        ;;
1618   esac
1619 done
1620
1621 tm_p_file_list=
1622 tm_p_include_list=
1623 for f in $tm_p_file; do
1624   case $f in
1625     tm-preds.h )
1626        tm_p_file_list="${tm_p_file_list} $f"
1627        tm_p_include_list="${tm_p_include_list} $f"
1628        ;;
1629     * )
1630        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1631        tm_p_include_list="${tm_p_include_list} config/$f"
1632   esac
1633 done
1634
1635 xm_file_list=
1636 xm_include_list=
1637 for f in $xm_file; do
1638   case $f in
1639     ansidecl.h )
1640        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1641        xm_include_list="${xm_include_list} $f"
1642        ;;
1643     auto-host.h )
1644        xm_file_list="${xm_file_list} $f"
1645        xm_include_list="${xm_include_list} $f"
1646        ;;
1647     * )
1648        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1649        xm_include_list="${xm_include_list} config/$f"
1650        ;;
1651   esac
1652 done
1653
1654 host_xm_file_list=
1655 host_xm_include_list=
1656 for f in $host_xm_file; do
1657   case $f in
1658     ansidecl.h )
1659        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1660        host_xm_include_list="${host_xm_include_list} $f"
1661        ;;
1662     auto-host.h )
1663        host_xm_file_list="${host_xm_file_list} $f"
1664        host_xm_include_list="${host_xm_include_list} $f"
1665        ;;
1666     * )
1667        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1668        host_xm_include_list="${host_xm_include_list} config/$f"
1669        ;;
1670   esac
1671 done
1672
1673 build_xm_file_list=
1674 for f in $build_xm_file; do
1675   case $f in
1676     ansidecl.h )
1677        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1678        build_xm_include_list="${build_xm_include_list} $f"
1679        ;;
1680     auto-build.h | auto-host.h )
1681        build_xm_file_list="${build_xm_file_list} $f"
1682        build_xm_include_list="${build_xm_include_list} $f"
1683        ;;
1684     * )
1685        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1686        build_xm_include_list="${build_xm_include_list} config/$f"
1687        ;;
1688   esac
1689 done
1690
1691 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1692 # cross-compiler which does not use the native headers and libraries.
1693 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1694 CROSS=                                          AC_SUBST(CROSS)
1695 ALL=all.internal                                AC_SUBST(ALL)
1696 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1697
1698 if test "x$with_build_sysroot" != x; then
1699   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1700 else
1701   # This value is used, even on a native system, because
1702   # CROSS_SYSTEM_HEADER_DIR is just
1703   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1704   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1705 fi
1706
1707 if test x$host != x$target
1708 then
1709         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1710         ALL=all.cross
1711         SYSTEM_HEADER_DIR=$build_system_header_dir
1712         case "$host","$target" in
1713         # Darwin crosses can use the host system's libraries and headers,
1714         # because of the fat library support.  Of course, it must be the
1715         # same version of Darwin on both sides.  Allow the user to
1716         # just say --target=foo-darwin without a version number to mean
1717         # "the version on this system".
1718             *-*-darwin*,*-*-darwin*)
1719                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1720                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1721                 if test $hostos = $targetos -o $targetos = darwin ; then
1722                     CROSS=
1723                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1724                     with_headers=yes
1725                 fi
1726                 ;;
1727
1728             i?86-*-*,x86_64-*-* \
1729             | powerpc*-*-*,powerpc64*-*-*)
1730                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1731         esac
1732 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1733         SYSTEM_HEADER_DIR=$build_system_header_dir
1734 fi
1735
1736 # If this is a cross-compiler that does not
1737 # have its own set of headers then define
1738 # inhibit_libc
1739
1740 # If this is using newlib, without having the headers available now,
1741 # then define inhibit_libc in LIBGCC2_CFLAGS.
1742 # This prevents libgcc2 from containing any code which requires libc
1743 # support.
1744 : ${inhibit_libc=false}
1745 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1746        test x$with_newlib = xyes ; } &&
1747      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1748        inhibit_libc=true
1749 fi
1750 AC_SUBST(inhibit_libc)
1751
1752 # When building gcc with a cross-compiler, we need to adjust things so
1753 # that the generator programs are still built with the native compiler.
1754 # Also, we cannot run fixincludes or fix-header.
1755
1756 # These are the normal (build=host) settings:
1757 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1758 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1759 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1760
1761 # Possibly disable fixproto, on a per-target basis.
1762 case ${use_fixproto} in
1763   no)
1764     STMP_FIXPROTO=
1765     ;;
1766   yes)
1767     STMP_FIXPROTO=stmp-fixproto
1768     ;;
1769 esac
1770 AC_SUBST(STMP_FIXPROTO)
1771
1772 # And these apply if build != host, or we are generating coverage data
1773 if test x$build != x$host || test "x$coverage_flags" != x
1774 then
1775     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1776
1777     if test "x$TARGET_SYSTEM_ROOT" = x; then
1778         if test "x$STMP_FIXPROTO" != x; then
1779           STMP_FIXPROTO=stmp-install-fixproto
1780         fi
1781     fi
1782 fi
1783
1784 # Expand extra_headers to include complete path.
1785 # This substitutes for lots of t-* files.
1786 extra_headers_list=
1787 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1788 for file in ${extra_headers} ; do
1789   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1790 done
1791
1792 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1793 if test x"$use_gcc_tgmath" = xyes
1794 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1795 fi
1796
1797 # Define collect2 in Makefile.
1798 case $host_can_use_collect2 in
1799   no) collect2= ;;
1800   *) collect2='collect2$(exeext)' ;;
1801 esac
1802 AC_SUBST([collect2])
1803
1804 # Add a definition of USE_COLLECT2 if system wants one.
1805 case $use_collect2 in
1806   no) use_collect2= ;;
1807   "") ;;
1808   *)
1809     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1810     xm_defines="${xm_defines} USE_COLLECT2"
1811     case $host_can_use_collect2 in
1812       no)
1813         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1814         ;;
1815     esac
1816     ;;
1817 esac
1818
1819 # ---------------------------
1820 # Assembler & linker features
1821 # ---------------------------
1822
1823 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1824 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1825 # However when ld-new is first executed from the build tree, libtool will
1826 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1827 # to the build tree.  While doing this we need to use the previous-stage
1828 # linker, or we have an infinite loop.  The presence of a shell script as
1829 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1830 # the gcc/collect-ld script.  So we need to know how libtool works, or
1831 # exec-tool will fail.
1832
1833 m4_defun([_LT_CONFIG_COMMANDS], [])
1834 AC_PROG_LIBTOOL
1835 AC_SUBST(objdir)
1836 AC_SUBST(enable_fast_install)
1837
1838 # Identify the assembler which will work hand-in-glove with the newly
1839 # built GCC, so that we can examine its features.  This is the assembler
1840 # which will be driven by the driver program.
1841 #
1842 # If build != host, and we aren't building gas in-tree, we identify a
1843 # build->target assembler and hope that it will have the same features
1844 # as the host->target assembler we'll be using.
1845 gcc_cv_gas_major_version=
1846 gcc_cv_gas_minor_version=
1847 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1848
1849 m4_pattern_allow([AS_FOR_TARGET])dnl
1850 AS_VAR_SET_IF(gcc_cv_as,, [
1851 if test -x "$DEFAULT_ASSEMBLER"; then
1852         gcc_cv_as="$DEFAULT_ASSEMBLER"
1853 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1854      && test -f ../gas/Makefile \
1855      && test x$build = x$host; then
1856         gcc_cv_as=../gas/as-new$build_exeext
1857 elif test -x as$build_exeext; then
1858         # Build using assembler in the current directory.
1859         gcc_cv_as=./as$build_exeext
1860 elif test -x $AS_FOR_TARGET; then
1861         gcc_cv_as="$AS_FOR_TARGET"
1862 else
1863         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1864 fi])
1865
1866 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1867 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1868 case "$ORIGINAL_AS_FOR_TARGET" in
1869   ./as | ./as$build_exeext) ;;
1870   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1871 esac
1872
1873 AC_MSG_CHECKING(what assembler to use)
1874 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1875   # Single tree build which includes gas.  We want to prefer it
1876   # over whatever linker top-level may have detected, since
1877   # we'll use what we're building after installation anyway.
1878   AC_MSG_RESULT(newly built gas)
1879   in_tree_gas=yes
1880   _gcc_COMPUTE_GAS_VERSION
1881   in_tree_gas_is_elf=no
1882   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1883      || (grep 'obj_format = multi' ../gas/Makefile \
1884          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1885   then
1886     in_tree_gas_is_elf=yes
1887   fi
1888 else
1889   AC_MSG_RESULT($gcc_cv_as)
1890   in_tree_gas=no
1891 fi
1892
1893 # Identify the linker which will work hand-in-glove with the newly
1894 # built GCC, so that we can examine its features.  This is the linker
1895 # which will be driven by the driver program.
1896 #
1897 # If build != host, and we aren't building gas in-tree, we identify a
1898 # build->target linker and hope that it will have the same features
1899 # as the host->target linker we'll be using.
1900 gcc_cv_gld_major_version=
1901 gcc_cv_gld_minor_version=
1902 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1903 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1904
1905 AS_VAR_SET_IF(gcc_cv_ld,, [
1906 if test -x "$DEFAULT_LINKER"; then
1907         gcc_cv_ld="$DEFAULT_LINKER"
1908 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1909      && test -f ../ld/Makefile \
1910      && test x$build = x$host; then
1911         gcc_cv_ld=../ld/ld-new$build_exeext
1912 elif test -x collect-ld$build_exeext; then
1913         # Build using linker in the current directory.
1914         gcc_cv_ld=./collect-ld$build_exeext
1915 elif test -x $LD_FOR_TARGET; then
1916         gcc_cv_ld="$LD_FOR_TARGET"
1917 else
1918         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1919 fi])
1920
1921 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1922 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1923 case "$ORIGINAL_LD_FOR_TARGET" in
1924   ./collect-ld | ./collect-ld$build_exeext) ;;
1925   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1926 esac
1927
1928 AC_MSG_CHECKING(what linker to use)
1929 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1930         # Single tree build which includes ld.  We want to prefer it
1931         # over whatever linker top-level may have detected, since
1932         # we'll use what we're building after installation anyway.
1933         AC_MSG_RESULT(newly built ld)
1934         in_tree_ld=yes
1935         in_tree_ld_is_elf=no
1936         if (grep 'EMUL = .*elf' ../ld/Makefile \
1937             || grep 'EMUL = .*linux' ../ld/Makefile \
1938             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1939           in_tree_ld_is_elf=yes
1940         fi
1941         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1942         do
1943 changequote(,)dnl
1944                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1945                 if test x$gcc_cv_gld_version != x; then
1946                         break
1947                 fi
1948         done
1949         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1950         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1951 changequote([,])dnl
1952 else
1953         AC_MSG_RESULT($gcc_cv_ld)
1954         in_tree_ld=no
1955 fi
1956
1957 # Figure out what nm we will be using.
1958 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1959 AS_VAR_SET_IF(gcc_cv_nm,, [
1960 if test -f $gcc_cv_binutils_srcdir/configure.in \
1961      && test -f ../binutils/Makefile \
1962      && test x$build = x$host; then
1963         gcc_cv_nm=../binutils/nm-new$build_exeext
1964 elif test -x nm$build_exeext; then
1965         gcc_cv_nm=./nm$build_exeext
1966 elif test -x $NM_FOR_TARGET; then
1967         gcc_cv_nm="$NM_FOR_TARGET"
1968 else
1969         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1970 fi])
1971
1972 AC_MSG_CHECKING(what nm to use)
1973 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1974         # Single tree build which includes binutils.
1975         AC_MSG_RESULT(newly built nm)
1976         in_tree_nm=yes
1977 else
1978         AC_MSG_RESULT($gcc_cv_nm)
1979         in_tree_nm=no
1980 fi
1981
1982 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1983 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1984 case "$ORIGINAL_NM_FOR_TARGET" in
1985   ./nm | ./nm$build_exeext) ;;
1986   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1987 esac
1988
1989
1990 # Figure out what objdump we will be using.
1991 AS_VAR_SET_IF(gcc_cv_objdump,, [
1992 if test -f $gcc_cv_binutils_srcdir/configure.in \
1993      && test -f ../binutils/Makefile \
1994      && test x$build = x$host; then
1995         # Single tree build which includes binutils.
1996         gcc_cv_objdump=../binutils/objdump$build_exeext
1997 elif test -x objdump$build_exeext; then
1998         gcc_cv_objdump=./objdump$build_exeext
1999 elif test -x $OBJDUMP_FOR_TARGET; then
2000         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2001 else
2002         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2003 fi])
2004
2005 AC_MSG_CHECKING(what objdump to use)
2006 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2007         # Single tree build which includes binutils.
2008         AC_MSG_RESULT(newly built objdump)
2009 elif test x$gcc_cv_objdump = x; then
2010         AC_MSG_RESULT(not found)
2011 else
2012         AC_MSG_RESULT($gcc_cv_objdump)
2013 fi
2014
2015 # Figure out what assembler alignment features are present.
2016 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2017  [2,6,0],,
2018 [.balign 4
2019 .p2align 2],,
2020 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2021   [Define if your assembler supports .balign and .p2align.])])
2022
2023 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2024  [2,8,0],,
2025  [.p2align 4,,7],,
2026 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2027   [Define if your assembler supports specifying the maximum number
2028    of bytes to skip when using the GAS .p2align command.])])
2029
2030 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2031  [2,8,0],,
2032  [.literal16],,
2033 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2034   [Define if your assembler supports .literal16.])])
2035
2036 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2037  [elf,2,9,0],,
2038  [conftest_label1: .word 0
2039 .subsection -1
2040 conftest_label2: .word 0
2041 .previous],
2042  [if test x$gcc_cv_nm != x; then
2043     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2044     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2045     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2046     then :
2047     else gcc_cv_as_subsection_m1=yes
2048     fi
2049     rm -f conftest.nm1 conftest.nm2
2050   fi],
2051  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2052   [Define if your assembler supports .subsection and .subsection -1 starts
2053    emitting at the beginning of your section.])])
2054
2055 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2056  [2,2,0],,
2057  [      .weak foobar],,
2058 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2059
2060 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2061  [2,17,0],,
2062  [      .weakref foobar, barfnot],,
2063 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2064
2065 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2066  [2,15,91],,
2067  [      .SPACE $TEXT$
2068         .NSUBSPA $CODE$,COMDAT],,
2069 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2070
2071 # .hidden needs to be supported in both the assembler and the linker,
2072 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2073 # This is irritatingly difficult to feature test for; we have to check the
2074 # date string after the version number.  If we've got an in-tree
2075 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2076 # to be safe.
2077 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2078 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2079  [elf,2,13,0],,
2080 [       .hidden foobar
2081 foobar:])
2082
2083 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2084 [if test $in_tree_ld = yes ; then
2085   gcc_cv_ld_hidden=no
2086   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2087      && test $in_tree_ld_is_elf = yes; then
2088      gcc_cv_ld_hidden=yes
2089   fi
2090 else
2091   gcc_cv_ld_hidden=yes
2092   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2093   if echo "$ld_ver" | grep GNU > /dev/null; then
2094 changequote(,)dnl
2095     ld_vers=`echo $ld_ver | sed -n \
2096         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2097     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2098     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2099     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2100     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2101     if test 0"$ld_date" -lt 20020404; then
2102       if test -n "$ld_date"; then
2103         # If there was date string, but was earlier than 2002-04-04, fail
2104         gcc_cv_ld_hidden=no
2105       elif test -z "$ld_vers"; then
2106         # If there was no date string nor ld version number, something is wrong
2107         gcc_cv_ld_hidden=no
2108       else
2109         test -z "$ld_vers_patch" && ld_vers_patch=0
2110         if test "$ld_vers_major" -lt 2; then
2111           gcc_cv_ld_hidden=no
2112         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2113           gcc_cv_ld_hidden="no"
2114         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2115           gcc_cv_ld_hidden=no
2116         fi
2117       fi
2118 changequote([,])dnl
2119     fi
2120   else
2121     case "${target}" in
2122       hppa64*-*-hpux* | ia64*-*-hpux*)
2123         gcc_cv_ld_hidden=yes
2124         ;;
2125       *)
2126         gcc_cv_ld_hidden=no
2127         ;;
2128     esac
2129   fi
2130 fi])
2131 libgcc_visibility=no
2132 AC_SUBST(libgcc_visibility)
2133 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2134 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2135   libgcc_visibility=yes
2136   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2137   [Define if your assembler and linker support .hidden.])
2138 fi
2139
2140 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2141 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2142   [elf,2,11,0],,
2143 [       .data
2144         .uleb128 L2 - L1
2145 L1:
2146         .uleb128 1280
2147         .sleb128 -1010
2148 L2:],
2149  [# GAS versions before 2.11 do not support uleb128,
2150   # despite appearing to.
2151   # ??? There exists an elf-specific test that will crash
2152   # the assembler.  Perhaps it's better to figure out whether
2153   # arbitrary sections are supported and try the test.
2154   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2155   if echo "$as_ver" | grep GNU > /dev/null; then
2156 changequote(,)dnl
2157     as_vers=`echo $as_ver | sed -n \
2158         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2159     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2160     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2161 changequote([,])dnl
2162     if test $as_major -eq 2 && test $as_minor -lt 11
2163     then :
2164     else gcc_cv_as_leb128=yes
2165     fi
2166   fi],
2167   [AC_DEFINE(HAVE_AS_LEB128, 1,
2168     [Define if your assembler supports .sleb128 and .uleb128.])])
2169
2170 # GAS versions up to and including 2.11.0 may mis-optimize
2171 # .eh_frame data.
2172 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2173   [elf,2,12,0],,
2174 [       .text
2175 .LFB1:
2176         .4byte  0
2177 .L1:
2178         .4byte  0
2179 .LFE1:
2180         .section        .eh_frame,"aw",@progbits
2181 __FRAME_BEGIN__:
2182         .4byte  .LECIE1-.LSCIE1
2183 .LSCIE1:
2184         .4byte  0x0
2185         .byte   0x1
2186         .ascii "z\0"
2187         .byte   0x1
2188         .byte   0x78
2189         .byte   0x1a
2190         .byte   0x0
2191         .byte   0x4
2192         .4byte  1
2193         .p2align 1
2194 .LECIE1:
2195 .LSFDE1:
2196         .4byte  .LEFDE1-.LASFDE1
2197 .LASFDE1:
2198         .4byte  .LASFDE1-__FRAME_BEGIN__
2199         .4byte  .LFB1
2200         .4byte  .LFE1-.LFB1
2201         .byte   0x4
2202         .4byte  .LFE1-.LFB1
2203         .byte   0x4
2204         .4byte  .L1-.LFB1
2205 .LEFDE1:],
2206 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2207 cat > conftest.lit <<EOF
2208  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2209  0010 01000000 12000000 18000000 00000000  ................
2210  0020 08000000 04080000 0044               .........D      @&t@
2211 EOF
2212 cat > conftest.big <<EOF
2213  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2214  0010 00000001 00000012 00000018 00000000  ................
2215  0020 00000008 04000000 0844               .........D      @&t@
2216 EOF
2217   # If the assembler didn't choke, and we can objdump,
2218   # and we got the correct data, then succeed.
2219   # The text in the here-document typically retains its unix-style line
2220   # endings, while the output of objdump will use host line endings.
2221   # Therefore, use diff -b for the comparisons.
2222   if test x$gcc_cv_objdump != x \
2223   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2224      | tail -3 > conftest.got \
2225   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2226     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2227   then
2228     gcc_cv_as_eh_frame=yes
2229   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2230     gcc_cv_as_eh_frame=buggy
2231   else
2232     # Uh oh, what do we do now?
2233     gcc_cv_as_eh_frame=no
2234   fi])
2235
2236 if test $gcc_cv_as_eh_frame = buggy; then
2237   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2238   [Define if your assembler mis-optimizes .eh_frame data.])
2239 fi
2240
2241 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2242  [elf,2,12,0], [--fatal-warnings],
2243  [.section .rodata.str, "aMS", @progbits, 1])
2244 if test $gcc_cv_as_shf_merge = no; then
2245   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2246     [elf,2,12,0], [--fatal-warnings],
2247     [.section .rodata.str, "aMS", %progbits, 1])
2248 fi
2249 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2250   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2251 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2252
2253 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2254  [elf,2,16,0], [--fatal-warnings],
2255  [.section .text,"axG",@progbits,.foo,comdat])
2256 if test $gcc_cv_as_comdat_group = yes; then
2257   gcc_cv_as_comdat_group_percent=no
2258 else
2259  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2260    [elf,2,16,0], [--fatal-warnings],
2261    [.section .text,"axG",%progbits,.foo,comdat])
2262 fi
2263 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2264   comdat_group=yes
2265   if test 0"$ld_date" -lt 20050308; then
2266     if test -n "$ld_date"; then
2267       # If there was date string, but was earlier than 2005-03-08, fail
2268       comdat_group=no
2269     elif test "$ld_vers_major" -lt 2; then
2270       comdat_group=no
2271     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2272       comdat_group=no
2273     fi
2274   fi
2275 else
2276   # assume linkers other than GNU ld don't support COMDAT group
2277   comdat_group=no
2278 fi
2279 if test $comdat_group = no; then
2280   gcc_cv_as_comdat_group=no
2281   gcc_cv_as_comdat_group_percent=no
2282 fi
2283 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2284   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2285 [Define 0/1 if your assembler and linker support COMDAT groups.])
2286
2287 # Thread-local storage - the check is heavily parametrized.
2288 conftest_s=
2289 tls_first_major=
2290 tls_first_minor=
2291 tls_as_opt=
2292 case "$target" in
2293 changequote(,)dnl
2294   alpha*-*-*)
2295     conftest_s='
2296         .section ".tdata","awT",@progbits
2297 foo:    .long   25
2298         .text
2299         ldq     $27,__tls_get_addr($29)         !literal!1
2300         lda     $16,foo($29)                    !tlsgd!1
2301         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2302         ldq     $27,__tls_get_addr($29)         !literal!2
2303         lda     $16,foo($29)                    !tlsldm!2
2304         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2305         ldq     $1,foo($29)                     !gotdtprel
2306         ldah    $2,foo($29)                     !dtprelhi
2307         lda     $3,foo($2)                      !dtprello
2308         lda     $4,foo($29)                     !dtprel
2309         ldq     $1,foo($29)                     !gottprel
2310         ldah    $2,foo($29)                     !tprelhi
2311         lda     $3,foo($2)                      !tprello
2312         lda     $4,foo($29)                     !tprel'
2313         tls_first_major=2
2314         tls_first_minor=13
2315         tls_as_opt=--fatal-warnings
2316         ;;
2317   frv*-*-*)
2318     conftest_s='
2319         .section ".tdata","awT",@progbits
2320 x:      .long   25
2321         .text
2322         call    #gettlsoff(x)'
2323         tls_first_major=2
2324         tls_first_minor=14
2325         ;;
2326   hppa*-*-linux*)
2327     conftest_s='
2328 t1:     .reg    %r20
2329 t2:     .reg    %r21
2330 gp:     .reg    %r19
2331         .section ".tdata","awT",@progbits
2332 foo:    .long   25
2333         .text
2334         .align  4
2335         addil LT%foo-$tls_gdidx$,gp
2336         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2337         b __tls_get_addr
2338         nop
2339         addil LT%foo-$tls_ldidx$,gp
2340         b __tls_get_addr
2341         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2342         addil LR%foo-$tls_dtpoff$,%ret0
2343         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2344         mfctl %cr27,%t1
2345         addil LT%foo-$tls_ieoff$,gp
2346         ldw RT%foo-$tls_ieoff$(%r1),%t2
2347         add %t1,%t2,%t3
2348         mfctl %cr27,%t1
2349         addil LR%foo-$tls_leoff$,%t1
2350         ldo RR%foo-$tls_leoff$(%r1),%t2'
2351         tls_first_major=2
2352         tls_first_minor=15
2353         tls_as_opt=--fatal-warnings
2354         ;;
2355   arm*-*-*)
2356     conftest_s='
2357         .section ".tdata","awT",%progbits
2358 foo:    .long   25
2359         .text
2360 .word foo(gottpoff)
2361 .word foo(tpoff)
2362 .word foo(tlsgd)
2363 .word foo(tlsldm)
2364 .word foo(tlsldo)'
2365         tls_first_major=2
2366         tls_first_minor=17
2367         ;;
2368   i[34567]86-*-*)
2369     conftest_s='
2370         .section ".tdata","awT",@progbits
2371 foo:    .long   25
2372         .text
2373         movl    %gs:0, %eax
2374         leal    foo@TLSGD(,%ebx,1), %eax
2375         leal    foo@TLSLDM(%ebx), %eax
2376         leal    foo@DTPOFF(%eax), %edx
2377         movl    foo@GOTTPOFF(%ebx), %eax
2378         subl    foo@GOTTPOFF(%ebx), %eax
2379         addl    foo@GOTNTPOFF(%ebx), %eax
2380         movl    foo@INDNTPOFF, %eax
2381         movl    $foo@TPOFF, %eax
2382         subl    $foo@TPOFF, %eax
2383         leal    foo@NTPOFF(%ecx), %eax'
2384         tls_first_major=2
2385         tls_first_minor=14
2386         tls_as_opt=--fatal-warnings
2387         ;;
2388   x86_64-*-*)
2389     conftest_s='
2390         .section ".tdata","awT",@progbits
2391 foo:    .long   25
2392         .text
2393         movq    %fs:0, %rax
2394         leaq    foo@TLSGD(%rip), %rdi
2395         leaq    foo@TLSLD(%rip), %rdi
2396         leaq    foo@DTPOFF(%rax), %rdx
2397         movq    foo@GOTTPOFF(%rip), %rax
2398         movq    $foo@TPOFF, %rax'
2399         tls_first_major=2
2400         tls_first_minor=14
2401         tls_as_opt=--fatal-warnings
2402         ;;
2403   ia64-*-*)
2404     conftest_s='
2405         .section ".tdata","awT",@progbits
2406 foo:    data8   25
2407         .text
2408         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2409         addl    r17 = @ltoff(@dtprel(foo#)), gp
2410         addl    r18 = @ltoff(@tprel(foo#)), gp
2411         addl    r19 = @dtprel(foo#), gp
2412         adds    r21 = @dtprel(foo#), r13
2413         movl    r23 = @dtprel(foo#)
2414         addl    r20 = @tprel(foo#), gp
2415         adds    r22 = @tprel(foo#), r13
2416         movl    r24 = @tprel(foo#)'
2417         tls_first_major=2
2418         tls_first_minor=13
2419         tls_as_opt=--fatal-warnings
2420         ;;
2421   mips*-*-*)
2422     conftest_s='
2423         .section .tdata,"awT",@progbits
2424 x:
2425         .word 2
2426         .text
2427         addiu $4, $28, %tlsgd(x)
2428         addiu $4, $28, %tlsldm(x)
2429         lui $4, %dtprel_hi(x)
2430         addiu $4, $4, %dtprel_lo(x)
2431         lw $4, %gottprel(x)($28)
2432         lui $4, %tprel_hi(x)
2433         addiu $4, $4, %tprel_lo(x)'
2434         tls_first_major=2
2435         tls_first_minor=16
2436         tls_as_opt='-32 --fatal-warnings'
2437         ;;
2438   powerpc-*-*)
2439     conftest_s='
2440         .section ".tdata","awT",@progbits
2441         .align 2
2442 ld0:    .space 4
2443 ld1:    .space 4
2444 x1:     .space 4
2445 x2:     .space 4
2446 x3:     .space 4
2447         .text
2448         addi 3,31,ld0@got@tlsgd
2449         bl __tls_get_addr
2450         addi 3,31,x1@got@tlsld
2451         bl __tls_get_addr
2452         addi 9,3,x1@dtprel
2453         addis 9,3,x2@dtprel@ha
2454         addi 9,9,x2@dtprel@l
2455         lwz 9,x3@got@tprel(31)
2456         add 9,9,x@tls
2457         addi 9,2,x1@tprel
2458         addis 9,2,x2@tprel@ha
2459         addi 9,9,x2@tprel@l'
2460         tls_first_major=2
2461         tls_first_minor=14
2462         tls_as_opt="-a32 --fatal-warnings"
2463         ;;
2464   powerpc64-*-*)
2465     conftest_s='
2466         .section ".tdata","awT",@progbits
2467         .align 3
2468 ld0:    .space 8
2469 ld1:    .space 8
2470 x1:     .space 8
2471 x2:     .space 8
2472 x3:     .space 8
2473         .text
2474         addi 3,2,ld0@got@tlsgd
2475         bl .__tls_get_addr
2476         nop
2477         addi 3,2,ld1@toc
2478         bl .__tls_get_addr
2479         nop
2480         addi 3,2,x1@got@tlsld
2481         bl .__tls_get_addr
2482         nop
2483         addi 9,3,x1@dtprel
2484         bl .__tls_get_addr
2485         nop
2486         addis 9,3,x2@dtprel@ha
2487         addi 9,9,x2@dtprel@l
2488         bl .__tls_get_addr
2489         nop
2490         ld 9,x3@got@dtprel(2)
2491         add 9,9,3
2492         bl .__tls_get_addr
2493         nop'
2494         tls_first_major=2
2495         tls_first_minor=14
2496         tls_as_opt="-a64 --fatal-warnings"
2497         ;;
2498   s390-*-*)
2499     conftest_s='
2500         .section ".tdata","awT",@progbits
2501 foo:    .long   25
2502         .text
2503         .long   foo@TLSGD
2504         .long   foo@TLSLDM
2505         .long   foo@DTPOFF
2506         .long   foo@NTPOFF
2507         .long   foo@GOTNTPOFF
2508         .long   foo@INDNTPOFF
2509         l       %r1,foo@GOTNTPOFF(%r12)
2510         l       %r1,0(%r1):tls_load:foo
2511         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2512         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2513         tls_first_major=2
2514         tls_first_minor=14
2515         tls_as_opt="-m31 --fatal-warnings"
2516         ;;
2517   s390x-*-*)
2518     conftest_s='
2519         .section ".tdata","awT",@progbits
2520 foo:    .long   25
2521         .text
2522         .quad   foo@TLSGD
2523         .quad   foo@TLSLDM
2524         .quad   foo@DTPOFF
2525         .quad   foo@NTPOFF
2526         .quad   foo@GOTNTPOFF
2527         lg      %r1,foo@GOTNTPOFF(%r12)
2528         larl    %r1,foo@INDNTPOFF
2529         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2530         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2531         tls_first_major=2
2532         tls_first_minor=14
2533         tls_as_opt="-m64 -Aesame --fatal-warnings"
2534         ;;
2535   sh-*-* | sh[34]-*-*)
2536     conftest_s='
2537         .section ".tdata","awT",@progbits
2538 foo:    .long   25
2539         .text
2540         .long   foo@TLSGD
2541         .long   foo@TLSLDM
2542         .long   foo@DTPOFF
2543         .long   foo@GOTTPOFF
2544         .long   foo@TPOFF'
2545         tls_first_major=2
2546         tls_first_minor=13
2547         tls_as_opt=--fatal-warnings
2548         ;;
2549   sparc*-*-*)
2550     case "$target" in
2551       sparc*-sun-solaris2.[56789]*)
2552         # TLS was introduced in the Solaris 9 4/04 release but
2553         # we do not enable it by default on Solaris 9 either.
2554         if test "x$enable_tls" = xyes ; then
2555           on_solaris=yes
2556         else
2557           enable_tls=no;
2558         fi
2559         ;;
2560       sparc*-sun-solaris2.*)
2561         on_solaris=yes
2562         ;;
2563       *)
2564         on_solaris=no
2565         ;;
2566     esac
2567     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2568       conftest_s='
2569         .section ".tdata",#alloc,#write,#tls
2570 foo:    .long   25
2571         .text
2572         sethi   %tgd_hi22(foo), %o0
2573         add     %o0, %tgd_lo10(foo), %o1
2574         add     %l7, %o1, %o0, %tgd_add(foo)
2575         call    __tls_get_addr, %tgd_call(foo)
2576         sethi   %tldm_hi22(foo), %l1
2577         add     %l1, %tldm_lo10(foo), %l2
2578         add     %l7, %l2, %o0, %tldm_add(foo)
2579         call    __tls_get_addr, %tldm_call(foo)
2580         sethi   %tldo_hix22(foo), %l3
2581         xor     %l3, %tldo_lox10(foo), %l4
2582         add     %o0, %l4, %l5, %tldo_add(foo)
2583         sethi   %tie_hi22(foo), %o3
2584         add     %o3, %tie_lo10(foo), %o3
2585         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2586         add     %g7, %o2, %o4, %tie_add(foo)
2587         sethi   %tle_hix22(foo), %l1
2588         xor     %l1, %tle_lox10(foo), %o5
2589         ld      [%g7 + %o5], %o1'
2590         tls_first_major=0
2591         tls_first_minor=0
2592     else
2593       conftest_s='
2594         .section ".tdata","awT",@progbits
2595 foo:    .long   25
2596         .text
2597         sethi   %tgd_hi22(foo), %o0
2598         add     %o0, %tgd_lo10(foo), %o1
2599         add     %l7, %o1, %o0, %tgd_add(foo)
2600         call    __tls_get_addr, %tgd_call(foo)
2601         sethi   %tldm_hi22(foo), %l1
2602         add     %l1, %tldm_lo10(foo), %l2
2603         add     %l7, %l2, %o0, %tldm_add(foo)
2604         call    __tls_get_addr, %tldm_call(foo)
2605         sethi   %tldo_hix22(foo), %l3
2606         xor     %l3, %tldo_lox10(foo), %l4
2607         add     %o0, %l4, %l5, %tldo_add(foo)
2608         sethi   %tie_hi22(foo), %o3
2609         add     %o3, %tie_lo10(foo), %o3
2610         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2611         add     %g7, %o2, %o4, %tie_add(foo)
2612         sethi   %tle_hix22(foo), %l1
2613         xor     %l1, %tle_lox10(foo), %o5
2614         ld      [%g7 + %o5], %o1'
2615         tls_first_major=2
2616         tls_first_minor=14
2617         tls_as_opt="-32 --fatal-warnings"
2618       fi
2619         ;;
2620 changequote([,])dnl
2621 esac
2622 set_have_as_tls=no
2623 if test "x$enable_tls" = xno ; then
2624   : # TLS explicitly disabled.
2625 elif test "x$enable_tls" = xyes ; then
2626   set_have_as_tls=yes # TLS explicitly enabled.
2627 elif test -z "$tls_first_major"; then
2628   : # If we don't have a check, assume no support.
2629 else
2630   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2631   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2632   [set_have_as_tls=yes])
2633 fi
2634 if test $set_have_as_tls = yes ; then
2635   AC_DEFINE(HAVE_AS_TLS, 1,
2636             [Define if your assembler supports thread-local storage.])
2637 fi
2638
2639 # Target-specific assembler checks.
2640
2641 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2642 gcc_cv_ld_static_dynamic=no
2643 if test $in_tree_ld = yes ; then
2644   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2645     gcc_cv_ld_static_dynamic=yes
2646   fi
2647 elif test x$gcc_cv_ld != x; then
2648         # Check if linker supports -Bstatic/-Bdynamic option
2649         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2650           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2651                 gcc_cv_ld_static_dynamic=yes
2652         fi
2653 fi
2654 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2655         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2656 [Define if your linker supports -Bstatic/-Bdynamic option.])
2657 fi
2658 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2659
2660 if test x"$demangler_in_ld" = xyes; then
2661   AC_MSG_CHECKING(linker --demangle support)
2662   gcc_cv_ld_demangle=no
2663   if test $in_tree_ld = yes; then
2664     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2665       gcc_cv_ld_demangle=yes
2666     fi
2667   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2668     # Check if the GNU linker supports --demangle option
2669     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2670       gcc_cv_ld_demangle=yes
2671     fi
2672   fi
2673   if test x"$gcc_cv_ld_demangle" = xyes; then
2674     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2675 [Define if your linker supports --demangle option.])
2676   fi
2677   AC_MSG_RESULT($gcc_cv_ld_demangle)
2678 fi
2679
2680 case "$target" in
2681   # All TARGET_ABI_OSF targets.
2682   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2683     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2684         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2685 [       .set nomacro
2686         .text
2687         extbl   $3, $2, $3      !lituse_bytoff!1
2688         ldq     $2, a($29)      !literal!1
2689         ldq     $4, b($29)      !literal!2
2690         ldq_u   $3, 0($2)       !lituse_base!1
2691         ldq     $27, f($29)     !literal!5
2692         jsr     $26, ($27), f   !lituse_jsr!5
2693         ldah    $29, 0($26)     !gpdisp!3
2694         lda     $0, c($29)      !gprel
2695         ldah    $1, d($29)      !gprelhigh
2696         lda     $1, d($1)       !gprellow
2697         lda     $29, 0($29)     !gpdisp!3],,
2698     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2699   [Define if your assembler supports explicit relocations.])])
2700     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2701         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2702 [       .set nomacro
2703         .text
2704         ldq     $27, a($29)     !literal!1
2705         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2706     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2707   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2708     ;;
2709
2710   cris-*-*)
2711     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2712       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2713       [-no-mul-bug-abort], [.text],,
2714       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2715                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2716     ;;
2717
2718   sparc*-*-*)
2719     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2720       [.register %g2, #scratch],,
2721       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2722                 [Define if your assembler supports .register.])])
2723
2724     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2725       [-relax], [.text],,
2726       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2727                 [Define if your assembler supports -relax option.])])
2728
2729     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2730       gcc_cv_as_sparc_ua_pcrel,,
2731       [-K PIC],
2732 [.text
2733 foo:
2734         nop
2735 .data
2736 .align 4
2737 .byte 0
2738 .uaword %r_disp32(foo)],
2739       [if test x$gcc_cv_ld != x \
2740        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2741          gcc_cv_as_sparc_ua_pcrel=yes
2742        fi
2743        rm -f conftest],
2744       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2745                 [Define if your assembler and linker support unaligned PC relative relocs.])
2746
2747       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2748         gcc_cv_as_sparc_ua_pcrel_hidden,,
2749         [-K PIC],
2750 [.data
2751 .align 4
2752 .byte 0x31
2753 .uaword %r_disp32(foo)
2754 .byte 0x32, 0x33, 0x34
2755 .global foo
2756 .hidden foo
2757 foo:
2758 .skip 4],
2759         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2760          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2761          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2762             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2763             if $gcc_cv_objdump -R conftest 2> /dev/null \
2764                | grep 'DISP32' > /dev/null 2>&1; then
2765                 :
2766             else
2767                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2768             fi
2769          fi
2770          rm -f conftest],
2771          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2772                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2773     ]) # unaligned pcrel relocs
2774
2775     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2776       gcc_cv_as_sparc_offsetable_lo10,,
2777       [-xarch=v9],
2778 [.text
2779         or %g1, %lo(ab) + 12, %g1
2780         or %g1, %lo(ab + 12), %g1],
2781       [if test x$gcc_cv_objdump != x \
2782        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2783           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2784          gcc_cv_as_sparc_offsetable_lo10=yes
2785        fi],
2786        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2787                  [Define if your assembler supports offsetable %lo().])])
2788     ;;
2789
2790 changequote(,)dnl
2791   i[34567]86-*-* | x86_64-*-*)
2792 changequote([,])dnl
2793     case $target_os in
2794       cygwin* | pe | mingw32*)
2795         # Used for DWARF 2 in PE
2796         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2797           gcc_cv_as_ix86_pe_secrel32,
2798           [2,15,91],,
2799 [.text
2800 foo:    nop
2801 .data
2802         .secrel32 foo],
2803           [if test x$gcc_cv_ld != x \
2804            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2805              gcc_cv_as_ix86_pe_secrel32=yes
2806            fi
2807            rm -f conftest],
2808           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2809             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2810         ;;
2811     esac
2812
2813     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2814        gcc_cv_as_ix86_filds_fists,
2815       [2,9,0],, [filds mem; fists mem],,
2816       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2817         [Define if your assembler uses the new HImode fild and fist notation.])])
2818
2819     gcc_GAS_CHECK_FEATURE([cmov syntax],
2820       gcc_cv_as_ix86_cmov_sun_syntax,,,
2821       [cmovl.l %edx, %eax],,
2822       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2823         [Define if your assembler supports the Sun syntax for cmov.])])
2824
2825     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2826       gcc_cv_as_ix86_ffreep,,,
2827       [ffreep %st(1)],,
2828       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2829         [Define if your assembler supports the ffreep mnemonic.])])
2830
2831     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2832       gcc_cv_as_ix86_sahf,,,
2833       [sahf],,
2834       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2835         [Define if your assembler supports the sahf mnemonic.])])
2836
2837     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2838       gcc_cv_as_ix86_diff_sect_delta,,,
2839       [.section .rodata
2840 .L1:
2841         .long .L2-.L1
2842         .long .L3-.L1
2843         .text
2844 .L3:    nop
2845 .L2:    nop],,
2846       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2847         [Define if your assembler supports the subtraction of symbols in different sections.])])
2848
2849     # This one is used unconditionally by i386.[ch]; it is to be defined
2850     # to 1 if the feature is present, 0 otherwise.
2851     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2852         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2853 [       .text
2854 .L0:
2855         nop
2856         .data
2857         .long .L0@GOTOFF])
2858     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2859       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2860       [Define true if the assembler supports '.long foo@GOTOFF'.])
2861     ;;
2862
2863   ia64*-*-*)
2864     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2865         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2866 [       .text
2867         addl r15 = @ltoffx(x#), gp
2868         ;;
2869         ld8.mov r16 = [[r15]], x#],,
2870     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2871           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2872
2873     ;;
2874
2875   powerpc*-*-*)
2876     case $target in
2877       *-*-aix*) conftest_s='    .machine "pwr5"
2878         .csect .text[[PR]]
2879         mfcr 3,128';;
2880       *-*-darwin*)
2881         gcc_GAS_CHECK_FEATURE([.machine directive support],
2882           gcc_cv_as_machine_directive,,,
2883           [     .machine ppc7400])
2884         if test x$gcc_cv_as_machine_directive != xyes; then
2885           echo "*** This target requires an assembler supporting \".machine\"" >&2
2886           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2887           test x$build = x$target && exit 1
2888         fi
2889         conftest_s='    .text
2890         mfcr r3,128';;
2891       *) conftest_s='   .machine power4
2892         .text
2893         mfcr 3,128';;
2894     esac
2895
2896     gcc_GAS_CHECK_FEATURE([mfcr field support],
2897       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2898       [$conftest_s],,
2899       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2900           [Define if your assembler supports mfcr field.])])
2901
2902     case $target in
2903       *-*-aix*) conftest_s='    .machine "pwr5"
2904         .csect .text[[PR]]
2905         popcntb 3,3';;
2906       *) conftest_s='   .machine power5
2907         .text
2908         popcntb 3,3';;
2909     esac
2910
2911     gcc_GAS_CHECK_FEATURE([popcntb support],
2912       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2913       [$conftest_s],,
2914       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2915           [Define if your assembler supports popcntb field.])])
2916
2917     case $target in
2918       *-*-aix*) conftest_s='    .machine "pwr5x"
2919         .csect .text[[PR]]
2920         frin 1,1';;
2921       *) conftest_s='   .machine power5
2922         .text
2923         frin 1,1';;
2924     esac
2925
2926     gcc_GAS_CHECK_FEATURE([fp round support],
2927       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2928       [$conftest_s],,
2929       [AC_DEFINE(HAVE_AS_FPRND, 1,
2930           [Define if your assembler supports fprnd.])])
2931
2932     case $target in
2933       *-*-aix*) conftest_s='    .machine "pwr6"
2934         .csect .text[[PR]]
2935         mffgpr 1,3';;
2936       *) conftest_s='   .machine power6
2937         .text
2938         mffgpr 1,3';;
2939     esac
2940
2941     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2942       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2943       [$conftest_s],,
2944       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2945           [Define if your assembler supports mffgpr and mftgpr.])])
2946
2947     case $target in
2948       *-*-aix*) conftest_s='    .csect .text[[PR]]
2949 LCF..0:
2950         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2951       *-*-darwin*)
2952         conftest_s='    .text
2953 LCF0:
2954         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2955       *) conftest_s='   .text
2956 .LCF0:
2957         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2958     esac
2959
2960     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2961       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2962       [$conftest_s],,
2963       [AC_DEFINE(HAVE_AS_REL16, 1,
2964           [Define if your assembler supports R_PPC_REL16 relocs.])])
2965
2966     case $target in
2967       *-*-aix*) conftest_s='    .machine "pwr6"
2968         .csect .text[[PR]]
2969         cmpb 3,4,5';;
2970       *) conftest_s='   .machine power6
2971         .text
2972         cmpb 3,4,5';;
2973     esac
2974
2975     gcc_GAS_CHECK_FEATURE([compare bytes support],
2976       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2977       [$conftest_s],,
2978       [AC_DEFINE(HAVE_AS_CMPB, 1,
2979           [Define if your assembler supports cmpb.])])
2980
2981     case $target in
2982       *-*-aix*) conftest_s='    .machine "pwr6"
2983         .csect .text[[PR]]
2984         dadd 1,2,3';;
2985       *) conftest_s='   .machine power6
2986         .text
2987         dadd 1,2,3';;
2988     esac
2989
2990     gcc_GAS_CHECK_FEATURE([decimal float support],
2991       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
2992       [$conftest_s],,
2993       [AC_DEFINE(HAVE_AS_DFP, 1,
2994           [Define if your assembler supports DFP instructions.])])
2995
2996     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
2997       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
2998       [.gnu_attribute 4,1],,
2999       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3000           [Define if your assembler supports .gnu_attribute.])])
3001     ;;
3002
3003   mips*-*-*)
3004     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3005       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3006 [       lw $4,%gp_rel(foo)($4)],,
3007       [if test x$target_cpu_default = x
3008        then target_cpu_default=MASK_EXPLICIT_RELOCS
3009        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3010        fi])
3011     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3012       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3013       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3014                  [Define if the assembler understands -mno-shared.])])
3015
3016     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3017       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3018       [.gnu_attribute 4,1],,
3019       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3020           [Define if your assembler supports .gnu_attribute.])])
3021
3022     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3023       gcc_cv_as_mips_dtprelword, [2,18,0],,
3024       [.section .tdata,"awT",@progbits
3025 x:
3026         .word 2
3027         .text
3028         .dtprelword x+0x8000],,
3029       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3030           [Define if your assembler supports .dtprelword.])])
3031     ;;
3032 esac
3033
3034 # Mips and HP-UX need the GNU assembler.
3035 # Linux on IA64 might be able to use the Intel assembler.
3036
3037 case "$target" in
3038   mips*-*-* | *-*-hpux* )
3039     if test x$gas_flag = xyes \
3040        || test x"$host" != x"$build" \
3041        || test ! -x "$gcc_cv_as" \
3042        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3043       :
3044     else
3045       echo "*** This configuration requires the GNU assembler" >&2
3046       exit 1
3047     fi
3048     ;;
3049 esac
3050
3051 # ??? Not all targets support dwarf2 debug_line, even within a version
3052 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3053 # info to the output file.  So, as supported targets are added to gas 2.11,
3054 # add some instruction here to (also) show we expect this might work.
3055 # ??? Once 2.11 is released, probably need to add first known working
3056 # version to the per-target configury.
3057 case "$target" in
3058   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3059   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
3060   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* | spu-*-*)
3061     insn="nop"
3062     ;;
3063   ia64*-*-* | s390*-*-*)
3064     insn="nop 0"
3065     ;;
3066   mmix-*-*)
3067     insn="swym 0"
3068     ;;
3069 esac
3070 if test x"$insn" != x; then
3071  conftest_s="\
3072         .file 1 \"conftest.s\"
3073         .loc 1 3 0
3074         $insn"
3075  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3076   gcc_cv_as_dwarf2_debug_line,
3077   [elf,2,11,0],, [$conftest_s],
3078   [if test x$gcc_cv_objdump != x \
3079    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3080       | grep debug_line > /dev/null 2>&1; then
3081      gcc_cv_as_dwarf2_debug_line=yes
3082    fi])
3083
3084 # The .debug_line file table must be in the exact order that
3085 # we specified the files, since these indices are also used
3086 # by DW_AT_decl_file.  Approximate this test by testing if
3087 # the assembler bitches if the same index is assigned twice.
3088  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3089   gcc_cv_as_dwarf2_file_buggy,,,
3090 [       .file 1 "foo.s"
3091         .file 1 "bar.s"])
3092
3093  if test $gcc_cv_as_dwarf2_debug_line = yes \
3094  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3095         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3096   [Define if your assembler supports dwarf2 .file/.loc directives,
3097    and preserves file table indices exactly as given.])
3098  fi
3099
3100  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3101   gcc_cv_as_gdwarf2_flag,
3102   [elf,2,11,0], [--gdwarf2], [$insn],,
3103   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3104 [Define if your assembler supports the --gdwarf2 option.])])
3105
3106  gcc_GAS_CHECK_FEATURE([--gstabs option],
3107   gcc_cv_as_gstabs_flag,
3108   [elf,2,11,0], [--gstabs], [$insn],
3109   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3110    # and warns about it, but still exits successfully.  So check for
3111    # this.
3112    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3113    then :
3114    else gcc_cv_as_gstabs_flag=yes
3115    fi],
3116   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3117 [Define if your assembler supports the --gstabs option.])])
3118
3119  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3120   gcc_cv_as_debug_prefix_map_flag,
3121   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3122   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3123 [Define if your assembler supports the --debug-prefix-map option.])])
3124 fi
3125
3126 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3127  [gcc_cv_as_line_zero],
3128  [gcc_cv_as_line_zero=no
3129   if test $in_tree_gas = yes; then
3130     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3131   elif test "x$gcc_cv_as" != x; then
3132     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3133     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3134        test "x`cat conftest.out`" = x
3135     then
3136       gcc_cv_as_line_zero=yes
3137     else
3138       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3139       cat conftest.s >&AS_MESSAGE_LOG_FD
3140       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3141       cat conftest.out >&AS_MESSAGE_LOG_FD
3142     fi
3143     rm -f conftest.o conftest.s conftest.out
3144   fi])
3145 if test "x$gcc_cv_as_line_zero" = xyes; then
3146   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3147 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3148 fi
3149
3150 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3151 gcc_cv_ld_ro_rw_mix=unknown
3152 if test $in_tree_ld = yes ; then
3153   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3154      && test $in_tree_ld_is_elf = yes; then
3155     gcc_cv_ld_ro_rw_mix=read-write
3156   fi
3157 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3158   echo '.section myfoosect, "a"' > conftest1.s
3159   echo '.section myfoosect, "aw"' > conftest2.s
3160   echo '.byte 1' >> conftest2.s
3161   echo '.section myfoosect, "a"' > conftest3.s
3162   echo '.byte 0' >> conftest3.s
3163   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3164      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3165      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3166      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3167         conftest2.o conftest3.o > /dev/null 2>&1; then
3168     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3169                          | sed -e '/myfoosect/!d' -e N`
3170     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3171       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3172         gcc_cv_ld_ro_rw_mix=read-only
3173       else
3174         gcc_cv_ld_ro_rw_mix=read-write
3175       fi
3176     fi
3177   fi
3178 changequote(,)dnl
3179   rm -f conftest.* conftest[123].*
3180 changequote([,])dnl
3181 fi
3182 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3183         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3184   [Define if your linker links a mix of read-only
3185    and read-write sections into a read-write section.])
3186 fi
3187 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3188
3189 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3190 gcc_cv_ld_eh_frame_hdr=no
3191 if test $in_tree_ld = yes ; then
3192   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3193      && test $in_tree_ld_is_elf = yes; then
3194     gcc_cv_ld_eh_frame_hdr=yes
3195   fi
3196 elif test x$gcc_cv_ld != x; then
3197         # Check if linker supports --eh-frame-hdr option
3198         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3199                 gcc_cv_ld_eh_frame_hdr=yes
3200         fi
3201 fi
3202 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3203 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3204         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3205 [Define if your linker supports --eh-frame-hdr option.])
3206 fi
3207 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3208
3209 AC_MSG_CHECKING(linker position independent executable support)
3210 gcc_cv_ld_pie=no
3211 if test $in_tree_ld = yes ; then
3212   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3213      && test $in_tree_ld_is_elf = yes; then
3214     gcc_cv_ld_pie=yes
3215   fi
3216 elif test x$gcc_cv_ld != x; then
3217         # Check if linker supports -pie option
3218         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3219                 gcc_cv_ld_pie=yes
3220         fi
3221 fi
3222 if test x"$gcc_cv_ld_pie" = xyes; then
3223         AC_DEFINE(HAVE_LD_PIE, 1,
3224 [Define if your linker supports -pie option.])
3225 fi
3226 AC_MSG_RESULT($gcc_cv_ld_pie)
3227
3228 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3229 gcc_cv_ld_eh_gc_sections=no
3230 if test $in_tree_ld = yes ; then
3231   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3232      && test $in_tree_ld_is_elf = yes; then
3233     gcc_cv_ld_eh_gc_sections=yes
3234   fi
3235 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3236   cat > conftest.s <<EOF
3237         .section        .text
3238 .globl _start
3239         .type _start, @function
3240 _start:
3241         .long foo
3242         .size _start, .-_start
3243         .section        .text.foo,"ax",@progbits
3244         .type foo, @function
3245 foo:
3246         .long 0
3247         .size foo, .-foo
3248         .section        .gcc_except_table.foo,"a",@progbits
3249 .L0:
3250         .long 0
3251         .section        .eh_frame,"a",@progbits
3252         .long .L0
3253 EOF
3254   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3255     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3256          | grep "gc-sections option ignored" > /dev/null; then
3257       gcc_cv_ld_eh_gc_sections=no
3258     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3259       gcc_cv_ld_eh_gc_sections=yes
3260       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3261       if test x$gcc_cv_as_comdat_group != xyes; then
3262         gcc_cv_ld_eh_gc_sections=no
3263         cat > conftest.s <<EOF
3264         .section        .text
3265 .globl _start
3266         .type _start, @function
3267 _start:
3268         .long foo
3269         .size _start, .-_start
3270         .section        .gnu.linkonce.t.foo,"ax",@progbits
3271         .type foo, @function
3272 foo:
3273         .long 0
3274         .size foo, .-foo
3275         .section        .gcc_except_table.foo,"a",@progbits
3276 .L0:
3277         .long 0
3278         .section        .eh_frame,"a",@progbits
3279         .long .L0
3280 EOF
3281         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3282           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3283                | grep "gc-sections option ignored" > /dev/null; then
3284             gcc_cv_ld_eh_gc_sections=no
3285           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3286             gcc_cv_ld_eh_gc_sections=yes
3287           fi
3288         fi
3289       fi
3290     fi
3291   fi
3292   rm -f conftest.s conftest.o conftest
3293 fi
3294 case "$target" in
3295   hppa*-*-linux*)
3296     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3297     gcc_cv_ld_eh_gc_sections=no
3298     ;;
3299 esac
3300 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3301         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3302   [Define if your linker supports garbage collection of
3303    sections in presence of EH frames.])
3304 fi
3305 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3306
3307 # --------
3308 # UNSORTED
3309 # --------
3310
3311 AC_CACHE_CHECK(linker --as-needed support,
3312 gcc_cv_ld_as_needed,
3313 [gcc_cv_ld_as_needed=no
3314 if test $in_tree_ld = yes ; then
3315   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3316      && test $in_tree_ld_is_elf = yes; then
3317     gcc_cv_ld_as_needed=yes
3318   fi
3319 elif test x$gcc_cv_ld != x; then
3320         # Check if linker supports --as-needed and --no-as-needed options
3321         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3322                 gcc_cv_ld_as_needed=yes
3323         fi
3324 fi
3325 ])
3326 if test x"$gcc_cv_ld_as_needed" = xyes; then
3327         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3328 [Define if your linker supports --as-needed and --no-as-needed options.])
3329 fi
3330
3331 case "$target:$tm_file" in
3332   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3333     AC_CACHE_CHECK(linker support for omitting dot symbols,
3334     gcc_cv_ld_no_dot_syms,
3335     [gcc_cv_ld_no_dot_syms=no
3336     if test $in_tree_ld = yes ; then
3337       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3338         gcc_cv_ld_no_dot_syms=yes
3339       fi
3340     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3341       cat > conftest1.s <<EOF
3342         .text
3343         bl .foo
3344 EOF
3345       cat > conftest2.s <<EOF
3346         .section ".opd","aw"
3347         .align 3
3348         .globl foo
3349         .type foo,@function
3350 foo:
3351         .quad .LEfoo,.TOC.@tocbase,0
3352         .text
3353 .LEfoo:
3354         blr
3355         .size foo,.-.LEfoo
3356 EOF
3357       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3358          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3359          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3360         gcc_cv_ld_no_dot_syms=yes
3361       fi
3362       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3363     fi
3364     ])
3365     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3366       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3367     [Define if your PowerPC64 linker only needs function descriptor syms.])
3368     fi
3369     ;;
3370 esac
3371
3372 AC_CACHE_CHECK(linker --sysroot support,
3373   gcc_cv_ld_sysroot,
3374   [gcc_cv_ld_sysroot=no
3375   if test $in_tree_ld = yes ; then
3376       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3377         gcc_cv_ld_sysroot=yes
3378       fi
3379   elif test x$gcc_cv_ld != x; then
3380     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3381       gcc_cv_ld_sysroot=yes
3382     fi
3383   fi])
3384 if test x"$gcc_cv_ld_sysroot" = xyes; then
3385   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3386   [Define if your linker supports --sysroot.])
3387 fi
3388
3389 if test x$with_sysroot = x && test x$host = x$target \
3390    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3391    && test "$prefix" != "NONE"; then
3392   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3393 [Define to PREFIX/include if cpp should also search that directory.])
3394 fi
3395
3396 # Test for stack protector support in target C library.
3397 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3398       gcc_cv_libc_provides_ssp,
3399       [gcc_cv_libc_provides_ssp=no
3400     case "$target" in
3401        *-*-linux*)
3402       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3403         if test "x$with_sysroot" = x; then
3404           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3405         elif test "x$with_build_sysroot" != "x"; then
3406           glibc_header_dir="${with_build_sysroot}/usr/include"
3407         elif test "x$with_sysroot" = xyes; then
3408           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3409         else
3410           glibc_header_dir="${with_sysroot}/usr/include"
3411         fi
3412       else
3413         glibc_header_dir=/usr/include
3414       fi
3415       # glibc 2.4 and later provides __stack_chk_fail and
3416       # either __stack_chk_guard, or TLS access to stack guard canary.
3417       if test -f $glibc_header_dir/features.h \
3418          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3419             $glibc_header_dir/features.h > /dev/null; then
3420         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3421            $glibc_header_dir/features.h > /dev/null; then
3422           gcc_cv_libc_provides_ssp=yes
3423         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3424              $glibc_header_dir/features.h > /dev/null \
3425              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3426              $glibc_header_dir/features.h > /dev/null; then
3427           gcc_cv_libc_provides_ssp=yes
3428         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3429              $glibc_header_dir/features.h > /dev/null && \
3430              test -f $glibc_header_dir/bits/uClibc_config.h && \
3431              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3432              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3433           gcc_cv_libc_provides_ssp=yes
3434         fi
3435       fi
3436         ;;
3437        *-*-darwin*)
3438          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3439            [echo "no __stack_chk_fail on this target"])
3440         ;;
3441   *) gcc_cv_libc_provides_ssp=no ;;
3442     esac])
3443
3444 if test x$gcc_cv_libc_provides_ssp = xyes; then
3445   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3446             [Define if your target C library provides stack protector support])
3447 fi
3448
3449 # Check if TFmode long double should be used by default or not.
3450 # Some glibc targets used DFmode long double, but with glibc 2.4
3451 # and later they can use TFmode.
3452 case "$target" in
3453   powerpc*-*-linux* | \
3454   powerpc*-*-gnu* | \
3455   sparc*-*-linux* | \
3456   s390*-*-linux* | \
3457   alpha*-*-linux*)
3458     AC_ARG_WITH(long-double-128,
3459 [  --with-long-double-128  Use 128-bit long double by default.],
3460       gcc_cv_target_ldbl128="$with_long_double_128",
3461       [gcc_cv_target_ldbl128=no
3462       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3463         if test "x$with_sysroot" = x; then
3464           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3465         elif test "x$with_build_sysroot" != "x"; then
3466           glibc_header_dir="${with_build_sysroot}/usr/include"
3467         elif test "x$with_sysroot" = xyes; then
3468           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3469         else
3470           glibc_header_dir="${with_sysroot}/usr/include"
3471         fi
3472       else
3473         glibc_header_dir=/usr/include
3474       fi
3475 changequote(,)dnl
3476       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3477         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3478       && gcc_cv_target_ldbl128=yes
3479 changequote([,])dnl
3480       ])
3481     ;;
3482 esac
3483 if test x$gcc_cv_target_ldbl128 = xyes; then
3484   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3485             [Define if TFmode long double should be the default])
3486 fi
3487
3488 # Find out what GC implementation we want, or may, use.
3489 AC_ARG_WITH(gc,
3490 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3491                           with the compiler],
3492 [case "$withval" in
3493   page)
3494     GGC=ggc-$withval
3495     ;;
3496   zone)
3497     GGC=ggc-$withval
3498     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3499     ;;
3500   *)
3501     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3502     ;;
3503 esac],
3504 [GGC=ggc-page])
3505 AC_SUBST(GGC)
3506 echo "Using $GGC for garbage collection."
3507
3508 # Use the system's zlib library.
3509 zlibdir=-L../zlib
3510 zlibinc="-I\$(srcdir)/../zlib"
3511 AC_ARG_WITH(system-zlib,
3512 [  --with-system-zlib      use installed libz],
3513 zlibdir=
3514 zlibinc=
3515 )
3516 AC_SUBST(zlibdir)
3517 AC_SUBST(zlibinc)
3518
3519 dnl Very limited version of automake's enable-maintainer-mode
3520
3521 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3522   dnl maintainer-mode is disabled by default
3523   AC_ARG_ENABLE(maintainer-mode,
3524 [  --enable-maintainer-mode
3525                           enable make rules and dependencies not useful
3526                           (and sometimes confusing) to the casual installer],
3527       maintainer_mode=$enableval,
3528       maintainer_mode=no)
3529
3530 AC_MSG_RESULT($maintainer_mode)
3531
3532 if test "$maintainer_mode" = "yes"; then
3533   MAINT=''
3534 else
3535   MAINT='#'
3536 fi
3537 AC_SUBST(MAINT)dnl
3538
3539 # --------------
3540 # Language hooks
3541 # --------------
3542
3543 # Make empty files to contain the specs and options for each language.
3544 # Then add #include lines to for a compiler that has specs and/or options.
3545
3546 subdirs=
3547 lang_opt_files=
3548 lang_specs_files=
3549 lang_tree_files=
3550 # These (without "all_") are set in each config-lang.in.
3551 # `language' must be a single word so is spelled singularly.
3552 all_languages=
3553 all_compilers=
3554 all_outputs='Makefile gccbug libada-mk'
3555 # List of language makefile fragments.
3556 all_lang_makefrags=
3557 # List of language subdirectory makefiles.  Deprecated.
3558 all_lang_makefiles=
3559 # Additional files for gengtype
3560 all_gtfiles="$target_gtfiles"
3561
3562 # These are the languages that are set in --enable-languages,
3563 # and are available in the GCC tree.
3564 all_selected_languages=
3565
3566 # Add the language fragments.
3567 # Languages are added via two mechanisms.  Some information must be
3568 # recorded in makefile variables, these are defined in config-lang.in.
3569 # We accumulate them and plug them into the main Makefile.
3570 # The other mechanism is a set of hooks for each of the main targets
3571 # like `clean', `install', etc.
3572
3573 language_hooks="Make-hooks"
3574
3575 for lang in ${srcdir}/*/config-lang.in
3576 do
3577 changequote(,)dnl
3578         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3579
3580         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3581         if test "x$lang_alias" = x
3582         then
3583               echo "$lang doesn't set \$language." 1>&2
3584               exit 1
3585         fi
3586         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3587         subdirs="$subdirs $subdir"
3588
3589         # $gcc_subdir is where the gcc integration files are to be found
3590         # for a language, both for internal compiler purposes (compiler
3591         # sources implementing front-end to GCC tree converters), and for
3592         # build infrastructure purposes (Make-lang.in, etc.)
3593         #
3594         # This will be <subdir> (relative to $srcdir) if a line like
3595         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3596         # is found in <langdir>/config-lang.in, and will remain <langdir>
3597         # otherwise.
3598         #
3599         # Except for the language alias (fetched above), the regular
3600         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3601         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3602         # only this and the language alias.
3603
3604         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3605         if [ "$gcc_subdir" = "" ]; then
3606            gcc_subdir="$subdir"
3607         fi
3608
3609         case ",$enable_languages," in
3610         *,$lang_alias,*)
3611             all_selected_languages="$all_selected_languages $lang_alias"
3612             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3613                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3614             fi
3615             ;;
3616         esac
3617 changequote([,])dnl
3618
3619         language=
3620         boot_language=
3621         compilers=
3622         outputs=
3623         gtfiles=
3624         subdir_requires=
3625         . ${srcdir}/$gcc_subdir/config-lang.in
3626         if test "x$language" = x
3627         then
3628                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3629                 exit 1
3630         fi
3631
3632         ok=:
3633         case ",$enable_languages," in
3634                 *,$lang_alias,*) ;;
3635                 *)
3636                         for i in $subdir_requires; do
3637                                 test -f "${srcdir}/$i/config-lang.in" && continue
3638                                 ok=false
3639                                 break
3640                         done
3641                 ;;
3642         esac
3643         $ok || continue
3644
3645         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3646         if test -f $srcdir/$gcc_subdir/lang.opt; then
3647             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3648         fi
3649         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3650             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3651         fi
3652         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3653                 then all_lang_makefiles="$gcc_subdir/Makefile"
3654         fi
3655         all_languages="$all_languages $language"
3656         all_compilers="$all_compilers $compilers"
3657         all_outputs="$all_outputs $outputs"
3658         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3659 done
3660
3661 # Pick up gtfiles for c
3662 gtfiles=
3663 . ${srcdir}/c-config-lang.in
3664 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3665
3666 check_languages=
3667 for language in $all_selected_languages
3668 do
3669         check_languages="$check_languages check-$language"
3670 done
3671
3672 # We link each language in with a set of hooks, reached indirectly via
3673 # lang.${target}.  Only do so for selected languages.
3674
3675 rm -f Make-hooks
3676 touch Make-hooks
3677 target_list="all.cross start.encap rest.encap tags \
3678         install-common install-man install-info install-pdf dvi pdf \
3679         html uninstall info man srcextra srcman srcinfo \
3680         mostlyclean clean distclean maintainer-clean"
3681
3682 for t in $target_list
3683 do
3684         x=
3685         for lang in $all_selected_languages
3686         do
3687                 x="$x $lang.$t"
3688         done
3689         echo "lang.$t: $x" >> Make-hooks
3690 done
3691
3692 # --------
3693 # UNSORTED
3694 # --------
3695
3696 # Create .gdbinit.
3697
3698 echo "dir ." > .gdbinit
3699 echo "dir ${srcdir}" >> .gdbinit
3700 if test x$gdb_needs_out_file_path = xyes
3701 then
3702         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3703 fi
3704 if test "x$subdirs" != x; then
3705         for s in $subdirs
3706         do
3707                 echo "dir ${srcdir}/$s" >> .gdbinit
3708         done
3709 fi
3710 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3711
3712 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3713 AC_SUBST(gcc_tooldir)
3714 AC_SUBST(dollar)
3715
3716 # Find a directory in which to install a shared libgcc.
3717
3718 AC_ARG_ENABLE(version-specific-runtime-libs,
3719 [  --enable-version-specific-runtime-libs
3720                           specify that runtime libraries should be
3721                           installed in a compiler-specific directory])
3722
3723 AC_ARG_WITH(slibdir,
3724 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3725 slibdir="$with_slibdir",
3726 if test "${enable_version_specific_runtime_libs+set}" = set; then
3727   slibdir='$(libsubdir)'
3728 elif test "$host" != "$target"; then
3729   slibdir='$(build_tooldir)/lib'
3730 else
3731   slibdir='$(libdir)'
3732 fi)
3733 AC_SUBST(slibdir)
3734
3735 AC_ARG_WITH(datarootdir,
3736 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3737 datarootdir="\${prefix}/$with_datarootdir",
3738 datarootdir='$(prefix)/share')
3739 AC_SUBST(datarootdir)
3740
3741 AC_ARG_WITH(docdir,
3742 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3743 docdir="\${prefix}/$with_docdir",
3744 docdir='$(datarootdir)')
3745 AC_SUBST(docdir)
3746
3747 AC_ARG_WITH(htmldir,
3748 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3749 htmldir="\${prefix}/$with_htmldir",
3750 htmldir='$(docdir)')
3751 AC_SUBST(htmldir)
3752
3753 # Substitute configuration variables
3754 AC_SUBST(subdirs)
3755 AC_SUBST(srcdir)
3756 AC_SUBST(all_compilers)
3757 AC_SUBST(all_gtfiles)
3758 AC_SUBST(all_lang_makefrags)
3759 AC_SUBST(all_lang_makefiles)
3760 AC_SUBST(all_languages)
3761 AC_SUBST(all_selected_languages)
3762 AC_SUBST(build_exeext)
3763 AC_SUBST(build_install_headers_dir)
3764 AC_SUBST(build_xm_file_list)
3765 AC_SUBST(build_xm_include_list)
3766 AC_SUBST(build_xm_defines)
3767 AC_SUBST(build_file_translate)
3768 AC_SUBST(check_languages)
3769 AC_SUBST(cpp_install_dir)
3770 AC_SUBST(xmake_file)
3771 AC_SUBST(tmake_file)
3772 AC_SUBST(extra_gcc_objs)
3773 AC_SUBST(extra_headers_list)
3774 AC_SUBST(extra_objs)
3775 AC_SUBST(extra_parts)
3776 AC_SUBST(extra_passes)
3777 AC_SUBST(extra_programs)
3778 AC_SUBST(float_h_file)
3779 AC_SUBST(gcc_config_arguments)
3780 AC_SUBST(gcc_gxx_include_dir)
3781 AC_SUBST(host_exeext)
3782 AC_SUBST(host_xm_file_list)
3783 AC_SUBST(host_xm_include_list)
3784 AC_SUBST(host_xm_defines)
3785 AC_SUBST(out_host_hook_obj)
3786 AC_SUBST(install)
3787 AC_SUBST(lang_opt_files)
3788 AC_SUBST(lang_specs_files)
3789 AC_SUBST(lang_tree_files)
3790 AC_SUBST(local_prefix)
3791 AC_SUBST(md_file)
3792 AC_SUBST(objc_boehm_gc)
3793 AC_SUBST(out_file)
3794 AC_SUBST(out_object_file)
3795 AC_SUBST(thread_file)
3796 AC_SUBST(tm_file_list)
3797 AC_SUBST(tm_include_list)
3798 AC_SUBST(tm_defines)
3799 AC_SUBST(tm_p_file_list)
3800 AC_SUBST(tm_p_include_list)
3801 AC_SUBST(xm_file_list)
3802 AC_SUBST(xm_include_list)
3803 AC_SUBST(xm_defines)
3804 AC_SUBST(c_target_objs)
3805 AC_SUBST(cxx_target_objs)
3806 AC_SUBST(target_cpu_default)
3807
3808 AC_SUBST_FILE(language_hooks)
3809
3810 # Echo link setup.
3811 if test x${build} = x${host} ; then
3812   if test x${host} = x${target} ; then
3813     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3814   else
3815     echo "Links are now set up to build a cross-compiler" 1>&2
3816     echo " from ${host} to ${target}." 1>&2
3817   fi
3818 else
3819   if test x${host} = x${target} ; then
3820     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3821     echo " for ${target}." 1>&2
3822   else
3823     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3824     echo " from ${host} to ${target}." 1>&2
3825   fi
3826 fi
3827
3828 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3829 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3830
3831 # Configure the subdirectories
3832 # AC_CONFIG_SUBDIRS($subdirs)
3833
3834 # Create the Makefile
3835 # and configure language subdirectories
3836 AC_CONFIG_FILES($all_outputs)
3837
3838 AC_CONFIG_COMMANDS([default],
3839 [
3840 case ${CONFIG_HEADERS} in
3841   *auto-host.h:config.in*)
3842   echo > cstamp-h ;;
3843 esac
3844 # Make sure all the subdirs exist.
3845 for d in $subdirs doc build
3846 do
3847     test -d $d || mkdir $d
3848 done
3849 ],
3850 [subdirs='$subdirs'])
3851 AC_OUTPUT