OSDN Git Service

* freeze.adb: Make Freeze_Fixed_Point_Type visible, for use in
[pf3gnuchains/gcc-fork.git] / gcc / ada / prj.ads
1 ------------------------------------------------------------------------------
2 --                                                                          --
3 --                         GNAT COMPILER COMPONENTS                         --
4 --                                                                          --
5 --                                  P R J                                   --
6 --                                                                          --
7 --                                 S p e c                                  --
8 --                                                                          --
9 --                            $Revision$
10 --                                                                          --
11 --             Copyright (C) 2001 Free Software Foundation, Inc.            --
12 --                                                                          --
13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
14 -- terms of the  GNU General Public License as published  by the Free Soft- --
15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
19 -- for  more details.  You should have  received  a copy of the GNU General --
20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
22 -- MA 02111-1307, USA.                                                      --
23 --                                                                          --
24 -- GNAT was originally developed  by the GNAT team at  New York University. --
25 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
26 --                                                                          --
27 ------------------------------------------------------------------------------
28
29 --  The following package declares the data types for GNAT project.
30 --  These data types may be used by GNAT Project-aware tools.
31
32 --  Children of these package implements various services on these data types.
33 --  See in particular Prj.Pars and Prj.Env.
34
35 with Casing;      use Casing;
36 with GNAT.OS_Lib; use GNAT.OS_Lib;
37 with Scans;       use Scans;
38 with Table;
39 with Types;       use Types;
40
41 package Prj is
42
43    type Put_Line_Access is access procedure (Line : String);
44    --  Use to customize error reporting in Prj.Proc and Prj.Nmsc.
45
46    type Verbosity is (Default, Medium, High);
47    --  Verbosity when parsing GNAT Project Files
48    --    Default is default (very quiet, if no errors).
49    --    Medium is more verbose.
50    --    High is extremely verbose.
51
52    type Lib_Kind is (Static, Dynamic, Relocatable);
53
54    function Empty_String return String_Id;
55
56    type String_List_Id is new Nat;
57    Nil_String : constant String_List_Id := 0;
58    type String_Element is record
59       Value    : String_Id      := No_String;
60       Location : Source_Ptr     := No_Location;
61       Next     : String_List_Id := Nil_String;
62    end record;
63    --  To hold values for string list variables and array elements
64
65    package String_Elements is new Table.Table
66      (Table_Component_Type => String_Element,
67       Table_Index_Type     => String_List_Id,
68       Table_Low_Bound      => 1,
69       Table_Initial        => 200,
70       Table_Increment      => 100,
71       Table_Name           => "Prj.String_Elements");
72    --  The table for string elements in string lists
73
74    type Variable_Kind is (Undefined, List, Single);
75    --  Different kinds of variables
76
77    type Variable_Value (Kind : Variable_Kind := Undefined) is record
78       Location : Source_Ptr := No_Location;
79       Default  : Boolean    := False;
80       case Kind is
81          when Undefined =>
82             null;
83          when List =>
84             Values : String_List_Id := Nil_String;
85          when Single =>
86             Value : String_Id := No_String;
87       end case;
88    end record;
89    --  Values for variables and array elements.
90    --  Default is True if the current value is the default one for the variable
91
92    Nil_Variable_Value : constant Variable_Value :=
93      (Kind     => Undefined,
94       Location => No_Location,
95       Default  => False);
96    --  Value of a non existing variable or array element
97
98    type Variable_Id is new Nat;
99    No_Variable : constant Variable_Id := 0;
100    type Variable is record
101       Next     : Variable_Id := No_Variable;
102       Name     : Name_Id;
103       Value    : Variable_Value;
104    end record;
105    --  To hold the list of variables in a project file and in packages
106
107    package Variable_Elements is new Table.Table
108      (Table_Component_Type => Variable,
109       Table_Index_Type     => Variable_Id,
110       Table_Low_Bound      => 1,
111       Table_Initial        => 200,
112       Table_Increment      => 100,
113       Table_Name           => "Prj.Variable_Elements");
114    --  The table of variable in list of variables
115
116    type Array_Element_Id is new Nat;
117    No_Array_Element : constant Array_Element_Id := 0;
118    type Array_Element is record
119       Index    : Name_Id;
120       Value    : Variable_Value;
121       Next     : Array_Element_Id := No_Array_Element;
122    end record;
123    --  Each Array_Element represents an array element and is linked (Next)
124    --  to the next array element, if any, in the array.
125
126    package Array_Elements is new Table.Table
127      (Table_Component_Type => Array_Element,
128       Table_Index_Type     => Array_Element_Id,
129       Table_Low_Bound      => 1,
130       Table_Initial        => 200,
131       Table_Increment      => 100,
132       Table_Name           => "Prj.Array_Elements");
133    --  The table that contains all array elements
134
135    type Array_Id is new Nat;
136    No_Array : constant Array_Id := 0;
137    type Array_Data is record
138       Name  : Name_Id          := No_Name;
139       Value : Array_Element_Id := No_Array_Element;
140       Next  : Array_Id         := No_Array;
141    end record;
142    --  Each Array_Data value represents an array.
143    --  Value is the id of the first element.
144    --  Next is the id of the next array in the project file or package.
145
146    package Arrays is new Table.Table
147      (Table_Component_Type => Array_Data,
148       Table_Index_Type     => Array_Id,
149       Table_Low_Bound      => 1,
150       Table_Initial        => 200,
151       Table_Increment      => 100,
152       Table_Name           => "Prj.Arrays");
153    --  The table that contains all arrays
154
155    type Package_Id is new Nat;
156    No_Package : constant Package_Id := 0;
157    type Declarations is record
158       Variables  : Variable_Id := No_Variable;
159       Attributes : Variable_Id := No_Variable;
160       Arrays     : Array_Id    := No_Array;
161       Packages   : Package_Id  := No_Package;
162    end record;
163
164    No_Declarations : constant Declarations :=
165      (Variables  => No_Variable,
166       Attributes => No_Variable,
167       Arrays     => No_Array,
168       Packages   => No_Package);
169    --  Declarations. Used in project structures and packages (what for???)
170
171    type Package_Element is record
172       Name   : Name_Id      := No_Name;
173       Decl   : Declarations := No_Declarations;
174       Parent : Package_Id   := No_Package;
175       Next   : Package_Id   := No_Package;
176    end record;
177    --  A package. Includes declarations that may include other packages.
178
179    package Packages is new Table.Table
180      (Table_Component_Type => Package_Element,
181       Table_Index_Type     => Package_Id,
182       Table_Low_Bound      => 1,
183       Table_Initial        => 100,
184       Table_Increment      => 100,
185       Table_Name           => "Prj.Packages");
186    --  The table that contains all packages.
187
188    function Image (Casing : Casing_Type) return String;
189    --  Similar to 'Image (but avoid use of this attribute in compiler)
190
191    function Value (Image : String) return Casing_Type;
192    --  Similar to 'Value (but avoid use of this attribute in compiler)
193    --  Raises Constraint_Error if not a Casing_Type image.
194
195    type Naming_Data is record
196       Current_Language : Name_Id := No_Name;
197       --  The programming language being currently considered
198
199       Dot_Replacement : Name_Id := No_Name;
200       --  The string to replace '.' in the source file name (for Ada).
201
202       Dot_Repl_Loc : Source_Ptr := No_Location;
203       --  The position in the project file source where
204       --  Dot_Replacement is defined.
205
206       Casing : Casing_Type := All_Lower_Case;
207       --  The casing of the source file name (for Ada).
208
209       Specification_Suffix : Array_Element_Id := No_Array_Element;
210       --  The string to append to the unit name for the
211       --  source file name of a specification.
212       --  Indexed by the programming language.
213
214       Current_Spec_Suffix : Name_Id := No_Name;
215       --  The specification suffix of the current programming language
216
217       Spec_Suffix_Loc : Source_Ptr := No_Location;
218       --  The position in the project file source where
219       --  Current_Spec_Suffix is defined.
220
221       Implementation_Suffix : Array_Element_Id := No_Array_Element;
222       --  The string to append to the unit name for the
223       --  source file name of a body.
224       --  Indexed by the programming language.
225
226       Current_Impl_Suffix : Name_Id := No_Name;
227       --  The implementation suffix of the current programming language
228
229       Impl_Suffix_Loc : Source_Ptr := No_Location;
230       --  The position in the project file source where
231       --  Current_Impl_Suffix is defined.
232
233       Separate_Suffix : Name_Id := No_Name;
234       --  The string to append to the unit name for the
235       --  source file name of an Ada subunit.
236
237       Sep_Suffix_Loc : Source_Ptr := No_Location;
238       --  The position in the project file source where
239       --  Separate_Suffix is defined.
240
241       Specifications : Array_Element_Id := No_Array_Element;
242       --  An associative array mapping individual specifications
243       --  to source file names. Specific to Ada.
244
245       Bodies : Array_Element_Id := No_Array_Element;
246       --  An associative array mapping individual bodies
247       --  to source file names. Specific to Ada.
248
249       Specification_Exceptions : Array_Element_Id := No_Array_Element;
250       --  An associative array mapping individual specifications
251       --  to source file names. Indexed by the programming language name.
252
253       Implementation_Exceptions : Array_Element_Id := No_Array_Element;
254       --  An associative array mapping individual bodies
255       --  to source file names. Indexed by the programming language name.
256
257    end record;
258    --  A naming scheme.
259
260    function Standard_Naming_Data return Naming_Data;
261    pragma Inline (Standard_Naming_Data);
262    --  The standard GNAT naming scheme.
263
264    function Same_Naming_Scheme
265      (Left, Right : Naming_Data)
266       return        Boolean;
267    --  Returns True if Left and Right are the same naming scheme
268    --  not considering Specifications and Bodies.
269
270    type Project_Id is new Nat;
271    No_Project : constant Project_Id := 0;
272    --  Id of a Project File
273
274    type Project_List is new Nat;
275    Empty_Project_List : constant Project_List := 0;
276    --  A list of project files.
277
278    type Project_Element is record
279       Project : Project_Id   := No_Project;
280       Next    : Project_List := Empty_Project_List;
281    end record;
282    --  Element in a list of project file.
283    --  Next is the id of the next project file in the list.
284
285    package Project_Lists is new Table.Table
286      (Table_Component_Type => Project_Element,
287       Table_Index_Type     => Project_List,
288       Table_Low_Bound      => 1,
289       Table_Initial        => 100,
290       Table_Increment      => 100,
291       Table_Name           => "Prj.Project_Lists");
292    --  The table that contains the lists of project files.
293
294    type Project_Data is record
295       First_Referred_By  : Project_Id := No_Project;
296       --  The project, if any, that was the first to be known
297       --  as importing or extending this project.
298       --  Set by Prj.Proc.Process.
299
300       Name : Name_Id := No_Name;
301       --  The name of the project.
302       --  Set by Prj.Proc.Process.
303
304       Path_Name : Name_Id := No_Name;
305       --  The path name of the project file.
306       --  Set by Prj.Proc.Process.
307
308       Location : Source_Ptr := No_Location;
309       --  The location in the project file source of the
310       --  reserved word project.
311       --  Set by Prj.Proc.Process.
312
313       Directory : Name_Id := No_Name;
314       --  The directory where the project file resides.
315       --  Set by Prj.Proc.Process.
316
317       Library : Boolean := False;
318       --  True if this is a library project.
319       --  Set by Prj.Nmsc.Check_Naming_Scheme.
320
321       Library_Dir : Name_Id := No_Name;
322       --  If a library project, directory where resides the library
323       --  Set by Prj.Nmsc.Check_Naming_Scheme.
324
325       Library_Name : Name_Id := No_Name;
326       --  If a library project, name of the library
327       --  Set by Prj.Nmsc.Check_Naming_Scheme.
328
329       Library_Kind : Lib_Kind := Static;
330       --  If a library project, kind of library
331       --  Set by Prj.Nmsc.Check_Naming_Scheme.
332
333       Lib_Internal_Name : Name_Id := No_Name;
334       --  If a library project, internal name store inside the library
335       --  Set by Prj.Nmsc.Check_Naming_Scheme.
336
337       Lib_Elaboration : Boolean := False;
338       --  If a library project, indicate if <lib>init and <lib>final
339       --  procedures need to be defined.
340       --  Set by Prj.Nmsc.Check_Naming_Scheme.
341
342       Sources_Present : Boolean := True;
343       --  A flag that indicates if there are sources in this project file.
344       --  There are no sources if 1) Source_Dirs is specified as an
345       --  empty list, 2) Source_Files is specified as an empty list, or
346       --  3) the current language is not in the list of the specified
347       --  Languages.
348
349       Sources : String_List_Id := Nil_String;
350       --  The list of all the source file names.
351       --  Set by Prj.Nmsc.Check_Naming_Scheme.
352
353       Source_Dirs : String_List_Id := Nil_String;
354       --  The list of all the source directories.
355       --  Set by Prj.Nmsc.Check_Naming_Scheme.
356
357       Object_Directory : Name_Id := No_Name;
358       --  The object directory of this project file.
359       --  Set by Prj.Nmsc.Check_Naming_Scheme.
360
361       Modifies : Project_Id := No_Project;
362       --  The reference of the project file, if any, that this
363       --  project file modifies.
364       --  Set by Prj.Proc.Process.
365
366       Modified_By : Project_Id := No_Project;
367       --  The reference of the project file, if any, that
368       --  modifies this project file.
369       --  Set by Prj.Proc.Process.
370
371       Naming : Naming_Data := Standard_Naming_Data;
372       --  The naming scheme of this project file.
373       --  Set by Prj.Nmsc.Check_Naming_Scheme.
374
375       Decl : Declarations := No_Declarations;
376       --  The declarations (variables, attributes and packages)
377       --  of this project file.
378       --  Set by Prj.Proc.Process.
379
380       Imported_Projects : Project_List := Empty_Project_List;
381       --  The list of all directly imported projects, if any.
382       --  Set by Prj.Proc.Process.
383
384       Include_Path : String_Access := null;
385       --  The cached value of ADA_INCLUDE_PATH for this project file.
386       --  Set by gnatmake (prj.Env.Set_Ada_Paths).
387       --  Do not use this field directly outside of the compiler, use
388       --  Prj.Env.Ada_Source_Path instead.
389
390       Objects_Path : String_Access := null;
391       --  The cached value of ADA_OBJECTS_PATH for this project file.
392       --  Set by gnatmake (prj.Env.Set_Ada_Paths).
393       --  Do not use this field directly outside of the compiler, use
394       --  Prj.Env.Ada_Source_Path instead.
395
396       Config_File_Name : Name_Id := No_Name;
397       --  The name of the configuration pragmas file, if any.
398       --  Set by gnatmage (Prj.Env.Create_Config_Pragmas_File).
399
400       Config_File_Temp : Boolean := False;
401       --  An indication that the configuration pragmas file is
402       --  a temporary file that must be deleted at the end.
403       --  Set by gnatmage (Prj.Env.Create_Config_Pragmas_File).
404
405       Config_Checked : Boolean := False;
406       --  A flag to avoid checking repetitively the configuration pragmas file.
407       --  Set by gnatmage (Prj.Env.Create_Config_Pragmas_File).
408
409       Language_Independent_Checked : Boolean := False;
410       --  A flag that indicates that the project file has been checked
411       --  for language independent features: Object_Directory,
412       --  Source_Directories, Library, non empty Naming Suffixs.
413
414       Checked : Boolean := False;
415       --  A flag to avoid checking repetitively the naming scheme of
416       --  this project file.
417       --  Set by Prj.Nmsc.Check_Naming_Scheme.
418
419       Seen  : Boolean := False;
420       Flag1 : Boolean := False;
421       Flag2 : Boolean := False;
422       --  Various flags that are used in an ad hoc manner
423       --  That's really not a good enough comment ??? we need to know what
424       --  these flags are used for, and give them proper names. If Flag1
425       --  and Flag2 have multiple uses, then either we use multiple fields
426       --  or a renaming scheme.
427
428    end record;
429    --  Project File representation.
430
431    function Empty_Project return Project_Data;
432    --  Return the representation of an empty project.
433
434    package Projects is new Table.Table (
435      Table_Component_Type => Project_Data,
436      Table_Index_Type     => Project_Id,
437      Table_Low_Bound      => 1,
438      Table_Initial        => 100,
439      Table_Increment      => 100,
440      Table_Name           => "Prj.Projects");
441    --  The set of all project files.
442
443    procedure Expect (The_Token : Token_Type; Token_Image : String);
444    --  Check that the current token is The_Token. If it is not, then
445    --  output an error message.
446
447    procedure Initialize;
448    --  This procedure must be called before using any services from the Prj
449    --  hierarchy. Namet.Initialize must be called before Prj.Initialize.
450
451    procedure Reset;
452    --  This procedure resets all the tables that are used when processing a
453    --  project file tree. Initialize must be called before the call to Reset.
454
455    generic
456       type State is limited private;
457       with procedure Action
458         (Project    : Project_Id;
459          With_State : in out State);
460    procedure For_Every_Project_Imported
461      (By         : Project_Id;
462       With_State : in out State);
463    --  Call Action for each project imported directly or indirectly by project
464    --  By. Action is called according to the order of importation: if A
465    --  imports B, directly or indirectly, Action will be called for A before
466    --  it is called for B. With_State may be used by Action to choose a
467    --  behavior or to report some global result.
468
469    function Ada_Default_Spec_Suffix return Name_Id;
470    --  Return the Name_Id for the standard GNAT suffix for Ada spec source
471    --  file name ".ads".
472
473    function Ada_Default_Impl_Suffix return Name_Id;
474    --  Return the Name_Id for the standard GNAT suffix for Ada body source
475    --  file name ".adb".
476
477 private
478
479    procedure Scan;
480    --  Calls Scn.Scan and change any Operator_Symbol to String_Literal
481
482 end Prj;