gcc/ada/g-hesora.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                     G N A T . H E A P _ S O R T _ A                      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                     Copyright (C) 1995-2007, AdaCore                     --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 pragma Warnings (Off);
  35 pragma Compiler_Unit;
  36 pragma Warnings (On);
  37
  38 package body GNAT.Heap_Sort_A is
  39
  40    ----------
  41    -- Sort --
  42    ----------
  43
  44    --  We are using the classical heapsort algorithm (i.e. Floyd's Treesort3)
  45    --  as described by Knuth ("The Art of Programming", Volume III, first
  46    --  edition, section 5.2.3, p. 145-147) with the modification that is
  47    --  mentioned in exercise 18. For more details on this algorithm, see
  48    --  Robert B. K. Dewar PhD thesis "The use of Computers in the X-ray
  49    --  Phase Problem". University of Chicago, 1968, which was the first
  50    --  publication of the modification, which reduces the number of compares
  51    --  from 2NlogN to NlogN.
  52
  53    procedure Sort (N : Natural; Move : Move_Procedure; Lt : Lt_Function) is
  54
  55       Max : Natural := N;
  56       --  Current Max index in tree being sifted
  57
  58       procedure Sift (S : Positive);
  59       --  This procedure sifts up node S, i.e. converts the subtree rooted
  60       --  at node S into a heap, given the precondition that any sons of
  61       --  S are already heaps. On entry, the contents of node S is found
  62       --  in the temporary (index 0), the actual contents of node S on
  63       --  entry are irrelevant. This is just a minor optimization to avoid
  64       --  what would otherwise be two junk moves in phase two of the sort.
  65
  66       procedure Sift (S : Positive) is
  67          C      : Positive := S;
  68          Son    : Positive;
  69          Father : Positive;
  70
  71       begin
  72          --  This is where the optimization is done, normally we would do a
  73          --  comparison at each stage between the current node and the larger
  74          --  of the two sons, and continue the sift only if the current node
  75          --  was less than this maximum. In this modified optimized version,
  76          --  we assume that the current node will be less than the larger
  77          --  son, and unconditionally sift up. Then when we get to the bottom
  78          --  of the tree, we check parents to make sure that we did not make
  79          --  a mistake. This roughly cuts the number of comparisons in half,
  80          --  since it is almost always the case that our assumption is correct.
  81
  82          --  Loop to pull up larger sons
  83
  84          loop
  85             Son := 2 * C;
  86             exit when Son > Max;
  87
  88             if Son < Max and then Lt (Son, Son + 1) then
  89                Son := Son + 1;
  90             end if;
  91
  92             Move (Son, C);
  93             C := Son;
  94          end loop;
  95
  96          --  Loop to check fathers
  97
  98          while C /= S loop
  99             Father := C / 2;
 100
 101             if Lt (Father, 0) then
 102                Move (Father, C);
 103                C := Father;
 104             else
 105                exit;
 106             end if;
 107          end loop;
 108
 109          --  Last step is to pop the sifted node into place
 110
 111          Move (0, C);
 112       end Sift;
 113
 114    --  Start of processing for Sort
 115
 116    begin
 117       --  Phase one of heapsort is to build the heap. This is done by
 118       --  sifting nodes N/2 .. 1 in sequence.
 119
 120       for J in reverse 1 .. N / 2 loop
 121          Move (J, 0);
 122          Sift (J);
 123       end loop;
 124
 125       --  In phase 2, the largest node is moved to end, reducing the size
 126       --  of the tree by one, and the displaced node is sifted down from
 127       --  the top, so that the largest node is again at the top.
 128
 129       while Max > 1 loop
 130          Move (Max, 0);
 131          Move (1, Max);
 132          Max := Max - 1;
 133          Sift (1);
 134       end loop;
 135
 136    end Sort;
 137
 138 end GNAT.Heap_Sort_A;