OSDN Git Service

02c6089e9e6fb12365658e277c81b5761bb3767c
[pf3gnuchains/gcc-fork.git] / gcc / configure.ac
1 # configure.ac for GCC
2 # Process this file with autoconf to generate a configuration script.
3
4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
5 # 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
6
7 #This file is part of GCC.
8
9 #GCC is free software; you can redistribute it and/or modify it under
10 #the terms of the GNU General Public License as published by the Free
11 #Software Foundation; either version 3, or (at your option) any later
12 #version.
13
14 #GCC is distributed in the hope that it will be useful, but WITHOUT
15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
17 #for more details.
18
19 #You should have received a copy of the GNU General Public License
20 #along with GCC; see the file COPYING3.  If not see
21 #<http://www.gnu.org/licenses/>.
22
23 # --------------------------------
24 # Initialization and sanity checks
25 # --------------------------------
26
27 AC_PREREQ(2.64)
28 AC_INIT
29 AC_CONFIG_SRCDIR(tree.c)
30 AC_CONFIG_HEADER(auto-host.h:config.in)
31
32 gcc_version=`cat $srcdir/BASE-VER`
33
34 # Determine the host, build, and target systems
35 AC_CANONICAL_BUILD
36 AC_CANONICAL_HOST
37 AC_CANONICAL_TARGET
38
39 # Determine the noncanonical target name, for directory use.
40 ACX_NONCANONICAL_TARGET
41
42 # Determine the target- and build-specific subdirectories
43 GCC_TOPLEV_SUBDIRS
44
45 # Set program_transform_name
46 AC_ARG_PROGRAM
47
48 # Check for bogus environment variables.
49 # Test if LIBRARY_PATH contains the notation for the current directory
50 # since this would lead to problems installing/building glibc.
51 # LIBRARY_PATH contains the current directory if one of the following
52 # is true:
53 # - one of the terminals (":" and ";") is the first or last sign
54 # - two terminals occur directly after each other
55 # - the path contains an element with a dot in it
56 AC_MSG_CHECKING(LIBRARY_PATH variable)
57 changequote(,)dnl
58 case ${LIBRARY_PATH} in
59   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
60     library_path_setting="contains current directory"
61     ;;
62   *)
63     library_path_setting="ok"
64     ;;
65 esac
66 changequote([,])dnl
67 AC_MSG_RESULT($library_path_setting)
68 if test "$library_path_setting" != "ok"; then
69 AC_MSG_ERROR([
70 *** LIBRARY_PATH shouldn't contain the current directory when
71 *** building gcc. Please change the environment variable
72 *** and run configure again.])
73 fi
74
75 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
76 # since this would lead to problems installing/building glibc.
77 # GCC_EXEC_PREFIX contains the current directory if one of the following
78 # is true:
79 # - one of the terminals (":" and ";") is the first or last sign
80 # - two terminals occur directly after each other
81 # - the path contains an element with a dot in it
82 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
83 changequote(,)dnl
84 case ${GCC_EXEC_PREFIX} in
85   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
86     gcc_exec_prefix_setting="contains current directory"
87     ;;
88   *)
89     gcc_exec_prefix_setting="ok"
90     ;;
91 esac
92 changequote([,])dnl
93 AC_MSG_RESULT($gcc_exec_prefix_setting)
94 if test "$gcc_exec_prefix_setting" != "ok"; then
95 AC_MSG_ERROR([
96 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
97 *** building gcc. Please change the environment variable
98 *** and run configure again.])
99 fi
100
101 # -----------
102 # Directories
103 # -----------
104
105 # Specify the local prefix
106 local_prefix=
107 AC_ARG_WITH(local-prefix,
108 [AS_HELP_STRING([--with-local-prefix=DIR],
109                 [specifies directory to put local include])],
110 [case "${withval}" in
111 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
112 no)     ;;
113 *)      local_prefix=$with_local_prefix ;;
114 esac])
115
116 # Default local prefix if it is empty
117 if test x$local_prefix = x; then
118         local_prefix=/usr/local
119 fi
120
121 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
122 # passed in by the toplevel make and thus we'd get different behavior
123 # depending on where we built the sources.
124 gcc_gxx_include_dir=
125 # Specify the g++ header file directory
126 AC_ARG_WITH(gxx-include-dir,
127 [AS_HELP_STRING([--with-gxx-include-dir=DIR],
128                 [specifies directory to put g++ header files])],
129 [case "${withval}" in
130 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
131 no)     ;;
132 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
133 esac])
134
135 # This logic must match libstdc++-v3/acinclude.m4:GLIBCXX_EXPORT_INSTALL_INFO.
136 if test x${gcc_gxx_include_dir} = x; then
137   if test x${enable_version_specific_runtime_libs} = xyes; then
138     gcc_gxx_include_dir='${libsubdir}/include/c++'
139   else
140     libstdcxx_incdir='include/c++/$(version)'
141     if test x$host != x$target; then
142        libstdcxx_incdir="$target_alias/$libstdcxx_incdir"
143     fi
144     gcc_gxx_include_dir="\$(libsubdir)/\$(libsubdir_to_prefix)$libstdcxx_incdir"
145   fi
146 fi
147
148 AC_ARG_WITH(cpp_install_dir,
149 [AC_HELP_STRING([--with-cpp-install-dir=DIR],
150                 [install the user visible C preprocessor in DIR
151                  (relative to PREFIX) as well as PREFIX/bin])],
152 [if test x$withval = xyes; then
153   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
154 elif test x$withval != xno; then
155   cpp_install_dir=$withval
156 fi])
157
158 # We would like to our source tree to be readonly.  However when releases or
159 # pre-releases are generated, the flex/bison generated files as well as the 
160 # various formats of manuals need to be included along with the rest of the
161 # sources.  Therefore we have --enable-generated-files-in-srcdir to do 
162 # just that.
163
164 AC_MSG_CHECKING([whether to place generated files in the source directory])
165   dnl generated-files-in-srcdir is disabled by default
166   AC_ARG_ENABLE(generated-files-in-srcdir, 
167     [AS_HELP_STRING([--enable-generated-files-in-srcdir],
168                     [put copies of generated files in source dir
169                      intended for creating source tarballs for users
170                      without texinfo bison or flex])],
171       generated_files_in_srcdir=$enableval,
172       generated_files_in_srcdir=no)
173
174 AC_MSG_RESULT($generated_files_in_srcdir)
175
176 if test "$generated_files_in_srcdir" = "yes"; then
177   GENINSRC=''
178 else
179   GENINSRC='#'
180 fi
181 AC_SUBST(GENINSRC)
182
183 # -------------------
184 # Find default linker
185 # -------------------
186
187 # With GNU ld
188 AC_ARG_WITH(gnu-ld,
189 [AS_HELP_STRING([--with-gnu-ld], [arrange to work with GNU ld])],
190 gnu_ld_flag="$with_gnu_ld",
191 gnu_ld_flag=no)
192
193 # With pre-defined ld
194 AC_ARG_WITH(ld,
195 [AS_HELP_STRING([--with-ld], [arrange to use the specified ld (full pathname)])],
196 DEFAULT_LINKER="$with_ld")
197 if test x"${DEFAULT_LINKER+set}" = x"set"; then
198   if test ! -x "$DEFAULT_LINKER"; then
199     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
200   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
201     gnu_ld_flag=yes
202   fi
203   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
204         [Define to enable the use of a default linker.])
205 fi
206
207 gnu_ld=`if test x"$gnu_ld_flag" = x"yes"; then echo 1; else echo 0; fi`
208 AC_DEFINE_UNQUOTED(HAVE_GNU_LD, $gnu_ld, [Define if using GNU ld.])
209
210 AC_MSG_CHECKING([whether a default linker was specified])
211 if test x"${DEFAULT_LINKER+set}" = x"set"; then
212   if test x"$gnu_ld_flag" = x"no"; then
213     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
214   else
215     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
216   fi
217 else
218   AC_MSG_RESULT(no)
219 fi
220
221 # With demangler in GNU ld
222 AC_ARG_WITH(demangler-in-ld,
223 [AS_HELP_STRING([--with-demangler-in-ld], [try to use demangler in GNU ld])],
224 demangler_in_ld="$with_demangler_in_ld",
225 demangler_in_ld=no)
226
227 # ----------------------
228 # Find default assembler
229 # ----------------------
230
231 # With GNU as
232 AC_ARG_WITH(gnu-as,
233 [AS_HELP_STRING([--with-gnu-as], [arrange to work with GNU as])],
234 gas_flag="$with_gnu_as",
235 gas_flag=no)
236
237 AC_ARG_WITH(as,
238 [AS_HELP_STRING([--with-as], [arrange to use the specified as (full pathname)])],
239 DEFAULT_ASSEMBLER="$with_as")
240 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
241   if test ! -x "$DEFAULT_ASSEMBLER"; then
242     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
243   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
244     gas_flag=yes
245   fi
246   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
247         [Define to enable the use of a default assembler.])
248 fi
249
250 gnu_as=`if test x"$gas_flag" = x"yes"; then echo 1; else echo 0; fi`
251 AC_DEFINE_UNQUOTED(HAVE_GNU_AS, $gnu_as, [Define if using GNU as.])
252
253 AC_MSG_CHECKING([whether a default assembler was specified])
254 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
255   if test x"$gas_flag" = x"no"; then
256     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
257   else
258     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
259   fi
260 else
261   AC_MSG_RESULT(no)
262 fi
263
264 # ---------------
265 # Find C compiler
266 # ---------------
267
268 # If a non-executable a.out is present (e.g. created by GNU as above even if
269 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
270 # file, even when creating an executable, so an execution test fails.
271 # Remove possible default executable files to avoid this.
272 #
273 # FIXME: This really belongs into AC_PROG_CC and can be removed once
274 # Autoconf includes it.
275 rm -f a.out a.exe b.out
276
277 # Find the native compiler
278 AC_PROG_CC
279 AM_PROG_CC_C_O
280 AC_PROG_CXX
281 ACX_PROG_GNAT([-I"$srcdir"/ada])
282
283 # autoconf is lame and doesn't give us any substitution variable for this.
284 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
285   NO_MINUS_C_MINUS_O=yes
286 else
287   OUTPUT_OPTION='-o $@'
288 fi
289 AC_SUBST(NO_MINUS_C_MINUS_O)
290 AC_SUBST(OUTPUT_OPTION)
291
292 # Remove the -O2: for historical reasons, unless bootstrapping we prefer
293 # optimizations to be activated explicitly by the toplevel.
294 case "$CC" in
295   */prev-gcc/xgcc*) ;;
296   *) CFLAGS=`echo $CFLAGS | sed "s/-O[[s0-9]]* *//" ` ;;
297 esac
298 AC_SUBST(CFLAGS)
299
300 # -------------------------
301 # Check C compiler features
302 # -------------------------
303
304 AC_USE_SYSTEM_EXTENSIONS
305 AC_PROG_CPP
306 AC_C_INLINE
307
308 AC_SYS_LARGEFILE
309
310 # sizeof(char) is 1 by definition.
311 AC_CHECK_SIZEOF(void *)
312 AC_CHECK_SIZEOF(short)
313 AC_CHECK_SIZEOF(int)
314 AC_CHECK_SIZEOF(long)
315 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
316 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
317 GCC_STDINT_TYPES
318
319 # ---------------------
320 # Warnings and checking
321 # ---------------------
322
323 # Check $CC warning features (if it's GCC).
324 # We want to use -pedantic, but we don't want warnings about
325 # * 'long long'
326 # * variadic macros
327 # * overlong strings
328 # So, we only use -pedantic if we can disable those warnings.
329
330 ACX_PROG_CC_WARNING_OPTS(
331         m4_quote(m4_do([-W -Wall -Wwrite-strings -Wcast-qual])), [loose_warn])
332 ACX_PROG_CC_WARNING_OPTS(
333         m4_quote(m4_do([-Wstrict-prototypes -Wmissing-prototypes])),
334         [c_loose_warn])
335 ACX_PROG_CC_WARNING_OPTS(
336         m4_quote(m4_do([-Wmissing-format-attribute])), [strict_warn])
337 ACX_PROG_CC_WARNING_OPTS(
338         m4_quote(m4_do([-Wold-style-definition -Wc++-compat])), [c_strict_warn])
339 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC(
340         m4_quote(m4_do([-Wno-long-long -Wno-variadic-macros ], 
341                        [-Wno-overlength-strings])), [strict_warn])
342 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual], [strict_warn])
343
344 # The above macros do nothing if the compiler is not GCC.  However, the
345 # Makefile has more goo to add other flags, so these variables are used
346 # to enable warnings only for GCC.
347 warn_cflags=
348 warn_cxxflags=
349 if test "x$GCC" = "xyes"; then
350   warn_cflags='$(GCC_WARN_CFLAGS)'
351   warn_cxxflags='$(GCC_WARN_CXXFLAGS)'
352 fi
353 AC_SUBST(warn_cflags)
354 AC_SUBST(warn_cxxflags)
355
356 # Enable expensive internal checks
357 is_release=
358 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
359   is_release=yes
360 fi
361
362 AC_ARG_ENABLE(checking,
363 [AS_HELP_STRING([[--enable-checking[=LIST]]],
364                 [enable expensive run-time checks.  With LIST,
365                  enable only specific categories of checks.
366                  Categories are: yes,no,all,none,release.
367                  Flags are: assert,df,fold,gc,gcac,gimple,misc,
368                  rtlflag,rtl,runtime,tree,valgrind,types])],
369 [ac_checking_flags="${enableval}"],[
370 # Determine the default checks.
371 if test x$is_release = x ; then
372   ac_checking_flags=yes
373 else
374   ac_checking_flags=release
375 fi])
376 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
377 for check in release $ac_checking_flags
378 do
379         case $check in
380         # these set all the flags to specific states
381         yes)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking= ;
382                         ac_fold_checking= ; ac_gc_checking=1 ;
383                         ac_gc_always_collect= ; ac_gimple_checking=1 ; ac_rtl_checking= ;
384                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
385                         ac_tree_checking=1 ; ac_valgrind_checking= ;
386                         ac_types_checking=1 ;;
387         no|none)        ac_assert_checking= ; ac_checking= ; ac_df_checking= ;
388                         ac_fold_checking= ; ac_gc_checking= ;
389                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
390                         ac_rtlflag_checking= ; ac_runtime_checking= ;
391                         ac_tree_checking= ; ac_valgrind_checking= ;
392                         ac_types_checking= ;;
393         all)            ac_assert_checking=1 ; ac_checking=1 ; ac_df_checking=1 ;
394                         ac_fold_checking=1 ; ac_gc_checking=1 ;
395                         ac_gc_always_collect=1 ; ac_gimple_checking=1 ; ac_rtl_checking=1 ;
396                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
397                         ac_tree_checking=1 ; ac_valgrind_checking= ;
398                         ac_types_checking=1 ;;
399         release)        ac_assert_checking=1 ; ac_checking= ; ac_df_checking= ;
400                         ac_fold_checking= ; ac_gc_checking= ;
401                         ac_gc_always_collect= ; ac_gimple_checking= ; ac_rtl_checking= ;
402                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
403                         ac_tree_checking= ; ac_valgrind_checking= ;
404                         ac_types_checking= ;;
405         # these enable particular checks
406         assert)         ac_assert_checking=1 ;;
407         df)             ac_df_checking=1 ;;
408         fold)           ac_fold_checking=1 ;;
409         gc)             ac_gc_checking=1 ;;
410         gcac)           ac_gc_always_collect=1 ;;
411         gimple)         ac_gimple_checking=1 ;;
412         misc)           ac_checking=1 ;;
413         rtl)            ac_rtl_checking=1 ;;
414         rtlflag)        ac_rtlflag_checking=1 ;;
415         runtime)        ac_runtime_checking=1 ;;
416         tree)           ac_tree_checking=1 ;;
417         types)          ac_types_checking=1 ;;
418         valgrind)       ac_valgrind_checking=1 ;;
419         *)      AC_MSG_ERROR(unknown check category $check) ;;
420         esac
421 done
422 IFS="$ac_save_IFS"
423
424 nocommon_flag=""
425 if test x$ac_checking != x ; then
426   AC_DEFINE(ENABLE_CHECKING, 1,
427 [Define if you want more run-time sanity checks.  This one gets a grab
428    bag of miscellaneous but relatively cheap checks.])
429   nocommon_flag=-fno-common
430 fi
431 AC_SUBST(nocommon_flag)
432 if test x$ac_df_checking != x ; then
433   AC_DEFINE(ENABLE_DF_CHECKING, 1,
434 [Define if you want more run-time sanity checks for dataflow.])
435 fi
436 if test x$ac_assert_checking != x ; then
437   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
438 [Define if you want assertions enabled.  This is a cheap check.])
439 fi
440 if test x$ac_gimple_checking != x ; then
441   AC_DEFINE(ENABLE_GIMPLE_CHECKING, 1,
442 [Define if you want operations on GIMPLE (the basic data structure of
443 the high-level optimizers) to be checked for dynamic type safety at
444 runtime.  This is moderately expensive.])
445 fi
446 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
447 if test x$ac_runtime_checking != x ; then
448   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
449 [Define if you want runtime assertions enabled.  This is a cheap check.])
450 fi
451 if test x$ac_tree_checking != x ; then
452   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
453 [Define if you want all operations on trees (the basic data
454    structure of the front ends) to be checked for dynamic type safety
455    at runtime.  This is moderately expensive.  The tree browser debugging
456    routines will also be enabled by this option.
457    ])
458   TREEBROWSER=tree-browser.o
459 fi
460 if test x$ac_types_checking != x ; then
461   AC_DEFINE(ENABLE_TYPES_CHECKING, 1,
462 [Define if you want all gimple types to be verified after gimplifiation.
463    This is cheap.
464    ])
465 fi
466 AC_SUBST(TREEBROWSER)
467 if test x$ac_rtl_checking != x ; then
468   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
469 [Define if you want all operations on RTL (the basic data structure
470    of the optimizer and back end) to be checked for dynamic type safety
471    at runtime.  This is quite expensive.])
472 fi
473 if test x$ac_rtlflag_checking != x ; then
474   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
475 [Define if you want RTL flag accesses to be checked against the RTL
476    codes that are supported for each access macro.  This is relatively
477    cheap.])
478 fi
479 if test x$ac_gc_checking != x ; then
480   AC_DEFINE(ENABLE_GC_CHECKING, 1,
481 [Define if you want the garbage collector to do object poisoning and
482    other memory allocation checks.  This is quite expensive.])
483 fi
484 if test x$ac_gc_always_collect != x ; then
485   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
486 [Define if you want the garbage collector to operate in maximally
487    paranoid mode, validating the entire heap and collecting garbage at
488    every opportunity.  This is extremely expensive.])
489 fi
490 if test x$ac_fold_checking != x ; then
491   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
492 [Define if you want fold checked that it never destructs its argument.
493    This is quite expensive.])
494 fi
495 valgrind_path_defines=
496 valgrind_command=
497
498 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
499 dnl # an if statement.  This was the source of very frustrating bugs
500 dnl # in converting to autoconf 2.5x!
501 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
502
503 if test x$ac_valgrind_checking != x ; then
504   # It is certainly possible that there's valgrind but no valgrind.h.
505   # GCC relies on making annotations so we must have both.
506   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
507   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
508     [[#include <valgrind/memcheck.h>
509 #ifndef VALGRIND_DISCARD
510 #error VALGRIND_DISCARD not defined
511 #endif]])],
512   [gcc_cv_header_valgrind_memcheck_h=yes],
513   [gcc_cv_header_valgrind_memcheck_h=no])
514   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
515   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
516   AC_PREPROC_IFELSE([AC_LANG_SOURCE(
517     [[#include <memcheck.h>
518 #ifndef VALGRIND_DISCARD
519 #error VALGRIND_DISCARD not defined
520 #endif]])],
521   [gcc_cv_header_memcheck_h=yes],
522   [gcc_cv_header_memcheck_h=no])
523   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
524   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
525         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
526   if test "x$valgrind_path" = "x" \
527     || (test $have_valgrind_h = no \
528         && test $gcc_cv_header_memcheck_h = no \
529         && test $gcc_cv_header_valgrind_memcheck_h = no); then
530         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
531   fi
532   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
533   valgrind_command="$valgrind_path -q"
534   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
535 [Define if you want to run subprograms and generated programs
536    through valgrind (a memory checker).  This is extremely expensive.])
537   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
538     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
539         [Define if valgrind's valgrind/memcheck.h header is installed.])
540   fi
541   if test $gcc_cv_header_memcheck_h = yes; then
542     AC_DEFINE(HAVE_MEMCHECK_H, 1,
543         [Define if valgrind's memcheck.h header is installed.])
544   fi
545 fi
546 AC_SUBST(valgrind_path_defines)
547 AC_SUBST(valgrind_command)
548
549 # Enable code coverage collection
550 AC_ARG_ENABLE(coverage,
551 [AS_HELP_STRING([[--enable-coverage[=LEVEL]]],
552                 [enable compiler's code coverage collection.
553                  Use to measure compiler performance and locate
554                  unused parts of the compiler. With LEVEL, specify
555                  optimization. Values are opt, noopt,
556                  default is noopt])],
557 [case "${enableval}" in
558   yes|noopt)
559     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
560     ;;
561   opt)
562     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
563     ;;
564   no)
565     # a.k.a. --disable-coverage
566     coverage_flags=""
567     ;;
568   *)
569     AC_MSG_ERROR(unknown coverage setting $enableval)
570     ;;
571 esac],
572 [coverage_flags=""])
573 AC_SUBST(coverage_flags)
574
575 AC_ARG_ENABLE(gather-detailed-mem-stats, 
576 [AS_HELP_STRING([--enable-gather-detailed-mem-stats],
577                 [enable detailed memory allocation stats gathering])], [],
578 [enable_gather_detailed_mem_stats=no])
579 if test x$enable_gather_detailed_mem_stats = xyes ; then
580   AC_DEFINE(GATHER_STATISTICS, 1,
581         [Define to enable detailed memory allocation stats gathering.])
582 fi
583
584 # -------------------------------
585 # Miscenalleous configure options
586 # -------------------------------
587
588 # See if we are building gcc with C++.
589 AC_ARG_ENABLE(build-with-cxx,
590 [AS_HELP_STRING([--enable-build-with-cxx],
591                 [build with C++ compiler instead of C compiler])],
592 ENABLE_BUILD_WITH_CXX=$enableval,
593 ENABLE_BUILD_WITH_CXX=no)
594 AC_SUBST(ENABLE_BUILD_WITH_CXX)
595 if test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
596   AC_DEFINE(ENABLE_BUILD_WITH_CXX, 1,
597             [Define if building with C++.])
598 fi
599
600 # With stabs
601 AC_ARG_WITH(stabs,
602 [AS_HELP_STRING([--with-stabs],
603                 [arrange to use stabs instead of host debug format])],
604 stabs="$with_stabs",
605 stabs=no)
606
607 # Determine whether or not multilibs are enabled.
608 AC_ARG_ENABLE(multilib,
609 [AS_HELP_STRING([--enable-multilib],
610                 [enable library support for multiple ABIs])],
611 [], [enable_multilib=yes])
612 AC_SUBST(enable_multilib)
613
614 # Enable __cxa_atexit for C++.
615 AC_ARG_ENABLE(__cxa_atexit,
616 [AS_HELP_STRING([--enable-__cxa_atexit], [enable __cxa_atexit for C++])],
617 [], [])
618
619 # Enable C extension for decimal float if target supports it.
620 GCC_AC_ENABLE_DECIMAL_FLOAT([$target])
621
622 dfp=`if test $enable_decimal_float != no; then echo 1; else echo 0; fi`
623 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_FLOAT, $dfp,
624 [Define to 1 to enable decimal float extension to C.])
625
626 # Use default_decimal_float for dependency.
627 enable_decimal_float=$default_decimal_float
628
629 bid=`if test $enable_decimal_float = bid; then echo 1; else echo 0; fi`
630 AC_DEFINE_UNQUOTED(ENABLE_DECIMAL_BID_FORMAT, $bid,
631 [Define to 1 to specify that we are using the BID decimal floating
632 point format instead of DPD])
633
634 # Enable C extension for fixed-point arithmetic.
635 AC_ARG_ENABLE(fixed-point,
636 [AS_HELP_STRING([--enable-fixed-point],
637                 [enable fixed-point arithmetic extension to C])],
638 [],
639 [
640   case $target in
641     mips*-*-*)
642       case $host in
643         mips*-sgi-irix*)
644           AC_MSG_WARN([fixed-point is not supported on IRIX, ignored])
645           enable_fixed_point=no
646           ;;
647         *)
648           enable_fixed_point=yes
649           ;;
650       esac
651       ;;
652     *)
653       AC_MSG_WARN([fixed-point is not supported for this target, ignored])
654       enable_fixed_point=no
655       ;;
656   esac
657 ])
658 AC_SUBST(enable_fixed_point)
659
660 fixedpoint=`if test $enable_fixed_point = yes; then echo 1; else echo 0; fi`
661 AC_DEFINE_UNQUOTED(ENABLE_FIXED_POINT, $fixedpoint,
662 [Define to 1 to enable fixed-point arithmetic extension to C.])
663
664 # Enable threads
665 # Pass with no value to take the default
666 # Pass with a value to specify a thread package
667 AC_ARG_ENABLE(threads,
668 [AS_HELP_STRING([[--enable-threads[=LIB]]],
669                 [enable thread usage for target GCC,
670                  using LIB thread package])],,
671 [enable_threads=''])
672
673 AC_ARG_ENABLE(tls,
674 [AS_HELP_STRING([--enable-tls],
675                 [enable or disable generation of tls code
676                  overriding the assembler check for tls support])],
677 [
678   case $enable_tls in
679     yes | no) ;;
680     *) AC_MSG_ERROR(['$enable_tls' is an invalid value for --enable-tls.
681 Valid choices are 'yes' and 'no'.]) ;;
682   esac
683 ], [enable_tls=''])
684
685 AC_ARG_ENABLE(objc-gc,
686 [AS_HELP_STRING([--enable-objc-gc],
687                 [enable the use of Boehm's garbage collector with
688                  the GNU Objective-C runtime])],
689 if test x$enable_objc_gc = xno; then
690         objc_boehm_gc=''
691 else
692         objc_boehm_gc=1
693 fi,
694 objc_boehm_gc='')
695
696 AC_ARG_WITH(dwarf2,
697 [AS_HELP_STRING([--with-dwarf2], [force the default debug format to be DWARF 2])],
698 dwarf2="$with_dwarf2",
699 dwarf2=no)
700
701 AC_ARG_ENABLE(shared,
702 [AS_HELP_STRING([--disable-shared], [don't provide a shared libgcc])],
703 [
704   case $enable_shared in
705   yes | no) ;;
706   *)
707     enable_shared=no
708     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
709     for pkg in $enableval; do
710       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
711         enable_shared=yes
712       fi
713     done
714     IFS="$ac_save_ifs"
715     ;;
716   esac
717 ], [enable_shared=yes])
718 AC_SUBST(enable_shared)
719
720 AC_ARG_WITH(build-sysroot, 
721   [AS_HELP_STRING([--with-build-sysroot=sysroot],
722                   [use sysroot as the system root during the build])])
723
724 AC_ARG_WITH(sysroot,
725 [AS_HELP_STRING([[--with-sysroot[=DIR]]],
726                 [search for usr/lib, usr/include, et al, within DIR])],
727 [
728  case ${with_sysroot} in
729  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
730  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
731  esac
732    
733  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
734  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
735         
736  if test "x$prefix" = xNONE; then
737   test_prefix=/usr/local
738  else
739   test_prefix=$prefix
740  fi
741  if test "x$exec_prefix" = xNONE; then
742   test_exec_prefix=$test_prefix
743  else
744   test_exec_prefix=$exec_prefix
745  fi
746  case ${TARGET_SYSTEM_ROOT} in
747  "${test_prefix}"|"${test_prefix}/"*|\
748  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
749  '${prefix}'|'${prefix}/'*|\
750  '${exec_prefix}'|'${exec_prefix}/'*)
751    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
752    TARGET_SYSTEM_ROOT_DEFINE="$t"
753    ;;
754  esac
755 ], [
756  TARGET_SYSTEM_ROOT=
757  TARGET_SYSTEM_ROOT_DEFINE=
758  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
759 ])
760 AC_SUBST(TARGET_SYSTEM_ROOT)
761 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
762 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
763
764 AC_ARG_WITH(specs,
765   [AS_HELP_STRING([--with-specs=SPECS],
766                   [add SPECS to driver command-line processing])],
767   [CONFIGURE_SPECS=$withval],
768   [CONFIGURE_SPECS=]
769 )
770 AC_SUBST(CONFIGURE_SPECS)
771
772 ACX_PKGVERSION([GCC])
773 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
774
775 # Sanity check enable_languages in case someone does not run the toplevel
776 # configure # script.
777 AC_ARG_ENABLE(languages,
778 [AS_HELP_STRING([--enable-languages=LIST], [specify which front-ends to build])],
779 [case ,${enable_languages}, in
780        ,,|,yes,)
781                 # go safe -- we cannot be much sure without the toplevel
782                 # configure's
783                 # analysis of which target libs are present and usable
784                 enable_languages=c
785                 ;;
786          *,all,*)
787                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
788                 ;;
789         *,c,*)
790                 ;;
791         *)
792                 enable_languages=c,${enable_languages}
793                 ;;
794 esac],
795 [enable_languages=c])
796
797 AC_ARG_WITH(multilib-list,
798 [AS_HELP_STRING([--with-multilib-list], [select multilibs (SH only)])],
799 :,
800 with_multilib_list=default)
801
802 # -------------------------
803 # Checks for other programs
804 # -------------------------
805
806 AC_PROG_MAKE_SET
807
808 # Find some useful tools
809 AC_PROG_AWK
810 # We need awk to create options.c and options.h.
811 # Bail out if it's missing.
812 case ${AWK} in
813   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
814 esac
815
816 gcc_AC_PROG_LN_S
817 ACX_PROG_LN($LN_S)
818 AC_PROG_RANLIB
819 case "${host}" in
820 *-*-darwin*)
821   # By default, the Darwin ranlib will not treat common symbols as
822   # definitions when  building the archive table of contents.  Other 
823   # ranlibs do that; pass an option to the Darwin ranlib that makes
824   # it behave similarly.
825   ranlib_flags="-c" 
826   ;;
827 *)
828   ranlib_flags=""
829 esac
830 AC_SUBST(ranlib_flags)
831      
832 gcc_AC_PROG_INSTALL
833
834 # See if cmp has --ignore-initial.
835 gcc_AC_PROG_CMP_IGNORE_INITIAL
836
837 # See if we have the mktemp command.
838 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
839
840 # See if makeinfo has been installed and is modern enough
841 # that we can use it.
842 ACX_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
843   [GNU texinfo.* \([0-9][0-9.]*\)],
844   [4.[7-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
845 if test $gcc_cv_prog_makeinfo_modern = no; then
846   AC_MSG_WARN([
847 *** Makeinfo is missing or too old.
848 *** Info documentation will not be built.])
849   BUILD_INFO=
850 else
851   BUILD_INFO=info
852 fi
853 AC_SUBST(BUILD_INFO)
854
855 # Is pod2man recent enough to regenerate manpages?
856 AC_MSG_CHECKING([for recent Pod::Man])
857 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
858   AC_MSG_RESULT(yes)
859   GENERATED_MANPAGES=generated-manpages
860 else
861   AC_MSG_RESULT(no)
862   GENERATED_MANPAGES=
863 fi
864 AC_SUBST(GENERATED_MANPAGES)
865
866 MISSING="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing"
867
868 # How about lex?
869 dnl Don't use AC_PROG_LEX; we insist on flex.
870 dnl LEXLIB is not useful in gcc.
871 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
872
873 # Bison?
874 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
875
876 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
877 # check for build == host before using them.
878
879 # NM
880 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
881   && test -d ../binutils ; then
882   NM='${objdir}/../binutils/nm-new'
883 else
884   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
885 fi
886
887 # AR
888 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
889   && test -d ../binutils ; then
890   AR='${objdir}/../binutils/ar'
891 else
892   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
893 fi
894
895
896 # --------------------
897 # Checks for C headers
898 # --------------------
899
900 # Need to reject headers which give warnings, so that the -Werror bootstrap
901 # works later. *sigh*  This needs to come before all header checks.
902 AC_PROG_CPP_WERROR
903
904 AC_HEADER_STDC
905 AC_HEADER_TIME
906 ACX_HEADER_STRING
907 AC_HEADER_SYS_WAIT
908 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
909                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
910                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
911                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
912
913 # Check for thread headers.
914 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
915 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
916
917 # These tests can't be done till we know if we have limits.h.
918 gcc_AC_C_CHAR_BIT
919 AC_C_BIGENDIAN
920
921 # ----------------------
922 # Checks for C++ headers
923 # ----------------------
924
925 dnl Autoconf will give an error in the configure script if there is no
926 dnl C++ preprocessor.  Hack to prevent that.
927 m4_pushdef([AC_MSG_ERROR], m4_defn([AC_MSG_WARN]))[]dnl
928 AC_PROG_CXXCPP
929 m4_popdef([AC_MSG_ERROR])[]dnl
930
931 AC_LANG_PUSH(C++)
932
933 AC_CHECK_HEADERS(unordered_map)
934 AC_CHECK_HEADERS(tr1/unordered_map)
935 AC_CHECK_HEADERS(ext/hash_map)
936
937 AC_LANG_POP(C++)
938
939 # --------
940 # UNSORTED
941 # --------
942
943
944 # These libraries may be used by collect2.
945 # We may need a special search path to get them linked.
946 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
947 [save_LIBS="$LIBS"
948 for libs in '' -lld -lmld \
949                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
950                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
951 do
952         LIBS="$libs"
953         AC_TRY_LINK_FUNC(ldopen,
954                 [gcc_cv_collect2_libs="$libs"; break])
955 done
956 LIBS="$save_LIBS"
957 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
958 case $gcc_cv_collect2_libs in
959         "none required")        ;;
960         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
961 esac
962 AC_SUBST(COLLECT2_LIBS)
963
964 # When building Ada code on Alpha, we need exc_resume which is usually in
965 # -lexc.  So test for it.
966 save_LIBS="$LIBS"
967 LIBS=
968 AC_SEARCH_LIBS(exc_resume, exc)
969 GNAT_LIBEXC="$LIBS"
970 LIBS="$save_LIBS"
971 AC_SUBST(GNAT_LIBEXC)
972
973 # Some systems put ldexp and frexp in libm instead of libc; assume
974 # they're both in the same place.  jcf-dump needs them.
975 save_LIBS="$LIBS"
976 LIBS=
977 AC_SEARCH_LIBS(ldexp, m)
978 LDEXP_LIB="$LIBS"
979 LIBS="$save_LIBS"
980 AC_SUBST(LDEXP_LIB)
981
982 # Use <inttypes.h> only if it exists,
983 # doesn't clash with <sys/types.h>, and declares intmax_t.
984 AC_MSG_CHECKING(for inttypes.h)
985 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
986 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
987 [[#include <sys/types.h>
988 #include <inttypes.h>]],
989   [[intmax_t i = -1;]])],
990   [gcc_cv_header_inttypes_h=yes],
991   [gcc_cv_header_inttypes_h=no])])
992 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
993 if test $gcc_cv_header_inttypes_h = yes; then
994   AC_DEFINE(HAVE_INTTYPES_H, 1,
995         [Define if you have a working <inttypes.h> header file.])
996 fi
997
998 dnl Disabled until we have a complete test for buggy enum bitfields.
999 dnl gcc_AC_C_ENUM_BF_UNSIGNED
1000
1001 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
1002   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
1003   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
1004   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
1005   putchar_unlocked putc_unlocked)
1006 AC_CHECK_FUNCS(times clock kill getrlimit setrlimit atoll atoq \
1007         sysconf strsignal getrusage nl_langinfo \
1008         gettimeofday mbstowcs wcswidth mmap setlocale \
1009         gcc_UNLOCKED_FUNCS)
1010
1011 if test x$ac_cv_func_mbstowcs = xyes; then
1012   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
1013 [    AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <stdlib.h>
1014 int main()
1015 {
1016   mbstowcs(0, "", 0);
1017   return 0;
1018 }]])],
1019     [gcc_cv_func_mbstowcs_works=yes],
1020     [gcc_cv_func_mbstowcs_works=no],
1021     [gcc_cv_func_mbstowcs_works=yes])])
1022   if test x$gcc_cv_func_mbstowcs_works = xyes; then
1023     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
1024   [Define this macro if mbstowcs does not crash when its
1025    first argument is NULL.])
1026   fi
1027 fi
1028
1029 AC_CHECK_TYPE(ssize_t, int)
1030 AC_CHECK_TYPE(caddr_t, char *)
1031
1032 gcc_AC_FUNC_MMAP_BLACKLIST
1033
1034 case "${host}" in
1035 *-*-*vms*)
1036   # Under VMS, vfork works very differently than on Unix. The standard test 
1037   # won't work, and it isn't easily adaptable. It makes more sense to
1038   # just force it.
1039   ac_cv_func_vfork_works=yes
1040   ;;
1041 esac
1042 AC_FUNC_FORK
1043
1044 AM_ICONV
1045 # Until we have in-tree GNU iconv:
1046 LIBICONV_DEP=
1047 AC_SUBST(LIBICONV_DEP)
1048
1049 AM_LC_MESSAGES
1050
1051 AM_LANGINFO_CODESET
1052
1053 # We will need to find libiberty.h and ansidecl.h
1054 saved_CFLAGS="$CFLAGS"
1055 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1056 gcc_AC_CHECK_DECLS(getenv atol asprintf sbrk abort atof getcwd getwd \
1057         strsignal strstr strverscmp \
1058         errno snprintf vsnprintf vasprintf malloc realloc calloc \
1059         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1060 #include "ansidecl.h"
1061 #include "system.h"])
1062
1063 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1064 #include "ansidecl.h"
1065 #include "system.h"
1066 #ifdef HAVE_SYS_RESOURCE_H
1067 #include <sys/resource.h>
1068 #endif
1069 ])
1070
1071 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1072 #include "ansidecl.h"
1073 #include "system.h"
1074 #ifdef HAVE_SYS_RESOURCE_H
1075 #include <sys/resource.h>
1076 #endif
1077 ]], [[rlim_t l = 0;]])],[],[AC_DEFINE([rlim_t],[long],
1078 [Define to `long' if <sys/resource.h> doesn't define.])])
1079
1080 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1081 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1082 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1083 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1084 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1085 #include "ansidecl.h"
1086 #include "system.h"
1087 #ifdef HAVE_LDFCN_H
1088 #undef FREAD
1089 #undef FWRITE
1090 #include <ldfcn.h>
1091 #endif
1092 ])
1093
1094 gcc_AC_CHECK_DECLS(times, , ,[
1095 #include "ansidecl.h"
1096 #include "system.h"
1097 #ifdef HAVE_SYS_TIMES_H
1098 #include <sys/times.h>
1099 #endif
1100 ])
1101
1102 gcc_AC_CHECK_DECLS(sigaltstack, , ,[
1103 #include "ansidecl.h"
1104 #include "system.h"
1105 #include <signal.h>
1106 ])
1107
1108 # More time-related stuff.
1109 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1110 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1111 #include "ansidecl.h"
1112 #include "system.h"
1113 #ifdef HAVE_SYS_TIMES_H
1114 #include <sys/times.h>
1115 #endif
1116 ]], [[struct tms tms;]])],[ac_cv_struct_tms=yes],[ac_cv_struct_tms=no])])
1117 if test $ac_cv_struct_tms = yes; then
1118   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1119   [Define if <sys/times.h> defines struct tms.])
1120 fi
1121
1122 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1123 # revisit after autoconf 2.50.
1124 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1125 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1126 #include "ansidecl.h"
1127 #include "system.h"
1128 ]], [[clock_t x;]])],[gcc_cv_type_clock_t=yes],[gcc_cv_type_clock_t=no])])
1129 if test $gcc_cv_type_clock_t = yes; then
1130   AC_DEFINE(HAVE_CLOCK_T, 1,
1131   [Define if <time.h> defines clock_t.])
1132 fi
1133
1134 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1135 CFLAGS="$saved_CFLAGS"
1136
1137 gcc_AC_INITFINI_ARRAY
1138
1139 # mkdir takes a single argument on some systems. 
1140 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1141
1142 # File extensions
1143 manext='.1'
1144 objext='.o'
1145 AC_SUBST(manext)
1146 AC_SUBST(objext)
1147
1148 # With Setjmp/Longjmp based exception handling.
1149 AC_ARG_ENABLE(sjlj-exceptions,
1150 [AS_HELP_STRING([--enable-sjlj-exceptions],
1151                 [arrange to use setjmp/longjmp exception handling])],
1152 [case $target in
1153   *-*-hpux10*)
1154     if test $enableval != yes; then
1155       AC_MSG_WARN([dwarf2 exceptions not supported, sjlj exceptions forced])
1156       enableval=yes
1157     fi
1158     ;;
1159 esac
1160 force_sjlj_exceptions=yes],
1161 [case $target in
1162   *-*-hpux10*)
1163     force_sjlj_exceptions=yes
1164     enableval=yes
1165     ;;
1166   *)
1167     force_sjlj_exceptions=no
1168     ;;
1169 esac])
1170 if test $force_sjlj_exceptions = yes; then
1171   sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1172   AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1173     [Define 0/1 to force the choice for exception handling model.])
1174 fi
1175
1176 # For platforms with the unwind ABI which includes an unwind library,
1177 # libunwind, we can choose to use the system libunwind.
1178 # config.gcc also contains tests of with_system_libunwind.
1179 GCC_CHECK_UNWIND_GETIPINFO
1180
1181 # --------------------------------------------------------
1182 # Build, host, and target specific configuration fragments
1183 # --------------------------------------------------------
1184
1185 # Collect build-machine-specific information.
1186 . ${srcdir}/config.build
1187
1188 # Collect host-machine-specific information.
1189 . ${srcdir}/config.host
1190
1191 target_gtfiles=
1192
1193 # Collect target-machine-specific information.
1194 . ${srcdir}/config.gcc
1195
1196 extra_objs="${host_extra_objs} ${extra_objs}"
1197 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1198
1199 # Default the target-machine variables that were not explicitly set.
1200 if test x"$tm_file" = x
1201 then tm_file=$cpu_type/$cpu_type.h; fi
1202
1203 if test x"$extra_headers" = x
1204 then extra_headers=; fi
1205
1206 if test x$md_file = x
1207 then md_file=$cpu_type/$cpu_type.md; fi
1208
1209 if test x$out_file = x
1210 then out_file=$cpu_type/$cpu_type.c; fi
1211
1212 if test x"$tmake_file" = x
1213 then tmake_file=$cpu_type/t-$cpu_type
1214 fi
1215
1216 if test x"$dwarf2" = xyes
1217 then tm_file="$tm_file tm-dwarf2.h"
1218 fi
1219
1220 # Say what files are being used for the output code and MD file.
1221 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1222 echo "Using \`$srcdir/config/$md_file' as machine description file."
1223
1224 # If any of the xm_file variables contain nonexistent files, warn
1225 # about them and drop them.
1226
1227 bx=
1228 for x in $build_xm_file; do
1229   if    test -f $srcdir/config/$x
1230   then      bx="$bx $x"
1231   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1232   fi
1233 done
1234 build_xm_file="$bx"
1235
1236 hx=
1237 for x in $host_xm_file; do
1238   if    test -f $srcdir/config/$x
1239   then      hx="$hx $x"
1240   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1241   fi
1242 done
1243 host_xm_file="$hx"
1244
1245 tx=
1246 for x in $xm_file; do
1247   if    test -f $srcdir/config/$x
1248   then      tx="$tx $x"
1249   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1250   fi
1251 done
1252 xm_file="$tx"
1253
1254 count=a
1255 for f in $tm_file; do
1256         count=${count}x
1257 done
1258 if test $count = ax; then
1259         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1260 else
1261         echo "Using the following target machine macro files:"
1262         for f in $tm_file; do
1263                 echo "  $srcdir/config/$f"
1264         done
1265 fi
1266
1267 if test x$need_64bit_hwint = xyes; then
1268         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1269 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1270 fi
1271
1272 if test x$use_long_long_for_widest_fast_int = xyes; then
1273         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1274 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1275 efficiently supported by the host hardware.])
1276 fi
1277
1278 count=a
1279 for f in $host_xm_file; do
1280         count=${count}x
1281 done
1282 if test $count = a; then
1283         :
1284 elif test $count = ax; then
1285         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1286 else
1287         echo "Using the following host machine macro files:"
1288         for f in $host_xm_file; do
1289                 echo "  $srcdir/config/$f"
1290         done
1291 fi
1292 echo "Using ${out_host_hook_obj} for host machine hooks."
1293
1294 if test "$host_xm_file" != "$build_xm_file"; then
1295         count=a
1296         for f in $build_xm_file; do
1297                 count=${count}x
1298         done
1299         if test $count = a; then
1300                 :
1301         elif test $count = ax; then
1302                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1303         else
1304                 echo "Using the following build machine macro files:"
1305                 for f in $build_xm_file; do
1306                         echo "  $srcdir/config/$f"
1307                 done
1308         fi
1309 fi
1310
1311 case ${host} in
1312   powerpc*-*-darwin*)
1313     AC_CACHE_CHECK([whether mcontext_t fields have underscores],
1314       gcc_cv_mcontext_underscores,
1315       AC_COMPILE_IFELSE([
1316 #include <sys/cdefs.h>
1317 #include <sys/signal.h>
1318 #include <ucontext.h>
1319 int main() { mcontext_t m; if (m->ss.srr0) return 0; return 0; }
1320 ],
1321         gcc_cv_mcontext_underscores=no, gcc_cv_mcontext_underscores=yes))
1322       if test $gcc_cv_mcontext_underscores = yes; then
1323         AC_DEFINE(HAS_MCONTEXT_T_UNDERSCORES,,dnl
1324           [mcontext_t fields start with __])
1325       fi
1326     ;;
1327 esac
1328
1329 # ---------
1330 # Threading
1331 # ---------
1332
1333 # Check if a valid thread package
1334 case ${enable_threads} in
1335   "" | no)
1336     # No threads
1337     target_thread_file='single'
1338     ;;
1339   yes)
1340     # default
1341     target_thread_file='single'
1342     ;;
1343   aix | dce | lynx | mipssde | nks | posix | posix95 | rtems | \
1344   single | tpf | vxworks | win32)
1345     target_thread_file=${enable_threads}
1346     ;;
1347   *)
1348     echo "${enable_threads} is an unknown thread package" 1>&2
1349     exit 1
1350     ;;
1351 esac
1352
1353 if test x${thread_file} = x; then
1354   # No thread file set by target-specific clauses in config.gcc,
1355   # so use file chosen by default logic above
1356   thread_file=${target_thread_file}
1357 fi
1358
1359 # Make gthr-default.h if we have a thread file.
1360 gthread_flags=
1361 if test $thread_file != single; then
1362   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h-t
1363   if diff gthr-default.h-t gthr-default.h 2>/dev/null; then
1364     rm -f gthr-default.h-t
1365   else
1366     mv -f gthr-default.h-t gthr-default.h
1367   fi
1368   gthread_flags=-DHAVE_GTHR_DEFAULT
1369 fi
1370 AC_SUBST(gthread_flags)
1371
1372 # --------
1373 # UNSORTED
1374 # --------
1375
1376 use_cxa_atexit=no
1377 if test x$enable___cxa_atexit = xyes || \
1378    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1379   if test x$host = x$target; then
1380     case $host in
1381       # mingw32 doesn't have __cxa_atexit but uses atexit registration
1382       # keyed to flag_use_cxa_atexit
1383       *-*-mingw32*)
1384         use_cxa_atexit=yes
1385         ;;
1386       *)
1387         AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1388           [echo "__cxa_atexit can't be enabled on this target"])
1389         ;;
1390     esac
1391   else
1392     # We can't check for __cxa_atexit when building a cross, so assume
1393     # it is available 
1394     use_cxa_atexit=yes
1395   fi
1396   if test x$use_cxa_atexit = xyes; then
1397     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 2,
1398       [Define if you want to use __cxa_atexit, rather than atexit, to
1399       register C++ destructors for local statics and global objects.
1400       This is essential for fully standards-compliant handling of
1401       destructors, but requires __cxa_atexit in libc.])
1402   fi
1403 fi
1404
1405 # Look for a file containing extra machine modes.
1406 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1407   extra_modes_file='$(srcdir)'/config/${extra_modes}
1408   AC_SUBST(extra_modes_file)
1409   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1410   [Define to the name of a file containing a list of extra machine modes
1411    for this architecture.])
1412 fi
1413
1414 # Convert extra_options into a form suitable for Makefile use.
1415 extra_opt_files=
1416 all_opt_files=
1417 for f in $extra_options; do
1418   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1419   all_opt_files="$all_opt_files $srcdir/config/$f"
1420 done
1421 AC_SUBST(extra_opt_files)
1422
1423 # auto-host.h is the file containing items generated by autoconf and is
1424 # the first file included by config.h.
1425 # If host=build, it is correct to have bconfig include auto-host.h
1426 # as well.  If host!=build, we are in error and need to do more 
1427 # work to find out the build config parameters.
1428 if test x$host = x$build
1429 then
1430         build_auto=auto-host.h
1431 else
1432         # We create a subdir, then run autoconf in the subdir.
1433         # To prevent recursion we set host and build for the new
1434         # invocation of configure to the build for this invocation
1435         # of configure. 
1436         tempdir=build.$$
1437         rm -rf $tempdir
1438         mkdir $tempdir
1439         cd $tempdir
1440         case ${srcdir} in
1441         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1442         *) realsrcdir=../${srcdir};;
1443         esac
1444         saved_CFLAGS="${CFLAGS}"
1445         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1446         LDFLAGS="${LDFLAGS_FOR_BUILD}" \
1447         ${realsrcdir}/configure \
1448                 --enable-languages=${enable_languages-all} \
1449                 --target=$target_alias --host=$build_alias --build=$build_alias
1450         CFLAGS="${saved_CFLAGS}"
1451
1452         # We just finished tests for the build machine, so rename
1453         # the file auto-build.h in the gcc directory.
1454         mv auto-host.h ../auto-build.h
1455         cd ..
1456         rm -rf $tempdir
1457         build_auto=auto-build.h
1458 fi
1459 AC_SUBST(build_subdir)
1460
1461 tm_file="${tm_file} defaults.h"
1462 tm_p_file="${tm_p_file} tm-preds.h"
1463 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1464 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1465 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1466 # put this back in temporarily.
1467 xm_file="auto-host.h ansidecl.h ${xm_file}"
1468
1469 # --------
1470 # UNSORTED
1471 # --------
1472
1473 changequote(,)dnl
1474 # Compile in configure arguments.
1475 if test -f configargs.h ; then
1476         # Being re-configured.
1477         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1478         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1479 else
1480         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1481 fi
1482
1483 # Double all backslashes and backslash all quotes to turn
1484 # gcc_config_arguments into a C string.
1485 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1486 $gcc_config_arguments
1487 EOF
1488 gcc_config_arguments_str=`cat conftest.out`
1489 rm -f conftest.out
1490
1491 cat > configargs.h <<EOF
1492 /* Generated automatically. */
1493 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1494 static const char thread_model[] = "$thread_file";
1495
1496 static const struct {
1497   const char *name, *value;
1498 } configure_default_options[] = $configure_default_options;
1499 EOF
1500 changequote([,])dnl
1501
1502 changequote(,)dnl
1503 gcc_BASEVER=`cat $srcdir/BASE-VER`
1504 gcc_DEVPHASE=`cat $srcdir/DEV-PHASE`
1505 gcc_DATESTAMP=`cat $srcdir/DATESTAMP`
1506 if test -f $srcdir/REVISION ; then
1507         gcc_REVISION=`cat $srcdir/REVISION`
1508 else
1509         gcc_REVISION=""
1510 fi
1511 cat > plugin-version.h <<EOF
1512 #include "configargs.h"
1513
1514 #define GCCPLUGIN_VERSION_MAJOR   `echo $gcc_BASEVER | sed -e 's/^\([0-9]*\).*$/\1/'`
1515 #define GCCPLUGIN_VERSION_MINOR   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.\([0-9]*\).*$/\1/'`
1516 #define GCCPLUGIN_VERSION_PATCHLEVEL   `echo $gcc_BASEVER | sed -e 's/^[0-9]*\.[0-9]*\.\([0-9]*\)$/\1/'`
1517 #define GCCPLUGIN_VERSION  (GCCPLUGIN_VERSION_MAJOR*1000 + GCCPLUGIN_VERSION_MINOR)
1518
1519 static char basever[] = "$gcc_BASEVER";
1520 static char datestamp[] = "$gcc_DATESTAMP";
1521 static char devphase[] = "$gcc_DEVPHASE";
1522 static char revision[] = "$gcc_REVISION";
1523
1524 /* FIXME plugins: We should make the version information more precise.
1525    One way to do is to add a checksum. */
1526
1527 static struct plugin_gcc_version gcc_version = {basever, datestamp,
1528                                                 devphase, revision,
1529                                                 configuration_arguments};
1530 EOF
1531 changequote([,])dnl
1532
1533 # Internationalization
1534 ZW_GNU_GETTEXT_SISTER_DIR
1535
1536 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1537 # -liconv on the link line twice.
1538 case "$LIBINTL" in *$LIBICONV*)
1539         LIBICONV= ;;
1540 esac
1541
1542 AC_ARG_ENABLE(secureplt,
1543 [AS_HELP_STRING([--enable-secureplt],
1544                 [enable -msecure-plt by default for PowerPC])],
1545 [], [])
1546
1547 AC_ARG_ENABLE(leading-mingw64-underscores,
1548   AS_HELP_STRING([--enable-leading-mingw64-underscores],
1549                  [enable leading underscores on 64 bit mingw targets]),
1550   [],[])
1551 AS_IF([ test x"$enable_leading_mingw64_underscores" = xyes ],
1552   [AC_DEFINE(USE_MINGW64_LEADING_UNDERSCORES, 1,
1553     [Define if we should use leading underscore on 64 bit mingw targets])])
1554
1555 AC_ARG_ENABLE(cld,
1556 [AS_HELP_STRING([--enable-cld], [enable -mcld by default for 32bit x86])], [],
1557 [enable_cld=no])
1558
1559 AC_ARG_ENABLE(frame-pointer,
1560 [AS_HELP_STRING([--enable-frame-pointer],
1561                 [enable -fno-omit-frame-pointer by default for 32bit x86])], [],
1562 [
1563 case $target_os in
1564 linux* | darwin[[8912]]*)
1565   # Enable -fomit-frame-pointer by default for Linux and Darwin with
1566   # DWARF2.
1567   enable_frame_pointer=no
1568   ;;
1569 *)
1570   enable_frame_pointer=yes
1571   ;;
1572 esac
1573 ])
1574
1575 # Windows32 Registry support for specifying GCC installation paths.
1576 AC_ARG_ENABLE(win32-registry,
1577 [AS_HELP_STRING([--disable-win32-registry],
1578                 [disable lookup of installation paths in the
1579                  Registry on Windows hosts])
1580 AS_HELP_STRING([--enable-win32-registry], [enable registry lookup (default)])
1581 AS_HELP_STRING([--enable-win32-registry=KEY],
1582                [use KEY instead of GCC version as the last portion
1583                 of the registry key])],,)
1584
1585 case $host_os in
1586   win32 | pe | cygwin* | mingw32* | uwin*)
1587     if test "x$enable_win32_registry" != xno; then
1588       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1589     fi
1590
1591     if test "x$enable_win32_registry" != xno; then
1592       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1593   [Define to 1 if installation paths should be looked up in the Windows
1594    Registry. Ignored on non-Windows hosts.])
1595
1596       if test "x$enable_win32_registry" != xyes \
1597          && test "x$enable_win32_registry" != x; then
1598         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1599   [Define to be the last component of the Windows registry key under which
1600    to look for installation paths.  The full key used will be 
1601    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1602    The default is the GCC version number.])
1603       fi
1604     fi
1605   ;;
1606 esac
1607
1608 # Get an absolute path to the GCC top-level source directory
1609 holddir=`${PWDCMD-pwd}`
1610 cd $srcdir
1611 topdir=`${PWDCMD-pwd}`
1612 cd $holddir
1613
1614 # Conditionalize the makefile for this host machine.
1615 xmake_file=
1616 for f in ${host_xmake_file}
1617 do
1618         if test -f ${srcdir}/config/$f
1619         then
1620                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1621         fi
1622 done
1623
1624 # Conditionalize the makefile for this target machine.
1625 tmake_file_=
1626 for f in ${tmake_file}
1627 do
1628         if test -f ${srcdir}/config/$f
1629         then
1630                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1631         fi
1632 done
1633 tmake_file="${tmake_file_}"
1634
1635 out_object_file=`basename $out_file .c`.o
1636 common_out_object_file=`basename $common_out_file .c`.o
1637
1638 tm_file_list="options.h"
1639 tm_include_list="options.h insn-constants.h"
1640 for f in $tm_file; do
1641   case $f in
1642     ./* )
1643        f=`echo $f | sed 's/^..//'`
1644        tm_file_list="${tm_file_list} $f"
1645        tm_include_list="${tm_include_list} $f"
1646        ;;
1647     defaults.h )
1648        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1649        tm_include_list="${tm_include_list} $f"
1650        ;;
1651     * )
1652        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1653        tm_include_list="${tm_include_list} config/$f"
1654        ;;
1655   esac
1656 done
1657
1658 libgcc_tm_file_list=
1659 libgcc_tm_include_list=
1660 for f in $libgcc_tm_file; do
1661   libgcc_tm_file_list="${libgcc_tm_file_list} \$(srcdir)/../libgcc/config/$f"
1662   libgcc_tm_include_list="${libgcc_tm_include_list} ../libgcc/config/$f"
1663 done
1664
1665 tm_p_file_list=
1666 tm_p_include_list=
1667 for f in $tm_p_file; do
1668   case $f in
1669     tm-preds.h )
1670        tm_p_file_list="${tm_p_file_list} $f"
1671        tm_p_include_list="${tm_p_include_list} $f"
1672        ;;
1673     * )
1674        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1675        tm_p_include_list="${tm_p_include_list} config/$f"
1676   esac
1677 done
1678
1679 xm_file_list=
1680 xm_include_list=
1681 for f in $xm_file; do
1682   case $f in
1683     ansidecl.h )
1684        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1685        xm_include_list="${xm_include_list} $f"
1686        ;;
1687     auto-host.h )
1688        xm_file_list="${xm_file_list} $f"
1689        xm_include_list="${xm_include_list} $f"
1690        ;;
1691     * )
1692        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1693        xm_include_list="${xm_include_list} config/$f"
1694        ;;
1695   esac
1696 done
1697
1698 host_xm_file_list=
1699 host_xm_include_list=
1700 for f in $host_xm_file; do
1701   case $f in
1702     ansidecl.h )
1703        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1704        host_xm_include_list="${host_xm_include_list} $f"
1705        ;;
1706     auto-host.h )
1707        host_xm_file_list="${host_xm_file_list} $f"
1708        host_xm_include_list="${host_xm_include_list} $f"
1709        ;;
1710     * )
1711        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1712        host_xm_include_list="${host_xm_include_list} config/$f"
1713        ;;
1714   esac
1715 done
1716
1717 build_xm_file_list=
1718 for f in $build_xm_file; do
1719   case $f in
1720     ansidecl.h )
1721        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1722        build_xm_include_list="${build_xm_include_list} $f"
1723        ;;
1724     auto-build.h | auto-host.h )
1725        build_xm_file_list="${build_xm_file_list} $f"
1726        build_xm_include_list="${build_xm_include_list} $f"
1727        ;;
1728     * )
1729        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1730        build_xm_include_list="${build_xm_include_list} config/$f"
1731        ;;
1732   esac
1733 done
1734
1735 # Define macro CROSS_DIRECTORY_STRUCTURE in compilation if this is a
1736 # cross-compiler which does not use the native headers and libraries.
1737 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1738 CROSS=                                          AC_SUBST(CROSS)
1739 ALL=all.internal                                AC_SUBST(ALL)
1740 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1741
1742 if test "x$with_build_sysroot" != x; then
1743   build_system_header_dir=$with_build_sysroot'$${sysroot_headers_suffix}$(NATIVE_SYSTEM_HEADER_DIR)'
1744 else
1745   # This value is used, even on a native system, because 
1746   # CROSS_SYSTEM_HEADER_DIR is just 
1747   # $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR).
1748   build_system_header_dir='$(CROSS_SYSTEM_HEADER_DIR)'
1749 fi
1750
1751 if test x$host != x$target
1752 then
1753         CROSS="-DCROSS_DIRECTORY_STRUCTURE"
1754         ALL=all.cross
1755         SYSTEM_HEADER_DIR=$build_system_header_dir
1756         case "$host","$target" in
1757         # Darwin crosses can use the host system's libraries and headers,
1758         # because of the fat library support.  Of course, it must be the
1759         # same version of Darwin on both sides.  Allow the user to
1760         # just say --target=foo-darwin without a version number to mean
1761         # "the version on this system".
1762             *-*-darwin*,*-*-darwin*)
1763                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1764                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1765                 if test $hostos = $targetos -o $targetos = darwin ; then
1766                     CROSS=
1767                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1768                     with_headers=yes
1769                 fi
1770                 ;;
1771
1772             i?86-*-*,x86_64-*-* \
1773             | powerpc*-*-*,powerpc64*-*-*)
1774                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1775         esac
1776
1777         case $target in
1778                 *-*-mingw*)
1779                         if test "x$with_headers" = x; then
1780                                 with_headers=yes
1781                         fi
1782                         ;;
1783                 *)
1784                         ;;
1785         esac
1786 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1787         SYSTEM_HEADER_DIR=$build_system_header_dir 
1788 fi
1789
1790 # If this is a cross-compiler that does not
1791 # have its own set of headers then define
1792 # inhibit_libc
1793
1794 # If this is using newlib, without having the headers available now,
1795 # then define inhibit_libc in LIBGCC2_CFLAGS.
1796 # This prevents libgcc2 from containing any code which requires libc
1797 # support.
1798 : ${inhibit_libc=false}
1799 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1800        test x$with_newlib = xyes ; } &&
1801      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1802        inhibit_libc=true
1803 fi
1804 AC_SUBST(inhibit_libc)
1805
1806 # When building gcc with a cross-compiler, we need to adjust things so
1807 # that the generator programs are still built with the native compiler.
1808 # Also, we cannot run fixincludes.
1809
1810 # These are the normal (build=host) settings:
1811 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1812 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1813 BUILD_LDFLAGS='$(LDFLAGS)'      AC_SUBST(BUILD_LDFLAGS)
1814 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1815
1816 # And these apply if build != host, or we are generating coverage data
1817 if test x$build != x$host || test "x$coverage_flags" != x
1818 then
1819     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1820     BUILD_LDFLAGS='$(LDFLAGS_FOR_BUILD)'
1821 fi
1822
1823 # Expand extra_headers to include complete path.
1824 # This substitutes for lots of t-* files.
1825 extra_headers_list=
1826 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1827 for file in ${extra_headers} ; do
1828   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1829 done
1830
1831 # If use_gcc_tgmath is set, append ginclude/tgmath.h.
1832 if test x"$use_gcc_tgmath" = xyes
1833 then extra_headers_list="${extra_headers_list} \$(srcdir)/ginclude/tgmath.h"
1834 fi
1835
1836 # Define collect2 in Makefile.
1837 case $host_can_use_collect2 in
1838   no) collect2= ;;
1839   *) collect2='collect2$(exeext)' ;;
1840 esac
1841 AC_SUBST([collect2])
1842
1843 # Add a definition of USE_COLLECT2 if system wants one.
1844 case $use_collect2 in
1845   no) use_collect2= ;;
1846   "") ;;
1847   *) 
1848     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1849     xm_defines="${xm_defines} USE_COLLECT2"
1850     case $host_can_use_collect2 in
1851       no)
1852         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1853         ;;
1854     esac
1855     ;;
1856 esac
1857
1858 AC_DEFINE_UNQUOTED(LTOPLUGINSONAME,"${host_lto_plugin_soname}",
1859 [Define to the name of the LTO plugin DSO that must be
1860   passed to the linker's -plugin=LIB option.])
1861
1862 # ---------------------------
1863 # Assembler & linker features
1864 # ---------------------------
1865
1866 # During stage 2, ld is actually gcc/collect-ld, which is a small script to
1867 # discern between when to use prev-ld/ld-new and when to use ld/ld-new.
1868 # However when ld-new is first executed from the build tree, libtool will
1869 # relink it as .libs/lt-ld-new, so that it can give it an RPATH that refers
1870 # to the build tree.  While doing this we need to use the previous-stage
1871 # linker, or we have an infinite loop.  The presence of a shell script as
1872 # ld/ld-new, and the fact that the script *uses ld itself*, is what confuses
1873 # the gcc/collect-ld script.  So we need to know how libtool works, or
1874 # exec-tool will fail.
1875
1876 m4_defun([_LT_CONFIG_COMMANDS], [])
1877 AC_PROG_LIBTOOL
1878 AC_SUBST(objdir)
1879 AC_SUBST(enable_fast_install)
1880
1881 # Identify the assembler which will work hand-in-glove with the newly
1882 # built GCC, so that we can examine its features.  This is the assembler
1883 # which will be driven by the driver program.
1884 #
1885 # If build != host, and we aren't building gas in-tree, we identify a
1886 # build->target assembler and hope that it will have the same features
1887 # as the host->target assembler we'll be using.
1888 gcc_cv_gas_major_version=
1889 gcc_cv_gas_minor_version=
1890 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1891
1892 m4_pattern_allow([AS_FOR_TARGET])dnl
1893 AS_VAR_SET_IF(gcc_cv_as,, [
1894 if test -x "$DEFAULT_ASSEMBLER"; then
1895         gcc_cv_as="$DEFAULT_ASSEMBLER"
1896 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1897      && test -f ../gas/Makefile \
1898      && test x$build = x$host; then
1899         gcc_cv_as=../gas/as-new$build_exeext
1900 elif test -x as$build_exeext; then
1901         # Build using assembler in the current directory.
1902         gcc_cv_as=./as$build_exeext
1903 elif ( set dummy $AS_FOR_TARGET; test -x $[2] ); then
1904         gcc_cv_as="$AS_FOR_TARGET"
1905 else
1906         AC_PATH_PROG(gcc_cv_as, $AS_FOR_TARGET)
1907 fi])
1908
1909 ORIGINAL_AS_FOR_TARGET=$gcc_cv_as
1910 AC_SUBST(ORIGINAL_AS_FOR_TARGET)
1911 case "$ORIGINAL_AS_FOR_TARGET" in
1912   ./as | ./as$build_exeext) ;;
1913   *) AC_CONFIG_FILES(as:exec-tool.in, [chmod +x as]) ;;
1914 esac 
1915
1916 AC_MSG_CHECKING(what assembler to use)
1917 if test "$gcc_cv_as" = ../gas/as-new$build_exeext; then
1918   # Single tree build which includes gas.  We want to prefer it
1919   # over whatever linker top-level may have detected, since
1920   # we'll use what we're building after installation anyway.
1921   AC_MSG_RESULT(newly built gas)
1922   in_tree_gas=yes
1923   _gcc_COMPUTE_GAS_VERSION
1924   in_tree_gas_is_elf=no
1925   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1926      || (grep 'obj_format = multi' ../gas/Makefile \
1927          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1928   then
1929     in_tree_gas_is_elf=yes
1930   fi
1931 else
1932   AC_MSG_RESULT($gcc_cv_as)
1933   in_tree_gas=no
1934 fi
1935
1936 # Identify the linker which will work hand-in-glove with the newly
1937 # built GCC, so that we can examine its features.  This is the linker
1938 # which will be driven by the driver program.
1939 #
1940 # If build != host, and we aren't building gas in-tree, we identify a
1941 # build->target linker and hope that it will have the same features
1942 # as the host->target linker we'll be using.
1943 gcc_cv_gld_major_version=
1944 gcc_cv_gld_minor_version=
1945 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1946 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1947
1948 AS_VAR_SET_IF(gcc_cv_ld,, [
1949 if test -x "$DEFAULT_LINKER"; then
1950         gcc_cv_ld="$DEFAULT_LINKER"
1951 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1952      && test -f ../ld/Makefile \
1953      && test x$build = x$host; then
1954         gcc_cv_ld=../ld/ld-new$build_exeext
1955 elif test -x collect-ld$build_exeext; then
1956         # Build using linker in the current directory.
1957         gcc_cv_ld=./collect-ld$build_exeext
1958 elif ( set dummy $LD_FOR_TARGET; test -x $[2] ); then
1959         gcc_cv_ld="$LD_FOR_TARGET"
1960 else
1961         AC_PATH_PROG(gcc_cv_ld, $LD_FOR_TARGET)
1962 fi])
1963
1964 ORIGINAL_PLUGIN_LD_FOR_TARGET=$gcc_cv_ld
1965 PLUGIN_LD=`basename $gcc_cv_ld`
1966 AC_ARG_WITH(plugin-ld,
1967 [AS_HELP_STRING([[--with-plugin-ld=[ARG]]], [specify the plugin linker])],
1968 [if test x"$withval" != x; then
1969    ORIGINAL_PLUGIN_LD_FOR_TARGET="$withval"
1970    PLUGIN_LD="$withval"
1971  fi])
1972 AC_SUBST(ORIGINAL_PLUGIN_LD_FOR_TARGET)
1973 AC_DEFINE_UNQUOTED(PLUGIN_LD, "$PLUGIN_LD", [Specify plugin linker])
1974
1975 # Check to see if we are using gold instead of ld
1976 AC_MSG_CHECKING(whether we are using gold)
1977 ld_is_gold=no
1978 if test x$gcc_cv_ld != x; then
1979   if $gcc_cv_ld --version 2>/dev/null | sed 1q \
1980      | grep "GNU gold" > /dev/null; then
1981     ld_is_gold=yes
1982   fi
1983 fi
1984 AC_MSG_RESULT($ld_is_gold)
1985
1986 ORIGINAL_LD_FOR_TARGET=$gcc_cv_ld
1987 AC_SUBST(ORIGINAL_LD_FOR_TARGET)
1988 case "$ORIGINAL_LD_FOR_TARGET" in
1989   ./collect-ld | ./collect-ld$build_exeext) ;;
1990   *) AC_CONFIG_FILES(collect-ld:exec-tool.in, [chmod +x collect-ld]) ;;
1991 esac 
1992
1993 AC_MSG_CHECKING(what linker to use)
1994 if test "$gcc_cv_ld" = ../ld/ld-new$build_exeext \
1995    || test "$gcc_cv_ld" = ../gold/ld-new$build_exeext; then
1996         # Single tree build which includes ld.  We want to prefer it
1997         # over whatever linker top-level may have detected, since
1998         # we'll use what we're building after installation anyway.
1999         AC_MSG_RESULT(newly built ld)
2000         in_tree_ld=yes
2001         in_tree_ld_is_elf=no
2002         if (grep 'EMUL = .*elf' ../ld/Makefile \
2003             || grep 'EMUL = .*linux' ../ld/Makefile \
2004             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
2005           in_tree_ld_is_elf=yes
2006         elif test "$ld_is_gold" = yes; then
2007           in_tree_ld_is_elf=yes
2008         fi
2009         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
2010         do
2011 changequote(,)dnl
2012                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
2013                 if test x$gcc_cv_gld_version != x; then
2014                         break
2015                 fi
2016         done
2017         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
2018         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
2019 changequote([,])dnl
2020 else
2021         AC_MSG_RESULT($gcc_cv_ld)
2022         in_tree_ld=no
2023 fi
2024
2025 # Figure out what nm we will be using.
2026 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
2027 AS_VAR_SET_IF(gcc_cv_nm,, [
2028 if test -f $gcc_cv_binutils_srcdir/configure.in \
2029      && test -f ../binutils/Makefile \
2030      && test x$build = x$host; then
2031         gcc_cv_nm=../binutils/nm-new$build_exeext
2032 elif test -x nm$build_exeext; then
2033         gcc_cv_nm=./nm$build_exeext
2034 elif ( set dummy $NM_FOR_TARGET; test -x $[2] ); then
2035         gcc_cv_nm="$NM_FOR_TARGET"
2036 else
2037         AC_PATH_PROG(gcc_cv_nm, $NM_FOR_TARGET)
2038 fi])
2039
2040 AC_MSG_CHECKING(what nm to use)
2041 if test "$gcc_cv_nm" = ../binutils/nm-new$build_exeext; then
2042         # Single tree build which includes binutils.
2043         AC_MSG_RESULT(newly built nm)
2044         in_tree_nm=yes
2045 else
2046         AC_MSG_RESULT($gcc_cv_nm)
2047         in_tree_nm=no
2048 fi
2049
2050 ORIGINAL_NM_FOR_TARGET=$gcc_cv_nm
2051 AC_SUBST(ORIGINAL_NM_FOR_TARGET)
2052 case "$ORIGINAL_NM_FOR_TARGET" in
2053   ./nm | ./nm$build_exeext) ;;
2054   *) AC_CONFIG_FILES(nm:exec-tool.in, [chmod +x nm]) ;;
2055 esac
2056
2057
2058 # Figure out what objdump we will be using.
2059 AS_VAR_SET_IF(gcc_cv_objdump,, [
2060 if test -f $gcc_cv_binutils_srcdir/configure.in \
2061      && test -f ../binutils/Makefile \
2062      && test x$build = x$host; then
2063         # Single tree build which includes binutils.
2064         gcc_cv_objdump=../binutils/objdump$build_exeext
2065 elif test -x objdump$build_exeext; then
2066         gcc_cv_objdump=./objdump$build_exeext
2067 elif ( set dummy $OBJDUMP_FOR_TARGET; test -x $[2] ); then
2068         gcc_cv_objdump="$OBJDUMP_FOR_TARGET"
2069 else
2070         AC_PATH_PROG(gcc_cv_objdump, $OBJDUMP_FOR_TARGET)
2071 fi])
2072
2073 AC_MSG_CHECKING(what objdump to use)
2074 if test "$gcc_cv_objdump" = ../binutils/objdump$build_exeext; then
2075         # Single tree build which includes binutils.
2076         AC_MSG_RESULT(newly built objdump)
2077 elif test x$gcc_cv_objdump = x; then
2078         AC_MSG_RESULT(not found)
2079 else
2080         AC_MSG_RESULT($gcc_cv_objdump)
2081 fi
2082
2083 # Figure out what readelf we will be using.
2084 AS_VAR_SET_IF(gcc_cv_readelf,, [
2085 if test -f $gcc_cv_binutils_srcdir/configure.in \
2086      && test -f ../binutils/Makefile \
2087      && test x$build = x$host; then
2088         # Single tree build which includes binutils.
2089         gcc_cv_readelf=../binutils/readelf$build_exeext
2090 elif test -x readelf$build_exeext; then
2091         gcc_cv_readelf=./readelf$build_exeext
2092 else
2093         AC_PATH_PROG(gcc_cv_readelf, readelf)
2094 fi])
2095
2096 AC_MSG_CHECKING(what readelf to use)
2097 if test "$gcc_cv_readelf" = ../binutils/readelf$build_exeext; then
2098         # Single tree build which includes binutils.
2099         AC_MSG_RESULT(newly built readelf)
2100 elif test x$gcc_cv_readelf = x; then
2101         AC_MSG_RESULT(not found)
2102 else
2103         AC_MSG_RESULT($gcc_cv_readelf)
2104 fi
2105
2106 # Figure out what assembler alignment features are present.
2107 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2108  [2,6,0],,
2109 [.balign 4
2110 .p2align 2],,
2111 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2112   [Define if your assembler supports .balign and .p2align.])])
2113
2114 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2115  [2,8,0],,
2116  [.p2align 4,,7],,
2117 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2118   [Define if your assembler supports specifying the maximum number
2119    of bytes to skip when using the GAS .p2align command.])])
2120
2121 gcc_GAS_CHECK_FEATURE([.literal16], gcc_cv_as_literal16,
2122  [2,8,0],,
2123  [.literal16],,
2124 [AC_DEFINE(HAVE_GAS_LITERAL16, 1,
2125   [Define if your assembler supports .literal16.])])
2126
2127 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2128  [elf,2,9,0],,
2129  [conftest_label1: .word 0
2130 .subsection -1
2131 conftest_label2: .word 0
2132 .previous],
2133  [if test x$gcc_cv_nm != x; then
2134     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2135     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2136     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2137     then :
2138     else gcc_cv_as_subsection_m1=yes
2139     fi
2140     rm -f conftest.nm1 conftest.nm2
2141   fi],
2142  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2143   [Define if your assembler supports .subsection and .subsection -1 starts
2144    emitting at the beginning of your section.])])
2145
2146 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2147  [2,2,0],,
2148  [      .weak foobar],,
2149 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2150
2151 gcc_GAS_CHECK_FEATURE([.weakref], gcc_cv_as_weakref,
2152  [2,17,0],,
2153  [      .weakref foobar, barfnot],,
2154 [AC_DEFINE(HAVE_GAS_WEAKREF, 1, [Define if your assembler supports .weakref.])])
2155
2156 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2157  [2,15,91],,
2158  [      .SPACE $TEXT$
2159         .NSUBSPA $CODE$,COMDAT],,
2160 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2161
2162 # .hidden needs to be supported in both the assembler and the linker,
2163 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2164 # This is irritatingly difficult to feature test for; we have to check the
2165 # date string after the version number.  If we've got an in-tree
2166 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2167 # to be safe.
2168 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2169 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2170  [elf,2,13,0],,
2171 [       .hidden foobar
2172 foobar:],[
2173 # Solaris 9/x86 as incorrectly emits an alias for a hidden symbol with
2174 # STV_HIDDEN, so disable .hidden support if so.
2175 case "${target}" in
2176   i?86-*-solaris2*)
2177     if test x$gcc_cv_as != x && test x$gcc_cv_objdump != x; then
2178       cat > conftest.s <<EOF
2179 .globl hidden
2180         .hidden hidden
2181 hidden:
2182 .globl default
2183         .set    default,hidden
2184 EOF
2185       if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1 \
2186         && $gcc_cv_objdump -t conftest.o 2>/dev/null | \
2187         grep '\.hidden default' > /dev/null; then
2188         gcc_cv_as_hidden=no
2189       else
2190         gcc_cv_as_hidden=yes
2191       fi
2192     else
2193       # Assume bug is present if objdump is missing.
2194       gcc_cv_as_hidden=no
2195     fi
2196     ;;
2197   *)
2198     gcc_cv_as_hidden=yes
2199     ;;
2200 esac])
2201 case "${target}" in
2202   *-*-darwin*)
2203     # Darwin as has some visibility support, though with a different syntax.
2204     gcc_cv_as_hidden=yes
2205     ;;
2206 esac
2207
2208 # gnu_indirect_function type is an extension proposed at
2209 # http://groups.google/com/group/generic-abi/files. It allows dynamic runtime
2210 # selection of function implementation
2211 AC_ARG_ENABLE(gnu-indirect-function,
2212  [AS_HELP_STRING([--enable-gnu-indirect-function],
2213                  [enable the use of the @gnu_indirect_function to glibc systems])],
2214  [case $enable_gnu_indirect_function in
2215     yes | no) ;;
2216     *) AC_MSG_ERROR(['$enable_gnu_indirect_function' is an invalid value for --enable-gnu-indirect-function.
2217 Valid choices are 'yes' and 'no'.]) ;;
2218   esac],
2219  [enable_gnu_indirect_function="$default_gnu_indirect_function"])
2220 if test x$enable_gnu_indirect_function = xyes; then
2221   AC_DEFINE(HAVE_GNU_INDIRECT_FUNCTION, 1,
2222    [Define if your system supports gnu indirect functions.])
2223 fi
2224
2225 changequote(,)dnl
2226 if test $in_tree_ld != yes ; then
2227   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2228   if echo "$ld_ver" | grep GNU > /dev/null; then
2229     if test x"$ld_is_gold" = xyes; then
2230       # GNU gold --version looks like this:
2231       #
2232       # GNU gold (GNU Binutils 2.21.51.20110225) 1.11
2233       #
2234       # We extract the binutils version which is more familiar and specific
2235       # than the gold version.
2236       ld_vers=`echo $ld_ver | sed -n \
2237           -e 's,^[^)]*[  ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
2238     else
2239       # GNU ld --version looks like this:
2240       #
2241       # GNU ld (GNU Binutils) 2.21.51.20110225
2242       ld_vers=`echo $ld_ver | sed -n \
2243           -e 's,^.*[     ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2244     fi
2245     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2246     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2247     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2248     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2249   else
2250     case "${target}" in
2251       *-*-solaris2*)
2252         #
2253         # Solaris 2 ld -V output looks like this for a regular version:
2254         #
2255         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1699
2256         #
2257         # but test versions add stuff at the end:
2258         #
2259         # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.1701:onnv-ab196087-6931056-03/25/10
2260         #
2261         ld_ver=`$gcc_cv_ld -V 2>&1`
2262         if echo "$ld_ver" | grep 'Solaris Link Editors' > /dev/null; then
2263           ld_vers=`echo $ld_ver | sed -n \
2264             -e 's,^.*: 5\.[0-9][0-9]*-\([0-9]\.[0-9][0-9]*\).*$,\1,p'`
2265           ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2266           ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2267         fi
2268         ;;
2269     esac
2270   fi
2271 fi
2272 changequote([,])dnl
2273
2274 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2275 [[if test $in_tree_ld = yes ; then
2276   gcc_cv_ld_hidden=no
2277   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2278      && test $in_tree_ld_is_elf = yes; then
2279      gcc_cv_ld_hidden=yes
2280   fi
2281 else
2282   gcc_cv_ld_hidden=yes
2283   if test x"$ld_is_gold" = xyes; then
2284     :
2285   elif echo "$ld_ver" | grep GNU > /dev/null; then
2286     if test 0"$ld_date" -lt 20020404; then
2287       if test -n "$ld_date"; then
2288         # If there was date string, but was earlier than 2002-04-04, fail
2289         gcc_cv_ld_hidden=no
2290       elif test -z "$ld_vers"; then
2291         # If there was no date string nor ld version number, something is wrong
2292         gcc_cv_ld_hidden=no
2293       else
2294         test -z "$ld_vers_patch" && ld_vers_patch=0
2295         if test "$ld_vers_major" -lt 2; then
2296           gcc_cv_ld_hidden=no
2297         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2298           gcc_cv_ld_hidden="no"
2299         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2300           gcc_cv_ld_hidden=no
2301         fi
2302       fi
2303     fi
2304   else
2305     case "${target}" in
2306       *-*-darwin*)
2307         # Darwin ld has some visibility support.
2308         gcc_cv_ld_hidden=yes
2309         ;;
2310       hppa64*-*-hpux* | ia64*-*-hpux*)
2311         gcc_cv_ld_hidden=yes
2312         ;;
2313       *-*-solaris2.8*)
2314         # .hidden support was backported to Solaris 8, starting with ld
2315         # version 1.276.
2316         if test "$ld_vers_minor" -ge 276; then
2317           gcc_cv_ld_hidden=yes
2318         else
2319           gcc_cv_ld_hidden=no
2320         fi
2321         ;;
2322       *-*-solaris2.9* | *-*-solaris2.1[0-9]*)
2323         # Support for .hidden in Sun ld appeared in Solaris 9 FCS, but
2324         # .symbolic was only added in Solaris 9 12/02.
2325         gcc_cv_ld_hidden=yes
2326         ;;
2327       *)
2328         gcc_cv_ld_hidden=no
2329         ;;
2330     esac
2331   fi
2332 fi]])
2333 libgcc_visibility=no
2334 AC_SUBST(libgcc_visibility)
2335 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2336 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2337   libgcc_visibility=yes
2338   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2339   [Define if your assembler and linker support .hidden.])
2340 fi
2341
2342 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2343 gcc_cv_ld_ro_rw_mix=unknown
2344 if test $in_tree_ld = yes ; then
2345   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2346      && test $in_tree_ld_is_elf = yes; then
2347     gcc_cv_ld_ro_rw_mix=read-write
2348   fi
2349 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2350   echo '.section myfoosect, "a"' > conftest1.s
2351   echo '.section myfoosect, "aw"' > conftest2.s
2352   echo '.byte 1' >> conftest2.s
2353   echo '.section myfoosect, "a"' > conftest3.s
2354   echo '.byte 0' >> conftest3.s
2355   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2356      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2357      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2358      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2359         conftest2.o conftest3.o > /dev/null 2>&1; then
2360     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2361                          | sed -e '/myfoosect/!d' -e N`
2362     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2363       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2364         gcc_cv_ld_ro_rw_mix=read-only
2365       else
2366         gcc_cv_ld_ro_rw_mix=read-write
2367       fi
2368     fi
2369   fi
2370 changequote(,)dnl
2371   rm -f conftest.* conftest[123].*
2372 changequote([,])dnl
2373 fi
2374 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2375         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2376   [Define if your linker links a mix of read-only
2377    and read-write sections into a read-write section.])
2378 fi
2379 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2380
2381 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2382 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2383   [elf,2,11,0],,
2384 [       .data
2385         .uleb128 L2 - L1
2386 L1:
2387         .uleb128 1280
2388         .sleb128 -1010
2389 L2:],
2390 [[# GAS versions before 2.11 do not support uleb128,
2391   # despite appearing to.
2392   # ??? There exists an elf-specific test that will crash
2393   # the assembler.  Perhaps it's better to figure out whether
2394   # arbitrary sections are supported and try the test.
2395   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2396   if echo "$as_ver" | grep GNU > /dev/null; then
2397     as_vers=`echo $as_ver | sed -n \
2398         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
2399     as_major=`expr "$as_vers" : '\([0-9]*\)'`
2400     as_minor=`expr "$as_vers" : '[0-9]*\.\([0-9]*\)'`
2401     if test $as_major -eq 2 && test $as_minor -lt 11
2402     then :
2403     else gcc_cv_as_leb128=yes
2404     fi
2405   fi]],
2406   [AC_DEFINE(HAVE_AS_LEB128, 1,
2407     [Define if your assembler supports .sleb128 and .uleb128.])])
2408
2409 # Check if we have assembler support for unwind directives.
2410 gcc_GAS_CHECK_FEATURE([cfi directives], gcc_cv_as_cfi_directive,
2411   ,,
2412 [       .text
2413         .cfi_startproc
2414         .cfi_offset 0, 0
2415         .cfi_same_value 1
2416         .cfi_def_cfa 1, 2
2417         .cfi_escape 1, 2, 3, 4, 5
2418         .cfi_endproc],
2419 [case "$target" in
2420   *-*-solaris*)
2421     # If the linker used on Solaris (like Sun ld) isn't capable of merging
2422     # read-only and read-write sections, we need to make sure that the
2423     # assembler used emits read-write .eh_frame sections.
2424     if test "x$gcc_cv_ld_ro_rw_mix" != xread-write; then
2425       if test "x$gcc_cv_objdump" != x; then
2426         if $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2427                 sed -e /.eh_frame/!d -e N | grep READONLY > /dev/null; then
2428           gcc_cv_as_cfi_directive=no
2429         else
2430           case "$target" in
2431             i?86-*-solaris2.1[[0-9]]*)
2432               # On Solaris/x86, make sure that GCC and gas agree on using
2433               # read-only .eh_frame sections for 64-bit.
2434               if $gcc_cv_as --64 -o conftest.o conftest.s > /dev/null 2>&1 && \
2435                 $gcc_cv_objdump -h conftest.o 2>/dev/null | \
2436                         sed -e /.eh_frame/!d -e N | \
2437                         grep READONLY > /dev/null; then
2438                 gcc_cv_as_cfi_directive=yes
2439               else
2440                 gcc_cv_as_cfi_directive=no
2441               fi
2442               ;;
2443             *)
2444               gcc_cv_as_cfi_directive=yes
2445               ;;
2446           esac 
2447         fi
2448       else
2449         # no objdump, err on the side of caution
2450         gcc_cv_as_cfi_directive=no
2451       fi
2452     else
2453       gcc_cv_as_cfi_directive=yes
2454     fi
2455     ;;
2456   *-*-*)
2457     gcc_cv_as_cfi_directive=yes
2458     ;;
2459 esac])
2460 if test $gcc_cv_as_cfi_directive = yes && test x$gcc_cv_objdump != x; then
2461 gcc_GAS_CHECK_FEATURE([working cfi advance], gcc_cv_as_cfi_advance_working,
2462   ,,
2463 [       .text
2464         .cfi_startproc
2465         .cfi_adjust_cfa_offset 64
2466         .skip 75040, 0
2467         .cfi_adjust_cfa_offset 128
2468         .cfi_endproc],
2469 [[
2470 if $gcc_cv_objdump -Wf conftest.o 2>/dev/null \
2471     | grep 'DW_CFA_advance_loc[24]:[    ][      ]*75040[        ]' >/dev/null; then
2472    gcc_cv_as_cfi_advance_working=yes
2473 fi
2474 ]])
2475 else
2476   # no objdump, err on the side of caution
2477   gcc_cv_as_cfi_advance_working=no
2478 fi
2479 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_DIRECTIVE)
2480 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_DIRECTIVE,
2481   [`if test $gcc_cv_as_cfi_directive = yes \
2482        && test $gcc_cv_as_cfi_advance_working = yes; then echo 1; else echo 0; fi`],
2483   [Define 0/1 if your assembler supports CFI directives.])
2484
2485 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE)
2486 gcc_GAS_CHECK_FEATURE([cfi personality directive],
2487   gcc_cv_as_cfi_personality_directive, ,,
2488 [       .text
2489         .cfi_startproc
2490         .cfi_personality 0, symbol
2491         .cfi_endproc])
2492 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_PERSONALITY_DIRECTIVE,
2493   [`if test $gcc_cv_as_cfi_personality_directive = yes;
2494     then echo 1; else echo 0; fi`],
2495   [Define 0/1 if your assembler supports .cfi_personality.])
2496
2497 gcc_GAS_CHECK_FEATURE([cfi sections directive],
2498   gcc_cv_as_cfi_sections_directive, ,,
2499 [       .text
2500         .cfi_sections .debug_frame, .eh_frame
2501         .cfi_startproc
2502         .cfi_endproc],
2503 [case $target_os in
2504   win32 | pe | cygwin* | mingw32* | uwin*)
2505     # Need to check that we generated the correct relocation for the
2506     # .debug_frame section.  This was fixed for binutils 2.21.
2507     gcc_cv_as_cfi_sections_directive=no
2508     if test "x$gcc_cv_objdump" != x; then
2509      if $gcc_cv_objdump -j .debug_frame -r conftest.o 2>/dev/null | \
2510         grep secrel > /dev/null; then
2511       gcc_cv_as_cfi_sections_directive=yes
2512      fi
2513     fi
2514     ;;
2515   *)
2516     gcc_cv_as_cfi_sections_directive=yes
2517     ;;
2518 esac])
2519 GCC_TARGET_TEMPLATE(HAVE_GAS_CFI_SECTIONS_DIRECTIVE)
2520 AC_DEFINE_UNQUOTED(HAVE_GAS_CFI_SECTIONS_DIRECTIVE,
2521   [`if test $gcc_cv_as_cfi_sections_directive = yes;
2522     then echo 1; else echo 0; fi`],
2523   [Define 0/1 if your assembler supports .cfi_sections.])
2524
2525 # GAS versions up to and including 2.11.0 may mis-optimize
2526 # .eh_frame data.
2527 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2528   [elf,2,12,0],,
2529 [       .text
2530 .LFB1:
2531         .4byte  0
2532 .L1:
2533         .4byte  0
2534 .LFE1:
2535         .section        .eh_frame,"aw",@progbits
2536 __FRAME_BEGIN__:
2537         .4byte  .LECIE1-.LSCIE1
2538 .LSCIE1:
2539         .4byte  0x0
2540         .byte   0x1
2541         .ascii "z\0"
2542         .byte   0x1
2543         .byte   0x78
2544         .byte   0x1a
2545         .byte   0x0
2546         .byte   0x4
2547         .4byte  1
2548         .p2align 1
2549 .LECIE1:
2550 .LSFDE1:
2551         .4byte  .LEFDE1-.LASFDE1
2552 .LASFDE1:
2553         .4byte  .LASFDE1-__FRAME_BEGIN__
2554         .4byte  .LFB1
2555         .4byte  .LFE1-.LFB1
2556         .byte   0x4
2557         .4byte  .LFE1-.LFB1
2558         .byte   0x4
2559         .4byte  .L1-.LFB1
2560 .LEFDE1:],
2561 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2562 cat > conftest.lit <<EOF
2563  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2564  0010 01000000 12000000 18000000 00000000  ................
2565  0020 08000000 04080000 0044               .........D      @&t@
2566 EOF
2567 cat > conftest.big <<EOF
2568  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2569  0010 00000001 00000012 00000018 00000000  ................
2570  0020 00000008 04000000 0844               .........D      @&t@
2571 EOF
2572   # If the assembler didn't choke, and we can objdump,
2573   # and we got the correct data, then succeed.
2574   # The text in the here-document typically retains its unix-style line
2575   # endings, while the output of objdump will use host line endings.
2576   # Therefore, use diff -b for the comparisons.
2577   if test x$gcc_cv_objdump != x \
2578   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2579      | tail -3 > conftest.got \
2580   && { diff -b conftest.lit conftest.got > /dev/null 2>&1 \
2581     || diff -b conftest.big conftest.got > /dev/null 2>&1; }
2582   then
2583     gcc_cv_as_eh_frame=yes
2584   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2585     gcc_cv_as_eh_frame=buggy
2586   else
2587     # Uh oh, what do we do now?
2588     gcc_cv_as_eh_frame=no
2589   fi])
2590
2591 if test $gcc_cv_as_eh_frame = buggy; then
2592   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2593   [Define if your assembler mis-optimizes .eh_frame data.])
2594 fi
2595
2596 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2597  [elf,2,12,0], [--fatal-warnings],
2598  [.section .rodata.str, "aMS", @progbits, 1])
2599 if test $gcc_cv_as_shf_merge = no; then
2600   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2601     [elf,2,12,0], [--fatal-warnings],
2602     [.section .rodata.str, "aMS", %progbits, 1])
2603 fi
2604 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2605   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2606 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2607
2608 gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as)],
2609  gcc_cv_as_comdat_group,
2610  [elf,2,16,0], [--fatal-warnings],
2611  [.section .text,"axG",@progbits,.foo,comdat])
2612 if test $gcc_cv_as_comdat_group = yes; then
2613   gcc_cv_as_comdat_group_percent=no
2614   gcc_cv_as_comdat_group_group=no
2615 else
2616  gcc_GAS_CHECK_FEATURE([COMDAT group support (GNU as, %type)],
2617    gcc_cv_as_comdat_group_percent,
2618    [elf,2,16,0], [--fatal-warnings],
2619    [.section .text,"axG",%progbits,.foo,comdat])
2620  if test $gcc_cv_as_comdat_group_percent = yes; then
2621    gcc_cv_as_comdat_group_group=no
2622  else
2623    case "${target}" in
2624      # Sun as uses a completely different syntax.
2625      *-*-solaris2*)
2626        case "${target}" in
2627          sparc*-*-solaris2*)
2628            conftest_s='
2629                .group foo,".text%foo",#comdat
2630                .section ".text%foo", #alloc,#execinstr,#progbits
2631                .globl foo
2632              foo:
2633              '
2634            ;;
2635          i?86-*-solaris2*)
2636            conftest_s='
2637                .group foo,.text%foo,#comdat
2638                .section .text%foo, "ax", @progbits
2639                .globl  foo
2640              foo:
2641              '
2642            ;;
2643        esac
2644        gcc_GAS_CHECK_FEATURE([COMDAT group support (Sun as, .group)],
2645          gcc_cv_as_comdat_group_group,
2646          ,, [$conftest_s])
2647        ;;
2648    esac
2649  fi
2650 fi
2651 if test x"$ld_is_gold" = xyes; then
2652   comdat_group=yes
2653 elif test $in_tree_ld = yes ; then
2654   comdat_group=no
2655   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
2656      && test $in_tree_ld_is_elf = yes; then
2657      comdat_group=yes
2658   fi
2659 elif echo "$ld_ver" | grep GNU > /dev/null; then
2660   comdat_group=yes
2661   if test 0"$ld_date" -lt 20050308; then
2662     if test -n "$ld_date"; then
2663       # If there was date string, but was earlier than 2005-03-08, fail
2664       comdat_group=no
2665     elif test "$ld_vers_major" -lt 2; then
2666       comdat_group=no
2667     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2668       comdat_group=no
2669     fi
2670   fi
2671 else
2672 changequote(,)dnl
2673   case "${target}" in
2674     *-*-solaris2.1[1-9]*)
2675       comdat_group=no
2676       # Sun ld has COMDAT group support since Solaris 9, but it doesn't
2677       # interoperate with GNU as until Solaris 11 build 130, i.e. ld
2678       # version 1.688.
2679       #
2680       # If using Sun as for COMDAT group as emitted by GCC, one needs at
2681       # least ld version 1.2267.
2682       if test "$ld_vers_major" -gt 1; then
2683         comdat_group=yes
2684       elif test "x$gas_flag" = xyes && test "$ld_vers_minor" -ge 1688; then
2685         comdat_group=yes
2686       elif test "$ld_vers_minor" -ge 2267; then
2687         comdat_group=yes
2688       fi
2689       ;;
2690     *)
2691       # Assume linkers other than GNU ld don't support COMDAT group.
2692       comdat_group=no
2693       ;;
2694   esac
2695 changequote([,])dnl
2696 fi
2697 # Allow overriding the automatic COMDAT group tests above.
2698 AC_ARG_ENABLE(comdat,
2699   [AS_HELP_STRING([--enable-comdat], [enable COMDAT group support])],
2700   [comdat_group="$enable_comdat"])
2701 if test $comdat_group = no; then
2702   gcc_cv_as_comdat_group=no
2703   gcc_cv_as_comdat_group_percent=no
2704   gcc_cv_as_comdat_group_group=no
2705 fi
2706 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2707   [`if test $gcc_cv_as_comdat_group = yes \
2708     || test $gcc_cv_as_comdat_group_percent = yes \
2709     || test $gcc_cv_as_comdat_group_group = yes; then echo 1; else echo 0; fi`],
2710 [Define 0/1 if your assembler and linker support COMDAT groups.])
2711
2712 gcc_GAS_CHECK_FEATURE([line table discriminator support],
2713  gcc_cv_as_discriminator,
2714  [2,19,51],,
2715 [       .text
2716         .file 1 "conf.c"
2717         .loc 1 1 0 discriminator 1],,
2718 [AC_DEFINE(HAVE_GAS_DISCRIMINATOR, 1,
2719   [Define if your assembler supports the .loc discriminator sub-directive.])])
2720
2721 # Thread-local storage - the check is heavily parameterized.
2722 conftest_s=
2723 tls_first_major=
2724 tls_first_minor=
2725 tls_as_opt=
2726 case "$target" in
2727 changequote(,)dnl
2728   alpha*-*-*)
2729     conftest_s='
2730         .section ".tdata","awT",@progbits
2731 foo:    .long   25
2732         .text
2733         ldq     $27,__tls_get_addr($29)         !literal!1
2734         lda     $16,foo($29)                    !tlsgd!1
2735         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2736         ldq     $27,__tls_get_addr($29)         !literal!2
2737         lda     $16,foo($29)                    !tlsldm!2
2738         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2739         ldq     $1,foo($29)                     !gotdtprel
2740         ldah    $2,foo($29)                     !dtprelhi
2741         lda     $3,foo($2)                      !dtprello
2742         lda     $4,foo($29)                     !dtprel
2743         ldq     $1,foo($29)                     !gottprel
2744         ldah    $2,foo($29)                     !tprelhi
2745         lda     $3,foo($2)                      !tprello
2746         lda     $4,foo($29)                     !tprel'
2747         tls_first_major=2
2748         tls_first_minor=13
2749         tls_as_opt=--fatal-warnings
2750         ;;
2751   cris-*-*|crisv32-*-*)
2752     conftest_s='
2753         .section ".tdata","awT",@progbits
2754 x:      .long   25
2755         .text
2756         move.d x:IE,$r10
2757         nop'
2758         tls_first_major=2
2759         tls_first_minor=20
2760         tls_as_opt=--fatal-warnings
2761         ;;
2762   frv*-*-*)
2763     conftest_s='
2764         .section ".tdata","awT",@progbits
2765 x:      .long   25
2766         .text
2767         call    #gettlsoff(x)'
2768         tls_first_major=2
2769         tls_first_minor=14
2770         ;;
2771   hppa*-*-linux*)
2772     conftest_s='
2773 t1:     .reg    %r20
2774 t2:     .reg    %r21
2775 gp:     .reg    %r19
2776         .section ".tdata","awT",@progbits
2777 foo:    .long   25
2778         .text
2779         .align  4
2780         addil LT%foo-$tls_gdidx$,gp
2781         ldo RT%foo-$tls_gdidx$(%r1),%arg0
2782         b __tls_get_addr
2783         nop             
2784         addil LT%foo-$tls_ldidx$,gp
2785         b __tls_get_addr
2786         ldo RT%foo-$tls_ldidx$(%r1),%arg0
2787         addil LR%foo-$tls_dtpoff$,%ret0
2788         ldo RR%foo-$tls_dtpoff$(%r1),%t1
2789         mfctl %cr27,%t1                 
2790         addil LT%foo-$tls_ieoff$,gp
2791         ldw RT%foo-$tls_ieoff$(%r1),%t2
2792         add %t1,%t2,%t3                 
2793         mfctl %cr27,%t1                 
2794         addil LR%foo-$tls_leoff$,%t1
2795         ldo RR%foo-$tls_leoff$(%r1),%t2'
2796         tls_first_major=2
2797         tls_first_minor=15
2798         tls_as_opt=--fatal-warnings
2799         ;;
2800   arm*-*-*)
2801     conftest_s='
2802         .section ".tdata","awT",%progbits
2803 foo:    .long   25
2804         .text
2805 .word foo(gottpoff)
2806 .word foo(tpoff)
2807 .word foo(tlsgd)
2808 .word foo(tlsldm)
2809 .word foo(tlsldo)'
2810         tls_first_major=2
2811         tls_first_minor=17
2812         ;;
2813   i[34567]86-*-*)
2814     case "$target" in
2815       i[34567]86-*-solaris2.*)
2816         on_solaris=yes
2817         tga_func=___tls_get_addr
2818         ;;
2819       *)
2820         on_solaris=no
2821         ;;
2822     esac
2823     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2824       conftest_s='
2825         .section .tdata,"awt",@progbits'
2826       tls_first_major=0
2827       tls_first_minor=0
2828 changequote([,])dnl
2829       AC_DEFINE(TLS_SECTION_ASM_FLAG, 't',
2830 [Define to the flag used to mark TLS sections if the default (`T') doesn't work.])
2831 changequote(,)dnl
2832     else
2833       conftest_s='
2834         .section ".tdata","awT",@progbits'
2835       tls_first_major=2
2836       tls_first_minor=14
2837       tls_as_opt="--fatal-warnings"
2838     fi
2839     conftest_s="$conftest_s
2840 foo:    .long   25
2841         .text
2842         movl    %gs:0, %eax
2843         leal    foo@tlsgd(,%ebx,1), %eax
2844         leal    foo@tlsldm(%ebx), %eax
2845         leal    foo@dtpoff(%eax), %edx
2846         movl    foo@gottpoff(%ebx), %eax
2847         subl    foo@gottpoff(%ebx), %eax
2848         addl    foo@gotntpoff(%ebx), %eax
2849         movl    foo@indntpoff, %eax
2850         movl    \$foo@tpoff, %eax
2851         subl    \$foo@tpoff, %eax
2852         leal    foo@ntpoff(%ecx), %eax"
2853     ;;
2854   x86_64-*-*)
2855     conftest_s='
2856         .section ".tdata","awT",@progbits
2857 foo:    .long   25
2858         .text
2859         movq    %fs:0, %rax
2860         leaq    foo@TLSGD(%rip), %rdi
2861         leaq    foo@TLSLD(%rip), %rdi
2862         leaq    foo@DTPOFF(%rax), %rdx
2863         movq    foo@GOTTPOFF(%rip), %rax
2864         movq    $foo@TPOFF, %rax'
2865         tls_first_major=2
2866         tls_first_minor=14
2867         tls_as_opt=--fatal-warnings
2868         ;;
2869   ia64-*-*)
2870     conftest_s='
2871         .section ".tdata","awT",@progbits
2872 foo:    data8   25
2873         .text
2874         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2875         addl    r17 = @ltoff(@dtprel(foo#)), gp
2876         addl    r18 = @ltoff(@tprel(foo#)), gp
2877         addl    r19 = @dtprel(foo#), gp
2878         adds    r21 = @dtprel(foo#), r13
2879         movl    r23 = @dtprel(foo#)
2880         addl    r20 = @tprel(foo#), gp
2881         adds    r22 = @tprel(foo#), r13
2882         movl    r24 = @tprel(foo#)'
2883         tls_first_major=2
2884         tls_first_minor=13
2885         tls_as_opt=--fatal-warnings
2886         ;;
2887   mips*-*-*)
2888     conftest_s='
2889         .section .tdata,"awT",@progbits
2890 x:
2891         .word 2
2892         .text
2893         addiu $4, $28, %tlsgd(x)
2894         addiu $4, $28, %tlsldm(x)
2895         lui $4, %dtprel_hi(x)
2896         addiu $4, $4, %dtprel_lo(x)
2897         lw $4, %gottprel(x)($28)
2898         lui $4, %tprel_hi(x)
2899         addiu $4, $4, %tprel_lo(x)'
2900         tls_first_major=2
2901         tls_first_minor=16
2902         tls_as_opt='-32 --fatal-warnings'
2903         ;;
2904   m68k-*-*)
2905     conftest_s='
2906         .section .tdata,"awT",@progbits
2907 x:
2908         .word 2
2909         .text
2910 foo:
2911         move.l x@TLSGD(%a5),%a0
2912         move.l x@TLSLDM(%a5),%a0
2913         move.l x@TLSLDO(%a5),%a0
2914         move.l x@TLSIE(%a5),%a0
2915         move.l x@TLSLE(%a5),%a0'
2916         tls_first_major=2
2917         tls_first_minor=19
2918         tls_as_opt='--fatal-warnings'
2919         ;;
2920   powerpc-*-*)
2921     conftest_s='
2922         .section ".tdata","awT",@progbits
2923         .align 2
2924 ld0:    .space 4
2925 ld1:    .space 4
2926 x1:     .space 4
2927 x2:     .space 4
2928 x3:     .space 4
2929         .text
2930         addi 3,31,ld0@got@tlsgd
2931         bl __tls_get_addr
2932         addi 3,31,x1@got@tlsld
2933         bl __tls_get_addr
2934         addi 9,3,x1@dtprel
2935         addis 9,3,x2@dtprel@ha
2936         addi 9,9,x2@dtprel@l
2937         lwz 9,x3@got@tprel(31)
2938         add 9,9,x@tls
2939         addi 9,2,x1@tprel
2940         addis 9,2,x2@tprel@ha
2941         addi 9,9,x2@tprel@l'
2942         tls_first_major=2
2943         tls_first_minor=14
2944         tls_as_opt="-a32 --fatal-warnings"
2945         ;;
2946   powerpc64-*-*)
2947     conftest_s='
2948         .section ".tdata","awT",@progbits
2949         .align 3
2950 ld0:    .space 8
2951 ld1:    .space 8
2952 x1:     .space 8
2953 x2:     .space 8
2954 x3:     .space 8
2955         .text
2956         addi 3,2,ld0@got@tlsgd
2957         bl .__tls_get_addr
2958         nop
2959         addi 3,2,ld1@toc
2960         bl .__tls_get_addr
2961         nop
2962         addi 3,2,x1@got@tlsld
2963         bl .__tls_get_addr
2964         nop
2965         addi 9,3,x1@dtprel
2966         bl .__tls_get_addr
2967         nop
2968         addis 9,3,x2@dtprel@ha
2969         addi 9,9,x2@dtprel@l
2970         bl .__tls_get_addr
2971         nop
2972         ld 9,x3@got@dtprel(2)
2973         add 9,9,3
2974         bl .__tls_get_addr
2975         nop'
2976         tls_first_major=2
2977         tls_first_minor=14
2978         tls_as_opt="-a64 --fatal-warnings"
2979         ;;
2980   s390-*-*)
2981     conftest_s='
2982         .section ".tdata","awT",@progbits
2983 foo:    .long   25
2984         .text
2985         .long   foo@TLSGD
2986         .long   foo@TLSLDM
2987         .long   foo@DTPOFF
2988         .long   foo@NTPOFF
2989         .long   foo@GOTNTPOFF
2990         .long   foo@INDNTPOFF
2991         l       %r1,foo@GOTNTPOFF(%r12)
2992         l       %r1,0(%r1):tls_load:foo
2993         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2994         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2995         tls_first_major=2
2996         tls_first_minor=14
2997         tls_as_opt="-m31 --fatal-warnings"
2998         ;;
2999   s390x-*-*)
3000     conftest_s='
3001         .section ".tdata","awT",@progbits
3002 foo:    .long   25
3003         .text
3004         .quad   foo@TLSGD
3005         .quad   foo@TLSLDM
3006         .quad   foo@DTPOFF
3007         .quad   foo@NTPOFF
3008         .quad   foo@GOTNTPOFF
3009         lg      %r1,foo@GOTNTPOFF(%r12)
3010         larl    %r1,foo@INDNTPOFF
3011         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
3012         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
3013         tls_first_major=2
3014         tls_first_minor=14
3015         tls_as_opt="-m64 -Aesame --fatal-warnings"
3016         ;;
3017   sh-*-* | sh[34]-*-*)
3018     conftest_s='
3019         .section ".tdata","awT",@progbits
3020 foo:    .long   25
3021         .text
3022         .long   foo@TLSGD
3023         .long   foo@TLSLDM
3024         .long   foo@DTPOFF
3025         .long   foo@GOTTPOFF
3026         .long   foo@TPOFF'
3027         tls_first_major=2
3028         tls_first_minor=13
3029         tls_as_opt=--fatal-warnings
3030         ;;
3031   sparc*-*-*)
3032     case "$target" in
3033       sparc*-sun-solaris2.*)
3034         on_solaris=yes
3035         tga_func=__tls_get_addr
3036         ;;
3037       *)
3038         on_solaris=no
3039         ;;
3040     esac
3041     if test x$on_solaris = xyes && test x$gas_flag = xno; then
3042       conftest_s='
3043         .section ".tdata",#alloc,#write,#tls'
3044         tls_first_major=0
3045         tls_first_minor=0
3046     else
3047       conftest_s='
3048         .section ".tdata","awT",@progbits'
3049         tls_first_major=2
3050         tls_first_minor=14
3051         tls_as_opt="-32 --fatal-warnings"
3052     fi
3053     conftest_s="$conftest_s
3054 foo:    .long   25
3055         .text
3056         sethi   %tgd_hi22(foo), %o0
3057         add     %o0, %tgd_lo10(foo), %o1
3058         add     %l7, %o1, %o0, %tgd_add(foo)
3059         call    __tls_get_addr, %tgd_call(foo)
3060         sethi   %tldm_hi22(foo), %l1
3061         add     %l1, %tldm_lo10(foo), %l2
3062         add     %l7, %l2, %o0, %tldm_add(foo)
3063         call    __tls_get_addr, %tldm_call(foo)
3064         sethi   %tldo_hix22(foo), %l3
3065         xor     %l3, %tldo_lox10(foo), %l4
3066         add     %o0, %l4, %l5, %tldo_add(foo)
3067         sethi   %tie_hi22(foo), %o3
3068         add     %o3, %tie_lo10(foo), %o3
3069         ld      [%l7 + %o3], %o2, %tie_ld(foo)
3070         add     %g7, %o2, %o4, %tie_add(foo)
3071         sethi   %tle_hix22(foo), %l1
3072         xor     %l1, %tle_lox10(foo), %o5
3073         ld      [%g7 + %o5], %o1"
3074         ;;
3075   xtensa*-*-*)
3076     conftest_s='
3077         .section ".tdata","awT",@progbits
3078 foo:    .long   25
3079         .text
3080         movi    a8, foo@TLSFUNC
3081         movi    a10, foo@TLSARG
3082         callx8.tls a8, foo@TLSCALL'
3083         tls_first_major=2
3084         tls_first_minor=19
3085         ;;
3086 changequote([,])dnl
3087 esac
3088 set_have_as_tls=no
3089 if test "x$enable_tls" = xno ; then
3090   : # TLS explicitly disabled.
3091 elif test "x$enable_tls" = xyes ; then
3092   set_have_as_tls=yes # TLS explicitly enabled.
3093 elif test -z "$tls_first_major"; then
3094   : # If we don't have a check, assume no support.
3095 else
3096   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
3097   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
3098   [set_have_as_tls=yes])
3099 fi
3100 case "$target" in
3101   *-*-irix6*)
3102     # IRIX 6.5 rld and libc.so lack TLS support, so even if gas and gld
3103     # with TLS support are in use, native TLS cannot work.
3104     set_have_as_tls=no
3105     ;;
3106   *-*-osf*)
3107     # Tru64 UNIX loader and libc.so lack TLS support, so even if gas and
3108     # gld with TLS support are in use, native TLS cannot work.
3109     set_have_as_tls=no
3110     ;;
3111   # TLS was introduced in the Solaris 9 FCS release and backported to
3112   # Solaris 8 patches.  Support for GNU-style TLS on x86 was only
3113   # introduced in Solaris 9 4/04, replacing the earlier Sun style that Sun
3114   # ld and GCC don't support any longer.
3115   *-*-solaris2.*)
3116     AC_MSG_CHECKING(linker and ld.so.1 TLS support)
3117     ld_tls_support=no
3118     # Check ld and ld.so.1 TLS support.
3119     if echo "$ld_ver" | grep GNU > /dev/null; then
3120       # Assume all interesting versions of GNU ld have TLS support.
3121       # FIXME: still need ld.so.1 support, i.e. ld version checks below.
3122       ld_tls_support=yes
3123     else
3124       case "$target" in
3125         # Solaris 8/x86 ld has GNU style TLS support since version 1.280.
3126         i?86-*-solaris2.8)
3127           min_tls_ld_vers_minor=280
3128           ;;
3129         # Solaris 8/SPARC ld has TLS support since version 1.272.
3130         sparc*-*-solaris2.8)
3131           min_tls_ld_vers_minor=272
3132           ;;
3133         # Solaris 9/x86 ld has GNU style TLS support since version 1.374.
3134         i?86-*-solaris2.9)
3135           min_tls_ld_vers_minor=374
3136           ;;
3137         # Solaris 9/SPARC and Solaris 10+ ld have TLS support since FCS.
3138         sparc*-*-solaris2.9 | *-*-solaris2.1[[0-9]]*)
3139           min_tls_ld_vers_minor=343
3140           ;;
3141       esac
3142       if test "$ld_vers_major" -gt 1 || \
3143         test "$ld_vers_minor" -ge "$min_tls_ld_vers_minor"; then
3144         ld_tls_support=yes
3145       else
3146         set_have_as_tls=no
3147       fi
3148     fi
3149     AC_MSG_RESULT($ld_tls_support)
3150
3151     save_LIBS="$LIBS"
3152     save_LDFLAGS="$LDFLAGS"
3153     LIBS=
3154     LDFLAGS=
3155
3156     AC_MSG_CHECKING(alternate thread library)
3157     case "$target" in
3158       # TLS support was backported to Solaris 8 patches, but only lives in
3159       # the alternate thread library which became the default in Solaris 9. 
3160       # We want to always use that, irrespective of TLS support.
3161       *-*-solaris2.8)
3162         # Take multilib subdir into account.  There's no spec to handle
3163         # this.  The 64 symlink exists since Solaris 8.
3164         lwp_dir=/usr/lib/lwp
3165         lwp_spec="-L$lwp_dir%{m64:/64} -R$lwp_dir%{m64:/64}"
3166         LDFLAGS="-L$lwp_dir -R$lwp_dir"
3167         ;;
3168       *-*-solaris2*)
3169         lwp_dir="none"
3170         lwp_spec=""
3171         ;;
3172     esac    
3173     # Always define LIB_THREAD_LDFLAGS_SPEC, even without TLS support.
3174     AC_DEFINE_UNQUOTED(LIB_THREAD_LDFLAGS_SPEC, "$lwp_spec",
3175         [Define to the linker flags to use for -pthread.])
3176     AC_MSG_RESULT($lwp_dir)
3177
3178     AC_MSG_CHECKING(library containing $tga_func)
3179     # Before Solaris 10, __tls_get_addr (SPARC/x64) resp. ___tls_get_addr
3180     # (32-bit x86) only lived in libthread, so check for that.  Keep
3181     # set_have_as_tls if found, disable if not.
3182     AC_SEARCH_LIBS([$tga_func], [thread],, [set_have_as_tls=no])
3183     # Clear LIBS if we cannot support TLS.
3184     if test $set_have_as_tls = no; then
3185       LIBS=
3186     fi
3187     # Always define LIB_TLS_SPEC, even without TLS support.
3188     AC_DEFINE_UNQUOTED(LIB_TLS_SPEC, "$LIBS",
3189         [Define to the library containing __tls_get_addr/___tls_get_addr.])
3190     AC_MSG_RESULT($LIBS)
3191
3192     LIBS="$save_LIBS"
3193     LDFLAGS="$save_LDFLAGS"
3194     ;;
3195 esac
3196 if test $set_have_as_tls = yes ; then
3197   AC_DEFINE(HAVE_AS_TLS, 1,
3198             [Define if your assembler and linker support thread-local storage.])
3199 fi
3200
3201 # Target-specific assembler checks.
3202
3203 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
3204 gcc_cv_ld_static_dynamic=no
3205 gcc_cv_ld_static_option='-Bstatic'
3206 gcc_cv_ld_dynamic_option='-Bdynamic'
3207 if test $in_tree_ld = yes ; then
3208   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2; then
3209     gcc_cv_ld_static_dynamic=yes
3210   fi
3211 elif test x$gcc_cv_ld != x; then
3212   # Check if linker supports -Bstatic/-Bdynamic option
3213   if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
3214      && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
3215       gcc_cv_ld_static_dynamic=yes
3216   else
3217     case "$target" in
3218       # Tru64 UNIX support -noso/-so_archive instead of -Bstatic/-Bdynamic.
3219       alpha*-dec-osf*)
3220         gcc_cv_ld_static_dynamic=yes
3221         gcc_cv_ld_static_option="-noso"
3222         gcc_cv_ld_dynamic_option="-so_archive"
3223         ;;
3224       # IRIX 6 ld supports -Bstatic/-Bdynamic.
3225       mips-sgi-irix6*)
3226         gcc_cv_ld_static_dynamic=yes
3227         ;;
3228       # Solaris 2 ld always supports -Bstatic/-Bdynamic.
3229       *-*-solaris2*)
3230         gcc_cv_ld_static_dynamic=yes
3231         ;;
3232     esac
3233   fi
3234 fi
3235 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
3236         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
3237 [Define if your linker supports -Bstatic/-Bdynamic or equivalent options.])
3238         AC_DEFINE_UNQUOTED(LD_STATIC_OPTION, "$gcc_cv_ld_static_option",
3239 [Define to the linker option to disable use of shared objects.])
3240         AC_DEFINE_UNQUOTED(LD_DYNAMIC_OPTION, "$gcc_cv_ld_dynamic_option",
3241 [Define to the linker option to enable use of shared objects.])
3242 fi
3243 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
3244
3245 if test x"$demangler_in_ld" = xyes; then
3246   AC_MSG_CHECKING(linker --demangle support)
3247   gcc_cv_ld_demangle=no
3248   if test $in_tree_ld = yes; then
3249     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
3250       gcc_cv_ld_demangle=yes
3251     fi
3252   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
3253     # Check if the GNU linker supports --demangle option
3254     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
3255       gcc_cv_ld_demangle=yes
3256     fi
3257   fi
3258   if test x"$gcc_cv_ld_demangle" = xyes; then
3259     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
3260 [Define if your linker supports --demangle option.])
3261   fi
3262   AC_MSG_RESULT($gcc_cv_ld_demangle)
3263 fi
3264
3265 AC_MSG_CHECKING(linker plugin support)
3266 gcc_cv_lto_plugin=0
3267 if test -f liblto_plugin.la; then
3268   save_ld_ver="$ld_ver"
3269   save_ld_vers_major="$ld_vers_major"
3270   save_ld_vers_minor="$ld_vers_minor"
3271   save_ld_is_gold="$ld_is_gold"
3272
3273   ld_is_gold=no
3274
3275   if test $in_tree_ld = yes -a x"$ORIGINAL_PLUGIN_LD_FOR_TARGET" = x"$gcc_cv_ld"; then
3276     ld_ver="GNU ld"
3277     # FIXME: ld_is_gold?
3278     ld_vers_major="$gcc_cv_gld_major_version"
3279     ld_vers_minor="$gcc_cv_gld_minor_version"
3280   else
3281     # Determine plugin linker version.
3282     # FIXME: Partial duplicate from above, generalize.
3283 changequote(,)dnl
3284     ld_ver=`$ORIGINAL_PLUGIN_LD_FOR_TARGET --version 2>/dev/null | sed 1q`
3285     if echo "$ld_ver" | grep GNU > /dev/null; then
3286       if echo "$ld_ver" | grep "GNU gold" > /dev/null; then
3287         ld_is_gold=yes
3288         ld_vers=`echo $ld_ver | sed -n \
3289             -e 's,^[^)]*[        ]\([0-9][0-9]*\.[0-9][0-9]*[^)]*\)) .*$,\1,p'`
3290       else
3291         ld_vers=`echo $ld_ver | sed -n \
3292             -e 's,^.*[   ]\([0-9][0-9]*\.[0-9][0-9]*.*\)$,\1,p'`
3293       fi
3294       ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
3295       ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
3296     fi
3297 changequote([,])dnl
3298   fi
3299
3300   # Determine plugin support.
3301   if echo "$ld_ver" | grep GNU > /dev/null; then
3302     # Require GNU ld or gold 2.21+ for plugin support by default.
3303     if test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -ge 21; then
3304       gcc_cv_lto_plugin=2
3305     # Allow -fuse-linker-plugin to enable plugin support in GNU gold 2.20.
3306     elif test "$ld_is_gold" = yes -a "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 20; then
3307       gcc_cv_lto_plugin=1
3308     fi
3309   fi
3310
3311   ld_ver="$save_ld_ver"
3312   ld_vers_major="$save_ld_vers_major"
3313   ld_vers_minor="$save_ld_vers_minor"
3314   ld_is_gold="$save_ld_is_gold"
3315 fi
3316 AC_DEFINE_UNQUOTED(HAVE_LTO_PLUGIN, $gcc_cv_lto_plugin,
3317   [Define to the level of your linker's plugin support.])
3318 AC_MSG_RESULT($gcc_cv_lto_plugin)
3319
3320 case "$target" in
3321   # All TARGET_ABI_OSF targets.
3322   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
3323     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3324         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
3325 [       .set nomacro
3326         .text
3327         extbl   $3, $2, $3      !lituse_bytoff!1
3328         ldq     $2, a($29)      !literal!1
3329         ldq     $4, b($29)      !literal!2
3330         ldq_u   $3, 0($2)       !lituse_base!1
3331         ldq     $27, f($29)     !literal!5
3332         jsr     $26, ($27), f   !lituse_jsr!5
3333         ldah    $29, 0($26)     !gpdisp!3
3334         lda     $0, c($29)      !gprel
3335         ldah    $1, d($29)      !gprelhigh
3336         lda     $1, d($1)       !gprellow
3337         lda     $29, 0($29)     !gpdisp!3],,
3338     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
3339   [Define if your assembler supports explicit relocations.])])
3340     gcc_GAS_CHECK_FEATURE([jsrdirect relocation support],
3341         gcc_cv_as_alpha_jsrdirect_relocs, [2,16,90],,
3342 [       .set nomacro
3343         .text
3344         ldq     $27, a($29)     !literal!1
3345         jsr     $26, ($27), a   !lituse_jsrdirect!1],,
3346     [AC_DEFINE(HAVE_AS_JSRDIRECT_RELOCS, 1,
3347   [Define if your assembler supports the lituse_jsrdirect relocation.])])
3348     ;;
3349
3350   cris-*-*)
3351     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
3352       gcc_cv_as_cris_no_mul_bug,[2,15,91],
3353       [-no-mul-bug-abort], [.text],,
3354       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
3355                 [Define if your assembler supports the -no-mul-bug-abort option.])])
3356     ;;
3357
3358   sparc*-*-*)
3359     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
3360       [.register %g2, #scratch],,
3361       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
3362                 [Define if your assembler supports .register.])])
3363
3364     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
3365       [-relax], [.text],,
3366       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
3367                 [Define if your assembler supports -relax option.])])
3368
3369     gcc_GAS_CHECK_FEATURE([GOTDATA_OP relocs],
3370       gcc_cv_as_sparc_gotdata_op,,
3371       [-K PIC],
3372 [.text
3373 .align 4
3374 foo:
3375         nop
3376 bar:
3377         sethi %gdop_hix22(foo), %g1
3378         xor    %g1, %gdop_lox10(foo), %g1
3379         ld    [[%l7 + %g1]], %g2, %gdop(foo)],
3380       [if test x$gcc_cv_ld != x \
3381        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3382          if test x$gcc_cv_objdump != x; then
3383            if $gcc_cv_objdump -s -j .text conftest 2> /dev/null \
3384               | grep ' 03000004 82186004 c405c001'> /dev/null 2>&1; then
3385                gcc_cv_as_sparc_gotdata_op=no
3386            else
3387                gcc_cv_as_sparc_gotdata_op=yes
3388            fi
3389          fi
3390        fi
3391        rm -f conftest],
3392       [AC_DEFINE(HAVE_AS_SPARC_GOTDATA_OP, 1,
3393                 [Define if your assembler and linker support GOTDATA_OP relocs.])])
3394
3395     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
3396       gcc_cv_as_sparc_ua_pcrel,,
3397       [-K PIC],
3398 [.text
3399 foo:
3400         nop
3401 .data
3402 .align 4
3403 .byte 0
3404 .uaword %r_disp32(foo)],
3405       [if test x$gcc_cv_ld != x \
3406        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
3407          gcc_cv_as_sparc_ua_pcrel=yes
3408        fi
3409        rm -f conftest],
3410       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
3411                 [Define if your assembler and linker support unaligned PC relative relocs.])
3412
3413       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
3414         gcc_cv_as_sparc_ua_pcrel_hidden,,
3415         [-K PIC],
3416 [.data
3417 .align 4
3418 .byte 0x31
3419 .uaword %r_disp32(foo)
3420 .byte 0x32, 0x33, 0x34
3421 .global foo
3422 .hidden foo
3423 foo:
3424 .skip 4],
3425         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
3426          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
3427          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
3428             | grep ' 31000000 07323334' > /dev/null 2>&1; then
3429             if $gcc_cv_objdump -R conftest 2> /dev/null \
3430                | grep 'DISP32' > /dev/null 2>&1; then
3431                 :
3432             else
3433                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
3434             fi
3435          fi
3436          rm -f conftest],
3437          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
3438                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
3439     ]) # unaligned pcrel relocs
3440
3441     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
3442       gcc_cv_as_sparc_offsetable_lo10,,
3443       [-xarch=v9],
3444 [.text
3445         or %g1, %lo(ab) + 12, %g1
3446         or %g1, %lo(ab + 12), %g1],
3447       [if test x$gcc_cv_objdump != x \
3448        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
3449           | grep ' 82106000 82106000' > /dev/null 2>&1; then
3450          gcc_cv_as_sparc_offsetable_lo10=yes
3451        fi],
3452        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
3453                  [Define if your assembler supports offsetable %lo().])])
3454     ;;
3455
3456 changequote(,)dnl
3457   i[34567]86-*-* | x86_64-*-*)
3458 changequote([,])dnl
3459     case $target_os in
3460       cygwin*)
3461         # Full C++ conformance when using a shared libstdc++-v3 requires some
3462         # support from the Cygwin DLL, which in more recent versions exports
3463         # wrappers to aid in interposing and redirecting operators new, delete,
3464         # etc., as per n2800 #17.6.4.6 [replacement.functions].  Check if we
3465         # are configuring for a version of Cygwin that exports the wrappers.
3466         if test x$host = x$target; then
3467           AC_CHECK_FUNC([__wrap__Znaj],[gcc_ac_cygwin_dll_wrappers=yes],[gcc_ac_cygwin_dll_wrappers=no])
3468         else
3469           # Can't check presence of libc functions during cross-compile, so
3470           # we just have to assume we're building for an up-to-date target.
3471           gcc_ac_cygwin_dll_wrappers=yes
3472         fi
3473         AC_DEFINE_UNQUOTED(USE_CYGWIN_LIBSTDCXX_WRAPPERS,
3474           [`if test $gcc_ac_cygwin_dll_wrappers = yes; then echo 1; else echo 0; fi`],
3475           [Define if you want to generate code by default that assumes that the
3476            Cygwin DLL exports wrappers to support libstdc++ function replacement.])
3477     esac
3478     case $target_os in
3479       cygwin* | pe | mingw32*)
3480         # Recent binutils allows the three-operand form of ".comm" on PE.  This
3481         # definition is used unconditionally to initialise the default state of
3482         # the target option variable that governs usage of the feature.
3483         gcc_GAS_CHECK_FEATURE([.comm with alignment], gcc_cv_as_comm_has_align,
3484          [2,19,52],,[.comm foo,1,32])
3485         AC_DEFINE_UNQUOTED(HAVE_GAS_ALIGNED_COMM,
3486           [`if test $gcc_cv_as_comm_has_align = yes; then echo 1; else echo 0; fi`],
3487           [Define if your assembler supports specifying the alignment
3488            of objects allocated using the GAS .comm command.])
3489         # Used for DWARF 2 in PE
3490         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
3491           gcc_cv_as_ix86_pe_secrel32,
3492           [2,15,91],,
3493 [.text
3494 foo:    nop
3495 .data
3496         .secrel32 foo],
3497           [if test x$gcc_cv_ld != x \
3498            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
3499              gcc_cv_as_ix86_pe_secrel32=yes
3500            fi
3501            rm -f conftest],
3502           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
3503             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
3504         # Test if the assembler supports the extended form of the .section
3505         # directive that specifies section alignment.  LTO support uses this,
3506         # but normally only after installation, so we warn but don't fail the
3507         # configure if LTO is enabled but the assembler does not support it.
3508         gcc_GAS_CHECK_FEATURE([.section with alignment], gcc_cv_as_section_has_align,
3509           [2,20,1],-fatal-warnings,[.section lto_test,"dr0"])
3510         if test x$gcc_cv_as_section_has_align != xyes; then
3511           case ",$enable_languages," in
3512             *,lto,*)
3513               AC_MSG_WARN([LTO for $target requires binutils >= 2.20.1, but version found appears insufficient; LTO will not work until binutils is upgraded.])
3514               ;;
3515           esac
3516         fi
3517         ;;
3518     esac
3519
3520     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
3521        gcc_cv_as_ix86_filds,,,
3522        [filds mem; fists mem],,
3523        [AC_DEFINE(HAVE_AS_IX86_FILDS, 1,
3524          [Define if your assembler uses filds and fists mnemonics.])])
3525
3526     gcc_GAS_CHECK_FEATURE([fildq and fistpq mnemonics],
3527        gcc_cv_as_ix86_fildq,,,
3528        [fildq mem; fistpq mem],,
3529        [AC_DEFINE(HAVE_AS_IX86_FILDQ, 1,
3530          [Define if your assembler uses fildq and fistq mnemonics.])])
3531
3532     gcc_GAS_CHECK_FEATURE([cmov syntax],
3533       gcc_cv_as_ix86_cmov_sun_syntax,,,
3534       [cmovl.l %edx, %eax],,
3535       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
3536         [Define if your assembler supports the Sun syntax for cmov.])])
3537
3538     gcc_GAS_CHECK_FEATURE([ffreep mnemonic],
3539       gcc_cv_as_ix86_ffreep,,,
3540       [ffreep %st(1)],,
3541       [AC_DEFINE(HAVE_AS_IX86_FFREEP, 1,
3542         [Define if your assembler supports the ffreep mnemonic.])])
3543
3544     gcc_GAS_CHECK_FEATURE([.quad directive],
3545       gcc_cv_as_ix86_quad,,,
3546       [.quad 0],,
3547       [AC_DEFINE(HAVE_AS_IX86_QUAD, 1,
3548         [Define if your assembler supports the .quad directive.])])
3549
3550     gcc_GAS_CHECK_FEATURE([sahf mnemonic],
3551       gcc_cv_as_ix86_sahf,,,
3552       [.code64
3553        sahf],,
3554       [AC_DEFINE(HAVE_AS_IX86_SAHF, 1,
3555         [Define if your assembler supports the sahf mnemonic in 64bit mode.])])
3556
3557     gcc_GAS_CHECK_FEATURE([swap suffix],
3558       gcc_cv_as_ix86_swap,,,
3559       [movl.s %esp, %ebp],,
3560       [AC_DEFINE(HAVE_AS_IX86_SWAP, 1,
3561         [Define if your assembler supports the swap suffix.])])
3562
3563     gcc_GAS_CHECK_FEATURE([different section symbol subtraction],
3564       gcc_cv_as_ix86_diff_sect_delta,,,
3565       [.section .rodata
3566 .L1:
3567         .long .L2-.L1
3568         .long .L3-.L1
3569         .text
3570 .L3:    nop
3571 .L2:    nop],,
3572       [AC_DEFINE(HAVE_AS_IX86_DIFF_SECT_DELTA, 1,
3573         [Define if your assembler supports the subtraction of symbols in different sections.])])
3574
3575     # These two are used unconditionally by i386.[ch]; it is to be defined
3576     # to 1 if the feature is present, 0 otherwise.
3577     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
3578         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
3579 [       .text
3580 .L0:
3581         nop
3582         .data
3583         .long .L0@GOTOFF])
3584     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
3585       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
3586       [Define true if the assembler supports '.long foo@GOTOFF'.])
3587
3588     gcc_GAS_CHECK_FEATURE([rep and lock prefix],
3589         gcc_cv_as_ix86_rep_lock_prefix,,,
3590         [rep movsl
3591          lock addl %edi, (%eax,%esi)
3592          lock orl $0, (%esp)],,
3593         [AC_DEFINE(HAVE_AS_IX86_REP_LOCK_PREFIX, 1,
3594           [Define if the assembler supports 'rep <insn>, lock <insn>'.])])
3595
3596     gcc_GAS_CHECK_FEATURE([R_386_TLS_GD_PLT reloc],
3597         gcc_cv_as_ix86_tlsgdplt,,,
3598         [call    tls_gd@tlsgdplt],,
3599       [AC_DEFINE(HAVE_AS_IX86_TLSGDPLT, 1,
3600         [Define if your assembler supports @tlsgdplt.])])
3601
3602     gcc_GAS_CHECK_FEATURE([R_386_TLS_LDM_PLT reloc],
3603         gcc_cv_as_ix86_tlsldmplt,,,
3604         [call    tls_ld@tlsldmplt],,
3605       [AC_DEFINE(HAVE_AS_IX86_TLSLDMPLT, 1,
3606         [Define if your assembler supports @tlsldmplt.])])
3607
3608     ;;
3609
3610   ia64*-*-*)
3611     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
3612         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
3613 [       .text
3614         addl r15 = @ltoffx(x#), gp
3615         ;;
3616         ld8.mov r16 = [[r15]], x#],,
3617     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
3618           [Define if your assembler supports ltoffx and ldxmov relocations.])])
3619
3620     ;;
3621
3622   powerpc*-*-*)
3623     case $target in
3624       *-*-aix*) conftest_s='    .machine "pwr5"
3625         .csect .text[[PR]]
3626         mfcr 3,128';;
3627       *-*-darwin*)
3628         gcc_GAS_CHECK_FEATURE([.machine directive support],
3629           gcc_cv_as_machine_directive,,,
3630           [     .machine ppc7400])
3631         if test x$gcc_cv_as_machine_directive != xyes; then
3632           echo "*** This target requires an assembler supporting \".machine\"" >&2
3633           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
3634           test x$build = x$target && exit 1
3635         fi
3636         conftest_s='    .text
3637         mfcr r3,128';;
3638       *) conftest_s='   .machine power4
3639         .text
3640         mfcr 3,128';;
3641     esac
3642
3643     gcc_GAS_CHECK_FEATURE([mfcr field support],
3644       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
3645       [$conftest_s],,
3646       [AC_DEFINE(HAVE_AS_MFCRF, 1,
3647           [Define if your assembler supports mfcr field.])])
3648
3649     case $target in
3650       *-*-aix*) conftest_s='    .machine "pwr5"
3651         .csect .text[[PR]]
3652         popcntb 3,3';;
3653       *) conftest_s='   .machine power5
3654         .text
3655         popcntb 3,3';;
3656     esac
3657
3658     gcc_GAS_CHECK_FEATURE([popcntb support],
3659       gcc_cv_as_powerpc_popcntb, [2,17,0],,
3660       [$conftest_s],,
3661       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
3662           [Define if your assembler supports popcntb field.])])
3663
3664     case $target in
3665       *-*-aix*) conftest_s='    .machine "pwr5x"
3666         .csect .text[[PR]]
3667         frin 1,1';;
3668       *) conftest_s='   .machine power5
3669         .text
3670         frin 1,1';;
3671     esac
3672
3673     gcc_GAS_CHECK_FEATURE([fp round support],
3674       gcc_cv_as_powerpc_fprnd, [2,17,0],,
3675       [$conftest_s],,
3676       [AC_DEFINE(HAVE_AS_FPRND, 1,
3677           [Define if your assembler supports fprnd.])])
3678
3679     case $target in
3680       *-*-aix*) conftest_s='    .machine "pwr6"
3681         .csect .text[[PR]]
3682         mffgpr 1,3';;
3683       *) conftest_s='   .machine power6
3684         .text
3685         mffgpr 1,3';;
3686     esac
3687
3688     gcc_GAS_CHECK_FEATURE([move fp gpr support],
3689       gcc_cv_as_powerpc_mfpgpr, [2,19,2],,
3690       [$conftest_s],,
3691       [AC_DEFINE(HAVE_AS_MFPGPR, 1,
3692           [Define if your assembler supports mffgpr and mftgpr.])])
3693
3694     case $target in
3695       *-*-aix*) conftest_s='    .csect .text[[PR]]
3696 LCF..0:
3697         addis 11,30,_GLOBAL_OFFSET_TABLE_-LCF..0@ha';;
3698       *-*-darwin*)
3699         conftest_s='    .text
3700 LCF0:
3701         addis r11,r30,_GLOBAL_OFFSET_TABLE_-LCF0@ha';;
3702       *) conftest_s='   .text
3703 .LCF0:
3704         addis 11,30,_GLOBAL_OFFSET_TABLE_-.LCF0@ha';;
3705     esac
3706
3707     gcc_GAS_CHECK_FEATURE([rel16 relocs],
3708       gcc_cv_as_powerpc_rel16, [2,17,0], -a32,
3709       [$conftest_s],,
3710       [AC_DEFINE(HAVE_AS_REL16, 1,
3711           [Define if your assembler supports R_PPC_REL16 relocs.])])
3712
3713     case $target in
3714       *-*-aix*) conftest_s='    .machine "pwr6"
3715         .csect .text[[PR]]
3716         cmpb 3,4,5';;
3717       *) conftest_s='   .machine power6
3718         .text
3719         cmpb 3,4,5';;
3720     esac
3721
3722     gcc_GAS_CHECK_FEATURE([compare bytes support],
3723       gcc_cv_as_powerpc_cmpb, [2,19,2], -a32,
3724       [$conftest_s],,
3725       [AC_DEFINE(HAVE_AS_CMPB, 1,
3726           [Define if your assembler supports cmpb.])])
3727
3728     case $target in
3729       *-*-aix*) conftest_s='    .machine "pwr6"
3730         .csect .text[[PR]]
3731         dadd 1,2,3';;
3732       *) conftest_s='   .machine power6
3733         .text
3734         dadd 1,2,3';;
3735     esac
3736
3737     gcc_GAS_CHECK_FEATURE([decimal float support],
3738       gcc_cv_as_powerpc_dfp, [2,19,2], -a32,
3739       [$conftest_s],,
3740       [AC_DEFINE(HAVE_AS_DFP, 1,
3741           [Define if your assembler supports DFP instructions.])])
3742
3743     case $target in
3744       *-*-aix*) conftest_s='    .machine "pwr7"
3745         .csect .text[[PR]]
3746         lxvd2x 1,2,3';;
3747       *) conftest_s='   .machine power7
3748         .text
3749         lxvd2x 1,2,3';;
3750     esac
3751
3752     gcc_GAS_CHECK_FEATURE([vector-scalar support],
3753       gcc_cv_as_powerpc_vsx, [2,19,2], -a32,
3754       [$conftest_s],,
3755       [AC_DEFINE(HAVE_AS_VSX, 1,
3756           [Define if your assembler supports VSX instructions.])])
3757
3758     case $target in
3759       *-*-aix*) conftest_s='    .machine "pwr7"
3760         .csect .text[[PR]]
3761         popcntd 3,3';;
3762       *) conftest_s='   .machine power7
3763         .text
3764         popcntd 3,3';;
3765     esac
3766
3767     gcc_GAS_CHECK_FEATURE([popcntd support],
3768       gcc_cv_as_powerpc_popcntd, [2,19,2], -a32,
3769       [$conftest_s],,
3770       [AC_DEFINE(HAVE_AS_POPCNTD, 1,
3771           [Define if your assembler supports POPCNTD instructions.])])
3772
3773     case $target in
3774       *-*-aix*) conftest_s='    .csect .text[[PR]]
3775         lwsync';;
3776       *) conftest_s='   .text
3777         lwsync';;
3778     esac
3779
3780     gcc_GAS_CHECK_FEATURE([lwsync support],
3781       gcc_cv_as_powerpc_lwsync, [2,19,2], -a32,
3782       [$conftest_s],,
3783       [AC_DEFINE(HAVE_AS_LWSYNC, 1,
3784           [Define if your assembler supports LWSYNC instructions.])])
3785
3786     case $target in
3787       *-*-aix*) conftest_s='    .machine "476"
3788         .csect .text[[PR]]
3789         dci 0';;
3790       *) conftest_s='   .machine "476"
3791         .text
3792         dci 0';;
3793     esac
3794
3795     gcc_GAS_CHECK_FEATURE([data cache invalidate support],
3796       gcc_cv_as_powerpc_dci, [9,99,0], -a32,
3797       [$conftest_s],,
3798       [AC_DEFINE(HAVE_AS_DCI, 1,
3799           [Define if your assembler supports the DCI/ICI instructions.])])
3800
3801     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3802       gcc_cv_as_powerpc_gnu_attribute, [2,18,0],,
3803       [.gnu_attribute 4,1],,
3804       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3805           [Define if your assembler supports .gnu_attribute.])])
3806
3807     gcc_GAS_CHECK_FEATURE([tls marker support],
3808       gcc_cv_as_powerpc_tls_markers, [2,20,0],,
3809       [ bl __tls_get_addr(x@tlsgd)],,
3810       [AC_DEFINE(HAVE_AS_TLS_MARKERS, 1,
3811           [Define if your assembler supports arg info for __tls_get_addr.])])
3812
3813     case $target in
3814       *-*-aix*)
3815         gcc_GAS_CHECK_FEATURE([.ref support],
3816           gcc_cv_as_aix_ref, [2.21.0],,
3817           [     .csect stuff[[rw]]
3818              stuff:
3819                 .long 1
3820                 .extern sym
3821                 .ref sym
3822           ],,
3823           [AC_DEFINE(HAVE_AS_REF, 1,
3824             [Define if your assembler supports .ref])])
3825         ;;
3826     esac
3827     ;;
3828
3829   mips*-*-*)
3830     gcc_GAS_CHECK_FEATURE([explicit relocation support],
3831       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
3832 [       lw $4,%gp_rel(foo)($4)],,
3833       [if test x$target_cpu_default = x
3834        then target_cpu_default=MASK_EXPLICIT_RELOCS
3835        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
3836        fi])
3837     gcc_GAS_CHECK_FEATURE([-mno-shared support],
3838       gcc_cv_as_mips_no_shared, [2,16,0], [-mno-shared], [nop],,
3839       [AC_DEFINE(HAVE_AS_NO_SHARED, 1,
3840                  [Define if the assembler understands -mno-shared.])])
3841
3842     gcc_GAS_CHECK_FEATURE([.gnu_attribute support],
3843       gcc_cv_as_mips_gnu_attribute, [2,18,0],,
3844       [.gnu_attribute 4,1],,
3845       [AC_DEFINE(HAVE_AS_GNU_ATTRIBUTE, 1,
3846           [Define if your assembler supports .gnu_attribute.])])
3847
3848     gcc_GAS_CHECK_FEATURE([.dtprelword support],
3849       gcc_cv_as_mips_dtprelword, [2,18,0],,
3850       [.section .tdata,"awT",@progbits
3851 x:
3852         .word 2
3853         .text
3854         .dtprelword x+0x8000],,
3855       [AC_DEFINE(HAVE_AS_DTPRELWORD, 1,
3856           [Define if your assembler supports .dtprelword.])])
3857
3858     gcc_GAS_CHECK_FEATURE([DSPR1 mult with four accumulators support],
3859       gcc_cv_as_mips_dspr1_mult,,,
3860 [       .set    mips32r2
3861         .set    nodspr2
3862         .set    dsp
3863         madd    $ac3,$4,$5
3864         maddu   $ac3,$4,$5
3865         msub    $ac3,$4,$5
3866         msubu   $ac3,$4,$5
3867         mult    $ac3,$4,$5
3868         multu   $ac3,$4,$5],,
3869       [AC_DEFINE(HAVE_AS_DSPR1_MULT, 1,
3870           [Define if your assembler supports DSPR1 mult.])])
3871
3872     AC_MSG_CHECKING(assembler and linker for explicit JALR relocation)
3873     gcc_cv_as_ld_jalr_reloc=no
3874     if test $gcc_cv_as_mips_explicit_relocs = yes; then
3875       if test $in_tree_ld = yes ; then
3876         if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 20 -o "$gcc_cv_gld_major_version" -gt 2 \
3877            && test $in_tree_ld_is_elf = yes; then
3878           gcc_cv_as_ld_jalr_reloc=yes
3879         fi
3880       elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x; then
3881         echo '  .ent x' > conftest.s
3882         echo 'x:        ld $2,%got_disp(y)($3)' >> conftest.s
3883         echo '  ld $25,%call16(y)($28)' >> conftest.s
3884         echo '  .reloc  1f,R_MIPS_JALR,y' >> conftest.s
3885         echo '1:        jalr $25' >> conftest.s
3886         echo '  .reloc  1f,R_MIPS_JALR,x' >> conftest.s
3887         echo '1:        jalr $25' >> conftest.s
3888         echo '  .end x' >> conftest.s
3889         if $gcc_cv_as -o conftest.o conftest.s >/dev/null 2>&AS_MESSAGE_LOG_FD \
3890            && $gcc_cv_ld -shared -o conftest.so conftest.o >/dev/null 2>&AS_MESSAGE_LOG_FD; then
3891           if $gcc_cv_objdump -d conftest.so | grep jalr >/dev/null 2>&1 \
3892              && $gcc_cv_objdump -d conftest.so | grep "bal.*<x>" >/dev/null 2>&1; then
3893             gcc_cv_as_ld_jalr_reloc=yes
3894           fi
3895         fi
3896         rm -f conftest.*
3897       fi
3898     fi
3899     if test $gcc_cv_as_ld_jalr_reloc = yes; then
3900       if test x$target_cpu_default = x; then
3901         target_cpu_default=MASK_RELAX_PIC_CALLS
3902       else
3903         target_cpu_default="($target_cpu_default)|MASK_RELAX_PIC_CALLS"
3904       fi
3905     fi
3906     AC_MSG_RESULT($gcc_cv_as_ld_jalr_reloc)
3907
3908     AC_CACHE_CHECK([linker for .eh_frame personality relaxation],
3909       [gcc_cv_ld_mips_personality_relaxation],
3910       [gcc_cv_ld_mips_personality_relaxation=no
3911        if test $in_tree_ld = yes ; then
3912          if test "$gcc_cv_gld_major_version" -eq 2 \
3913                  -a "$gcc_cv_gld_minor_version" -ge 21 \
3914                  -o "$gcc_cv_gld_major_version" -gt 2; then
3915            gcc_cv_ld_mips_personality_relaxation=yes
3916          fi
3917        elif test x$gcc_cv_as != x \
3918                  -a x$gcc_cv_ld != x \
3919                  -a x$gcc_cv_readelf != x ; then
3920          cat > conftest.s <<EOF
3921         .cfi_startproc
3922         .cfi_personality 0x80,indirect_ptr
3923         .ent test
3924 test:
3925         nop
3926         .end test
3927         .cfi_endproc
3928
3929         .section .data,"aw",@progbits
3930 indirect_ptr:
3931         .dc.a personality
3932 EOF
3933          if $gcc_cv_as -KPIC -o conftest.o conftest.s > /dev/null 2>&1 \
3934             && $gcc_cv_ld -o conftest conftest.o -shared > /dev/null 2>&1; then
3935            if $gcc_cv_readelf -d conftest 2>&1 \
3936               | grep TEXTREL > /dev/null 2>&1; then
3937              :
3938            elif $gcc_cv_readelf --relocs conftest 2>&1 \
3939                 | grep 'R_MIPS_REL32 *$' > /dev/null 2>&1; then
3940              :
3941            else
3942              gcc_cv_ld_mips_personality_relaxation=yes
3943            fi
3944          fi
3945        fi
3946        rm -f conftest.s conftest.o conftest])
3947     if test x$gcc_cv_ld_mips_personality_relaxation = xyes; then
3948             AC_DEFINE(HAVE_LD_PERSONALITY_RELAXATION, 1,
3949       [Define if your linker can relax absolute .eh_frame personality
3950 pointers into PC-relative form.])
3951     fi
3952     ;;
3953 esac
3954
3955 # Mips and HP-UX need the GNU assembler.
3956 # Linux on IA64 might be able to use the Intel assembler.
3957
3958 case "$target" in
3959   mips*-*-* | *-*-hpux* )
3960     if test x$gas_flag = xyes \
3961        || test x"$host" != x"$build" \
3962        || test ! -x "$gcc_cv_as" \
3963        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
3964       :
3965     else
3966       echo "*** This configuration requires the GNU assembler" >&2
3967       exit 1
3968     fi
3969     ;;
3970 esac
3971
3972 # ??? Not all targets support dwarf2 debug_line, even within a version
3973 # of gas.  Moreover, we need to emit a valid instruction to trigger any
3974 # info to the output file.  So, as supported targets are added to gas 2.11,
3975 # add some instruction here to (also) show we expect this might work.
3976 # ??? Once 2.11 is released, probably need to add first known working
3977 # version to the per-target configury.
3978 case "$cpu_type" in
3979   alpha | arm | avr | bfin | cris | i386 | m32c | m68k | microblaze | mips \
3980   | pa | rs6000 | score | sparc | spu | xstormy16 | xtensa)
3981     insn="nop"
3982     ;;
3983   ia64 | s390)
3984     insn="nop 0"
3985     ;;
3986   mmix)
3987     insn="swym 0"
3988     ;;
3989 esac
3990 if test x"$insn" != x; then
3991  conftest_s="\
3992         .file 1 \"conftest.s\"
3993         .loc 1 3 0
3994         $insn"
3995  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
3996   gcc_cv_as_dwarf2_debug_line,
3997   [elf,2,11,0],, [$conftest_s],
3998   [if test x$gcc_cv_objdump != x \
3999    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
4000       | grep debug_line > /dev/null 2>&1; then
4001      gcc_cv_as_dwarf2_debug_line=yes
4002    fi])
4003
4004 # The .debug_line file table must be in the exact order that
4005 # we specified the files, since these indices are also used
4006 # by DW_AT_decl_file.  Approximate this test by testing if
4007 # the assembler bitches if the same index is assigned twice.
4008  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
4009   gcc_cv_as_dwarf2_file_buggy,,,
4010 [       .file 1 "foo.s"
4011         .file 1 "bar.s"])
4012
4013  if test $gcc_cv_as_dwarf2_debug_line = yes \
4014  && test $gcc_cv_as_dwarf2_file_buggy = no; then
4015         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
4016   [Define if your assembler supports dwarf2 .file/.loc directives,
4017    and preserves file table indices exactly as given.])
4018  fi
4019
4020  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
4021   gcc_cv_as_gdwarf2_flag,
4022   [elf,2,11,0], [--gdwarf2], [$insn],,
4023   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
4024 [Define if your assembler supports the --gdwarf2 option.])])
4025
4026  gcc_GAS_CHECK_FEATURE([--gstabs option],
4027   gcc_cv_as_gstabs_flag,
4028   [elf,2,11,0], [--gstabs], [$insn],
4029   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
4030    # and warns about it, but still exits successfully.  So check for
4031    # this.
4032    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
4033    then :
4034    else gcc_cv_as_gstabs_flag=yes
4035    fi],
4036   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
4037 [Define if your assembler supports the --gstabs option.])])
4038
4039  gcc_GAS_CHECK_FEATURE([--debug-prefix-map option],
4040   gcc_cv_as_debug_prefix_map_flag,
4041   [2,18,0], [--debug-prefix-map /a=/b], [$insn],,
4042   [AC_DEFINE(HAVE_AS_DEBUG_PREFIX_MAP, 1,
4043 [Define if your assembler supports the --debug-prefix-map option.])])
4044 fi
4045
4046 gcc_GAS_CHECK_FEATURE([.lcomm with alignment], gcc_cv_as_lcomm_with_alignment,
4047  ,,
4048 [.lcomm bar,4,16],,
4049 [AC_DEFINE(HAVE_GAS_LCOMM_WITH_ALIGNMENT, 1,
4050   [Define if your assembler supports .lcomm with an alignment field.])])
4051
4052 AC_ARG_ENABLE(gnu-unique-object,
4053  [AS_HELP_STRING([--enable-gnu-unique-object],
4054    [enable the use of the @gnu_unique_object ELF extension on glibc systems])],
4055  [case $enable_gnu_unique_object in
4056     yes | no) ;;
4057     *) AC_MSG_ERROR(['$enable_gnu_unique_object' is an invalid value for --enable-gnu-unique-object.
4058 Valid choices are 'yes' and 'no'.]) ;;
4059   esac],
4060  [gcc_GAS_CHECK_FEATURE([gnu_unique_object], gcc_cv_as_gnu_unique_object,
4061    [elf,2,19,52],,
4062    [.type foo, @gnu_unique_object],,
4063 # Also check for ld.so support, i.e. glibc 2.11 or higher.
4064    [[if test x$host = x$build -a x$host = x$target &&
4065        ldd --version 2>/dev/null &&
4066        glibcver=`ldd --version 2>/dev/null | sed 's/.* //;q'`; then
4067       glibcmajor=`expr "$glibcver" : "\([0-9]*\)"`
4068       glibcminor=`expr "$glibcver" : "[2-9]*\.\([0-9]*\)"`
4069       glibcnum=`expr $glibcmajor \* 1000 + $glibcminor`
4070       if test "$glibcnum" -ge 2011 ; then
4071         enable_gnu_unique_object=yes
4072       fi
4073     fi]])])
4074 if test x$enable_gnu_unique_object = xyes; then
4075   AC_DEFINE(HAVE_GAS_GNU_UNIQUE_OBJECT, 1,
4076    [Define if your assembler supports @gnu_unique_object.])
4077 fi
4078
4079 AC_CACHE_CHECK([assembler for tolerance to line number 0],
4080  [gcc_cv_as_line_zero],
4081  [gcc_cv_as_line_zero=no
4082   if test $in_tree_gas = yes; then
4083     gcc_GAS_VERSION_GTE_IFELSE(2, 16, 91, [gcc_cv_as_line_zero=yes])
4084   elif test "x$gcc_cv_as" != x; then
4085     { echo '# 1 "test.s" 1'; echo '# 0 "" 2'; } > conftest.s
4086     if AC_TRY_COMMAND([$gcc_cv_as -o conftest.o conftest.s >&AS_MESSAGE_LOG_FD 2>conftest.out]) &&
4087        test "x`cat conftest.out`" = x
4088     then
4089       gcc_cv_as_line_zero=yes
4090     else
4091       echo "configure: failed program was" >&AS_MESSAGE_LOG_FD
4092       cat conftest.s >&AS_MESSAGE_LOG_FD
4093       echo "configure: error output was" >&AS_MESSAGE_LOG_FD
4094       cat conftest.out >&AS_MESSAGE_LOG_FD
4095     fi
4096     rm -f conftest.o conftest.s conftest.out
4097   fi])
4098 if test "x$gcc_cv_as_line_zero" = xyes; then
4099   AC_DEFINE([HAVE_AS_LINE_ZERO], 1,
4100 [Define if the assembler won't complain about a line such as # 0 "" 2.])
4101 fi
4102
4103 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
4104 gcc_cv_ld_eh_frame_hdr=no
4105 if test $in_tree_ld = yes ; then
4106   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
4107      && test $in_tree_ld_is_elf = yes; then
4108     gcc_cv_ld_eh_frame_hdr=yes
4109   fi
4110 elif test x$gcc_cv_ld != x; then
4111   if echo "$ld_ver" | grep GNU > /dev/null; then
4112     # Check if linker supports --eh-frame-hdr option
4113     if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
4114       gcc_cv_ld_eh_frame_hdr=yes
4115     fi
4116   else
4117     case "$target" in
4118       *-*-solaris2*)
4119         # Sun ld has various bugs in .eh_frame_hdr support before version 1.2251.
4120         if test "$ld_vers_major" -gt 1 || test "$ld_vers_minor" -ge 2251; then
4121           gcc_cv_ld_eh_frame_hdr=yes
4122         fi
4123         ;;
4124     esac
4125   fi
4126 fi
4127 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
4128 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
4129         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
4130 [Define if your linker supports .eh_frame_hdr.])
4131 fi
4132 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
4133
4134 AC_MSG_CHECKING(linker position independent executable support)
4135 gcc_cv_ld_pie=no
4136 if test $in_tree_ld = yes ; then
4137   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
4138      && test $in_tree_ld_is_elf = yes; then
4139     gcc_cv_ld_pie=yes
4140   fi
4141 elif test x$gcc_cv_ld != x; then
4142         # Check if linker supports -pie option
4143         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
4144                 gcc_cv_ld_pie=yes
4145         fi
4146 fi
4147 if test x"$gcc_cv_ld_pie" = xyes; then
4148         AC_DEFINE(HAVE_LD_PIE, 1,
4149 [Define if your linker supports -pie option.])
4150 fi
4151 AC_MSG_RESULT($gcc_cv_ld_pie)
4152
4153 AC_MSG_CHECKING(linker EH-compatible garbage collection of sections)
4154 gcc_cv_ld_eh_gc_sections=no
4155 if test $in_tree_ld = yes ; then
4156   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 17 -o "$gcc_cv_gld_major_version" -gt 2 \
4157      && test $in_tree_ld_is_elf = yes; then
4158     gcc_cv_ld_eh_gc_sections=yes
4159   fi
4160 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
4161   cat > conftest.s <<EOF
4162         .section        .text
4163 .globl _start
4164         .type _start, @function
4165 _start:
4166         .long foo
4167         .size _start, .-_start
4168         .section        .text.foo,"ax",@progbits
4169         .type foo, @function
4170 foo:
4171         .long 0
4172         .size foo, .-foo
4173         .section        .gcc_except_table.foo,"a",@progbits
4174 .L0:
4175         .long 0
4176         .section        .eh_frame,"a",@progbits
4177         .long .L0
4178 EOF
4179   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4180     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4181          | grep "gc-sections option ignored" > /dev/null; then
4182       gcc_cv_ld_eh_gc_sections=no
4183     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4184          | grep gcc_except_table > /dev/null; then
4185       gcc_cv_ld_eh_gc_sections=yes
4186       # If no COMDAT groups, the compiler will emit .gnu.linkonce.t. sections.
4187       if test x$gcc_cv_as_comdat_group != xyes; then
4188         gcc_cv_ld_eh_gc_sections=no
4189         cat > conftest.s <<EOF
4190         .section        .text
4191 .globl _start
4192         .type _start, @function
4193 _start:
4194         .long foo
4195         .size _start, .-_start
4196         .section        .gnu.linkonce.t.foo,"ax",@progbits
4197         .type foo, @function
4198 foo:
4199         .long 0
4200         .size foo, .-foo
4201         .section        .gcc_except_table.foo,"a",@progbits
4202 .L0:
4203         .long 0
4204         .section        .eh_frame,"a",@progbits
4205         .long .L0
4206 EOF
4207         if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4208           if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4209                | grep "gc-sections option ignored" > /dev/null; then
4210             gcc_cv_ld_eh_gc_sections=no
4211           elif $gcc_cv_objdump -h conftest 2> /dev/null \
4212                | grep gcc_except_table > /dev/null; then
4213             gcc_cv_ld_eh_gc_sections=yes
4214           fi
4215         fi
4216       fi
4217     fi
4218   fi
4219   rm -f conftest.s conftest.o conftest
4220 fi
4221 case "$target" in
4222   hppa*-*-linux*)
4223     # ??? This apparently exposes a binutils bug with PC-relative relocations.
4224     gcc_cv_ld_eh_gc_sections=no
4225     ;;
4226 esac
4227 if test x$gcc_cv_ld_eh_gc_sections = xyes; then
4228         AC_DEFINE(HAVE_LD_EH_GC_SECTIONS, 1,
4229   [Define if your linker supports garbage collection of
4230    sections in presence of EH frames.])
4231 fi
4232 AC_MSG_RESULT($gcc_cv_ld_eh_gc_sections)
4233
4234 AC_MSG_CHECKING(linker EH garbage collection of sections bug)
4235 gcc_cv_ld_eh_gc_sections_bug=no
4236 if test $in_tree_ld = yes ; then
4237   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -lt 19 -o "$gcc_cv_gld_major_version" -lt 2 \
4238      && test $in_tree_ld_is_elf = yes; then
4239     gcc_cv_ld_eh_gc_sections_bug=yes
4240   fi
4241 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x -a x$gcc_cv_as_comdat_group = xyes; then
4242   gcc_cv_ld_eh_gc_sections_bug=yes
4243   cat > conftest.s <<EOF
4244         .section        .text
4245 .globl _start
4246         .type _start, @function
4247 _start:
4248         .long foo
4249         .size _start, .-_start
4250         .section        .text.startup.foo,"ax",@progbits
4251         .type foo, @function
4252 foo:
4253         .long 0
4254         .size foo, .-foo
4255         .section        .gcc_except_table.foo,"a",@progbits
4256 .L0:
4257         .long 0
4258         .section        .eh_frame,"a",@progbits
4259         .long .L0
4260 EOF
4261   if $gcc_cv_as -o conftest.o conftest.s > /dev/null 2>&1; then
4262     if $gcc_cv_ld -o conftest conftest.o --entry=_start --gc-sections 2>&1 \
4263          | grep "gc-sections option ignored" > /dev/null; then
4264       :
4265     elif $gcc_cv_objdump -h conftest 2> /dev/null \
4266          | grep gcc_except_table > /dev/null; then
4267       gcc_cv_ld_eh_gc_sections_bug=no
4268     fi
4269   fi
4270   rm -f conftest.s conftest.o conftest