gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   5 # 2007, 2008 Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 3, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING3.  If not see
  21 #<http://www.gnu.org/licenses/>.
  22
  23 # --------------------------------
  24 # Initialization and sanity checks
  25 # --------------------------------
  26
  27 AC_PREREQ(2.59)
  28 AC_INIT
  29 AC_CONFIG_SRCDIR(tree.c)
  30 AC_CONFIG_HEADER(auto-host.h:config.in)
  31
  32 gcc_version=`cat $srcdir/BASE-VER`
  33
  34 # Determine the host, build, and target systems
  35 AC_CANONICAL_BUILD
  36 AC_CANONICAL_HOST
  37 AC_CANONICAL_TARGET
  38
  39 # Determine the noncanonical target name, for directory use.
  40 ACX_NONCANONICAL_TARGET
  41
  42 # Determine the target- and build-specific subdirectories
  43 GCC_TOPLEV_SUBDIRS
  44
  45 # Set program_transform_name
  46 AC_ARG_PROGRAM
  47
  48 # Check for bogus environment variables.
  49 # Test if LIBRARY_PATH contains the notation for the current directory
  50 # since this would lead to problems installing/building glibc.
  51 # LIBRARY_PATH contains the current directory if one of the following
  52 # is true:
  53 # - one of the terminals (":" and ";") is the first or last sign
  54 # - two terminals occur directly after each other
  55 # - the path contains an element with a dot in it
  56 AC_MSG_CHECKING(LIBRARY_PATH variable)
  57 changequote(,)dnl
  58 case ${LIBRARY_PATH} in
  59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  60     library_path_setting="contains current directory"
  61     ;;
  62   *)
  63     library_path_setting="ok"
  64     ;;
  65 esac
  66 changequote([,])dnl
  67 AC_MSG_RESULT($library_path_setting)
  68 if test "$library_path_setting" != "ok"; then
  69 AC_MSG_ERROR([
  70 *** LIBRARY_PATH shouldn't contain the current directory when
  71 *** building gcc. Please change the environment variable
  72 *** and run configure again.])
  73 fi
  74
  75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  76 # since this would lead to problems installing/building glibc.
  77 # GCC_EXEC_PREFIX contains the current directory if one of the following
  78 # is true:
  79 # - one of the terminals (":" and ";") is the first or last sign
  80 # - two terminals occur directly after each other
  81 # - the path contains an element with a dot in it
  82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  83 changequote(,)dnl
  84 case ${GCC_EXEC_PREFIX} in
  85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  86     gcc_exec_prefix_setting="contains current directory"
  87     ;;
  88   *)
  89     gcc_exec_prefix_setting="ok"
  90     ;;
  91 esac
  92 changequote([,])dnl
  93 AC_MSG_RESULT($gcc_exec_prefix_setting)
  94 if test "$gcc_exec_prefix_setting" != "ok"; then
  95 AC_MSG_ERROR([
  96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  97 *** building gcc. Please change the environment variable
  98 *** and run configure again.])
  99 fi
 100
 101 # -----------
 102 # Directories
 103 # -----------
 104
 105 # Specify the local prefix
 106 local_prefix=
 107 AC_ARG_WITH(local-prefix,
 108 [  --with-local-prefix=DIR specifies directory to put local include],
 109 [case "${withval}" in
 110 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 111 no)     ;;
 112 *)      local_prefix=$with_local_prefix ;;
 113 esac])
 114
 115 # Default local prefix if it is empty
 116 if test x$local_prefix = x; then
 117         local_prefix=/usr/local
 118 fi
 119
 120 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 121 # passed in by the toplevel make and thus we'd get different behavior
 122 # depending on where we built the sources.
 123 gcc_gxx_include_dir=
 124 # Specify the g++ header file directory
 125 AC_ARG_WITH(gxx-include-dir,
 126 [  --with-gxx-include-dir=DIR
 127                           specifies directory to put g++ header files],
 128 [case "${withval}" in
 129 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 130 no)     ;;
 131 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 132 esac])
 133
 134 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
 135 if test x${gcc_gxx_include_dir} = x; then
 136   if test x${enable_version_specific_runtime_libs} = xyes; then
 137     gcc_gxx_include_dir='${libsubdir}/include/c++'
 138   else
 139     libstdcxx_incdir='include/c++/$(version)'
 140     if test x$host != x$target; then
 141        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
 142     fi
 143     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
 144   fi
 145 fi
 146
 147 AC_ARG_WITH(cpp_install_dir,
 148 [  --with-cpp-install-dir=DIR
 149                           install the user visible C preprocessor in DIR
 150                           (relative to PREFIX) as well as PREFIX/bin],
 151 [if test x$withval = xyes; then
 152   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 153 elif test x$withval != xno; then
 154   cpp_install_dir=$withval
 155 fi])
 156
 157 # We would like to our source tree to be readonly.  However when releases or
 158 # pre-releases are generated, the flex/bison generated files as well as the
 159 # various formats of manuals need to be included along with the rest of the
 160 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 161 # just that.
 162
 163 AC_MSG_CHECKING([whether to place generated files in the source directory])
 164   dnl generated-files-in-srcdir is disabled by default
 165   AC_ARG_ENABLE(generated-files-in-srcdir,
 166 [  --enable-generated-files-in-srcdir
 167                           put copies of generated files in source dir
 168                           intended for creating source tarballs for users
 169                           without texinfo bison or flex.],
 170       generated_files_in_srcdir=$enableval,
 171       generated_files_in_srcdir=no)
 172
 173 AC_MSG_RESULT($generated_files_in_srcdir)
 174
 175 if test "$generated_files_in_srcdir" = "yes"; then
 176   GENINSRC=''
 177 else
 178   GENINSRC='#'
 179 fi
 180 AC_SUBST(GENINSRC)
 181
 182 # -------------------
 183 # Find default linker
 184 # -------------------
 185
 186 # With GNU ld
 187 AC_ARG_WITH(gnu-ld,
 188 [  --with-gnu-ld           arrange to work with GNU ld.],
 189 gnu_ld_flag="$with_gnu_ld",
 190 gnu_ld_flag=no)
 191
 192 # With pre-defined ld
 193 AC_ARG_WITH(ld,
 194 [  --with-ld               arrange to use the specified ld (full pathname)],
 195 DEFAULT_LINKER="$with_ld")
 196 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 197   if test ! -x "$DEFAULT_LINKER"; then
 198     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 199   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 200     gnu_ld_flag=yes
 201   fi
 202   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 203         [Define to enable the use of a default linker.])
 204 fi
 205
 206 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
 207 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
 208
 209 AC_MSG_CHECKING([whether a default linker was specified])
 210 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 211   if test x"$gnu_ld_flag" = x"no"; then
 212     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 213   else
 214     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 215   fi
 216 else
 217   AC_MSG_RESULT(no)
 218 fi
 219
 220 # With demangler in GNU ld
 221 AC_ARG_WITH(demangler-in-ld,
 222 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 223 demangler_in_ld="$with_demangler_in_ld",
 224 demangler_in_ld=no)
 225
 226 # ----------------------
 227 # Find default assembler
 228 # ----------------------
 229
 230 # With GNU as
 231 AC_ARG_WITH(gnu-as,
 232 [  --with-gnu-as           arrange to work with GNU as],
 233 gas_flag="$with_gnu_as",
 234 gas_flag=no)
 235
 236 AC_ARG_WITH(as,
 237 [  --with-as               arrange to use the specified as (full pathname)],
 238 DEFAULT_ASSEMBLER="$with_as")
 239 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 240   if test ! -x "$DEFAULT_ASSEMBLER"; then
 241     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 242   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 243     gas_flag=yes
 244   fi
 245   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 246         [Define to enable the use of a default assembler.])
 247 fi
 248
 249 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
 250 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
 251
 252 AC_MSG_CHECKING([whether a default assembler was specified])
 253 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 254   if test x"$gas_flag" = x"no"; then
 255     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 256   else
 257     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 258   fi
 259 else
 260   AC_MSG_RESULT(no)
 261 fi
 262
 263 # ---------------
 264 # Find C compiler
 265 # ---------------
 266
 267 # If a non-executable a.out is present (e.g. created by GNU as above even if
 268 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 269 # file, even when creating an executable, so an execution test fails.
 270 # Remove possible default executable files to avoid this.
 271 #
 272 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 273 # Autoconf includes it.
 274 rm -f a.out a.exe b.out
 275
 276 # Find the native compiler
 277 AC_PROG_CC
 278 AM_PROG_CC_C_O
 279 ACX_PROG_GNAT([-I"$srcdir"/ada])
 280
 281 # autoconf is lame and doesn't give us any substitution variable for this.
 282 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 283   NO_MINUS_C_MINUS_O=yes
 284 else
 285   OUTPUT_OPTION='-o $@'
 286 fi
 287 AC_SUBST(NO_MINUS_C_MINUS_O)
 288 AC_SUBST(OUTPUT_OPTION)
 289
 290 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
 291 # optimizations to be activated explicitly by the toplevel.
 292 case "$CC" in
 293   */prev-gcc/xgcc*) ;;
 294   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
 295 esac
 296 AC_SUBST(CFLAGS)
 297
 298 # -------------------------
 299 # Check C compiler features
 300 # -------------------------
 301
 302 AC_USE_SYSTEM_EXTENSIONS
 303 AC_PROG_CPP
 304 AC_C_INLINE
 305
 306 # sizeof(char) is 1 by definition.
 307 AC_CHECK_SIZEOF(void *)
 308 AC_CHECK_SIZEOF(short)
 309 AC_CHECK_SIZEOF(int)
 310 AC_CHECK_SIZEOF(long)
 311 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 312 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 313
 314 # ---------------------
 315 # Warnings and checking
 316 # ---------------------
 317
 318 # Check $CC warning features (if it's GCC).
 319 # We want to use -pedantic, but we don't want warnings about
 320 # * 'long long'
 321 # * variadic macros
 322 # * overlong strings
 323 # So, we only use -pedantic if we can disable those warnings.
 324
 325 ACX_PROG_CC_WARNING_OPTS(
 326         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wstrict-prototypes ],
 327                        [-Wmissing-prototypes -Wcast-qual])), [loose_warn])
 328 ACX_PROG_CC_WARNING_OPTS(
 329         m4_quote(m4_do([-Wold-style-definition -Wc++-compat ],
 330                        [-Wmissing-format-attribute])), [strict_warn])
 331 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
 332         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ],
 333                        [-Wno-overlength-strings])), [strict_warn])
 334 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
 335
 336 # The above macros do nothing if the compiler is not GCC.  However, the
 337 # Makefile has more goo to add other flags, so this variabl is used to
 338 # enables warnings only for GCC.
 339 warn_cflags=
 340 if test "x$GCC" = "xyes"; then
 341   warn_cflags='$(GCC_WARN_CFLAGS)'
 342 fi
 343 AC_SUBST(warn_cflags)
 344
 345 # Enable expensive internal checks
 346 is_release=
 347 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 348   is_release=yes
 349 fi
 350
 351 AC_ARG_ENABLE(checking,
 352 [  --enable-checking[=LIST]
 353                           enable expensive run-time checks.  With LIST,
 354                           enable only specific categories of checks.
 355                           Categories are: yes,no,all,none,release.
 356                           Flags are: assert,df,fold,gc,gcac,gimple,misc,
 357                           rtlflag,rtl,runtime,tree,valgrind,types.],
 358 [ac_checking_flags="${enableval}"],[
 359 # Determine the default checks.
 360 if test x$is_release = x ; then
 361   ac_checking_flags=yes
 362 else
 363   ac_checking_flags=release
 364 fi])
 365 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 366 for check in release $ac_checking_flags
 367 do
 368         case $check in
 369         # these set all the flags to specific states
 370         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
 371                         ac_fold_checking= ; ac_gc_checking=1 ;
 372                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
 373                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 374                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 375                         ac_types_checking=1 ;;
 376         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
 377                         ac_fold_checking= ; ac_gc_checking= ;
 378                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 379                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 380                         ac_tree_checking= ; ac_valgrind_checking= ;
 381                         ac_types_checking= ;;
 382         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
 383                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 384                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
 385                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 386                         ac_tree_checking=1 ; ac_valgrind_checking= ;
 387                         ac_types_checking=1 ;;
 388         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
 389                         ac_fold_checking= ; ac_gc_checking= ;
 390                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
 391                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 392                         ac_tree_checking= ; ac_valgrind_checking= ;
 393                         ac_types_checking= ;;
 394         # these enable particular checks
 395         assert)         ac_assert_checking=1 ;;
 396         df)             ac_df_checking=1 ;;
 397         fold)           ac_fold_checking=1 ;;
 398         gc)             ac_gc_checking=1 ;;
 399         gcac)           ac_gc_always_collect=1 ;;
 400         gimple)         ac_gimple_checking=1 ;;
 401         misc)           ac_checking=1 ;;
 402         rtl)            ac_rtl_checking=1 ;;
 403         rtlflag)        ac_rtlflag_checking=1 ;;
 404         runtime)        ac_runtime_checking=1 ;;
 405         tree)           ac_tree_checking=1 ;;
 406         types)          ac_types_checking=1 ;;
 407         valgrind)       ac_valgrind_checking=1 ;;
 408         *)      AC_MSG_ERROR(unknown check category $check) ;;
 409         esac
 410 done
 411 IFS="$ac_save_IFS"
 412
 413 nocommon_flag=""
 414 if test x$ac_checking != x ; then
 415   AC_DEFINE(ENABLE_CHECKING, 1,
 416 [Define if you want more run-time sanity checks.  This one gets a grab
 417    bag of miscellaneous but relatively cheap checks.])
 418   nocommon_flag=-fno-common
 419 fi
 420 AC_SUBST(nocommon_flag)
 421 if test x$ac_df_checking != x ; then
 422   AC_DEFINE(ENABLE_DF_CHECKING, 1,
 423 [Define if you want more run-time sanity checks for dataflow.])
 424 fi
 425 if test x$ac_assert_checking != x ; then
 426   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 427 [Define if you want assertions enabled.  This is a cheap check.])
 428 fi
 429 if test x$ac_gimple_checking != x ; then
 430   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
 431 [Define if you want operations on GIMPLE (the basic data structure of
 432 the high-level optimizers) to be checked for dynamic type safety at
 433 runtime.  This is moderately expensive.])
 434 fi
 435 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 436 if test x$ac_runtime_checking != x ; then
 437   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 438 [Define if you want runtime assertions enabled.  This is a cheap check.])
 439 fi
 440 if test x$ac_tree_checking != x ; then
 441   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 442 [Define if you want all operations on trees (the basic data
 443    structure of the front ends) to be checked for dynamic type safety
 444    at runtime.  This is moderately expensive.  The tree browser debugging
 445    routines will also be enabled by this option.
 446    ])
 447   TREEBROWSER=tree-browser.o
 448 fi
 449 if test x$ac_types_checking != x ; then
 450   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
 451 [Define if you want all gimple types to be verified after gimplifiation.
 452    This is cheap.
 453    ])
 454 fi
 455 AC_SUBST(TREEBROWSER)
 456 if test x$ac_rtl_checking != x ; then
 457   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 458 [Define if you want all operations on RTL (the basic data structure
 459    of the optimizer and back end) to be checked for dynamic type safety
 460    at runtime.  This is quite expensive.])
 461 fi
 462 if test x$ac_rtlflag_checking != x ; then
 463   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 464 [Define if you want RTL flag accesses to be checked against the RTL
 465    codes that are supported for each access macro.  This is relatively
 466    cheap.])
 467 fi
 468 if test x$ac_gc_checking != x ; then
 469   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 470 [Define if you want the garbage collector to do object poisoning and
 471    other memory allocation checks.  This is quite expensive.])
 472 fi
 473 if test x$ac_gc_always_collect != x ; then
 474   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 475 [Define if you want the garbage collector to operate in maximally
 476    paranoid mode, validating the entire heap and collecting garbage at
 477    every opportunity.  This is extremely expensive.])
 478 fi
 479 if test x$ac_fold_checking != x ; then
 480   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 481 [Define if you want fold checked that it never destructs its argument.
 482    This is quite expensive.])
 483 fi
 484 valgrind_path_defines=
 485 valgrind_command=
 486
 487 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 488 dnl # an if statement.  This was the source of very frustrating bugs
 489 dnl # in converting to autoconf 2.5x!
 490 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 491
 492 if test x$ac_valgrind_checking != x ; then
 493   # It is certainly possible that there's valgrind but no valgrind.h.
 494   # GCC relies on making annotations so we must have both.
 495   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 496   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 497     [[#include <valgrind/memcheck.h>
 498 #ifndef VALGRIND_DISCARD
 499 #error VALGRIND_DISCARD not defined
 500 #endif]])],
 501   [gcc_cv_header_valgrind_memcheck_h=yes],
 502   [gcc_cv_header_valgrind_memcheck_h=no])
 503   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 504   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 505   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
 506     [[#include <memcheck.h>
 507 #ifndef VALGRIND_DISCARD
 508 #error VALGRIND_DISCARD not defined
 509 #endif]])],
 510   [gcc_cv_header_memcheck_h=yes],
 511   [gcc_cv_header_memcheck_h=no])
 512   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 513   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 514         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 515   if test "x$valgrind_path" = "x" \
 516     || (test $have_valgrind_h = no \
 517         && test $gcc_cv_header_memcheck_h = no \
 518         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 519         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 520   fi
 521   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 522   valgrind_command="$valgrind_path -q"
 523   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 524 [Define if you want to run subprograms and generated programs
 525    through valgrind (a memory checker).  This is extremely expensive.])
 526   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 527     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 528         [Define if valgrind's valgrind/memcheck.h header is installed.])
 529   fi
 530   if test $gcc_cv_header_memcheck_h = yes; then
 531     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 532         [Define if valgrind's memcheck.h header is installed.])
 533   fi
 534 fi
 535 AC_SUBST(valgrind_path_defines)
 536 AC_SUBST(valgrind_command)
 537
 538 # Enable code coverage collection
 539 AC_ARG_ENABLE(coverage,
 540 [  --enable-coverage[=LEVEL]
 541                           enable compiler's code coverage collection.
 542                           Use to measure compiler performance and locate
 543                           unused parts of the compiler. With LEVEL, specify
 544                           optimization. Values are opt, noopt,
 545                           default is noopt],
 546 [case "${enableval}" in
 547   yes|noopt)
 548     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 549     ;;
 550   opt)
 551     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 552     ;;
 553   no)
 554     # a.k.a. --disable-coverage
 555     coverage_flags=""
 556     ;;
 557   *)
 558     AC_MSG_ERROR(unknown coverage setting $enableval)
 559     ;;
 560 esac],
 561 [coverage_flags=""])
 562 AC_SUBST(coverage_flags)
 563
 564 AC_ARG_ENABLE(gather-detailed-mem-stats,
 565 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 566 [enable_gather_detailed_mem_stats=no])
 567 if test x$enable_gather_detailed_mem_stats = xyes ; then
 568   AC_DEFINE(GATHER_STATISTICS, 1,
 569         [Define to enable detailed memory allocation stats gathering.])
 570 fi
 571
 572 # -------------------------------
 573 # Miscenalleous configure options
 574 # -------------------------------
 575
 576 # With stabs
 577 AC_ARG_WITH(stabs,
 578 [  --with-stabs            arrange to use stabs instead of host debug format],
 579 stabs="$with_stabs",
 580 stabs=no)
 581
 582 # Determine whether or not multilibs are enabled.
 583 AC_ARG_ENABLE(multilib,
 584 [  --enable-multilib       enable library support for multiple ABIs],
 585 [], [enable_multilib=yes])
 586 AC_SUBST(enable_multilib)
 587
 588 # Enable __cxa_atexit for C++.
 589 AC_ARG_ENABLE(__cxa_atexit,
 590 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 591 [], [])
 592
 593 # Enable C extension for decimal float if target supports it.
 594 AC_ARG_ENABLE(decimal-float,
 595 [  --enable-decimal-float={no,yes,bid,dpd}
 596                         enable decimal float extension to C.  Selecting 'bid'
 597                         or 'dpd' choses which decimal floating point format
 598                         to use],
 599 [
 600   case $enable_decimal_float in
 601     yes | no | bid | dpd) ;;
 602     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
 603 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
 604   esac
 605 ],
 606 [
 607   case $target in
 608     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux*)
 609       enable_decimal_float=yes
 610       ;;
 611     *)
 612       AC_MSG_WARN(decimal float is not supported for this target, ignored)
 613       enable_decimal_float=no
 614       ;;
 615   esac
 616 ])
 617
 618 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
 619 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
 620 [Define to 1 to enable decimal float extension to C.])
 621
 622 # x86's use BID format instead of DPD
 623 case x$enable_decimal_float in
 624   xyes)
 625     case $target in
 626       i?86*-*-linux* | x86_64*-*-linux*)
 627         enable_decimal_float=bid
 628         ;;
 629       *)
 630         enable_decimal_float=dpd
 631         ;;
 632     esac
 633     ;;
 634   xno)
 635     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
 636     # dependency on libdecnumber.
 637     enable_decimal_float=dpd
 638     ;;
 639 esac
 640 AC_SUBST(enable_decimal_float)
 641
 642 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
 643 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
 644 [Define to 1 to specify that we are using the BID decimal floating
 645 point format instead of DPD])
 646
 647 # Enable C extension for fixed-point arithmetic.
 648 AC_ARG_ENABLE(fixed-point,
 649 [  --enable-fixed-point    enable fixed-point arithmetic extension to C],
 650 [
 651 ],
 652 [
 653   case $target in
 654     mips*-*-*)
 655       case $host in
 656         mips*-sgi-irix*)
 657           AC_MSG_WARN(fixed-point is not supported on IRIX, ignored)
 658           enable_fixed_point=no
 659           ;;
 660         *)
 661           enable_fixed_point=yes
 662           ;;
 663       esac
 664       ;;
 665     *)
 666       AC_MSG_WARN(fixed-point is not supported for this target, ignored)
 667       enable_fixed_point=no
 668       ;;
 669   esac
 670 ])
 671 AC_SUBST(enable_fixed_point)
 672
 673 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
 674 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
 675 [Define to 1 to enable fixed-point arithmetic extension to C.])
 676
 677 # Enable threads
 678 # Pass with no value to take the default
 679 # Pass with a value to specify a thread package
 680 AC_ARG_ENABLE(threads,
 681 [  --enable-threads        enable thread usage for target GCC
 682   --enable-threads=LIB    use LIB thread package for target GCC],,
 683 [enable_threads=''])
 684
 685 AC_ARG_ENABLE(tls,
 686 [  --enable-tls            enable or disable generation of tls code
 687                           overriding the assembler check for tls support],
 688 [
 689   case $enable_tls in
 690     yes | no) ;;
 691     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
 692 Valid choices are 'yes' and 'no'.]) ;;
 693   esac
 694 ], [enable_tls=''])
 695
 696 AC_ARG_ENABLE(objc-gc,
 697 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 698                           the GNU Objective-C runtime],
 699 if test x$enable_objc_gc = xno; then
 700         objc_boehm_gc=''
 701 else
 702         objc_boehm_gc=1
 703 fi,
 704 objc_boehm_gc='')
 705
 706 AC_ARG_WITH(dwarf2,
 707 [  --with-dwarf2           force the default debug format to be DWARF 2],
 708 dwarf2="$with_dwarf2",
 709 dwarf2=no)
 710
 711 AC_ARG_ENABLE(shared,
 712 [  --disable-shared        don't provide a shared libgcc],
 713 [
 714   case $enable_shared in
 715   yes | no) ;;
 716   *)
 717     enable_shared=no
 718     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 719     for pkg in $enableval; do
 720       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 721         enable_shared=yes
 722       fi
 723     done
 724     IFS="$ac_save_ifs"
 725     ;;
 726   esac
 727 ], [enable_shared=yes])
 728 AC_SUBST(enable_shared)
 729
 730 AC_ARG_WITH(build-sysroot,
 731   [  --with-build-sysroot=sysroot
 732                           use sysroot as the system root during the build])
 733
 734 AC_ARG_WITH(sysroot,
 735 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 736 [
 737  case ${with_sysroot} in
 738  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 739  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 740  esac
 741
 742  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 743  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
 744
 745  if test "x$prefix" = xNONE; then
 746   test_prefix=/usr/local
 747  else
 748   test_prefix=$prefix
 749  fi
 750  if test "x$exec_prefix" = xNONE; then
 751   test_exec_prefix=$test_prefix
 752  else
 753   test_exec_prefix=$exec_prefix
 754  fi
 755  case ${TARGET_SYSTEM_ROOT} in
 756  "${test_prefix}"|"${test_prefix}/"*|\
 757  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
 758  '${prefix}'|'${prefix}/'*|\
 759  '${exec_prefix}'|'${exec_prefix}/'*)
 760    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 761    TARGET_SYSTEM_ROOT_DEFINE="$t"
 762    ;;
 763  esac
 764 ], [
 765  TARGET_SYSTEM_ROOT=
 766  TARGET_SYSTEM_ROOT_DEFINE=
 767  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 768 ])
 769 AC_SUBST(TARGET_SYSTEM_ROOT)
 770 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 771 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 772
 773 # Build with intermodule optimisations
 774 AC_ARG_ENABLE(intermodule,
 775 [  --enable-intermodule    build the compiler in one step],
 776 [case ${enable_intermodule} in
 777   yes) onestep="-onestep";;
 778   *) onestep="";;
 779 esac],
 780 [onestep=""])
 781 AC_SUBST(onestep)
 782
 783 ACX_PKGVERSION([GCC])
 784 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
 785
 786 # Sanity check enable_languages in case someone does not run the toplevel
 787 # configure # script.
 788 AC_ARG_ENABLE(languages,
 789 [  --enable-languages=LIST specify which front-ends to build],
 790 [case ,${enable_languages}, in
 791        ,,|,yes,)
 792                 # go safe -- we cannot be much sure without the toplevel
 793                 # configure's
 794                 # analysis of which target libs are present and usable
 795                 enable_languages=c
 796                 ;;
 797          *,all,*)
 798                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 799                 ;;
 800         *,c,*)
 801                 ;;
 802         *)
 803                 enable_languages=c,${enable_languages}
 804                 ;;
 805 esac],
 806 [enable_languages=c])
 807
 808 # Used by documentation targets
 809 AC_SUBST(datarootdir)
 810 AC_SUBST(docdir)
 811 AC_SUBST(htmldir)
 812
 813 # -------------------------
 814 # Checks for other programs
 815 # -------------------------
 816
 817 AC_PROG_MAKE_SET
 818
 819 # Find some useful tools
 820 AC_PROG_AWK
 821 # We need awk to create options.c and options.h.
 822 # Bail out if it's missing.
 823 case ${AWK} in
 824   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 825 esac
 826
 827 gcc_AC_PROG_LN_S
 828 ACX_PROG_LN($LN_S)
 829 AC_PROG_RANLIB
 830 case "${host}" in
 831 *-*-darwin*)
 832   # By default, the Darwin ranlib will not treat common symbols as
 833   # definitions when  building the archive table of contents.  Other
 834   # ranlibs do that; pass an option to the Darwin ranlib that makes
 835   # it behave similarly.
 836   ranlib_flags="-c"
 837   ;;
 838 *)
 839   ranlib_flags=""
 840 esac
 841 AC_SUBST(ranlib_flags)
 842
 843 gcc_AC_PROG_INSTALL
 844
 845 # See if cmp has --ignore-initial.
 846 gcc_AC_PROG_CMP_IGNORE_INITIAL
 847
 848 # See if we have the mktemp command.
 849 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 850
 851 # See if makeinfo has been installed and is modern enough
 852 # that we can use it.
 853 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 854   [GNU texinfo.* \([0-9][0-9.]*\)],
 855   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 856 if test $gcc_cv_prog_makeinfo_modern = no; then
 857   AC_MSG_WARN([
 858 *** Makeinfo is missing or too old.
 859 *** Info documentation will not be built.])
 860   BUILD_INFO=
 861 else
 862   BUILD_INFO=info
 863 fi
 864 AC_SUBST(BUILD_INFO)
 865
 866 # Is pod2man recent enough to regenerate manpages?
 867 AC_MSG_CHECKING([for recent Pod::Man])
 868 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 869   AC_MSG_RESULT(yes)
 870   GENERATED_MANPAGES=generated-manpages
 871 else
 872   AC_MSG_RESULT(no)
 873   GENERATED_MANPAGES=
 874 fi
 875 AC_SUBST(GENERATED_MANPAGES)
 876
 877 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
 878
 879 # How about lex?
 880 dnl Don't use AC_PROG_LEX; we insist on flex.
 881 dnl LEXLIB is not useful in gcc.
 882 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 883
 884 # Bison?
 885 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 886
 887 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 888 # check for build == host before using them.
 889
 890 # NM
 891 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 892   && test -d ../binutils ; then
 893   NM='$(objdir)/../binutils/nm-new'
 894 else
 895   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 896 fi
 897
 898 # AR
 899 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 900   && test -d ../binutils ; then
 901   AR='$(objdir)/../binutils/ar'
 902 else
 903   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 904 fi
 905
 906
 907 # --------------------
 908 # Checks for C headers
 909 # --------------------
 910
 911 # Need to reject headers which give warnings, so that the -Werror bootstrap
 912 # works later. *sigh*  This needs to come before all header checks.
 913 AC_PROG_CPP_WERROR
 914
 915 AC_HEADER_STDC
 916 AC_HEADER_TIME
 917 ACX_HEADER_STRING
 918 AC_HEADER_SYS_WAIT
 919 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 920                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 921                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 922                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 923
 924 # Check for thread headers.
 925 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 926 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 927
 928 # These tests can't be done till we know if we have limits.h.
 929 gcc_AC_C_CHAR_BIT
 930 AC_C_BIGENDIAN
 931
 932 # --------
 933 # UNSORTED
 934 # --------
 935
 936
 937 # These libraries may be used by collect2.
 938 # We may need a special search path to get them linked.
 939 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 940 [save_LIBS="$LIBS"
 941 for libs in '' -lld -lmld \
 942                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 943                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 944 do
 945         LIBS="$libs"
 946         AC_TRY_LINK_FUNC(ldopen,
 947                 [gcc_cv_collect2_libs="$libs"; break])
 948 done
 949 LIBS="$save_LIBS"
 950 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 951 case $gcc_cv_collect2_libs in
 952         "none required")        ;;
 953         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 954 esac
 955 AC_SUBST(COLLECT2_LIBS)
 956
 957 # When building Ada code on Alpha, we need exc_resume which is usually in
 958 # -lexc.  So test for it.
 959 save_LIBS="$LIBS"
 960 LIBS=
 961 AC_SEARCH_LIBS(exc_resume, exc)
 962 GNAT_LIBEXC="$LIBS"
 963 LIBS="$save_LIBS"
 964 AC_SUBST(GNAT_LIBEXC)
 965
 966 # Some systems put ldexp and frexp in libm instead of libc; assume
 967 # they're both in the same place.  jcf-dump needs them.
 968 save_LIBS="$LIBS"
 969 LIBS=
 970 AC_SEARCH_LIBS(ldexp, m)
 971 LDEXP_LIB="$LIBS"
 972 LIBS="$save_LIBS"
 973 AC_SUBST(LDEXP_LIB)
 974
 975 # Use <inttypes.h> only if it exists,
 976 # doesn't clash with <sys/types.h>, and declares intmax_t.
 977 AC_MSG_CHECKING(for inttypes.h)
 978 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 979 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 980 [[#include <sys/types.h>
 981 #include <inttypes.h>]],
 982   [[intmax_t i = -1;]])],
 983   [gcc_cv_header_inttypes_h=yes],
 984   [gcc_cv_header_inttypes_h=no])])
 985 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 986 if test $gcc_cv_header_inttypes_h = yes; then
 987   AC_DEFINE(HAVE_INTTYPES_H, 1,
 988         [Define if you have a working <inttypes.h> header file.])
 989 fi
 990
 991 dnl Disabled until we have a complete test for buggy enum bitfields.
 992 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 993
 994 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 995   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 996   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 997   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 998   putchar_unlocked putc_unlocked)
 999 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1000         sysconf strsignal getrusage nl_langinfo \
1001         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
1002         gcc_UNLOCKED_FUNCS)
1003
1004 if test x$ac_cv_func_mbstowcs = xyes; then
1005   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1006 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1007 int main()
1008 {
1009   mbstowcs(0, "", 0);
1010   return 0;
1011 }]])],
1012     [gcc_cv_func_mbstowcs_works=yes],
1013     [gcc_cv_func_mbstowcs_works=no],
1014     [gcc_cv_func_mbstowcs_works=yes])])
1015   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1016     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1017   [Define this macro if mbstowcs does not crash when its
1018    first argument is NULL.])
1019   fi
1020 fi
1021
1022 AC_CHECK_TYPE(ssize_t, int)
1023 AC_CHECK_TYPE(caddr_t, char *)
1024
1025 # Try to determine the array type of the second argument of getgroups
1026 # for the target system (int or gid_t).
1027 AC_TYPE_GETGROUPS
1028 if test "${target}" = "${build}"; then
1029   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1030 else
1031   case "${target}" in
1032         # This condition may need some tweaking.  It should include all
1033         # targets where the array type of the second argument of getgroups
1034         # is int and the type of gid_t is not equivalent to int.
1035         *-*-sunos* | *-*-ultrix*)
1036                 TARGET_GETGROUPS_T=int
1037                 ;;
1038         *)
1039                 TARGET_GETGROUPS_T=gid_t
1040                 ;;
1041   esac
1042 fi
1043 AC_SUBST(TARGET_GETGROUPS_T)
1044
1045 gcc_AC_FUNC_MMAP_BLACKLIST
1046
1047 case "${host}" in
1048 *-*-*vms*)
1049   # Under VMS, vfork works very differently than on Unix. The standard test
1050   # won't work, and it isn't easily adaptable. It makes more sense to
1051   # just force it.
1052   ac_cv_func_vfork_works=yes
1053   ;;
1054 esac
1055 AC_FUNC_FORK
1056
1057 AM_ICONV
1058 # Until we have in-tree GNU iconv:
1059 LIBICONV_DEP=
1060 AC_SUBST(LIBICONV_DEP)
1061
1062 AM_LC_MESSAGES
1063
1064 AM_LANGINFO_CODESET
1065
1066 # We will need to find libiberty.h and ansidecl.h
1067 saved_CFLAGS="$CFLAGS"
1068 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1069 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1070         strsignal strstr strverscmp \
1071         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1072         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1073 #include "ansidecl.h"
1074 #include "system.h"])
1075
1076 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1077 #include "ansidecl.h"
1078 #include "system.h"
1079 #ifdef HAVE_SYS_RESOURCE_H
1080 #include <sys/resource.h>
1081 #endif
1082 ])
1083
1084 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1085 #include "ansidecl.h"
1086 #include "system.h"
1087 #ifdef HAVE_SYS_RESOURCE_H
1088 #include <sys/resource.h>
1089 #endif
1090 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1091 [Define to `long' if <sys/resource.h> doesn't define.])])
1092
1093 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1094 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1095 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1096 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1097 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 #ifdef HAVE_LDFCN_H
1101 #undef FREAD
1102 #undef FWRITE
1103 #include <ldfcn.h>
1104 #endif
1105 ])
1106
1107 gcc_AC_CHECK_DECLS(times, , ,[
1108 #include "ansidecl.h"
1109 #include "system.h"
1110 #ifdef HAVE_SYS_TIMES_H
1111 #include <sys/times.h>
1112 #endif
1113 ])
1114
1115 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1116 #include "ansidecl.h"
1117 #include "system.h"
1118 #include <signal.h>
1119 ])
1120
1121 # More time-related stuff.
1122 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1123 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1124 #include "ansidecl.h"
1125 #include "system.h"
1126 #ifdef HAVE_SYS_TIMES_H
1127 #include <sys/times.h>
1128 #endif
1129 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1130 if test $ac_cv_struct_tms = yes; then
1131   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1132   [Define if <sys/times.h> defines struct tms.])
1133 fi
1134
1135 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1136 # revisit after autoconf 2.50.
1137 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1138 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1139 #include "ansidecl.h"
1140 #include "system.h"
1141 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1142 if test $gcc_cv_type_clock_t = yes; then
1143   AC_DEFINE(HAVE_CLOCK_T, 1,
1144   [Define if <time.h> defines clock_t.])
1145 fi
1146
1147 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1148 CFLAGS="$saved_CFLAGS"
1149
1150 gcc_AC_INITFINI_ARRAY
1151
1152 # mkdir takes a single argument on some systems.
1153 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1154
1155 # File extensions
1156 manext='.1'
1157 objext='.o'
1158 AC_SUBST(manext)
1159 AC_SUBST(objext)
1160
1161 # With Setjmp/Longjmp based exception handling.
1162 AC_ARG_ENABLE(sjlj-exceptions,
1163 [  --enable-sjlj-exceptions
1164                           arrange to use setjmp/longjmp exception handling],
1165 [case $target in
1166   *-*-hpux10*)
1167     if test $enableval != yes; then
1168       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1169       enableval=yes
1170     fi
1171     ;;
1172 esac
1173 force_sjlj_exceptions=yes],
1174 [case $target in
1175   *-*-hpux10*)
1176     force_sjlj_exceptions=yes
1177     enableval=yes
1178     ;;
1179   *)
1180     force_sjlj_exceptions=no
1181     ;;
1182 esac])
1183 if test $force_sjlj_exceptions = yes; then
1184   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1185   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1186     [Define 0/1 to force the choice for exception handling model.])
1187 fi
1188
1189 # For platforms with the unwind ABI which includes an unwind library,
1190 # libunwind, we can choose to use the system libunwind.
1191 AC_ARG_WITH(system-libunwind,
1192 [  --with-system-libunwind use installed libunwind])
1193
1194 # config.gcc also contains tests of with_system_libunwind.
1195 if test x$with_system_libunwind = xyes; then
1196         AC_DEFINE(HAVE_GETIPINFO, 1,
1197 [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1198 fi
1199
1200 # --------------------------------------------------------
1201 # Build, host, and target specific configuration fragments
1202 # --------------------------------------------------------
1203
1204 # Collect build-machine-specific information.
1205 . ${srcdir}/config.build
1206
1207 # Collect host-machine-specific information.
1208 . ${srcdir}/config.host
1209
1210 target_gtfiles=
1211
1212 # Collect target-machine-specific information.
1213 . ${srcdir}/config.gcc
1214
1215 extra_objs="${host_extra_objs} ${extra_objs}"
1216 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1217
1218 # Default the target-machine variables that were not explicitly set.
1219 if test x"$tm_file" = x
1220 then tm_file=$cpu_type/$cpu_type.h; fi
1221
1222 if test x"$extra_headers" = x
1223 then extra_headers=; fi
1224
1225 if test x$md_file = x
1226 then md_file=$cpu_type/$cpu_type.md; fi
1227
1228 if test x$out_file = x
1229 then out_file=$cpu_type/$cpu_type.c; fi
1230
1231 if test x"$tmake_file" = x
1232 then tmake_file=$cpu_type/t-$cpu_type
1233 fi
1234
1235 if test x"$dwarf2" = xyes
1236 then tm_file="$tm_file tm-dwarf2.h"
1237 fi
1238
1239 # Say what files are being used for the output code and MD file.
1240 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1241 echo "Using \`$srcdir/config/$md_file' as machine description file."
1242
1243 # If any of the xm_file variables contain nonexistent files, warn
1244 # about them and drop them.
1245
1246 bx=
1247 for x in $build_xm_file; do
1248   if    test -f $srcdir/config/$x
1249   then      bx="$bx $x"
1250   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1251   fi
1252 done
1253 build_xm_file="$bx"
1254
1255 hx=
1256 for x in $host_xm_file; do
1257   if    test -f $srcdir/config/$x
1258   then      hx="$hx $x"
1259   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1260   fi
1261 done
1262 host_xm_file="$hx"
1263
1264 tx=
1265 for x in $xm_file; do
1266   if    test -f $srcdir/config/$x
1267   then      tx="$tx $x"
1268   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1269   fi
1270 done
1271 xm_file="$tx"
1272
1273 count=a
1274 for f in $tm_file; do
1275         count=${count}x
1276 done
1277 if test $count = ax; then
1278         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1279 else
1280         echo "Using the following target machine macro files:"
1281         for f in $tm_file; do
1282                 echo "  $srcdir/config/$f"
1283         done
1284 fi
1285
1286 if test x$need_64bit_hwint = xyes; then
1287         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1288 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1289 fi
1290
1291 if test x$use_long_long_for_widest_fast_int = xyes; then
1292         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1293 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1294 efficiently supported by the host hardware.])
1295 fi
1296
1297 count=a
1298 for f in $host_xm_file; do
1299         count=${count}x
1300 done
1301 if test $count = a; then
1302         :
1303 elif test $count = ax; then
1304         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1305 else
1306         echo "Using the following host machine macro files:"
1307         for f in $host_xm_file; do
1308                 echo "  $srcdir/config/$f"
1309         done
1310 fi
1311 echo "Using ${out_host_hook_obj} for host machine hooks."
1312
1313 if test "$host_xm_file" != "$build_xm_file"; then
1314         count=a
1315         for f in $build_xm_file; do
1316                 count=${count}x
1317         done
1318         if test $count = a; then
1319                 :
1320         elif test $count = ax; then
1321                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1322         else
1323                 echo "Using the following build machine macro files:"
1324                 for f in $build_xm_file; do
1325                         echo "  $srcdir/config/$f"
1326                 done
1327         fi
1328 fi
1329
1330 case ${host} in
1331   powerpc*-*-darwin*)
1332     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1333       gcc_cv_mcontext_underscores,
1334       AC_COMPILE_IFELSE([
1335 #include <sys/cdefs.h>
1336 #include <sys/signal.h>
1337 #include <ucontext.h>
1338 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1339 ],
1340         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1341       if test $gcc_cv_mcontext_underscores = yes; then
1342         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1343           [mcontext_t fields start with __])
1344       fi
1345     ;;
1346 esac
1347
1348 # ---------
1349 # Threading
1350 # ---------
1351
1352 # Check if a valid thread package
1353 case ${enable_threads} in
1354   "" | no)
1355     # No threads
1356     target_thread_file='single'
1357     ;;
1358   yes)
1359     # default
1360     target_thread_file='single'
1361     ;;
1362   aix | dce | gnat | irix | posix | posix95 | rtems | \
1363   single | solaris | vxworks | win32 | mipssde)
1364     target_thread_file=${enable_threads}
1365     ;;
1366   *)
1367     echo "${enable_threads} is an unknown thread package" 1>&2
1368     exit 1
1369     ;;
1370 esac
1371
1372 if test x${thread_file} = x; then
1373   # No thread file set by target-specific clauses in config.gcc,
1374   # so use file chosen by default logic above
1375   thread_file=${target_thread_file}
1376 fi
1377
1378 # Make gthr-default.h if we have a thread file.
1379 gthread_flags=
1380 if test $thread_file != single; then
1381   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1382   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1383     rm -f gthr-default.h-t
1384   else
1385     mv -f gthr-default.h-t gthr-default.h
1386   fi
1387   gthread_flags=-DHAVE_GTHR_DEFAULT
1388 fi
1389 AC_SUBST(gthread_flags)
1390
1391 # --------
1392 # UNSORTED
1393 # --------
1394
1395 use_cxa_atexit=no
1396 if test x$enable___cxa_atexit = xyes || \
1397    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1398   if test x$host = x$target; then
1399     case $host in
1400       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1401       # keyed to flag_use_cxa_atexit
1402       *-*-mingw32*)
1403         use_cxa_atexit=yes
1404         ;;
1405       *)
1406         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1407           [echo "__cxa_atexit can't be enabled on this target"])
1408         ;;
1409     esac
1410   else
1411     # We can't check for __cxa_atexit when building a cross, so assume
1412     # it is available
1413     use_cxa_atexit=yes
1414   fi
1415   if test x$use_cxa_atexit = xyes; then
1416     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1417       [Define if you want to use __cxa_atexit, rather than atexit, to
1418       register C++ destructors for local statics and global objects.
1419       This is essential for fully standards-compliant handling of
1420       destructors, but requires __cxa_atexit in libc.])
1421   fi
1422 fi
1423
1424 use_getipinfo=yes
1425 if test x$with_system_libunwind = xyes; then
1426    if test x$host = x$target; then
1427      AC_SEARCH_LIBS(_Unwind_GetIPInfo, unwind,, [use_getipinfo=no])
1428    fi
1429 fi
1430 GCC_TARGET_TEMPLATE(HAVE_GETIPINFO)
1431 if test x$use_getipinfo = xyes; then
1432    AC_DEFINE(HAVE_GETIPINFO, 1,
1433         [Define to 1 if system unwind library has _Unwind_GetIPInfo.])
1434 else
1435    echo "The system unwind library does not support _Unwind_GetIPInfo."
1436 fi
1437
1438 # Look for a file containing extra machine modes.
1439 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1440   extra_modes_file='$(srcdir)'/config/${extra_modes}
1441   AC_SUBST(extra_modes_file)
1442   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1443   [Define to the name of a file containing a list of extra machine modes
1444    for this architecture.])
1445 fi
1446
1447 # Convert extra_options into a form suitable for Makefile use.
1448 extra_opt_files=
1449 for f in $extra_options; do
1450   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1451 done
1452 AC_SUBST(extra_opt_files)
1453
1454 # auto-host.h is the file containing items generated by autoconf and is
1455 # the first file included by config.h.
1456 # If host=build, it is correct to have bconfig include auto-host.h
1457 # as well.  If host!=build, we are in error and need to do more
1458 # work to find out the build config parameters.
1459 if test x$host = x$build
1460 then
1461         build_auto=auto-host.h
1462 else
1463         # We create a subdir, then run autoconf in the subdir.
1464         # To prevent recursion we set host and build for the new
1465         # invocation of configure to the build for this invocation
1466         # of configure.
1467         tempdir=build.$$
1468         rm -rf $tempdir
1469         mkdir $tempdir
1470         cd $tempdir
1471         case ${srcdir} in
1472         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1473         *) realsrcdir=../${srcdir};;
1474         esac
1475         saved_CFLAGS="${CFLAGS}"
1476         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1477         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1478         ${realsrcdir}/configure \
1479                 --enable-languages=${enable_languages-all} \
1480                 --target=$target_alias --host=$build_alias --build=$build_alias
1481         CFLAGS="${saved_CFLAGS}"
1482
1483         # We just finished tests for the build machine, so rename
1484         # the file auto-build.h in the gcc directory.
1485         mv auto-host.h ../auto-build.h
1486         cd ..
1487         rm -rf $tempdir
1488         build_auto=auto-build.h
1489 fi
1490 AC_SUBST(build_subdir)
1491
1492 tm_file="${tm_file} defaults.h"
1493 tm_p_file="${tm_p_file} tm-preds.h"
1494 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1495 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1496 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1497 # put this back in temporarily.
1498 xm_file="auto-host.h ansidecl.h ${xm_file}"
1499
1500 # --------
1501 # UNSORTED
1502 # --------
1503
1504 changequote(,)dnl
1505 # Compile in configure arguments.
1506 if test -f configargs.h ; then
1507         # Being re-configured.
1508         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1509         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1510 else
1511         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1512 fi
1513
1514 # Double all backslashes and backslash all quotes to turn
1515 # gcc_config_arguments into a C string.
1516 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1517 $gcc_config_arguments
1518 EOF
1519 gcc_config_arguments_str=`cat conftest.out`
1520 rm -f conftest.out
1521
1522 cat > configargs.h <<EOF
1523 /* Generated automatically. */
1524 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1525 static const char thread_model[] = "$thread_file";
1526
1527 static const struct {
1528   const char *name, *value;
1529 } configure_default_options[] = $configure_default_options;
1530 EOF
1531 changequote([,])dnl
1532
1533 # Internationalization
1534 ZW_GNU_GETTEXT_SISTER_DIR
1535
1536 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1537 # -liconv on the link line twice.
1538 case "$LIBINTL" in *$LIBICONV*)
1539         LIBICONV= ;;
1540 esac
1541
1542 AC_ARG_ENABLE(secureplt,
1543 [  --enable-secureplt      enable -msecure-plt by default for PowerPC],
1544 [], [])
1545
1546 AC_ARG_ENABLE(cld,
1547 [  --enable-cld            enable -mcld by default for 32bit x86], [],
1548 [enable_cld=no])
1549
1550 # Windows32 Registry support for specifying GCC installation paths.
1551 AC_ARG_ENABLE(win32-registry,
1552 [  --disable-win32-registry
1553                           disable lookup of installation paths in the
1554                           Registry on Windows hosts
1555   --enable-win32-registry enable registry lookup (default)
1556   --enable-win32-registry=KEY
1557                           use KEY instead of GCC version as the last portion
1558                           of the registry key],,)
1559
1560 case $host_os in
1561   win32 | pe | cygwin* | mingw32* | uwin*)
1562     if test "x$enable_win32_registry" != xno; then
1563       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1564     fi
1565
1566     if test "x$enable_win32_registry" != xno; then
1567       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1568   [Define to 1 if installation paths should be looked up in the Windows
1569    Registry. Ignored on non-Windows hosts.])
1570
1571       if test "x$enable_win32_registry" != xyes \
1572          && test "x$enable_win32_registry" != x; then
1573         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1574   [Define to be the last component of the Windows registry key under which
1575    to look for installation paths.  The full key used will be
1576    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1577    The default is the GCC version number.])
1578       fi
1579     fi
1580   ;;
1581 esac
1582
1583 # Get an absolute path to the GCC top-level source directory
1584 holddir=`${PWDCMD-pwd}`
1585 cd $srcdir
1586 topdir=`${PWDCMD-pwd}`
1587 cd $holddir
1588
1589 # Conditionalize the makefile for this host machine.
1590 xmake_file=
1591 for f in ${host_xmake_file}
1592 do
1593         if test -f ${srcdir}/config/$f
1594         then
1595                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1596         fi
1597 done
1598
1599 # Conditionalize the makefile for this target machine.
1600 tmake_file_=
1601 for f in ${tmake_file}
1602 do
1603         if test -f ${srcdir}/config/$f
1604         then
1605                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1606         fi
1607 done
1608 tmake_file="${tmake_file_}"
1609
1610 out_object_file=`basename $out_file .c`.o
1611
1612 tm_file_list="options.h"
1613 tm_include_list="options.h"
1614 for f in $tm_file; do
1615   case $f in
1616     ./* )
1617        f=`echo $f | sed 's/^..//'`
1618        tm_file_list="${tm_file_list} $f"
1619        tm_include_list="${tm_include_list} $f"
1620        ;;
1621     defaults.h )
1622        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1623        tm_include_list="${tm_include_list} $f"
1624        ;;
1625     * )
1626        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1627        tm_include_list="${tm_include_list} config/$f"
1628        ;;
1629   esac
1630 done
1631
1632 tm_p_file_list=
1633 tm_p_include_list=
1634 for f in $tm_p_file; do
1635   case $f in
1636     tm-preds.h )
1637        tm_p_file_list="${tm_p_file_list} $f"
1638        tm_p_include_list="${tm_p_include_list} $f"
1639        ;;
1640     * )
1641        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1642        tm_p_include_list="${tm_p_include_list} config/$f"
1643   esac
1644 done
1645
1646 xm_file_list=
1647 xm_include_list=
1648 for f in $xm_file; do
1649   case $f in
1650     ansidecl.h )
1651        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1652        xm_include_list="${xm_include_list} $f"
1653        ;;
1654     auto-host.h )
1655        xm_file_list="${xm_file_list} $f"
1656        xm_include_list="${xm_include_list} $f"
1657        ;;
1658     * )
1659        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1660        xm_include_list="${xm_include_list} config/$f"
1661        ;;
1662   esac
1663 done
1664
1665 host_xm_file_list=
1666 host_xm_include_list=
1667 for f in $host_xm_file; do
1668   case $f in
1669     ansidecl.h )
1670        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1671        host_xm_include_list="${host_xm_include_list} $f"
1672        ;;
1673     auto-host.h )
1674        host_xm_file_list="${host_xm_file_list} $f"
1675        host_xm_include_list="${host_xm_include_list} $f"
1676        ;;
1677     * )
1678        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1679        host_xm_include_list="${host_xm_include_list} config/$f"
1680        ;;
1681   esac
1682 done
1683
1684 build_xm_file_list=
1685 for f in $build_xm_file; do
1686   case $f in
1687     ansidecl.h )
1688        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1689        build_xm_include_list="${build_xm_include_list} $f"
1690        ;;
1691     auto-build.h | auto-host.h )
1692        build_xm_file_list="${build_xm_file_list} $f"
1693        build_xm_include_list="${build_xm_include_list} $f"
1694        ;;
1695     * )
1696        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1697        build_xm_include_list="${build_xm_include_list} config/$f"
1698        ;;
1699   esac
1700 done
1701
1702 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1703 # cross-compiler which does not use the native headers and libraries.
1704 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1705 CROSS=                                          AC_SUBST(CROSS)
1706 ALL=all.internal                                AC_SUBST(ALL)
1707 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1708
1709 if test "x$with_build_sysroot" != x; then
1710   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1711 else
1712   # This value is used, even on a native system, because
1713   # CROSS_SYSTEM_HEADER_DIR is just
1714   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1715   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1716 fi
1717
1718 if test x$host != x$target
1719 then
1720         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1721         ALL=all.cross
1722         SYSTEM_HEADER_DIR=$build_system_header_dir
1723         case "$host","$target" in
1724         # Darwin crosses can use the host system's libraries and headers,
1725         # because of the fat library support.  Of course, it must be the
1726         # same version of Darwin on both sides.  Allow the user to
1727         # just say --target=foo-darwin without a version number to mean
1728         # "the version on this system".
1729             *-*-darwin*,*-*-darwin*)
1730                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1731                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1732                 if test $hostos = $targetos -o $targetos = darwin ; then
1733                     CROSS=
1734                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1735                     with_headers=yes
1736                 fi
1737                 ;;
1738
1739             i?86-*-*,x86_64-*-* \
1740             | powerpc*-*-*,powerpc64*-*-*)
1741                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1742         esac
1743 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1744         SYSTEM_HEADER_DIR=$build_system_header_dir
1745 fi
1746
1747 # If this is a cross-compiler that does not
1748 # have its own set of headers then define
1749 # inhibit_libc
1750
1751 # If this is using newlib, without having the headers available now,
1752 # then define inhibit_libc in LIBGCC2_CFLAGS.
1753 # This prevents libgcc2 from containing any code which requires libc
1754 # support.
1755 : ${inhibit_libc=false}
1756 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1757        test x$with_newlib = xyes ; } &&
1758      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1759        inhibit_libc=true
1760 fi
1761 AC_SUBST(inhibit_libc)
1762
1763 # When building gcc with a cross-compiler, we need to adjust things so
1764 # that the generator programs are still built with the native compiler.
1765 # Also, we cannot run fixincludes or fix-header.
1766
1767 # These are the normal (build=host) settings:
1768 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1769 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1770 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1771 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1772
1773 # Possibly disable fixproto, on a per-target basis.
1774 case ${use_fixproto} in
1775   no)
1776     STMP_FIXPROTO=
1777     ;;
1778   yes)
1779     STMP_FIXPROTO=stmp-fixproto
1780     ;;
1781 esac
1782 AC_SUBST(STMP_FIXPROTO)
1783
1784 # And these apply if build != host, or we are generating coverage data
1785 if test x$build != x$host || test "x$coverage_flags" != x
1786 then
1787     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1788     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1789
1790     if test "x$TARGET_SYSTEM_ROOT" = x; then
1791         if test "x$STMP_FIXPROTO" != x; then
1792           STMP_FIXPROTO=stmp-install-fixproto
1793         fi
1794     fi
1795 fi
1796
1797 # Expand extra_headers to include complete path.
1798 # This substitutes for lots of t-* files.
1799 extra_headers_list=
1800 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1801 for file in ${extra_headers} ; do
1802   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1803 done
1804
1805 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1806 if test x"$use_gcc_tgmath" = xyes
1807 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1808 fi
1809
1810 # Define collect2 in Makefile.
1811 case $host_can_use_collect2 in
1812   no) collect2= ;;
1813   *) collect2='collect2$(exeext)' ;;
1814 esac
1815 AC_SUBST([collect2])
1816
1817 # Add a definition of USE_COLLECT2 if system wants one.
1818 case $use_collect2 in
1819   no) use_collect2= ;;
1820   "") ;;
1821   *)
1822     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1823     xm_defines="${xm_defines} USE_COLLECT2"
1824     case $host_can_use_collect2 in
1825       no)
1826         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1827         ;;
1828     esac
1829     ;;
1830 esac
1831
1832 # ---------------------------
1833 # Assembler & linker features
1834 # ---------------------------
1835
1836 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1837 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1838 # However when ld-new is first executed from the build tree, libtool will
1839 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1840 # to the build tree.  While doing this we need to use the previous-stage
1841 # linker, or we have an infinite loop.  The presence of a shell script as
1842 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1843 # the gcc/collect-ld script.  So we need to know how libtool works, or
1844 # exec-tool will fail.
1845
1846 m4_defun([_LT_CONFIG_COMMANDS], [])
1847 AC_PROG_LIBTOOL
1848 AC_SUBST(objdir)
1849 AC_SUBST(enable_fast_install)
1850
1851 # Identify the assembler which will work hand-in-glove with the newly
1852 # built GCC, so that we can examine its features.  This is the assembler
1853 # which will be driven by the driver program.
1854 #
1855 # If build != host, and we aren't building gas in-tree, we identify a
1856 # build->target assembler and hope that it will have the same features
1857 # as the host->target assembler we'll be using.
1858 gcc_cv_gas_major_version=
1859 gcc_cv_gas_minor_version=
1860 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1861
1862 m4_pattern_allow([AS_FOR_TARGET])dnl
1863 AS_VAR_SET_IF(gcc_cv_as,, [
1864 if test -x "$DEFAULT_ASSEMBLER"; then
1865         gcc_cv_as="$DEFAULT_ASSEMBLER"
1866 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1867      && test -f ../gas/Makefile \
1868      && test x$build = x$host; then
1869         gcc_cv_as=../gas/as-new$build_exeext
1870 elif test -x as$build_exeext; then
1871         # Build using assembler in the current directory.
1872         gcc_cv_as=./as$build_exeext
1873 elif test -x $AS_FOR_TARGET; then
1874         gcc_cv_as="$AS_FOR_TARGET"
1875 else
1876         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1877 fi])
1878
1879 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1880 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1881 case "$ORIGINAL_AS_FOR_TARGET" in
1882   ./as | ./as$build_exeext) ;;
1883   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1884 esac
1885
1886 AC_MSG_CHECKING(what assembler to use)
1887 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1888   # Single tree build which includes gas.  We want to prefer it
1889   # over whatever linker top-level may have detected, since
1890   # we'll use what we're building after installation anyway.
1891   AC_MSG_RESULT(newly built gas)
1892   in_tree_gas=yes
1893   _gcc_COMPUTE_GAS_VERSION
1894   in_tree_gas_is_elf=no
1895   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1896      || (grep 'obj_format = multi' ../gas/Makefile \
1897          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1898   then
1899     in_tree_gas_is_elf=yes
1900   fi
1901 else
1902   AC_MSG_RESULT($gcc_cv_as)
1903   in_tree_gas=no
1904 fi
1905
1906 # Identify the linker which will work hand-in-glove with the newly
1907 # built GCC, so that we can examine its features.  This is the linker
1908 # which will be driven by the driver program.
1909 #
1910 # If build != host, and we aren't building gas in-tree, we identify a
1911 # build->target linker and hope that it will have the same features
1912 # as the host->target linker we'll be using.
1913 gcc_cv_gld_major_version=
1914 gcc_cv_gld_minor_version=
1915 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1916 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1917
1918 AS_VAR_SET_IF(gcc_cv_ld,, [
1919 if test -x "$DEFAULT_LINKER"; then
1920         gcc_cv_ld="$DEFAULT_LINKER"
1921 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1922      && test -f ../ld/Makefile \
1923      && test x$build = x$host; then
1924         gcc_cv_ld=../ld/ld-new$build_exeext
1925 elif test -x collect-ld$build_exeext; then
1926         # Build using linker in the current directory.
1927         gcc_cv_ld=./collect-ld$build_exeext
1928 elif test -x $LD_FOR_TARGET; then
1929         gcc_cv_ld="$LD_FOR_TARGET"
1930 else
1931         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1932 fi])
1933
1934 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1935 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1936 case "$ORIGINAL_LD_FOR_TARGET" in
1937   ./collect-ld | ./collect-ld$build_exeext) ;;
1938   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1939 esac
1940
1941 AC_MSG_CHECKING(what linker to use)
1942 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext; then
1943         # Single tree build which includes ld.  We want to prefer it
1944         # over whatever linker top-level may have detected, since
1945         # we'll use what we're building after installation anyway.
1946         AC_MSG_RESULT(newly built ld)
1947         in_tree_ld=yes
1948         in_tree_ld_is_elf=no
1949         if (grep 'EMUL = .*elf' ../ld/Makefile \
1950             || grep 'EMUL = .*linux' ../ld/Makefile \
1951             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1952           in_tree_ld_is_elf=yes
1953         fi
1954         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1955         do
1956 changequote(,)dnl
1957                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1958                 if test x$gcc_cv_gld_version != x; then
1959                         break
1960                 fi
1961         done
1962         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1963         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1964 changequote([,])dnl
1965 else
1966         AC_MSG_RESULT($gcc_cv_ld)
1967         in_tree_ld=no
1968 fi
1969
1970 # Figure out what nm we will be using.
1971 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1972 AS_VAR_SET_IF(gcc_cv_nm,, [
1973 if test -f $gcc_cv_binutils_srcdir/configure.in \
1974      && test -f ../binutils/Makefile \
1975      && test x$build = x$host; then
1976         gcc_cv_nm=../binutils/nm-new$build_exeext
1977 elif test -x nm$build_exeext; then
1978         gcc_cv_nm=./nm$build_exeext
1979 elif test -x $NM_FOR_TARGET; then
1980         gcc_cv_nm="$NM_FOR_TARGET"
1981 else
1982         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
1983 fi])
1984
1985 AC_MSG_CHECKING(what nm to use)
1986 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
1987         # Single tree build which includes binutils.
1988         AC_MSG_RESULT(newly built nm)
1989         in_tree_nm=yes
1990 else
1991         AC_MSG_RESULT($gcc_cv_nm)
1992         in_tree_nm=no
1993 fi
1994
1995 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
1996 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
1997 case "$ORIGINAL_NM_FOR_TARGET" in
1998   ./nm | ./nm$build_exeext) ;;
1999   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2000 esac
2001
2002
2003 # Figure out what objdump we will be using.
2004 AS_VAR_SET_IF(gcc_cv_objdump,, [
2005 if test -f $gcc_cv_binutils_srcdir/configure.in \
2006      && test -f ../binutils/Makefile \
2007      && test x$build = x$host; then
2008         # Single tree build which includes binutils.
2009         gcc_cv_objdump=../binutils/objdump$build_exeext
2010 elif test -x objdump$build_exeext; then
2011         gcc_cv_objdump=./objdump$build_exeext
2012 elif test -x $OBJDUMP_FOR_TARGET; then
2013         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2014 else
2015         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2016 fi])
2017
2018 AC_MSG_CHECKING(what objdump to use)
2019 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2020         # Single tree build which includes binutils.
2021         AC_MSG_RESULT(newly built objdump)
2022 elif test x$gcc_cv_objdump = x; then
2023         AC_MSG_RESULT(not found)
2024 else
2025         AC_MSG_RESULT($gcc_cv_objdump)
2026 fi
2027
2028 # Figure out what assembler alignment features are present.
2029 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2030  [2,6,0],,
2031 [.balign 4
2032 .p2align 2],,
2033 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2034   [Define if your assembler supports .balign and .p2align.])])
2035
2036 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2037  [2,8,0],,
2038  [.p2align 4,,7],,
2039 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2040   [Define if your assembler supports specifying the maximum number
2041    of bytes to skip when using the GAS .p2align command.])])
2042
2043 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2044  [2,8,0],,
2045  [.literal16],,
2046 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2047   [Define if your assembler supports .literal16.])])
2048
2049 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2050  [elf,2,9,0],,
2051  [conftest_label1: .word 0
2052 .subsection -1
2053 conftest_label2: .word 0
2054 .previous],
2055  [if test x$gcc_cv_nm != x; then
2056     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2057     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2058     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2059     then :
2060     else gcc_cv_as_subsection_m1=yes
2061     fi
2062     rm -f conftest.nm1 conftest.nm2
2063   fi],
2064  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2065   [Define if your assembler supports .subsection and .subsection -1 starts
2066    emitting at the beginning of your section.])])
2067
2068 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2069  [2,2,0],,
2070  [      .weak foobar],,
2071 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2072
2073 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2074  [2,17,0],,
2075  [      .weakref foobar, barfnot],,
2076 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2077
2078 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2079  [2,15,91],,
2080  [      .SPACE $TEXT$
2081         .NSUBSPA $CODE$,COMDAT],,
2082 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2083
2084 # .hidden needs to be supported in both the assembler and the linker,
2085 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2086 # This is irritatingly difficult to feature test for; we have to check the
2087 # date string after the version number.  If we've got an in-tree
2088 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2089 # to be safe.
2090 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2091 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2092  [elf,2,13,0],,
2093 [       .hidden foobar
2094 foobar:])
2095
2096 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2097 [if test $in_tree_ld = yes ; then
2098   gcc_cv_ld_hidden=no
2099   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2100      && test $in_tree_ld_is_elf = yes; then
2101      gcc_cv_ld_hidden=yes
2102   fi
2103 else
2104   gcc_cv_ld_hidden=yes
2105   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2106   if echo "$ld_ver" | grep GNU > /dev/null; then
2107 changequote(,)dnl
2108     ld_vers=`echo $ld_ver | sed -n \
2109         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2110     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2111     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2112     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2113     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2114     if test 0"$ld_date" -lt 20020404; then
2115       if test -n "$ld_date"; then
2116         # If there was date string, but was earlier than 2002-04-04, fail
2117         gcc_cv_ld_hidden=no
2118       elif test -z "$ld_vers"; then
2119         # If there was no date string nor ld version number, something is wrong
2120         gcc_cv_ld_hidden=no
2121       else
2122         test -z "$ld_vers_patch" && ld_vers_patch=0
2123         if test "$ld_vers_major" -lt 2; then
2124           gcc_cv_ld_hidden=no
2125         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2126           gcc_cv_ld_hidden="no"
2127         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2128           gcc_cv_ld_hidden=no
2129         fi
2130       fi
2131 changequote([,])dnl
2132     fi
2133   else
2134     case "${target}" in
2135       hppa64*-*-hpux* | ia64*-*-hpux*)
2136         gcc_cv_ld_hidden=yes
2137         ;;
2138       *)
2139         gcc_cv_ld_hidden=no
2140         ;;
2141     esac
2142   fi
2143 fi])
2144 libgcc_visibility=no
2145 AC_SUBST(libgcc_visibility)
2146 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2147 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2148   libgcc_visibility=yes
2149   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2150   [Define if your assembler and linker support .hidden.])
2151 fi
2152
2153 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2154 gcc_cv_ld_ro_rw_mix=unknown
2155 if test $in_tree_ld = yes ; then
2156   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2157      && test $in_tree_ld_is_elf = yes; then
2158     gcc_cv_ld_ro_rw_mix=read-write
2159   fi
2160 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2161   echo '.section myfoosect, "a"' > conftest1.s
2162   echo '.section myfoosect, "aw"' > conftest2.s
2163   echo '.byte 1' >> conftest2.s
2164   echo '.section myfoosect, "a"' > conftest3.s
2165   echo '.byte 0' >> conftest3.s
2166   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2167      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2168      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2169      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2170         conftest2.o conftest3.o > /dev/null 2>&1; then
2171     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2172                          | sed -e '/myfoosect/!d' -e N`
2173     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2174       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2175         gcc_cv_ld_ro_rw_mix=read-only
2176       else
2177         gcc_cv_ld_ro_rw_mix=read-write
2178       fi
2179     fi
2180   fi
2181 changequote(,)dnl
2182   rm -f conftest.* conftest[123].*
2183 changequote([,])dnl
2184 fi
2185 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2186         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2187   [Define if your linker links a mix of read-only
2188    and read-write sections into a read-write section.])
2189 fi
2190 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2191
2192 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2193 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2194   [elf,2,11,0],,
2195 [       .data
2196         .uleb128 L2 - L1
2197 L1:
2198         .uleb128 1280
2199         .sleb128 -1010
2200 L2:],
2201  [# GAS versions before 2.11 do not support uleb128,
2202   # despite appearing to.
2203   # ??? There exists an elf-specific test that will crash
2204   # the assembler.  Perhaps it's better to figure out whether
2205   # arbitrary sections are supported and try the test.
2206   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2207   if echo "$as_ver" | grep GNU > /dev/null; then
2208 changequote(,)dnl
2209     as_vers=`echo $as_ver | sed -n \
2210         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2211     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2212     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2213 changequote([,])dnl
2214     if test $as_major -eq 2 && test $as_minor -lt 11
2215     then :
2216     else gcc_cv_as_leb128=yes
2217     fi
2218   fi],
2219   [AC_DEFINE(HAVE_AS_LEB128, 1,
2220     [Define if your assembler supports .sleb128 and .uleb128.])])
2221
2222 # Check if we have assembler support for unwind directives.
2223 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2224   ,,
2225 [       .text
2226         .cfi_startproc
2227         .cfi_offset 0, 0
2228         .cfi_same_value 1
2229         .cfi_def_cfa 1, 2
2230         .cfi_escape 1, 2, 3, 4, 5
2231         .cfi_endproc],
2232 [case "$target" in
2233   *-*-solaris*)
2234     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2235     # read-only and read-write sections, we need to make sure that the
2236     # assembler used emits read-write .eh_frame sections.
2237     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2238       if test "x$gcc_cv_objdump" != x; then
2239         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2240                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2241           gcc_cv_as_cfi_directive=no
2242         else
2243           gcc_cv_as_cfi_directive=yes
2244         fi
2245       else
2246         # no objdump, err on the side of caution
2247         gcc_cv_as_cfi_directive=no
2248       fi
2249     else
2250       gcc_cv_as_cfi_directive=yes
2251     fi
2252     ;;
2253   *-*-*)
2254     gcc_cv_as_cfi_directive=yes
2255     ;;
2256 esac])
2257 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2258   [`if test $gcc_cv_as_cfi_directive = yes; then echo 1; else echo 0; fi`],
2259   [Define 0/1 if your assembler supports CFI directives.])
2260
2261 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2262   gcc_cv_as_cfi_personality_directive, ,,
2263 [       .text
2264         .cfi_startproc
2265         .cfi_personality 0, symbol
2266         .cfi_endproc])
2267 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2268   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2269     then echo 1; else echo 0; fi`],
2270   [Define 0/1 if your assembler supports .cfi_personality.])
2271
2272 # GAS versions up to and including 2.11.0 may mis-optimize
2273 # .eh_frame data.
2274 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2275   [elf,2,12,0],,
2276 [       .text
2277 .LFB1:
2278         .4byte  0
2279 .L1:
2280         .4byte  0
2281 .LFE1:
2282         .section        .eh_frame,"aw",@progbits
2283 __FRAME_BEGIN__:
2284         .4byte  .LECIE1-.LSCIE1
2285 .LSCIE1:
2286         .4byte  0x0
2287         .byte   0x1
2288         .ascii "z\0"
2289         .byte   0x1
2290         .byte   0x78
2291         .byte   0x1a
2292         .byte   0x0
2293         .byte   0x4
2294         .4byte  1
2295         .p2align 1
2296 .LECIE1:
2297 .LSFDE1:
2298         .4byte  .LEFDE1-.LASFDE1
2299 .LASFDE1:
2300         .4byte  .LASFDE1-__FRAME_BEGIN__
2301         .4byte  .LFB1
2302         .4byte  .LFE1-.LFB1
2303         .byte   0x4
2304         .4byte  .LFE1-.LFB1
2305         .byte   0x4
2306         .4byte  .L1-.LFB1
2307 .LEFDE1:],
2308 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2309 cat > conftest.lit <<EOF
2310  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2311  0010 01000000 12000000 18000000 00000000  ................
2312  0020 08000000 04080000 0044               .........D      @&t@
2313 EOF
2314 cat > conftest.big <<EOF
2315  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2316  0010 00000001 00000012 00000018 00000000  ................
2317  0020 00000008 04000000 0844               .........D      @&t@
2318 EOF
2319   # If the assembler didn't choke, and we can objdump,
2320   # and we got the correct data, then succeed.
2321   # The text in the here-document typically retains its unix-style line
2322   # endings, while the output of objdump will use host line endings.
2323   # Therefore, use diff -b for the comparisons.
2324   if test x$gcc_cv_objdump != x \
2325   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2326      | tail -3 > conftest.got \
2327   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2328     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2329   then
2330     gcc_cv_as_eh_frame=yes
2331   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2332     gcc_cv_as_eh_frame=buggy
2333   else
2334     # Uh oh, what do we do now?
2335     gcc_cv_as_eh_frame=no
2336   fi])
2337
2338 if test $gcc_cv_as_eh_frame = buggy; then
2339   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2340   [Define if your assembler mis-optimizes .eh_frame data.])
2341 fi
2342
2343 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2344  [elf,2,12,0], [--fatal-warnings],
2345  [.section .rodata.str, "aMS", @progbits, 1])
2346 if test $gcc_cv_as_shf_merge = no; then
2347   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2348     [elf,2,12,0], [--fatal-warnings],
2349     [.section .rodata.str, "aMS", %progbits, 1])
2350 fi
2351 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2352   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2353 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2354
2355 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2356  [elf,2,16,0], [--fatal-warnings],
2357  [.section .text,"axG",@progbits,.foo,comdat])
2358 if test $gcc_cv_as_comdat_group = yes; then
2359   gcc_cv_as_comdat_group_percent=no
2360 else
2361  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2362    [elf,2,16,0], [--fatal-warnings],
2363    [.section .text,"axG",%progbits,.foo,comdat])
2364 fi
2365 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2366   comdat_group=yes
2367   if test 0"$ld_date" -lt 20050308; then
2368     if test -n "$ld_date"; then
2369       # If there was date string, but was earlier than 2005-03-08, fail
2370       comdat_group=no
2371     elif test "$ld_vers_major" -lt 2; then
2372       comdat_group=no
2373     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2374       comdat_group=no
2375     fi
2376   fi
2377 else
2378   # assume linkers other than GNU ld don't support COMDAT group
2379   comdat_group=no
2380 fi
2381 if test $comdat_group = no; then
2382   gcc_cv_as_comdat_group=no
2383   gcc_cv_as_comdat_group_percent=no
2384 fi
2385 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2386   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2387 [Define 0/1 if your assembler and linker support COMDAT groups.])
2388
2389 # Thread-local storage - the check is heavily parameterized.
2390 conftest_s=
2391 tls_first_major=
2392 tls_first_minor=
2393 tls_as_opt=
2394 case "$target" in
2395 changequote(,)dnl
2396   alpha*-*-*)
2397     conftest_s='
2398         .section ".tdata","awT",@progbits
2399 foo:    .long   25
2400         .text
2401         ldq     $27,__tls_get_addr($29)         !literal!1
2402         lda     $16,foo($29)                    !tlsgd!1
2403         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2404         ldq     $27,__tls_get_addr($29)         !literal!2
2405         lda     $16,foo($29)                    !tlsldm!2
2406         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2407         ldq     $1,foo($29)                     !gotdtprel
2408         ldah    $2,foo($29)                     !dtprelhi
2409         lda     $3,foo($2)                      !dtprello
2410         lda     $4,foo($29)                     !dtprel
2411         ldq     $1,foo($29)                     !gottprel
2412         ldah    $2,foo($29)                     !tprelhi
2413         lda     $3,foo($2)                      !tprello
2414         lda     $4,foo($29)                     !tprel'
2415         tls_first_major=2
2416         tls_first_minor=13
2417         tls_as_opt=--fatal-warnings
2418         ;;
2419   frv*-*-*)
2420     conftest_s='
2421         .section ".tdata","awT",@progbits
2422 x:      .long   25
2423         .text
2424         call    #gettlsoff(x)'
2425         tls_first_major=2
2426         tls_first_minor=14
2427         ;;
2428   hppa*-*-linux*)
2429     conftest_s='
2430 t1:     .reg    %r20
2431 t2:     .reg    %r21
2432 gp:     .reg    %r19
2433         .section ".tdata","awT",@progbits
2434 foo:    .long   25
2435         .text
2436         .align  4
2437         addil LT%foo-$tls_gdidx$,gp
2438         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2439         b __tls_get_addr
2440         nop
2441         addil LT%foo-$tls_ldidx$,gp
2442         b __tls_get_addr
2443         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2444         addil LR%foo-$tls_dtpoff$,%ret0
2445         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2446         mfctl %cr27,%t1
2447         addil LT%foo-$tls_ieoff$,gp
2448         ldw RT%foo-$tls_ieoff$(%r1),%t2
2449         add %t1,%t2,%t3
2450         mfctl %cr27,%t1
2451         addil LR%foo-$tls_leoff$,%t1
2452         ldo RR%foo-$tls_leoff$(%r1),%t2'
2453         tls_first_major=2
2454         tls_first_minor=15
2455         tls_as_opt=--fatal-warnings
2456         ;;
2457   arm*-*-*)
2458     conftest_s='
2459         .section ".tdata","awT",%progbits
2460 foo:    .long   25
2461         .text
2462 .word foo(gottpoff)
2463 .word foo(tpoff)
2464 .word foo(tlsgd)
2465 .word foo(tlsldm)
2466 .word foo(tlsldo)'
2467         tls_first_major=2
2468         tls_first_minor=17
2469         ;;
2470   i[34567]86-*-*)
2471     conftest_s='
2472         .section ".tdata","awT",@progbits
2473 foo:    .long   25
2474         .text
2475         movl    %gs:0, %eax
2476         leal    foo@TLSGD(,%ebx,1), %eax
2477         leal    foo@TLSLDM(%ebx), %eax
2478         leal    foo@DTPOFF(%eax), %edx
2479         movl    foo@GOTTPOFF(%ebx), %eax
2480         subl    foo@GOTTPOFF(%ebx), %eax
2481         addl    foo@GOTNTPOFF(%ebx), %eax
2482         movl    foo@INDNTPOFF, %eax
2483         movl    $foo@TPOFF, %eax
2484         subl    $foo@TPOFF, %eax
2485         leal    foo@NTPOFF(%ecx), %eax'
2486         tls_first_major=2
2487         tls_first_minor=14
2488         tls_as_opt=--fatal-warnings
2489         ;;
2490   x86_64-*-*)
2491     conftest_s='
2492         .section ".tdata","awT",@progbits
2493 foo:    .long   25
2494         .text
2495         movq    %fs:0, %rax
2496         leaq    foo@TLSGD(%rip), %rdi
2497         leaq    foo@TLSLD(%rip), %rdi
2498         leaq    foo@DTPOFF(%rax), %rdx
2499         movq    foo@GOTTPOFF(%rip), %rax
2500         movq    $foo@TPOFF, %rax'
2501         tls_first_major=2
2502         tls_first_minor=14
2503         tls_as_opt=--fatal-warnings
2504         ;;
2505   ia64-*-*)
2506     conftest_s='
2507         .section ".tdata","awT",@progbits
2508 foo:    data8   25
2509         .text
2510         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2511         addl    r17 = @ltoff(@dtprel(foo#)), gp
2512         addl    r18 = @ltoff(@tprel(foo#)), gp
2513         addl    r19 = @dtprel(foo#), gp
2514         adds    r21 = @dtprel(foo#), r13
2515         movl    r23 = @dtprel(foo#)
2516         addl    r20 = @tprel(foo#), gp
2517         adds    r22 = @tprel(foo#), r13
2518         movl    r24 = @tprel(foo#)'
2519         tls_first_major=2
2520         tls_first_minor=13
2521         tls_as_opt=--fatal-warnings
2522         ;;
2523   mips*-*-*)
2524     conftest_s='
2525         .section .tdata,"awT",@progbits
2526 x:
2527         .word 2
2528         .text
2529         addiu $4, $28, %tlsgd(x)
2530         addiu $4, $28, %tlsldm(x)
2531         lui $4, %dtprel_hi(x)
2532         addiu $4, $4, %dtprel_lo(x)
2533         lw $4, %gottprel(x)($28)
2534         lui $4, %tprel_hi(x)
2535         addiu $4, $4, %tprel_lo(x)'
2536         tls_first_major=2
2537         tls_first_minor=16
2538         tls_as_opt='-32 --fatal-warnings'
2539         ;;
2540   powerpc-*-*)
2541     conftest_s='
2542         .section ".tdata","awT",@progbits
2543         .align 2
2544 ld0:    .space 4
2545 ld1:    .space 4
2546 x1:     .space 4
2547 x2:     .space 4
2548 x3:     .space 4
2549         .text
2550         addi 3,31,ld0@got@tlsgd
2551         bl __tls_get_addr
2552         addi 3,31,x1@got@tlsld
2553         bl __tls_get_addr
2554         addi 9,3,x1@dtprel
2555         addis 9,3,x2@dtprel@ha
2556         addi 9,9,x2@dtprel@l
2557         lwz 9,x3@got@tprel(31)
2558         add 9,9,x@tls
2559         addi 9,2,x1@tprel
2560         addis 9,2,x2@tprel@ha
2561         addi 9,9,x2@tprel@l'
2562         tls_first_major=2
2563         tls_first_minor=14
2564         tls_as_opt="-a32 --fatal-warnings"
2565         ;;
2566   powerpc64-*-*)
2567     conftest_s='
2568         .section ".tdata","awT",@progbits
2569         .align 3
2570 ld0:    .space 8
2571 ld1:    .space 8
2572 x1:     .space 8
2573 x2:     .space 8
2574 x3:     .space 8
2575         .text
2576         addi 3,2,ld0@got@tlsgd
2577         bl .__tls_get_addr
2578         nop
2579         addi 3,2,ld1@toc
2580         bl .__tls_get_addr
2581         nop
2582         addi 3,2,x1@got@tlsld
2583         bl .__tls_get_addr
2584         nop
2585         addi 9,3,x1@dtprel
2586         bl .__tls_get_addr
2587         nop
2588         addis 9,3,x2@dtprel@ha
2589         addi 9,9,x2@dtprel@l
2590         bl .__tls_get_addr
2591         nop
2592         ld 9,x3@got@dtprel(2)
2593         add 9,9,3
2594         bl .__tls_get_addr
2595         nop'
2596         tls_first_major=2
2597         tls_first_minor=14
2598         tls_as_opt="-a64 --fatal-warnings"
2599         ;;
2600   s390-*-*)
2601     conftest_s='
2602         .section ".tdata","awT",@progbits
2603 foo:    .long   25
2604         .text
2605         .long   foo@TLSGD
2606         .long   foo@TLSLDM
2607         .long   foo@DTPOFF
2608         .long   foo@NTPOFF
2609         .long   foo@GOTNTPOFF
2610         .long   foo@INDNTPOFF
2611         l       %r1,foo@GOTNTPOFF(%r12)
2612         l       %r1,0(%r1):tls_load:foo
2613         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2614         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2615         tls_first_major=2
2616         tls_first_minor=14
2617         tls_as_opt="-m31 --fatal-warnings"
2618         ;;
2619   s390x-*-*)
2620     conftest_s='
2621         .section ".tdata","awT",@progbits
2622 foo:    .long   25
2623         .text
2624         .quad   foo@TLSGD
2625         .quad   foo@TLSLDM
2626         .quad   foo@DTPOFF
2627         .quad   foo@NTPOFF
2628         .quad   foo@GOTNTPOFF
2629         lg      %r1,foo@GOTNTPOFF(%r12)
2630         larl    %r1,foo@INDNTPOFF
2631         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2632         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2633         tls_first_major=2
2634         tls_first_minor=14
2635         tls_as_opt="-m64 -Aesame --fatal-warnings"
2636         ;;
2637   sh-*-* | sh[34]-*-*)
2638     conftest_s='
2639         .section ".tdata","awT",@progbits
2640 foo:    .long   25
2641         .text
2642         .long   foo@TLSGD
2643         .long   foo@TLSLDM
2644         .long   foo@DTPOFF
2645         .long   foo@GOTTPOFF
2646         .long   foo@TPOFF'
2647         tls_first_major=2
2648         tls_first_minor=13
2649         tls_as_opt=--fatal-warnings
2650         ;;
2651   sparc*-*-*)
2652     case "$target" in
2653       sparc*-sun-solaris2.[56789]*)
2654         # TLS was introduced in the Solaris 9 4/04 release but
2655         # we do not enable it by default on Solaris 9 either.
2656         if test "x$enable_tls" = xyes ; then
2657           on_solaris=yes
2658         else
2659           enable_tls=no;
2660         fi
2661         ;;
2662       sparc*-sun-solaris2.*)
2663         on_solaris=yes
2664         ;;
2665       *)
2666         on_solaris=no
2667         ;;
2668     esac
2669     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2670       conftest_s='
2671         .section ".tdata",#alloc,#write,#tls
2672 foo:    .long   25
2673         .text
2674         sethi   %tgd_hi22(foo), %o0
2675         add     %o0, %tgd_lo10(foo), %o1
2676         add     %l7, %o1, %o0, %tgd_add(foo)
2677         call    __tls_get_addr, %tgd_call(foo)
2678         sethi   %tldm_hi22(foo), %l1
2679         add     %l1, %tldm_lo10(foo), %l2
2680         add     %l7, %l2, %o0, %tldm_add(foo)
2681         call    __tls_get_addr, %tldm_call(foo)
2682         sethi   %tldo_hix22(foo), %l3
2683         xor     %l3, %tldo_lox10(foo), %l4
2684         add     %o0, %l4, %l5, %tldo_add(foo)
2685         sethi   %tie_hi22(foo), %o3
2686         add     %o3, %tie_lo10(foo), %o3
2687         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2688         add     %g7, %o2, %o4, %tie_add(foo)
2689         sethi   %tle_hix22(foo), %l1
2690         xor     %l1, %tle_lox10(foo), %o5
2691         ld      [%g7 + %o5], %o1'
2692         tls_first_major=0
2693         tls_first_minor=0
2694     else
2695       conftest_s='
2696         .section ".tdata","awT",@progbits
2697 foo:    .long   25
2698         .text
2699         sethi   %tgd_hi22(foo), %o0
2700         add     %o0, %tgd_lo10(foo), %o1
2701         add     %l7, %o1, %o0, %tgd_add(foo)
2702         call    __tls_get_addr, %tgd_call(foo)
2703         sethi   %tldm_hi22(foo), %l1
2704         add     %l1, %tldm_lo10(foo), %l2
2705         add     %l7, %l2, %o0, %tldm_add(foo)
2706         call    __tls_get_addr, %tldm_call(foo)
2707         sethi   %tldo_hix22(foo), %l3
2708         xor     %l3, %tldo_lox10(foo), %l4
2709         add     %o0, %l4, %l5, %tldo_add(foo)
2710         sethi   %tie_hi22(foo), %o3
2711         add     %o3, %tie_lo10(foo), %o3
2712         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2713         add     %g7, %o2, %o4, %tie_add(foo)
2714         sethi   %tle_hix22(foo), %l1
2715         xor     %l1, %tle_lox10(foo), %o5
2716         ld      [%g7 + %o5], %o1'
2717         tls_first_major=2
2718         tls_first_minor=14
2719         tls_as_opt="-32 --fatal-warnings"
2720       fi
2721         ;;
2722   xtensa*-*-*)
2723     conftest_s='
2724         .section ".tdata","awT",@progbits
2725 foo:    .long   25
2726         .text
2727         movi    a8, foo@TLSFUNC
2728         movi    a10, foo@TLSARG
2729         callx8.tls a8, foo@TLSCALL'
2730         tls_first_major=2
2731         tls_first_minor=19
2732         ;;
2733 changequote([,])dnl
2734 esac
2735 set_have_as_tls=no
2736 if test "x$enable_tls" = xno ; then
2737   : # TLS explicitly disabled.
2738 elif test "x$enable_tls" = xyes ; then
2739   set_have_as_tls=yes # TLS explicitly enabled.
2740 elif test -z "$tls_first_major"; then
2741   : # If we don't have a check, assume no support.
2742 else
2743   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2744   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2745   [set_have_as_tls=yes])
2746 fi
2747 if test $set_have_as_tls = yes ; then
2748   AC_DEFINE(HAVE_AS_TLS, 1,
2749             [Define if your assembler supports thread-local storage.])
2750 fi
2751
2752 # Target-specific assembler checks.
2753
2754 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2755 gcc_cv_ld_static_dynamic=no
2756 if test $in_tree_ld = yes ; then
2757   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2758     gcc_cv_ld_static_dynamic=yes
2759   fi
2760 elif test x$gcc_cv_ld != x; then
2761         # Check if linker supports -Bstatic/-Bdynamic option
2762         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2763           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2764                 gcc_cv_ld_static_dynamic=yes
2765         fi
2766 fi
2767 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2768         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2769 [Define if your linker supports -Bstatic/-Bdynamic option.])
2770 fi
2771 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2772
2773 if test x"$demangler_in_ld" = xyes; then
2774   AC_MSG_CHECKING(linker --demangle support)
2775   gcc_cv_ld_demangle=no
2776   if test $in_tree_ld = yes; then
2777     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2778       gcc_cv_ld_demangle=yes
2779     fi
2780   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2781     # Check if the GNU linker supports --demangle option
2782     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2783       gcc_cv_ld_demangle=yes
2784     fi
2785   fi
2786   if test x"$gcc_cv_ld_demangle" = xyes; then
2787     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2788 [Define if your linker supports --demangle option.])
2789   fi
2790   AC_MSG_RESULT($gcc_cv_ld_demangle)
2791 fi
2792
2793 case "$target" in
2794   # All TARGET_ABI_OSF targets.
2795   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2796     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2797         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2798 [       .set nomacro
2799         .text
2800         extbl   $3, $2, $3      !lituse_bytoff!1
2801         ldq     $2, a($29)      !literal!1
2802         ldq     $4, b($29)      !literal!2
2803         ldq_u   $3, 0($2)       !lituse_base!1
2804         ldq     $27, f($29)     !literal!5
2805         jsr     $26, ($27), f   !lituse_jsr!5
2806         ldah    $29, 0($26)     !gpdisp!3
2807         lda     $0, c($29)      !gprel
2808         ldah    $1, d($29)      !gprelhigh
2809         lda     $1, d($1)       !gprellow
2810         lda     $29, 0($29)     !gpdisp!3],,
2811     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2812   [Define if your assembler supports explicit relocations.])])
2813     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
2814         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
2815 [       .set nomacro
2816         .text
2817         ldq     $27, a($29)     !literal!1
2818         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
2819     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
2820   [Define if your assembler supports the lituse_jsrdirect relocation.])])
2821     ;;
2822
2823   cris-*-*)
2824     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2825       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2826       [-no-mul-bug-abort], [.text],,
2827       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2828                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2829     ;;
2830
2831   sparc*-*-*)
2832     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2833       [.register %g2, #scratch],,
2834       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2835                 [Define if your assembler supports .register.])])
2836
2837     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2838       [-relax], [.text],,
2839       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2840                 [Define if your assembler supports -relax option.])])
2841
2842     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2843       gcc_cv_as_sparc_ua_pcrel,,
2844       [-K PIC],
2845 [.text
2846 foo:
2847         nop
2848 .data
2849 .align 4
2850 .byte 0
2851 .uaword %r_disp32(foo)],
2852       [if test x$gcc_cv_ld != x \
2853        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2854          gcc_cv_as_sparc_ua_pcrel=yes
2855        fi
2856        rm -f conftest],
2857       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2858                 [Define if your assembler and linker support unaligned PC relative relocs.])
2859
2860       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2861         gcc_cv_as_sparc_ua_pcrel_hidden,,
2862         [-K PIC],
2863 [.data
2864 .align 4
2865 .byte 0x31
2866 .uaword %r_disp32(foo)
2867 .byte 0x32, 0x33, 0x34
2868 .global foo
2869 .hidden foo
2870 foo:
2871 .skip 4],
2872         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2873          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2874          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2875             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2876             if $gcc_cv_objdump -R conftest 2> /dev/null \
2877                | grep 'DISP32' > /dev/null 2>&1; then
2878                 :
2879             else
2880                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2881             fi
2882          fi
2883          rm -f conftest],
2884          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2885                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2886     ]) # unaligned pcrel relocs
2887
2888     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2889       gcc_cv_as_sparc_offsetable_lo10,,
2890       [-xarch=v9],
2891 [.text
2892         or %g1, %lo(ab) + 12, %g1
2893         or %g1, %lo(ab + 12), %g1],
2894       [if test x$gcc_cv_objdump != x \
2895        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2896           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2897          gcc_cv_as_sparc_offsetable_lo10=yes
2898        fi],
2899        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2900                  [Define if your assembler supports offsetable %lo().])])
2901     ;;
2902
2903 changequote(,)dnl
2904   i[34567]86-*-* | x86_64-*-*)
2905 changequote([,])dnl
2906     case $target_os in
2907       cygwin* | pe | mingw32*)
2908         # Used for DWARF 2 in PE
2909         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2910           gcc_cv_as_ix86_pe_secrel32,
2911           [2,15,91],,
2912 [.text
2913 foo:    nop
2914 .data
2915         .secrel32 foo],
2916           [if test x$gcc_cv_ld != x \
2917            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2918              gcc_cv_as_ix86_pe_secrel32=yes
2919            fi
2920            rm -f conftest],
2921           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2922             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2923         ;;
2924     esac
2925
2926     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2927        gcc_cv_as_ix86_filds_fists,
2928       [2,9,0],, [filds mem; fists mem],,
2929       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2930         [Define if your assembler uses the new HImode fild and fist notation.])])
2931
2932     gcc_GAS_CHECK_FEATURE([cmov syntax],
2933       gcc_cv_as_ix86_cmov_sun_syntax,,,
2934       [cmovl.l %edx, %eax],,
2935       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2936         [Define if your assembler supports the Sun syntax for cmov.])])
2937
2938     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
2939       gcc_cv_as_ix86_ffreep,,,
2940       [ffreep %st(1)],,
2941       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
2942         [Define if your assembler supports the ffreep mnemonic.])])
2943
2944     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
2945       gcc_cv_as_ix86_sahf,,,
2946       [sahf],,
2947       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
2948         [Define if your assembler supports the sahf mnemonic.])])
2949
2950     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
2951       gcc_cv_as_ix86_diff_sect_delta,,,
2952       [.section .rodata
2953 .L1:
2954         .long .L2-.L1
2955         .long .L3-.L1
2956         .text
2957 .L3:    nop
2958 .L2:    nop],,
2959       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
2960         [Define if your assembler supports the subtraction of symbols in different sections.])])
2961
2962     # This one is used unconditionally by i386.[ch]; it is to be defined
2963     # to 1 if the feature is present, 0 otherwise.
2964     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2965         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2966 [       .text
2967 .L0:
2968         nop
2969         .data
2970         .long .L0@GOTOFF])
2971     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2972       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2973       [Define true if the assembler supports '.long foo@GOTOFF'.])
2974     ;;
2975
2976   ia64*-*-*)
2977     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2978         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2979 [       .text
2980         addl r15 = @ltoffx(x#), gp
2981         ;;
2982         ld8.mov r16 = [[r15]], x#],,
2983     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2984           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2985
2986     ;;
2987
2988   powerpc*-*-*)
2989     case $target in
2990       *-*-aix*) conftest_s='    .machine "pwr5"
2991         .csect .text[[PR]]
2992         mfcr 3,128';;
2993       *-*-darwin*)
2994         gcc_GAS_CHECK_FEATURE([.machine directive support],
2995           gcc_cv_as_machine_directive,,,
2996           [     .machine ppc7400])
2997         if test x$gcc_cv_as_machine_directive != xyes; then
2998           echo "*** This target requires an assembler supporting \".machine\"" >&2
2999           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3000           test x$build = x$target && exit 1
3001         fi
3002         conftest_s='    .text
3003         mfcr r3,128';;
3004       *) conftest_s='   .machine power4
3005         .text
3006         mfcr 3,128';;
3007     esac
3008
3009     gcc_GAS_CHECK_FEATURE([mfcr field support],
3010       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3011       [$conftest_s],,
3012       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3013           [Define if your assembler supports mfcr field.])])
3014
3015     case $target in
3016       *-*-aix*) conftest_s='    .machine "pwr5"
3017         .csect .text[[PR]]
3018         popcntb 3,3';;
3019       *) conftest_s='   .machine power5
3020         .text
3021         popcntb 3,3';;
3022     esac
3023
3024     gcc_GAS_CHECK_FEATURE([popcntb support],
3025       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3026       [$conftest_s],,
3027       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3028           [Define if your assembler supports popcntb field.])])
3029
3030     case $target in
3031       *-*-aix*) conftest_s='    .machine "pwr5x"
3032         .csect .text[[PR]]
3033         frin 1,1';;
3034       *) conftest_s='   .machine power5
3035         .text
3036         frin 1,1';;
3037     esac
3038
3039     gcc_GAS_CHECK_FEATURE([fp round support],
3040       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3041       [$conftest_s],,
3042       [AC_DEFINE(HAVE_AS_FPRND, 1,
3043           [Define if your assembler supports fprnd.])])
3044
3045     case $target in
3046       *-*-aix*) conftest_s='    .machine "pwr6"
3047         .csect .text[[PR]]
3048         mffgpr 1,3';;
3049       *) conftest_s='   .machine power6
3050         .text
3051         mffgpr 1,3';;
3052     esac
3053
3054     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3055       gcc_cv_as_powerpc_mfpgpr, [9,99,0],,
3056       [$conftest_s],,
3057       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3058           [Define if your assembler supports mffgpr and mftgpr.])])
3059
3060     case $target in
3061       *-*-aix*) conftest_s='    .csect .text[[PR]]
3062 LCF..0:
3063         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3064       *-*-darwin*)
3065         conftest_s='    .text
3066 LCF0:
3067         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3068       *) conftest_s='   .text
3069 .LCF0:
3070         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3071     esac
3072
3073     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3074       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3075       [$conftest_s],,
3076       [AC_DEFINE(HAVE_AS_REL16, 1,
3077           [Define if your assembler supports R_PPC_REL16 relocs.])])
3078
3079     case $target in
3080       *-*-aix*) conftest_s='    .machine "pwr6"
3081         .csect .text[[PR]]
3082         cmpb 3,4,5';;
3083       *) conftest_s='   .machine power6
3084         .text
3085         cmpb 3,4,5';;
3086     esac
3087
3088     gcc_GAS_CHECK_FEATURE([compare bytes support],
3089       gcc_cv_as_powerpc_cmpb, [9,99,0], -a32,
3090       [$conftest_s],,
3091       [AC_DEFINE(HAVE_AS_CMPB, 1,
3092           [Define if your assembler supports cmpb.])])
3093
3094     case $target in
3095       *-*-aix*) conftest_s='    .machine "pwr6"
3096         .csect .text[[PR]]
3097         dadd 1,2,3';;
3098       *) conftest_s='   .machine power6
3099         .text
3100         dadd 1,2,3';;
3101     esac
3102
3103     gcc_GAS_CHECK_FEATURE([decimal float support],
3104       gcc_cv_as_powerpc_dfp, [9,99,0], -a32,
3105       [$conftest_s],,
3106       [AC_DEFINE(HAVE_AS_DFP, 1,
3107           [Define if your assembler supports DFP instructions.])])
3108
3109     case $target in
3110       *-*-aix*) conftest_s='    .machine "pwr7"
3111         .csect .text[[PR]]
3112         lxvd2x 1,2,3';;
3113       *) conftest_s='   .machine power7
3114         .text
3115         lxvd2x 1,2,3';;
3116     esac
3117
3118     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3119       gcc_cv_as_powerpc_vsx, [9,99,0], -a32,
3120       [$conftest_s],,
3121       [AC_DEFINE(HAVE_AS_VSX, 1,
3122           [Define if your assembler supports VSX instructions.])])
3123
3124     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3125       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3126       [.gnu_attribute 4,1],,
3127       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3128           [Define if your assembler supports .gnu_attribute.])])
3129     ;;
3130
3131   mips*-*-*)
3132     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3133       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3134 [       lw $4,%gp_rel(foo)($4)],,
3135       [if test x$target_cpu_default = x
3136        then target_cpu_default=MASK_EXPLICIT_RELOCS
3137        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3138        fi])
3139     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3140       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3141       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3142                  [Define if the assembler understands -mno-shared.])])
3143
3144     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3145       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3146       [.gnu_attribute 4,1],,
3147       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3148           [Define if your assembler supports .gnu_attribute.])])
3149
3150     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3151       gcc_cv_as_mips_dtprelword, [2,18,0],,
3152       [.section .tdata,"awT",@progbits
3153 x:
3154         .word 2
3155         .text
3156         .dtprelword x+0x8000],,
3157       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3158           [Define if your assembler supports .dtprelword.])])
3159     ;;
3160 esac
3161
3162 # Mips and HP-UX need the GNU assembler.
3163 # Linux on IA64 might be able to use the Intel assembler.
3164
3165 case "$target" in
3166   mips*-*-* | *-*-hpux* )
3167     if test x$gas_flag = xyes \
3168        || test x"$host" != x"$build" \
3169        || test ! -x "$gcc_cv_as" \
3170        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3171       :
3172     else
3173       echo "*** This configuration requires the GNU assembler" >&2
3174       exit 1
3175     fi
3176     ;;
3177 esac
3178
3179 # ??? Not all targets support dwarf2 debug_line, even within a version
3180 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3181 # info to the output file.  So, as supported targets are added to gas 2.11,
3182 # add some instruction here to (also) show we expect this might work.
3183 # ??? Once 2.11 is released, probably need to add first known working
3184 # version to the per-target configury.
3185 case "$target" in
3186   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
3187   | x86_64*-*-* | hppa*-*-* | arm*-*-* \
3188   | xstormy16*-*-* | cris-*-* | xtensa*-*-* | bfin-*-* | score*-*-* \
3189   | spu-*-* | fido*-*-*)
3190     insn="nop"
3191     ;;
3192   ia64*-*-* | s390*-*-*)
3193     insn="nop 0"
3194     ;;
3195   mmix-*-*)
3196     insn="swym 0"
3197     ;;
3198 esac
3199 if test x"$insn" != x; then
3200  conftest_s="\
3201         .file 1 \"conftest.s\"
3202         .loc 1 3 0
3203         $insn"
3204  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3205   gcc_cv_as_dwarf2_debug_line,
3206   [elf,2,11,0],, [$conftest_s],
3207   [if test x$gcc_cv_objdump != x \
3208    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
3209       | grep debug_line > /dev/null 2>&1; then
3210      gcc_cv_as_dwarf2_debug_line=yes
3211    fi])
3212
3213 # The .debug_line file table must be in the exact order that
3214 # we specified the files, since these indices are also used
3215 # by DW_AT_decl_file.  Approximate this test by testing if
3216 # the assembler bitches if the same index is assigned twice.
3217  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
3218   gcc_cv_as_dwarf2_file_buggy,,,
3219 [       .file 1 "foo.s"
3220         .file 1 "bar.s"])
3221
3222  if test $gcc_cv_as_dwarf2_debug_line = yes \
3223  && test $gcc_cv_as_dwarf2_file_buggy = no; then
3224         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
3225   [Define if your assembler supports dwarf2 .file/.loc directives,
3226    and preserves file table indices exactly as given.])
3227  fi
3228
3229  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
3230   gcc_cv_as_gdwarf2_flag,
3231   [elf,2,11,0], [--gdwarf2], [$insn],,
3232   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
3233 [Define if your assembler supports the --gdwarf2 option.])])
3234
3235  gcc_GAS_CHECK_FEATURE([--gstabs option],
3236   gcc_cv_as_gstabs_flag,
3237   [elf,2,11,0], [--gstabs], [$insn],
3238   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
3239    # and warns about it, but still exits successfully.  So check for
3240    # this.
3241    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
3242    then :
3243    else gcc_cv_as_gstabs_flag=yes
3244    fi],
3245   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
3246 [Define if your assembler supports the --gstabs option.])])
3247
3248  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
3249   gcc_cv_as_debug_prefix_map_flag,
3250   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
3251   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
3252 [Define if your assembler supports the --debug-prefix-map option.])])
3253 fi
3254
3255 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
3256  ,,
3257 [.lcomm bar,4,16],,
3258 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
3259   [Define if your assembler supports .lcomm with an alignment field.])])
3260
3261 AC_CACHE_CHECK([assembler for tolerance to line number 0],
3262  [gcc_cv_as_line_zero],
3263  [gcc_cv_as_line_zero=no
3264   if test $in_tree_gas = yes; then
3265     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
3266   elif test "x$gcc_cv_as" != x; then
3267     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
3268     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
3269        test "x`cat conftest.out`" = x
3270     then
3271       gcc_cv_as_line_zero=yes
3272     else
3273       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
3274       cat conftest.s >&AS_MESSAGE_LOG_FD
3275       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
3276       cat conftest.out >&AS_MESSAGE_LOG_FD
3277     fi
3278     rm -f conftest.o conftest.s conftest.out
3279   fi])
3280 if test "x$gcc_cv_as_line_zero" = xyes; then
3281   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
3282 [Define if the assembler won't complain about a line such as # 0 "" 2.])
3283 fi
3284
3285 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
3286 gcc_cv_ld_eh_frame_hdr=no
3287 if test $in_tree_ld = yes ; then
3288   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
3289      && test $in_tree_ld_is_elf = yes; then
3290     gcc_cv_ld_eh_frame_hdr=yes
3291   fi
3292 elif test x$gcc_cv_ld != x; then
3293         # Check if linker supports --eh-frame-hdr option
3294         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
3295                 gcc_cv_ld_eh_frame_hdr=yes
3296         fi
3297 fi
3298 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
3299 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
3300         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
3301 [Define if your linker supports --eh-frame-hdr option.])
3302 fi
3303 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
3304
3305 AC_MSG_CHECKING(linker position independent executable support)
3306 gcc_cv_ld_pie=no
3307 if test $in_tree_ld = yes ; then
3308   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
3309      && test $in_tree_ld_is_elf = yes; then
3310     gcc_cv_ld_pie=yes
3311   fi
3312 elif test x$gcc_cv_ld != x; then
3313         # Check if linker supports -pie option
3314         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
3315                 gcc_cv_ld_pie=yes
3316         fi
3317 fi
3318 if test x"$gcc_cv_ld_pie" = xyes; then
3319         AC_DEFINE(HAVE_LD_PIE, 1,
3320 [Define if your linker supports -pie option.])
3321 fi
3322 AC_MSG_RESULT($gcc_cv_ld_pie)
3323
3324 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
3325 gcc_cv_ld_eh_gc_sections=no
3326 if test $in_tree_ld = yes ; then
3327   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
3328      && test $in_tree_ld_is_elf = yes; then
3329     gcc_cv_ld_eh_gc_sections=yes
3330   fi
3331 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
3332   cat > conftest.s <<EOF
3333         .section        .text
3334 .globl _start
3335         .type _start, @function
3336 _start:
3337         .long foo
3338         .size _start, .-_start
3339         .section        .text.foo,"ax",@progbits
3340         .type foo, @function
3341 foo:
3342         .long 0
3343         .size foo, .-foo
3344         .section        .gcc_except_table.foo,"a",@progbits
3345 .L0:
3346         .long 0
3347         .section        .eh_frame,"a",@progbits
3348         .long .L0
3349 EOF
3350   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3351     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3352          | grep "gc-sections option ignored" > /dev/null; then
3353       gcc_cv_ld_eh_gc_sections=no
3354     elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3355       gcc_cv_ld_eh_gc_sections=yes
3356       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
3357       if test x$gcc_cv_as_comdat_group != xyes; then
3358         gcc_cv_ld_eh_gc_sections=no
3359         cat > conftest.s <<EOF
3360         .section        .text
3361 .globl _start
3362         .type _start, @function
3363 _start:
3364         .long foo
3365         .size _start, .-_start
3366         .section        .gnu.linkonce.t.foo,"ax",@progbits
3367         .type foo, @function
3368 foo:
3369         .long 0
3370         .size foo, .-foo
3371         .section        .gcc_except_table.foo,"a",@progbits
3372 .L0:
3373         .long 0
3374         .section        .eh_frame,"a",@progbits
3375         .long .L0
3376 EOF
3377         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
3378           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
3379                | grep "gc-sections option ignored" > /dev/null; then
3380             gcc_cv_ld_eh_gc_sections=no
3381           elif $gcc_cv_objdump -h conftest | grep gcc_except_table > /dev/null; then
3382             gcc_cv_ld_eh_gc_sections=yes
3383           fi
3384         fi
3385       fi
3386     fi
3387   fi
3388   rm -f conftest.s conftest.o conftest
3389 fi
3390 case "$target" in
3391   hppa*-*-linux*)
3392     # ??? This apparently exposes a binutils bug with PC-relative relocations.
3393     gcc_cv_ld_eh_gc_sections=no
3394     ;;
3395 esac
3396 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
3397         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
3398   [Define if your linker supports garbage collection of
3399    sections in presence of EH frames.])
3400 fi
3401 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
3402
3403 # --------
3404 # UNSORTED
3405 # --------
3406
3407 AC_CACHE_CHECK(linker --as-needed support,
3408 gcc_cv_ld_as_needed,
3409 [gcc_cv_ld_as_needed=no
3410 if test $in_tree_ld = yes ; then
3411   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3412      && test $in_tree_ld_is_elf = yes; then
3413     gcc_cv_ld_as_needed=yes
3414   fi
3415 elif test x$gcc_cv_ld != x; then
3416         # Check if linker supports --as-needed and --no-as-needed options
3417         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3418                 gcc_cv_ld_as_needed=yes
3419         fi
3420 fi
3421 ])
3422 if test x"$gcc_cv_ld_as_needed" = xyes; then
3423         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3424 [Define if your linker supports --as-needed and --no-as-needed options.])
3425 fi
3426
3427 case "$target:$tm_file" in
3428   powerpc64*-*-linux* | powerpc*-*-linux*rs6000/biarch64.h*)
3429     AC_CACHE_CHECK(linker support for omitting dot symbols,
3430     gcc_cv_ld_no_dot_syms,
3431     [gcc_cv_ld_no_dot_syms=no
3432     if test $in_tree_ld = yes ; then
3433       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3434         gcc_cv_ld_no_dot_syms=yes
3435       fi
3436     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3437       cat > conftest1.s <<EOF
3438         .text
3439         bl .foo
3440 EOF
3441       cat > conftest2.s <<EOF
3442         .section ".opd","aw"
3443         .align 3
3444         .globl foo
3445         .type foo,@function
3446 foo:
3447         .quad .LEfoo,.TOC.@tocbase,0
3448         .text
3449 .LEfoo:
3450         blr
3451         .size foo,.-.LEfoo
3452 EOF
3453       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3454          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3455          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3456         gcc_cv_ld_no_dot_syms=yes
3457       fi
3458       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3459     fi
3460     ])
3461     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3462       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3463     [Define if your PowerPC64 linker only needs function descriptor syms.])
3464     fi
3465     ;;
3466 esac
3467
3468 AC_CACHE_CHECK(linker --sysroot support,
3469   gcc_cv_ld_sysroot,
3470   [gcc_cv_ld_sysroot=no
3471   if test $in_tree_ld = yes ; then
3472       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3473         gcc_cv_ld_sysroot=yes
3474       fi
3475   elif test x$gcc_cv_ld != x; then
3476     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3477       gcc_cv_ld_sysroot=yes
3478     fi
3479   fi])
3480 if test x"$gcc_cv_ld_sysroot" = xyes; then
3481   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3482   [Define if your linker supports --sysroot.])
3483 fi
3484
3485 if test x$with_sysroot = x && test x$host = x$target \
3486    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" \
3487    && test "$prefix" != "NONE"; then
3488   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3489 [Define to PREFIX/include if cpp should also search that directory.])
3490 fi
3491
3492 # Test for stack protector support in target C library.
3493 AC_CACHE_CHECK(__stack_chk_fail in target C library,
3494       gcc_cv_libc_provides_ssp,
3495       [gcc_cv_libc_provides_ssp=no
3496     case "$target" in
3497        *-*-linux*)
3498       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3499         if test "x$with_sysroot" = x; then
3500           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3501         elif test "x$with_build_sysroot" != "x"; then
3502           glibc_header_dir="${with_build_sysroot}/usr/include"
3503         elif test "x$with_sysroot" = xyes; then
3504           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3505         else
3506           glibc_header_dir="${with_sysroot}/usr/include"
3507         fi
3508       else
3509         glibc_header_dir=/usr/include
3510       fi
3511       # glibc 2.4 and later provides __stack_chk_fail and
3512       # either __stack_chk_guard, or TLS access to stack guard canary.
3513       if test -f $glibc_header_dir/features.h \
3514          && $EGREP '^@<:@       @:>@*#[         ]*define[       ]+__GNU_LIBRARY__[      ]+([1-9][0-9]|[6-9])' \
3515             $glibc_header_dir/features.h > /dev/null; then
3516         if $EGREP '^@<:@        @:>@*#[         ]*define[       ]+__GLIBC__[    ]+([1-9][0-9]|[3-9])' \
3517            $glibc_header_dir/features.h > /dev/null; then
3518           gcc_cv_libc_provides_ssp=yes
3519         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__GLIBC__[    ]+2' \
3520              $glibc_header_dir/features.h > /dev/null \
3521              && $EGREP '^@<:@   @:>@*#[         ]*define[       ]+__GLIBC_MINOR__[      ]+([1-9][0-9]|[4-9])' \
3522              $glibc_header_dir/features.h > /dev/null; then
3523           gcc_cv_libc_provides_ssp=yes
3524         elif $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC__[   ]+1' \
3525              $glibc_header_dir/features.h > /dev/null && \
3526              test -f $glibc_header_dir/bits/uClibc_config.h && \
3527              $EGREP '^@<:@      @:>@*#[         ]*define[       ]+__UCLIBC_HAS_SSP__[   ]+1' \
3528              $glibc_header_dir/bits/uClibc_config.h > /dev/null; then
3529           gcc_cv_libc_provides_ssp=yes
3530         fi
3531       fi
3532         ;;
3533        *-*-darwin*)
3534          AC_CHECK_FUNC(__stack_chk_fail,[gcc_cv_libc_provides_ssp=yes],
3535            [echo "no __stack_chk_fail on this target"])
3536         ;;
3537   *) gcc_cv_libc_provides_ssp=no ;;
3538     esac])
3539
3540 if test x$gcc_cv_libc_provides_ssp = xyes; then
3541   AC_DEFINE(TARGET_LIBC_PROVIDES_SSP, 1,
3542             [Define if your target C library provides stack protector support])
3543 fi
3544
3545 # Check if TFmode long double should be used by default or not.
3546 # Some glibc targets used DFmode long double, but with glibc 2.4
3547 # and later they can use TFmode.
3548 case "$target" in
3549   powerpc*-*-linux* | \
3550   powerpc*-*-gnu* | \
3551   sparc*-*-linux* | \
3552   s390*-*-linux* | \
3553   alpha*-*-linux*)
3554     AC_ARG_WITH(long-double-128,
3555 [  --with-long-double-128  Use 128-bit long double by default.],
3556       gcc_cv_target_ldbl128="$with_long_double_128",
3557       [gcc_cv_target_ldbl128=no
3558       if test x$host != x$target || test "x$TARGET_SYSTEM_ROOT" != x; then
3559         if test "x$with_sysroot" = x; then
3560           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-include"
3561         elif test "x$with_build_sysroot" != "x"; then
3562           glibc_header_dir="${with_build_sysroot}/usr/include"
3563         elif test "x$with_sysroot" = xyes; then
3564           glibc_header_dir="${exec_prefix}/${target_noncanonical}/sys-root/usr/include"
3565         else
3566           glibc_header_dir="${with_sysroot}/usr/include"
3567         fi
3568       else
3569         glibc_header_dir=/usr/include
3570       fi
3571 changequote(,)dnl
3572       grep '^[  ]*#[    ]*define[       ][      ]*__LONG_DOUBLE_MATH_OPTIONAL' \
3573         $glibc_header_dir/bits/wordsize.h > /dev/null 2>&1 \
3574       && gcc_cv_target_ldbl128=yes
3575 changequote([,])dnl
3576       ])
3577     ;;
3578 esac
3579 if test x$gcc_cv_target_ldbl128 = xyes; then
3580   AC_DEFINE(TARGET_DEFAULT_LONG_DOUBLE_128, 1,
3581             [Define if TFmode long double should be the default])
3582 fi
3583
3584 # Find out what GC implementation we want, or may, use.
3585 AC_ARG_WITH(gc,
3586 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3587                           with the compiler],
3588 [case "$withval" in
3589   page)
3590     GGC=ggc-$withval
3591     ;;
3592   zone)
3593     GGC=ggc-$withval
3594     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3595     ;;
3596   *)
3597     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3598     ;;
3599 esac],
3600 [GGC=ggc-page])
3601 AC_SUBST(GGC)
3602 echo "Using $GGC for garbage collection."
3603
3604 # Use the system's zlib library.
3605 zlibdir=-L../zlib
3606 zlibinc="-I\$(srcdir)/../zlib"
3607 AC_ARG_WITH(system-zlib,
3608 [  --with-system-zlib      use installed libz],
3609 zlibdir=
3610 zlibinc=
3611 )
3612 AC_SUBST(zlibdir)
3613 AC_SUBST(zlibinc)
3614
3615 dnl Very limited version of automake's enable-maintainer-mode
3616
3617 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3618   dnl maintainer-mode is disabled by default
3619   AC_ARG_ENABLE(maintainer-mode,
3620 [  --enable-maintainer-mode
3621                           enable make rules and dependencies not useful
3622                           (and sometimes confusing) to the casual installer],
3623       maintainer_mode=$enableval,
3624       maintainer_mode=no)
3625
3626 AC_MSG_RESULT($maintainer_mode)
3627
3628 if test "$maintainer_mode" = "yes"; then
3629   MAINT=''
3630 else
3631   MAINT='#'
3632 fi
3633 AC_SUBST(MAINT)dnl
3634
3635 # --------------
3636 # Language hooks
3637 # --------------
3638
3639 # Make empty files to contain the specs and options for each language.
3640 # Then add #include lines to for a compiler that has specs and/or options.
3641
3642 subdirs=
3643 lang_opt_files=
3644 lang_specs_files=
3645 lang_tree_files=
3646 # These (without "all_") are set in each config-lang.in.
3647 # `language' must be a single word so is spelled singularly.
3648 all_languages=
3649 all_compilers=
3650 all_outputs='Makefile gccbug'
3651 # List of language makefile fragments.
3652 all_lang_makefrags=
3653 # List of language subdirectory makefiles.  Deprecated.
3654 all_lang_makefiles=
3655 # Additional files for gengtype
3656 all_gtfiles="$target_gtfiles"
3657
3658 # These are the languages that are set in --enable-languages,
3659 # and are available in the GCC tree.
3660 all_selected_languages=
3661
3662 # Add the language fragments.
3663 # Languages are added via two mechanisms.  Some information must be
3664 # recorded in makefile variables, these are defined in config-lang.in.
3665 # We accumulate them and plug them into the main Makefile.
3666 # The other mechanism is a set of hooks for each of the main targets
3667 # like `clean', `install', etc.
3668
3669 language_hooks="Make-hooks"
3670
3671 for lang in ${srcdir}/*/config-lang.in
3672 do
3673 changequote(,)dnl
3674         test "$lang" = "${srcdir}/*/config-lang.in" && continue
3675
3676         lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
3677         if test "x$lang_alias" = x
3678         then
3679               echo "$lang doesn't set \$language." 1>&2
3680               exit 1
3681         fi
3682         subdir="`echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`"
3683         subdirs="$subdirs $subdir"
3684
3685         # $gcc_subdir is where the gcc integration files are to be found
3686         # for a language, both for internal compiler purposes (compiler
3687         # sources implementing front-end to GCC tree converters), and for
3688         # build infrastructure purposes (Make-lang.in, etc.)
3689         #
3690         # This will be <subdir> (relative to $srcdir) if a line like
3691         # gcc_subdir="<subdir>" or gcc_subdir=<subdir>
3692         # is found in <langdir>/config-lang.in, and will remain <langdir>
3693         # otherwise.
3694         #
3695         # Except for the language alias (fetched above), the regular
3696         # "config-lang.in" contents are always retrieved from $gcc_subdir,
3697         # so a <langdir>/config-lang.in setting gcc_subdir typically sets
3698         # only this and the language alias.
3699
3700         gcc_subdir=`sed -n -e 's,^gcc_subdir=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^gcc_subdir=\([^   ]*\).*$,\1,p' $lang`
3701         if [ "$gcc_subdir" = "" ]; then
3702            gcc_subdir="$subdir"
3703         fi
3704
3705         case ",$enable_languages," in
3706         *,$lang_alias,*)
3707             all_selected_languages="$all_selected_languages $lang_alias"
3708             if test -f $srcdir/$gcc_subdir/lang-specs.h; then
3709                 lang_specs_files="$lang_specs_files $srcdir/$gcc_subdir/lang-specs.h"
3710             fi
3711             ;;
3712         esac
3713 changequote([,])dnl
3714
3715         language=
3716         boot_language=
3717         compilers=
3718         outputs=
3719         gtfiles=
3720         subdir_requires=
3721         . ${srcdir}/$gcc_subdir/config-lang.in
3722         if test "x$language" = x
3723         then
3724                 echo "${srcdir}/$gcc_subdir/config-lang.in doesn't set \$language." 1>&2
3725                 exit 1
3726         fi
3727
3728         ok=:
3729         case ",$enable_languages," in
3730                 *,$lang_alias,*) ;;
3731                 *)
3732                         for i in $subdir_requires; do
3733                                 test -f "${srcdir}/$i/config-lang.in" && continue
3734                                 ok=false
3735                                 break
3736                         done
3737                 ;;
3738         esac
3739         $ok || continue
3740
3741         all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$gcc_subdir/Make-lang.in"
3742         if test -f $srcdir/$gcc_subdir/lang.opt; then
3743             lang_opt_files="$lang_opt_files $srcdir/$gcc_subdir/lang.opt"
3744         fi
3745         if test -f $srcdir/$gcc_subdir/$subdir-tree.def; then
3746             lang_tree_files="$lang_tree_files $srcdir/$gcc_subdir/$subdir-tree.def"
3747         fi
3748         if test -f ${srcdir}/$gcc_subdir/Makefile.in
3749                 then all_lang_makefiles="$gcc_subdir/Makefile"
3750         fi
3751         all_languages="$all_languages $language"
3752         all_compilers="$all_compilers $compilers"
3753         all_outputs="$all_outputs $outputs"
3754         all_gtfiles="$all_gtfiles [[$subdir]] $gtfiles"
3755 done
3756
3757 # Pick up gtfiles for c
3758 gtfiles=
3759 . ${srcdir}/c-config-lang.in
3760 all_gtfiles="$all_gtfiles [[c]] $gtfiles"
3761
3762 check_languages=
3763 for language in $all_selected_languages
3764 do
3765         check_languages="$check_languages check-$language"
3766 done
3767
3768 # We link each language in with a set of hooks, reached indirectly via
3769 # lang.${target}.  Only do so for selected languages.
3770
3771 rm -f Make-hooks
3772 touch Make-hooks
3773 target_list="all.cross start.encap rest.encap tags \
3774         install-common install-man install-info install-pdf dvi pdf \
3775         html uninstall info man srcextra srcman srcinfo \
3776         mostlyclean clean distclean maintainer-clean"
3777
3778 for t in $target_list
3779 do
3780         x=
3781         for lang in $all_selected_languages
3782         do
3783                 x="$x $lang.$t"
3784         done
3785         echo "lang.$t: $x" >> Make-hooks
3786 done
3787
3788 # --------
3789 # UNSORTED
3790 # --------
3791
3792 # Create .gdbinit.
3793
3794 echo "dir ." > .gdbinit
3795 echo "dir ${srcdir}" >> .gdbinit
3796 if test x$gdb_needs_out_file_path = xyes
3797 then
3798         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3799 fi
3800 if test "x$subdirs" != x; then
3801         for s in $subdirs
3802         do
3803                 echo "dir ${srcdir}/$s" >> .gdbinit
3804         done
3805 fi
3806 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3807
3808 gcc_tooldir='$(libsubdir)/$(libsubdir_to_prefix)$(target_noncanonical)'
3809 AC_SUBST(gcc_tooldir)
3810 AC_SUBST(dollar)
3811
3812 # Find a directory in which to install a shared libgcc.
3813
3814 AC_ARG_ENABLE(version-specific-runtime-libs,
3815 [  --enable-version-specific-runtime-libs
3816                           specify that runtime libraries should be
3817                           installed in a compiler-specific directory])
3818
3819 AC_ARG_WITH(slibdir,
3820 [  --with-slibdir=DIR      shared libraries in DIR [[LIBDIR]]],
3821 slibdir="$with_slibdir",
3822 if test "${enable_version_specific_runtime_libs+set}" = set; then
3823   slibdir='$(libsubdir)'
3824 elif test "$host" != "$target"; then
3825   slibdir='$(build_tooldir)/lib'
3826 else
3827   slibdir='$(libdir)'
3828 fi)
3829 AC_SUBST(slibdir)
3830
3831 AC_ARG_WITH(datarootdir,
3832 [  --with-datarootdir=DIR  Use DIR as the data root [[PREFIX/share]]],
3833 datarootdir="\${prefix}/$with_datarootdir",
3834 datarootdir='$(prefix)/share')
3835 AC_SUBST(datarootdir)
3836
3837 AC_ARG_WITH(docdir,
3838 [  --with-docdir=DIR       Install documentation in DIR [[DATAROOTDIR]]],
3839 docdir="\${prefix}/$with_docdir",
3840 docdir='$(datarootdir)')
3841 AC_SUBST(docdir)
3842
3843 AC_ARG_WITH(htmldir,
3844 [  --with-htmldir=DIR      html documentation in in DIR [[DOCDIR]]],
3845 htmldir="\${prefix}/$with_htmldir",
3846 htmldir='$(docdir)')
3847 AC_SUBST(htmldir)
3848
3849 # Substitute configuration variables
3850 AC_SUBST(subdirs)
3851 AC_SUBST(srcdir)
3852 AC_SUBST(all_compilers)
3853 AC_SUBST(all_gtfiles)
3854 AC_SUBST(all_lang_makefrags)
3855 AC_SUBST(all_lang_makefiles)
3856 AC_SUBST(all_languages)
3857 AC_SUBST(all_selected_languages)
3858 AC_SUBST(build_exeext)
3859 AC_SUBST(build_install_headers_dir)
3860 AC_SUBST(build_xm_file_list)
3861 AC_SUBST(build_xm_include_list)
3862 AC_SUBST(build_xm_defines)
3863 AC_SUBST(build_file_translate)
3864 AC_SUBST(check_languages)
3865 AC_SUBST(cpp_install_dir)
3866 AC_SUBST(xmake_file)
3867 AC_SUBST(tmake_file)
3868 AC_SUBST(extra_gcc_objs)
3869 AC_SUBST(extra_headers_list)
3870 AC_SUBST(extra_objs)
3871 AC_SUBST(extra_parts)
3872 AC_SUBST(extra_passes)
3873 AC_SUBST(extra_programs)
3874 AC_SUBST(float_h_file)
3875 AC_SUBST(gcc_config_arguments)
3876 AC_SUBST(gcc_gxx_include_dir)
3877 AC_SUBST(host_exeext)
3878 AC_SUBST(host_xm_file_list)
3879 AC_SUBST(host_xm_include_list)
3880 AC_SUBST(host_xm_defines)
3881 AC_SUBST(out_host_hook_obj)
3882 AC_SUBST(install)
3883 AC_SUBST(lang_opt_files)
3884 AC_SUBST(lang_specs_files)
3885 AC_SUBST(lang_tree_files)
3886 AC_SUBST(local_prefix)
3887 AC_SUBST(md_file)
3888 AC_SUBST(objc_boehm_gc)
3889 AC_SUBST(out_file)
3890 AC_SUBST(out_object_file)
3891 AC_SUBST(thread_file)
3892 AC_SUBST(tm_file_list)
3893 AC_SUBST(tm_include_list)
3894 AC_SUBST(tm_defines)
3895 AC_SUBST(tm_p_file_list)
3896 AC_SUBST(tm_p_include_list)
3897 AC_SUBST(xm_file_list)
3898 AC_SUBST(xm_include_list)
3899 AC_SUBST(xm_defines)
3900 AC_SUBST(c_target_objs)
3901 AC_SUBST(cxx_target_objs)
3902 AC_SUBST(fortran_target_objs)
3903 AC_SUBST(target_cpu_default)
3904
3905 AC_SUBST_FILE(language_hooks)
3906
3907 # Echo link setup.
3908 if test x${build} = x${host} ; then
3909   if test x${host} = x${target} ; then
3910     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3911   else
3912     echo "Links are now set up to build a cross-compiler" 1>&2
3913     echo " from ${host} to ${target}." 1>&2
3914   fi
3915 else
3916   if test x${host} = x${target} ; then
3917     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3918     echo " for ${target}." 1>&2
3919   else
3920     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3921     echo " from ${host} to ${target}." 1>&2
3922   fi
3923 fi
3924
3925 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3926 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3927
3928 AC_ARG_VAR(PPLLIBS,[How to link PPL])
3929 AC_ARG_VAR(PPLINC,[How to find PPL include files])
3930
3931 AC_ARG_VAR(CLOOGLIBS,[How to link CLOOG])
3932 AC_ARG_VAR(CLOOGINC,[How to find CLOOG include files])
3933 if test "x${CLOOGLIBS}" != "x" ; then
3934    AC_DEFINE(HAVE_cloog, 1, [Define if cloog is in use.])
3935 fi
3936
3937 # Configure the subdirectories
3938 # AC_CONFIG_SUBDIRS($subdirs)
3939
3940 # Create the Makefile
3941 # and configure language subdirectories
3942 AC_CONFIG_FILES($all_outputs)
3943
3944 AC_CONFIG_COMMANDS([default],
3945 [
3946 case ${CONFIG_HEADERS} in
3947   *auto-host.h:config.in*)
3948   echo > cstamp-h ;;
3949 esac
3950 # Make sure all the subdirs exist.
3951 for d in $subdirs doc build
3952 do
3953     test -d $d || mkdir $d
3954 done
3955 ],
3956 [subdirs='$subdirs'])
3957 AC_OUTPUT