OSDN Git Service

920a42a0185740f5c326867fc6d5e29b5eedec66
[pf3gnuchains/gcc-fork.git] / gcc / ada / sem_aggr.adb
1 ------------------------------------------------------------------------------
2 --                                                                          --
3 --                         GNAT COMPILER COMPONENTS                         --
4 --                                                                          --
5 --                             S E M _ A G G R                              --
6 --                                                                          --
7 --                                 B o d y                                  --
8 --                                                                          --
9 --          Copyright (C) 1992-2012, Free Software Foundation, Inc.         --
10 --                                                                          --
11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
12 -- terms of the  GNU General Public License as published  by the Free Soft- --
13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
17 -- for  more details.  You should have  received  a copy of the GNU General --
18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
20 --                                                                          --
21 -- GNAT was originally developed  by the GNAT team at  New York University. --
22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
23 --                                                                          --
24 ------------------------------------------------------------------------------
25
26 with Atree;    use Atree;
27 with Checks;   use Checks;
28 with Einfo;    use Einfo;
29 with Elists;   use Elists;
30 with Errout;   use Errout;
31 with Expander; use Expander;
32 with Exp_Tss;  use Exp_Tss;
33 with Exp_Util; use Exp_Util;
34 with Freeze;   use Freeze;
35 with Itypes;   use Itypes;
36 with Lib;      use Lib;
37 with Lib.Xref; use Lib.Xref;
38 with Namet;    use Namet;
39 with Namet.Sp; use Namet.Sp;
40 with Nmake;    use Nmake;
41 with Nlists;   use Nlists;
42 with Opt;      use Opt;
43 with Restrict; use Restrict;
44 with Sem;      use Sem;
45 with Sem_Aux;  use Sem_Aux;
46 with Sem_Cat;  use Sem_Cat;
47 with Sem_Ch3;  use Sem_Ch3;
48 with Sem_Ch8;  use Sem_Ch8;
49 with Sem_Ch13; use Sem_Ch13;
50 with Sem_Eval; use Sem_Eval;
51 with Sem_Res;  use Sem_Res;
52 with Sem_Util; use Sem_Util;
53 with Sem_Type; use Sem_Type;
54 with Sem_Warn; use Sem_Warn;
55 with Sinfo;    use Sinfo;
56 with Snames;   use Snames;
57 with Stringt;  use Stringt;
58 with Stand;    use Stand;
59 with Style;    use Style;
60 with Targparm; use Targparm;
61 with Tbuild;   use Tbuild;
62 with Uintp;    use Uintp;
63
64 package body Sem_Aggr is
65
66    type Case_Bounds is record
67      Choice_Lo   : Node_Id;
68      Choice_Hi   : Node_Id;
69      Choice_Node : Node_Id;
70    end record;
71
72    type Case_Table_Type is array (Nat range <>) of Case_Bounds;
73    --  Table type used by Check_Case_Choices procedure
74
75    -----------------------
76    -- Local Subprograms --
77    -----------------------
78
79    procedure Sort_Case_Table (Case_Table : in out Case_Table_Type);
80    --  Sort the Case Table using the Lower Bound of each Choice as the key.
81    --  A simple insertion sort is used since the number of choices in a case
82    --  statement of variant part will usually be small and probably in near
83    --  sorted order.
84
85    procedure Check_Can_Never_Be_Null (Typ : Entity_Id; Expr : Node_Id);
86    --  Ada 2005 (AI-231): Check bad usage of null for a component for which
87    --  null exclusion (NOT NULL) is specified. Typ can be an E_Array_Type for
88    --  the array case (the component type of the array will be used) or an
89    --  E_Component/E_Discriminant entity in the record case, in which case the
90    --  type of the component will be used for the test. If Typ is any other
91    --  kind of entity, the call is ignored. Expr is the component node in the
92    --  aggregate which is known to have a null value. A warning message will be
93    --  issued if the component is null excluding.
94    --
95    --  It would be better to pass the proper type for Typ ???
96
97    procedure Check_Expr_OK_In_Limited_Aggregate (Expr : Node_Id);
98    --  Check that Expr is either not limited or else is one of the cases of
99    --  expressions allowed for a limited component association (namely, an
100    --  aggregate, function call, or <> notation). Report error for violations.
101
102    procedure Check_Qualified_Aggregate (Level : Nat; Expr : Node_Id);
103    --  Given aggregate Expr, check that sub-aggregates of Expr that are nested
104    --  at Level are qualified. If Level = 0, this applies to Expr directly.
105    --  Only issue errors in formal verification mode.
106
107    function Is_Top_Level_Aggregate (Expr : Node_Id) return Boolean;
108    --  Return True of Expr is an aggregate not contained directly in another
109    --  aggregate.
110
111    ------------------------------------------------------
112    -- Subprograms used for RECORD AGGREGATE Processing --
113    ------------------------------------------------------
114
115    procedure Resolve_Record_Aggregate (N : Node_Id; Typ : Entity_Id);
116    --  This procedure performs all the semantic checks required for record
117    --  aggregates. Note that for aggregates analysis and resolution go
118    --  hand in hand. Aggregate analysis has been delayed up to here and
119    --  it is done while resolving the aggregate.
120    --
121    --    N is the N_Aggregate node.
122    --    Typ is the record type for the aggregate resolution
123    --
124    --  While performing the semantic checks, this procedure builds a new
125    --  Component_Association_List where each record field appears alone in a
126    --  Component_Choice_List along with its corresponding expression. The
127    --  record fields in the Component_Association_List appear in the same order
128    --  in which they appear in the record type Typ.
129    --
130    --  Once this new Component_Association_List is built and all the semantic
131    --  checks performed, the original aggregate subtree is replaced with the
132    --  new named record aggregate just built. Note that subtree substitution is
133    --  performed with Rewrite so as to be able to retrieve the original
134    --  aggregate.
135    --
136    --  The aggregate subtree manipulation performed by Resolve_Record_Aggregate
137    --  yields the aggregate format expected by Gigi. Typically, this kind of
138    --  tree manipulations are done in the expander. However, because the
139    --  semantic checks that need to be performed on record aggregates really go
140    --  hand in hand with the record aggregate normalization, the aggregate
141    --  subtree transformation is performed during resolution rather than
142    --  expansion. Had we decided otherwise we would have had to duplicate most
143    --  of the code in the expansion procedure Expand_Record_Aggregate. Note,
144    --  however, that all the expansion concerning aggregates for tagged records
145    --  is done in Expand_Record_Aggregate.
146    --
147    --  The algorithm of Resolve_Record_Aggregate proceeds as follows:
148    --
149    --  1. Make sure that the record type against which the record aggregate
150    --     has to be resolved is not abstract. Furthermore if the type is a
151    --     null aggregate make sure the input aggregate N is also null.
152    --
153    --  2. Verify that the structure of the aggregate is that of a record
154    --     aggregate. Specifically, look for component associations and ensure
155    --     that each choice list only has identifiers or the N_Others_Choice
156    --     node. Also make sure that if present, the N_Others_Choice occurs
157    --     last and by itself.
158    --
159    --  3. If Typ contains discriminants, the values for each discriminant is
160    --     looked for. If the record type Typ has variants, we check that the
161    --     expressions corresponding to each discriminant ruling the (possibly
162    --     nested) variant parts of Typ, are static. This allows us to determine
163    --     the variant parts to which the rest of the aggregate must conform.
164    --     The names of discriminants with their values are saved in a new
165    --     association list, New_Assoc_List which is later augmented with the
166    --     names and values of the remaining components in the record type.
167    --
168    --     During this phase we also make sure that every discriminant is
169    --     assigned exactly one value. Note that when several values for a given
170    --     discriminant are found, semantic processing continues looking for
171    --     further errors. In this case it's the first discriminant value found
172    --     which we will be recorded.
173    --
174    --     IMPORTANT NOTE: For derived tagged types this procedure expects
175    --     First_Discriminant and Next_Discriminant to give the correct list
176    --     of discriminants, in the correct order.
177    --
178    --  4. After all the discriminant values have been gathered, we can set the
179    --     Etype of the record aggregate. If Typ contains no discriminants this
180    --     is straightforward: the Etype of N is just Typ, otherwise a new
181    --     implicit constrained subtype of Typ is built to be the Etype of N.
182    --
183    --  5. Gather the remaining record components according to the discriminant
184    --     values. This involves recursively traversing the record type
185    --     structure to see what variants are selected by the given discriminant
186    --     values. This processing is a little more convoluted if Typ is a
187    --     derived tagged types since we need to retrieve the record structure
188    --     of all the ancestors of Typ.
189    --
190    --  6. After gathering the record components we look for their values in the
191    --     record aggregate and emit appropriate error messages should we not
192    --     find such values or should they be duplicated.
193    --
194    --  7. We then make sure no illegal component names appear in the record
195    --     aggregate and make sure that the type of the record components
196    --     appearing in a same choice list is the same. Finally we ensure that
197    --     the others choice, if present, is used to provide the value of at
198    --     least a record component.
199    --
200    --  8. The original aggregate node is replaced with the new named aggregate
201    --     built in steps 3 through 6, as explained earlier.
202    --
203    --  Given the complexity of record aggregate resolution, the primary goal of
204    --  this routine is clarity and simplicity rather than execution and storage
205    --  efficiency. If there are only positional components in the aggregate the
206    --  running time is linear. If there are associations the running time is
207    --  still linear as long as the order of the associations is not too far off
208    --  the order of the components in the record type. If this is not the case
209    --  the running time is at worst quadratic in the size of the association
210    --  list.
211
212    procedure Check_Misspelled_Component
213      (Elements  : Elist_Id;
214       Component : Node_Id);
215    --  Give possible misspelling diagnostic if Component is likely to be a
216    --  misspelling of one of the components of the Assoc_List. This is called
217    --  by Resolve_Aggr_Expr after producing an invalid component error message.
218
219    procedure Check_Static_Discriminated_Subtype (T : Entity_Id; V : Node_Id);
220    --  An optimization: determine whether a discriminated subtype has a static
221    --  constraint, and contains array components whose length is also static,
222    --  either because they are constrained by the discriminant, or because the
223    --  original component bounds are static.
224
225    -----------------------------------------------------
226    -- Subprograms used for ARRAY AGGREGATE Processing --
227    -----------------------------------------------------
228
229    function Resolve_Array_Aggregate
230      (N              : Node_Id;
231       Index          : Node_Id;
232       Index_Constr   : Node_Id;
233       Component_Typ  : Entity_Id;
234       Others_Allowed : Boolean) return Boolean;
235    --  This procedure performs the semantic checks for an array aggregate.
236    --  True is returned if the aggregate resolution succeeds.
237    --
238    --  The procedure works by recursively checking each nested aggregate.
239    --  Specifically, after checking a sub-aggregate nested at the i-th level
240    --  we recursively check all the subaggregates at the i+1-st level (if any).
241    --  Note that for aggregates analysis and resolution go hand in hand.
242    --  Aggregate analysis has been delayed up to here and it is done while
243    --  resolving the aggregate.
244    --
245    --    N is the current N_Aggregate node to be checked.
246    --
247    --    Index is the index node corresponding to the array sub-aggregate that
248    --    we are currently checking (RM 4.3.3 (8)). Its Etype is the
249    --    corresponding index type (or subtype).
250    --
251    --    Index_Constr is the node giving the applicable index constraint if
252    --    any (RM 4.3.3 (10)). It "is a constraint provided by certain
253    --    contexts [...] that can be used to determine the bounds of the array
254    --    value specified by the aggregate". If Others_Allowed below is False
255    --    there is no applicable index constraint and this node is set to Index.
256    --
257    --    Component_Typ is the array component type.
258    --
259    --    Others_Allowed indicates whether an others choice is allowed
260    --    in the context where the top-level aggregate appeared.
261    --
262    --  The algorithm of Resolve_Array_Aggregate proceeds as follows:
263    --
264    --  1. Make sure that the others choice, if present, is by itself and
265    --     appears last in the sub-aggregate. Check that we do not have
266    --     positional and named components in the array sub-aggregate (unless
267    --     the named association is an others choice). Finally if an others
268    --     choice is present, make sure it is allowed in the aggregate context.
269    --
270    --  2. If the array sub-aggregate contains discrete_choices:
271    --
272    --     (A) Verify their validity. Specifically verify that:
273    --
274    --        (a) If a null range is present it must be the only possible
275    --            choice in the array aggregate.
276    --
277    --        (b) Ditto for a non static range.
278    --
279    --        (c) Ditto for a non static expression.
280    --
281    --        In addition this step analyzes and resolves each discrete_choice,
282    --        making sure that its type is the type of the corresponding Index.
283    --        If we are not at the lowest array aggregate level (in the case of
284    --        multi-dimensional aggregates) then invoke Resolve_Array_Aggregate
285    --        recursively on each component expression. Otherwise, resolve the
286    --        bottom level component expressions against the expected component
287    --        type ONLY IF the component corresponds to a single discrete choice
288    --        which is not an others choice (to see why read the DELAYED
289    --        COMPONENT RESOLUTION below).
290    --
291    --     (B) Determine the bounds of the sub-aggregate and lowest and
292    --         highest choice values.
293    --
294    --  3. For positional aggregates:
295    --
296    --     (A) Loop over the component expressions either recursively invoking
297    --         Resolve_Array_Aggregate on each of these for multi-dimensional
298    --         array aggregates or resolving the bottom level component
299    --         expressions against the expected component type.
300    --
301    --     (B) Determine the bounds of the positional sub-aggregates.
302    --
303    --  4. Try to determine statically whether the evaluation of the array
304    --     sub-aggregate raises Constraint_Error. If yes emit proper
305    --     warnings. The precise checks are the following:
306    --
307    --     (A) Check that the index range defined by aggregate bounds is
308    --         compatible with corresponding index subtype.
309    --         We also check against the base type. In fact it could be that
310    --         Low/High bounds of the base type are static whereas those of
311    --         the index subtype are not. Thus if we can statically catch
312    --         a problem with respect to the base type we are guaranteed
313    --         that the same problem will arise with the index subtype
314    --
315    --     (B) If we are dealing with a named aggregate containing an others
316    --         choice and at least one discrete choice then make sure the range
317    --         specified by the discrete choices does not overflow the
318    --         aggregate bounds. We also check against the index type and base
319    --         type bounds for the same reasons given in (A).
320    --
321    --     (C) If we are dealing with a positional aggregate with an others
322    --         choice make sure the number of positional elements specified
323    --         does not overflow the aggregate bounds. We also check against
324    --         the index type and base type bounds as mentioned in (A).
325    --
326    --     Finally construct an N_Range node giving the sub-aggregate bounds.
327    --     Set the Aggregate_Bounds field of the sub-aggregate to be this
328    --     N_Range. The routine Array_Aggr_Subtype below uses such N_Ranges
329    --     to build the appropriate aggregate subtype. Aggregate_Bounds
330    --     information is needed during expansion.
331    --
332    --  DELAYED COMPONENT RESOLUTION: The resolution of bottom level component
333    --  expressions in an array aggregate may call Duplicate_Subexpr or some
334    --  other routine that inserts code just outside the outermost aggregate.
335    --  If the array aggregate contains discrete choices or an others choice,
336    --  this may be wrong. Consider for instance the following example.
337    --
338    --    type Rec is record
339    --       V : Integer := 0;
340    --    end record;
341    --
342    --    type Acc_Rec is access Rec;
343    --    Arr : array (1..3) of Acc_Rec := (1 .. 3 => new Rec);
344    --
345    --  Then the transformation of "new Rec" that occurs during resolution
346    --  entails the following code modifications
347    --
348    --    P7b : constant Acc_Rec := new Rec;
349    --    RecIP (P7b.all);
350    --    Arr : array (1..3) of Acc_Rec := (1 .. 3 => P7b);
351    --
352    --  This code transformation is clearly wrong, since we need to call
353    --  "new Rec" for each of the 3 array elements. To avoid this problem we
354    --  delay resolution of the components of non positional array aggregates
355    --  to the expansion phase. As an optimization, if the discrete choice
356    --  specifies a single value we do not delay resolution.
357
358    function Array_Aggr_Subtype (N : Node_Id; Typ : Node_Id) return Entity_Id;
359    --  This routine returns the type or subtype of an array aggregate.
360    --
361    --    N is the array aggregate node whose type we return.
362    --
363    --    Typ is the context type in which N occurs.
364    --
365    --  This routine creates an implicit array subtype whose bounds are
366    --  those defined by the aggregate. When this routine is invoked
367    --  Resolve_Array_Aggregate has already processed aggregate N. Thus the
368    --  Aggregate_Bounds of each sub-aggregate, is an N_Range node giving the
369    --  sub-aggregate bounds. When building the aggregate itype, this function
370    --  traverses the array aggregate N collecting such Aggregate_Bounds and
371    --  constructs the proper array aggregate itype.
372    --
373    --  Note that in the case of multidimensional aggregates each inner
374    --  sub-aggregate corresponding to a given array dimension, may provide a
375    --  different bounds. If it is possible to determine statically that
376    --  some sub-aggregates corresponding to the same index do not have the
377    --  same bounds, then a warning is emitted. If such check is not possible
378    --  statically (because some sub-aggregate bounds are dynamic expressions)
379    --  then this job is left to the expander. In all cases the particular
380    --  bounds that this function will chose for a given dimension is the first
381    --  N_Range node for a sub-aggregate corresponding to that dimension.
382    --
383    --  Note that the Raises_Constraint_Error flag of an array aggregate
384    --  whose evaluation is determined to raise CE by Resolve_Array_Aggregate,
385    --  is set in Resolve_Array_Aggregate but the aggregate is not
386    --  immediately replaced with a raise CE. In fact, Array_Aggr_Subtype must
387    --  first construct the proper itype for the aggregate (Gigi needs
388    --  this). After constructing the proper itype we will eventually  replace
389    --  the top-level aggregate with a raise CE (done in Resolve_Aggregate).
390    --  Of course in cases such as:
391    --
392    --     type Arr is array (integer range <>) of Integer;
393    --     A : Arr := (positive range -1 .. 2 => 0);
394    --
395    --  The bounds of the aggregate itype are cooked up to look reasonable
396    --  (in this particular case the bounds will be 1 .. 2).
397
398    procedure Aggregate_Constraint_Checks
399      (Exp       : Node_Id;
400       Check_Typ : Entity_Id);
401    --  Checks expression Exp against subtype Check_Typ. If Exp is an
402    --  aggregate and Check_Typ a constrained record type with discriminants,
403    --  we generate the appropriate discriminant checks. If Exp is an array
404    --  aggregate then emit the appropriate length checks. If Exp is a scalar
405    --  type, or a string literal, Exp is changed into Check_Typ'(Exp) to
406    --  ensure that range checks are performed at run time.
407
408    procedure Make_String_Into_Aggregate (N : Node_Id);
409    --  A string literal can appear in  a context in  which a one dimensional
410    --  array of characters is expected. This procedure simply rewrites the
411    --  string as an aggregate, prior to resolution.
412
413    ---------------------------------
414    -- Aggregate_Constraint_Checks --
415    ---------------------------------
416
417    procedure Aggregate_Constraint_Checks
418      (Exp       : Node_Id;
419       Check_Typ : Entity_Id)
420    is
421       Exp_Typ : constant Entity_Id  := Etype (Exp);
422
423    begin
424       if Raises_Constraint_Error (Exp) then
425          return;
426       end if;
427
428       --  Ada 2005 (AI-230): Generate a conversion to an anonymous access
429       --  component's type to force the appropriate accessibility checks.
430
431       --  Ada 2005 (AI-231): Generate conversion to the null-excluding
432       --  type to force the corresponding run-time check
433
434       if Is_Access_Type (Check_Typ)
435         and then ((Is_Local_Anonymous_Access (Check_Typ))
436                     or else (Can_Never_Be_Null (Check_Typ)
437                                and then not Can_Never_Be_Null (Exp_Typ)))
438       then
439          Rewrite (Exp, Convert_To (Check_Typ, Relocate_Node (Exp)));
440          Analyze_And_Resolve (Exp, Check_Typ);
441          Check_Unset_Reference (Exp);
442       end if;
443
444       --  This is really expansion activity, so make sure that expansion
445       --  is on and is allowed.
446
447       if not Expander_Active or else In_Spec_Expression then
448          return;
449       end if;
450
451       --  First check if we have to insert discriminant checks
452
453       if Has_Discriminants (Exp_Typ) then
454          Apply_Discriminant_Check (Exp, Check_Typ);
455
456       --  Next emit length checks for array aggregates
457
458       elsif Is_Array_Type (Exp_Typ) then
459          Apply_Length_Check (Exp, Check_Typ);
460
461       --  Finally emit scalar and string checks. If we are dealing with a
462       --  scalar literal we need to check by hand because the Etype of
463       --  literals is not necessarily correct.
464
465       elsif Is_Scalar_Type (Exp_Typ)
466         and then Compile_Time_Known_Value (Exp)
467       then
468          if Is_Out_Of_Range (Exp, Base_Type (Check_Typ)) then
469             Apply_Compile_Time_Constraint_Error
470               (Exp, "value not in range of}?", CE_Range_Check_Failed,
471                Ent => Base_Type (Check_Typ),
472                Typ => Base_Type (Check_Typ));
473
474          elsif Is_Out_Of_Range (Exp, Check_Typ) then
475             Apply_Compile_Time_Constraint_Error
476               (Exp, "value not in range of}?", CE_Range_Check_Failed,
477                Ent => Check_Typ,
478                Typ => Check_Typ);
479
480          elsif not Range_Checks_Suppressed (Check_Typ) then
481             Apply_Scalar_Range_Check (Exp, Check_Typ);
482          end if;
483
484       --  Verify that target type is also scalar, to prevent view anomalies
485       --  in instantiations.
486
487       elsif (Is_Scalar_Type (Exp_Typ)
488               or else Nkind (Exp) = N_String_Literal)
489         and then Is_Scalar_Type (Check_Typ)
490         and then Exp_Typ /= Check_Typ
491       then
492          if Is_Entity_Name (Exp)
493            and then Ekind (Entity (Exp)) = E_Constant
494          then
495             --  If expression is a constant, it is worthwhile checking whether
496             --  it is a bound of the type.
497
498             if (Is_Entity_Name (Type_Low_Bound (Check_Typ))
499                  and then Entity (Exp) = Entity (Type_Low_Bound (Check_Typ)))
500               or else (Is_Entity_Name (Type_High_Bound (Check_Typ))
501                 and then Entity (Exp) = Entity (Type_High_Bound (Check_Typ)))
502             then
503                return;
504
505             else
506                Rewrite (Exp, Convert_To (Check_Typ, Relocate_Node (Exp)));
507                Analyze_And_Resolve (Exp, Check_Typ);
508                Check_Unset_Reference (Exp);
509             end if;
510          else
511             Rewrite (Exp, Convert_To (Check_Typ, Relocate_Node (Exp)));
512             Analyze_And_Resolve (Exp, Check_Typ);
513             Check_Unset_Reference (Exp);
514          end if;
515
516       end if;
517    end Aggregate_Constraint_Checks;
518
519    ------------------------
520    -- Array_Aggr_Subtype --
521    ------------------------
522
523    function Array_Aggr_Subtype
524      (N   : Node_Id;
525       Typ : Entity_Id) return Entity_Id
526    is
527       Aggr_Dimension : constant Pos := Number_Dimensions (Typ);
528       --  Number of aggregate index dimensions
529
530       Aggr_Range : array (1 .. Aggr_Dimension) of Node_Id := (others => Empty);
531       --  Constrained N_Range of each index dimension in our aggregate itype
532
533       Aggr_Low   : array (1 .. Aggr_Dimension) of Node_Id := (others => Empty);
534       Aggr_High  : array (1 .. Aggr_Dimension) of Node_Id := (others => Empty);
535       --  Low and High bounds for each index dimension in our aggregate itype
536
537       Is_Fully_Positional : Boolean := True;
538
539       procedure Collect_Aggr_Bounds (N : Node_Id; Dim : Pos);
540       --  N is an array (sub-)aggregate. Dim is the dimension corresponding
541       --  to (sub-)aggregate N. This procedure collects and removes the side
542       --  effects of the constrained N_Range nodes corresponding to each index
543       --  dimension of our aggregate itype. These N_Range nodes are collected
544       --  in Aggr_Range above.
545       --
546       --  Likewise collect in Aggr_Low & Aggr_High above the low and high
547       --  bounds of each index dimension. If, when collecting, two bounds
548       --  corresponding to the same dimension are static and found to differ,
549       --  then emit a warning, and mark N as raising Constraint_Error.
550
551       -------------------------
552       -- Collect_Aggr_Bounds --
553       -------------------------
554
555       procedure Collect_Aggr_Bounds (N : Node_Id; Dim : Pos) is
556          This_Range : constant Node_Id := Aggregate_Bounds (N);
557          --  The aggregate range node of this specific sub-aggregate
558
559          This_Low  : constant Node_Id := Low_Bound (Aggregate_Bounds (N));
560          This_High : constant Node_Id := High_Bound (Aggregate_Bounds (N));
561          --  The aggregate bounds of this specific sub-aggregate
562
563          Assoc : Node_Id;
564          Expr  : Node_Id;
565
566       begin
567          Remove_Side_Effects (This_Low,  Variable_Ref => True);
568          Remove_Side_Effects (This_High, Variable_Ref => True);
569
570          --  Collect the first N_Range for a given dimension that you find.
571          --  For a given dimension they must be all equal anyway.
572
573          if No (Aggr_Range (Dim)) then
574             Aggr_Low (Dim)   := This_Low;
575             Aggr_High (Dim)  := This_High;
576             Aggr_Range (Dim) := This_Range;
577
578          else
579             if Compile_Time_Known_Value (This_Low) then
580                if not Compile_Time_Known_Value (Aggr_Low (Dim)) then
581                   Aggr_Low (Dim)  := This_Low;
582
583                elsif Expr_Value (This_Low) /= Expr_Value (Aggr_Low (Dim)) then
584                   Set_Raises_Constraint_Error (N);
585                   Error_Msg_N ("sub-aggregate low bound mismatch?", N);
586                   Error_Msg_N
587                      ("\Constraint_Error will be raised at run time?", N);
588                end if;
589             end if;
590
591             if Compile_Time_Known_Value (This_High) then
592                if not Compile_Time_Known_Value (Aggr_High (Dim)) then
593                   Aggr_High (Dim)  := This_High;
594
595                elsif
596                  Expr_Value (This_High) /= Expr_Value (Aggr_High (Dim))
597                then
598                   Set_Raises_Constraint_Error (N);
599                   Error_Msg_N ("sub-aggregate high bound mismatch?", N);
600                   Error_Msg_N
601                      ("\Constraint_Error will be raised at run time?", N);
602                end if;
603             end if;
604          end if;
605
606          if Dim < Aggr_Dimension then
607
608             --  Process positional components
609
610             if Present (Expressions (N)) then
611                Expr := First (Expressions (N));
612                while Present (Expr) loop
613                   Collect_Aggr_Bounds (Expr, Dim + 1);
614                   Next (Expr);
615                end loop;
616             end if;
617
618             --  Process component associations
619
620             if Present (Component_Associations (N)) then
621                Is_Fully_Positional := False;
622
623                Assoc := First (Component_Associations (N));
624                while Present (Assoc) loop
625                   Expr := Expression (Assoc);
626                   Collect_Aggr_Bounds (Expr, Dim + 1);
627                   Next (Assoc);
628                end loop;
629             end if;
630          end if;
631       end Collect_Aggr_Bounds;
632
633       --  Array_Aggr_Subtype variables
634
635       Itype : Entity_Id;
636       --  The final itype of the overall aggregate
637
638       Index_Constraints : constant List_Id := New_List;
639       --  The list of index constraints of the aggregate itype
640
641    --  Start of processing for Array_Aggr_Subtype
642
643    begin
644       --  Make sure that the list of index constraints is properly attached to
645       --  the tree, and then collect the aggregate bounds.
646
647       Set_Parent (Index_Constraints, N);
648       Collect_Aggr_Bounds (N, 1);
649
650       --  Build the list of constrained indexes of our aggregate itype
651
652       for J in 1 .. Aggr_Dimension loop
653          Create_Index : declare
654             Index_Base : constant Entity_Id :=
655                            Base_Type (Etype (Aggr_Range (J)));
656             Index_Typ  : Entity_Id;
657
658          begin
659             --  Construct the Index subtype, and associate it with the range
660             --  construct that generates it.
661
662             Index_Typ :=
663               Create_Itype (Subtype_Kind (Ekind (Index_Base)), Aggr_Range (J));
664
665             Set_Etype (Index_Typ, Index_Base);
666
667             if Is_Character_Type (Index_Base) then
668                Set_Is_Character_Type (Index_Typ);
669             end if;
670
671             Set_Size_Info      (Index_Typ,                (Index_Base));
672             Set_RM_Size        (Index_Typ, RM_Size        (Index_Base));
673             Set_First_Rep_Item (Index_Typ, First_Rep_Item (Index_Base));
674             Set_Scalar_Range   (Index_Typ, Aggr_Range (J));
675
676             if Is_Discrete_Or_Fixed_Point_Type (Index_Typ) then
677                Set_RM_Size (Index_Typ, UI_From_Int (Minimum_Size (Index_Typ)));
678             end if;
679
680             Set_Etype (Aggr_Range (J), Index_Typ);
681
682             Append (Aggr_Range (J), To => Index_Constraints);
683          end Create_Index;
684       end loop;
685
686       --  Now build the Itype
687
688       Itype := Create_Itype (E_Array_Subtype, N);
689
690       Set_First_Rep_Item         (Itype, First_Rep_Item        (Typ));
691       Set_Convention             (Itype, Convention            (Typ));
692       Set_Depends_On_Private     (Itype, Has_Private_Component (Typ));
693       Set_Etype                  (Itype, Base_Type             (Typ));
694       Set_Has_Alignment_Clause   (Itype, Has_Alignment_Clause  (Typ));
695       Set_Is_Aliased             (Itype, Is_Aliased            (Typ));
696       Set_Depends_On_Private     (Itype, Depends_On_Private    (Typ));
697
698       Copy_Suppress_Status (Index_Check,  Typ, Itype);
699       Copy_Suppress_Status (Length_Check, Typ, Itype);
700
701       Set_First_Index    (Itype, First (Index_Constraints));
702       Set_Is_Constrained (Itype, True);
703       Set_Is_Internal    (Itype, True);
704
705       --  A simple optimization: purely positional aggregates of static
706       --  components should be passed to gigi unexpanded whenever possible, and
707       --  regardless of the staticness of the bounds themselves. Subsequent
708       --  checks in exp_aggr verify that type is not packed, etc.
709
710       Set_Size_Known_At_Compile_Time (Itype,
711          Is_Fully_Positional
712            and then Comes_From_Source (N)
713            and then Size_Known_At_Compile_Time (Component_Type (Typ)));
714
715       --  We always need a freeze node for a packed array subtype, so that we
716       --  can build the Packed_Array_Type corresponding to the subtype. If
717       --  expansion is disabled, the packed array subtype is not built, and we
718       --  must not generate a freeze node for the type, or else it will appear
719       --  incomplete to gigi.
720
721       if Is_Packed (Itype)
722         and then not In_Spec_Expression
723         and then Expander_Active
724       then
725          Freeze_Itype (Itype, N);
726       end if;
727
728       return Itype;
729    end Array_Aggr_Subtype;
730
731    --------------------------------
732    -- Check_Misspelled_Component --
733    --------------------------------
734
735    procedure Check_Misspelled_Component
736      (Elements  : Elist_Id;
737       Component : Node_Id)
738    is
739       Max_Suggestions   : constant := 2;
740
741       Nr_Of_Suggestions : Natural := 0;
742       Suggestion_1      : Entity_Id := Empty;
743       Suggestion_2      : Entity_Id := Empty;
744       Component_Elmt    : Elmt_Id;
745
746    begin
747       --  All the components of List are matched against Component and a count
748       --  is maintained of possible misspellings. When at the end of the the
749       --  analysis there are one or two (not more!) possible misspellings,
750       --  these misspellings will be suggested as possible correction.
751
752       Component_Elmt := First_Elmt (Elements);
753       while Nr_Of_Suggestions <= Max_Suggestions
754         and then Present (Component_Elmt)
755       loop
756          if Is_Bad_Spelling_Of
757               (Chars (Node (Component_Elmt)),
758                Chars (Component))
759          then
760             Nr_Of_Suggestions := Nr_Of_Suggestions + 1;
761
762             case Nr_Of_Suggestions is
763                when 1      => Suggestion_1 := Node (Component_Elmt);
764                when 2      => Suggestion_2 := Node (Component_Elmt);
765                when others => exit;
766             end case;
767          end if;
768
769          Next_Elmt (Component_Elmt);
770       end loop;
771
772       --  Report at most two suggestions
773
774       if Nr_Of_Suggestions = 1 then
775          Error_Msg_NE -- CODEFIX
776            ("\possible misspelling of&", Component, Suggestion_1);
777
778       elsif Nr_Of_Suggestions = 2 then
779          Error_Msg_Node_2 := Suggestion_2;
780          Error_Msg_NE -- CODEFIX
781            ("\possible misspelling of& or&", Component, Suggestion_1);
782       end if;
783    end Check_Misspelled_Component;
784
785    ----------------------------------------
786    -- Check_Expr_OK_In_Limited_Aggregate --
787    ----------------------------------------
788
789    procedure Check_Expr_OK_In_Limited_Aggregate (Expr : Node_Id) is
790    begin
791       if Is_Limited_Type (Etype (Expr))
792          and then Comes_From_Source (Expr)
793          and then not In_Instance_Body
794       then
795          if not OK_For_Limited_Init (Etype (Expr), Expr) then
796             Error_Msg_N ("initialization not allowed for limited types", Expr);
797             Explain_Limited_Type (Etype (Expr), Expr);
798          end if;
799       end if;
800    end Check_Expr_OK_In_Limited_Aggregate;
801
802    -------------------------------
803    -- Check_Qualified_Aggregate --
804    -------------------------------
805
806    procedure Check_Qualified_Aggregate (Level : Nat; Expr : Node_Id) is
807       Comp_Expr : Node_Id;
808       Comp_Assn : Node_Id;
809
810    begin
811       if Level = 0 then
812          if Nkind (Parent (Expr)) /= N_Qualified_Expression then
813             Check_SPARK_Restriction ("aggregate should be qualified", Expr);
814          end if;
815
816       else
817          Comp_Expr := First (Expressions (Expr));
818          while Present (Comp_Expr) loop
819             if Nkind (Comp_Expr) = N_Aggregate then
820                Check_Qualified_Aggregate (Level - 1, Comp_Expr);
821             end if;
822
823             Comp_Expr := Next (Comp_Expr);
824          end loop;
825
826          Comp_Assn := First (Component_Associations (Expr));
827          while Present (Comp_Assn) loop
828             Comp_Expr := Expression (Comp_Assn);
829
830             if Nkind (Comp_Expr) = N_Aggregate then
831                Check_Qualified_Aggregate (Level - 1, Comp_Expr);
832             end if;
833
834             Comp_Assn := Next (Comp_Assn);
835          end loop;
836       end if;
837    end Check_Qualified_Aggregate;
838
839    ----------------------------------------
840    -- Check_Static_Discriminated_Subtype --
841    ----------------------------------------
842
843    procedure Check_Static_Discriminated_Subtype (T : Entity_Id; V : Node_Id) is
844       Disc : constant Entity_Id := First_Discriminant (T);
845       Comp : Entity_Id;
846       Ind  : Entity_Id;
847
848    begin
849       if Has_Record_Rep_Clause (T) then
850          return;
851
852       elsif Present (Next_Discriminant (Disc)) then
853          return;
854
855       elsif Nkind (V) /= N_Integer_Literal then
856          return;
857       end if;
858
859       Comp := First_Component (T);
860       while Present (Comp) loop
861          if Is_Scalar_Type (Etype (Comp)) then
862             null;
863
864          elsif Is_Private_Type (Etype (Comp))
865            and then Present (Full_View (Etype (Comp)))
866            and then Is_Scalar_Type (Full_View (Etype (Comp)))
867          then
868             null;
869
870          elsif Is_Array_Type (Etype (Comp)) then
871             if Is_Bit_Packed_Array (Etype (Comp)) then
872                return;
873             end if;
874
875             Ind := First_Index (Etype (Comp));
876             while Present (Ind) loop
877                if Nkind (Ind) /= N_Range
878                  or else Nkind (Low_Bound (Ind)) /= N_Integer_Literal
879                  or else Nkind (High_Bound (Ind)) /= N_Integer_Literal
880                then
881                   return;
882                end if;
883
884                Next_Index (Ind);
885             end loop;
886
887          else
888             return;
889          end if;
890
891          Next_Component (Comp);
892       end loop;
893
894       --  On exit, all components have statically known sizes
895
896       Set_Size_Known_At_Compile_Time (T);
897    end Check_Static_Discriminated_Subtype;
898
899    -------------------------
900    -- Is_Others_Aggregate --
901    -------------------------
902
903    function Is_Others_Aggregate (Aggr : Node_Id) return Boolean is
904    begin
905       return No (Expressions (Aggr))
906         and then
907           Nkind (First (Choices (First (Component_Associations (Aggr)))))
908             = N_Others_Choice;
909    end Is_Others_Aggregate;
910
911    ----------------------------
912    -- Is_Top_Level_Aggregate --
913    ----------------------------
914
915    function Is_Top_Level_Aggregate (Expr : Node_Id) return Boolean is
916    begin
917       return Nkind (Parent (Expr)) /= N_Aggregate
918         and then (Nkind (Parent (Expr)) /= N_Component_Association
919                    or else Nkind (Parent (Parent (Expr))) /= N_Aggregate);
920    end Is_Top_Level_Aggregate;
921
922    --------------------------------
923    -- Make_String_Into_Aggregate --
924    --------------------------------
925
926    procedure Make_String_Into_Aggregate (N : Node_Id) is
927       Exprs  : constant List_Id    := New_List;
928       Loc    : constant Source_Ptr := Sloc (N);
929       Str    : constant String_Id  := Strval (N);
930       Strlen : constant Nat        := String_Length (Str);
931       C      : Char_Code;
932       C_Node : Node_Id;
933       New_N  : Node_Id;
934       P      : Source_Ptr;
935
936    begin
937       P := Loc + 1;
938       for J in  1 .. Strlen loop
939          C := Get_String_Char (Str, J);
940          Set_Character_Literal_Name (C);
941
942          C_Node :=
943            Make_Character_Literal (P,
944              Chars              => Name_Find,
945              Char_Literal_Value => UI_From_CC (C));
946          Set_Etype (C_Node, Any_Character);
947          Append_To (Exprs, C_Node);
948
949          P := P + 1;
950          --  Something special for wide strings???
951       end loop;
952
953       New_N := Make_Aggregate (Loc, Expressions => Exprs);
954       Set_Analyzed (New_N);
955       Set_Etype (New_N, Any_Composite);
956
957       Rewrite (N, New_N);
958    end Make_String_Into_Aggregate;
959
960    -----------------------
961    -- Resolve_Aggregate --
962    -----------------------
963
964    procedure Resolve_Aggregate (N : Node_Id; Typ : Entity_Id) is
965       Loc   : constant Source_Ptr := Sloc (N);
966       Pkind : constant Node_Kind  := Nkind (Parent (N));
967
968       Aggr_Subtyp : Entity_Id;
969       --  The actual aggregate subtype. This is not necessarily the same as Typ
970       --  which is the subtype of the context in which the aggregate was found.
971
972    begin
973       --  Ignore junk empty aggregate resulting from parser error
974
975       if No (Expressions (N))
976         and then No (Component_Associations (N))
977         and then not Null_Record_Present (N)
978       then
979          return;
980       end if;
981
982       --  If the aggregate has box-initialized components, its type must be
983       --  frozen so that initialization procedures can properly be called
984       --  in the resolution that follows.  The replacement of boxes with
985       --  initialization calls is properly an expansion activity but it must
986       --  be done during revolution.
987
988       if Expander_Active
989         and then  Present (Component_Associations (N))
990       then
991          declare
992             Comp : Node_Id;
993
994          begin
995             Comp := First (Component_Associations (N));
996             while Present (Comp) loop
997                if Box_Present (Comp) then
998                   Insert_Actions (N, Freeze_Entity (Typ, N));
999                   exit;
1000                end if;
1001
1002                Next (Comp);
1003             end loop;
1004          end;
1005       end if;
1006
1007       --  An unqualified aggregate is restricted in SPARK to:
1008
1009       --    An aggregate item inside an aggregate for a multi-dimensional array
1010
1011       --    An expression being assigned to an unconstrained array, but only if
1012       --    the aggregate specifies a value for OTHERS only.
1013
1014       if Nkind (Parent (N)) = N_Qualified_Expression then
1015          if Is_Array_Type (Typ) then
1016             Check_Qualified_Aggregate (Number_Dimensions (Typ), N);
1017          else
1018             Check_Qualified_Aggregate (1, N);
1019          end if;
1020       else
1021          if Is_Array_Type (Typ)
1022            and then Nkind (Parent (N)) = N_Assignment_Statement
1023            and then not Is_Constrained (Etype (Name (Parent (N))))
1024          then
1025             if not Is_Others_Aggregate (N) then
1026                Check_SPARK_Restriction
1027                  ("array aggregate should have only OTHERS", N);
1028             end if;
1029
1030          elsif Is_Top_Level_Aggregate (N) then
1031             Check_SPARK_Restriction ("aggregate should be qualified", N);
1032
1033          --  The legality of this unqualified aggregate is checked by calling
1034          --  Check_Qualified_Aggregate from one of its enclosing aggregate,
1035          --  unless one of these already causes an error to be issued.
1036
1037          else
1038             null;
1039          end if;
1040       end if;
1041
1042       --  Check for aggregates not allowed in configurable run-time mode.
1043       --  We allow all cases of aggregates that do not come from source, since
1044       --  these are all assumed to be small (e.g. bounds of a string literal).
1045       --  We also allow aggregates of types we know to be small.
1046
1047       if not Support_Aggregates_On_Target
1048         and then Comes_From_Source (N)
1049         and then (not Known_Static_Esize (Typ) or else Esize (Typ) > 64)
1050       then
1051          Error_Msg_CRT ("aggregate", N);
1052       end if;
1053
1054       --  Ada 2005 (AI-287): Limited aggregates allowed
1055
1056       --  In an instance, ignore aggregate subcomponents tnat may be limited,
1057       --  because they originate in view conflicts. If the original aggregate
1058       --  is legal and the actuals are legal, the aggregate itself is legal.
1059
1060       if Is_Limited_Type (Typ)
1061         and then Ada_Version < Ada_2005
1062         and then not In_Instance
1063       then
1064          Error_Msg_N ("aggregate type cannot be limited", N);
1065          Explain_Limited_Type (Typ, N);
1066
1067       elsif Is_Class_Wide_Type (Typ) then
1068          Error_Msg_N ("type of aggregate cannot be class-wide", N);
1069
1070       elsif Typ = Any_String
1071         or else Typ = Any_Composite
1072       then
1073          Error_Msg_N ("no unique type for aggregate", N);
1074          Set_Etype (N, Any_Composite);
1075
1076       elsif Is_Array_Type (Typ) and then Null_Record_Present (N) then
1077          Error_Msg_N ("null record forbidden in array aggregate", N);
1078
1079       elsif Is_Record_Type (Typ) then
1080          Resolve_Record_Aggregate (N, Typ);
1081
1082       elsif Is_Array_Type (Typ) then
1083
1084          --  First a special test, for the case of a positional aggregate
1085          --  of characters which can be replaced by a string literal.
1086
1087          --  Do not perform this transformation if this was a string literal to
1088          --  start with, whose components needed constraint checks, or if the
1089          --  component type is non-static, because it will require those checks
1090          --  and be transformed back into an aggregate.
1091
1092          if Number_Dimensions (Typ) = 1
1093            and then Is_Standard_Character_Type (Component_Type (Typ))
1094            and then No (Component_Associations (N))
1095            and then not Is_Limited_Composite (Typ)
1096            and then not Is_Private_Composite (Typ)
1097            and then not Is_Bit_Packed_Array (Typ)
1098            and then Nkind (Original_Node (Parent (N))) /= N_String_Literal
1099            and then Is_Static_Subtype (Component_Type (Typ))
1100          then
1101             declare
1102                Expr : Node_Id;
1103
1104             begin
1105                Expr := First (Expressions (N));
1106                while Present (Expr) loop
1107                   exit when Nkind (Expr) /= N_Character_Literal;
1108                   Next (Expr);
1109                end loop;
1110
1111                if No (Expr) then
1112                   Start_String;
1113
1114                   Expr := First (Expressions (N));
1115                   while Present (Expr) loop
1116                      Store_String_Char (UI_To_CC (Char_Literal_Value (Expr)));
1117                      Next (Expr);
1118                   end loop;
1119
1120                   Rewrite (N, Make_String_Literal (Loc, End_String));
1121
1122                   Analyze_And_Resolve (N, Typ);
1123                   return;
1124                end if;
1125             end;
1126          end if;
1127
1128          --  Here if we have a real aggregate to deal with
1129
1130          Array_Aggregate : declare
1131             Aggr_Resolved : Boolean;
1132
1133             Aggr_Typ : constant Entity_Id := Etype (Typ);
1134             --  This is the unconstrained array type, which is the type against
1135             --  which the aggregate is to be resolved. Typ itself is the array
1136             --  type of the context which may not be the same subtype as the
1137             --  subtype for the final aggregate.
1138
1139          begin
1140             --  In the following we determine whether an OTHERS choice is
1141             --  allowed inside the array aggregate. The test checks the context
1142             --  in which the array aggregate occurs. If the context does not
1143             --  permit it, or the aggregate type is unconstrained, an OTHERS
1144             --  choice is not allowed (except that it is always allowed on the
1145             --  right-hand side of an assignment statement; in this case the
1146             --  constrainedness of the type doesn't matter).
1147
1148             --  If expansion is disabled (generic context, or semantics-only
1149             --  mode) actual subtypes cannot be constructed, and the type of an
1150             --  object may be its unconstrained nominal type. However, if the
1151             --  context is an assignment, we assume that OTHERS is allowed,
1152             --  because the target of the assignment will have a constrained
1153             --  subtype when fully compiled.
1154
1155             --  Note that there is no node for Explicit_Actual_Parameter.
1156             --  To test for this context we therefore have to test for node
1157             --  N_Parameter_Association which itself appears only if there is a
1158             --  formal parameter. Consequently we also need to test for
1159             --  N_Procedure_Call_Statement or N_Function_Call.
1160
1161             Set_Etype (N, Aggr_Typ);  --  May be overridden later on
1162
1163             if Pkind = N_Assignment_Statement
1164               or else (Is_Constrained (Typ)
1165                         and then
1166                           (Pkind = N_Parameter_Association     or else
1167                            Pkind = N_Function_Call             or else
1168                            Pkind = N_Procedure_Call_Statement  or else
1169                            Pkind = N_Generic_Association       or else
1170                            Pkind = N_Formal_Object_Declaration or else
1171                            Pkind = N_Simple_Return_Statement   or else
1172                            Pkind = N_Object_Declaration        or else
1173                            Pkind = N_Component_Declaration     or else
1174                            Pkind = N_Parameter_Specification   or else
1175                            Pkind = N_Qualified_Expression      or else
1176                            Pkind = N_Aggregate                 or else
1177                            Pkind = N_Extension_Aggregate       or else
1178                            Pkind = N_Component_Association))
1179             then
1180                Aggr_Resolved :=
1181                  Resolve_Array_Aggregate
1182                    (N,
1183                     Index          => First_Index (Aggr_Typ),
1184                     Index_Constr   => First_Index (Typ),
1185                     Component_Typ  => Component_Type (Typ),
1186                     Others_Allowed => True);
1187
1188             elsif not Expander_Active
1189               and then Pkind = N_Assignment_Statement
1190             then
1191                Aggr_Resolved :=
1192                  Resolve_Array_Aggregate
1193                    (N,
1194                     Index          => First_Index (Aggr_Typ),
1195                     Index_Constr   => First_Index (Typ),
1196                     Component_Typ  => Component_Type (Typ),
1197                     Others_Allowed => True);
1198
1199             else
1200                Aggr_Resolved :=
1201                  Resolve_Array_Aggregate
1202                    (N,
1203                     Index          => First_Index (Aggr_Typ),
1204                     Index_Constr   => First_Index (Aggr_Typ),
1205                     Component_Typ  => Component_Type (Typ),
1206                     Others_Allowed => False);
1207             end if;
1208
1209             if not Aggr_Resolved then
1210
1211                --  A parenthesized expression may have been intended as an
1212                --  aggregate, leading to a type error when analyzing the
1213                --  component. This can also happen for a nested component
1214                --  (see Analyze_Aggr_Expr).
1215
1216                if Paren_Count (N) > 0 then
1217                   Error_Msg_N
1218                     ("positional aggregate cannot have one component", N);
1219                end if;
1220
1221                Aggr_Subtyp := Any_Composite;
1222
1223             else
1224                Aggr_Subtyp := Array_Aggr_Subtype (N, Typ);
1225             end if;
1226
1227             Set_Etype (N, Aggr_Subtyp);
1228          end Array_Aggregate;
1229
1230       elsif Is_Private_Type (Typ)
1231         and then Present (Full_View (Typ))
1232         and then (In_Inlined_Body or In_Instance_Body)
1233         and then Is_Composite_Type (Full_View (Typ))
1234       then
1235          Resolve (N, Full_View (Typ));
1236
1237       else
1238          Error_Msg_N ("illegal context for aggregate", N);
1239       end if;
1240
1241       --  If we can determine statically that the evaluation of the aggregate
1242       --  raises Constraint_Error, then replace the aggregate with an
1243       --  N_Raise_Constraint_Error node, but set the Etype to the right
1244       --  aggregate subtype. Gigi needs this.
1245
1246       if Raises_Constraint_Error (N) then
1247          Aggr_Subtyp := Etype (N);
1248          Rewrite (N,
1249            Make_Raise_Constraint_Error (Loc, Reason => CE_Range_Check_Failed));
1250          Set_Raises_Constraint_Error (N);
1251          Set_Etype (N, Aggr_Subtyp);
1252          Set_Analyzed (N);
1253       end if;
1254    end Resolve_Aggregate;
1255
1256    -----------------------------
1257    -- Resolve_Array_Aggregate --
1258    -----------------------------
1259
1260    function Resolve_Array_Aggregate
1261      (N              : Node_Id;
1262       Index          : Node_Id;
1263       Index_Constr   : Node_Id;
1264       Component_Typ  : Entity_Id;
1265       Others_Allowed : Boolean) return Boolean
1266    is
1267       Loc : constant Source_Ptr := Sloc (N);
1268
1269       Failure : constant Boolean := False;
1270       Success : constant Boolean := True;
1271
1272       Index_Typ      : constant Entity_Id := Etype (Index);
1273       Index_Typ_Low  : constant Node_Id   := Type_Low_Bound  (Index_Typ);
1274       Index_Typ_High : constant Node_Id   := Type_High_Bound (Index_Typ);
1275       --  The type of the index corresponding to the array sub-aggregate along
1276       --  with its low and upper bounds.
1277
1278       Index_Base      : constant Entity_Id := Base_Type (Index_Typ);
1279       Index_Base_Low  : constant Node_Id   := Type_Low_Bound (Index_Base);
1280       Index_Base_High : constant Node_Id   := Type_High_Bound (Index_Base);
1281       --  Ditto for the base type
1282
1283       function Add (Val : Uint; To : Node_Id) return Node_Id;
1284       --  Creates a new expression node where Val is added to expression To.
1285       --  Tries to constant fold whenever possible. To must be an already
1286       --  analyzed expression.
1287
1288       procedure Check_Bound (BH : Node_Id; AH : in out Node_Id);
1289       --  Checks that AH (the upper bound of an array aggregate) is less than
1290       --  or equal to BH (the upper bound of the index base type). If the check
1291       --  fails, a warning is emitted, the Raises_Constraint_Error flag of N is
1292       --  set, and AH is replaced with a duplicate of BH.
1293
1294       procedure Check_Bounds (L, H : Node_Id; AL, AH : Node_Id);
1295       --  Checks that range AL .. AH is compatible with range L .. H. Emits a
1296       --  warning if not and sets the Raises_Constraint_Error flag in N.
1297
1298       procedure Check_Length (L, H : Node_Id; Len : Uint);
1299       --  Checks that range L .. H contains at least Len elements. Emits a
1300       --  warning if not and sets the Raises_Constraint_Error flag in N.
1301
1302       function Dynamic_Or_Null_Range (L, H : Node_Id) return Boolean;
1303       --  Returns True if range L .. H is dynamic or null
1304
1305       procedure Get (Value : out Uint; From : Node_Id; OK : out Boolean);
1306       --  Given expression node From, this routine sets OK to False if it
1307       --  cannot statically evaluate From. Otherwise it stores this static
1308       --  value into Value.
1309
1310       function Resolve_Aggr_Expr
1311         (Expr        : Node_Id;
1312          Single_Elmt : Boolean) return Boolean;
1313       --  Resolves aggregate expression Expr. Returns False if resolution
1314       --  fails. If Single_Elmt is set to False, the expression Expr may be
1315       --  used to initialize several array aggregate elements (this can happen
1316       --  for discrete choices such as "L .. H => Expr" or the OTHERS choice).
1317       --  In this event we do not resolve Expr unless expansion is disabled.
1318       --  To know why, see the DELAYED COMPONENT RESOLUTION note above.
1319       --
1320       --  NOTE: In the case of "... => <>", we pass the in the
1321       --  N_Component_Association node as Expr, since there is no Expression in
1322       --  that case, and we need a Sloc for the error message.
1323
1324       ---------
1325       -- Add --
1326       ---------
1327
1328       function Add (Val : Uint; To : Node_Id) return Node_Id is
1329          Expr_Pos : Node_Id;
1330          Expr     : Node_Id;
1331          To_Pos   : Node_Id;
1332
1333       begin
1334          if Raises_Constraint_Error (To) then
1335             return To;
1336          end if;
1337
1338          --  First test if we can do constant folding
1339
1340          if Compile_Time_Known_Value (To)
1341            or else Nkind (To) = N_Integer_Literal
1342          then
1343             Expr_Pos := Make_Integer_Literal (Loc, Expr_Value (To) + Val);
1344             Set_Is_Static_Expression (Expr_Pos);
1345             Set_Etype (Expr_Pos, Etype (To));
1346             Set_Analyzed (Expr_Pos, Analyzed (To));
1347
1348             if not Is_Enumeration_Type (Index_Typ) then
1349                Expr := Expr_Pos;
1350
1351             --  If we are dealing with enumeration return
1352             --     Index_Typ'Val (Expr_Pos)
1353
1354             else
1355                Expr :=
1356                  Make_Attribute_Reference
1357                    (Loc,
1358                     Prefix         => New_Reference_To (Index_Typ, Loc),
1359                     Attribute_Name => Name_Val,
1360                     Expressions    => New_List (Expr_Pos));
1361             end if;
1362
1363             return Expr;
1364          end if;
1365
1366          --  If we are here no constant folding possible
1367
1368          if not Is_Enumeration_Type (Index_Base) then
1369             Expr :=
1370               Make_Op_Add (Loc,
1371                 Left_Opnd  => Duplicate_Subexpr (To),
1372                 Right_Opnd => Make_Integer_Literal (Loc, Val));
1373
1374          --  If we are dealing with enumeration return
1375          --    Index_Typ'Val (Index_Typ'Pos (To) + Val)
1376
1377          else
1378             To_Pos :=
1379               Make_Attribute_Reference
1380                 (Loc,
1381                  Prefix         => New_Reference_To (Index_Typ, Loc),
1382                  Attribute_Name => Name_Pos,
1383                  Expressions    => New_List (Duplicate_Subexpr (To)));
1384
1385             Expr_Pos :=
1386               Make_Op_Add (Loc,
1387                            Left_Opnd  => To_Pos,
1388                            Right_Opnd => Make_Integer_Literal (Loc, Val));
1389
1390             Expr :=
1391               Make_Attribute_Reference
1392                 (Loc,
1393                  Prefix         => New_Reference_To (Index_Typ, Loc),
1394                  Attribute_Name => Name_Val,
1395                  Expressions    => New_List (Expr_Pos));
1396
1397             --  If the index type has a non standard representation, the
1398             --  attributes 'Val and 'Pos expand into function calls and the
1399             --  resulting expression is considered non-safe for reevaluation
1400             --  by the backend. Relocate it into a constant temporary in order
1401             --  to make it safe for reevaluation.
1402
1403             if Has_Non_Standard_Rep (Etype (N)) then
1404                declare
1405                   Def_Id : Entity_Id;
1406
1407                begin
1408                   Def_Id := Make_Temporary (Loc, 'R', Expr);
1409                   Set_Etype (Def_Id, Index_Typ);
1410                   Insert_Action (N,
1411                     Make_Object_Declaration (Loc,
1412                       Defining_Identifier => Def_Id,
1413                       Object_Definition   => New_Reference_To (Index_Typ, Loc),
1414                       Constant_Present    => True,
1415                       Expression          => Relocate_Node (Expr)));
1416
1417                   Expr := New_Reference_To (Def_Id, Loc);
1418                end;
1419             end if;
1420          end if;
1421
1422          return Expr;
1423       end Add;
1424
1425       -----------------
1426       -- Check_Bound --
1427       -----------------
1428
1429       procedure Check_Bound (BH : Node_Id; AH : in out Node_Id) is
1430          Val_BH : Uint;
1431          Val_AH : Uint;
1432
1433          OK_BH : Boolean;
1434          OK_AH : Boolean;
1435
1436       begin
1437          Get (Value => Val_BH, From => BH, OK => OK_BH);
1438          Get (Value => Val_AH, From => AH, OK => OK_AH);
1439
1440          if OK_BH and then OK_AH and then Val_BH < Val_AH then
1441             Set_Raises_Constraint_Error (N);
1442             Error_Msg_N ("upper bound out of range?", AH);
1443             Error_Msg_N ("\Constraint_Error will be raised at run time?", AH);
1444
1445             --  You need to set AH to BH or else in the case of enumerations
1446             --  indexes we will not be able to resolve the aggregate bounds.
1447
1448             AH := Duplicate_Subexpr (BH);
1449          end if;
1450       end Check_Bound;
1451
1452       ------------------
1453       -- Check_Bounds --
1454       ------------------
1455
1456       procedure Check_Bounds (L, H : Node_Id; AL, AH : Node_Id) is
1457          Val_L  : Uint;
1458          Val_H  : Uint;
1459          Val_AL : Uint;
1460          Val_AH : Uint;
1461
1462          OK_L : Boolean;
1463          OK_H : Boolean;
1464
1465          OK_AL : Boolean;
1466          OK_AH  : Boolean;
1467          pragma Warnings (Off, OK_AL);
1468          pragma Warnings (Off, OK_AH);
1469
1470       begin
1471          if Raises_Constraint_Error (N)
1472            or else Dynamic_Or_Null_Range (AL, AH)
1473          then
1474             return;
1475          end if;
1476
1477          Get (Value => Val_L, From => L, OK => OK_L);
1478          Get (Value => Val_H, From => H, OK => OK_H);
1479
1480          Get (Value => Val_AL, From => AL, OK => OK_AL);
1481          Get (Value => Val_AH, From => AH, OK => OK_AH);
1482
1483          if OK_L and then Val_L > Val_AL then
1484             Set_Raises_Constraint_Error (N);
1485             Error_Msg_N ("lower bound of aggregate out of range?", N);
1486             Error_Msg_N ("\Constraint_Error will be raised at run time?", N);
1487          end if;
1488
1489          if OK_H and then Val_H < Val_AH then
1490             Set_Raises_Constraint_Error (N);
1491             Error_Msg_N ("upper bound of aggregate out of range?", N);
1492             Error_Msg_N ("\Constraint_Error will be raised at run time?", N);
1493          end if;
1494       end Check_Bounds;
1495
1496       ------------------
1497       -- Check_Length --
1498       ------------------
1499
1500       procedure Check_Length (L, H : Node_Id; Len : Uint) is
1501          Val_L  : Uint;
1502          Val_H  : Uint;
1503
1504          OK_L  : Boolean;
1505          OK_H  : Boolean;
1506
1507          Range_Len : Uint;
1508
1509       begin
1510          if Raises_Constraint_Error (N) then
1511             return;
1512          end if;
1513
1514          Get (Value => Val_L, From => L, OK => OK_L);
1515          Get (Value => Val_H, From => H, OK => OK_H);
1516
1517          if not OK_L or else not OK_H then
1518             return;
1519          end if;
1520
1521          --  If null range length is zero
1522
1523          if Val_L > Val_H then
1524             Range_Len := Uint_0;
1525          else
1526             Range_Len := Val_H - Val_L + 1;
1527          end if;
1528
1529          if Range_Len < Len then
1530             Set_Raises_Constraint_Error (N);
1531             Error_Msg_N ("too many elements?", N);
1532             Error_Msg_N ("\Constraint_Error will be raised at run time?", N);
1533          end if;
1534       end Check_Length;
1535
1536       ---------------------------
1537       -- Dynamic_Or_Null_Range --
1538       ---------------------------
1539
1540       function Dynamic_Or_Null_Range (L, H : Node_Id) return Boolean is
1541          Val_L : Uint;
1542          Val_H : Uint;
1543
1544          OK_L  : Boolean;
1545          OK_H  : Boolean;
1546
1547       begin
1548          Get (Value => Val_L, From => L, OK => OK_L);
1549          Get (Value => Val_H, From => H, OK => OK_H);
1550
1551          return not OK_L or else not OK_H
1552            or else not Is_OK_Static_Expression (L)
1553            or else not Is_OK_Static_Expression (H)
1554            or else Val_L > Val_H;
1555       end Dynamic_Or_Null_Range;
1556
1557       ---------
1558       -- Get --
1559       ---------
1560
1561       procedure Get (Value : out Uint; From : Node_Id; OK : out Boolean) is
1562       begin
1563          OK := True;
1564
1565          if Compile_Time_Known_Value (From) then
1566             Value := Expr_Value (From);
1567
1568          --  If expression From is something like Some_Type'Val (10) then
1569          --  Value = 10
1570
1571          elsif Nkind (From) = N_Attribute_Reference
1572            and then Attribute_Name (From) = Name_Val
1573            and then Compile_Time_Known_Value (First (Expressions (From)))
1574          then
1575             Value := Expr_Value (First (Expressions (From)));
1576
1577          else
1578             Value := Uint_0;
1579             OK := False;
1580          end if;
1581       end Get;
1582
1583       -----------------------
1584       -- Resolve_Aggr_Expr --
1585       -----------------------
1586
1587       function Resolve_Aggr_Expr
1588         (Expr        : Node_Id;
1589          Single_Elmt : Boolean) return Boolean
1590       is
1591          Nxt_Ind        : constant Node_Id := Next_Index (Index);
1592          Nxt_Ind_Constr : constant Node_Id := Next_Index (Index_Constr);
1593          --  Index is the current index corresponding to the expression
1594
1595          Resolution_OK : Boolean := True;
1596          --  Set to False if resolution of the expression failed
1597
1598       begin
1599          --  Defend against previous errors
1600
1601          if Nkind (Expr) = N_Error
1602            or else Error_Posted (Expr)
1603          then
1604             return True;
1605          end if;
1606
1607          --  If the array type against which we are resolving the aggregate
1608          --  has several dimensions, the expressions nested inside the
1609          --  aggregate must be further aggregates (or strings).
1610
1611          if Present (Nxt_Ind) then
1612             if Nkind (Expr) /= N_Aggregate then
1613
1614                --  A string literal can appear where a one-dimensional array
1615                --  of characters is expected. If the literal looks like an
1616                --  operator, it is still an operator symbol, which will be
1617                --  transformed into a string when analyzed.
1618
1619                if Is_Character_Type (Component_Typ)
1620                  and then No (Next_Index (Nxt_Ind))
1621                  and then Nkind_In (Expr, N_String_Literal, N_Operator_Symbol)
1622                then
1623                   --  A string literal used in a multidimensional array
1624                   --  aggregate in place of the final one-dimensional
1625                   --  aggregate must not be enclosed in parentheses.
1626
1627                   if Paren_Count (Expr) /= 0 then
1628                      Error_Msg_N ("no parenthesis allowed here", Expr);
1629                   end if;
1630
1631                   Make_String_Into_Aggregate (Expr);
1632
1633                else
1634                   Error_Msg_N ("nested array aggregate expected", Expr);
1635
1636                   --  If the expression is parenthesized, this may be
1637                   --  a missing component association for a 1-aggregate.
1638
1639                   if Paren_Count (Expr) > 0 then
1640                      Error_Msg_N
1641                        ("\if single-component aggregate is intended,"
1642                         & " write e.g. (1 ='> ...)", Expr);
1643                   end if;
1644
1645                   return Failure;
1646                end if;
1647             end if;
1648
1649             --  If it's "... => <>", nothing to resolve
1650
1651             if Nkind (Expr) = N_Component_Association then
1652                pragma Assert (Box_Present (Expr));
1653                return Success;
1654             end if;
1655
1656             --  Ada 2005 (AI-231): Propagate the type to the nested aggregate.
1657             --  Required to check the null-exclusion attribute (if present).
1658             --  This value may be overridden later on.
1659
1660             Set_Etype (Expr, Etype (N));
1661
1662             Resolution_OK := Resolve_Array_Aggregate
1663               (Expr, Nxt_Ind, Nxt_Ind_Constr, Component_Typ, Others_Allowed);
1664
1665          else
1666
1667             --  If it's "... => <>", nothing to resolve
1668
1669             if Nkind (Expr) = N_Component_Association then
1670                pragma Assert (Box_Present (Expr));
1671                return Success;
1672             end if;
1673
1674             --  Do not resolve the expressions of discrete or others choices
1675             --  unless the expression covers a single component, or the
1676             --  expander is inactive.
1677
1678             --  In Alfa mode, expressions that can perform side-effects will be
1679             --  recognized by the gnat2why back-end, and the whole subprogram
1680             --  will be ignored. So semantic analysis can be performed safely.
1681
1682             if Single_Elmt
1683               or else not Full_Expander_Active
1684               or else In_Spec_Expression
1685             then
1686                Analyze_And_Resolve (Expr, Component_Typ);
1687                Check_Expr_OK_In_Limited_Aggregate (Expr);
1688                Check_Non_Static_Context (Expr);
1689                Aggregate_Constraint_Checks (Expr, Component_Typ);
1690                Check_Unset_Reference (Expr);
1691             end if;
1692          end if;
1693
1694          --  If an aggregate component has a type with predicates, an explicit
1695          --  predicate check must be applied, as for an assignment statement,
1696          --  because the aggegate might not be expanded into individual
1697          --  component assignments.
1698
1699          if Present (Predicate_Function (Component_Typ)) then
1700             Apply_Predicate_Check (Expr, Component_Typ);
1701          end if;
1702
1703          if Raises_Constraint_Error (Expr)
1704            and then Nkind (Parent (Expr)) /= N_Component_Association
1705          then
1706             Set_Raises_Constraint_Error (N);
1707          end if;
1708
1709          --  If the expression has been marked as requiring a range check,
1710          --  then generate it here.
1711
1712          if Do_Range_Check (Expr) then
1713             Set_Do_Range_Check (Expr, False);
1714             Generate_Range_Check (Expr, Component_Typ, CE_Range_Check_Failed);
1715          end if;
1716
1717          return Resolution_OK;
1718       end Resolve_Aggr_Expr;
1719
1720       --  Variables local to Resolve_Array_Aggregate
1721
1722       Assoc   : Node_Id;
1723       Choice  : Node_Id;
1724       Expr    : Node_Id;
1725
1726       Discard : Node_Id;
1727       pragma Warnings (Off, Discard);
1728
1729       Aggr_Low  : Node_Id := Empty;
1730       Aggr_High : Node_Id := Empty;
1731       --  The actual low and high bounds of this sub-aggregate
1732
1733       Choices_Low  : Node_Id := Empty;
1734       Choices_High : Node_Id := Empty;
1735       --  The lowest and highest discrete choices values for a named aggregate
1736
1737       Nb_Elements : Uint := Uint_0;
1738       --  The number of elements in a positional aggregate
1739
1740       Others_Present : Boolean := False;
1741
1742       Nb_Choices : Nat := 0;
1743       --  Contains the overall number of named choices in this sub-aggregate
1744
1745       Nb_Discrete_Choices : Nat := 0;
1746       --  The overall number of discrete choices (not counting others choice)
1747
1748       Case_Table_Size : Nat;
1749       --  Contains the size of the case table needed to sort aggregate choices
1750
1751    --  Start of processing for Resolve_Array_Aggregate
1752
1753    begin
1754       --  Ignore junk empty aggregate resulting from parser error
1755
1756       if No (Expressions (N))
1757         and then No (Component_Associations (N))
1758         and then not Null_Record_Present (N)
1759       then
1760          return False;
1761       end if;
1762
1763       --  STEP 1: make sure the aggregate is correctly formatted
1764
1765       if Present (Component_Associations (N)) then
1766          Assoc := First (Component_Associations (N));
1767          while Present (Assoc) loop
1768             Choice := First (Choices (Assoc));
1769             while Present (Choice) loop
1770                if Nkind (Choice) = N_Others_Choice then
1771                   Others_Present := True;
1772
1773                   if Choice /= First (Choices (Assoc))
1774                     or else Present (Next (Choice))
1775                   then
1776                      Error_Msg_N
1777                        ("OTHERS must appear alone in a choice list", Choice);
1778                      return Failure;
1779                   end if;
1780
1781                   if Present (Next (Assoc)) then
1782                      Error_Msg_N
1783                        ("OTHERS must appear last in an aggregate", Choice);
1784                      return Failure;
1785                   end if;
1786
1787                   if Ada_Version = Ada_83
1788                     and then Assoc /= First (Component_Associations (N))
1789                     and then Nkind_In (Parent (N), N_Assignment_Statement,
1790                                                    N_Object_Declaration)
1791                   then
1792                      Error_Msg_N
1793                        ("(Ada 83) illegal context for OTHERS choice", N);
1794                   end if;
1795                end if;
1796
1797                Nb_Choices := Nb_Choices + 1;
1798                Next (Choice);
1799             end loop;
1800
1801             Next (Assoc);
1802          end loop;
1803       end if;
1804
1805       --  At this point we know that the others choice, if present, is by
1806       --  itself and appears last in the aggregate. Check if we have mixed
1807       --  positional and discrete associations (other than the others choice).
1808
1809       if Present (Expressions (N))
1810         and then (Nb_Choices > 1
1811                    or else (Nb_Choices = 1 and then not Others_Present))
1812       then
1813          Error_Msg_N
1814            ("named association cannot follow positional association",
1815             First (Choices (First (Component_Associations (N)))));
1816          return Failure;
1817       end if;
1818
1819       --  Test for the validity of an others choice if present
1820
1821       if Others_Present and then not Others_Allowed then
1822          Error_Msg_N
1823            ("OTHERS choice not allowed here",
1824             First (Choices (First (Component_Associations (N)))));
1825          return Failure;
1826       end if;
1827
1828       if Others_Present
1829         and then Nkind (Parent (N)) /= N_Component_Association
1830         and then No (Expressions (N))
1831         and then
1832           Nkind (First (Choices (First (Component_Associations (N)))))
1833             = N_Others_Choice
1834         and then Is_Elementary_Type (Component_Typ)
1835         and then False
1836       then
1837          declare
1838             Assoc : constant Node_Id := First (Component_Associations (N));
1839          begin
1840             Rewrite (Assoc,
1841               Make_Component_Association (Loc,
1842                  Choices =>
1843                    New_List (
1844                      Make_Attribute_Reference (Loc,
1845                        Prefix => New_Occurrence_Of (Index_Typ, Loc),
1846                        Attribute_Name => Name_Range)),
1847                  Expression => Relocate_Node (Expression (Assoc))));
1848             return Resolve_Array_Aggregate
1849               (N, Index, Index_Constr, Component_Typ, Others_Allowed);
1850          end;
1851       end if;
1852
1853       --  Protect against cascaded errors
1854
1855       if Etype (Index_Typ) = Any_Type then
1856          return Failure;
1857       end if;
1858
1859       --  STEP 2: Process named components
1860
1861       if No (Expressions (N)) then
1862          if Others_Present then
1863             Case_Table_Size := Nb_Choices - 1;
1864          else
1865             Case_Table_Size := Nb_Choices;
1866          end if;
1867
1868          Step_2 : declare
1869             Low  : Node_Id;
1870             High : Node_Id;
1871             --  Denote the lowest and highest values in an aggregate choice
1872
1873             Hi_Val : Uint;
1874             Lo_Val : Uint;
1875             --  High end of one range and Low end of the next. Should be
1876             --  contiguous if there is no hole in the list of values.
1877
1878             Missing_Values : Boolean;
1879             --  Set True if missing index values
1880
1881             S_Low  : Node_Id := Empty;
1882             S_High : Node_Id := Empty;
1883             --  if a choice in an aggregate is a subtype indication these
1884             --  denote the lowest and highest values of the subtype
1885
1886             Table : Case_Table_Type (1 .. Case_Table_Size);
1887             --  Used to sort all the different choice values
1888
1889             Single_Choice : Boolean;
1890             --  Set to true every time there is a single discrete choice in a
1891             --  discrete association
1892
1893             Prev_Nb_Discrete_Choices : Nat;
1894             --  Used to keep track of the number of discrete choices in the
1895             --  current association.
1896
1897             Errors_Posted_On_Choices : Boolean := False;
1898             --  Keeps track of whether any choices have semantic errors
1899
1900          begin
1901             --  STEP 2 (A): Check discrete choices validity
1902
1903             Assoc := First (Component_Associations (N));
1904             while Present (Assoc) loop
1905                Prev_Nb_Discrete_Choices := Nb_Discrete_Choices;
1906                Choice := First (Choices (Assoc));
1907                loop
1908                   Analyze (Choice);
1909
1910                   if Nkind (Choice) = N_Others_Choice then
1911                      Single_Choice := False;
1912                      exit;
1913
1914                   --  Test for subtype mark without constraint
1915
1916                   elsif Is_Entity_Name (Choice) and then
1917                     Is_Type (Entity (Choice))
1918                   then
1919                      if Base_Type (Entity (Choice)) /= Index_Base then
1920                         Error_Msg_N
1921                           ("invalid subtype mark in aggregate choice",
1922                            Choice);
1923                         return Failure;
1924                      end if;
1925
1926                   --  Case of subtype indication
1927
1928                   elsif Nkind (Choice) = N_Subtype_Indication then
1929                      Resolve_Discrete_Subtype_Indication (Choice, Index_Base);
1930
1931                      --  Does the subtype indication evaluation raise CE ?
1932
1933                      Get_Index_Bounds (Subtype_Mark (Choice), S_Low, S_High);
1934                      Get_Index_Bounds (Choice, Low, High);
1935                      Check_Bounds (S_Low, S_High, Low, High);
1936
1937                   --  Case of range or expression
1938
1939                   else
1940                      Resolve (Choice, Index_Base);
1941                      Check_Unset_Reference (Choice);
1942                      Check_Non_Static_Context (Choice);
1943
1944                      --  If semantic errors were posted on the choice, then
1945                      --  record that for possible early return from later
1946                      --  processing (see handling of enumeration choices).
1947
1948                      if Error_Posted (Choice) then
1949                         Errors_Posted_On_Choices := True;
1950                      end if;
1951
1952                      --  Do not range check a choice. This check is redundant
1953                      --  since this test is already done when we check that the
1954                      --  bounds of the array aggregate are within range.
1955
1956                      Set_Do_Range_Check (Choice, False);
1957
1958                      --  In SPARK, the choice must be static
1959
1960                      if not (Is_Static_Expression (Choice)
1961                               or else (Nkind (Choice) = N_Range
1962                                         and then Is_Static_Range (Choice)))
1963                      then
1964                         Check_SPARK_Restriction
1965                           ("choice should be static", Choice);
1966                      end if;
1967                   end if;
1968
1969                   --  If we could not resolve the discrete choice stop here
1970
1971                   if Etype (Choice) = Any_Type then
1972                      return Failure;
1973
1974                   --  If the discrete choice raises CE get its original bounds
1975
1976                   elsif Nkind (Choice) = N_Raise_Constraint_Error then
1977                      Set_Raises_Constraint_Error (N);
1978                      Get_Index_Bounds (Original_Node (Choice), Low, High);
1979
1980                   --  Otherwise get its bounds as usual
1981
1982                   else
1983                      Get_Index_Bounds (Choice, Low, High);
1984                   end if;
1985
1986                   if (Dynamic_Or_Null_Range (Low, High)
1987                        or else (Nkind (Choice) = N_Subtype_Indication
1988                                  and then
1989                                    Dynamic_Or_Null_Range (S_Low, S_High)))
1990                     and then Nb_Choices /= 1
1991                   then
1992                      Error_Msg_N
1993                        ("dynamic or empty choice in aggregate " &
1994                         "must be the only choice", Choice);
1995                      return Failure;
1996                   end if;
1997
1998                   Nb_Discrete_Choices := Nb_Discrete_Choices + 1;
1999                   Table (Nb_Discrete_Choices).Choice_Lo := Low;
2000                   Table (Nb_Discrete_Choices).Choice_Hi := High;
2001
2002                   Next (Choice);
2003
2004                   if No (Choice) then
2005
2006                      --  Check if we have a single discrete choice and whether
2007                      --  this discrete choice specifies a single value.
2008
2009                      Single_Choice :=
2010                        (Nb_Discrete_Choices = Prev_Nb_Discrete_Choices + 1)
2011                          and then (Low = High);
2012
2013                      exit;
2014                   end if;
2015                end loop;
2016
2017                --  Ada 2005 (AI-231)
2018
2019                if Ada_Version >= Ada_2005
2020                  and then Known_Null (Expression (Assoc))
2021                then
2022                   Check_Can_Never_Be_Null (Etype (N), Expression (Assoc));
2023                end if;
2024
2025                --  Ada 2005 (AI-287): In case of default initialized component
2026                --  we delay the resolution to the expansion phase.
2027
2028                if Box_Present (Assoc) then
2029
2030                   --  Ada 2005 (AI-287): In case of default initialization of a
2031                   --  component the expander will generate calls to the
2032                   --  corresponding initialization subprogram. We need to call
2033                   --  Resolve_Aggr_Expr to check the rules about
2034                   --  dimensionality.
2035
2036                   if not Resolve_Aggr_Expr (Assoc,
2037                                             Single_Elmt => Single_Choice)
2038                   then
2039                      return Failure;
2040                   end if;
2041
2042                elsif not Resolve_Aggr_Expr (Expression (Assoc),
2043                                             Single_Elmt => Single_Choice)
2044                then
2045                   return Failure;
2046
2047                --  Check incorrect use of dynamically tagged expression
2048
2049                --  We differentiate here two cases because the expression may
2050                --  not be decorated. For example, the analysis and resolution
2051                --  of the expression associated with the others choice will be
2052                --  done later with the full aggregate. In such case we
2053                --  duplicate the expression tree to analyze the copy and
2054                --  perform the required check.
2055
2056                elsif not Present (Etype (Expression (Assoc))) then
2057                   declare
2058                      Save_Analysis : constant Boolean := Full_Analysis;
2059                      Expr          : constant Node_Id :=
2060                                        New_Copy_Tree (Expression (Assoc));
2061
2062                   begin
2063                      Expander_Mode_Save_And_Set (False);
2064                      Full_Analysis := False;
2065
2066                      --  Analyze the expression, making sure it is properly
2067                      --  attached to the tree before we do the analysis.
2068
2069                      Set_Parent (Expr, Parent (Expression (Assoc)));
2070                      Analyze (Expr);
2071
2072                      --  If the expression is a literal, propagate this info
2073                      --  to the expression in the association, to enable some
2074                      --  optimizations downstream.
2075
2076                      if Is_Entity_Name (Expr)
2077                        and then Present (Entity (Expr))
2078                        and then Ekind (Entity (Expr)) = E_Enumeration_Literal
2079                      then
2080                         Analyze_And_Resolve
2081                           (Expression (Assoc), Component_Typ);
2082                      end if;
2083
2084                      Full_Analysis := Save_Analysis;
2085                      Expander_Mode_Restore;
2086
2087                      if Is_Tagged_Type (Etype (Expr)) then
2088                         Check_Dynamically_Tagged_Expression
2089                           (Expr => Expr,
2090                            Typ  => Component_Type (Etype (N)),
2091                            Related_Nod => N);
2092                      end if;
2093                   end;
2094
2095                elsif Is_Tagged_Type (Etype (Expression (Assoc))) then
2096                   Check_Dynamically_Tagged_Expression
2097                     (Expr        => Expression (Assoc),
2098                      Typ         => Component_Type (Etype (N)),
2099                      Related_Nod => N);
2100                end if;
2101
2102                Next (Assoc);
2103             end loop;
2104
2105             --  If aggregate contains more than one choice then these must be
2106             --  static. Sort them and check that they are contiguous.
2107
2108             if Nb_Discrete_Choices > 1 then
2109                Sort_Case_Table (Table);
2110                Missing_Values := False;
2111
2112                Outer : for J in 1 .. Nb_Discrete_Choices - 1 loop
2113                   if Expr_Value (Table (J).Choice_Hi) >=
2114                        Expr_Value (Table (J + 1).Choice_Lo)
2115                   then
2116                      Error_Msg_N
2117                        ("duplicate choice values in array aggregate",
2118                         Table (J).Choice_Hi);
2119                      return Failure;
2120
2121                   elsif not Others_Present then
2122                      Hi_Val := Expr_Value (Table (J).Choice_Hi);
2123                      Lo_Val := Expr_Value (Table (J + 1).Choice_Lo);
2124
2125                      --  If missing values, output error messages
2126
2127                      if Lo_Val - Hi_Val > 1 then
2128
2129                         --  Header message if not first missing value
2130
2131                         if not Missing_Values then
2132                            Error_Msg_N
2133                              ("missing index value(s) in array aggregate", N);
2134                            Missing_Values := True;
2135                         end if;
2136
2137                         --  Output values of missing indexes
2138
2139                         Lo_Val := Lo_Val - 1;
2140                         Hi_Val := Hi_Val + 1;
2141
2142                         --  Enumeration type case
2143
2144                         if Is_Enumeration_Type (Index_Typ) then
2145                            Error_Msg_Name_1 :=
2146                              Chars
2147                                (Get_Enum_Lit_From_Pos
2148                                  (Index_Typ, Hi_Val, Loc));
2149
2150                            if Lo_Val = Hi_Val then
2151                               Error_Msg_N ("\  %", N);
2152                            else
2153                               Error_Msg_Name_2 :=
2154                                 Chars
2155                                   (Get_Enum_Lit_From_Pos
2156                                     (Index_Typ, Lo_Val, Loc));
2157                               Error_Msg_N ("\  % .. %", N);
2158                            end if;
2159
2160                         --  Integer types case
2161
2162                         else
2163                            Error_Msg_Uint_1 := Hi_Val;
2164
2165                            if Lo_Val = Hi_Val then
2166                               Error_Msg_N ("\  ^", N);
2167                            else
2168                               Error_Msg_Uint_2 := Lo_Val;
2169                               Error_Msg_N ("\  ^ .. ^", N);
2170                            end if;
2171                         end if;
2172                      end if;
2173                   end if;
2174                end loop Outer;
2175
2176                if Missing_Values then
2177                   Set_Etype (N, Any_Composite);
2178                   return Failure;
2179                end if;
2180             end if;
2181
2182             --  STEP 2 (B): Compute aggregate bounds and min/max choices values
2183
2184             if Nb_Discrete_Choices > 0 then
2185                Choices_Low  := Table (1).Choice_Lo;
2186                Choices_High := Table (Nb_Discrete_Choices).Choice_Hi;
2187             end if;
2188
2189             --  If Others is present, then bounds of aggregate come from the
2190             --  index constraint (not the choices in the aggregate itself).
2191
2192             if Others_Present then
2193                Get_Index_Bounds (Index_Constr, Aggr_Low, Aggr_High);
2194
2195             --  No others clause present
2196
2197             else
2198                --  Special processing if others allowed and not present. This
2199                --  means that the bounds of the aggregate come from the index
2200                --  constraint (and the length must match).
2201
2202                if Others_Allowed then
2203                   Get_Index_Bounds (Index_Constr, Aggr_Low, Aggr_High);
2204
2205                   --  If others allowed, and no others present, then the array
2206                   --  should cover all index values. If it does not, we will
2207                   --  get a length check warning, but there is two cases where
2208                   --  an additional warning is useful:
2209
2210                   --  If we have no positional components, and the length is
2211                   --  wrong (which we can tell by others being allowed with
2212                   --  missing components), and the index type is an enumeration
2213                   --  type, then issue appropriate warnings about these missing
2214                   --  components. They are only warnings, since the aggregate
2215                   --  is fine, it's just the wrong length. We skip this check
2216                   --  for standard character types (since there are no literals
2217                   --  and it is too much trouble to concoct them), and also if
2218                   --  any of the bounds have not-known-at-compile-time values.
2219
2220                   --  Another case warranting a warning is when the length is
2221                   --  right, but as above we have an index type that is an
2222                   --  enumeration, and the bounds do not match. This is a
2223                   --  case where dubious sliding is allowed and we generate
2224                   --  a warning that the bounds do not match.
2225
2226                   if No (Expressions (N))
2227                     and then Nkind (Index) = N_Range
2228                     and then Is_Enumeration_Type (Etype (Index))
2229                     and then not Is_Standard_Character_Type (Etype (Index))
2230                     and then Compile_Time_Known_Value (Aggr_Low)
2231                     and then Compile_Time_Known_Value (Aggr_High)
2232                     and then Compile_Time_Known_Value (Choices_Low)
2233                     and then Compile_Time_Known_Value (Choices_High)
2234                   then
2235                      --  If any of the expressions or range bounds in choices
2236                      --  have semantic errors, then do not attempt further
2237                      --  resolution, to prevent cascaded errors.
2238
2239                      if Errors_Posted_On_Choices then
2240                         return Failure;
2241                      end if;
2242
2243                      declare
2244                         ALo : constant Node_Id := Expr_Value_E (Aggr_Low);
2245                         AHi : constant Node_Id := Expr_Value_E (Aggr_High);
2246                         CLo : constant Node_Id := Expr_Value_E (Choices_Low);
2247                         CHi : constant Node_Id := Expr_Value_E (Choices_High);
2248
2249                         Ent : Entity_Id;
2250
2251                      begin
2252                         --  Warning case 1, missing values at start/end. Only
2253                         --  do the check if the number of entries is too small.
2254
2255                         if (Enumeration_Pos (CHi) - Enumeration_Pos (CLo))
2256                               <
2257                            (Enumeration_Pos (AHi) - Enumeration_Pos (ALo))
2258                         then
2259                            Error_Msg_N
2260                              ("missing index value(s) in array aggregate?", N);
2261
2262                            --  Output missing value(s) at start
2263
2264                            if Chars (ALo) /= Chars (CLo) then
2265                               Ent := Prev (CLo);
2266
2267                               if Chars (ALo) = Chars (Ent) then
2268                                  Error_Msg_Name_1 := Chars (ALo);
2269                                  Error_Msg_N ("\  %?", N);
2270                               else
2271                                  Error_Msg_Name_1 := Chars (ALo);
2272                                  Error_Msg_Name_2 := Chars (Ent);
2273                                  Error_Msg_N ("\  % .. %?", N);
2274                               end if;
2275                            end if;
2276
2277                            --  Output missing value(s) at end
2278
2279                            if Chars (AHi) /= Chars (CHi) then
2280                               Ent := Next (CHi);
2281
2282                               if Chars (AHi) = Chars (Ent) then
2283                                  Error_Msg_Name_1 := Chars (Ent);
2284                                  Error_Msg_N ("\  %?", N);
2285                               else
2286                                  Error_Msg_Name_1 := Chars (Ent);
2287                                  Error_Msg_Name_2 := Chars (AHi);
2288                                  Error_Msg_N ("\  % .. %?", N);
2289                               end if;
2290                            end if;
2291
2292                         --  Warning case 2, dubious sliding. The First_Subtype
2293                         --  test distinguishes between a constrained type where
2294                         --  sliding is not allowed (so we will get a warning
2295                         --  later that Constraint_Error will be raised), and
2296                         --  the unconstrained case where sliding is permitted.
2297
2298                         elsif (Enumeration_Pos (CHi) - Enumeration_Pos (CLo))
2299                                  =
2300                               (Enumeration_Pos (AHi) - Enumeration_Pos (ALo))
2301                           and then Chars (ALo) /= Chars (CLo)
2302                           and then
2303                             not Is_Constrained (First_Subtype (Etype (N)))
2304                         then
2305                            Error_Msg_N
2306                              ("bounds of aggregate do not match target?", N);
2307                         end if;
2308                      end;
2309                   end if;
2310                end if;
2311
2312                --  If no others, aggregate bounds come from aggregate
2313
2314                Aggr_Low  := Choices_Low;
2315                Aggr_High := Choices_High;
2316             end if;
2317          end Step_2;
2318
2319       --  STEP 3: Process positional components
2320
2321       else
2322          --  STEP 3 (A): Process positional elements
2323
2324          Expr := First (Expressions (N));
2325          Nb_Elements := Uint_0;
2326          while Present (Expr) loop
2327             Nb_Elements := Nb_Elements + 1;
2328
2329             --  Ada 2005 (AI-231)
2330
2331             if Ada_Version >= Ada_2005
2332               and then Known_Null (Expr)
2333             then
2334                Check_Can_Never_Be_Null (Etype (N), Expr);
2335             end if;
2336
2337             if not Resolve_Aggr_Expr (Expr, Single_Elmt => True) then
2338                return Failure;
2339             end if;
2340
2341             --  Check incorrect use of dynamically tagged expression
2342
2343             if Is_Tagged_Type (Etype (Expr)) then
2344                Check_Dynamically_Tagged_Expression
2345                  (Expr => Expr,
2346                   Typ  => Component_Type (Etype (N)),
2347                   Related_Nod => N);
2348             end if;
2349
2350             Next (Expr);
2351          end loop;
2352
2353          if Others_Present then
2354             Assoc := Last (Component_Associations (N));
2355
2356             --  Ada 2005 (AI-231)
2357
2358             if Ada_Version >= Ada_2005
2359               and then Known_Null (Assoc)
2360             then
2361                Check_Can_Never_Be_Null (Etype (N), Expression (Assoc));
2362             end if;
2363
2364             --  Ada 2005 (AI-287): In case of default initialized component,
2365             --  we delay the resolution to the expansion phase.
2366
2367             if Box_Present (Assoc) then
2368
2369                --  Ada 2005 (AI-287): In case of default initialization of a
2370                --  component the expander will generate calls to the
2371                --  corresponding initialization subprogram. We need to call
2372                --  Resolve_Aggr_Expr to check the rules about
2373                --  dimensionality.
2374
2375                if not Resolve_Aggr_Expr (Assoc, Single_Elmt => False) then
2376                   return Failure;
2377                end if;
2378
2379             elsif not Resolve_Aggr_Expr (Expression (Assoc),
2380                                          Single_Elmt => False)
2381             then
2382                return Failure;
2383
2384             --  Check incorrect use of dynamically tagged expression. The
2385             --  expression of the others choice has not been resolved yet.
2386             --  In order to diagnose the semantic error we create a duplicate
2387             --  tree to analyze it and perform the check.
2388
2389             else
2390                declare
2391                   Save_Analysis : constant Boolean := Full_Analysis;
2392                   Expr          : constant Node_Id :=
2393                                     New_Copy_Tree (Expression (Assoc));
2394
2395                begin
2396                   Expander_Mode_Save_And_Set (False);
2397                   Full_Analysis := False;
2398                   Analyze (Expr);
2399                   Full_Analysis := Save_Analysis;
2400                   Expander_Mode_Restore;
2401
2402                   if Is_Tagged_Type (Etype (Expr)) then
2403                      Check_Dynamically_Tagged_Expression
2404                        (Expr => Expr,
2405                         Typ  => Component_Type (Etype (N)),
2406                         Related_Nod => N);
2407                   end if;
2408                end;
2409             end if;
2410          end if;
2411
2412          --  STEP 3 (B): Compute the aggregate bounds
2413
2414          if Others_Present then
2415             Get_Index_Bounds (Index_Constr, Aggr_Low, Aggr_High);
2416
2417          else
2418             if Others_Allowed then
2419                Get_Index_Bounds (Index_Constr, Aggr_Low, Discard);
2420             else
2421                Aggr_Low := Index_Typ_Low;
2422             end if;
2423
2424             Aggr_High := Add (Nb_Elements - 1, To => Aggr_Low);
2425             Check_Bound (Index_Base_High, Aggr_High);
2426          end if;
2427       end if;
2428
2429       --  STEP 4: Perform static aggregate checks and save the bounds
2430
2431       --  Check (A)
2432
2433       Check_Bounds (Index_Typ_Low, Index_Typ_High, Aggr_Low, Aggr_High);
2434       Check_Bounds (Index_Base_Low, Index_Base_High, Aggr_Low, Aggr_High);
2435
2436       --  Check (B)
2437
2438       if Others_Present and then Nb_Discrete_Choices > 0 then
2439          Check_Bounds (Aggr_Low, Aggr_High, Choices_Low, Choices_High);
2440          Check_Bounds (Index_Typ_Low, Index_Typ_High,
2441                        Choices_Low, Choices_High);
2442          Check_Bounds (Index_Base_Low, Index_Base_High,
2443                        Choices_Low, Choices_High);
2444
2445       --  Check (C)
2446
2447       elsif Others_Present and then Nb_Elements > 0 then
2448          Check_Length (Aggr_Low, Aggr_High, Nb_Elements);
2449          Check_Length (Index_Typ_Low, Index_Typ_High, Nb_Elements);
2450          Check_Length (Index_Base_Low, Index_Base_High, Nb_Elements);
2451       end if;
2452
2453       if Raises_Constraint_Error (Aggr_Low)
2454         or else Raises_Constraint_Error (Aggr_High)
2455       then
2456          Set_Raises_Constraint_Error (N);
2457       end if;
2458
2459       Aggr_Low := Duplicate_Subexpr (Aggr_Low);
2460
2461       --  Do not duplicate Aggr_High if Aggr_High = Aggr_Low + Nb_Elements
2462       --  since the addition node returned by Add is not yet analyzed. Attach
2463       --  to tree and analyze first. Reset analyzed flag to ensure it will get
2464       --  analyzed when it is a literal bound whose type must be properly set.
2465
2466       if Others_Present or else Nb_Discrete_Choices > 0 then
2467          Aggr_High := Duplicate_Subexpr (Aggr_High);
2468
2469          if Etype (Aggr_High) = Universal_Integer then
2470             Set_Analyzed (Aggr_High, False);
2471          end if;
2472       end if;
2473
2474       --  If the aggregate already has bounds attached to it, it means this is
2475       --  a positional aggregate created as an optimization by
2476       --  Exp_Aggr.Convert_To_Positional, so we don't want to change those
2477       --  bounds.
2478
2479       if Present (Aggregate_Bounds (N)) and then not Others_Allowed then
2480          Aggr_Low  := Low_Bound  (Aggregate_Bounds (N));
2481          Aggr_High := High_Bound (Aggregate_Bounds (N));
2482       end if;
2483
2484       Set_Aggregate_Bounds
2485         (N, Make_Range (Loc, Low_Bound => Aggr_Low, High_Bound => Aggr_High));
2486
2487       --  The bounds may contain expressions that must be inserted upwards.
2488       --  Attach them fully to the tree. After analysis, remove side effects
2489       --  from upper bound, if still needed.
2490
2491       Set_Parent (Aggregate_Bounds (N), N);
2492       Analyze_And_Resolve (Aggregate_Bounds (N), Index_Typ);
2493       Check_Unset_Reference (Aggregate_Bounds (N));
2494
2495       if not Others_Present and then Nb_Discrete_Choices = 0 then
2496          Set_High_Bound (Aggregate_Bounds (N),
2497              Duplicate_Subexpr (High_Bound (Aggregate_Bounds (N))));
2498       end if;
2499
2500       return Success;
2501    end Resolve_Array_Aggregate;
2502
2503    ---------------------------------
2504    -- Resolve_Extension_Aggregate --
2505    ---------------------------------
2506
2507    --  There are two cases to consider:
2508
2509    --  a) If the ancestor part is a type mark, the components needed are the
2510    --  difference between the components of the expected type and the
2511    --  components of the given type mark.
2512
2513    --  b) If the ancestor part is an expression, it must be unambiguous, and
2514    --  once we have its type we can also compute the needed components as in
2515    --  the previous case. In both cases, if the ancestor type is not the
2516    --  immediate ancestor, we have to build this ancestor recursively.
2517
2518    --  In both cases, discriminants of the ancestor type do not play a role in
2519    --  the resolution of the needed components, because inherited discriminants
2520    --  cannot be used in a type extension. As a result we can compute
2521    --  independently the list of components of the ancestor type and of the
2522    --  expected type.
2523
2524    procedure Resolve_Extension_Aggregate (N : Node_Id; Typ : Entity_Id) is
2525       A      : constant Node_Id := Ancestor_Part (N);
2526       A_Type : Entity_Id;
2527       I      : Interp_Index;
2528       It     : Interp;
2529
2530       function Valid_Limited_Ancestor (Anc : Node_Id) return Boolean;
2531       --  If the type is limited, verify that the ancestor part is a legal
2532       --  expression (aggregate or function call, including 'Input)) that does
2533       --  not require a copy, as specified in 7.5(2).
2534
2535       function Valid_Ancestor_Type return Boolean;
2536       --  Verify that the type of the ancestor part is a non-private ancestor
2537       --  of the expected type, which must be a type extension.
2538
2539       ----------------------------
2540       -- Valid_Limited_Ancestor --
2541       ----------------------------
2542
2543       function Valid_Limited_Ancestor (Anc : Node_Id) return Boolean is
2544       begin
2545          if Is_Entity_Name (Anc)
2546            and then Is_Type (Entity (Anc))
2547          then
2548             return True;
2549
2550          elsif Nkind_In (Anc, N_Aggregate, N_Function_Call) then
2551             return True;
2552
2553          elsif Nkind (Anc) = N_Attribute_Reference
2554            and then Attribute_Name (Anc) = Name_Input
2555          then
2556             return True;
2557
2558          elsif Nkind (Anc) = N_Qualified_Expression then
2559             return Valid_Limited_Ancestor (Expression (Anc));
2560
2561          else
2562             return False;
2563          end if;
2564       end Valid_Limited_Ancestor;
2565
2566       -------------------------
2567       -- Valid_Ancestor_Type --
2568       -------------------------
2569
2570       function Valid_Ancestor_Type return Boolean is
2571          Imm_Type : Entity_Id;
2572
2573       begin
2574          Imm_Type := Base_Type (Typ);
2575          while Is_Derived_Type (Imm_Type) loop
2576             if Etype (Imm_Type) = Base_Type (A_Type) then
2577                return True;
2578
2579             --  The base type of the parent type may appear as  a private
2580             --  extension if it is declared as such in a parent unit of the
2581             --  current one. For consistency of the subsequent analysis use
2582             --  the partial view for the ancestor part.
2583
2584             elsif Is_Private_Type (Etype (Imm_Type))
2585               and then Present (Full_View (Etype (Imm_Type)))
2586               and then Base_Type (A_Type) = Full_View (Etype (Imm_Type))
2587             then
2588                A_Type := Etype (Imm_Type);
2589                return True;
2590
2591             --  The parent type may be a private extension. The aggregate is
2592             --  legal if the type of the aggregate is an extension of it that
2593             --  is not a private extension.
2594
2595             elsif Is_Private_Type (A_Type)
2596               and then not Is_Private_Type (Imm_Type)
2597               and then Present (Full_View (A_Type))
2598               and then Base_Type (Full_View (A_Type)) = Etype (Imm_Type)
2599             then
2600                return True;
2601
2602             else
2603                Imm_Type := Etype (Base_Type (Imm_Type));
2604             end if;
2605          end loop;
2606
2607          --  If previous loop did not find a proper ancestor, report error
2608
2609          Error_Msg_NE ("expect ancestor type of &", A, Typ);
2610          return False;
2611       end Valid_Ancestor_Type;
2612
2613    --  Start of processing for Resolve_Extension_Aggregate
2614
2615    begin
2616       --  Analyze the ancestor part and account for the case where it is a
2617       --  parameterless function call.
2618
2619       Analyze (A);
2620       Check_Parameterless_Call (A);
2621
2622       --  In SPARK, the ancestor part cannot be a type mark
2623
2624       if Is_Entity_Name (A)
2625         and then Is_Type (Entity (A))
2626       then
2627          Check_SPARK_Restriction ("ancestor part cannot be a type mark", A);
2628
2629          --  AI05-0115: if the ancestor part is a subtype mark, the ancestor
2630          --  must not have unknown discriminants.
2631
2632          if Has_Unknown_Discriminants (Root_Type (Typ)) then
2633             Error_Msg_NE
2634               ("aggregate not available for type& whose ancestor "
2635                  & "has unknown discriminants", N, Typ);
2636          end if;
2637       end if;
2638
2639       if not Is_Tagged_Type (Typ) then
2640          Error_Msg_N ("type of extension aggregate must be tagged", N);
2641          return;
2642
2643       elsif Is_Limited_Type (Typ) then
2644
2645          --  Ada 2005 (AI-287): Limited aggregates are allowed
2646
2647          if Ada_Version < Ada_2005 then
2648             Error_Msg_N ("aggregate type cannot be limited", N);
2649             Explain_Limited_Type (Typ, N);
2650             return;
2651
2652          elsif Valid_Limited_Ancestor (A) then
2653             null;
2654
2655          else
2656             Error_Msg_N
2657               ("limited ancestor part must be aggregate or function call", A);
2658          end if;
2659
2660       elsif Is_Class_Wide_Type (Typ) then
2661          Error_Msg_N ("aggregate cannot be of a class-wide type", N);
2662          return;
2663       end if;
2664
2665       if Is_Entity_Name (A)
2666         and then Is_Type (Entity (A))
2667       then
2668          A_Type := Get_Full_View (Entity (A));
2669
2670          if Valid_Ancestor_Type then
2671             Set_Entity (A, A_Type);
2672             Set_Etype  (A, A_Type);
2673
2674             Validate_Ancestor_Part (N);
2675             Resolve_Record_Aggregate (N, Typ);
2676          end if;
2677
2678       elsif Nkind (A) /= N_Aggregate then
2679          if Is_Overloaded (A) then
2680             A_Type := Any_Type;
2681
2682             Get_First_Interp (A, I, It);
2683             while Present (It.Typ) loop
2684                --  Only consider limited interpretations in the Ada 2005 case
2685
2686                if Is_Tagged_Type (It.Typ)
2687                  and then (Ada_Version >= Ada_2005
2688                             or else not Is_Limited_Type (It.Typ))
2689                then
2690                   if A_Type /= Any_Type then
2691                      Error_Msg_N ("cannot resolve expression", A);
2692                      return;
2693                   else
2694                      A_Type := It.Typ;
2695                   end if;
2696                end if;
2697
2698                Get_Next_Interp (I, It);
2699             end loop;
2700
2701             if A_Type = Any_Type then
2702                if Ada_Version >= Ada_2005 then
2703                   Error_Msg_N ("ancestor part must be of a tagged type", A);
2704                else
2705                   Error_Msg_N
2706                     ("ancestor part must be of a nonlimited tagged type", A);
2707                end if;
2708
2709                return;
2710             end if;
2711
2712          else
2713             A_Type := Etype (A);
2714          end if;
2715
2716          if Valid_Ancestor_Type then
2717             Resolve (A, A_Type);
2718             Check_Unset_Reference (A);
2719             Check_Non_Static_Context (A);
2720
2721             --  The aggregate is illegal if the ancestor expression is a call
2722             --  to a function with a limited unconstrained result, unless the
2723             --  type of the aggregate is a null extension. This restriction
2724             --  was added in AI05-67 to simplify implementation.
2725
2726             if Nkind (A) = N_Function_Call
2727               and then Is_Limited_Type (A_Type)
2728               and then not Is_Null_Extension (Typ)
2729               and then not Is_Constrained (A_Type)
2730             then
2731                Error_Msg_N
2732                  ("type of limited ancestor part must be constrained", A);
2733
2734             --  Reject the use of CPP constructors that leave objects partially
2735             --  initialized. For example:
2736
2737             --    type CPP_Root is tagged limited record ...
2738             --    pragma Import (CPP, CPP_Root);
2739
2740             --    type CPP_DT is new CPP_Root and Iface ...
2741             --    pragma Import (CPP, CPP_DT);
2742
2743             --    type Ada_DT is new CPP_DT with ...
2744
2745             --    Obj : Ada_DT := Ada_DT'(New_CPP_Root with others => <>);
2746
2747             --  Using the constructor of CPP_Root the slots of the dispatch
2748             --  table of CPP_DT cannot be set, and the secondary tag of
2749             --  CPP_DT is unknown.
2750
2751             elsif Nkind (A) = N_Function_Call
2752               and then Is_CPP_Constructor_Call (A)
2753               and then Enclosing_CPP_Parent (Typ) /= A_Type
2754             then
2755                Error_Msg_NE
2756                  ("?must use 'C'P'P constructor for type &", A,
2757                   Enclosing_CPP_Parent (Typ));
2758
2759                --  The following call is not needed if the previous warning
2760                --  is promoted to an error.
2761
2762                Resolve_Record_Aggregate (N, Typ);
2763
2764             elsif Is_Class_Wide_Type (Etype (A))
2765               and then Nkind (Original_Node (A)) = N_Function_Call
2766             then
2767                --  If the ancestor part is a dispatching call, it appears
2768                --  statically to be a legal ancestor, but it yields any member
2769                --  of the class, and it is not possible to determine whether
2770                --  it is an ancestor of the extension aggregate (much less
2771                --  which ancestor). It is not possible to determine the
2772                --  components of the extension part.
2773
2774                --  This check implements AI-306, which in fact was motivated by
2775                --  an AdaCore query to the ARG after this test was added.
2776
2777                Error_Msg_N ("ancestor part must be statically tagged", A);
2778             else
2779                Resolve_Record_Aggregate (N, Typ);
2780             end if;
2781          end if;
2782
2783       else
2784          Error_Msg_N ("no unique type for this aggregate",  A);
2785       end if;
2786    end Resolve_Extension_Aggregate;
2787
2788    ------------------------------
2789    -- Resolve_Record_Aggregate --
2790    ------------------------------
2791
2792    procedure Resolve_Record_Aggregate (N : Node_Id; Typ : Entity_Id) is
2793       Assoc : Node_Id;
2794       --  N_Component_Association node belonging to the input aggregate N
2795
2796       Expr            : Node_Id;
2797       Positional_Expr : Node_Id;
2798       Component       : Entity_Id;
2799       Component_Elmt  : Elmt_Id;
2800
2801       Components : constant Elist_Id := New_Elmt_List;
2802       --  Components is the list of the record components whose value must be
2803       --  provided in the aggregate. This list does include discriminants.
2804
2805       New_Assoc_List : constant List_Id := New_List;
2806       New_Assoc      : Node_Id;
2807       --  New_Assoc_List is the newly built list of N_Component_Association
2808       --  nodes. New_Assoc is one such N_Component_Association node in it.
2809       --  Note that while Assoc and New_Assoc contain the same kind of nodes,
2810       --  they are used to iterate over two different N_Component_Association
2811       --  lists.
2812
2813       Others_Etype : Entity_Id := Empty;
2814       --  This variable is used to save the Etype of the last record component
2815       --  that takes its value from the others choice. Its purpose is:
2816       --
2817       --    (a) make sure the others choice is useful
2818       --
2819       --    (b) make sure the type of all the components whose value is
2820       --        subsumed by the others choice are the same.
2821       --
2822       --  This variable is updated as a side effect of function Get_Value.
2823
2824       Is_Box_Present : Boolean := False;
2825       Others_Box     : Boolean := False;
2826       --  Ada 2005 (AI-287): Variables used in case of default initialization
2827       --  to provide a functionality similar to Others_Etype. Box_Present
2828       --  indicates that the component takes its default initialization;
2829       --  Others_Box indicates that at least one component takes its default
2830       --  initialization. Similar to Others_Etype, they are also updated as a
2831       --  side effect of function Get_Value.
2832
2833       procedure Add_Association
2834         (Component      : Entity_Id;
2835          Expr           : Node_Id;
2836          Assoc_List     : List_Id;
2837          Is_Box_Present : Boolean := False);
2838       --  Builds a new N_Component_Association node which associates Component
2839       --  to expression Expr and adds it to the association list being built,
2840       --  either New_Assoc_List, or the association being built for an inner
2841       --  aggregate.
2842
2843       function Discr_Present (Discr : Entity_Id) return Boolean;
2844       --  If aggregate N is a regular aggregate this routine will return True.
2845       --  Otherwise, if N is an extension aggregate, Discr is a discriminant
2846       --  whose value may already have been specified by N's ancestor part.
2847       --  This routine checks whether this is indeed the case and if so returns
2848       --  False, signaling that no value for Discr should appear in N's
2849       --  aggregate part. Also, in this case, the routine appends to
2850       --  New_Assoc_List the discriminant value specified in the ancestor part.
2851       --
2852       --  If the aggregate is in a context with expansion delayed, it will be
2853       --  reanalyzed. The inherited discriminant values must not be reinserted
2854       --  in the component list to prevent spurious errors, but they must be
2855       --  present on first analysis to build the proper subtype indications.
2856       --  The flag Inherited_Discriminant is used to prevent the re-insertion.
2857
2858       function Get_Value
2859         (Compon                 : Node_Id;
2860          From                   : List_Id;
2861          Consider_Others_Choice : Boolean := False)
2862          return                   Node_Id;
2863       --  Given a record component stored in parameter Compon, this function
2864       --  returns its value as it appears in the list From, which is a list
2865       --  of N_Component_Association nodes.
2866       --
2867       --  If no component association has a choice for the searched component,
2868       --  the value provided by the others choice is returned, if there is one,
2869       --  and Consider_Others_Choice is set to true. Otherwise Empty is
2870       --  returned. If there is more than one component association giving a
2871       --  value for the searched record component, an error message is emitted
2872       --  and the first found value is returned.
2873       --
2874       --  If Consider_Others_Choice is set and the returned expression comes
2875       --  from the others choice, then Others_Etype is set as a side effect.
2876       --  An error message is emitted if the components taking their value from
2877       --  the others choice do not have same type.
2878
2879       procedure Resolve_Aggr_Expr (Expr : Node_Id; Component : Node_Id);
2880       --  Analyzes and resolves expression Expr against the Etype of the
2881       --  Component. This routine also applies all appropriate checks to Expr.
2882       --  It finally saves a Expr in the newly created association list that
2883       --  will be attached to the final record aggregate. Note that if the
2884       --  Parent pointer of Expr is not set then Expr was produced with a
2885       --  New_Copy_Tree or some such.
2886
2887       ---------------------
2888       -- Add_Association --
2889       ---------------------
2890
2891       procedure Add_Association
2892         (Component      : Entity_Id;
2893          Expr           : Node_Id;
2894          Assoc_List     : List_Id;
2895          Is_Box_Present : Boolean := False)
2896       is
2897          Loc : Source_Ptr;
2898          Choice_List : constant List_Id := New_List;
2899          New_Assoc   : Node_Id;
2900
2901       begin
2902          --  If this is a box association the expression is missing, so
2903          --  use the Sloc of the aggregate itself for the new association.
2904
2905          if Present (Expr) then
2906             Loc := Sloc (Expr);
2907          else
2908             Loc := Sloc (N);
2909          end if;
2910
2911          Append (New_Occurrence_Of (Component, Loc), Choice_List);
2912          New_Assoc :=
2913            Make_Component_Association (Loc,
2914              Choices     => Choice_List,
2915              Expression  => Expr,
2916              Box_Present => Is_Box_Present);
2917          Append (New_Assoc, Assoc_List);
2918       end Add_Association;
2919
2920       -------------------
2921       -- Discr_Present --
2922       -------------------
2923
2924       function Discr_Present (Discr : Entity_Id) return Boolean is
2925          Regular_Aggr : constant Boolean := Nkind (N) /= N_Extension_Aggregate;
2926
2927          Loc : Source_Ptr;
2928
2929          Ancestor     : Node_Id;
2930          Comp_Assoc   : Node_Id;
2931          Discr_Expr   : Node_Id;
2932
2933          Ancestor_Typ : Entity_Id;
2934          Orig_Discr   : Entity_Id;
2935          D            : Entity_Id;
2936          D_Val        : Elmt_Id := No_Elmt; -- stop junk warning
2937
2938          Ancestor_Is_Subtyp : Boolean;
2939
2940       begin
2941          if Regular_Aggr then
2942             return True;
2943          end if;
2944
2945          --  Check whether inherited discriminant values have already been
2946          --  inserted in the aggregate. This will be the case if we are
2947          --  re-analyzing an aggregate whose expansion was delayed.
2948
2949          if Present (Component_Associations (N)) then
2950             Comp_Assoc := First (Component_Associations (N));
2951             while Present (Comp_Assoc) loop
2952                if Inherited_Discriminant (Comp_Assoc) then
2953                   return True;
2954                end if;
2955
2956                Next (Comp_Assoc);
2957             end loop;
2958          end if;
2959
2960          Ancestor     := Ancestor_Part (N);
2961          Ancestor_Typ := Etype (Ancestor);
2962          Loc          := Sloc (Ancestor);
2963
2964          --  For a private type with unknown discriminants, use the underlying
2965          --  record view if it is available.
2966
2967          if Has_Unknown_Discriminants (Ancestor_Typ)
2968            and then Present (Full_View (Ancestor_Typ))
2969            and then Present (Underlying_Record_View (Full_View (Ancestor_Typ)))
2970          then
2971             Ancestor_Typ := Underlying_Record_View (Full_View (Ancestor_Typ));
2972          end if;
2973
2974          Ancestor_Is_Subtyp :=
2975            Is_Entity_Name (Ancestor) and then Is_Type (Entity (Ancestor));
2976
2977          --  If the ancestor part has no discriminants clearly N's aggregate
2978          --  part must provide a value for Discr.
2979
2980          if not Has_Discriminants (Ancestor_Typ) then
2981             return True;
2982
2983          --  If the ancestor part is an unconstrained subtype mark then the
2984          --  Discr must be present in N's aggregate part.
2985
2986          elsif Ancestor_Is_Subtyp
2987            and then not Is_Constrained (Entity (Ancestor))
2988          then
2989             return True;
2990          end if;
2991
2992          --  Now look to see if Discr was specified in the ancestor part
2993
2994          if Ancestor_Is_Subtyp then
2995             D_Val := First_Elmt (Discriminant_Constraint (Entity (Ancestor)));
2996          end if;
2997
2998          Orig_Discr := Original_Record_Component (Discr);
2999
3000          D := First_Discriminant (Ancestor_Typ);
3001          while Present (D) loop
3002
3003             --  If Ancestor has already specified Disc value then insert its
3004             --  value in the final aggregate.
3005
3006             if Original_Record_Component (D) = Orig_Discr then
3007                if Ancestor_Is_Subtyp then
3008                   Discr_Expr := New_Copy_Tree (Node (D_Val));
3009                else
3010                   Discr_Expr :=
3011                     Make_Selected_Component (Loc,
3012                       Prefix        => Duplicate_Subexpr (Ancestor),
3013                       Selector_Name => New_Occurrence_Of (Discr, Loc));
3014                end if;
3015
3016                Resolve_Aggr_Expr (Discr_Expr, Discr);
3017                Set_Inherited_Discriminant (Last (New_Assoc_List));
3018                return False;
3019             end if;
3020
3021             Next_Discriminant (D);
3022
3023             if Ancestor_Is_Subtyp then
3024                Next_Elmt (D_Val);
3025             end if;
3026          end loop;
3027
3028          return True;
3029       end Discr_Present;
3030
3031       ---------------
3032       -- Get_Value --
3033       ---------------
3034
3035       function Get_Value
3036         (Compon                 : Node_Id;
3037          From                   : List_Id;
3038          Consider_Others_Choice : Boolean := False)
3039          return                   Node_Id
3040       is
3041          Assoc         : Node_Id;
3042          Expr          : Node_Id := Empty;
3043          Selector_Name : Node_Id;
3044
3045       begin
3046          Is_Box_Present := False;
3047
3048          if Present (From) then
3049             Assoc := First (From);
3050          else
3051             return Empty;
3052          end if;
3053
3054          while Present (Assoc) loop
3055             Selector_Name := First (Choices (Assoc));
3056             while Present (Selector_Name) loop
3057                if Nkind (Selector_Name) = N_Others_Choice then
3058                   if Consider_Others_Choice and then No (Expr) then
3059
3060                      --  We need to duplicate the expression for each
3061                      --  successive component covered by the others choice.
3062                      --  This is redundant if the others_choice covers only
3063                      --  one component (small optimization possible???), but
3064                      --  indispensable otherwise, because each one must be
3065                      --  expanded individually to preserve side-effects.
3066
3067                      --  Ada 2005 (AI-287): In case of default initialization
3068                      --  of components, we duplicate the corresponding default
3069                      --  expression (from the record type declaration). The
3070                      --  copy must carry the sloc of the association (not the
3071                      --  original expression) to prevent spurious elaboration
3072                      --  checks when the default includes function calls.
3073
3074                      if Box_Present (Assoc) then
3075                         Others_Box     := True;
3076                         Is_Box_Present := True;
3077
3078                         if Expander_Active then
3079                            return
3080                              New_Copy_Tree
3081                                (Expression (Parent (Compon)),
3082                                 New_Sloc => Sloc (Assoc));
3083                         else
3084                            return Expression (Parent (Compon));
3085                         end if;
3086
3087                      else
3088                         if Present (Others_Etype) and then
3089                            Base_Type (Others_Etype) /= Base_Type (Etype
3090                                                                    (Compon))
3091                         then
3092                            Error_Msg_N ("components in OTHERS choice must " &
3093                                         "have same type", Selector_Name);
3094                         end if;
3095
3096                         Others_Etype := Etype (Compon);
3097
3098                         if Expander_Active then
3099                            return New_Copy_Tree (Expression (Assoc));
3100                         else
3101                            return Expression (Assoc);
3102                         end if;
3103                      end if;
3104                   end if;
3105
3106                elsif Chars (Compon) = Chars (Selector_Name) then
3107                   if No (Expr) then
3108
3109                      --  Ada 2005 (AI-231)
3110
3111                      if Ada_Version >= Ada_2005
3112                        and then Known_Null (Expression (Assoc))
3113                      then
3114                         Check_Can_Never_Be_Null (Compon, Expression (Assoc));
3115                      end if;
3116
3117                      --  We need to duplicate the expression when several
3118                      --  components are grouped together with a "|" choice.
3119                      --  For instance "filed1 | filed2 => Expr"
3120
3121                      --  Ada 2005 (AI-287)
3122
3123                      if Box_Present (Assoc) then
3124                         Is_Box_Present := True;
3125
3126                         --  Duplicate the default expression of the component
3127                         --  from the record type declaration, so a new copy
3128                         --  can be attached to the association.
3129
3130                         --  Note that we always copy the default expression,
3131                         --  even when the association has a single choice, in
3132                         --  order to create a proper association for the
3133                         --  expanded aggregate.
3134
3135                         Expr := New_Copy_Tree (Expression (Parent (Compon)));
3136
3137                         --  Component may have no default, in which case the
3138                         --  expression is empty and the component is default-
3139                         --  initialized, but an association for the component
3140                         --  exists, and it is not covered by an others clause.
3141
3142                         return Expr;
3143
3144                      else
3145                         if Present (Next (Selector_Name)) then
3146                            Expr := New_Copy_Tree (Expression (Assoc));
3147                         else
3148                            Expr := Expression (Assoc);
3149                         end if;
3150                      end if;
3151
3152                      Generate_Reference (Compon, Selector_Name, 'm');
3153
3154                   else
3155                      Error_Msg_NE
3156                        ("more than one value supplied for &",
3157                         Selector_Name, Compon);
3158
3159                   end if;
3160                end if;
3161
3162                Next (Selector_Name);
3163             end loop;
3164
3165             Next (Assoc);
3166          end loop;
3167
3168          return Expr;
3169       end Get_Value;
3170
3171       -----------------------
3172       -- Resolve_Aggr_Expr --
3173       -----------------------
3174
3175       procedure Resolve_Aggr_Expr (Expr : Node_Id; Component : Node_Id) is
3176          New_C     : Entity_Id := Component;
3177          Expr_Type : Entity_Id := Empty;
3178
3179          function Has_Expansion_Delayed (Expr : Node_Id) return Boolean;
3180          --  If the expression is an aggregate (possibly qualified) then its
3181          --  expansion is delayed until the enclosing aggregate is expanded
3182          --  into assignments. In that case, do not generate checks on the
3183          --  expression, because they will be generated later, and will other-
3184          --  wise force a copy (to remove side-effects) that would leave a
3185          --  dynamic-sized aggregate in the code, something that gigi cannot
3186          --  handle.
3187
3188          Relocate : Boolean;
3189          --  Set to True if the resolved Expr node needs to be relocated when
3190          --  attached to the newly created association list. This node need not
3191          --  be relocated if its parent pointer is not set. In fact in this
3192          --  case Expr is the output of a New_Copy_Tree call. If Relocate is
3193          --  True then we have analyzed the expression node in the original
3194          --  aggregate and hence it needs to be relocated when moved over to
3195          --  the new association list.
3196
3197          ---------------------------
3198          -- Has_Expansion_Delayed --
3199          ---------------------------
3200
3201          function Has_Expansion_Delayed (Expr : Node_Id) return Boolean is
3202             Kind : constant Node_Kind := Nkind (Expr);
3203          begin
3204             return (Nkind_In (Kind, N_Aggregate, N_Extension_Aggregate)
3205                      and then Present (Etype (Expr))
3206                      and then Is_Record_Type (Etype (Expr))
3207                      and then Expansion_Delayed (Expr))
3208               or else (Kind = N_Qualified_Expression
3209                         and then Has_Expansion_Delayed (Expression (Expr)));
3210          end Has_Expansion_Delayed;
3211
3212       --  Start of processing for Resolve_Aggr_Expr
3213
3214       begin
3215          --  If the type of the component is elementary or the type of the
3216          --  aggregate does not contain discriminants, use the type of the
3217          --  component to resolve Expr.
3218
3219          if Is_Elementary_Type (Etype (Component))
3220            or else not Has_Discriminants (Etype (N))
3221          then
3222             Expr_Type := Etype (Component);
3223
3224          --  Otherwise we have to pick up the new type of the component from
3225          --  the new constrained subtype of the aggregate. In fact components
3226          --  which are of a composite type might be constrained by a
3227          --  discriminant, and we want to resolve Expr against the subtype were
3228          --  all discriminant occurrences are replaced with their actual value.
3229
3230          else
3231             New_C := First_Component (Etype (N));
3232             while Present (New_C) loop
3233                if Chars (New_C) = Chars (Component) then
3234                   Expr_Type := Etype (New_C);
3235                   exit;
3236                end if;
3237
3238                Next_Component (New_C);
3239             end loop;
3240
3241             pragma Assert (Present (Expr_Type));
3242
3243             --  For each range in an array type where a discriminant has been
3244             --  replaced with the constraint, check that this range is within
3245             --  the range of the base type. This checks is done in the init
3246             --  proc for regular objects, but has to be done here for
3247             --  aggregates since no init proc is called for them.
3248
3249             if Is_Array_Type (Expr_Type) then
3250                declare
3251                   Index : Node_Id;
3252                   --  Range of the current constrained index in the array
3253
3254                   Orig_Index : Node_Id := First_Index (Etype (Component));
3255                   --  Range corresponding to the range Index above in the
3256                   --  original unconstrained record type. The bounds of this
3257                   --  range may be governed by discriminants.
3258
3259                   Unconstr_Index : Node_Id := First_Index (Etype (Expr_Type));
3260                   --  Range corresponding to the range Index above for the
3261                   --  unconstrained array type. This range is needed to apply
3262                   --  range checks.
3263
3264                begin
3265                   Index := First_Index (Expr_Type);
3266                   while Present (Index) loop
3267                      if Depends_On_Discriminant (Orig_Index) then
3268                         Apply_Range_Check (Index, Etype (Unconstr_Index));
3269                      end if;
3270
3271                      Next_Index (Index);
3272                      Next_Index (Orig_Index);
3273                      Next_Index (Unconstr_Index);
3274                   end loop;
3275                end;
3276             end if;
3277          end if;
3278
3279          --  If the Parent pointer of Expr is not set, Expr is an expression
3280          --  duplicated by New_Tree_Copy (this happens for record aggregates
3281          --  that look like (Field1 | Filed2 => Expr) or (others => Expr)).
3282          --  Such a duplicated expression must be attached to the tree
3283          --  before analysis and resolution to enforce the rule that a tree
3284          --  fragment should never be analyzed or resolved unless it is
3285          --  attached to the current compilation unit.
3286
3287          if No (Parent (Expr)) then
3288             Set_Parent (Expr, N);
3289             Relocate := False;
3290          else
3291             Relocate := True;
3292          end if;
3293
3294          Analyze_And_Resolve (Expr, Expr_Type);
3295          Check_Expr_OK_In_Limited_Aggregate (Expr);
3296          Check_Non_Static_Context (Expr);
3297          Check_Unset_Reference (Expr);
3298
3299          --  Check wrong use of class-wide types
3300
3301          if Is_Class_Wide_Type (Etype (Expr)) then
3302             Error_Msg_N ("dynamically tagged expression not allowed", Expr);
3303          end if;
3304
3305          if not Has_Expansion_Delayed (Expr) then
3306             Aggregate_Constraint_Checks (Expr, Expr_Type);
3307          end if;
3308
3309          --  If an aggregate component has a type with predicates, an explicit
3310          --  predicate check must be applied, as for an assignment statement,
3311          --  because the aggegate might not be expanded into individual
3312          --  component assignments.
3313
3314          if Present (Predicate_Function (Expr_Type)) then
3315             Apply_Predicate_Check (Expr, Expr_Type);
3316          end if;
3317
3318          if Raises_Constraint_Error (Expr) then
3319             Set_Raises_Constraint_Error (N);
3320          end if;
3321
3322          --  If the expression has been marked as requiring a range check, then
3323          --  generate it here.
3324
3325          if Do_Range_Check (Expr) then
3326             Set_Do_Range_Check (Expr, False);
3327             Generate_Range_Check (Expr, Expr_Type, CE_Range_Check_Failed);
3328          end if;
3329
3330          if Relocate then
3331             Add_Association (New_C, Relocate_Node (Expr), New_Assoc_List);
3332          else
3333             Add_Association (New_C, Expr, New_Assoc_List);
3334          end if;
3335       end Resolve_Aggr_Expr;
3336
3337    --  Start of processing for Resolve_Record_Aggregate
3338
3339    begin
3340       --  A record aggregate is restricted in SPARK:
3341       --    Each named association can have only a single choice.
3342       --    OTHERS cannot be used.
3343       --    Positional and named associations cannot be mixed.
3344
3345       if Present (Component_Associations (N))
3346         and then Present (First (Component_Associations (N)))
3347       then
3348
3349          if Present (Expressions (N)) then
3350             Check_SPARK_Restriction
3351               ("named association cannot follow positional one",
3352                First (Choices (First (Component_Associations (N)))));
3353          end if;
3354
3355          declare
3356             Assoc : Node_Id;
3357
3358          begin
3359             Assoc := First (Component_Associations (N));
3360             while Present (Assoc) loop
3361                if List_Length (Choices (Assoc)) > 1 then
3362                   Check_SPARK_Restriction
3363                     ("component association in record aggregate must "
3364                      & "contain a single choice", Assoc);
3365                end if;
3366
3367                if Nkind (First (Choices (Assoc))) = N_Others_Choice then
3368                   Check_SPARK_Restriction
3369                     ("record aggregate cannot contain OTHERS", Assoc);
3370                end if;
3371
3372                Assoc := Next (Assoc);
3373             end loop;
3374          end;
3375       end if;
3376
3377       --  We may end up calling Duplicate_Subexpr on expressions that are
3378       --  attached to New_Assoc_List. For this reason we need to attach it
3379       --  to the tree by setting its parent pointer to N. This parent point
3380       --  will change in STEP 8 below.
3381
3382       Set_Parent (New_Assoc_List, N);
3383
3384       --  STEP 1: abstract type and null record verification
3385
3386       if Is_Abstract_Type (Typ) then
3387          Error_Msg_N ("type of aggregate cannot be abstract",  N);
3388       end if;
3389
3390       if No (First_Entity (Typ)) and then Null_Record_Present (N) then
3391          Set_Etype (N, Typ);
3392          return;
3393
3394       elsif Present (First_Entity (Typ))
3395         and then Null_Record_Present (N)
3396         and then not Is_Tagged_Type (Typ)
3397       then
3398          Error_Msg_N ("record aggregate cannot be null", N);
3399          return;
3400
3401       --  If the type has no components, then the aggregate should either
3402       --  have "null record", or in Ada 2005 it could instead have a single
3403       --  component association given by "others => <>". For Ada 95 we flag an
3404       --  error at this point, but for Ada 2005 we proceed with checking the
3405       --  associations below, which will catch the case where it's not an
3406       --  aggregate with "others => <>". Note that the legality of a <>
3407       --  aggregate for a null record type was established by AI05-016.
3408
3409       elsif No (First_Entity (Typ))
3410          and then Ada_Version < Ada_2005
3411       then
3412          Error_Msg_N ("record aggregate must be null", N);
3413          return;
3414       end if;
3415
3416       --  STEP 2: Verify aggregate structure
3417
3418       Step_2 : declare
3419          Selector_Name : Node_Id;
3420          Bad_Aggregate : Boolean := False;
3421
3422       begin
3423          if Present (Component_Associations (N)) then
3424             Assoc := First (Component_Associations (N));
3425          else
3426             Assoc := Empty;
3427          end if;
3428
3429          while Present (Assoc) loop
3430             Selector_Name := First (Choices (Assoc));
3431             while Present (Selector_Name) loop
3432                if Nkind (Selector_Name) = N_Identifier then
3433                   null;
3434
3435                elsif Nkind (Selector_Name) = N_Others_Choice then
3436                   if Selector_Name /= First (Choices (Assoc))
3437                     or else Present (Next (Selector_Name))
3438                   then
3439                      Error_Msg_N
3440                        ("OTHERS must appear alone in a choice list",
3441                         Selector_Name);
3442                      return;
3443
3444                   elsif Present (Next (Assoc)) then
3445                      Error_Msg_N
3446                        ("OTHERS must appear last in an aggregate",
3447                         Selector_Name);
3448                      return;
3449
3450                   --  (Ada 2005): If this is an association with a box,
3451                   --  indicate that the association need not represent
3452                   --  any component.
3453
3454                   elsif Box_Present (Assoc) then
3455                      Others_Box := True;
3456                   end if;
3457
3458                else
3459                   Error_Msg_N
3460                     ("selector name should be identifier or OTHERS",
3461                      Selector_Name);
3462                   Bad_Aggregate := True;
3463                end if;
3464
3465                Next (Selector_Name);
3466             end loop;
3467
3468             Next (Assoc);
3469          end loop;
3470
3471          if Bad_Aggregate then
3472             return;
3473          end if;
3474       end Step_2;
3475
3476       --  STEP 3: Find discriminant Values
3477
3478       Step_3 : declare
3479          Discrim               : Entity_Id;
3480          Missing_Discriminants : Boolean := False;
3481
3482       begin
3483          if Present (Expressions (N)) then
3484             Positional_Expr := First (Expressions (N));
3485          else
3486             Positional_Expr := Empty;
3487          end if;
3488
3489          --  AI05-0115: if the ancestor part is a subtype mark, the ancestor
3490          --  must npt have unknown discriminants.
3491
3492          if Is_Derived_Type (Typ)
3493            and then Has_Unknown_Discriminants (Root_Type (Typ))
3494            and then Nkind (N) /= N_Extension_Aggregate
3495          then
3496             Error_Msg_NE
3497               ("aggregate not available for type& whose ancestor "
3498                  & "has unknown discriminants ", N, Typ);
3499          end if;
3500
3501          if Has_Unknown_Discriminants (Typ)
3502            and then Present (Underlying_Record_View (Typ))
3503          then
3504             Discrim := First_Discriminant (Underlying_Record_View (Typ));
3505          elsif Has_Discriminants (Typ) then
3506             Discrim := First_Discriminant (Typ);
3507          else
3508             Discrim := Empty;
3509          end if;
3510
3511          --  First find the discriminant values in the positional components
3512
3513          while Present (Discrim) and then Present (Positional_Expr) loop
3514             if Discr_Present (Discrim) then
3515                Resolve_Aggr_Expr (Positional_Expr, Discrim);
3516
3517                --  Ada 2005 (AI-231)
3518
3519                if Ada_Version >= Ada_2005
3520                  and then Known_Null (Positional_Expr)
3521                then
3522                   Check_Can_Never_Be_Null (Discrim, Positional_Expr);
3523                end if;
3524
3525                Next (Positional_Expr);
3526             end if;
3527
3528             if Present (Get_Value (Discrim, Component_Associations (N))) then
3529                Error_Msg_NE
3530                  ("more than one value supplied for discriminant&",
3531                   N, Discrim);
3532             end if;
3533
3534             Next_Discriminant (Discrim);
3535          end loop;
3536
3537          --  Find remaining discriminant values, if any, among named components
3538
3539          while Present (Discrim) loop
3540             Expr := Get_Value (Discrim, Component_Associations (N), True);
3541
3542             if not Discr_Present (Discrim) then
3543                if Present (Expr) then
3544                   Error_Msg_NE
3545                     ("more than one value supplied for discriminant&",
3546                      N, Discrim);
3547                end if;
3548
3549             elsif No (Expr) then
3550                Error_Msg_NE
3551                  ("no value supplied for discriminant &", N, Discrim);
3552                Missing_Discriminants := True;
3553
3554             else
3555                Resolve_Aggr_Expr (Expr, Discrim);
3556             end if;
3557
3558             Next_Discriminant (Discrim);
3559          end loop;
3560
3561          if Missing_Discriminants then
3562             return;
3563          end if;
3564
3565          --  At this point and until the beginning of STEP 6, New_Assoc_List
3566          --  contains only the discriminants and their values.
3567
3568       end Step_3;
3569
3570       --  STEP 4: Set the Etype of the record aggregate
3571
3572       --  ??? This code is pretty much a copy of Sem_Ch3.Build_Subtype. That
3573       --  routine should really be exported in sem_util or some such and used
3574       --  in sem_ch3 and here rather than have a copy of the code which is a
3575       --  maintenance nightmare.
3576
3577       --  ??? Performance WARNING. The current implementation creates a new
3578       --  itype for all aggregates whose base type is discriminated.
3579       --  This means that for record aggregates nested inside an array
3580       --  aggregate we will create a new itype for each record aggregate
3581       --  if the array component type has discriminants. For large aggregates
3582       --  this may be a problem. What should be done in this case is
3583       --  to reuse itypes as much as possible.
3584
3585       if Has_Discriminants (Typ)
3586         or else (Has_Unknown_Discriminants (Typ)
3587                    and then Present (Underlying_Record_View (Typ)))
3588       then
3589          Build_Constrained_Itype : declare
3590             Loc         : constant Source_Ptr := Sloc (N);
3591             Indic       : Node_Id;
3592             Subtyp_Decl : Node_Id;
3593             Def_Id      : Entity_Id;
3594
3595             C : constant List_Id := New_List;
3596
3597          begin
3598             New_Assoc := First (New_Assoc_List);
3599             while Present (New_Assoc) loop
3600                Append (Duplicate_Subexpr (Expression (New_Assoc)), To => C);
3601                Next (New_Assoc);
3602             end loop;
3603
3604             if Has_Unknown_Discriminants (Typ)
3605               and then Present (Underlying_Record_View (Typ))
3606             then
3607                Indic :=
3608                  Make_Subtype_Indication (Loc,
3609                    Subtype_Mark =>
3610                      New_Occurrence_Of (Underlying_Record_View (Typ), Loc),
3611                    Constraint  =>
3612                      Make_Index_Or_Discriminant_Constraint (Loc, C));
3613             else
3614                Indic :=
3615                  Make_Subtype_Indication (Loc,
3616                    Subtype_Mark =>
3617                      New_Occurrence_Of (Base_Type (Typ), Loc),
3618                    Constraint  =>
3619                      Make_Index_Or_Discriminant_Constraint (Loc, C));
3620             end if;
3621
3622             Def_Id := Create_Itype (Ekind (Typ), N);
3623
3624             Subtyp_Decl :=
3625               Make_Subtype_Declaration (Loc,
3626                 Defining_Identifier => Def_Id,
3627                 Subtype_Indication  => Indic);
3628             Set_Parent (Subtyp_Decl, Parent (N));
3629
3630             --  Itypes must be analyzed with checks off (see itypes.ads)
3631
3632             Analyze (Subtyp_Decl, Suppress => All_Checks);
3633
3634             Set_Etype (N, Def_Id);
3635             Check_Static_Discriminated_Subtype
3636               (Def_Id, Expression (First (New_Assoc_List)));
3637          end Build_Constrained_Itype;
3638
3639       else
3640          Set_Etype (N, Typ);
3641       end if;
3642
3643       --  STEP 5: Get remaining components according to discriminant values
3644
3645       Step_5 : declare
3646          Record_Def      : Node_Id;
3647          Parent_Typ      : Entity_Id;
3648          Root_Typ        : Entity_Id;
3649          Parent_Typ_List : Elist_Id;
3650          Parent_Elmt     : Elmt_Id;
3651          Errors_Found    : Boolean := False;
3652          Dnode           : Node_Id;
3653
3654          function Find_Private_Ancestor return Entity_Id;
3655          --  AI05-0115: Find earlier ancestor in the derivation chain that is
3656          --  derived from a private view. Whether the aggregate is legal
3657          --  depends on the current visibility of the type as well as that