OSDN Git Service

c0bc236c82263adcb0e7fa02281960af04a52786
[pf3gnuchains/gcc-fork.git] / gcc / ada / sem_attr.adb
1 ------------------------------------------------------------------------------
2 --                                                                          --
3 --                         GNAT COMPILER COMPONENTS                         --
4 --                                                                          --
5 --                             S E M _ A T T R                              --
6 --                                                                          --
7 --                                 B o d y                                  --
8 --                                                                          --
9 --                            $Revision$
10 --                                                                          --
11 --          Copyright (C) 1992-2001, Free Software Foundation, Inc.         --
12 --                                                                          --
13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
14 -- terms of the  GNU General Public License as published  by the Free Soft- --
15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
19 -- for  more details.  You should have  received  a copy of the GNU General --
20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
22 -- MA 02111-1307, USA.                                                      --
23 --                                                                          --
24 -- GNAT was originally developed  by the GNAT team at  New York University. --
25 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
26 --                                                                          --
27 ------------------------------------------------------------------------------
28
29 with Ada.Characters.Latin_1; use Ada.Characters.Latin_1;
30
31 with Atree;    use Atree;
32 with Checks;   use Checks;
33 with Einfo;    use Einfo;
34 with Errout;   use Errout;
35 with Eval_Fat;
36 with Exp_Tss;  use Exp_Tss;
37 with Exp_Util; use Exp_Util;
38 with Expander; use Expander;
39 with Freeze;   use Freeze;
40 with Lib.Xref; use Lib.Xref;
41 with Namet;    use Namet;
42 with Nlists;   use Nlists;
43 with Nmake;    use Nmake;
44 with Opt;      use Opt;
45 with Restrict; use Restrict;
46 with Rtsfind;  use Rtsfind;
47 with Sem;      use Sem;
48 with Sem_Cat;  use Sem_Cat;
49 with Sem_Ch6;  use Sem_Ch6;
50 with Sem_Ch8;  use Sem_Ch8;
51 with Sem_Ch13; use Sem_Ch13;
52 with Sem_Dist; use Sem_Dist;
53 with Sem_Eval; use Sem_Eval;
54 with Sem_Res;  use Sem_Res;
55 with Sem_Type; use Sem_Type;
56 with Sem_Util; use Sem_Util;
57 with Stand;    use Stand;
58 with Sinfo;    use Sinfo;
59 with Sinput;   use Sinput;
60 with Snames;   use Snames;
61 with Stand;
62 with Stringt;  use Stringt;
63 with Targparm; use Targparm;
64 with Ttypes;   use Ttypes;
65 with Ttypef;   use Ttypef;
66 with Tbuild;   use Tbuild;
67 with Uintp;    use Uintp;
68 with Urealp;   use Urealp;
69 with Widechar; use Widechar;
70
71 package body Sem_Attr is
72
73    True_Value  : constant Uint := Uint_1;
74    False_Value : constant Uint := Uint_0;
75    --  Synonyms to be used when these constants are used as Boolean values
76
77    Bad_Attribute : exception;
78    --  Exception raised if an error is detected during attribute processing,
79    --  used so that we can abandon the processing so we don't run into
80    --  trouble with cascaded errors.
81
82    --  The following array is the list of attributes defined in the Ada 83 RM
83
84    Attribute_83 : Attribute_Class_Array := Attribute_Class_Array'(
85       Attribute_Address           |
86       Attribute_Aft               |
87       Attribute_Alignment         |
88       Attribute_Base              |
89       Attribute_Callable          |
90       Attribute_Constrained       |
91       Attribute_Count             |
92       Attribute_Delta             |
93       Attribute_Digits            |
94       Attribute_Emax              |
95       Attribute_Epsilon           |
96       Attribute_First             |
97       Attribute_First_Bit         |
98       Attribute_Fore              |
99       Attribute_Image             |
100       Attribute_Large             |
101       Attribute_Last              |
102       Attribute_Last_Bit          |
103       Attribute_Leading_Part      |
104       Attribute_Length            |
105       Attribute_Machine_Emax      |
106       Attribute_Machine_Emin      |
107       Attribute_Machine_Mantissa  |
108       Attribute_Machine_Overflows |
109       Attribute_Machine_Radix     |
110       Attribute_Machine_Rounds    |
111       Attribute_Mantissa          |
112       Attribute_Pos               |
113       Attribute_Position          |
114       Attribute_Pred              |
115       Attribute_Range             |
116       Attribute_Safe_Emax         |
117       Attribute_Safe_Large        |
118       Attribute_Safe_Small        |
119       Attribute_Size              |
120       Attribute_Small             |
121       Attribute_Storage_Size      |
122       Attribute_Succ              |
123       Attribute_Terminated        |
124       Attribute_Val               |
125       Attribute_Value             |
126       Attribute_Width             => True,
127       others                      => False);
128
129    -----------------------
130    -- Local_Subprograms --
131    -----------------------
132
133    procedure Eval_Attribute (N : Node_Id);
134    --  Performs compile time evaluation of attributes where possible, leaving
135    --  the Is_Static_Expression/Raises_Constraint_Error flags appropriately
136    --  set, and replacing the node with a literal node if the value can be
137    --  computed at compile time. All static attribute references are folded,
138    --  as well as a number of cases of non-static attributes that can always
139    --  be computed at compile time (e.g. floating-point model attributes that
140    --  are applied to non-static subtypes). Of course in such cases, the
141    --  Is_Static_Expression flag will not be set on the resulting literal.
142    --  Note that the only required action of this procedure is to catch the
143    --  static expression cases as described in the RM. Folding of other cases
144    --  is done where convenient, but some additional non-static folding is in
145    --  N_Expand_Attribute_Reference in cases where this is more convenient.
146
147    function Is_Anonymous_Tagged_Base
148      (Anon : Entity_Id;
149       Typ  : Entity_Id)
150       return Boolean;
151    --  For derived tagged types that constrain parent discriminants we build
152    --  an anonymous unconstrained base type. We need to recognize the relation
153    --  between the two when analyzing an access attribute for a constrained
154    --  component, before the full declaration for Typ has been analyzed, and
155    --  where therefore the prefix of the attribute does not match the enclosing
156    --  scope.
157
158    -----------------------
159    -- Analyze_Attribute --
160    -----------------------
161
162    procedure Analyze_Attribute (N : Node_Id) is
163       Loc     : constant Source_Ptr   := Sloc (N);
164       Aname   : constant Name_Id      := Attribute_Name (N);
165       P       : constant Node_Id      := Prefix (N);
166       Exprs   : constant List_Id      := Expressions (N);
167       Attr_Id : constant Attribute_Id := Get_Attribute_Id (Aname);
168       E1      : Node_Id;
169       E2      : Node_Id;
170
171       P_Type : Entity_Id;
172       --  Type of prefix after analysis
173
174       P_Base_Type : Entity_Id;
175       --  Base type of prefix after analysis
176
177       P_Root_Type : Entity_Id;
178       --  Root type of prefix after analysis
179
180       Unanalyzed  : Node_Id;
181
182       -----------------------
183       -- Local Subprograms --
184       -----------------------
185
186       procedure Access_Attribute;
187       --  Used for Access, Unchecked_Access, Unrestricted_Access attributes.
188       --  Internally, Id distinguishes which of the three cases is involved.
189
190       procedure Check_Array_Or_Scalar_Type;
191       --  Common procedure used by First, Last, Range attribute to check
192       --  that the prefix is a constrained array or scalar type, or a name
193       --  of an array object, and that an argument appears only if appropriate
194       --  (i.e. only in the array case).
195
196       procedure Check_Array_Type;
197       --  Common semantic checks for all array attributes. Checks that the
198       --  prefix is a constrained array type or the name of an array object.
199       --  The error message for non-arrays is specialized appropriately.
200
201       procedure Check_Asm_Attribute;
202       --  Common semantic checks for Asm_Input and Asm_Output attributes
203
204       procedure Check_Component;
205       --  Common processing for Bit_Position, First_Bit, Last_Bit, and
206       --  Position. Checks prefix is an appropriate selected component.
207
208       procedure Check_Decimal_Fixed_Point_Type;
209       --  Check that prefix of attribute N is a decimal fixed-point type
210
211       procedure Check_Dereference;
212       --  If the prefix of attribute is an object of an access type, then
213       --  introduce an explicit deference, and adjust P_Type accordingly.
214
215       procedure Check_Discrete_Type;
216       --  Verify that prefix of attribute N is a discrete type
217
218       procedure Check_E0;
219       --  Check that no attribute arguments are present
220
221       procedure Check_Either_E0_Or_E1;
222       --  Check that there are zero or one attribute arguments present
223
224       procedure Check_E1;
225       --  Check that exactly one attribute argument is present
226
227       procedure Check_E2;
228       --  Check that two attribute arguments are present
229
230       procedure Check_Enum_Image;
231       --  If the prefix type is an enumeration type, set all its literals
232       --  as referenced, since the image function could possibly end up
233       --  referencing any of the literals indirectly.
234
235       procedure Check_Enumeration_Type;
236       --  Verify that prefix of attribute N is an enumeration type
237
238       procedure Check_Fixed_Point_Type;
239       --  Verify that prefix of attribute N is a fixed type
240
241       procedure Check_Fixed_Point_Type_0;
242       --  Verify that prefix of attribute N is a fixed type and that
243       --  no attribute expressions are present
244
245       procedure Check_Floating_Point_Type;
246       --  Verify that prefix of attribute N is a float type
247
248       procedure Check_Floating_Point_Type_0;
249       --  Verify that prefix of attribute N is a float type and that
250       --  no attribute expressions are present
251
252       procedure Check_Floating_Point_Type_1;
253       --  Verify that prefix of attribute N is a float type and that
254       --  exactly one attribute expression is present
255
256       procedure Check_Floating_Point_Type_2;
257       --  Verify that prefix of attribute N is a float type and that
258       --  two attribute expressions are present
259
260       procedure Legal_Formal_Attribute;
261       --  Common processing for attributes Definite, and Has_Discriminants
262
263       procedure Check_Integer_Type;
264       --  Verify that prefix of attribute N is an integer type
265
266       procedure Check_Library_Unit;
267       --  Verify that prefix of attribute N is a library unit
268
269       procedure Check_Not_Incomplete_Type;
270       --  Check that P (the prefix of the attribute) is not an incomplete
271       --  type or a private type for which no full view has been given.
272
273       procedure Check_Object_Reference (P : Node_Id);
274       --  Check that P (the prefix of the attribute) is an object reference
275
276       procedure Check_Program_Unit;
277       --  Verify that prefix of attribute N is a program unit
278
279       procedure Check_Real_Type;
280       --  Verify that prefix of attribute N is fixed or float type
281
282       procedure Check_Scalar_Type;
283       --  Verify that prefix of attribute N is a scalar type
284
285       procedure Check_Standard_Prefix;
286       --  Verify that prefix of attribute N is package Standard
287
288       procedure Check_Stream_Attribute (Nam : Name_Id);
289       --  Validity checking for stream attribute. Nam is the name of the
290       --  corresponding possible defined attribute function (e.g. for the
291       --  Read attribute, Nam will be Name_uRead).
292
293       procedure Check_Task_Prefix;
294       --  Verify that prefix of attribute N is a task or task type
295
296       procedure Check_Type;
297       --  Verify that the prefix of attribute N is a type
298
299       procedure Check_Unit_Name (Nod : Node_Id);
300       --  Check that Nod is of the form of a library unit name, i.e that
301       --  it is an identifier, or a selected component whose prefix is
302       --  itself of the form of a library unit name. Note that this is
303       --  quite different from Check_Program_Unit, since it only checks
304       --  the syntactic form of the name, not the semantic identity. This
305       --  is because it is used with attributes (Elab_Body, Elab_Spec, and
306       --  UET_Address) which can refer to non-visible unit.
307
308       procedure Error_Attr (Msg : String; Error_Node : Node_Id);
309       pragma No_Return (Error_Attr);
310       --  Posts error using Error_Msg_N at given node, sets type of attribute
311       --  node to Any_Type, and then raises Bad_Attribute to avoid any further
312       --  semantic processing. The message typically contains a % insertion
313       --  character which is replaced by the attribute name.
314
315       procedure Standard_Attribute (Val : Int);
316       --  Used to process attributes whose prefix is package Standard which
317       --  yield values of type Universal_Integer. The attribute reference
318       --  node is rewritten with an integer literal of the given value.
319
320       procedure Unexpected_Argument (En : Node_Id);
321       --  Signal unexpected attribute argument (En is the argument)
322
323       procedure Validate_Non_Static_Attribute_Function_Call;
324       --  Called when processing an attribute that is a function call to a
325       --  non-static function, i.e. an attribute function that either takes
326       --  non-scalar arguments or returns a non-scalar result. Verifies that
327       --  such a call does not appear in a preelaborable context.
328
329       ----------------------
330       -- Access_Attribute --
331       ----------------------
332
333       procedure Access_Attribute is
334          Acc_Type : Entity_Id;
335
336          Scop : Entity_Id;
337          Typ  : Entity_Id;
338
339          function Build_Access_Object_Type (DT : Entity_Id) return Entity_Id;
340          --  Build an access-to-object type whose designated type is DT,
341          --  and whose Ekind is appropriate to the attribute type. The
342          --  type that is constructed is returned as the result.
343
344          procedure Build_Access_Subprogram_Type (P : Node_Id);
345          --  Build an access to subprogram whose designated type is
346          --  the type of the prefix. If prefix is overloaded, so it the
347          --  node itself. The result is stored in Acc_Type.
348
349          ------------------------------
350          -- Build_Access_Object_Type --
351          ------------------------------
352
353          function Build_Access_Object_Type (DT : Entity_Id) return Entity_Id is
354             Typ : Entity_Id;
355
356          begin
357             if Aname = Name_Unrestricted_Access then
358                Typ :=
359                  New_Internal_Entity
360                    (E_Allocator_Type, Current_Scope, Loc, 'A');
361             else
362                Typ :=
363                  New_Internal_Entity
364                    (E_Access_Attribute_Type, Current_Scope, Loc, 'A');
365             end if;
366
367             Set_Etype                     (Typ, Typ);
368             Init_Size_Align               (Typ);
369             Set_Is_Itype                  (Typ);
370             Set_Associated_Node_For_Itype (Typ, N);
371             Set_Directly_Designated_Type  (Typ, DT);
372             return Typ;
373          end Build_Access_Object_Type;
374
375          ----------------------------------
376          -- Build_Access_Subprogram_Type --
377          ----------------------------------
378
379          procedure Build_Access_Subprogram_Type (P : Node_Id) is
380             Index    : Interp_Index;
381             It       : Interp;
382
383             function Get_Kind (E : Entity_Id) return Entity_Kind;
384             --  Distinguish between access to regular and protected
385             --  subprograms.
386
387             function Get_Kind (E : Entity_Id) return Entity_Kind is
388             begin
389                if Convention (E) = Convention_Protected then
390                   return E_Access_Protected_Subprogram_Type;
391                else
392                   return E_Access_Subprogram_Type;
393                end if;
394             end Get_Kind;
395
396          --  Start of processing for Build_Access_Subprogram_Type
397
398          begin
399             if not Is_Overloaded (P) then
400                Acc_Type :=
401                  New_Internal_Entity
402                    (Get_Kind (Entity (P)), Current_Scope, Loc, 'A');
403                Set_Etype (Acc_Type, Acc_Type);
404                Set_Directly_Designated_Type (Acc_Type, Entity (P));
405                Set_Etype (N, Acc_Type);
406
407             else
408                Get_First_Interp (P, Index, It);
409                Set_Etype (N, Any_Type);
410
411                while Present (It.Nam) loop
412
413                   if not Is_Intrinsic_Subprogram (It.Nam) then
414                      Acc_Type :=
415                        New_Internal_Entity
416                          (Get_Kind (It.Nam), Current_Scope, Loc, 'A');
417                      Set_Etype (Acc_Type, Acc_Type);
418                      Set_Directly_Designated_Type (Acc_Type, It.Nam);
419                      Add_One_Interp (N, Acc_Type, Acc_Type);
420                   end if;
421
422                   Get_Next_Interp (Index, It);
423                end loop;
424
425                if Etype (N) = Any_Type then
426                   Error_Attr ("prefix of % attribute cannot be intrinsic", P);
427                end if;
428             end if;
429          end Build_Access_Subprogram_Type;
430
431       --  Start of processing for Access_Attribute
432
433       begin
434          Check_E0;
435
436          if Nkind (P) = N_Character_Literal then
437             Error_Attr
438               ("prefix of % attribute cannot be enumeration literal", P);
439
440          --  In the case of an access to subprogram, use the name of the
441          --  subprogram itself as the designated type. Type-checking in
442          --  this case compares the signatures of the designated types.
443
444          elsif Is_Entity_Name (P)
445            and then Is_Overloadable (Entity (P))
446          then
447             Build_Access_Subprogram_Type (P);
448             return;
449
450          --  Component is an operation of a protected type.
451
452          elsif (Nkind (P) = N_Selected_Component
453            and then Is_Overloadable (Entity (Selector_Name (P))))
454          then
455             if Ekind (Entity (Selector_Name (P))) = E_Entry then
456                Error_Attr ("Prefix of % attribute must be subprogram", P);
457             end if;
458
459             Build_Access_Subprogram_Type (Selector_Name (P));
460             return;
461          end if;
462
463          --  Deal with incorrect reference to a type, but note that some
464          --  accesses are allowed (references to the current type instance).
465
466          if Is_Entity_Name (P) then
467             Scop := Current_Scope;
468             Typ := Entity (P);
469
470             if Is_Type (Typ) then
471
472                --  OK if we are within the scope of a limited type
473                --  let's mark the component as having per object constraint
474
475                if Is_Anonymous_Tagged_Base (Scop, Typ) then
476                   Typ := Scop;
477                   Set_Entity (P, Typ);
478                   Set_Etype  (P, Typ);
479                end if;
480
481                if Typ = Scop then
482                   declare
483                      Q : Node_Id := Parent (N);
484
485                   begin
486                      while Present (Q)
487                        and then Nkind (Q) /= N_Component_Declaration
488                      loop
489                         Q := Parent (Q);
490                      end loop;
491                      if Present (Q) then
492                         Set_Has_Per_Object_Constraint (
493                           Defining_Identifier (Q), True);
494                      end if;
495                   end;
496
497                   if Nkind (P) = N_Expanded_Name then
498                      Error_Msg_N
499                        ("current instance prefix must be a direct name", P);
500                   end if;
501
502                   --  If a current instance attribute appears within a
503                   --  a component constraint it must appear alone; other
504                   --  contexts (default expressions, within a task body)
505                   --  are not subject to this restriction.
506
507                   if not In_Default_Expression
508                     and then not Has_Completion (Scop)
509                     and then
510                       Nkind (Parent (N)) /= N_Discriminant_Association
511                     and then
512                       Nkind (Parent (N)) /= N_Index_Or_Discriminant_Constraint
513                   then
514                      Error_Msg_N
515                        ("current instance attribute must appear alone", N);
516                   end if;
517
518                --  OK if we are in initialization procedure for the type
519                --  in question, in which case the reference to the type
520                --  is rewritten as a reference to the current object.
521
522                elsif Ekind (Scop) = E_Procedure
523                  and then Chars (Scop) = Name_uInit_Proc
524                  and then Etype (First_Formal (Scop)) = Typ
525                then
526                   Rewrite (N,
527                     Make_Attribute_Reference (Loc,
528                       Prefix         => Make_Identifier (Loc, Name_uInit),
529                       Attribute_Name => Name_Unrestricted_Access));
530                   Analyze (N);
531                   return;
532
533                --  OK if a task type, this test needs sharpening up ???
534
535                elsif Is_Task_Type (Typ) then
536                   null;
537
538                --  Otherwise we have an error case
539
540                else
541                   Error_Attr ("% attribute cannot be applied to type", P);
542                   return;
543                end if;
544             end if;
545          end if;
546
547          --  If we fall through, we have a normal access to object case.
548          --  Unrestricted_Access is legal wherever an allocator would be
549          --  legal, so its Etype is set to E_Allocator. The expected type
550          --  of the other attributes is a general access type, and therefore
551          --  we label them with E_Access_Attribute_Type.
552
553          if not Is_Overloaded (P) then
554             Acc_Type := Build_Access_Object_Type (P_Type);
555             Set_Etype (N, Acc_Type);
556          else
557             declare
558                Index : Interp_Index;
559                It    : Interp;
560
561             begin
562                Set_Etype (N, Any_Type);
563                Get_First_Interp (P, Index, It);
564
565                while Present (It.Typ) loop
566                   Acc_Type := Build_Access_Object_Type (It.Typ);
567                   Add_One_Interp (N, Acc_Type, Acc_Type);
568                   Get_Next_Interp (Index, It);
569                end loop;
570             end;
571          end if;
572
573          --  Check for aliased view unless unrestricted case. We allow
574          --  a nonaliased prefix when within an instance because the
575          --  prefix may have been a tagged formal object, which is
576          --  defined to be aliased even when the actual might not be
577          --  (other instance cases will have been caught in the generic).
578
579          if Aname /= Name_Unrestricted_Access
580            and then not Is_Aliased_View (P)
581            and then not In_Instance
582          then
583             Error_Attr ("prefix of % attribute must be aliased", P);
584          end if;
585
586       end Access_Attribute;
587
588       --------------------------------
589       -- Check_Array_Or_Scalar_Type --
590       --------------------------------
591
592       procedure Check_Array_Or_Scalar_Type is
593          Index : Entity_Id;
594
595          D : Int;
596          --  Dimension number for array attributes.
597
598       begin
599          --  Case of string literal or string literal subtype. These cases
600          --  cannot arise from legal Ada code, but the expander is allowed
601          --  to generate them. They require special handling because string
602          --  literal subtypes do not have standard bounds (the whole idea
603          --  of these subtypes is to avoid having to generate the bounds)
604
605          if Ekind (P_Type) = E_String_Literal_Subtype then
606             Set_Etype (N, Etype (First_Index (P_Base_Type)));
607             return;
608
609          --  Scalar types
610
611          elsif Is_Scalar_Type (P_Type) then
612             Check_Type;
613
614             if Present (E1) then
615                Error_Attr ("invalid argument in % attribute", E1);
616             else
617                Set_Etype (N, P_Base_Type);
618                return;
619             end if;
620
621          --  The following is a special test to allow 'First to apply to
622          --  private scalar types if the attribute comes from generated
623          --  code. This occurs in the case of Normalize_Scalars code.
624
625          elsif Is_Private_Type (P_Type)
626            and then Present (Full_View (P_Type))
627            and then Is_Scalar_Type (Full_View (P_Type))
628            and then not Comes_From_Source (N)
629          then
630             Set_Etype (N, Implementation_Base_Type (P_Type));
631
632          --  Array types other than string literal subtypes handled above
633
634          else
635             Check_Array_Type;
636
637             --  We know prefix is an array type, or the name of an array
638             --  object, and that the expression, if present, is static
639             --  and within the range of the dimensions of the type.
640
641             if Is_Array_Type (P_Type) then
642                Index := First_Index (P_Base_Type);
643
644             else pragma Assert (Is_Access_Type (P_Type));
645                Index := First_Index (Base_Type (Designated_Type (P_Type)));
646             end if;
647
648             if No (E1) then
649
650                --  First dimension assumed
651
652                Set_Etype (N, Base_Type (Etype (Index)));
653
654             else
655                D := UI_To_Int (Intval (E1));
656
657                for J in 1 .. D - 1 loop
658                   Next_Index (Index);
659                end loop;
660
661                Set_Etype (N, Base_Type (Etype (Index)));
662                Set_Etype (E1, Standard_Integer);
663             end if;
664          end if;
665       end Check_Array_Or_Scalar_Type;
666
667       ----------------------
668       -- Check_Array_Type --
669       ----------------------
670
671       procedure Check_Array_Type is
672          D : Int;
673          --  Dimension number for array attributes.
674
675       begin
676          --  If the type is a string literal type, then this must be generated
677          --  internally, and no further check is required on its legality.
678
679          if Ekind (P_Type) = E_String_Literal_Subtype then
680             return;
681
682          --  If the type is a composite, it is an illegal aggregate, no point
683          --  in going on.
684
685          elsif P_Type = Any_Composite then
686             raise Bad_Attribute;
687          end if;
688
689          --  Normal case of array type or subtype
690
691          Check_Either_E0_Or_E1;
692
693          if Is_Array_Type (P_Type) then
694             if not Is_Constrained (P_Type)
695               and then Is_Entity_Name (P)
696               and then Is_Type (Entity (P))
697             then
698                --  Note: we do not call Error_Attr here, since we prefer to
699                --  continue, using the relevant index type of the array,
700                --  even though it is unconstrained. This gives better error
701                --  recovery behavior.
702
703                Error_Msg_Name_1 := Aname;
704                Error_Msg_N
705                  ("prefix for % attribute must be constrained array", P);
706             end if;
707
708             D := Number_Dimensions (P_Type);
709
710          elsif Is_Access_Type (P_Type)
711            and then Is_Array_Type (Designated_Type (P_Type))
712          then
713             if Is_Entity_Name (P) and then Is_Type (Entity (P)) then
714                Error_Attr ("prefix of % attribute cannot be access type", P);
715             end if;
716
717             D := Number_Dimensions (Designated_Type (P_Type));
718
719             --  If there is an implicit dereference, then we must freeze
720             --  the designated type of the access type, since the type of
721             --  the referenced array is this type (see AI95-00106).
722
723             Freeze_Before (N, Designated_Type (P_Type));
724
725          else
726             if Is_Private_Type (P_Type) then
727                Error_Attr
728                  ("prefix for % attribute may not be private type", P);
729
730             elsif Attr_Id = Attribute_First
731                     or else
732                   Attr_Id = Attribute_Last
733             then
734                Error_Attr ("invalid prefix for % attribute", P);
735
736             else
737                Error_Attr ("prefix for % attribute must be array", P);
738             end if;
739          end if;
740
741          if Present (E1) then
742             Resolve (E1, Any_Integer);
743             Set_Etype (E1, Standard_Integer);
744
745             if not Is_Static_Expression (E1)
746               or else Raises_Constraint_Error (E1)
747             then
748                Error_Attr ("expression for dimension must be static", E1);
749
750             elsif  UI_To_Int (Expr_Value (E1)) > D
751               or else UI_To_Int (Expr_Value (E1)) < 1
752             then
753                Error_Attr ("invalid dimension number for array type", E1);
754             end if;
755          end if;
756       end Check_Array_Type;
757
758       -------------------------
759       -- Check_Asm_Attribute --
760       -------------------------
761
762       procedure Check_Asm_Attribute is
763       begin
764          Check_Type;
765          Check_E2;
766
767          --  Check first argument is static string expression
768
769          Analyze_And_Resolve (E1, Standard_String);
770
771          if Etype (E1) = Any_Type then
772             return;
773
774          elsif not Is_OK_Static_Expression (E1) then
775             Error_Attr
776               ("constraint argument must be static string expression", E1);
777          end if;
778
779          --  Check second argument is right type
780
781          Analyze_And_Resolve (E2, Entity (P));
782
783          --  Note: that is all we need to do, we don't need to check
784          --  that it appears in a correct context. The Ada type system
785          --  will do that for us.
786
787       end Check_Asm_Attribute;
788
789       ---------------------
790       -- Check_Component --
791       ---------------------
792
793       procedure Check_Component is
794       begin
795          Check_E0;
796
797          if Nkind (P) /= N_Selected_Component
798            or else
799              (Ekind (Entity (Selector_Name (P))) /= E_Component
800                and then
801               Ekind (Entity (Selector_Name (P))) /= E_Discriminant)
802          then
803             Error_Attr
804               ("prefix for % attribute must be selected component", P);
805          end if;
806       end Check_Component;
807
808       ------------------------------------
809       -- Check_Decimal_Fixed_Point_Type --
810       ------------------------------------
811
812       procedure Check_Decimal_Fixed_Point_Type is
813       begin
814          Check_Type;
815
816          if not Is_Decimal_Fixed_Point_Type (P_Type) then
817             Error_Attr
818               ("prefix of % attribute must be decimal type", P);
819          end if;
820       end Check_Decimal_Fixed_Point_Type;
821
822       -----------------------
823       -- Check_Dereference --
824       -----------------------
825
826       procedure Check_Dereference is
827       begin
828          if Is_Object_Reference (P)
829            and then Is_Access_Type (P_Type)
830          then
831             Rewrite (P,
832               Make_Explicit_Dereference (Sloc (P),
833                 Prefix => Relocate_Node (P)));
834
835             Analyze_And_Resolve (P);
836             P_Type := Etype (P);
837
838             if P_Type = Any_Type then
839                raise Bad_Attribute;
840             end if;
841
842             P_Base_Type := Base_Type (P_Type);
843             P_Root_Type := Root_Type (P_Base_Type);
844          end if;
845       end Check_Dereference;
846
847       -------------------------
848       -- Check_Discrete_Type --
849       -------------------------
850
851       procedure Check_Discrete_Type is
852       begin
853          Check_Type;
854
855          if not Is_Discrete_Type (P_Type) then
856             Error_Attr ("prefix of % attribute must be discrete type", P);
857          end if;
858       end Check_Discrete_Type;
859
860       --------------
861       -- Check_E0 --
862       --------------
863
864       procedure Check_E0 is
865       begin
866          if Present (E1) then
867             Unexpected_Argument (E1);
868          end if;
869       end Check_E0;
870
871       --------------
872       -- Check_E1 --
873       --------------
874
875       procedure Check_E1 is
876       begin
877          Check_Either_E0_Or_E1;
878
879          if No (E1) then
880
881             --  Special-case attributes that are functions and that appear as
882             --  the prefix of another attribute. Error is posted on parent.
883
884             if Nkind (Parent (N)) = N_Attribute_Reference
885               and then (Attribute_Name (Parent (N)) = Name_Address
886                           or else
887                         Attribute_Name (Parent (N)) = Name_Code_Address
888                           or else
889                         Attribute_Name (Parent (N)) = Name_Access)
890             then
891                Error_Msg_Name_1 := Attribute_Name (Parent (N));
892                Error_Msg_N ("illegal prefix for % attribute", Parent (N));
893                Set_Etype (Parent (N), Any_Type);
894                Set_Entity (Parent (N), Any_Type);
895                raise Bad_Attribute;
896
897             else
898                Error_Attr ("missing argument for % attribute", N);
899             end if;
900          end if;
901       end Check_E1;
902
903       --------------
904       -- Check_E2 --
905       --------------
906
907       procedure Check_E2 is
908       begin
909          if No (E1) then
910             Error_Attr ("missing arguments for % attribute (2 required)", N);
911          elsif No (E2) then
912             Error_Attr ("missing argument for % attribute (2 required)", N);
913          end if;
914       end Check_E2;
915
916       ---------------------------
917       -- Check_Either_E0_Or_E1 --
918       ---------------------------
919
920       procedure Check_Either_E0_Or_E1 is
921       begin
922          if Present (E2) then
923             Unexpected_Argument (E2);
924          end if;
925       end Check_Either_E0_Or_E1;
926
927       ----------------------
928       -- Check_Enum_Image --
929       ----------------------
930
931       procedure Check_Enum_Image is
932          Lit : Entity_Id;
933
934       begin
935          if Is_Enumeration_Type (P_Base_Type) then
936             Lit := First_Literal (P_Base_Type);
937             while Present (Lit) loop
938                Set_Referenced (Lit);
939                Next_Literal (Lit);
940             end loop;
941          end if;
942       end Check_Enum_Image;
943
944       ----------------------------
945       -- Check_Enumeration_Type --
946       ----------------------------
947
948       procedure Check_Enumeration_Type is
949       begin
950          Check_Type;
951
952          if not Is_Enumeration_Type (P_Type) then
953             Error_Attr ("prefix of % attribute must be enumeration type", P);
954          end if;
955       end Check_Enumeration_Type;
956
957       ----------------------------
958       -- Check_Fixed_Point_Type --
959       ----------------------------
960
961       procedure Check_Fixed_Point_Type is
962       begin
963          Check_Type;
964
965          if not Is_Fixed_Point_Type (P_Type) then
966             Error_Attr ("prefix of % attribute must be fixed point type", P);
967          end if;
968       end Check_Fixed_Point_Type;
969
970       ------------------------------
971       -- Check_Fixed_Point_Type_0 --
972       ------------------------------
973
974       procedure Check_Fixed_Point_Type_0 is
975       begin
976          Check_Fixed_Point_Type;
977          Check_E0;
978       end Check_Fixed_Point_Type_0;
979
980       -------------------------------
981       -- Check_Floating_Point_Type --
982       -------------------------------
983
984       procedure Check_Floating_Point_Type is
985       begin
986          Check_Type;
987
988          if not Is_Floating_Point_Type (P_Type) then
989             Error_Attr ("prefix of % attribute must be float type", P);
990          end if;
991       end Check_Floating_Point_Type;
992
993       ---------------------------------
994       -- Check_Floating_Point_Type_0 --
995       ---------------------------------
996
997       procedure Check_Floating_Point_Type_0 is
998       begin
999          Check_Floating_Point_Type;
1000          Check_E0;
1001       end Check_Floating_Point_Type_0;
1002
1003       ---------------------------------
1004       -- Check_Floating_Point_Type_1 --
1005       ---------------------------------
1006
1007       procedure Check_Floating_Point_Type_1 is
1008       begin
1009          Check_Floating_Point_Type;
1010          Check_E1;
1011       end Check_Floating_Point_Type_1;
1012
1013       ---------------------------------
1014       -- Check_Floating_Point_Type_2 --
1015       ---------------------------------
1016
1017       procedure Check_Floating_Point_Type_2 is
1018       begin
1019          Check_Floating_Point_Type;
1020          Check_E2;
1021       end Check_Floating_Point_Type_2;
1022
1023       ------------------------
1024       -- Check_Integer_Type --
1025       ------------------------
1026
1027       procedure Check_Integer_Type is
1028       begin
1029          Check_Type;
1030
1031          if not Is_Integer_Type (P_Type) then
1032             Error_Attr ("prefix of % attribute must be integer type", P);
1033          end if;
1034       end Check_Integer_Type;
1035
1036       ------------------------
1037       -- Check_Library_Unit --
1038       ------------------------
1039
1040       procedure Check_Library_Unit is
1041       begin
1042          if not Is_Compilation_Unit (Entity (P)) then
1043             Error_Attr ("prefix of % attribute must be library unit", P);
1044          end if;
1045       end Check_Library_Unit;
1046
1047       -------------------------------
1048       -- Check_Not_Incomplete_Type --
1049       -------------------------------
1050
1051       procedure Check_Not_Incomplete_Type is
1052       begin
1053          if not Is_Entity_Name (P)
1054            or else not Is_Type (Entity (P))
1055            or else In_Default_Expression
1056          then
1057             return;
1058
1059          else
1060             Check_Fully_Declared (P_Type, P);
1061          end if;
1062       end Check_Not_Incomplete_Type;
1063
1064       ----------------------------
1065       -- Check_Object_Reference --
1066       ----------------------------
1067
1068       procedure Check_Object_Reference (P : Node_Id) is
1069          Rtyp : Entity_Id;
1070
1071       begin
1072          --  If we need an object, and we have a prefix that is the name of
1073          --  a function entity, convert it into a function call.
1074
1075          if Is_Entity_Name (P)
1076            and then Ekind (Entity (P)) = E_Function
1077          then
1078             Rtyp := Etype (Entity (P));
1079
1080             Rewrite (P,
1081               Make_Function_Call (Sloc (P),
1082                 Name => Relocate_Node (P)));
1083
1084             Analyze_And_Resolve (P, Rtyp);
1085
1086          --  Otherwise we must have an object reference
1087
1088          elsif not Is_Object_Reference (P) then
1089             Error_Attr ("prefix of % attribute must be object", P);
1090          end if;
1091       end Check_Object_Reference;
1092
1093       ------------------------
1094       -- Check_Program_Unit --
1095       ------------------------
1096
1097       procedure Check_Program_Unit is
1098       begin
1099          if Is_Entity_Name (P) then
1100             declare
1101                K : constant Entity_Kind := Ekind (Entity (P));
1102                T : constant Entity_Id   := Etype (Entity (P));
1103
1104             begin
1105                if K in Subprogram_Kind
1106                  or else K in Task_Kind
1107                  or else K in Protected_Kind
1108                  or else K = E_Package
1109                  or else K in Generic_Unit_Kind
1110                  or else (K = E_Variable
1111                             and then
1112                               (Is_Task_Type (T)
1113                                  or else
1114                                Is_Protected_Type (T)))
1115                then
1116                   return;
1117                end if;
1118             end;
1119          end if;
1120
1121          Error_Attr ("prefix of % attribute must be program unit", P);
1122       end Check_Program_Unit;
1123
1124       ---------------------
1125       -- Check_Real_Type --
1126       ---------------------
1127
1128       procedure Check_Real_Type is
1129       begin
1130          Check_Type;
1131
1132          if not Is_Real_Type (P_Type) then
1133             Error_Attr ("prefix of % attribute must be real type", P);
1134          end if;
1135       end Check_Real_Type;
1136
1137       -----------------------
1138       -- Check_Scalar_Type --
1139       -----------------------
1140
1141       procedure Check_Scalar_Type is
1142       begin
1143          Check_Type;
1144
1145          if not Is_Scalar_Type (P_Type) then
1146             Error_Attr ("prefix of % attribute must be scalar type", P);
1147          end if;
1148       end Check_Scalar_Type;
1149
1150       ---------------------------
1151       -- Check_Standard_Prefix --
1152       ---------------------------
1153
1154       procedure Check_Standard_Prefix is
1155       begin
1156          Check_E0;
1157
1158          if Nkind (P) /= N_Identifier
1159            or else Chars (P) /= Name_Standard
1160          then
1161             Error_Attr ("only allowed prefix for % attribute is Standard", P);
1162          end if;
1163
1164       end Check_Standard_Prefix;
1165
1166       ----------------------------
1167       -- Check_Stream_Attribute --
1168       ----------------------------
1169
1170       procedure Check_Stream_Attribute (Nam : Name_Id) is
1171          Etyp : Entity_Id;
1172          Btyp : Entity_Id;
1173
1174       begin
1175          Validate_Non_Static_Attribute_Function_Call;
1176
1177          --  With the exception of 'Input, Stream attributes are procedures,
1178          --  and can only appear at the position of procedure calls. We check
1179          --  for this here, before they are rewritten, to give a more precise
1180          --  diagnostic.
1181
1182          if Nam = Name_uInput then
1183             null;
1184
1185          elsif Is_List_Member (N)
1186            and then Nkind (Parent (N)) /= N_Procedure_Call_Statement
1187            and then Nkind (Parent (N)) /= N_Aggregate
1188          then
1189             null;
1190
1191          else
1192             Error_Attr
1193               ("invalid context for attribute %, which is a procedure", N);
1194          end if;
1195
1196          Check_Type;
1197          Btyp := Implementation_Base_Type (P_Type);
1198
1199          --  Stream attributes not allowed on limited types unless the
1200          --  special OK_For_Stream flag is set.
1201
1202          if Is_Limited_Type (P_Type)
1203            and then Comes_From_Source (N)
1204            and then not Present (TSS (Btyp, Nam))
1205            and then No (Get_Rep_Pragma (Btyp, Name_Stream_Convert))
1206          then
1207             --  Special case the message if we are compiling the stub version
1208             --  of a remote operation. One error on the type is sufficient.
1209
1210             if (Is_Remote_Types (Current_Scope)
1211                  or else Is_Remote_Call_Interface (Current_Scope))
1212               and then not Error_Posted (Btyp)
1213             then
1214                Error_Msg_Node_2 := Current_Scope;
1215                Error_Msg_NE
1216                  ("limited type& used in& has no stream attributes", P, Btyp);
1217                Set_Error_Posted (Btyp);
1218
1219             elsif not Error_Posted (Btyp) then
1220                Error_Msg_NE
1221                  ("limited type& has no stream attributes", P, Btyp);
1222             end if;
1223          end if;
1224
1225          --  Here we must check that the first argument is an access type
1226          --  that is compatible with Ada.Streams.Root_Stream_Type'Class.
1227
1228          Analyze_And_Resolve (E1);
1229          Etyp := Etype (E1);
1230
1231          --  Note: the double call to Root_Type here is needed because the
1232          --  root type of a class-wide type is the corresponding type (e.g.
1233          --  X for X'Class, and we really want to go to the root.
1234
1235          if not Is_Access_Type (Etyp)
1236            or else Root_Type (Root_Type (Designated_Type (Etyp))) /=
1237                      RTE (RE_Root_Stream_Type)
1238          then
1239             Error_Attr
1240               ("expected access to Ada.Streams.Root_Stream_Type''Class", E1);
1241          end if;
1242
1243          --  Check that the second argument is of the right type if there is
1244          --  one (the Input attribute has only one argument so this is skipped)
1245
1246          if Present (E2) then
1247             Analyze (E2);
1248
1249             if Nam = Name_uRead
1250               and then not Is_OK_Variable_For_Out_Formal (E2)
1251             then
1252                Error_Attr
1253                  ("second argument of % attribute must be a variable", E2);
1254             end if;
1255
1256             Resolve (E2, P_Type);
1257          end if;
1258       end Check_Stream_Attribute;
1259
1260       -----------------------
1261       -- Check_Task_Prefix --
1262       -----------------------
1263
1264       procedure Check_Task_Prefix is
1265       begin
1266          Analyze (P);
1267
1268          if Is_Task_Type (Etype (P))
1269            or else (Is_Access_Type (Etype (P))
1270               and then Is_Task_Type (Designated_Type (Etype (P))))
1271          then
1272             Resolve (P, Etype (P));
1273          else
1274             Error_Attr ("prefix of % attribute must be a task", P);
1275          end if;
1276       end Check_Task_Prefix;
1277
1278       ----------------
1279       -- Check_Type --
1280       ----------------
1281
1282       --  The possibilities are an entity name denoting a type, or an
1283       --  attribute reference that denotes a type (Base or Class). If
1284       --  the type is incomplete, replace it with its full view.
1285
1286       procedure Check_Type is
1287       begin
1288          if not Is_Entity_Name (P)
1289            or else not Is_Type (Entity (P))
1290          then
1291             Error_Attr ("prefix of % attribute must be a type", P);
1292
1293          elsif Ekind (Entity (P)) = E_Incomplete_Type
1294             and then Present (Full_View (Entity (P)))
1295          then
1296             P_Type := Full_View (Entity (P));
1297             Set_Entity (P, P_Type);
1298          end if;
1299       end Check_Type;
1300
1301       ---------------------
1302       -- Check_Unit_Name --
1303       ---------------------
1304
1305       procedure Check_Unit_Name (Nod : Node_Id) is
1306       begin
1307          if Nkind (Nod) = N_Identifier then
1308             return;
1309
1310          elsif Nkind (Nod) = N_Selected_Component then
1311             Check_Unit_Name (Prefix (Nod));
1312
1313             if Nkind (Selector_Name (Nod)) = N_Identifier then
1314                return;
1315             end if;
1316          end if;
1317
1318          Error_Attr ("argument for % attribute must be unit name", P);
1319       end Check_Unit_Name;
1320
1321       ----------------
1322       -- Error_Attr --
1323       ----------------
1324
1325       procedure Error_Attr (Msg : String; Error_Node : Node_Id) is
1326       begin
1327          Error_Msg_Name_1 := Aname;
1328          Error_Msg_N (Msg, Error_Node);
1329          Set_Etype (N, Any_Type);
1330          Set_Entity (N, Any_Type);
1331          raise Bad_Attribute;
1332       end Error_Attr;
1333
1334       ----------------------------
1335       -- Legal_Formal_Attribute --
1336       ----------------------------
1337
1338       procedure Legal_Formal_Attribute is
1339       begin
1340          Check_E0;
1341
1342          if not Is_Entity_Name (P)
1343            or else not Is_Type (Entity (P))
1344          then
1345             Error_Attr (" prefix of % attribute must be generic type", N);
1346
1347          elsif Is_Generic_Actual_Type (Entity (P))
1348            or In_Instance
1349          then
1350             null;
1351
1352          elsif Is_Generic_Type (Entity (P)) then
1353             if not Is_Indefinite_Subtype (Entity (P)) then
1354                Error_Attr
1355                  (" prefix of % attribute must be indefinite generic type", N);
1356             end if;
1357
1358          else
1359             Error_Attr
1360               (" prefix of % attribute must be indefinite generic type", N);
1361          end if;
1362
1363          Set_Etype (N, Standard_Boolean);
1364       end Legal_Formal_Attribute;
1365
1366       ------------------------
1367       -- Standard_Attribute --
1368       ------------------------
1369
1370       procedure Standard_Attribute (Val : Int) is
1371       begin
1372          Check_Standard_Prefix;
1373          Rewrite (N,
1374            Make_Integer_Literal (Loc, Val));
1375          Analyze (N);
1376       end Standard_Attribute;
1377
1378       -------------------------
1379       -- Unexpected Argument --
1380       -------------------------
1381
1382       procedure Unexpected_Argument (En : Node_Id) is
1383       begin
1384          Error_Attr ("unexpected argument for % attribute", En);
1385       end Unexpected_Argument;
1386
1387       -------------------------------------------------
1388       -- Validate_Non_Static_Attribute_Function_Call --
1389       -------------------------------------------------
1390
1391       --  This function should be moved to Sem_Dist ???
1392
1393       procedure Validate_Non_Static_Attribute_Function_Call is
1394       begin
1395          if In_Preelaborated_Unit
1396            and then not In_Subprogram_Or_Concurrent_Unit
1397          then
1398             Error_Msg_N ("non-static function call in preelaborated unit", N);
1399          end if;
1400       end Validate_Non_Static_Attribute_Function_Call;
1401
1402    -----------------------------------------------
1403    -- Start of Processing for Analyze_Attribute --
1404    -----------------------------------------------
1405
1406    begin
1407       --  Immediate return if unrecognized attribute (already diagnosed
1408       --  by parser, so there is nothing more that we need to do)
1409
1410       if not Is_Attribute_Name (Aname) then
1411          raise Bad_Attribute;
1412       end if;
1413
1414       --  Deal with Ada 83 and Features issues
1415
1416       if not Attribute_83 (Attr_Id) then
1417          if Ada_83 and then Comes_From_Source (N) then
1418             Error_Msg_Name_1 := Aname;
1419             Error_Msg_N ("(Ada 83) attribute% is not standard?", N);
1420          end if;
1421
1422          if Attribute_Impl_Def (Attr_Id) then
1423             Check_Restriction (No_Implementation_Attributes, N);
1424          end if;
1425       end if;
1426
1427       --   Remote access to subprogram type access attribute reference needs
1428       --   unanalyzed copy for tree transformation. The analyzed copy is used
1429       --   for its semantic information (whether prefix is a remote subprogram
1430       --   name), the unanalyzed copy is used to construct new subtree rooted
1431       --   with N_aggregate which represents a fat pointer aggregate.
1432
1433       if Aname = Name_Access then
1434          Unanalyzed := Copy_Separate_Tree (N);
1435       end if;
1436
1437       --  Analyze prefix and exit if error in analysis. If the prefix is an
1438       --  incomplete type, use full view if available. A special case is
1439       --  that we never analyze the prefix of an Elab_Body or Elab_Spec
1440       --  or UET_Address attribute.
1441
1442       if Aname /= Name_Elab_Body
1443            and then
1444          Aname /= Name_Elab_Spec
1445            and then
1446          Aname /= Name_UET_Address
1447       then
1448          Analyze (P);
1449          P_Type := Etype (P);
1450
1451          if Is_Entity_Name (P)
1452            and then Present (Entity (P))
1453            and then Is_Type (Entity (P))
1454            and then Ekind (Entity (P)) = E_Incomplete_Type
1455          then
1456             P_Type := Get_Full_View (P_Type);
1457             Set_Entity (P, P_Type);
1458             Set_Etype  (P, P_Type);
1459          end if;
1460
1461          if P_Type = Any_Type then
1462             raise Bad_Attribute;
1463          end if;
1464
1465          P_Base_Type := Base_Type (P_Type);
1466          P_Root_Type := Root_Type (P_Base_Type);
1467       end if;
1468
1469       --  Analyze expressions that may be present, exiting if an error occurs
1470
1471       if No (Exprs) then
1472          E1 := Empty;
1473          E2 := Empty;
1474
1475       else
1476          E1 := First (Exprs);
1477          Analyze (E1);
1478
1479          --  Check for missing or bad expression (result of previous error)
1480
1481          if No (E1) or else Etype (E1) = Any_Type then
1482             raise Bad_Attribute;
1483          end if;
1484
1485          E2 := Next (E1);
1486
1487          if Present (E2) then
1488             Analyze (E2);
1489
1490             if Etype (E2) = Any_Type then
1491                raise Bad_Attribute;
1492             end if;
1493
1494             if Present (Next (E2)) then
1495                Unexpected_Argument (Next (E2));
1496             end if;
1497          end if;
1498       end if;
1499
1500       if Is_Overloaded (P)
1501         and then Aname /= Name_Access
1502         and then Aname /= Name_Address
1503         and then Aname /= Name_Code_Address
1504         and then Aname /= Name_Count
1505         and then Aname /= Name_Unchecked_Access
1506       then
1507          Error_Attr ("ambiguous prefix for % attribute", P);
1508       end if;
1509
1510       --  Remaining processing depends on attribute
1511
1512       case Attr_Id is
1513
1514       ------------------
1515       -- Abort_Signal --
1516       ------------------
1517
1518       when Attribute_Abort_Signal =>
1519          Check_Standard_Prefix;
1520          Rewrite (N,
1521            New_Reference_To (Stand.Abort_Signal, Loc));
1522          Analyze (N);
1523
1524       ------------
1525       -- Access --
1526       ------------
1527
1528       when Attribute_Access =>
1529          Access_Attribute;
1530
1531       -------------
1532       -- Address --
1533       -------------
1534
1535       when Attribute_Address =>
1536          Check_E0;
1537
1538          --  Check for some junk cases, where we have to allow the address
1539          --  attribute but it does not make much sense, so at least for now
1540          --  just replace with Null_Address.
1541
1542          --  We also do this if the prefix is a reference to the AST_Entry
1543          --  attribute. If expansion is active, the attribute will be
1544          --  replaced by a function call, and address will work fine and
1545          --  get the proper value, but if expansion is not active, then
1546          --  the check here allows proper semantic analysis of the reference.
1547
1548          --  An Address attribute created by expansion is legal even when it
1549          --  applies to other entity-denoting expressions.
1550
1551          if (Is_Entity_Name (P)) then
1552             if Is_Subprogram (Entity (P))
1553               or else Is_Object (Entity (P))
1554               or else Ekind (Entity (P)) = E_Label
1555             then
1556                Set_Address_Taken (Entity (P));
1557
1558             elsif ((Ekind (Entity (P)) = E_Task_Type
1559                       or else Ekind (Entity (P)) = E_Protected_Type)
1560                     and then Etype (Entity (P)) = Base_Type (Entity (P)))
1561               or else Ekind (Entity (P)) = E_Package
1562               or else Is_Generic_Unit (Entity (P))
1563             then
1564                Rewrite (N,
1565                  New_Occurrence_Of (RTE (RE_Null_Address), Sloc (N)));
1566
1567             else
1568                Error_Attr ("invalid prefix for % attribute", P);
1569             end if;
1570
1571          elsif Nkind (P) = N_Attribute_Reference
1572           and then Attribute_Name (P) = Name_AST_Entry
1573          then
1574             Rewrite (N,
1575               New_Occurrence_Of (RTE (RE_Null_Address), Sloc (N)));
1576
1577          elsif Is_Object_Reference (P) then
1578             null;
1579
1580          elsif Nkind (P) = N_Selected_Component
1581            and then Is_Subprogram (Entity (Selector_Name (P)))
1582          then
1583             null;
1584
1585          elsif not Comes_From_Source (N) then
1586             null;
1587
1588          else
1589             Error_Attr ("invalid prefix for % attribute", P);
1590          end if;
1591
1592          Set_Etype (N, RTE (RE_Address));
1593
1594       ------------------
1595       -- Address_Size --
1596       ------------------
1597
1598       when Attribute_Address_Size =>
1599          Standard_Attribute (System_Address_Size);
1600
1601       --------------
1602       -- Adjacent --
1603       --------------
1604
1605       when Attribute_Adjacent =>
1606          Check_Floating_Point_Type_2;
1607          Set_Etype (N, P_Base_Type);
1608          Resolve (E1, P_Base_Type);
1609          Resolve (E2, P_Base_Type);
1610
1611       ---------
1612       -- Aft --
1613       ---------
1614
1615       when Attribute_Aft =>
1616          Check_Fixed_Point_Type_0;
1617          Set_Etype (N, Universal_Integer);
1618
1619       ---------------
1620       -- Alignment --
1621       ---------------
1622
1623       when Attribute_Alignment =>
1624
1625          --  Don't we need more checking here, cf Size ???
1626
1627          Check_E0;
1628          Check_Not_Incomplete_Type;
1629          Set_Etype (N, Universal_Integer);
1630
1631       ---------------
1632       -- Asm_Input --
1633       ---------------
1634
1635       when Attribute_Asm_Input =>
1636          Check_Asm_Attribute;
1637          Set_Etype (N, RTE (RE_Asm_Input_Operand));
1638
1639       ----------------
1640       -- Asm_Output --
1641       ----------------
1642
1643       when Attribute_Asm_Output =>
1644          Check_Asm_Attribute;
1645
1646          if Etype (E2) = Any_Type then
1647             return;
1648
1649          elsif Aname = Name_Asm_Output then
1650             if not Is_Variable (E2) then
1651                Error_Attr
1652                  ("second argument for Asm_Output is not variable", E2);
1653             end if;
1654          end if;
1655
1656          Note_Possible_Modification (E2);
1657          Set_Etype (N, RTE (RE_Asm_Output_Operand));
1658
1659       ---------------
1660       -- AST_Entry --
1661       ---------------
1662
1663       when Attribute_AST_Entry => AST_Entry : declare
1664          Ent  : Entity_Id;
1665          Pref : Node_Id;
1666          Ptyp : Entity_Id;
1667
1668          Indexed : Boolean;
1669          --  Indicates if entry family index is present. Note the coding
1670          --  here handles the entry family case, but in fact it cannot be
1671          --  executed currently, because pragma AST_Entry does not permit
1672          --  the specification of an entry family.
1673
1674          procedure Bad_AST_Entry;
1675          --  Signal a bad AST_Entry pragma
1676
1677          function OK_Entry (E : Entity_Id) return Boolean;
1678          --  Checks that E is of an appropriate entity kind for an entry
1679          --  (i.e. E_Entry if Index is False, or E_Entry_Family if Index
1680          --  is set True for the entry family case). In the True case,
1681          --  makes sure that Is_AST_Entry is set on the entry.
1682
1683          procedure Bad_AST_Entry is
1684          begin
1685             Error_Attr ("prefix for % attribute must be task entry", P);
1686          end Bad_AST_Entry;
1687
1688          function OK_Entry (E : Entity_Id) return Boolean is
1689             Result : Boolean;
1690
1691          begin
1692             if Indexed then
1693                Result := (Ekind (E) = E_Entry_Family);
1694             else
1695                Result := (Ekind (E) = E_Entry);
1696             end if;
1697
1698             if Result then
1699                if not Is_AST_Entry (E) then
1700                   Error_Msg_Name_2 := Aname;
1701                   Error_Attr
1702                     ("% attribute requires previous % pragma", P);
1703                end if;
1704             end if;
1705
1706             return Result;
1707          end OK_Entry;
1708
1709       --  Start of processing for AST_Entry
1710
1711       begin
1712          Check_VMS (N);
1713          Check_E0;
1714
1715          --  Deal with entry family case
1716
1717          if Nkind (P) = N_Indexed_Component then
1718             Pref := Prefix (P);
1719             Indexed := True;
1720          else
1721             Pref := P;
1722             Indexed := False;
1723          end if;
1724
1725          Ptyp := Etype (Pref);
1726
1727          if Ptyp = Any_Type or else Error_Posted (Pref) then
1728             return;
1729          end if;
1730
1731          --  If the prefix is a selected component whose prefix is of an
1732          --  access type, then introduce an explicit dereference.
1733
1734          if Nkind (Pref) = N_Selected_Component
1735            and then Is_Access_Type (Ptyp)
1736          then
1737             Rewrite (Pref,
1738               Make_Explicit_Dereference (Sloc (Pref),
1739                 Relocate_Node (Pref)));
1740             Analyze_And_Resolve (Pref, Designated_Type (Ptyp));
1741          end if;
1742
1743          --  Prefix can be of the form a.b, where a is a task object
1744          --  and b is one of the entries of the corresponding task type.
1745
1746          if Nkind (Pref) = N_Selected_Component
1747            and then OK_Entry (Entity (Selector_Name (Pref)))
1748            and then Is_Object_Reference (Prefix (Pref))
1749            and then Is_Task_Type (Etype (Prefix (Pref)))
1750          then
1751             null;
1752
1753          --  Otherwise the prefix must be an entry of a containing task,
1754          --  or of a variable of the enclosing task type.
1755
1756          else
1757             if Nkind (Pref) = N_Identifier
1758               or else Nkind (Pref) = N_Expanded_Name
1759             then
1760                Ent := Entity (Pref);
1761
1762                if not OK_Entry (Ent)
1763                  or else not In_Open_Scopes (Scope (Ent))
1764                then
1765                   Bad_AST_Entry;
1766                end if;
1767
1768             else
1769                Bad_AST_Entry;
1770             end if;
1771          end if;
1772
1773          Set_Etype (N, RTE (RE_AST_Handler));
1774       end AST_Entry;
1775
1776       ----------
1777       -- Base --
1778       ----------
1779
1780       when Attribute_Base => Base : declare
1781          Typ : Entity_Id;
1782
1783       begin
1784          Check_Either_E0_Or_E1;
1785          Find_Type (P);
1786          Typ := Entity (P);
1787
1788          if Sloc (Typ) = Standard_Location
1789            and then Base_Type (Typ) = Typ
1790            and then Warn_On_Redundant_Constructs
1791          then
1792             Error_Msg_NE
1793               ("?redudant attribute, & is its own base type", N, Typ);
1794          end if;
1795
1796          Set_Etype (N, Base_Type (Entity (P)));
1797
1798          --  If we have an expression present, then really this is a conversion
1799          --  and the tree must be reformed. Note that this is one of the cases
1800          --  in which we do a replace rather than a rewrite, because the
1801          --  original tree is junk.
1802
1803          if Present (E1) then
1804             Replace (N,
1805               Make_Type_Conversion (Loc,
1806                 Subtype_Mark =>
1807                   Make_Attribute_Reference (Loc,
1808                     Prefix => Prefix (N),
1809                     Attribute_Name => Name_Base),
1810                 Expression => Relocate_Node (E1)));
1811
1812             --  E1 may be overloaded, and its interpretations preserved.
1813
1814             Save_Interps (E1, Expression (N));
1815             Analyze (N);
1816
1817          --  For other cases, set the proper type as the entity of the
1818          --  attribute reference, and then rewrite the node to be an
1819          --  occurrence of the referenced base type. This way, no one
1820          --  else in the compiler has to worry about the base attribute.
1821
1822          else
1823             Set_Entity (N, Base_Type (Entity (P)));
1824             Rewrite (N,
1825               New_Reference_To (Entity (N), Loc));
1826             Analyze (N);
1827          end if;
1828       end Base;
1829
1830       ---------
1831       -- Bit --
1832       ---------
1833
1834       when Attribute_Bit => Bit :
1835       begin
1836          Check_E0;
1837
1838          if not Is_Object_Reference (P) then
1839             Error_Attr ("prefix for % attribute must be object", P);
1840
1841          --  What about the access object cases ???
1842
1843          else
1844             null;
1845          end if;
1846
1847          Set_Etype (N, Universal_Integer);
1848       end Bit;
1849
1850       ---------------
1851       -- Bit_Order --
1852       ---------------
1853
1854       when Attribute_Bit_Order => Bit_Order :
1855       begin
1856          Check_E0;
1857          Check_Type;
1858
1859          if not Is_Record_Type (P_Type) then
1860             Error_Attr ("prefix of % attribute must be record type", P);
1861          end if;
1862
1863          if Bytes_Big_Endian xor Reverse_Bit_Order (P_Type) then
1864             Rewrite (N,
1865               New_Occurrence_Of (RTE (RE_High_Order_First), Loc));
1866          else
1867             Rewrite (N,
1868               New_Occurrence_Of (RTE (RE_Low_Order_First), Loc));
1869          end if;
1870
1871          Set_Etype (N, RTE (RE_Bit_Order));
1872          Resolve (N, Etype (N));
1873
1874          --  Reset incorrect indication of staticness
1875
1876          Set_Is_Static_Expression (N, False);
1877       end Bit_Order;
1878
1879       ------------------
1880       -- Bit_Position --
1881       ------------------
1882
1883       --  Note: in generated code, we can have a Bit_Position attribute
1884       --  applied to a (naked) record component (i.e. the prefix is an
1885       --  identifier that references an E_Component or E_Discriminant
1886       --  entity directly, and this is interpreted as expected by Gigi.
1887       --  The following code will not tolerate such usage, but when the
1888       --  expander creates this special case, it marks it as analyzed
1889       --  immediately and sets an appropriate type.
1890
1891       when Attribute_Bit_Position =>
1892
1893          if Comes_From_Source (N) then
1894             Check_Component;
1895          end if;
1896
1897          Set_Etype (N, Universal_Integer);
1898
1899       ------------------
1900       -- Body_Version --
1901       ------------------
1902
1903       when Attribute_Body_Version =>
1904          Check_E0;
1905          Check_Program_Unit;
1906          Set_Etype (N, RTE (RE_Version_String));
1907
1908       --------------
1909       -- Callable --
1910       --------------
1911
1912       when Attribute_Callable =>
1913          Check_E0;
1914          Set_Etype (N, Standard_Boolean);
1915          Check_Task_Prefix;
1916
1917       ------------
1918       -- Caller --
1919       ------------
1920
1921       when Attribute_Caller => Caller : declare
1922          Ent        : Entity_Id;
1923          S          : Entity_Id;
1924
1925       begin
1926          Check_E0;
1927
1928          if Nkind (P) = N_Identifier
1929            or else Nkind (P) = N_Expanded_Name
1930          then
1931             Ent := Entity (P);
1932
1933             if not Is_Entry (Ent) then
1934                Error_Attr ("invalid entry name", N);
1935             end if;
1936
1937          else
1938             Error_Attr ("invalid entry name", N);
1939             return;
1940          end if;
1941
1942          for J in reverse 0 .. Scope_Stack.Last loop
1943             S := Scope_Stack.Table (J).Entity;
1944
1945             if S = Scope (Ent) then
1946                Error_Attr ("Caller must appear in matching accept or body", N);
1947             elsif S = Ent then
1948                exit;
1949             end if;
1950          end loop;
1951
1952          Set_Etype (N, RTE (RO_AT_Task_ID));
1953       end Caller;
1954
1955       -------------
1956       -- Ceiling --
1957       -------------
1958
1959       when Attribute_Ceiling =>
1960          Check_Floating_Point_Type_1;
1961          Set_Etype (N, P_Base_Type);
1962          Resolve (E1, P_Base_Type);
1963
1964       -----------
1965       -- Class --
1966       -----------
1967
1968       when Attribute_Class => Class : declare
1969       begin
1970          Check_Restriction (No_Dispatch, N);
1971          Check_Either_E0_Or_E1;
1972
1973          --  If we have an expression present, then really this is a conversion
1974          --  and the tree must be reformed into a proper conversion. This is a
1975          --  Replace rather than a Rewrite, because the original tree is junk.
1976          --  If expression is overloaded, propagate interpretations to new one.
1977
1978          if Present (E1) then
1979             Replace (N,
1980               Make_Type_Conversion (Loc,
1981                 Subtype_Mark =>
1982                   Make_Attribute_Reference (Loc,
1983                     Prefix => Prefix (N),
1984                     Attribute_Name => Name_Class),
1985                 Expression => Relocate_Node (E1)));
1986
1987             Save_Interps (E1, Expression (N));
1988             Analyze (N);
1989
1990          --  Otherwise we just need to find the proper type
1991
1992          else
1993             Find_Type (N);
1994          end if;
1995
1996       end Class;
1997
1998       ------------------
1999       -- Code_Address --
2000       ------------------
2001
2002       when Attribute_Code_Address =>
2003          Check_E0;
2004
2005          if Nkind (P) = N_Attribute_Reference
2006            and then (Attribute_Name (P) = Name_Elab_Body
2007                        or else
2008                      Attribute_Name (P) = Name_Elab_Spec)
2009          then
2010             null;
2011
2012          elsif not Is_Entity_Name (P)
2013            or else (Ekind (Entity (P)) /= E_Function
2014                       and then
2015                     Ekind (Entity (P)) /= E_Procedure)
2016          then
2017             Error_Attr ("invalid prefix for % attribute", P);
2018             Set_Address_Taken (Entity (P));
2019          end if;
2020
2021          Set_Etype (N, RTE (RE_Address));
2022
2023       --------------------
2024       -- Component_Size --
2025       --------------------
2026
2027       when Attribute_Component_Size =>
2028          Check_E0;
2029          Set_Etype (N, Universal_Integer);
2030
2031          --  Note: unlike other array attributes, unconstrained arrays are OK
2032
2033          if Is_Array_Type (P_Type) and then not Is_Constrained (P_Type) then
2034             null;
2035          else
2036             Check_Array_Type;
2037          end if;
2038
2039       -------------
2040       -- Compose --
2041       -------------
2042
2043       when Attribute_Compose =>
2044          Check_Floating_Point_Type_2;
2045          Set_Etype (N, P_Base_Type);
2046          Resolve (E1, P_Base_Type);
2047          Resolve (E2, Any_Integer);
2048
2049       -----------------
2050       -- Constrained --
2051       -----------------
2052
2053       when Attribute_Constrained =>
2054          Check_E0;
2055          Set_Etype (N, Standard_Boolean);
2056
2057          --  Case from RM J.4(2) of constrained applied to private type
2058
2059          if Is_Entity_Name (P) and then Is_Type (Entity (P)) then
2060
2061             --  If we are within an instance, the attribute must be legal
2062             --  because it was valid in the generic unit.
2063
2064             if In_Instance then
2065                return;
2066
2067             --  For sure OK if we have a real private type itself, but must
2068             --  be completed, cannot apply Constrained to incomplete type.
2069
2070             elsif Is_Private_Type (Entity (P)) then
2071                Check_Not_Incomplete_Type;
2072                return;
2073             end if;
2074
2075          else
2076             Check_Object_Reference (P);
2077
2078             --  If N does not come from source, then we allow the
2079             --  the attribute prefix to be of a private type whose
2080             --  full type has discriminants. This occurs in cases
2081             --  involving expanded calls to stream attributes.
2082
2083             if not Comes_From_Source (N) then
2084                P_Type := Underlying_Type (P_Type);
2085             end if;
2086
2087             --  Must have discriminants or be an access type designating
2088             --  a type with discriminants. If it is a classwide type is
2089             --  has unknown discriminants.
2090
2091             if Has_Discriminants (P_Type)
2092                or else Has_Unknown_Discriminants (P_Type)
2093                or else
2094                  (Is_Access_Type (P_Type)
2095                    and then Has_Discriminants (Designated_Type (P_Type)))
2096             then
2097                return;
2098
2099             --  Also allow an object of a generic type if extensions allowed
2100             --  and allow this for any type at all.
2101
2102             elsif (Is_Generic_Type (P_Type)
2103                      or else Is_Generic_Actual_Type (P_Type))
2104               and then Extensions_Allowed
2105             then
2106                return;
2107             end if;
2108          end if;
2109
2110          --  Fall through if bad prefix
2111
2112          Error_Attr
2113            ("prefix of % attribute must be object of discriminated type", P);
2114
2115       ---------------
2116       -- Copy_Sign --
2117       ---------------
2118
2119       when Attribute_Copy_Sign =>
2120          Check_Floating_Point_Type_2;
2121          Set_Etype (N, P_Base_Type);
2122          Resolve (E1, P_Base_Type);
2123          Resolve (E2, P_Base_Type);
2124
2125       -----------
2126       -- Count --
2127       -----------
2128
2129       when Attribute_Count => Count :
2130       declare
2131          Ent : Entity_Id;
2132          S   : Entity_Id;
2133          Tsk : Entity_Id;
2134
2135       begin
2136          Check_E0;
2137
2138          if Nkind (P) = N_Identifier
2139            or else Nkind (P) = N_Expanded_Name
2140          then
2141             Ent := Entity (P);
2142
2143             if Ekind (Ent) /= E_Entry then
2144                Error_Attr ("invalid entry name", N);
2145             end if;
2146
2147          elsif Nkind (P) = N_Indexed_Component then
2148             Ent := Entity (Prefix (P));
2149
2150             if Ekind (Ent) /= E_Entry_Family then
2151                Error_Attr ("invalid entry family name", P);
2152                return;
2153             end if;
2154
2155          else
2156             Error_Attr ("invalid entry name", N);
2157             return;
2158          end if;
2159
2160          for J in reverse 0 .. Scope_Stack.Last loop
2161             S := Scope_Stack.Table (J).Entity;
2162
2163             if S = Scope (Ent) then
2164                if Nkind (P) = N_Expanded_Name then
2165                   Tsk := Entity (Prefix (P));
2166
2167                   --  The prefix denotes either the task type, or else a
2168                   --  single task whose task type is being analyzed.
2169
2170                   if (Is_Type (Tsk)
2171                       and then Tsk = S)
2172
2173                     or else (not Is_Type (Tsk)
2174                       and then Etype (Tsk) = S
2175                       and then not (Comes_From_Source (S)))
2176                   then
2177                      null;
2178                   else
2179                      Error_Msg_N
2180                        ("Count must apply to entry of current task", N);
2181                   end if;
2182                end if;
2183
2184                exit;
2185
2186             elsif Ekind (Scope (Ent)) in Task_Kind
2187               and then Ekind (S) /= E_Loop
2188               and then Ekind (S) /= E_Block
2189               and then Ekind (S) /= E_Entry
2190               and then Ekind (S) /= E_Entry_Family
2191             then
2192                Error_Attr ("Count cannot appear in inner unit", N);
2193
2194             elsif Ekind (Scope (Ent)) = E_Protected_Type
2195               and then not Has_Completion (Scope (Ent))
2196             then
2197                Error_Attr ("attribute % can only be used inside body", N);
2198             end if;
2199          end loop;
2200
2201          if Is_Overloaded (P) then
2202             declare
2203                Index : Interp_Index;
2204                It    : Interp;
2205
2206             begin
2207                Get_First_Interp (P, Index, It);
2208
2209                while Present (It.Nam) loop
2210                   if It.Nam = Ent then
2211                      null;
2212
2213                   elsif Scope (It.Nam) = Scope (Ent) then
2214                      Error_Attr ("ambiguous entry name", N);
2215
2216                   else
2217                      --  For now make this into a warning. Will become an
2218                      --  error after the 3.15 release.
2219
2220                      Error_Msg_N
2221                        ("ambiguous name, resolved to entry?", N);
2222                      Error_Msg_N
2223                        ("\(this will become an error in a later release)?", N);
2224                   end if;
2225
2226                   Get_Next_Interp (Index, It);
2227                end loop;
2228             end;
2229          end if;
2230
2231          Set_Etype (N, Universal_Integer);
2232       end Count;
2233
2234       -----------------------
2235       -- Default_Bit_Order --
2236       -----------------------
2237
2238       when Attribute_Default_Bit_Order => Default_Bit_Order :
2239       begin
2240          Check_Standard_Prefix;
2241          Check_E0;
2242
2243          if Bytes_Big_Endian then
2244             Rewrite (N,
2245               Make_Integer_Literal (Loc, False_Value));
2246          else
2247             Rewrite (N,
2248               Make_Integer_Literal (Loc, True_Value));
2249          end if;
2250
2251          Set_Etype (N, Universal_Integer);
2252          Set_Is_Static_Expression (N);
2253       end Default_Bit_Order;
2254
2255       --------------
2256       -- Definite --
2257       --------------
2258
2259       when Attribute_Definite =>
2260          Legal_Formal_Attribute;
2261
2262       -----------
2263       -- Delta --
2264       -----------
2265
2266       when Attribute_Delta =>
2267          Check_Fixed_Point_Type_0;
2268          Set_Etype (N, Universal_Real);
2269
2270       ------------
2271       -- Denorm --
2272       ------------
2273
2274       when Attribute_Denorm =>
2275          Check_Floating_Point_Type_0;
2276          Set_Etype (N, Standard_Boolean);
2277
2278       ------------
2279       -- Digits --
2280       ------------
2281
2282       when Attribute_Digits =>
2283          Check_E0;
2284          Check_Type;
2285
2286          if not Is_Floating_Point_Type (P_Type)
2287            and then not Is_Decimal_Fixed_Point_Type (P_Type)
2288          then
2289             Error_Attr
2290               ("prefix of % attribute must be float or decimal type", P);
2291          end if;
2292
2293          Set_Etype (N, Universal_Integer);
2294
2295       ---------------
2296       -- Elab_Body --
2297       ---------------
2298
2299       --  Also handles processing for Elab_Spec
2300
2301       when Attribute_Elab_Body | Attribute_Elab_Spec =>
2302          Check_E0;
2303          Check_Unit_Name (P);
2304          Set_Etype (N, Standard_Void_Type);
2305
2306          --  We have to manually call the expander in this case to get
2307          --  the necessary expansion (normally attributes that return
2308          --  entities are not expanded).
2309
2310          Expand (N);
2311
2312       ---------------
2313       -- Elab_Spec --
2314       ---------------
2315
2316       --  Shares processing with Elab_Body
2317
2318       ----------------
2319       -- Elaborated --
2320       ----------------
2321
2322       when Attribute_Elaborated =>
2323          Check_E0;
2324          Check_Library_Unit;
2325          Set_Etype (N, Standard_Boolean);
2326
2327       ----------
2328       -- Emax --
2329       ----------
2330
2331       when Attribute_Emax =>
2332          Check_Floating_Point_Type_0;
2333          Set_Etype (N, Universal_Integer);
2334
2335       --------------
2336       -- Enum_Rep --
2337       --------------
2338
2339       when Attribute_Enum_Rep => Enum_Rep : declare
2340       begin
2341          if Present (E1) then
2342             Check_E1;
2343             Check_Discrete_Type;
2344             Resolve (E1, P_Base_Type);
2345
2346          else
2347             if not Is_Entity_Name (P)
2348               or else (not Is_Object (Entity (P))
2349                          and then
2350                        Ekind (Entity (P)) /= E_Enumeration_Literal)
2351             then
2352                Error_Attr
2353                  ("prefix of %attribute must be " &
2354                   "discrete type/object or enum literal", P);
2355             end if;
2356          end if;
2357
2358          Set_Etype (N, Universal_Integer);
2359       end Enum_Rep;
2360
2361       -------------
2362       -- Epsilon --
2363       -------------
2364
2365       when Attribute_Epsilon =>
2366          Check_Floating_Point_Type_0;
2367          Set_Etype (N, Universal_Real);
2368
2369       --------------
2370       -- Exponent --
2371       --------------
2372
2373       when Attribute_Exponent =>
2374          Check_Floating_Point_Type_1;
2375          Set_Etype (N, Universal_Integer);
2376          Resolve (E1, P_Base_Type);
2377
2378       ------------------
2379       -- External_Tag --
2380       ------------------
2381
2382       when Attribute_External_Tag =>
2383          Check_E0;
2384          Check_Type;
2385
2386          Set_Etype (N, Standard_String);
2387
2388          if not Is_Tagged_Type (P_Type) then
2389             Error_Attr ("prefix of % attribute must be tagged", P);
2390          end if;
2391
2392       -----------
2393       -- First --
2394       -----------
2395
2396       when Attribute_First =>
2397          Check_Array_Or_Scalar_Type;
2398
2399       ---------------
2400       -- First_Bit --
2401       ---------------
2402
2403       when Attribute_First_Bit =>
2404          Check_Component;
2405          Set_Etype (N, Universal_Integer);
2406
2407       -----------------
2408       -- Fixed_Value --
2409       -----------------
2410
2411       when Attribute_Fixed_Value =>
2412          Check_E1;
2413          Check_Fixed_Point_Type;
2414          Resolve (E1, Any_Integer);
2415          Set_Etype (N, P_Base_Type);
2416
2417       -----------
2418       -- Floor --
2419       -----------
2420
2421       when Attribute_Floor =>
2422          Check_Floating_Point_Type_1;
2423          Set_Etype (N, P_Base_Type);
2424          Resolve (E1, P_Base_Type);
2425
2426       ----------
2427       -- Fore --
2428       ----------
2429
2430       when Attribute_Fore =>
2431          Check_Fixed_Point_Type_0;
2432          Set_Etype (N, Universal_Integer);
2433
2434       --------------
2435       -- Fraction --
2436       --------------
2437
2438       when Attribute_Fraction =>
2439          Check_Floating_Point_Type_1;
2440          Set_Etype (N, P_Base_Type);
2441          Resolve (E1, P_Base_Type);
2442
2443       -----------------------
2444       -- Has_Discriminants --
2445       -----------------------
2446
2447       when Attribute_Has_Discriminants =>
2448          Legal_Formal_Attribute;
2449
2450       --------------
2451       -- Identity --
2452       --------------
2453
2454       when Attribute_Identity =>
2455          Check_E0;
2456          Analyze (P);
2457
2458          if Etype (P) =  Standard_Exception_Type then
2459             Set_Etype (N, RTE (RE_Exception_Id));
2460
2461          elsif Is_Task_Type (Etype (P))
2462            or else (Is_Access_Type (Etype (P))
2463               and then Is_Task_Type (Designated_Type (Etype (P))))
2464          then
2465             Resolve (P, Etype (P));
2466             Set_Etype (N, RTE (RO_AT_Task_ID));
2467
2468          else
2469             Error_Attr ("prefix of % attribute must be a task or an "
2470               & "exception", P);
2471          end if;
2472
2473       -----------
2474       -- Image --
2475       -----------
2476
2477       when Attribute_Image => Image :
2478       begin
2479          Set_Etype (N, Standard_String);
2480          Check_Scalar_Type;
2481
2482          if Is_Real_Type (P_Type) then
2483             if Ada_83 and then Comes_From_Source (N) then
2484                Error_Msg_Name_1 := Aname;
2485                Error_Msg_N
2486                  ("(Ada 83) % attribute not allowed for real types", N);
2487             end if;
2488          end if;
2489
2490          if Is_Enumeration_Type (P_Type) then
2491             Check_Restriction (No_Enumeration_Maps, N);
2492          end if;
2493
2494          Check_E1;
2495          Resolve (E1, P_Base_Type);
2496          Check_Enum_Image;
2497          Validate_Non_Static_Attribute_Function_Call;
2498       end Image;
2499
2500       ---------
2501       -- Img --
2502       ---------
2503
2504       when Attribute_Img => Img :
2505       begin
2506          Set_Etype (N, Standard_String);
2507
2508          if not Is_Scalar_Type (P_Type)
2509            or else (Is_Entity_Name (P) and then Is_Type (Entity (P)))
2510          then
2511             Error_Attr
2512               ("prefix of % attribute must be scalar object name", N);
2513          end if;
2514
2515          Check_Enum_Image;
2516       end Img;
2517
2518       -----------
2519       -- Input --
2520       -----------
2521
2522       when Attribute_Input =>
2523          Check_E1;
2524          Check_Stream_Attribute (Name_uInput);
2525          Disallow_In_No_Run_Time_Mode (N);
2526          Set_Etype (N, P_Base_Type);
2527
2528       -------------------
2529       -- Integer_Value --
2530       -------------------
2531
2532       when Attribute_Integer_Value =>
2533          Check_E1;
2534          Check_Integer_Type;
2535          Resolve (E1, Any_Fixed);
2536          Set_Etype (N, P_Base_Type);
2537
2538       -----------
2539       -- Large --
2540       -----------
2541
2542       when Attribute_Large =>
2543          Check_E0;
2544          Check_Real_Type;
2545          Set_Etype (N, Universal_Real);
2546
2547       ----------
2548       -- Last --
2549       ----------
2550
2551       when Attribute_Last =>
2552          Check_Array_Or_Scalar_Type;
2553
2554       --------------
2555       -- Last_Bit --
2556       --------------
2557
2558       when Attribute_Last_Bit =>
2559          Check_Component;
2560          Set_Etype (N, Universal_Integer);
2561
2562       ------------------
2563       -- Leading_Part --
2564       ------------------
2565
2566       when Attribute_Leading_Part =>
2567          Check_Floating_Point_Type_2;
2568          Set_Etype (N, P_Base_Type);
2569          Resolve (E1, P_Base_Type);
2570          Resolve (E2, Any_Integer);
2571
2572       ------------
2573       -- Length --
2574       ------------
2575
2576       when Attribute_Length =>
2577          Check_Array_Type;
2578          Set_Etype (N, Universal_Integer);
2579
2580       -------------
2581       -- Machine --
2582       -------------
2583
2584       when Attribute_Machine =>
2585          Check_Floating_Point_Type_1;
2586          Set_Etype (N, P_Base_Type);
2587          Resolve (E1, P_Base_Type);
2588
2589       ------------------
2590       -- Machine_Emax --
2591       ------------------
2592
2593       when Attribute_Machine_Emax =>
2594          Check_Floating_Point_Type_0;
2595          Set_Etype (N, Universal_Integer);
2596
2597       ------------------
2598       -- Machine_Emin --
2599       ------------------
2600
2601       when Attribute_Machine_Emin =>
2602          Check_Floating_Point_Type_0;
2603          Set_Etype (N, Universal_Integer);
2604
2605       ----------------------
2606       -- Machine_Mantissa --
2607       ----------------------
2608
2609       when Attribute_Machine_Mantissa =>
2610          Check_Floating_Point_Type_0;
2611          Set_Etype (N, Universal_Integer);
2612
2613       -----------------------
2614       -- Machine_Overflows --
2615       -----------------------
2616
2617       when Attribute_Machine_Overflows =>
2618          Check_Real_Type;
2619          Check_E0;
2620          Set_Etype (N, Standard_Boolean);
2621
2622       -------------------
2623       -- Machine_Radix --
2624       -------------------
2625
2626       when Attribute_Machine_Radix =>
2627          Check_Real_Type;
2628          Check_E0;
2629          Set_Etype (N, Universal_Integer);
2630
2631       --------------------
2632       -- Machine_Rounds --
2633       --------------------
2634
2635       when Attribute_Machine_Rounds =>
2636          Check_Real_Type;
2637          Check_E0;
2638          Set_Etype (N, Standard_Boolean);
2639
2640       ------------------
2641       -- Machine_Size --
2642       ------------------
2643
2644       when Attribute_Machine_Size =>
2645          Check_E0;
2646          Check_Type;
2647          Check_Not_Incomplete_Type;
2648          Set_Etype (N, Universal_Integer);
2649
2650       --------------
2651       -- Mantissa --
2652       --------------
2653
2654       when Attribute_Mantissa =>
2655          Check_E0;
2656          Check_Real_Type;
2657          Set_Etype (N, Universal_Integer);
2658
2659       ---------
2660       -- Max --
2661       ---------
2662
2663       when Attribute_Max =>
2664          Check_E2;
2665          Check_Scalar_Type;
2666          Resolve (E1, P_Base_Type);
2667          Resolve (E2, P_Base_Type);
2668          Set_Etype (N, P_Base_Type);
2669
2670       ----------------------------
2671       -- Max_Interrupt_Priority --
2672       ----------------------------
2673
2674       when Attribute_Max_Interrupt_Priority =>
2675          Standard_Attribute
2676            (UI_To_Int
2677              (Expr_Value
2678                (Expression
2679                  (Parent (RTE (RE_Max_Interrupt_Priority))))));
2680
2681       ------------------
2682       -- Max_Priority --
2683       ------------------
2684
2685       when Attribute_Max_Priority =>
2686          Standard_Attribute
2687            (UI_To_Int
2688              (Expr_Value
2689                (Expression
2690                  (Parent (RTE (RE_Max_Priority))))));
2691
2692       ----------------------------------
2693       -- Max_Size_In_Storage_Elements --
2694       ----------------------------------
2695
2696       when Attribute_Max_Size_In_Storage_Elements =>
2697          Check_E0;
2698          Check_Type;
2699          Check_Not_Incomplete_Type;
2700          Set_Etype (N, Universal_Integer);
2701
2702       -----------------------
2703       -- Maximum_Alignment --
2704       -----------------------
2705
2706       when Attribute_Maximum_Alignment =>
2707          Standard_Attribute (Ttypes.Maximum_Alignment);
2708
2709       --------------------
2710       -- Mechanism_Code --
2711       --------------------
2712
2713       when Attribute_Mechanism_Code =>
2714
2715          if not Is_Entity_Name (P)
2716            or else not Is_Subprogram (Entity (P))
2717          then
2718             Error_Attr ("prefix of % attribute must be subprogram", P);
2719          end if;
2720
2721          Check_Either_E0_Or_E1;
2722
2723          if Present (E1) then
2724             Resolve (E1, Any_Integer);
2725             Set_Etype (E1, Standard_Integer);
2726
2727             if not Is_Static_Expression (E1) then
2728                Error_Attr
2729                  ("expression for parameter number must be static", E1);
2730
2731             elsif UI_To_Int (Intval (E1)) > Number_Formals (Entity (P))
2732               or else UI_To_Int (Intval (E1)) < 0
2733             then
2734                Error_Attr ("invalid parameter number for %attribute", E1);
2735             end if;
2736          end if;
2737
2738          Set_Etype (N, Universal_Integer);
2739
2740       ---------
2741       -- Min --
2742       ---------
2743
2744       when Attribute_Min =>
2745          Check_E2;
2746          Check_Scalar_Type;
2747          Resolve (E1, P_Base_Type);
2748          Resolve (E2, P_Base_Type);
2749          Set_Etype (N, P_Base_Type);
2750
2751       -----------
2752       -- Model --
2753       -----------
2754
2755       when Attribute_Model =>
2756          Check_Floating_Point_Type_1;
2757          Set_Etype (N, P_Base_Type);
2758          Resolve (E1, P_Base_Type);
2759
2760       ----------------
2761       -- Model_Emin --
2762       ----------------
2763
2764       when Attribute_Model_Emin =>
2765          Check_Floating_Point_Type_0;
2766          Set_Etype (N, Universal_Integer);
2767
2768       -------------------
2769       -- Model_Epsilon --
2770       -------------------
2771
2772       when Attribute_Model_Epsilon =>
2773          Check_Floating_Point_Type_0;
2774          Set_Etype (N, Universal_Real);
2775
2776       --------------------
2777       -- Model_Mantissa --
2778       --------------------
2779
2780       when Attribute_Model_Mantissa =>
2781          Check_Floating_Point_Type_0;
2782          Set_Etype (N, Universal_Integer);
2783
2784       -----------------
2785       -- Model_Small --
2786       -----------------
2787
2788       when Attribute_Model_Small =>
2789          Check_Floating_Point_Type_0;
2790          Set_Etype (N, Universal_Real);
2791
2792       -------------
2793       -- Modulus --
2794       -------------
2795
2796       when Attribute_Modulus =>
2797          Check_E0;
2798          Check_Type;
2799
2800          if not Is_Modular_Integer_Type (P_Type) then
2801             Error_Attr ("prefix of % attribute must be modular type", P);
2802          end if;
2803
2804          Set_Etype (N, Universal_Integer);
2805
2806       --------------------
2807       -- Null_Parameter --
2808       --------------------
2809
2810       when Attribute_Null_Parameter => Null_Parameter : declare
2811          Parnt  : constant Node_Id := Parent (N);
2812          GParnt : constant Node_Id := Parent (Parnt);
2813
2814          procedure Bad_Null_Parameter (Msg : String);
2815          --  Used if bad Null parameter attribute node is found. Issues
2816          --  given error message, and also sets the type to Any_Type to
2817          --  avoid blowups later on from dealing with a junk node.
2818
2819          procedure Must_Be_Imported (Proc_Ent : Entity_Id);
2820          --  Called to check that Proc_Ent is imported subprogram
2821
2822          ------------------------
2823          -- Bad_Null_Parameter --
2824          ------------------------
2825
2826          procedure Bad_Null_Parameter (Msg : String) is
2827          begin
2828             Error_Msg_N (Msg, N);
2829             Set_Etype (N, Any_Type);
2830          end Bad_Null_Parameter;
2831
2832          ----------------------
2833          -- Must_Be_Imported --
2834          ----------------------
2835
2836          procedure Must_Be_Imported (Proc_Ent : Entity_Id) is
2837             Pent : Entity_Id := Proc_Ent;
2838
2839          begin
2840             while Present (Alias (Pent)) loop
2841                Pent := Alias (Pent);
2842             end loop;
2843
2844             --  Ignore check if procedure not frozen yet (we will get
2845             --  another chance when the default parameter is reanalyzed)
2846
2847             if not Is_Frozen (Pent) then
2848                return;
2849
2850             elsif not Is_Imported (Pent) then
2851                Bad_Null_Parameter
2852                  ("Null_Parameter can only be used with imported subprogram");
2853
2854             else
2855                return;
2856             end if;
2857          end Must_Be_Imported;
2858
2859       --  Start of processing for Null_Parameter
2860
2861       begin
2862          Check_Type;
2863          Check_E0;
2864          Set_Etype (N, P_Type);
2865
2866          --  Case of attribute used as default expression
2867
2868          if Nkind (Parnt) = N_Parameter_Specification then
2869             Must_Be_Imported (Defining_Entity (GParnt));
2870
2871          --  Case of attribute used as actual for subprogram (positional)
2872
2873          elsif (Nkind (Parnt) = N_Procedure_Call_Statement
2874                  or else
2875                 Nkind (Parnt) = N_Function_Call)
2876             and then Is_Entity_Name (Name (Parnt))
2877          then
2878             Must_Be_Imported (Entity (Name (Parnt)));
2879
2880          --  Case of attribute used as actual for subprogram (named)
2881
2882          elsif Nkind (Parnt) = N_Parameter_Association
2883            and then (Nkind (GParnt) = N_Procedure_Call_Statement
2884                        or else
2885                      Nkind (GParnt) = N_Function_Call)
2886            and then Is_Entity_Name (Name (GParnt))
2887          then
2888             Must_Be_Imported (Entity (Name (GParnt)));
2889
2890          --  Not an allowed case
2891
2892          else
2893             Bad_Null_Parameter
2894               ("Null_Parameter must be actual or default parameter");
2895          end if;
2896
2897       end Null_Parameter;
2898
2899       -----------------
2900       -- Object_Size --
2901       -----------------
2902
2903       when Attribute_Object_Size =>
2904          Check_E0;
2905          Check_Type;
2906          Check_Not_Incomplete_Type;
2907          Set_Etype (N, Universal_Integer);
2908
2909       ------------
2910       -- Output --
2911       ------------
2912
2913       when Attribute_Output =>
2914          Check_E2;
2915          Check_Stream_Attribute (Name_uInput);
2916          Set_Etype (N, Standard_Void_Type);
2917          Disallow_In_No_Run_Time_Mode (N);
2918          Resolve (N, Standard_Void_Type);
2919
2920       ------------------
2921       -- Partition_ID --
2922       ------------------
2923
2924       when Attribute_Partition_ID =>
2925          Check_E0;
2926
2927          if P_Type /= Any_Type then
2928             if not Is_Library_Level_Entity (Entity (P)) then
2929                Error_Attr
2930                  ("prefix of % attribute must be library-level entity", P);
2931
2932             --  The defining entity of prefix should not be declared inside
2933             --  a Pure unit. RM E.1(8).
2934             --  The Is_Pure flag has been set during declaration.
2935
2936             elsif Is_Entity_Name (P)
2937               and then Is_Pure (Entity (P))
2938             then
2939                Error_Attr
2940                  ("prefix of % attribute must not be declared pure", P);
2941             end if;
2942          end if;
2943
2944          Set_Etype (N, Universal_Integer);
2945
2946       -------------------------
2947       -- Passed_By_Reference --
2948       -------------------------
2949
2950       when Attribute_Passed_By_Reference =>
2951          Check_E0;
2952          Check_Type;
2953          Set_Etype (N, Standard_Boolean);
2954
2955       ---------
2956       -- Pos --
2957       ---------
2958
2959       when Attribute_Pos =>
2960          Check_Discrete_Type;
2961          Check_E1;
2962          Resolve (E1, P_Base_Type);
2963          Set_Etype (N, Universal_Integer);
2964
2965       --------------
2966       -- Position --
2967       --------------
2968
2969       when Attribute_Position =>
2970          Check_Component;
2971          Set_Etype (N, Universal_Integer);
2972
2973       ----------
2974       -- Pred --
2975       ----------
2976
2977       when Attribute_Pred =>
2978          Check_Scalar_Type;
2979          Check_E1;
2980          Resolve (E1, P_Base_Type);
2981          Set_Etype (N, P_Base_Type);
2982
2983          --  Nothing to do for real type case
2984
2985          if Is_Real_Type (P_Type) then
2986             null;
2987
2988          --  If not modular type, test for overflow check required
2989
2990          else
2991             if not Is_Modular_Integer_Type (P_Type)
2992               and then not Range_Checks_Suppressed (P_Base_Type)
2993             then
2994                Enable_Range_Check (E1);
2995             end if;
2996          end if;
2997
2998       -----------
2999       -- Range --
3000       -----------
3001
3002       when Attribute_Range =>
3003          Check_Array_Or_Scalar_Type;
3004
3005          if Ada_83
3006            and then Is_Scalar_Type (P_Type)
3007            and then Comes_From_Source (N)
3008          then
3009             Error_Attr
3010               ("(Ada 83) % attribute not allowed for scalar type", P);
3011          end if;
3012
3013       ------------------
3014       -- Range_Length --
3015       ------------------
3016
3017       when Attribute_Range_Length =>
3018          Check_Discrete_Type;
3019          Set_Etype (N, Universal_Integer);
3020
3021       ----------
3022       -- Read --
3023       ----------
3024
3025       when Attribute_Read =>
3026          Check_E2;
3027          Check_Stream_Attribute (Name_uRead);
3028          Set_Etype (N, Standard_Void_Type);
3029          Resolve (N, Standard_Void_Type);
3030          Disallow_In_No_Run_Time_Mode (N);
3031          Note_Possible_Modification (E2);
3032
3033       ---------------
3034       -- Remainder --
3035       ---------------
3036
3037       when Attribute_Remainder =>
3038          Check_Floating_Point_Type_2;
3039          Set_Etype (N, P_Base_Type);
3040          Resolve (E1, P_Base_Type);
3041          Resolve (E2, P_Base_Type);
3042
3043       -----------
3044       -- Round --
3045       -----------
3046
3047       when Attribute_Round =>
3048          Check_E1;
3049          Check_Decimal_Fixed_Point_Type;
3050          Set_Etype (N, P_Base_Type);
3051
3052          --  Because the context is universal_real (3.5.10(12)) it is a legal
3053          --  context for a universal fixed expression. This is the only
3054          --  attribute whose functional description involves U_R.
3055
3056          if Etype (E1) = Universal_Fixed then
3057             declare
3058                Conv : constant Node_Id := Make_Type_Conversion (Loc,
3059                   Subtype_Mark => New_Occurrence_Of (Universal_Real, Loc),
3060                   Expression   => Relocate_Node (E1));
3061
3062             begin
3063                Rewrite (E1, Conv);
3064                Analyze (E1);
3065             end;
3066          end if;
3067
3068          Resolve (E1, Any_Real);
3069
3070       --------------
3071       -- Rounding --
3072       --------------
3073
3074       when Attribute_Rounding =>
3075          Check_Floating_Point_Type_1;
3076          Set_Etype (N, P_Base_Type);
3077          Resolve (E1, P_Base_Type);
3078
3079       ---------------
3080       -- Safe_Emax --
3081       ---------------
3082
3083       when Attribute_Safe_Emax =>
3084          Check_Floating_Point_Type_0;
3085          Set_Etype (N, Universal_Integer);
3086
3087       ----------------
3088       -- Safe_First --
3089       ----------------
3090
3091       when Attribute_Safe_First =>
3092          Check_Floating_Point_Type_0;
3093          Set_Etype (N, Universal_Real);
3094
3095       ----------------
3096       -- Safe_Large --
3097       ----------------
3098
3099       when Attribute_Safe_Large =>
3100          Check_E0;
3101          Check_Real_Type;
3102          Set_Etype (N, Universal_Real);
3103
3104       ---------------
3105       -- Safe_Last --
3106       ---------------
3107
3108       when Attribute_Safe_Last =>
3109          Check_Floating_Point_Type_0;
3110          Set_Etype (N, Universal_Real);
3111
3112       ----------------
3113       -- Safe_Small --
3114       ----------------
3115
3116       when Attribute_Safe_Small =>
3117          Check_E0;
3118          Check_Real_Type;
3119          Set_Etype (N, Universal_Real);
3120
3121       -----------
3122       -- Scale --
3123       -----------
3124
3125       when Attribute_Scale =>
3126          Check_E0;
3127          Check_Decimal_Fixed_Point_Type;
3128          Set_Etype (N, Universal_Integer);
3129
3130       -------------
3131       -- Scaling --
3132       -------------
3133
3134       when Attribute_Scaling =>
3135          Check_Floating_Point_Type_2;
3136          Set_Etype (N, P_Base_Type);
3137          Resolve (E1, P_Base_Type);
3138
3139       ------------------
3140       -- Signed_Zeros --
3141       ------------------
3142
3143       when Attribute_Signed_Zeros =>
3144          Check_Floating_Point_Type_0;
3145          Set_Etype (N, Standard_Boolean);
3146
3147       ----------
3148       -- Size --
3149       ----------
3150
3151       when Attribute_Size | Attribute_VADS_Size =>
3152          Check_E0;
3153
3154          if Is_Object_Reference (P)
3155            or else (Is_Entity_Name (P)
3156                      and then Ekind (Entity (P)) = E_Function)
3157          then
3158             Check_Object_Reference (P);
3159
3160          elsif Is_Entity_Name (P)
3161            and then Is_Type (Entity (P))
3162          then
3163             null;
3164
3165          elsif Nkind (P) = N_Type_Conversion
3166            and then not Comes_From_Source (P)
3167          then
3168             null;
3169
3170          else
3171             Error_Attr ("invalid prefix for % attribute", P);
3172          end if;
3173
3174          Check_Not_Incomplete_Type;
3175          Set_Etype (N, Universal_Integer);
3176
3177       -----------
3178       -- Small --
3179       -----------
3180
3181       when Attribute_Small =>
3182          Check_E0;
3183          Check_Real_Type;
3184          Set_Etype (N, Universal_Real);
3185
3186       ------------------
3187       -- Storage_Pool --
3188       ------------------
3189
3190       when Attribute_Storage_Pool =>
3191          if Is_Access_Type (P_Type) then
3192             Check_E0;
3193
3194             --  Set appropriate entity
3195
3196             if Present (Associated_Storage_Pool (Root_Type (P_Type))) then
3197                Set_Entity (N, Associated_Storage_Pool (Root_Type (P_Type)));
3198             else
3199                Set_Entity (N, RTE (RE_Global_Pool_Object));
3200             end if;
3201
3202             Set_Etype (N, Class_Wide_Type (RTE (RE_Root_Storage_Pool)));
3203
3204             --  Validate_Remote_Access_To_Class_Wide_Type for attribute
3205             --  Storage_Pool since this attribute is not defined for such
3206             --  types (RM E.2.3(22)).
3207
3208             Validate_Remote_Access_To_Class_Wide_Type (N);
3209
3210          else
3211             Error_Attr ("prefix of % attribute must be access type", P);
3212          end if;
3213
3214       ------------------
3215       -- Storage_Size --
3216       ------------------
3217
3218       when Attribute_Storage_Size =>
3219
3220          if Is_Task_Type (P_Type) then
3221             Check_E0;
3222             Set_Etype (N, Universal_Integer);
3223
3224          elsif Is_Access_Type (P_Type) then
3225             if Is_Entity_Name (P)
3226               and then Is_Type (Entity (P))
3227             then
3228                Check_E0;
3229                Check_Type;
3230                Set_Etype (N, Universal_Integer);
3231
3232                --   Validate_Remote_Access_To_Class_Wide_Type for attribute
3233                --   Storage_Size since this attribute is not defined for
3234                --   such types (RM E.2.3(22)).
3235
3236                Validate_Remote_Access_To_Class_Wide_Type (N);
3237
3238             --  The prefix is allowed to be an implicit dereference
3239             --  of an access value designating a task.
3240
3241             else
3242                Check_E0;
3243                Check_Task_Prefix;
3244                Set_Etype (N, Universal_Integer);
3245             end if;
3246
3247          else
3248             Error_Attr
3249               ("prefix of % attribute must be access or task type", P);
3250          end if;
3251
3252       ------------------
3253       -- Storage_Unit --
3254       ------------------
3255
3256       when Attribute_Storage_Unit =>
3257          Standard_Attribute (Ttypes.System_Storage_Unit);
3258
3259       ----------
3260       -- Succ --
3261       ----------
3262
3263       when Attribute_Succ =>
3264          Check_Scalar_Type;
3265          Check_E1;
3266          Resolve (E1, P_Base_Type);
3267          Set_Etype (N, P_Base_Type);
3268
3269          --  Nothing to do for real type case
3270
3271          if Is_Real_Type (P_Type) then
3272             null;
3273
3274          --  If not modular type, test for overflow check required.
3275
3276          else
3277             if not Is_Modular_Integer_Type (P_Type)
3278               and then not Range_Checks_Suppressed (P_Base_Type)
3279             then
3280                Enable_Range_Check (E1);
3281             end if;
3282          end if;
3283
3284       ---------
3285       -- Tag --
3286       ---------
3287
3288       when Attribute_Tag =>
3289          Check_E0;
3290          Check_Dereference;
3291
3292          if not Is_Tagged_Type (P_Type) then
3293             Error_Attr ("prefix of % attribute must be tagged", P);
3294
3295          --  Next test does not apply to generated code
3296          --  why not, and what does the illegal reference mean???
3297
3298          elsif Is_Object_Reference (P)
3299            and then not Is_Class_Wide_Type (P_Type)
3300            and then Comes_From_Source (N)
3301          then
3302             Error_Attr
3303               ("% attribute can only be applied to objects of class-wide type",
3304                P);
3305          end if;
3306
3307          Set_Etype (N, RTE (RE_Tag));
3308
3309       ----------------
3310       -- Terminated --
3311       ----------------
3312
3313       when Attribute_Terminated =>
3314          Check_E0;
3315          Set_Etype (N, Standard_Boolean);
3316          Check_Task_Prefix;
3317
3318       ----------
3319       -- Tick --
3320       ----------
3321
3322       when Attribute_Tick =>
3323          Check_Standard_Prefix;
3324          Rewrite (N,
3325            Make_Real_Literal (Loc,
3326              UR_From_Components (
3327                Num   => UI_From_Int (Ttypes.System_Tick_Nanoseconds),
3328                Den   => UI_From_Int (9),
3329                Rbase => 10)));
3330          Analyze (N);
3331
3332       ----------------
3333       -- To_Address --
3334       ----------------
3335
3336       when Attribute_To_Address =>
3337          Check_E1;
3338          Analyze (P);
3339
3340          if Nkind (P) /= N_Identifier
3341            or else Chars (P) /= Name_System
3342          then
3343             Error_Attr ("prefix of %attribute must be System", P);
3344          end if;
3345
3346          Generate_Reference (RTE (RE_Address), P);
3347          Analyze_And_Resolve (E1, Any_Integer);
3348          Set_Etype (N, RTE (RE_Address));
3349
3350       ----------------
3351       -- Truncation --
3352       ----------------
3353
3354       when Attribute_Truncation =>
3355          Check_Floating_Point_Type_1;
3356          Resolve (E1, P_Base_Type);
3357          Set_Etype (N, P_Base_Type);
3358
3359       ----------------
3360       -- Type_Class --
3361       ----------------
3362
3363       when Attribute_Type_Class =>
3364          Check_E0;
3365          Check_Type;
3366          Check_Not_Incomplete_Type;
3367          Set_Etype (N, RTE (RE_Type_Class));
3368
3369       -----------------
3370       -- UET_Address --
3371       -----------------
3372
3373       when Attribute_UET_Address =>
3374          Check_E0;
3375          Check_Unit_Name (P);
3376          Set_Etype (N, RTE (RE_Address));
3377
3378       -----------------------
3379       -- Unbiased_Rounding --
3380       -----------------------
3381
3382       when Attribute_Unbiased_Rounding =>
3383          Check_Floating_Point_Type_1;
3384          Set_Etype (N, P_Base_Type);
3385          Resolve (E1, P_Base_Type);
3386
3387       ----------------------
3388       -- Unchecked_Access --
3389       ----------------------
3390
3391       when Attribute_Unchecked_Access =>
3392          if Comes_From_Source (N) then
3393             Check_Restriction (No_Unchecked_Access, N);
3394          end if;
3395
3396          Access_Attribute;
3397
3398       ------------------------------
3399       -- Universal_Literal_String --
3400       ------------------------------
3401
3402       --  This is a GNAT specific attribute whose prefix must be a named
3403       --  number where the expression is either a single numeric literal,
3404       --  or a numeric literal immediately preceded by a minus sign. The
3405       --  result is equivalent to a string literal containing the text of
3406       --  the literal as it appeared in the source program with a possible
3407       --  leading minus sign.
3408
3409       when Attribute_Universal_Literal_String => Universal_Literal_String :
3410       begin
3411          Check_E0;
3412
3413          if not Is_Entity_Name (P)
3414            or else Ekind (Entity (P)) not in Named_Kind
3415          then
3416             Error_Attr ("prefix for % attribute must be named number", P);
3417
3418          else
3419             declare
3420                Expr     : Node_Id;
3421                Negative : Boolean;
3422                S        : Source_Ptr;
3423                Src      : Source_Buffer_Ptr;
3424
3425             begin
3426                Expr := Original_Node (Expression (Parent (Entity (P))));
3427
3428                if Nkind (Expr) = N_Op_Minus then
3429                   Negative := True;
3430                   Expr := Original_Node (Right_Opnd (Expr));
3431                else
3432                   Negative := False;
3433                end if;
3434
3435                if Nkind (Expr) /= N_Integer_Literal
3436                  and then Nkind (Expr) /= N_Real_Literal
3437                then
3438                   Error_Attr
3439                     ("named number for % attribute must be simple literal", N);
3440                end if;
3441
3442                --  Build string literal corresponding to source literal text
3443
3444                Start_String;
3445
3446                if Negative then
3447                   Store_String_Char (Get_Char_Code ('-'));
3448                end if;
3449
3450                S := Sloc (Expr);
3451                Src := Source_Text (Get_Source_File_Index (S));
3452
3453                while Src (S) /= ';' and then Src (S) /= ' ' loop
3454                   Store_String_Char (Get_Char_Code (Src (S)));
3455                   S := S + 1;
3456                end loop;
3457
3458                --  Now we rewrite the attribute with the string literal
3459
3460                Rewrite (N,
3461                  Make_String_Literal (Loc, End_String));
3462                Analyze (N);
3463             end;
3464          end if;
3465       end Universal_Literal_String;
3466
3467       -------------------------
3468       -- Unrestricted_Access --
3469       -------------------------
3470
3471       --  This is a GNAT specific attribute which is like Access except that
3472       --  all scope checks and checks for aliased views are omitted.
3473
3474       when Attribute_Unrestricted_Access =>
3475          if Comes_From_Source (N) then
3476             Check_Restriction (No_Unchecked_Access, N);
3477          end if;
3478
3479          if Is_Entity_Name (P) then
3480             Set_Address_Taken (Entity (P));
3481          end if;
3482
3483          Access_Attribute;
3484
3485       ---------
3486       -- Val --
3487       ---------
3488
3489       when Attribute_Val => Val : declare
3490       begin
3491          Check_E1;
3492          Check_Discrete_Type;
3493          Resolve (E1, Any_Integer);
3494          Set_Etype (N, P_Base_Type);
3495
3496          --  Note, we need a range check in general, but we wait for the
3497          --  Resolve call to do this, since we want to let Eval_Attribute
3498          --  have a chance to find an static illegality first!
3499       end Val;
3500
3501       -----------
3502       -- Valid --
3503       -----------
3504
3505       when Attribute_Valid =>
3506          Check_E0;
3507
3508          --  Ignore check for object if we have a 'Valid reference generated
3509          --  by the expanded code, since in some cases valid checks can occur
3510          --  on items that are names, but are not objects (e.g. attributes).
3511
3512          if Comes_From_Source (N) then
3513             Check_Object_Reference (P);
3514          end if;
3515
3516          if not Is_Scalar_Type (P_Type) then
3517             Error_Attr ("object for % attribute must be of scalar type", P);
3518          end if;
3519
3520          Set_Etype (N, Standard_Boolean);
3521
3522       -----------
3523       -- Value --
3524       -----------
3525
3526       when Attribute_Value => Value :
3527       begin
3528          Check_E1;
3529          Check_Scalar_Type;
3530
3531          if Is_Enumeration_Type (P_Type) then
3532             Check_Restriction (No_Enumeration_Maps, N);
3533          end if;
3534
3535          --  Set Etype before resolving expression because expansion
3536          --  of expression may require enclosing type.
3537
3538          Set_Etype (N, P_Type);
3539          Validate_Non_Static_Attribute_Function_Call;
3540       end Value;
3541
3542       ----------------
3543       -- Value_Size --
3544       ----------------
3545
3546       when Attribute_Value_Size =>
3547          Check_E0;
3548          Check_Type;
3549          Check_Not_Incomplete_Type;
3550          Set_Etype (N, Universal_Integer);
3551
3552       -------------
3553       -- Version --
3554       -------------
3555
3556       when Attribute_Version =>
3557          Check_E0;
3558          Check_Program_Unit;
3559          Set_Etype (N, RTE (RE_Version_String));
3560
3561       ------------------
3562       -- Wchar_T_Size --
3563       ------------------
3564
3565       when Attribute_Wchar_T_Size =>
3566          Standard_Attribute (Interfaces_Wchar_T_Size);
3567
3568       ----------------
3569       -- Wide_Image --
3570       ----------------
3571
3572       when Attribute_Wide_Image => Wide_Image :
3573       begin
3574          Check_Scalar_Type;
3575          Set_Etype (N, Standard_Wide_String);
3576          Check_E1;
3577          Resolve (E1, P_Base_Type);
3578          Validate_Non_Static_Attribute_Function_Call;
3579       end Wide_Image;
3580
3581       ----------------
3582       -- Wide_Value --
3583       ----------------
3584
3585       when Attribute_Wide_Value => Wide_Value :
3586       begin
3587          Check_E1;
3588          Check_Scalar_Type;
3589
3590          --  Set Etype before resolving expression because expansion
3591          --  of expression may require enclosing type.
3592
3593          Set_Etype (N, P_Type);
3594          Validate_Non_Static_Attribute_Function_Call;
3595       end Wide_Value;
3596
3597       ----------------
3598       -- Wide_Width --
3599       ----------------
3600
3601       when Attribute_Wide_Width =>
3602          Check_E0;
3603          Check_Scalar_Type;
3604          Set_Etype (N, Universal_Integer);
3605
3606       -----------
3607       -- Width --
3608       -----------
3609
3610       when Attribute_Width =>
3611          Check_E0;
3612          Check_Scalar_Type;
3613          Set_Etype (N, Universal_Integer);
3614
3615       ---------------
3616       -- Word_Size --
3617       ---------------
3618
3619       when Attribute_Word_Size =>
3620          Standard_Attribute (System_Word_Size);
3621
3622       -----------
3623       -- Write --
3624       -----------
3625
3626       when Attribute_Write =>
3627          Check_E2;
3628          Check_Stream_Attribute (Name_uWrite);
3629          Set_Etype (N, Standard_Void_Type);
3630          Disallow_In_No_Run_Time_Mode (N);
3631          Resolve (N, Standard_Void_Type);
3632
3633       end case;
3634
3635    --  All errors raise Bad_Attribute, so that we get out before any further
3636    --  damage occurs when an error is detected (for example, if we check for
3637    --  one attribute expression, and the check succeeds, we want to be able
3638    --  to proceed securely assuming that an expression is in fact present.
3639
3640    exception
3641       when Bad_Attribute =>
3642          Set_Etype (N, Any_Type);
3643          return;
3644
3645    end Analyze_Attribute;
3646
3647    --------------------
3648    -- Eval_Attribute --
3649    --------------------
3650
3651    procedure Eval_Attribute (N : Node_Id) is
3652       Loc   : constant Source_Ptr   := Sloc (N);
3653       Aname : constant Name_Id      := Attribute_Name (N);
3654       Id    : constant Attribute_Id := Get_Attribute_Id (Aname);
3655       P     : constant Node_Id      := Prefix (N);
3656
3657       C_Type : constant Entity_Id := Etype (N);
3658       --  The type imposed by the context.
3659
3660       E1 : Node_Id;
3661       --  First expression, or Empty if none
3662
3663       E2 : Node_Id;
3664       --  Second expression, or Empty if none
3665
3666       P_Entity : Entity_Id;
3667       --  Entity denoted by prefix
3668
3669       P_Type : Entity_Id;
3670       --  The type of the prefix
3671
3672       P_Base_Type : Entity_Id;
3673       --  The base type of the prefix type
3674
3675       P_Root_Type : Entity_Id;
3676       --  The root type of the prefix type
3677
3678       Static : Boolean;
3679       --  True if prefix type is static
3680
3681       Lo_Bound, Hi_Bound : Node_Id;
3682       --  Expressions for low and high bounds of type or array index referenced
3683       --  by First, Last, or Length attribute for array, set by Set_Bounds.
3684
3685       CE_Node : Node_Id;
3686       --  Constraint error node used if we have an attribute reference has
3687       --  an argument that raises a constraint error. In this case we replace
3688       --  the attribute with a raise constraint_error node. This is important
3689       --  processing, since otherwise gigi might see an attribute which it is
3690       --  unprepared to deal with.
3691
3692       function Aft_Value return Nat;
3693       --  Computes Aft value for current attribute prefix (used by Aft itself
3694       --  and also by Width for computing the Width of a fixed point type).
3695
3696       procedure Check_Expressions;
3697       --  In case where the attribute is not foldable, the expressions, if
3698       --  any, of the attribute, are in a non-static context. This procedure
3699       --  performs the required additional checks.
3700
3701       procedure Compile_Time_Known_Attribute (N : Node_Id; Val : Uint);
3702       --  This procedure is called when the attribute N has a non-static
3703       --  but compile time known value given by Val. It includes the
3704       --  necessary checks for out of range values.
3705
3706       procedure Float_Attribute_Universal_Integer
3707         (IEEES_Val : Int;
3708          IEEEL_Val : Int;
3709          IEEEX_Val : Int;
3710          VAXFF_Val : Int;
3711          VAXDF_Val : Int;
3712          VAXGF_Val : Int);
3713       --  This procedure evaluates a float attribute with no arguments that
3714       --  returns a universal integer result. The parameters give the values
3715       --  for the possible floating-point root types. See ttypef for details.
3716       --  The prefix type is a float type (and is thus not a generic type).
3717
3718       procedure Float_Attribute_Universal_Real
3719         (IEEES_Val : String;
3720          IEEEL_Val : String;
3721          IEEEX_Val : String;
3722          VAXFF_Val : String;
3723          VAXDF_Val : String;
3724          VAXGF_Val : String);
3725       --  This procedure evaluates a float attribute with no arguments that
3726       --  returns a universal real result. The parameters give the values
3727       --  required for the possible floating-point root types in string
3728       --  format as real literals with a possible leading minus sign.
3729       --  The prefix type is a float type (and is thus not a generic type).
3730
3731       function Fore_Value return Nat;
3732       --  Computes the Fore value for the current attribute prefix, which is
3733       --  known to be a static fixed-point type. Used by Fore and Width.
3734
3735       function Mantissa return Uint;
3736       --  Returns the Mantissa value for the prefix type
3737
3738       procedure Set_Bounds;
3739       --  Used for First, Last and Length attributes applied to an array or
3740       --  array subtype. Sets the variables Index_Lo and Index_Hi to the low
3741       --  and high bound expressions for the index referenced by the attribute
3742       --  designator (i.e. the first index if no expression is present, and
3743       --  the N'th index if the value N is present as an expression).
3744
3745       ---------------
3746       -- Aft_Value --
3747       ---------------
3748
3749       function Aft_Value return Nat is
3750          Result    : Nat;
3751          Delta_Val : Ureal;
3752
3753       begin
3754          Result := 1;
3755          Delta_Val := Delta_Value (P_Type);
3756
3757          while Delta_Val < Ureal_Tenth loop
3758             Delta_Val := Delta_Val * Ureal_10;
3759             Result := Result + 1;
3760          end loop;
3761
3762          return Result;
3763       end Aft_Value;
3764
3765       -----------------------
3766       -- Check_Expressions --
3767       -----------------------
3768
3769       procedure Check_Expressions is
3770          E : Node_Id := E1;
3771
3772       begin
3773          while Present (E) loop
3774             Check_Non_Static_Context (E);
3775             Next (E);
3776          end loop;
3777       end Check_Expressions;
3778
3779       ----------------------------------
3780       -- Compile_Time_Known_Attribute --
3781       ----------------------------------
3782
3783       procedure Compile_Time_Known_Attribute (N : Node_Id; Val : Uint) is
3784          T : constant Entity_Id := Etype (N);
3785
3786       begin
3787          Fold_Uint (N, Val);
3788          Set_Is_Static_Expression (N, False);
3789
3790          --  Check that result is in bounds of the type if it is static
3791
3792          if Is_In_Range (N, T) then
3793             null;
3794
3795          elsif Is_Out_Of_Range (N, T) then
3796             Apply_Compile_Time_Constraint_Error
3797               (N, "value not in range of}?");
3798
3799          elsif not Range_Checks_Suppressed (T) then
3800             Enable_Range_Check (N);
3801
3802          else
3803             Set_Do_Range_Check (N, False);
3804          end if;
3805       end Compile_Time_Known_Attribute;
3806
3807       ---------------------------------------
3808       -- Float_Attribute_Universal_Integer --
3809       ---------------------------------------
3810
3811       procedure Float_Attribute_Universal_Integer
3812         (IEEES_Val : Int;
3813          IEEEL_Val : Int;
3814          IEEEX_Val : Int;
3815          VAXFF_Val : Int;
3816          VAXDF_Val : Int;
3817          VAXGF_Val : Int)
3818       is
3819          Val  : Int;
3820          Digs : constant Nat := UI_To_Int (Digits_Value (P_Base_Type));
3821
3822       begin
3823          if not Vax_Float (P_Base_Type) then
3824             if Digs = IEEES_Digits then
3825                Val := IEEES_Val;
3826             elsif Digs = IEEEL_Digits then
3827                Val := IEEEL_Val;
3828             else pragma Assert (Digs = IEEEX_Digits);
3829                Val := IEEEX_Val;
3830             end if;
3831
3832          else
3833             if Digs = VAXFF_Digits then
3834                Val := VAXFF_Val;
3835             elsif Digs = VAXDF_Digits then
3836                Val := VAXDF_Val;
3837             else pragma Assert (Digs = VAXGF_Digits);
3838                Val := VAXGF_Val;
3839             end if;
3840          end if;
3841
3842          Fold_Uint (N, UI_From_Int (Val));
3843       end Float_Attribute_Universal_Integer;
3844
3845       ------------------------------------
3846       -- Float_Attribute_Universal_Real --
3847       ------------------------------------
3848
3849       procedure Float_Attribute_Universal_Real
3850         (IEEES_Val : String;
3851          IEEEL_Val : String;
3852          IEEEX_Val : String;
3853          VAXFF_Val : String;
3854          VAXDF_Val : String;
3855          VAXGF_Val : String)
3856       is
3857          Val  : Node_Id;
3858          Digs : constant Nat := UI_To_Int (Digits_Value (P_Base_Type));
3859
3860       begin
3861          if not Vax_Float (P_Base_Type) then
3862             if Digs = IEEES_Digits then
3863                Val := Real_Convert (IEEES_Val);
3864             elsif Digs = IEEEL_Digits then
3865                Val := Real_Convert (IEEEL_Val);
3866             else pragma Assert (Digs = IEEEX_Digits);
3867                Val := Real_Convert (IEEEX_Val);
3868             end if;
3869
3870          else
3871             if Digs = VAXFF_Digits then
3872                Val := Real_Convert (VAXFF_Val);
3873             elsif Digs = VAXDF_Digits then
3874                Val := Real_Convert (VAXDF_Val);
3875             else pragma Assert (Digs = VAXGF_Digits);
3876                Val := Real_Convert (VAXGF_Val);
3877             end if;
3878          end if;
3879
3880          Set_Sloc (Val, Loc);
3881          Rewrite (N, Val);
3882          Analyze_And_Resolve (N, C_Type);
3883       end Float_Attribute_Universal_Real;
3884
3885       ----------------
3886       -- Fore_Value --
3887       ----------------
3888
3889       --  Note that the Fore calculation is based on the actual values
3890       --  of the bounds, and does not take into account possible rounding.
3891
3892       function Fore_Value return Nat is
3893          Lo      : constant Uint  := Expr_Value (Type_Low_Bound (P_Type));
3894          Hi      : constant Uint  := Expr_Value (Type_High_Bound (P_Type));
3895          Small   : constant Ureal := Small_Value (P_Type);
3896          Lo_Real : constant Ureal := Lo * Small;
3897          Hi_Real : constant Ureal := Hi * Small;
3898          T       : Ureal;
3899          R       : Nat;
3900
3901       begin
3902          --  Bounds are given in terms of small units, so first compute
3903          --  proper values as reals.
3904
3905          T := UR_Max (abs Lo_Real, abs Hi_Real);
3906          R := 2;
3907
3908          --  Loop to compute proper value if more than one digit required
3909
3910          while T >= Ureal_10 loop
3911             R := R + 1;
3912             T := T / Ureal_10;
3913          end loop;
3914
3915          return R;
3916       end Fore_Value;
3917
3918       --------------
3919       -- Mantissa --
3920       --------------
3921
3922       --  Table of mantissa values accessed by function  Computed using
3923       --  the relation:
3924
3925       --    T'Mantissa = integer next above (D * log(10)/log(2)) + 1)
3926
3927       --  where D is T'Digits (RM83 3.5.7)
3928
3929       Mantissa_Value : constant array (Nat range 1 .. 40) of Nat := (
3930           1 =>   5,
3931           2 =>   8,
3932           3 =>  11,
3933           4 =>  15,
3934           5 =>  18,
3935           6 =>  21,
3936           7 =>  25,
3937           8 =>  28,
3938           9 =>  31,
3939          10 =>  35,
3940          11 =>  38,
3941          12 =>  41,
3942          13 =>  45,
3943          14 =>  48,
3944          15 =>  51,
3945          16 =>  55,
3946          17 =>  58,
3947          18 =>  61,
3948          19 =>  65,
3949          20 =>  68,
3950          21 =>  71,
3951          22 =>  75,
3952          23 =>  78,
3953          24 =>  81,
3954          25 =>  85,
3955          26 =>  88,
3956          27 =>  91,
3957          28 =>  95,
3958          29 =>  98,
3959          30 => 101,
3960          31 => 104,
3961          32 => 108,
3962          33 => 111,
3963          34 => 114,
3964          35 => 118,
3965          36 => 121,
3966          37 => 124,
3967          38 => 128,
3968          39 => 131,
3969          40 => 134);
3970
3971       function Mantissa return Uint is
3972       begin
3973          return
3974            UI_From_Int (Mantissa_Value (UI_To_Int (Digits_Value (P_Type))));
3975       end Mantissa;
3976
3977       ----------------
3978       -- Set_Bounds --
3979       ----------------
3980
3981       procedure Set_Bounds is
3982          Ndim : Nat;
3983          Indx : Node_Id;
3984          Ityp : Entity_Id;
3985
3986       begin
3987          --  For a string literal subtype, we have to construct the bounds.
3988          --  Valid Ada code never applies attributes to string literals, but
3989          --  it is convenient to allow the expander to generate attribute
3990          --  references of this type (e.g. First and Last applied to a string
3991          --  literal).
3992
3993          --  Note that the whole point of the E_String_Literal_Subtype is to
3994          --  avoid this construction of bounds, but the cases in which we
3995          --  have to materialize them are rare enough that we don't worry!
3996
3997          --  The low bound is simply the low bound of the base type. The
3998          --  high bound is computed from the length of the string and this
3999          --  low bound.
4000
4001          if Ekind (P_Type) = E_String_Literal_Subtype then
4002             Lo_Bound :=
4003               Type_Low_Bound (Etype (First_Index (Base_Type (P_Type))));
4004
4005             Hi_Bound :=
4006               Make_Integer_Literal (Sloc (P),
4007                 Intval =>
4008                   Expr_Value (Lo_Bound) + String_Literal_Length (P_Type) - 1);
4009
4010             Set_Parent (Hi_Bound, P);
4011             Analyze_And_Resolve (Hi_Bound, Etype (Lo_Bound));
4012             return;
4013
4014          --  For non-array case, just get bounds of scalar type
4015
4016          elsif Is_Scalar_Type (P_Type) then
4017             Ityp := P_Type;
4018