OSDN Git Service

PR c/14765
[pf3gnuchains/gcc-fork.git] / gcc / c-parse.in
1 /* YACC parser for C syntax and for Objective C.  -*-c-*-
2    Copyright (C) 1987, 1988, 1989, 1992, 1993, 1994, 1995, 1996, 1997,
3    1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
4
5 This file is part of GCC.
6
7 GCC is free software; you can redistribute it and/or modify it under
8 the terms of the GNU General Public License as published by the Free
9 Software Foundation; either version 2, or (at your option) any later
10 version.
11
12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
14 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 for more details.
16
17 You should have received a copy of the GNU General Public License
18 along with GCC; see the file COPYING.  If not, write to the Free
19 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
20 02111-1307, USA.  */
21
22 /* This file defines the grammar of C and that of Objective C.
23    @@ifobjc ... @@end_ifobjc  conditionals contain code for Objective C only.
24    @@ifc ... @@end_ifc  conditionals contain code for C only.
25    Sed commands in Makefile.in are used to convert this file into
26    c-parse.y and into objc-parse.y.  */
27
28 /* To whomever it may concern: I have heard that such a thing was once
29    written by AT&T, but I have never seen it.  */
30
31 @@ifc
32 %expect 10 /* shift/reduce conflicts, and no reduce/reduce conflicts.  */
33 @@end_ifc
34
35 %{
36 #include "config.h"
37 #include "system.h"
38 #include "coretypes.h"
39 #include "tm.h"
40 #include "tree.h"
41 #include "langhooks.h"
42 #include "input.h"
43 #include "cpplib.h"
44 #include "intl.h"
45 #include "timevar.h"
46 #include "c-pragma.h"           /* For YYDEBUG definition, and parse_in.  */
47 #include "c-tree.h"
48 #include "flags.h"
49 #include "varray.h"
50 #include "output.h"
51 #include "toplev.h"
52 #include "ggc.h"
53
54 @@ifobjc
55 #include "objc-act.h"
56 @@end_ifobjc
57
58 /* Like YYERROR but do call yyerror.  */
59 #define YYERROR1 { yyerror ("syntax error"); YYERROR; }
60
61 /* Like the default stack expander, except (1) use realloc when possible,
62    (2) impose no hard maxiumum on stack size, (3) REALLY do not use alloca.
63
64    Irritatingly, YYSTYPE is defined after this %{ %} block, so we cannot
65    give malloced_yyvs its proper type.  This is ok since all we need from
66    it is to be able to free it.  */
67
68 static short *malloced_yyss;
69 static void *malloced_yyvs;
70
71 #define yyoverflow(MSG, SS, SSSIZE, VS, VSSIZE, YYSSZ)                  \
72 do {                                                                    \
73   size_t newsize;                                                       \
74   short *newss;                                                         \
75   YYSTYPE *newvs;                                                       \
76   newsize = *(YYSSZ) *= 2;                                              \
77   if (malloced_yyss)                                                    \
78     {                                                                   \
79       newss = really_call_realloc (*(SS), newsize * sizeof (short));    \
80       newvs = really_call_realloc (*(VS), newsize * sizeof (YYSTYPE));  \
81     }                                                                   \
82   else                                                                  \
83     {                                                                   \
84       newss = really_call_malloc (newsize * sizeof (short));            \
85       newvs = really_call_malloc (newsize * sizeof (YYSTYPE));          \
86       if (newss)                                                        \
87         memcpy (newss, *(SS), (SSSIZE));                                \
88       if (newvs)                                                        \
89         memcpy (newvs, *(VS), (VSSIZE));                                \
90     }                                                                   \
91   if (!newss || !newvs)                                                 \
92     {                                                                   \
93       yyerror (MSG);                                                    \
94       return 2;                                                         \
95     }                                                                   \
96   *(SS) = newss;                                                        \
97   *(VS) = newvs;                                                        \
98   malloced_yyss = newss;                                                \
99   malloced_yyvs = (void *) newvs;                                       \
100 } while (0)
101 %}
102
103 %start program
104
105 %union {long itype; tree ttype; enum tree_code code;
106         location_t location; }
107
108 /* All identifiers that are not reserved words
109    and are not declared typedefs in the current block */
110 %token IDENTIFIER
111
112 /* All identifiers that are declared typedefs in the current block.
113    In some contexts, they are treated just like IDENTIFIER,
114    but they can also serve as typespecs in declarations.  */
115 %token TYPENAME
116
117 /* Reserved words that specify storage class.
118    yylval contains an IDENTIFIER_NODE which indicates which one.  */
119 %token SCSPEC                   /* Storage class other than static.  */
120 %token STATIC                   /* Static storage class.  */
121
122 /* Reserved words that specify type.
123    yylval contains an IDENTIFIER_NODE which indicates which one.  */
124 %token TYPESPEC
125
126 /* Reserved words that qualify type: "const", "volatile", or "restrict".
127    yylval contains an IDENTIFIER_NODE which indicates which one.  */
128 %token TYPE_QUAL
129
130 /* Character or numeric constants.
131    yylval is the node for the constant.  */
132 %token CONSTANT
133
134 /* String constants in raw form.
135    yylval is a STRING_CST node.  */
136
137 %token STRING
138
139 /* "...", used for functions with variable arglists.  */
140 %token ELLIPSIS
141
142 /* the reserved words */
143 /* SCO include files test "ASM", so use something else. */
144 %token SIZEOF ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
145 %token BREAK CONTINUE RETURN GOTO ASM_KEYWORD TYPEOF ALIGNOF
146 %token ATTRIBUTE EXTENSION LABEL
147 %token REALPART IMAGPART VA_ARG CHOOSE_EXPR TYPES_COMPATIBLE_P
148 %token PTR_VALUE PTR_BASE PTR_EXTENT
149 %token FUNC_NAME OFFSETOF
150
151 /* Add precedence rules to solve dangling else s/r conflict */
152 %nonassoc IF
153 %nonassoc ELSE
154
155 /* Define the operator tokens and their precedences.
156    The value is an integer because, if used, it is the tree code
157    to use in the expression made from the operator.  */
158
159 %right <code> ASSIGN '='
160 %right <code> '?' ':'
161 %left <code> OROR
162 %left <code> ANDAND
163 %left <code> '|'
164 %left <code> '^'
165 %left <code> '&'
166 %left <code> EQCOMPARE
167 %left <code> ARITHCOMPARE
168 %left <code> LSHIFT RSHIFT
169 %left <code> '+' '-'
170 %left <code> '*' '/' '%'
171 %right <code> UNARY PLUSPLUS MINUSMINUS
172 %left HYPERUNARY
173 %left <code> POINTSAT '.' '(' '['
174
175 /* The Objective-C keywords.  These are included in C and in
176    Objective C, so that the token codes are the same in both.  */
177 %token INTERFACE IMPLEMENTATION END SELECTOR DEFS ENCODE
178 %token CLASSNAME PUBLIC PRIVATE PROTECTED PROTOCOL OBJECTNAME CLASS ALIAS
179 %token AT_THROW AT_TRY AT_CATCH AT_FINALLY AT_SYNCHRONIZED
180 %token OBJC_STRING
181
182 %type <code> unop
183 %type <ttype> ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
184 %type <ttype> BREAK CONTINUE RETURN GOTO ASM_KEYWORD SIZEOF TYPEOF ALIGNOF
185
186 %type <ttype> identifier IDENTIFIER TYPENAME CONSTANT expr nonnull_exprlist exprlist
187 %type <ttype> expr_no_commas cast_expr unary_expr primary STRING
188 %type <ttype> declspecs_nosc_nots_nosa_noea declspecs_nosc_nots_nosa_ea
189 %type <ttype> declspecs_nosc_nots_sa_noea declspecs_nosc_nots_sa_ea
190 %type <ttype> declspecs_nosc_ts_nosa_noea declspecs_nosc_ts_nosa_ea
191 %type <ttype> declspecs_nosc_ts_sa_noea declspecs_nosc_ts_sa_ea
192 %type <ttype> declspecs_sc_nots_nosa_noea declspecs_sc_nots_nosa_ea
193 %type <ttype> declspecs_sc_nots_sa_noea declspecs_sc_nots_sa_ea
194 %type <ttype> declspecs_sc_ts_nosa_noea declspecs_sc_ts_nosa_ea
195 %type <ttype> declspecs_sc_ts_sa_noea declspecs_sc_ts_sa_ea
196 %type <ttype> declspecs_ts declspecs_nots
197 %type <ttype> declspecs_ts_nosa declspecs_nots_nosa
198 %type <ttype> declspecs_nosc_ts declspecs_nosc_nots declspecs_nosc declspecs
199 %type <ttype> maybe_type_quals_attrs typespec_nonattr typespec_attr
200 %type <ttype> typespec_reserved_nonattr typespec_reserved_attr
201 %type <ttype> typespec_nonreserved_nonattr
202 %type <ttype> offsetof_member_designator
203
204 %type <ttype> scspec SCSPEC STATIC TYPESPEC TYPE_QUAL maybe_volatile
205 %type <ttype> initdecls notype_initdecls initdcl notype_initdcl init
206 %type <ttype> simple_asm_expr maybeasm asm_stmt asm_argument
207 %type <ttype> asm_operands nonnull_asm_operands asm_operand asm_clobbers
208 %type <ttype> maybe_attribute attributes attribute attribute_list attrib
209 %type <ttype> any_word
210
211 %type <ttype> compstmt compstmt_start compstmt_nostart compstmt_primary_start
212 %type <ttype> do_stmt_start pop_scope stmt label
213
214 %type <ttype> c99_block_start c99_block_end
215 %type <ttype> declarator
216 %type <ttype> notype_declarator after_type_declarator
217 %type <ttype> parm_declarator
218 %type <ttype> parm_declarator_starttypename parm_declarator_nostarttypename
219 %type <ttype> array_declarator
220
221 %type <ttype> structsp_attr structsp_nonattr
222 %type <ttype> component_decl_list component_decl_list2
223 %type <ttype> component_decl components components_notype component_declarator
224 %type <ttype> component_notype_declarator
225 %type <ttype> enumlist enumerator
226 %type <ttype> struct_head union_head enum_head
227 %type <ttype> typename absdcl absdcl1 absdcl1_ea absdcl1_noea
228 %type <ttype> direct_absdcl1 absdcl_maybe_attribute
229 %type <ttype> xexpr parms parm firstparm identifiers
230
231 %type <ttype> parmlist parmlist_1 parmlist_2
232 %type <ttype> parmlist_or_identifiers parmlist_or_identifiers_1
233 %type <ttype> identifiers_or_typenames
234
235 %type <itype> setspecs setspecs_fp extension
236
237 %type <location> save_location
238 \f
239 @@ifobjc
240 /* the Objective-C nonterminals */
241
242 %type <ttype> ivar_decl_list ivar_decls ivar_decl ivars ivar_declarator
243 %type <ttype> methoddecl unaryselector keywordselector selector
244 %type <ttype> keyworddecl receiver objcmessageexpr messageargs
245 %type <ttype> keywordexpr keywordarglist keywordarg
246 %type <ttype> myparms myparm optparmlist reservedwords objcselectorexpr
247 %type <ttype> selectorarg keywordnamelist keywordname objcencodeexpr
248 %type <ttype> non_empty_protocolrefs protocolrefs identifier_list objcprotocolexpr
249
250 %type <ttype> CLASSNAME OBJECTNAME OBJC_STRING
251
252 %type <ttype> superclass
253 %type <itype> objc_try_catch_stmt objc_finally_block
254 @@end_ifobjc
255 \f
256 %{
257 /* Number of statements (loosely speaking) and compound statements
258    seen so far.  */
259 static int stmt_count;
260 static int compstmt_count;
261
262 /* Input location of the end of the body of last simple_if;
263    used by the stmt-rule immediately after simple_if returns.  */
264 static location_t if_stmt_locus;
265
266
267 /* List of types and structure classes of the current declaration.  */
268 static GTY(()) tree current_declspecs;
269 static GTY(()) tree prefix_attributes;
270
271 /* List of all the attributes applying to the identifier currently being
272    declared; includes prefix_attributes and possibly some more attributes
273    just after a comma.  */
274 static GTY(()) tree all_prefix_attributes;
275
276 /* Stack of saved values of current_declspecs, prefix_attributes and
277    all_prefix_attributes.  */
278 static GTY(()) tree declspec_stack;
279
280 /* PUSH_DECLSPEC_STACK is called from setspecs; POP_DECLSPEC_STACK
281    should be called from the productions making use of setspecs.  */
282 #define PUSH_DECLSPEC_STACK                                              \
283   do {                                                                   \
284     declspec_stack = tree_cons (build_tree_list (prefix_attributes,      \
285                                                  all_prefix_attributes), \
286                                 current_declspecs,                       \
287                                 declspec_stack);                         \
288   } while (0)
289
290 #define POP_DECLSPEC_STACK                                              \
291   do {                                                                  \
292     current_declspecs = TREE_VALUE (declspec_stack);                    \
293     prefix_attributes = TREE_PURPOSE (TREE_PURPOSE (declspec_stack));   \
294     all_prefix_attributes = TREE_VALUE (TREE_PURPOSE (declspec_stack)); \
295     declspec_stack = TREE_CHAIN (declspec_stack);                       \
296   } while (0)
297
298 /* For __extension__, save/restore the warning flags which are
299    controlled by __extension__.  */
300 #define SAVE_EXT_FLAGS()                \
301         (pedantic                       \
302          | (warn_pointer_arith << 1)    \
303          | (warn_traditional << 2)      \
304          | (flag_iso << 3))
305
306 #define RESTORE_EXT_FLAGS(val)                  \
307   do {                                          \
308     pedantic = val & 1;                         \
309     warn_pointer_arith = (val >> 1) & 1;        \
310     warn_traditional = (val >> 2) & 1;          \
311     flag_iso = (val >> 3) & 1;                  \
312   } while (0)
313
314 @@ifobjc
315 /* Objective-C specific parser/lexer information */
316
317 static enum tree_code objc_inherit_code;
318 static int objc_pq_context = 0, objc_public_flag = 0;
319
320 /* The following flag is needed to contextualize ObjC lexical analysis.
321    In some cases (e.g., 'int NSObject;'), it is undesirable to bind
322    an identifier to an ObjC class, even if a class with that name
323    exists.  */
324 static int objc_need_raw_identifier;
325 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   objc_need_raw_identifier = VAL
326 @@end_ifobjc
327
328 @@ifc
329 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   /* nothing */
330 @@end_ifc
331
332 /* Tell yyparse how to print a token's value, if yydebug is set.  */
333
334 #define YYPRINT(FILE,YYCHAR,YYLVAL) yyprint(FILE,YYCHAR,YYLVAL)
335
336 static void yyprint (FILE *, int, YYSTYPE);
337 static void yyerror (const char *);
338 static int yylexname (void);
339 static inline int _yylex (void);
340 static int  yylex (void);
341 static void init_reswords (void);
342
343   /* Initialisation routine for this file.  */
344 void
345 c_parse_init (void)
346 {
347   init_reswords ();
348 }
349
350 %}
351 \f
352 %%
353 program: /* empty */
354                 { if (pedantic)
355                     pedwarn ("ISO C forbids an empty source file");
356                 }
357         | extdefs
358         ;
359
360 /* the reason for the strange actions in this rule
361  is so that notype_initdecls when reached via datadef
362  can find a valid list of type and sc specs in $0. */
363
364 extdefs:
365         {$<ttype>$ = NULL_TREE; } extdef
366         | extdefs {$<ttype>$ = NULL_TREE; ggc_collect(); } extdef
367         ;
368
369 extdef:
370         fndef
371         | datadef
372         | asmdef
373         | extension extdef
374                 { RESTORE_EXT_FLAGS ($1); }
375 @@ifobjc
376         | objcdef
377 @@end_ifobjc
378         ;
379
380 datadef:
381           setspecs notype_initdecls ';'
382                 { if (pedantic)
383                     error ("ISO C forbids data definition with no type or storage class");
384                   else
385                     warning ("data definition has no type or storage class");
386
387                   POP_DECLSPEC_STACK; }
388         | declspecs_nots setspecs notype_initdecls ';'
389                 { POP_DECLSPEC_STACK; }
390         | declspecs_ts setspecs initdecls ';'
391                 { POP_DECLSPEC_STACK; }
392         | declspecs ';'
393           { shadow_tag ($1); }
394         | error ';'
395         | error '}'
396         | ';'
397                 { if (pedantic)
398                     pedwarn ("ISO C does not allow extra `;' outside of a function"); }
399         ;
400 \f
401 fndef:
402           declspecs_ts setspecs declarator
403                 { if (! start_function (current_declspecs, $3,
404                                         all_prefix_attributes))
405                     YYERROR1;
406                 }
407           old_style_parm_decls save_location
408                 { DECL_SOURCE_LOCATION (current_function_decl) = $6;
409                   store_parm_decls (); }
410           compstmt_or_error
411                 { finish_function ();
412                   POP_DECLSPEC_STACK; }
413         | declspecs_ts setspecs declarator error
414                 { POP_DECLSPEC_STACK; }
415         | declspecs_nots setspecs notype_declarator
416                 { if (! start_function (current_declspecs, $3,
417                                         all_prefix_attributes))
418                     YYERROR1;
419                 }
420           old_style_parm_decls save_location
421                 { DECL_SOURCE_LOCATION (current_function_decl) = $6;
422                   store_parm_decls (); }
423           compstmt_or_error
424                 { finish_function ();
425                   POP_DECLSPEC_STACK; }
426         | declspecs_nots setspecs notype_declarator error
427                 { POP_DECLSPEC_STACK; }
428         | setspecs notype_declarator
429                 { if (! start_function (NULL_TREE, $2,
430                                         all_prefix_attributes))
431                     YYERROR1;
432                 }
433           old_style_parm_decls save_location
434                 { DECL_SOURCE_LOCATION (current_function_decl) = $5;
435                   store_parm_decls (); }
436           compstmt_or_error
437                 { finish_function ();
438                   POP_DECLSPEC_STACK; }
439         | setspecs notype_declarator error
440                 { POP_DECLSPEC_STACK; }
441         ;
442
443 identifier:
444         IDENTIFIER
445         | TYPENAME
446 @@ifobjc
447         | OBJECTNAME
448         | CLASSNAME
449 @@end_ifobjc
450         ;
451
452 unop:     '&'
453                 { $$ = ADDR_EXPR; }
454         | '-'
455                 { $$ = NEGATE_EXPR; }
456         | '+'
457                 { $$ = CONVERT_EXPR;
458 @@ifc
459   if (warn_traditional && !in_system_header)
460     warning ("traditional C rejects the unary plus operator");
461 @@end_ifc
462                 }
463         | PLUSPLUS
464                 { $$ = PREINCREMENT_EXPR; }
465         | MINUSMINUS
466                 { $$ = PREDECREMENT_EXPR; }
467         | '~'
468                 { $$ = BIT_NOT_EXPR; }
469         | '!'
470                 { $$ = TRUTH_NOT_EXPR; }
471         ;
472
473 expr:   nonnull_exprlist
474                 { $$ = build_compound_expr ($1); }
475         ;
476
477 exprlist:
478           /* empty */
479                 { $$ = NULL_TREE; }
480         | nonnull_exprlist
481         ;
482
483 nonnull_exprlist:
484         expr_no_commas
485                 { $$ = build_tree_list (NULL_TREE, $1); }
486         | nonnull_exprlist ',' expr_no_commas
487                 { chainon ($1, build_tree_list (NULL_TREE, $3)); }
488         ;
489
490 unary_expr:
491         primary
492         | '*' cast_expr   %prec UNARY
493                 { $$ = build_indirect_ref ($2, "unary *"); }
494         /* __extension__ turns off -pedantic for following primary.  */
495         | extension cast_expr     %prec UNARY
496                 { $$ = $2;
497                   RESTORE_EXT_FLAGS ($1); }
498         | unop cast_expr  %prec UNARY
499                 { $$ = build_unary_op ($1, $2, 0);
500                   overflow_warning ($$); }
501         /* Refer to the address of a label as a pointer.  */
502         | ANDAND identifier
503                 { $$ = finish_label_address_expr ($2); }
504         | sizeof unary_expr  %prec UNARY
505                 { skip_evaluation--;
506                   if (TREE_CODE ($2) == COMPONENT_REF
507                       && DECL_C_BIT_FIELD (TREE_OPERAND ($2, 1)))
508                     error ("`sizeof' applied to a bit-field");
509                   $$ = c_sizeof (TREE_TYPE ($2)); }
510         | sizeof '(' typename ')'  %prec HYPERUNARY
511                 { skip_evaluation--;
512                   $$ = c_sizeof (groktypename ($3)); }
513         | alignof unary_expr  %prec UNARY
514                 { skip_evaluation--;
515                   $$ = c_alignof_expr ($2); }
516         | alignof '(' typename ')'  %prec HYPERUNARY
517                 { skip_evaluation--;
518                   $$ = c_alignof (groktypename ($3)); }
519         | REALPART cast_expr %prec UNARY
520                 { $$ = build_unary_op (REALPART_EXPR, $2, 0); }
521         | IMAGPART cast_expr %prec UNARY
522                 { $$ = build_unary_op (IMAGPART_EXPR, $2, 0); }
523         ;
524
525 sizeof:
526         SIZEOF { skip_evaluation++; }
527         ;
528
529 alignof:
530         ALIGNOF { skip_evaluation++; }
531         ;
532
533 typeof:
534         TYPEOF { skip_evaluation++; }
535         ;
536
537 cast_expr:
538         unary_expr
539         | '(' typename ')' cast_expr  %prec UNARY
540                 { $$ = c_cast_expr ($2, $4); }
541         ;
542
543 expr_no_commas:
544           cast_expr
545         | expr_no_commas '+' expr_no_commas
546                 { $$ = parser_build_binary_op ($2, $1, $3); }
547         | expr_no_commas '-' expr_no_commas
548                 { $$ = parser_build_binary_op ($2, $1, $3); }
549         | expr_no_commas '*' expr_no_commas
550                 { $$ = parser_build_binary_op ($2, $1, $3); }
551         | expr_no_commas '/' expr_no_commas
552                 { $$ = parser_build_binary_op ($2, $1, $3); }
553         | expr_no_commas '%' expr_no_commas
554                 { $$ = parser_build_binary_op ($2, $1, $3); }
555         | expr_no_commas LSHIFT expr_no_commas
556                 { $$ = parser_build_binary_op ($2, $1, $3); }
557         | expr_no_commas RSHIFT expr_no_commas
558                 { $$ = parser_build_binary_op ($2, $1, $3); }
559         | expr_no_commas ARITHCOMPARE expr_no_commas
560                 { $$ = parser_build_binary_op ($2, $1, $3); }
561         | expr_no_commas EQCOMPARE expr_no_commas
562                 { $$ = parser_build_binary_op ($2, $1, $3); }
563         | expr_no_commas '&' expr_no_commas
564                 { $$ = parser_build_binary_op ($2, $1, $3); }
565         | expr_no_commas '|' expr_no_commas
566                 { $$ = parser_build_binary_op ($2, $1, $3); }
567         | expr_no_commas '^' expr_no_commas
568                 { $$ = parser_build_binary_op ($2, $1, $3); }
569         | expr_no_commas ANDAND
570                 { $1 = lang_hooks.truthvalue_conversion
571                     (default_conversion ($1));
572                   skip_evaluation += $1 == truthvalue_false_node; }
573           expr_no_commas
574                 { skip_evaluation -= $1 == truthvalue_false_node;
575                   $$ = parser_build_binary_op (TRUTH_ANDIF_EXPR, $1, $4); }
576         | expr_no_commas OROR
577                 { $1 = lang_hooks.truthvalue_conversion
578                     (default_conversion ($1));
579                   skip_evaluation += $1 == truthvalue_true_node; }
580           expr_no_commas
581                 { skip_evaluation -= $1 == truthvalue_true_node;
582                   $$ = parser_build_binary_op (TRUTH_ORIF_EXPR, $1, $4); }
583         | expr_no_commas '?'
584                 { $1 = lang_hooks.truthvalue_conversion
585                     (default_conversion ($1));
586                   skip_evaluation += $1 == truthvalue_false_node; }
587           expr ':'
588                 { skip_evaluation += (($1 == truthvalue_true_node)
589                                       - ($1 == truthvalue_false_node)); }
590           expr_no_commas
591                 { skip_evaluation -= $1 == truthvalue_true_node;
592                   $$ = build_conditional_expr ($1, $4, $7); }
593         | expr_no_commas '?'
594                 { if (pedantic)
595                     pedwarn ("ISO C forbids omitting the middle term of a ?: expression");
596                   /* Make sure first operand is calculated only once.  */
597                   $<ttype>2 = save_expr (default_conversion ($1));
598                   $1 = lang_hooks.truthvalue_conversion ($<ttype>2);
599                   skip_evaluation += $1 == truthvalue_true_node; }
600           ':' expr_no_commas
601                 { skip_evaluation -= $1 == truthvalue_true_node;
602                   $$ = build_conditional_expr ($1, $<ttype>2, $5); }
603         | expr_no_commas '=' expr_no_commas
604                 { char class;
605                   $$ = build_modify_expr ($1, NOP_EXPR, $3);
606                   class = TREE_CODE_CLASS (TREE_CODE ($$));
607                   if (IS_EXPR_CODE_CLASS (class))
608                     C_SET_EXP_ORIGINAL_CODE ($$, MODIFY_EXPR);
609                 }
610         | expr_no_commas ASSIGN expr_no_commas
611                 { char class;
612                   $$ = build_modify_expr ($1, $2, $3);
613                   /* This inhibits warnings in
614                      c_common_truthvalue_conversion.  */
615                   class = TREE_CODE_CLASS (TREE_CODE ($$));
616                   if (IS_EXPR_CODE_CLASS (class))
617                     C_SET_EXP_ORIGINAL_CODE ($$, ERROR_MARK);
618                 }
619         ;
620
621 primary:
622         IDENTIFIER
623                 {
624                   if (yychar == YYEMPTY)
625                     yychar = YYLEX;
626                   $$ = build_external_ref ($1, yychar == '(');
627                 }
628         | CONSTANT
629         | STRING
630         | FUNC_NAME
631                 { $$ = fname_decl (C_RID_CODE ($$), $$); }
632         | '(' typename ')' '{'
633                 { start_init (NULL_TREE, NULL, 0);
634                   $2 = groktypename ($2);
635                   really_start_incremental_init ($2); }
636           initlist_maybe_comma '}'  %prec UNARY
637                 { tree constructor = pop_init_level (0);
638                   tree type = $2;
639                   finish_init ();
640
641                   if (pedantic && ! flag_isoc99)
642                     pedwarn ("ISO C90 forbids compound literals");
643                   $$ = build_compound_literal (type, constructor);
644                 }
645         | '(' expr ')'
646                 { char class = TREE_CODE_CLASS (TREE_CODE ($2));
647                   if (IS_EXPR_CODE_CLASS (class))
648                     C_SET_EXP_ORIGINAL_CODE ($2, ERROR_MARK);
649                   $$ = $2; }
650         | '(' error ')'
651                 { $$ = error_mark_node; }
652         | compstmt_primary_start compstmt_nostart ')'
653                  { tree saved_last_tree;
654
655                    if (pedantic)
656                      pedwarn ("ISO C forbids braced-groups within expressions");
657                   saved_last_tree = COMPOUND_BODY ($1);
658                   RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
659                   last_tree = saved_last_tree;
660                   TREE_CHAIN (last_tree) = NULL_TREE;
661                   if (!last_expr_type)
662                     last_expr_type = void_type_node;
663                   $$ = build1 (STMT_EXPR, last_expr_type, $1);
664                   TREE_SIDE_EFFECTS ($$) = 1;
665                   annotate_with_locus ($$, input_location);
666                 }
667         | compstmt_primary_start error ')'
668                 {
669                   last_tree = COMPOUND_BODY ($1);
670                   TREE_CHAIN (last_tree) = NULL_TREE;
671                   $$ = error_mark_node;
672                 }
673         | primary '(' exprlist ')'   %prec '.'
674                 { $$ = build_function_call ($1, $3); }
675         | VA_ARG '(' expr_no_commas ',' typename ')'
676                 { $$ = build_va_arg ($3, groktypename ($5)); }
677
678         | OFFSETOF '(' typename ',' offsetof_member_designator ')'
679                 { $$ = build_offsetof (groktypename ($3), $5); }
680         | OFFSETOF '(' error ')'
681                 { $$ = error_mark_node; }
682         | CHOOSE_EXPR '(' expr_no_commas ',' expr_no_commas ','
683                           expr_no_commas ')'
684                 {
685                   tree c;
686
687                   c = fold ($3);
688                   STRIP_NOPS (c);
689                   if (TREE_CODE (c) != INTEGER_CST)
690                     error ("first argument to __builtin_choose_expr not"
691                            " a constant");
692                   $$ = integer_zerop (c) ? $7 : $5;
693                 }
694         | CHOOSE_EXPR '(' error ')'
695                 { $$ = error_mark_node; }
696         | TYPES_COMPATIBLE_P '(' typename ',' typename ')'
697                 {
698                   tree e1, e2;
699
700                   e1 = TYPE_MAIN_VARIANT (groktypename ($3));
701                   e2 = TYPE_MAIN_VARIANT (groktypename ($5));
702
703                   $$ = comptypes (e1, e2, COMPARE_STRICT)
704                     ? build_int_2 (1, 0) : build_int_2 (0, 0);
705                 }
706         | TYPES_COMPATIBLE_P '(' error ')'
707                 { $$ = error_mark_node; }
708         | primary '[' expr ']'   %prec '.'
709                 { $$ = build_array_ref ($1, $3); }
710         | primary '.' identifier
711                 { $$ = build_component_ref ($1, $3); }
712         | primary POINTSAT identifier
713                 {
714                   tree expr = build_indirect_ref ($1, "->");
715                   $$ = build_component_ref (expr, $3);
716                 }
717         | primary PLUSPLUS
718                 { $$ = build_unary_op (POSTINCREMENT_EXPR, $1, 0); }
719         | primary MINUSMINUS
720                 { $$ = build_unary_op (POSTDECREMENT_EXPR, $1, 0); }
721 @@ifobjc
722         | objcmessageexpr
723                 { $$ = build_message_expr ($1); }
724         | objcselectorexpr
725                 { $$ = build_selector_expr ($1); }
726         | objcprotocolexpr
727                 { $$ = build_protocol_expr ($1); }
728         | objcencodeexpr
729                 { $$ = build_encode_expr ($1); }
730         | OBJC_STRING
731                 { $$ = build_objc_string_object ($1); }
732 @@end_ifobjc
733         ;
734
735 /* This is the second argument to __builtin_offsetof.  We must have one
736    identifier, and beyond that we want to accept sub structure and sub
737    array references.  We return tree list where each element has
738    PURPOSE set for component refs or VALUE set for array refs.  We'll
739    turn this into something real inside build_offsetof.  */
740
741 offsetof_member_designator:
742           identifier
743                 { $$ = tree_cons ($1, NULL_TREE, NULL_TREE); }
744         | offsetof_member_designator '.' identifier
745                 { $$ = tree_cons ($3, NULL_TREE, $1); }
746         | offsetof_member_designator '[' expr ']'
747                 { $$ = tree_cons (NULL_TREE, $3, $1); }
748         ;
749
750 old_style_parm_decls:
751         /* empty */
752         | datadecls
753         ;
754
755 /* The following are analogous to lineno_decl, decls and decl
756    except that they do not allow nested functions.
757    They are used for old-style parm decls.  */
758 lineno_datadecl:
759           save_location datadecl
760                 { }
761         ;
762
763 datadecls:
764         lineno_datadecl
765         | errstmt
766         | datadecls lineno_datadecl
767         | lineno_datadecl errstmt
768         ;
769
770 /* We don't allow prefix attributes here because they cause reduce/reduce
771    conflicts: we can't know whether we're parsing a function decl with
772    attribute suffix, or function defn with attribute prefix on first old
773    style parm.  */
774 datadecl:
775         declspecs_ts_nosa setspecs initdecls ';'
776                 { POP_DECLSPEC_STACK; }
777         | declspecs_nots_nosa setspecs notype_initdecls ';'
778                 { POP_DECLSPEC_STACK; }
779         | declspecs_ts_nosa ';'
780                 { shadow_tag_warned ($1, 1);
781                   pedwarn ("empty declaration"); }
782         | declspecs_nots_nosa ';'
783                 { pedwarn ("empty declaration"); }
784         ;
785
786 /* This combination which saves a lineno before a decl
787    is the normal thing to use, rather than decl itself.
788    This is to avoid shift/reduce conflicts in contexts
789    where statement labels are allowed.  */
790 lineno_decl:
791           save_location decl
792                 { }
793         ;
794
795 /* records the type and storage class specs to use for processing
796    the declarators that follow.
797    Maintains a stack of outer-level values of current_declspecs,
798    for the sake of parm declarations nested in function declarators.  */
799 setspecs: /* empty */
800                 { pending_xref_error ();
801                   PUSH_DECLSPEC_STACK;
802                   split_specs_attrs ($<ttype>0,
803                                      &current_declspecs, &prefix_attributes);
804                   all_prefix_attributes = prefix_attributes; }
805         ;
806
807 /* Possibly attributes after a comma, which should reset all_prefix_attributes
808    to prefix_attributes with these ones chained on the front.  */
809 maybe_resetattrs:
810           maybe_attribute
811                 { all_prefix_attributes = chainon ($1, prefix_attributes); }
812         ;
813
814 decl:
815         declspecs_ts setspecs initdecls ';'
816                 { POP_DECLSPEC_STACK; }
817         | declspecs_nots setspecs notype_initdecls ';'
818                 { POP_DECLSPEC_STACK; }
819         | declspecs_ts setspecs nested_function
820                 { POP_DECLSPEC_STACK; }
821         | declspecs_nots setspecs notype_nested_function
822                 { POP_DECLSPEC_STACK; }
823         | declspecs ';'
824                 { shadow_tag ($1); }
825         | extension decl
826                 { RESTORE_EXT_FLAGS ($1); }
827         ;
828
829 /* A list of declaration specifiers.  These are:
830
831    - Storage class specifiers (scspec), which for GCC currently includes
832    function specifiers ("inline").
833
834    - Type specifiers (typespec_*).
835
836    - Type qualifiers (TYPE_QUAL).
837
838    - Attribute specifier lists (attributes).
839
840    These are stored as a TREE_LIST; the head of the list is the last
841    item in the specifier list.  Each entry in the list has either a
842    TREE_PURPOSE that is an attribute specifier list, or a TREE_VALUE that
843    is a single other specifier or qualifier; and a TREE_CHAIN that is the
844    rest of the list.  TREE_STATIC is set on the list if something other
845    than a storage class specifier or attribute has been seen; this is used
846    to warn for the obsolescent usage of storage class specifiers other than
847    at the start of the list.  (Doing this properly would require function
848    specifiers to be handled separately from storage class specifiers.)
849
850    The various cases below are classified according to:
851
852    (a) Whether a storage class specifier is included or not; some
853    places in the grammar disallow storage class specifiers (_sc or _nosc).
854
855    (b) Whether a type specifier has been seen; after a type specifier,
856    a typedef name is an identifier to redeclare (_ts or _nots).
857
858    (c) Whether the list starts with an attribute; in certain places,
859    the grammar requires specifiers that don't start with an attribute
860    (_sa or _nosa).
861
862    (d) Whether the list ends with an attribute (or a specifier such that
863    any following attribute would have been parsed as part of that specifier);
864    this avoids shift-reduce conflicts in the parsing of attributes
865    (_ea or _noea).
866
867    TODO:
868
869    (i) Distinguish between function specifiers and storage class specifiers,
870    at least for the purpose of warnings about obsolescent usage.
871
872    (ii) Halve the number of productions here by eliminating the _sc/_nosc
873    distinction and instead checking where required that storage class
874    specifiers aren't present.  */
875
876 /* Declspecs which contain at least one type specifier or typedef name.
877    (Just `const' or `volatile' is not enough.)
878    A typedef'd name following these is taken as a name to be declared.
879    Declspecs have a non-NULL TREE_VALUE, attributes do not.  */
880
881 declspecs_nosc_nots_nosa_noea:
882           TYPE_QUAL
883                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
884                   TREE_STATIC ($$) = 1; }
885         | declspecs_nosc_nots_nosa_noea TYPE_QUAL
886                 { $$ = tree_cons (NULL_TREE, $2, $1);
887                   TREE_STATIC ($$) = 1; }
888         | declspecs_nosc_nots_nosa_ea TYPE_QUAL
889                 { $$ = tree_cons (NULL_TREE, $2, $1);
890                   TREE_STATIC ($$) = 1; }
891         ;
892
893 declspecs_nosc_nots_nosa_ea:
894           declspecs_nosc_nots_nosa_noea attributes
895                 { $$ = tree_cons ($2, NULL_TREE, $1);
896                   TREE_STATIC ($$) = TREE_STATIC ($1); }
897         ;
898
899 declspecs_nosc_nots_sa_noea:
900           declspecs_nosc_nots_sa_noea TYPE_QUAL
901                 { $$ = tree_cons (NULL_TREE, $2, $1);
902                   TREE_STATIC ($$) = 1; }
903         | declspecs_nosc_nots_sa_ea TYPE_QUAL
904                 { $$ = tree_cons (NULL_TREE, $2, $1);
905                   TREE_STATIC ($$) = 1; }
906         ;
907
908 declspecs_nosc_nots_sa_ea:
909           attributes
910                 { $$ = tree_cons ($1, NULL_TREE, NULL_TREE);
911                   TREE_STATIC ($$) = 0; }
912         | declspecs_nosc_nots_sa_noea attributes
913                 { $$ = tree_cons ($2, NULL_TREE, $1);
914                   TREE_STATIC ($$) = TREE_STATIC ($1); }
915         ;
916
917 declspecs_nosc_ts_nosa_noea:
918           typespec_nonattr
919                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
920                   TREE_STATIC ($$) = 1; }
921         | declspecs_nosc_ts_nosa_noea TYPE_QUAL
922                 { $$ = tree_cons (NULL_TREE, $2, $1);
923                   TREE_STATIC ($$) = 1; }
924         | declspecs_nosc_ts_nosa_ea TYPE_QUAL
925                 { $$ = tree_cons (NULL_TREE, $2, $1);
926                   TREE_STATIC ($$) = 1; }
927         | declspecs_nosc_ts_nosa_noea typespec_reserved_nonattr
928                 { $$ = tree_cons (NULL_TREE, $2, $1);
929                   TREE_STATIC ($$) = 1; }
930         | declspecs_nosc_ts_nosa_ea typespec_reserved_nonattr
931                 { $$ = tree_cons (NULL_TREE, $2, $1);
932                   TREE_STATIC ($$) = 1; }
933         | declspecs_nosc_nots_nosa_noea typespec_nonattr
934                 { $$ = tree_cons (NULL_TREE, $2, $1);
935                   TREE_STATIC ($$) = 1; }
936         | declspecs_nosc_nots_nosa_ea typespec_nonattr
937                 { $$ = tree_cons (NULL_TREE, $2, $1);
938                   TREE_STATIC ($$) = 1; }
939         ;
940
941 declspecs_nosc_ts_nosa_ea:
942           typespec_attr
943                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
944                   TREE_STATIC ($$) = 1; }
945         | declspecs_nosc_ts_nosa_noea attributes
946                 { $$ = tree_cons ($2, NULL_TREE, $1);
947                   TREE_STATIC ($$) = TREE_STATIC ($1); }
948         | declspecs_nosc_ts_nosa_noea typespec_reserved_attr
949                 { $$ = tree_cons (NULL_TREE, $2, $1);
950                   TREE_STATIC ($$) = 1; }
951         | declspecs_nosc_ts_nosa_ea typespec_reserved_attr
952                 { $$ = tree_cons (NULL_TREE, $2, $1);
953                   TREE_STATIC ($$) = 1; }
954         | declspecs_nosc_nots_nosa_noea typespec_attr
955                 { $$ = tree_cons (NULL_TREE, $2, $1);
956                   TREE_STATIC ($$) = 1; }
957         | declspecs_nosc_nots_nosa_ea typespec_attr
958                 { $$ = tree_cons (NULL_TREE, $2, $1);
959                   TREE_STATIC ($$) = 1; }
960         ;
961
962 declspecs_nosc_ts_sa_noea:
963           declspecs_nosc_ts_sa_noea TYPE_QUAL
964                 { $$ = tree_cons (NULL_TREE, $2, $1);
965                   TREE_STATIC ($$) = 1; }
966         | declspecs_nosc_ts_sa_ea TYPE_QUAL
967                 { $$ = tree_cons (NULL_TREE, $2, $1);
968                   TREE_STATIC ($$) = 1; }
969         | declspecs_nosc_ts_sa_noea typespec_reserved_nonattr
970                 { $$ = tree_cons (NULL_TREE, $2, $1);
971                   TREE_STATIC ($$) = 1; }
972         | declspecs_nosc_ts_sa_ea typespec_reserved_nonattr
973                 { $$ = tree_cons (NULL_TREE, $2, $1);
974                   TREE_STATIC ($$) = 1; }
975         | declspecs_nosc_nots_sa_noea typespec_nonattr
976                 { $$ = tree_cons (NULL_TREE, $2, $1);
977                   TREE_STATIC ($$) = 1; }
978         | declspecs_nosc_nots_sa_ea typespec_nonattr
979                 { $$ = tree_cons (NULL_TREE, $2, $1);
980                   TREE_STATIC ($$) = 1; }
981         ;
982
983 declspecs_nosc_ts_sa_ea:
984           declspecs_nosc_ts_sa_noea attributes
985                 { $$ = tree_cons ($2, NULL_TREE, $1);
986                   TREE_STATIC ($$) = TREE_STATIC ($1); }
987         | declspecs_nosc_ts_sa_noea typespec_reserved_attr
988                 { $$ = tree_cons (NULL_TREE, $2, $1);
989                   TREE_STATIC ($$) = 1; }
990         | declspecs_nosc_ts_sa_ea typespec_reserved_attr
991                 { $$ = tree_cons (NULL_TREE, $2, $1);
992                   TREE_STATIC ($$) = 1; }
993         | declspecs_nosc_nots_sa_noea typespec_attr
994                 { $$ = tree_cons (NULL_TREE, $2, $1);
995                   TREE_STATIC ($$) = 1; }
996         | declspecs_nosc_nots_sa_ea typespec_attr
997                 { $$ = tree_cons (NULL_TREE, $2, $1);
998                   TREE_STATIC ($$) = 1; }
999         ;
1000
1001 declspecs_sc_nots_nosa_noea:
1002           scspec
1003                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
1004                   TREE_STATIC ($$) = 0; }
1005         | declspecs_sc_nots_nosa_noea TYPE_QUAL
1006                 { $$ = tree_cons (NULL_TREE, $2, $1);
1007                   TREE_STATIC ($$) = 1; }
1008         | declspecs_sc_nots_nosa_ea TYPE_QUAL
1009                 { $$ = tree_cons (NULL_TREE, $2, $1);
1010                   TREE_STATIC ($$) = 1; }
1011         | declspecs_nosc_nots_nosa_noea scspec
1012                 { if (extra_warnings && TREE_STATIC ($1))
1013                     warning ("`%s' is not at beginning of declaration",
1014                              IDENTIFIER_POINTER ($2));
1015                   $$ = tree_cons (NULL_TREE, $2, $1);
1016                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1017         | declspecs_nosc_nots_nosa_ea scspec
1018                 { if (extra_warnings && TREE_STATIC ($1))
1019                     warning ("`%s' is not at beginning of declaration",
1020                              IDENTIFIER_POINTER ($2));
1021                   $$ = tree_cons (NULL_TREE, $2, $1);
1022                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1023         | declspecs_sc_nots_nosa_noea scspec
1024                 { if (extra_warnings && TREE_STATIC ($1))
1025                     warning ("`%s' is not at beginning of declaration",
1026                              IDENTIFIER_POINTER ($2));
1027                   $$ = tree_cons (NULL_TREE, $2, $1);
1028                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1029         | declspecs_sc_nots_nosa_ea scspec
1030                 { if (extra_warnings && TREE_STATIC ($1))
1031                     warning ("`%s' is not at beginning of declaration",
1032                              IDENTIFIER_POINTER ($2));
1033                   $$ = tree_cons (NULL_TREE, $2, $1);
1034                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1035         ;
1036
1037 declspecs_sc_nots_nosa_ea:
1038           declspecs_sc_nots_nosa_noea attributes
1039                 { $$ = tree_cons ($2, NULL_TREE, $1);
1040                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1041         ;
1042
1043 declspecs_sc_nots_sa_noea:
1044           declspecs_sc_nots_sa_noea TYPE_QUAL
1045                 { $$ = tree_cons (NULL_TREE, $2, $1);
1046                   TREE_STATIC ($$) = 1; }
1047         | declspecs_sc_nots_sa_ea TYPE_QUAL
1048                 { $$ = tree_cons (NULL_TREE, $2, $1);
1049                   TREE_STATIC ($$) = 1; }
1050         | declspecs_nosc_nots_sa_noea scspec
1051                 { if (extra_warnings && TREE_STATIC ($1))
1052                     warning ("`%s' is not at beginning of declaration",
1053                              IDENTIFIER_POINTER ($2));
1054                   $$ = tree_cons (NULL_TREE, $2, $1);
1055                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1056         | declspecs_nosc_nots_sa_ea scspec
1057                 { if (extra_warnings && TREE_STATIC ($1))
1058                     warning ("`%s' is not at beginning of declaration",
1059                              IDENTIFIER_POINTER ($2));
1060                   $$ = tree_cons (NULL_TREE, $2, $1);
1061                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1062         | declspecs_sc_nots_sa_noea scspec
1063                 { if (extra_warnings && TREE_STATIC ($1))
1064                     warning ("`%s' is not at beginning of declaration",
1065                              IDENTIFIER_POINTER ($2));
1066                   $$ = tree_cons (NULL_TREE, $2, $1);
1067                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1068         | declspecs_sc_nots_sa_ea scspec
1069                 { if (extra_warnings && TREE_STATIC ($1))
1070                     warning ("`%s' is not at beginning of declaration",
1071                              IDENTIFIER_POINTER ($2));
1072                   $$ = tree_cons (NULL_TREE, $2, $1);
1073                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1074         ;
1075
1076 declspecs_sc_nots_sa_ea:
1077           declspecs_sc_nots_sa_noea attributes
1078                 { $$ = tree_cons ($2, NULL_TREE, $1);
1079                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1080         ;
1081
1082 declspecs_sc_ts_nosa_noea:
1083           declspecs_sc_ts_nosa_noea TYPE_QUAL
1084                 { $$ = tree_cons (NULL_TREE, $2, $1);
1085                   TREE_STATIC ($$) = 1; }
1086         | declspecs_sc_ts_nosa_ea TYPE_QUAL
1087                 { $$ = tree_cons (NULL_TREE, $2, $1);
1088                   TREE_STATIC ($$) = 1; }
1089         | declspecs_sc_ts_nosa_noea typespec_reserved_nonattr
1090                 { $$ = tree_cons (NULL_TREE, $2, $1);
1091                   TREE_STATIC ($$) = 1; }
1092         | declspecs_sc_ts_nosa_ea typespec_reserved_nonattr
1093                 { $$ = tree_cons (NULL_TREE, $2, $1);
1094                   TREE_STATIC ($$) = 1; }
1095         | declspecs_sc_nots_nosa_noea typespec_nonattr
1096                 { $$ = tree_cons (NULL_TREE, $2, $1);
1097                   TREE_STATIC ($$) = 1; }
1098         | declspecs_sc_nots_nosa_ea typespec_nonattr
1099                 { $$ = tree_cons (NULL_TREE, $2, $1);
1100                   TREE_STATIC ($$) = 1; }
1101         | declspecs_nosc_ts_nosa_noea scspec
1102                 { if (extra_warnings && TREE_STATIC ($1))
1103                     warning ("`%s' is not at beginning of declaration",
1104                              IDENTIFIER_POINTER ($2));
1105                   $$ = tree_cons (NULL_TREE, $2, $1);
1106                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1107         | declspecs_nosc_ts_nosa_ea scspec
1108                 { if (extra_warnings && TREE_STATIC ($1))
1109                     warning ("`%s' is not at beginning of declaration",
1110                              IDENTIFIER_POINTER ($2));
1111                   $$ = tree_cons (NULL_TREE, $2, $1);
1112                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1113         | declspecs_sc_ts_nosa_noea scspec
1114                 { if (extra_warnings && TREE_STATIC ($1))
1115                     warning ("`%s' is not at beginning of declaration",
1116                              IDENTIFIER_POINTER ($2));
1117                   $$ = tree_cons (NULL_TREE, $2, $1);
1118                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1119         | declspecs_sc_ts_nosa_ea scspec
1120                 { if (extra_warnings && TREE_STATIC ($1))
1121                     warning ("`%s' is not at beginning of declaration",
1122                              IDENTIFIER_POINTER ($2));
1123                   $$ = tree_cons (NULL_TREE, $2, $1);
1124                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1125         ;
1126
1127 declspecs_sc_ts_nosa_ea:
1128           declspecs_sc_ts_nosa_noea attributes
1129                 { $$ = tree_cons ($2, NULL_TREE, $1);
1130                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1131         | declspecs_sc_ts_nosa_noea typespec_reserved_attr
1132                 { $$ = tree_cons (NULL_TREE, $2, $1);
1133                   TREE_STATIC ($$) = 1; }
1134         | declspecs_sc_ts_nosa_ea typespec_reserved_attr
1135                 { $$ = tree_cons (NULL_TREE, $2, $1);
1136                   TREE_STATIC ($$) = 1; }
1137         | declspecs_sc_nots_nosa_noea typespec_attr
1138                 { $$ = tree_cons (NULL_TREE, $2, $1);
1139                   TREE_STATIC ($$) = 1; }
1140         | declspecs_sc_nots_nosa_ea typespec_attr
1141                 { $$ = tree_cons (NULL_TREE, $2, $1);
1142                   TREE_STATIC ($$) = 1; }
1143         ;
1144
1145 declspecs_sc_ts_sa_noea:
1146           declspecs_sc_ts_sa_noea TYPE_QUAL
1147                 { $$ = tree_cons (NULL_TREE, $2, $1);
1148                   TREE_STATIC ($$) = 1; }
1149         | declspecs_sc_ts_sa_ea TYPE_QUAL
1150                 { $$ = tree_cons (NULL_TREE, $2, $1);
1151                   TREE_STATIC ($$) = 1; }
1152         | declspecs_sc_ts_sa_noea typespec_reserved_nonattr
1153                 { $$ = tree_cons (NULL_TREE, $2, $1);
1154                   TREE_STATIC ($$) = 1; }
1155         | declspecs_sc_ts_sa_ea typespec_reserved_nonattr
1156                 { $$ = tree_cons (NULL_TREE, $2, $1);
1157                   TREE_STATIC ($$) = 1; }
1158         | declspecs_sc_nots_sa_noea typespec_nonattr
1159                 { $$ = tree_cons (NULL_TREE, $2, $1);
1160                   TREE_STATIC ($$) = 1; }
1161         | declspecs_sc_nots_sa_ea typespec_nonattr
1162                 { $$ = tree_cons (NULL_TREE, $2, $1);
1163                   TREE_STATIC ($$) = 1; }
1164         | declspecs_nosc_ts_sa_noea scspec
1165                 { if (extra_warnings && TREE_STATIC ($1))
1166                     warning ("`%s' is not at beginning of declaration",
1167                              IDENTIFIER_POINTER ($2));
1168                   $$ = tree_cons (NULL_TREE, $2, $1);
1169                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1170         | declspecs_nosc_ts_sa_ea scspec
1171                 { if (extra_warnings && TREE_STATIC ($1))
1172                     warning ("`%s' is not at beginning of declaration",
1173                              IDENTIFIER_POINTER ($2));
1174                   $$ = tree_cons (NULL_TREE, $2, $1);
1175                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1176         | declspecs_sc_ts_sa_noea scspec
1177                 { if (extra_warnings && TREE_STATIC ($1))
1178                     warning ("`%s' is not at beginning of declaration",
1179                              IDENTIFIER_POINTER ($2));
1180                   $$ = tree_cons (NULL_TREE, $2, $1);
1181                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1182         | declspecs_sc_ts_sa_ea scspec
1183                 { if (extra_warnings && TREE_STATIC ($1))
1184                     warning ("`%s' is not at beginning of declaration",
1185                              IDENTIFIER_POINTER ($2));
1186                   $$ = tree_cons (NULL_TREE, $2, $1);
1187                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1188         ;
1189
1190 declspecs_sc_ts_sa_ea:
1191           declspecs_sc_ts_sa_noea attributes
1192                 { $$ = tree_cons ($2, NULL_TREE, $1);
1193                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1194         | declspecs_sc_ts_sa_noea typespec_reserved_attr
1195                 { $$ = tree_cons (NULL_TREE, $2, $1);
1196                   TREE_STATIC ($$) = 1; }
1197         | declspecs_sc_ts_sa_ea typespec_reserved_attr
1198                 { $$ = tree_cons (NULL_TREE, $2, $1);
1199                   TREE_STATIC ($$) = 1; }
1200         | declspecs_sc_nots_sa_noea typespec_attr
1201                 { $$ = tree_cons (NULL_TREE, $2, $1);
1202                   TREE_STATIC ($$) = 1; }
1203         | declspecs_sc_nots_sa_ea typespec_attr
1204                 { $$ = tree_cons (NULL_TREE, $2, $1);
1205                   TREE_STATIC ($$) = 1; }
1206         ;
1207
1208 /* Particular useful classes of declspecs.  */
1209 declspecs_ts:
1210           declspecs_nosc_ts_nosa_noea
1211         | declspecs_nosc_ts_nosa_ea
1212         | declspecs_nosc_ts_sa_noea
1213         | declspecs_nosc_ts_sa_ea
1214         | declspecs_sc_ts_nosa_noea
1215         | declspecs_sc_ts_nosa_ea
1216         | declspecs_sc_ts_sa_noea
1217         | declspecs_sc_ts_sa_ea
1218         ;
1219
1220 declspecs_nots:
1221           declspecs_nosc_nots_nosa_noea
1222         | declspecs_nosc_nots_nosa_ea
1223         | declspecs_nosc_nots_sa_noea
1224         | declspecs_nosc_nots_sa_ea
1225         | declspecs_sc_nots_nosa_noea
1226         | declspecs_sc_nots_nosa_ea
1227         | declspecs_sc_nots_sa_noea
1228         | declspecs_sc_nots_sa_ea
1229         ;
1230
1231 declspecs_ts_nosa:
1232           declspecs_nosc_ts_nosa_noea
1233         | declspecs_nosc_ts_nosa_ea
1234         | declspecs_sc_ts_nosa_noea
1235         | declspecs_sc_ts_nosa_ea
1236         ;
1237
1238 declspecs_nots_nosa:
1239           declspecs_nosc_nots_nosa_noea
1240         | declspecs_nosc_nots_nosa_ea
1241         | declspecs_sc_nots_nosa_noea
1242         | declspecs_sc_nots_nosa_ea
1243         ;
1244
1245 declspecs_nosc_ts:
1246           declspecs_nosc_ts_nosa_noea
1247         | declspecs_nosc_ts_nosa_ea
1248         | declspecs_nosc_ts_sa_noea
1249         | declspecs_nosc_ts_sa_ea
1250         ;
1251
1252 declspecs_nosc_nots:
1253           declspecs_nosc_nots_nosa_noea
1254         | declspecs_nosc_nots_nosa_ea
1255         | declspecs_nosc_nots_sa_noea
1256         | declspecs_nosc_nots_sa_ea
1257         ;
1258
1259 declspecs_nosc:
1260           declspecs_nosc_ts_nosa_noea
1261         | declspecs_nosc_ts_nosa_ea
1262         | declspecs_nosc_ts_sa_noea
1263         | declspecs_nosc_ts_sa_ea
1264         | declspecs_nosc_nots_nosa_noea
1265         | declspecs_nosc_nots_nosa_ea
1266         | declspecs_nosc_nots_sa_noea
1267         | declspecs_nosc_nots_sa_ea
1268         ;
1269
1270 declspecs:
1271           declspecs_nosc_nots_nosa_noea
1272         | declspecs_nosc_nots_nosa_ea
1273         | declspecs_nosc_nots_sa_noea
1274         | declspecs_nosc_nots_sa_ea
1275         | declspecs_nosc_ts_nosa_noea
1276         | declspecs_nosc_ts_nosa_ea
1277         | declspecs_nosc_ts_sa_noea
1278         | declspecs_nosc_ts_sa_ea
1279         | declspecs_sc_nots_nosa_noea
1280         | declspecs_sc_nots_nosa_ea
1281         | declspecs_sc_nots_sa_noea
1282         | declspecs_sc_nots_sa_ea
1283         | declspecs_sc_ts_nosa_noea
1284         | declspecs_sc_ts_nosa_ea
1285         | declspecs_sc_ts_sa_noea
1286         | declspecs_sc_ts_sa_ea
1287         ;
1288
1289 /* A (possibly empty) sequence of type qualifiers and attributes.  */
1290 maybe_type_quals_attrs:
1291           /* empty */
1292                 { $$ = NULL_TREE; }
1293         | declspecs_nosc_nots
1294                 { $$ = $1; }
1295         ;
1296
1297 /* A type specifier (but not a type qualifier).
1298    Once we have seen one of these in a declaration,
1299    if a typedef name appears then it is being redeclared.
1300
1301    The _reserved versions start with a reserved word and may appear anywhere
1302    in the declaration specifiers; the _nonreserved versions may only
1303    appear before any other type specifiers, and after that are (if names)
1304    being redeclared.
1305
1306    FIXME: should the _nonreserved version be restricted to names being
1307    redeclared only?  The other entries there relate only the GNU extensions
1308    and Objective C, and are historically parsed thus, and don't make sense
1309    after other type specifiers, but it might be cleaner to count them as
1310    _reserved.
1311
1312    _attr means: specifiers that either end with attributes,
1313    or are such that any following attributes would
1314    be parsed as part of the specifier.
1315
1316    _nonattr: specifiers.  */
1317
1318 typespec_nonattr:
1319           typespec_reserved_nonattr
1320         | typespec_nonreserved_nonattr
1321         ;
1322
1323 typespec_attr:
1324           typespec_reserved_attr
1325         ;
1326
1327 typespec_reserved_nonattr:
1328           TYPESPEC
1329                 { OBJC_NEED_RAW_IDENTIFIER (1); }
1330         | structsp_nonattr
1331         ;
1332
1333 typespec_reserved_attr:
1334           structsp_attr
1335         ;
1336
1337 typespec_nonreserved_nonattr:
1338           TYPENAME
1339                 { /* For a typedef name, record the meaning, not the name.
1340                      In case of `foo foo, bar;'.  */
1341                   $$ = lookup_name ($1); }
1342 @@ifobjc
1343         | CLASSNAME protocolrefs
1344                 { $$ = get_static_reference ($1, $2); }
1345         | OBJECTNAME protocolrefs
1346                 { $$ = get_object_reference ($2); }
1347
1348 /* Make "<SomeProtocol>" equivalent to "id <SomeProtocol>"
1349    - nisse@lysator.liu.se */
1350         | non_empty_protocolrefs
1351                 { $$ = get_object_reference ($1); }
1352 @@end_ifobjc
1353         | typeof '(' expr ')'
1354                 { skip_evaluation--;
1355                   if (TREE_CODE ($3) == COMPONENT_REF
1356                       && DECL_C_BIT_FIELD (TREE_OPERAND ($3, 1)))
1357                     error ("`typeof' applied to a bit-field");
1358                   $$ = TREE_TYPE ($3); }
1359         | typeof '(' typename ')'
1360                 { skip_evaluation--; $$ = groktypename ($3); }
1361         ;
1362
1363 /* typespec_nonreserved_attr does not exist.  */
1364
1365 initdecls:
1366         initdcl
1367         | initdecls ',' maybe_resetattrs initdcl
1368         ;
1369
1370 notype_initdecls:
1371         notype_initdcl
1372         | notype_initdecls ',' maybe_resetattrs notype_initdcl
1373         ;
1374
1375 initdcl:
1376           declarator maybeasm maybe_attribute '='
1377                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1378                                           chainon ($3, all_prefix_attributes));
1379                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1380           init
1381 /* Note how the declaration of the variable is in effect while its init is parsed! */
1382                 { finish_init ();
1383                   finish_decl ($<ttype>5, $6, $2); }
1384         | declarator maybeasm maybe_attribute
1385                 { tree d = start_decl ($1, current_declspecs, 0,
1386                                        chainon ($3, all_prefix_attributes));
1387                   finish_decl (d, NULL_TREE, $2);
1388                 }
1389         ;
1390
1391 notype_initdcl:
1392           notype_declarator maybeasm maybe_attribute '='
1393                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1394                                           chainon ($3, all_prefix_attributes));
1395                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1396           init
1397 /* Note how the declaration of the variable is in effect while its init is parsed! */
1398                 { finish_init ();
1399                   finish_decl ($<ttype>5, $6, $2); }
1400         | notype_declarator maybeasm maybe_attribute
1401                 { tree d = start_decl ($1, current_declspecs, 0,
1402                                        chainon ($3, all_prefix_attributes));
1403                   finish_decl (d, NULL_TREE, $2); }
1404         ;
1405 /* the * rules are dummies to accept the Apollo extended syntax
1406    so that the header files compile. */
1407 maybe_attribute:
1408       /* empty */
1409                 { $$ = NULL_TREE; }
1410         | attributes
1411                 { $$ = $1; }
1412         ;
1413
1414 attributes:
1415       attribute
1416                 { $$ = $1; }
1417         | attributes attribute
1418                 { $$ = chainon ($1, $2); }
1419         ;
1420
1421 attribute:
1422       ATTRIBUTE stop_string_translation
1423                 '(' '(' attribute_list ')' ')' start_string_translation
1424                 { $$ = $5; }
1425       | ATTRIBUTE error start_string_translation
1426                 {}
1427         ;
1428
1429 attribute_list:
1430       attrib
1431                 { $$ = $1; }
1432         | attribute_list ',' attrib
1433                 { $$ = chainon ($1, $3); }
1434         ;
1435
1436 attrib:
1437     /* empty */
1438                 { $$ = NULL_TREE; }
1439         | any_word
1440                 { $$ = build_tree_list ($1, NULL_TREE); }
1441         | any_word '(' IDENTIFIER ')'
1442                 { $$ = build_tree_list ($1, build_tree_list (NULL_TREE, $3)); }
1443         | any_word '(' IDENTIFIER ',' nonnull_exprlist ')'
1444                 { $$ = build_tree_list ($1, tree_cons (NULL_TREE, $3, $5)); }
1445         | any_word '(' exprlist ')'
1446                 { $$ = build_tree_list ($1, $3); }
1447         ;
1448
1449 /* This still leaves out most reserved keywords,
1450    shouldn't we include them?  */
1451
1452 any_word:
1453           identifier
1454         | scspec
1455         | TYPESPEC
1456         | TYPE_QUAL
1457         ;
1458
1459 scspec:
1460           STATIC
1461         | SCSPEC
1462         ;
1463 \f
1464 /* Initializers.  `init' is the entry point.  */
1465
1466 init:
1467         expr_no_commas
1468         | '{'
1469                 { really_start_incremental_init (NULL_TREE); }
1470           initlist_maybe_comma '}'
1471                 { $$ = pop_init_level (0); }
1472         | error
1473                 { $$ = error_mark_node; }
1474         ;
1475
1476 /* `initlist_maybe_comma' is the guts of an initializer in braces.  */
1477 initlist_maybe_comma:
1478           /* empty */
1479                 { if (pedantic)
1480                     pedwarn ("ISO C forbids empty initializer braces"); }
1481         | initlist1 maybecomma
1482         ;
1483
1484 initlist1:
1485           initelt
1486         | initlist1 ',' initelt
1487         ;
1488
1489 /* `initelt' is a single element of an initializer.
1490    It may use braces.  */
1491 initelt:
1492           designator_list '=' initval
1493                 { if (pedantic && ! flag_isoc99)
1494                     pedwarn ("ISO C90 forbids specifying subobject to initialize"); }
1495         | designator initval
1496                 { if (pedantic)
1497                     pedwarn ("obsolete use of designated initializer without `='"); }
1498         | identifier ':'
1499                 { set_init_label ($1);
1500                   if (pedantic)
1501                     pedwarn ("obsolete use of designated initializer with `:'"); }
1502           initval
1503                 {}
1504         | initval
1505         ;
1506
1507 initval:
1508           '{'
1509                 { push_init_level (0); }
1510           initlist_maybe_comma '}'
1511                 { process_init_element (pop_init_level (0)); }
1512         | expr_no_commas
1513                 { process_init_element ($1); }
1514         | error
1515         ;
1516
1517 designator_list:
1518           designator
1519         | designator_list designator
1520         ;
1521
1522 designator:
1523           '.' identifier
1524                 { set_init_label ($2); }
1525         | '[' expr_no_commas ELLIPSIS expr_no_commas ']'
1526                 { set_init_index ($2, $4);
1527                   if (pedantic)
1528                     pedwarn ("ISO C forbids specifying range of elements to initialize"); }
1529         | '[' expr_no_commas ']'
1530                 { set_init_index ($2, NULL_TREE); }
1531         ;
1532 \f
1533 nested_function:
1534           declarator
1535                 { if (pedantic)
1536                     pedwarn ("ISO C forbids nested functions");
1537
1538                   push_function_context ();
1539                   if (! start_function (current_declspecs, $1,
1540                                         all_prefix_attributes))
1541                     {
1542                       pop_function_context ();
1543                       YYERROR1;
1544                     }
1545                 }
1546            old_style_parm_decls save_location
1547                 { tree decl = current_function_decl;
1548                   DECL_SOURCE_LOCATION (decl) = $4;
1549                   store_parm_decls (); }
1550 /* This used to use compstmt_or_error.
1551    That caused a bug with input `f(g) int g {}',
1552    where the use of YYERROR1 above caused an error
1553    which then was handled by compstmt_or_error.
1554    There followed a repeated execution of that same rule,
1555    which called YYERROR1 again, and so on.  */
1556           compstmt
1557                 { tree decl = current_function_decl;
1558                   finish_function ();
1559                   pop_function_context ();
1560                   add_decl_stmt (decl); }
1561         ;
1562
1563 notype_nested_function:
1564           notype_declarator
1565                 { if (pedantic)
1566                     pedwarn ("ISO C forbids nested functions");
1567
1568                   push_function_context ();
1569                   if (! start_function (current_declspecs, $1,
1570                                         all_prefix_attributes))
1571                     {
1572                       pop_function_context ();
1573                       YYERROR1;
1574                     }
1575                 }
1576           old_style_parm_decls save_location
1577                 { tree decl = current_function_decl;
1578                   DECL_SOURCE_LOCATION (decl) = $4;
1579                   store_parm_decls (); }
1580 /* This used to use compstmt_or_error.
1581    That caused a bug with input `f(g) int g {}',
1582    where the use of YYERROR1 above caused an error
1583    which then was handled by compstmt_or_error.
1584    There followed a repeated execution of that same rule,
1585    which called YYERROR1 again, and so on.  */
1586           compstmt
1587                 { tree decl = current_function_decl;
1588                   finish_function ();
1589                   pop_function_context ();
1590                   add_decl_stmt (decl); }
1591         ;
1592
1593 /* Any kind of declarator (thus, all declarators allowed
1594    after an explicit typespec).  */
1595
1596 declarator:
1597           after_type_declarator
1598         | notype_declarator
1599         ;
1600
1601 /* A declarator that is allowed only after an explicit typespec.  */
1602
1603 after_type_declarator:
1604           '(' maybe_attribute after_type_declarator ')'
1605                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1606         | after_type_declarator '(' parmlist_or_identifiers  %prec '.'
1607                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1608         | after_type_declarator array_declarator  %prec '.'
1609                 { $$ = set_array_declarator_type ($2, $1, 0); }
1610         | '*' maybe_type_quals_attrs after_type_declarator  %prec UNARY
1611                 { $$ = make_pointer_declarator ($2, $3); }
1612         | TYPENAME
1613 @@ifobjc
1614         | OBJECTNAME
1615 @@end_ifobjc
1616         ;
1617
1618 /* Kinds of declarator that can appear in a parameter list
1619    in addition to notype_declarator.  This is like after_type_declarator
1620    but does not allow a typedef name in parentheses as an identifier
1621    (because it would conflict with a function with that typedef as arg).  */
1622 parm_declarator:
1623           parm_declarator_starttypename
1624         | parm_declarator_nostarttypename
1625         ;
1626
1627 parm_declarator_starttypename:
1628           parm_declarator_starttypename '(' parmlist_or_identifiers  %prec '.'
1629                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1630         | parm_declarator_starttypename array_declarator  %prec '.'
1631                 { $$ = set_array_declarator_type ($2, $1, 0); }
1632         | TYPENAME
1633 @@ifobjc
1634         | OBJECTNAME
1635 @@end_ifobjc
1636         ;
1637
1638 parm_declarator_nostarttypename:
1639           parm_declarator_nostarttypename '(' parmlist_or_identifiers  %prec '.'
1640                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1641         | parm_declarator_nostarttypename array_declarator  %prec '.'
1642                 { $$ = set_array_declarator_type ($2, $1, 0); }
1643         | '*' maybe_type_quals_attrs parm_declarator_starttypename  %prec UNARY
1644                 { $$ = make_pointer_declarator ($2, $3); }
1645         | '*' maybe_type_quals_attrs parm_declarator_nostarttypename  %prec UNARY
1646                 { $$ = make_pointer_declarator ($2, $3); }
1647         | '(' maybe_attribute parm_declarator_nostarttypename ')'
1648                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1649         ;
1650
1651 /* A declarator allowed whether or not there has been
1652    an explicit typespec.  These cannot redeclare a typedef-name.  */
1653
1654 notype_declarator:
1655           notype_declarator '(' parmlist_or_identifiers  %prec '.'
1656                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1657         | '(' maybe_attribute notype_declarator ')'
1658                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1659         | '*' maybe_type_quals_attrs notype_declarator  %prec UNARY
1660                 { $$ = make_pointer_declarator ($2, $3); }
1661         | notype_declarator array_declarator  %prec '.'
1662                 { $$ = set_array_declarator_type ($2, $1, 0); }
1663         | IDENTIFIER
1664         ;
1665
1666 struct_head:
1667           STRUCT
1668                 { $$ = NULL_TREE; }
1669         | STRUCT attributes
1670                 { $$ = $2; }
1671         ;
1672
1673 union_head:
1674           UNION
1675                 { $$ = NULL_TREE; }
1676         | UNION attributes
1677                 { $$ = $2; }
1678         ;
1679
1680 enum_head:
1681           ENUM
1682                 { $$ = NULL_TREE; }
1683         | ENUM attributes
1684                 { $$ = $2; }
1685         ;
1686
1687 /* structsp_attr: struct/union/enum specifiers that either
1688    end with attributes, or are such that any following attributes would
1689    be parsed as part of the struct/union/enum specifier.
1690
1691    structsp_nonattr: other struct/union/enum specifiers.  */
1692
1693 structsp_attr:
1694           struct_head identifier '{'
1695                 { $$ = start_struct (RECORD_TYPE, $2);
1696                   /* Start scope of tag before parsing components.  */
1697                 }
1698           component_decl_list '}' maybe_attribute
1699                 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1700                                       chainon ($1, $7)); }
1701         | struct_head '{' component_decl_list '}' maybe_attribute
1702                 { $$ = finish_struct (start_struct (RECORD_TYPE, NULL_TREE),
1703                                       nreverse ($3), chainon ($1, $5));
1704                 }
1705         | union_head identifier '{'
1706                 { $$ = start_struct (UNION_TYPE, $2); }
1707           component_decl_list '}' maybe_attribute
1708                 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1709                                       chainon ($1, $7)); }
1710         | union_head '{' component_decl_list '}' maybe_attribute
1711                 { $$ = finish_struct (start_struct (UNION_TYPE, NULL_TREE),
1712                                       nreverse ($3), chainon ($1, $5));
1713                 }
1714         | enum_head identifier '{'
1715                 { $$ = start_enum ($2); }
1716           enumlist maybecomma_warn '}' maybe_attribute
1717                 { $$ = finish_enum ($<ttype>4, nreverse ($5),
1718                                     chainon ($1, $8)); }
1719         | enum_head '{'
1720                 { $$ = start_enum (NULL_TREE); }
1721           enumlist maybecomma_warn '}' maybe_attribute
1722                 { $$ = finish_enum ($<ttype>3, nreverse ($4),
1723                                     chainon ($1, $7)); }
1724         ;
1725
1726 structsp_nonattr:
1727           struct_head identifier
1728                 { $$ = xref_tag (RECORD_TYPE, $2); }
1729         | union_head identifier
1730                 { $$ = xref_tag (UNION_TYPE, $2); }
1731         | enum_head identifier
1732                 { $$ = xref_tag (ENUMERAL_TYPE, $2);
1733                   /* In ISO C, enumerated types can be referred to
1734                      only if already defined.  */
1735                   if (pedantic && !COMPLETE_TYPE_P ($$))
1736                     pedwarn ("ISO C forbids forward references to `enum' types"); }
1737         ;
1738
1739 maybecomma:
1740           /* empty */
1741         | ','
1742         ;
1743
1744 maybecomma_warn:
1745           /* empty */
1746         | ','
1747                 { if (pedantic && ! flag_isoc99)
1748                     pedwarn ("comma at end of enumerator list"); }
1749         ;
1750
1751 /* We chain the components in reverse order.  They are put in forward
1752    order in structsp_attr.
1753
1754    Note that component_declarator returns single decls, so components
1755    and components_notype can use TREE_CHAIN directly, wheras components
1756    and components_notype return lists (of comma separated decls), so
1757    component_decl_list and component_decl_list2 must use chainon.
1758
1759    The theory behind all this is that there will be more semicolon
1760    separated fields than comma separated fields, and so we'll be
1761    minimizing the number of node traversals required by chainon.  */
1762
1763 component_decl_list:
1764           component_decl_list2
1765                 { $$ = $1; }
1766         | component_decl_list2 component_decl
1767                 { $$ = chainon ($2, $1);
1768                   pedwarn ("no semicolon at end of struct or union"); }
1769         ;
1770
1771 component_decl_list2:   /* empty */
1772                 { $$ = NULL_TREE; }
1773         | component_decl_list2 component_decl ';'
1774                 { $$ = chainon ($2, $1); }
1775         | component_decl_list2 ';'
1776                 { if (pedantic)
1777                     pedwarn ("extra semicolon in struct or union specified"); }
1778 @@ifobjc
1779         /* foo(sizeof(struct{ @defs(ClassName)})); */
1780         | DEFS '(' CLASSNAME ')'
1781                 { $$ = nreverse (get_class_ivars_from_name ($3)); }
1782 @@end_ifobjc
1783         ;
1784
1785 component_decl:
1786           declspecs_nosc_ts setspecs components
1787                 { $$ = $3;
1788                   POP_DECLSPEC_STACK; }
1789         | declspecs_nosc_ts setspecs
1790                 {
1791                   /* Support for unnamed structs or unions as members of
1792                      structs or unions (which is [a] useful and [b] supports
1793                      MS P-SDK).  */
1794                   if (pedantic)
1795                     pedwarn ("ISO C doesn't support unnamed structs/unions");
1796
1797                   $$ = grokfield(NULL, current_declspecs, NULL_TREE);
1798                   POP_DECLSPEC_STACK; }
1799         | declspecs_nosc_nots setspecs components_notype
1800                 { $$ = $3;
1801                   POP_DECLSPEC_STACK; }
1802         | declspecs_nosc_nots
1803                 { if (pedantic)
1804                     pedwarn ("ISO C forbids member declarations with no members");
1805                   shadow_tag_warned ($1, pedantic);
1806                   $$ = NULL_TREE; }
1807         | error
1808                 { $$ = NULL_TREE; }
1809         | extension component_decl
1810                 { $$ = $2;
1811                   RESTORE_EXT_FLAGS ($1); }
1812         ;
1813
1814 components:
1815           component_declarator
1816         | components ',' maybe_resetattrs component_declarator
1817                 { TREE_CHAIN ($4) = $1; $$ = $4; }
1818         ;
1819
1820 components_notype:
1821           component_notype_declarator
1822         | components_notype ',' maybe_resetattrs component_notype_declarator
1823                 { TREE_CHAIN ($4) = $1; $$ = $4; }
1824         ;
1825
1826 component_declarator:
1827           declarator maybe_attribute
1828                 { $$ = grokfield ($1, current_declspecs, NULL_TREE);
1829                   decl_attributes (&$$,
1830                                    chainon ($2, all_prefix_attributes), 0); }
1831         | declarator ':' expr_no_commas maybe_attribute
1832                 { $$ = grokfield ($1, current_declspecs, $3);
1833                   decl_attributes (&$$,
1834                                    chainon ($4, all_prefix_attributes), 0); }
1835         | ':' expr_no_commas maybe_attribute
1836                 { $$ = grokfield (NULL_TREE, current_declspecs, $2);
1837                   decl_attributes (&$$,
1838                                    chainon ($3, all_prefix_attributes), 0); }
1839         ;
1840
1841 component_notype_declarator:
1842           notype_declarator maybe_attribute
1843                 { $$ = grokfield ($1, current_declspecs, NULL_TREE);
1844                   decl_attributes (&$$,
1845                                    chainon ($2, all_prefix_attributes), 0); }
1846         | notype_declarator ':' expr_no_commas maybe_attribute
1847                 { $$ = grokfield ($1, current_declspecs, $3);
1848                   decl_attributes (&$$,
1849                                    chainon ($4, all_prefix_attributes), 0); }
1850         | ':' expr_no_commas maybe_attribute
1851                 { $$ = grokfield (NULL_TREE, current_declspecs, $2);
1852                   decl_attributes (&$$,
1853                                    chainon ($3, all_prefix_attributes), 0); }
1854         ;
1855
1856 /* We chain the enumerators in reverse order.
1857    They are put in forward order in structsp_attr.  */
1858
1859 enumlist:
1860           enumerator
1861         | enumlist ',' enumerator
1862                 { if ($1 == error_mark_node)
1863                     $$ = $1;
1864                   else
1865                     TREE_CHAIN ($3) = $1, $$ = $3; }
1866         | error
1867                 { $$ = error_mark_node; }
1868         ;
1869
1870
1871 enumerator:
1872           identifier
1873                 { $$ = build_enumerator ($1, NULL_TREE); }
1874         | identifier '=' expr_no_commas
1875                 { $$ = build_enumerator ($1, $3); }
1876         ;
1877
1878 typename:
1879           declspecs_nosc
1880                 { pending_xref_error ();
1881                   $<ttype>$ = $1; }
1882           absdcl
1883                 { $$ = build_tree_list ($<ttype>2, $3); }
1884         ;
1885
1886 absdcl:   /* an absolute declarator */
1887         /* empty */
1888                 { $$ = NULL_TREE; }
1889         | absdcl1
1890         ;
1891
1892 absdcl_maybe_attribute:   /* absdcl maybe_attribute, but not just attributes */
1893         /* empty */
1894                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1895                                                          NULL_TREE),
1896                                         all_prefix_attributes); }
1897         | absdcl1
1898                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1899                                                          $1),
1900                                         all_prefix_attributes); }
1901         | absdcl1_noea attributes
1902                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1903                                                          $1),
1904                                         chainon ($2, all_prefix_attributes)); }
1905         ;
1906
1907 absdcl1:  /* a nonempty absolute declarator */
1908           absdcl1_ea
1909         | absdcl1_noea
1910         ;
1911
1912 absdcl1_noea:
1913           direct_absdcl1
1914         | '*' maybe_type_quals_attrs absdcl1_noea
1915                 { $$ = make_pointer_declarator ($2, $3); }
1916         ;
1917
1918 absdcl1_ea:
1919           '*' maybe_type_quals_attrs
1920                 { $$ = make_pointer_declarator ($2, NULL_TREE); }
1921         | '*' maybe_type_quals_attrs absdcl1_ea
1922                 { $$ = make_pointer_declarator ($2, $3); }
1923         ;
1924
1925 direct_absdcl1:
1926           '(' maybe_attribute absdcl1 ')'
1927                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1928         | direct_absdcl1 '(' parmlist
1929                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1930         | direct_absdcl1 array_declarator
1931                 { $$ = set_array_declarator_type ($2, $1, 1); }
1932         | '(' parmlist
1933                 { $$ = build_nt (CALL_EXPR, NULL_TREE, $2, NULL_TREE); }
1934         | array_declarator
1935                 { $$ = set_array_declarator_type ($1, NULL_TREE, 1); }
1936         ;
1937
1938 /* The [...] part of a declarator for an array type.  */
1939
1940 array_declarator:
1941         '[' maybe_type_quals_attrs expr_no_commas ']'
1942                 { $$ = build_array_declarator ($3, $2, 0, 0); }
1943         | '[' maybe_type_quals_attrs ']'
1944                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 0); }
1945         | '[' maybe_type_quals_attrs '*' ']'
1946                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 1); }
1947         | '[' STATIC maybe_type_quals_attrs expr_no_commas ']'
1948                 { $$ = build_array_declarator ($4, $3, 1, 0); }
1949         /* declspecs_nosc_nots is a synonym for type_quals_attrs.  */
1950         | '[' declspecs_nosc_nots STATIC expr_no_commas ']'
1951                 { $$ = build_array_declarator ($4, $2, 1, 0); }
1952         ;
1953
1954 /* A nonempty series of declarations and statements (possibly followed by
1955    some labels) that can form the body of a compound statement.
1956    NOTE: we don't allow labels on declarations; this might seem like a
1957    natural extension, but there would be a conflict between attributes
1958    on the label and prefix attributes on the declaration.  */
1959
1960 stmts_and_decls:
1961           lineno_stmt_decl_or_labels_ending_stmt
1962         | lineno_stmt_decl_or_labels_ending_decl
1963         | lineno_stmt_decl_or_labels_ending_label
1964                 {
1965                   error ("label at end of compound statement");
1966                 }
1967         | lineno_stmt_decl_or_labels_ending_error
1968         ;
1969
1970 lineno_stmt_decl_or_labels_ending_stmt:
1971           lineno_stmt
1972         | lineno_stmt_decl_or_labels_ending_stmt lineno_stmt
1973         | lineno_stmt_decl_or_labels_ending_decl lineno_stmt
1974         | lineno_stmt_decl_or_labels_ending_label lineno_stmt
1975         | lineno_stmt_decl_or_labels_ending_error lineno_stmt
1976         ;
1977
1978 lineno_stmt_decl_or_labels_ending_decl:
1979           lineno_decl
1980         | lineno_stmt_decl_or_labels_ending_stmt lineno_decl
1981                 {
1982                   if ((pedantic && !flag_isoc99)
1983                       || warn_declaration_after_statement)
1984                     pedwarn_c90 ("ISO C90 forbids mixed declarations and code");
1985                 }
1986         | lineno_stmt_decl_or_labels_ending_decl lineno_decl
1987         | lineno_stmt_decl_or_labels_ending_error lineno_decl
1988         ;
1989
1990 lineno_stmt_decl_or_labels_ending_label:
1991           lineno_label
1992         | lineno_stmt_decl_or_labels_ending_stmt lineno_label
1993         | lineno_stmt_decl_or_labels_ending_decl lineno_label
1994         | lineno_stmt_decl_or_labels_ending_label lineno_label
1995         | lineno_stmt_decl_or_labels_ending_error lineno_label
1996         ;
1997
1998 lineno_stmt_decl_or_labels_ending_error:
1999         errstmt
2000         | lineno_stmt_decl_or_labels errstmt
2001         ;
2002
2003 lineno_stmt_decl_or_labels:
2004           lineno_stmt_decl_or_labels_ending_stmt
2005         | lineno_stmt_decl_or_labels_ending_decl
2006         | lineno_stmt_decl_or_labels_ending_label
2007         | lineno_stmt_decl_or_labels_ending_error
2008         ;
2009
2010 errstmt:  error ';'
2011         ;
2012
2013 push_scope:  /* empty */
2014                 { push_scope ();
2015                   clear_last_expr ();
2016                   add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2017                 }
2018         ;
2019
2020 pop_scope:  /* empty */
2021                 {
2022 @@ifobjc
2023                   if (c_dialect_objc ())
2024                     objc_clear_super_receiver ();
2025 @@end_ifobjc
2026                   $$ = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0);
2027                 }
2028         ;
2029
2030 /* Start and end blocks created for the new scopes of C99.  */
2031 c99_block_start: /* empty */
2032                 { if (flag_isoc99)
2033                     {
2034                       $$ = c_begin_compound_stmt ();
2035                       push_scope ();
2036                       clear_last_expr ();
2037                       add_scope_stmt (/*begin_p=*/1, /*partial_p=*/0);
2038                     }
2039                   else
2040                     $$ = NULL_TREE;
2041                 }
2042         ;
2043
2044 /* Productions using c99_block_start and c99_block_end will need to do what's
2045    in compstmt: RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); $$ = $2; where
2046    $1 is the value of c99_block_start and $2 of c99_block_end.  */
2047 c99_block_end: /* empty */
2048                 { if (flag_isoc99)
2049                     {
2050                       tree scope_stmt = add_scope_stmt (/*begin_p=*/0, /*partial_p=*/0);
2051                       $$ = pop_scope ();
2052                       SCOPE_STMT_BLOCK (TREE_PURPOSE (scope_stmt))
2053                         = SCOPE_STMT_BLOCK (TREE_VALUE (scope_stmt))
2054                         = $$;
2055                     }
2056                   else
2057                     $$ = NULL_TREE; }
2058         ;
2059
2060 /* Read zero or more forward-declarations for labels
2061    that nested functions can jump to.  */
2062 maybe_label_decls:
2063           /* empty */
2064         | label_decls
2065                 { if (pedantic)
2066                     pedwarn ("ISO C forbids label declarations"); }
2067         ;
2068
2069 label_decls:
2070           label_decl
2071         | label_decls label_decl
2072         ;
2073
2074 label_decl:
2075           LABEL identifiers_or_typenames ';'
2076                 { tree link;
2077                   for (link = $2; link; link = TREE_CHAIN (link))
2078                     {
2079                       tree label = declare_label (TREE_VALUE (link));
2080                       C_DECLARED_LABEL_FLAG (label) = 1;
2081                       add_decl_stmt (label);
2082                     }
2083                 }
2084         ;
2085
2086 /* This is the body of a function definition.
2087    It causes syntax errors to ignore to the next openbrace.  */
2088 compstmt_or_error:
2089           compstmt
2090                 {}
2091         | error compstmt
2092         ;
2093
2094 compstmt_start: '{' { compstmt_count++;
2095                       $$ = c_begin_compound_stmt (); }
2096         ;
2097
2098 compstmt_nostart: '}'
2099                 { $$ = convert (void_type_node, integer_zero_node); }
2100         | push_scope maybe_label_decls compstmt_contents_nonempty '}' pop_scope
2101                 { $$ = pop_scope ();
2102                   SCOPE_STMT_BLOCK (TREE_PURPOSE ($5))
2103                     = SCOPE_STMT_BLOCK (TREE_VALUE ($5))
2104                     = $$; }
2105         ;
2106
2107 compstmt_contents_nonempty:
2108           stmts_and_decls
2109         | error
2110         ;
2111
2112 compstmt_primary_start:
2113         '(' '{'
2114                 { if (current_function_decl == 0)
2115                     {
2116                       error ("braced-group within expression allowed only inside a function");
2117                       YYERROR;
2118                     }
2119                   /* We must force a BLOCK for this level
2120                      so that, if it is not expanded later,
2121                      there is a way to turn off the entire subtree of blocks
2122                      that are contained in it.  */
2123                   keep_next_level ();
2124                   compstmt_count++;
2125                   $$ = add_stmt (build_stmt (COMPOUND_STMT, last_tree));
2126                   last_expr_type = NULL_TREE;
2127                 }
2128         ;
2129
2130 compstmt: compstmt_start compstmt_nostart
2131                 { RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2132                   last_expr_type = NULL_TREE;
2133                   $$ = $1; }
2134         ;
2135
2136 /* Value is number of statements counted as of the closeparen.  */
2137 simple_if:
2138           if_prefix c99_block_lineno_labeled_stmt
2139                 { c_finish_then (); }
2140 /* Make sure c_expand_end_cond is run once
2141    for each call to c_expand_start_cond.
2142    Otherwise a crash is likely.  */
2143         | if_prefix error
2144         ;
2145
2146 if_prefix:
2147           /* We must build the IF_STMT node before parsing its
2148              condition so that EXPR_LOCUS refers to the line
2149              containing the "if", and not the line containing
2150              the close-parenthesis.
2151
2152              c_begin_if_stmt returns the IF_STMT node, which
2153              we later pass to c_expand_start_cond to fill
2154              in the condition and other tidbits.  */
2155           IF
2156                 { $<ttype>$ = c_begin_if_stmt (); }
2157             '(' expr ')'
2158                 { c_expand_start_cond (lang_hooks.truthvalue_conversion ($4),
2159                                        compstmt_count,$<ttype>2);
2160                   $<itype>$ = stmt_count;
2161                   if_stmt_locus = $<location>-1; }
2162         ;
2163
2164 /* This is a subroutine of stmt.
2165    It is used twice, once for valid DO statements
2166    and once for catching errors in parsing the end test.  */
2167 do_stmt_start:
2168           DO
2169                 { stmt_count++;
2170                   compstmt_count++;
2171                   c_in_iteration_stmt++;
2172                   $<ttype>$
2173                     = add_stmt (build_stmt (DO_STMT, NULL_TREE,
2174                                             NULL_TREE));
2175                   /* In the event that a parse error prevents
2176                      parsing the complete do-statement, set the
2177                      condition now.  Otherwise, we can get crashes at
2178                      RTL-generation time.  */
2179                   DO_COND ($<ttype>$) = error_mark_node; }
2180           c99_block_lineno_labeled_stmt WHILE
2181                 { $$ = $<ttype>2;
2182                   RECHAIN_STMTS ($$, DO_BODY ($$));
2183                   c_in_iteration_stmt--; }
2184         ;
2185
2186 /* The forced readahead in here is because we might be at the end of a
2187    line, and the line and file won't be bumped until yylex absorbs the
2188    first token on the next line.  */
2189
2190 save_location:
2191                 { if (yychar == YYEMPTY)
2192                     yychar = YYLEX;
2193                   $$ = input_location; }
2194         ;
2195
2196 lineno_labeled_stmt:
2197           lineno_stmt
2198         | lineno_label lineno_labeled_stmt
2199         ;
2200
2201 /* Like lineno_labeled_stmt, but a block in C99.  */
2202 c99_block_lineno_labeled_stmt:
2203           c99_block_start lineno_labeled_stmt c99_block_end
2204                 { if (flag_isoc99)
2205                     RECHAIN_STMTS ($1, COMPOUND_BODY ($1)); }
2206         ;
2207
2208 lineno_stmt:
2209           save_location stmt
2210                 { if ($2)
2211                     {
2212                       SET_EXPR_LOCUS ($2, NULL);
2213                       annotate_with_locus ($2, $1);
2214                     }
2215                 }
2216         ;
2217
2218 lineno_label:
2219           save_location label
2220                 { if ($2)
2221                     {
2222                       SET_EXPR_LOCUS ($2, NULL);
2223                       annotate_with_locus ($2, $1);
2224                     }
2225                 }
2226         ;
2227
2228 select_or_iter_stmt:
2229           simple_if ELSE
2230                 { c_expand_start_else ();
2231                   $<itype>1 = stmt_count; }
2232           c99_block_lineno_labeled_stmt
2233                 { c_finish_else ();
2234                   c_expand_end_cond ();
2235                   if (extra_warnings && stmt_count == $<itype>1)
2236                     warning ("empty body in an else-statement"); }
2237         | simple_if %prec IF
2238                 { c_expand_end_cond ();
2239                   /* This warning is here instead of in simple_if, because we
2240                      do not want a warning if an empty if is followed by an
2241                      else statement.  Increment stmt_count so we don't
2242                      give a second error if this is a nested `if'.  */
2243                   if (extra_warnings && stmt_count++ == $<itype>1)
2244                     warning ("%Hempty body in an if-statement",
2245                              &if_stmt_locus); }
2246 /* Make sure c_expand_end_cond is run once
2247    for each call to c_expand_start_cond.
2248    Otherwise a crash is likely.  */
2249         | simple_if ELSE error
2250                 { c_expand_end_cond (); }
2251        /* We must build the WHILE_STMT node before parsing its
2252           condition so that EXPR_LOCUS refers to the line
2253           containing the "while", and not the line containing
2254           the close-parenthesis.
2255
2256           c_begin_while_stmt returns the WHILE_STMT node, which
2257           we later pass to c_finish_while_stmt_cond to fill
2258           in the condition and other tidbits.  */
2259         | WHILE
2260                 { stmt_count++;
2261                   $<ttype>$ = c_begin_while_stmt (); }
2262           '(' expr ')'
2263                 { c_in_iteration_stmt++;
2264                   $4 = lang_hooks.truthvalue_conversion ($4);
2265                   c_finish_while_stmt_cond
2266                     (lang_hooks.truthvalue_conversion ($4), $<ttype>2);
2267                   $<ttype>$ = add_stmt ($<ttype>2); }
2268           c99_block_lineno_labeled_stmt
2269                 { c_in_iteration_stmt--;
2270                   RECHAIN_STMTS ($<ttype>6, WHILE_BODY ($<ttype>6)); }
2271         | do_stmt_start
2272           '(' expr ')' ';'
2273                 { DO_COND ($1) = lang_hooks.truthvalue_conversion ($3); }
2274         | do_stmt_start error
2275                 { }
2276         | FOR
2277                 { $<ttype>$ = build_stmt (FOR_STMT, NULL_TREE, NULL_TREE,
2278                                           NULL_TREE, NULL_TREE);
2279                   add_stmt ($<ttype>$); }
2280           '(' for_init_stmt
2281                 { stmt_count++;
2282                   RECHAIN_STMTS ($<ttype>2, FOR_INIT_STMT ($<ttype>2)); }
2283           xexpr ';'
2284                 { if ($6)
2285                     FOR_COND ($<ttype>2)
2286                       = lang_hooks.truthvalue_conversion ($6); }
2287           xexpr ')'
2288                 { c_in_iteration_stmt++;
2289                   FOR_EXPR ($<ttype>2) = $9; }
2290           c99_block_lineno_labeled_stmt
2291                 { RECHAIN_STMTS ($<ttype>2, FOR_BODY ($<ttype>2));
2292                   c_in_iteration_stmt--;}
2293         | SWITCH '(' expr ')'
2294                 { stmt_count++;
2295                   $<ttype>$ = c_start_case ($3);
2296                   c_in_case_stmt++; }
2297           c99_block_lineno_labeled_stmt
2298                 { c_finish_case ();
2299                   c_in_case_stmt--; }
2300         ;
2301
2302 for_init_stmt:
2303           xexpr ';'
2304                 { add_stmt (build_stmt (EXPR_STMT, $1)); }
2305         | decl
2306                 { check_for_loop_decls (); }
2307         ;
2308
2309 xexpr:
2310         /* empty */
2311                 { $$ = NULL_TREE; }
2312         | expr
2313         ;
2314
2315 /* Parse a single real statement, not including any labels.  */
2316 stmt:
2317           compstmt
2318                 { stmt_count++; $$ = $1; }
2319         | expr ';'
2320                 { stmt_count++;
2321                   $$ = c_expand_expr_stmt ($1); }
2322         | c99_block_start select_or_iter_stmt c99_block_end
2323                 { if (flag_isoc99)
2324                     RECHAIN_STMTS ($1, COMPOUND_BODY ($1));
2325                   $$ = NULL_TREE; }
2326         | BREAK ';'
2327                 { stmt_count++;
2328                 if (!(c_in_iteration_stmt || c_in_case_stmt))
2329                   {
2330                     error ("break statement not within loop or switch");
2331                     $$ = NULL_TREE;
2332                   }
2333                 else
2334                   $$ = add_stmt (build_break_stmt ()); }
2335         | CONTINUE ';'
2336                 { stmt_count++;
2337                 if (!c_in_iteration_stmt)
2338                   {
2339                     error ("continue statement not within a loop");
2340                     $$ = NULL_TREE;
2341                   }
2342                 else
2343                   $$ = add_stmt (build_continue_stmt ()); }
2344         | RETURN ';'
2345                 { stmt_count++;
2346                   $$ = c_expand_return (NULL_TREE); }
2347         | RETURN expr ';'
2348                 { stmt_count++;
2349                   $$ = c_expand_return ($2); }
2350         | asm_stmt
2351         | GOTO identifier ';'
2352                 { tree decl;
2353                   stmt_count++;
2354                   decl = lookup_label ($2);
2355                   if (decl != 0)
2356                     {
2357                       TREE_USED (decl) = 1;
2358                       $$ = add_stmt (build_stmt (GOTO_STMT, decl));
2359                     }
2360                   else
2361                     $$ = NULL_TREE;
2362                 }
2363         | GOTO '*' expr ';'
2364                 { if (pedantic)
2365                     pedwarn ("ISO C forbids `goto *expr;'");
2366                   stmt_count++;
2367                   $3 = convert (ptr_type_node, $3);
2368                   $$ = add_stmt (build_stmt (GOTO_STMT, $3)); }
2369         | ';'
2370                 { $$ = NULL_TREE; }
2371 @@ifobjc
2372         | AT_THROW expr ';'
2373                 { stmt_count++;
2374                   $$ = objc_build_throw_stmt ($2);
2375                 }
2376         | AT_THROW ';'
2377                 { stmt_count++;
2378                   $$ = objc_build_throw_stmt (NULL_TREE);
2379                 }
2380         | objc_try_catch_stmt
2381                 { objc_build_finally_prologue (); }
2382           objc_finally_block
2383                 { $$ = objc_build_try_catch_finally_stmt ($1, $3); }
2384         | AT_SYNCHRONIZED '(' expr ')'
2385                 { objc_build_synchronized_prologue ($3); }
2386           compstmt
2387                 { $$ = objc_build_synchronized_epilogue (); }
2388         ;
2389
2390 objc_try_catch_stmt:
2391           objc_try_stmt
2392                 { objc_build_try_epilogue (1); }
2393           objc_catch_list
2394                 { objc_build_catch_epilogue (); $$ = 1; }
2395         | objc_try_stmt
2396                 { objc_build_try_epilogue (0); $$ = 0; }
2397         ;
2398
2399
2400 objc_try_stmt:
2401           AT_TRY
2402                 { objc_build_try_prologue (); }
2403           compstmt
2404         ;
2405
2406 objc_catch_list:
2407           objc_catch_list objc_catch_block
2408         | objc_catch_block
2409         ;
2410
2411 objc_catch_block:
2412           AT_CATCH '(' parm ')'
2413                 { objc_build_catch_stmt ($3); }
2414           compstmt
2415                 { stmt_count++; }
2416         ;
2417
2418 objc_finally_block:
2419           AT_FINALLY compstmt
2420             { $$ = 1; }
2421         | /* NULL */
2422             { $$ = 0; }
2423 @@end_ifobjc
2424         ;
2425
2426 /* Any kind of label, including jump labels and case labels.
2427    ANSI C accepts labels only before statements, but we allow them
2428    also at the end of a compound statement.  */
2429
2430 label:    CASE expr_no_commas ':'
2431                 { stmt_count++;
2432                   $$ = do_case ($2, NULL_TREE); }
2433         | CASE expr_no_commas ELLIPSIS expr_no_commas ':'
2434                 { stmt_count++;
2435                   $$ = do_case ($2, $4); }
2436         | DEFAULT ':'
2437                 { stmt_count++;
2438                   $$ = do_case (NULL_TREE, NULL_TREE); }
2439         | identifier save_location ':' maybe_attribute
2440                 { tree label = define_label ($2, $1);
2441                   stmt_count++;
2442                   if (label)
2443                     {
2444                       decl_attributes (&label, $4, 0);
2445                       $$ = add_stmt (build_stmt (LABEL_STMT, label));
2446                     }
2447                   else
2448                     $$ = NULL_TREE;
2449                 }
2450         ;
2451
2452 /* Asm expressions and statements */
2453
2454 /* simple_asm_expr is used in restricted contexts, where a full
2455    expression with inputs and outputs does not make sense.  */
2456 simple_asm_expr:
2457         ASM_KEYWORD stop_string_translation
2458               '(' STRING ')' start_string_translation
2459                 { $$ = $4; }
2460         ;
2461
2462 /* maybeasm: used for assembly names for declarations */
2463 maybeasm:
2464           /* empty */
2465                 { $$ = NULL_TREE; }
2466         | simple_asm_expr
2467         ;
2468
2469 /* asmdef: asm() outside a function body.  */
2470 asmdef:
2471         simple_asm_expr ';'
2472                 { assemble_asm ($1); }
2473         | ASM_KEYWORD error start_string_translation ';'
2474                 {}
2475         ;
2476
2477 /* Full-blown asm statement with inputs, outputs, clobbers, and
2478    volatile tag allowed.  */
2479 asm_stmt:
2480         ASM_KEYWORD maybe_volatile stop_string_translation
2481                 '(' asm_argument ')' start_string_translation ';'
2482                 { stmt_count++;
2483                   $$ = build_asm_stmt ($2, $5); }
2484         ;
2485
2486 asm_argument:
2487         /* no operands */
2488         STRING
2489                 { $$ = build_asm_expr ($1, 0, 0, 0, true); }
2490         /* output operands */
2491         | STRING ':' asm_operands
2492                 { $$ = build_asm_expr ($1, $3, 0, 0, false); }
2493         /* output and input operands */
2494         | STRING ':' asm_operands ':' asm_operands
2495                 { $$ = build_asm_expr ($1, $3, $5, 0, false); }
2496         /* output and input operands and clobbers */
2497         | STRING ':' asm_operands ':' asm_operands ':' asm_clobbers
2498                 { $$ = build_asm_expr ($1, $3, $5, $7, false); }
2499         ;
2500
2501 /* Either 'volatile' or nothing.  First thing in an `asm' statement.  */
2502
2503 maybe_volatile:
2504         /* empty */
2505                 { $$ = 0; }
2506         | TYPE_QUAL
2507                 { if ($1 != ridpointers[RID_VOLATILE])
2508                     {
2509                       warning ("%E qualifier ignored on asm", $1);
2510                       $$ = 0;
2511                     }
2512                   else
2513                     $$ = $1;
2514                 }
2515         ;
2516
2517 /* These are the operands other than the first string and colon
2518    in  asm ("addextend %2,%1": "=dm" (x), "0" (y), "g" (*x))  */
2519 asm_operands: /* empty */
2520                 { $$ = NULL_TREE; }
2521         | nonnull_asm_operands
2522         ;
2523
2524 nonnull_asm_operands:
2525           asm_operand
2526         | nonnull_asm_operands ',' asm_operand
2527                 { $$ = chainon ($1, $3); }
2528         ;
2529
2530 asm_operand:
2531           STRING start_string_translation '(' expr ')' stop_string_translation
2532                 { $$ = build_tree_list (build_tree_list (NULL_TREE, $1), $4); }
2533         | '[' identifier ']' STRING start_string_translation
2534           '(' expr ')' stop_string_translation
2535                 { $2 = build_string (IDENTIFIER_LENGTH ($2),
2536                                      IDENTIFIER_POINTER ($2));
2537                   $$ = build_tree_list (build_tree_list ($2, $4), $7); }
2538         ;
2539
2540 asm_clobbers:
2541           STRING
2542                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE); }
2543         | asm_clobbers ',' STRING
2544                 { $$ = tree_cons (NULL_TREE, $3, $1); }
2545         ;
2546
2547 stop_string_translation:
2548         { c_lex_string_translate = false; }
2549         ;
2550
2551 start_string_translation:
2552         { c_lex_string_translate = true; }
2553         ;
2554
2555 \f
2556 /* This is what appears inside the parens in a function declarator.
2557    Its value is a list of ..._TYPE nodes.  Attributes must appear here
2558    to avoid a conflict with their appearance after an open parenthesis
2559    in an abstract declarator, as in
2560    "void bar (int (__attribute__((__mode__(SI))) int foo));".  */
2561 parmlist:
2562           maybe_attribute
2563                 { push_scope ();
2564                   declare_parm_level (); }
2565           parmlist_1
2566                 { $$ = $3;
2567                   pop_scope (); }
2568         ;
2569
2570 parmlist_1:
2571           parmlist_2 ')'
2572         | parms ';'
2573                 { mark_forward_parm_decls (); }
2574           maybe_attribute
2575                 { /* Dummy action so attributes are in known place
2576                      on parser stack.  */ }
2577           parmlist_1
2578                 { $$ = $6; }
2579         | error ')'
2580                 { $$ = make_node (TREE_LIST); }
2581         ;
2582
2583 /* This is what appears inside the parens in a function declarator.
2584    Is value is represented in the format that grokdeclarator expects.  */
2585 parmlist_2:  /* empty */
2586                 { $$ = make_node (TREE_LIST); }
2587         | ELLIPSIS
2588                 { $$ = make_node (TREE_LIST); 
2589                   /* Suppress -Wold-style-definition for this case.  */
2590                   TREE_CHAIN ($$) = error_mark_node;
2591                   error ("ISO C requires a named argument before `...'");
2592                 }
2593         | parms
2594                 { $$ = get_parm_info (/*ellipsis=*/false); }
2595         | parms ',' ELLIPSIS
2596                 { $$ = get_parm_info (/*ellipsis=*/true); }
2597         ;
2598
2599 parms:
2600         firstparm
2601                 { push_parm_decl ($1); }
2602         | parms ',' parm
2603                 { push_parm_decl ($3); }
2604         ;
2605
2606 /* A single parameter declaration or parameter type name,
2607    as found in a parmlist.  */
2608 parm:
2609           declspecs_ts setspecs parm_declarator maybe_attribute
2610                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2611                                                          $3),
2612                                         chainon ($4, all_prefix_attributes));
2613                   POP_DECLSPEC_STACK; }
2614         | declspecs_ts setspecs notype_declarator maybe_attribute
2615                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2616                                                          $3),
2617                                         chainon ($4, all_prefix_attributes));
2618                   POP_DECLSPEC_STACK; }
2619         | declspecs_ts setspecs absdcl_maybe_attribute
2620                 { $$ = $3;
2621                   POP_DECLSPEC_STACK; }
2622         | declspecs_nots setspecs notype_declarator maybe_attribute
2623                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2624                                                          $3),
2625                                         chainon ($4, all_prefix_attributes));
2626                   POP_DECLSPEC_STACK; }
2627
2628         | declspecs_nots setspecs absdcl_maybe_attribute
2629                 { $$ = $3;
2630                   POP_DECLSPEC_STACK; }
2631         ;
2632
2633 /* The first parm, which must suck attributes from off the top of the parser
2634    stack.  */
2635 firstparm:
2636           declspecs_ts_nosa setspecs_fp parm_declarator maybe_attribute
2637                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2638                                                          $3),
2639                                         chainon ($4, all_prefix_attributes));
2640                   POP_DECLSPEC_STACK; }
2641         | declspecs_ts_nosa setspecs_fp notype_declarator maybe_attribute
2642                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2643                                                          $3),
2644                                         chainon ($4, all_prefix_attributes));
2645                   POP_DECLSPEC_STACK; }
2646         | declspecs_ts_nosa setspecs_fp absdcl_maybe_attribute
2647                 { $$ = $3;
2648                   POP_DECLSPEC_STACK; }
2649         | declspecs_nots_nosa setspecs_fp notype_declarator maybe_attribute
2650                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2651                                                          $3),
2652                                         chainon ($4, all_prefix_attributes));
2653                   POP_DECLSPEC_STACK; }
2654
2655         | declspecs_nots_nosa setspecs_fp absdcl_maybe_attribute
2656                 { $$ = $3;
2657                   POP_DECLSPEC_STACK; }
2658         ;
2659
2660 setspecs_fp:
2661           setspecs
2662                 { prefix_attributes = chainon (prefix_attributes, $<ttype>-2);
2663                   all_prefix_attributes = prefix_attributes; }
2664         ;
2665
2666 /* This is used in a function definition
2667    where either a parmlist or an identifier list is ok.
2668    Its value is a list of ..._TYPE nodes or a list of identifiers.  */
2669 parmlist_or_identifiers:
2670           maybe_attribute
2671                 { push_scope ();
2672                   declare_parm_level (); }
2673           parmlist_or_identifiers_1
2674                 { $$ = $3;
2675                   pop_scope (); }
2676         ;
2677
2678 parmlist_or_identifiers_1:
2679           parmlist_1
2680         | identifiers ')'
2681                 { tree t;
2682                   for (t = $1; t; t = TREE_CHAIN (t))
2683                     if (TREE_VALUE (t) == NULL_TREE)
2684                       error ("`...' in old-style identifier list");
2685                   $$ = tree_cons (NULL_TREE, NULL_TREE, $1);
2686
2687                   /* Make sure we have a parmlist after attributes.  */
2688                   if ($<ttype>-1 != 0
2689                       && (TREE_CODE ($$) != TREE_LIST
2690                           || TREE_PURPOSE ($$) == 0
2691                           || TREE_CODE (TREE_PURPOSE ($$)) != PARM_DECL))
2692                     YYERROR1;
2693                 }
2694         ;
2695
2696 /* A nonempty list of identifiers.  */
2697 identifiers:
2698         IDENTIFIER
2699                 { $$ = build_tree_list (NULL_TREE, $1); }
2700         | identifiers ',' IDENTIFIER
2701                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2702         ;
2703
2704 /* A nonempty list of identifiers, including typenames.  */
2705 identifiers_or_typenames:
2706         identifier
2707                 { $$ = build_tree_list (NULL_TREE, $1); }
2708         | identifiers_or_typenames ',' identifier
2709                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2710         ;
2711
2712 extension:
2713         EXTENSION
2714                 { $$ = SAVE_EXT_FLAGS();
2715                   pedantic = 0;
2716                   warn_pointer_arith = 0;
2717                   warn_traditional = 0;
2718                   flag_iso = 0; }
2719         ;
2720 \f
2721 @@ifobjc
2722 /* Objective-C productions.  */
2723
2724 objcdef:
2725           classdef
2726         | classdecl
2727         | aliasdecl
2728         | protocoldef
2729         | methoddef
2730         | END
2731                 {
2732                   if (objc_implementation_context)
2733                     {
2734                       finish_class (objc_implementation_context);
2735                       objc_ivar_chain = NULL_TREE;
2736                       objc_implementation_context = NULL_TREE;
2737                     }
2738                   else
2739                     warning ("`@end' must appear in an implementation context");
2740                 }
2741         ;
2742
2743 /* A nonempty list of identifiers.  */
2744 identifier_list:
2745         identifier
2746                 { $$ = build_tree_list (NULL_TREE, $1); }
2747         | identifier_list ',' identifier
2748                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2749         ;
2750
2751 classdecl:
2752           CLASS identifier_list ';'
2753                 {
2754                   objc_declare_class ($2);
2755                 }
2756         ;
2757
2758 aliasdecl:
2759           ALIAS identifier identifier ';'
2760                 {
2761                   objc_declare_alias ($2, $3);
2762                 }
2763         ;
2764
2765 superclass:
2766           ':' identifier { $$ = $2; }
2767         | /* NULL */ %prec HYPERUNARY    { $$ = NULL_TREE; }
2768         ;
2769
2770 class_ivars:
2771           '{' ivar_decl_list '}'
2772         | /* NULL */
2773         ;
2774
2775 classdef:
2776           INTERFACE identifier superclass protocolrefs
2777                 {
2778                   objc_interface_context = objc_ivar_context
2779                     = start_class (CLASS_INTERFACE_TYPE, $2, $3, $4);
2780                   objc_public_flag = 0;
2781                 }
2782           class_ivars
2783                 {
2784                   continue_class (objc_interface_context);
2785                 }
2786           methodprotolist END
2787                 {
2788                   finish_class (objc_interface_context);
2789                   objc_interface_context = NULL_TREE;
2790                 }
2791
2792         | IMPLEMENTATION identifier superclass
2793                 {
2794                   objc_implementation_context = objc_ivar_context
2795                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $3, NULL_TREE);
2796                   objc_public_flag = 0;
2797                 }
2798           class_ivars
2799                 {
2800                   objc_ivar_chain
2801                     = continue_class (objc_implementation_context);
2802                 }
2803
2804         | INTERFACE identifier '(' identifier ')' protocolrefs
2805                 {
2806                   objc_interface_context
2807                     = start_class (CATEGORY_INTERFACE_TYPE, $2, $4, $6);
2808                   continue_class (objc_interface_context);
2809                 }
2810           methodprotolist END
2811                 {
2812                   finish_class (objc_interface_context);
2813                   objc_interface_context = NULL_TREE;
2814                 }
2815
2816         | IMPLEMENTATION identifier '(' identifier ')'
2817                 {
2818                   objc_implementation_context
2819                     = start_class (CATEGORY_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2820                   objc_ivar_chain
2821                     = continue_class (objc_implementation_context);
2822                 }
2823         ;
2824
2825 protocoldef:
2826           PROTOCOL identifier protocolrefs
2827                 {
2828                   objc_pq_context = 1;
2829                   objc_interface_context
2830                     = start_protocol(PROTOCOL_INTERFACE_TYPE, $2, $3);
2831                 }
2832           methodprotolist END
2833                 {
2834                   objc_pq_context = 0;
2835                   finish_protocol(objc_interface_context);
2836                   objc_interface_context = NULL_TREE;
2837                 }
2838         /* The @protocol forward-declaration production introduces a
2839            reduce/reduce conflict on ';', which should be resolved in
2840            favor of the production 'identifier_list -> identifier'.  */
2841         | PROTOCOL identifier_list ';'
2842                 {
2843                   objc_declare_protocols ($2);
2844                 }
2845         ;
2846
2847 protocolrefs:
2848           /* empty */
2849                 {
2850                   $$ = NULL_TREE;
2851                 }
2852         | non_empty_protocolrefs
2853         ;
2854
2855 non_empty_protocolrefs:
2856           ARITHCOMPARE identifier_list ARITHCOMPARE
2857                 {
2858                   if ($1 == LT_EXPR && $3 == GT_EXPR)
2859                     $$ = $2;
2860                   else
2861                     YYERROR1;
2862                 }
2863         ;
2864
2865 ivar_decl_list:
2866           ivar_decl_list visibility_spec ivar_decls
2867         | ivar_decls
2868         ;
2869
2870 visibility_spec:
2871           PRIVATE { objc_public_flag = 2; }
2872         | PROTECTED { objc_public_flag = 0; }
2873         | PUBLIC { objc_public_flag = 1; }
2874         ;
2875
2876 ivar_decls:
2877           /* empty */
2878                 {
2879                   $$ = NULL_TREE;
2880                 }
2881         | ivar_decls ivar_decl ';'
2882         | ivar_decls ';'
2883                 {
2884                   if (pedantic)
2885                     pedwarn ("extra semicolon in struct or union specified");
2886                 }
2887         ;
2888
2889
2890 /* There is a shift-reduce conflict here, because `components' may
2891    start with a `typename'.  It happens that shifting (the default resolution)
2892    does the right thing, because it treats the `typename' as part of
2893    a `typed_typespecs'.
2894
2895    It is possible that this same technique would allow the distinction
2896    between `notype_initdecls' and `initdecls' to be eliminated.
2897    But I am being cautious and not trying it.  */
2898
2899 ivar_decl:
2900         declspecs_nosc_ts setspecs ivars
2901                 { $$ = $3;
2902                   POP_DECLSPEC_STACK; }
2903         | declspecs_nosc_nots setspecs ivars
2904                 { $$ = $3;
2905                   POP_DECLSPEC_STACK; }
2906         | error
2907                 { $$ = NULL_TREE; }
2908         ;
2909
2910 ivars:
2911           /* empty */
2912                 { $$ = NULL_TREE; }
2913         | ivar_declarator
2914         | ivars ',' maybe_resetattrs ivar_declarator
2915         ;
2916
2917 ivar_declarator:
2918           declarator
2919                 {
2920                   $$ = add_instance_variable (objc_ivar_context,
2921                                               objc_public_flag,
2922                                               $1, current_declspecs,
2923                                               NULL_TREE);
2924                 }
2925         | declarator ':' expr_no_commas
2926                 {
2927                   $$ = add_instance_variable (objc_ivar_context,
2928                                               objc_public_flag,
2929                                               $1, current_declspecs, $3);
2930                 }
2931         | ':' expr_no_commas
2932                 {
2933                   $$ = add_instance_variable (objc_ivar_context,
2934                                               objc_public_flag,
2935                                               NULL_TREE,
2936                                               current_declspecs, $2);
2937                 }
2938         ;
2939
2940 methodtype:
2941           '+'
2942                 { objc_inherit_code = CLASS_METHOD_DECL; }
2943         | '-'
2944                 { objc_inherit_code = INSTANCE_METHOD_DECL; }
2945         ;
2946
2947 methoddef:
2948           methodtype
2949                 {
2950                   objc_pq_context = 1;
2951                   if (!objc_implementation_context)
2952                     fatal_error ("method definition not in class context");
2953                 }
2954           methoddecl
2955                 {
2956                   objc_pq_context = 0;
2957                   objc_add_method (objc_implementation_context,
2958                                    $3,
2959                                    objc_inherit_code == CLASS_METHOD_DECL);
2960                   start_method_def ($3);
2961                 }
2962           optarglist
2963                 {
2964                   continue_method_def ();
2965                 }
2966           compstmt_or_error
2967                 {
2968                   finish_method_def ();
2969                 }
2970         ;
2971
2972 /* the reason for the strange actions in this rule
2973  is so that notype_initdecls when reached via datadef
2974  can find a valid list of type and sc specs in $0. */
2975
2976 methodprotolist:
2977           /* empty  */
2978         | methodprotolist methodproto
2979         | methodprotolist { $<ttype>$ = NULL_TREE; } datadef
2980         ;
2981
2982 semi_or_error:
2983           ';'
2984         | error
2985         ;
2986
2987 methodproto:
2988           methodtype
2989                 {
2990                   /* Remember protocol qualifiers in prototypes.  */
2991                   objc_pq_context = 1;
2992                 }
2993           methoddecl
2994                 {
2995                   /* Forget protocol qualifiers here.  */
2996                   objc_pq_context = 0;
2997                   objc_add_method (objc_interface_context,
2998                                    $3,
2999                                    objc_inherit_code == CLASS_METHOD_DECL);
3000                 }
3001           semi_or_error
3002         ;
3003
3004 methoddecl:
3005           '(' typename ')' unaryselector
3006                 {
3007                   $$ = build_method_decl (objc_inherit_code, $2, $4, NULL_TREE);
3008                 }
3009
3010         | unaryselector
3011                 {
3012                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, NULL_TREE);
3013                 }
3014
3015         | '(' typename ')' keywordselector optparmlist
3016                 {
3017                   $$ = build_method_decl (objc_inherit_code, $2, $4, $5);
3018                 }
3019
3020         | keywordselector optparmlist
3021                 {
3022                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, $2);
3023                 }
3024         ;
3025
3026 /* "optarglist" assumes that start_method_def has already been called...
3027    if it is not, the "xdecls" will not be placed in the proper scope */
3028
3029 optarglist:
3030           /* empty */
3031         | ';' myxdecls
3032         ;
3033
3034 /* to get around the following situation: "int foo (int a) int b; {}" that
3035    is synthesized when parsing "- a:a b:b; id c; id d; { ... }" */
3036
3037 myxdecls:
3038           /* empty */
3039         | mydecls
3040         ;
3041
3042 mydecls:
3043         mydecl
3044         | errstmt
3045         | mydecls mydecl
3046         | mydecl errstmt
3047         ;
3048
3049 mydecl:
3050         declspecs_ts setspecs myparms ';'
3051                 { POP_DECLSPEC_STACK; }
3052         | declspecs_ts ';'
3053                 { shadow_tag ($1); }
3054         | declspecs_nots ';'
3055                 { pedwarn ("empty declaration"); }
3056         ;
3057
3058 myparms:
3059         myparm
3060                 { push_parm_decl ($1); }
3061         | myparms ',' myparm
3062                 { push_parm_decl ($3); }
3063         ;
3064
3065 /* A single parameter declaration or parameter type name,
3066    as found in a parmlist. DOES NOT ALLOW AN INITIALIZER OR ASMSPEC */
3067
3068 myparm:
3069           parm_declarator maybe_attribute
3070                 { $$ = build_tree_list (build_tree_list (current_declspecs,
3071                                                          $1),
3072                                         chainon ($2, all_prefix_attributes)); }
3073         | notype_declarator maybe_attribute
3074                 { $$ = build_tree_list (build_tree_list (current_declspecs,
3075                                                          $1),
3076                                         chainon ($2, all_prefix_attributes)); }
3077         | absdcl_maybe_attribute
3078                 { $$ = $1; }
3079         ;
3080
3081 optparmlist:
3082           /* empty */
3083                 {
3084                   $$ = NULL_TREE;
3085                 }
3086         | ',' ELLIPSIS
3087                 {
3088                   /* oh what a kludge! */
3089                   $$ = objc_ellipsis_node;
3090                 }
3091         | ','
3092                 {
3093                   push_scope ();
3094                 }
3095           parmlist_2
3096                 {
3097                   /* returns a tree list node generated by get_parm_info */
3098                   $$ = $3;
3099                   pop_scope ();
3100                 }
3101         ;
3102
3103 unaryselector:
3104           selector
3105         ;
3106
3107 keywordselector:
3108           keyworddecl
3109
3110         | keywordselector keyworddecl
3111                 {
3112                   $$ = chainon ($1, $2);
3113                 }
3114         ;
3115
3116 selector:
3117           IDENTIFIER
3118         | TYPENAME
3119         | CLASSNAME
3120         | OBJECTNAME
3121         | reservedwords
3122         ;
3123
3124 reservedwords:
3125           ENUM | STRUCT | UNION | IF | ELSE | WHILE | DO | FOR
3126         | SWITCH | CASE | DEFAULT | BREAK | CONTINUE | RETURN
3127         | GOTO | ASM_KEYWORD | SIZEOF | TYPEOF | ALIGNOF
3128         | TYPESPEC | TYPE_QUAL
3129         ;
3130
3131 keyworddecl:
3132           selector ':' '(' typename ')' identifier
3133                 {
3134                   $$ = build_keyword_decl ($1, $4, $6);
3135                 }
3136
3137         | selector ':' identifier
3138                 {
3139                   $$ = build_keyword_decl ($1, NULL_TREE, $3);
3140                 }
3141
3142         | ':' '(' typename ')' identifier
3143                 {
3144                   $$ = build_keyword_decl (NULL_TREE, $3, $5);
3145                 }
3146
3147         | ':' identifier
3148                 {
3149                   $$ = build_keyword_decl (NULL_TREE, NULL_TREE, $2);
3150                 }
3151         ;
3152
3153 messageargs:
3154           selector
3155         | keywordarglist
3156         ;
3157
3158 keywordarglist:
3159           keywordarg
3160         | keywordarglist keywordarg
3161                 {
3162                   $$ = chainon ($1, $2);
3163                 }
3164         ;
3165
3166
3167 keywordexpr:
3168           nonnull_exprlist
3169                 {
3170                   if (TREE_CHAIN ($1) == NULL_TREE)
3171                     /* just return the expr., remove a level of indirection */
3172                     $$ = TREE_VALUE ($1);
3173                   else
3174                     /* we have a comma expr., we will collapse later */
3175                     $$ = $1;
3176                 }
3177         ;
3178
3179 keywordarg:
3180           selector ':' keywordexpr
3181                 {
3182                   $$ = build_tree_list ($1, $3);
3183                 }
3184         | ':' keywordexpr
3185                 {
3186                   $$ = build_tree_list (NULL_TREE, $2);
3187                 }
3188         ;
3189
3190 receiver:
3191           expr
3192         | CLASSNAME
3193                 {
3194                   $$ = get_class_reference ($1);
3195                 }
3196         | TYPENAME
3197                 {
3198                   $$ = get_class_reference ($1);
3199                 }
3200         ;
3201
3202 objcmessageexpr:
3203           '[' receiver messageargs ']'
3204                 { $$ = build_tree_list ($2, $3); }
3205         ;
3206
3207 selectorarg:
3208           selector
3209         | keywordnamelist
3210         ;
3211
3212 keywordnamelist:
3213           keywordname
3214         | keywordnamelist keywordname
3215                 {
3216                   $$ = chainon ($1, $2);
3217                 }
3218         ;
3219
3220 keywordname:
3221           selector ':'
3222                 {
3223                   $$ = build_tree_list ($1, NULL_TREE);
3224                 }
3225         | ':'
3226                 {
3227                   $$ = build_tree_list (NULL_TREE, NULL_TREE);
3228                 }
3229         ;
3230
3231 objcselectorexpr:
3232           SELECTOR '(' selectorarg ')'
3233                 {
3234                   $$ = $3;
3235                 }
3236         ;
3237
3238 objcprotocolexpr:
3239           PROTOCOL '(' identifier ')'
3240                 {
3241                   $$ = $3;
3242                 }
3243         ;
3244
3245 /* extension to support C-structures in the archiver */
3246
3247 objcencodeexpr:
3248           ENCODE '(' typename ')'
3249                 {
3250                   $$ = groktypename ($3);
3251   &n