gcc/ada/s-carun8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                   GNU ADA RUNTIME LIBRARY COMPONENTS                     --
   4 --                                                                          --
   5 --       S Y S T E M . C O M P A R E _ A R R A Y _ U N S I G N E D _ 8      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2004 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Unchecked_Conversion;
  35
  36 package body System.Compare_Array_Unsigned_8 is
  37
  38    function "+" (Left, Right : Address) return Address;
  39    pragma Import (Intrinsic, "+");
  40    --  Provide addition operation on type Address (this may not be directly
  41    --  available if type System.Address is non-private and the operations on
  42    --  the type are made abstract to hide them from public users of System.
  43
  44    type Word is mod 2 ** 32;
  45    --  Used to process operands by words
  46
  47    type Big_Words is array (Natural) of Word;
  48    type Big_Words_Ptr is access Big_Words;
  49    --  Array type used to access by words
  50
  51    type Byte is mod 2 ** 8;
  52    --  Used to process operands by bytes
  53
  54    type Big_Bytes is array (Natural) of Byte;
  55    type Big_Bytes_Ptr is access Big_Bytes;
  56    --  Array type used to access by bytes
  57
  58    function To_Big_Words is new
  59      Unchecked_Conversion (System.Address, Big_Words_Ptr);
  60
  61    function To_Big_Bytes is new
  62      Unchecked_Conversion (System.Address, Big_Bytes_Ptr);
  63
  64    ----------------------
  65    -- Compare_Array_U8 --
  66    ----------------------
  67
  68    function Compare_Array_U8
  69      (Left      : System.Address;
  70       Right     : System.Address;
  71       Left_Len  : Natural;
  72       Right_Len : Natural)
  73       return      Integer
  74    is
  75       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
  76
  77    begin
  78       --  If operands are non-aligned, or length is too short, go by bytes
  79
  80       if (((Left or Right) and 2#11#) /= 0) or else Compare_Len < 4 then
  81          return Compare_Array_U8_Unaligned (Left, Right, Left_Len, Right_Len);
  82       end if;
  83
  84       --  Here we can go by words
  85
  86       declare
  87          LeftP  : constant Big_Words_Ptr := To_Big_Words (Left);
  88          RightP : constant Big_Words_Ptr := To_Big_Words (Right);
  89          Clen4  : constant Natural       := Compare_Len / 4 - 1;
  90          Clen4F : constant Natural       := Clen4 * 4;
  91
  92       begin
  93          for J in 0 .. Clen4 loop
  94             if LeftP (J) /= RightP (J) then
  95                return Compare_Array_U8_Unaligned
  96                         (Left  + Address (4 * J),
  97                          Right + Address (4 * J),
  98                          4, 4);
  99             end if;
 100          end loop;
 101
 102          return Compare_Array_U8_Unaligned
 103                   (Left      + Address (Clen4F),
 104                    Right     + Address (Clen4F),
 105                    Left_Len  - Clen4F,
 106                    Right_Len - Clen4F);
 107       end;
 108    end Compare_Array_U8;
 109
 110    --------------------------------
 111    -- Compare_Array_U8_Unaligned --
 112    --------------------------------
 113
 114    function Compare_Array_U8_Unaligned
 115      (Left      : System.Address;
 116       Right     : System.Address;
 117       Left_Len  : Natural;
 118       Right_Len : Natural)
 119       return      Integer
 120    is
 121       Compare_Len : constant Natural := Natural'Min (Left_Len, Right_Len);
 122
 123       LeftP  : constant Big_Bytes_Ptr := To_Big_Bytes (Left);
 124       RightP : constant Big_Bytes_Ptr := To_Big_Bytes (Right);
 125
 126    begin
 127       for J in 0 .. Compare_Len - 1 loop
 128          if LeftP (J) /= RightP (J) then
 129             if LeftP (J) > RightP (J) then
 130                return +1;
 131             else
 132                return -1;
 133             end if;
 134          end if;
 135       end loop;
 136
 137       if Left_Len = Right_Len then
 138          return 0;
 139       elsif Left_Len > Right_Len then
 140          return +1;
 141       else
 142          return -1;
 143       end if;
 144    end Compare_Array_U8_Unaligned;
 145
 146 end System.Compare_Array_Unsigned_8;