OSDN Git Service

2d7823435f4e958524a9a0eb4454101701d8a42f
[pf3gnuchains/gcc-fork.git] / gcc / configure.ac
1 # configure.ac for GCC
2 # Process this file with autoconf to generate a configuration script.
3
4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
5 # 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
6
7 #This file is part of GCC.
8
9 #GCC is free software; you can redistribute it and/or modify it under
10 #the terms of the GNU General Public License as published by the Free
11 #Software Foundation; either version 3, or (at your option) any later
12 #version.
13
14 #GCC is distributed in the hope that it will be useful, but WITHOUT
15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
17 #for more details.
18
19 #You should have received a copy of the GNU General Public License
20 #along with GCC; see the file COPYING3.  If not see
21 #<http://www.gnu.org/licenses/>.
22
23 # --------------------------------
24 # Initialization and sanity checks
25 # --------------------------------
26
27 AC_PREREQ(2.64)
28 AC_INIT
29 AC_CONFIG_SRCDIR(tree.c)
30 AC_CONFIG_HEADER(auto-host.h:config.in)
31
32 gcc_version=`cat $srcdir/BASE-VER`
33
34 # Determine the host, build, and target systems
35 AC_CANONICAL_BUILD
36 AC_CANONICAL_HOST
37 AC_CANONICAL_TARGET
38
39 # Determine the noncanonical target name, for directory use.
40 ACX_NONCANONICAL_TARGET
41
42 # Determine the target- and build-specific subdirectories
43 GCC_TOPLEV_SUBDIRS
44
45 # Set program_transform_name
46 AC_ARG_PROGRAM
47
48 # Check for bogus environment variables.
49 # Test if LIBRARY_PATH contains the notation for the current directory
50 # since this would lead to problems installing/building glibc.
51 # LIBRARY_PATH contains the current directory if one of the following
52 # is true:
53 # - one of the terminals (":" and ";") is the first or last sign
54 # - two terminals occur directly after each other
55 # - the path contains an element with a dot in it
56 AC_MSG_CHECKING(LIBRARY_PATH variable)
57 changequote(,)dnl
58 case ${LIBRARY_PATH} in
59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
60     library_path_setting="contains current directory"
61     ;;
62   *)
63     library_path_setting="ok"
64     ;;
65 esac
66 changequote([,])dnl
67 AC_MSG_RESULT($library_path_setting)
68 if test "$library_path_setting" != "ok"; then
69 AC_MSG_ERROR([
70 *** LIBRARY_PATH shouldn't contain the current directory when
71 *** building gcc. Please change the environment variable
72 *** and run configure again.])
73 fi
74
75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
76 # since this would lead to problems installing/building glibc.
77 # GCC_EXEC_PREFIX contains the current directory if one of the following
78 # is true:
79 # - one of the terminals (":" and ";") is the first or last sign
80 # - two terminals occur directly after each other
81 # - the path contains an element with a dot in it
82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
83 changequote(,)dnl
84 case ${GCC_EXEC_PREFIX} in
85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
86     gcc_exec_prefix_setting="contains current directory"
87     ;;
88   *)
89     gcc_exec_prefix_setting="ok"
90     ;;
91 esac
92 changequote([,])dnl
93 AC_MSG_RESULT($gcc_exec_prefix_setting)
94 if test "$gcc_exec_prefix_setting" != "ok"; then
95 AC_MSG_ERROR([
96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
97 *** building gcc. Please change the environment variable
98 *** and run configure again.])
99 fi
100
101 # -----------
102 # Directories
103 # -----------
104
105 # Specify the local prefix
106 local_prefix=
107 AC_ARG_WITH(local-prefix,
108 [  --with-local-prefix=DIR specifies directory to put local include],
109 [case "${withval}" in
110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
111 no)     ;;
112 *)      local_prefix=$with_local_prefix ;;
113 esac])
114
115 # Default local prefix if it is empty
116 if test x$local_prefix = x; then
117         local_prefix=/usr/local
118 fi
119
120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
121 # passed in by the toplevel make and thus we'd get different behavior
122 # depending on where we built the sources.
123 gcc_gxx_include_dir=
124 # Specify the g++ header file directory
125 AC_ARG_WITH(gxx-include-dir,
126 [  --with-gxx-include-dir=DIR
127                           specifies directory to put g++ header files],
128 [case "${withval}" in
129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
130 no)     ;;
131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
132 esac])
133
134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
135 if test x${gcc_gxx_include_dir} = x; then
136   if test x${enable_version_specific_runtime_libs} = xyes; then
137     gcc_gxx_include_dir='${libsubdir}/include/c++'
138   else
139     libstdcxx_incdir='include/c++/$(version)'
140     if test x$host != x$target; then
141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
142     fi
143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
144   fi
145 fi
146
147 AC_ARG_WITH(cpp_install_dir,
148 [  --with-cpp-install-dir=DIR
149                           install the user visible C preprocessor in DIR
150                           (relative to PREFIX) as well as PREFIX/bin],
151 [if test x$withval = xyes; then
152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
153 elif test x$withval != xno; then
154   cpp_install_dir=$withval
155 fi])
156
157 # We would like to our source tree to be readonly.  However when releases or
158 # pre-releases are generated, the flex/bison generated files as well as the 
159 # various formats of manuals need to be included along with the rest of the
160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do 
161 # just that.
162
163 AC_MSG_CHECKING([whether to place generated files in the source directory])
164   dnl generated-files-in-srcdir is disabled by default
165   AC_ARG_ENABLE(generated-files-in-srcdir, 
166 [  --enable-generated-files-in-srcdir
167                           put copies of generated files in source dir
168                           intended for creating source tarballs for users
169                           without texinfo bison or flex.],
170       generated_files_in_srcdir=$enableval,
171       generated_files_in_srcdir=no)
172
173 AC_MSG_RESULT($generated_files_in_srcdir)
174
175 if test "$generated_files_in_srcdir" = "yes"; then
176   GENINSRC=''
177 else
178   GENINSRC='#'
179 fi
180 AC_SUBST(GENINSRC)
181
182 # -------------------
183 # Find default linker
184 # -------------------
185
186 # With GNU ld
187 AC_ARG_WITH(gnu-ld,
188 [  --with-gnu-ld           arrange to work with GNU ld.],
189 gnu_ld_flag="$with_gnu_ld",
190 gnu_ld_flag=no)
191
192 # With pre-defined ld
193 AC_ARG_WITH(ld,
194 [  --with-ld               arrange to use the specified ld (full pathname)],
195 DEFAULT_LINKER="$with_ld")
196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
197   if test ! -x "$DEFAULT_LINKER"; then
198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
200     gnu_ld_flag=yes
201   fi
202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
203         [Define to enable the use of a default linker.])
204 fi
205
206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
208
209 AC_MSG_CHECKING([whether a default linker was specified])
210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
211   if test x"$gnu_ld_flag" = x"no"; then
212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
213   else
214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
215   fi
216 else
217   AC_MSG_RESULT(no)
218 fi
219
220 # With demangler in GNU ld
221 AC_ARG_WITH(demangler-in-ld,
222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
223 demangler_in_ld="$with_demangler_in_ld",
224 demangler_in_ld=no)
225
226 # ----------------------
227 # Find default assembler
228 # ----------------------
229
230 # With GNU as
231 AC_ARG_WITH(gnu-as,
232 [  --with-gnu-as           arrange to work with GNU as],
233 gas_flag="$with_gnu_as",
234 gas_flag=no)
235
236 AC_ARG_WITH(as,
237 [  --with-as               arrange to use the specified as (full pathname)],
238 DEFAULT_ASSEMBLER="$with_as")
239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
240   if test ! -x "$DEFAULT_ASSEMBLER"; then
241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
243     gas_flag=yes
244   fi
245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
246         [Define to enable the use of a default assembler.])
247 fi
248
249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
251
252 AC_MSG_CHECKING([whether a default assembler was specified])
253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
254   if test x"$gas_flag" = x"no"; then
255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
256   else
257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
258   fi
259 else
260   AC_MSG_RESULT(no)
261 fi
262
263 # ---------------
264 # Find C compiler
265 # ---------------
266
267 # If a non-executable a.out is present (e.g. created by GNU as above even if
268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
269 # file, even when creating an executable, so an execution test fails.
270 # Remove possible default executable files to avoid this.
271 #
272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
273 # Autoconf includes it.
274 rm -f a.out a.exe b.out
275
276 # Find the native compiler
277 AC_PROG_CC
278 AM_PROG_CC_C_O
279 AC_PROG_CXX
280 ACX_PROG_GNAT([-I"$srcdir"/ada])
281
282 # autoconf is lame and doesn't give us any substitution variable for this.
283 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
284   NO_MINUS_C_MINUS_O=yes
285 else
286   OUTPUT_OPTION='-o $@'
287 fi
288 AC_SUBST(NO_MINUS_C_MINUS_O)
289 AC_SUBST(OUTPUT_OPTION)
290
291 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
292 # optimizations to be activated explicitly by the toplevel.
293 case "$CC" in
294   */prev-gcc/xgcc*) ;;
295   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
296 esac
297 AC_SUBST(CFLAGS)
298
299 # -------------------------
300 # Check C compiler features
301 # -------------------------
302
303 AC_USE_SYSTEM_EXTENSIONS
304 AC_PROG_CPP
305 AC_C_INLINE
306
307 # sizeof(char) is 1 by definition.
308 AC_CHECK_SIZEOF(void *)
309 AC_CHECK_SIZEOF(short)
310 AC_CHECK_SIZEOF(int)
311 AC_CHECK_SIZEOF(long)
312 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
313 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
314 GCC_STDINT_TYPES
315
316 # ---------------------
317 # Warnings and checking
318 # ---------------------
319
320 # Check $CC warning features (if it's GCC).
321 # We want to use -pedantic, but we don't want warnings about
322 # * 'long long'
323 # * variadic macros
324 # * overlong strings
325 # So, we only use -pedantic if we can disable those warnings.
326
327 ACX_PROG_CC_WARNING_OPTS(
328         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
329 ACX_PROG_CC_WARNING_OPTS(
330         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
331         [c_loose_warn])
332 ACX_PROG_CC_WARNING_OPTS(
333         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
334 ACX_PROG_CC_WARNING_OPTS(
335         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
336 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
337         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ], 
338                        [-Wno-overlength-strings])), [strict_warn])
339 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
340
341 # The above macros do nothing if the compiler is not GCC.  However, the
342 # Makefile has more goo to add other flags, so these variables are used
343 # to enable warnings only for GCC.
344 warn_cflags=
345 warn_cxxflags=
346 if test "x$GCC" = "xyes"; then
347   warn_cflags='$(GCC_WARN_CFLAGS)'
348   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
349 fi
350 AC_SUBST(warn_cflags)
351 AC_SUBST(warn_cxxflags)
352
353 # Enable expensive internal checks
354 is_release=
355 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
356   is_release=yes
357 fi
358
359 AC_ARG_ENABLE(checking,
360 [  --enable-checking[=LIST]
361                           enable expensive run-time checks.  With LIST,
362                           enable only specific categories of checks.
363                           Categories are: yes,no,all,none,release.
364                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
365                           rtlflag,rtl,runtime,tree,valgrind,types.],
366 [ac_checking_flags="${enableval}"],[
367 # Determine the default checks.
368 if test x$is_release = x ; then
369   ac_checking_flags=yes
370 else
371   ac_checking_flags=release
372 fi])
373 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
374 for check in release $ac_checking_flags
375 do
376         case $check in
377         # these set all the flags to specific states
378         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
379                         ac_fold_checking= ; ac_gc_checking=1 ;
380                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
381                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
382                         ac_tree_checking=1 ; ac_valgrind_checking= ;
383                         ac_types_checking=1 ;;
384         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
385                         ac_fold_checking= ; ac_gc_checking= ;
386                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
387                         ac_rtlflag_checking= ; ac_runtime_checking= ;
388                         ac_tree_checking= ; ac_valgrind_checking= ;
389                         ac_types_checking= ;;
390         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
391                         ac_fold_checking=1 ; ac_gc_checking=1 ;
392                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
393                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
394                         ac_tree_checking=1 ; ac_valgrind_checking= ;
395                         ac_types_checking=1 ;;
396         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
397                         ac_fold_checking= ; ac_gc_checking= ;
398                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
399                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
400                         ac_tree_checking= ; ac_valgrind_checking= ;
401                         ac_types_checking= ;;
402         # these enable particular checks
403         assert)         ac_assert_checking=1 ;;
404         df)             ac_df_checking=1 ;;
405         fold)           ac_fold_checking=1 ;;
406         gc)             ac_gc_checking=1 ;;
407         gcac)           ac_gc_always_collect=1 ;;
408         gimple)         ac_gimple_checking=1 ;;
409         misc)           ac_checking=1 ;;
410         rtl)            ac_rtl_checking=1 ;;
411         rtlflag)        ac_rtlflag_checking=1 ;;
412         runtime)        ac_runtime_checking=1 ;;
413         tree)           ac_tree_checking=1 ;;
414         types)          ac_types_checking=1 ;;
415         valgrind)       ac_valgrind_checking=1 ;;
416         *)      AC_MSG_ERROR(unknown check category $check) ;;
417         esac
418 done
419 IFS="$ac_save_IFS"
420
421 nocommon_flag=""
422 if test x$ac_checking != x ; then
423   AC_DEFINE(ENABLE_CHECKING, 1,
424 [Define if you want more run-time sanity checks.  This one gets a grab
425    bag of miscellaneous but relatively cheap checks.])
426   nocommon_flag=-fno-common
427 fi
428 AC_SUBST(nocommon_flag)
429 if test x$ac_df_checking != x ; then
430   AC_DEFINE(ENABLE_DF_CHECKING, 1,
431 [Define if you want more run-time sanity checks for dataflow.])
432 fi
433 if test x$ac_assert_checking != x ; then
434   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
435 [Define if you want assertions enabled.  This is a cheap check.])
436 fi
437 if test x$ac_gimple_checking != x ; then
438   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
439 [Define if you want operations on GIMPLE (the basic data structure of
440 the high-level optimizers) to be checked for dynamic type safety at
441 runtime.  This is moderately expensive.])
442 fi
443 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
444 if test x$ac_runtime_checking != x ; then
445   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
446 [Define if you want runtime assertions enabled.  This is a cheap check.])
447 fi
448 if test x$ac_tree_checking != x ; then
449   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
450 [Define if you want all operations on trees (the basic data
451    structure of the front ends) to be checked for dynamic type safety
452    at runtime.  This is moderately expensive.  The tree browser debugging
453    routines will also be enabled by this option.
454    ])
455   TREEBROWSER=tree-browser.o
456 fi
457 if test x$ac_types_checking != x ; then
458   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
459 [Define if you want all gimple types to be verified after gimplifiation.
460    This is cheap.
461    ])
462 fi
463 AC_SUBST(TREEBROWSER)
464 if test x$ac_rtl_checking != x ; then
465   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
466 [Define if you want all operations on RTL (the basic data structure
467    of the optimizer and back end) to be checked for dynamic type safety
468    at runtime.  This is quite expensive.])
469 fi
470 if test x$ac_rtlflag_checking != x ; then
471   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
472 [Define if you want RTL flag accesses to be checked against the RTL
473    codes that are supported for each access macro.  This is relatively
474    cheap.])
475 fi
476 if test x$ac_gc_checking != x ; then
477   AC_DEFINE(ENABLE_GC_CHECKING, 1,
478 [Define if you want the garbage collector to do object poisoning and
479    other memory allocation checks.  This is quite expensive.])
480 fi
481 if test x$ac_gc_always_collect != x ; then
482   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
483 [Define if you want the garbage collector to operate in maximally
484    paranoid mode, validating the entire heap and collecting garbage at
485    every opportunity.  This is extremely expensive.])
486 fi
487 if test x$ac_fold_checking != x ; then
488   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
489 [Define if you want fold checked that it never destructs its argument.
490    This is quite expensive.])
491 fi
492 valgrind_path_defines=
493 valgrind_command=
494
495 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
496 dnl # an if statement.  This was the source of very frustrating bugs
497 dnl # in converting to autoconf 2.5x!
498 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
499
500 if test x$ac_valgrind_checking != x ; then
501   # It is certainly possible that there's valgrind but no valgrind.h.
502   # GCC relies on making annotations so we must have both.
503   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
504   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
505     [[#include <valgrind/memcheck.h>
506 #ifndef VALGRIND_DISCARD
507 #error VALGRIND_DISCARD not defined
508 #endif]])],
509   [gcc_cv_header_valgrind_memcheck_h=yes],
510   [gcc_cv_header_valgrind_memcheck_h=no])
511   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
512   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
513   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
514     [[#include <memcheck.h>
515 #ifndef VALGRIND_DISCARD
516 #error VALGRIND_DISCARD not defined
517 #endif]])],
518   [gcc_cv_header_memcheck_h=yes],
519   [gcc_cv_header_memcheck_h=no])
520   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
521   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
522         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
523   if test "x$valgrind_path" = "x" \
524     || (test $have_valgrind_h = no \
525         && test $gcc_cv_header_memcheck_h = no \
526         && test $gcc_cv_header_valgrind_memcheck_h = no); then
527         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
528   fi
529   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
530   valgrind_command="$valgrind_path -q"
531   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
532 [Define if you want to run subprograms and generated programs
533    through valgrind (a memory checker).  This is extremely expensive.])
534   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
535     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
536         [Define if valgrind's valgrind/memcheck.h header is installed.])
537   fi
538   if test $gcc_cv_header_memcheck_h = yes; then
539     AC_DEFINE(HAVE_MEMCHECK_H, 1,
540         [Define if valgrind's memcheck.h header is installed.])
541   fi
542 fi
543 AC_SUBST(valgrind_path_defines)
544 AC_SUBST(valgrind_command)
545
546 # Enable code coverage collection
547 AC_ARG_ENABLE(coverage,
548 [  --enable-coverage[=LEVEL]
549                           enable compiler's code coverage collection.
550                           Use to measure compiler performance and locate
551                           unused parts of the compiler. With LEVEL, specify
552                           optimization. Values are opt, noopt,
553                           default is noopt],
554 [case "${enableval}" in
555   yes|noopt)
556     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
557     ;;
558   opt)
559     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
560     ;;
561   no)
562     # a.k.a. --disable-coverage
563     coverage_flags=""
564     ;;
565   *)
566     AC_MSG_ERROR(unknown coverage setting $enableval)
567     ;;
568 esac],
569 [coverage_flags=""])
570 AC_SUBST(coverage_flags)
571
572 AC_ARG_ENABLE(gather-detailed-mem-stats, 
573 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
574 [enable_gather_detailed_mem_stats=no])
575 if test x$enable_gather_detailed_mem_stats = xyes ; then
576   AC_DEFINE(GATHER_STATISTICS, 1,
577         [Define to enable detailed memory allocation stats gathering.])
578 fi
579
580 # -------------------------------
581 # Miscenalleous configure options
582 # -------------------------------
583
584 # See if we are building gcc with C++.
585 AC_ARG_ENABLE(build-with-cxx,
586 [  --enable-build-with-cxx build with C++ compiler instead of C compiler],
587 ENABLE_BUILD_WITH_CXX=$enableval,
588 ENABLE_BUILD_WITH_CXX=no)
589 AC_SUBST(ENABLE_BUILD_WITH_CXX)
590
591 # With stabs
592 AC_ARG_WITH(stabs,
593 [  --with-stabs            arrange to use stabs instead of host debug format],
594 stabs="$with_stabs",
595 stabs=no)
596
597 # Determine whether or not multilibs are enabled.
598 AC_ARG_ENABLE(multilib,
599 [  --enable-multilib       enable library support for multiple ABIs],
600 [], [enable_multilib=yes])
601 AC_SUBST(enable_multilib)
602
603 # Enable __cxa_atexit for C++.
604 AC_ARG_ENABLE(__cxa_atexit,
605 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
606 [], [])
607
608 # Enable C extension for decimal float if target supports it.
609 AC_ARG_ENABLE(decimal-float,
610 [  --enable-decimal-float={no,yes,bid,dpd}
611                         enable decimal float extension to C.  Selecting 'bid'
612                         or 'dpd' choses which decimal floating point format
613                         to use],
614 [
615   case $enable_decimal_float in
616     yes | no | bid | dpd) ;;
617     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
618 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
619   esac
620 ],
621 [
622   case $target in
623     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
624       enable_decimal_float=yes
625       ;;
626     *)
627       AC_MSG_WARN(decimal float is not supported for this target, ignored)
628       enable_decimal_float=no
629       ;;
630   esac
631 ])
632
633 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
634 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
635 [Define to 1 to enable decimal float extension to C.])
636
637 # x86's use BID format instead of DPD
638 case x$enable_decimal_float in
639   xyes)
640     case $target in
641       i?86*-*-linux* | x86_64*-*-linux*)
642         enable_decimal_float=bid
643         ;;
644       *)
645         enable_decimal_float=dpd
646         ;;
647     esac
648     ;;
649   xno)
650     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
651     # dependency on libdecnumber.
652     enable_decimal_float=dpd
653     ;;
654 esac
655 AC_SUBST(enable_decimal_float)
656
657 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
658 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
659 [Define to 1 to specify that we are using the BID decimal floating
660 point format instead of DPD])
661
662 # Enable C extension for fixed-point arithmetic.
663 AC_ARG_ENABLE(fixed-point,
664 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
665 [
666 ],
667 [
668   case $target in
669     mips*-*-*)
670       case $host in
671         mips*-sgi-irix*)
672           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
673           enable_fixed_point=no
674           ;;
675         *)
676           enable_fixed_point=yes
677           ;;
678       esac
679       ;;
680     *)
681       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
682       enable_fixed_point=no
683       ;;
684   esac
685 ])
686 AC_SUBST(enable_fixed_point)
687
688 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
689 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
690 [Define to 1 to enable fixed-point arithmetic extension to C.])
691
692 # Enable threads
693 # Pass with no value to take the default
694 # Pass with a value to specify a thread package
695 AC_ARG_ENABLE(threads,
696 [  --enable-threads        enable thread usage for target GCC
697   --enable-threads=LIB    use LIB thread package for target GCC],,
698 [enable_threads=''])
699
700 AC_ARG_ENABLE(tls,
701 [  --enable-tls            enable or disable generation of tls code
702                           overriding the assembler check for tls support],
703 [
704   case $enable_tls in
705     yes | no) ;;
706     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
707 Valid choices are 'yes' and 'no'.]) ;;
708   esac
709 ], [enable_tls=''])
710
711 AC_ARG_ENABLE(objc-gc,
712 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
713                           the GNU Objective-C runtime],
714 if test x$enable_objc_gc = xno; then
715         objc_boehm_gc=''
716 else
717         objc_boehm_gc=1
718 fi,
719 objc_boehm_gc='')
720
721 AC_ARG_WITH(dwarf2,
722 [  --with-dwarf2           force the default debug format to be DWARF 2],
723 dwarf2="$with_dwarf2",
724 dwarf2=no)
725
726 AC_ARG_ENABLE(shared,
727 [  --disable-shared        don't provide a shared libgcc],
728 [
729   case $enable_shared in
730   yes | no) ;;
731   *)
732     enable_shared=no
733     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
734     for pkg in $enableval; do
735       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
736         enable_shared=yes
737       fi
738     done
739     IFS="$ac_save_ifs"
740     ;;
741   esac
742 ], [enable_shared=yes])
743 AC_SUBST(enable_shared)
744
745 AC_ARG_WITH(build-sysroot, 
746   [  --with-build-sysroot=sysroot
747                           use sysroot as the system root during the build])
748
749 AC_ARG_WITH(sysroot,
750 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
751 [
752  case ${with_sysroot} in
753  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
754  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
755  esac
756    
757  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
758  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
759         
760  if test "x$prefix" = xNONE; then
761   test_prefix=/usr/local
762  else
763   test_prefix=$prefix
764  fi
765  if test "x$exec_prefix" = xNONE; then
766   test_exec_prefix=$test_prefix
767  else
768   test_exec_prefix=$exec_prefix
769  fi
770  case ${TARGET_SYSTEM_ROOT} in
771  "${test_prefix}"|"${test_prefix}/"*|\
772  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
773  '${prefix}'|'${prefix}/'*|\
774  '${exec_prefix}'|'${exec_prefix}/'*)
775    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
776    TARGET_SYSTEM_ROOT_DEFINE="$t"
777    ;;
778  esac
779 ], [
780  TARGET_SYSTEM_ROOT=
781  TARGET_SYSTEM_ROOT_DEFINE=
782  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
783 ])
784 AC_SUBST(TARGET_SYSTEM_ROOT)
785 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
786 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
787
788 AC_ARG_WITH(specs,
789   [AS_HELP_STRING([--with-specs=SPECS],
790                   [add SPECS to driver command-line processing])],
791   [CONFIGURE_SPECS=$withval],
792   [CONFIGURE_SPECS=]
793 )
794 AC_SUBST(CONFIGURE_SPECS)
795
796 # Build with intermodule optimisations
797 AC_ARG_ENABLE(intermodule,
798 [  --enable-intermodule    build the compiler in one step],
799 [case ${enable_intermodule} in
800   yes) onestep="-onestep";;
801   *) onestep="";;
802 esac],
803 [onestep=""])
804 AC_SUBST(onestep)
805
806 ACX_PKGVERSION([GCC])
807 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
808
809 # Sanity check enable_languages in case someone does not run the toplevel
810 # configure # script.
811 AC_ARG_ENABLE(languages,
812 [  --enable-languages=LIST specify which front-ends to build],
813 [case ,${enable_languages}, in
814        ,,|,yes,)
815                 # go safe -- we cannot be much sure without the toplevel
816                 # configure's
817                 # analysis of which target libs are present and usable
818                 enable_languages=c
819                 ;;
820          *,all,*)
821                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
822                 ;;
823         *,c,*)
824                 ;;
825         *)
826                 enable_languages=c,${enable_languages}
827                 ;;
828 esac],
829 [enable_languages=c])
830
831 AC_ARG_WITH(multilib-list,
832 [  --with-multilib-list    Select multilibs (SH only)],
833 :,
834 with_multilib_list=default)
835
836 # -------------------------
837 # Checks for other programs
838 # -------------------------
839
840 AC_PROG_MAKE_SET
841
842 # Find some useful tools
843 AC_PROG_AWK
844 # We need awk to create options.c and options.h.
845 # Bail out if it's missing.
846 case ${AWK} in
847   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
848 esac
849
850 gcc_AC_PROG_LN_S
851 ACX_PROG_LN($LN_S)
852 AC_PROG_RANLIB
853 case "${host}" in
854 *-*-darwin*)
855   # By default, the Darwin ranlib will not treat common symbols as
856   # definitions when  building the archive table of contents.  Other 
857   # ranlibs do that; pass an option to the Darwin ranlib that makes
858   # it behave similarly.
859   ranlib_flags="-c" 
860   ;;
861 *)
862   ranlib_flags=""
863 esac
864 AC_SUBST(ranlib_flags)
865      
866 gcc_AC_PROG_INSTALL
867
868 # See if cmp has --ignore-initial.
869 gcc_AC_PROG_CMP_IGNORE_INITIAL
870
871 # See if we have the mktemp command.
872 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
873
874 # See if makeinfo has been installed and is modern enough
875 # that we can use it.
876 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
877   [GNU texinfo.* \([0-9][0-9.]*\)],
878   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
879 if test $gcc_cv_prog_makeinfo_modern = no; then
880   AC_MSG_WARN([
881 *** Makeinfo is missing or too old.
882 *** Info documentation will not be built.])
883   BUILD_INFO=
884 else
885   BUILD_INFO=info
886 fi
887 AC_SUBST(BUILD_INFO)
888
889 # Is pod2man recent enough to regenerate manpages?
890 AC_MSG_CHECKING([for recent Pod::Man])
891 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
892   AC_MSG_RESULT(yes)
893   GENERATED_MANPAGES=generated-manpages
894 else
895   AC_MSG_RESULT(no)
896   GENERATED_MANPAGES=
897 fi
898 AC_SUBST(GENERATED_MANPAGES)
899
900 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
901
902 # How about lex?
903 dnl Don't use AC_PROG_LEX; we insist on flex.
904 dnl LEXLIB is not useful in gcc.
905 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
906
907 # Bison?
908 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
909
910 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
911 # check for build == host before using them.
912
913 # NM
914 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
915   && test -d ../binutils ; then
916   NM='$(objdir)/../binutils/nm-new'
917 else
918   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
919 fi
920
921 # AR
922 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
923   && test -d ../binutils ; then
924   AR='$(objdir)/../binutils/ar'
925 else
926   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
927 fi
928
929
930 # --------------------
931 # Checks for C headers
932 # --------------------
933
934 # Need to reject headers which give warnings, so that the -Werror bootstrap
935 # works later. *sigh*  This needs to come before all header checks.
936 AC_PROG_CPP_WERROR
937
938 AC_HEADER_STDC
939 AC_HEADER_TIME
940 ACX_HEADER_STRING
941 AC_HEADER_SYS_WAIT
942 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
943                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
944                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
945                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
946
947 # Check for thread headers.
948 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
949 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
950
951 # These tests can't be done till we know if we have limits.h.
952 gcc_AC_C_CHAR_BIT
953 AC_C_BIGENDIAN
954
955 # --------
956 # UNSORTED
957 # --------
958
959
960 # These libraries may be used by collect2.
961 # We may need a special search path to get them linked.
962 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
963 [save_LIBS="$LIBS"
964 for libs in '' -lld -lmld \
965                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
966                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
967 do
968         LIBS="$libs"
969         AC_TRY_LINK_FUNC(ldopen,
970                 [gcc_cv_collect2_libs="$libs"; break])
971 done
972 LIBS="$save_LIBS"
973 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
974 case $gcc_cv_collect2_libs in
975         "none required")        ;;
976         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
977 esac
978 AC_SUBST(COLLECT2_LIBS)
979
980 # When building Ada code on Alpha, we need exc_resume which is usually in
981 # -lexc.  So test for it.
982 save_LIBS="$LIBS"
983 LIBS=
984 AC_SEARCH_LIBS(exc_resume, exc)
985 GNAT_LIBEXC="$LIBS"
986 LIBS="$save_LIBS"
987 AC_SUBST(GNAT_LIBEXC)
988
989 # Some systems put ldexp and frexp in libm instead of libc; assume
990 # they're both in the same place.  jcf-dump needs them.
991 save_LIBS="$LIBS"
992 LIBS=
993 AC_SEARCH_LIBS(ldexp, m)
994 LDEXP_LIB="$LIBS"
995 LIBS="$save_LIBS"
996 AC_SUBST(LDEXP_LIB)
997
998 # Use <inttypes.h> only if it exists,
999 # doesn't clash with <sys/types.h>, and declares intmax_t.
1000 AC_MSG_CHECKING(for inttypes.h)
1001 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
1002 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1003 [[#include <sys/types.h>
1004 #include <inttypes.h>]],
1005   [[intmax_t i = -1;]])],
1006   [gcc_cv_header_inttypes_h=yes],
1007   [gcc_cv_header_inttypes_h=no])])
1008 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
1009 if test $gcc_cv_header_inttypes_h = yes; then
1010   AC_DEFINE(HAVE_INTTYPES_H, 1,
1011         [Define if you have a working <inttypes.h> header file.])
1012 fi
1013
1014 dnl Disabled until we have a complete test for buggy enum bitfields.
1015 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1016
1017 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1018   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1019   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1020   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1021   putchar_unlocked putc_unlocked)
1022 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1023         sysconf strsignal getrusage nl_langinfo \
1024         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1025         gcc_UNLOCKED_FUNCS)
1026
1027 if test x$ac_cv_func_mbstowcs = xyes; then
1028   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1029 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1030 int main()
1031 {
1032   mbstowcs(0, "", 0);
1033   return 0;
1034 }]])],
1035     [gcc_cv_func_mbstowcs_works=yes],
1036     [gcc_cv_func_mbstowcs_works=no],
1037     [gcc_cv_func_mbstowcs_works=yes])])
1038   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1039     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1040   [Define this macro if mbstowcs does not crash when its
1041    first argument is NULL.])
1042   fi
1043 fi
1044
1045 AC_CHECK_TYPE(ssize_t, int)
1046 AC_CHECK_TYPE(caddr_t, char *)
1047
1048 gcc_AC_FUNC_MMAP_BLACKLIST
1049
1050 case "${host}" in
1051 *-*-*vms*)
1052   # Under VMS, vfork works very differently than on Unix. The standard test 
1053   # won't work, and it isn't easily adaptable. It makes more sense to
1054   # just force it.
1055   ac_cv_func_vfork_works=yes
1056   ;;
1057 esac
1058 AC_FUNC_FORK
1059
1060 AM_ICONV
1061 # Until we have in-tree GNU iconv:
1062 LIBICONV_DEP=
1063 AC_SUBST(LIBICONV_DEP)
1064
1065 AM_LC_MESSAGES
1066
1067 AM_LANGINFO_CODESET
1068
1069 # We will need to find libiberty.h and ansidecl.h
1070 saved_CFLAGS="$CFLAGS"
1071 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1072 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1073         strsignal strstr strverscmp \
1074         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1075         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1076 #include "ansidecl.h"
1077 #include "system.h"])
1078
1079 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1080 #include "ansidecl.h"
1081 #include "system.h"
1082 #ifdef HAVE_SYS_RESOURCE_H
1083 #include <sys/resource.h>
1084 #endif
1085 ])
1086
1087 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #ifdef HAVE_SYS_RESOURCE_H
1091 #include <sys/resource.h>
1092 #endif
1093 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1094 [Define to `long' if <sys/resource.h> doesn't define.])])
1095
1096 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1097 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1098 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1099 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1100 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1101 #include "ansidecl.h"
1102 #include "system.h"
1103 #ifdef HAVE_LDFCN_H
1104 #undef FREAD
1105 #undef FWRITE
1106 #include <ldfcn.h>
1107 #endif
1108 ])
1109
1110 gcc_AC_CHECK_DECLS(times, , ,[
1111 #include "ansidecl.h"
1112 #include "system.h"
1113 #ifdef HAVE_SYS_TIMES_H
1114 #include <sys/times.h>
1115 #endif
1116 ])
1117
1118 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1119 #include "ansidecl.h"
1120 #include "system.h"
1121 #include <signal.h>
1122 ])
1123
1124 # More time-related stuff.
1125 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1126 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1127 #include "ansidecl.h"
1128 #include "system.h"
1129 #ifdef HAVE_SYS_TIMES_H
1130 #include <sys/times.h>
1131 #endif
1132 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1133 if test $ac_cv_struct_tms = yes; then
1134   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1135   [Define if <sys/times.h> defines struct tms.])
1136 fi
1137
1138 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1139 # revisit after autoconf 2.50.
1140 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1141 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1142 #include "ansidecl.h"
1143 #include "system.h"
1144 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1145 if test $gcc_cv_type_clock_t = yes; then
1146   AC_DEFINE(HAVE_CLOCK_T, 1,
1147   [Define if <time.h> defines clock_t.])
1148 fi
1149
1150 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1151 CFLAGS="$saved_CFLAGS"
1152
1153 gcc_AC_INITFINI_ARRAY
1154
1155 # mkdir takes a single argument on some systems. 
1156 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1157
1158 # File extensions
1159 manext='.1'
1160 objext='.o'
1161 AC_SUBST(manext)
1162 AC_SUBST(objext)
1163
1164 # With Setjmp/Longjmp based exception handling.
1165 AC_ARG_ENABLE(sjlj-exceptions,
1166 [  --enable-sjlj-exceptions
1167                           arrange to use setjmp/longjmp exception handling],
1168 [case $target in
1169   *-*-hpux10*)
1170     if test $enableval != yes; then
1171       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1172       enableval=yes
1173     fi
1174     ;;
1175 esac
1176 force_sjlj_exceptions=yes],
1177 [case $target in
1178   *-*-hpux10*)
1179     force_sjlj_exceptions=yes
1180     enableval=yes
1181     ;;
1182   *)
1183     force_sjlj_exceptions=no
1184     ;;
1185 esac])
1186 if test $force_sjlj_exceptions = yes; then
1187   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1188   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1189     [Define 0/1 to force the choice for exception handling model.])
1190 fi
1191
1192 # For platforms with the unwind ABI which includes an unwind library,
1193 # libunwind, we can choose to use the system libunwind.
1194 # config.gcc also contains tests of with_system_libunwind.
1195 GCC_CHECK_UNWIND_GETIPINFO
1196
1197 # --------------------------------------------------------
1198 # Build, host, and target specific configuration fragments
1199 # --------------------------------------------------------
1200
1201 # Collect build-machine-specific information.
1202 . ${srcdir}/config.build
1203
1204 # Collect host-machine-specific information.
1205 . ${srcdir}/config.host
1206
1207 target_gtfiles=
1208
1209 # Collect target-machine-specific information.
1210 . ${srcdir}/config.gcc
1211
1212 extra_objs="${host_extra_objs} ${extra_objs}"
1213 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1214
1215 # Default the target-machine variables that were not explicitly set.
1216 if test x"$tm_file" = x
1217 then tm_file=$cpu_type/$cpu_type.h; fi
1218
1219 if test x"$extra_headers" = x
1220 then extra_headers=; fi
1221
1222 if test x$md_file = x
1223 then md_file=$cpu_type/$cpu_type.md; fi
1224
1225 if test x$out_file = x
1226 then out_file=$cpu_type/$cpu_type.c; fi
1227
1228 if test x"$tmake_file" = x
1229 then tmake_file=$cpu_type/t-$cpu_type
1230 fi
1231
1232 if test x"$dwarf2" = xyes
1233 then tm_file="$tm_file tm-dwarf2.h"
1234 fi
1235
1236 # Say what files are being used for the output code and MD file.
1237 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1238 echo "Using \`$srcdir/config/$md_file' as machine description file."
1239
1240 # If any of the xm_file variables contain nonexistent files, warn
1241 # about them and drop them.
1242
1243 bx=
1244 for x in $build_xm_file; do
1245   if    test -f $srcdir/config/$x
1246   then      bx="$bx $x"
1247   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1248   fi
1249 done
1250 build_xm_file="$bx"
1251
1252 hx=
1253 for x in $host_xm_file; do
1254   if    test -f $srcdir/config/$x
1255   then      hx="$hx $x"
1256   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1257   fi
1258 done
1259 host_xm_file="$hx"
1260
1261 tx=
1262 for x in $xm_file; do
1263   if    test -f $srcdir/config/$x
1264   then      tx="$tx $x"
1265   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1266   fi
1267 done
1268 xm_file="$tx"
1269
1270 count=a
1271 for f in $tm_file; do
1272         count=${count}x
1273 done
1274 if test $count = ax; then
1275         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1276 else
1277         echo "Using the following target machine macro files:"
1278         for f in $tm_file; do
1279                 echo "  $srcdir/config/$f"
1280         done
1281 fi
1282
1283 if test x$need_64bit_hwint = xyes; then
1284         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1285 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1286 fi
1287
1288 if test x$use_long_long_for_widest_fast_int = xyes; then
1289         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1290 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1291 efficiently supported by the host hardware.])
1292 fi
1293
1294 count=a
1295 for f in $host_xm_file; do
1296         count=${count}x
1297 done
1298 if test $count = a; then
1299         :
1300 elif test $count = ax; then
1301         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1302 else
1303         echo "Using the following host machine macro files:"
1304         for f in $host_xm_file; do
1305                 echo "  $srcdir/config/$f"
1306         done
1307 fi
1308 echo "Using ${out_host_hook_obj} for host machine hooks."
1309
1310 if test "$host_xm_file" != "$build_xm_file"; then
1311         count=a
1312         for f in $build_xm_file; do
1313                 count=${count}x
1314         done
1315         if test $count = a; then
1316                 :
1317         elif test $count = ax; then
1318                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1319         else
1320                 echo "Using the following build machine macro files:"
1321                 for f in $build_xm_file; do
1322                         echo "  $srcdir/config/$f"
1323                 done
1324         fi
1325 fi
1326
1327 case ${host} in
1328   powerpc*-*-darwin*)
1329     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1330       gcc_cv_mcontext_underscores,
1331       AC_COMPILE_IFELSE([
1332 #include <sys/cdefs.h>
1333 #include <sys/signal.h>
1334 #include <ucontext.h>
1335 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1336 ],
1337         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1338       if test $gcc_cv_mcontext_underscores = yes; then
1339         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1340           [mcontext_t fields start with __])
1341       fi
1342     ;;
1343 esac
1344
1345 # ---------
1346 # Threading
1347 # ---------
1348
1349 # Check if a valid thread package
1350 case ${enable_threads} in
1351   "" | no)
1352     # No threads
1353     target_thread_file='single'
1354     ;;
1355   yes)
1356     # default
1357     target_thread_file='single'
1358     ;;
1359   aix | dce | gnat | irix | posix | posix95 | rtems | \
1360   single | solaris | vxworks | win32 | mipssde)
1361     target_thread_file=${enable_threads}
1362     ;;
1363   *)
1364     echo "${enable_threads} is an unknown thread package" 1>&2
1365     exit 1
1366     ;;
1367 esac
1368
1369 if test x${thread_file} = x; then
1370   # No thread file set by target-specific clauses in config.gcc,
1371   # so use file chosen by default logic above
1372   thread_file=${target_thread_file}
1373 fi
1374
1375 # Make gthr-default.h if we have a thread file.
1376 gthread_flags=
1377 if test $thread_file != single; then
1378   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1379   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1380     rm -f gthr-default.h-t
1381   else
1382     mv -f gthr-default.h-t gthr-default.h
1383   fi
1384   gthread_flags=-DHAVE_GTHR_DEFAULT
1385 fi
1386 AC_SUBST(gthread_flags)
1387
1388 # --------
1389 # UNSORTED
1390 # --------
1391
1392 use_cxa_atexit=no
1393 if test x$enable___cxa_atexit = xyes || \
1394    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1395   if test x$host = x$target; then
1396     case $host in
1397       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1398       # keyed to flag_use_cxa_atexit
1399       *-*-mingw32*)
1400         use_cxa_atexit=yes
1401         ;;
1402       *)
1403         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1404           [echo "__cxa_atexit can't be enabled on this target"])
1405         ;;
1406     esac
1407   else
1408     # We can't check for __cxa_atexit when building a cross, so assume
1409     # it is available 
1410     use_cxa_atexit=yes
1411   fi
1412   if test x$use_cxa_atexit = xyes; then
1413     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1414       [Define if you want to use __cxa_atexit, rather than atexit, to
1415       register C++ destructors for local statics and global objects.
1416       This is essential for fully standards-compliant handling of
1417       destructors, but requires __cxa_atexit in libc.])
1418   fi
1419 fi
1420
1421 # Look for a file containing extra machine modes.
1422 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1423   extra_modes_file='$(srcdir)'/config/${extra_modes}
1424   AC_SUBST(extra_modes_file)
1425   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1426   [Define to the name of a file containing a list of extra machine modes
1427    for this architecture.])
1428 fi
1429
1430 # Convert extra_options into a form suitable for Makefile use.
1431 extra_opt_files=
1432 for f in $extra_options; do
1433   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1434 done
1435 AC_SUBST(extra_opt_files)
1436
1437 # auto-host.h is the file containing items generated by autoconf and is
1438 # the first file included by config.h.
1439 # If host=build, it is correct to have bconfig include auto-host.h
1440 # as well.  If host!=build, we are in error and need to do more 
1441 # work to find out the build config parameters.
1442 if test x$host = x$build
1443 then
1444         build_auto=auto-host.h
1445 else
1446         # We create a subdir, then run autoconf in the subdir.
1447         # To prevent recursion we set host and build for the new
1448         # invocation of configure to the build for this invocation
1449         # of configure. 
1450         tempdir=build.$$
1451         rm -rf $tempdir
1452         mkdir $tempdir
1453         cd $tempdir
1454         case ${srcdir} in
1455         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1456         *) realsrcdir=../${srcdir};;
1457         esac
1458         saved_CFLAGS="${CFLAGS}"
1459         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1460         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1461         ${realsrcdir}/configure \
1462                 --enable-languages=${enable_languages-all} \
1463                 --target=$target_alias --host=$build_alias --build=$build_alias
1464         CFLAGS="${saved_CFLAGS}"
1465
1466         # We just finished tests for the build machine, so rename
1467         # the file auto-build.h in the gcc directory.
1468         mv auto-host.h ../auto-build.h
1469         cd ..
1470         rm -rf $tempdir
1471         build_auto=auto-build.h
1472 fi
1473 AC_SUBST(build_subdir)
1474
1475 tm_file="${tm_file} defaults.h"
1476 tm_p_file="${tm_p_file} tm-preds.h"
1477 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1478 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1479 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1480 # put this back in temporarily.
1481 xm_file="auto-host.h ansidecl.h ${xm_file}"
1482
1483 # --------
1484 # UNSORTED
1485 # --------
1486
1487 changequote(,)dnl
1488 # Compile in configure arguments.
1489 if test -f configargs.h ; then
1490         # Being re-configured.
1491         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1492         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1493 else
1494         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1495 fi
1496
1497 # Double all backslashes and backslash all quotes to turn
1498 # gcc_config_arguments into a C string.
1499 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1500 $gcc_config_arguments
1501 EOF
1502 gcc_config_arguments_str=`cat conftest.out`
1503 rm -f conftest.out
1504
1505 cat > configargs.h <<EOF
1506 /* Generated automatically. */
1507 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1508 static const char thread_model[] = "$thread_file";
1509
1510 static const struct {
1511   const char *name, *value;
1512 } configure_default_options[] = $configure_default_options;
1513 EOF
1514 changequote([,])dnl
1515
1516 changequote(,)dnl
1517 gcc_BASEVER=`cat $srcdir/BASE-VER`
1518 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1519 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1520 if test -f $srcdir/REVISION ; then
1521         gcc_REVISION=`cat $srcdir/REVISION`
1522 else
1523         gcc_REVISION=""
1524 fi
1525 cat > plugin-version.h <<EOF
1526 #include "configargs.h"
1527
1528 static char basever[] = "$gcc_BASEVER";
1529 static char datestamp[] = "$gcc_DATESTAMP";
1530 static char devphase[] = "$gcc_DEVPHASE";
1531 static char revision[] = "$gcc_REVISION";
1532
1533 /* FIXME plugins: We should make the version information more precise.
1534    One way to do is to add a checksum. */
1535
1536 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1537                                                 devphase, revision,
1538                                                 configuration_arguments};
1539 EOF
1540 changequote([,])dnl
1541
1542 # Internationalization
1543 ZW_GNU_GETTEXT_SISTER_DIR
1544
1545 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1546 # -liconv on the link line twice.
1547 case "$LIBINTL" in *$LIBICONV*)
1548         LIBICONV= ;;
1549 esac
1550
1551 AC_ARG_ENABLE(secureplt,
1552 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1553 [], [])
1554
1555 AC_ARG_ENABLE(cld,
1556 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1557 [enable_cld=no])
1558
1559 # Windows32 Registry support for specifying GCC installation paths.
1560 AC_ARG_ENABLE(win32-registry,
1561 [  --disable-win32-registry
1562                           disable lookup of installation paths in the
1563                           Registry on Windows hosts
1564   --enable-win32-registry enable registry lookup (default)
1565   --enable-win32-registry=KEY
1566                           use KEY instead of GCC version as the last portion
1567                           of the registry key],,)
1568
1569 case $host_os in
1570   win32 | pe | cygwin* | mingw32* | uwin*)
1571     if test "x$enable_win32_registry" != xno; then
1572       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1573     fi
1574
1575     if test "x$enable_win32_registry" != xno; then
1576       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1577   [Define to 1 if installation paths should be looked up in the Windows
1578    Registry. Ignored on non-Windows hosts.])
1579
1580       if test "x$enable_win32_registry" != xyes \
1581          && test "x$enable_win32_registry" != x; then
1582         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1583   [Define to be the last component of the Windows registry key under which
1584    to look for installation paths.  The full key used will be 
1585    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1586    The default is the GCC version number.])
1587       fi
1588     fi
1589   ;;
1590 esac
1591
1592 # Get an absolute path to the GCC top-level source directory
1593 holddir=`${PWDCMD-pwd}`
1594 cd $srcdir
1595 topdir=`${PWDCMD-pwd}`
1596 cd $holddir
1597
1598 # Conditionalize the makefile for this host machine.
1599 xmake_file=
1600 for f in ${host_xmake_file}
1601 do
1602         if test -f ${srcdir}/config/$f
1603         then
1604                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1605         fi
1606 done
1607
1608 # Conditionalize the makefile for this target machine.
1609 tmake_file_=
1610 for f in ${tmake_file}
1611 do
1612         if test -f ${srcdir}/config/$f
1613         then
1614                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1615         fi
1616 done
1617 tmake_file="${tmake_file_}"
1618
1619 out_object_file=`basename $out_file .c`.o
1620
1621 tm_file_list="options.h"
1622 tm_include_list="options.h"
1623 for f in $tm_file; do
1624   case $f in
1625     ./* )
1626        f=`echo $f | sed 's/^..//'`
1627        tm_file_list="${tm_file_list} $f"
1628        tm_include_list="${tm_include_list} $f"
1629        ;;
1630     defaults.h )
1631        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1632        tm_include_list="${tm_include_list} $f"
1633        ;;
1634     * )
1635        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1636        tm_include_list="${tm_include_list} config/$f"
1637        ;;
1638   esac
1639 done
1640
1641 tm_p_file_list=
1642 tm_p_include_list=
1643 for f in $tm_p_file; do
1644   case $f in
1645     tm-preds.h )
1646        tm_p_file_list="${tm_p_file_list} $f"
1647        tm_p_include_list="${tm_p_include_list} $f"
1648        ;;
1649     * )
1650        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1651        tm_p_include_list="${tm_p_include_list} config/$f"
1652   esac
1653 done
1654
1655 xm_file_list=
1656 xm_include_list=
1657 for f in $xm_file; do
1658   case $f in
1659     ansidecl.h )
1660        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1661        xm_include_list="${xm_include_list} $f"
1662        ;;
1663     auto-host.h )
1664        xm_file_list="${xm_file_list} $f"
1665        xm_include_list="${xm_include_list} $f"
1666        ;;
1667     * )
1668        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1669        xm_include_list="${xm_include_list} config/$f"
1670        ;;
1671   esac
1672 done
1673
1674 host_xm_file_list=
1675 host_xm_include_list=
1676 for f in $host_xm_file; do
1677   case $f in
1678     ansidecl.h )
1679        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1680        host_xm_include_list="${host_xm_include_list} $f"
1681        ;;
1682     auto-host.h )
1683        host_xm_file_list="${host_xm_file_list} $f"
1684        host_xm_include_list="${host_xm_include_list} $f"
1685        ;;
1686     * )
1687        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1688        host_xm_include_list="${host_xm_include_list} config/$f"
1689        ;;
1690   esac
1691 done
1692
1693 build_xm_file_list=
1694 for f in $build_xm_file; do
1695   case $f in
1696     ansidecl.h )
1697        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1698        build_xm_include_list="${build_xm_include_list} $f"
1699        ;;
1700     auto-build.h | auto-host.h )
1701        build_xm_file_list="${build_xm_file_list} $f"
1702        build_xm_include_list="${build_xm_include_list} $f"
1703        ;;
1704     * )
1705        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1706        build_xm_include_list="${build_xm_include_list} config/$f"
1707        ;;
1708   esac
1709 done
1710
1711 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1712 # cross-compiler which does not use the native headers and libraries.
1713 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1714 CROSS=                                          AC_SUBST(CROSS)
1715 ALL=all.internal                                AC_SUBST(ALL)
1716 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1717
1718 if test "x$with_build_sysroot" != x; then
1719   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1720 else
1721   # This value is used, even on a native system, because 
1722   # CROSS_SYSTEM_HEADER_DIR is just 
1723   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1724   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1725 fi
1726
1727 if test x$host != x$target
1728 then
1729         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1730         ALL=all.cross
1731         SYSTEM_HEADER_DIR=$build_system_header_dir
1732         case "$host","$target" in
1733         # Darwin crosses can use the host system's libraries and headers,
1734         # because of the fat library support.  Of course, it must be the
1735         # same version of Darwin on both sides.  Allow the user to
1736         # just say --target=foo-darwin without a version number to mean
1737         # "the version on this system".
1738             *-*-darwin*,*-*-darwin*)
1739                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1740                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1741                 if test $hostos = $targetos -o $targetos = darwin ; then
1742                     CROSS=
1743                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1744                     with_headers=yes
1745                 fi
1746                 ;;
1747
1748             i?86-*-*,x86_64-*-* \
1749             | powerpc*-*-*,powerpc64*-*-*)
1750                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1751         esac
1752 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1753         SYSTEM_HEADER_DIR=$build_system_header_dir 
1754 fi
1755
1756 # If this is a cross-compiler that does not
1757 # have its own set of headers then define
1758 # inhibit_libc
1759
1760 # If this is using newlib, without having the headers available now,
1761 # then define inhibit_libc in LIBGCC2_CFLAGS.
1762 # This prevents libgcc2 from containing any code which requires libc
1763 # support.
1764 : ${inhibit_libc=false}
1765 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1766        test x$with_newlib = xyes ; } &&
1767      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1768        inhibit_libc=true
1769 fi
1770 AC_SUBST(inhibit_libc)
1771
1772 # When building gcc with a cross-compiler, we need to adjust things so
1773 # that the generator programs are still built with the native compiler.
1774 # Also, we cannot run fixincludes.
1775
1776 # These are the normal (build=host) settings:
1777 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1778 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1779 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1780 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1781
1782 # And these apply if build != host, or we are generating coverage data
1783 if test x$build != x$host || test "x$coverage_flags" != x
1784 then
1785     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1786     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1787 fi
1788
1789 # Expand extra_headers to include complete path.
1790 # This substitutes for lots of t-* files.
1791 extra_headers_list=
1792 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1793 for file in ${extra_headers} ; do
1794   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1795 done
1796
1797 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1798 if test x"$use_gcc_tgmath" = xyes
1799 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1800 fi
1801
1802 # Define collect2 in Makefile.
1803 case $host_can_use_collect2 in
1804   no) collect2= ;;
1805   *) collect2='collect2$(exeext)' ;;
1806 esac
1807 AC_SUBST([collect2])
1808
1809 # Add a definition of USE_COLLECT2 if system wants one.
1810 case $use_collect2 in
1811   no) use_collect2= ;;
1812   "") ;;
1813   *) 
1814     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1815     xm_defines="${xm_defines} USE_COLLECT2"
1816     case $host_can_use_collect2 in
1817       no)
1818         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1819         ;;
1820     esac
1821     ;;
1822 esac
1823
1824 # ---------------------------
1825 # Assembler & linker features
1826 # ---------------------------
1827
1828 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1829 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1830 # However when ld-new is first executed from the build tree, libtool will
1831 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1832 # to the build tree.  While doing this we need to use the previous-stage
1833 # linker, or we have an infinite loop.  The presence of a shell script as
1834 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1835 # the gcc/collect-ld script.  So we need to know how libtool works, or
1836 # exec-tool will fail.
1837
1838 m4_defun([_LT_CONFIG_COMMANDS], [])
1839 AC_PROG_LIBTOOL
1840 AC_SUBST(objdir)
1841 AC_SUBST(enable_fast_install)
1842
1843 # Identify the assembler which will work hand-in-glove with the newly
1844 # built GCC, so that we can examine its features.  This is the assembler
1845 # which will be driven by the driver program.
1846 #
1847 # If build != host, and we aren't building gas in-tree, we identify a
1848 # build->target assembler and hope that it will have the same features
1849 # as the host->target assembler we'll be using.
1850 gcc_cv_gas_major_version=
1851 gcc_cv_gas_minor_version=
1852 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1853
1854 m4_pattern_allow([AS_FOR_TARGET])dnl
1855 AS_VAR_SET_IF(gcc_cv_as,, [
1856 if test -x "$DEFAULT_ASSEMBLER"; then
1857         gcc_cv_as="$DEFAULT_ASSEMBLER"
1858 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1859      && test -f ../gas/Makefile \
1860      && test x$build = x$host; then
1861         gcc_cv_as=../gas/as-new$build_exeext
1862 elif test -x as$build_exeext; then
1863         # Build using assembler in the current directory.
1864         gcc_cv_as=./as$build_exeext
1865 elif test -x $AS_FOR_TARGET; then
1866         gcc_cv_as="$AS_FOR_TARGET"
1867 else
1868         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1869 fi])
1870
1871 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1872 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1873 case "$ORIGINAL_AS_FOR_TARGET" in
1874   ./as | ./as$build_exeext) ;;
1875   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1876 esac 
1877
1878 AC_MSG_CHECKING(what assembler to use)
1879 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1880   # Single tree build which includes gas.  We want to prefer it
1881   # over whatever linker top-level may have detected, since
1882   # we'll use what we're building after installation anyway.
1883   AC_MSG_RESULT(newly built gas)
1884   in_tree_gas=yes
1885   _gcc_COMPUTE_GAS_VERSION
1886   in_tree_gas_is_elf=no
1887   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1888      || (grep 'obj_format = multi' ../gas/Makefile \
1889          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1890   then
1891     in_tree_gas_is_elf=yes
1892   fi
1893 else
1894   AC_MSG_RESULT($gcc_cv_as)
1895   in_tree_gas=no
1896 fi
1897
1898 # Identify the linker which will work hand-in-glove with the newly
1899 # built GCC, so that we can examine its features.  This is the linker
1900 # which will be driven by the driver program.
1901 #
1902 # If build != host, and we aren't building gas in-tree, we identify a
1903 # build->target linker and hope that it will have the same features
1904 # as the host->target linker we'll be using.
1905 gcc_cv_gld_major_version=
1906 gcc_cv_gld_minor_version=
1907 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1908 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1909
1910 AS_VAR_SET_IF(gcc_cv_ld,, [
1911 if test -x "$DEFAULT_LINKER"; then
1912         gcc_cv_ld="$DEFAULT_LINKER"
1913 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1914      && test -f ../ld/Makefile \
1915      && test x$build = x$host; then
1916         gcc_cv_ld=../ld/ld-new$build_exeext
1917 elif test -x collect-ld$build_exeext; then
1918         # Build using linker in the current directory.
1919         gcc_cv_ld=./collect-ld$build_exeext
1920 elif test -x $LD_FOR_TARGET; then
1921         gcc_cv_ld="$LD_FOR_TARGET"
1922 else
1923         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1924 fi])
1925
1926 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1927 PLUGIN_LD=`basename $gcc_cv_ld`
1928 AC_ARG_WITH(plugin-ld,
1929 [  --with-plugin-ld=[[ARG]]  specify the plugin linker],
1930 [if test x"$withval" != x; then
1931    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1932    PLUGIN_LD="$withval"
1933  fi])
1934 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1935 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1936
1937 # Check to see if we are using gold instead of ld
1938 AC_MSG_CHECKING(whether we are using gold)
1939 ld_is_gold=no
1940 if test x$gcc_cv_ld != x; then
1941   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
1942      | grep "GNU gold" > /dev/null; then
1943     ld_is_gold=yes
1944   fi
1945 fi
1946 AC_MSG_RESULT($ld_is_gold)
1947
1948 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1949 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1950 case "$ORIGINAL_LD_FOR_TARGET" in
1951   ./collect-ld | ./collect-ld$build_exeext) ;;
1952   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1953 esac 
1954
1955 AC_MSG_CHECKING(what linker to use)
1956 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1957         # Single tree build which includes ld.  We want to prefer it
1958         # over whatever linker top-level may have detected, since
1959         # we'll use what we're building after installation anyway.
1960         AC_MSG_RESULT(newly built ld)
1961         in_tree_ld=yes
1962         in_tree_ld_is_elf=no
1963         if (grep 'EMUL = .*elf' ../ld/Makefile \
1964             || grep 'EMUL = .*linux' ../ld/Makefile \
1965             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1966           in_tree_ld_is_elf=yes
1967         fi
1968         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1969         do
1970 changequote(,)dnl
1971                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1972                 if test x$gcc_cv_gld_version != x; then
1973                         break
1974                 fi
1975         done
1976         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1977         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1978 changequote([,])dnl
1979 else
1980         AC_MSG_RESULT($gcc_cv_ld)
1981         in_tree_ld=no
1982 fi
1983
1984 # Figure out what nm we will be using.
1985 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1986 AS_VAR_SET_IF(gcc_cv_nm,, [
1987 if test -f $gcc_cv_binutils_srcdir/configure.in \
1988      && test -f ../binutils/Makefile \
1989      && test x$build = x$host; then
1990         gcc_cv_nm=../binutils/nm-new$build_exeext
1991 elif test -x nm$build_exeext; then
1992         gcc_cv_nm=./nm$build_exeext
1993 elif test -x $NM_FOR_TARGET; then
1994         gcc_cv_nm="$NM_FOR_TARGET"
1995 else
1996         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1997 fi])
1998
1999 AC_MSG_CHECKING(what nm to use)
2000 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2001         # Single tree build which includes binutils.
2002         AC_MSG_RESULT(newly built nm)
2003         in_tree_nm=yes
2004 else
2005         AC_MSG_RESULT($gcc_cv_nm)
2006         in_tree_nm=no
2007 fi
2008
2009 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2010 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2011 case "$ORIGINAL_NM_FOR_TARGET" in
2012   ./nm | ./nm$build_exeext) ;;
2013   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2014 esac
2015
2016
2017 # Figure out what objdump we will be using.
2018 AS_VAR_SET_IF(gcc_cv_objdump,, [
2019 if test -f $gcc_cv_binutils_srcdir/configure.in \
2020      && test -f ../binutils/Makefile \
2021      && test x$build = x$host; then
2022         # Single tree build which includes binutils.
2023         gcc_cv_objdump=../binutils/objdump$build_exeext
2024 elif test -x objdump$build_exeext; then
2025         gcc_cv_objdump=./objdump$build_exeext
2026 elif test -x $OBJDUMP_FOR_TARGET; then
2027         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2028 else
2029         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2030 fi])
2031
2032 AC_MSG_CHECKING(what objdump to use)
2033 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2034         # Single tree build which includes binutils.
2035         AC_MSG_RESULT(newly built objdump)
2036 elif test x$gcc_cv_objdump = x; then
2037         AC_MSG_RESULT(not found)
2038 else
2039         AC_MSG_RESULT($gcc_cv_objdump)
2040 fi
2041
2042 # Figure out what readelf we will be using.
2043 AS_VAR_SET_IF(gcc_cv_readelf,, [
2044 if test -f $gcc_cv_binutils_srcdir/configure.in \
2045      && test -f ../binutils/Makefile \
2046      && test x$build = x$host; then
2047         # Single tree build which includes binutils.
2048         gcc_cv_readelf=../binutils/readelf$build_exeext
2049 elif test -x readelf$build_exeext; then
2050         gcc_cv_readelf=./readelf$build_exeext
2051 else
2052         AC_PATH_PROG(gcc_cv_readelf, readelf)
2053 fi])
2054
2055 AC_MSG_CHECKING(what readelf to use)
2056 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2057         # Single tree build which includes binutils.
2058         AC_MSG_RESULT(newly built readelf)
2059 elif test x$gcc_cv_readelf = x; then
2060         AC_MSG_RESULT(not found)
2061 else
2062         AC_MSG_RESULT($gcc_cv_readelf)
2063 fi
2064
2065 # Figure out what assembler alignment features are present.
2066 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2067  [2,6,0],,
2068 [.balign 4
2069 .p2align 2],,
2070 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2071   [Define if your assembler supports .balign and .p2align.])])
2072
2073 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2074  [2,8,0],,
2075  [.p2align 4,,7],,
2076 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2077   [Define if your assembler supports specifying the maximum number
2078    of bytes to skip when using the GAS .p2align command.])])
2079
2080 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2081  [2,8,0],,
2082  [.literal16],,
2083 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2084   [Define if your assembler supports .literal16.])])
2085
2086 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2087  [elf,2,9,0],,
2088  [conftest_label1: .word 0
2089 .subsection -1
2090 conftest_label2: .word 0
2091 .previous],
2092  [if test x$gcc_cv_nm != x; then
2093     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2094     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2095     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2096     then :
2097     else gcc_cv_as_subsection_m1=yes
2098     fi
2099     rm -f conftest.nm1 conftest.nm2
2100   fi],
2101  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2102   [Define if your assembler supports .subsection and .subsection -1 starts
2103    emitting at the beginning of your section.])])
2104
2105 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2106  [2,2,0],,
2107  [      .weak foobar],,
2108 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2109
2110 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2111  [2,17,0],,
2112  [      .weakref foobar, barfnot],,
2113 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2114
2115 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2116  [2,15,91],,
2117  [      .SPACE $TEXT$
2118         .NSUBSPA $CODE$,COMDAT],,
2119 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2120
2121 # .hidden needs to be supported in both the assembler and the linker,
2122 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2123 # This is irritatingly difficult to feature test for; we have to check the
2124 # date string after the version number.  If we've got an in-tree
2125 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2126 # to be safe.
2127 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2128 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2129  [elf,2,13,0],,
2130 [       .hidden foobar
2131 foobar:])
2132
2133 changequote(,)dnl
2134 if test $in_tree_ld != yes ; then
2135   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2136   if test x"$ld_is_gold" = xyes; then
2137     gcc_cv_ld_hidden=yes
2138   elif echo "$ld_ver" | grep GNU > /dev/null; then
2139     ld_vers=`echo $ld_ver | sed -n \
2140         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2141     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2142     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2143     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2144     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2145   else
2146     case "${target}" in
2147       *-*-solaris2*)
2148         #
2149         # Solaris 2 ld -V output looks like this for a regular version:
2150         #
2151         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1699
2152         #
2153         # but test versions add stuff at the end:
2154         #
2155         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1701:onnv-ab196087-6931056-03/25/10
2156         #
2157         ld_ver=`$gcc_cv_ld -V 2>&1`
2158         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2159           ld_vers=`echo $ld_ver | sed -n \
2160             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2161           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2162           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2163         fi
2164         ;;
2165     esac
2166   fi
2167 fi
2168 changequote([,])dnl
2169
2170 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2171 [[if test $in_tree_ld = yes ; then
2172   gcc_cv_ld_hidden=no
2173   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2174      && test $in_tree_ld_is_elf = yes; then
2175      gcc_cv_ld_hidden=yes
2176   fi
2177 else
2178   gcc_cv_ld_hidden=yes
2179   if echo "$ld_ver" | grep GNU > /dev/null; then
2180     if test 0"$ld_date" -lt 20020404; then
2181       if test -n "$ld_date"; then
2182         # If there was date string, but was earlier than 2002-04-04, fail
2183         gcc_cv_ld_hidden=no
2184       elif test -z "$ld_vers"; then
2185         # If there was no date string nor ld version number, something is wrong
2186         gcc_cv_ld_hidden=no
2187       else
2188         test -z "$ld_vers_patch" && ld_vers_patch=0
2189         if test "$ld_vers_major" -lt 2; then
2190           gcc_cv_ld_hidden=no
2191         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2192           gcc_cv_ld_hidden="no"
2193         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2194           gcc_cv_ld_hidden=no
2195         fi
2196       fi
2197     fi
2198   else
2199     case "${target}" in
2200       hppa64*-*-hpux* | ia64*-*-hpux*)
2201         gcc_cv_ld_hidden=yes
2202         ;;
2203       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2204         gcc_cv_ld_hidden=yes
2205         ;;
2206       *)
2207         gcc_cv_ld_hidden=no
2208         ;;
2209     esac
2210   fi
2211 fi]])
2212 libgcc_visibility=no
2213 AC_SUBST(libgcc_visibility)
2214 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2215 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2216   libgcc_visibility=yes
2217   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2218   [Define if your assembler and linker support .hidden.])
2219 fi
2220
2221 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2222 gcc_cv_ld_ro_rw_mix=unknown
2223 if test $in_tree_ld = yes ; then
2224   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2225      && test $in_tree_ld_is_elf = yes; then
2226     gcc_cv_ld_ro_rw_mix=read-write
2227   fi
2228 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2229   echo '.section myfoosect, "a"' > conftest1.s
2230   echo '.section myfoosect, "aw"' > conftest2.s
2231   echo '.byte 1' >> conftest2.s
2232   echo '.section myfoosect, "a"' > conftest3.s
2233   echo '.byte 0' >> conftest3.s
2234   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2235      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2236      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2237      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2238         conftest2.o conftest3.o > /dev/null 2>&1; then
2239     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2240                          | sed -e '/myfoosect/!d' -e N`
2241     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2242       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2243         gcc_cv_ld_ro_rw_mix=read-only
2244       else
2245         gcc_cv_ld_ro_rw_mix=read-write
2246       fi
2247     fi
2248   fi
2249 changequote(,)dnl
2250   rm -f conftest.* conftest[123].*
2251 changequote([,])dnl
2252 fi
2253 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2254         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2255   [Define if your linker links a mix of read-only
2256    and read-write sections into a read-write section.])
2257 fi
2258 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2259
2260 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2261 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2262   [elf,2,11,0],,
2263 [       .data
2264         .uleb128 L2 - L1
2265 L1:
2266         .uleb128 1280
2267         .sleb128 -1010
2268 L2:],
2269 [[# GAS versions before 2.11 do not support uleb128,
2270   # despite appearing to.
2271   # ??? There exists an elf-specific test that will crash
2272   # the assembler.  Perhaps it's better to figure out whether
2273   # arbitrary sections are supported and try the test.
2274   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2275   if echo "$as_ver" | grep GNU > /dev/null; then
2276     as_vers=`echo $as_ver | sed -n \
2277         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2278     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2279     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2280     if test $as_major -eq 2 && test $as_minor -lt 11
2281     then :
2282     else gcc_cv_as_leb128=yes
2283     fi
2284   fi]],
2285   [AC_DEFINE(HAVE_AS_LEB128, 1,
2286     [Define if your assembler supports .sleb128 and .uleb128.])])
2287
2288 # Check if we have assembler support for unwind directives.
2289 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2290   ,,
2291 [       .text
2292         .cfi_startproc
2293         .cfi_offset 0, 0
2294         .cfi_same_value 1
2295         .cfi_def_cfa 1, 2
2296         .cfi_escape 1, 2, 3, 4, 5
2297         .cfi_endproc],
2298 [case "$target" in
2299   *-*-solaris*)
2300     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2301     # read-only and read-write sections, we need to make sure that the
2302     # assembler used emits read-write .eh_frame sections.
2303     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2304       if test "x$gcc_cv_objdump" != x; then
2305         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2306                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2307           gcc_cv_as_cfi_directive=no
2308         else
2309           case "$target" in
2310             i?86-*-solaris2.1[[0-9]]*)
2311               # On Solaris/x86, make sure that GCC and gas agree on using
2312               # read-only .eh_frame sections for 64-bit.
2313               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2314                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2315                         sed -e /.eh_frame/!d -e N | \
2316                         grep READONLY > /dev/null; then
2317                 gcc_cv_as_cfi_directive=yes
2318               else
2319                 gcc_cv_as_cfi_directive=no
2320               fi
2321               ;;
2322             *)
2323               gcc_cv_as_cfi_directive=yes
2324               ;;
2325           esac 
2326         fi
2327       else
2328         # no objdump, err on the side of caution
2329         gcc_cv_as_cfi_directive=no
2330       fi
2331     else
2332       gcc_cv_as_cfi_directive=yes
2333     fi
2334     ;;
2335   *-*-*)
2336     gcc_cv_as_cfi_directive=yes
2337     ;;
2338 esac])
2339 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_readelf != x; then
2340 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2341   ,,
2342 [       .text
2343         .cfi_startproc
2344         .cfi_adjust_cfa_offset 64
2345         .skip 75040, 0
2346         .cfi_adjust_cfa_offset 128
2347         .cfi_endproc],
2348 [[
2349 if $gcc_cv_readelf -wf conftest.o 2>/dev/null \
2350     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2351    gcc_cv_as_cfi_advance_working=yes
2352 fi
2353 ]])
2354 else
2355   # no readelf, err on the side of caution
2356   gcc_cv_as_cfi_advance_working=no
2357 fi
2358 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2359   [`if test $gcc_cv_as_cfi_directive = yes \
2360        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2361   [Define 0/1 if your assembler supports CFI directives.])
2362
2363 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2364   gcc_cv_as_cfi_personality_directive, ,,
2365 [       .text
2366         .cfi_startproc
2367         .cfi_personality 0, symbol
2368         .cfi_endproc])
2369 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2370   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2371     then echo 1; else echo 0; fi`],
2372   [Define 0/1 if your assembler supports .cfi_personality.])
2373
2374 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2375   gcc_cv_as_cfi_sections_directive, ,,
2376 [       .text
2377         .cfi_sections .debug_frame, .eh_frame
2378         .cfi_startproc
2379         .cfi_endproc])
2380 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2381   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2382     then echo 1; else echo 0; fi`],
2383   [Define 0/1 if your assembler supports .cfi_sections.])
2384
2385 # GAS versions up to and including 2.11.0 may mis-optimize
2386 # .eh_frame data.
2387 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2388   [elf,2,12,0],,
2389 [       .text
2390 .LFB1:
2391         .4byte  0
2392 .L1:
2393         .4byte  0
2394 .LFE1:
2395         .section        .eh_frame,"aw",@progbits
2396 __FRAME_BEGIN__:
2397         .4byte  .LECIE1-.LSCIE1
2398 .LSCIE1:
2399         .4byte  0x0
2400         .byte   0x1
2401         .ascii "z\0"
2402         .byte   0x1
2403         .byte   0x78
2404         .byte   0x1a
2405         .byte   0x0
2406         .byte   0x4
2407         .4byte  1
2408         .p2align 1
2409 .LECIE1:
2410 .LSFDE1:
2411         .4byte  .LEFDE1-.LASFDE1
2412 .LASFDE1:
2413         .4byte  .LASFDE1-__FRAME_BEGIN__
2414         .4byte  .LFB1
2415         .4byte  .LFE1-.LFB1
2416         .byte   0x4
2417         .4byte  .LFE1-.LFB1
2418         .byte   0x4
2419         .4byte  .L1-.LFB1
2420 .LEFDE1:],
2421 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2422 cat > conftest.lit <<EOF
2423  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2424  0010 01000000 12000000 18000000 00000000  ................
2425  0020 08000000 04080000 0044               .........D      @&t@
2426 EOF
2427 cat > conftest.big <<EOF
2428  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2429  0010 00000001 00000012 00000018 00000000  ................
2430  0020 00000008 04000000 0844               .........D      @&t@
2431 EOF
2432   # If the assembler didn't choke, and we can objdump,
2433   # and we got the correct data, then succeed.
2434   # The text in the here-document typically retains its unix-style line
2435   # endings, while the output of objdump will use host line endings.
2436   # Therefore, use diff -b for the comparisons.
2437   if test x$gcc_cv_objdump != x \
2438   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2439      | tail -3 > conftest.got \
2440   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2441     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2442   then
2443     gcc_cv_as_eh_frame=yes
2444   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2445     gcc_cv_as_eh_frame=buggy
2446   else
2447     # Uh oh, what do we do now?
2448     gcc_cv_as_eh_frame=no
2449   fi])
2450
2451 if test $gcc_cv_as_eh_frame = buggy; then
2452   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2453   [Define if your assembler mis-optimizes .eh_frame data.])
2454 fi
2455
2456 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2457  [elf,2,12,0], [--fatal-warnings],
2458  [.section .rodata.str, "aMS", @progbits, 1])
2459 if test $gcc_cv_as_shf_merge = no; then
2460   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2461     [elf,2,12,0], [--fatal-warnings],
2462     [.section .rodata.str, "aMS", %progbits, 1])
2463 fi
2464 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2465   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2466 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2467
2468 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2469  [elf,2,16,0], [--fatal-warnings],
2470  [.section .text,"axG",@progbits,.foo,comdat])
2471 if test $gcc_cv_as_comdat_group = yes; then
2472   gcc_cv_as_comdat_group_percent=no
2473 else
2474  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2475    [elf,2,16,0], [--fatal-warnings],
2476    [.section .text,"axG",%progbits,.foo,comdat])
2477 fi
2478 if test x"$ld_is_gold" = xyes; then
2479   comdat_group=yes
2480 elif test $in_tree_ld = yes ; then
2481   comdat_group=no
2482   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2483      && test $in_tree_ld_is_elf = yes; then
2484      comdat_group=yes
2485   fi
2486 elif echo "$ld_ver" | grep GNU > /dev/null; then
2487   comdat_group=yes
2488   if test 0"$ld_date" -lt 20050308; then
2489     if test -n "$ld_date"; then
2490       # If there was date string, but was earlier than 2005-03-08, fail
2491       comdat_group=no
2492     elif test "$ld_vers_major" -lt 2; then
2493       comdat_group=no
2494     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2495       comdat_group=no
2496     fi
2497   fi
2498 else
2499 changequote(,)dnl
2500   case "${target}" in
2501     *-*-solaris2.1[1-9]*)
2502       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2503       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2504       # version 1.688.
2505       #
2506       # FIXME: Maybe need to refine later when COMDAT group support with
2507       # Sun as is implemented.
2508       if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 1688; then
2509         comdat_group=yes
2510       else
2511         comdat_group=no
2512       fi
2513       ;;
2514     *)
2515       # Assume linkers other than GNU ld don't support COMDAT group.
2516       comdat_group=no
2517       ;;
2518   esac
2519 changequote([,])dnl
2520 fi
2521 # Allow overriding the automatic COMDAT group tests above.
2522 AC_ARG_ENABLE(comdat,
2523   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2524   [comdat_group="$enable_comdat"])
2525 if test $comdat_group = no; then
2526   gcc_cv_as_comdat_group=no
2527   gcc_cv_as_comdat_group_percent=no
2528 fi
2529 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2530   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2531 [Define 0/1 if your assembler and linker support COMDAT groups.])
2532
2533 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2534  gcc_cv_as_discriminator,
2535  [2,19,51],,
2536 [       .text
2537         .file 1 "conf.c"
2538         .loc 1 1 0 discriminator 1],,
2539 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2540   [Define if your assembler supports the .loc discriminator sub-directive.])])
2541
2542 # Thread-local storage - the check is heavily parameterized.
2543 conftest_s=
2544 tls_first_major=
2545 tls_first_minor=
2546 tls_as_opt=
2547 case "$target" in
2548 changequote(,)dnl
2549   alpha*-*-*)
2550     conftest_s='
2551         .section ".tdata","awT",@progbits
2552 foo:    .long   25
2553         .text
2554         ldq     $27,__tls_get_addr($29)         !literal!1
2555         lda     $16,foo($29)                    !tlsgd!1
2556         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2557         ldq     $27,__tls_get_addr($29)         !literal!2
2558         lda     $16,foo($29)                    !tlsldm!2
2559         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2560         ldq     $1,foo($29)                     !gotdtprel
2561         ldah    $2,foo($29)                     !dtprelhi
2562         lda     $3,foo($2)                      !dtprello
2563         lda     $4,foo($29)                     !dtprel
2564         ldq     $1,foo($29)                     !gottprel
2565         ldah    $2,foo($29)                     !tprelhi
2566         lda     $3,foo($2)                      !tprello
2567         lda     $4,foo($29)                     !tprel'
2568         tls_first_major=2
2569         tls_first_minor=13
2570         tls_as_opt=--fatal-warnings
2571         ;;
2572   cris-*-*|crisv32-*-*)
2573     conftest_s='
2574         .section ".tdata","awT",@progbits
2575 x:      .long   25
2576         .text
2577         move.d x:IE,$r10
2578         nop'
2579         tls_first_major=2
2580         tls_first_minor=20
2581         tls_as_opt=--fatal-warnings
2582         ;;
2583   frv*-*-*)
2584     conftest_s='
2585         .section ".tdata","awT",@progbits
2586 x:      .long   25
2587         .text
2588         call    #gettlsoff(x)'
2589         tls_first_major=2
2590         tls_first_minor=14
2591         ;;
2592   hppa*-*-linux*)
2593     conftest_s='
2594 t1:     .reg    %r20
2595 t2:     .reg    %r21
2596 gp:     .reg    %r19
2597         .section ".tdata","awT",@progbits
2598 foo:    .long   25
2599         .text
2600         .align  4
2601         addil LT%foo-$tls_gdidx$,gp
2602         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2603         b __tls_get_addr
2604         nop             
2605         addil LT%foo-$tls_ldidx$,gp
2606         b __tls_get_addr
2607         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2608         addil LR%foo-$tls_dtpoff$,%ret0
2609         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2610         mfctl %cr27,%t1                 
2611         addil LT%foo-$tls_ieoff$,gp
2612         ldw RT%foo-$tls_ieoff$(%r1),%t2
2613         add %t1,%t2,%t3                 
2614         mfctl %cr27,%t1                 
2615         addil LR%foo-$tls_leoff$,%t1
2616         ldo RR%foo-$tls_leoff$(%r1),%t2'
2617         tls_first_major=2
2618         tls_first_minor=15
2619         tls_as_opt=--fatal-warnings
2620         ;;
2621   arm*-*-*)
2622     conftest_s='
2623         .section ".tdata","awT",%progbits
2624 foo:    .long   25
2625         .text
2626 .word foo(gottpoff)
2627 .word foo(tpoff)
2628 .word foo(tlsgd)
2629 .word foo(tlsldm)
2630 .word foo(tlsldo)'
2631         tls_first_major=2
2632         tls_first_minor=17
2633         ;;
2634   i[34567]86-*-*)
2635     case "$target" in
2636       i[34567]86-*-solaris2.[56789]*)
2637         # TLS was introduced in the Solaris 9 4/04 release but
2638         # we do not enable it by default on Solaris 9 either.
2639         if test "x$enable_tls" = xyes ; then
2640           on_solaris=yes
2641         else
2642           enable_tls=no;
2643         fi
2644         ;;
2645       i[34567]86-*-solaris2.*)
2646         on_solaris=yes
2647         ;;
2648       *)
2649         on_solaris=no
2650         ;;
2651     esac
2652     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2653       conftest_s='
2654         .section .tdata,"awt",@progbits'
2655       tls_first_major=0
2656       tls_first_minor=0
2657 changequote([,])dnl
2658       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2659 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2660 changequote(,)dnl
2661     else
2662       conftest_s='
2663         .section ".tdata","awT",@progbits'
2664       tls_first_major=2
2665       tls_first_minor=14
2666       tls_as_opt="--fatal-warnings"
2667     fi
2668     conftest_s="$conftest_s
2669 foo:    .long   25
2670         .text
2671         movl    %gs:0, %eax
2672         leal    foo@tlsgd(,%ebx,1), %eax
2673         leal    foo@tlsldm(%ebx), %eax
2674         leal    foo@dtpoff(%eax), %edx
2675         movl    foo@gottpoff(%ebx), %eax
2676         subl    foo@gottpoff(%ebx), %eax
2677         addl    foo@gotntpoff(%ebx), %eax
2678         movl    foo@indntpoff, %eax
2679         movl    \$foo@tpoff, %eax
2680         subl    \$foo@tpoff, %eax
2681         leal    foo@ntpoff(%ecx), %eax"
2682     ;;
2683   x86_64-*-*)
2684     conftest_s='
2685         .section ".tdata","awT",@progbits
2686 foo:    .long   25
2687         .text
2688         movq    %fs:0, %rax
2689         leaq    foo@TLSGD(%rip), %rdi
2690         leaq    foo@TLSLD(%rip), %rdi
2691         leaq    foo@DTPOFF(%rax), %rdx
2692         movq    foo@GOTTPOFF(%rip), %rax
2693         movq    $foo@TPOFF, %rax'
2694         tls_first_major=2
2695         tls_first_minor=14
2696         tls_as_opt=--fatal-warnings
2697         ;;
2698   ia64-*-*)
2699     conftest_s='
2700         .section ".tdata","awT",@progbits
2701 foo:    data8   25
2702         .text
2703         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2704         addl    r17 = @ltoff(@dtprel(foo#)), gp
2705         addl    r18 = @ltoff(@tprel(foo#)), gp
2706         addl    r19 = @dtprel(foo#), gp
2707         adds    r21 = @dtprel(foo#), r13
2708         movl    r23 = @dtprel(foo#)
2709         addl    r20 = @tprel(foo#), gp
2710         adds    r22 = @tprel(foo#), r13
2711         movl    r24 = @tprel(foo#)'
2712         tls_first_major=2
2713         tls_first_minor=13
2714         tls_as_opt=--fatal-warnings
2715         ;;
2716   mips*-*-*)
2717     conftest_s='
2718         .section .tdata,"awT",@progbits
2719 x:
2720         .word 2
2721         .text
2722         addiu $4, $28, %tlsgd(x)
2723         addiu $4, $28, %tlsldm(x)
2724         lui $4, %dtprel_hi(x)
2725         addiu $4, $4, %dtprel_lo(x)
2726         lw $4, %gottprel(x)($28)
2727         lui $4, %tprel_hi(x)
2728         addiu $4, $4, %tprel_lo(x)'
2729         tls_first_major=2
2730         tls_first_minor=16
2731         tls_as_opt='-32 --fatal-warnings'
2732         ;;
2733   m68k-*-*)
2734     conftest_s='
2735         .section .tdata,"awT",@progbits
2736 x:
2737         .word 2
2738         .text
2739 foo:
2740         move.l x@TLSGD(%a5),%a0
2741         move.l x@TLSLDM(%a5),%a0
2742         move.l x@TLSLDO(%a5),%a0
2743         move.l x@TLSIE(%a5),%a0
2744         move.l x@TLSLE(%a5),%a0'
2745         tls_first_major=2
2746         tls_first_minor=19
2747         tls_as_opt='--fatal-warnings'
2748         ;;
2749   powerpc-*-*)
2750     conftest_s='
2751         .section ".tdata","awT",@progbits
2752         .align 2
2753 ld0:    .space 4
2754 ld1:    .space 4
2755 x1:     .space 4
2756 x2:     .space 4
2757 x3:     .space 4
2758         .text
2759         addi 3,31,ld0@got@tlsgd
2760         bl __tls_get_addr
2761         addi 3,31,x1@got@tlsld
2762         bl __tls_get_addr
2763         addi 9,3,x1@dtprel
2764         addis 9,3,x2@dtprel@ha
2765         addi 9,9,x2@dtprel@l
2766         lwz 9,x3@got@tprel(31)
2767         add 9,9,x@tls
2768         addi 9,2,x1@tprel
2769         addis 9,2,x2@tprel@ha
2770         addi 9,9,x2@tprel@l'
2771         tls_first_major=2
2772         tls_first_minor=14
2773         tls_as_opt="-a32 --fatal-warnings"
2774         ;;
2775   powerpc64-*-*)
2776     conftest_s='
2777         .section ".tdata","awT",@progbits
2778         .align 3
2779 ld0:    .space 8
2780 ld1:    .space 8
2781 x1:     .space 8
2782 x2:     .space 8
2783 x3:     .space 8
2784         .text
2785         addi 3,2,ld0@got@tlsgd
2786         bl .__tls_get_addr
2787         nop
2788         addi 3,2,ld1@toc
2789         bl .__tls_get_addr
2790         nop
2791         addi 3,2,x1@got@tlsld
2792         bl .__tls_get_addr
2793         nop
2794         addi 9,3,x1@dtprel
2795         bl .__tls_get_addr
2796         nop
2797         addis 9,3,x2@dtprel@ha
2798         addi 9,9,x2@dtprel@l
2799         bl .__tls_get_addr
2800         nop
2801         ld 9,x3@got@dtprel(2)
2802         add 9,9,3
2803         bl .__tls_get_addr
2804         nop'
2805         tls_first_major=2
2806         tls_first_minor=14
2807         tls_as_opt="-a64 --fatal-warnings"
2808         ;;
2809   s390-*-*)
2810     conftest_s='
2811         .section ".tdata","awT",@progbits
2812 foo:    .long   25
2813         .text
2814         .long   foo@TLSGD
2815         .long   foo@TLSLDM
2816         .long   foo@DTPOFF
2817         .long   foo@NTPOFF
2818         .long   foo@GOTNTPOFF
2819         .long   foo@INDNTPOFF
2820         l       %r1,foo@GOTNTPOFF(%r12)
2821         l       %r1,0(%r1):tls_load:foo
2822         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2823         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2824         tls_first_major=2
2825         tls_first_minor=14
2826         tls_as_opt="-m31 --fatal-warnings"
2827         ;;
2828   s390x-*-*)
2829     conftest_s='
2830         .section ".tdata","awT",@progbits
2831 foo:    .long   25
2832         .text
2833         .quad   foo@TLSGD
2834         .quad   foo@TLSLDM
2835         .quad   foo@DTPOFF
2836         .quad   foo@NTPOFF
2837         .quad   foo@GOTNTPOFF
2838         lg      %r1,foo@GOTNTPOFF(%r12)
2839         larl    %r1,foo@INDNTPOFF
2840         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2841         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2842         tls_first_major=2
2843         tls_first_minor=14
2844         tls_as_opt="-m64 -Aesame --fatal-warnings"
2845         ;;
2846   sh-*-* | sh[34]-*-*)
2847     conftest_s='
2848         .section ".tdata","awT",@progbits
2849 foo:    .long   25
2850         .text
2851         .long   foo@TLSGD
2852         .long   foo@TLSLDM
2853         .long   foo@DTPOFF
2854         .long   foo@GOTTPOFF
2855         .long   foo@TPOFF'
2856         tls_first_major=2
2857         tls_first_minor=13
2858         tls_as_opt=--fatal-warnings
2859         ;;
2860   sparc*-*-*)
2861     case "$target" in
2862       sparc*-sun-solaris2.[56789]*)
2863         # TLS was introduced in the Solaris 9 4/04 release but
2864         # we do not enable it by default on Solaris 9 either.
2865         if test "x$enable_tls" = xyes ; then
2866           on_solaris=yes
2867         else
2868           enable_tls=no;
2869         fi
2870         ;;
2871       sparc*-sun-solaris2.*)
2872         on_solaris=yes
2873         ;;
2874       *)
2875         on_solaris=no
2876         ;;
2877     esac
2878     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2879       conftest_s='
2880         .section ".tdata",#alloc,#write,#tls
2881 foo:    .long   25
2882         .text
2883         sethi   %tgd_hi22(foo), %o0
2884         add     %o0, %tgd_lo10(foo), %o1
2885         add     %l7, %o1, %o0, %tgd_add(foo)
2886         call    __tls_get_addr, %tgd_call(foo)
2887         sethi   %tldm_hi22(foo), %l1
2888         add     %l1, %tldm_lo10(foo), %l2
2889         add     %l7, %l2, %o0, %tldm_add(foo)
2890         call    __tls_get_addr, %tldm_call(foo)
2891         sethi   %tldo_hix22(foo), %l3
2892         xor     %l3, %tldo_lox10(foo), %l4
2893         add     %o0, %l4, %l5, %tldo_add(foo)
2894         sethi   %tie_hi22(foo), %o3
2895         add     %o3, %tie_lo10(foo), %o3
2896         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2897         add     %g7, %o2, %o4, %tie_add(foo)
2898         sethi   %tle_hix22(foo), %l1
2899         xor     %l1, %tle_lox10(foo), %o5
2900         ld      [%g7 + %o5], %o1'
2901         tls_first_major=0
2902         tls_first_minor=0
2903     else
2904       conftest_s='
2905         .section ".tdata","awT",@progbits
2906 foo:    .long   25
2907         .text
2908         sethi   %tgd_hi22(foo), %o0
2909         add     %o0, %tgd_lo10(foo), %o1
2910         add     %l7, %o1, %o0, %tgd_add(foo)
2911         call    __tls_get_addr, %tgd_call(foo)
2912         sethi   %tldm_hi22(foo), %l1
2913         add     %l1, %tldm_lo10(foo), %l2
2914         add     %l7, %l2, %o0, %tldm_add(foo)
2915         call    __tls_get_addr, %tldm_call(foo)
2916         sethi   %tldo_hix22(foo), %l3
2917         xor     %l3, %tldo_lox10(foo), %l4
2918         add     %o0, %l4, %l5, %tldo_add(foo)
2919         sethi   %tie_hi22(foo), %o3
2920         add     %o3, %tie_lo10(foo), %o3
2921         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2922         add     %g7, %o2, %o4, %tie_add(foo)
2923         sethi   %tle_hix22(foo), %l1
2924         xor     %l1, %tle_lox10(foo), %o5
2925         ld      [%g7 + %o5], %o1'
2926         tls_first_major=2
2927         tls_first_minor=14
2928         tls_as_opt="-32 --fatal-warnings"
2929       fi
2930         ;;
2931   xtensa*-*-*)
2932     conftest_s='
2933         .section ".tdata","awT",@progbits
2934 foo:    .long   25
2935         .text
2936         movi    a8, foo@TLSFUNC
2937         movi    a10, foo@TLSARG
2938         callx8.tls a8, foo@TLSCALL'
2939         tls_first_major=2
2940         tls_first_minor=19
2941         ;;
2942 changequote([,])dnl
2943 esac
2944 set_have_as_tls=no
2945 if test "x$enable_tls" = xno ; then
2946   : # TLS explicitly disabled.
2947 elif test "x$enable_tls" = xyes ; then
2948   set_have_as_tls=yes # TLS explicitly enabled.
2949 elif test -z "$tls_first_major"; then
2950   : # If we don't have a check, assume no support.
2951 else
2952   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2953   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2954   [set_have_as_tls=yes])
2955 fi
2956 if test $set_have_as_tls = yes ; then
2957   AC_DEFINE(HAVE_AS_TLS, 1,
2958             [Define if your assembler supports thread-local storage.])
2959 fi
2960
2961 # Target-specific assembler checks.
2962
2963 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2964 gcc_cv_ld_static_dynamic=no
2965 if test $in_tree_ld = yes ; then
2966   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
2967     gcc_cv_ld_static_dynamic=yes
2968   fi
2969 elif test x$gcc_cv_ld != x; then
2970         # Check if linker supports -Bstatic/-Bdynamic option
2971         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2972           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2973                 gcc_cv_ld_static_dynamic=yes
2974         fi
2975 fi
2976 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2977         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2978 [Define if your linker supports -Bstatic/-Bdynamic option.])
2979 fi
2980 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2981
2982 if test x"$demangler_in_ld" = xyes; then
2983   AC_MSG_CHECKING(linker --demangle support)
2984   gcc_cv_ld_demangle=no
2985   if test $in_tree_ld = yes; then
2986     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2987       gcc_cv_ld_demangle=yes
2988     fi
2989   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2990     # Check if the GNU linker supports --demangle option
2991     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2992       gcc_cv_ld_demangle=yes
2993     fi
2994   fi
2995   if test x"$gcc_cv_ld_demangle" = xyes; then
2996     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2997 [Define if your linker supports --demangle option.])
2998   fi
2999   AC_MSG_RESULT($gcc_cv_ld_demangle)
3000 fi
3001
3002 case "$target" in
3003   # All TARGET_ABI_OSF targets.
3004   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
3005     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3006         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3007 [       .set nomacro
3008         .text
3009         extbl   $3, $2, $3      !lituse_bytoff!1
3010         ldq     $2, a($29)      !literal!1
3011         ldq     $4, b($29)      !literal!2
3012         ldq_u   $3, 0($2)       !lituse_base!1
3013         ldq     $27, f($29)     !literal!5
3014         jsr     $26, ($27), f   !lituse_jsr!5
3015         ldah    $29, 0($26)     !gpdisp!3
3016         lda     $0, c($29)      !gprel
3017         ldah    $1, d($29)      !gprelhigh
3018         lda     $1, d($1)       !gprellow
3019         lda     $29, 0($29)     !gpdisp!3],,
3020     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3021   [Define if your assembler supports explicit relocations.])])
3022     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3023         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3024 [       .set nomacro
3025         .text
3026         ldq     $27, a($29)     !literal!1
3027         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3028     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3029   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3030     ;;
3031
3032   cris-*-*)
3033     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3034       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3035       [-no-mul-bug-abort], [.text],,
3036       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3037                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3038     ;;
3039
3040   sparc*-*-*)
3041     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3042       [.register %g2, #scratch],,
3043       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3044                 [Define if your assembler supports .register.])])
3045
3046     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3047       [-relax], [.text],,
3048       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3049                 [Define if your assembler supports -relax option.])])
3050
3051     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3052       gcc_cv_as_sparc_gotdata_op,,
3053       [-K PIC],
3054 [.text
3055 foo:
3056         nop
3057 bar:
3058         sethi %gdop_hix22(foo), %g1
3059         xor    %g1, %gdop_lox10(foo), %g1
3060         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3061       [if test x$gcc_cv_ld != x \
3062        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3063          if $gcc_cv_ld -v | grep GNU >/dev/null 2>&1; then
3064            if test x$gcc_cv_objdump != x; then
3065              if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3066                 | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3067                gcc_cv_as_sparc_gotdata_op=no
3068              else
3069                gcc_cv_as_sparc_gotdata_op=yes
3070              fi
3071            fi
3072          else
3073            gcc_cv_as_sparc_gotdata_op=yes
3074          fi
3075        fi
3076        rm -f conftest],
3077       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3078                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3079
3080     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3081       gcc_cv_as_sparc_ua_pcrel,,
3082       [-K PIC],
3083 [.text
3084 foo:
3085         nop
3086 .data
3087 .align 4
3088 .byte 0
3089 .uaword %r_disp32(foo)],
3090       [if test x$gcc_cv_ld != x \
3091        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3092          gcc_cv_as_sparc_ua_pcrel=yes
3093        fi
3094        rm -f conftest],
3095       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3096                 [Define if your assembler and linker support unaligned PC relative relocs.])
3097
3098       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3099         gcc_cv_as_sparc_ua_pcrel_hidden,,
3100         [-K PIC],
3101 [.data
3102 .align 4
3103 .byte 0x31
3104 .uaword %r_disp32(foo)
3105 .byte 0x32, 0x33, 0x34
3106 .global foo
3107 .hidden foo
3108 foo:
3109 .skip 4],
3110         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3111          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3112          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3113             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3114             if $gcc_cv_objdump -R conftest 2> /dev/null \
3115                | grep 'DISP32' > /dev/null 2>&1; then
3116                 :
3117             else
3118                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3119             fi
3120          fi
3121          rm -f conftest],
3122          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3123                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3124     ]) # unaligned pcrel relocs
3125
3126     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3127       gcc_cv_as_sparc_offsetable_lo10,,
3128       [-xarch=v9],
3129 [.text
3130         or %g1, %lo(ab) + 12, %g1
3131         or %g1, %lo(ab + 12), %g1],
3132       [if test x$gcc_cv_objdump != x \
3133        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3134           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3135          gcc_cv_as_sparc_offsetable_lo10=yes
3136        fi],
3137        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3138                  [Define if your assembler supports offsetable %lo().])])
3139     ;;
3140
3141 changequote(,)dnl
3142   i[34567]86-*-* | x86_64-*-*)
3143 changequote([,])dnl
3144     case $target_os in
3145       cygwin*)
3146         # Full C++ conformance when using a shared libstdc++-v3 requires some
3147         # support from the Cygwin DLL, which in more recent versions exports
3148         # wrappers to aid in interposing and redirecting operators new, delete,
3149         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3150         # are configuring for a version of Cygwin that exports the wrappers.
3151         if test x$host = x$target; then
3152           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3153         else
3154           # Can't check presence of libc functions during cross-compile, so
3155           # we just have to assume we're building for an up-to-date target.
3156           gcc_ac_cygwin_dll_wrappers=yes
3157         fi
3158         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3159           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3160           [Define if you want to generate code by default that assumes that the
3161            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3162     esac
3163     case $target_os in
3164       cygwin* | pe | mingw32*)
3165         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3166         # definition is used unconditionally to initialise the default state of
3167         # the target option variable that governs usage of the feature.
3168         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3169          [2,19,52],,[.comm foo,1,32])
3170         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3171           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3172           [Define if your assembler supports specifying the alignment
3173            of objects allocated using the GAS .comm command.])
3174         # Used for DWARF 2 in PE
3175         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3176           gcc_cv_as_ix86_pe_secrel32,
3177           [2,15,91],,
3178 [.text
3179 foo:    nop
3180 .data
3181         .secrel32 foo],
3182           [if test x$gcc_cv_ld != x \
3183            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3184              gcc_cv_as_ix86_pe_secrel32=yes
3185            fi
3186            rm -f conftest],
3187           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3188             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3189         ;;
3190     esac
3191
3192     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3193        gcc_cv_as_ix86_filds,,,
3194        [filds mem; fists mem],,
3195        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3196          [Define if your assembler uses filds and fists mnemonics.])])
3197
3198     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3199        gcc_cv_as_ix86_fildq,,,
3200        [fildq mem; fistpq mem],,
3201        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3202          [Define if your assembler uses fildq and fistq mnemonics.])])
3203
3204     gcc_GAS_CHECK_FEATURE([cmov syntax],
3205       gcc_cv_as_ix86_cmov_sun_syntax,,,
3206       [cmovl.l %edx, %eax],,
3207       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3208         [Define if your assembler supports the Sun syntax for cmov.])])
3209
3210     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3211       gcc_cv_as_ix86_ffreep,,,
3212       [ffreep %st(1)],,
3213       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3214         [Define if your assembler supports the ffreep mnemonic.])])
3215
3216     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3217       gcc_cv_as_ix86_sahf,,,
3218       [sahf],,
3219       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3220         [Define if your assembler supports the sahf mnemonic.])])
3221
3222     gcc_GAS_CHECK_FEATURE([swap suffix],
3223       gcc_cv_as_ix86_swap,,,
3224       [movl.s %esp, %ebp],,
3225       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3226         [Define if your assembler supports the swap suffix.])])
3227
3228     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3229       gcc_cv_as_ix86_diff_sect_delta,,,
3230       [.section .rodata
3231 .L1:
3232         .long .L2-.L1
3233         .long .L3-.L1
3234         .text
3235 .L3:    nop
3236 .L2:    nop],,
3237       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3238         [Define if your assembler supports the subtraction of symbols in different sections.])])
3239
3240     # This one is used unconditionally by i386.[ch]; it is to be defined
3241     # to 1 if the feature is present, 0 otherwise.
3242     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3243         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3244 [       .text
3245 .L0:
3246         nop
3247         .data
3248         .long .L0@GOTOFF])
3249     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3250       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3251       [Define true if the assembler supports '.long foo@GOTOFF'.])
3252     ;;
3253
3254   ia64*-*-*)
3255     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3256         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3257 [       .text
3258         addl r15 = @ltoffx(x#), gp
3259         ;;
3260         ld8.mov r16 = [[r15]], x#],,
3261     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3262           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3263
3264     ;;
3265
3266   powerpc*-*-*)
3267     case $target in
3268       *-*-aix*) conftest_s='    .machine "pwr5"
3269         .csect .text[[PR]]
3270         mfcr 3,128';;
3271       *-*-darwin*)
3272         gcc_GAS_CHECK_FEATURE([.machine directive support],
3273           gcc_cv_as_machine_directive,,,
3274           [     .machine ppc7400])
3275         if test x$gcc_cv_as_machine_directive != xyes; then
3276           echo "*** This target requires an assembler supporting \".machine\"" >&2
3277           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3278           test x$build = x$target && exit 1
3279         fi
3280         conftest_s='    .text
3281         mfcr r3,128';;
3282       *) conftest_s='   .machine power4
3283         .text
3284         mfcr 3,128';;
3285     esac
3286
3287     gcc_GAS_CHECK_FEATURE([mfcr field support],
3288       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3289       [$conftest_s],,
3290       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3291           [Define if your assembler supports mfcr field.])])
3292
3293     case $target in
3294       *-*-aix*) conftest_s='    .machine "pwr5"
3295         .csect .text[[PR]]
3296         popcntb 3,3';;
3297       *) conftest_s='   .machine power5
3298         .text
3299         popcntb 3,3';;
3300     esac
3301
3302     gcc_GAS_CHECK_FEATURE([popcntb support],
3303       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3304       [$conftest_s],,
3305       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3306           [Define if your assembler supports popcntb field.])])
3307
3308     case $target in
3309       *-*-aix*) conftest_s='    .machine "pwr5x"
3310         .csect .text[[PR]]
3311         frin 1,1';;
3312       *) conftest_s='   .machine power5
3313         .text
3314         frin 1,1';;
3315     esac
3316
3317     gcc_GAS_CHECK_FEATURE([fp round support],
3318       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3319       [$conftest_s],,
3320       [AC_DEFINE(HAVE_AS_FPRND, 1,
3321           [Define if your assembler supports fprnd.])])
3322
3323     case $target in
3324       *-*-aix*) conftest_s='    .machine "pwr6"
3325         .csect .text[[PR]]
3326         mffgpr 1,3';;
3327       *) conftest_s='   .machine power6
3328         .text
3329         mffgpr 1,3';;
3330     esac
3331
3332     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3333       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3334       [$conftest_s],,
3335       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3336           [Define if your assembler supports mffgpr and mftgpr.])])
3337
3338     case $target in
3339       *-*-aix*) conftest_s='    .csect .text[[PR]]
3340 LCF..0:
3341         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3342       *-*-darwin*)
3343         conftest_s='    .text
3344 LCF0:
3345         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3346       *) conftest_s='   .text
3347 .LCF0:
3348         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3349     esac
3350
3351     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3352       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3353       [$conftest_s],,
3354       [AC_DEFINE(HAVE_AS_REL16, 1,
3355           [Define if your assembler supports R_PPC_REL16 relocs.])])
3356
3357     case $target in
3358       *-*-aix*) conftest_s='    .machine "pwr6"
3359         .csect .text[[PR]]
3360         cmpb 3,4,5';;
3361       *) conftest_s='   .machine power6
3362         .text
3363         cmpb 3,4,5';;
3364     esac
3365
3366     gcc_GAS_CHECK_FEATURE([compare bytes support],
3367       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3368       [$conftest_s],,
3369       [AC_DEFINE(HAVE_AS_CMPB, 1,
3370           [Define if your assembler supports cmpb.])])
3371
3372     case $target in
3373       *-*-aix*) conftest_s='    .machine "pwr6"
3374         .csect .text[[PR]]
3375         dadd 1,2,3';;
3376       *) conftest_s='   .machine power6
3377         .text
3378         dadd 1,2,3';;
3379     esac
3380
3381     gcc_GAS_CHECK_FEATURE([decimal float support],
3382       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3383       [$conftest_s],,
3384       [AC_DEFINE(HAVE_AS_DFP, 1,
3385           [Define if your assembler supports DFP instructions.])])
3386
3387     case $target in
3388       *-*-aix*) conftest_s='    .machine "pwr7"
3389         .csect .text[[PR]]
3390         lxvd2x 1,2,3';;
3391       *) conftest_s='   .machine power7
3392         .text
3393         lxvd2x 1,2,3';;
3394     esac
3395
3396     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3397       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3398       [$conftest_s],,
3399       [AC_DEFINE(HAVE_AS_VSX, 1,
3400           [Define if your assembler supports VSX instructions.])])
3401
3402     case $target in
3403       *-*-aix*) conftest_s='    .machine "pwr7"
3404         .csect .text[[PR]]
3405         popcntd 3,3';;
3406       *) conftest_s='   .machine power7
3407         .text
3408         popcntd 3,3';;
3409     esac
3410
3411     gcc_GAS_CHECK_FEATURE([popcntd support],
3412       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3413       [$conftest_s],,
3414       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3415           [Define if your assembler supports POPCNTD instructions.])])
3416
3417     case $target in
3418       *-*-aix*) conftest_s='    .csect .text[[PR]]
3419         lwsync';;
3420       *) conftest_s='   .text
3421         lwsync';;
3422     esac
3423
3424     gcc_GAS_CHECK_FEATURE([lwsync support],
3425       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3426       [$conftest_s],,
3427       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3428           [Define if your assembler supports LWSYNC instructions.])])
3429
3430     case $target in
3431       *-*-aix*) conftest_s='    .machine "476"
3432         .csect .text[[PR]]
3433         dci 0';;
3434       *) conftest_s='   .machine "476"
3435         .text
3436         dci 0';;
3437     esac
3438
3439     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3440       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3441       [$conftest_s],,
3442       [AC_DEFINE(HAVE_AS_DCI, 1,
3443           [Define if your assembler supports the DCI/ICI instructions.])])
3444
3445     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3446       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3447       [.gnu_attribute 4,1],,
3448       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3449           [Define if your assembler supports .gnu_attribute.])])
3450
3451     gcc_GAS_CHECK_FEATURE([tls marker support],
3452       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3453       [ bl __tls_get_addr(x@tlsgd)],,
3454       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3455           [Define if your assembler supports arg info for __tls_get_addr.])])
3456
3457     case $target in
3458       *-*-aix*)
3459         gcc_GAS_CHECK_FEATURE([.ref support],
3460           gcc_cv_as_aix_ref, [2.21.0],,
3461           [     .csect stuff[[rw]]
3462              stuff:
3463                 .long 1
3464                 .extern sym
3465                 .ref sym
3466           ],,
3467           [AC_DEFINE(HAVE_AS_REF, 1,
3468             [Define if your assembler supports .ref])])
3469         ;;
3470     esac
3471     ;;
3472
3473   mips*-*-*)
3474     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3475       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3476 [       lw $4,%gp_rel(foo)($4)],,
3477       [if test x$target_cpu_default = x
3478        then target_cpu_default=MASK_EXPLICIT_RELOCS
3479        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3480        fi])
3481     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3482       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3483       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3484                  [Define if the assembler understands -mno-shared.])])
3485
3486     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3487       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3488       [.gnu_attribute 4,1],,
3489       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3490           [Define if your assembler supports .gnu_attribute.])])
3491
3492     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3493       gcc_cv_as_mips_dtprelword, [2,18,0],,
3494       [.section .tdata,"awT",@progbits
3495 x:
3496         .word 2
3497         .text
3498         .dtprelword x+0x8000],,
3499       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3500           [Define if your assembler supports .dtprelword.])])
3501
3502     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3503     gcc_cv_as_ld_jalr_reloc=no
3504     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3505       if test $in_tree_ld = yes ; then
3506         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3507            && test $in_tree_ld_is_elf = yes; then
3508           gcc_cv_as_ld_jalr_reloc=yes
3509         fi
3510       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3511         echo '  .ent x' > conftest.s
3512         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3513         echo '  ld $25,%call16(y)($28)' >> conftest.s
3514         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3515         echo '1:        jalr $25' >> conftest.s
3516         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3517         echo '1:        jalr $25' >> conftest.s
3518         echo '  .end x' >> conftest.s
3519         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3520            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3521           if $gcc_cv_objdump -d conftest.so | grep -q jalr \
3522              && $gcc_cv_objdump -d conftest.so | grep -q "bal.*<x>"; then
3523             gcc_cv_as_ld_jalr_reloc=yes
3524           fi
3525         fi
3526         rm -f conftest.*
3527       fi
3528     fi
3529     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3530       if test x$target_cpu_default = x; then
3531         target_cpu_default=MASK_RELAX_PIC_CALLS
3532       else
3533         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3534       fi
3535     fi
3536     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3537
3538     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3539       [gcc_cv_ld_mips_personality_relaxation],
3540       [gcc_cv_ld_mips_personality_relaxation=no
3541        if test $in_tree_ld = yes ; then
3542          if test "$gcc_cv_gld_major_version" -eq 2 \
3543                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3544                  -o "$gcc_cv_gld_major_version" -gt 2; then
3545            gcc_cv_ld_mips_personality_relaxation=yes
3546          fi
3547        elif test x$gcc_cv_as != x \
3548                  -a x$gcc_cv_ld != x \
3549                  -a x$gcc_cv_readelf != x ; then
3550          cat > conftest.s <<EOF
3551         .cfi_startproc
3552         .cfi_personality 0x80,indirect_ptr
3553         .ent test
3554 test:
3555         nop
3556         .end test
3557         .cfi_endproc
3558
3559         .section .data,"aw",@progbits
3560 indirect_ptr:
3561         .dc.a personality
3562 EOF
3563          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3564             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3565            if $gcc_cv_readelf -d conftest 2>&1 \
3566               | grep TEXTREL > /dev/null 2>&1; then
3567              :
3568            elif $gcc_cv_readelf --relocs conftest 2>&1 \
3569                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
3570              :
3571            else
3572              gcc_cv_ld_mips_personality_relaxation=yes
3573            fi
3574          fi
3575        fi
3576        rm -f conftest.s conftest.o conftest])
3577     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
3578             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
3579       [Define if your linker can relax absolute .eh_frame personality
3580 pointers into PC-relative form.])
3581     fi
3582     ;;
3583 esac
3584
3585 # Mips and HP-UX need the GNU assembler.
3586 # Linux on IA64 might be able to use the Intel assembler.
3587
3588 case "$target" in
3589   mips*-*-* | *-*-hpux* )
3590     if test x$gas_flag = xyes \
3591        || test x"$host" != x"$build" \
3592        || test ! -x "$gcc_cv_as" \
3593        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3594       :
3595     else
3596       echo "*** This configuration requires the GNU assembler" >&2
3597       exit 1
3598     fi
3599     ;;
3600 esac
3601
3602 # ??? Not all targets support dwarf2 debug_line, even within a version
3603 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3604 # info to the output file.  So, as supported targets are added to gas 2.11,
3605 # add some instruction here to (also) show we expect this might work.
3606 # ??? Once 2.11 is released, probably need to add first known working
3607 # version to the per-target configury.
3608 case "$target" in
3609   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3610   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3611   | xstormy16*-*-* | cris-*-* | crisv32-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3612   | spu-*-* | fido*-*-* | m32c-*-*)
3613     insn="nop"
3614     ;;
3615   ia64*-*-* | s390*-*-*)
3616     insn="nop 0"
3617     ;;
3618   mmix-*-*)
3619     insn="swym 0"
3620     ;;
3621 esac
3622 if test x"$insn" != x; then
3623  conftest_s="\
3624         .file 1 \"conftest.s\"
3625         .loc 1 3 0
3626         $insn"