OSDN Git Service

2010-10-08 Robert Dewar <dewar@adacore.com>
[pf3gnuchains/gcc-fork.git] / gcc / ada / gnat1drv.adb
1 ------------------------------------------------------------------------------
2 --                                                                          --
3 --                         GNAT COMPILER COMPONENTS                         --
4 --                                                                          --
5 --                             G N A T 1 D R V                              --
6 --                                                                          --
7 --                                 B o d y                                  --
8 --                                                                          --
9 --          Copyright (C) 1992-2010, Free Software Foundation, Inc.         --
10 --                                                                          --
11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
12 -- terms of the  GNU General Public License as published  by the Free Soft- --
13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
17 -- for  more details.  You should have  received  a copy of the GNU General --
18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
20 --                                                                          --
21 -- GNAT was originally developed  by the GNAT team at  New York University. --
22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
23 --                                                                          --
24 ------------------------------------------------------------------------------
25
26 with Atree;    use Atree;
27 with Back_End; use Back_End;
28 with Comperr;
29 with Csets;    use Csets;
30 with Debug;    use Debug;
31 with Elists;
32 with Errout;   use Errout;
33 with Exp_CG;
34 with Fmap;
35 with Fname;    use Fname;
36 with Fname.UF; use Fname.UF;
37 with Frontend;
38 with Gnatvsn;  use Gnatvsn;
39 with Hostparm;
40 with Inline;
41 with Lib;      use Lib;
42 with Lib.Writ; use Lib.Writ;
43 with Lib.Xref;
44 with Namet;    use Namet;
45 with Nlists;
46 with Opt;      use Opt;
47 with Osint;    use Osint;
48 with Output;   use Output;
49 with Par_SCO;
50 with Prepcomp;
51 with Repinfo;  use Repinfo;
52 with Restrict;
53 with Rident;   use Rident;
54 with Rtsfind;
55 with SCOs;
56 with Sem;
57 with Sem_Ch8;
58 with Sem_Ch12;
59 with Sem_Ch13;
60 with Sem_Elim;
61 with Sem_Eval;
62 with Sem_Type;
63 with Sinfo;    use Sinfo;
64 with Sinput.L; use Sinput.L;
65 with Snames;
66 with Sprint;   use Sprint;
67 with Stringt;
68 with Stylesw;  use Stylesw;
69 with Targparm; use Targparm;
70 with Tree_Gen;
71 with Treepr;   use Treepr;
72 with Ttypes;
73 with Types;    use Types;
74 with Uintp;    use Uintp;
75 with Uname;    use Uname;
76 with Urealp;
77 with Usage;
78 with Validsw;  use Validsw;
79
80 with System.Assertions;
81
82 procedure Gnat1drv is
83    Main_Unit_Node : Node_Id;
84    --  Compilation unit node for main unit
85
86    Main_Kind : Node_Kind;
87    --  Kind of main compilation unit node
88
89    Back_End_Mode : Back_End.Back_End_Mode_Type;
90    --  Record back end mode
91
92    procedure Adjust_Global_Switches;
93    --  There are various interactions between front end switch settings,
94    --  including debug switch settings and target dependent parameters.
95    --  This procedure takes care of properly handling these interactions.
96    --  We do it after scanning out all the switches, so that we are not
97    --  depending on the order in which switches appear.
98
99    procedure Check_Bad_Body;
100    --  Called to check if the unit we are compiling has a bad body
101
102    procedure Check_Rep_Info;
103    --  Called when we are not generating code, to check if -gnatR was requested
104    --  and if so, explain that we will not be honoring the request.
105
106    procedure Check_Library_Items;
107    --  For debugging -- checks the behavior of Walk_Library_Items
108    pragma Warnings (Off, Check_Library_Items);
109    --  In case the call below is commented out
110
111    ----------------------------
112    -- Adjust_Global_Switches --
113    ----------------------------
114
115    procedure Adjust_Global_Switches is
116    begin
117       --  Debug flag -gnatd.I is a synonym for Generate_SCIL and requires code
118       --  generation.
119
120       if Debug_Flag_Dot_II
121         and then Operating_Mode = Generate_Code
122       then
123          Generate_SCIL := True;
124       end if;
125
126       --  Set ASIS mode if -gnatt and -gnatc are set
127
128       if Operating_Mode = Check_Semantics and then Tree_Output then
129          ASIS_Mode := True;
130
131          --  Turn off inlining in ASIS mode, since ASIS cannot handle the extra
132          --  information in the trees caused by inlining being active.
133
134          --  More specifically, the tree seems to be malformed from the ASIS
135          --  point of view if -gnatc and -gnatn appear together???
136
137          Inline_Active := False;
138
139          --  Turn off SCIL generation in ASIS mode, since SCIL requires front-
140          --  end expansion.
141
142          Generate_SCIL := False;
143       end if;
144
145       --  SCIL mode needs to disable front-end inlining since the generated
146       --  trees (in particular order and consistency between specs compiled
147       --  as part of a main unit or as part of a with-clause) are causing
148       --  troubles.
149
150       if Generate_SCIL then
151          Front_End_Inlining := False;
152       end if;
153
154       --  Tune settings for optimal SCIL generation in CodePeer mode
155
156       if CodePeer_Mode then
157
158          --  Turn off inlining, confuses CodePeer output and gains nothing
159
160          Front_End_Inlining := False;
161          Inline_Active      := False;
162
163          --  Turn off ASIS mode: incompatible with front-end expansion
164
165          ASIS_Mode := False;
166
167          --  Disable front-end optimizations, to keep the tree as close to the
168          --  source code as possible, and also to avoid inconsistencies between
169          --  trees when using different optimization switches.
170
171          Optimization_Level := 0;
172
173          --  Enable some restrictions systematically to simplify the generated
174          --  code (and ease analysis). Note that restriction checks are also
175          --  disabled in CodePeer mode, see Restrict.Check_Restriction
176
177          Restrict.Restrictions.Set   (No_Task_Hierarchy)               := True;
178          Restrict.Restrictions.Set   (No_Abort_Statements)             := True;
179          Restrict.Restrictions.Set   (Max_Asynchronous_Select_Nesting) := True;
180          Restrict.Restrictions.Value (Max_Asynchronous_Select_Nesting) := 0;
181
182          --  Suppress overflow, division by zero and access checks since they
183          --  are handled implicitly by CodePeer.
184
185          --  Turn off dynamic elaboration checks: generates inconsistencies in
186          --  trees between specs compiled as part of a main unit or as part of
187          --  a with-clause.
188
189          --  Turn off alignment checks: these cannot be proved statically by
190          --  CodePeer and generate false positives.
191
192          --  Enable all other language checks
193
194          Suppress_Options :=
195            (Access_Check      => True,
196             Alignment_Check   => True,
197             Division_Check    => True,
198             Elaboration_Check => True,
199             Overflow_Check    => True,
200             others            => False);
201          Enable_Overflow_Checks := False;
202          Dynamic_Elaboration_Checks := False;
203
204          --  Kill debug of generated code, since it messes up sloc values
205
206          Debug_Generated_Code := False;
207
208          --  Turn cross-referencing on in case it was disabled (e.g. by -gnatD)
209          --  Do we really need to spend time generating xref in CodePeer
210          --  mode??? Consider setting Xref_Active to False.
211
212          Xref_Active := True;
213
214          --  Polling mode forced off, since it generates confusing junk
215
216          Polling_Required := False;
217
218          --  Set operating mode to Generate_Code to benefit from full front-end
219          --  expansion (e.g. generics).
220
221          Operating_Mode := Generate_Code;
222
223          --  We need SCIL generation of course
224
225          Generate_SCIL := True;
226
227          --  Enable assertions and debug pragmas, since they give CodePeer
228          --  valuable extra information.
229
230          Assertions_Enabled    := True;
231          Debug_Pragmas_Enabled := True;
232
233          --  Disable all simple value propagation. This is an optimization
234          --  which is valuable for code optimization, and also for generation
235          --  of compiler warnings, but these are being turned off by default,
236          --  and CodePeer generates better messages (referencing original
237          --  variables) this way.
238
239          Debug_Flag_MM := True;
240
241          --  Set normal RM validity checking, and checking of IN OUT parameters
242          --  (this might give CodePeer more useful checks to analyze, to be
243          --  confirmed???). All other validity checking is turned off, since
244          --  this can generate very complex trees that only confuse CodePeer
245          --  and do not bring enough useful info.
246
247          Reset_Validity_Check_Options;
248          Validity_Check_Default       := True;
249          Validity_Check_In_Out_Params := True;
250          Validity_Check_In_Params     := True;
251
252          --  Turn off style check options since we are not interested in any
253          --  front-end warnings when we are getting CodePeer output.
254
255          Reset_Style_Check_Options;
256
257          --  Always perform semantics and generate ali files in CodePeer mode,
258          --  so that a gnatmake -c -k will proceed further when possible.
259
260          Force_ALI_Tree_File := True;
261          Try_Semantics := True;
262       end if;
263
264       --  Set Configurable_Run_Time mode if system.ads flag set
265
266       if Targparm.Configurable_Run_Time_On_Target or Debug_Flag_YY then
267          Configurable_Run_Time_Mode := True;
268       end if;
269
270       --  Set -gnatR3m mode if debug flag A set
271
272       if Debug_Flag_AA then
273          Back_Annotate_Rep_Info := True;
274          List_Representation_Info := 1;
275          List_Representation_Info_Mechanisms := True;
276       end if;
277
278       --  Force Target_Strict_Alignment true if debug flag -gnatd.a is set
279
280       if Debug_Flag_Dot_A then
281          Ttypes.Target_Strict_Alignment := True;
282       end if;
283
284       --  Disable static allocation of dispatch tables if -gnatd.t or if layout
285       --  is enabled. The front end's layout phase currently treats types that
286       --  have discriminant-dependent arrays as not being static even when a
287       --  discriminant constraint on the type is static, and this leads to
288       --  problems with subtypes of type Ada.Tags.Dispatch_Table_Wrapper. ???
289
290       if Debug_Flag_Dot_T or else Frontend_Layout_On_Target then
291          Static_Dispatch_Tables := False;
292       end if;
293
294       --  Flip endian mode if -gnatd8 set
295
296       if Debug_Flag_8 then
297          Ttypes.Bytes_Big_Endian := not Ttypes.Bytes_Big_Endian;
298       end if;
299
300       --  Deal with forcing OpenVMS switches True if debug flag M is set, but
301       --  record the setting of Targparm.Open_VMS_On_Target in True_VMS_Target
302       --  before doing this, so we know if we are in real OpenVMS or not!
303
304       Opt.True_VMS_Target := Targparm.OpenVMS_On_Target;
305
306       if Debug_Flag_M then
307          Targparm.OpenVMS_On_Target := True;
308          Hostparm.OpenVMS := True;
309       end if;
310
311       --  Activate front end layout if debug flag -gnatdF is set
312
313       if Debug_Flag_FF then
314          Targparm.Frontend_Layout_On_Target := True;
315       end if;
316
317       --  Set and check exception mechnism
318
319       if Targparm.ZCX_By_Default_On_Target then
320          if Targparm.GCC_ZCX_Support_On_Target then
321             Exception_Mechanism := Back_End_Exceptions;
322          else
323             Osint.Fail ("Zero Cost Exceptions not supported on this target");
324          end if;
325       end if;
326
327       --  Set proper status for overflow checks. We turn on overflow checks if
328       --  -gnatp was not specified, and either -gnato is set or the back-end
329       --  takes care of overflow checks. Otherwise we suppress overflow checks
330       --  by default (since front end checks are expensive).
331
332       if not Opt.Suppress_Checks
333         and then (Opt.Enable_Overflow_Checks
334                     or else
335                       (Targparm.Backend_Divide_Checks_On_Target
336                         and
337                        Targparm.Backend_Overflow_Checks_On_Target))
338       then
339          Suppress_Options (Overflow_Check) := False;
340       else
341          Suppress_Options (Overflow_Check) := True;
342       end if;
343
344       --  Set switch indicating if we can use N_Expression_With_Actions
345
346       --  Debug flag -gnatd.X decisively sets usage on
347
348       if Debug_Flag_Dot_XX then
349          Use_Expression_With_Actions := True;
350
351       --  Debug flag -gnatd.Y decisively sets usage off
352
353       elsif Debug_Flag_Dot_YY then
354          Use_Expression_With_Actions := False;
355
356       --  Otherwise this feature is implemented, so we allow its use
357
358       else
359          Use_Expression_With_Actions := True;
360       end if;
361
362       --  Set switch indicating if back end can handle limited types, and
363       --  guarantee that no incorrect copies are made (e.g. in the context
364       --  of a conditional expression).
365
366       --  Debug flag -gnatd.L decisively sets usage on
367
368       if Debug_Flag_Dot_LL then
369          Back_End_Handles_Limited_Types := True;
370
371       --  If no debug flag, usage off for AAMP, VM, SCIL cases
372
373       elsif AAMP_On_Target
374         or else VM_Target /= No_VM
375         or else Generate_SCIL
376       then
377          Back_End_Handles_Limited_Types := False;
378
379       --  Otherwise normal gcc back end, for now still turn flag off by
380       --  default, since there are unresolved problems in the front end.
381
382       else
383          Back_End_Handles_Limited_Types := False;
384       end if;
385    end Adjust_Global_Switches;
386
387    --------------------
388    -- Check_Bad_Body --
389    --------------------
390
391    procedure Check_Bad_Body is
392       Sname   : Unit_Name_Type;
393       Src_Ind : Source_File_Index;
394       Fname   : File_Name_Type;
395
396       procedure Bad_Body_Error (Msg : String);
397       --  Issue message for bad body found
398
399       --------------------
400       -- Bad_Body_Error --
401       --------------------
402
403       procedure Bad_Body_Error (Msg : String) is
404       begin
405          Error_Msg_N (Msg, Main_Unit_Node);
406          Error_Msg_File_1 := Fname;
407          Error_Msg_N ("remove incorrect body in file{!", Main_Unit_Node);
408       end Bad_Body_Error;
409
410    --  Start of processing for Check_Bad_Body
411
412    begin
413       --  Nothing to do if we are only checking syntax, because we don't know
414       --  enough to know if we require or forbid a body in this case.
415
416       if Operating_Mode = Check_Syntax then
417          return;
418       end if;
419
420       --  Check for body not allowed
421
422       if (Main_Kind = N_Package_Declaration
423            and then not Body_Required (Main_Unit_Node))
424         or else (Main_Kind = N_Generic_Package_Declaration
425                   and then not Body_Required (Main_Unit_Node))
426         or else Main_Kind = N_Package_Renaming_Declaration
427         or else Main_Kind = N_Subprogram_Renaming_Declaration
428         or else Nkind (Original_Node (Unit (Main_Unit_Node)))
429                          in N_Generic_Instantiation
430       then
431          Sname := Unit_Name (Main_Unit);
432
433          --  If we do not already have a body name, then get the body name
434          --  (but how can we have a body name here???)
435
436          if not Is_Body_Name (Sname) then
437             Sname := Get_Body_Name (Sname);
438          end if;
439
440          Fname := Get_File_Name (Sname, Subunit => False);
441          Src_Ind := Load_Source_File (Fname);
442
443          --  Case where body is present and it is not a subunit. Exclude the
444          --  subunit case, because it has nothing to do with the package we are
445          --  compiling. It is illegal for a child unit and a subunit with the
446          --  same expanded name (RM 10.2(9)) to appear together in a partition,
447          --  but there is nothing to stop a compilation environment from having
448          --  both, and the test here simply allows that. If there is an attempt
449          --  to include both in a partition, this is diagnosed at bind time. In
450          --  Ada 83 mode this is not a warning case.
451
452          --  Note: if weird file names are being used, we can have a situation
453          --  where the file name that supposedly contains body in fact contains
454          --  a spec, or we can't tell what it contains. Skip the error message
455          --  in these cases.
456
457          --  Also ignore body that is nothing but pragma No_Body; (that's the
458          --  whole point of this pragma, to be used this way and to cause the
459          --  body file to be ignored in this context).
460
461          if Src_Ind /= No_Source_File
462            and then Get_Expected_Unit_Type (Fname) = Expect_Body
463            and then not Source_File_Is_Subunit (Src_Ind)
464            and then not Source_File_Is_No_Body (Src_Ind)
465          then
466             Errout.Finalize (Last_Call => False);
467
468             Error_Msg_Unit_1 := Sname;
469
470             --  Ada 83 case of a package body being ignored. This is not an
471             --  error as far as the Ada 83 RM is concerned, but it is almost
472             --  certainly not what is wanted so output a warning. Give this
473             --  message only if there were no errors, since otherwise it may
474             --  be incorrect (we may have misinterpreted a junk spec as not
475             --  needing a body when it really does).
476
477             if Main_Kind = N_Package_Declaration
478               and then Ada_Version = Ada_83
479               and then Operating_Mode = Generate_Code
480               and then Distribution_Stub_Mode /= Generate_Caller_Stub_Body
481               and then not Compilation_Errors
482             then
483                Error_Msg_N
484                  ("package $$ does not require a body?", Main_Unit_Node);
485                Error_Msg_File_1 := Fname;
486                Error_Msg_N ("body in file{? will be ignored", Main_Unit_Node);
487
488                --  Ada 95 cases of a body file present when no body is
489                --  permitted. This we consider to be an error.
490
491             else
492                --  For generic instantiations, we never allow a body
493
494                if Nkind (Original_Node (Unit (Main_Unit_Node)))
495                in N_Generic_Instantiation
496                then
497                   Bad_Body_Error
498                     ("generic instantiation for $$ does not allow a body");
499
500                   --  A library unit that is a renaming never allows a body
501
502                elsif Main_Kind in N_Renaming_Declaration then
503                   Bad_Body_Error
504                     ("renaming declaration for $$ does not allow a body!");
505
506                   --  Remaining cases are packages and generic packages. Here
507                   --  we only do the test if there are no previous errors,
508                   --  because if there are errors, they may lead us to
509                   --  incorrectly believe that a package does not allow a body
510                   --  when in fact it does.
511
512                elsif not Compilation_Errors then
513                   if Main_Kind = N_Package_Declaration then
514                      Bad_Body_Error
515                        ("package $$ does not allow a body!");
516
517                   elsif Main_Kind = N_Generic_Package_Declaration then
518                      Bad_Body_Error
519                        ("generic package $$ does not allow a body!");
520                   end if;
521                end if;
522
523             end if;
524          end if;
525       end if;
526    end Check_Bad_Body;
527
528    -------------------------
529    -- Check_Library_Items --
530    -------------------------
531
532    --  Walk_Library_Items has plenty of assertions, so all we need to do is
533    --  call it, just for these assertions, not actually doing anything else.
534
535    procedure Check_Library_Items is
536
537       procedure Action (Item : Node_Id);
538       --  Action passed to Walk_Library_Items to do nothing
539
540       ------------
541       -- Action --
542       ------------
543
544       procedure Action (Item : Node_Id) is
545       begin
546          null;
547       end Action;
548
549       procedure Walk is new Sem.Walk_Library_Items (Action);
550
551    --  Start of processing for Check_Library_Items
552
553    begin
554       Walk;
555    end Check_Library_Items;
556
557    --------------------
558    -- Check_Rep_Info --
559    --------------------
560
561    procedure Check_Rep_Info is
562    begin
563       if List_Representation_Info /= 0
564         or else List_Representation_Info_Mechanisms
565       then
566          Set_Standard_Error;
567          Write_Eol;
568          Write_Str
569            ("cannot generate representation information, no code generated");
570          Write_Eol;
571          Write_Eol;
572          Set_Standard_Output;
573       end if;
574    end Check_Rep_Info;
575
576 --  Start of processing for Gnat1drv
577
578 begin
579    --  This inner block is set up to catch assertion errors and constraint
580    --  errors. Since the code for handling these errors can cause another
581    --  exception to be raised (namely Unrecoverable_Error), we need two
582    --  nested blocks, so that the outer one handles unrecoverable error.
583
584    begin
585       --  Initialize all packages. For the most part, these initialization
586       --  calls can be made in any order. Exceptions are as follows:
587
588       --  Lib.Initialize need to be called before Scan_Compiler_Arguments,
589       --  because it initializes a table filled by Scan_Compiler_Arguments.
590
591       Osint.Initialize;
592       Fmap.Reset_Tables;
593       Lib.Initialize;
594       Lib.Xref.Initialize;
595       Scan_Compiler_Arguments;
596       Osint.Add_Default_Search_Dirs;
597
598       Nlists.Initialize;
599       Sinput.Initialize;
600       Sem.Initialize;
601       Exp_CG.Initialize;
602       Csets.Initialize;
603       Uintp.Initialize;
604       Urealp.Initialize;
605       Errout.Initialize;
606       SCOs.Initialize;
607       Snames.Initialize;
608       Stringt.Initialize;
609       Inline.Initialize;
610       Par_SCO.Initialize;
611       Sem_Ch8.Initialize;
612       Sem_Ch12.Initialize;
613       Sem_Ch13.Initialize;
614       Sem_Elim.Initialize;
615       Sem_Eval.Initialize;
616       Sem_Type.Init_Interp_Tables;
617
618       --  Acquire target parameters from system.ads (source of package System)
619
620       declare
621          use Sinput;
622
623          S : Source_File_Index;
624          N : File_Name_Type;
625
626       begin
627          Name_Buffer (1 .. 10) := "system.ads";
628          Name_Len := 10;
629          N := Name_Find;
630          S := Load_Source_File (N);
631
632          if S = No_Source_File then
633             Write_Line
634               ("fatal error, run-time library not installed correctly");
635             Write_Line ("cannot locate file system.ads");
636             raise Unrecoverable_Error;
637
638          --  Remember source index of system.ads (which was read successfully)
639
640          else
641             System_Source_File_Index := S;
642          end if;
643
644          Targparm.Get_Target_Parameters
645            (System_Text  => Source_Text  (S),
646             Source_First => Source_First (S),
647             Source_Last  => Source_Last  (S));
648
649          --  Acquire configuration pragma information from Targparm
650
651          Restrict.Restrictions := Targparm.Restrictions_On_Target;
652       end;
653
654       Adjust_Global_Switches;
655
656       --  Output copyright notice if full list mode unless we have a list
657       --  file, in which case we defer this so that it is output in the file
658
659       if (Verbose_Mode or else (Full_List and then Full_List_File_Name = null))
660         and then not Debug_Flag_7
661       then
662          Write_Eol;
663          Write_Str ("GNAT ");
664          Write_Str (Gnat_Version_String);
665          Write_Eol;
666          Write_Str ("Copyright 1992-" & Current_Year
667                     & ", Free Software Foundation, Inc.");
668          Write_Eol;
669       end if;
670
671       --  Check we do not have more than one source file, this happens only in
672       --  the case where the driver is called directly, it cannot happen when
673       --  gnat1 is invoked from gcc in the normal case.
674
675       if Osint.Number_Of_Files /= 1 then
676          Usage;
677          Write_Eol;
678          Osint.Fail ("you must provide one source file");
679
680       elsif Usage_Requested then
681          Usage;
682       end if;
683
684       Original_Operating_Mode := Operating_Mode;
685       Frontend;
686
687       --  Exit with errors if the main source could not be parsed
688
689       if Sinput.Main_Source_File = No_Source_File then
690          Errout.Finalize (Last_Call => True);
691          Errout.Output_Messages;
692          Exit_Program (E_Errors);
693       end if;
694
695       Main_Unit_Node := Cunit (Main_Unit);
696       Main_Kind := Nkind (Unit (Main_Unit_Node));
697       Check_Bad_Body;
698
699       --  Exit if compilation errors detected
700
701       Errout.Finalize (Last_Call => False);
702
703       if Compilation_Errors then
704          Treepr.Tree_Dump;
705          Sem_Ch13.Validate_Unchecked_Conversions;
706          Sem_Ch13.Validate_Address_Clauses;
707          Sem_Ch13.Validate_Independence;
708          Errout.Output_Messages;
709          Namet.Finalize;
710
711          --  Generate ALI file if specially requested
712
713          if Opt.Force_ALI_Tree_File then
714             Write_ALI (Object => False);
715             Tree_Gen;
716          end if;
717
718          Errout.Finalize (Last_Call => True);
719          Exit_Program (E_Errors);
720       end if;
721
722       --  Set Generate_Code on main unit and its spec. We do this even if are
723       --  not generating code, since Lib-Writ uses this to determine which
724       --  units get written in the ali file.
725
726       Set_Generate_Code (Main_Unit);
727
728       --  If we have a corresponding spec, and it comes from source or it is
729       --  not a generated spec for a child subprogram body, then we need object
730       --  code for the spec unit as well.
731
732       if Nkind (Unit (Main_Unit_Node)) in N_Unit_Body
733         and then not Acts_As_Spec (Main_Unit_Node)
734       then
735          if Nkind (Unit (Main_Unit_Node)) = N_Subprogram_Body
736            and then not Comes_From_Source (Library_Unit (Main_Unit_Node))
737          then
738             null;
739          else
740             Set_Generate_Code
741               (Get_Cunit_Unit_Number (Library_Unit (Main_Unit_Node)));
742          end if;
743       end if;
744
745       --  Case of no code required to be generated, exit indicating no error
746
747       if Original_Operating_Mode = Check_Syntax then
748          Treepr.Tree_Dump;
749          Errout.Finalize (Last_Call => True);
750          Errout.Output_Messages;
751          Tree_Gen;
752          Namet.Finalize;
753          Check_Rep_Info;
754
755          --  Use a goto instead of calling Exit_Program so that finalization
756          --  occurs normally.
757
758          goto End_Of_Program;
759
760       elsif Original_Operating_Mode = Check_Semantics then
761          Back_End_Mode := Declarations_Only;
762
763       --  All remaining cases are cases in which the user requested that code
764       --  be generated (i.e. no -gnatc or -gnats switch was used). Check if we
765       --  can in fact satisfy this request.
766
767       --  Cannot generate code if someone has turned off code generation for
768       --  any reason at all. We will try to figure out a reason below.
769
770       elsif Operating_Mode /= Generate_Code then
771          Back_End_Mode := Skip;
772
773       --  We can generate code for a subprogram body unless there were missing
774       --  subunits. Note that we always generate code for all generic units (a
775       --  change from some previous versions of GNAT).
776
777       elsif Main_Kind = N_Subprogram_Body and then not Subunits_Missing then
778          Back_End_Mode := Generate_Object;
779
780       --  We can generate code for a package body unless there are subunits
781       --  missing (note that we always generate code for generic units, which
782       --  is a change from some earlier versions of GNAT).
783
784       elsif Main_Kind = N_Package_Body and then not Subunits_Missing then
785          Back_End_Mode := Generate_Object;
786
787       --  We can generate code for a package declaration or a subprogram
788       --  declaration only if it does not required a body.
789
790       elsif Nkind_In (Main_Kind,
791               N_Package_Declaration,
792               N_Subprogram_Declaration)
793         and then
794           (not Body_Required (Main_Unit_Node)
795              or else
796            Distribution_Stub_Mode = Generate_Caller_Stub_Body)
797       then
798          Back_End_Mode := Generate_Object;
799
800       --  We can generate code for a generic package declaration of a generic
801       --  subprogram declaration only if does not require a body.
802
803       elsif Nkind_In (Main_Kind, N_Generic_Package_Declaration,
804                                  N_Generic_Subprogram_Declaration)
805         and then not Body_Required (Main_Unit_Node)
806       then
807          Back_End_Mode := Generate_Object;
808
809       --  Compilation units that are renamings do not require bodies, so we can
810       --  generate code for them.
811
812       elsif Nkind_In (Main_Kind, N_Package_Renaming_Declaration,
813                                  N_Subprogram_Renaming_Declaration)
814       then
815          Back_End_Mode := Generate_Object;
816
817       --  Compilation units that are generic renamings do not require bodies
818       --  so we can generate code for them.
819
820       elsif Main_Kind in N_Generic_Renaming_Declaration then
821          Back_End_Mode := Generate_Object;
822
823       --  It's not an error to generate SCIL for e.g. a spec which has a body
824
825       elsif CodePeer_Mode then
826          Back_End_Mode := Generate_Object;
827
828       --  In all other cases (specs which have bodies, generics, and bodies
829       --  where subunits are missing), we cannot generate code and we generate
830       --  a warning message. Note that generic instantiations are gone at this
831       --  stage since they have been replaced by their instances.
832
833       else
834          Back_End_Mode := Skip;
835       end if;
836
837       --  At this stage Back_End_Mode is set to indicate if the backend should
838       --  be called to generate code. If it is Skip, then code generation has
839       --  been turned off, even though code was requested by the original
840       --  command. This is not an error from the user point of view, but it is
841       --  an error from the point of view of the gcc driver, so we must exit
842       --  with an error status.
843
844       --  We generate an informative message (from the gcc point of view, it
845       --  is an error message, but from the users point of view this is not an
846       --  error, just a consequence of compiling something that cannot
847       --  generate code).
848
849       if Back_End_Mode = Skip then
850          Set_Standard_Error;
851          Write_Str ("cannot generate code for ");
852          Write_Str ("file ");
853          Write_Name (Unit_File_Name (Main_Unit));
854
855          if Subunits_Missing then
856             Write_Str (" (missing subunits)");
857             Write_Eol;
858
859          elsif Main_Kind = N_Subunit then
860             Write_Str (" (subunit)");
861             Write_Eol;
862
863          elsif Main_Kind = N_Subprogram_Declaration then
864             Write_Str (" (subprogram spec)");
865             Write_Eol;
866
867          --  Generic package body in GNAT implementation mode
868
869          elsif Main_Kind = N_Package_Body and then GNAT_Mode then
870             Write_Str (" (predefined generic)");
871             Write_Eol;
872
873          --  Only other case is a package spec
874
875          else
876             Write_Str (" (package spec)");
877             Write_Eol;
878          end if;
879
880          Set_Standard_Output;
881
882          Sem_Ch13.Validate_Unchecked_Conversions;
883          Sem_Ch13.Validate_Address_Clauses;
884          Sem_Ch13.Validate_Independence;
885          Errout.Finalize (Last_Call => True);
886          Errout.Output_Messages;
887          Treepr.Tree_Dump;
888          Tree_Gen;
889          Write_ALI (Object => False);
890          Namet.Finalize;
891          Check_Rep_Info;
892
893          --  Exit program with error indication, to kill object file
894
895          Exit_Program (E_No_Code);
896       end if;
897
898       --  In -gnatc mode, we only do annotation if -gnatt or -gnatR is also set
899       --  as indicated by Back_Annotate_Rep_Info being set to True.
900
901       --  We don't call for annotations on a subunit, because to process those
902       --  the back-end requires that the parent(s) be properly compiled.
903
904       --  Annotation is suppressed for targets where front-end layout is
905       --  enabled, because the front end determines representations.
906
907       --  Annotation is also suppressed in the case of compiling for a VM,
908       --  since representations are largely symbolic there.
909
910       if Back_End_Mode = Declarations_Only
911         and then (not (Back_Annotate_Rep_Info or Generate_SCIL)
912                    or else Main_Kind = N_Subunit
913                    or else Targparm.Frontend_Layout_On_Target
914                    or else Targparm.VM_Target /= No_VM)
915       then
916          Sem_Ch13.Validate_Unchecked_Conversions;
917          Sem_Ch13.Validate_Address_Clauses;
918          Sem_Ch13.Validate_Independence;
919          Errout.Finalize (Last_Call => True);
920          Errout.Output_Messages;
921          Write_ALI (Object => False);
922          Tree_Dump;
923          Tree_Gen;
924          Namet.Finalize;
925          Check_Rep_Info;
926          return;
927       end if;
928
929       --  Ensure that we properly register a dependency on system.ads, since
930       --  even if we do not semantically depend on this, Targparm has read
931       --  system parameters from the system.ads file.
932
933       Lib.Writ.Ensure_System_Dependency;
934
935       --  Add dependencies, if any, on preprocessing data file and on
936       --  preprocessing definition file(s).
937
938       Prepcomp.Add_Dependencies;
939
940       --  Back end needs to explicitly unlock tables it needs to touch
941
942       Atree.Lock;
943       Elists.Lock;
944       Fname.UF.Lock;
945       Inline.Lock;
946       Lib.Lock;
947       Nlists.Lock;
948       Sem.Lock;
949       Sinput.Lock;
950       Namet.Lock;
951       Stringt.Lock;
952
953       --  ???Check_Library_Items under control of a debug flag, because it
954       --  currently does not work if the -gnatn switch (back end inlining) is
955       --  used.
956
957       if Debug_Flag_Dot_WW then
958          Check_Library_Items;
959       end if;
960
961       --  Here we call the back end to generate the output code
962
963       Generating_Code := True;
964       Back_End.Call_Back_End (Back_End_Mode);
965
966       --  Once the backend is complete, we unlock the names table. This call
967       --  allows a few extra entries, needed for example for the file name for
968       --  the library file output.
969
970       Namet.Unlock;
971
972       --  Generate the call-graph output of dispatching calls
973
974       Exp_CG.Generate_CG_Output;
975
976       --  Validate unchecked conversions (using the values for size and
977       --  alignment annotated by the backend where possible).
978
979       Sem_Ch13.Validate_Unchecked_Conversions;
980
981       --  Validate address clauses (again using alignment values annotated
982       --  by the backend where possible).
983
984       Sem_Ch13.Validate_Address_Clauses;
985
986       --  Validate independence pragmas (again using values annotated by
987       --  the back end for component layout etc.)
988
989       Sem_Ch13.Validate_Independence;
990
991       --  Now we complete output of errors, rep info and the tree info. These
992       --  are delayed till now, since it is perfectly possible for gigi to
993       --  generate errors, modify the tree (in particular by setting flags
994       --  indicating that elaboration is required, and also to back annotate
995       --  representation information for List_Rep_Info.
996
997       Errout.Finalize (Last_Call => True);
998       Errout.Output_Messages;
999       List_Rep_Info;
1000
1001       --  Only write the library if the backend did not generate any error
1002       --  messages. Otherwise signal errors to the driver program so that
1003       --  there will be no attempt to generate an object file.
1004
1005       if Compilation_Errors then
1006          Treepr.Tree_Dump;
1007          Exit_Program (E_Errors);
1008       end if;
1009
1010       Write_ALI (Object => (Back_End_Mode = Generate_Object));
1011
1012       --  Generate ASIS tree after writing the ALI file, since in ASIS mode,
1013       --  Write_ALI may in fact result in further tree decoration from the
1014       --  original tree file. Note that we dump the tree just before generating
1015       --  it, so that the dump will exactly reflect what is written out.
1016
1017       Treepr.Tree_Dump;
1018       Tree_Gen;
1019
1020       --  Finalize name table and we are all done
1021
1022       Namet.Finalize;
1023
1024    exception
1025       --  Handle fatal internal compiler errors
1026
1027       when Rtsfind.RE_Not_Available =>
1028          Comperr.Compiler_Abort ("RE_Not_Available");
1029
1030       when System.Assertions.Assert_Failure =>
1031          Comperr.Compiler_Abort ("Assert_Failure");
1032
1033       when Constraint_Error =>
1034          Comperr.Compiler_Abort ("Constraint_Error");
1035
1036       when Program_Error =>
1037          Comperr.Compiler_Abort ("Program_Error");
1038
1039       when Storage_Error =>
1040
1041          --  Assume this is a bug. If it is real, the message will in any case
1042          --  say Storage_Error, giving a strong hint!
1043
1044          Comperr.Compiler_Abort ("Storage_Error");
1045    end;
1046
1047    <<End_Of_Program>>
1048    null;
1049
1050    --  The outer exception handles an unrecoverable error
1051
1052 exception
1053    when Unrecoverable_Error =>
1054       Errout.Finalize (Last_Call => True);
1055       Errout.Output_Messages;
1056
1057       Set_Standard_Error;
1058       Write_Str ("compilation abandoned");
1059       Write_Eol;
1060
1061       Set_Standard_Output;
1062       Source_Dump;
1063       Tree_Dump;
1064       Exit_Program (E_Errors);
1065
1066 end Gnat1drv;