gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  22 #02110-1301, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 gcc_version=`cat $srcdir/BASE-VER`
  34
  35 # Determine the host, build, and target systems
  36 AC_CANONICAL_BUILD
  37 AC_CANONICAL_HOST
  38 AC_CANONICAL_TARGET
  39
  40 # Determine the noncanonical target name, for directory use.
  41 ACX_NONCANONICAL_TARGET
  42
  43 # Determine the target- and build-specific subdirectories
  44 GCC_TOPLEV_SUBDIRS
  45
  46 # Set program_transform_name
  47 AC_ARG_PROGRAM
  48
  49 # Check for bogus environment variables.
  50 # Test if LIBRARY_PATH contains the notation for the current directory
  51 # since this would lead to problems installing/building glibc.
  52 # LIBRARY_PATH contains the current directory if one of the following
  53 # is true:
  54 # - one of the terminals (":" and ";") is the first or last sign
  55 # - two terminals occur directly after each other
  56 # - the path contains an element with a dot in it
  57 AC_MSG_CHECKING(LIBRARY_PATH variable)
  58 changequote(,)dnl
  59 case ${LIBRARY_PATH} in
  60   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  61     library_path_setting="contains current directory"
  62     ;;
  63   *)
  64     library_path_setting="ok"
  65     ;;
  66 esac
  67 changequote([,])dnl
  68 AC_MSG_RESULT($library_path_setting)
  69 if test "$library_path_setting" != "ok"; then
  70 AC_MSG_ERROR([
  71 *** LIBRARY_PATH shouldn't contain the current directory when
  72 *** building gcc. Please change the environment variable
  73 *** and run configure again.])
  74 fi
  75
  76 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  77 # since this would lead to problems installing/building glibc.
  78 # GCC_EXEC_PREFIX contains the current directory if one of the following
  79 # is true:
  80 # - one of the terminals (":" and ";") is the first or last sign
  81 # - two terminals occur directly after each other
  82 # - the path contains an element with a dot in it
  83 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  84 changequote(,)dnl
  85 case ${GCC_EXEC_PREFIX} in
  86   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  87     gcc_exec_prefix_setting="contains current directory"
  88     ;;
  89   *)
  90     gcc_exec_prefix_setting="ok"
  91     ;;
  92 esac
  93 changequote([,])dnl
  94 AC_MSG_RESULT($gcc_exec_prefix_setting)
  95 if test "$gcc_exec_prefix_setting" != "ok"; then
  96 AC_MSG_ERROR([
  97 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  98 *** building gcc. Please change the environment variable
  99 *** and run configure again.])
 100 fi
 101
 102 # -----------
 103 # Directories
 104 # -----------
 105
 106 # Specify the local prefix
 107 local_prefix=
 108 AC_ARG_WITH(local-prefix,
 109 [  --with-local-prefix=DIR specifies directory to put local include],
 110 [case "${withval}" in
 111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 112 no)     ;;
 113 *)      local_prefix=$with_local_prefix ;;
 114 esac])
 115
 116 # Default local prefix if it is empty
 117 if test x$local_prefix = x; then
 118         local_prefix=/usr/local
 119 fi
 120
 121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 122 # passed in by the toplevel make and thus we'd get different behavior
 123 # depending on where we built the sources.
 124 gcc_gxx_include_dir=
 125 # Specify the g++ header file directory
 126 AC_ARG_WITH(gxx-include-dir,
 127 [  --with-gxx-include-dir=DIR
 128                           specifies directory to put g++ header files],
 129 [case "${withval}" in
 130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 131 no)     ;;
 132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 133 esac])
 134
 135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 136 if test x${gcc_gxx_include_dir} = x; then
 137   if test x${enable_version_specific_runtime_libs} = xyes; then
 138     gcc_gxx_include_dir='${libsubdir}/include/c++'
 139   else
 140     libstdcxx_incdir='include/c++/$(version)'
 141     if test x$host != x$target; then
 142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 143     fi
 144     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 145   fi
 146 fi
 147
 148 AC_ARG_WITH(cpp_install_dir,
 149 [  --with-cpp-install-dir=DIR
 150                           install the user visible C preprocessor in DIR
 151                           (relative to PREFIX) as well as PREFIX/bin],
 152 [if test x$withval = xyes; then
 153   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 154 elif test x$withval != xno; then
 155   cpp_install_dir=$withval
 156 fi])
 157
 158 # We would like to our source tree to be readonly.  However when releases or
 159 # pre-releases are generated, the flex/bison generated files as well as the
 160 # various formats of manuals need to be included along with the rest of the
 161 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 162 # just that.
 163
 164 AC_MSG_CHECKING([whether to place generated files in the source directory])
 165   dnl generated-files-in-srcdir is disabled by default
 166   AC_ARG_ENABLE(generated-files-in-srcdir,
 167 [  --enable-generated-files-in-srcdir
 168                           put copies of generated files in source dir
 169                           intended for creating source tarballs for users
 170                           without texinfo bison or flex.],
 171       generated_files_in_srcdir=$enableval,
 172       generated_files_in_srcdir=no)
 173
 174 AC_MSG_RESULT($generated_files_in_srcdir)
 175
 176 if test "$generated_files_in_srcdir" = "yes"; then
 177   GENINSRC=''
 178 else
 179   GENINSRC='#'
 180 fi
 181 AC_SUBST(GENINSRC)
 182
 183 # -------------------
 184 # Find default linker
 185 # -------------------
 186
 187 # With GNU ld
 188 AC_ARG_WITH(gnu-ld,
 189 [  --with-gnu-ld           arrange to work with GNU ld.],
 190 gnu_ld_flag="$with_gnu_ld",
 191 gnu_ld_flag=no)
 192
 193 # With pre-defined ld
 194 AC_ARG_WITH(ld,
 195 [  --with-ld               arrange to use the specified ld (full pathname)],
 196 DEFAULT_LINKER="$with_ld")
 197 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 198   if test ! -x "$DEFAULT_LINKER"; then
 199     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 200   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 201     gnu_ld_flag=yes
 202   fi
 203   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 204         [Define to enable the use of a default linker.])
 205 fi
 206
 207 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 208 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 209
 210 AC_MSG_CHECKING([whether a default linker was specified])
 211 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 212   if test x"$gnu_ld_flag" = x"no"; then
 213     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 214   else
 215     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 216   fi
 217 else
 218   AC_MSG_RESULT(no)
 219 fi
 220
 221 # With demangler in GNU ld
 222 AC_ARG_WITH(demangler-in-ld,
 223 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 224 demangler_in_ld="$with_demangler_in_ld",
 225 demangler_in_ld=no)
 226
 227 # ----------------------
 228 # Find default assembler
 229 # ----------------------
 230
 231 # With GNU as
 232 AC_ARG_WITH(gnu-as,
 233 [  --with-gnu-as           arrange to work with GNU as],
 234 gas_flag="$with_gnu_as",
 235 gas_flag=no)
 236
 237 AC_ARG_WITH(as,
 238 [  --with-as               arrange to use the specified as (full pathname)],
 239 DEFAULT_ASSEMBLER="$with_as")
 240 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 241   if test ! -x "$DEFAULT_ASSEMBLER"; then
 242     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 243   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 244     gas_flag=yes
 245   fi
 246   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 247         [Define to enable the use of a default assembler.])
 248 fi
 249
 250 AC_MSG_CHECKING([whether a default assembler was specified])
 251 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 252   if test x"$gas_flag" = x"no"; then
 253     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 254   else
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 256   fi
 257 else
 258   AC_MSG_RESULT(no)
 259 fi
 260
 261 # ---------------
 262 # Find C compiler
 263 # ---------------
 264
 265 # If a non-executable a.out is present (e.g. created by GNU as above even if
 266 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 267 # file, even when creating an executable, so an execution test fails.
 268 # Remove possible default executable files to avoid this.
 269 #
 270 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 271 # Autoconf includes it.
 272 rm -f a.out a.exe b.out
 273
 274 # Find the native compiler
 275 AC_PROG_CC
 276 AM_PROG_CC_C_O
 277 # autoconf is lame and doesn't give us any substitution variable for this.
 278 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 279   NO_MINUS_C_MINUS_O=yes
 280 else
 281   OUTPUT_OPTION='-o $@'
 282 fi
 283 AC_SUBST(NO_MINUS_C_MINUS_O)
 284 AC_SUBST(OUTPUT_OPTION)
 285
 286 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 287 # optimizations to be activated explicitly by the toplevel.
 288 case "$CC" in
 289   */prev-gcc/xgcc*) ;;
 290   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 291 esac
 292 AC_SUBST(CFLAGS)
 293
 294 # -------------------------
 295 # Check C compiler features
 296 # -------------------------
 297
 298 AC_PROG_CPP
 299 AC_C_INLINE
 300
 301 # sizeof(char) is 1 by definition.
 302 AC_CHECK_SIZEOF(void *)
 303 AC_CHECK_SIZEOF(short)
 304 AC_CHECK_SIZEOF(int)
 305 AC_CHECK_SIZEOF(long)
 306 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 307 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 308
 309 # ---------------------
 310 # Warnings and checking
 311 # ---------------------
 312
 313 # Check $CC warning features (if it's GCC).
 314 # We want to use -pedantic, but we don't want warnings about
 315 # * 'long long'
 316 # * variadic macros
 317 # * overlong strings
 318 # So, we only use -pedantic if we can disable those warnings.
 319
 320 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 321                           -Wmissing-prototypes], [loose_warn])
 322 ACX_PROG_CC_WARNING_OPTS([-Wc++-compat], [cxx_compat_warn])
 323 ACX_PROG_CC_WARNING_OPTS([-Wold-style-definition \
 324                           -Wmissing-format-attribute], [strict_warn])
 325 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([-Wno-long-long -Wno-variadic-macros \
 326                                      -Wno-overlength-strings], [strict_warn])
 327 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 328
 329 # The above macros do nothing if the compiler is not GCC.  However, the
 330 # Makefile has more goo to add other flags, so this variabl is used to
 331 # enables warnings only for GCC.
 332 warn_cflags=
 333 if test "x$GCC" = "xyes"; then
 334   warn_cflags='$(GCC_WARN_CFLAGS)'
 335 fi
 336 AC_SUBST(warn_cflags)
 337
 338 # Enable expensive internal checks
 339 is_release=
 340 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 341   is_release=yes
 342 fi
 343
 344 AC_ARG_ENABLE(checking,
 345 [  --enable-checking[=LIST]
 346                           enable expensive run-time checks.  With LIST,
 347                           enable only specific categories of checks.
 348                           Categories are: yes,no,all,none,release.
 349                           Flags are: assert,df,fold,gc,gcac,misc,
 350                           rtlflag,rtl,runtime,tree,valgrind.],
 351 [ac_checking_flags="${enableval}"],[
 352 # Determine the default checks.
 353 if test x$is_release = x ; then
 354   ac_checking_flags=yes
 355 else
 356   ac_checking_flags=release
 357 fi])
 358 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 359 for check in release $ac_checking_flags
 360 do
 361         case $check in
 362         # these set all the flags to specific states
 363         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 364                         ac_fold_checking= ; ac_gc_checking=1 ;
 365                         ac_gc_always_collect= ; ac_rtl_checking= ;
 366                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 367                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 368         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 369                         ac_fold_checking= ; ac_gc_checking= ;
 370                         ac_gc_always_collect= ; ac_rtl_checking= ;
 371                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 372                         ac_tree_checking= ; ac_valgrind_checking= ;;
 373         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 374                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 375                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 376                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 377                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 378         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 379                         ac_fold_checking= ; ac_gc_checking= ;
 380                         ac_gc_always_collect= ; ac_rtl_checking= ;
 381                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 382                         ac_tree_checking= ; ac_valgrind_checking= ;;
 383         # these enable particular checks
 384         assert)         ac_assert_checking=1 ;;
 385         df)             ac_df_checking=1 ;;
 386         fold)           ac_fold_checking=1 ;;
 387         gc)             ac_gc_checking=1 ;;
 388         gcac)           ac_gc_always_collect=1 ;;
 389         misc)           ac_checking=1 ;;
 390         rtl)            ac_rtl_checking=1 ;;
 391         rtlflag)        ac_rtlflag_checking=1 ;;
 392         runtime)        ac_runtime_checking=1 ;;
 393         tree)           ac_tree_checking=1 ;;
 394         valgrind)       ac_valgrind_checking=1 ;;
 395         *)      AC_MSG_ERROR(unknown check category $check) ;;
 396         esac
 397 done
 398 IFS="$ac_save_IFS"
 399
 400 nocommon_flag=""
 401 if test x$ac_checking != x ; then
 402   AC_DEFINE(ENABLE_CHECKING, 1,
 403 [Define if you want more run-time sanity checks.  This one gets a grab
 404    bag of miscellaneous but relatively cheap checks.])
 405   nocommon_flag=-fno-common
 406 fi
 407 AC_SUBST(nocommon_flag)
 408 if test x$ac_df_checking != x ; then
 409   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 410 [Define if you want more run-time sanity checks for dataflow.])
 411 fi
 412 if test x$ac_assert_checking != x ; then
 413   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 414 [Define if you want assertions enabled.  This is a cheap check.])
 415 fi
 416 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 417 if test x$ac_runtime_checking != x ; then
 418   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 419 [Define if you want runtime assertions enabled.  This is a cheap check.])
 420 fi
 421 if test x$ac_tree_checking != x ; then
 422   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 423 [Define if you want all operations on trees (the basic data
 424    structure of the front ends) to be checked for dynamic type safety
 425    at runtime.  This is moderately expensive.  The tree browser debugging
 426    routines will also be enabled by this option.
 427    ])
 428   TREEBROWSER=tree-browser.o
 429 fi
 430 AC_SUBST(TREEBROWSER)
 431 if test x$ac_rtl_checking != x ; then
 432   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 433 [Define if you want all operations on RTL (the basic data structure
 434    of the optimizer and back end) to be checked for dynamic type safety
 435    at runtime.  This is quite expensive.])
 436 fi
 437 if test x$ac_rtlflag_checking != x ; then
 438   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 439 [Define if you want RTL flag accesses to be checked against the RTL
 440    codes that are supported for each access macro.  This is relatively
 441    cheap.])
 442 fi
 443 if test x$ac_gc_checking != x ; then
 444   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 445 [Define if you want the garbage collector to do object poisoning and
 446    other memory allocation checks.  This is quite expensive.])
 447 fi
 448 if test x$ac_gc_always_collect != x ; then
 449   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 450 [Define if you want the garbage collector to operate in maximally
 451    paranoid mode, validating the entire heap and collecting garbage at
 452    every opportunity.  This is extremely expensive.])
 453 fi
 454 if test x$ac_fold_checking != x ; then
 455   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 456 [Define if you want fold checked that it never destructs its argument.
 457    This is quite expensive.])
 458 fi
 459 valgrind_path_defines=
 460 valgrind_command=
 461
 462 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 463 dnl # an if statement.  This was the source of very frustrating bugs
 464 dnl # in converting to autoconf 2.5x!
 465 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 466
 467 if test x$ac_valgrind_checking != x ; then
 468   # It is certainly possible that there's valgrind but no valgrind.h.
 469   # GCC relies on making annotations so we must have both.
 470   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 471   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 472     [[#include <valgrind/memcheck.h>
 473 #ifndef VALGRIND_DISCARD
 474 #error VALGRIND_DISCARD not defined
 475 #endif]])],
 476   [gcc_cv_header_valgrind_memcheck_h=yes],
 477   [gcc_cv_header_valgrind_memcheck_h=no])
 478   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 479   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 480   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 481     [[#include <memcheck.h>
 482 #ifndef VALGRIND_DISCARD
 483 #error VALGRIND_DISCARD not defined
 484 #endif]])],
 485   [gcc_cv_header_memcheck_h=yes],
 486   [gcc_cv_header_memcheck_h=no])
 487   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 488   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 489         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 490   if test "x$valgrind_path" = "x" \
 491     || (test $have_valgrind_h = no \
 492         && test $gcc_cv_header_memcheck_h = no \
 493         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 494         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 495   fi
 496   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 497   valgrind_command="$valgrind_path -q"
 498   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 499 [Define if you want to run subprograms and generated programs
 500    through valgrind (a memory checker).  This is extremely expensive.])
 501   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 502     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 503         [Define if valgrind's valgrind/memcheck.h header is installed.])
 504   fi
 505   if test $gcc_cv_header_memcheck_h = yes; then
 506     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 507         [Define if valgrind's memcheck.h header is installed.])
 508   fi
 509 fi
 510 AC_SUBST(valgrind_path_defines)
 511 AC_SUBST(valgrind_command)
 512
 513 AC_ARG_ENABLE(mapped-location,
 514 [  --enable-mapped-location   location_t is fileline integer cookie],,
 515 enable_mapped_location=no)
 516
 517 if test "$enable_mapped_location" = yes ; then
 518   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 519 [Define if location_t is fileline integer cookie.])
 520 fi
 521
 522 # Enable code coverage collection
 523 AC_ARG_ENABLE(coverage,
 524 [  --enable-coverage[=LEVEL]
 525                           enable compiler's code coverage collection.
 526                           Use to measure compiler performance and locate
 527                           unused parts of the compiler. With LEVEL, specify
 528                           optimization. Values are opt, noopt,
 529                           default is noopt],
 530 [case "${enableval}" in
 531   yes|noopt)
 532     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 533     ;;
 534   opt)
 535     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 536     ;;
 537   no)
 538     # a.k.a. --disable-coverage
 539     coverage_flags=""
 540     ;;
 541   *)
 542     AC_MSG_ERROR(unknown coverage setting $enableval)
 543     ;;
 544 esac],
 545 [coverage_flags=""])
 546 AC_SUBST(coverage_flags)
 547
 548 AC_ARG_ENABLE(gather-detailed-mem-stats,
 549 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 550 [enable_gather_detailed_mem_stats=no])
 551 if test x$enable_gather_detailed_mem_stats = xyes ; then
 552   AC_DEFINE(GATHER_STATISTICS, 1,
 553         [Define to enable detailed memory allocation stats gathering.])
 554 fi
 555
 556 # -------------------------------
 557 # Miscenalleous configure options
 558 # -------------------------------
 559
 560 # With stabs
 561 AC_ARG_WITH(stabs,
 562 [  --with-stabs            arrange to use stabs instead of host debug format],
 563 stabs="$with_stabs",
 564 stabs=no)
 565
 566 # Determine whether or not multilibs are enabled.
 567 AC_ARG_ENABLE(multilib,
 568 [  --enable-multilib       enable library support for multiple ABIs],
 569 [], [enable_multilib=yes])
 570 AC_SUBST(enable_multilib)
 571
 572 # Enable __cxa_atexit for C++.
 573 AC_ARG_ENABLE(__cxa_atexit,
 574 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 575 [], [])
 576
 577 # Enable C extension for decimal float if target supports it.
 578 AC_ARG_ENABLE(decimal-float,
 579 [  --enable-decimal-float={no,yes,bid,dpd}
 580                         enable decimal float extension to C.  Selecting 'bid'
 581                         or 'dpd' choses which decimal floating point format
 582                         to use],
 583 [
 584   case $enable_decimal_float in
 585     yes | no | bid | dpd) ;;
 586     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 587 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 588   esac
 589 ],
 590 [
 591   case $target in
 592     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 593       enable_decimal_float=yes
 594       ;;
 595     *)
 596       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 597       enable_decimal_float=no
 598       ;;
 599   esac
 600 ])
 601
 602 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 603 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 604 [Define to 1 to enable decimal float extension to C.])
 605
 606 # x86's use BID format instead of DPD
 607 case x$enable_decimal_float in
 608   xyes)
 609     case $target in
 610       i?86*-*-linux* | x86_64*-*-linux*)
 611         enable_decimal_float=bid
 612         ;;
 613       *)
 614         enable_decimal_float=dpd
 615         ;;
 616     esac
 617     ;;
 618   xno)
 619     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 620     # dependency on libdecnumber.
 621     enable_decimal_float=dpd
 622     ;;
 623 esac
 624 AC_SUBST(enable_decimal_float)
 625
 626 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 627 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 628 [Define to 1 to specify that we are using the BID decimal floating
 629 point format instead of DPD])
 630
 631 # Enable threads
 632 # Pass with no value to take the default
 633 # Pass with a value to specify a thread package
 634 AC_ARG_ENABLE(threads,
 635 [  --enable-threads        enable thread usage for target GCC
 636   --enable-threads=LIB    use LIB thread package for target GCC],,
 637 [enable_threads=''])
 638
 639 AC_ARG_ENABLE(tls,
 640 [  --enable-tls            enable or disable generation of tls code
 641                           overriding the assembler check for tls support],
 642 [
 643   case $enable_tls in
 644     yes | no) ;;
 645     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 646 Valid choices are 'yes' and 'no'.]) ;;
 647   esac
 648 ], [enable_tls=''])
 649
 650 AC_ARG_ENABLE(objc-gc,
 651 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 652                           the GNU Objective-C runtime],
 653 if test x$enable_objc_gc = xno; then
 654         objc_boehm_gc=''
 655 else
 656         objc_boehm_gc=1
 657 fi,
 658 objc_boehm_gc='')
 659
 660 AC_ARG_WITH(dwarf2,
 661 [  --with-dwarf2           force the default debug format to be DWARF 2],
 662 dwarf2="$with_dwarf2",
 663 dwarf2=no)
 664
 665 AC_ARG_ENABLE(shared,
 666 [  --disable-shared        don't provide a shared libgcc],
 667 [
 668   case $enable_shared in
 669   yes | no) ;;
 670   *)
 671     enable_shared=no
 672     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 673     for pkg in $enableval; do
 674       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 675         enable_shared=yes
 676       fi
 677     done
 678     IFS="$ac_save_ifs"
 679     ;;
 680   esac
 681 ], [enable_shared=yes])
 682 AC_SUBST(enable_shared)
 683
 684 AC_ARG_WITH(build-sysroot,
 685   [  --with-build-sysroot=sysroot
 686                           use sysroot as the system root during the build])
 687
 688 AC_ARG_WITH(sysroot,
 689 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 690 [
 691  case ${with_sysroot} in
 692  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 693  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 694  esac
 695
 696  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 697  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 698
 699  if test "x$prefix" = xNONE; then
 700   test_prefix=/usr/local
 701  else
 702   test_prefix=$prefix
 703  fi
 704  if test "x$exec_prefix" = xNONE; then
 705   test_exec_prefix=$test_prefix
 706  else
 707   test_exec_prefix=$exec_prefix
 708  fi
 709  case ${TARGET_SYSTEM_ROOT} in
 710  "${test_prefix}"|"${test_prefix}/"*|\
 711  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 712  '${prefix}'|'${prefix}/'*|\
 713  '${exec_prefix}'|'${exec_prefix}/'*)
 714    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 715    TARGET_SYSTEM_ROOT_DEFINE="$t"
 716    ;;
 717  esac
 718 ], [
 719  TARGET_SYSTEM_ROOT=
 720  TARGET_SYSTEM_ROOT_DEFINE=
 721  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 722 ])
 723 AC_SUBST(TARGET_SYSTEM_ROOT)
 724 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 725 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 726
 727 # Build with intermodule optimisations
 728 AC_ARG_ENABLE(intermodule,
 729 [  --enable-intermodule    build the compiler in one step],
 730 [case ${enable_intermodule} in
 731   yes) onestep="-onestep";;
 732   *) onestep="";;
 733 esac],
 734 [onestep=""])
 735 AC_SUBST(onestep)
 736
 737 # Sanity check enable_languages in case someone does not run the toplevel
 738 # configure # script.
 739 AC_ARG_ENABLE(languages,
 740 [  --enable-languages=LIST specify which front-ends to build],
 741 [case ,${enable_languages}, in
 742        ,,|,yes,)
 743                 # go safe -- we cannot be much sure without the toplevel
 744                 # configure's
 745                 # analysis of which target libs are present and usable
 746                 enable_languages=c
 747                 ;;
 748          *,all,*)
 749                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 750                 ;;
 751         *,c,*)
 752                 ;;
 753         *)
 754                 enable_languages=c,${enable_languages}
 755                 ;;
 756 esac],
 757 [enable_languages=c])
 758
 759 # Used by documentation targets
 760 AC_SUBST(datarootdir)
 761 AC_SUBST(docdir)
 762 AC_SUBST(htmldir)
 763
 764 # -------------------------
 765 # Checks for other programs
 766 # -------------------------
 767
 768 AC_PROG_MAKE_SET
 769
 770 # Find some useful tools
 771 AC_PROG_AWK
 772 # We need awk to create options.c and options.h.
 773 # Bail out if it's missing.
 774 case ${AWK} in
 775   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 776 esac
 777
 778 gcc_AC_PROG_LN_S
 779 ACX_PROG_LN($LN_S)
 780 AC_PROG_RANLIB
 781 case "${host}" in
 782 *-*-darwin*)
 783   # By default, the Darwin ranlib will not treat common symbols as
 784   # definitions when  building the archive table of contents.  Other
 785   # ranlibs do that; pass an option to the Darwin ranlib that makes
 786   # it behave similarly.
 787   ranlib_flags="-c"
 788   ;;
 789 *)
 790   ranlib_flags=""
 791 esac
 792 AC_SUBST(ranlib_flags)
 793
 794 gcc_AC_PROG_INSTALL
 795
 796 # See if cmp has --ignore-initial.
 797 gcc_AC_PROG_CMP_IGNORE_INITIAL
 798
 799 # See if we have the mktemp command.
 800 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 801
 802 # See if makeinfo has been installed and is modern enough
 803 # that we can use it.
 804 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 805   [GNU texinfo.* \([0-9][0-9.]*\)],
 806   [4.[4-9]*])
 807 if test $gcc_cv_prog_makeinfo_modern = no; then
 808   AC_MSG_WARN([
 809 *** Makeinfo is missing or too old.
 810 *** Info documentation will not be built.])
 811   BUILD_INFO=
 812 else
 813   BUILD_INFO=info
 814 fi
 815 AC_SUBST(BUILD_INFO)
 816
 817 # Is pod2man recent enough to regenerate manpages?
 818 AC_MSG_CHECKING([for recent Pod::Man])
 819 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 820   AC_MSG_RESULT(yes)
 821   GENERATED_MANPAGES=generated-manpages
 822 else
 823   AC_MSG_RESULT(no)
 824   GENERATED_MANPAGES=
 825 fi
 826 AC_SUBST(GENERATED_MANPAGES)
 827
 828 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 829
 830 # How about lex?
 831 dnl Don't use AC_PROG_LEX; we insist on flex.
 832 dnl LEXLIB is not useful in gcc.
 833 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 834
 835 # Bison?
 836 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 837
 838 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 839 # check for build == host before using them.
 840
 841 # NM
 842 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 843   && test -d ../binutils ; then
 844   NM='$(objdir)/../binutils/nm-new'
 845 else
 846   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 847 fi
 848
 849 # AR
 850 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 851   && test -d ../binutils ; then
 852   AR='$(objdir)/../binutils/ar'
 853 else
 854   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 855 fi
 856
 857
 858 # --------------------
 859 # Checks for C headers
 860 # --------------------
 861
 862 AC_MSG_CHECKING(for GNU C library)
 863 AC_CACHE_VAL(gcc_cv_glibc,
 864 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 865   [[#include <features.h>]], [[
 866 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 867 #error Not a GNU C library system
 868 #endif]])],
 869   [gcc_cv_glibc=yes],
 870   [gcc_cv_glibc=no])])
 871 AC_MSG_RESULT($gcc_cv_glibc)
 872 if test $gcc_cv_glibc = yes; then
 873   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 874 fi
 875
 876 # Need to reject headers which give warnings, so that the -Werror bootstrap
 877 # works later. *sigh*  This needs to come before all header checks.
 878 AC_PROG_CPP_WERROR
 879
 880 AC_HEADER_STDC
 881 AC_HEADER_TIME
 882 ACX_HEADER_STRING
 883 AC_HEADER_SYS_WAIT
 884 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 885                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 886                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 887                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 888
 889 # Check for thread headers.
 890 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 891 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 892
 893 # These tests can't be done till we know if we have limits.h.
 894 gcc_AC_C_CHAR_BIT
 895 AC_C_BIGENDIAN
 896
 897 # --------
 898 # UNSORTED
 899 # --------
 900
 901
 902 # These libraries may be used by collect2.
 903 # We may need a special search path to get them linked.
 904 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 905 [save_LIBS="$LIBS"
 906 for libs in '' -lld -lmld \
 907                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 908                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 909 do
 910         LIBS="$libs"
 911         AC_TRY_LINK_FUNC(ldopen,
 912                 [gcc_cv_collect2_libs="$libs"; break])
 913 done
 914 LIBS="$save_LIBS"
 915 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 916 case $gcc_cv_collect2_libs in
 917         "none required")        ;;
 918         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 919 esac
 920 AC_SUBST(COLLECT2_LIBS)
 921
 922 # When building Ada code on Alpha, we need exc_resume which is usually in
 923 # -lexc.  So test for it.
 924 save_LIBS="$LIBS"
 925 LIBS=
 926 AC_SEARCH_LIBS(exc_resume, exc)
 927 GNAT_LIBEXC="$LIBS"
 928 LIBS="$save_LIBS"
 929 AC_SUBST(GNAT_LIBEXC)
 930
 931 # Some systems put ldexp and frexp in libm instead of libc; assume
 932 # they're both in the same place.  jcf-dump needs them.
 933 save_LIBS="$LIBS"
 934 LIBS=
 935 AC_SEARCH_LIBS(ldexp, m)
 936 LDEXP_LIB="$LIBS"
 937 LIBS="$save_LIBS"
 938 AC_SUBST(LDEXP_LIB)
 939
 940 # Use <inttypes.h> only if it exists,
 941 # doesn't clash with <sys/types.h>, and declares intmax_t.
 942 AC_MSG_CHECKING(for inttypes.h)
 943 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 944 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 945 [[#include <sys/types.h>
 946 #include <inttypes.h>]],
 947   [[intmax_t i = -1;]])],
 948   [gcc_cv_header_inttypes_h=yes],
 949   [gcc_cv_header_inttypes_h=no])])
 950 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 951 if test $gcc_cv_header_inttypes_h = yes; then
 952   AC_DEFINE(HAVE_INTTYPES_H, 1,
 953         [Define if you have a working <inttypes.h> header file.])
 954 fi
 955
 956 dnl Disabled until we have a complete test for buggy enum bitfields.
 957 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 958
 959 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 960   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 961   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 962   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 963   putchar_unlocked putc_unlocked)
 964 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
 965         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 966         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 967         gcc_UNLOCKED_FUNCS)
 968
 969 if test x$ac_cv_func_mbstowcs = xyes; then
 970   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 971 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
 972 int main()
 973 {
 974   mbstowcs(0, "", 0);
 975   return 0;
 976 }]])],
 977     [gcc_cv_func_mbstowcs_works=yes],
 978     [gcc_cv_func_mbstowcs_works=no],
 979     [gcc_cv_func_mbstowcs_works=yes])])
 980   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 981     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 982   [Define this macro if mbstowcs does not crash when its
 983    first argument is NULL.])
 984   fi
 985 fi
 986
 987 AC_CHECK_TYPE(ssize_t, int)
 988
 989 # Try to determine the array type of the second argument of getgroups
 990 # for the target system (int or gid_t).
 991 AC_TYPE_GETGROUPS
 992 if test "${target}" = "${build}"; then
 993   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
 994 else
 995   case "${target}" in
 996         # This condition may need some tweaking.  It should include all
 997         # targets where the array type of the second argument of getgroups
 998         # is int and the type of gid_t is not equivalent to int.
 999         *-*-sunos* | *-*-ultrix*)
1000                 TARGET_GETGROUPS_T=int
1001                 ;;
1002         *)
1003                 TARGET_GETGROUPS_T=gid_t
1004                 ;;
1005   esac
1006 fi
1007 AC_SUBST(TARGET_GETGROUPS_T)
1008
1009 gcc_AC_FUNC_MMAP_BLACKLIST
1010
1011 case "${host}" in
1012 *-*-*vms*)
1013   # Under VMS, vfork works very differently than on Unix. The standard test
1014   # won't work, and it isn't easily adaptable. It makes more sense to
1015   # just force it.
1016   ac_cv_func_vfork_works=yes
1017   ;;
1018 esac
1019 AC_FUNC_FORK
1020
1021 AM_ICONV
1022 # Until we have in-tree GNU iconv:
1023 LIBICONV_DEP=
1024 AC_SUBST(LIBICONV_DEP)
1025
1026 AM_LC_MESSAGES
1027
1028 AM_LANGINFO_CODESET
1029
1030 # We will need to find libiberty.h and ansidecl.h
1031 saved_CFLAGS="$CFLAGS"
1032 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1033 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1034         strsignal strstr strverscmp \
1035         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1036         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1037 #include "ansidecl.h"
1038 #include "system.h"])
1039
1040 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1041 #include "ansidecl.h"
1042 #include "system.h"
1043 #ifdef HAVE_SYS_RESOURCE_H
1044 #include <sys/resource.h>
1045 #endif
1046 ])
1047
1048 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1049 #include "ansidecl.h"
1050 #include "system.h"
1051 #ifdef HAVE_SYS_RESOURCE_H
1052 #include <sys/resource.h>
1053 #endif
1054 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1055 [Define to \`long' if <sys/resource.h> doesn't define.])])
1056
1057 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1058 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1059 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1060 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1061 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1062 #include "ansidecl.h"
1063 #include "system.h"
1064 #ifdef HAVE_LDFCN_H
1065 #undef FREAD
1066 #undef FWRITE
1067 #include <ldfcn.h>
1068 #endif
1069 ])
1070
1071 gcc_AC_CHECK_DECLS(times, , ,[
1072 #include "ansidecl.h"
1073 #include "system.h"
1074 #ifdef HAVE_SYS_TIMES_H
1075 #include <sys/times.h>
1076 #endif
1077 ])
1078
1079 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1080 #include "ansidecl.h"
1081 #include "system.h"
1082 #include <signal.h>
1083 ])
1084
1085 # More time-related stuff.
1086 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1087 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #ifdef HAVE_SYS_TIMES_H
1091 #include <sys/times.h>
1092 #endif
1093 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1094 if test $ac_cv_struct_tms = yes; then
1095   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1096   [Define if <sys/times.h> defines struct tms.])
1097 fi
1098
1099 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1100 # revisit after autoconf 2.50.
1101 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1102 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1103 #include "ansidecl.h"
1104 #include "system.h"
1105 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1106 if test $gcc_cv_type_clock_t = yes; then
1107   AC_DEFINE(HAVE_CLOCK_T, 1,
1108   [Define if <time.h> defines clock_t.])
1109 fi
1110
1111 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1112 CFLAGS="$saved_CFLAGS"
1113
1114 gcc_AC_INITFINI_ARRAY
1115
1116 # mkdir takes a single argument on some systems.
1117 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1118
1119 # File extensions
1120 manext='.1'
1121 objext='.o'
1122 AC_SUBST(manext)
1123 AC_SUBST(objext)
1124
1125 # With Setjmp/Longjmp based exception handling.
1126 AC_ARG_ENABLE(sjlj-exceptions,
1127 [  --enable-sjlj-exceptions
1128                           arrange to use setjmp/longjmp exception handling],
1129 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1130 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1131   [Define 0/1 to force the choice for exception handling model.])])
1132
1133 # For platforms with the unwind ABI which includes an unwind library,
1134 # libunwind, we can choose to use the system libunwind.
1135 AC_ARG_WITH(system-libunwind,
1136 [  --with-system-libunwind use installed libunwind])
1137
1138 # config.gcc also contains tests of with_system_libunwind.
1139 if test x$with_system_libunwind = xyes; then
1140         AC_DEFINE(HAVE_GETIPINFO, 1,
1141 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1142 fi
1143
1144 # --------------------------------------------------------
1145 # Build, host, and target specific configuration fragments
1146 # --------------------------------------------------------
1147
1148 # Collect build-machine-specific information.
1149 . ${srcdir}/config.build
1150
1151 # Collect host-machine-specific information.
1152 . ${srcdir}/config.host
1153
1154 target_gtfiles=
1155
1156 # Collect target-machine-specific information.
1157 . ${srcdir}/config.gcc
1158
1159 extra_objs="${host_extra_objs} ${extra_objs}"
1160 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1161
1162 # Default the target-machine variables that were not explicitly set.
1163 if test x"$tm_file" = x
1164 then tm_file=$cpu_type/$cpu_type.h; fi
1165
1166 if test x"$extra_headers" = x
1167 then extra_headers=; fi
1168
1169 if test x$md_file = x
1170 then md_file=$cpu_type/$cpu_type.md; fi
1171
1172 if test x$out_file = x
1173 then out_file=$cpu_type/$cpu_type.c; fi
1174
1175 if test x"$tmake_file" = x
1176 then tmake_file=$cpu_type/t-$cpu_type
1177 fi
1178
1179 if test x"$dwarf2" = xyes
1180 then tm_file="$tm_file tm-dwarf2.h"
1181 fi
1182
1183 # Say what files are being used for the output code and MD file.
1184 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1185 echo "Using \`$srcdir/config/$md_file' as machine description file."
1186
1187 # If any of the xm_file variables contain nonexistent files, warn
1188 # about them and drop them.
1189
1190 bx=
1191 for x in $build_xm_file; do
1192   if    test -f $srcdir/config/$x
1193   then      bx="$bx $x"
1194   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1195   fi
1196 done
1197 build_xm_file="$bx"
1198
1199 hx=
1200 for x in $host_xm_file; do
1201   if    test -f $srcdir/config/$x
1202   then      hx="$hx $x"
1203   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1204   fi
1205 done
1206 host_xm_file="$hx"
1207
1208 tx=
1209 for x in $xm_file; do
1210   if    test -f $srcdir/config/$x
1211   then      tx="$tx $x"
1212   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1213   fi
1214 done
1215 xm_file="$tx"
1216
1217 count=a
1218 for f in $tm_file; do
1219         count=${count}x
1220 done
1221 if test $count = ax; then
1222         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1223 else
1224         echo "Using the following target machine macro files:"
1225         for f in $tm_file; do
1226                 echo "  $srcdir/config/$f"
1227         done
1228 fi
1229
1230 if test x$need_64bit_hwint = xyes; then
1231         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1232 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1233 fi
1234
1235 if test x$use_long_long_for_widest_fast_int = xyes; then
1236         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1237 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1238 efficiently supported by the host hardware.])
1239 fi
1240
1241 count=a
1242 for f in $host_xm_file; do
1243         count=${count}x
1244 done
1245 if test $count = a; then
1246         :
1247 elif test $count = ax; then
1248         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1249 else
1250         echo "Using the following host machine macro files:"
1251         for f in $host_xm_file; do
1252                 echo "  $srcdir/config/$f"
1253         done
1254 fi
1255 echo "Using ${out_host_hook_obj} for host machine hooks."
1256
1257 if test "$host_xm_file" != "$build_xm_file"; then
1258         count=a
1259         for f in $build_xm_file; do
1260                 count=${count}x
1261         done
1262         if test $count = a; then
1263                 :
1264         elif test $count = ax; then
1265                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1266         else
1267                 echo "Using the following build machine macro files:"
1268                 for f in $build_xm_file; do
1269                         echo "  $srcdir/config/$f"
1270                 done
1271         fi
1272 fi
1273
1274 case ${host} in
1275   powerpc*-*-darwin*)
1276     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1277       gcc_cv_mcontext_underscores,
1278       AC_COMPILE_IFELSE([
1279 #include <sys/cdefs.h>
1280 #include <sys/signal.h>
1281 #include <ucontext.h>
1282 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1283 ],
1284         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1285       if test $gcc_cv_mcontext_underscores = yes; then
1286         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1287           [mcontext_t fields start with __])
1288       fi
1289     ;;
1290 esac
1291
1292 # ---------
1293 # Threading
1294 # ---------
1295
1296 # Check if a valid thread package
1297 case ${enable_threads} in
1298   "" | no)
1299     # No threads
1300     target_thread_file='single'
1301     ;;
1302   yes)
1303     # default
1304     target_thread_file='single'
1305     ;;
1306   aix | dce | gnat | irix | posix | posix95 | rtems | \
1307   single | solaris | vxworks | win32 )
1308     target_thread_file=${enable_threads}
1309     ;;
1310   *)
1311     echo "${enable_threads} is an unknown thread package" 1>&2
1312     exit 1
1313     ;;
1314 esac
1315
1316 if test x${thread_file} = x; then
1317   # No thread file set by target-specific clauses in config.gcc,
1318   # so use file chosen by default logic above
1319   thread_file=${target_thread_file}
1320 fi
1321
1322 # Make gthr-default.h if we have a thread file.
1323 gthread_flags=
1324 if test $thread_file != single; then
1325   rm -f gthr-default.h
1326   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1327   gthread_flags=-DHAVE_GTHR_DEFAULT
1328 fi
1329 AC_SUBST(gthread_flags)
1330
1331 # --------
1332 # UNSORTED
1333 # --------
1334
1335 use_cxa_atexit=no
1336 if test x$enable___cxa_atexit = xyes || \
1337    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1338   if test x$host = x$target; then
1339     case $host in
1340       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1341       # keyed to flag_use_cxa_atexit
1342       *-*-mingw32*)
1343         use_cxa_atexit=yes
1344         ;;
1345       *)
1346         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1347           [echo "__cxa_atexit can't be enabled on this target"])
1348         ;;
1349     esac
1350   else
1351     # We can't check for __cxa_atexit when building a cross, so assume
1352     # it is available
1353     use_cxa_atexit=yes
1354   fi
1355   if test x$use_cxa_atexit = xyes; then
1356     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1357       [Define if you want to use __cxa_atexit, rather than atexit, to
1358       register C++ destructors for local statics and global objects.
1359       This is essential for fully standards-compliant handling of
1360       destructors, but requires __cxa_atexit in libc.])
1361   fi
1362 fi
1363
1364 use_getipinfo=yes
1365 if test x$with_system_libunwind = xyes; then
1366    if test x$host = x$target; then
1367      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1368    fi
1369 fi
1370 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1371 if test x$use_getipinfo = xyes; then
1372    AC_DEFINE(HAVE_GETIPINFO, 1,
1373         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1374 else
1375    echo "The system unwind library does not support _Unwind_GetIPInfo."
1376 fi
1377
1378 # Look for a file containing extra machine modes.
1379 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1380   extra_modes_file='$(srcdir)'/config/${extra_modes}
1381   AC_SUBST(extra_modes_file)
1382   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1383   [Define to the name of a file containing a list of extra machine modes
1384    for this architecture.])
1385 fi
1386
1387 # Convert extra_options into a form suitable for Makefile use.
1388 extra_opt_files=
1389 for f in $extra_options; do
1390   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1391 done
1392 AC_SUBST(extra_opt_files)
1393
1394 # auto-host.h is the file containing items generated by autoconf and is
1395 # the first file included by config.h.
1396 # If host=build, it is correct to have bconfig include auto-host.h
1397 # as well.  If host!=build, we are in error and need to do more
1398 # work to find out the build config parameters.
1399 if test x$host = x$build
1400 then
1401         build_auto=auto-host.h
1402 else
1403         # We create a subdir, then run autoconf in the subdir.
1404         # To prevent recursion we set host and build for the new
1405         # invocation of configure to the build for this invocation
1406         # of configure.
1407         tempdir=build.$$
1408         rm -rf $tempdir
1409         mkdir $tempdir
1410         cd $tempdir
1411         case ${srcdir} in
1412         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1413         *) realsrcdir=../${srcdir};;
1414         esac
1415         saved_CFLAGS="${CFLAGS}"
1416         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1417         ${realsrcdir}/configure \
1418                 --enable-languages=${enable_languages-all} \
1419                 --target=$target_alias --host=$build_alias --build=$build_alias
1420         CFLAGS="${saved_CFLAGS}"
1421
1422         # We just finished tests for the build machine, so rename
1423         # the file auto-build.h in the gcc directory.
1424         mv auto-host.h ../auto-build.h
1425         cd ..
1426         rm -rf $tempdir
1427         build_auto=auto-build.h
1428 fi
1429 AC_SUBST(build_subdir)
1430
1431 tm_file="${tm_file} defaults.h"
1432 tm_p_file="${tm_p_file} tm-preds.h"
1433 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1434 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1435 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1436 # put this back in temporarily.
1437 xm_file="auto-host.h ansidecl.h ${xm_file}"
1438
1439 # --------
1440 # UNSORTED
1441 # --------
1442
1443 changequote(,)dnl
1444 # Compile in configure arguments.
1445 if test -f configargs.h ; then
1446         # Being re-configured.
1447         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1448         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1449 else
1450         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1451 fi
1452
1453 # Double all backslashes and backslash all quotes to turn
1454 # gcc_config_arguments into a C string.
1455 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1456 $gcc_config_arguments
1457 EOF
1458 gcc_config_arguments_str=`cat conftest.out`
1459 rm -f conftest.out
1460
1461 cat > configargs.h <<EOF
1462 /* Generated automatically. */
1463 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1464 static const char thread_model[] = "$thread_file";
1465
1466 static const struct {
1467   const char *name, *value;
1468 } configure_default_options[] = $configure_default_options;
1469 EOF
1470 changequote([,])dnl
1471
1472 # Internationalization
1473 ZW_GNU_GETTEXT_SISTER_DIR
1474
1475 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1476 # -liconv on the link line twice.
1477 case "$LIBINTL" in *$LIBICONV*)
1478         LIBICONV= ;;
1479 esac
1480
1481 AC_ARG_ENABLE(secureplt,
1482 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1483 [], [])
1484
1485 # Windows32 Registry support for specifying GCC installation paths.
1486 AC_ARG_ENABLE(win32-registry,
1487 [  --disable-win32-registry
1488                           disable lookup of installation paths in the
1489                           Registry on Windows hosts
1490   --enable-win32-registry enable registry lookup (default)
1491   --enable-win32-registry=KEY
1492                           use KEY instead of GCC version as the last portion
1493                           of the registry key],,)
1494
1495 case $host_os in
1496   win32 | pe | cygwin* | mingw32* | uwin*)
1497     if test "x$enable_win32_registry" != xno; then
1498       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1499     fi
1500
1501     if test "x$enable_win32_registry" != xno; then
1502       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1503   [Define to 1 if installation paths should be looked up in the Windows
1504    Registry. Ignored on non-Windows hosts.])
1505
1506       if test "x$enable_win32_registry" != xyes \
1507          && test "x$enable_win32_registry" != x; then
1508         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1509   [Define to be the last component of the Windows registry key under which
1510    to look for installation paths.  The full key used will be
1511    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1512    The default is the GCC version number.])
1513       fi
1514     fi
1515   ;;
1516 esac
1517
1518 # Get an absolute path to the GCC top-level source directory
1519 holddir=`${PWDCMD-pwd}`
1520 cd $srcdir
1521 topdir=`${PWDCMD-pwd}`
1522 cd $holddir
1523
1524 # Conditionalize the makefile for this host machine.
1525 xmake_file=
1526 for f in ${host_xmake_file}
1527 do
1528         if test -f ${srcdir}/config/$f
1529         then
1530                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1531         fi
1532 done
1533
1534 # Conditionalize the makefile for this target machine.
1535 tmake_file_=
1536 for f in ${tmake_file}
1537 do
1538         if test -f ${srcdir}/config/$f
1539         then
1540                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1541         fi
1542 done
1543 tmake_file="${tmake_file_}"
1544
1545 # This is a terrible hack which will go away some day.
1546 host_cc_for_libada=${CC}
1547 AC_SUBST(host_cc_for_libada)
1548
1549 out_object_file=`basename $out_file .c`.o
1550
1551 tm_file_list="options.h"
1552 tm_include_list="options.h"
1553 for f in $tm_file; do
1554   case $f in
1555     ./* )
1556        f=`echo $f | sed 's/^..//'`
1557        tm_file_list="${tm_file_list} $f"
1558        tm_include_list="${tm_include_list} $f"
1559        ;;
1560     defaults.h )
1561        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1562        tm_include_list="${tm_include_list} $f"
1563        ;;
1564     * )
1565        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1566        tm_include_list="${tm_include_list} config/$f"
1567        ;;
1568   esac
1569 done
1570
1571 tm_p_file_list=
1572 tm_p_include_list=
1573 for f in $tm_p_file; do
1574   case $f in
1575     tm-preds.h )
1576        tm_p_file_list="${tm_p_file_list} $f"
1577        tm_p_include_list="${tm_p_include_list} $f"
1578        ;;
1579     * )
1580        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1581        tm_p_include_list="${tm_p_include_list} config/$f"
1582   esac
1583 done
1584
1585 xm_file_list=
1586 xm_include_list=
1587 for f in $xm_file; do
1588   case $f in
1589     ansidecl.h )
1590        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1591        xm_include_list="${xm_include_list} $f"
1592        ;;
1593     auto-host.h )
1594        xm_file_list="${xm_file_list} $f"
1595        xm_include_list="${xm_include_list} $f"
1596        ;;
1597     * )
1598        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1599        xm_include_list="${xm_include_list} config/$f"
1600        ;;
1601   esac
1602 done
1603
1604 host_xm_file_list=
1605 host_xm_include_list=
1606 for f in $host_xm_file; do
1607   case $f in
1608     ansidecl.h )
1609        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1610        host_xm_include_list="${host_xm_include_list} $f"
1611        ;;
1612     auto-host.h )
1613        host_xm_file_list="${host_xm_file_list} $f"
1614        host_xm_include_list="${host_xm_include_list} $f"
1615        ;;
1616     * )
1617        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1618        host_xm_include_list="${host_xm_include_list} config/$f"
1619        ;;
1620   esac
1621 done
1622
1623 build_xm_file_list=
1624 for f in $build_xm_file; do
1625   case $f in
1626     ansidecl.h )
1627        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1628        build_xm_include_list="${build_xm_include_list} $f"
1629        ;;
1630     auto-build.h | auto-host.h )
1631        build_xm_file_list="${build_xm_file_list} $f"
1632        build_xm_include_list="${build_xm_include_list} $f"
1633        ;;
1634     * )
1635        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1636        build_xm_include_list="${build_xm_include_list} config/$f"
1637        ;;
1638   esac
1639 done
1640
1641 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1642 # cross-compiler which does not use the native headers and libraries.
1643 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1644 CROSS=                                          AC_SUBST(CROSS)
1645 ALL=all.internal                                AC_SUBST(ALL)
1646 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1647
1648 if test "x$with_build_sysroot" != x; then
1649   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1650 else
1651   # This value is used, even on a native system, because
1652   # CROSS_SYSTEM_HEADER_DIR is just
1653   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1654   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1655 fi
1656
1657 if test x$host != x$target
1658 then
1659         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1660         ALL=all.cross
1661         SYSTEM_HEADER_DIR=$build_system_header_dir
1662         case "$host","$target" in
1663         # Darwin crosses can use the host system's libraries and headers,
1664         # because of the fat library support.  Of course, it must be the
1665         # same version of Darwin on both sides.  Allow the user to
1666         # just say --target=foo-darwin without a version number to mean
1667         # "the version on this system".
1668             *-*-darwin*,*-*-darwin*)
1669                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1670                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1671                 if test $hostos = $targetos -o $targetos = darwin ; then
1672                     CROSS=
1673                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1674                     with_headers=yes
1675                 fi
1676                 ;;
1677
1678             i?86-*-*,x86_64-*-* \
1679             | powerpc*-*-*,powerpc64*-*-*)
1680                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1681         esac
1682 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1683         SYSTEM_HEADER_DIR=$build_system_header_dir
1684 fi
1685
1686 # If this is a cross-compiler that does not
1687 # have its own set of headers then define
1688 # inhibit_libc
1689
1690 # If this is using newlib, without having the headers available now,
1691 # then define inhibit_libc in LIBGCC2_CFLAGS.
1692 # This prevents libgcc2 from containing any code which requires libc
1693 # support.
1694 inhibit_libc=false
1695 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1696        test x$with_newlib = xyes ; } &&
1697      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1698        inhibit_libc=true
1699 fi
1700 AC_SUBST(inhibit_libc)
1701
1702 # When building gcc with a cross-compiler, we need to adjust things so
1703 # that the generator programs are still built with the native compiler.
1704 # Also, we cannot run fixincludes or fix-header.
1705
1706 # These are the normal (build=host) settings:
1707 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1708 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1709 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1710
1711 # Possibly disable fixproto, on a per-target basis.
1712 case ${use_fixproto} in
1713   no)
1714     STMP_FIXPROTO=
1715     ;;
1716   yes)
1717     STMP_FIXPROTO=stmp-fixproto
1718     ;;
1719 esac
1720 AC_SUBST(STMP_FIXPROTO)
1721
1722 # And these apply if build != host, or we are generating coverage data
1723 if test x$build != x$host || test "x$coverage_flags" != x
1724 then
1725     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1726
1727     if test "x$TARGET_SYSTEM_ROOT" = x; then
1728         if test "x$STMP_FIXPROTO" != x; then
1729           STMP_FIXPROTO=stmp-install-fixproto
1730         fi
1731     fi
1732 fi
1733
1734 # Expand extra_headers to include complete path.
1735 # This substitutes for lots of t-* files.
1736 extra_headers_list=
1737 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1738 for file in ${extra_headers} ; do
1739   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1740 done
1741
1742 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1743 if test x"$use_gcc_tgmath" = xyes
1744 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1745 fi
1746
1747 # Define collect2 in Makefile.
1748 case $host_can_use_collect2 in
1749   no) collect2= ;;
1750   *) collect2='collect2$(exeext)' ;;
1751 esac
1752 AC_SUBST([collect2])
1753
1754 # Add a definition of USE_COLLECT2 if system wants one.
1755 case $use_collect2 in
1756   no) use_collect2= ;;
1757   "") ;;
1758   *)
1759     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1760     xm_defines="${xm_defines} USE_COLLECT2"
1761     case $host_can_use_collect2 in
1762       no)
1763         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1764         ;;
1765     esac
1766     ;;
1767 esac
1768
1769 # ---------------------------
1770 # Assembler & linker features
1771 # ---------------------------
1772
1773 # Identify the assembler which will work hand-in-glove with the newly
1774 # built GCC, so that we can examine its features.  This is the assembler
1775 # which will be driven by the driver program.
1776 #
1777 # If build != host, and we aren't building gas in-tree, we identify a
1778 # build->target assembler and hope that it will have the same features
1779 # as the host->target assembler we'll be using.
1780 gcc_cv_gas_major_version=
1781 gcc_cv_gas_minor_version=
1782 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1783
1784 m4_pattern_allow([AS_FOR_TARGET])dnl
1785 AS_VAR_SET_IF(gcc_cv_as,, [
1786 if test -x "$DEFAULT_ASSEMBLER"; then
1787         gcc_cv_as="$DEFAULT_ASSEMBLER"
1788 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1789      && test -f ../gas/Makefile \
1790      && test x$build = x$host; then
1791         gcc_cv_as=../gas/as-new$build_exeext
1792 elif test -x as$build_exeext; then
1793         # Build using assembler in the current directory.
1794         gcc_cv_as=./as$build_exeext
1795 elif test -x $AS_FOR_TARGET; then
1796         gcc_cv_as="$AS_FOR_TARGET"
1797 else
1798         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1799 fi])
1800
1801 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1802 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1803 case "$ORIGINAL_AS_FOR_TARGET" in
1804   ./as | ./as$build_exeext) ;;
1805   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1806 esac
1807
1808 AC_MSG_CHECKING(what assembler to use)
1809 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1810   # Single tree build which includes gas.  We want to prefer it
1811   # over whatever linker top-level may have detected, since
1812   # we'll use what we're building after installation anyway.
1813   AC_MSG_RESULT(newly built gas)
1814   in_tree_gas=yes
1815   _gcc_COMPUTE_GAS_VERSION
1816   in_tree_gas_is_elf=no
1817   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1818      || (grep 'obj_format = multi' ../gas/Makefile \
1819          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1820   then
1821     in_tree_gas_is_elf=yes
1822   fi
1823 else
1824   AC_MSG_RESULT($gcc_cv_as)
1825   in_tree_gas=no
1826 fi
1827
1828 # Identify the linker which will work hand-in-glove with the newly
1829 # built GCC, so that we can examine its features.  This is the linker
1830 # which will be driven by the driver program.
1831 #
1832 # If build != host, and we aren't building gas in-tree, we identify a
1833 # build->target linker and hope that it will have the same features
1834 # as the host->target linker we'll be using.
1835 gcc_cv_gld_major_version=
1836 gcc_cv_gld_minor_version=
1837 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1838 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1839
1840 AS_VAR_SET_IF(gcc_cv_ld,, [
1841 if test -x "$DEFAULT_LINKER"; then
1842         gcc_cv_ld="$DEFAULT_LINKER"
1843 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1844      && test -f ../ld/Makefile \
1845      && test x$build = x$host; then
1846         gcc_cv_ld=../ld/ld-new$build_exeext
1847 elif test -x collect-ld$build_exeext; then
1848         # Build using linker in the current directory.
1849         gcc_cv_ld=./collect-ld$build_exeext
1850 elif test -x $LD_FOR_TARGET; then
1851         gcc_cv_ld="$LD_FOR_TARGET"
1852 else
1853         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1854 fi])
1855
1856 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1857 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1858 case "$ORIGINAL_LD_FOR_TARGET" in
1859   ./collect-ld | ./collect-ld$build_exeext) ;;
1860   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1861 esac
1862
1863 AC_MSG_CHECKING(what linker to use)
1864 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1865         # Single tree build which includes ld.  We want to prefer it
1866         # over whatever linker top-level may have detected, since
1867         # we'll use what we're building after installation anyway.
1868         AC_MSG_RESULT(newly built ld)
1869         in_tree_ld=yes
1870         in_tree_ld_is_elf=no
1871         if (grep 'EMUL = .*elf' ../ld/Makefile \
1872             || grep 'EMUL = .*linux' ../ld/Makefile \
1873             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1874           in_tree_ld_is_elf=yes
1875         fi
1876         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1877         do
1878 changequote(,)dnl
1879                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1880                 if test x$gcc_cv_gld_version != x; then
1881                         break
1882                 fi
1883         done
1884         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1885         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1886 changequote([,])dnl
1887 else
1888         AC_MSG_RESULT($gcc_cv_ld)
1889         in_tree_ld=no
1890 fi
1891
1892 # Figure out what nm we will be using.
1893 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1894 AS_VAR_SET_IF(gcc_cv_nm,, [
1895 if test -f $gcc_cv_binutils_srcdir/configure.in \
1896      && test -f ../binutils/Makefile \
1897      && test x$build = x$host; then
1898         gcc_cv_nm=../binutils/nm-new$build_exeext
1899 elif test -x nm$build_exeext; then
1900         gcc_cv_nm=./nm$build_exeext
1901 elif test -x $NM_FOR_TARGET; then
1902         gcc_cv_nm="$NM_FOR_TARGET"
1903 else
1904         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1905 fi])
1906
1907 AC_MSG_CHECKING(what nm to use)
1908 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1909         # Single tree build which includes binutils.
1910         AC_MSG_RESULT(newly built nm)
1911         in_tree_nm=yes
1912 else
1913         AC_MSG_RESULT($gcc_cv_nm)
1914         in_tree_nm=no
1915 fi
1916
1917 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1918 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1919 case "$ORIGINAL_NM_FOR_TARGET" in
1920   ./nm | ./nm$build_exeext) ;;
1921   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
1922 esac
1923
1924
1925 # Figure out what objdump we will be using.
1926 AS_VAR_SET_IF(gcc_cv_objdump,, [
1927 if test -f $gcc_cv_binutils_srcdir/configure.in \
1928      && test -f ../binutils/Makefile \
1929      && test x$build = x$host; then
1930         # Single tree build which includes binutils.
1931         gcc_cv_objdump=../binutils/objdump$build_exeext
1932 elif test -x objdump$build_exeext; then
1933         gcc_cv_objdump=./objdump$build_exeext
1934 elif test -x $OBJDUMP_FOR_TARGET; then
1935         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
1936 else
1937         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
1938 fi])
1939
1940 AC_MSG_CHECKING(what objdump to use)
1941 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
1942         # Single tree build which includes binutils.
1943         AC_MSG_RESULT(newly built objdump)
1944 elif test x$gcc_cv_objdump = x; then
1945         AC_MSG_RESULT(not found)
1946 else
1947         AC_MSG_RESULT($gcc_cv_objdump)
1948 fi
1949
1950 # Figure out what assembler alignment features are present.
1951 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
1952  [2,6,0],,
1953 [.balign 4
1954 .p2align 2],,
1955 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
1956   [Define if your assembler supports .balign and .p2align.])])
1957
1958 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
1959  [2,8,0],,
1960  [.p2align 4,,7],,
1961 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
1962   [Define if your assembler supports specifying the maximum number
1963    of bytes to skip when using the GAS .p2align command.])])
1964
1965 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
1966  [2,8,0],,
1967  [.literal16],,
1968 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
1969   [Define if your assembler supports .literal16.])])
1970
1971 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
1972  [elf,2,9,0],,
1973  [conftest_label1: .word 0
1974 .subsection -1
1975 conftest_label2: .word 0
1976 .previous],
1977  [if test x$gcc_cv_nm != x; then
1978     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
1979     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
1980     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
1981     then :
1982     else gcc_cv_as_subsection_m1=yes
1983     fi
1984     rm -f conftest.nm1 conftest.nm2
1985   fi],
1986  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
1987   [Define if your assembler supports .subsection and .subsection -1 starts
1988    emitting at the beginning of your section.])])
1989
1990 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
1991  [2,2,0],,
1992  [      .weak foobar],,
1993 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
1994
1995 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
1996  [2,17,0],,
1997  [      .weakref foobar, barfnot],,
1998 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
1999
2000 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2001  [2,15,91],,
2002  [      .SPACE $TEXT$
2003         .NSUBSPA $CODE$,COMDAT],,
2004 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2005
2006 # .hidden needs to be supported in both the assembler and the linker,
2007 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2008 # This is irritatingly difficult to feature test for; we have to check the
2009 # date string after the version number.  If we've got an in-tree
2010 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2011 # to be safe.
2012 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2013 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2014  [elf,2,13,0],,
2015 [       .hidden foobar
2016 foobar:])
2017
2018 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2019 [if test $in_tree_ld = yes ; then
2020   gcc_cv_ld_hidden=no
2021   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2022      && test $in_tree_ld_is_elf = yes; then
2023      gcc_cv_ld_hidden=yes
2024   fi
2025 else
2026   gcc_cv_ld_hidden=yes
2027   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2028   if echo "$ld_ver" | grep GNU > /dev/null; then
2029 changequote(,)dnl
2030     ld_vers=`echo $ld_ver | sed -n \
2031         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2032         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2033         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2034         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2035         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2036         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2037         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   -].*$,\1,p'`
2038     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2039     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2040     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2041     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2042     if test 0"$ld_date" -lt 20020404; then
2043       if test -n "$ld_date"; then
2044         # If there was date string, but was earlier than 2002-04-04, fail
2045         gcc_cv_ld_hidden=no
2046       elif test -z "$ld_vers"; then
2047         # If there was no date string nor ld version number, something is wrong
2048         gcc_cv_ld_hidden=no
2049       else
2050         test -z "$ld_vers_patch" && ld_vers_patch=0
2051         if test "$ld_vers_major" -lt 2; then
2052           gcc_cv_ld_hidden=no
2053         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2054           gcc_cv_ld_hidden="no"
2055         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2056           gcc_cv_ld_hidden=no
2057         fi
2058       fi
2059 changequote([,])dnl
2060     fi
2061   else
2062     case "${target}" in
2063       hppa64*-*-hpux* | ia64*-*-hpux*)
2064         gcc_cv_ld_hidden=yes
2065         ;;
2066       *)
2067         gcc_cv_ld_hidden=no
2068         ;;
2069     esac
2070   fi
2071 fi])
2072 libgcc_visibility=no
2073 AC_SUBST(libgcc_visibility)
2074 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2075 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2076   libgcc_visibility=yes
2077   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2078   [Define if your assembler and linker support .hidden.])
2079 fi
2080
2081 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2082 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2083   [elf,2,11,0],,
2084 [       .data
2085         .uleb128 L2 - L1
2086 L1:
2087         .uleb128 1280
2088         .sleb128 -1010
2089 L2:],
2090  [# GAS versions before 2.11 do not support uleb128,
2091   # despite appearing to.
2092   # ??? There exists an elf-specific test that will crash
2093   # the assembler.  Perhaps it's better to figure out whether
2094   # arbitrary sections are supported and try the test.
2095   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2096   if echo "$as_ver" | grep GNU > /dev/null; then
2097 changequote(,)dnl
2098     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2099     as_major=`echo $as_ver | sed 's/\..*//'`
2100     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2101 changequote([,])dnl
2102     if test $as_major -eq 2 && test $as_minor -lt 11
2103     then :
2104     else gcc_cv_as_leb128=yes
2105     fi
2106   fi],
2107   [AC_DEFINE(HAVE_AS_LEB128, 1,
2108     [Define if your assembler supports .sleb128 and .uleb128.])])
2109
2110 # GAS versions up to and including 2.11.0 may mis-optimize
2111 # .eh_frame data.
2112 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2113   [elf,2,12,0],,
2114 [       .text
2115 .LFB1:
2116         .4byte  0
2117 .L1:
2118         .4byte  0
2119 .LFE1:
2120         .section        .eh_frame,"aw",@progbits
2121 __FRAME_BEGIN__:
2122         .4byte  .LECIE1-.LSCIE1
2123 .LSCIE1:
2124         .4byte  0x0
2125         .byte   0x1
2126         .ascii "z\0"
2127         .byte   0x1
2128         .byte   0x78
2129         .byte   0x1a
2130         .byte   0x0
2131         .byte   0x4
2132         .4byte  1
2133         .p2align 1
2134 .LECIE1:
2135 .LSFDE1:
2136         .4byte  .LEFDE1-.LASFDE1
2137 .LASFDE1:
2138         .4byte  .LASFDE1-__FRAME_BEGIN__
2139         .4byte  .LFB1
2140         .4byte  .LFE1-.LFB1
2141         .byte   0x4
2142         .4byte  .LFE1-.LFB1
2143         .byte   0x4
2144         .4byte  .L1-.LFB1
2145 .LEFDE1:],
2146 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2147 cat > conftest.lit <<EOF
2148  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2149  0010 01000000 12000000 18000000 00000000  ................
2150  0020 08000000 04080000 0044               .........D      @&t@
2151 EOF
2152 cat > conftest.big <<EOF
2153  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2154  0010 00000001 00000012 00000018 00000000  ................
2155  0020 00000008 04000000 0844               .........D      @&t@
2156 EOF
2157   # If the assembler didn't choke, and we can objdump,
2158   # and we got the correct data, then succeed.
2159   # The text in the here-document typically retains its unix-style line
2160   # endings, while the output of objdump will use host line endings.
2161   # Therefore, use diff -b for the comparisons.
2162   if test x$gcc_cv_objdump != x \
2163   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2164      | tail -3 > conftest.got \
2165   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2166     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2167   then
2168     gcc_cv_as_eh_frame=yes
2169   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2170     gcc_cv_as_eh_frame=buggy
2171   else
2172     # Uh oh, what do we do now?
2173     gcc_cv_as_eh_frame=no
2174   fi])
2175
2176 if test $gcc_cv_as_eh_frame = buggy; then
2177   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2178   [Define if your assembler mis-optimizes .eh_frame data.])
2179 fi
2180
2181 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2182  [elf,2,12,0], [--fatal-warnings],
2183  [.section .rodata.str, "aMS", @progbits, 1])
2184 if test $gcc_cv_as_shf_merge = no; then
2185   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2186     [elf,2,12,0], [--fatal-warnings],
2187     [.section .rodata.str, "aMS", %progbits, 1])
2188 fi
2189 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2190   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2191 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2192
2193 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2194  [elf,2,16,0], [--fatal-warnings],
2195  [.section .text,"axG",@progbits,.foo,comdat])
2196 if test $gcc_cv_as_comdat_group = yes; then
2197   gcc_cv_as_comdat_group_percent=no
2198 else
2199  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2200    [elf,2,16,0], [--fatal-warnings],
2201    [.section .text,"axG",%progbits,.foo,comdat])
2202 fi
2203 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2204   comdat_group=yes
2205   if test 0"$ld_date" -lt 20050308; then
2206     if test -n "$ld_date"; then
2207       # If there was date string, but was earlier than 2005-03-08, fail
2208       comdat_group=no
2209     elif test "$ld_vers_major" -lt 2; then
2210       comdat_group=no
2211     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2212       comdat_group=no
2213     fi
2214   fi
2215 else
2216   # assume linkers other than GNU ld don't support COMDAT group
2217   comdat_group=no
2218 fi
2219 if test $comdat_group = no; then
2220   gcc_cv_as_comdat_group=no
2221   gcc_cv_as_comdat_group_percent=no
2222 fi
2223 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2224   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2225 [Define 0/1 if your assembler and linker support COMDAT groups.])
2226
2227 # Thread-local storage - the check is heavily parametrized.
2228 conftest_s=
2229 tls_first_major=
2230 tls_first_minor=
2231 tls_as_opt=
2232 case "$target" in
2233 changequote(,)dnl
2234   alpha*-*-*)
2235     conftest_s='
2236         .section ".tdata","awT",@progbits
2237 foo:    .long   25
2238         .text
2239         ldq     $27,__tls_get_addr($29)         !literal!1
2240         lda     $16,foo($29)                    !tlsgd!1
2241         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2242         ldq     $27,__tls_get_addr($29)         !literal!2
2243         lda     $16,foo($29)                    !tlsldm!2
2244         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2245         ldq     $1,foo($29)                     !gotdtprel
2246         ldah    $2,foo($29)                     !dtprelhi
2247         lda     $3,foo($2)                      !dtprello
2248         lda     $4,foo($29)                     !dtprel
2249         ldq     $1,foo($29)                     !gottprel
2250         ldah    $2,foo($29)                     !tprelhi
2251         lda     $3,foo($2)                      !tprello
2252         lda     $4,foo($29)                     !tprel'
2253         tls_first_major=2
2254         tls_first_minor=13
2255         tls_as_opt=--fatal-warnings
2256         ;;
2257   frv*-*-*)
2258     conftest_s='
2259         .section ".tdata","awT",@progbits
2260 x:      .long   25
2261         .text
2262         call    #gettlsoff(x)'
2263         tls_first_major=2
2264         tls_first_minor=14
2265         ;;
2266   hppa*-*-linux*)
2267     conftest_s='
2268 t1:     .reg    %r20
2269 t2:     .reg    %r21
2270 gp:     .reg    %r19
2271         .section ".tdata","awT",@progbits
2272 foo:    .long   25
2273         .text
2274         .align  4
2275         addil LT%foo-$tls_gdidx$,gp
2276         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2277         b __tls_get_addr
2278         nop
2279         addil LT%foo-$tls_ldidx$,gp
2280         b __tls_get_addr
2281         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2282         addil LR%foo-$tls_dtpoff$,%ret0
2283         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2284         mfctl %cr27,%t1
2285         addil LT%foo-$tls_ieoff$,gp
2286         ldw RT%foo-$tls_ieoff$(%r1),%t2
2287         add %t1,%t2,%t3
2288         mfctl %cr27,%t1
2289         addil LR%foo-$tls_leoff$,%t1
2290         ldo RR%foo-$tls_leoff$(%r1),%t2'
2291         tls_first_major=2
2292         tls_first_minor=15
2293         tls_as_opt=--fatal-warnings
2294         ;;
2295   arm*-*-*)
2296     conftest_s='
2297         .section ".tdata","awT",%progbits
2298 foo:    .long   25
2299         .text
2300 .word foo(gottpoff)
2301 .word foo(tpoff)
2302 .word foo(tlsgd)
2303 .word foo(tlsldm)
2304 .word foo(tlsldo)'
2305         tls_first_major=2
2306         tls_first_minor=17
2307         ;;
2308   i[34567]86-*-*)
2309     conftest_s='
2310         .section ".tdata","awT",@progbits
2311 foo:    .long   25
2312         .text
2313         movl    %gs:0, %eax
2314         leal    foo@TLSGD(,%ebx,1), %eax
2315         leal    foo@TLSLDM(%ebx), %eax
2316         leal    foo@DTPOFF(%eax), %edx
2317         movl    foo@GOTTPOFF(%ebx), %eax
2318         subl    foo@GOTTPOFF(%ebx), %eax
2319         addl    foo@GOTNTPOFF(%ebx), %eax
2320         movl    foo@INDNTPOFF, %eax
2321         movl    $foo@TPOFF, %eax
2322         subl    $foo@TPOFF, %eax
2323         leal    foo@NTPOFF(%ecx), %eax'
2324         tls_first_major=2
2325         tls_first_minor=14
2326         tls_as_opt=--fatal-warnings
2327         ;;
2328   x86_64-*-*)
2329     conftest_s='
2330         .section ".tdata","awT",@progbits
2331 foo:    .long   25
2332         .text
2333         movq    %fs:0, %rax
2334         leaq    foo@TLSGD(%rip), %rdi
2335         leaq    foo@TLSLD(%rip), %rdi
2336         leaq    foo@DTPOFF(%rax), %rdx
2337         movq    foo@GOTTPOFF(%rip), %rax
2338         movq    $foo@TPOFF, %rax'
2339         tls_first_major=2
2340         tls_first_minor=14
2341         tls_as_opt=--fatal-warnings
2342         ;;
2343   ia64-*-*)
2344     conftest_s='
2345         .section ".tdata","awT",@progbits
2346 foo:    data8   25
2347         .text
2348         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2349         addl    r17 = @ltoff(@dtprel(foo#)), gp
2350         addl    r18 = @ltoff(@tprel(foo#)), gp
2351         addl    r19 = @dtprel(foo#), gp
2352         adds    r21 = @dtprel(foo#), r13
2353         movl    r23 = @dtprel(foo#)
2354         addl    r20 = @tprel(foo#), gp
2355         adds    r22 = @tprel(foo#), r13
2356         movl    r24 = @tprel(foo#)'
2357         tls_first_major=2
2358         tls_first_minor=13
2359         tls_as_opt=--fatal-warnings
2360         ;;
2361   mips*-*-*)
2362     conftest_s='
2363         .section .tdata,"awT",@progbits
2364 x:
2365         .word 2
2366         .text
2367         addiu $4, $28, %tlsgd(x)
2368         addiu $4, $28, %tlsldm(x)
2369         lui $4, %dtprel_hi(x)
2370         addiu $4, $4, %dtprel_lo(x)
2371         lw $4, %gottprel(x)($28)
2372         lui $4, %tprel_hi(x)
2373         addiu $4, $4, %tprel_lo(x)'
2374         tls_first_major=2
2375         tls_first_minor=16
2376         tls_as_opt='-32 --fatal-warnings'
2377         ;;
2378   powerpc-*-*)
2379     conftest_s='
2380         .section ".tdata","awT",@progbits
2381         .align 2
2382 ld0:    .space 4
2383 ld1:    .space 4
2384 x1:     .space 4
2385 x2:     .space 4
2386 x3:     .space 4
2387         .text
2388         addi 3,31,ld0@got@tlsgd
2389         bl __tls_get_addr
2390         addi 3,31,x1@got@tlsld
2391         bl __tls_get_addr
2392         addi 9,3,x1@dtprel
2393         addis 9,3,x2@dtprel@ha
2394         addi 9,9,x2@dtprel@l
2395         lwz 9,x3@got@tprel(31)
2396         add 9,9,x@tls
2397         addi 9,2,x1@tprel
2398         addis 9,2,x2@tprel@ha
2399         addi 9,9,x2@tprel@l'
2400         tls_first_major=2
2401         tls_first_minor=14
2402         tls_as_opt="-a32 --fatal-warnings"
2403         ;;
2404   powerpc64-*-*)
2405     conftest_s='
2406         .section ".tdata","awT",@progbits
2407         .align 3
2408 ld0:    .space 8
2409 ld1:    .space 8
2410 x1:     .space 8
2411 x2:     .space 8
2412 x3:     .space 8
2413         .text
2414         addi 3,2,ld0@got@tlsgd
2415         bl .__tls_get_addr
2416         nop
2417         addi 3,2,ld1@toc
2418         bl .__tls_get_addr
2419         nop
2420         addi 3,2,x1@got@tlsld
2421         bl .__tls_get_addr
2422         nop
2423         addi 9,3,x1@dtprel
2424         bl .__tls_get_addr
2425         nop
2426         addis 9,3,x2@dtprel@ha
2427         addi 9,9,x2@dtprel@l
2428         bl .__tls_get_addr
2429         nop
2430         ld 9,x3@got@dtprel(2)
2431         add 9,9,3
2432         bl .__tls_get_addr
2433         nop'
2434         tls_first_major=2
2435         tls_first_minor=14
2436         tls_as_opt="-a64 --fatal-warnings"
2437         ;;
2438   s390-*-*)
2439     conftest_s='
2440         .section ".tdata","awT",@progbits
2441 foo:    .long   25
2442         .text
2443         .long   foo@TLSGD
2444         .long   foo@TLSLDM
2445         .long   foo@DTPOFF
2446         .long   foo@NTPOFF
2447         .long   foo@GOTNTPOFF
2448         .long   foo@INDNTPOFF
2449         l       %r1,foo@GOTNTPOFF(%r12)
2450         l       %r1,0(%r1):tls_load:foo
2451         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2452         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2453         tls_first_major=2
2454         tls_first_minor=14
2455         tls_as_opt="-m31 --fatal-warnings"
2456         ;;
2457   s390x-*-*)
2458     conftest_s='
2459         .section ".tdata","awT",@progbits
2460 foo:    .long   25
2461         .text
2462         .quad   foo@TLSGD
2463         .quad   foo@TLSLDM
2464         .quad   foo@DTPOFF
2465         .quad   foo@NTPOFF
2466         .quad   foo@GOTNTPOFF
2467         lg      %r1,foo@GOTNTPOFF(%r12)
2468         larl    %r1,foo@INDNTPOFF
2469         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2470         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2471         tls_first_major=2
2472         tls_first_minor=14
2473         tls_as_opt="-m64 -Aesame --fatal-warnings"
2474         ;;
2475   sh-*-* | sh[34]-*-*)
2476     conftest_s='
2477         .section ".tdata","awT",@progbits
2478 foo:    .long   25
2479         .text
2480         .long   foo@TLSGD
2481         .long   foo@TLSLDM
2482         .long   foo@DTPOFF
2483         .long   foo@GOTTPOFF
2484         .long   foo@TPOFF'
2485         tls_first_major=2
2486         tls_first_minor=13
2487         tls_as_opt=--fatal-warnings
2488         ;;
2489   sparc*-*-*)
2490     case "$target" in
2491       sparc*-sun-solaris2.[56789]*)
2492         # TLS was introduced in the Solaris 9 4/04 release but
2493         # we do not enable it by default on Solaris 9 either.
2494         if test "x$enable_tls" = xyes ; then
2495           on_solaris=yes
2496         else
2497           enable_tls=no;
2498         fi
2499         ;;
2500       sparc*-sun-solaris2.*)
2501         on_solaris=yes
2502         ;;
2503       *)
2504         on_solaris=no
2505         ;;
2506     esac
2507     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2508       conftest_s='
2509         .section ".tdata",#alloc,#write,#tls
2510 foo:    .long   25
2511         .text
2512         sethi   %tgd_hi22(foo), %o0
2513         add     %o0, %tgd_lo10(foo), %o1
2514         add     %l7, %o1, %o0, %tgd_add(foo)
2515         call    __tls_get_addr, %tgd_call(foo)
2516         sethi   %tldm_hi22(foo), %l1
2517         add     %l1, %tldm_lo10(foo), %l2
2518         add     %l7, %l2, %o0, %tldm_add(foo)
2519         call    __tls_get_addr, %tldm_call(foo)
2520         sethi   %tldo_hix22(foo), %l3
2521         xor     %l3, %tldo_lox10(foo), %l4
2522         add     %o0, %l4, %l5, %tldo_add(foo)
2523         sethi   %tie_hi22(foo), %o3
2524         add     %o3, %tie_lo10(foo), %o3
2525         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2526         add     %g7, %o2, %o4, %tie_add(foo)
2527         sethi   %tle_hix22(foo), %l1
2528         xor     %l1, %tle_lox10(foo), %o5
2529         ld      [%g7 + %o5], %o1'
2530         tls_first_major=0
2531         tls_first_minor=0
2532     else
2533       conftest_s='
2534         .section ".tdata","awT",@progbits
2535 foo:    .long   25
2536         .text
2537         sethi   %tgd_hi22(foo), %o0
2538         add     %o0, %tgd_lo10(foo), %o1
2539         add     %l7, %o1, %o0, %tgd_add(foo)
2540         call    __tls_get_addr, %tgd_call(foo)
2541         sethi   %tldm_hi22(foo), %l1
2542         add     %l1, %tldm_lo10(foo), %l2
2543         add     %l7, %l2, %o0, %tldm_add(foo)
2544         call    __tls_get_addr, %tldm_call(foo)
2545         sethi   %tldo_hix22(foo), %l3
2546         xor     %l3, %tldo_lox10(foo), %l4
2547         add     %o0, %l4, %l5, %tldo_add(foo)
2548         sethi   %tie_hi22(foo), %o3
2549         add     %o3, %tie_lo10(foo), %o3
2550         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2551         add     %g7, %o2, %o4, %tie_add(foo)
2552         sethi   %tle_hix22(foo), %l1
2553         xor     %l1, %tle_lox10(foo), %o5
2554         ld      [%g7 + %o5], %o1'
2555         tls_first_major=2
2556         tls_first_minor=14
2557         tls_as_opt="-32 --fatal-warnings"
2558       fi
2559         ;;
2560 changequote([,])dnl
2561 esac
2562 set_have_as_tls=no
2563 if test "x$enable_tls" = xno ; then
2564   : # TLS explicitly disabled.
2565 elif test "x$enable_tls" = xyes ; then
2566   set_have_as_tls=yes # TLS explicitly enabled.
2567 elif test -z "$tls_first_major"; then
2568   : # If we don't have a check, assume no support.
2569 else
2570   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2571   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2572   [set_have_as_tls=yes])
2573 fi
2574 if test $set_have_as_tls = yes ; then
2575   AC_DEFINE(HAVE_AS_TLS, 1,
2576             [Define if your assembler supports thread-local storage.])
2577 fi
2578
2579 # Target-specific assembler checks.
2580
2581 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2582 gcc_cv_ld_static_dynamic=no
2583 if test $in_tree_ld = yes ; then
2584   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2585     gcc_cv_ld_static_dynamic=yes
2586   fi
2587 elif test x$gcc_cv_ld != x; then
2588         # Check if linker supports -Bstatic/-Bdynamic option
2589         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2590           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2591                 gcc_cv_ld_static_dynamic=yes
2592         fi
2593 fi
2594 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2595         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2596 [Define if your linker supports -Bstatic/-Bdynamic option.])
2597 fi
2598 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2599
2600 if test x"$demangler_in_ld" = xyes; then
2601   AC_MSG_CHECKING(linker --demangle support)
2602   gcc_cv_ld_demangle=no
2603   if test $in_tree_ld = yes; then
2604     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2605       gcc_cv_ld_demangle=yes
2606     fi
2607   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2608     # Check if the GNU linker supports --demangle option
2609     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2610       gcc_cv_ld_demangle=yes
2611     fi
2612   fi
2613   if test x"$gcc_cv_ld_demangle" = xyes; then
2614     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2615 [Define if your linker supports --demangle option.])
2616   fi
2617   AC_MSG_RESULT($gcc_cv_ld_demangle)
2618 fi
2619
2620 case "$target" in
2621   # All TARGET_ABI_OSF targets.
2622   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2623     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2624         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2625 [       .set nomacro
2626         .text
2627         extbl   $3, $2, $3      !lituse_bytoff!1
2628         ldq     $2, a($29)      !literal!1
2629         ldq     $4, b($29)      !literal!2
2630         ldq_u   $3, 0($2)       !lituse_base!1
2631         ldq     $27, f($29)     !literal!5
2632         jsr     $26, ($27), f   !lituse_jsr!5
2633         ldah    $29, 0($26)     !gpdisp!3
2634         lda     $0, c($29)      !gprel
2635         ldah    $1, d($29)      !gprelhigh
2636         lda     $1, d($1)       !gprellow
2637         lda     $29, 0($29)     !gpdisp!3],,
2638     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2639   [Define if your assembler supports explicit relocations.])])
2640     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2641         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2642 [       .set nomacro
2643         .text
2644         ldq     $27, a($29)     !literal!1
2645         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2646     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2647   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2648     ;;
2649
2650   cris-*-*)
2651     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2652       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2653       [-no-mul-bug-abort], [.text],,
2654       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2655                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2656     ;;
2657
2658   sparc*-*-*)
2659     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2660       [.register %g2, #scratch],,
2661       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2662                 [Define if your assembler supports .register.])])
2663
2664     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2665       [-relax], [.text],,
2666       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2667                 [Define if your assembler supports -relax option.])])
2668
2669     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2670       gcc_cv_as_sparc_ua_pcrel,,
2671       [-K PIC],
2672 [.text
2673 foo:
2674         nop
2675 .data
2676 .align 4
2677 .byte 0
2678 .uaword %r_disp32(foo)],
2679       [if test x$gcc_cv_ld != x \
2680        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2681          gcc_cv_as_sparc_ua_pcrel=yes
2682        fi
2683        rm -f conftest],
2684       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2685                 [Define if your assembler and linker support unaligned PC relative relocs.])
2686
2687       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2688         gcc_cv_as_sparc_ua_pcrel_hidden,,
2689         [-K PIC],
2690 [.data
2691 .align 4
2692 .byte 0x31
2693 .uaword %r_disp32(foo)
2694 .byte 0x32, 0x33, 0x34
2695 .global foo
2696 .hidden foo
2697 foo:
2698 .skip 4],
2699         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2700          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2701          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2702             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2703             if $gcc_cv_objdump -R conftest 2> /dev/null \
2704                | grep 'DISP32' > /dev/null 2>&1; then
2705                 :
2706             else
2707                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2708             fi
2709          fi
2710          rm -f conftest],
2711          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2712                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2713     ]) # unaligned pcrel relocs
2714
2715     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2716       gcc_cv_as_sparc_offsetable_lo10,,
2717       [-xarch=v9],
2718 [.text
2719         or %g1, %lo(ab) + 12, %g1
2720         or %g1, %lo(ab + 12), %g1],
2721       [if test x$gcc_cv_objdump != x \
2722        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2723           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2724          gcc_cv_as_sparc_offsetable_lo10=yes
2725        fi],
2726        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2727                  [Define if your assembler supports offsetable %lo().])])
2728     ;;
2729
2730 changequote(,)dnl
2731   i[34567]86-*-* | x86_64-*-*)
2732 changequote([,])dnl
2733     case $target_os in
2734       cygwin* | pe | mingw32*)
2735         # Used for DWARF 2 in PE
2736         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2737           gcc_cv_as_ix86_pe_secrel32,
2738           [2,15,91],,
2739 [.text
2740 foo:    nop
2741 .data
2742         .secrel32 foo],
2743           [if test x$gcc_cv_ld != x \
2744            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2745              gcc_cv_as_ix86_pe_secrel32=yes
2746            fi
2747            rm -f conftest],
2748           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2749             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2750         ;;
2751     esac
2752
2753     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2754        gcc_cv_as_ix86_filds_fists,
2755       [2,9,0],, [filds mem; fists mem],,
2756       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2757         [Define if your assembler uses the new HImode fild and fist notation.])])
2758
2759     gcc_GAS_CHECK_FEATURE([cmov syntax],
2760       gcc_cv_as_ix86_cmov_sun_syntax,,,
2761       [cmovl.l %edx, %eax],,
2762       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2763         [Define if your assembler supports the Sun syntax for cmov.])])
2764
2765     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2766       gcc_cv_as_ix86_ffreep,,,
2767       [ffreep %st(1)],,
2768       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2769         [Define if your assembler supports the ffreep mnemonic.])])
2770
2771     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2772       gcc_cv_as_ix86_sahf,,,
2773       [sahf],,
2774       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2775         [Define if your assembler supports the sahf mnemonic.])])
2776
2777     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2778       gcc_cv_as_ix86_diff_sect_delta,,,
2779       [.section .rodata
2780 .L1:
2781         .long .L2-.L1
2782         .long .L3-.L1
2783         .text
2784 .L3:    nop
2785 .L2:    nop],,
2786       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2787         [Define if your assembler supports the subtraction of symbols in different sections.])])
2788
2789     # This one is used unconditionally by i386.[ch]; it is to be defined
2790     # to 1 if the feature is present, 0 otherwise.
2791     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2792         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2793 [       .text
2794 .L0:
2795         nop
2796         .data
2797         .long .L0@GOTOFF])
2798     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2799       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2800       [Define true if the assembler supports '.long foo@GOTOFF'.])
2801     ;;
2802
2803   ia64*-*-*)
2804     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2805         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2806 [       .text
2807         addl r15 = @ltoffx(x#), gp
2808         ;;
2809         ld8.mov r16 = [[r15]], x#],,
2810     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2811           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2812
2813     ;;
2814
2815   powerpc*-*-*)
2816     case $target in
2817       *-*-aix*) conftest_s='    .machine "pwr5"
2818         .csect .text[[PR]]
2819         mfcr 3,128';;
2820       *-*-darwin*)
2821         gcc_GAS_CHECK_FEATURE([.machine directive support],
2822           gcc_cv_as_machine_directive,,,
2823           [     .machine ppc7400])
2824         if test x$gcc_cv_as_machine_directive != xyes; then
2825           echo "*** This target requires an assembler supporting \".machine\"" >&2
2826           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2827           test x$build = x$target && exit 1
2828         fi
2829         conftest_s='    .text
2830         mfcr r3,128';;
2831       *) conftest_s='   .machine power4
2832         .text
2833         mfcr 3,128';;
2834     esac
2835
2836     gcc_GAS_CHECK_FEATURE([mfcr field support],
2837       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2838       [$conftest_s],,
2839       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2840           [Define if your assembler supports mfcr field.])])
2841
2842     case $target in
2843       *-*-aix*) conftest_s='    .machine "pwr5"
2844         .csect .text[[PR]]
2845         popcntb 3,3';;
2846       *) conftest_s='   .machine power5
2847         .text
2848         popcntb 3,3';;
2849     esac
2850
2851     gcc_GAS_CHECK_FEATURE([popcntb support],
2852       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2853       [$conftest_s],,
2854       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2855           [Define if your assembler supports popcntb field.])])
2856
2857     case $target in
2858       *-*-aix*) conftest_s='    .machine "pwr5x"
2859         .csect .text[[PR]]
2860         frin 1,1';;
2861       *) conftest_s='   .machine power5
2862         .text
2863         frin 1,1';;
2864     esac
2865
2866     gcc_GAS_CHECK_FEATURE([fp round support],
2867       gcc_cv_as_powerpc_fprnd, [2,17,0],,
2868       [$conftest_s],,
2869       [AC_DEFINE(HAVE_AS_FPRND, 1,
2870           [Define if your assembler supports fprnd.])])
2871
2872     case $target in
2873       *-*-aix*) conftest_s='    .machine "pwr6"
2874         .csect .text[[PR]]
2875         mffgpr 1,3';;
2876       *) conftest_s='   .machine power6
2877         .text
2878         mffgpr 1,3';;
2879     esac
2880
2881     gcc_GAS_CHECK_FEATURE([move fp gpr support],
2882       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
2883       [$conftest_s],,
2884       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
2885           [Define if your assembler supports mffgpr and mftgpr.])])
2886
2887     case $target in
2888       *-*-aix*) conftest_s='    .csect .text[[PR]]
2889 LCF..0:
2890         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
2891       *-*-darwin*)
2892         conftest_s='    .text
2893 LCF0:
2894         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
2895       *) conftest_s='   .text
2896 .LCF0:
2897         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
2898     esac
2899
2900     gcc_GAS_CHECK_FEATURE([rel16 relocs],
2901       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
2902       [$conftest_s],,
2903       [AC_DEFINE(HAVE_AS_REL16, 1,
2904           [Define if your assembler supports R_PPC_REL16 relocs.])])
2905
2906     case $target in
2907       *-*-aix*) conftest_s='    .machine "pwr6"
2908         .csect .text[[PR]]
2909         cmpb 3,4,5';;
2910       *) conftest_s='   .machine power6
2911         .text
2912         cmpb 3,4,5';;
2913     esac
2914
2915     gcc_GAS_CHECK_FEATURE([compare bytes support],
2916       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
2917       [$conftest_s],,
2918       [AC_DEFINE(HAVE_AS_CMPB, 1,
2919           [Define if your assembler supports cmpb.])])
2920
2921     case $target in
2922       *-*-aix*) conftest_s='    .machine "pwr6"
2923         .csect .text[[PR]]
2924         dadd 1,2,3';;
2925       *) conftest_s='   .machine power6
2926         .text
2927         dadd 1,2,3';;
2928     esac
2929
2930     gcc_GAS_CHECK_FEATURE([decimal float support],
2931       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
2932       [$conftest_s],,
2933       [AC_DEFINE(HAVE_AS_DFP, 1,
2934           [Define if your assembler supports DFP instructions.])])
2935
2936     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
2937       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
2938       [.gnu_attribute 4,1],,
2939       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
2940           [Define if your assembler supports .gnu_attribute.])])
2941     ;;
2942
2943   mips*-*-*)
2944     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2945       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2946 [       lw $4,%gp_rel(foo)($4)],,
2947       [if test x$target_cpu_default = x
2948        then target_cpu_default=MASK_EXPLICIT_RELOCS
2949        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2950        fi])
2951     gcc_GAS_CHECK_FEATURE([-mno-shared support],
2952       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
2953       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
2954                  [Define if the assembler understands -mno-shared.])])
2955
2956     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
2957       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
2958       [.gnu_attribute 4,1],,
2959       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
2960           [Define if your assembler supports .gnu_attribute.])])
2961
2962     gcc_GAS_CHECK_FEATURE([.dtprelword support],
2963       gcc_cv_as_mips_dtprelword, [2,18,0],,
2964       [.section .tdata,"awT",@progbits
2965 x:
2966         .word 2
2967         .text
2968         .dtprelword x+0x8000],,
2969       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
2970           [Define if your assembler supports .dtprelword.])])
2971     ;;
2972 esac
2973
2974 # Mips and HP-UX need the GNU assembler.
2975 # Linux on IA64 might be able to use the Intel assembler.
2976
2977 case "$target" in
2978   mips*-*-* | *-*-hpux* )
2979     if test x$gas_flag = xyes \
2980        || test x"$host" != x"$build" \
2981        || test ! -x "$gcc_cv_as" \
2982        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2983       :
2984     else
2985       echo "*** This configuration requires the GNU assembler" >&2
2986       exit 1
2987     fi
2988     ;;
2989 esac
2990
2991 # ??? Not all targets support dwarf2 debug_line, even within a version
2992 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2993 # info to the output file.  So, as supported targets are added to gas 2.11,
2994 # add some instruction here to (also) show we expect this might work.
2995 # ??? Once 2.11 is released, probably need to add first known working
2996 # version to the per-target configury.
2997 case "$target" in
2998   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2999   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
3000   | xstormy16*-*-* | cris-*-* | xtensa-*-* | bfin-*-* | score*-*-* | spu-*-*)
3001     insn="nop"
3002     ;;
3003   ia64*-*-* | s390*-*-*)
3004     insn="nop 0"
3005     ;;
3006   mmix-*-*)
3007     insn="swym 0"
3008     ;;
3009 esac
3010 if test x"$insn" != x; then
3011  conftest_s="\
3012         .file 1 \"conftest.s\"
3013         .loc 1 3 0
3014         $insn"
3015  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3016   gcc_cv_as_dwarf2_debug_line,
3017   [elf,2,11,0],, [$conftest_s],
3018   [if test x$gcc_cv_objdump != x \
3019    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3020       | grep debug_line > /dev/null 2>&1; then
3021      gcc_cv_as_dwarf2_debug_line=yes
3022    fi])
3023
3024 # The .debug_line file table must be in the exact order that
3025 # we specified the files, since these indices are also used
3026 # by DW_AT_decl_file.  Approximate this test by testing if
3027 # the assembler bitches if the same index is assigned twice.
3028  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3029   gcc_cv_as_dwarf2_file_buggy,,,
3030 [       .file 1 "foo.s"
3031         .file 1 "bar.s"])
3032
3033  if test $gcc_cv_as_dwarf2_debug_line = yes \
3034  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3035         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3036   [Define if your assembler supports dwarf2 .file/.loc directives,
3037    and preserves file table indices exactly as given.])
3038  fi
3039
3040  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3041   gcc_cv_as_gdwarf2_flag,
3042   [elf,2,11,0], [--gdwarf2], [$insn],,
3043   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3044 [Define if your assembler supports the --gdwarf2 option.])])
3045
3046  gcc_GAS_CHECK_FEATURE([--gstabs option],
3047   gcc_cv_as_gstabs_flag,
3048   [elf,2,11,0], [--gstabs], [$insn],
3049   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3050    # and warns about it, but still exits successfully.  So check for
3051    # this.
3052    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3053    then :
3054    else gcc_cv_as_gstabs_flag=yes
3055    fi],
3056   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3057 [Define if your assembler supports the --gstabs option.])])
3058 fi
3059
3060 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3061  [gcc_cv_as_line_zero],
3062  [gcc_cv_as_line_zero=no
3063   if test $in_tree_gas = yes; then
3064     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3065   elif test "x$gcc_cv_as" != x; then
3066     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3067     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3068        test "x`cat conftest.out`" = x
3069     then
3070       gcc_cv_as_line_zero=yes
3071     else
3072       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3073       cat conftest.s >&AS_MESSAGE_LOG_FD
3074       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3075       cat conftest.out >&AS_MESSAGE_LOG_FD
3076     fi
3077     rm -f conftest.o conftest.s conftest.out
3078   fi])
3079 if test "x$gcc_cv_as_line_zero" = xyes; then
3080   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3081 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3082 fi
3083
3084 AC_MSG_CHECKING(linker read-only and read-write section mixing)
3085 gcc_cv_ld_ro_rw_mix=unknown
3086 if test $in_tree_ld = yes ; then
3087   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
3088      && test $in_tree_ld_is_elf = yes; then
3089     gcc_cv_ld_ro_rw_mix=read-write
3090   fi
3091 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3092   echo '.section myfoosect, "a"' > conftest1.s
3093   echo '.section myfoosect, "aw"' > conftest2.s
3094   echo '.byte 1' >> conftest2.s
3095   echo '.section myfoosect, "a"' > conftest3.s
3096   echo '.byte 0' >> conftest3.s
3097   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
3098      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
3099      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
3100      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
3101         conftest2.o conftest3.o > /dev/null 2>&1; then
3102     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
3103                          | sed -e '/myfoosect/!d' -e N`
3104     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
3105       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
3106         gcc_cv_ld_ro_rw_mix=read-only
3107       else
3108         gcc_cv_ld_ro_rw_mix=read-write
3109       fi
3110     fi
3111   fi
3112 changequote(,)dnl
3113   rm -f conftest.* conftest[123].*
3114 changequote([,])dnl
3115 fi
3116 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
3117         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
3118   [Define if your linker links a mix of read-only
3119    and read-write sections into a read-write section.])
3120 fi
3121 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
3122
3123 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3124 gcc_cv_ld_eh_frame_hdr=no
3125 if test $in_tree_ld = yes ; then
3126   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3127      && test $in_tree_ld_is_elf = yes; then
3128     gcc_cv_ld_eh_frame_hdr=yes
3129   fi
3130 elif test x$gcc_cv_ld != x; then
3131         # Check if linker supports --eh-frame-hdr option
3132         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3133                 gcc_cv_ld_eh_frame_hdr=yes
3134         fi
3135 fi
3136 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3137 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3138         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3139 [Define if your linker supports --eh-frame-hdr option.])
3140 fi
3141 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3142
3143 AC_MSG_CHECKING(linker position independent executable support)
3144 gcc_cv_ld_pie=no
3145 if test $in_tree_ld = yes ; then
3146   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3147      && test $in_tree_ld_is_elf = yes; then
3148     gcc_cv_ld_pie=yes
3149   fi
3150 elif test x$gcc_cv_ld != x; then
3151         # Check if linker supports -pie option
3152         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3153                 gcc_cv_ld_pie=yes
3154         fi
3155 fi
3156 if test x"$gcc_cv_ld_pie" = xyes; then
3157         AC_DEFINE(HAVE_LD_PIE, 1,
3158 [Define if your linker supports -pie option.])
3159 fi
3160 AC_MSG_RESULT($gcc_cv_ld_pie)
3161
3162 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3163 gcc_cv_ld_eh_gc_sections=no
3164 if test $in_tree_ld = yes ; then
3165   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3166      && test $in_tree_ld_is_elf = yes; then
3167     gcc_cv_ld_eh_gc_sections=yes
3168   fi
3169 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3170   cat > conftest.s <<EOF
3171         .section        .text
3172 .globl _start
3173         .type _start, @function
3174 _start:
3175         .long foo
3176         .size _start, .-_start
3177         .section        .text.foo,"ax",@progbits
3178         .type foo, @function
3179 foo:
3180         .long 0
3181         .size foo, .-foo
3182         .section        .gcc_except_table.foo,"a",@progbits
3183 .L0:
3184         .long 0
3185         .section        .eh_frame,"a",@progbits
3186         .long .L0
3187 EOF
3188   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3189     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3190          | grep "gc-sections option ignored" > /dev/null; then
3191       gcc_cv_ld_eh_gc_sections=no
3192     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3193       gcc_cv_ld_eh_gc_sections=yes
3194       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3195       if test x$gcc_cv_as_comdat_group != xyes; then
3196         gcc_cv_ld_eh_gc_sections=no
3197         cat > conftest.s <<EOF
3198         .section        .text
3199 .globl _start
3200         .type _start, @function
3201 _start:
3202         .long foo
3203         .size _start, .-_start
3204         .section        .gnu.linkonce.t.foo,"ax",@progbits
3205         .type foo, @function
3206 foo:
3207         .long 0
3208         .size foo, .-foo
3209         .section        .gcc_except_table.foo,"a",@progbits
3210 .L0:
3211         .long 0
3212         .section        .eh_frame,"a",@progbits
3213         .long .L0
3214 EOF
3215         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3216           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3217                | grep "gc-sections option ignored" > /dev/null; then
3218             gcc_cv_ld_eh_gc_sections=no
3219           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3220             gcc_cv_ld_eh_gc_sections=yes
3221           fi
3222         fi
3223       fi
3224     fi
3225   fi
3226   rm -f conftest.s conftest.o conftest
3227 fi
3228 case "$target" in
3229   hppa*-*-linux*)
3230     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3231     gcc_cv_ld_eh_gc_sections=no
3232     ;;
3233 esac
3234 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3235         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3236   [Define if your linker supports garbage collection of
3237    sections in presence of EH frames.])
3238 fi
3239 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3240
3241 # --------
3242 # UNSORTED
3243 # --------
3244
3245 AC_CACHE_CHECK(linker --as-needed support,
3246 gcc_cv_ld_as_needed,
3247 [gcc_cv_ld_as_needed=no
3248 if test $in_tree_ld = yes ; then
3249   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3250      && test $in_tree_ld_is_elf = yes; then
3251     gcc_cv_ld_as_needed=yes
3252   fi
3253 elif test x$gcc_cv_ld != x; then
3254         # Check if linker supports --as-needed and --no-as-needed options
3255         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3256                 gcc_cv_ld_as_needed=yes
3257         fi
3258 fi
3259 ])
3260 if test x"$gcc_cv_ld_as_needed" = xyes; then
3261         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3262 [Define if your linker supports --as-needed and --no-as-needed options.])
3263 fi
3264
3265 case "$target:$tm_file" in
3266   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3267     AC_CACHE_CHECK(linker support for omitting dot symbols,
3268     gcc_cv_ld_no_dot_syms,
3269     [gcc_cv_ld_no_dot_syms=no
3270     if test $in_tree_ld = yes ; then
3271       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3272         gcc_cv_ld_no_dot_syms=yes
3273       fi
3274     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3275       cat > conftest1.s <<EOF
3276         .text
3277         bl .foo
3278 EOF
3279       cat > conftest2.s <<EOF
3280         .section ".opd","aw"
3281         .align 3
3282         .globl foo
3283         .type foo,@function
3284 foo:
3285         .quad .LEfoo,.TOC.@tocbase,0
3286         .text
3287 .LEfoo:
3288         blr
3289         .size foo,.-.LEfoo
3290 EOF
3291       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3292          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3293          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3294         gcc_cv_ld_no_dot_syms=yes
3295       fi
3296       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3297     fi
3298     ])
3299     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3300       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3301     [Define if your PowerPC64 linker only needs function descriptor syms.])
3302     fi
3303     ;;
3304 esac
3305
3306 AC_CACHE_CHECK(linker --sysroot support,
3307   gcc_cv_ld_sysroot,
3308   [gcc_cv_ld_sysroot=no
3309   if test $in_tree_ld = yes ; then
3310       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3311         gcc_cv_ld_sysroot=yes
3312       fi
3313   elif test x$gcc_cv_ld != x; then
3314     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3315       gcc_cv_ld_sysroot=yes
3316     fi
3317   fi])
3318 if test x"$gcc_cv_ld_sysroot" = xyes; then
3319   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3320   [Define if your linker supports --sysroot.])
3321 fi
3322
3323 if test x$with_sysroot = x && test x$host = x$target \
3324    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3325    && test "$prefix" != "NONE"; then
3326   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3327 [Define to PREFIX/include if cpp should also search that directory.])
3328 fi
3329
3330 # Test for stack protector support in target C library.
3331 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3332       gcc_cv_libc_provides_ssp,
3333       [gcc_cv_libc_provides_ssp=no
3334     case "$target" in
3335        *-*-linux*)
3336       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3337         if test "x$with_sysroot" = x; then
3338           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3339         elif test "x$with_build_sysroot" != "x"; then
3340           glibc_header_dir="${with_build_sysroot}/usr/include"
3341         elif test "x$with_sysroot" = xyes; then
3342           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3343         else
3344           glibc_header_dir="${with_sysroot}/usr/include"
3345         fi
3346       else
3347         glibc_header_dir=/usr/include
3348       fi
3349       # glibc 2.4 and later provides __stack_chk_fail and
3350       # either __stack_chk_guard, or TLS access to stack guard canary.
3351       if test -f $glibc_header_dir/features.h \
3352          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3353             $glibc_header_dir/features.h > /dev/null; then
3354         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3355            $glibc_header_dir/features.h > /dev/null; then
3356           gcc_cv_libc_provides_ssp=yes
3357         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3358              $glibc_header_dir/features.h > /dev/null \
3359              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3360              $glibc_header_dir/features.h > /dev/null; then
3361           gcc_cv_libc_provides_ssp=yes
3362         fi
3363         fi
3364         ;;
3365        *-*-darwin*)
3366          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3367            [echo "no __stack_chk_fail on this target"])
3368         ;;
3369   *) gcc_cv_libc_provides_ssp=no ;;
3370     esac])
3371
3372 if test x$gcc_cv_libc_provides_ssp = xyes; then
3373   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3374             [Define if your target C library provides stack protector support])
3375 fi
3376
3377 # Check if TFmode long double should be used by default or not.
3378 # Some glibc targets used DFmode long double, but with glibc 2.4
3379 # and later they can use TFmode.
3380 case "$target" in
3381   powerpc*-*-linux* | \
3382   powerpc*-*-gnu* | \
3383   sparc*-*-linux* | \
3384   s390*-*-linux* | \
3385   alpha*-*-linux*)
3386     AC_ARG_WITH(long-double-128,
3387 [  --with-long-double-128  Use 128-bit long double by default.],
3388       gcc_cv_target_ldbl128="$with_long_double_128",
3389       [gcc_cv_target_ldbl128=no
3390       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3391         if test "x$with_sysroot" = x; then
3392           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3393         elif test "x$with_build_sysroot" != "x"; then
3394           glibc_header_dir="${with_build_sysroot}/usr/include"
3395         elif test "x$with_sysroot" = xyes; then
3396           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3397         else
3398           glibc_header_dir="${with_sysroot}/usr/include"
3399         fi
3400       else
3401         glibc_header_dir=/usr/include
3402       fi
3403 changequote(,)dnl
3404       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3405         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3406       && gcc_cv_target_ldbl128=yes
3407 changequote([,])dnl
3408       ])
3409     ;;
3410 esac
3411 if test x$gcc_cv_target_ldbl128 = xyes; then
3412   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3413             [Define if TFmode long double should be the default])
3414 fi
3415
3416 # Find out what GC implementation we want, or may, use.
3417 AC_ARG_WITH(gc,
3418 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3419                           with the compiler],
3420 [case "$withval" in
3421   page)
3422     GGC=ggc-$withval
3423     ;;
3424   zone)
3425     GGC=ggc-$withval
3426     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3427     ;;
3428   *)
3429     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3430     ;;
3431 esac],
3432 [GGC=ggc-page])
3433 AC_SUBST(GGC)
3434 echo "Using $GGC for garbage collection."
3435
3436 # Use the system's zlib library.
3437 zlibdir=-L../zlib
3438 zlibinc="-I\$(srcdir)/../zlib"
3439 AC_ARG_WITH(system-zlib,
3440 [  --with-system-zlib      use installed libz],
3441 zlibdir=
3442 zlibinc=
3443 )
3444 AC_SUBST(zlibdir)
3445 AC_SUBST(zlibinc)
3446
3447 dnl Very limited version of automake's enable-maintainer-mode
3448
3449 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3450   dnl maintainer-mode is disabled by default
3451   AC_ARG_ENABLE(maintainer-mode,
3452 [  --enable-maintainer-mode
3453                           enable make rules and dependencies not useful
3454                           (and sometimes confusing) to the casual installer],
3455       maintainer_mode=$enableval,
3456       maintainer_mode=no)
3457
3458 AC_MSG_RESULT($maintainer_mode)
3459
3460 if test "$maintainer_mode" = "yes"; then
3461   MAINT=''
3462 else
3463   MAINT='#'
3464 fi
3465 AC_SUBST(MAINT)dnl
3466
3467 # --------------
3468 # Language hooks
3469 # --------------
3470
3471 # Make empty files to contain the specs and options for each language.
3472 # Then add #include lines to for a compiler that has specs and/or options.
3473
3474 subdirs=
3475 lang_opt_files=
3476 lang_specs_files=
3477 lang_tree_files=
3478 # These (without "all_") are set in each config-lang.in.
3479 # `language' must be a single word so is spelled singularly.
3480 all_languages=
3481 all_compilers=
3482 all_outputs='Makefile gccbug libada-mk'
3483 # List of language makefile fragments.
3484 all_lang_makefrags=
3485 # List of language subdirectory makefiles.  Deprecated.
3486 all_lang_makefiles=
3487 # Additional files for gengtype
3488 all_gtfiles="$target_gtfiles"
3489
3490 # These are the languages that are set in --enable-languages,
3491 # and are available in the GCC tree.
3492 all_selected_languages=
3493
3494 # Add the language fragments.
3495 # Languages are added via two mechanisms.  Some information must be
3496 # recorded in makefile variables, these are defined in config-lang.in.
3497 # We accumulate them and plug them into the main Makefile.
3498 # The other mechanism is a set of hooks for each of the main targets
3499 # like `clean', `install', etc.
3500
3501 language_hooks="Make-hooks"
3502
3503 for lang in ${srcdir}/*/config-lang.in
3504 do
3505 changequote(,)dnl
3506         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3507
3508         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3509         if test "x$lang_alias" = x
3510         then
3511               echo "$lang doesn't set \$language." 1>&2
3512               exit 1
3513         fi
3514         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3515         subdirs="$subdirs $subdir"
3516         case ",$enable_languages," in
3517         *,$lang_alias,*)
3518             all_selected_languages="$all_selected_languages $lang_alias"
3519             if test -f $srcdir/$subdir/lang-specs.h; then
3520                 lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3521             fi
3522             ;;
3523         esac
3524 changequote([,])dnl
3525
3526         language=
3527         boot_language=
3528         compilers=
3529         outputs=
3530         gtfiles=
3531         subdir_requires=
3532         . ${srcdir}/$subdir/config-lang.in
3533         if test "x$language" = x
3534         then
3535                 echo "${srcdir}/$subdir/config-lang.in doesn't set \$language." 1>&2
3536                 exit 1
3537         fi
3538
3539         ok=:
3540         case ",$enable_languages," in
3541                 *,$lang_alias,*) ;;
3542                 *)
3543                         for i in $subdir_requires; do
3544                                 test -f "${srcdir}/$i/config-lang.in" && continue
3545                                 ok=false
3546                                 break
3547                         done
3548                 ;;
3549         esac
3550         $ok || continue
3551
3552         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$subdir/Make-lang.in"
3553         if test -f $srcdir/$subdir/lang.opt; then
3554             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3555         fi
3556         if test -f $srcdir/$subdir/$subdir-tree.def; then
3557             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3558         fi
3559         if test -f ${srcdir}/$subdir/Makefile.in
3560                 then all_lang_makefiles="$subdir/Makefile"
3561         fi
3562         all_languages="$all_languages $language"
3563         all_compilers="$all_compilers $compilers"
3564         all_outputs="$all_outputs $outputs"
3565         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3566 done
3567
3568 # Pick up gtfiles for c
3569 gtfiles=
3570 . ${srcdir}/c-config-lang.in
3571 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3572
3573 check_languages=
3574 for language in $all_selected_languages
3575 do
3576         check_languages="$check_languages check-$language"
3577 done
3578
3579 # We link each language in with a set of hooks, reached indirectly via
3580 # lang.${target}.  Only do so for selected languages.
3581
3582 rm -f Make-hooks
3583 touch Make-hooks
3584 target_list="all.cross start.encap rest.encap tags \
3585         install-common install-man install-info install-pdf dvi pdf \
3586         html uninstall info man srcextra srcman srcinfo \
3587         mostlyclean clean distclean maintainer-clean"
3588
3589 for t in $target_list
3590 do
3591         x=
3592         for lang in $all_selected_languages
3593         do
3594                 x="$x $lang.$t"
3595         done
3596         echo "lang.$t: $x" >> Make-hooks
3597 done
3598
3599 # --------
3600 # UNSORTED
3601 # --------
3602
3603 # Create .gdbinit.
3604
3605 echo "dir ." > .gdbinit
3606 echo "dir ${srcdir}" >> .gdbinit
3607 if test x$gdb_needs_out_file_path = xyes
3608 then
3609         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3610 fi
3611 if test "x$subdirs" != x; then
3612         for s in $subdirs
3613         do
3614                 echo "dir ${srcdir}/$s" >> .gdbinit
3615         done
3616 fi
3617 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3618
3619 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3620 AC_SUBST(gcc_tooldir)
3621 AC_SUBST(dollar)
3622
3623 # Find a directory in which to install a shared libgcc.
3624
3625 AC_ARG_ENABLE(version-specific-runtime-libs,
3626 [  --enable-version-specific-runtime-libs
3627                           specify that runtime libraries should be
3628                           installed in a compiler-specific directory])
3629
3630 AC_ARG_WITH(slibdir,
3631 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3632 slibdir="$with_slibdir",
3633 if test "${enable_version_specific_runtime_libs+set}" = set; then
3634   slibdir='$(libsubdir)'
3635 elif test "$host" != "$target"; then
3636   slibdir='$(build_tooldir)/lib'
3637 else
3638   slibdir='$(libdir)'
3639 fi)
3640 AC_SUBST(slibdir)
3641
3642 objdir=`${PWDCMD-pwd}`
3643 AC_SUBST(objdir)
3644
3645 AC_ARG_WITH(datarootdir,
3646 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3647 datarootdir="\${prefix}/$with_datarootdir",
3648 datarootdir='$(prefix)/share')
3649 AC_SUBST(datarootdir)
3650
3651 AC_ARG_WITH(docdir,
3652 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3653 docdir="\${prefix}/$with_docdir",
3654 docdir='$(datarootdir)')
3655 AC_SUBST(docdir)
3656
3657 AC_ARG_WITH(htmldir,
3658 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3659 htmldir="\${prefix}/$with_htmldir",
3660 htmldir='$(docdir)')
3661 AC_SUBST(htmldir)
3662
3663 # Substitute configuration variables
3664 AC_SUBST(subdirs)
3665 AC_SUBST(srcdir)
3666 AC_SUBST(all_compilers)
3667 AC_SUBST(all_gtfiles)
3668 AC_SUBST(all_lang_makefrags)
3669 AC_SUBST(all_lang_makefiles)
3670 AC_SUBST(all_languages)
3671 AC_SUBST(all_selected_languages)
3672 AC_SUBST(build_exeext)
3673 AC_SUBST(build_install_headers_dir)
3674 AC_SUBST(build_xm_file_list)
3675 AC_SUBST(build_xm_include_list)
3676 AC_SUBST(build_xm_defines)
3677 AC_SUBST(check_languages)
3678 AC_SUBST(cpp_install_dir)
3679 AC_SUBST(xmake_file)
3680 AC_SUBST(tmake_file)
3681 AC_SUBST(extra_gcc_objs)
3682 AC_SUBST(extra_headers_list)
3683 AC_SUBST(extra_objs)
3684 AC_SUBST(extra_parts)
3685 AC_SUBST(extra_passes)
3686 AC_SUBST(extra_programs)
3687 AC_SUBST(float_h_file)
3688 AC_SUBST(gcc_config_arguments)
3689 AC_SUBST(gcc_gxx_include_dir)
3690 AC_SUBST(host_exeext)
3691 AC_SUBST(host_xm_file_list)
3692 AC_SUBST(host_xm_include_list)
3693 AC_SUBST(host_xm_defines)
3694 AC_SUBST(out_host_hook_obj)
3695 AC_SUBST(install)
3696 AC_SUBST(lang_opt_files)
3697 AC_SUBST(lang_specs_files)
3698 AC_SUBST(lang_tree_files)
3699 AC_SUBST(local_prefix)
3700 AC_SUBST(md_file)
3701 AC_SUBST(objc_boehm_gc)
3702 AC_SUBST(out_file)
3703 AC_SUBST(out_object_file)
3704 AC_SUBST(thread_file)
3705 AC_SUBST(tm_file_list)
3706 AC_SUBST(tm_include_list)
3707 AC_SUBST(tm_defines)
3708 AC_SUBST(tm_p_file_list)
3709 AC_SUBST(tm_p_include_list)
3710 AC_SUBST(xm_file_list)
3711 AC_SUBST(xm_include_list)
3712 AC_SUBST(xm_defines)
3713 AC_SUBST(c_target_objs)
3714 AC_SUBST(cxx_target_objs)
3715 AC_SUBST(target_cpu_default)
3716
3717 AC_SUBST_FILE(language_hooks)
3718
3719 # Echo link setup.
3720 if test x${build} = x${host} ; then
3721   if test x${host} = x${target} ; then
3722     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3723   else
3724     echo "Links are now set up to build a cross-compiler" 1>&2
3725     echo " from ${host} to ${target}." 1>&2
3726   fi
3727 else
3728   if test x${host} = x${target} ; then
3729     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3730     echo " for ${target}." 1>&2
3731   else
3732     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3733     echo " from ${host} to ${target}." 1>&2
3734   fi
3735 fi
3736
3737 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3738 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3739
3740 # Configure the subdirectories
3741 # AC_CONFIG_SUBDIRS($subdirs)
3742
3743 # Create the Makefile
3744 # and configure language subdirectories
3745 AC_CONFIG_FILES($all_outputs)
3746
3747 AC_CONFIG_COMMANDS([default],
3748 [
3749 case ${CONFIG_HEADERS} in
3750   *auto-host.h:config.in*)
3751   echo > cstamp-h ;;
3752 esac
3753 # Make sure all the subdirs exist.
3754 for d in $subdirs doc build
3755 do
3756     test -d $d || mkdir $d
3757 done
3758 ],
3759 [subdirs='$subdirs'])
3760 AC_OUTPUT