OSDN Git Service

* c-tree.h (struct c_expr): Define.
[pf3gnuchains/gcc-fork.git] / gcc / c-parse.in
1 /* YACC parser for C syntax and for Objective C.  -*-c-*-
2    Copyright (C) 1987, 1988, 1989, 1992, 1993, 1994, 1995, 1996, 1997,
3    1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
4
5 This file is part of GCC.
6
7 GCC is free software; you can redistribute it and/or modify it under
8 the terms of the GNU General Public License as published by the Free
9 Software Foundation; either version 2, or (at your option) any later
10 version.
11
12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
14 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 for more details.
16
17 You should have received a copy of the GNU General Public License
18 along with GCC; see the file COPYING.  If not, write to the Free
19 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
20 02111-1307, USA.  */
21
22 /* This file defines the grammar of C and that of Objective C.
23    @@ifobjc ... @@end_ifobjc  conditionals contain code for Objective C only.
24    @@ifc ... @@end_ifc  conditionals contain code for C only.
25    Sed commands in Makefile.in are used to convert this file into
26    c-parse.y and into objc-parse.y.  */
27
28 /* To whomever it may concern: I have heard that such a thing was once
29    written by AT&T, but I have never seen it.  */
30
31 @@ifc
32 %expect 13 /* shift/reduce conflicts, and no reduce/reduce conflicts.  */
33 @@end_ifc
34
35 %{
36 #include "config.h"
37 #include "system.h"
38 #include "coretypes.h"
39 #include "tm.h"
40 #include "tree.h"
41 #include "langhooks.h"
42 #include "input.h"
43 #include "cpplib.h"
44 #include "intl.h"
45 #include "timevar.h"
46 #include "c-pragma.h"           /* For YYDEBUG definition, and parse_in.  */
47 #include "c-tree.h"
48 #include "flags.h"
49 #include "varray.h"
50 #include "output.h"
51 #include "toplev.h"
52 #include "ggc.h"
53
54 @@ifobjc
55 #include "objc-act.h"
56 @@end_ifobjc
57
58 /* Like YYERROR but do call yyerror.  */
59 #define YYERROR1 { yyerror ("syntax error"); YYERROR; }
60
61 /* Like the default stack expander, except (1) use realloc when possible,
62    (2) impose no hard maxiumum on stack size, (3) REALLY do not use alloca.
63
64    Irritatingly, YYSTYPE is defined after this %{ %} block, so we cannot
65    give malloced_yyvs its proper type.  This is ok since all we need from
66    it is to be able to free it.  */
67
68 static short *malloced_yyss;
69 static void *malloced_yyvs;
70
71 #define yyoverflow(MSG, SS, SSSIZE, VS, VSSIZE, YYSSZ)                  \
72 do {                                                                    \
73   size_t newsize;                                                       \
74   short *newss;                                                         \
75   YYSTYPE *newvs;                                                       \
76   newsize = *(YYSSZ) *= 2;                                              \
77   if (malloced_yyss)                                                    \
78     {                                                                   \
79       newss = really_call_realloc (*(SS), newsize * sizeof (short));    \
80       newvs = really_call_realloc (*(VS), newsize * sizeof (YYSTYPE));  \
81     }                                                                   \
82   else                                                                  \
83     {                                                                   \
84       newss = really_call_malloc (newsize * sizeof (short));            \
85       newvs = really_call_malloc (newsize * sizeof (YYSTYPE));          \
86       if (newss)                                                        \
87         memcpy (newss, *(SS), (SSSIZE));                                \
88       if (newvs)                                                        \
89         memcpy (newvs, *(VS), (VSSIZE));                                \
90     }                                                                   \
91   if (!newss || !newvs)                                                 \
92     {                                                                   \
93       yyerror (MSG);                                                    \
94       return 2;                                                         \
95     }                                                                   \
96   *(SS) = newss;                                                        \
97   *(VS) = newvs;                                                        \
98   malloced_yyss = newss;                                                \
99   malloced_yyvs = (void *) newvs;                                       \
100 } while (0)
101 %}
102
103 %start program
104
105 %union {long itype; tree ttype; struct c_expr exprtype; enum tree_code code;
106         location_t location; }
107
108 /* All identifiers that are not reserved words
109    and are not declared typedefs in the current block */
110 %token IDENTIFIER
111
112 /* All identifiers that are declared typedefs in the current block.
113    In some contexts, they are treated just like IDENTIFIER,
114    but they can also serve as typespecs in declarations.  */
115 %token TYPENAME
116
117 /* Reserved words that specify storage class.
118    yylval contains an IDENTIFIER_NODE which indicates which one.  */
119 %token SCSPEC                   /* Storage class other than static.  */
120 %token STATIC                   /* Static storage class.  */
121
122 /* Reserved words that specify type.
123    yylval contains an IDENTIFIER_NODE which indicates which one.  */
124 %token TYPESPEC
125
126 /* Reserved words that qualify type: "const", "volatile", or "restrict".
127    yylval contains an IDENTIFIER_NODE which indicates which one.  */
128 %token TYPE_QUAL
129
130 /* Character or numeric constants.
131    yylval is the node for the constant.  */
132 %token CONSTANT
133
134 /* String constants in raw form.
135    yylval is a STRING_CST node.  */
136
137 %token STRING
138
139 /* "...", used for functions with variable arglists.  */
140 %token ELLIPSIS
141
142 /* the reserved words */
143 /* SCO include files test "ASM", so use something else. */
144 %token SIZEOF ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
145 %token BREAK CONTINUE RETURN GOTO ASM_KEYWORD TYPEOF ALIGNOF
146 %token ATTRIBUTE EXTENSION LABEL
147 %token REALPART IMAGPART VA_ARG CHOOSE_EXPR TYPES_COMPATIBLE_P
148 %token PTR_VALUE PTR_BASE PTR_EXTENT
149 %token FUNC_NAME OFFSETOF
150
151 /* Add precedence rules to solve dangling else s/r conflict */
152 %nonassoc IF
153 %nonassoc ELSE
154
155 /* Define the operator tokens and their precedences.
156    The value is an integer because, if used, it is the tree code
157    to use in the expression made from the operator.  */
158
159 %right <code> ASSIGN '='
160 %right <code> '?' ':'
161 %left <code> OROR
162 %left <code> ANDAND
163 %left <code> '|'
164 %left <code> '^'
165 %left <code> '&'
166 %left <code> EQCOMPARE
167 %left <code> ARITHCOMPARE
168 %left <code> LSHIFT RSHIFT
169 %left <code> '+' '-'
170 %left <code> '*' '/' '%'
171 %right <code> UNARY PLUSPLUS MINUSMINUS
172 %left HYPERUNARY
173 %left <code> POINTSAT '.' '(' '['
174
175 /* The Objective-C keywords.  These are included in C and in
176    Objective C, so that the token codes are the same in both.  */
177 %token AT_INTERFACE AT_IMPLEMENTATION AT_END AT_SELECTOR AT_DEFS AT_ENCODE
178 %token CLASSNAME AT_PUBLIC AT_PRIVATE AT_PROTECTED AT_PROTOCOL 
179 %token OBJECTNAME AT_CLASS AT_ALIAS
180 %token AT_THROW AT_TRY AT_CATCH AT_FINALLY AT_SYNCHRONIZED
181 %token OBJC_STRING
182
183 %type <code> unop
184 %type <ttype> ENUM STRUCT UNION IF ELSE WHILE DO FOR SWITCH CASE DEFAULT
185 %type <ttype> BREAK CONTINUE RETURN GOTO ASM_KEYWORD SIZEOF TYPEOF ALIGNOF
186
187 %type <ttype> identifier IDENTIFIER TYPENAME CONSTANT STRING FUNC_NAME
188 %type <ttype> nonnull_exprlist exprlist
189 %type <exprtype> expr expr_no_commas cast_expr unary_expr primary
190 %type <ttype> declspecs_nosc_nots_nosa_noea declspecs_nosc_nots_nosa_ea
191 %type <ttype> declspecs_nosc_nots_sa_noea declspecs_nosc_nots_sa_ea
192 %type <ttype> declspecs_nosc_ts_nosa_noea declspecs_nosc_ts_nosa_ea
193 %type <ttype> declspecs_nosc_ts_sa_noea declspecs_nosc_ts_sa_ea
194 %type <ttype> declspecs_sc_nots_nosa_noea declspecs_sc_nots_nosa_ea
195 %type <ttype> declspecs_sc_nots_sa_noea declspecs_sc_nots_sa_ea
196 %type <ttype> declspecs_sc_ts_nosa_noea declspecs_sc_ts_nosa_ea
197 %type <ttype> declspecs_sc_ts_sa_noea declspecs_sc_ts_sa_ea
198 %type <ttype> declspecs_ts declspecs_nots
199 %type <ttype> declspecs_ts_nosa declspecs_nots_nosa
200 %type <ttype> declspecs_nosc_ts declspecs_nosc_nots declspecs_nosc declspecs
201 %type <ttype> maybe_type_quals_attrs typespec_nonattr typespec_attr
202 %type <ttype> typespec_reserved_nonattr typespec_reserved_attr
203 %type <ttype> typespec_nonreserved_nonattr
204 %type <ttype> offsetof_member_designator
205
206 %type <ttype> scspec SCSPEC STATIC TYPESPEC TYPE_QUAL maybe_volatile
207 %type <ttype> initdecls notype_initdecls initdcl notype_initdcl init
208 %type <ttype> simple_asm_expr maybeasm asm_stmt asm_argument
209 %type <ttype> asm_operands nonnull_asm_operands asm_operand asm_clobbers
210 %type <ttype> maybe_attribute attributes attribute attribute_list attrib
211 %type <ttype> any_word
212
213 %type <ttype> compstmt compstmt_start compstmt_primary_start
214 %type <ttype> stmt label stmt_nocomp start_break start_continue
215
216 %type <ttype> c99_block_start c99_block_lineno_labeled_stmt
217 %type <ttype> if_statement_1 if_statement_2
218 %type <ttype> declarator
219 %type <ttype> notype_declarator after_type_declarator
220 %type <ttype> parm_declarator
221 %type <ttype> parm_declarator_starttypename parm_declarator_nostarttypename
222 %type <ttype> array_declarator
223
224 %type <ttype> structsp_attr structsp_nonattr
225 %type <ttype> component_decl_list component_decl_list2
226 %type <ttype> component_decl components components_notype component_declarator
227 %type <ttype> component_notype_declarator
228 %type <ttype> enumlist enumerator
229 %type <ttype> struct_head union_head enum_head
230 %type <ttype> typename absdcl absdcl1 absdcl1_ea absdcl1_noea
231 %type <ttype> direct_absdcl1 absdcl_maybe_attribute
232 %type <ttype> condition xexpr for_cond_expr for_incr_expr
233 %type <ttype> parms parm firstparm identifiers
234
235 %type <ttype> parmlist parmlist_1 parmlist_2
236 %type <ttype> parmlist_or_identifiers parmlist_or_identifiers_1
237 %type <ttype> identifiers_or_typenames
238
239 %type <itype> setspecs setspecs_fp extension
240
241 %type <location> save_location
242 \f
243 @@ifobjc
244 /* the Objective-C nonterminals */
245
246 %type <ttype> ivar_decl_list ivar_decls ivar_decl ivars ivar_declarator
247 %type <ttype> methoddecl unaryselector keywordselector selector
248 %type <ttype> keyworddecl receiver objcmessageexpr messageargs
249 %type <ttype> keywordexpr keywordarglist keywordarg
250 %type <ttype> myparms myparm optparmlist reservedwords objcselectorexpr
251 %type <ttype> selectorarg keywordnamelist keywordname objcencodeexpr
252 %type <ttype> non_empty_protocolrefs protocolrefs identifier_list objcprotocolexpr
253
254 %type <ttype> CLASSNAME OBJECTNAME OBJC_STRING
255
256 %type <ttype> superclass
257 @@end_ifobjc
258 \f
259 %{
260 /* List of types and structure classes of the current declaration.  */
261 static GTY(()) tree current_declspecs;
262 static GTY(()) tree prefix_attributes;
263
264 /* List of all the attributes applying to the identifier currently being
265    declared; includes prefix_attributes and possibly some more attributes
266    just after a comma.  */
267 static GTY(()) tree all_prefix_attributes;
268
269 /* Stack of saved values of current_declspecs, prefix_attributes and
270    all_prefix_attributes.  */
271 static GTY(()) tree declspec_stack;
272
273 /* PUSH_DECLSPEC_STACK is called from setspecs; POP_DECLSPEC_STACK
274    should be called from the productions making use of setspecs.  */
275 #define PUSH_DECLSPEC_STACK                                              \
276   do {                                                                   \
277     declspec_stack = tree_cons (build_tree_list (prefix_attributes,      \
278                                                  all_prefix_attributes), \
279                                 current_declspecs,                       \
280                                 declspec_stack);                         \
281   } while (0)
282
283 #define POP_DECLSPEC_STACK                                              \
284   do {                                                                  \
285     current_declspecs = TREE_VALUE (declspec_stack);                    \
286     prefix_attributes = TREE_PURPOSE (TREE_PURPOSE (declspec_stack));   \
287     all_prefix_attributes = TREE_VALUE (TREE_PURPOSE (declspec_stack)); \
288     declspec_stack = TREE_CHAIN (declspec_stack);                       \
289   } while (0)
290
291 /* For __extension__, save/restore the warning flags which are
292    controlled by __extension__.  */
293 #define SAVE_EXT_FLAGS()                \
294         (pedantic                       \
295          | (warn_pointer_arith << 1)    \
296          | (warn_traditional << 2)      \
297          | (flag_iso << 3))
298
299 #define RESTORE_EXT_FLAGS(val)                  \
300   do {                                          \
301     pedantic = val & 1;                         \
302     warn_pointer_arith = (val >> 1) & 1;        \
303     warn_traditional = (val >> 2) & 1;          \
304     flag_iso = (val >> 3) & 1;                  \
305   } while (0)
306
307 @@ifobjc
308 /* Objective-C specific parser/lexer information */
309
310 static enum tree_code objc_inherit_code;
311 static int objc_pq_context = 0, objc_public_flag = 0;
312
313 /* The following flag is needed to contextualize ObjC lexical analysis.
314    In some cases (e.g., 'int NSObject;'), it is undesirable to bind
315    an identifier to an ObjC class, even if a class with that name
316    exists.  */
317 static int objc_need_raw_identifier;
318 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   objc_need_raw_identifier = VAL
319 @@end_ifobjc
320
321 @@ifc
322 #define OBJC_NEED_RAW_IDENTIFIER(VAL)   /* nothing */
323 @@end_ifc
324
325 /* Tell yyparse how to print a token's value, if yydebug is set.  */
326
327 #define YYPRINT(FILE,YYCHAR,YYLVAL) yyprint(FILE,YYCHAR,YYLVAL)
328
329 static void yyprint (FILE *, int, YYSTYPE);
330 static void yyerror (const char *);
331 static int yylexname (void);
332 static inline int _yylex (void);
333 static int  yylex (void);
334 static void init_reswords (void);
335
336   /* Initialisation routine for this file.  */
337 void
338 c_parse_init (void)
339 {
340   init_reswords ();
341 }
342
343 %}
344 \f
345 %%
346 program: /* empty */
347                 { if (pedantic)
348                     pedwarn ("ISO C forbids an empty source file");
349                 }
350         | extdefs
351         ;
352
353 /* the reason for the strange actions in this rule
354  is so that notype_initdecls when reached via datadef
355  can find a valid list of type and sc specs in $0. */
356
357 extdefs:
358         {$<ttype>$ = NULL_TREE; } extdef
359         | extdefs {$<ttype>$ = NULL_TREE; ggc_collect(); } extdef
360         ;
361
362 extdef:
363         fndef
364         | datadef
365         | asmdef
366         | extension extdef
367                 { RESTORE_EXT_FLAGS ($1); }
368 @@ifobjc
369         | objcdef
370 @@end_ifobjc
371         ;
372
373 datadef:
374           setspecs notype_initdecls ';'
375                 { if (pedantic)
376                     error ("ISO C forbids data definition with no type or storage class");
377                   else
378                     warning ("data definition has no type or storage class");
379
380                   POP_DECLSPEC_STACK; }
381         | declspecs_nots setspecs notype_initdecls ';'
382                 { POP_DECLSPEC_STACK; }
383         | declspecs_ts setspecs initdecls ';'
384                 { POP_DECLSPEC_STACK; }
385         | declspecs ';'
386           { shadow_tag ($1); }
387         | error ';'
388         | error '}'
389         | ';'
390                 { if (pedantic)
391                     pedwarn ("ISO C does not allow extra `;' outside of a function"); }
392         ;
393 \f
394 fndef:
395           declspecs_ts setspecs declarator
396                 { if (! start_function (current_declspecs, $3,
397                                         all_prefix_attributes))
398                     YYERROR1;
399                 }
400           old_style_parm_decls save_location
401                 { DECL_SOURCE_LOCATION (current_function_decl) = $6;
402                   store_parm_decls (); }
403           compstmt_or_error
404                 { finish_function ();
405                   POP_DECLSPEC_STACK; }
406         | declspecs_ts setspecs declarator error
407                 { POP_DECLSPEC_STACK; }
408         | declspecs_nots setspecs notype_declarator
409                 { if (! start_function (current_declspecs, $3,
410                                         all_prefix_attributes))
411                     YYERROR1;
412                 }
413           old_style_parm_decls save_location
414                 { DECL_SOURCE_LOCATION (current_function_decl) = $6;
415                   store_parm_decls (); }
416           compstmt_or_error
417                 { finish_function ();
418                   POP_DECLSPEC_STACK; }
419         | declspecs_nots setspecs notype_declarator error
420                 { POP_DECLSPEC_STACK; }
421         | setspecs notype_declarator
422                 { if (! start_function (NULL_TREE, $2,
423                                         all_prefix_attributes))
424                     YYERROR1;
425                 }
426           old_style_parm_decls save_location
427                 { DECL_SOURCE_LOCATION (current_function_decl) = $5;
428                   store_parm_decls (); }
429           compstmt_or_error
430                 { finish_function ();
431                   POP_DECLSPEC_STACK; }
432         | setspecs notype_declarator error
433                 { POP_DECLSPEC_STACK; }
434         ;
435
436 identifier:
437         IDENTIFIER
438         | TYPENAME
439 @@ifobjc
440         | OBJECTNAME
441         | CLASSNAME
442 @@end_ifobjc
443         ;
444
445 unop:     '&'
446                 { $$ = ADDR_EXPR; }
447         | '-'
448                 { $$ = NEGATE_EXPR; }
449         | '+'
450                 { $$ = CONVERT_EXPR;
451 @@ifc
452   if (warn_traditional && !in_system_header)
453     warning ("traditional C rejects the unary plus operator");
454 @@end_ifc
455                 }
456         | PLUSPLUS
457                 { $$ = PREINCREMENT_EXPR; }
458         | MINUSMINUS
459                 { $$ = PREDECREMENT_EXPR; }
460         | '~'
461                 { $$ = BIT_NOT_EXPR; }
462         | '!'
463                 { $$ = TRUTH_NOT_EXPR; }
464         ;
465
466 expr:   expr_no_commas
467         | expr ',' expr_no_commas
468                 { $$.value = build_compound_expr ($1.value, $3.value);
469                   $$.original_code = COMPOUND_EXPR; }
470         ;
471
472 exprlist:
473           /* empty */
474                 { $$ = NULL_TREE; }
475         | nonnull_exprlist
476         ;
477
478 nonnull_exprlist:
479         expr_no_commas
480                 { $$ = build_tree_list (NULL_TREE, $1.value); }
481         | nonnull_exprlist ',' expr_no_commas
482                 { chainon ($1, build_tree_list (NULL_TREE, $3.value)); }
483         ;
484
485 unary_expr:
486         primary
487         | '*' cast_expr   %prec UNARY
488                 { $$.value = build_indirect_ref ($2.value, "unary *");
489                   $$.original_code = ERROR_MARK; }
490         /* __extension__ turns off -pedantic for following primary.  */
491         | extension cast_expr     %prec UNARY
492                 { $$ = $2;
493                   RESTORE_EXT_FLAGS ($1); }
494         | unop cast_expr  %prec UNARY
495                 { $$.value = build_unary_op ($1, $2.value, 0);
496                   overflow_warning ($$.value);
497                   $$.original_code = ERROR_MARK; }
498         /* Refer to the address of a label as a pointer.  */
499         | ANDAND identifier
500                 { $$.value = finish_label_address_expr ($2);
501                   $$.original_code = ERROR_MARK; }
502         | sizeof unary_expr  %prec UNARY
503                 { skip_evaluation--;
504                   if (TREE_CODE ($2.value) == COMPONENT_REF
505                       && DECL_C_BIT_FIELD (TREE_OPERAND ($2.value, 1)))
506                     error ("`sizeof' applied to a bit-field");
507                   $$.value = c_sizeof (TREE_TYPE ($2.value));
508                   $$.original_code = ERROR_MARK; }
509         | sizeof '(' typename ')'  %prec HYPERUNARY
510                 { skip_evaluation--;
511                   $$.value = c_sizeof (groktypename ($3));
512                   $$.original_code = ERROR_MARK; }
513         | alignof unary_expr  %prec UNARY
514                 { skip_evaluation--;
515                   $$.value = c_alignof_expr ($2.value);
516                   $$.original_code = ERROR_MARK; }
517         | alignof '(' typename ')'  %prec HYPERUNARY
518                 { skip_evaluation--;
519                   $$.value = c_alignof (groktypename ($3));
520                   $$.original_code = ERROR_MARK; }
521         | REALPART cast_expr %prec UNARY
522                 { $$.value = build_unary_op (REALPART_EXPR, $2.value, 0);
523                   $$.original_code = ERROR_MARK; }
524         | IMAGPART cast_expr %prec UNARY
525                 { $$.value = build_unary_op (IMAGPART_EXPR, $2.value, 0);
526                   $$.original_code = ERROR_MARK; }
527         ;
528
529 sizeof:
530         SIZEOF { skip_evaluation++; }
531         ;
532
533 alignof:
534         ALIGNOF { skip_evaluation++; }
535         ;
536
537 typeof:
538         TYPEOF { skip_evaluation++; }
539         ;
540
541 cast_expr:
542         unary_expr
543         | '(' typename ')' cast_expr  %prec UNARY
544                 { $$.value = c_cast_expr ($2, $4.value);
545                   $$.original_code = ERROR_MARK; }
546         ;
547
548 expr_no_commas:
549           cast_expr
550         | expr_no_commas '+' expr_no_commas
551                 { $$ = parser_build_binary_op ($2, $1, $3); }
552         | expr_no_commas '-' expr_no_commas
553                 { $$ = parser_build_binary_op ($2, $1, $3); }
554         | expr_no_commas '*' expr_no_commas
555                 { $$ = parser_build_binary_op ($2, $1, $3); }
556         | expr_no_commas '/' expr_no_commas
557                 { $$ = parser_build_binary_op ($2, $1, $3); }
558         | expr_no_commas '%' expr_no_commas
559                 { $$ = parser_build_binary_op ($2, $1, $3); }
560         | expr_no_commas LSHIFT expr_no_commas
561                 { $$ = parser_build_binary_op ($2, $1, $3); }
562         | expr_no_commas RSHIFT expr_no_commas
563                 { $$ = parser_build_binary_op ($2, $1, $3); }
564         | expr_no_commas ARITHCOMPARE expr_no_commas
565                 { $$ = parser_build_binary_op ($2, $1, $3); }
566         | expr_no_commas EQCOMPARE expr_no_commas
567                 { $$ = parser_build_binary_op ($2, $1, $3); }
568         | expr_no_commas '&' expr_no_commas
569                 { $$ = parser_build_binary_op ($2, $1, $3); }
570         | expr_no_commas '|' expr_no_commas
571                 { $$ = parser_build_binary_op ($2, $1, $3); }
572         | expr_no_commas '^' expr_no_commas
573                 { $$ = parser_build_binary_op ($2, $1, $3); }
574         | expr_no_commas ANDAND
575                 { $1.value = lang_hooks.truthvalue_conversion
576                     (default_conversion ($1.value));
577                   skip_evaluation += $1.value == truthvalue_false_node; }
578           expr_no_commas
579                 { skip_evaluation -= $1.value == truthvalue_false_node;
580                   $$ = parser_build_binary_op (TRUTH_ANDIF_EXPR, $1, $4); }
581         | expr_no_commas OROR
582                 { $1.value = lang_hooks.truthvalue_conversion
583                     (default_conversion ($1.value));
584                   skip_evaluation += $1.value == truthvalue_true_node; }
585           expr_no_commas
586                 { skip_evaluation -= $1.value == truthvalue_true_node;
587                   $$ = parser_build_binary_op (TRUTH_ORIF_EXPR, $1, $4); }
588         | expr_no_commas '?'
589                 { $1.value = lang_hooks.truthvalue_conversion
590                     (default_conversion ($1.value));
591                   skip_evaluation += $1.value == truthvalue_false_node; }
592           expr ':'
593                 { skip_evaluation += (($1.value == truthvalue_true_node)
594                                       - ($1.value == truthvalue_false_node)); }
595           expr_no_commas
596                 { skip_evaluation -= $1.value == truthvalue_true_node;
597                   $$.value = build_conditional_expr ($1.value, $4.value,
598                                                      $7.value);
599                   $$.original_code = ERROR_MARK; }
600         | expr_no_commas '?'
601                 { if (pedantic)
602                     pedwarn ("ISO C forbids omitting the middle term of a ?: expression");
603                   /* Make sure first operand is calculated only once.  */
604                   $<ttype>2 = save_expr (default_conversion ($1.value));
605                   $1.value = lang_hooks.truthvalue_conversion ($<ttype>2);
606                   skip_evaluation += $1.value == truthvalue_true_node; }
607           ':' expr_no_commas
608                 { skip_evaluation -= $1.value == truthvalue_true_node;
609                   $$.value = build_conditional_expr ($1.value, $<ttype>2,
610                                                      $5.value);
611                   $$.original_code = ERROR_MARK; }
612         | expr_no_commas '=' expr_no_commas
613                 { $$.value = build_modify_expr ($1.value, NOP_EXPR, $3.value);
614                   $$.original_code = MODIFY_EXPR;
615                 }
616         | expr_no_commas ASSIGN expr_no_commas
617                 { $$.value = build_modify_expr ($1.value, $2, $3.value);
618                   TREE_NO_WARNING ($$.value) = 1;
619                   $$.original_code = ERROR_MARK;
620                 }
621         ;
622
623 primary:
624         IDENTIFIER
625                 {
626                   if (yychar == YYEMPTY)
627                     yychar = YYLEX;
628                   $$.value = build_external_ref ($1, yychar == '(');
629                   $$.original_code = ERROR_MARK;
630                 }
631         | CONSTANT
632                 { $$.value = $1; $$.original_code = ERROR_MARK; }
633         | STRING
634                 { $$.value = $1; $$.original_code = ERROR_MARK; }
635         | FUNC_NAME
636                 { $$.value = fname_decl (C_RID_CODE ($1), $1);
637                   $$.original_code = ERROR_MARK; }
638         | '(' typename ')' '{'
639                 { start_init (NULL_TREE, NULL, 0);
640                   $2 = groktypename ($2);
641                   really_start_incremental_init ($2); }
642           initlist_maybe_comma '}'  %prec UNARY
643                 { tree constructor = pop_init_level (0);
644                   tree type = $2;
645                   finish_init ();
646
647                   if (pedantic && ! flag_isoc99)
648                     pedwarn ("ISO C90 forbids compound literals");
649                   $$.value = build_compound_literal (type, constructor);
650                   $$.original_code = ERROR_MARK;
651                 }
652         | '(' expr ')'
653                 { $$.value = $2.value;
654                   if (TREE_CODE ($$.value) == MODIFY_EXPR)
655                     TREE_NO_WARNING ($$.value) = 1;
656                   $$.original_code = ERROR_MARK; }
657         | '(' error ')'
658                 { $$.value = error_mark_node; $$.original_code = ERROR_MARK; }
659         | compstmt_primary_start compstmt_nostart ')'
660                 { if (pedantic)
661                     pedwarn ("ISO C forbids braced-groups within expressions");
662                   $$.value = c_finish_stmt_expr ($1);
663                   $$.original_code = ERROR_MARK;
664                 }
665         | compstmt_primary_start error ')'
666                 { c_finish_stmt_expr ($1);
667                   $$.value = error_mark_node;
668                   $$.original_code = ERROR_MARK;
669                 }
670         | primary '(' exprlist ')'   %prec '.'
671                 { $$.value = build_function_call ($1.value, $3);
672                   $$.original_code = ERROR_MARK; }
673         | VA_ARG '(' expr_no_commas ',' typename ')'
674                 { $$.value = build_va_arg ($3.value, groktypename ($5));
675                   $$.original_code = ERROR_MARK; }
676
677         | OFFSETOF '(' typename ',' offsetof_member_designator ')'
678                 { $$.value = build_offsetof (groktypename ($3), $5);
679                   $$.original_code = ERROR_MARK; }
680         | OFFSETOF '(' error ')'
681                 { $$.value = error_mark_node; $$.original_code = ERROR_MARK; }
682         | CHOOSE_EXPR '(' expr_no_commas ',' expr_no_commas ','
683                           expr_no_commas ')'
684                 {
685                   tree c;
686
687                   c = fold ($3.value);
688                   STRIP_NOPS (c);
689                   if (TREE_CODE (c) != INTEGER_CST)
690                     error ("first argument to __builtin_choose_expr not"
691                            " a constant");
692                   $$ = integer_zerop (c) ? $7 : $5;
693                 }
694         | CHOOSE_EXPR '(' error ')'
695                 { $$.value = error_mark_node; $$.original_code = ERROR_MARK; }
696         | TYPES_COMPATIBLE_P '(' typename ',' typename ')'
697                 {
698                   tree e1, e2;
699
700                   e1 = TYPE_MAIN_VARIANT (groktypename ($3));
701                   e2 = TYPE_MAIN_VARIANT (groktypename ($5));
702
703                   $$.value = comptypes (e1, e2)
704                     ? build_int_2 (1, 0) : build_int_2 (0, 0);
705                   $$.original_code = ERROR_MARK;
706                 }
707         | TYPES_COMPATIBLE_P '(' error ')'
708                 { $$.value = error_mark_node; $$.original_code = ERROR_MARK; }
709         | primary '[' expr ']'   %prec '.'
710                 { $$.value = build_array_ref ($1.value, $3.value);
711                   $$.original_code = ERROR_MARK; }
712         | primary '.' identifier
713                 { $$.value = build_component_ref ($1.value, $3);
714                   $$.original_code = ERROR_MARK; }
715         | primary POINTSAT identifier
716                 {
717                   tree expr = build_indirect_ref ($1.value, "->");
718                   $$.value = build_component_ref (expr, $3);
719                   $$.original_code = ERROR_MARK;
720                 }
721         | primary PLUSPLUS
722                 { $$.value = build_unary_op (POSTINCREMENT_EXPR, $1.value, 0);
723                   $$.original_code = ERROR_MARK; }
724         | primary MINUSMINUS
725                 { $$.value = build_unary_op (POSTDECREMENT_EXPR, $1.value, 0);
726                   $$.original_code = ERROR_MARK; }
727 @@ifobjc
728         | objcmessageexpr
729                 { $$.value = build_message_expr ($1);
730                   $$.original_code = ERROR_MARK; }
731         | objcselectorexpr
732                 { $$.value = build_selector_expr ($1);
733                   $$.original_code = ERROR_MARK; }
734         | objcprotocolexpr
735                 { $$.value = build_protocol_expr ($1);
736                   $$.original_code = ERROR_MARK; }
737         | objcencodeexpr
738                 { $$.value = build_encode_expr ($1);
739                   $$.original_code = ERROR_MARK; }
740         | OBJC_STRING
741                 { $$.value = build_objc_string_object ($1);
742                   $$.original_code = ERROR_MARK; }
743 @@end_ifobjc
744         ;
745
746 /* This is the second argument to __builtin_offsetof.  We must have one
747    identifier, and beyond that we want to accept sub structure and sub
748    array references.  We return tree list where each element has
749    PURPOSE set for component refs or VALUE set for array refs.  We'll
750    turn this into something real inside build_offsetof.  */
751
752 offsetof_member_designator:
753           identifier
754                 { $$ = tree_cons ($1, NULL_TREE, NULL_TREE); }
755         | offsetof_member_designator '.' identifier
756                 { $$ = tree_cons ($3, NULL_TREE, $1); }
757         | offsetof_member_designator '[' expr ']'
758                 { $$ = tree_cons (NULL_TREE, $3.value, $1); }
759         ;
760
761 old_style_parm_decls:
762         /* empty */
763         | datadecls
764         ;
765
766 /* The following are analogous to lineno_decl, decls and decl
767    except that they do not allow nested functions.
768    They are used for old-style parm decls.  */
769 lineno_datadecl:
770           save_location datadecl
771                 { }
772         ;
773
774 datadecls:
775         lineno_datadecl
776         | errstmt
777         | datadecls lineno_datadecl
778         | lineno_datadecl errstmt
779         ;
780
781 /* We don't allow prefix attributes here because they cause reduce/reduce
782    conflicts: we can't know whether we're parsing a function decl with
783    attribute suffix, or function defn with attribute prefix on first old
784    style parm.  */
785 datadecl:
786         declspecs_ts_nosa setspecs initdecls ';'
787                 { POP_DECLSPEC_STACK; }
788         | declspecs_nots_nosa setspecs notype_initdecls ';'
789                 { POP_DECLSPEC_STACK; }
790         | declspecs_ts_nosa ';'
791                 { shadow_tag_warned ($1, 1);
792                   pedwarn ("empty declaration"); }
793         | declspecs_nots_nosa ';'
794                 { pedwarn ("empty declaration"); }
795         ;
796
797 /* This combination which saves a lineno before a decl
798    is the normal thing to use, rather than decl itself.
799    This is to avoid shift/reduce conflicts in contexts
800    where statement labels are allowed.  */
801 lineno_decl:
802           save_location decl
803                 { }
804         ;
805
806 /* records the type and storage class specs to use for processing
807    the declarators that follow.
808    Maintains a stack of outer-level values of current_declspecs,
809    for the sake of parm declarations nested in function declarators.  */
810 setspecs: /* empty */
811                 { pending_xref_error ();
812                   PUSH_DECLSPEC_STACK;
813                   split_specs_attrs ($<ttype>0,
814                                      &current_declspecs, &prefix_attributes);
815                   all_prefix_attributes = prefix_attributes; }
816         ;
817
818 /* Possibly attributes after a comma, which should reset all_prefix_attributes
819    to prefix_attributes with these ones chained on the front.  */
820 maybe_resetattrs:
821           maybe_attribute
822                 { all_prefix_attributes = chainon ($1, prefix_attributes); }
823         ;
824
825 decl:
826         declspecs_ts setspecs initdecls ';'
827                 { POP_DECLSPEC_STACK; }
828         | declspecs_nots setspecs notype_initdecls ';'
829                 { POP_DECLSPEC_STACK; }
830         | declspecs_ts setspecs nested_function
831                 { POP_DECLSPEC_STACK; }
832         | declspecs_nots setspecs notype_nested_function
833                 { POP_DECLSPEC_STACK; }
834         | declspecs ';'
835                 { shadow_tag ($1); }
836         | extension decl
837                 { RESTORE_EXT_FLAGS ($1); }
838         ;
839
840 /* A list of declaration specifiers.  These are:
841
842    - Storage class specifiers (scspec), which for GCC currently includes
843    function specifiers ("inline").
844
845    - Type specifiers (typespec_*).
846
847    - Type qualifiers (TYPE_QUAL).
848
849    - Attribute specifier lists (attributes).
850
851    These are stored as a TREE_LIST; the head of the list is the last
852    item in the specifier list.  Each entry in the list has either a
853    TREE_PURPOSE that is an attribute specifier list, or a TREE_VALUE that
854    is a single other specifier or qualifier; and a TREE_CHAIN that is the
855    rest of the list.  TREE_STATIC is set on the list if something other
856    than a storage class specifier or attribute has been seen; this is used
857    to warn for the obsolescent usage of storage class specifiers other than
858    at the start of the list.  (Doing this properly would require function
859    specifiers to be handled separately from storage class specifiers.)
860
861    The various cases below are classified according to:
862
863    (a) Whether a storage class specifier is included or not; some
864    places in the grammar disallow storage class specifiers (_sc or _nosc).
865
866    (b) Whether a type specifier has been seen; after a type specifier,
867    a typedef name is an identifier to redeclare (_ts or _nots).
868
869    (c) Whether the list starts with an attribute; in certain places,
870    the grammar requires specifiers that don't start with an attribute
871    (_sa or _nosa).
872
873    (d) Whether the list ends with an attribute (or a specifier such that
874    any following attribute would have been parsed as part of that specifier);
875    this avoids shift-reduce conflicts in the parsing of attributes
876    (_ea or _noea).
877
878    TODO:
879
880    (i) Distinguish between function specifiers and storage class specifiers,
881    at least for the purpose of warnings about obsolescent usage.
882
883    (ii) Halve the number of productions here by eliminating the _sc/_nosc
884    distinction and instead checking where required that storage class
885    specifiers aren't present.  */
886
887 /* Declspecs which contain at least one type specifier or typedef name.
888    (Just `const' or `volatile' is not enough.)
889    A typedef'd name following these is taken as a name to be declared.
890    Declspecs have a non-NULL TREE_VALUE, attributes do not.  */
891
892 declspecs_nosc_nots_nosa_noea:
893           TYPE_QUAL
894                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
895                   TREE_STATIC ($$) = 1; }
896         | declspecs_nosc_nots_nosa_noea TYPE_QUAL
897                 { $$ = tree_cons (NULL_TREE, $2, $1);
898                   TREE_STATIC ($$) = 1; }
899         | declspecs_nosc_nots_nosa_ea TYPE_QUAL
900                 { $$ = tree_cons (NULL_TREE, $2, $1);
901                   TREE_STATIC ($$) = 1; }
902         ;
903
904 declspecs_nosc_nots_nosa_ea:
905           declspecs_nosc_nots_nosa_noea attributes
906                 { $$ = tree_cons ($2, NULL_TREE, $1);
907                   TREE_STATIC ($$) = TREE_STATIC ($1); }
908         ;
909
910 declspecs_nosc_nots_sa_noea:
911           declspecs_nosc_nots_sa_noea TYPE_QUAL
912                 { $$ = tree_cons (NULL_TREE, $2, $1);
913                   TREE_STATIC ($$) = 1; }
914         | declspecs_nosc_nots_sa_ea TYPE_QUAL
915                 { $$ = tree_cons (NULL_TREE, $2, $1);
916                   TREE_STATIC ($$) = 1; }
917         ;
918
919 declspecs_nosc_nots_sa_ea:
920           attributes
921                 { $$ = tree_cons ($1, NULL_TREE, NULL_TREE);
922                   TREE_STATIC ($$) = 0; }
923         | declspecs_nosc_nots_sa_noea attributes
924                 { $$ = tree_cons ($2, NULL_TREE, $1);
925                   TREE_STATIC ($$) = TREE_STATIC ($1); }
926         ;
927
928 declspecs_nosc_ts_nosa_noea:
929           typespec_nonattr
930                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
931                   TREE_STATIC ($$) = 1; }
932         | declspecs_nosc_ts_nosa_noea TYPE_QUAL
933                 { $$ = tree_cons (NULL_TREE, $2, $1);
934                   TREE_STATIC ($$) = 1; }
935         | declspecs_nosc_ts_nosa_ea TYPE_QUAL
936                 { $$ = tree_cons (NULL_TREE, $2, $1);
937                   TREE_STATIC ($$) = 1; }
938         | declspecs_nosc_ts_nosa_noea typespec_reserved_nonattr
939                 { $$ = tree_cons (NULL_TREE, $2, $1);
940                   TREE_STATIC ($$) = 1; }
941         | declspecs_nosc_ts_nosa_ea typespec_reserved_nonattr
942                 { $$ = tree_cons (NULL_TREE, $2, $1);
943                   TREE_STATIC ($$) = 1; }
944         | declspecs_nosc_nots_nosa_noea typespec_nonattr
945                 { $$ = tree_cons (NULL_TREE, $2, $1);
946                   TREE_STATIC ($$) = 1; }
947         | declspecs_nosc_nots_nosa_ea typespec_nonattr
948                 { $$ = tree_cons (NULL_TREE, $2, $1);
949                   TREE_STATIC ($$) = 1; }
950         ;
951
952 declspecs_nosc_ts_nosa_ea:
953           typespec_attr
954                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
955                   TREE_STATIC ($$) = 1; }
956         | declspecs_nosc_ts_nosa_noea attributes
957                 { $$ = tree_cons ($2, NULL_TREE, $1);
958                   TREE_STATIC ($$) = TREE_STATIC ($1); }
959         | declspecs_nosc_ts_nosa_noea typespec_reserved_attr
960                 { $$ = tree_cons (NULL_TREE, $2, $1);
961                   TREE_STATIC ($$) = 1; }
962         | declspecs_nosc_ts_nosa_ea typespec_reserved_attr
963                 { $$ = tree_cons (NULL_TREE, $2, $1);
964                   TREE_STATIC ($$) = 1; }
965         | declspecs_nosc_nots_nosa_noea typespec_attr
966                 { $$ = tree_cons (NULL_TREE, $2, $1);
967                   TREE_STATIC ($$) = 1; }
968         | declspecs_nosc_nots_nosa_ea typespec_attr
969                 { $$ = tree_cons (NULL_TREE, $2, $1);
970                   TREE_STATIC ($$) = 1; }
971         ;
972
973 declspecs_nosc_ts_sa_noea:
974           declspecs_nosc_ts_sa_noea TYPE_QUAL
975                 { $$ = tree_cons (NULL_TREE, $2, $1);
976                   TREE_STATIC ($$) = 1; }
977         | declspecs_nosc_ts_sa_ea TYPE_QUAL
978                 { $$ = tree_cons (NULL_TREE, $2, $1);
979                   TREE_STATIC ($$) = 1; }
980         | declspecs_nosc_ts_sa_noea typespec_reserved_nonattr
981                 { $$ = tree_cons (NULL_TREE, $2, $1);
982                   TREE_STATIC ($$) = 1; }
983         | declspecs_nosc_ts_sa_ea typespec_reserved_nonattr
984                 { $$ = tree_cons (NULL_TREE, $2, $1);
985                   TREE_STATIC ($$) = 1; }
986         | declspecs_nosc_nots_sa_noea typespec_nonattr
987                 { $$ = tree_cons (NULL_TREE, $2, $1);
988                   TREE_STATIC ($$) = 1; }
989         | declspecs_nosc_nots_sa_ea typespec_nonattr
990                 { $$ = tree_cons (NULL_TREE, $2, $1);
991                   TREE_STATIC ($$) = 1; }
992         ;
993
994 declspecs_nosc_ts_sa_ea:
995           declspecs_nosc_ts_sa_noea attributes
996                 { $$ = tree_cons ($2, NULL_TREE, $1);
997                   TREE_STATIC ($$) = TREE_STATIC ($1); }
998         | declspecs_nosc_ts_sa_noea typespec_reserved_attr
999                 { $$ = tree_cons (NULL_TREE, $2, $1);
1000                   TREE_STATIC ($$) = 1; }
1001         | declspecs_nosc_ts_sa_ea typespec_reserved_attr
1002                 { $$ = tree_cons (NULL_TREE, $2, $1);
1003                   TREE_STATIC ($$) = 1; }
1004         | declspecs_nosc_nots_sa_noea typespec_attr
1005                 { $$ = tree_cons (NULL_TREE, $2, $1);
1006                   TREE_STATIC ($$) = 1; }
1007         | declspecs_nosc_nots_sa_ea typespec_attr
1008                 { $$ = tree_cons (NULL_TREE, $2, $1);
1009                   TREE_STATIC ($$) = 1; }
1010         ;
1011
1012 declspecs_sc_nots_nosa_noea:
1013           scspec
1014                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE);
1015                   TREE_STATIC ($$) = 0; }
1016         | declspecs_sc_nots_nosa_noea TYPE_QUAL
1017                 { $$ = tree_cons (NULL_TREE, $2, $1);
1018                   TREE_STATIC ($$) = 1; }
1019         | declspecs_sc_nots_nosa_ea TYPE_QUAL
1020                 { $$ = tree_cons (NULL_TREE, $2, $1);
1021                   TREE_STATIC ($$) = 1; }
1022         | declspecs_nosc_nots_nosa_noea scspec
1023                 { if (extra_warnings && TREE_STATIC ($1))
1024                     warning ("`%s' is not at beginning of declaration",
1025                              IDENTIFIER_POINTER ($2));
1026                   $$ = tree_cons (NULL_TREE, $2, $1);
1027                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1028         | declspecs_nosc_nots_nosa_ea scspec
1029                 { if (extra_warnings && TREE_STATIC ($1))
1030                     warning ("`%s' is not at beginning of declaration",
1031                              IDENTIFIER_POINTER ($2));
1032                   $$ = tree_cons (NULL_TREE, $2, $1);
1033                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1034         | declspecs_sc_nots_nosa_noea scspec
1035                 { if (extra_warnings && TREE_STATIC ($1))
1036                     warning ("`%s' is not at beginning of declaration",
1037                              IDENTIFIER_POINTER ($2));
1038                   $$ = tree_cons (NULL_TREE, $2, $1);
1039                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1040         | declspecs_sc_nots_nosa_ea scspec
1041                 { if (extra_warnings && TREE_STATIC ($1))
1042                     warning ("`%s' is not at beginning of declaration",
1043                              IDENTIFIER_POINTER ($2));
1044                   $$ = tree_cons (NULL_TREE, $2, $1);
1045                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1046         ;
1047
1048 declspecs_sc_nots_nosa_ea:
1049           declspecs_sc_nots_nosa_noea attributes
1050                 { $$ = tree_cons ($2, NULL_TREE, $1);
1051                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1052         ;
1053
1054 declspecs_sc_nots_sa_noea:
1055           declspecs_sc_nots_sa_noea TYPE_QUAL
1056                 { $$ = tree_cons (NULL_TREE, $2, $1);
1057                   TREE_STATIC ($$) = 1; }
1058         | declspecs_sc_nots_sa_ea TYPE_QUAL
1059                 { $$ = tree_cons (NULL_TREE, $2, $1);
1060                   TREE_STATIC ($$) = 1; }
1061         | declspecs_nosc_nots_sa_noea scspec
1062                 { if (extra_warnings && TREE_STATIC ($1))
1063                     warning ("`%s' is not at beginning of declaration",
1064                              IDENTIFIER_POINTER ($2));
1065                   $$ = tree_cons (NULL_TREE, $2, $1);
1066                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1067         | declspecs_nosc_nots_sa_ea scspec
1068                 { if (extra_warnings && TREE_STATIC ($1))
1069                     warning ("`%s' is not at beginning of declaration",
1070                              IDENTIFIER_POINTER ($2));
1071                   $$ = tree_cons (NULL_TREE, $2, $1);
1072                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1073         | declspecs_sc_nots_sa_noea scspec
1074                 { if (extra_warnings && TREE_STATIC ($1))
1075                     warning ("`%s' is not at beginning of declaration",
1076                              IDENTIFIER_POINTER ($2));
1077                   $$ = tree_cons (NULL_TREE, $2, $1);
1078                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1079         | declspecs_sc_nots_sa_ea scspec
1080                 { if (extra_warnings && TREE_STATIC ($1))
1081                     warning ("`%s' is not at beginning of declaration",
1082                              IDENTIFIER_POINTER ($2));
1083                   $$ = tree_cons (NULL_TREE, $2, $1);
1084                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1085         ;
1086
1087 declspecs_sc_nots_sa_ea:
1088           declspecs_sc_nots_sa_noea attributes
1089                 { $$ = tree_cons ($2, NULL_TREE, $1);
1090                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1091         ;
1092
1093 declspecs_sc_ts_nosa_noea:
1094           declspecs_sc_ts_nosa_noea TYPE_QUAL
1095                 { $$ = tree_cons (NULL_TREE, $2, $1);
1096                   TREE_STATIC ($$) = 1; }
1097         | declspecs_sc_ts_nosa_ea TYPE_QUAL
1098                 { $$ = tree_cons (NULL_TREE, $2, $1);
1099                   TREE_STATIC ($$) = 1; }
1100         | declspecs_sc_ts_nosa_noea typespec_reserved_nonattr
1101                 { $$ = tree_cons (NULL_TREE, $2, $1);
1102                   TREE_STATIC ($$) = 1; }
1103         | declspecs_sc_ts_nosa_ea typespec_reserved_nonattr
1104                 { $$ = tree_cons (NULL_TREE, $2, $1);
1105                   TREE_STATIC ($$) = 1; }
1106         | declspecs_sc_nots_nosa_noea typespec_nonattr
1107                 { $$ = tree_cons (NULL_TREE, $2, $1);
1108                   TREE_STATIC ($$) = 1; }
1109         | declspecs_sc_nots_nosa_ea typespec_nonattr
1110                 { $$ = tree_cons (NULL_TREE, $2, $1);
1111                   TREE_STATIC ($$) = 1; }
1112         | declspecs_nosc_ts_nosa_noea scspec
1113                 { if (extra_warnings && TREE_STATIC ($1))
1114                     warning ("`%s' is not at beginning of declaration",
1115                              IDENTIFIER_POINTER ($2));
1116                   $$ = tree_cons (NULL_TREE, $2, $1);
1117                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1118         | declspecs_nosc_ts_nosa_ea scspec
1119                 { if (extra_warnings && TREE_STATIC ($1))
1120                     warning ("`%s' is not at beginning of declaration",
1121                              IDENTIFIER_POINTER ($2));
1122                   $$ = tree_cons (NULL_TREE, $2, $1);
1123                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1124         | declspecs_sc_ts_nosa_noea scspec
1125                 { if (extra_warnings && TREE_STATIC ($1))
1126                     warning ("`%s' is not at beginning of declaration",
1127                              IDENTIFIER_POINTER ($2));
1128                   $$ = tree_cons (NULL_TREE, $2, $1);
1129                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1130         | declspecs_sc_ts_nosa_ea scspec
1131                 { if (extra_warnings && TREE_STATIC ($1))
1132                     warning ("`%s' is not at beginning of declaration",
1133                              IDENTIFIER_POINTER ($2));
1134                   $$ = tree_cons (NULL_TREE, $2, $1);
1135                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1136         ;
1137
1138 declspecs_sc_ts_nosa_ea:
1139           declspecs_sc_ts_nosa_noea attributes
1140                 { $$ = tree_cons ($2, NULL_TREE, $1);
1141                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1142         | declspecs_sc_ts_nosa_noea typespec_reserved_attr
1143                 { $$ = tree_cons (NULL_TREE, $2, $1);
1144                   TREE_STATIC ($$) = 1; }
1145         | declspecs_sc_ts_nosa_ea typespec_reserved_attr
1146                 { $$ = tree_cons (NULL_TREE, $2, $1);
1147                   TREE_STATIC ($$) = 1; }
1148         | declspecs_sc_nots_nosa_noea typespec_attr
1149                 { $$ = tree_cons (NULL_TREE, $2, $1);
1150                   TREE_STATIC ($$) = 1; }
1151         | declspecs_sc_nots_nosa_ea typespec_attr
1152                 { $$ = tree_cons (NULL_TREE, $2, $1);
1153                   TREE_STATIC ($$) = 1; }
1154         ;
1155
1156 declspecs_sc_ts_sa_noea:
1157           declspecs_sc_ts_sa_noea TYPE_QUAL
1158                 { $$ = tree_cons (NULL_TREE, $2, $1);
1159                   TREE_STATIC ($$) = 1; }
1160         | declspecs_sc_ts_sa_ea TYPE_QUAL
1161                 { $$ = tree_cons (NULL_TREE, $2, $1);
1162                   TREE_STATIC ($$) = 1; }
1163         | declspecs_sc_ts_sa_noea typespec_reserved_nonattr
1164                 { $$ = tree_cons (NULL_TREE, $2, $1);
1165                   TREE_STATIC ($$) = 1; }
1166         | declspecs_sc_ts_sa_ea typespec_reserved_nonattr
1167                 { $$ = tree_cons (NULL_TREE, $2, $1);
1168                   TREE_STATIC ($$) = 1; }
1169         | declspecs_sc_nots_sa_noea typespec_nonattr
1170                 { $$ = tree_cons (NULL_TREE, $2, $1);
1171                   TREE_STATIC ($$) = 1; }
1172         | declspecs_sc_nots_sa_ea typespec_nonattr
1173                 { $$ = tree_cons (NULL_TREE, $2, $1);
1174                   TREE_STATIC ($$) = 1; }
1175         | declspecs_nosc_ts_sa_noea scspec
1176                 { if (extra_warnings && TREE_STATIC ($1))
1177                     warning ("`%s' is not at beginning of declaration",
1178                              IDENTIFIER_POINTER ($2));
1179                   $$ = tree_cons (NULL_TREE, $2, $1);
1180                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1181         | declspecs_nosc_ts_sa_ea scspec
1182                 { if (extra_warnings && TREE_STATIC ($1))
1183                     warning ("`%s' is not at beginning of declaration",
1184                              IDENTIFIER_POINTER ($2));
1185                   $$ = tree_cons (NULL_TREE, $2, $1);
1186                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1187         | declspecs_sc_ts_sa_noea scspec
1188                 { if (extra_warnings && TREE_STATIC ($1))
1189                     warning ("`%s' is not at beginning of declaration",
1190                              IDENTIFIER_POINTER ($2));
1191                   $$ = tree_cons (NULL_TREE, $2, $1);
1192                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1193         | declspecs_sc_ts_sa_ea scspec
1194                 { if (extra_warnings && TREE_STATIC ($1))
1195                     warning ("`%s' is not at beginning of declaration",
1196                              IDENTIFIER_POINTER ($2));
1197                   $$ = tree_cons (NULL_TREE, $2, $1);
1198                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1199         ;
1200
1201 declspecs_sc_ts_sa_ea:
1202           declspecs_sc_ts_sa_noea attributes
1203                 { $$ = tree_cons ($2, NULL_TREE, $1);
1204                   TREE_STATIC ($$) = TREE_STATIC ($1); }
1205         | declspecs_sc_ts_sa_noea typespec_reserved_attr
1206                 { $$ = tree_cons (NULL_TREE, $2, $1);
1207                   TREE_STATIC ($$) = 1; }
1208         | declspecs_sc_ts_sa_ea typespec_reserved_attr
1209                 { $$ = tree_cons (NULL_TREE, $2, $1);
1210                   TREE_STATIC ($$) = 1; }
1211         | declspecs_sc_nots_sa_noea typespec_attr
1212                 { $$ = tree_cons (NULL_TREE, $2, $1);
1213                   TREE_STATIC ($$) = 1; }
1214         | declspecs_sc_nots_sa_ea typespec_attr
1215                 { $$ = tree_cons (NULL_TREE, $2, $1);
1216                   TREE_STATIC ($$) = 1; }
1217         ;
1218
1219 /* Particular useful classes of declspecs.  */
1220 declspecs_ts:
1221           declspecs_nosc_ts_nosa_noea
1222         | declspecs_nosc_ts_nosa_ea
1223         | declspecs_nosc_ts_sa_noea
1224         | declspecs_nosc_ts_sa_ea
1225         | declspecs_sc_ts_nosa_noea
1226         | declspecs_sc_ts_nosa_ea
1227         | declspecs_sc_ts_sa_noea
1228         | declspecs_sc_ts_sa_ea
1229         ;
1230
1231 declspecs_nots:
1232           declspecs_nosc_nots_nosa_noea
1233         | declspecs_nosc_nots_nosa_ea
1234         | declspecs_nosc_nots_sa_noea
1235         | declspecs_nosc_nots_sa_ea
1236         | declspecs_sc_nots_nosa_noea
1237         | declspecs_sc_nots_nosa_ea
1238         | declspecs_sc_nots_sa_noea
1239         | declspecs_sc_nots_sa_ea
1240         ;
1241
1242 declspecs_ts_nosa:
1243           declspecs_nosc_ts_nosa_noea
1244         | declspecs_nosc_ts_nosa_ea
1245         | declspecs_sc_ts_nosa_noea
1246         | declspecs_sc_ts_nosa_ea
1247         ;
1248
1249 declspecs_nots_nosa:
1250           declspecs_nosc_nots_nosa_noea
1251         | declspecs_nosc_nots_nosa_ea
1252         | declspecs_sc_nots_nosa_noea
1253         | declspecs_sc_nots_nosa_ea
1254         ;
1255
1256 declspecs_nosc_ts:
1257           declspecs_nosc_ts_nosa_noea
1258         | declspecs_nosc_ts_nosa_ea
1259         | declspecs_nosc_ts_sa_noea
1260         | declspecs_nosc_ts_sa_ea
1261         ;
1262
1263 declspecs_nosc_nots:
1264           declspecs_nosc_nots_nosa_noea
1265         | declspecs_nosc_nots_nosa_ea
1266         | declspecs_nosc_nots_sa_noea
1267         | declspecs_nosc_nots_sa_ea
1268         ;
1269
1270 declspecs_nosc:
1271           declspecs_nosc_ts_nosa_noea
1272         | declspecs_nosc_ts_nosa_ea
1273         | declspecs_nosc_ts_sa_noea
1274         | declspecs_nosc_ts_sa_ea
1275         | declspecs_nosc_nots_nosa_noea
1276         | declspecs_nosc_nots_nosa_ea
1277         | declspecs_nosc_nots_sa_noea
1278         | declspecs_nosc_nots_sa_ea
1279         ;
1280
1281 declspecs:
1282           declspecs_nosc_nots_nosa_noea
1283         | declspecs_nosc_nots_nosa_ea
1284         | declspecs_nosc_nots_sa_noea
1285         | declspecs_nosc_nots_sa_ea
1286         | declspecs_nosc_ts_nosa_noea
1287         | declspecs_nosc_ts_nosa_ea
1288         | declspecs_nosc_ts_sa_noea
1289         | declspecs_nosc_ts_sa_ea
1290         | declspecs_sc_nots_nosa_noea
1291         | declspecs_sc_nots_nosa_ea
1292         | declspecs_sc_nots_sa_noea
1293         | declspecs_sc_nots_sa_ea
1294         | declspecs_sc_ts_nosa_noea
1295         | declspecs_sc_ts_nosa_ea
1296         | declspecs_sc_ts_sa_noea
1297         | declspecs_sc_ts_sa_ea
1298         ;
1299
1300 /* A (possibly empty) sequence of type qualifiers and attributes.  */
1301 maybe_type_quals_attrs:
1302           /* empty */
1303                 { $$ = NULL_TREE; }
1304         | declspecs_nosc_nots
1305                 { $$ = $1; }
1306         ;
1307
1308 /* A type specifier (but not a type qualifier).
1309    Once we have seen one of these in a declaration,
1310    if a typedef name appears then it is being redeclared.
1311
1312    The _reserved versions start with a reserved word and may appear anywhere
1313    in the declaration specifiers; the _nonreserved versions may only
1314    appear before any other type specifiers, and after that are (if names)
1315    being redeclared.
1316
1317    FIXME: should the _nonreserved version be restricted to names being
1318    redeclared only?  The other entries there relate only the GNU extensions
1319    and Objective C, and are historically parsed thus, and don't make sense
1320    after other type specifiers, but it might be cleaner to count them as
1321    _reserved.
1322
1323    _attr means: specifiers that either end with attributes,
1324    or are such that any following attributes would
1325    be parsed as part of the specifier.
1326
1327    _nonattr: specifiers.  */
1328
1329 typespec_nonattr:
1330           typespec_reserved_nonattr
1331         | typespec_nonreserved_nonattr
1332         ;
1333
1334 typespec_attr:
1335           typespec_reserved_attr
1336         ;
1337
1338 typespec_reserved_nonattr:
1339           TYPESPEC
1340                 { OBJC_NEED_RAW_IDENTIFIER (1); }
1341         | structsp_nonattr
1342         ;
1343
1344 typespec_reserved_attr:
1345           structsp_attr
1346         ;
1347
1348 typespec_nonreserved_nonattr:
1349           TYPENAME
1350                 { /* For a typedef name, record the meaning, not the name.
1351                      In case of `foo foo, bar;'.  */
1352                   $$ = lookup_name ($1); }
1353 @@ifobjc
1354         | CLASSNAME protocolrefs
1355                 { $$ = get_static_reference ($1, $2); }
1356         | OBJECTNAME protocolrefs
1357                 { $$ = get_protocol_reference ($2); }
1358
1359 /* Make "<SomeProtocol>" equivalent to "id <SomeProtocol>"
1360    - nisse@lysator.liu.se */
1361         | non_empty_protocolrefs
1362                 { $$ = get_protocol_reference ($1); }
1363 @@end_ifobjc
1364         | typeof '(' expr ')'
1365                 { skip_evaluation--;
1366                   if (TREE_CODE ($3.value) == COMPONENT_REF
1367                       && DECL_C_BIT_FIELD (TREE_OPERAND ($3.value, 1)))
1368                     error ("`typeof' applied to a bit-field");
1369                   $$ = TREE_TYPE ($3.value); }
1370         | typeof '(' typename ')'
1371                 { skip_evaluation--; $$ = groktypename ($3); }
1372         ;
1373
1374 /* typespec_nonreserved_attr does not exist.  */
1375
1376 initdecls:
1377         initdcl
1378         | initdecls ',' maybe_resetattrs initdcl
1379         ;
1380
1381 notype_initdecls:
1382         notype_initdcl
1383         | notype_initdecls ',' maybe_resetattrs notype_initdcl
1384         ;
1385
1386 initdcl:
1387           declarator maybeasm maybe_attribute '='
1388                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1389                                           chainon ($3, all_prefix_attributes));
1390                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1391           init
1392 /* Note how the declaration of the variable is in effect while its init is parsed! */
1393                 { finish_init ();
1394                   finish_decl ($<ttype>5, $6, $2); }
1395         | declarator maybeasm maybe_attribute
1396                 { tree d = start_decl ($1, current_declspecs, 0,
1397                                        chainon ($3, all_prefix_attributes));
1398                   finish_decl (d, NULL_TREE, $2);
1399                 }
1400         ;
1401
1402 notype_initdcl:
1403           notype_declarator maybeasm maybe_attribute '='
1404                 { $<ttype>$ = start_decl ($1, current_declspecs, 1,
1405                                           chainon ($3, all_prefix_attributes));
1406                   start_init ($<ttype>$, $2, global_bindings_p ()); }
1407           init
1408 /* Note how the declaration of the variable is in effect while its init is parsed! */
1409                 { finish_init ();
1410                   finish_decl ($<ttype>5, $6, $2); }
1411         | notype_declarator maybeasm maybe_attribute
1412                 { tree d = start_decl ($1, current_declspecs, 0,
1413                                        chainon ($3, all_prefix_attributes));
1414                   finish_decl (d, NULL_TREE, $2); }
1415         ;
1416 /* the * rules are dummies to accept the Apollo extended syntax
1417    so that the header files compile. */
1418 maybe_attribute:
1419       /* empty */
1420                 { $$ = NULL_TREE; }
1421         | attributes
1422                 { $$ = $1; }
1423         ;
1424
1425 attributes:
1426       attribute
1427                 { $$ = $1; }
1428         | attributes attribute
1429                 { $$ = chainon ($1, $2); }
1430         ;
1431
1432 attribute:
1433       ATTRIBUTE stop_string_translation
1434                 '(' '(' attribute_list ')' ')' start_string_translation
1435                 { $$ = $5; }
1436       | ATTRIBUTE error start_string_translation
1437                 {}
1438         ;
1439
1440 attribute_list:
1441       attrib
1442                 { $$ = $1; }
1443         | attribute_list ',' attrib
1444                 { $$ = chainon ($1, $3); }
1445         ;
1446
1447 attrib:
1448     /* empty */
1449                 { $$ = NULL_TREE; }
1450         | any_word
1451                 { $$ = build_tree_list ($1, NULL_TREE); }
1452         | any_word '(' IDENTIFIER ')'
1453                 { $$ = build_tree_list ($1, build_tree_list (NULL_TREE, $3)); }
1454         | any_word '(' IDENTIFIER ',' nonnull_exprlist ')'
1455                 { $$ = build_tree_list ($1, tree_cons (NULL_TREE, $3, $5)); }
1456         | any_word '(' exprlist ')'
1457                 { $$ = build_tree_list ($1, $3); }
1458         ;
1459
1460 /* This still leaves out most reserved keywords,
1461    shouldn't we include them?  */
1462
1463 any_word:
1464           identifier
1465         | scspec
1466         | TYPESPEC
1467         | TYPE_QUAL
1468         ;
1469
1470 scspec:
1471           STATIC
1472         | SCSPEC
1473         ;
1474 \f
1475 /* Initializers.  `init' is the entry point.  */
1476
1477 init:
1478         expr_no_commas
1479                 { $$ = $1.value; }
1480         | '{'
1481                 { really_start_incremental_init (NULL_TREE); }
1482           initlist_maybe_comma '}'
1483                 { $$ = pop_init_level (0); }
1484         | error
1485                 { $$ = error_mark_node; }
1486         ;
1487
1488 /* `initlist_maybe_comma' is the guts of an initializer in braces.  */
1489 initlist_maybe_comma:
1490           /* empty */
1491                 { if (pedantic)
1492                     pedwarn ("ISO C forbids empty initializer braces"); }
1493         | initlist1 maybecomma
1494         ;
1495
1496 initlist1:
1497           initelt
1498         | initlist1 ',' initelt
1499         ;
1500
1501 /* `initelt' is a single element of an initializer.
1502    It may use braces.  */
1503 initelt:
1504           designator_list '=' initval
1505                 { if (pedantic && ! flag_isoc99)
1506                     pedwarn ("ISO C90 forbids specifying subobject to initialize"); }
1507         | designator initval
1508                 { if (pedantic)
1509                     pedwarn ("obsolete use of designated initializer without `='"); }
1510         | identifier ':'
1511                 { set_init_label ($1);
1512                   if (pedantic)
1513                     pedwarn ("obsolete use of designated initializer with `:'"); }
1514           initval
1515                 {}
1516         | initval
1517         ;
1518
1519 initval:
1520           '{'
1521                 { push_init_level (0); }
1522           initlist_maybe_comma '}'
1523                 { process_init_element (pop_init_level (0)); }
1524         | expr_no_commas
1525                 { process_init_element ($1.value); }
1526         | error
1527         ;
1528
1529 designator_list:
1530           designator
1531         | designator_list designator
1532         ;
1533
1534 designator:
1535           '.' identifier
1536                 { set_init_label ($2); }
1537         | '[' expr_no_commas ELLIPSIS expr_no_commas ']'
1538                 { set_init_index ($2.value, $4.value);
1539                   if (pedantic)
1540                     pedwarn ("ISO C forbids specifying range of elements to initialize"); }
1541         | '[' expr_no_commas ']'
1542                 { set_init_index ($2.value, NULL_TREE); }
1543         ;
1544 \f
1545 nested_function:
1546         declarator
1547                 { if (pedantic)
1548                     pedwarn ("ISO C forbids nested functions");
1549
1550                   push_function_context ();
1551                   if (! start_function (current_declspecs, $1,
1552                                         all_prefix_attributes))
1553                     {
1554                       pop_function_context ();
1555                       YYERROR1;
1556                     }
1557                 }
1558         old_style_parm_decls save_location
1559                 { tree decl = current_function_decl;
1560                   DECL_SOURCE_LOCATION (decl) = $4;
1561                   store_parm_decls (); }
1562         /* This used to use compstmt_or_error.  That caused a bug with
1563            input `f(g) int g {}', where the use of YYERROR1 above caused
1564            an error which then was handled by compstmt_or_error.  There
1565            followed a repeated execution of that same rule, which called
1566            YYERROR1 again, and so on.  */
1567         compstmt
1568                 { tree decl = current_function_decl;
1569                   add_stmt ($6);
1570                   finish_function ();
1571                   pop_function_context ();
1572                   add_stmt (build_stmt (DECL_EXPR, decl)); }
1573         ;
1574
1575 notype_nested_function:
1576         notype_declarator
1577                 { if (pedantic)
1578                     pedwarn ("ISO C forbids nested functions");
1579
1580                   push_function_context ();
1581                   if (! start_function (current_declspecs, $1,
1582                                         all_prefix_attributes))
1583                     {
1584                       pop_function_context ();
1585                       YYERROR1;
1586                     }
1587                 }
1588         old_style_parm_decls save_location
1589                 { tree decl = current_function_decl;
1590                   DECL_SOURCE_LOCATION (decl) = $4;
1591                   store_parm_decls (); }
1592         /* This used to use compstmt_or_error.  That caused a bug with
1593            input `f(g) int g {}', where the use of YYERROR1 above caused
1594            an error which then was handled by compstmt_or_error.  There
1595            followed a repeated execution of that same rule, which called
1596            YYERROR1 again, and so on.  */
1597         compstmt
1598                 { tree decl = current_function_decl;
1599                   add_stmt ($6);
1600                   finish_function ();
1601                   pop_function_context ();
1602                   add_stmt (build_stmt (DECL_EXPR, decl)); }
1603         ;
1604
1605 /* Any kind of declarator (thus, all declarators allowed
1606    after an explicit typespec).  */
1607
1608 declarator:
1609           after_type_declarator
1610         | notype_declarator
1611         ;
1612
1613 /* A declarator that is allowed only after an explicit typespec.  */
1614
1615 after_type_declarator:
1616           '(' maybe_attribute after_type_declarator ')'
1617                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1618         | after_type_declarator '(' parmlist_or_identifiers  %prec '.'
1619                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1620         | after_type_declarator array_declarator  %prec '.'
1621                 { $$ = set_array_declarator_type ($2, $1, 0); }
1622         | '*' maybe_type_quals_attrs after_type_declarator  %prec UNARY
1623                 { $$ = make_pointer_declarator ($2, $3); }
1624         | TYPENAME
1625 @@ifobjc
1626         | OBJECTNAME
1627 @@end_ifobjc
1628         ;
1629
1630 /* Kinds of declarator that can appear in a parameter list
1631    in addition to notype_declarator.  This is like after_type_declarator
1632    but does not allow a typedef name in parentheses as an identifier
1633    (because it would conflict with a function with that typedef as arg).  */
1634 parm_declarator:
1635           parm_declarator_starttypename
1636         | parm_declarator_nostarttypename
1637         ;
1638
1639 parm_declarator_starttypename:
1640           parm_declarator_starttypename '(' parmlist_or_identifiers  %prec '.'
1641                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1642         | parm_declarator_starttypename array_declarator  %prec '.'
1643                 { $$ = set_array_declarator_type ($2, $1, 0); }
1644         | TYPENAME
1645 @@ifobjc
1646         | OBJECTNAME
1647 @@end_ifobjc
1648         ;
1649
1650 parm_declarator_nostarttypename:
1651           parm_declarator_nostarttypename '(' parmlist_or_identifiers  %prec '.'
1652                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1653         | parm_declarator_nostarttypename array_declarator  %prec '.'
1654                 { $$ = set_array_declarator_type ($2, $1, 0); }
1655         | '*' maybe_type_quals_attrs parm_declarator_starttypename  %prec UNARY
1656                 { $$ = make_pointer_declarator ($2, $3); }
1657         | '*' maybe_type_quals_attrs parm_declarator_nostarttypename  %prec UNARY
1658                 { $$ = make_pointer_declarator ($2, $3); }
1659         | '(' maybe_attribute parm_declarator_nostarttypename ')'
1660                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1661         ;
1662
1663 /* A declarator allowed whether or not there has been
1664    an explicit typespec.  These cannot redeclare a typedef-name.  */
1665
1666 notype_declarator:
1667           notype_declarator '(' parmlist_or_identifiers  %prec '.'
1668                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1669         | '(' maybe_attribute notype_declarator ')'
1670                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1671         | '*' maybe_type_quals_attrs notype_declarator  %prec UNARY
1672                 { $$ = make_pointer_declarator ($2, $3); }
1673         | notype_declarator array_declarator  %prec '.'
1674                 { $$ = set_array_declarator_type ($2, $1, 0); }
1675         | IDENTIFIER
1676         ;
1677
1678 struct_head:
1679           STRUCT
1680                 { $$ = NULL_TREE; }
1681         | STRUCT attributes
1682                 { $$ = $2; }
1683         ;
1684
1685 union_head:
1686           UNION
1687                 { $$ = NULL_TREE; }
1688         | UNION attributes
1689                 { $$ = $2; }
1690         ;
1691
1692 enum_head:
1693           ENUM
1694                 { $$ = NULL_TREE; }
1695         | ENUM attributes
1696                 { $$ = $2; }
1697         ;
1698
1699 /* structsp_attr: struct/union/enum specifiers that either
1700    end with attributes, or are such that any following attributes would
1701    be parsed as part of the struct/union/enum specifier.
1702
1703    structsp_nonattr: other struct/union/enum specifiers.  */
1704
1705 structsp_attr:
1706           struct_head identifier '{'
1707                 { $$ = start_struct (RECORD_TYPE, $2);
1708                   /* Start scope of tag before parsing components.  */
1709                 }
1710           component_decl_list '}' maybe_attribute
1711                 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1712                                       chainon ($1, $7)); }
1713         | struct_head '{' component_decl_list '}' maybe_attribute
1714                 { $$ = finish_struct (start_struct (RECORD_TYPE, NULL_TREE),
1715                                       nreverse ($3), chainon ($1, $5));
1716                 }
1717         | union_head identifier '{'
1718                 { $$ = start_struct (UNION_TYPE, $2); }
1719           component_decl_list '}' maybe_attribute
1720                 { $$ = finish_struct ($<ttype>4, nreverse ($5),
1721                                       chainon ($1, $7)); }
1722         | union_head '{' component_decl_list '}' maybe_attribute
1723                 { $$ = finish_struct (start_struct (UNION_TYPE, NULL_TREE),
1724                                       nreverse ($3), chainon ($1, $5));
1725                 }
1726         | enum_head identifier '{'
1727                 { $$ = start_enum ($2); }
1728           enumlist maybecomma_warn '}' maybe_attribute
1729                 { $$ = finish_enum ($<ttype>4, nreverse ($5),
1730                                     chainon ($1, $8)); }
1731         | enum_head '{'
1732                 { $$ = start_enum (NULL_TREE); }
1733           enumlist maybecomma_warn '}' maybe_attribute
1734                 { $$ = finish_enum ($<ttype>3, nreverse ($4),
1735                                     chainon ($1, $7)); }
1736         ;
1737
1738 structsp_nonattr:
1739           struct_head identifier
1740                 { $$ = xref_tag (RECORD_TYPE, $2); }
1741         | union_head identifier
1742                 { $$ = xref_tag (UNION_TYPE, $2); }
1743         | enum_head identifier
1744                 { $$ = xref_tag (ENUMERAL_TYPE, $2);
1745                   /* In ISO C, enumerated types can be referred to
1746                      only if already defined.  */
1747                   if (pedantic && !COMPLETE_TYPE_P ($$))
1748                     pedwarn ("ISO C forbids forward references to `enum' types"); }
1749         ;
1750
1751 maybecomma:
1752           /* empty */
1753         | ','
1754         ;
1755
1756 maybecomma_warn:
1757           /* empty */
1758         | ','
1759                 { if (pedantic && ! flag_isoc99)
1760                     pedwarn ("comma at end of enumerator list"); }
1761         ;
1762
1763 /* We chain the components in reverse order.  They are put in forward
1764    order in structsp_attr.
1765
1766    Note that component_declarator returns single decls, so components
1767    and components_notype can use TREE_CHAIN directly, wheras components
1768    and components_notype return lists (of comma separated decls), so
1769    component_decl_list and component_decl_list2 must use chainon.
1770
1771    The theory behind all this is that there will be more semicolon
1772    separated fields than comma separated fields, and so we'll be
1773    minimizing the number of node traversals required by chainon.  */
1774
1775 component_decl_list:
1776           component_decl_list2
1777                 { $$ = $1; }
1778         | component_decl_list2 component_decl
1779                 { $$ = chainon ($2, $1);
1780                   pedwarn ("no semicolon at end of struct or union"); }
1781         ;
1782
1783 component_decl_list2:   /* empty */
1784                 { $$ = NULL_TREE; }
1785         | component_decl_list2 component_decl ';'
1786                 { $$ = chainon ($2, $1); }
1787         | component_decl_list2 ';'
1788                 { if (pedantic)
1789                     pedwarn ("extra semicolon in struct or union specified"); }
1790 @@ifobjc
1791         /* foo(sizeof(struct{ @defs(ClassName)})); */
1792         | AT_DEFS '(' CLASSNAME ')'
1793                 { $$ = nreverse (get_class_ivars_from_name ($3)); }
1794 @@end_ifobjc
1795         ;
1796
1797 component_decl:
1798           declspecs_nosc_ts setspecs components
1799                 { $$ = $3;
1800                   POP_DECLSPEC_STACK; }
1801         | declspecs_nosc_ts setspecs
1802                 {
1803                   /* Support for unnamed structs or unions as members of
1804                      structs or unions (which is [a] useful and [b] supports
1805                      MS P-SDK).  */
1806                   if (pedantic)
1807                     pedwarn ("ISO C doesn't support unnamed structs/unions");
1808
1809                   $$ = grokfield(NULL, current_declspecs, NULL_TREE);
1810                   POP_DECLSPEC_STACK; }
1811         | declspecs_nosc_nots setspecs components_notype
1812                 { $$ = $3;
1813                   POP_DECLSPEC_STACK; }
1814         | declspecs_nosc_nots
1815                 { if (pedantic)
1816                     pedwarn ("ISO C forbids member declarations with no members");
1817                   shadow_tag_warned ($1, pedantic);
1818                   $$ = NULL_TREE; }
1819         | error
1820                 { $$ = NULL_TREE; }
1821         | extension component_decl
1822                 { $$ = $2;
1823                   RESTORE_EXT_FLAGS ($1); }
1824         ;
1825
1826 components:
1827           component_declarator
1828         | components ',' maybe_resetattrs component_declarator
1829                 { TREE_CHAIN ($4) = $1; $$ = $4; }
1830         ;
1831
1832 components_notype:
1833           component_notype_declarator
1834         | components_notype ',' maybe_resetattrs component_notype_declarator
1835                 { TREE_CHAIN ($4) = $1; $$ = $4; }
1836         ;
1837
1838 component_declarator:
1839           declarator maybe_attribute
1840                 { $$ = grokfield ($1, current_declspecs, NULL_TREE);
1841                   decl_attributes (&$$,
1842                                    chainon ($2, all_prefix_attributes), 0); }
1843         | declarator ':' expr_no_commas maybe_attribute
1844                 { $$ = grokfield ($1, current_declspecs, $3.value);
1845                   decl_attributes (&$$,
1846                                    chainon ($4, all_prefix_attributes), 0); }
1847         | ':' expr_no_commas maybe_attribute
1848                 { $$ = grokfield (NULL_TREE, current_declspecs, $2.value);
1849                   decl_attributes (&$$,
1850                                    chainon ($3, all_prefix_attributes), 0); }
1851         ;
1852
1853 component_notype_declarator:
1854           notype_declarator maybe_attribute
1855                 { $$ = grokfield ($1, current_declspecs, NULL_TREE);
1856                   decl_attributes (&$$,
1857                                    chainon ($2, all_prefix_attributes), 0); }
1858         | notype_declarator ':' expr_no_commas maybe_attribute
1859                 { $$ = grokfield ($1, current_declspecs, $3.value);
1860                   decl_attributes (&$$,
1861                                    chainon ($4, all_prefix_attributes), 0); }
1862         | ':' expr_no_commas maybe_attribute
1863                 { $$ = grokfield (NULL_TREE, current_declspecs, $2.value);
1864                   decl_attributes (&$$,
1865                                    chainon ($3, all_prefix_attributes), 0); }
1866         ;
1867
1868 /* We chain the enumerators in reverse order.
1869    They are put in forward order in structsp_attr.  */
1870
1871 enumlist:
1872           enumerator
1873         | enumlist ',' enumerator
1874                 { if ($1 == error_mark_node)
1875                     $$ = $1;
1876                   else
1877                     TREE_CHAIN ($3) = $1, $$ = $3; }
1878         | error
1879                 { $$ = error_mark_node; }
1880         ;
1881
1882
1883 enumerator:
1884           identifier
1885                 { $$ = build_enumerator ($1, NULL_TREE); }
1886         | identifier '=' expr_no_commas
1887                 { $$ = build_enumerator ($1, $3.value); }
1888         ;
1889
1890 typename:
1891           declspecs_nosc
1892                 { pending_xref_error ();
1893                   $<ttype>$ = $1; }
1894           absdcl
1895                 { $$ = build_tree_list ($<ttype>2, $3); }
1896         ;
1897
1898 absdcl:   /* an absolute declarator */
1899         /* empty */
1900                 { $$ = NULL_TREE; }
1901         | absdcl1
1902         ;
1903
1904 absdcl_maybe_attribute:   /* absdcl maybe_attribute, but not just attributes */
1905         /* empty */
1906                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1907                                                          NULL_TREE),
1908                                         all_prefix_attributes); }
1909         | absdcl1
1910                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1911                                                          $1),
1912                                         all_prefix_attributes); }
1913         | absdcl1_noea attributes
1914                 { $$ = build_tree_list (build_tree_list (current_declspecs,
1915                                                          $1),
1916                                         chainon ($2, all_prefix_attributes)); }
1917         ;
1918
1919 absdcl1:  /* a nonempty absolute declarator */
1920           absdcl1_ea
1921         | absdcl1_noea
1922         ;
1923
1924 absdcl1_noea:
1925           direct_absdcl1
1926         | '*' maybe_type_quals_attrs absdcl1_noea
1927                 { $$ = make_pointer_declarator ($2, $3); }
1928         ;
1929
1930 absdcl1_ea:
1931           '*' maybe_type_quals_attrs
1932                 { $$ = make_pointer_declarator ($2, NULL_TREE); }
1933         | '*' maybe_type_quals_attrs absdcl1_ea
1934                 { $$ = make_pointer_declarator ($2, $3); }
1935         ;
1936
1937 direct_absdcl1:
1938           '(' maybe_attribute absdcl1 ')'
1939                 { $$ = $2 ? tree_cons ($2, $3, NULL_TREE) : $3; }
1940         | direct_absdcl1 '(' parmlist
1941                 { $$ = build_nt (CALL_EXPR, $1, $3, NULL_TREE); }
1942         | direct_absdcl1 array_declarator
1943                 { $$ = set_array_declarator_type ($2, $1, 1); }
1944         | '(' parmlist
1945                 { $$ = build_nt (CALL_EXPR, NULL_TREE, $2, NULL_TREE); }
1946         | array_declarator
1947                 { $$ = set_array_declarator_type ($1, NULL_TREE, 1); }
1948         ;
1949
1950 /* The [...] part of a declarator for an array type.  */
1951
1952 array_declarator:
1953         '[' maybe_type_quals_attrs expr_no_commas ']'
1954                 { $$ = build_array_declarator ($3.value, $2, 0, 0); }
1955         | '[' maybe_type_quals_attrs ']'
1956                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 0); }
1957         | '[' maybe_type_quals_attrs '*' ']'
1958                 { $$ = build_array_declarator (NULL_TREE, $2, 0, 1); }
1959         | '[' STATIC maybe_type_quals_attrs expr_no_commas ']'
1960                 { $$ = build_array_declarator ($4.value, $3, 1, 0); }
1961         /* declspecs_nosc_nots is a synonym for type_quals_attrs.  */
1962         | '[' declspecs_nosc_nots STATIC expr_no_commas ']'
1963                 { $$ = build_array_declarator ($4.value, $2, 1, 0); }
1964         ;
1965
1966 /* A nonempty series of declarations and statements (possibly followed by
1967    some labels) that can form the body of a compound statement.
1968    NOTE: we don't allow labels on declarations; this might seem like a
1969    natural extension, but there would be a conflict between attributes
1970    on the label and prefix attributes on the declaration.  */
1971
1972 stmts_and_decls:
1973           lineno_stmt_decl_or_labels_ending_stmt
1974         | lineno_stmt_decl_or_labels_ending_decl
1975         | lineno_stmt_decl_or_labels_ending_label
1976                 {
1977                   error ("label at end of compound statement");
1978                 }
1979         | lineno_stmt_decl_or_labels_ending_error
1980         ;
1981
1982 lineno_stmt_decl_or_labels_ending_stmt:
1983           lineno_stmt
1984         | lineno_stmt_decl_or_labels_ending_stmt lineno_stmt
1985         | lineno_stmt_decl_or_labels_ending_decl lineno_stmt
1986         | lineno_stmt_decl_or_labels_ending_label lineno_stmt
1987         | lineno_stmt_decl_or_labels_ending_error lineno_stmt
1988         ;
1989
1990 lineno_stmt_decl_or_labels_ending_decl:
1991           lineno_decl
1992         | lineno_stmt_decl_or_labels_ending_stmt lineno_decl
1993                 {
1994                   if ((pedantic && !flag_isoc99)
1995                       || warn_declaration_after_statement)
1996                     pedwarn_c90 ("ISO C90 forbids mixed declarations and code");
1997                 }
1998         | lineno_stmt_decl_or_labels_ending_decl lineno_decl
1999         | lineno_stmt_decl_or_labels_ending_error lineno_decl
2000         ;
2001
2002 lineno_stmt_decl_or_labels_ending_label:
2003           lineno_label
2004         | lineno_stmt_decl_or_labels_ending_stmt lineno_label
2005         | lineno_stmt_decl_or_labels_ending_decl lineno_label
2006         | lineno_stmt_decl_or_labels_ending_label lineno_label
2007         | lineno_stmt_decl_or_labels_ending_error lineno_label
2008         ;
2009
2010 lineno_stmt_decl_or_labels_ending_error:
2011         errstmt
2012         | lineno_stmt_decl_or_labels errstmt
2013         ;
2014
2015 lineno_stmt_decl_or_labels:
2016           lineno_stmt_decl_or_labels_ending_stmt
2017         | lineno_stmt_decl_or_labels_ending_decl
2018         | lineno_stmt_decl_or_labels_ending_label
2019         | lineno_stmt_decl_or_labels_ending_error
2020         ;
2021
2022 errstmt:  error ';'
2023         ;
2024
2025 /* Start and end blocks created for the new scopes of C99.  */
2026 c99_block_start: /* empty */
2027                 { $$ = c_begin_compound_stmt (flag_isoc99); }
2028         ;
2029
2030 /* Read zero or more forward-declarations for labels
2031    that nested functions can jump to.  */
2032 maybe_label_decls:
2033           /* empty */
2034         | label_decls
2035                 { if (pedantic)
2036                     pedwarn ("ISO C forbids label declarations"); }
2037         ;
2038
2039 label_decls:
2040           label_decl
2041         | label_decls label_decl
2042         ;
2043
2044 label_decl:
2045           LABEL identifiers_or_typenames ';'
2046                 { tree link;
2047                   for (link = $2; link; link = TREE_CHAIN (link))
2048                     {
2049                       tree label = declare_label (TREE_VALUE (link));
2050                       C_DECLARED_LABEL_FLAG (label) = 1;
2051                       add_stmt (build_stmt (DECL_EXPR, label));
2052                     }
2053                 }
2054         ;
2055
2056 /* This is the body of a function definition.
2057    It causes syntax errors to ignore to the next openbrace.  */
2058 compstmt_or_error:
2059           compstmt
2060                 { add_stmt ($1); }
2061         | error compstmt
2062         ;
2063
2064 compstmt_start: '{' { $$ = c_begin_compound_stmt (true); }
2065         ;
2066
2067 compstmt_nostart: '}'
2068         | maybe_label_decls compstmt_contents_nonempty '}'
2069         ;
2070
2071 compstmt_contents_nonempty:
2072           stmts_and_decls
2073         | error
2074         ;
2075
2076 compstmt_primary_start:
2077         '(' '{'
2078                 { if (current_function_decl == 0)
2079                     {
2080                       error ("braced-group within expression allowed "
2081                              "only inside a function");
2082                       YYERROR;
2083                     }
2084                   $$ = c_begin_stmt_expr ();
2085                 }
2086         ;
2087
2088 compstmt: compstmt_start compstmt_nostart
2089                 { $$ = c_end_compound_stmt ($1, true); }
2090         ;
2091
2092 /* The forced readahead in here is because we might be at the end of a
2093    line, and the line and file won't be bumped until yylex absorbs the
2094    first token on the next line.  */
2095
2096 save_location:
2097                 { if (yychar == YYEMPTY)
2098                     yychar = YYLEX;
2099                   $$ = input_location; }
2100         ;
2101
2102 lineno_labels:
2103           /* empty */
2104         | lineno_labels lineno_label
2105         ;
2106
2107 /* A labeled statement.  In C99 it also generates an implicit block.  */
2108 c99_block_lineno_labeled_stmt:
2109           c99_block_start lineno_labels lineno_stmt
2110                 { $$ = c_end_compound_stmt ($1, flag_isoc99); }
2111         ;
2112
2113 lineno_stmt:
2114           save_location stmt
2115                 { 
2116                   /* Two cases cannot and do not have line numbers associated:
2117                      If stmt is degenerate, such as "2;", then stmt is an 
2118                      INTEGER_CST, which cannot hold line numbers.  But that's
2119                      ok because the statement will either be changed to a
2120                      MODIFY_EXPR during gimplification of the statement expr,
2121                      or discarded.  If stmt was compound, but without new
2122                      variables, we will have skipped the creation of a BIND
2123                      and will have a bare STATEMENT_LIST.  But that's ok
2124                      because (recursively) all of the component statments
2125                      should already have line numbers assigned.  */
2126                   if ($2 && EXPR_P ($2))
2127                     SET_EXPR_LOCATION ($2, $1);
2128                 }
2129         ;
2130
2131 lineno_label:
2132           save_location label
2133                 { if ($2) SET_EXPR_LOCATION ($2, $1); }
2134         ;
2135
2136 condition: save_location expr
2137                 { $$ = lang_hooks.truthvalue_conversion ($2.value);
2138                   if (EXPR_P ($$))
2139                     SET_EXPR_LOCATION ($$, $1); }
2140         ;
2141
2142 /* Implement -Wparenthesis by special casing IF statement directly nested
2143    within IF statement.  This requires some amount of duplication of the
2144    productions under c99_block_lineno_labeled_stmt in order to work out.
2145    But it's still likely more maintainable than lots of state outside the
2146    parser...  */
2147
2148 if_statement_1:
2149         c99_block_start lineno_labels if_statement
2150                 { $$ = c_end_compound_stmt ($1, flag_isoc99); }
2151         ;
2152
2153 if_statement_2:
2154           c99_block_start lineno_labels ';'
2155                 { if (extra_warnings)
2156                     add_stmt (build (NOP_EXPR, NULL_TREE, NULL_TREE));
2157                   $$ = c_end_compound_stmt ($1, flag_isoc99); }
2158         | c99_block_lineno_labeled_stmt
2159         ;
2160
2161 if_statement:
2162           IF c99_block_start save_location '(' condition ')'
2163             if_statement_1 ELSE if_statement_2
2164                 { c_finish_if_stmt ($3, $5, $7, $9, true);
2165                   add_stmt (c_end_compound_stmt ($2, flag_isoc99)); }
2166         | IF c99_block_start save_location '(' condition ')'
2167             if_statement_2 ELSE if_statement_2
2168                 { c_finish_if_stmt ($3, $5, $7, $9, false);
2169                   add_stmt (c_end_compound_stmt ($2, flag_isoc99)); }
2170         | IF c99_block_start save_location '(' condition ')'
2171             if_statement_1                              %prec IF
2172                 { c_finish_if_stmt ($3, $5, $7, NULL, true);
2173                   add_stmt (c_end_compound_stmt ($2, flag_isoc99)); }
2174         | IF c99_block_start save_location '(' condition ')'
2175             if_statement_2                              %prec IF
2176                 { c_finish_if_stmt ($3, $5, $7, NULL, false);
2177                   add_stmt (c_end_compound_stmt ($2, flag_isoc99)); }
2178         ;
2179
2180 start_break: /* empty */
2181                 { $$ = c_break_label; c_break_label = NULL; }
2182         ;
2183
2184 start_continue: /* empty */
2185                 { $$ = c_cont_label; c_cont_label = NULL; }
2186         ;
2187
2188 while_statement:
2189         WHILE c99_block_start save_location '(' condition ')'
2190         start_break start_continue c99_block_lineno_labeled_stmt
2191                 { c_finish_loop ($3, $5, NULL, $9, c_break_label,
2192                                  c_cont_label, true);
2193                   add_stmt (c_end_compound_stmt ($2, flag_isoc99));
2194                   c_break_label = $7; c_cont_label = $8; }
2195         ;
2196
2197 do_statement:
2198         DO c99_block_start save_location start_break start_continue
2199         c99_block_lineno_labeled_stmt WHILE
2200                 { $<ttype>$ = c_break_label; c_break_label = $4; }
2201                 { $<ttype>$ = c_cont_label; c_cont_label = $5; }
2202         '(' condition ')' ';'
2203                 { c_finish_loop ($3, $11, NULL, $6, $<ttype>8,
2204                                  $<ttype>9, false);
2205                   add_stmt (c_end_compound_stmt ($2, flag_isoc99)); }
2206         ;
2207
2208 xexpr:
2209         /* empty */
2210                 { $$ = NULL_TREE; }
2211         | expr
2212                 { $$ = $1.value; }
2213         ;
2214
2215 for_init_stmt:
2216           xexpr ';'
2217                 { c_finish_expr_stmt ($1); }
2218         | decl
2219                 { check_for_loop_decls (); }
2220         ;
2221
2222 for_cond_expr: save_location xexpr
2223                 { if ($2)
2224                     {
2225                       $$ = lang_hooks.truthvalue_conversion ($2);
2226                       if (EXPR_P ($$))
2227                         SET_EXPR_LOCATION ($$, $1);
2228                     }
2229                   else
2230                     $$ = NULL;
2231                 }
2232         ;
2233
2234 for_incr_expr: xexpr
2235                 { $$ = c_process_expr_stmt ($1); }
2236         ;
2237
2238 for_statement:
2239         FOR c99_block_start '(' for_init_stmt
2240         save_location for_cond_expr ';' for_incr_expr ')'
2241         start_break start_continue c99_block_lineno_labeled_stmt
2242                 { c_finish_loop ($5, $6, $8, $12, c_break_label,
2243                                  c_cont_label, true);
2244                   add_stmt (c_end_compound_stmt ($2, flag_isoc99));
2245                   c_break_label = $10; c_cont_label = $11; }
2246         ;
2247
2248 switch_statement:
2249         SWITCH c99_block_start '(' expr ')'
2250                 { $<ttype>$ = c_start_case ($4.value); }
2251         start_break c99_block_lineno_labeled_stmt
2252                 { c_finish_case ($8);
2253                   if (c_break_label)
2254                     add_stmt (build (LABEL_EXPR, void_type_node,
2255                                      c_break_label));
2256                   c_break_label = $7;
2257                   add_stmt (c_end_compound_stmt ($2, flag_isoc99)); }
2258         ;
2259
2260 /* Parse a single real statement, not including any labels or compounds.  */
2261 stmt_nocomp:
2262           expr ';'
2263                 { $$ = c_finish_expr_stmt ($1.value); }
2264         | if_statement
2265                 { $$ = NULL_TREE; }
2266         | while_statement
2267                 { $$ = NULL_TREE; }
2268         | do_statement
2269                 { $$ = NULL_TREE; }
2270         | for_statement
2271                 { $$ = NULL_TREE; }
2272         | switch_statement
2273                 { $$ = NULL_TREE; }
2274         | BREAK ';'
2275                 { $$ = c_finish_bc_stmt (&c_break_label, true); }
2276         | CONTINUE ';'
2277                 { $$ = c_finish_bc_stmt (&c_cont_label, false); }
2278         | RETURN ';'
2279                 { $$ = c_finish_return (NULL_TREE); }
2280         | RETURN expr ';'
2281                 { $$ = c_finish_return ($2.value); }
2282         | asm_stmt
2283         | GOTO identifier ';'
2284                 { $$ = c_finish_goto_label ($2); }
2285         | GOTO '*' expr ';'
2286                 { $$ = c_finish_goto_ptr ($3.value); }
2287         | ';'
2288                 { $$ = NULL_TREE; }
2289 @@ifobjc
2290         | AT_THROW expr ';'
2291                 { $$ = objc_build_throw_stmt ($2.value); }
2292         | AT_THROW ';'
2293                 { $$ = objc_build_throw_stmt (NULL_TREE); }
2294         | objc_try_catch_stmt
2295                 { $$ = NULL_TREE; }
2296         | AT_SYNCHRONIZED save_location '(' expr ')' compstmt
2297                 { objc_build_synchronized ($2, $4.value, $6); $$ = NULL_TREE; }
2298         ;
2299
2300 objc_catch_prefix:
2301         AT_CATCH '(' parm ')'
2302                 { objc_begin_catch_clause ($3); }
2303         ;
2304
2305 objc_catch_clause:
2306           objc_catch_prefix '{' compstmt_nostart
2307                 { objc_finish_catch_clause (); }
2308         | objc_catch_prefix '{' error '}'
2309                 { objc_finish_catch_clause (); }
2310         ;
2311
2312 objc_opt_catch_list:
2313           /* empty */
2314         | objc_opt_catch_list objc_catch_clause
2315         ;
2316
2317 objc_try_catch_clause:
2318         AT_TRY save_location compstmt
2319                 { objc_begin_try_stmt ($2, $3); }
2320         objc_opt_catch_list
2321         ;
2322
2323 objc_finally_clause:
2324         AT_FINALLY save_location compstmt
2325                 { objc_build_finally_clause ($2, $3); }
2326         ;
2327
2328 objc_try_catch_stmt:
2329           objc_try_catch_clause
2330                 { objc_finish_try_stmt (); }
2331         | objc_try_catch_clause objc_finally_clause
2332                 { objc_finish_try_stmt (); }
2333 @@end_ifobjc
2334         ;
2335
2336 /* Parse a single or compound real statement, not including any labels.  */
2337 stmt:
2338           compstmt
2339                 { add_stmt ($1); $$ = NULL_TREE; }
2340         | stmt_nocomp
2341         ;
2342
2343 /* Any kind of label, including jump labels and case labels.
2344    ANSI C accepts labels only before statements, but we allow them
2345    also at the end of a compound statement.  */
2346
2347 label:    CASE expr_no_commas ':'
2348                 { $$ = do_case ($2.value, NULL_TREE); }
2349         | CASE expr_no_commas ELLIPSIS expr_no_commas ':'
2350                 { $$ = do_case ($2.value, $4.value); }
2351         | DEFAULT ':'
2352                 { $$ = do_case (NULL_TREE, NULL_TREE); }
2353         | identifier save_location ':' maybe_attribute
2354                 { tree label = define_label ($2, $1);
2355                   if (label)
2356                     {
2357                       decl_attributes (&label, $4, 0);
2358                       $$ = add_stmt (build_stmt (LABEL_EXPR, label));
2359                     }
2360                   else
2361                     $$ = NULL_TREE;
2362                 }
2363         ;
2364
2365 /* Asm expressions and statements */
2366
2367 /* simple_asm_expr is used in restricted contexts, where a full
2368    expression with inputs and outputs does not make sense.  */
2369 simple_asm_expr:
2370         ASM_KEYWORD stop_string_translation
2371               '(' STRING ')' start_string_translation
2372                 { $$ = $4; }
2373         ;
2374
2375 /* maybeasm: used for assembly names for declarations */
2376 maybeasm:
2377           /* empty */
2378                 { $$ = NULL_TREE; }
2379         | simple_asm_expr
2380         ;
2381
2382 /* asmdef: asm() outside a function body.  */
2383 asmdef:
2384         simple_asm_expr ';'
2385                 { assemble_asm ($1); }
2386         | ASM_KEYWORD error start_string_translation ';'
2387                 {}
2388         ;
2389
2390 /* Full-blown asm statement with inputs, outputs, clobbers, and
2391    volatile tag allowed.  */
2392 asm_stmt:
2393         ASM_KEYWORD maybe_volatile stop_string_translation
2394                 '(' asm_argument ')' start_string_translation ';'
2395                 { $$ = build_asm_stmt ($2, $5); }
2396         ;
2397
2398 asm_argument:
2399         /* no operands */
2400         STRING
2401                 { $$ = build_asm_expr ($1, 0, 0, 0, true); }
2402         /* output operands */
2403         | STRING ':' asm_operands
2404                 { $$ = build_asm_expr ($1, $3, 0, 0, false); }
2405         /* output and input operands */
2406         | STRING ':' asm_operands ':' asm_operands
2407                 { $$ = build_asm_expr ($1, $3, $5, 0, false); }
2408         /* output and input operands and clobbers */
2409         | STRING ':' asm_operands ':' asm_operands ':' asm_clobbers
2410                 { $$ = build_asm_expr ($1, $3, $5, $7, false); }
2411         ;
2412
2413 /* Either 'volatile' or nothing.  First thing in an `asm' statement.  */
2414
2415 maybe_volatile:
2416         /* empty */
2417                 { $$ = 0; }
2418         | TYPE_QUAL
2419                 { if ($1 != ridpointers[RID_VOLATILE])
2420                     {
2421                       warning ("%E qualifier ignored on asm", $1);
2422                       $$ = 0;
2423                     }
2424                   else
2425                     $$ = $1;
2426                 }
2427         ;
2428
2429 /* These are the operands other than the first string and colon
2430    in  asm ("addextend %2,%1": "=dm" (x), "0" (y), "g" (*x))  */
2431 asm_operands: /* empty */
2432                 { $$ = NULL_TREE; }
2433         | nonnull_asm_operands
2434         ;
2435
2436 nonnull_asm_operands:
2437           asm_operand
2438         | nonnull_asm_operands ',' asm_operand
2439                 { $$ = chainon ($1, $3); }
2440         ;
2441
2442 asm_operand:
2443           STRING start_string_translation '(' expr ')' stop_string_translation
2444                 { $$ = build_tree_list (build_tree_list (NULL_TREE, $1),
2445                                         $4.value); }
2446         | '[' identifier ']' STRING start_string_translation
2447           '(' expr ')' stop_string_translation
2448                 { $2 = build_string (IDENTIFIER_LENGTH ($2),
2449                                      IDENTIFIER_POINTER ($2));
2450                   $$ = build_tree_list (build_tree_list ($2, $4), $7.value); }
2451         ;
2452
2453 asm_clobbers:
2454           STRING
2455                 { $$ = tree_cons (NULL_TREE, $1, NULL_TREE); }
2456         | asm_clobbers ',' STRING
2457                 { $$ = tree_cons (NULL_TREE, $3, $1); }
2458         ;
2459
2460 stop_string_translation:
2461         { c_lex_string_translate = 0; }
2462         ;
2463
2464 start_string_translation:
2465         { c_lex_string_translate = 1; }
2466         ;
2467
2468 \f
2469 /* This is what appears inside the parens in a function declarator.
2470    Its value is a list of ..._TYPE nodes.  Attributes must appear here
2471    to avoid a conflict with their appearance after an open parenthesis
2472    in an abstract declarator, as in
2473    "void bar (int (__attribute__((__mode__(SI))) int foo));".  */
2474 parmlist:
2475           maybe_attribute
2476                 { push_scope ();
2477                   declare_parm_level (); }
2478           parmlist_1
2479                 { $$ = $3;
2480                   pop_scope (); }
2481         ;
2482
2483 parmlist_1:
2484           parmlist_2 ')'
2485         | parms ';'
2486                 { mark_forward_parm_decls (); }
2487           maybe_attribute
2488                 { /* Dummy action so attributes are in known place
2489                      on parser stack.  */ }
2490           parmlist_1
2491                 { $$ = $6; }
2492         | error ')'
2493                 { $$ = make_node (TREE_LIST); }
2494         ;
2495
2496 /* This is what appears inside the parens in a function declarator.
2497    Is value is represented in the format that grokdeclarator expects.  */
2498 parmlist_2:  /* empty */
2499                 { $$ = make_node (TREE_LIST); }
2500         | ELLIPSIS
2501                 { $$ = make_node (TREE_LIST); 
2502                   /* Suppress -Wold-style-definition for this case.  */
2503                   TREE_CHAIN ($$) = error_mark_node;
2504                   error ("ISO C requires a named argument before `...'");
2505                 }
2506         | parms
2507                 { $$ = get_parm_info (/*ellipsis=*/false); }
2508         | parms ',' ELLIPSIS
2509                 { $$ = get_parm_info (/*ellipsis=*/true); }
2510         ;
2511
2512 parms:
2513         firstparm
2514                 { push_parm_decl ($1); }
2515         | parms ',' parm
2516                 { push_parm_decl ($3); }
2517         ;
2518
2519 /* A single parameter declaration or parameter type name,
2520    as found in a parmlist.  */
2521 parm:
2522           declspecs_ts setspecs parm_declarator maybe_attribute
2523                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2524                                                          $3),
2525                                         chainon ($4, all_prefix_attributes));
2526                   POP_DECLSPEC_STACK; }
2527         | declspecs_ts setspecs notype_declarator maybe_attribute
2528                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2529                                                          $3),
2530                                         chainon ($4, all_prefix_attributes));
2531                   POP_DECLSPEC_STACK; }
2532         | declspecs_ts setspecs absdcl_maybe_attribute
2533                 { $$ = $3;
2534                   POP_DECLSPEC_STACK; }
2535         | declspecs_nots setspecs notype_declarator maybe_attribute
2536                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2537                                                          $3),
2538                                         chainon ($4, all_prefix_attributes));
2539                   POP_DECLSPEC_STACK; }
2540
2541         | declspecs_nots setspecs absdcl_maybe_attribute
2542                 { $$ = $3;
2543                   POP_DECLSPEC_STACK; }
2544         ;
2545
2546 /* The first parm, which must suck attributes from off the top of the parser
2547    stack.  */
2548 firstparm:
2549           declspecs_ts_nosa setspecs_fp parm_declarator maybe_attribute
2550                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2551                                                          $3),
2552                                         chainon ($4, all_prefix_attributes));
2553                   POP_DECLSPEC_STACK; }
2554         | declspecs_ts_nosa setspecs_fp notype_declarator maybe_attribute
2555                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2556                                                          $3),
2557                                         chainon ($4, all_prefix_attributes));
2558                   POP_DECLSPEC_STACK; }
2559         | declspecs_ts_nosa setspecs_fp absdcl_maybe_attribute
2560                 { $$ = $3;
2561                   POP_DECLSPEC_STACK; }
2562         | declspecs_nots_nosa setspecs_fp notype_declarator maybe_attribute
2563                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2564                                                          $3),
2565                                         chainon ($4, all_prefix_attributes));
2566                   POP_DECLSPEC_STACK; }
2567
2568         | declspecs_nots_nosa setspecs_fp absdcl_maybe_attribute
2569                 { $$ = $3;
2570                   POP_DECLSPEC_STACK; }
2571         ;
2572
2573 setspecs_fp:
2574           setspecs
2575                 { prefix_attributes = chainon (prefix_attributes, $<ttype>-2);
2576                   all_prefix_attributes = prefix_attributes; }
2577         ;
2578
2579 /* This is used in a function definition
2580    where either a parmlist or an identifier list is ok.
2581    Its value is a list of ..._TYPE nodes or a list of identifiers.  */
2582 parmlist_or_identifiers:
2583           maybe_attribute
2584                 { push_scope ();
2585                   declare_parm_level (); }
2586           parmlist_or_identifiers_1
2587                 { $$ = $3;
2588                   pop_scope (); }
2589         ;
2590
2591 parmlist_or_identifiers_1:
2592           parmlist_1
2593         | identifiers ')'
2594                 { tree t;
2595                   for (t = $1; t; t = TREE_CHAIN (t))
2596                     if (TREE_VALUE (t) == NULL_TREE)
2597                       error ("`...' in old-style identifier list");
2598                   $$ = tree_cons (NULL_TREE, NULL_TREE, $1);
2599
2600                   /* Make sure we have a parmlist after attributes.  */
2601                   if ($<ttype>-1 != 0
2602                       && (TREE_CODE ($$) != TREE_LIST
2603                           || TREE_PURPOSE ($$) == 0
2604                           || TREE_CODE (TREE_PURPOSE ($$)) != PARM_DECL))
2605                     YYERROR1;
2606                 }
2607         ;
2608
2609 /* A nonempty list of identifiers.  */
2610 identifiers:
2611         IDENTIFIER
2612                 { $$ = build_tree_list (NULL_TREE, $1); }
2613         | identifiers ',' IDENTIFIER
2614                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2615         ;
2616
2617 /* A nonempty list of identifiers, including typenames.  */
2618 identifiers_or_typenames:
2619         identifier
2620                 { $$ = build_tree_list (NULL_TREE, $1); }
2621         | identifiers_or_typenames ',' identifier
2622                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2623         ;
2624
2625 extension:
2626         EXTENSION
2627                 { $$ = SAVE_EXT_FLAGS();
2628                   pedantic = 0;
2629                   warn_pointer_arith = 0;
2630                   warn_traditional = 0;
2631                   flag_iso = 0; }
2632         ;
2633 \f
2634 @@ifobjc
2635 /* Objective-C productions.  */
2636
2637 objcdef:
2638           classdef
2639         | classdecl
2640         | aliasdecl
2641         | protocoldef
2642         | methoddef
2643         | AT_END
2644                 {
2645                   if (objc_implementation_context)
2646                     {
2647                       finish_class (objc_implementation_context);
2648                       objc_ivar_chain = NULL_TREE;
2649                       objc_implementation_context = NULL_TREE;
2650                     }
2651                   else
2652                     warning ("`@end' must appear in an implementation context");
2653                 }
2654         ;
2655
2656 /* A nonempty list of identifiers.  */
2657 identifier_list:
2658         identifier
2659                 { $$ = build_tree_list (NULL_TREE, $1); }
2660         | identifier_list ',' identifier
2661                 { $$ = chainon ($1, build_tree_list (NULL_TREE, $3)); }
2662         ;
2663
2664 classdecl:
2665           AT_CLASS identifier_list ';'
2666                 {
2667                   objc_declare_class ($2);
2668                 }
2669         ;
2670
2671 aliasdecl:
2672           AT_ALIAS identifier identifier ';'
2673                 {
2674                   objc_declare_alias ($2, $3);
2675                 }
2676         ;
2677
2678 superclass:
2679           ':' identifier { $$ = $2; }
2680         | /* NULL */ %prec HYPERUNARY    { $$ = NULL_TREE; }
2681         ;
2682
2683 class_ivars:
2684           '{' ivar_decl_list '}'
2685         | /* NULL */
2686         ;
2687
2688 classdef:
2689           AT_INTERFACE identifier superclass protocolrefs
2690                 {
2691                   objc_interface_context = objc_ivar_context
2692                     = start_class (CLASS_INTERFACE_TYPE, $2, $3, $4);
2693                   objc_public_flag = 0;
2694                 }
2695           class_ivars
2696                 {
2697                   continue_class (objc_interface_context);
2698                 }
2699           methodprotolist AT_END
2700                 {
2701                   finish_class (objc_interface_context);
2702                   objc_interface_context = NULL_TREE;
2703                 }
2704
2705         | AT_IMPLEMENTATION identifier superclass
2706                 {
2707                   objc_implementation_context = objc_ivar_context
2708                     = start_class (CLASS_IMPLEMENTATION_TYPE, $2, $3, NULL_TREE);
2709                   objc_public_flag = 0;
2710                 }
2711           class_ivars
2712                 {
2713                   objc_ivar_chain
2714                     = continue_class (objc_implementation_context);
2715                 }
2716
2717         | AT_INTERFACE identifier '(' identifier ')' protocolrefs
2718                 {
2719                   objc_interface_context
2720                     = start_class (CATEGORY_INTERFACE_TYPE, $2, $4, $6);
2721                   continue_class (objc_interface_context);
2722                 }
2723           methodprotolist AT_END
2724                 {
2725                   finish_class (objc_interface_context);
2726                   objc_interface_context = NULL_TREE;
2727                 }
2728
2729         | AT_IMPLEMENTATION identifier '(' identifier ')'
2730                 {
2731                   objc_implementation_context
2732                     = start_class (CATEGORY_IMPLEMENTATION_TYPE, $2, $4, NULL_TREE);
2733                   objc_ivar_chain
2734                     = continue_class (objc_implementation_context);
2735                 }
2736         ;
2737
2738 protocoldef:
2739           AT_PROTOCOL identifier protocolrefs
2740                 {
2741                   objc_pq_context = 1;
2742                   objc_interface_context
2743                     = start_protocol(PROTOCOL_INTERFACE_TYPE, $2, $3);
2744                 }
2745           methodprotolist AT_END
2746                 {
2747                   objc_pq_context = 0;
2748                   finish_protocol(objc_interface_context);
2749                   objc_interface_context = NULL_TREE;
2750                 }
2751         /* The @protocol forward-declaration production introduces a
2752            reduce/reduce conflict on ';', which should be resolved in
2753            favor of the production 'identifier_list -> identifier'.  */
2754         | AT_PROTOCOL identifier_list ';'
2755                 {
2756                   objc_declare_protocols ($2);
2757                 }
2758         ;
2759
2760 protocolrefs:
2761           /* empty */
2762                 {
2763                   $$ = NULL_TREE;
2764                 }
2765         | non_empty_protocolrefs
2766         ;
2767
2768 non_empty_protocolrefs:
2769           ARITHCOMPARE identifier_list ARITHCOMPARE
2770                 {
2771                   if ($1 == LT_EXPR && $3 == GT_EXPR)
2772                     $$ = $2;
2773                   else
2774                     YYERROR1;
2775                 }
2776         ;
2777
2778 ivar_decl_list:
2779           ivar_decl_list visibility_spec ivar_decls
2780         | ivar_decls
2781         ;
2782
2783 visibility_spec:
2784           AT_PRIVATE { objc_public_flag = 2; }
2785         | AT_PROTECTED { objc_public_flag = 0; }
2786         | AT_PUBLIC { objc_public_flag = 1; }
2787         ;
2788
2789 ivar_decls:
2790           /* empty */
2791                 {
2792                   $$ = NULL_TREE;
2793                 }
2794         | ivar_decls ivar_decl ';'
2795         | ivar_decls ';'
2796                 {
2797                   if (pedantic)
2798                     pedwarn ("extra semicolon in struct or union specified");
2799                 }
2800         ;
2801
2802
2803 /* There is a shift-reduce conflict here, because `components' may
2804    start with a `typename'.  It happens that shifting (the default resolution)
2805    does the right thing, because it treats the `typename' as part of
2806    a `typed_typespecs'.
2807
2808    It is possible that this same technique would allow the distinction
2809    between `notype_initdecls' and `initdecls' to be eliminated.
2810    But I am being cautious and not trying it.  */
2811
2812 ivar_decl:
2813         declspecs_nosc_ts setspecs ivars
2814                 { $$ = $3;
2815                   POP_DECLSPEC_STACK; }
2816         | declspecs_nosc_nots setspecs ivars
2817                 { $$ = $3;
2818                   POP_DECLSPEC_STACK; }
2819         | error
2820                 { $$ = NULL_TREE; }
2821         ;
2822
2823 ivars:
2824           /* empty */
2825                 { $$ = NULL_TREE; }
2826         | ivar_declarator
2827         | ivars ',' maybe_resetattrs ivar_declarator
2828         ;
2829
2830 ivar_declarator:
2831           declarator
2832                 {
2833                   $$ = add_instance_variable (objc_ivar_context,
2834                                               objc_public_flag,
2835                                               $1, current_declspecs,
2836                                               NULL_TREE);
2837                 }
2838         | declarator ':' expr_no_commas
2839                 {
2840                   $$ = add_instance_variable (objc_ivar_context,
2841                                               objc_public_flag,
2842                                               $1, current_declspecs, $3.value);
2843                 }
2844         | ':' expr_no_commas
2845                 {
2846                   $$ = add_instance_variable (objc_ivar_context,
2847                                               objc_public_flag,
2848                                               NULL_TREE,
2849                                               current_declspecs, $2.value);
2850                 }
2851         ;
2852
2853 methodtype:
2854           '+'
2855                 { objc_inherit_code = CLASS_METHOD_DECL; }
2856         | '-'
2857                 { objc_inherit_code = INSTANCE_METHOD_DECL; }
2858         ;
2859
2860 methoddef:
2861           methodtype
2862                 {
2863                   objc_pq_context = 1;
2864                   if (!objc_implementation_context)
2865                     fatal_error ("method definition not in class context");
2866                 }
2867           methoddecl
2868                 {
2869                   objc_pq_context = 0;
2870                   objc_add_method (objc_implementation_context,
2871                                    $3,
2872                                    objc_inherit_code == CLASS_METHOD_DECL);
2873                   start_method_def ($3);
2874                 }
2875           optarglist
2876                 {
2877                   continue_method_def ();
2878                 }
2879           compstmt_or_error
2880                 {
2881                   finish_method_def ();
2882                 }
2883         ;
2884
2885 /* the reason for the strange actions in this rule
2886  is so that notype_initdecls when reached via datadef
2887  can find a valid list of type and sc specs in $0. */
2888
2889 methodprotolist:
2890           /* empty  */
2891         | methodprotolist methodproto
2892         | methodprotolist { $<ttype>$ = NULL_TREE; } datadef
2893         ;
2894
2895 semi_or_error:
2896           ';'
2897         | error
2898         ;
2899
2900 methodproto:
2901           methodtype
2902                 {
2903                   /* Remember protocol qualifiers in prototypes.  */
2904                   objc_pq_context = 1;
2905                 }
2906           methoddecl
2907                 {
2908                   /* Forget protocol qualifiers here.  */
2909                   objc_pq_context = 0;
2910                   objc_add_method (objc_interface_context,
2911                                    $3,
2912                                    objc_inherit_code == CLASS_METHOD_DECL);
2913                 }
2914           semi_or_error
2915         ;
2916
2917 methoddecl:
2918           '(' typename ')' unaryselector
2919                 {
2920                   $$ = build_method_decl (objc_inherit_code, $2, $4, NULL_TREE);
2921                 }
2922
2923         | unaryselector
2924                 {
2925                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, NULL_TREE);
2926                 }
2927
2928         | '(' typename ')' keywordselector optparmlist
2929                 {
2930                   $$ = build_method_decl (objc_inherit_code, $2, $4, $5);
2931                 }
2932
2933         | keywordselector optparmlist
2934                 {
2935                   $$ = build_method_decl (objc_inherit_code, NULL_TREE, $1, $2);
2936                 }
2937         ;
2938
2939 /* "optarglist" assumes that start_method_def has already been called...
2940    if it is not, the "xdecls" will not be placed in the proper scope */
2941
2942 optarglist:
2943           /* empty */
2944         | ';' myxdecls
2945         ;
2946
2947 /* to get around the following situation: "int foo (int a) int b; {}" that
2948    is synthesized when parsing "- a:a b:b; id c; id d; { ... }" */
2949
2950 myxdecls:
2951           /* empty */
2952         | mydecls
2953         ;
2954
2955 mydecls:
2956         mydecl
2957         | errstmt
2958         | mydecls mydecl
2959         | mydecl errstmt
2960         ;
2961
2962 mydecl:
2963         declspecs_ts setspecs myparms ';'
2964                 { POP_DECLSPEC_STACK; }
2965         | declspecs_ts ';'
2966                 { shadow_tag ($1); }
2967         | declspecs_nots ';'
2968                 { pedwarn ("empty declaration"); }
2969         ;
2970
2971 myparms:
2972         myparm
2973                 { push_parm_decl ($1); }
2974         | myparms ',' myparm
2975                 { push_parm_decl ($3); }
2976         ;
2977
2978 /* A single parameter declaration or parameter type name,
2979    as found in a parmlist. DOES NOT ALLOW AN INITIALIZER OR ASMSPEC */
2980
2981 myparm:
2982           parm_declarator maybe_attribute
2983                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2984                                                          $1),
2985                                         chainon ($2, all_prefix_attributes)); }
2986         | notype_declarator maybe_attribute
2987                 { $$ = build_tree_list (build_tree_list (current_declspecs,
2988                                                          $1),
2989                                         chainon ($2, all_prefix_attributes)); }
2990         | absdcl_maybe_attribute
2991                 { $$ = $1; }
2992         ;
2993
2994 optparmlist:
2995           /* empty */
2996                 {
2997                   $$ = NULL_TREE;
2998                 }
2999         | ',' ELLIPSIS
3000                 {
3001                   /* oh what a kludge! */
3002                   $$ = objc_ellipsis_node;
3003                 }
3004         | ','
3005                 {
3006                   push_scope ();
3007                 }
3008           parmlist_2
3009                 {
3010                   /* returns a tree list node generated by get_parm_info */
3011                   $$ = $3;
3012                   pop_scope ();
3013                 }
3014         ;
3015
3016 unaryselector:
3017           selector
3018         ;
3019
3020 keywordselector:
3021           keyworddecl
3022
3023         | keywordselector keyworddecl
3024                 {
3025                   $$ = chainon ($1, $2);
3026                 }
3027         ;
3028
3029 selector:
3030           IDENTIFIER
3031         | TYPENAME
3032         | CLASSNAME
3033         | OBJECTNAME
3034         | reservedwords
3035         ;
3036
3037 reservedwords:
3038           ENUM | STRUCT | UNION | IF | ELSE | WHILE | DO | FOR
3039         | SWITCH | CASE | DEFAULT | BREAK | CONTINUE | RETURN
3040         | GOTO | ASM_KEYWORD | SIZEOF | TYPEOF | ALIGNOF
3041         | TYPESPEC | TYPE_QUAL
3042         ;
3043
3044 keyworddecl:
3045           selector ':' '(' typename ')' identifier
3046                 {
3047                   $$ = build_keyword_decl ($1, $4, $6);
3048                 }
3049
3050         | selector ':' identifier
3051                 {
3052                   $$ = build_keyword_decl ($1, NULL_TREE, $3);
3053                 }
3054
3055         | ':' '(' typename ')' identifier
3056                 {
3057                   $$ = build_keyword_decl (NULL_TREE, $3, $5);
3058                 }
3059
3060         | ':' identifier
3061                 {
3062                   $$ = build_keyword_decl (NULL_TREE, NULL_TREE, $2);
3063                 }
3064         ;
3065
3066 messageargs:
3067           selector
3068         | keywordarglist
3069         ;
3070
3071 keywordarglist:
3072           keywordarg
3073         | keywordarglist keywordarg
3074                 {
3075                   $$ = chainon ($1, $2);
3076                 }
3077         ;
3078
3079
3080 keywordexpr:
3081           nonnull_exprlist
3082                 {
3083                   if (TREE_CHAIN ($1) == NULL_TREE)
3084                     /* just return the expr., remove a level of indirection */
3085                     $$ = TREE_VALUE ($1);
3086                   else
3087                     /* we have a comma expr., we will collapse later */
3088                     $$ = $1;
3089                 }
3090         ;
3091
3092 keywordarg:
3093           selector ':' keywordexpr
3094                 {
3095                   $$ = build_tree_list ($1, $3);
3096                 }
3097         | ':' keywordexpr
3098                 {
3099                   $$ = build_tree_list (NULL_TREE, $2);
3100                 }
3101         ;
3102
3103 receiver:
3104           expr
3105                 { $$ = $1.value; }
3106         | CLASSNAME
3107                 {
3108                   $$ = get_class_reference ($1);
3109                 }
3110         | TYPENAME
3111                 {
3112                   $$ = get_class_reference ($1);
3113                 }
3114         ;
3115
3116 objcmessageexpr:
3117           '[' receiver messageargs ']'
3118                 { $$ = build_tree_list ($2, $3); }
3119         ;
3120
3121 selectorarg:
3122           selector
3123         | keywordnamelist
3124         ;
3125
3126 keywordnamelist:
3127           keywordname
3128         | keywordnamelist keywordname
3129                 {
3130                   $$ = chainon ($1, $2);
3131                 }
3132         ;
3133
3134 keywordname:
3135           selector ':'
3136                 {
3137                   $$ = build_tree_list ($1, NULL_TREE);
3138                 }
3139         | ':'
3140                 {
3141                   $$ = build_tree_list (NULL_TREE, NULL_TREE);
3142                 }
3143         ;
3144
3145 objcselectorexpr:
3146           AT_SELECTOR '(' selectorarg ')'
3147                 {
3148                   $$ = $3;
3149                 }
3150         ;
3151
3152 objcprotocolexpr:
3153           AT_PROTOCOL '(' identifier ')'
3154                 {
3155                   $$ = $3;
3156                 }
3157         ;
3158
3159 /* extension to support C-structures in the archiver */
3160
3161 objcencodeexpr:
3162           AT_ENCODE '(' typename ')'
3163                 {
3164                   $$ = groktypename ($3);
3165                 }
3166         ;
3167
3168 @@end_ifobjc
3169 %%
3170
3171 /* yylex() is a thin wrapper around c_lex(), all it does is translate
3172    cpplib.h's token codes into yacc's token codes.  */
3173
3174 static enum cpp_ttype last_token;
3175
3176 /* The reserved keyword table.  */
3177 struct resword
3178 {
3179   const char *word;
3180   ENUM_BITFIELD(rid) rid : 16;
3181   unsigned int disable   : 16;
3182 };
3183
3184 /* Disable mask.  Keywords are disabled if (reswords[i].disable & mask) is
3185    _true_.  */
3186 #define D_C89   0x01    /* not in C89 */
3187 #define D_EXT   0x02    /* GCC extension */
3188 #define D_EXT89 0x04    /* GCC extension incorporated in C99 */
3189 #define D_OBJC  0x08    /* Objective C only */
3190
3191 static const struct resword reswords[] =
3192 {
3193   { "_Bool",            RID_BOOL,       0 },
3194   { "_Complex",         RID_COMPLEX,    0 },
3195   { "__FUNCTION__",     RID_FUNCTION_NAME, 0 },
3196   { "__PRETTY_FUNCTION__", RID_PRETTY_FUNCTION_NAME, 0 },
3197   { "__alignof",        RID_ALIGNOF,    0 },
3198   { "__alignof__",      RID_ALIGNOF,    0 },
3199   { "__asm",            RID_ASM,        0 },
3200   { "__asm__",          RID_ASM,        0 },
3201   { "__attribute",      RID_ATTRIBUTE,  0 },
3202   { "__attribute__",    RID_ATTRIBUTE,  0 },
3203   { "__builtin_choose_expr", RID_CHOOSE_EXPR, 0 },
3204   { "__builtin_offsetof", RID_OFFSETOF, 0 },
3205   { "__builtin_types_compatible_p", RID_TYPES_COMPATIBLE_P, 0 },
3206   { "__builtin_va_arg", RID_VA_ARG,     0 },
3207   { "__complex",        RID_COMPLEX,    0 },
3208   { "__complex__",      RID_COMPLEX,    0 },
3209   { "__const",          RID_CONST,      0 },
3210   { "__const__",        RID_CONST,      0 },
3211   { "__extension__",    RID_EXTENSION,  0 },
3212   { "__func__",         RID_C99_FUNCTION_NAME, 0 },
3213   { "__imag",           RID_IMAGPART,   0 },
3214   { "__imag__",         RID_IMAGPART,   0 },
3215   { "__inline",         RID_INLINE,     0 },
3216   { "__inline__",       RID_INLINE,     0 },
3217   { "__label__",        RID_LABEL,      0 },
3218   { "__ptrbase",        RID_PTRBASE,    0 },
3219   { "__ptrbase__",      RID_PTRBASE,    0 },
3220   { "__ptrextent",      RID_PTREXTENT,  0 },
3221   { "__ptrextent__",    RID_PTREXTENT,  0 },
3222   { "__ptrvalue",       RID_PTRVALUE,   0 },
3223   { "__ptrvalue__",     RID_PTRVALUE,   0 },
3224   { "__real",           RID_REALPART,   0 },
3225   { "__real__",         RID_REALPART,   0 },
3226   { "__restrict",       RID_RESTRICT,   0 },
3227   { "__restrict__",     RID_RESTRICT,   0 },
3228   { "__signed",         RID_SIGNED,     0 },
3229   { "__signed__",       RID_SIGNED,     0 },
3230   { "__thread",         RID_THREAD,     0 },
3231   { "__typeof",         RID_TYPEOF,     0 },
3232   { "__typeof__",       RID_TYPEOF,     0 },
3233   { "__volatile",       RID_VOLATILE,   0 },
3234   { "__volatile__",     RID_VOLATILE,   0 },
3235   { "asm",              RID_ASM,        D_EXT },
3236   { "auto",             RID_AUTO,       0 },
3237   { "break",            RID_BREAK,      0 },
3238   { "case",             RID_CASE,       0 },
3239   { "char",             RID_CHAR,       0 },
3240   { "const",            RID_CONST,      0 },
3241   { "continue",         RID_CONTINUE,   0 },
3242   { "default",          RID_DEFAULT,    0 },
3243   { "do",               RID_DO,         0 },
3244   { "double",           RID_DOUBLE,     0 },
3245   { "else",             RID_ELSE,       0 },
3246   { "enum",             RID_ENUM,       0 },
3247   { "extern",           RID_EXTERN,     0 },
3248   { "float",            RID_FLOAT,      0 },
3249   { "for",              RID_FOR,