gcc/ada/freeze.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               F R E E Z E                                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2011, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Einfo;    use Einfo;
  29 with Elists;   use Elists;
  30 with Errout;   use Errout;
  31 with Exp_Ch3;  use Exp_Ch3;
  32 with Exp_Ch7;  use Exp_Ch7;
  33 with Exp_Disp; use Exp_Disp;
  34 with Exp_Pakd; use Exp_Pakd;
  35 with Exp_Util; use Exp_Util;
  36 with Exp_Tss;  use Exp_Tss;
  37 with Layout;   use Layout;
  38 with Lib;      use Lib;
  39 with Namet;    use Namet;
  40 with Nlists;   use Nlists;
  41 with Nmake;    use Nmake;
  42 with Opt;      use Opt;
  43 with Restrict; use Restrict;
  44 with Rident;   use Rident;
  45 with Sem;      use Sem;
  46 with Sem_Aux;  use Sem_Aux;
  47 with Sem_Cat;  use Sem_Cat;
  48 with Sem_Ch6;  use Sem_Ch6;
  49 with Sem_Ch7;  use Sem_Ch7;
  50 with Sem_Ch8;  use Sem_Ch8;
  51 with Sem_Ch13; use Sem_Ch13;
  52 with Sem_Eval; use Sem_Eval;
  53 with Sem_Mech; use Sem_Mech;
  54 with Sem_Prag; use Sem_Prag;
  55 with Sem_Res;  use Sem_Res;
  56 with Sem_Util; use Sem_Util;
  57 with Sinfo;    use Sinfo;
  58 with Snames;   use Snames;
  59 with Stand;    use Stand;
  60 with Targparm; use Targparm;
  61 with Tbuild;   use Tbuild;
  62 with Ttypes;   use Ttypes;
  63 with Uintp;    use Uintp;
  64 with Urealp;   use Urealp;
  65
  66 package body Freeze is
  67
  68    -----------------------
  69    -- Local Subprograms --
  70    -----------------------
  71
  72    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id);
  73    --  Typ is a type that is being frozen. If no size clause is given,
  74    --  but a default Esize has been computed, then this default Esize is
  75    --  adjusted up if necessary to be consistent with a given alignment,
  76    --  but never to a value greater than Long_Long_Integer'Size. This
  77    --  is used for all discrete types and for fixed-point types.
  78
  79    procedure Build_And_Analyze_Renamed_Body
  80      (Decl  : Node_Id;
  81       New_S : Entity_Id;
  82       After : in out Node_Id);
  83    --  Build body for a renaming declaration, insert in tree and analyze
  84
  85    procedure Check_Address_Clause (E : Entity_Id);
  86    --  Apply legality checks to address clauses for object declarations,
  87    --  at the point the object is frozen.
  88
  89    procedure Check_Strict_Alignment (E : Entity_Id);
  90    --  E is a base type. If E is tagged or has a component that is aliased
  91    --  or tagged or contains something this is aliased or tagged, set
  92    --  Strict_Alignment.
  93
  94    procedure Check_Unsigned_Type (E : Entity_Id);
  95    pragma Inline (Check_Unsigned_Type);
  96    --  If E is a fixed-point or discrete type, then all the necessary work
  97    --  to freeze it is completed except for possible setting of the flag
  98    --  Is_Unsigned_Type, which is done by this procedure. The call has no
  99    --  effect if the entity E is not a discrete or fixed-point type.
 100
 101    procedure Freeze_And_Append
 102      (Ent    : Entity_Id;
 103       N      : Node_Id;
 104       Result : in out List_Id);
 105    --  Freezes Ent using Freeze_Entity, and appends the resulting list of
 106    --  nodes to Result, modifying Result from No_List if necessary. N has
 107    --  the same usage as in Freeze_Entity.
 108
 109    procedure Freeze_Enumeration_Type (Typ : Entity_Id);
 110    --  Freeze enumeration type. The Esize field is set as processing
 111    --  proceeds (i.e. set by default when the type is declared and then
 112    --  adjusted by rep clauses. What this procedure does is to make sure
 113    --  that if a foreign convention is specified, and no specific size
 114    --  is given, then the size must be at least Integer'Size.
 115
 116    procedure Freeze_Static_Object (E : Entity_Id);
 117    --  If an object is frozen which has Is_Statically_Allocated set, then
 118    --  all referenced types must also be marked with this flag. This routine
 119    --  is in charge of meeting this requirement for the object entity E.
 120
 121    procedure Freeze_Subprogram (E : Entity_Id);
 122    --  Perform freezing actions for a subprogram (create extra formals,
 123    --  and set proper default mechanism values). Note that this routine
 124    --  is not called for internal subprograms, for which neither of these
 125    --  actions is needed (or desirable, we do not want for example to have
 126    --  these extra formals present in initialization procedures, where they
 127    --  would serve no purpose). In this call E is either a subprogram or
 128    --  a subprogram type (i.e. an access to a subprogram).
 129
 130    function Is_Fully_Defined (T : Entity_Id) return Boolean;
 131    --  True if T is not private and has no private components, or has a full
 132    --  view. Used to determine whether the designated type of an access type
 133    --  should be frozen when the access type is frozen. This is done when an
 134    --  allocator is frozen, or an expression that may involve attributes of
 135    --  the designated type. Otherwise freezing the access type does not freeze
 136    --  the designated type.
 137
 138    procedure Process_Default_Expressions
 139      (E     : Entity_Id;
 140       After : in out Node_Id);
 141    --  This procedure is called for each subprogram to complete processing of
 142    --  default expressions at the point where all types are known to be frozen.
 143    --  The expressions must be analyzed in full, to make sure that all error
 144    --  processing is done (they have only been pre-analyzed). If the expression
 145    --  is not an entity or literal, its analysis may generate code which must
 146    --  not be executed. In that case we build a function body to hold that
 147    --  code. This wrapper function serves no other purpose (it used to be
 148    --  called to evaluate the default, but now the default is inlined at each
 149    --  point of call).
 150
 151    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id);
 152    --  Typ is a record or array type that is being frozen. This routine sets
 153    --  the default component alignment from the scope stack values if the
 154    --  alignment is otherwise not specified.
 155
 156    procedure Check_Debug_Info_Needed (T : Entity_Id);
 157    --  As each entity is frozen, this routine is called to deal with the
 158    --  setting of Debug_Info_Needed for the entity. This flag is set if
 159    --  the entity comes from source, or if we are in Debug_Generated_Code
 160    --  mode or if the -gnatdV debug flag is set. However, it never sets
 161    --  the flag if Debug_Info_Off is set. This procedure also ensures that
 162    --  subsidiary entities have the flag set as required.
 163
 164    procedure Undelay_Type (T : Entity_Id);
 165    --  T is a type of a component that we know to be an Itype. We don't want
 166    --  this to have a Freeze_Node, so ensure it doesn't. Do the same for any
 167    --  Full_View or Corresponding_Record_Type.
 168
 169    procedure Warn_Overlay
 170      (Expr : Node_Id;
 171       Typ  : Entity_Id;
 172       Nam  : Node_Id);
 173    --  Expr is the expression for an address clause for entity Nam whose type
 174    --  is Typ. If Typ has a default initialization, and there is no explicit
 175    --  initialization in the source declaration, check whether the address
 176    --  clause might cause overlaying of an entity, and emit a warning on the
 177    --  side effect that the initialization will cause.
 178
 179    -------------------------------
 180    -- Adjust_Esize_For_Alignment --
 181    -------------------------------
 182
 183    procedure Adjust_Esize_For_Alignment (Typ : Entity_Id) is
 184       Align : Uint;
 185
 186    begin
 187       if Known_Esize (Typ) and then Known_Alignment (Typ) then
 188          Align := Alignment_In_Bits (Typ);
 189
 190          if Align > Esize (Typ)
 191            and then Align <= Standard_Long_Long_Integer_Size
 192          then
 193             Set_Esize (Typ, Align);
 194          end if;
 195       end if;
 196    end Adjust_Esize_For_Alignment;
 197
 198    ------------------------------------
 199    -- Build_And_Analyze_Renamed_Body --
 200    ------------------------------------
 201
 202    procedure Build_And_Analyze_Renamed_Body
 203      (Decl  : Node_Id;
 204       New_S : Entity_Id;
 205       After : in out Node_Id)
 206    is
 207       Body_Decl    : constant Node_Id := Unit_Declaration_Node (New_S);
 208       Ent          : constant Entity_Id := Defining_Entity (Decl);
 209       Body_Node    : Node_Id;
 210       Renamed_Subp : Entity_Id;
 211
 212    begin
 213       --  If the renamed subprogram is intrinsic, there is no need for a
 214       --  wrapper body: we set the alias that will be called and expanded which
 215       --  completes the declaration. This transformation is only legal if the
 216       --  renamed entity has already been elaborated.
 217
 218       --  Note that it is legal for a renaming_as_body to rename an intrinsic
 219       --  subprogram, as long as the renaming occurs before the new entity
 220       --  is frozen. See RM 8.5.4 (5).
 221
 222       if Nkind (Body_Decl) = N_Subprogram_Renaming_Declaration
 223         and then Is_Entity_Name (Name (Body_Decl))
 224       then
 225          Renamed_Subp := Entity (Name (Body_Decl));
 226       else
 227          Renamed_Subp := Empty;
 228       end if;
 229
 230       if Present (Renamed_Subp)
 231         and then Is_Intrinsic_Subprogram (Renamed_Subp)
 232         and then
 233           (not In_Same_Source_Unit (Renamed_Subp, Ent)
 234             or else Sloc (Renamed_Subp) < Sloc (Ent))
 235
 236         --  We can make the renaming entity intrinsic if the renamed function
 237         --  has an interface name, or if it is one of the shift/rotate
 238         --  operations known to the compiler.
 239
 240         and then (Present (Interface_Name (Renamed_Subp))
 241                    or else Chars (Renamed_Subp) = Name_Rotate_Left
 242                    or else Chars (Renamed_Subp) = Name_Rotate_Right
 243                    or else Chars (Renamed_Subp) = Name_Shift_Left
 244                    or else Chars (Renamed_Subp) = Name_Shift_Right
 245                    or else Chars (Renamed_Subp) = Name_Shift_Right_Arithmetic)
 246       then
 247          Set_Interface_Name (Ent, Interface_Name (Renamed_Subp));
 248
 249          if Present (Alias (Renamed_Subp)) then
 250             Set_Alias (Ent, Alias (Renamed_Subp));
 251          else
 252             Set_Alias (Ent, Renamed_Subp);
 253          end if;
 254
 255          Set_Is_Intrinsic_Subprogram (Ent);
 256          Set_Has_Completion (Ent);
 257
 258       else
 259          Body_Node := Build_Renamed_Body (Decl, New_S);
 260          Insert_After (After, Body_Node);
 261          Mark_Rewrite_Insertion (Body_Node);
 262          Analyze (Body_Node);
 263          After := Body_Node;
 264       end if;
 265    end Build_And_Analyze_Renamed_Body;
 266
 267    ------------------------
 268    -- Build_Renamed_Body --
 269    ------------------------
 270
 271    function Build_Renamed_Body
 272      (Decl  : Node_Id;
 273       New_S : Entity_Id) return Node_Id
 274    is
 275       Loc : constant Source_Ptr := Sloc (New_S);
 276       --  We use for the source location of the renamed body, the location of
 277       --  the spec entity. It might seem more natural to use the location of
 278       --  the renaming declaration itself, but that would be wrong, since then
 279       --  the body we create would look as though it was created far too late,
 280       --  and this could cause problems with elaboration order analysis,
 281       --  particularly in connection with instantiations.
 282
 283       N          : constant Node_Id := Unit_Declaration_Node (New_S);
 284       Nam        : constant Node_Id := Name (N);
 285       Old_S      : Entity_Id;
 286       Spec       : constant Node_Id := New_Copy_Tree (Specification (Decl));
 287       Actuals    : List_Id := No_List;
 288       Call_Node  : Node_Id;
 289       Call_Name  : Node_Id;
 290       Body_Node  : Node_Id;
 291       Formal     : Entity_Id;
 292       O_Formal   : Entity_Id;
 293       Param_Spec : Node_Id;
 294
 295       Pref : Node_Id := Empty;
 296       --  If the renamed entity is a primitive operation given in prefix form,
 297       --  the prefix is the target object and it has to be added as the first
 298       --  actual in the generated call.
 299
 300    begin
 301       --  Determine the entity being renamed, which is the target of the call
 302       --  statement. If the name is an explicit dereference, this is a renaming
 303       --  of a subprogram type rather than a subprogram. The name itself is
 304       --  fully analyzed.
 305
 306       if Nkind (Nam) = N_Selected_Component then
 307          Old_S := Entity (Selector_Name (Nam));
 308
 309       elsif Nkind (Nam) = N_Explicit_Dereference then
 310          Old_S := Etype (Nam);
 311
 312       elsif Nkind (Nam) = N_Indexed_Component then
 313          if Is_Entity_Name (Prefix (Nam)) then
 314             Old_S := Entity (Prefix (Nam));
 315          else
 316             Old_S := Entity (Selector_Name (Prefix (Nam)));
 317          end if;
 318
 319       elsif Nkind (Nam) = N_Character_Literal then
 320          Old_S := Etype (New_S);
 321
 322       else
 323          Old_S := Entity (Nam);
 324       end if;
 325
 326       if Is_Entity_Name (Nam) then
 327
 328          --  If the renamed entity is a predefined operator, retain full name
 329          --  to ensure its visibility.
 330
 331          if Ekind (Old_S) = E_Operator
 332            and then Nkind (Nam) = N_Expanded_Name
 333          then
 334             Call_Name := New_Copy (Name (N));
 335          else
 336             Call_Name := New_Reference_To (Old_S, Loc);
 337          end if;
 338
 339       else
 340          if Nkind (Nam) = N_Selected_Component
 341            and then Present (First_Formal (Old_S))
 342            and then
 343              (Is_Controlling_Formal (First_Formal (Old_S))
 344                 or else Is_Class_Wide_Type (Etype (First_Formal (Old_S))))
 345          then
 346
 347             --  Retrieve the target object, to be added as a first actual
 348             --  in the call.
 349
 350             Call_Name := New_Occurrence_Of (Old_S, Loc);
 351             Pref := Prefix (Nam);
 352
 353          else
 354             Call_Name := New_Copy (Name (N));
 355          end if;
 356
 357          --  Original name may have been overloaded, but is fully resolved now
 358
 359          Set_Is_Overloaded (Call_Name, False);
 360       end if;
 361
 362       --  For simple renamings, subsequent calls can be expanded directly as
 363       --  calls to the renamed entity. The body must be generated in any case
 364       --  for calls that may appear elsewhere. This is not done in the case
 365       --  where the subprogram is an instantiation because the actual proper
 366       --  body has not been built yet.
 367
 368       if Ekind_In (Old_S, E_Function, E_Procedure)
 369         and then Nkind (Decl) = N_Subprogram_Declaration
 370         and then not Is_Generic_Instance (Old_S)
 371       then
 372          Set_Body_To_Inline (Decl, Old_S);
 373       end if;
 374
 375       --  The body generated for this renaming is an internal artifact, and
 376       --  does not  constitute a freeze point for the called entity.
 377
 378       Set_Must_Not_Freeze (Call_Name);
 379
 380       Formal := First_Formal (Defining_Entity (Decl));
 381
 382       if Present (Pref) then
 383          declare
 384             Pref_Type : constant Entity_Id := Etype (Pref);
 385             Form_Type : constant Entity_Id := Etype (First_Formal (Old_S));
 386
 387          begin
 388             --  The controlling formal may be an access parameter, or the
 389             --  actual may be an access value, so adjust accordingly.
 390
 391             if Is_Access_Type (Pref_Type)
 392               and then not Is_Access_Type (Form_Type)
 393             then
 394                Actuals := New_List
 395                  (Make_Explicit_Dereference (Loc, Relocate_Node (Pref)));
 396
 397             elsif Is_Access_Type (Form_Type)
 398               and then not Is_Access_Type (Pref)
 399             then
 400                Actuals := New_List
 401                  (Make_Attribute_Reference (Loc,
 402                    Attribute_Name => Name_Access,
 403                    Prefix => Relocate_Node (Pref)));
 404             else
 405                Actuals := New_List (Pref);
 406             end if;
 407          end;
 408
 409       elsif Present (Formal) then
 410          Actuals := New_List;
 411
 412       else
 413          Actuals := No_List;
 414       end if;
 415
 416       if Present (Formal) then
 417          while Present (Formal) loop
 418             Append (New_Reference_To (Formal, Loc), Actuals);
 419             Next_Formal (Formal);
 420          end loop;
 421       end if;
 422
 423       --  If the renamed entity is an entry, inherit its profile. For other
 424       --  renamings as bodies, both profiles must be subtype conformant, so it
 425       --  is not necessary to replace the profile given in the declaration.
 426       --  However, default values that are aggregates are rewritten when
 427       --  partially analyzed, so we recover the original aggregate to insure
 428       --  that subsequent conformity checking works. Similarly, if the default
 429       --  expression was constant-folded, recover the original expression.
 430
 431       Formal := First_Formal (Defining_Entity (Decl));
 432
 433       if Present (Formal) then
 434          O_Formal := First_Formal (Old_S);
 435          Param_Spec := First (Parameter_Specifications (Spec));
 436          while Present (Formal) loop
 437             if Is_Entry (Old_S) then
 438                if Nkind (Parameter_Type (Param_Spec)) /=
 439                                                     N_Access_Definition
 440                then
 441                   Set_Etype (Formal, Etype (O_Formal));
 442                   Set_Entity (Parameter_Type (Param_Spec), Etype (O_Formal));
 443                end if;
 444
 445             elsif Nkind (Default_Value (O_Formal)) = N_Aggregate
 446               or else Nkind (Original_Node (Default_Value (O_Formal))) /=
 447                                            Nkind (Default_Value (O_Formal))
 448             then
 449                Set_Expression (Param_Spec,
 450                  New_Copy_Tree (Original_Node (Default_Value (O_Formal))));
 451             end if;
 452
 453             Next_Formal (Formal);
 454             Next_Formal (O_Formal);
 455             Next (Param_Spec);
 456          end loop;
 457       end if;
 458
 459       --  If the renamed entity is a function, the generated body contains a
 460       --  return statement. Otherwise, build a procedure call. If the entity is
 461       --  an entry, subsequent analysis of the call will transform it into the
 462       --  proper entry or protected operation call. If the renamed entity is
 463       --  a character literal, return it directly.
 464
 465       if Ekind (Old_S) = E_Function
 466         or else Ekind (Old_S) = E_Operator
 467         or else (Ekind (Old_S) = E_Subprogram_Type
 468                   and then Etype (Old_S) /= Standard_Void_Type)
 469       then
 470          Call_Node :=
 471            Make_Simple_Return_Statement (Loc,
 472               Expression =>
 473                 Make_Function_Call (Loc,
 474                   Name => Call_Name,
 475                   Parameter_Associations => Actuals));
 476
 477       elsif Ekind (Old_S) = E_Enumeration_Literal then
 478          Call_Node :=
 479            Make_Simple_Return_Statement (Loc,
 480               Expression => New_Occurrence_Of (Old_S, Loc));
 481
 482       elsif Nkind (Nam) = N_Character_Literal then
 483          Call_Node :=
 484            Make_Simple_Return_Statement (Loc,
 485              Expression => Call_Name);
 486
 487       else
 488          Call_Node :=
 489            Make_Procedure_Call_Statement (Loc,
 490              Name => Call_Name,
 491              Parameter_Associations => Actuals);
 492       end if;
 493
 494       --  Create entities for subprogram body and formals
 495
 496       Set_Defining_Unit_Name (Spec,
 497         Make_Defining_Identifier (Loc, Chars => Chars (New_S)));
 498
 499       Param_Spec := First (Parameter_Specifications (Spec));
 500       while Present (Param_Spec) loop
 501          Set_Defining_Identifier (Param_Spec,
 502            Make_Defining_Identifier (Loc,
 503              Chars => Chars (Defining_Identifier (Param_Spec))));
 504          Next (Param_Spec);
 505       end loop;
 506
 507       Body_Node :=
 508         Make_Subprogram_Body (Loc,
 509           Specification => Spec,
 510           Declarations => New_List,
 511           Handled_Statement_Sequence =>
 512             Make_Handled_Sequence_Of_Statements (Loc,
 513               Statements => New_List (Call_Node)));
 514
 515       if Nkind (Decl) /= N_Subprogram_Declaration then
 516          Rewrite (N,
 517            Make_Subprogram_Declaration (Loc,
 518              Specification => Specification (N)));
 519       end if;
 520
 521       --  Link the body to the entity whose declaration it completes. If
 522       --  the body is analyzed when the renamed entity is frozen, it may
 523       --  be necessary to restore the proper scope (see package Exp_Ch13).
 524
 525       if Nkind (N) =  N_Subprogram_Renaming_Declaration
 526         and then Present (Corresponding_Spec (N))
 527       then
 528          Set_Corresponding_Spec (Body_Node, Corresponding_Spec (N));
 529       else
 530          Set_Corresponding_Spec (Body_Node, New_S);
 531       end if;
 532
 533       return Body_Node;
 534    end Build_Renamed_Body;
 535
 536    --------------------------
 537    -- Check_Address_Clause --
 538    --------------------------
 539
 540    procedure Check_Address_Clause (E : Entity_Id) is
 541       Addr : constant Node_Id   := Address_Clause (E);
 542       Expr : Node_Id;
 543       Decl : constant Node_Id   := Declaration_Node (E);
 544       Typ  : constant Entity_Id := Etype (E);
 545
 546    begin
 547       if Present (Addr) then
 548          Expr := Expression (Addr);
 549
 550          if Needs_Constant_Address (Decl, Typ) then
 551             Check_Constant_Address_Clause (Expr, E);
 552
 553             --  Has_Delayed_Freeze was set on E when the address clause was
 554             --  analyzed. Reset the flag now unless freeze actions were
 555             --  attached to it in the mean time.
 556
 557             if No (Freeze_Node (E)) then
 558                Set_Has_Delayed_Freeze (E, False);
 559             end if;
 560          end if;
 561
 562          --  If Rep_Clauses are to be ignored, remove address clause from
 563          --  list attached to entity, because it may be illegal for gigi,
 564          --  for example by breaking order of elaboration..
 565
 566          if Ignore_Rep_Clauses then
 567             declare
 568                Rep : Node_Id;
 569
 570             begin
 571                Rep := First_Rep_Item (E);
 572
 573                if Rep = Addr then
 574                   Set_First_Rep_Item (E, Next_Rep_Item (Addr));
 575
 576                else
 577                   while Present (Rep)
 578                     and then Next_Rep_Item (Rep) /= Addr
 579                   loop
 580                      Rep := Next_Rep_Item (Rep);
 581                   end loop;
 582                end if;
 583
 584                if Present (Rep) then
 585                   Set_Next_Rep_Item (Rep, Next_Rep_Item (Addr));
 586                end if;
 587             end;
 588
 589             Rewrite (Addr, Make_Null_Statement (Sloc (E)));
 590
 591          elsif not Error_Posted (Expr)
 592            and then not Needs_Finalization (Typ)
 593          then
 594             Warn_Overlay (Expr, Typ, Name (Addr));
 595          end if;
 596       end if;
 597    end Check_Address_Clause;
 598
 599    -----------------------------
 600    -- Check_Compile_Time_Size --
 601    -----------------------------
 602
 603    procedure Check_Compile_Time_Size (T : Entity_Id) is
 604
 605       procedure Set_Small_Size (T : Entity_Id; S : Uint);
 606       --  Sets the compile time known size (32 bits or less) in the Esize
 607       --  field, of T checking for a size clause that was given which attempts
 608       --  to give a smaller size, and also checking for an alignment clause.
 609
 610       function Size_Known (T : Entity_Id) return Boolean;
 611       --  Recursive function that does all the work
 612
 613       function Static_Discriminated_Components (T : Entity_Id) return Boolean;
 614       --  If T is a constrained subtype, its size is not known if any of its
 615       --  discriminant constraints is not static and it is not a null record.
 616       --  The test is conservative and doesn't check that the components are
 617       --  in fact constrained by non-static discriminant values. Could be made
 618       --  more precise ???
 619
 620       --------------------
 621       -- Set_Small_Size --
 622       --------------------
 623
 624       procedure Set_Small_Size (T : Entity_Id; S : Uint) is
 625       begin
 626          if S > 32 then
 627             return;
 628
 629          --  Check for bad size clause given
 630
 631          elsif Has_Size_Clause (T) then
 632             if RM_Size (T) < S then
 633                Error_Msg_Uint_1 := S;
 634                Error_Msg_NE
 635                  ("size for& too small, minimum allowed is ^",
 636                   Size_Clause (T), T);
 637             end if;
 638
 639          --  Set size if not set already
 640
 641          elsif Unknown_RM_Size (T) then
 642             Set_RM_Size (T, S);
 643          end if;
 644       end Set_Small_Size;
 645
 646       ----------------
 647       -- Size_Known --
 648       ----------------
 649
 650       function Size_Known (T : Entity_Id) return Boolean is
 651          Index : Entity_Id;
 652          Comp  : Entity_Id;
 653          Ctyp  : Entity_Id;
 654          Low   : Node_Id;
 655          High  : Node_Id;
 656
 657       begin
 658          if Size_Known_At_Compile_Time (T) then
 659             return True;
 660
 661          --  Always True for scalar types. This is true even for generic formal
 662          --  scalar types. We used to return False in the latter case, but the
 663          --  size is known at compile time, even in the template, we just do
 664          --  not know the exact size but that's not the point of this routine.
 665
 666          elsif Is_Scalar_Type (T)
 667            or else Is_Task_Type (T)
 668          then
 669             return True;
 670
 671          --  Array types
 672
 673          elsif Is_Array_Type (T) then
 674
 675             --  String literals always have known size, and we can set it
 676
 677             if Ekind (T) = E_String_Literal_Subtype then
 678                Set_Small_Size (T, Component_Size (T)
 679                                * String_Literal_Length (T));
 680                return True;
 681
 682             --  Unconstrained types never have known at compile time size
 683
 684             elsif not Is_Constrained (T) then
 685                return False;
 686
 687             --  Don't do any recursion on type with error posted, since we may
 688             --  have a malformed type that leads us into a loop.
 689
 690             elsif Error_Posted (T) then
 691                return False;
 692
 693             --  Otherwise if component size unknown, then array size unknown
 694
 695             elsif not Size_Known (Component_Type (T)) then
 696                return False;
 697             end if;
 698
 699             --  Check for all indexes static, and also compute possible size
 700             --  (in case it is less than 32 and may be packable).
 701
 702             declare
 703                Esiz : Uint := Component_Size (T);
 704                Dim  : Uint;
 705
 706             begin
 707                Index := First_Index (T);
 708                while Present (Index) loop
 709                   if Nkind (Index) = N_Range then
 710                      Get_Index_Bounds (Index, Low, High);
 711
 712                   elsif Error_Posted (Scalar_Range (Etype (Index))) then
 713                      return False;
 714
 715                   else
 716                      Low  := Type_Low_Bound (Etype (Index));
 717                      High := Type_High_Bound (Etype (Index));
 718                   end if;
 719
 720                   if not Compile_Time_Known_Value (Low)
 721                     or else not Compile_Time_Known_Value (High)
 722                     or else Etype (Index) = Any_Type
 723                   then
 724                      return False;
 725
 726                   else
 727                      Dim := Expr_Value (High) - Expr_Value (Low) + 1;
 728
 729                      if Dim >= 0 then
 730                         Esiz := Esiz * Dim;
 731                      else
 732                         Esiz := Uint_0;
 733                      end if;
 734                   end if;
 735
 736                   Next_Index (Index);
 737                end loop;
 738
 739                Set_Small_Size (T, Esiz);
 740                return True;
 741             end;
 742
 743          --  Access types always have known at compile time sizes
 744
 745          elsif Is_Access_Type (T) then
 746             return True;
 747
 748          --  For non-generic private types, go to underlying type if present
 749
 750          elsif Is_Private_Type (T)
 751            and then not Is_Generic_Type (T)
 752            and then Present (Underlying_Type (T))
 753          then
 754             --  Don't do any recursion on type with error posted, since we may
 755             --  have a malformed type that leads us into a loop.
 756
 757             if Error_Posted (T) then
 758                return False;
 759             else
 760                return Size_Known (Underlying_Type (T));
 761             end if;
 762
 763          --  Record types
 764
 765          elsif Is_Record_Type (T) then
 766
 767             --  A class-wide type is never considered to have a known size
 768
 769             if Is_Class_Wide_Type (T) then
 770                return False;
 771
 772             --  A subtype of a variant record must not have non-static
 773             --  discriminated components.
 774
 775             elsif T /= Base_Type (T)
 776               and then not Static_Discriminated_Components (T)
 777             then
 778                return False;
 779
 780             --  Don't do any recursion on type with error posted, since we may
 781             --  have a malformed type that leads us into a loop.
 782
 783             elsif Error_Posted (T) then
 784                return False;
 785             end if;
 786
 787             --  Now look at the components of the record
 788
 789             declare
 790                --  The following two variables are used to keep track of the
 791                --  size of packed records if we can tell the size of the packed
 792                --  record in the front end. Packed_Size_Known is True if so far
 793                --  we can figure out the size. It is initialized to True for a
 794                --  packed record, unless the record has discriminants. The
 795                --  reason we eliminate the discriminated case is that we don't
 796                --  know the way the back end lays out discriminated packed
 797                --  records. If Packed_Size_Known is True, then Packed_Size is
 798                --  the size in bits so far.
 799
 800                Packed_Size_Known : Boolean :=
 801                                      Is_Packed (T)
 802                                        and then not Has_Discriminants (T);
 803
 804                Packed_Size : Uint := Uint_0;
 805
 806             begin
 807                --  Test for variant part present
 808
 809                if Has_Discriminants (T)
 810                  and then Present (Parent (T))
 811                  and then Nkind (Parent (T)) = N_Full_Type_Declaration
 812                  and then Nkind (Type_Definition (Parent (T))) =
 813                                                N_Record_Definition
 814                  and then not Null_Present (Type_Definition (Parent (T)))
 815                  and then Present (Variant_Part
 816                             (Component_List (Type_Definition (Parent (T)))))
 817                then
 818                   --  If variant part is present, and type is unconstrained,
 819                   --  then we must have defaulted discriminants, or a size
 820                   --  clause must be present for the type, or else the size
 821                   --  is definitely not known at compile time.
 822
 823                   if not Is_Constrained (T)
 824                     and then
 825                       No (Discriminant_Default_Value (First_Discriminant (T)))
 826                     and then Unknown_RM_Size (T)
 827                   then
 828                      return False;
 829                   end if;
 830                end if;
 831
 832                --  Loop through components
 833
 834                Comp := First_Component_Or_Discriminant (T);
 835                while Present (Comp) loop
 836                   Ctyp := Etype (Comp);
 837
 838                   --  We do not know the packed size if there is a component
 839                   --  clause present (we possibly could, but this would only
 840                   --  help in the case of a record with partial rep clauses.
 841                   --  That's because in the case of full rep clauses, the
 842                   --  size gets figured out anyway by a different circuit).
 843
 844                   if Present (Component_Clause (Comp)) then
 845                      Packed_Size_Known := False;
 846                   end if;
 847
 848                   --  We need to identify a component that is an array where
 849                   --  the index type is an enumeration type with non-standard
 850                   --  representation, and some bound of the type depends on a
 851                   --  discriminant.
 852
 853                   --  This is because gigi computes the size by doing a
 854                   --  substitution of the appropriate discriminant value in
 855                   --  the size expression for the base type, and gigi is not
 856                   --  clever enough to evaluate the resulting expression (which
 857                   --  involves a call to rep_to_pos) at compile time.
 858
 859                   --  It would be nice if gigi would either recognize that
 860                   --  this expression can be computed at compile time, or
 861                   --  alternatively figured out the size from the subtype
 862                   --  directly, where all the information is at hand ???
 863
 864                   if Is_Array_Type (Etype (Comp))
 865                     and then Present (Packed_Array_Type (Etype (Comp)))
 866                   then
 867                      declare
 868                         Ocomp  : constant Entity_Id :=
 869                                    Original_Record_Component (Comp);
 870                         OCtyp  : constant Entity_Id := Etype (Ocomp);
 871                         Ind    : Node_Id;
 872                         Indtyp : Entity_Id;
 873                         Lo, Hi : Node_Id;
 874
 875                      begin
 876                         Ind := First_Index (OCtyp);
 877                         while Present (Ind) loop
 878                            Indtyp := Etype (Ind);
 879
 880                            if Is_Enumeration_Type (Indtyp)
 881                              and then Has_Non_Standard_Rep (Indtyp)
 882                            then
 883                               Lo := Type_Low_Bound  (Indtyp);
 884                               Hi := Type_High_Bound (Indtyp);
 885
 886                               if Is_Entity_Name (Lo)
 887                                 and then Ekind (Entity (Lo)) = E_Discriminant
 888                               then
 889                                  return False;
 890
 891                               elsif Is_Entity_Name (Hi)
 892                                 and then Ekind (Entity (Hi)) = E_Discriminant
 893                               then
 894                                  return False;
 895                               end if;
 896                            end if;
 897
 898                            Next_Index (Ind);
 899                         end loop;
 900                      end;
 901                   end if;
 902
 903                   --  Clearly size of record is not known if the size of one of
 904                   --  the components is not known.
 905
 906                   if not Size_Known (Ctyp) then
 907                      return False;
 908                   end if;
 909
 910                   --  Accumulate packed size if possible
 911
 912                   if Packed_Size_Known then
 913
 914                      --  We can only deal with elementary types, since for
 915                      --  non-elementary components, alignment enters into the
 916                      --  picture, and we don't know enough to handle proper
 917                      --  alignment in this context. Packed arrays count as
 918                      --  elementary if the representation is a modular type.
 919
 920                      if Is_Elementary_Type (Ctyp)
 921                        or else (Is_Array_Type (Ctyp)
 922                                  and then Present (Packed_Array_Type (Ctyp))
 923                                  and then Is_Modular_Integer_Type
 924                                             (Packed_Array_Type (Ctyp)))
 925                      then
 926                         --  If RM_Size is known and static, then we can keep
 927                         --  accumulating the packed size.
 928
 929                         if Known_Static_RM_Size (Ctyp) then
 930
 931                            --  A little glitch, to be removed sometime ???
 932                            --  gigi does not understand zero sizes yet.
 933
 934                            if RM_Size (Ctyp) = Uint_0 then
 935                               Packed_Size_Known := False;
 936
 937                            --  Normal case where we can keep accumulating the
 938                            --  packed array size.
 939
 940                            else
 941                               Packed_Size := Packed_Size + RM_Size (Ctyp);
 942                            end if;
 943
 944                         --  If we have a field whose RM_Size is not known then
 945                         --  we can't figure out the packed size here.
 946
 947                         else
 948                            Packed_Size_Known := False;
 949                         end if;
 950
 951                      --  If we have a non-elementary type we can't figure out
 952                      --  the packed array size (alignment issues).
 953
 954                      else
 955                         Packed_Size_Known := False;
 956                      end if;
 957                   end if;
 958
 959                   Next_Component_Or_Discriminant (Comp);
 960                end loop;
 961
 962                if Packed_Size_Known then
 963                   Set_Small_Size (T, Packed_Size);
 964                end if;
 965
 966                return True;
 967             end;
 968
 969          --  All other cases, size not known at compile time
 970
 971          else
 972             return False;
 973          end if;
 974       end Size_Known;
 975
 976       -------------------------------------
 977       -- Static_Discriminated_Components --
 978       -------------------------------------
 979
 980       function Static_Discriminated_Components
 981         (T : Entity_Id) return Boolean
 982       is
 983          Constraint : Elmt_Id;
 984
 985       begin
 986          if Has_Discriminants (T)
 987            and then Present (Discriminant_Constraint (T))
 988            and then Present (First_Component (T))
 989          then
 990             Constraint := First_Elmt (Discriminant_Constraint (T));
 991             while Present (Constraint) loop
 992                if not Compile_Time_Known_Value (Node (Constraint)) then
 993                   return False;
 994                end if;
 995
 996                Next_Elmt (Constraint);
 997             end loop;
 998          end if;
 999
1000          return True;
1001       end Static_Discriminated_Components;
1002
1003    --  Start of processing for Check_Compile_Time_Size
1004
1005    begin
1006       Set_Size_Known_At_Compile_Time (T, Size_Known (T));
1007    end Check_Compile_Time_Size;
1008
1009    -----------------------------
1010    -- Check_Debug_Info_Needed --
1011    -----------------------------
1012
1013    procedure Check_Debug_Info_Needed (T : Entity_Id) is
1014    begin
1015       if Debug_Info_Off (T) then
1016          return;
1017
1018       elsif Comes_From_Source (T)
1019         or else Debug_Generated_Code
1020         or else Debug_Flag_VV
1021         or else Needs_Debug_Info (T)
1022       then
1023          Set_Debug_Info_Needed (T);
1024       end if;
1025    end Check_Debug_Info_Needed;
1026
1027    ----------------------------
1028    -- Check_Strict_Alignment --
1029    ----------------------------
1030
1031    procedure Check_Strict_Alignment (E : Entity_Id) is
1032       Comp  : Entity_Id;
1033
1034    begin
1035       if Is_Tagged_Type (E) or else Is_Concurrent_Type (E) then
1036          Set_Strict_Alignment (E);
1037
1038       elsif Is_Array_Type (E) then
1039          Set_Strict_Alignment (E, Strict_Alignment (Component_Type (E)));
1040
1041       elsif Is_Record_Type (E) then
1042          if Is_Limited_Record (E) then
1043             Set_Strict_Alignment (E);
1044             return;
1045          end if;
1046
1047          Comp := First_Component (E);
1048          while Present (Comp) loop
1049             if not Is_Type (Comp)
1050               and then (Strict_Alignment (Etype (Comp))
1051                          or else Is_Aliased (Comp))
1052             then
1053                Set_Strict_Alignment (E);
1054                return;
1055             end if;
1056
1057             Next_Component (Comp);
1058          end loop;
1059       end if;
1060    end Check_Strict_Alignment;
1061
1062    -------------------------
1063    -- Check_Unsigned_Type --
1064    -------------------------
1065
1066    procedure Check_Unsigned_Type (E : Entity_Id) is
1067       Ancestor : Entity_Id;
1068       Lo_Bound : Node_Id;
1069       Btyp     : Entity_Id;
1070
1071    begin
1072       if not Is_Discrete_Or_Fixed_Point_Type (E) then
1073          return;
1074       end if;
1075
1076       --  Do not attempt to analyze case where range was in error
1077
1078       if No (Scalar_Range (E))
1079         or else Error_Posted (Scalar_Range (E))
1080       then
1081          return;
1082       end if;
1083
1084       --  The situation that is non trivial is something like
1085
1086       --     subtype x1 is integer range -10 .. +10;
1087       --     subtype x2 is x1 range 0 .. V1;
1088       --     subtype x3 is x2 range V2 .. V3;
1089       --     subtype x4 is x3 range V4 .. V5;
1090
1091       --  where Vn are variables. Here the base type is signed, but we still
1092       --  know that x4 is unsigned because of the lower bound of x2.
1093
1094       --  The only way to deal with this is to look up the ancestor chain
1095
1096       Ancestor := E;
1097       loop
1098          if Ancestor = Any_Type or else Etype (Ancestor) = Any_Type then
1099             return;
1100          end if;
1101
1102          Lo_Bound := Type_Low_Bound (Ancestor);
1103
1104          if Compile_Time_Known_Value (Lo_Bound) then
1105
1106             if Expr_Rep_Value (Lo_Bound) >= 0 then
1107                Set_Is_Unsigned_Type (E, True);
1108             end if;
1109
1110             return;
1111
1112          else
1113             Ancestor := Ancestor_Subtype (Ancestor);
1114
1115             --  If no ancestor had a static lower bound, go to base type
1116
1117             if No (Ancestor) then
1118
1119                --  Note: the reason we still check for a compile time known
1120                --  value for the base type is that at least in the case of
1121                --  generic formals, we can have bounds that fail this test,
1122                --  and there may be other cases in error situations.
1123
1124                Btyp := Base_Type (E);
1125
1126                if Btyp = Any_Type or else Etype (Btyp) = Any_Type then
1127                   return;
1128                end if;
1129
1130                Lo_Bound := Type_Low_Bound (Base_Type (E));
1131
1132                if Compile_Time_Known_Value (Lo_Bound)
1133                  and then Expr_Rep_Value (Lo_Bound) >= 0
1134                then
1135                   Set_Is_Unsigned_Type (E, True);
1136                end if;
1137
1138                return;
1139             end if;
1140          end if;
1141       end loop;
1142    end Check_Unsigned_Type;
1143
1144    -------------------------
1145    -- Is_Atomic_Aggregate --
1146    -------------------------
1147
1148    function  Is_Atomic_Aggregate
1149      (E   : Entity_Id;
1150       Typ : Entity_Id) return Boolean
1151    is
1152       Loc   : constant Source_Ptr := Sloc (E);
1153       New_N : Node_Id;
1154       Par   : Node_Id;
1155       Temp  : Entity_Id;
1156
1157    begin
1158       Par := Parent (E);
1159
1160       --  Array may be qualified, so find outer context
1161
1162       if Nkind (Par) = N_Qualified_Expression then
1163          Par := Parent (Par);
1164       end if;
1165
1166       if Nkind_In (Par, N_Object_Declaration, N_Assignment_Statement)
1167         and then Comes_From_Source (Par)
1168       then
1169          Temp := Make_Temporary (Loc, 'T', E);
1170          New_N :=
1171            Make_Object_Declaration (Loc,
1172              Defining_Identifier => Temp,
1173              Object_Definition   => New_Occurrence_Of (Typ, Loc),
1174              Expression          => Relocate_Node (E));
1175          Insert_Before (Par, New_N);
1176          Analyze (New_N);
1177
1178          Set_Expression (Par, New_Occurrence_Of (Temp, Loc));
1179          return True;
1180
1181       else
1182          return False;
1183       end if;
1184    end Is_Atomic_Aggregate;
1185
1186    ----------------
1187    -- Freeze_All --
1188    ----------------
1189
1190    --  Note: the easy coding for this procedure would be to just build a
1191    --  single list of freeze nodes and then insert them and analyze them
1192    --  all at once. This won't work, because the analysis of earlier freeze
1193    --  nodes may recursively freeze types which would otherwise appear later
1194    --  on in the freeze list. So we must analyze and expand the freeze nodes
1195    --  as they are generated.
1196
1197    procedure Freeze_All (From : Entity_Id; After : in out Node_Id) is
1198       E     : Entity_Id;
1199       Decl  : Node_Id;
1200
1201       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id);
1202       --  This is the internal recursive routine that does freezing of entities
1203       --  (but NOT the analysis of default expressions, which should not be
1204       --  recursive, we don't want to analyze those till we are sure that ALL
1205       --  the types are frozen).
1206
1207       --------------------
1208       -- Freeze_All_Ent --
1209       --------------------
1210
1211       procedure Freeze_All_Ent (From : Entity_Id; After : in out Node_Id) is
1212          E     : Entity_Id;
1213          Flist : List_Id;
1214          Lastn : Node_Id;
1215
1216          procedure Process_Flist;
1217          --  If freeze nodes are present, insert and analyze, and reset cursor
1218          --  for next insertion.
1219
1220          -------------------
1221          -- Process_Flist --
1222          -------------------
1223
1224          procedure Process_Flist is
1225          begin
1226             if Is_Non_Empty_List (Flist) then
1227                Lastn := Next (After);
1228                Insert_List_After_And_Analyze (After, Flist);
1229
1230                if Present (Lastn) then
1231                   After := Prev (Lastn);
1232                else
1233                   After := Last (List_Containing (After));
1234                end if;
1235             end if;
1236          end Process_Flist;
1237
1238       --  Start or processing for Freeze_All_Ent
1239
1240       begin
1241          E := From;
1242          while Present (E) loop
1243
1244             --  If the entity is an inner package which is not a package
1245             --  renaming, then its entities must be frozen at this point. Note
1246             --  that such entities do NOT get frozen at the end of the nested
1247             --  package itself (only library packages freeze).
1248
1249             --  Same is true for task declarations, where anonymous records
1250             --  created for entry parameters must be frozen.
1251
1252             if Ekind (E) = E_Package
1253               and then No (Renamed_Object (E))
1254               and then not Is_Child_Unit (E)
1255               and then not Is_Frozen (E)
1256             then
1257                Push_Scope (E);
1258                Install_Visible_Declarations (E);
1259                Install_Private_Declarations (E);
1260
1261                Freeze_All (First_Entity (E), After);
1262
1263                End_Package_Scope (E);
1264
1265                if Is_Generic_Instance (E)
1266                  and then Has_Delayed_Freeze (E)
1267                then
1268                   Set_Has_Delayed_Freeze (E, False);
1269                   Expand_N_Package_Declaration (Unit_Declaration_Node (E));
1270                end if;
1271
1272             elsif Ekind (E) in Task_Kind
1273               and then
1274                 (Nkind (Parent (E)) = N_Task_Type_Declaration
1275                    or else
1276                  Nkind (Parent (E)) = N_Single_Task_Declaration)
1277             then
1278                Push_Scope (E);
1279                Freeze_All (First_Entity (E), After);
1280                End_Scope;
1281
1282             --  For a derived tagged type, we must ensure that all the
1283             --  primitive operations of the parent have been frozen, so that
1284             --  their addresses will be in the parent's dispatch table at the
1285             --  point it is inherited.
1286
1287             elsif Ekind (E) = E_Record_Type
1288               and then Is_Tagged_Type (E)
1289               and then Is_Tagged_Type (Etype (E))
1290               and then Is_Derived_Type (E)
1291             then
1292                declare
1293                   Prim_List : constant Elist_Id :=
1294                                Primitive_Operations (Etype (E));
1295
1296                   Prim : Elmt_Id;
1297                   Subp : Entity_Id;
1298
1299                begin
1300                   Prim := First_Elmt (Prim_List);
1301                   while Present (Prim) loop
1302                      Subp := Node (Prim);
1303
1304                      if Comes_From_Source (Subp)
1305                        and then not Is_Frozen (Subp)
1306                      then
1307                         Flist := Freeze_Entity (Subp, After);
1308                         Process_Flist;
1309                      end if;
1310
1311                      Next_Elmt (Prim);
1312                   end loop;
1313                end;
1314             end if;
1315
1316             if not Is_Frozen (E) then
1317                Flist := Freeze_Entity (E, After);
1318                Process_Flist;
1319
1320             --  If already frozen, and there are delayed aspects, this is where
1321             --  we do the visibility check for these aspects (see Sem_Ch13 spec
1322             --  for a description of how we handle aspect visibility).
1323
1324             elsif Has_Delayed_Aspects (E) then
1325                declare
1326                   Ritem : Node_Id;
1327
1328                begin
1329                   Ritem := First_Rep_Item (E);
1330                   while Present (Ritem) loop
1331                      if Nkind (Ritem) = N_Aspect_Specification
1332                        and then Entity (Ritem) = E
1333                        and then Is_Delayed_Aspect (Ritem)
1334                      then
1335                         Check_Aspect_At_End_Of_Declarations (Ritem);
1336                      end if;
1337
1338                      Ritem := Next_Rep_Item (Ritem);
1339                   end loop;
1340                end;
1341             end if;
1342
1343             --  If an incomplete type is still not frozen, this may be a
1344             --  premature freezing because of a body declaration that follows.
1345             --  Indicate where the freezing took place. Freezing will happen
1346             --  if the body comes from source, but not if it is internally
1347             --  generated, for example as the body of a type invariant.
1348
1349             --  If the freezing is caused by the end of the current declarative
1350             --  part, it is a Taft Amendment type, and there is no error.
1351
1352             if not Is_Frozen (E)
1353               and then Ekind (E) = E_Incomplete_Type
1354             then
1355                declare
1356                   Bod : constant Node_Id := Next (After);
1357
1358                begin
1359                   --  The presence of a body freezes all entities previously
1360                   --  declared in the current list of declarations, but this
1361                   --  does not apply if the body does not come from source.
1362                   --  A type invariant is transformed into a subprogram body
1363                   --  which is placed at the end of the private part of the
1364                   --  current package, but this body does not freeze incomplete
1365                   --  types that may be declared in this private part.
1366
1367                   if (Nkind_In (Bod, N_Subprogram_Body,
1368                                      N_Entry_Body,
1369                                      N_Package_Body,
1370                                      N_Protected_Body,
1371                                      N_Task_Body)
1372                         or else Nkind (Bod) in N_Body_Stub)
1373                     and then
1374                       List_Containing (After) = List_Containing (Parent (E))
1375                     and then Comes_From_Source (Bod)
1376                   then
1377                      Error_Msg_Sloc := Sloc (Next (After));
1378                      Error_Msg_NE
1379                        ("type& is frozen# before its full declaration",
1380                          Parent (E), E);
1381                   end if;
1382                end;
1383             end if;
1384
1385             Next_Entity (E);
1386          end loop;
1387       end Freeze_All_Ent;
1388
1389    --  Start of processing for Freeze_All
1390
1391    begin
1392       Freeze_All_Ent (From, After);
1393
1394       --  Now that all types are frozen, we can deal with default expressions
1395       --  that require us to build a default expression functions. This is the
1396       --  point at which such functions are constructed (after all types that
1397       --  might be used in such expressions have been frozen).
1398
1399       --  For subprograms that are renaming_as_body, we create the wrapper
1400       --  bodies as needed.
1401
1402       --  We also add finalization chains to access types whose designated
1403       --  types are controlled. This is normally done when freezing the type,
1404       --  but this misses recursive type definitions where the later members
1405       --  of the recursion introduce controlled components.
1406
1407       --  Loop through entities
1408
1409       E := From;
1410       while Present (E) loop
1411          if Is_Subprogram (E) then
1412
1413             if not Default_Expressions_Processed (E) then
1414                Process_Default_Expressions (E, After);
1415             end if;
1416
1417             if not Has_Completion (E) then
1418                Decl := Unit_Declaration_Node (E);
1419
1420                if Nkind (Decl) = N_Subprogram_Renaming_Declaration then
1421                   if Error_Posted (Decl) then
1422                      Set_Has_Completion (E);
1423                   else
1424                      Build_And_Analyze_Renamed_Body (Decl, E, After);
1425                   end if;
1426
1427                elsif Nkind (Decl) = N_Subprogram_Declaration
1428                  and then Present (Corresponding_Body (Decl))
1429                  and then
1430                    Nkind (Unit_Declaration_Node (Corresponding_Body (Decl)))
1431                                           = N_Subprogram_Renaming_Declaration
1432                then
1433                   Build_And_Analyze_Renamed_Body
1434                     (Decl, Corresponding_Body (Decl), After);
1435                end if;
1436             end if;
1437
1438          elsif Ekind (E) in Task_Kind
1439            and then
1440              (Nkind (Parent (E)) = N_Task_Type_Declaration
1441                 or else
1442               Nkind (Parent (E)) = N_Single_Task_Declaration)
1443          then
1444             declare
1445                Ent : Entity_Id;
1446
1447             begin
1448                Ent := First_Entity (E);
1449                while Present (Ent) loop
1450                   if Is_Entry (Ent)
1451                     and then not Default_Expressions_Processed (Ent)
1452                   then
1453                      Process_Default_Expressions (Ent, After);
1454                   end if;
1455
1456                   Next_Entity (Ent);
1457                end loop;
1458             end;
1459
1460          --  We add finalization masters to access types whose designated types
1461          --  require finalization. This is normally done when freezing the
1462          --  type, but this misses recursive type definitions where the later
1463          --  members of the recursion introduce controlled components (such as
1464          --  can happen when incomplete types are involved), as well cases
1465          --  where a component type is private and the controlled full type
1466          --  occurs after the access type is frozen. Cases that don't need a
1467          --  finalization master are generic formal types (the actual type will
1468          --  have it) and types with Java and CIL conventions, since those are
1469          --  used for API bindings. (Are there any other cases that should be
1470          --  excluded here???)
1471
1472          elsif Is_Access_Type (E)
1473            and then Comes_From_Source (E)
1474            and then not Is_Generic_Type (E)
1475            and then Needs_Finalization (Designated_Type (E))
1476          then
1477             Build_Finalization_Master (E);
1478          end if;
1479
1480          Next_Entity (E);
1481       end loop;
1482    end Freeze_All;
1483
1484    -----------------------
1485    -- Freeze_And_Append --
1486    -----------------------
1487
1488    procedure Freeze_And_Append
1489      (Ent    : Entity_Id;
1490       N      : Node_Id;
1491       Result : in out List_Id)
1492    is
1493       L : constant List_Id := Freeze_Entity (Ent, N);
1494    begin
1495       if Is_Non_Empty_List (L) then
1496          if Result = No_List then
1497             Result := L;
1498          else
1499             Append_List (L, Result);
1500          end if;
1501       end if;
1502    end Freeze_And_Append;
1503
1504    -------------------
1505    -- Freeze_Before --
1506    -------------------
1507
1508    procedure Freeze_Before (N : Node_Id; T : Entity_Id) is
1509       Freeze_Nodes : constant List_Id := Freeze_Entity (T, N);
1510    begin
1511       if Is_Non_Empty_List (Freeze_Nodes) then
1512          Insert_Actions (N, Freeze_Nodes);
1513       end if;
1514    end Freeze_Before;
1515
1516    -------------------
1517    -- Freeze_Entity --
1518    -------------------
1519
1520    function Freeze_Entity (E : Entity_Id; N : Node_Id) return List_Id is
1521       Loc    : constant Source_Ptr := Sloc (N);
1522       Test_E : Entity_Id := E;
1523       Comp   : Entity_Id;
1524       F_Node : Node_Id;
1525       Indx   : Node_Id;
1526       Formal : Entity_Id;
1527       Atype  : Entity_Id;
1528
1529       Result : List_Id := No_List;
1530       --  List of freezing actions, left at No_List if none
1531
1532       Has_Default_Initialization : Boolean := False;
1533       --  This flag gets set to true for a variable with default initialization
1534
1535       procedure Add_To_Result (N : Node_Id);
1536       --  N is a freezing action to be appended to the Result
1537
1538       procedure Check_Current_Instance (Comp_Decl : Node_Id);
1539       --  Check that an Access or Unchecked_Access attribute with a prefix
1540       --  which is the current instance type can only be applied when the type
1541       --  is limited.
1542
1543       procedure Check_Suspicious_Modulus (Utype : Entity_Id);
1544       --  Give warning for modulus of 8, 16, 32, or 64 given as an explicit
1545       --  integer literal without an explicit corresponding size clause. The
1546       --  caller has checked that Utype is a modular integer type.
1547
1548       function After_Last_Declaration return Boolean;
1549       --  If Loc is a freeze_entity that appears after the last declaration
1550       --  in the scope, inhibit error messages on late completion.
1551
1552       procedure Freeze_Record_Type (Rec : Entity_Id);
1553       --  Freeze each component, handle some representation clauses, and freeze
1554       --  primitive operations if this is a tagged type.
1555
1556       -------------------
1557       -- Add_To_Result --
1558       -------------------
1559
1560       procedure Add_To_Result (N : Node_Id) is
1561       begin
1562          if No (Result) then
1563             Result := New_List (N);
1564          else
1565             Append (N, Result);
1566          end if;
1567       end Add_To_Result;
1568
1569       ----------------------------
1570       -- After_Last_Declaration --
1571       ----------------------------
1572
1573       function After_Last_Declaration return Boolean is
1574          Spec : constant Node_Id := Parent (Current_Scope);
1575       begin
1576          if Nkind (Spec) = N_Package_Specification then
1577             if Present (Private_Declarations (Spec)) then
1578                return Loc >= Sloc (Last (Private_Declarations (Spec)));
1579             elsif Present (Visible_Declarations (Spec)) then
1580                return Loc >= Sloc (Last (Visible_Declarations (Spec)));
1581             else
1582                return False;
1583             end if;
1584          else
1585             return False;
1586          end if;
1587       end After_Last_Declaration;
1588
1589       ----------------------------
1590       -- Check_Current_Instance --
1591       ----------------------------
1592
1593       procedure Check_Current_Instance (Comp_Decl : Node_Id) is
1594
1595          Rec_Type : constant Entity_Id :=
1596                       Scope (Defining_Identifier (Comp_Decl));
1597
1598          Decl : constant Node_Id := Parent (Rec_Type);
1599
1600          function Process (N : Node_Id) return Traverse_Result;
1601          --  Process routine to apply check to given node
1602
1603          -------------
1604          -- Process --
1605          -------------
1606
1607          function Process (N : Node_Id) return Traverse_Result is
1608          begin
1609             case Nkind (N) is
1610                when N_Attribute_Reference =>
1611                   if (Attribute_Name (N) = Name_Access
1612                         or else
1613                       Attribute_Name (N) = Name_Unchecked_Access)
1614                     and then Is_Entity_Name (Prefix (N))
1615                     and then Is_Type (Entity (Prefix (N)))
1616                     and then Entity (Prefix (N)) = E
1617                   then
1618                      Error_Msg_N
1619                        ("current instance must be a limited type", Prefix (N));
1620                      return Abandon;
1621                   else
1622                      return OK;
1623                   end if;
1624
1625                when others => return OK;
1626             end case;
1627          end Process;
1628
1629          procedure Traverse is new Traverse_Proc (Process);
1630
1631       --  Start of processing for Check_Current_Instance
1632
1633       begin
1634          --  In Ada 95, the (imprecise) rule is that the current instance
1635          --  of a limited type is aliased. In Ada 2005, limitedness must be
1636          --  explicit: either a tagged type, or a limited record.
1637
1638          if Is_Limited_Type (Rec_Type)
1639            and then (Ada_Version < Ada_2005 or else Is_Tagged_Type (Rec_Type))
1640          then
1641             return;
1642
1643          elsif Nkind (Decl) = N_Full_Type_Declaration
1644            and then Limited_Present (Type_Definition (Decl))
1645          then
1646             return;
1647
1648          else
1649             Traverse (Comp_Decl);
1650          end if;
1651       end Check_Current_Instance;
1652
1653       ------------------------------
1654       -- Check_Suspicious_Modulus --
1655       ------------------------------
1656
1657       procedure Check_Suspicious_Modulus (Utype : Entity_Id) is
1658          Decl : constant Node_Id := Declaration_Node (Underlying_Type (Utype));
1659
1660       begin
1661          if Nkind (Decl) = N_Full_Type_Declaration then
1662             declare
1663                Tdef : constant Node_Id := Type_Definition (Decl);
1664
1665             begin
1666                if Nkind (Tdef) = N_Modular_Type_Definition then
1667                   declare
1668                      Modulus : constant Node_Id :=
1669                                  Original_Node (Expression (Tdef));
1670                   begin
1671                      if Nkind (Modulus) = N_Integer_Literal then
1672                         declare
1673                            Modv : constant Uint := Intval (Modulus);
1674                            Sizv : constant Uint := RM_Size (Utype);
1675
1676                         begin
1677                            --  First case, modulus and size are the same. This
1678                            --  happens if you have something like mod 32, with
1679                            --  an explicit size of 32, this is for sure a case
1680                            --  where the warning is given, since it is seems
1681                            --  very unlikely that someone would want e.g. a
1682                            --  five bit type stored in 32 bits. It is much
1683                            --  more likely they wanted a 32-bit type.
1684
1685                            if Modv = Sizv then
1686                               null;
1687
1688                            --  Second case, the modulus is 32 or 64 and no
1689                            --  size clause is present. This is a less clear
1690                            --  case for giving the warning, but in the case
1691                            --  of 32/64 (5-bit or 6-bit types) these seem rare
1692                            --  enough that it is a likely error (and in any
1693                            --  case using 2**5 or 2**6 in these cases seems
1694                            --  clearer. We don't include 8 or 16 here, simply
1695                            --  because in practice 3-bit and 4-bit types are
1696                            --  more common and too many false positives if
1697                            --  we warn in these cases.
1698
1699                            elsif not Has_Size_Clause (Utype)
1700                              and then (Modv = Uint_32 or else Modv = Uint_64)
1701                            then
1702                               null;
1703
1704                            --  No warning needed
1705
1706                            else
1707                               return;
1708                            end if;
1709
1710                            --  If we fall through, give warning
1711
1712                            Error_Msg_Uint_1 := Modv;
1713                            Error_Msg_N
1714                              ("?2 '*'*^' may have been intended here",
1715                               Modulus);
1716                         end;
1717                      end if;
1718                   end;
1719                end if;
1720             end;
1721          end if;
1722       end Check_Suspicious_Modulus;
1723
1724       ------------------------
1725       -- Freeze_Record_Type --
1726       ------------------------
1727
1728       procedure Freeze_Record_Type (Rec : Entity_Id) is
1729          Comp : Entity_Id;
1730          IR   : Node_Id;
1731          ADC  : Node_Id;
1732          Prev : Entity_Id;
1733
1734          Junk : Boolean;
1735          pragma Warnings (Off, Junk);
1736
1737          Unplaced_Component : Boolean := False;
1738          --  Set True if we find at least one component with no component
1739          --  clause (used to warn about useless Pack pragmas).
1740
1741          Placed_Component : Boolean := False;
1742          --  Set True if we find at least one component with a component
1743          --  clause (used to warn about useless Bit_Order pragmas, and also
1744          --  to detect cases where Implicit_Packing may have an effect).
1745
1746          All_Scalar_Components : Boolean := True;
1747          --  Set False if we encounter a component of a non-scalar type
1748
1749          Scalar_Component_Total_RM_Size : Uint := Uint_0;
1750          Scalar_Component_Total_Esize   : Uint := Uint_0;
1751          --  Accumulates total RM_Size values and total Esize values of all
1752          --  scalar components. Used for processing of Implicit_Packing.
1753
1754          function Check_Allocator (N : Node_Id) return Node_Id;
1755          --  If N is an allocator, possibly wrapped in one or more level of
1756          --  qualified expression(s), return the inner allocator node, else
1757          --  return Empty.
1758
1759          procedure Check_Itype (Typ : Entity_Id);
1760          --  If the component subtype is an access to a constrained subtype of
1761          --  an already frozen type, make the subtype frozen as well. It might
1762          --  otherwise be frozen in the wrong scope, and a freeze node on
1763          --  subtype has no effect. Similarly, if the component subtype is a
1764          --  regular (not protected) access to subprogram, set the anonymous
1765          --  subprogram type to frozen as well, to prevent an out-of-scope
1766          --  freeze node at some eventual point of call. Protected operations
1767          --  are handled elsewhere.
1768
1769          ---------------------
1770          -- Check_Allocator --
1771          ---------------------
1772
1773          function Check_Allocator (N : Node_Id) return Node_Id is
1774             Inner : Node_Id;
1775          begin
1776             Inner := N;
1777             loop
1778                if Nkind (Inner) = N_Allocator then
1779                   return Inner;
1780                elsif Nkind (Inner) = N_Qualified_Expression then
1781                   Inner := Expression (Inner);
1782                else
1783                   return Empty;
1784                end if;
1785             end loop;
1786          end Check_Allocator;
1787
1788          -----------------
1789          -- Check_Itype --
1790          -----------------
1791
1792          procedure Check_Itype (Typ : Entity_Id) is
1793             Desig : constant Entity_Id := Designated_Type (Typ);
1794
1795          begin
1796             if not Is_Frozen (Desig)
1797               and then Is_Frozen (Base_Type (Desig))
1798             then
1799                Set_Is_Frozen (Desig);
1800
1801                --  In addition, add an Itype_Reference to ensure that the
1802                --  access subtype is elaborated early enough. This cannot be
1803                --  done if the subtype may depend on discriminants.
1804
1805                if Ekind (Comp) = E_Component
1806                  and then Is_Itype (Etype (Comp))
1807                  and then not Has_Discriminants (Rec)
1808                then
1809                   IR := Make_Itype_Reference (Sloc (Comp));
1810                   Set_Itype (IR, Desig);
1811                   Add_To_Result (IR);
1812                end if;
1813
1814             elsif Ekind (Typ) = E_Anonymous_Access_Subprogram_Type
1815               and then Convention (Desig) /= Convention_Protected
1816             then
1817                Set_Is_Frozen (Desig);
1818             end if;
1819          end Check_Itype;
1820
1821       --  Start of processing for Freeze_Record_Type
1822
1823       begin
1824          --  Freeze components and embedded subtypes
1825
1826          Comp := First_Entity (Rec);
1827          Prev := Empty;
1828          while Present (Comp) loop
1829
1830             --  First handle the component case
1831
1832             if Ekind (Comp) = E_Component
1833               or else Ekind (Comp) = E_Discriminant
1834             then
1835                declare
1836                   CC : constant Node_Id := Component_Clause (Comp);
1837
1838                begin
1839                   --  Freezing a record type freezes the type of each of its
1840                   --  components. However, if the type of the component is
1841                   --  part of this record, we do not want or need a separate
1842                   --  Freeze_Node. Note that Is_Itype is wrong because that's
1843                   --  also set in private type cases. We also can't check for
1844                   --  the Scope being exactly Rec because of private types and
1845                   --  record extensions.
1846
1847                   if Is_Itype (Etype (Comp))
1848                     and then Is_Record_Type (Underlying_Type
1849                                              (Scope (Etype (Comp))))
1850                   then
1851                      Undelay_Type (Etype (Comp));
1852                   end if;
1853
1854                   Freeze_And_Append (Etype (Comp), N, Result);
1855
1856                   --  Check for error of component clause given for variable
1857                   --  sized type. We have to delay this test till this point,
1858                   --  since the component type has to be frozen for us to know
1859                   --  if it is variable length. We omit this test in a generic
1860                   --  context, it will be applied at instantiation time.
1861
1862                   --  We also omit this test in CodePeer mode, since we do not
1863                   --  have sufficient info on size and representation clauses.
1864
1865                   if Present (CC) then
1866                      Placed_Component := True;
1867
1868                      if Inside_A_Generic then
1869                         null;
1870
1871                      elsif CodePeer_Mode then
1872                         null;
1873
1874                      elsif not
1875                        Size_Known_At_Compile_Time
1876                          (Underlying_Type (Etype (Comp)))
1877                      then
1878                         Error_Msg_N
1879                           ("component clause not allowed for variable " &
1880                            "length component", CC);
1881                      end if;
1882
1883                   else
1884                      Unplaced_Component := True;
1885                   end if;
1886
1887                   --  Case of component requires byte alignment
1888
1889                   if Must_Be_On_Byte_Boundary (Etype (Comp)) then
1890
1891                      --  Set the enclosing record to also require byte align
1892
1893                      Set_Must_Be_On_Byte_Boundary (Rec);
1894
1895                      --  Check for component clause that is inconsistent with
1896                      --  the required byte boundary alignment.
1897
1898                      if Present (CC)
1899                        and then Normalized_First_Bit (Comp) mod
1900                                   System_Storage_Unit /= 0
1901                      then
1902                         Error_Msg_N
1903                           ("component & must be byte aligned",
1904                            Component_Name (Component_Clause (Comp)));
1905                      end if;
1906                   end if;
1907                end;
1908             end if;
1909
1910             --  Gather data for possible Implicit_Packing later. Note that at
1911             --  this stage we might be dealing with a real component, or with
1912             --  an implicit subtype declaration.
1913
1914             if not Is_Scalar_Type (Etype (Comp)) then
1915                All_Scalar_Components := False;
1916             else
1917                Scalar_Component_Total_RM_Size :=
1918                  Scalar_Component_Total_RM_Size + RM_Size (Etype (Comp));
1919                Scalar_Component_Total_Esize :=
1920                  Scalar_Component_Total_Esize + Esize (Etype (Comp));
1921             end if;
1922
1923             --  If the component is an Itype with Delayed_Freeze and is either
1924             --  a record or array subtype and its base type has not yet been
1925             --  frozen, we must remove this from the entity list of this record
1926             --  and put it on the entity list of the scope of its base type.
1927             --  Note that we know that this is not the type of a component
1928             --  since we cleared Has_Delayed_Freeze for it in the previous
1929             --  loop. Thus this must be the Designated_Type of an access type,
1930             --  which is the type of a component.
1931
1932             if Is_Itype (Comp)
1933               and then Is_Type (Scope (Comp))
1934               and then Is_Composite_Type (Comp)
1935               and then Base_Type (Comp) /= Comp
1936               and then Has_Delayed_Freeze (Comp)
1937               and then not Is_Frozen (Base_Type (Comp))
1938             then
1939                declare
1940                   Will_Be_Frozen : Boolean := False;
1941                   S              : Entity_Id;
1942
1943                begin
1944                   --  We have a pretty bad kludge here. Suppose Rec is subtype
1945                   --  being defined in a subprogram that's created as part of
1946                   --  the freezing of Rec'Base. In that case, we know that
1947                   --  Comp'Base must have already been frozen by the time we
1948                   --  get to elaborate this because Gigi doesn't elaborate any
1949                   --  bodies until it has elaborated all of the declarative
1950                   --  part. But Is_Frozen will not be set at this point because
1951                   --  we are processing code in lexical order.
1952
1953                   --  We detect this case by going up the Scope chain of Rec
1954                   --  and seeing if we have a subprogram scope before reaching
1955                   --  the top of the scope chain or that of Comp'Base. If we
1956                   --  do, then mark that Comp'Base will actually be frozen. If
1957                   --  so, we merely undelay it.
1958
1959                   S := Scope (Rec);
1960                   while Present (S) loop
1961                      if Is_Subprogram (S) then
1962                         Will_Be_Frozen := True;
1963                         exit;
1964                      elsif S = Scope (Base_Type (Comp)) then
1965                         exit;
1966                      end if;
1967
1968                      S := Scope (S);
1969                   end loop;
1970
1971                   if Will_Be_Frozen then
1972                      Undelay_Type (Comp);
1973                   else
1974                      if Present (Prev) then
1975                         Set_Next_Entity (Prev, Next_Entity (Comp));
1976                      else
1977                         Set_First_Entity (Rec, Next_Entity (Comp));
1978                      end if;
1979
1980                      --  Insert in entity list of scope of base type (which
1981                      --  must be an enclosing scope, because still unfrozen).
1982
1983                      Append_Entity (Comp, Scope (Base_Type (Comp)));
1984                   end if;
1985                end;
1986
1987             --  If the component is an access type with an allocator as default
1988             --  value, the designated type will be frozen by the corresponding
1989             --  expression in init_proc. In order to place the freeze node for
1990             --  the designated type before that for the current record type,
1991             --  freeze it now.
1992
1993             --  Same process if the component is an array of access types,
1994             --  initialized with an aggregate. If the designated type is
1995             --  private, it cannot contain allocators, and it is premature
1996             --  to freeze the type, so we check for this as well.
1997
1998             elsif Is_Access_Type (Etype (Comp))
1999               and then Present (Parent (Comp))
2000               and then Present (Expression (Parent (Comp)))
2001             then
2002                declare
2003                   Alloc : constant Node_Id :=
2004                             Check_Allocator (Expression (Parent (Comp)));
2005
2006                begin
2007                   if Present (Alloc) then
2008
2009                      --  If component is pointer to a classwide type, freeze
2010                      --  the specific type in the expression being allocated.
2011                      --  The expression may be a subtype indication, in which
2012                      --  case freeze the subtype mark.
2013
2014                      if Is_Class_Wide_Type
2015                           (Designated_Type (Etype (Comp)))
2016                      then
2017                         if Is_Entity_Name (Expression (Alloc)) then
2018                            Freeze_And_Append
2019                              (Entity (Expression (Alloc)), N, Result);
2020                         elsif
2021                           Nkind (Expression (Alloc)) = N_Subtype_Indication
2022                         then
2023                            Freeze_And_Append
2024                             (Entity (Subtype_Mark (Expression (Alloc))),
2025                              N, Result);
2026                         end if;
2027
2028                      elsif Is_Itype (Designated_Type (Etype (Comp))) then
2029                         Check_Itype (Etype (Comp));
2030
2031                      else
2032                         Freeze_And_Append
2033                           (Designated_Type (Etype (Comp)), N, Result);
2034                      end if;
2035                   end if;
2036                end;
2037
2038             elsif Is_Access_Type (Etype (Comp))
2039               and then Is_Itype (Designated_Type (Etype (Comp)))
2040             then
2041                Check_Itype (Etype (Comp));
2042
2043             elsif Is_Array_Type (Etype (Comp))
2044               and then Is_Access_Type (Component_Type (Etype (Comp)))
2045               and then Present (Parent (Comp))
2046               and then Nkind (Parent (Comp)) = N_Component_Declaration
2047               and then Present (Expression (Parent (Comp)))
2048               and then Nkind (Expression (Parent (Comp))) = N_Aggregate
2049               and then Is_Fully_Defined
2050                  (Designated_Type (Component_Type (Etype (Comp))))
2051             then
2052                Freeze_And_Append
2053                  (Designated_Type
2054                    (Component_Type (Etype (Comp))), N, Result);
2055             end if;
2056
2057             Prev := Comp;
2058             Next_Entity (Comp);
2059          end loop;
2060
2061          --  Deal with Bit_Order aspect specifying a non-default bit order
2062
2063          if Reverse_Bit_Order (Rec) and then Base_Type (Rec) = Rec then
2064             if not Placed_Component then
2065                ADC :=
2066                  Get_Attribute_Definition_Clause (Rec, Attribute_Bit_Order);
2067                Error_Msg_N ("?Bit_Order specification has no effect", ADC);
2068                Error_Msg_N
2069                  ("\?since no component clauses were specified", ADC);
2070
2071             --  Here is where we do the processing for reversed bit order
2072
2073             else
2074                Adjust_Record_For_Reverse_Bit_Order (Rec);
2075             end if;
2076          end if;
2077
2078          --  Complete error checking on record representation clause (e.g.
2079          --  overlap of components). This is called after adjusting the
2080          --  record for reverse bit order.
2081
2082          declare
2083             RRC : constant Node_Id := Get_Record_Representation_Clause (Rec);
2084          begin
2085             if Present (RRC) then
2086                Check_Record_Representation_Clause (RRC);
2087             end if;
2088          end;
2089
2090          --  Set OK_To_Reorder_Components depending on debug flags
2091
2092          if Is_Base_Type (Rec) and then Convention (Rec) = Convention_Ada then
2093             if (Has_Discriminants (Rec) and then Debug_Flag_Dot_V)
2094                   or else
2095                (not Has_Discriminants (Rec) and then Debug_Flag_Dot_R)
2096             then
2097                Set_OK_To_Reorder_Components (Rec);
2098             end if;
2099          end if;
2100
2101          --  Check for useless pragma Pack when all components placed. We only
2102          --  do this check for record types, not subtypes, since a subtype may
2103          --  have all its components placed, and it still makes perfectly good
2104          --  sense to pack other subtypes or the parent type. We do not give
2105          --  this warning if Optimize_Alignment is set to Space, since the
2106          --  pragma Pack does have an effect in this case (it always resets
2107          --  the alignment to one).
2108
2109          if Ekind (Rec) = E_Record_Type
2110            and then Is_Packed (Rec)
2111            and then not Unplaced_Component
2112            and then Optimize_Alignment /= 'S'
2113          then
2114             --  Reset packed status. Probably not necessary, but we do it so
2115             --  that there is no chance of the back end doing something strange
2116             --  with this redundant indication of packing.
2117
2118             Set_Is_Packed (Rec, False);
2119
2120             --  Give warning if redundant constructs warnings on
2121
2122             if Warn_On_Redundant_Constructs then
2123                Error_Msg_N -- CODEFIX
2124                  ("?pragma Pack has no effect, no unplaced components",
2125                   Get_Rep_Pragma (Rec, Name_Pack));
2126             end if;
2127          end if;
2128
2129          --  If this is the record corresponding to a remote type, freeze the
2130          --  remote type here since that is what we are semantically freezing.
2131          --  This prevents the freeze node for that type in an inner scope.
2132
2133          --  Also, Check for controlled components and unchecked unions.
2134          --  Finally, enforce the restriction that access attributes with a
2135          --  current instance prefix can only apply to limited types.
2136
2137          if Ekind (Rec) = E_Record_Type then
2138             if Present (Corresponding_Remote_Type (Rec)) then
2139                Freeze_And_Append (Corresponding_Remote_Type (Rec), N, Result);
2140             end if;
2141
2142             Comp := First_Component (Rec);
2143             while Present (Comp) loop
2144
2145                --  Do not set Has_Controlled_Component on a class-wide
2146                --  equivalent type. See Make_CW_Equivalent_Type.
2147
2148                if not Is_Class_Wide_Equivalent_Type (Rec)
2149                  and then (Has_Controlled_Component (Etype (Comp))
2150                             or else (Chars (Comp) /= Name_uParent
2151                                       and then Is_Controlled (Etype (Comp)))
2152                             or else (Is_Protected_Type (Etype (Comp))
2153                                       and then Present
2154                                         (Corresponding_Record_Type
2155                                           (Etype (Comp)))
2156                                       and then Has_Controlled_Component
2157                                         (Corresponding_Record_Type
2158                                           (Etype (Comp)))))
2159                then
2160                   Set_Has_Controlled_Component (Rec);
2161                   exit;
2162                end if;
2163
2164                if Has_Unchecked_Union (Etype (Comp)) then
2165                   Set_Has_Unchecked_Union (Rec);
2166                end if;
2167
2168                if Has_Per_Object_Constraint (Comp) then
2169
2170                   --  Scan component declaration for likely misuses of current
2171                   --  instance, either in a constraint or a default expression.
2172
2173                   Check_Current_Instance (Parent (Comp));
2174                end if;
2175
2176                Next_Component (Comp);
2177             end loop;
2178          end if;
2179
2180          Set_Component_Alignment_If_Not_Set (Rec);
2181
2182          --  For first subtypes, check if there are any fixed-point fields with
2183          --  component clauses, where we must check the size. This is not done
2184          --  till the freeze point, since for fixed-point types, we do not know
2185          --  the size until the type is frozen. Similar processing applies to
2186          --  bit packed arrays.
2187
2188          if Is_First_Subtype (Rec) then
2189             Comp := First_Component (Rec);
2190             while Present (Comp) loop
2191                if Present (Component_Clause (Comp))
2192                  and then (Is_Fixed_Point_Type (Etype (Comp))
2193                              or else
2194                            Is_Bit_Packed_Array (Etype (Comp)))
2195                then
2196                   Check_Size
2197                     (Component_Name (Component_Clause (Comp)),
2198                      Etype (Comp),
2199                      Esize (Comp),
2200                      Junk);
2201                end if;
2202
2203                Next_Component (Comp);
2204             end loop;
2205          end if;
2206
2207          --  Generate warning for applying C or C++ convention to a record
2208          --  with discriminants. This is suppressed for the unchecked union
2209          --  case, since the whole point in this case is interface C. We also
2210          --  do not generate this within instantiations, since we will have
2211          --  generated a message on the template.
2212
2213          if Has_Discriminants (E)
2214            and then not Is_Unchecked_Union (E)
2215            and then (Convention (E) = Convention_C
2216                        or else
2217                      Convention (E) = Convention_CPP)
2218            and then Comes_From_Source (E)
2219            and then not In_Instance
2220            and then not Has_Warnings_Off (E)
2221            and then not Has_Warnings_Off (Base_Type (E))
2222          then
2223             declare
2224                Cprag : constant Node_Id := Get_Rep_Pragma (E, Name_Convention);
2225                A2    : Node_Id;
2226
2227             begin
2228                if Present (Cprag) then
2229                   A2 := Next (First (Pragma_Argument_Associations (Cprag)));
2230
2231                   if Convention (E) = Convention_C then
2232                      Error_Msg_N
2233                        ("?variant record has no direct equivalent in C", A2);
2234                   else
2235                      Error_Msg_N
2236                        ("?variant record has no direct equivalent in C++", A2);
2237                   end if;
2238
2239                   Error_Msg_NE
2240                     ("\?use of convention for type& is dubious", A2, E);
2241                end if;
2242             end;
2243          end if;
2244
2245          --  See if Size is too small as is (and implicit packing might help)
2246
2247          if not Is_Packed (Rec)
2248
2249            --  No implicit packing if even one component is explicitly placed
2250
2251            and then not Placed_Component
2252
2253            --  Must have size clause and all scalar components
2254
2255            and then Has_Size_Clause (Rec)
2256            and then All_Scalar_Components
2257
2258            --  Do not try implicit packing on records with discriminants, too
2259            --  complicated, especially in the variant record case.
2260
2261            and then not Has_Discriminants (Rec)
2262
2263            --  We can implicitly pack if the specified size of the record is
2264            --  less than the sum of the object sizes (no point in packing if
2265            --  this is not the case).
2266
2267            and then RM_Size (Rec) < Scalar_Component_Total_Esize
2268
2269            --  And the total RM size cannot be greater than the specified size
2270            --  since otherwise packing will not get us where we have to be!
2271
2272            and then RM_Size (Rec) >= Scalar_Component_Total_RM_Size
2273
2274            --  Never do implicit packing in CodePeer or Alfa modes since
2275            --  we don't do any packing in these modes, since this generates
2276            --  over-complex code that confuses static analysis, and in
2277            --  general, neither CodePeer not GNATprove care about the
2278            --  internal representation of objects.
2279
2280            and then not (CodePeer_Mode or Alfa_Mode)
2281          then
2282             --  If implicit packing enabled, do it
2283
2284             if Implicit_Packing then
2285                Set_Is_Packed (Rec);
2286
2287                --  Otherwise flag the size clause
2288
2289             else
2290                declare
2291                   Sz : constant Node_Id := Size_Clause (Rec);
2292                begin
2293                   Error_Msg_NE -- CODEFIX
2294                     ("size given for& too small", Sz, Rec);
2295                   Error_Msg_N -- CODEFIX
2296                     ("\use explicit pragma Pack "
2297                      & "or use pragma Implicit_Packing", Sz);
2298                end;
2299             end if;
2300          end if;
2301       end Freeze_Record_Type;
2302
2303    --  Start of processing for Freeze_Entity
2304
2305    begin
2306       --  We are going to test for various reasons why this entity need not be
2307       --  frozen here, but in the case of an Itype that's defined within a
2308       --  record, that test actually applies to the record.
2309
2310       if Is_Itype (E) and then Is_Record_Type (Scope (E)) then
2311          Test_E := Scope (E);
2312       elsif Is_Itype (E) and then Present (Underlying_Type (Scope (E)))
2313         and then Is_Record_Type (Underlying_Type (Scope (E)))
2314       then
2315          Test_E := Underlying_Type (Scope (E));
2316       end if;
2317
2318       --  Do not freeze if already frozen since we only need one freeze node
2319
2320       if Is_Frozen (E) then
2321          return No_List;
2322
2323       --  It is improper to freeze an external entity within a generic because
2324       --  its freeze node will appear in a non-valid context. The entity will
2325       --  be frozen in the proper scope after the current generic is analyzed.
2326
2327       elsif Inside_A_Generic and then External_Ref_In_Generic (Test_E) then
2328          return No_List;
2329
2330       --  AI05-0213: A formal incomplete type does not freeze the actual. In
2331       --  the instance, the same applies to the subtype renaming the actual.
2332
2333       elsif Is_Private_Type (E)
2334         and then Is_Generic_Actual_Type (E)
2335         and then No (Full_View (Base_Type (E)))
2336         and then Ada_Version >= Ada_2012
2337       then
2338          return No_List;
2339
2340       --  Do not freeze a global entity within an inner scope created during
2341       --  expansion. A call to subprogram E within some internal procedure
2342       --  (a stream attribute for example) might require freezing E, but the
2343       --  freeze node must appear in the same declarative part as E itself.
2344       --  The two-pass elaboration mechanism in gigi guarantees that E will
2345       --  be frozen before the inner call is elaborated. We exclude constants
2346       --  from this test, because deferred constants may be frozen early, and
2347       --  must be diagnosed (e.g. in the case of a deferred constant being used
2348       --  in a default expression). If the enclosing subprogram comes from
2349       --  source, or is a generic instance, then the freeze point is the one
2350       --  mandated by the language, and we freeze the entity. A subprogram that
2351       --  is a child unit body that acts as a spec does not have a spec that
2352       --  comes from source, but can only come from source.
2353
2354       elsif In_Open_Scopes (Scope (Test_E))
2355         and then Scope (Test_E) /= Current_Scope
2356         and then Ekind (Test_E) /= E_Constant
2357       then
2358          declare
2359             S : Entity_Id;
2360
2361          begin
2362             S := Current_Scope;
2363             while Present (S) loop
2364                if Is_Overloadable (S) then
2365                   if Comes_From_Source (S)
2366                     or else Is_Generic_Instance (S)
2367                     or else Is_Child_Unit (S)
2368                   then
2369                      exit;
2370                   else
2371                      return No_List;
2372                   end if;
2373                end if;
2374
2375                S := Scope (S);
2376             end loop;
2377          end;
2378
2379       --  Similarly, an inlined instance body may make reference to global
2380       --  entities, but these references cannot be the proper freezing point
2381       --  for them, and in the absence of inlining freezing will take place in
2382       --  their own scope. Normally instance bodies are analyzed after the
2383       --  enclosing compilation, and everything has been frozen at the proper
2384       --  place, but with front-end inlining an instance body is compiled
2385       --  before the end of the enclosing scope, and as a result out-of-order
2386       --  freezing must be prevented.
2387
2388       elsif Front_End_Inlining
2389         and then In_Instance_Body
2390         and then Present (Scope (Test_E))
2391       then
2392          declare
2393             S : Entity_Id;
2394
2395          begin
2396             S := Scope (Test_E);
2397             while Present (S) loop
2398                if Is_Generic_Instance (S) then
2399                   exit;
2400                else
2401                   S := Scope (S);
2402                end if;
2403             end loop;
2404
2405             if No (S) then
2406                return No_List;
2407             end if;
2408          end;
2409       end if;
2410
2411       --  Deal with delayed aspect specifications. The analysis of the aspect
2412       --  is required to be delayed to the freeze point, so we evaluate the
2413       --  pragma or attribute definition clause in the tree at this point.
2414
2415       if Has_Delayed_Aspects (E) then
2416          declare
2417             Ritem : Node_Id;
2418             Aitem : Node_Id;
2419
2420          begin
2421             --  Look for aspect specification entries for this entity
2422
2423             Ritem := First_Rep_Item (E);
2424             while Present (Ritem) loop
2425                if Nkind (Ritem) = N_Aspect_Specification
2426                  and then Entity (Ritem) = E
2427                  and then Is_Delayed_Aspect (Ritem)
2428                  and then Scope (E) = Current_Scope
2429                then
2430                   Aitem := Aspect_Rep_Item (Ritem);
2431
2432                   --  Skip if this is an aspect with no corresponding pragma
2433                   --  or attribute definition node (such as Default_Value).
2434
2435                   if Present (Aitem) then
2436                      Set_Parent (Aitem, Ritem);
2437                      Analyze (Aitem);
2438                   end if;
2439                end if;
2440
2441                Next_Rep_Item (Ritem);
2442             end loop;
2443          end;
2444       end if;
2445
2446       --  Here to freeze the entity
2447
2448       Set_Is_Frozen (E);
2449
2450       --  Case of entity being frozen is other than a type
2451
2452       if not Is_Type (E) then
2453
2454          --  If entity is exported or imported and does not have an external
2455          --  name, now is the time to provide the appropriate default name.
2456          --  Skip this if the entity is stubbed, since we don't need a name
2457          --  for any stubbed routine. For the case on intrinsics, if no
2458          --  external name is specified, then calls will be handled in
2459          --  Exp_Intr.Expand_Intrinsic_Call, and no name is needed. If an
2460          --  external name is provided, then Expand_Intrinsic_Call leaves
2461          --  calls in place for expansion by GIGI.
2462
2463          if (Is_Imported (E) or else Is_Exported (E))
2464            and then No (Interface_Name (E))
2465            and then Convention (E) /= Convention_Stubbed
2466            and then Convention (E) /= Convention_Intrinsic
2467          then
2468             Set_Encoded_Interface_Name
2469               (E, Get_Default_External_Name (E));
2470
2471          --  If entity is an atomic object appearing in a declaration and
2472          --  the expression is an aggregate, assign it to a temporary to
2473          --  ensure that the actual assignment is done atomically rather
2474          --  than component-wise (the assignment to the temp may be done
2475          --  component-wise, but that is harmless).
2476
2477          elsif Is_Atomic (E)
2478            and then Nkind (Parent (E)) = N_Object_Declaration
2479            and then Present (Expression (Parent (E)))
2480            and then Nkind (Expression (Parent (E))) = N_Aggregate
2481            and then Is_Atomic_Aggregate (Expression (Parent (E)), Etype (E))
2482          then
2483             null;
2484          end if;
2485
2486          --  For a subprogram, freeze all parameter types and also the return
2487          --  type (RM 13.14(14)). However skip this for internal subprograms.
2488          --  This is also the point where any extra formal parameters are
2489          --  created since we now know whether the subprogram will use a
2490          --  foreign convention.
2491
2492          if Is_Subprogram (E) then
2493             if not Is_Internal (E) then
2494                declare
2495                   F_Type    : Entity_Id;
2496                   R_Type    : Entity_Id;
2497                   Warn_Node : Node_Id;
2498
2499                begin
2500                   --  Loop through formals
2501
2502                   Formal := First_Formal (E);
2503                   while Present (Formal) loop
2504                      F_Type := Etype (Formal);
2505
2506                      --  AI05-0151 : incomplete types can appear in a profile.
2507                      --  By the time the entity is frozen, the full view must
2508                      --  be available, unless it is a limited view.
2509
2510                      if Is_Incomplete_Type (F_Type)
2511                        and then Present (Full_View (F_Type))
2512                      then
2513                         F_Type := Full_View (F_Type);
2514                         Set_Etype (Formal, F_Type);
2515                      end if;
2516
2517                      Freeze_And_Append (F_Type, N, Result);
2518
2519                      if Is_Private_Type (F_Type)
2520                        and then Is_Private_Type (Base_Type (F_Type))
2521                        and then No (Full_View (Base_Type (F_Type)))
2522                        and then not Is_Generic_Type (F_Type)
2523                        and then not Is_Derived_Type (F_Type)
2524                      then
2525                         --  If the type of a formal is incomplete, subprogram
2526                         --  is being frozen prematurely. Within an instance
2527                         --  (but not within a wrapper package) this is an
2528                         --  artifact of our need to regard the end of an
2529                         --  instantiation as a freeze point. Otherwise it is
2530                         --  a definite error.
2531
2532                         if In_Instance then
2533                            Set_Is_Frozen (E, False);
2534                            return No_List;
2535
2536                         elsif not After_Last_Declaration
2537                           and then not Freezing_Library_Level_Tagged_Type
2538                         then
2539                            Error_Msg_Node_1 := F_Type;
2540                            Error_Msg
2541                              ("type& must be fully defined before this point",
2542                                Loc);
2543                         end if;
2544                      end if;
2545
2546                      --  Check suspicious parameter for C function. These tests
2547                      --  apply only to exported/imported subprograms.
2548
2549                      if Warn_On_Export_Import
2550                        and then Comes_From_Source (E)
2551                        and then (Convention (E) = Convention_C
2552                                    or else
2553                                  Convention (E) = Convention_CPP)
2554                        and then (Is_Imported (E) or else Is_Exported (E))
2555                        and then Convention (E) /= Convention (Formal)
2556                        and then not Has_Warnings_Off (E)
2557                        and then not Has_Warnings_Off (F_Type)
2558                        and then not Has_Warnings_Off (Formal)
2559                      then
2560                         --  Qualify mention of formals with subprogram name
2561
2562                         Error_Msg_Qual_Level := 1;
2563
2564                         --  Check suspicious use of fat C pointer
2565
2566                         if Is_Access_Type (F_Type)
2567                           and then Esize (F_Type) > Ttypes.System_Address_Size
2568                         then
2569                            Error_Msg_N
2570                              ("?type of & does not correspond to C pointer!",
2571                               Formal);
2572
2573                         --  Check suspicious return of boolean
2574
2575                         elsif Root_Type (F_Type) = Standard_Boolean
2576                           and then Convention (F_Type) = Convention_Ada
2577                           and then not Has_Warnings_Off (F_Type)
2578                           and then not Has_Size_Clause (F_Type)
2579                           and then VM_Target = No_VM
2580                         then
2581                            Error_Msg_N ("& is an 8-bit Ada Boolean?", Formal);
2582                            Error_Msg_N
2583                              ("\use appropriate corresponding type in C "
2584                               & "(e.g. char)?", Formal);
2585
2586                         --  Check suspicious tagged type
2587
2588                         elsif (Is_Tagged_Type (F_Type)
2589                                 or else (Is_Access_Type (F_Type)
2590                                            and then
2591                                              Is_Tagged_Type
2592                                                (Designated_Type (F_Type))))
2593                           and then Convention (E) = Convention_C
2594                         then
2595                            Error_Msg_N
2596                              ("?& involves a tagged type which does not "
2597                               & "correspond to any C type!", Formal);
2598
2599                         --  Check wrong convention subprogram pointer
2600
2601                         elsif Ekind (F_Type) = E_Access_Subprogram_Type
2602                           and then not Has_Foreign_Convention (F_Type)
2603                         then
2604                            Error_Msg_N
2605                              ("?subprogram pointer & should "
2606                               & "have foreign convention!", Formal);
2607                            Error_Msg_Sloc := Sloc (F_Type);
2608                            Error_Msg_NE
2609                              ("\?add Convention pragma to declaration of &#",
2610                               Formal, F_Type);
2611                         end if;
2612
2613                         --  Turn off name qualification after message output
2614
2615                         Error_Msg_Qual_Level := 0;
2616                      end if;
2617
2618                      --  Check for unconstrained array in exported foreign
2619                      --  convention case.
2620
2621                      if Has_Foreign_Convention (E)
2622                        and then not Is_Imported (E)
2623                        and then Is_Array_Type (F_Type)
2624                        and then not Is_Constrained (F_Type)
2625                        and then Warn_On_Export_Import
2626
2627                        --  Exclude VM case, since both .NET and JVM can handle
2628                        --  unconstrained arrays without a problem.
2629
2630                        and then VM_Target = No_VM
2631                      then
2632                         Error_Msg_Qual_Level := 1;
2633
2634                         --  If this is an inherited operation, place the
2635                         --  warning on the derived type declaration, rather
2636                         --  than on the original subprogram.
2637
2638                         if Nkind (Original_Node (Parent (E))) =
2639                           N_Full_Type_Declaration
2640                         then
2641                            Warn_Node := Parent (E);
2642
2643                            if Formal = First_Formal (E) then
2644                               Error_Msg_NE
2645                                 ("?in inherited operation&", Warn_Node, E);
2646                            end if;
2647                         else
2648                            Warn_Node := Formal;
2649                         end if;
2650
2651                         Error_Msg_NE
2652                           ("?type of argument& is unconstrained array",
2653                            Warn_Node, Formal);
2654                         Error_Msg_NE
2655                           ("?foreign caller must pass bounds explicitly",
2656                            Warn_Node, Formal);
2657                         Error_Msg_Qual_Level := 0;
2658                      end if;
2659
2660                      if not From_With_Type (F_Type) then
2661                         if Is_Access_Type (F_Type) then
2662                            F_Type := Designated_Type (F_Type);
2663                         end if;
2664
2665                         --  If the formal is an anonymous_access_to_subprogram
2666                         --  freeze the  subprogram type as well, to prevent
2667                         --  scope anomalies in gigi, because there is no other
2668                         --  clear point at which it could be frozen.
2669
2670                         if Is_Itype (Etype (Formal))
2671                           and then Ekind (F_Type) = E_Subprogram_Type
2672                         then
2673                            Freeze_And_Append (F_Type, N, Result);
2674                         end if;
2675                      end if;
2676
2677                      Next_Formal (Formal);
2678                   end loop;
2679
2680                   --  Case of function: similar checks on return type
2681
2682                   if Ekind (E) = E_Function then
2683
2684                      --  Freeze return type
2685
2686                      R_Type := Etype (E);
2687
2688                      --  AI05-0151: the return type may have been incomplete
2689                      --  at the point of declaration.
2690
2691                      if Ekind (R_Type) = E_Incomplete_Type
2692                        and then Present (Full_View (R_Type))
2693                      then
2694                         R_Type := Full_View (R_Type);
2695                         Set_Etype (E, R_Type);
2696                      end if;
2697
2698                      Freeze_And_Append (R_Type, N, Result);
2699
2700                      --  Check suspicious return type for C function
2701
2702                      if Warn_On_Export_Import
2703                        and then (Convention (E) = Convention_C
2704                                    or else
2705                                  Convention (E) = Convention_CPP)
2706                        and then (Is_Imported (E) or else Is_Exported (E))
2707                      then
2708                         --  Check suspicious return of fat C pointer
2709
2710                         if Is_Access_Type (R_Type)
2711                           and then Esize (R_Type) > Ttypes.System_Address_Size
2712                           and then not Has_Warnings_Off (E)
2713                           and then not Has_Warnings_Off (R_Type)
2714                         then
2715                            Error_Msg_N
2716                              ("?return type of& does not "
2717                               & "correspond to C pointer!", E);
2718
2719                         --  Check suspicious return of boolean
2720
2721                         elsif Root_Type (R_Type) = Standard_Boolean
2722                           and then Convention (R_Type) = Convention_Ada
2723                           and then VM_Target = No_VM
2724                           and then not Has_Warnings_Off (E)
2725                           and then not Has_Warnings_Off (R_Type)
2726                           and then not Has_Size_Clause (R_Type)
2727                         then
2728                            declare
2729                               N : constant Node_Id :=
2730                                     Result_Definition (Declaration_Node (E));
2731                            begin
2732                               Error_Msg_NE
2733                                 ("return type of & is an 8-bit Ada Boolean?",
2734                                  N, E);
2735                               Error_Msg_NE
2736                                 ("\use appropriate corresponding type in C "
2737                                  & "(e.g. char)?", N, E);
2738                            end;
2739
2740                         --  Check suspicious return tagged type
2741
2742                         elsif (Is_Tagged_Type (R_Type)
2743                                 or else (Is_Access_Type (R_Type)
2744                                            and then
2745                                              Is_Tagged_Type
2746                                                (Designated_Type (R_Type))))
2747                           and then Convention (E) = Convention_C
2748                           and then not Has_Warnings_Off (E)
2749                           and then not Has_Warnings_Off (R_Type)
2750                         then
2751                            Error_Msg_N
2752                              ("?return type of & does not "
2753                               & "correspond to C type!", E);
2754
2755                         --  Check return of wrong convention subprogram pointer
2756
2757                         elsif Ekind (R_Type) = E_Access_Subprogram_Type
2758                           and then not Has_Foreign_Convention (R_Type)
2759                           and then not Has_Warnings_Off (E)
2760                           and then not Has_Warnings_Off (R_Type)
2761                         then
2762                            Error_Msg_N
2763                              ("?& should return a foreign "
2764                               & "convention subprogram pointer", E);
2765                            Error_Msg_Sloc := Sloc (R_Type);
2766                            Error_Msg_NE
2767                              ("\?add Convention pragma to declaration of& #",
2768                               E, R_Type);
2769                         end if;
2770                      end if;
2771
2772                      --  Give warning for suspicious return of a result of an
2773                      --  unconstrained array type in a foreign convention
2774                      --  function.
2775
2776                      if Has_Foreign_Convention (E)
2777
2778                        --  We are looking for a return of unconstrained array
2779
2780                        and then Is_Array_Type (R_Type)
2781                        and then not Is_Constrained (R_Type)
2782
2783                        --  Exclude imported routines, the warning does not
2784                        --  belong on the import, but rather on the routine
2785                        --  definition.
2786
2787                        and then not Is_Imported (E)
2788
2789                        --  Exclude VM case, since both .NET and JVM can handle
2790                        --  return of unconstrained arrays without a problem.
2791
2792                        and then VM_Target = No_VM
2793
2794                        --  Check that general warning is enabled, and that it
2795                        --  is not suppressed for this particular case.
2796
2797                        and then Warn_On_Export_Import
2798                        and then not Has_Warnings_Off (E)
2799                        and then not Has_Warnings_Off (R_Type)
2800                      then
2801                         Error_Msg_N
2802                           ("?foreign convention function& should not " &
2803                            "return unconstrained array!", E);
2804                      end if;
2805                   end if;
2806                end;
2807             end if;
2808
2809             --  Must freeze its parent first if it is a derived subprogram
2810
2811             if Present (Alias (E)) then
2812                Freeze_And_Append (Alias (E), N, Result);
2813             end if;
2814
2815             --  We don't freeze internal subprograms, because we don't normally
2816             --  want addition of extra formals or mechanism setting to happen
2817             --  for those. However we do pass through predefined dispatching
2818             --  cases, since extra formals may be needed in some cases, such as
2819             --  for the stream 'Input function (build-in-place formals).
2820
2821             if not Is_Internal (E)
2822               or else Is_Predefined_Dispatching_Operation (E)
2823             then
2824                Freeze_Subprogram (E);
2825             end if;
2826
2827          --  Here for other than a subprogram or type
2828
2829          else
2830             --  If entity has a type, and it is not a generic unit, then
2831             --  freeze it first (RM 13.14(10)).
2832
2833             if Present (Etype (E))
2834               and then Ekind (E) /= E_Generic_Function
2835             then
2836                Freeze_And_Append (Etype (E), N, Result);
2837             end if;
2838
2839             --  Special processing for objects created by object declaration
2840
2841             if Nkind (Declaration_Node (E)) = N_Object_Declaration then
2842
2843                --  Abstract type allowed only for C++ imported variables or
2844                --  constants.
2845
2846                --  Note: we inhibit this check for objects that do not come
2847                --  from source because there is at least one case (the
2848                --  expansion of x'Class'Input where x is abstract) where we
2849                --  legitimately generate an abstract object.
2850
2851                if Is_Abstract_Type (Etype (E))
2852                  and then Comes_From_Source (Parent (E))
2853                  and then not (Is_Imported (E)
2854                                  and then Is_CPP_Class (Etype (E)))
2855                then
2856                   Error_Msg_N ("type of object cannot be abstract",
2857                                Object_Definition (Parent (E)));
2858
2859                   if Is_CPP_Class (Etype (E)) then
2860                      Error_Msg_NE
2861                        ("\} may need a cpp_constructor",
2862                        Object_Definition (Parent (E)), Etype (E));
2863                   end if;
2864                end if;
2865
2866                --  For object created by object declaration, perform required
2867                --  categorization (preelaborate and pure) checks. Defer these
2868                --  checks to freeze time since pragma Import inhibits default
2869                --  initialization and thus pragma Import affects these checks.
2870
2871                Validate_Object_Declaration (Declaration_Node (E));
2872
2873                --  If there is an address clause, check that it is valid
2874
2875                Check_Address_Clause (E);
2876
2877                --  If the object needs any kind of default initialization, an
2878                --  error must be issued if No_Default_Initialization applies.
2879                --  The check doesn't apply to imported objects, which are not
2880                --  ever default initialized, and is why the check is deferred
2881                --  until freezing, at which point we know if Import applies.
2882                --  Deferred constants are also exempted from this test because
2883                --  their completion is explicit, or through an import pragma.
2884
2885                if Ekind (E) = E_Constant
2886                  and then Present (Full_View (E))
2887                then
2888                   null;
2889
2890                elsif Comes_From_Source (E)
2891                  and then not Is_Imported (E)
2892                  and then not Has_Init_Expression (Declaration_Node (E))
2893                  and then
2894                    ((Has_Non_Null_Base_Init_Proc (Etype (E))
2895                       and then not No_Initialization (Declaration_Node (E))
2896                       and then not Is_Value_Type (Etype (E))
2897                       and then not Initialization_Suppressed (Etype (E)))
2898                     or else
2899                       (Needs_Simple_Initialization (Etype (E))
2900                         and then not Is_Internal (E)))
2901                then
2902                   Has_Default_Initialization := True;
2903                   Check_Restriction
2904                     (No_Default_Initialization, Declaration_Node (E));
2905                end if;
2906
2907                --  Check that a Thread_Local_Storage variable does not have
2908                --  default initialization, and any explicit initialization must
2909                --  either be the null constant or a static constant.
2910
2911                if Has_Pragma_Thread_Local_Storage (E) then
2912                   declare
2913                      Decl : constant Node_Id := Declaration_Node (E);
2914                   begin
2915                      if Has_Default_Initialization
2916                        or else
2917                          (Has_Init_Expression (Decl)
2918                             and then
2919                              (No (Expression (Decl))
2920                                 or else not
2921                                   (Is_Static_Expression (Expression (Decl))
2922                                      or else
2923                                    Nkind (Expression (Decl)) = N_Null)))
2924                      then
2925                         Error_Msg_NE
2926                           ("Thread_Local_Storage variable& is "
2927                            & "improperly initialized", Decl, E);
2928                         Error_Msg_NE
2929                           ("\only allowed initialization is explicit "
2930                            & "NULL or static expression", Decl, E);
2931                      end if;
2932                   end;
2933                end if;
2934
2935                --  For imported objects, set Is_Public unless there is also an
2936                --  address clause, which means that there is no external symbol
2937                --  needed for the Import (Is_Public may still be set for other
2938                --  unrelated reasons). Note that we delayed this processing
2939                --  till freeze time so that we can be sure not to set the flag
2940                --  if there is an address clause. If there is such a clause,
2941                --  then the only purpose of the Import pragma is to suppress
2942                --  implicit initialization.
2943
2944                if Is_Imported (E)
2945                  and then No (Address_Clause (E))
2946                then
2947                   Set_Is_Public (E);
2948                end if;
2949
2950                --  For convention C objects of an enumeration type, warn if
2951                --  the size is not integer size and no explicit size given.
2952                --  Skip warning for Boolean, and Character, assume programmer
2953                --  expects 8-bit sizes for these cases.
2954
2955                if (Convention (E) = Convention_C
2956                     or else
2957                    Convention (E) = Convention_CPP)
2958                  and then Is_Enumeration_Type (Etype (E))
2959                  and then not Is_Character_Type (Etype (E))
2960                  and then not Is_Boolean_Type (Etype (E))
2961                  and then Esize (Etype (E)) < Standard_Integer_Size
2962                  and then not Has_Size_Clause (E)
2963                then
2964                   Error_Msg_Uint_1 := UI_From_Int (Standard_Integer_Size);
2965                   Error_Msg_N
2966                     ("?convention C enumeration object has size less than ^",
2967                      E);
2968                   Error_Msg_N ("\?use explicit size clause to set size", E);
2969                end if;
2970             end if;
2971
2972             --  Check that a constant which has a pragma Volatile[_Components]
2973             --  or Atomic[_Components] also has a pragma Import (RM C.6(13)).
2974
2975             --  Note: Atomic[_Components] also sets Volatile[_Components]
2976
2977             if Ekind (E) = E_Constant
2978               and then (Has_Volatile_Components (E) or else Is_Volatile (E))
2979               and then not Is_Imported (E)
2980             then
2981                --  Make sure we actually have a pragma, and have not merely
2982                --  inherited the indication from elsewhere (e.g. an address
2983                --  clause, which is not good enough in RM terms!)
2984
2985                if Has_Rep_Pragma (E, Name_Atomic)
2986                     or else
2987                   Has_Rep_Pragma (E, Name_Atomic_Components)
2988                then
2989                   Error_Msg_N
2990                     ("stand alone atomic constant must be " &
2991                      "imported (RM C.6(13))", E);
2992
2993                elsif Has_Rep_Pragma (E, Name_Volatile)
2994                        or else
2995                      Has_Rep_Pragma (E, Name_Volatile_Components)
2996                then
2997                   Error_Msg_N
2998                     ("stand alone volatile constant must be " &
2999                      "imported (RM C.6(13))", E);
3000                end if;
3001             end if;
3002
3003             --  Static objects require special handling
3004
3005             if (Ekind (E) = E_Constant or else Ekind (E) = E_Variable)
3006               and then Is_Statically_Allocated (E)
3007             then
3008                Freeze_Static_Object (E);
3009             end if;
3010
3011             --  Remaining step is to layout objects
3012
3013             if Ekind (E) = E_Variable
3014                  or else
3015                Ekind (E) = E_Constant
3016                  or else
3017                Ekind (E) = E_Loop_Parameter
3018                  or else
3019                Is_Formal (E)
3020             then
3021                Layout_Object (E);
3022             end if;
3023          end if;
3024
3025       --  Case of a type or subtype being frozen
3026
3027       else
3028          --  We used to check here that a full type must have preelaborable
3029          --  initialization if it completes a private type specified with
3030          --  pragma Preelaborable_Initialization, but that missed cases where
3031          --  the types occur within a generic package, since the freezing
3032          --  that occurs within a containing scope generally skips traversal
3033          --  of a generic unit's declarations (those will be frozen within
3034          --  instances). This check was moved to Analyze_Package_Specification.
3035
3036          --  The type may be defined in a generic unit. This can occur when
3037          --  freezing a generic function that returns the type (which is
3038          --  defined in a parent unit). It is clearly meaningless to freeze
3039          --  this type. However, if it is a subtype, its size may be determi-
3040          --  nable and used in subsequent checks, so might as well try to
3041          --  compute it.
3042
3043          --  In Ada2012, freeze entities is also used in the front-end to
3044          --  trigger the analysis of aspect expressions, so in this case we
3045          --  want to continue the freezing process.
3046
3047          if Present (Scope (E))
3048            and then Is_Generic_Unit (Scope (E))
3049            and then not Has_Predicates (E)
3050          then
3051             Check_Compile_Time_Size (E);
3052             return No_List;
3053          end if;
3054
3055          --  Deal with special cases of freezing for subtype
3056
3057          if E /= Base_Type (E) then
3058
3059             --  Before we do anything else, a specialized test for the case of
3060             --  a size given for an array where the array needs to be packed,
3061             --  but was not so the size cannot be honored. This would of course
3062             --  be caught by the backend, and indeed we don't catch all cases.
3063             --  The point is that we can give a better error message in those
3064             --  cases that we do catch with the circuitry here. Also if pragma
3065             --  Implicit_Packing is set, this is where the packing occurs.
3066
3067             --  The reason we do this so early is that the processing in the
3068             --  automatic packing case affects the layout of the base type, so
3069             --  it must be done before we freeze the base type.
3070
3071             if Is_Array_Type (E) then
3072                declare
3073                   Lo, Hi : Node_Id;
3074                   Ctyp   : constant Entity_Id := Component_Type (E);
3075
3076                begin
3077                   --  Check enabling conditions. These are straightforward
3078                   --  except for the test for a limited composite type. This
3079                   --  eliminates the rare case of a array of limited components
3080                   --  where there are issues of whether or not we can go ahead
3081                   --  and pack the array (since we can't freely pack and unpack
3082                   --  arrays if they are limited).
3083
3084                   --  Note that we check the root type explicitly because the
3085                   --  whole point is we are doing this test before we have had
3086                   --  a chance to freeze the base type (and it is that freeze
3087                   --  action that causes stuff to be inherited).
3088
3089                   if Present (Size_Clause (E))
3090                     and then Known_Static_RM_Size (E)
3091                     and then not Is_Packed (E)
3092                     and then not Has_Pragma_Pack (E)
3093                     and then Number_Dimensions (E) = 1
3094                     and then not Has_Component_Size_Clause (E)
3095                     and then Known_Static_RM_Size (Ctyp)
3096                     and then not Is_Limited_Composite (E)
3097                     and then not Is_Packed (Root_Type (E))
3098                     and then not Has_Component_Size_Clause (Root_Type (E))
3099                     and then not (CodePeer_Mode or Alfa_Mode)
3100                   then
3101                      Get_Index_Bounds (First_Index (E), Lo, Hi);
3102
3103                      if Compile_Time_Known_Value (Lo)
3104                        and then Compile_Time_Known_Value (Hi)
3105                        and then Known_Static_RM_Size (Ctyp)
3106                        and then RM_Size (Ctyp) < 64
3107                      then
3108                         declare
3109                            Lov  : constant Uint      := Expr_Value (Lo);
3110                            Hiv  : constant Uint      := Expr_Value (Hi);
3111                            Len  : constant Uint      := UI_Max
3112                                                          (Uint_0,
3113                                                           Hiv - Lov + 1);
3114                            Rsiz : constant Uint      := RM_Size (Ctyp);
3115                            SZ   : constant Node_Id   := Size_Clause (E);
3116                            Btyp : constant Entity_Id := Base_Type (E);
3117
3118                         --  What we are looking for here is the situation where
3119                         --  the RM_Size given would be exactly right if there
3120                         --  was a pragma Pack (resulting in the component size
3121                         --  being the same as the RM_Size). Furthermore, the
3122                         --  component type size must be an odd size (not a
3123                         --  multiple of storage unit). If the component RM size
3124                         --  is an exact number of storage units that is a power
3125                         --  of two, the array is not packed and has a standard
3126                         --  representation.
3127
3128                         begin
3129                            if RM_Size (E) = Len * Rsiz
3130                              and then Rsiz mod System_Storage_Unit /= 0
3131                            then
3132                               --  For implicit packing mode, just set the
3133                               --  component size silently.
3134
3135                               if Implicit_Packing then
3136                                  Set_Component_Size       (Btyp, Rsiz);
3137                                  Set_Is_Bit_Packed_Array  (Btyp);
3138                                  Set_Is_Packed            (Btyp);
3139                                  Set_Has_Non_Standard_Rep (Btyp);
3140
3141                                  --  Otherwise give an error message
3142
3143                               else
3144                                  Error_Msg_NE
3145                                    ("size given for& too small", SZ, E);
3146                                  Error_Msg_N -- CODEFIX
3147                                    ("\use explicit pragma Pack "
3148                                     & "or use pragma Implicit_Packing", SZ);
3149                               end if;
3150
3151                            elsif RM_Size (E) = Len * Rsiz
3152                              and then Implicit_Packing
3153                              and then
3154                                (Rsiz / System_Storage_Unit = 1
3155                                  or else Rsiz / System_Storage_Unit = 2
3156                                  or else Rsiz / System_Storage_Unit = 4)
3157                            then
3158
3159                               --  Not a packed array, but indicate the desired
3160                               --  component size, for the back-end.
3161
3162                               Set_Component_Size (Btyp, Rsiz);
3163                            end if;
3164                         end;
3165                      end if;
3166                   end if;
3167                end;
3168             end if;
3169
3170             --  If ancestor subtype present, freeze that first. Note that this
3171             --  will also get the base type frozen. Need RM reference ???
3172
3173             Atype := Ancestor_Subtype (E);
3174
3175             if Present (Atype) then
3176                Freeze_And_Append (Atype, N, Result);
3177
3178             --  No ancestor subtype present
3179
3180             else
3181                --  See if we have a nearest ancestor that has a predicate.
3182                --  That catches the case of derived type with a predicate.
3183                --  Need RM reference here ???
3184
3185                Atype := Nearest_Ancestor (E);
3186
3187                if Present (Atype) and then Has_Predicates (Atype) then
3188                   Freeze_And_Append (Atype, N, Result);
3189                end if;
3190
3191                --  Freeze base type before freezing the entity (RM 13.14(15))
3192
3193                if E /= Base_Type (E) then
3194                   Freeze_And_Append (Base_Type (E), N, Result);
3195                end if;
3196             end if;
3197
3198          --  For a derived type, freeze its parent type first (RM 13.14(15))
3199
3200          elsif Is_Derived_Type (E) then
3201             Freeze_And_Append (Etype (E), N, Result);
3202             Freeze_And_Append (First_Subtype (Etype (E)), N, Result);
3203          end if;
3204
3205          --  For array type, freeze index types and component type first
3206          --  before freezing the array (RM 13.14(15)).
3207
3208          if Is_Array_Type (E) then
3209             declare
3210                FS     : constant Entity_Id := First_Subtype (E);
3211                Ctyp   : constant Entity_Id := Component_Type (E);
3212                Clause : Entity_Id;
3213
3214                Non_Standard_Enum : Boolean := False;
3215                --  Set true if any of the index types is an enumeration type
3216                --  with a non-standard representation.
3217
3218             begin
3219                Freeze_And_Append (Ctyp, N, Result);
3220
3221                Indx := First_Index (E);
3222                while Present (Indx) loop
3223                   Freeze_And_Append (Etype (Indx), N, Result);
3224
3225                   if Is_Enumeration_Type (Etype (Indx))
3226                     and then Has_Non_Standard_Rep (Etype (Indx))
3227                   then
3228                      Non_Standard_Enum := True;
3229                   end if;
3230
3231                   Next_Index (Indx);
3232                end loop;
3233
3234                --  Processing that is done only for base types
3235
3236                if Ekind (E) = E_Array_Type then
3237
3238                   --  Propagate flags for component type
3239
3240                   if Is_Controlled (Component_Type (E))
3241                     or else Has_Controlled_Component (Ctyp)
3242                   then
3243                      Set_Has_Controlled_Component (E);
3244                   end if;
3245
3246                   if Has_Unchecked_Union (Component_Type (E)) then
3247                      Set_Has_Unchecked_Union (E);
3248                   end if;
3249
3250                   --  If packing was requested or if the component size was set
3251                   --  explicitly, then see if bit packing is required. This
3252                   --  processing is only done for base types, since all the
3253                   --  representation aspects involved are type-related. This
3254                   --  is not just an optimization, if we start processing the
3255                   --  subtypes, they interfere with the settings on the base
3256                   --  type (this is because Is_Packed has a slightly different
3257                   --  meaning before and after freezing).
3258
3259                   declare
3260                      Csiz : Uint;
3261                      Esiz : Uint;
3262
3263                   begin
3264                      if (Is_Packed (E) or else Has_Pragma_Pack (E))
3265                        and then Known_Static_RM_Size (Ctyp)
3266                        and then not Has_Component_Size_Clause (E)
3267                      then
3268                         Csiz := UI_Max (RM_Size (Ctyp), 1);
3269
3270                      elsif Known_Component_Size (E) then
3271                         Csiz := Component_Size (E);
3272
3273                      elsif not Known_Static_Esize (Ctyp) then
3274                         Csiz := Uint_0;
3275
3276                      else
3277                         Esiz := Esize (Ctyp);
3278
3279                         --  We can set the component size if it is less than
3280                         --  16, rounding it up to the next storage unit size.
3281
3282                         if Esiz <= 8 then
3283                            Csiz := Uint_8;
3284                         elsif Esiz <= 16 then
3285                            Csiz := Uint_16;
3286                         else
3287                            Csiz := Uint_0;
3288                         end if;
3289
3290                         --  Set component size up to match alignment if it
3291                         --  would otherwise be less than the alignment. This
3292                         --  deals with cases of types whose alignment exceeds
3293                         --  their size (padded types).
3294
3295                         if Csiz /= 0 then
3296                            declare
3297                               A : constant Uint := Alignment_In_Bits (Ctyp);
3298                            begin
3299                               if Csiz < A then
3300                                  Csiz := A;
3301                               end if;
3302                            end;
3303                         end if;
3304                      end if;
3305
3306                      --  Case of component size that may result in packing
3307
3308                      if 1 <= Csiz and then Csiz <= 64 then
3309                         declare
3310                            Ent         : constant Entity_Id :=
3311                                            First_Subtype (E);
3312                            Pack_Pragma : constant Node_Id :=
3313                                            Get_Rep_Pragma (Ent, Name_Pack);
3314                            Comp_Size_C : constant Node_Id :=
3315                                            Get_Attribute_Definition_Clause
3316                                              (Ent, Attribute_Component_Size);
3317                         begin
3318                            --  Warn if we have pack and component size so that
3319                            --  the pack is ignored.
3320
3321                            --  Note: here we must check for the presence of a
3322                            --  component size before checking for a Pack pragma
3323                            --  to deal with the case where the array type is a
3324                            --  derived type whose parent is currently private.
3325
3326                            if Present (Comp_Size_C)
3327                              and then Has_Pragma_Pack (Ent)
3328                              and then Warn_On_Redundant_Constructs
3329                            then
3330                               Error_Msg_Sloc := Sloc (Comp_Size_C);
3331                               Error_Msg_NE
3332                                 ("?pragma Pack for& ignored!",
3333                                  Pack_Pragma, Ent);
3334                               Error_Msg_N
3335                                 ("\?explicit component size given#!",
3336                                  Pack_Pragma);
3337                               Set_Is_Packed (Base_Type (Ent), False);
3338                               Set_Is_Bit_Packed_Array (Base_Type (Ent), False);
3339                            end if;
3340
3341                            --  Set component size if not already set by a
3342                            --  component size clause.
3343
3344                            if not Present (Comp_Size_C) then
3345                               Set_Component_Size (E, Csiz);
3346                            end if;
3347
3348                            --  Check for base type of 8, 16, 32 bits, where an
3349                            --  unsigned subtype has a length one less than the
3350                            --  base type (e.g. Natural subtype of Integer).
3351
3352                            --  In such cases, if a component size was not set
3353                            --  explicitly, then generate a warning.
3354
3355                            if Has_Pragma_Pack (E)
3356                              and then not Present (Comp_Size_C)
3357                              and then
3358                                (Csiz = 7 or else Csiz = 15 or else Csiz = 31)
3359                              and then Esize (Base_Type (Ctyp)) = Csiz + 1
3360                            then
3361                               Error_Msg_Uint_1 := Csiz;
3362
3363                               if Present (Pack_Pragma) then
3364                                  Error_Msg_N
3365                                    ("?pragma Pack causes component size "
3366                                     & "to be ^!", Pack_Pragma);
3367                                  Error_Msg_N
3368                                    ("\?use Component_Size to set "
3369                                     & "desired value!", Pack_Pragma);
3370                               end if;
3371                            end if;
3372
3373                            --  Actual packing is not needed for 8, 16, 32, 64.
3374                            --  Also not needed for 24 if alignment is 1.
3375
3376                            if        Csiz = 8
3377                              or else Csiz = 16
3378                              or else Csiz = 32
3379                              or else Csiz = 64
3380                              or else (Csiz = 24 and then Alignment (Ctyp) = 1)
3381                            then
3382                               --  Here the array was requested to be packed,
3383                               --  but the packing request had no effect, so
3384                               --  Is_Packed is reset.
3385
3386                               --  Note: semantically this means that we lose
3387                               --  track of the fact that a derived type
3388                               --  inherited a pragma Pack that was non-
3389                               --  effective, but that seems fine.
3390
3391                               --  We regard a Pack pragma as a request to set
3392                               --  a representation characteristic, and this
3393                               --  request may be ignored.
3394
3395                               Set_Is_Packed           (Base_Type (E), False);
3396                               Set_Is_Bit_Packed_Array (Base_Type (E), False);
3397
3398                               if Known_Static_Esize (Component_Type (E))
3399                                 and then Esize (Component_Type (E)) = Csiz
3400                               then
3401                                  Set_Has_Non_Standard_Rep
3402                                    (Base_Type (E), False);
3403                               end if;
3404
3405                            --  In all other cases, packing is indeed needed
3406
3407                            else
3408                               Set_Has_Non_Standard_Rep (Base_Type (E), True);
3409                               Set_Is_Bit_Packed_Array  (Base_Type (E), True);
3410                               Set_Is_Packed            (Base_Type (E), True);
3411                            end if;
3412                         end;
3413                      end if;
3414                   end;
3415
3416                   --  Check for Atomic_Components or Aliased with unsuitable
3417                   --  packing or explicit component size clause given.
3418
3419                   if (Has_Atomic_Components (E)
3420                        or else Has_Aliased_Components (E))
3421                     and then (Has_Component_Size_Clause (E)
3422                                or else Is_Packed (E))
3423                   then
3424                      Alias_Atomic_Check : declare
3425
3426                         procedure Complain_CS (T : String);
3427                         --  Outputs error messages for incorrect CS clause or
3428                         --  pragma Pack for aliased or atomic components (T is
3429                         --  "aliased" or "atomic");
3430
3431                         -----------------
3432                         -- Complain_CS --
3433                         -----------------
3434
3435                         procedure Complain_CS (T : String) is
3436                         begin
3437                            if Has_Component_Size_Clause (E) then
3438                               Clause :=
3439                                 Get_Attribute_Definition_Clause
3440                                   (FS, Attribute_Component_Size);
3441
3442                               if Known_Static_Esize (Ctyp) then
3443                                  Error_Msg_N
3444                                    ("incorrect component size for "
3445                                     & T & " components", Clause);
3446                                  Error_Msg_Uint_1 := Esize (Ctyp);
3447                                  Error_Msg_N
3448                                    ("\only allowed value is^", Clause);
3449
3450                               else
3451                                  Error_Msg_N
3452                                    ("component size cannot be given for "
3453                                     & T & " components", Clause);
3454                               end if;
3455
3456                            else
3457                               Error_Msg_N
3458                                 ("cannot pack " & T & " components",
3459                                  Get_Rep_Pragma (FS, Name_Pack));
3460                            end if;
3461
3462                            return;
3463                         end Complain_CS;
3464
3465                      --  Start of processing for Alias_Atomic_Check
3466
3467                      begin
3468
3469                         --  If object size of component type isn't known, we
3470                         --  cannot be sure so we defer to the back end.
3471
3472                         if not Known_Static_Esize (Ctyp) then
3473                            null;
3474
3475                         --  Case where component size has no effect. First
3476                         --  check for object size of component type multiple
3477                         --  of the storage unit size.
3478
3479                         elsif Esize (Ctyp) mod System_Storage_Unit = 0
3480
3481                           --  OK in both packing case and component size case
3482                           --  if RM size is known and static and the same as
3483                           --  the object size.
3484
3485                           and then
3486                             ((Known_Static_RM_Size (Ctyp)
3487                                and then Esize (Ctyp) = RM_Size (Ctyp))
3488
3489                              --  Or if we have an explicit component size
3490                              --  clause and the component size and object size
3491                              --  are equal.
3492
3493                              or else
3494                                  (Has_Component_Size_Clause (E)
3495                                  and then Component_Size (E) = Esize (Ctyp)))
3496                         then
3497                            null;
3498
3499                         elsif Has_Aliased_Components (E)
3500                           or else Is_Aliased (Ctyp)
3501                         then
3502                            Complain_CS ("aliased");
3503
3504                         elsif Has_Atomic_Components (E)
3505                           or else Is_Atomic (Ctyp)
3506                         then
3507                            Complain_CS ("atomic");
3508                         end if;
3509                      end Alias_Atomic_Check;
3510                   end if;
3511
3512                   --  Warn for case of atomic type
3513
3514                   Clause := Get_Rep_Pragma (FS, Name_Atomic);
3515
3516                   if Present (Clause)
3517                     and then not Addressable (Component_Size (FS))
3518                   then
3519                      Error_Msg_NE
3520                        ("non-atomic components of type& may not be "
3521                         & "accessible by separate tasks?", Clause, E);
3522
3523                      if Has_Component_Size_Clause (E) then
3524                         Error_Msg_Sloc :=
3525                           Sloc
3526                             (Get_Attribute_Definition_Clause
3527                                  (FS, Attribute_Component_Size));
3528                         Error_Msg_N
3529                           ("\because of component size clause#?",
3530                            Clause);
3531
3532                      elsif Has_Pragma_Pack (E) then
3533                         Error_Msg_Sloc :=
3534                           Sloc (Get_Rep_Pragma (FS, Name_Pack));
3535                         Error_Msg_N
3536                           ("\because of pragma Pack#?", Clause);
3537                      end if;
3538                   end if;
3539
3540                --  Processing that is done only for subtypes
3541
3542                else
3543                   --  Acquire alignment from base type
3544
3545                   if Unknown_Alignment (E) then
3546                      Set_Alignment (E, Alignment (Base_Type (E)));
3547                      Adjust_Esize_Alignment (E);
3548                   end if;
3549                end if;
3550
3551                --  For bit-packed arrays, check the size
3552
3553                if Is_Bit_Packed_Array (E) and then Known_RM_Size (E) then
3554                   declare
3555                      SizC : constant Node_Id := Size_Clause (E);
3556
3557                      Discard : Boolean;
3558                      pragma Warnings (Off, Discard);
3559
3560                   begin
3561                      --  It is not clear if it is possible to have no size
3562                      --  clause at this stage, but it is not worth worrying
3563                      --  about. Post error on the entity name in the size
3564                      --  clause if present, else on the type entity itself.
3565
3566                      if Present (SizC) then
3567                         Check_Size (Name (SizC), E, RM_Size (E), Discard);
3568                      else
3569                         Check_Size (E, E, RM_Size (E), Discard);
3570                      end if;
3571                   end;
3572                end if;
3573
3574                --  If any of the index types was an enumeration type with a
3575                --  non-standard rep clause, then we indicate that the array
3576                --  type is always packed (even if it is not bit packed).
3577
3578                if Non_Standard_Enum then
3579                   Set_Has_Non_Standard_Rep (Base_Type (E));
3580                   Set_Is_Packed            (Base_Type (E));
3581                end if;
3582
3583                Set_Component_Alignment_If_Not_Set (E);
3584
3585                --  If the array is packed, we must create the packed array
3586                --  type to be used to actually implement the type. This is
3587                --  only needed for real array types (not for string literal
3588                --  types, since they are present only for the front end).
3589
3590                if Is_Packed (E)
3591                  and then Ekind (E) /= E_String_Literal_Subtype
3592                then
3593                   Create_Packed_Array_Type (E);
3594                   Freeze_And_Append (Packed_Array_Type (E), N, Result);
3595
3596                   --  Size information of packed array type is copied to the
3597                   --  array type, since this is really the representation. But
3598                   --  do not override explicit existing size values. If the
3599                   --  ancestor subtype is constrained the packed_array_type
3600                   --  will be inherited from it, but the size may have been
3601                   --  provided already, and must not be overridden either.
3602
3603                   if not Has_Size_Clause (E)
3604                     and then
3605                       (No (Ancestor_Subtype (E))
3606                         or else not Has_Size_Clause (Ancestor_Subtype (E)))
3607                   then
3608                      Set_Esize     (E, Esize     (Packed_Array_Type (E)));
3609                      Set_RM_Size   (E, RM_Size   (Packed_Array_Type (E)));
3610                   end if;
3611
3612                   if not Has_Alignment_Clause (E) then
3613                      Set_Alignment (E, Alignment (Packed_Array_Type (E)));
3614                   end if;
3615                end if;
3616
3617                --  For non-packed arrays set the alignment of the array to the
3618                --  alignment of the component type if it is unknown. Skip this
3619                --  in atomic case (atomic arrays may need larger alignments).
3620
3621                if not Is_Packed (E)
3622                  and then Unknown_Alignment (E)
3623                  and then Known_Alignment (Ctyp)
3624                  and then Known_Static_Component_Size (E)
3625                  and then Known_Static_Esize (Ctyp)
3626                  and then Esize (Ctyp) = Component_Size (E)
3627                  and then not Is_Atomic (E)
3628                then
3629                   Set_Alignment (E, Alignment (Component_Type (E)));
3630                end if;
3631             end;
3632
3633          --  For a class-wide type, the corresponding specific type is
3634          --  frozen as well (RM 13.14(15))
3635
3636          elsif Is_Class_Wide_Type (E) then
3637             Freeze_And_Append (Root_Type (E), N, Result);
3638
3639             --  If the base type of the class-wide type is still incomplete,
3640             --  the class-wide remains unfrozen as well. This is legal when
3641             --  E is the formal of a primitive operation of some other type
3642             --  which is being frozen.
3643
3644             if not Is_Frozen (Root_Type (E)) then
3645                Set_Is_Frozen (E, False);
3646                return Result;
3647             end if;
3648
3649             --  If the Class_Wide_Type is an Itype (when type is the anonymous
3650             --  parent of a derived type) and it is a library-level entity,
3651             --  generate an itype reference for it. Otherwise, its first
3652             --  explicit reference may be in an inner scope, which will be
3653             --  rejected by the back-end.
3654
3655             if Is_Itype (E)
3656               and then Is_Compilation_Unit (Scope (E))
3657             then
3658                declare
3659                   Ref : constant Node_Id := Make_Itype_Reference (Loc);
3660
3661                begin
3662                   Set_Itype (Ref, E);
3663                   Add_To_Result (Ref);
3664                end;
3665             end if;
3666
3667             --  The equivalent type associated with a class-wide subtype needs
3668             --  to be frozen to ensure that its layout is done.
3669
3670             if Ekind (E) = E_Class_Wide_Subtype
3671               and then Present (Equivalent_Type (E))
3672             then
3673                Freeze_And_Append (Equivalent_Type (E), N, Result);
3674             end if;
3675
3676          --  For a record (sub)type, freeze all the component types (RM
3677          --  13.14(15). We test for E_Record_(sub)Type here, rather than using
3678          --  Is_Record_Type, because we don't want to attempt the freeze for
3679          --  the case of a private type with record extension (we will do that
3680          --  later when the full type is frozen).
3681
3682          elsif Ekind (E) = E_Record_Type
3683            or else Ekind (E) = E_Record_Subtype
3684          then
3685             Freeze_Record_Type (E);
3686
3687          --  For a concurrent type, freeze corresponding record type. This
3688          --  does not correspond to any specific rule in the RM, but the
3689          --  record type is essentially part of the concurrent type.
3690          --  Freeze as well all local entities. This includes record types
3691          --  created for entry parameter blocks, and whatever local entities
3692          --  may appear in the private part.
3693
3694          elsif Is_Concurrent_Type (E) then
3695             if Present (Corresponding_Record_Type (E)) then
3696                Freeze_And_Append
3697                  (Corresponding_Record_Type (E), N, Result);
3698             end if;
3699
3700             Comp := First_Entity (E);
3701             while Present (Comp) loop
3702                if Is_Type (Comp) then
3703                   Freeze_And_Append (Comp, N, Result);
3704
3705                elsif (Ekind (Comp)) /= E_Function then
3706                   if Is_Itype (Etype (Comp))
3707                     and then Underlying_Type (Scope (Etype (Comp))) = E
3708                   then
3709                      Undelay_Type (Etype (Comp));
3710                   end if;
3711
3712                   Freeze_And_Append (Etype (Comp), N, Result);
3713                end if;
3714
3715                Next_Entity (Comp);
3716             end loop;
3717
3718          --  Private types are required to point to the same freeze node as
3719          --  their corresponding full views. The freeze node itself has to
3720          --  point to the partial view of the entity (because from the partial
3721          --  view, we can retrieve the full view, but not the reverse).
3722          --  However, in order to freeze correctly, we need to freeze the full
3723          --  view. If we are freezing at the end of a scope (or within the
3724          --  scope of the private type), the partial and full views will have
3725          --  been swapped, the full view appears first in the entity chain and
3726          --  the swapping mechanism ensures that the pointers are properly set
3727          --  (on scope exit).
3728
3729          --  If we encounter the partial view before the full view (e.g. when
3730          --  freezing from another scope), we freeze the full view, and then
3731          --  set the pointers appropriately since we cannot rely on swapping to
3732          --  fix things up (subtypes in an outer scope might not get swapped).
3733
3734          elsif Is_Incomplete_Or_Private_Type (E)
3735            and then not Is_Generic_Type (E)
3736          then
3737             --  The construction of the dispatch table associated with library
3738             --  level tagged types forces freezing of all the primitives of the
3739             --  type, which may cause premature freezing of the partial view.
3740             --  For example:
3741
3742             --     package Pkg is
3743             --        type T is tagged private;
3744             --        type DT is new T with private;
3745             --        procedure Prim (X : in out T; Y : in out DT'Class);
3746             --     private
3747             --        type T is tagged null record;
3748             --        Obj : T;
3749             --        type DT is new T with null record;
3750             --     end;
3751
3752             --  In this case the type will be frozen later by the usual
3753             --  mechanism: an object declaration, an instantiation, or the
3754             --  end of a declarative part.
3755
3756             if Is_Library_Level_Tagged_Type (E)
3757               and then not Present (Full_View (E))
3758             then
3759                Set_Is_Frozen (E, False);
3760                return Result;
3761
3762             --  Case of full view present
3763
3764             elsif Present (Full_View (E)) then
3765
3766                --  If full view has already been frozen, then no further
3767                --  processing is required
3768
3769                if Is_Frozen (Full_View (E)) then
3770                   Set_Has_Delayed_Freeze (E, False);
3771                   Set_Freeze_Node (E, Empty);
3772                   Check_Debug_Info_Needed (E);
3773
3774                --  Otherwise freeze full view and patch the pointers so that
3775                --  the freeze node will elaborate both views in the back-end.
3776
3777                else
3778                   declare
3779                      Full : constant Entity_Id := Full_View (E);
3780
3781                   begin
3782                      if Is_Private_Type (Full)
3783                        and then Present (Underlying_Full_View (Full))
3784                      then
3785                         Freeze_And_Append
3786                           (Underlying_Full_View (Full), N, Result);
3787                      end if;
3788
3789                      Freeze_And_Append (Full, N, Result);
3790
3791                      if Has_Delayed_Freeze (E) then
3792                         F_Node := Freeze_Node (Full);
3793
3794                         if Present (F_Node) then
3795                            Set_Freeze_Node (E, F_Node);
3796                            Set_Entity (F_Node, E);
3797
3798                         else
3799                            --  {Incomplete,Private}_Subtypes with Full_Views
3800                            --  constrained by discriminants.
3801
3802                            Set_Has_Delayed_Freeze (E, False);
3803                            Set_Freeze_Node (E, Empty);
3804                         end if;
3805                      end if;
3806                   end;
3807
3808                   Check_Debug_Info_Needed (E);
3809                end if;
3810
3811                --  AI-117 requires that the convention of a partial view be the
3812                --  same as the convention of the full view. Note that this is a
3813                --  recognized breach of privacy, but it's essential for logical
3814                --  consistency of representation, and the lack of a rule in
3815                --  RM95 was an oversight.
3816
3817                Set_Convention (E, Convention (Full_View (E)));
3818
3819                Set_Size_Known_At_Compile_Time (E,
3820                  Size_Known_At_Compile_Time (Full_View (E)));
3821
3822                --  Size information is copied from the full view to the
3823                --  incomplete or private view for consistency.
3824
3825                --  We skip this is the full view is not a type. This is very
3826                --  strange of course, and can only happen as a result of
3827                --  certain illegalities, such as a premature attempt to derive
3828                --  from an incomplete type.
3829
3830                if Is_Type (Full_View (E)) then
3831                   Set_Size_Info (E, Full_View (E));
3832                   Set_RM_Size   (E, RM_Size (Full_View (E)));
3833                end if;
3834
3835                return Result;
3836
3837             --  Case of no full view present. If entity is derived or subtype,
3838             --  it is safe to freeze, correctness depends on the frozen status
3839             --  of parent. Otherwise it is either premature usage, or a Taft
3840             --  amendment type, so diagnosis is at the point of use and the
3841             --  type might be frozen later.
3842
3843             elsif E /= Base_Type (E)
3844               or else Is_Derived_Type (E)
3845             then
3846                null;
3847
3848             else
3849                Set_Is_Frozen (E, False);
3850                return No_List;
3851             end if;
3852
3853          --  For access subprogram, freeze types of all formals, the return
3854          --  type was already frozen, since it is the Etype of the function.
3855          --  Formal types can be tagged Taft amendment types, but otherwise
3856          --  they cannot be incomplete.
3857
3858          elsif Ekind (E) = E_Subprogram_Type then
3859             Formal := First_Formal (E);
3860             while Present (Formal) loop
3861                if Ekind (Etype (Formal)) = E_Incomplete_Type
3862                  and then No (Full_View (Etype (Formal)))
3863                  and then not Is_Value_Type (Etype (Formal))
3864                then
3865                   if Is_Tagged_Type (Etype (Formal)) then
3866                      null;
3867
3868                   --  AI05-151: Incomplete types are allowed in access to
3869                   --  subprogram specifications.
3870
3871                   elsif Ada_Version < Ada_2012 then
3872                      Error_Msg_NE
3873                        ("invalid use of incomplete type&", E, Etype (Formal));
3874                   end if;
3875                end if;
3876
3877                Freeze_And_Append (Etype (Formal), N, Result);
3878                Next_Formal (Formal);
3879             end loop;
3880
3881             Freeze_Subprogram (E);
3882
3883          --  For access to a protected subprogram, freeze the equivalent type
3884          --  (however this is not set if we are not generating code or if this
3885          --  is an anonymous type used just for resolution).
3886
3887          elsif Is_Access_Protected_Subprogram_Type (E) then
3888             if Present (Equivalent_Type (E)) then
3889                Freeze_And_Append (Equivalent_Type (E), N, Result);
3890             end if;
3891          end if;
3892
3893          --  Generic types are never seen by the back-end, and are also not
3894          --  processed by the expander (since the expander is turned off for
3895          --  generic processing), so we never need freeze nodes for them.
3896
3897          if Is_Generic_Type (E) then
3898             return Result;
3899          end if;
3900
3901          --  Some special processing for non-generic types to complete
3902          --  representation details not known till the freeze point.
3903
3904          if Is_Fixed_Point_Type (E) then
3905             Freeze_Fixed_Point_Type (E);
3906
3907             --  Some error checks required for ordinary fixed-point type. Defer
3908             --  these till the freeze-point since we need the small and range
3909             --  values. We only do these checks for base types
3910
3911             if Is_Ordinary_Fixed_Point_Type (E) and then Is_Base_Type (E) then
3912                if Small_Value (E) < Ureal_2_M_80 then
3913                   Error_Msg_Name_1 := Name_Small;
3914                   Error_Msg_N
3915                     ("`&''%` too small, minimum allowed is 2.0'*'*(-80)", E);
3916
3917                elsif Small_Value (E) > Ureal_2_80 then
3918                   Error_Msg_Name_1 := Name_Small;
3919                   Error_Msg_N
3920                     ("`&''%` too large, maximum allowed is 2.0'*'*80", E);
3921                end if;
3922
3923                if Expr_Value_R (Type_Low_Bound (E)) < Ureal_M_10_36 then
3924                   Error_Msg_Name_1 := Name_First;
3925                   Error_Msg_N
3926                     ("`&''%` too small, minimum allowed is -10.0'*'*36", E);
3927                end if;
3928
3929                if Expr_Value_R (Type_High_Bound (E)) > Ureal_10_36 then
3930                   Error_Msg_Name_1 := Name_Last;
3931                   Error_Msg_N
3932                     ("`&''%` too large, maximum allowed is 10.0'*'*36", E);
3933                end if;
3934             end if;
3935
3936          elsif Is_Enumeration_Type (E) then
3937             Freeze_Enumeration_Type (E);
3938
3939          elsif Is_Integer_Type (E) then
3940             Adjust_Esize_For_Alignment (E);
3941
3942             if Is_Modular_Integer_Type (E)
3943               and then Warn_On_Suspicious_Modulus_Value
3944             then
3945                Check_Suspicious_Modulus (E);
3946             end if;
3947
3948          elsif Is_Access_Type (E) then
3949
3950             --  If a pragma Default_Storage_Pool applies, and this type has no
3951             --  Storage_Pool or Storage_Size clause (which must have occurred
3952             --  before the freezing point), then use the default. This applies
3953             --  only to base types.
3954
3955             if Present (Default_Pool)
3956               and then Is_Base_Type (E)
3957               and then not Has_Storage_Size_Clause (E)
3958               and then No (Associated_Storage_Pool (E))
3959             then
3960                --  Case of pragma Default_Storage_Pool (null)
3961
3962                if Nkind (Default_Pool) = N_Null then
3963                   Set_No_Pool_Assigned (E);
3964
3965                --  Case of pragma Default_Storage_Pool (storage_pool_NAME)
3966
3967                else
3968                   Set_Associated_Storage_Pool (E, Entity (Default_Pool));
3969                end if;
3970             end if;
3971
3972             --  Check restriction for standard storage pool
3973
3974             if No (Associated_Storage_Pool (E)) then
3975                Check_Restriction (No_Standard_Storage_Pools, E);
3976             end if;
3977
3978             --  Deal with error message for pure access type. This is not an
3979             --  error in Ada 2005 if there is no pool (see AI-366).
3980
3981             if Is_Pure_Unit_Access_Type (E)
3982               and then (Ada_Version < Ada_2005
3983                          or else not No_Pool_Assigned (E))
3984             then
3985                Error_Msg_N ("named access type not allowed in pure unit", E);
3986
3987                if Ada_Version >= Ada_2005 then
3988                   Error_Msg_N
3989                     ("\would be legal if Storage_Size of 0 given?", E);
3990
3991                elsif No_Pool_Assigned (E) then
3992                   Error_Msg_N
3993                     ("\would be legal in Ada 2005?", E);
3994
3995                else
3996                   Error_Msg_N
3997                     ("\would be legal in Ada 2005 if "
3998                      & "Storage_Size of 0 given?", E);
3999                end if;
4000             end if;
4001          end if;
4002
4003          --  Case of composite types
4004
4005          if Is_Composite_Type (E) then
4006
4007             --  AI-117 requires that all new primitives of a tagged type must
4008             --  inherit the convention of the full view of the type. Inherited
4009             --  and overriding operations are defined to inherit the convention
4010             --  of their parent or overridden subprogram (also specified in
4011             --  AI-117), which will have occurred earlier (in Derive_Subprogram
4012             --  and New_Overloaded_Entity). Here we set the convention of
4013             --  primitives that are still convention Ada, which will ensure
4014             --  that any new primitives inherit the type's convention. Class-
4015             --  wide types can have a foreign convention inherited from their
4016             --  specific type, but are excluded from this since they don't have
4017             --  any associated primitives.
4018
4019             if Is_Tagged_Type (E)
4020               and then not Is_Class_Wide_Type (E)
4021               and then Convention (E) /= Convention_Ada
4022             then
4023                declare
4024                   Prim_List : constant Elist_Id := Primitive_Operations (E);
4025                   Prim      : Elmt_Id;
4026
4027                begin
4028                   Prim := First_Elmt (Prim_List);
4029                   while Present (Prim) loop
4030                      if Convention (Node (Prim)) = Convention_Ada then
4031                         Set_Convention (Node (Prim), Convention (E));
4032                      end if;
4033
4034                      Next_Elmt (Prim);
4035                   end loop;
4036                end;
4037             end if;
4038          end if;
4039
4040          --  Now that all types from which E may depend are frozen, see if the
4041          --  size is known at compile time, if it must be unsigned, or if
4042          --  strict alignment is required
4043
4044          Check_Compile_Time_Size (E);
4045          Check_Unsigned_Type (E);
4046
4047          if Base_Type (E) = E then
4048             Check_Strict_Alignment (E);
4049          end if;
4050
4051          --  Do not allow a size clause for a type which does not have a size
4052          --  that is known at compile time
4053
4054          if Has_Size_Clause (E)
4055            and then not Size_Known_At_Compile_Time (E)
4056          then
4057             --  Suppress this message if errors posted on E, even if we are
4058             --  in all errors mode, since this is often a junk message
4059
4060             if not Error_Posted (E) then
4061                Error_Msg_N
4062                  ("size clause not allowed for variable length type",
4063                   Size_Clause (E));
4064             end if;
4065          end if;
4066
4067          --  Now we set/verify the representation information, in particular
4068          --  the size and alignment values. This processing is not required for
4069          --  generic types, since generic types do not play any part in code
4070          --  generation, and so the size and alignment values for such types
4071          --  are irrelevant.
4072
4073          if Is_Generic_Type (E) then
4074             return Result;
4075
4076          --  Otherwise we call the layout procedure
4077
4078          else
4079             Layout_Type (E);
4080          end if;
4081
4082          --  If this is an access to subprogram whose designated type is itself
4083          --  a subprogram type, the return type of this anonymous subprogram
4084          --  type must be decorated as well.
4085
4086          if Ekind (E) = E_Anonymous_Access_Subprogram_Type
4087            and then Ekind (Designated_Type (E)) = E_Subprogram_Type
4088          then
4089             Layout_Type (Etype (Designated_Type (E)));
4090          end if;
4091
4092          --  If the type has a Defaut_Value/Default_Component_Value aspect,
4093          --  this is where we analye the expression (after the type is frozen,
4094          --  since in the case of Default_Value, we are analyzing with the
4095          --  type itself, and we treat Default_Component_Value similarly for
4096          --  the sake of uniformity.
4097
4098          if Is_First_Subtype (E) and then Has_Default_Aspect (E) then
4099             declare
4100                Nam    : Name_Id;
4101                Aspect : Node_Id;
4102                Exp    : Node_Id;
4103                Typ    : Entity_Id;
4104
4105             begin
4106                if Is_Scalar_Type (E) then
4107                   Nam := Name_Default_Value;
4108                   Typ := E;
4109                else
4110                   Nam := Name_Default_Component_Value;
4111                   Typ := Component_Type (E);
4112                end if;
4113
4114                Aspect := Get_Rep_Item_For_Entity (E, Nam);
4115                Exp := Expression (Aspect);
4116                Analyze_And_Resolve (Exp, Typ);
4117
4118                if Etype (Exp) /= Any_Type then
4119                   if not Is_Static_Expression (Exp) then
4120                      Error_Msg_Name_1 := Nam;
4121                      Flag_Non_Static_Expr
4122                        ("aspect% requires static expression", Exp);
4123                   end if;
4124                end if;
4125             end;
4126          end if;
4127
4128          --  End of freeze processing for type entities
4129       end if;
4130
4131       --  Here is where we logically freeze the current entity. If it has a
4132       --  freeze node, then this is the point at which the freeze node is
4133       --  linked into the result list.
4134
4135       if Has_Delayed_Freeze (E) then
4136
4137          --  If a freeze node is already allocated, use it, otherwise allocate
4138          --  a new one. The preallocation happens in the case of anonymous base
4139          --  types, where we preallocate so that we can set First_Subtype_Link.
4140          --  Note that we reset the Sloc to the current freeze location.
4141
4142          if Present (Freeze_Node (E)) then
4143             F_Node := Freeze_Node (E);
4144             Set_Sloc (F_Node, Loc);
4145
4146          else
4147             F_Node := New_Node (N_Freeze_Entity, Loc);
4148             Set_Freeze_Node (E, F_Node);
4149             Set_Access_Types_To_Process (F_Node, No_Elist);
4150             Set_TSS_Elist (F_Node, No_Elist);
4151             Set_Actions (F_Node, No_List);
4152          end if;
4153
4154          Set_Entity (F_Node, E);
4155          Add_To_Result (F_Node);
4156
4157          --  A final pass over record types with discriminants. If the type
4158          --  has an incomplete declaration, there may be constrained access
4159          --  subtypes declared elsewhere, which do not depend on the discrimi-
4160          --  nants of the type, and which are used as component types (i.e.
4161          --  the full view is a recursive type). The designated types of these
4162          --  subtypes can only be elaborated after the type itself, and they
4163          --  need an itype reference.
4164
4165          if Ekind (E) = E_Record_Type
4166            and then Has_Discriminants (E)
4167          then
4168             declare
4169                Comp : Entity_Id;
4170                IR   : Node_Id;
4171                Typ  : Entity_Id;
4172
4173             begin
4174                Comp := First_Component (E);
4175                while Present (Comp) loop
4176                   Typ  := Etype (Comp);
4177
4178                   if Ekind (Comp) = E_Component
4179                     and then Is_Access_Type (Typ)
4180                     and then Scope (Typ) /= E
4181                     and then Base_Type (Designated_Type (Typ)) = E
4182                     and then Is_Itype (Designated_Type (Typ))
4183                   then
4184                      IR := Make_Itype_Reference (Sloc (Comp));
4185                      Set_Itype (IR, Designated_Type (Typ));
4186                      Append (IR, Result);
4187                   end if;
4188
4189                   Next_Component (Comp);
4190                end loop;
4191             end;
4192          end if;
4193       end if;
4194
4195       --  When a type is frozen, the first subtype of the type is frozen as
4196       --  well (RM 13.14(15)). This has to be done after freezing the type,
4197       --  since obviously the first subtype depends on its own base type.
4198
4199       if Is_Type (E) then
4200          Freeze_And_Append (First_Subtype (E), N, Result);
4201
4202          --  If we just froze a tagged non-class wide record, then freeze the
4203          --  corresponding class-wide type. This must be done after the tagged
4204          --  type itself is frozen, because the class-wide type refers to the
4205          --  tagged type which generates the class.
4206
4207          if Is_Tagged_Type (E)
4208            and then not Is_Class_Wide_Type (E)
4209            and then Present (Class_Wide_Type (E))
4210          then
4211             Freeze_And_Append (Class_Wide_Type (E), N, Result);
4212          end if;
4213       end if;
4214
4215       Check_Debug_Info_Needed (E);
4216
4217       --  Special handling for subprograms
4218
4219       if Is_Subprogram (E) then
4220
4221          --  If subprogram has address clause then reset Is_Public flag, since
4222          --  we do not want the backend to generate external references.
4223
4224          if Present (Address_Clause (E))
4225            and then not Is_Library_Level_Entity (E)
4226          then
4227             Set_Is_Public (E, False);
4228
4229          --  If no address clause and not intrinsic, then for imported
4230          --  subprogram in main unit, generate descriptor if we are in
4231          --  Propagate_Exceptions mode.
4232
4233          --  This is very odd code, it makes a null result, why ???
4234
4235          elsif Propagate_Exceptions
4236            and then Is_Imported (E)
4237            and then not Is_Intrinsic_Subprogram (E)
4238            and then Convention (E) /= Convention_Stubbed
4239          then
4240             if Result = No_List then
4241                Result := Empty_List;
4242             end if;
4243          end if;
4244       end if;
4245
4246       return Result;
4247    end Freeze_Entity;
4248
4249    -----------------------------
4250    -- Freeze_Enumeration_Type --
4251    -----------------------------
4252
4253    procedure Freeze_Enumeration_Type (Typ : Entity_Id) is
4254    begin
4255       --  By default, if no size clause is present, an enumeration type with
4256       --  Convention C is assumed to interface to a C enum, and has integer
4257       --  size. This applies to types. For subtypes, verify that its base
4258       --  type has no size clause either. Treat other foreign conventions
4259       --  in the same way, and also make sure alignment is set right.
4260
4261       if Has_Foreign_Convention (Typ)
4262         and then not Has_Size_Clause (Typ)
4263         and then not Has_Size_Clause (Base_Type (Typ))
4264         and then Esize (Typ) < Standard_Integer_Size
4265       then
4266          Init_Esize (Typ, Standard_Integer_Size);
4267          Set_Alignment (Typ, Alignment (Standard_Integer));
4268
4269       else
4270          --  If the enumeration type interfaces to C, and it has a size clause
4271          --  that specifies less than int size, it warrants a warning. The
4272          --  user may intend the C type to be an enum or a char, so this is
4273          --  not by itself an error that the Ada compiler can detect, but it
4274          --  it is a worth a heads-up. For Boolean and Character types we
4275          --  assume that the programmer has the proper C type in mind.
4276
4277          if Convention (Typ) = Convention_C
4278            and then Has_Size_Clause (Typ)
4279            and then Esize (Typ) /= Esize (Standard_Integer)
4280            and then not Is_Boolean_Type (Typ)
4281            and then not Is_Character_Type (Typ)
4282          then
4283             Error_Msg_N
4284               ("C enum types have the size of a C int?", Size_Clause (Typ));
4285          end if;
4286
4287          Adjust_Esize_For_Alignment (Typ);
4288       end if;
4289    end Freeze_Enumeration_Type;
4290
4291    -----------------------
4292    -- Freeze_Expression --
4293    -----------------------
4294
4295    procedure Freeze_Expression (N : Node_Id) is
4296       In_Spec_Exp : constant Boolean := In_Spec_Expression;
4297       Typ         : Entity_Id;
4298       Nam         : Entity_Id;
4299       Desig_Typ   : Entity_Id;
4300       P           : Node_Id;
4301       Parent_P    : Node_Id;
4302
4303       Freeze_Outside : Boolean := False;
4304       --  This flag is set true if the entity must be frozen outside the
4305       --  current subprogram. This happens in the case of expander generated
4306       --  subprograms (_Init_Proc, _Input, _Output, _Read, _Write) which do
4307       --  not freeze all entities like other bodies, but which nevertheless
4308       --  may reference entities that have to be frozen before the body and
4309       --  obviously cannot be frozen inside the body.
4310
4311       function In_Exp_Body (N : Node_Id) return Boolean;
4312       --  Given an N_Handled_Sequence_Of_Statements node N, determines whether
4313       --  it is the handled statement sequence of an expander-generated
4314       --  subprogram (init proc, stream subprogram, or renaming as body).
4315       --  If so, this is not a freezing context.
4316
4317       -----------------
4318       -- In_Exp_Body --
4319       -----------------
4320
4321       function In_Exp_Body (N : Node_Id) return Boolean is
4322          P  : Node_Id;
4323          Id : Entity_Id;
4324
4325       begin
4326          if Nkind (N) = N_Subprogram_Body then
4327             P := N;
4328          else
4329             P := Parent (N);
4330          end if;
4331
4332          if Nkind (P) /= N_Subprogram_Body then
4333             return False;
4334
4335          else
4336             Id := Defining_Unit_Name (Specification (P));
4337
4338             if Nkind (Id) = N_Defining_Identifier
4339               and then (Is_Init_Proc (Id)              or else
4340                         Is_TSS (Id, TSS_Stream_Input)  or else
4341                         Is_TSS (Id, TSS_Stream_Output) or else
4342                         Is_TSS (Id, TSS_Stream_Read)   or else
4343                         Is_TSS (Id, TSS_Stream_Write)  or else
4344                         Nkind (Original_Node (P)) =
4345                           N_Subprogram_Renaming_Declaration)
4346             then
4347                return True;
4348             else
4349                return False;
4350             end if;
4351          end if;
4352       end In_Exp_Body;
4353
4354    --  Start of processing for Freeze_Expression
4355
4356    begin
4357       --  Immediate return if freezing is inhibited. This flag is set by the
4358       --  analyzer to stop freezing on generated expressions that would cause
4359       --  freezing if they were in the source program, but which are not
4360       --  supposed to freeze, since they are created.
4361
4362       if Must_Not_Freeze (N) then
4363          return;
4364       end if;
4365
4366       --  If expression is non-static, then it does not freeze in a default
4367       --  expression, see section "Handling of Default Expressions" in the
4368       --  spec of package Sem for further details. Note that we have to make
4369       --  sure that we actually have a real expression (if we have a subtype
4370       --  indication, we can't test Is_Static_Expression!) However, we exclude
4371       --  the case of the prefix of an attribute of a static scalar subtype
4372       --  from this early return, because static subtype attributes should
4373       --  always cause freezing, even in default expressions, but the attribute
4374       --  may not have been marked as static yet (because in Resolve_Attribute,
4375       --  the call to Eval_Attribute follows the call of Freeze_Expression on
4376       --  the prefix).
4377
4378       if In_Spec_Exp
4379         and then Nkind (N) in N_Subexpr
4380         and then not Is_Static_Expression (N)
4381         and then (Nkind (Parent (N)) /= N_Attribute_Reference
4382                    or else not (Is_Entity_Name (N)
4383                                  and then Is_Type (Entity (N))
4384                                  and then Is_Static_Subtype (Entity (N))))
4385       then
4386          return;
4387       end if;
4388
4389       --  Freeze type of expression if not frozen already
4390
4391       Typ := Empty;
4392
4393       if Nkind (N) in N_Has_Etype then
4394          if not Is_Frozen (Etype (N)) then
4395             Typ := Etype (N);
4396
4397          --  Base type may be an derived numeric type that is frozen at
4398          --  the point of declaration, but first_subtype is still unfrozen.
4399
4400          elsif not Is_Frozen (First_Subtype (Etype (N))) then
4401             Typ := First_Subtype (Etype (N));
4402          end if;
4403       end if;
4404
4405       --  For entity name, freeze entity if not frozen already. A special
4406       --  exception occurs for an identifier that did not come from source.
4407       --  We don't let such identifiers freeze a non-internal entity, i.e.
4408       --  an entity that did come from source, since such an identifier was
4409       --  generated by the expander, and cannot have any semantic effect on
4410       --  the freezing semantics. For example, this stops the parameter of
4411       --  an initialization procedure from freezing the variable.
4412
4413       if Is_Entity_Name (N)
4414         and then not Is_Frozen (Entity (N))
4415         and then (Nkind (N) /= N_Identifier
4416                    or else Comes_From_Source (N)
4417                    or else not Comes_From_Source (Entity (N)))
4418       then
4419          Nam := Entity (N);
4420       else
4421          Nam := Empty;
4422       end if;
4423
4424       --  For an allocator freeze designated type if not frozen already
4425
4426       --  For an aggregate whose component type is an access type, freeze the
4427       --  designated type now, so that its freeze does not appear within the
4428       --  loop that might be created in the expansion of the aggregate. If the
4429       --  designated type is a private type without full view, the expression
4430       --  cannot contain an allocator, so the type is not frozen.
4431
4432       --  For a function, we freeze the entity when the subprogram declaration
4433       --  is frozen, but a function call may appear in an initialization proc.
4434       --  before the declaration is frozen. We need to generate the extra
4435       --  formals, if any, to ensure that the expansion of the call includes
4436       --  the proper actuals. This only applies to Ada subprograms, not to
4437       --  imported ones.
4438
4439       Desig_Typ := Empty;
4440
4441       case Nkind (N) is
4442          when N_Allocator =>
4443             Desig_Typ := Designated_Type (Etype (N));
4444
4445          when N_Aggregate =>
4446             if Is_Array_Type (Etype (N))
4447               and then Is_Access_Type (Component_Type (Etype (N)))
4448             then
4449                Desig_Typ := Designated_Type (Component_Type (Etype (N)));
4450             end if;
4451
4452          when N_Selected_Component |
4453             N_Indexed_Component    |
4454             N_Slice                =>
4455
4456             if Is_Access_Type (Etype (Prefix (N))) then
4457                Desig_Typ := Designated_Type (Etype (Prefix (N)));
4458             end if;
4459
4460          when N_Identifier =>
4461             if Present (Nam)
4462               and then Ekind (Nam) = E_Function
4463               and then Nkind (Parent (N)) = N_Function_Call
4464               and then Convention (Nam) = Convention_Ada
4465             then
4466                Create_Extra_Formals (Nam);
4467             end if;
4468
4469          when others =>
4470             null;
4471       end case;
4472
4473       if Desig_Typ /= Empty
4474         and then (Is_Frozen (Desig_Typ)
4475                    or else (not Is_Fully_Defined (Desig_Typ)))
4476       then
4477          Desig_Typ := Empty;
4478       end if;
4479
4480       --  All done if nothing needs freezing
4481
4482       if No (Typ)
4483         and then No (Nam)
4484         and then No (Desig_Typ)
4485       then
4486          return;
4487       end if;
4488
4489       --  Loop for looking at the right place to insert the freeze nodes,
4490       --  exiting from the loop when it is appropriate to insert the freeze
4491       --  node before the current node P.
4492
4493       --  Also checks some special exceptions to the freezing rules. These
4494       --  cases result in a direct return, bypassing the freeze action.
4495
4496       P := N;
4497       loop
4498          Parent_P := Parent (P);
4499
4500          --  If we don't have a parent, then we are not in a well-formed tree.
4501          --  This is an unusual case, but there are some legitimate situations
4502          --  in which this occurs, notably when the expressions in the range of
4503          --  a type declaration are resolved. We simply ignore the freeze
4504          --  request in this case. Is this right ???
4505
4506          if No (Parent_P) then
4507             return;
4508          end if;
4509
4510          --  See if we have got to an appropriate point in the tree
4511
4512          case Nkind (Parent_P) is
4513
4514             --  A special test for the exception of (RM 13.14(8)) for the case
4515             --  of per-object expressions (RM 3.8(18)) occurring in component
4516             --  definition or a discrete subtype definition. Note that we test
4517             --  for a component declaration which includes both cases we are
4518             --  interested in, and furthermore the tree does not have explicit
4519             --  nodes for either of these two constructs.
4520
4521             when N_Component_Declaration =>
4522
4523                --  The case we want to test for here is an identifier that is
4524                --  a per-object expression, this is either a discriminant that
4525                --  appears in a context other than the component declaration
4526                --  or it is a reference to the type of the enclosing construct.
4527
4528                --  For either of these cases, we skip the freezing
4529
4530                if not In_Spec_Expression
4531                  and then Nkind (N) = N_Identifier
4532                  and then (Present (Entity (N)))
4533                then
4534                   --  We recognize the discriminant case by just looking for
4535                   --  a reference to a discriminant. It can only be one for
4536                   --  the enclosing construct. Skip freezing in this case.
4537
4538                   if Ekind (Entity (N)) = E_Discriminant then
4539                      return;
4540
4541                   --  For the case of a reference to the enclosing record,
4542                   --  (or task or protected type), we look for a type that
4543                   --  matches the current scope.
4544
4545                   elsif Entity (N) = Current_Scope then
4546                      return;
4547                   end if;
4548                end if;
4549
4550             --  If we have an enumeration literal that appears as the choice in
4551             --  the aggregate of an enumeration representation clause, then
4552             --  freezing does not occur (RM 13.14(10)).
4553
4554             when N_Enumeration_Representation_Clause =>
4555
4556                --  The case we are looking for is an enumeration literal
4557
4558                if (Nkind (N) = N_Identifier or Nkind (N) = N_Character_Literal)
4559                  and then Is_Enumeration_Type (Etype (N))
4560                then
4561                   --  If enumeration literal appears directly as the choice,
4562                   --  do not freeze (this is the normal non-overloaded case)
4563
4564                   if Nkind (Parent (N)) = N_Component_Association
4565                     and then First (Choices (Parent (N))) = N
4566                   then
4567                      return;
4568
4569                   --  If enumeration literal appears as the name of function
4570                   --  which is the choice, then also do not freeze. This
4571                   --  happens in the overloaded literal case, where the
4572                   --  enumeration literal is temporarily changed to a function
4573                   --  call for overloading analysis purposes.
4574
4575                   elsif Nkind (Parent (N)) = N_Function_Call
4576                      and then
4577                        Nkind (Parent (Parent (N))) = N_Component_Association
4578                      and then
4579                        First (Choices (Parent (Parent (N)))) = Parent (N)
4580                   then
4581                      return;
4582                   end if;
4583                end if;
4584
4585             --  Normally if the parent is a handled sequence of statements,
4586             --  then the current node must be a statement, and that is an
4587             --  appropriate place to insert a freeze node.
4588
4589             when N_Handled_Sequence_Of_Statements =>
4590
4591                --  An exception occurs when the sequence of statements is for
4592                --  an expander generated body that did not do the usual freeze
4593                --  all operation. In this case we usually want to freeze
4594                --  outside this body, not inside it, and we skip past the
4595                --  subprogram body that we are inside.
4596
4597                if In_Exp_Body (Parent_P) then
4598
4599                   --  However, we *do* want to freeze at this point if we have
4600                   --  an entity to freeze, and that entity is declared *inside*
4601                   --  the body of the expander generated procedure. This case
4602                   --  is recognized by the scope of the type, which is either
4603                   --  the spec for some enclosing body, or (in the case of
4604                   --  init_procs, for which there are no separate specs) the
4605                   --  current scope.
4606
4607                   declare
4608                      Subp : constant Node_Id := Parent (Parent_P);
4609                      Cspc : Entity_Id;
4610
4611                   begin
4612                      if Nkind (Subp) = N_Subprogram_Body then
4613                         Cspc := Corresponding_Spec (Subp);
4614
4615                         if (Present (Typ) and then Scope (Typ) = Cspc)
4616                              or else
4617                            (Present (Nam) and then Scope (Nam) = Cspc)
4618                         then
4619                            exit;
4620
4621                         elsif Present (Typ)
4622                           and then Scope (Typ) = Current_Scope
4623                           and then Current_Scope = Defining_Entity (Subp)
4624                         then
4625                            exit;
4626                         end if;
4627                      end if;
4628                   end;
4629
4630                   --  If not that exception to the exception, then this is
4631                   --  where we delay the freeze till outside the body.
4632
4633                   Parent_P := Parent (Parent_P);
4634                   Freeze_Outside := True;
4635
4636                --  Here if normal case where we are in handled statement
4637                --  sequence and want to do the insertion right there.
4638
4639                else
4640                   exit;
4641                end if;
4642
4643             --  If parent is a body or a spec or a block, then the current node
4644             --  is a statement or declaration and we can insert the freeze node
4645             --  before it.
4646
4647             when N_Block_Statement       |
4648                  N_Entry_Body            |
4649                  N_Package_Body          |
4650                  N_Package_Specification |
4651                  N_Protected_Body        |
4652                  N_Subprogram_Body       |
4653                  N_Task_Body             => exit;
4654
4655             --  The expander is allowed to define types in any statements list,
4656             --  so any of the following parent nodes also mark a freezing point
4657             --  if the actual node is in a list of statements or declarations.
4658
4659             when N_Abortable_Part             |
4660                  N_Accept_Alternative         |
4661                  N_And_Then                   |
4662                  N_Case_Statement_Alternative |
4663                  N_Compilation_Unit_Aux       |
4664                  N_Conditional_Entry_Call     |
4665                  N_Delay_Alternative          |
4666                  N_Elsif_Part                 |
4667                  N_Entry_Call_Alternative     |
4668                  N_Exception_Handler          |
4669                  N_Extended_Return_Statement  |
4670                  N_Freeze_Entity              |
4671                  N_If_Statement               |
4672                  N_Or_Else                    |
4673                  N_Selective_Accept           |
4674                  N_Triggering_Alternative     =>
4675
4676                exit when Is_List_Member (P);
4677
4678             --  Note: The N_Loop_Statement is a special case. A type that
4679             --  appears in the source can never be frozen in a loop (this
4680             --  occurs only because of a loop expanded by the expander), so we
4681             --  keep on going. Otherwise we terminate the search. Same is true
4682             --  of any entity which comes from source. (if they have predefined
4683             --  type, that type does not appear to come from source, but the
4684             --  entity should not be frozen here).
4685
4686             when N_Loop_Statement =>
4687                exit when not Comes_From_Source (Etype (N))
4688                  and then (No (Nam) or else not Comes_From_Source (Nam));
4689
4690             --  For all other cases, keep looking at parents
4691
4692             when others =>
4693                null;
4694          end case;
4695
4696          --  We fall through the case if we did not yet find the proper
4697          --  place in the free for inserting the freeze node, so climb!
4698
4699          P := Parent_P;
4700       end loop;
4701
4702       --  If the expression appears in a record or an initialization procedure,
4703       --  the freeze nodes are collected and attached to the current scope, to
4704       --  be inserted and analyzed on exit from the scope, to insure that
4705       --  generated entities appear in the correct scope. If the expression is
4706       --  a default for a discriminant specification, the scope is still void.
4707       --  The expression can also appear in the discriminant part of a private
4708       --  or concurrent type.
4709
4710       --  If the expression appears in a constrained subcomponent of an
4711       --  enclosing record declaration, the freeze nodes must be attached to
4712       --  the outer record type so they can eventually be placed in the
4713       --  enclosing declaration list.
4714
4715       --  The other case requiring this special handling is if we are in a
4716       --  default expression, since in that case we are about to freeze a
4717       --  static type, and the freeze scope needs to be the outer scope, not
4718       --  the scope of the subprogram with the default parameter.
4719
4720       --  For default expressions and other spec expressions in generic units,
4721       --  the Move_Freeze_Nodes mechanism (see sem_ch12.adb) takes care of
4722       --  placing them at the proper place, after the generic unit.
4723
4724       if (In_Spec_Exp and not Inside_A_Generic)
4725         or else Freeze_Outside
4726         or else (Is_Type (Current_Scope)
4727                   and then (not Is_Concurrent_Type (Current_Scope)
4728                              or else not Has_Completion (Current_Scope)))
4729         or else Ekind (Current_Scope) = E_Void
4730       then
4731          declare
4732             N            : constant Node_Id    := Current_Scope;
4733             Freeze_Nodes : List_Id             := No_List;
4734             Pos          : Int                 := Scope_Stack.Last;
4735
4736          begin
4737             if Present (Desig_Typ) then
4738                Freeze_And_Append (Desig_Typ, N, Freeze_Nodes);
4739             end if;
4740
4741             if Present (Typ) then
4742                Freeze_And_Append (Typ, N, Freeze_Nodes);
4743             end if;
4744
4745             if Present (Nam) then
4746                Freeze_And_Append (Nam, N, Freeze_Nodes);
4747             end if;
4748
4749             --  The current scope may be that of a constrained component of
4750             --  an enclosing record declaration, which is above the current
4751             --  scope in the scope stack.
4752             --  If the expression is within a top-level pragma, as for a pre-
4753             --  condition on a library-level subprogram, nothing to do.
4754
4755             if not Is_Compilation_Unit (Current_Scope)
4756               and then Is_Record_Type (Scope (Current_Scope))
4757             then
4758                Pos := Pos - 1;
4759             end if;
4760
4761             if Is_Non_Empty_List (Freeze_Nodes) then
4762                if No (Scope_Stack.Table (Pos).Pending_Freeze_Actions) then
4763                   Scope_Stack.Table (Pos).Pending_Freeze_Actions :=
4764                     Freeze_Nodes;
4765                else
4766                   Append_List (Freeze_Nodes,
4767                     Scope_Stack.Table (Pos).Pending_Freeze_Actions);
4768                end if;
4769             end if;
4770          end;
4771
4772          return;
4773       end if;
4774
4775       --  Now we have the right place to do the freezing. First, a special
4776       --  adjustment, if we are in spec-expression analysis mode, these freeze
4777       --  actions must not be thrown away (normally all inserted actions are
4778       --  thrown away in this mode. However, the freeze actions are from static
4779       --  expressions and one of the important reasons we are doing this
4780       --  special analysis is to get these freeze actions. Therefore we turn
4781       --  off the In_Spec_Expression mode to propagate these freeze actions.
4782       --  This also means they get properly analyzed and expanded.
4783
4784       In_Spec_Expression := False;
4785
4786       --  Freeze the designated type of an allocator (RM 13.14(13))
4787
4788       if Present (Desig_Typ) then
4789          Freeze_Before (P, Desig_Typ);
4790       end if;
4791
4792       --  Freeze type of expression (RM 13.14(10)). Note that we took care of
4793       --  the enumeration representation clause exception in the loop above.
4794
4795       if Present (Typ) then
4796          Freeze_Before (P, Typ);
4797       end if;
4798
4799       --  Freeze name if one is present (RM 13.14(11))
4800
4801       if Present (Nam) then
4802          Freeze_Before (P, Nam);
4803       end if;
4804
4805       --  Restore In_Spec_Expression flag
4806
4807       In_Spec_Expression := In_Spec_Exp;
4808    end Freeze_Expression;
4809
4810    -----------------------------
4811    -- Freeze_Fixed_Point_Type --
4812    -----------------------------
4813
4814    --  Certain fixed-point types and subtypes, including implicit base types
4815    --  and declared first subtypes, have not yet set up a range. This is
4816    --  because the range cannot be set until the Small and Size values are
4817    --  known, and these are not known till the type is frozen.
4818
4819    --  To signal this case, Scalar_Range contains an unanalyzed syntactic range
4820    --  whose bounds are unanalyzed real literals. This routine will recognize
4821    --  this case, and transform this range node into a properly typed range
4822    --  with properly analyzed and resolved values.
4823
4824    procedure Freeze_Fixed_Point_Type (Typ : Entity_Id) is
4825       Rng   : constant Node_Id    := Scalar_Range (Typ);
4826       Lo    : constant Node_Id    := Low_Bound (Rng);
4827       Hi    : constant Node_Id    := High_Bound (Rng);
4828       Btyp  : constant Entity_Id  := Base_Type (Typ);
4829       Brng  : constant Node_Id    := Scalar_Range (Btyp);
4830       BLo   : constant Node_Id    := Low_Bound (Brng);
4831       BHi   : constant Node_Id    := High_Bound (Brng);
4832       Small : constant Ureal      := Small_Value (Typ);
4833       Loval : Ureal;
4834       Hival : Ureal;
4835       Atype : Entity_Id;
4836
4837       Actual_Size : Nat;
4838
4839       function Fsize (Lov, Hiv : Ureal) return Nat;
4840       --  Returns size of type with given bounds. Also leaves these
4841       --  bounds set as the current bounds of the Typ.
4842
4843       -----------
4844       -- Fsize --
4845       -----------
4846
4847       function Fsize (Lov, Hiv : Ureal) return Nat is
4848       begin
4849          Set_Realval (Lo, Lov);
4850          Set_Realval (Hi, Hiv);
4851          return Minimum_Size (Typ);
4852       end Fsize;
4853
4854    --  Start of processing for Freeze_Fixed_Point_Type
4855
4856    begin
4857       --  If Esize of a subtype has not previously been set, set it now
4858
4859       if Unknown_Esize (Typ) then
4860          Atype := Ancestor_Subtype (Typ);
4861
4862          if Present (Atype) then
4863             Set_Esize (Typ, Esize (Atype));
4864          else
4865             Set_Esize (Typ, Esize (Base_Type (Typ)));
4866          end if;
4867       end if;
4868
4869       --  Immediate return if the range is already analyzed. This means that
4870       --  the range is already set, and does not need to be computed by this
4871       --  routine.
4872
4873       if Analyzed (Rng) then
4874          return;
4875       end if;
4876
4877       --  Immediate return if either of the bounds raises Constraint_Error
4878
4879       if Raises_Constraint_Error (Lo)
4880         or else Raises_Constraint_Error (Hi)
4881       then
4882          return;
4883       end if;
4884
4885       Loval := Realval (Lo);
4886       Hival := Realval (Hi);
4887
4888       --  Ordinary fixed-point case
4889
4890       if Is_Ordinary_Fixed_Point_Type (Typ) then
4891
4892          --  For the ordinary fixed-point case, we are allowed to fudge the
4893          --  end-points up or down by small. Generally we prefer to fudge up,
4894          --  i.e. widen the bounds for non-model numbers so that the end points
4895          --  are included. However there are cases in which this cannot be
4896          --  done, and indeed cases in which we may need to narrow the bounds.
4897          --  The following circuit makes the decision.
4898
4899          --  Note: our terminology here is that Incl_EP means that the bounds
4900          --  are widened by Small if necessary to include the end points, and
4901          --  Excl_EP means that the bounds are narrowed by Small to exclude the
4902          --  end-points if this reduces the size.
4903
4904          --  Note that in the Incl case, all we care about is including the
4905          --  end-points. In the Excl case, we want to narrow the bounds as
4906          --  much as permitted by the RM, to give the smallest possible size.
4907
4908          Fudge : declare
4909             Loval_Incl_EP : Ureal;
4910             Hival_Incl_EP : Ureal;
4911
4912             Loval_Excl_EP : Ureal;
4913             Hival_Excl_EP : Ureal;
4914
4915             Size_Incl_EP  : Nat;
4916             Size_Excl_EP  : Nat;
4917
4918             Model_Num     : Ureal;
4919             First_Subt    : Entity_Id;
4920             Actual_Lo     : Ureal;
4921             Actual_Hi     : Ureal;
4922
4923          begin
4924             --  First step. Base types are required to be symmetrical. Right
4925             --  now, the base type range is a copy of the first subtype range.
4926             --  This will be corrected before we are done, but right away we
4927             --  need to deal with the case where both bounds are non-negative.
4928             --  In this case, we set the low bound to the negative of the high
4929             --  bound, to make sure that the size is computed to include the
4930             --  required sign. Note that we do not need to worry about the
4931             --  case of both bounds negative, because the sign will be dealt
4932             --  with anyway. Furthermore we can't just go making such a bound
4933             --  symmetrical, since in a twos-complement system, there is an
4934             --  extra negative value which could not be accommodated on the
4935             --  positive side.
4936
4937             if Typ = Btyp
4938               and then not UR_Is_Negative (Loval)
4939               and then Hival > Loval
4940             then
4941                Loval := -Hival;
4942                Set_Realval (Lo, Loval);
4943             end if;
4944
4945             --  Compute the fudged bounds. If the number is a model number,
4946             --  then we do nothing to include it, but we are allowed to backoff
4947             --  to the next adjacent model number when we exclude it. If it is
4948             --  not a model number then we straddle the two values with the
4949             --  model numbers on either side.
4950
4951             Model_Num := UR_Trunc (Loval / Small) * Small;
4952
4953             if Loval = Model_Num then
4954                Loval_Incl_EP := Model_Num;
4955             else
4956                Loval_Incl_EP := Model_Num - Small;
4957             end if;
4958
4959             --  The low value excluding the end point is Small greater, but
4960             --  we do not do this exclusion if the low value is positive,
4961             --  since it can't help the size and could actually hurt by
4962             --  crossing the high bound.
4963
4964             if UR_Is_Negative (Loval_Incl_EP) then
4965                Loval_Excl_EP := Loval_Incl_EP + Small;
4966
4967                --  If the value went from negative to zero, then we have the
4968                --  case where Loval_Incl_EP is the model number just below
4969                --  zero, so we want to stick to the negative value for the
4970                --  base type to maintain the condition that the size will
4971                --  include signed values.
4972
4973                if Typ = Btyp
4974                  and then UR_Is_Zero (Loval_Excl_EP)
4975                then
4976                   Loval_Excl_EP := Loval_Incl_EP;
4977                end if;
4978
4979             else
4980                Loval_Excl_EP := Loval_Incl_EP;
4981             end if;
4982
4983             --  Similar processing for upper bound and high value
4984
4985             Model_Num := UR_Trunc (Hival / Small) * Small;
4986
4987             if Hival = Model_Num then
4988                Hival_Incl_EP := Model_Num;
4989             else
4990                Hival_Incl_EP := Model_Num + Small;
4991             end if;
4992
4993             if UR_Is_Positive (Hival_Incl_EP) then
4994                Hival_Excl_EP := Hival_Incl_EP - Small;
4995             else
4996                Hival_Excl_EP := Hival_Incl_EP;
4997             end if;
4998
4999             --  One further adjustment is needed. In the case of subtypes, we
5000             --  cannot go outside the range of the base type, or we get
5001             --  peculiarities, and the base type range is already set. This
5002             --  only applies to the Incl values, since clearly the Excl values
5003             --  are already as restricted as they are allowed to be.
5004
5005             if Typ /= Btyp then
5006                Loval_Incl_EP := UR_Max (Loval_Incl_EP, Realval (BLo));
5007                Hival_Incl_EP := UR_Min (Hival_Incl_EP, Realval (BHi));
5008             end if;
5009
5010             --  Get size including and excluding end points
5011
5012             Size_Incl_EP := Fsize (Loval_Incl_EP, Hival_Incl_EP);
5013             Size_Excl_EP := Fsize (Loval_Excl_EP, Hival_Excl_EP);
5014
5015             --  No need to exclude end-points if it does not reduce size
5016
5017             if Fsize (Loval_Incl_EP, Hival_Excl_EP) = Size_Excl_EP then
5018                Loval_Excl_EP := Loval_Incl_EP;
5019             end if;
5020
5021             if Fsize (Loval_Excl_EP, Hival_Incl_EP) = Size_Excl_EP then
5022                Hival_Excl_EP := Hival_Incl_EP;
5023             end if;
5024
5025             --  Now we set the actual size to be used. We want to use the
5026             --  bounds fudged up to include the end-points but only if this
5027             --  can be done without violating a specifically given size
5028             --  size clause or causing an unacceptable increase in size.
5029
5030             --  Case of size clause given
5031
5032             if Has_Size_Clause (Typ) then
5033
5034                --  Use the inclusive size only if it is consistent with
5035                --  the explicitly specified size.
5036
5037                if Size_Incl_EP <= RM_Size (Typ) then
5038                   Actual_Lo   := Loval_Incl_EP;
5039                   Actual_Hi   := Hival_Incl_EP;
5040                   Actual_Size := Size_Incl_EP;
5041
5042                --  If the inclusive size is too large, we try excluding
5043                --  the end-points (will be caught later if does not work).
5044
5045                else
5046                   Actual_Lo   := Loval_Excl_EP;
5047                   Actual_Hi   := Hival_Excl_EP;
5048                   Actual_Size := Size_Excl_EP;
5049                end if;
5050
5051             --  Case of size clause not given
5052
5053             else
5054                --  If we have a base type whose corresponding first subtype
5055                --  has an explicit size that is large enough to include our
5056                --  end-points, then do so. There is no point in working hard
5057                --  to get a base type whose size is smaller than the specified
5058                --  size of the first subtype.
5059
5060                First_Subt := First_Subtype (Typ);
5061
5062                if Has_Size_Clause (First_Subt)
5063                  and then Size_Incl_EP <= Esize (First_Subt)
5064                then
5065                   Actual_Size := Size_Incl_EP;
5066                   Actual_Lo   := Loval_Incl_EP;
5067                   Actual_Hi   := Hival_Incl_EP;
5068
5069                --  If excluding the end-points makes the size smaller and
5070                --  results in a size of 8,16,32,64, then we take the smaller
5071                --  size. For the 64 case, this is compulsory. For the other
5072                --  cases, it seems reasonable. We like to include end points
5073                --  if we can, but not at the expense of moving to the next
5074                --  natural boundary of size.
5075
5076                elsif Size_Incl_EP /= Size_Excl_EP
5077                  and then Addressable (Size_Excl_EP)
5078                then
5079                   Actual_Size := Size_Excl_EP;
5080                   Actual_Lo   := Loval_Excl_EP;
5081                   Actual_Hi   := Hival_Excl_EP;
5082
5083                --  Otherwise we can definitely include the end points
5084
5085                else
5086                   Actual_Size := Size_Incl_EP;
5087                   Actual_Lo   := Loval_Incl_EP;
5088                   Actual_Hi   := Hival_Incl_EP;
5089                end if;
5090
5091                --  One pathological case: normally we never fudge a low bound
5092                --  down, since it would seem to increase the size (if it has
5093                --  any effect), but for ranges containing single value, or no
5094                --  values, the high bound can be small too large. Consider:
5095
5096                --    type t is delta 2.0**(-14)
5097                --      range 131072.0 .. 0;
5098
5099                --  That lower bound is *just* outside the range of 32 bits, and
5100                --  does need fudging down in this case. Note that the bounds
5101                --  will always have crossed here, since the high bound will be
5102                --  fudged down if necessary, as in the case of:
5103
5104                --    type t is delta 2.0**(-14)
5105                --      range 131072.0 .. 131072.0;
5106
5107                --  So we detect the situation by looking for crossed bounds,
5108                --  and if the bounds are crossed, and the low bound is greater
5109                --  than zero, we will always back it off by small, since this
5110                --  is completely harmless.
5111
5112                if Actual_Lo > Actual_Hi then
5113                   if UR_Is_Positive (Actual_Lo) then
5114                      Actual_Lo   := Loval_Incl_EP - Small;
5115                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5116
5117                   --  And of course, we need to do exactly the same parallel
5118                   --  fudge for flat ranges in the negative region.
5119
5120                   elsif UR_Is_Negative (Actual_Hi) then
5121                      Actual_Hi := Hival_Incl_EP + Small;
5122                      Actual_Size := Fsize (Actual_Lo, Actual_Hi);
5123                   end if;
5124                end if;
5125             end if;
5126
5127             Set_Realval (Lo, Actual_Lo);
5128             Set_Realval (Hi, Actual_Hi);
5129          end Fudge;
5130
5131       --  For the decimal case, none of this fudging is required, since there
5132       --  are no end-point problems in the decimal case (the end-points are
5133       --  always included).
5134
5135       else
5136          Actual_Size := Fsize (Loval, Hival);
5137       end if;
5138
5139       --  At this stage, the actual size has been calculated and the proper
5140       --  required bounds are stored in the low and high bounds.
5141
5142       if Actual_Size > 64 then
5143          Error_Msg_Uint_1 := UI_From_Int (Actual_Size);
5144          Error_Msg_N
5145            ("size required (^) for type& too large, maximum allowed is 64",
5146             Typ);
5147          Actual_Size := 64;
5148       end if;
5149
5150       --  Check size against explicit given size
5151
5152       if Has_Size_Clause (Typ) then
5153          if Actual_Size > RM_Size (Typ) then
5154             Error_Msg_Uint_1 := RM_Size (Typ);
5155             Error_Msg_Uint_2 := UI_From_Int (Actual_Size);
5156             Error_Msg_NE
5157               ("size given (^) for type& too small, minimum allowed is ^",
5158                Size_Clause (Typ), Typ);
5159
5160          else
5161             Actual_Size := UI_To_Int (Esize (Typ));
5162          end if;
5163
5164       --  Increase size to next natural boundary if no size clause given
5165
5166       else
5167          if Actual_Size <= 8 then
5168             Actual_Size := 8;
5169          elsif Actual_Size <= 16 then
5170             Actual_Size := 16;
5171          elsif Actual_Size <= 32 then
5172             Actual_Size := 32;
5173          else
5174             Actual_Size := 64;
5175          end if;
5176
5177          Init_Esize (Typ, Actual_Size);
5178          Adjust_Esize_For_Alignment (Typ);
5179       end if;
5180
5181       --  If we have a base type, then expand the bounds so that they extend to
5182       --  the full width of the allocated size in bits, to avoid junk range
5183       --  checks on intermediate computations.
5184
5185       if Base_Type (Typ) = Typ then
5186          Set_Realval (Lo, -(Small * (Uint_2 ** (Actual_Size - 1))));
5187          Set_Realval (Hi,  (Small * (Uint_2 ** (Actual_Size - 1) - 1)));
5188       end if;
5189
5190       --  Final step is to reanalyze the bounds using the proper type
5191       --  and set the Corresponding_Integer_Value fields of the literals.
5192
5193       Set_Etype (Lo, Empty);
5194       Set_Analyzed (Lo, False);
5195       Analyze (Lo);
5196
5197       --  Resolve with universal fixed if the base type, and the base type if
5198       --  it is a subtype. Note we can't resolve the base type with itself,
5199       --  that would be a reference before definition.
5200
5201       if Typ = Btyp then
5202          Resolve (Lo, Universal_Fixed);
5203       else
5204          Resolve (Lo, Btyp);
5205       end if;
5206
5207       --  Set corresponding integer value for bound
5208
5209       Set_Corresponding_Integer_Value
5210         (Lo, UR_To_Uint (Realval (Lo) / Small));
5211
5212       --  Similar processing for high bound
5213
5214       Set_Etype (Hi, Empty);
5215       Set_Analyzed (Hi, False);
5216       Analyze (Hi);
5217
5218       if Typ = Btyp then
5219          Resolve (Hi, Universal_Fixed);
5220       else
5221          Resolve (Hi, Btyp);
5222       end if;
5223
5224       Set_Corresponding_Integer_Value
5225         (Hi, UR_To_Uint (Realval (Hi) / Small));
5226
5227       --  Set type of range to correspond to bounds
5228
5229       Set_Etype (Rng, Etype (Lo));
5230
5231       --  Set Esize to calculated size if not set already
5232
5233       if Unknown_Esize (Typ) then
5234          Init_Esize (Typ, Actual_Size);
5235       end if;
5236
5237       --  Set RM_Size if not already set. If already set, check value
5238
5239       declare
5240          Minsiz : constant Uint := UI_From_Int (Minimum_Size (Typ));
5241
5242       begin
5243          if RM_Size (Typ) /= Uint_0 then
5244             if RM_Size (Typ) < Minsiz then
5245                Error_Msg_Uint_1 := RM_Size (Typ);
5246                Error_Msg_Uint_2 := Minsiz;
5247                Error_Msg_NE
5248                  ("size given (^) for type& too small, minimum allowed is ^",
5249                   Size_Clause (Typ), Typ);
5250             end if;
5251
5252          else
5253             Set_RM_Size (Typ, Minsiz);
5254          end if;
5255       end;
5256    end Freeze_Fixed_Point_Type;
5257
5258    ------------------
5259    -- Freeze_Itype --
5260    ------------------
5261
5262    procedure Freeze_Itype (T : Entity_Id; N : Node_Id) is
5263       L : List_Id;
5264
5265    begin
5266       Set_Has_Delayed_Freeze (T);
5267       L := Freeze_Entity (T, N);
5268
5269       if Is_Non_Empty_List (L) then
5270          Insert_Actions (N, L);
5271       end if;
5272    end Freeze_Itype;
5273
5274    --------------------------
5275    -- Freeze_Static_Object --
5276    --------------------------
5277
5278    procedure Freeze_Static_Object (E : Entity_Id) is
5279
5280       Cannot_Be_Static : exception;
5281       --  Exception raised if the type of a static object cannot be made
5282       --  static. This happens if the type depends on non-global objects.
5283
5284       procedure Ensure_Expression_Is_SA (N : Node_Id);
5285       --  Called to ensure that an expression used as part of a type definition
5286       --  is statically allocatable, which means that the expression type is
5287       --  statically allocatable, and the expression is either static, or a
5288       --  reference to a library level constant.
5289
5290       procedure Ensure_Type_Is_SA (Typ : Entity_Id);
5291       --  Called to mark a type as static, checking that it is possible
5292       --  to set the type as static. If it is not possible, then the
5293       --  exception Cannot_Be_Static is raised.
5294
5295       -----------------------------
5296       -- Ensure_Expression_Is_SA --
5297       -----------------------------
5298
5299       procedure Ensure_Expression_Is_SA (N : Node_Id) is
5300          Ent : Entity_Id;
5301
5302       begin
5303          Ensure_Type_Is_SA (Etype (N));
5304
5305          if Is_Static_Expression (N) then
5306             return;
5307
5308          elsif Nkind (N) = N_Identifier then
5309             Ent := Entity (N);
5310
5311             if Present (Ent)
5312               and then Ekind (Ent) = E_Constant
5313               and then Is_Library_Level_Entity (Ent)
5314             then
5315                return;
5316             end if;
5317          end if;
5318
5319          raise Cannot_Be_Static;
5320       end Ensure_Expression_Is_SA;
5321
5322       -----------------------
5323       -- Ensure_Type_Is_SA --
5324       -----------------------
5325
5326       procedure Ensure_Type_Is_SA (Typ : Entity_Id) is
5327          N : Node_Id;
5328          C : Entity_Id;
5329
5330       begin
5331          --  If type is library level, we are all set
5332
5333          if Is_Library_Level_Entity (Typ) then
5334             return;
5335          end if;
5336
5337          --  We are also OK if the type already marked as statically allocated,
5338          --  which means we processed it before.
5339
5340          if Is_Statically_Allocated (Typ) then
5341             return;
5342          end if;
5343
5344          --  Mark type as statically allocated
5345
5346          Set_Is_Statically_Allocated (Typ);
5347
5348          --  Check that it is safe to statically allocate this type
5349
5350          if Is_Scalar_Type (Typ) or else Is_Real_Type (Typ) then
5351             Ensure_Expression_Is_SA (Type_Low_Bound (Typ));
5352             Ensure_Expression_Is_SA (Type_High_Bound (Typ));
5353
5354          elsif Is_Array_Type (Typ) then
5355             N := First_Index (Typ);
5356             while Present (N) loop
5357                Ensure_Type_Is_SA (Etype (N));
5358                Next_Index (N);
5359             end loop;
5360
5361             Ensure_Type_Is_SA (Component_Type (Typ));
5362
5363          elsif Is_Access_Type (Typ) then
5364             if Ekind (Designated_Type (Typ)) = E_Subprogram_Type then
5365
5366                declare
5367                   F : Entity_Id;
5368                   T : constant Entity_Id := Etype (Designated_Type (Typ));
5369
5370                begin
5371                   if T /= Standard_Void_Type then
5372                      Ensure_Type_Is_SA (T);
5373                   end if;
5374
5375                   F := First_Formal (Designated_Type (Typ));
5376                   while Present (F) loop
5377                      Ensure_Type_Is_SA (Etype (F));
5378                      Next_Formal (F);
5379                   end loop;
5380                end;
5381
5382             else
5383                Ensure_Type_Is_SA (Designated_Type (Typ));
5384             end if;
5385
5386          elsif Is_Record_Type (Typ) then
5387             C := First_Entity (Typ);
5388             while Present (C) loop
5389                if Ekind (C) = E_Discriminant
5390                  or else Ekind (C) = E_Component
5391                then
5392                   Ensure_Type_Is_SA (Etype (C));
5393
5394                elsif Is_Type (C) then
5395                   Ensure_Type_Is_SA (C);
5396                end if;
5397
5398                Next_Entity (C);
5399             end loop;
5400
5401          elsif Ekind (Typ) = E_Subprogram_Type then
5402             Ensure_Type_Is_SA (Etype (Typ));
5403
5404             C := First_Formal (Typ);
5405             while Present (C) loop
5406                Ensure_Type_Is_SA (Etype (C));
5407                Next_Formal (C);
5408             end loop;
5409
5410          else
5411             raise Cannot_Be_Static;
5412          end if;
5413       end Ensure_Type_Is_SA;
5414
5415    --  Start of processing for Freeze_Static_Object
5416
5417    begin
5418       Ensure_Type_Is_SA (Etype (E));
5419
5420    exception
5421       when Cannot_Be_Static =>
5422
5423          --  If the object that cannot be static is imported or exported, then
5424          --  issue an error message saying that this object cannot be imported
5425          --  or exported. If it has an address clause it is an overlay in the
5426          --  current partition and the static requirement is not relevant.
5427          --  Do not issue any error message when ignoring rep clauses.
5428
5429          if Ignore_Rep_Clauses then
5430             null;
5431
5432          elsif Is_Imported (E) then
5433             if No (Address_Clause (E)) then
5434                Error_Msg_N
5435                  ("& cannot be imported (local type is not constant)", E);
5436             end if;
5437
5438          --  Otherwise must be exported, something is wrong if compiler
5439          --  is marking something as statically allocated which cannot be).
5440
5441          else pragma Assert (Is_Exported (E));
5442             Error_Msg_N
5443               ("& cannot be exported (local type is not constant)", E);
5444          end if;
5445    end Freeze_Static_Object;
5446
5447    -----------------------
5448    -- Freeze_Subprogram --
5449    -----------------------
5450
5451    procedure Freeze_Subprogram (E : Entity_Id) is
5452       Retype : Entity_Id;
5453       F      : Entity_Id;
5454
5455    begin
5456       --  Subprogram may not have an address clause unless it is imported
5457
5458       if Present (Address_Clause (E)) then
5459          if not Is_Imported (E) then
5460             Error_Msg_N
5461               ("address clause can only be given " &
5462                "for imported subprogram",
5463                Name (Address_Clause (E)));
5464          end if;
5465       end if;
5466
5467       --  Reset the Pure indication on an imported subprogram unless an
5468       --  explicit Pure_Function pragma was present. We do this because
5469       --  otherwise it is an insidious error to call a non-pure function from
5470       --  pure unit and have calls mysteriously optimized away. What happens
5471       --  here is that the Import can bypass the normal check to ensure that
5472       --  pure units call only pure subprograms.
5473
5474       if Is_Imported (E)
5475         and then Is_Pure (E)
5476         and then not Has_Pragma_Pure_Function (E)
5477       then
5478          Set_Is_Pure (E, False);
5479       end if;
5480
5481       --  For non-foreign convention subprograms, this is where we create
5482       --  the extra formals (for accessibility level and constrained bit
5483       --  information). We delay this till the freeze point precisely so
5484       --  that we know the convention!
5485
5486       if not Has_Foreign_Convention (E) then
5487          Create_Extra_Formals (E);
5488          Set_Mechanisms (E);
5489
5490          --  If this is convention Ada and a Valued_Procedure, that's odd
5491
5492          if Ekind (E) = E_Procedure
5493            and then Is_Valued_Procedure (E)
5494            and then Convention (E) = Convention_Ada
5495            and then Warn_On_Export_Import
5496          then
5497             Error_Msg_N
5498               ("?Valued_Procedure has no effect for convention Ada", E);
5499             Set_Is_Valued_Procedure (E, False);
5500          end if;
5501
5502       --  Case of foreign convention
5503
5504       else
5505          Set_Mechanisms (E);
5506
5507          --  For foreign conventions, warn about return of an
5508          --  unconstrained array.
5509
5510          --  Note: we *do* allow a return by descriptor for the VMS case,
5511          --  though here there is probably more to be done ???
5512
5513          if Ekind (E) = E_Function then
5514             Retype := Underlying_Type (Etype (E));
5515
5516             --  If no return type, probably some other error, e.g. a
5517             --  missing full declaration, so ignore.
5518
5519             if No (Retype) then
5520                null;
5521
5522             --  If the return type is generic, we have emitted a warning
5523             --  earlier on, and there is nothing else to check here. Specific
5524             --  instantiations may lead to erroneous behavior.
5525
5526             elsif Is_Generic_Type (Etype (E)) then
5527                null;
5528
5529             --  Display warning if returning unconstrained array
5530
5531             elsif Is_Array_Type (Retype)
5532               and then not Is_Constrained (Retype)
5533
5534               --  Exclude cases where descriptor mechanism is set, since the
5535               --  VMS descriptor mechanisms allow such unconstrained returns.
5536
5537               and then Mechanism (E) not in Descriptor_Codes
5538
5539                --  Check appropriate warning is enabled (should we check for
5540                --  Warnings (Off) on specific entities here, probably so???)
5541
5542               and then Warn_On_Export_Import
5543
5544               --  Exclude the VM case, since return of unconstrained arrays
5545               --  is properly handled in both the JVM and .NET cases.
5546
5547               and then VM_Target = No_VM
5548             then
5549                Error_Msg_N
5550                 ("?foreign convention function& should not return " &
5551                   "unconstrained array", E);
5552                return;
5553             end if;
5554          end if;
5555
5556          --  If any of the formals for an exported foreign convention
5557          --  subprogram have defaults, then emit an appropriate warning since
5558          --  this is odd (default cannot be used from non-Ada code)
5559
5560          if Is_Exported (E) then
5561             F := First_Formal (E);
5562             while Present (F) loop
5563                if Warn_On_Export_Import
5564                  and then Present (Default_Value (F))
5565                then
5566                   Error_Msg_N
5567                     ("?parameter cannot be defaulted in non-Ada call",
5568                      Default_Value (F));
5569                end if;
5570
5571                Next_Formal (F);
5572             end loop;
5573          end if;
5574       end if;
5575
5576       --  For VMS, descriptor mechanisms for parameters are allowed only for
5577       --  imported/exported subprograms. Moreover, the NCA descriptor is not
5578       --  allowed for parameters of exported subprograms.
5579
5580       if OpenVMS_On_Target then
5581          if Is_Exported (E) then
5582             F := First_Formal (E);
5583             while Present (F) loop
5584                if Mechanism (F) = By_Descriptor_NCA then
5585                   Error_Msg_N
5586                     ("'N'C'A' descriptor for parameter not permitted", F);
5587                   Error_Msg_N
5588                     ("\can only be used for imported subprogram", F);
5589                end if;
5590
5591                Next_Formal (F);
5592             end loop;
5593
5594          elsif not Is_Imported (E) then
5595             F := First_Formal (E);
5596             while Present (F) loop
5597                if Mechanism (F) in Descriptor_Codes then
5598                   Error_Msg_N
5599                     ("descriptor mechanism for parameter not permitted", F);
5600                   Error_Msg_N
5601                     ("\can only be used for imported/exported subprogram", F);
5602                end if;
5603
5604                Next_Formal (F);
5605             end loop;
5606          end if;
5607       end if;
5608
5609       --  Pragma Inline_Always is disallowed for dispatching subprograms
5610       --  because the address of such subprograms is saved in the dispatch
5611       --  table to support dispatching calls, and dispatching calls cannot
5612       --  be inlined. This is consistent with the restriction against using
5613       --  'Access or 'Address on an Inline_Always subprogram.
5614
5615       if Is_Dispatching_Operation (E)
5616         and then Has_Pragma_Inline_Always (E)
5617       then
5618          Error_Msg_N
5619            ("pragma Inline_Always not allowed for dispatching subprograms", E);
5620       end if;
5621
5622       --  Because of the implicit representation of inherited predefined
5623       --  operators in the front-end, the overriding status of the operation
5624       --  may be affected when a full view of a type is analyzed, and this is
5625       --  not captured by the analysis of the corresponding type declaration.
5626       --  Therefore the correctness of a not-overriding indicator must be
5627       --  rechecked when the subprogram is frozen.
5628
5629       if Nkind (E) = N_Defining_Operator_Symbol
5630         and then not Error_Posted (Parent (E))
5631       then
5632          Check_Overriding_Indicator (E, Empty, Is_Primitive (E));
5633       end if;
5634    end Freeze_Subprogram;
5635
5636    ----------------------
5637    -- Is_Fully_Defined --
5638    ----------------------
5639
5640    function Is_Fully_Defined (T : Entity_Id) return Boolean is
5641    begin
5642       if Ekind (T) = E_Class_Wide_Type then
5643          return Is_Fully_Defined (Etype (T));
5644
5645       elsif Is_Array_Type (T) then
5646          return Is_Fully_Defined (Component_Type (T));
5647
5648       elsif Is_Record_Type (T)
5649         and not Is_Private_Type (T)
5650       then
5651          --  Verify that the record type has no components with private types
5652          --  without completion.
5653
5654          declare
5655             Comp : Entity_Id;
5656
5657          begin
5658             Comp := First_Component (T);
5659             while Present (Comp) loop
5660                if not Is_Fully_Defined (Etype (Comp)) then
5661                   return False;
5662                end if;
5663
5664                Next_Component (Comp);
5665             end loop;
5666             return True;
5667          end;
5668
5669       --  For the designated type of an access to subprogram, all types in
5670       --  the profile must be fully defined.
5671
5672       elsif Ekind (T) = E_Subprogram_Type then
5673          declare
5674             F : Entity_Id;
5675
5676          begin
5677             F := First_Formal (T);
5678             while Present (F) loop
5679                if not Is_Fully_Defined (Etype (F)) then
5680                   return False;
5681                end if;
5682
5683                Next_Formal (F);
5684             end loop;
5685
5686             return Is_Fully_Defined (Etype (T));
5687          end;
5688
5689       else
5690          return not Is_Private_Type (T)
5691            or else Present (Full_View (Base_Type (T)));
5692       end if;
5693    end Is_Fully_Defined;
5694
5695    ---------------------------------
5696    -- Process_Default_Expressions --
5697    ---------------------------------
5698
5699    procedure Process_Default_Expressions
5700      (E     : Entity_Id;
5701       After : in out Node_Id)
5702    is
5703       Loc    : constant Source_Ptr := Sloc (E);
5704       Dbody  : Node_Id;
5705       Formal : Node_Id;
5706       Dcopy  : Node_Id;
5707       Dnam   : Entity_Id;
5708
5709    begin
5710       Set_Default_Expressions_Processed (E);
5711
5712       --  A subprogram instance and its associated anonymous subprogram share
5713       --  their signature. The default expression functions are defined in the
5714       --  wrapper packages for the anonymous subprogram, and should not be
5715       --  generated again for the instance.
5716
5717       if Is_Generic_Instance (E)
5718         and then Present (Alias (E))
5719         and then Default_Expressions_Processed (Alias (E))
5720       then
5721          return;
5722       end if;
5723
5724       Formal := First_Formal (E);
5725       while Present (Formal) loop
5726          if Present (Default_Value (Formal)) then
5727
5728             --  We work with a copy of the default expression because we
5729             --  do not want to disturb the original, since this would mess
5730             --  up the conformance checking.
5731
5732             Dcopy := New_Copy_Tree (Default_Value (Formal));
5733
5734             --  The analysis of the expression may generate insert actions,
5735             --  which of course must not be executed. We wrap those actions
5736             --  in a procedure that is not called, and later on eliminated.
5737             --  The following cases have no side-effects, and are analyzed
5738             --  directly.
5739
5740             if Nkind (Dcopy) = N_Identifier
5741               or else Nkind (Dcopy) = N_Expanded_Name
5742               or else Nkind (Dcopy) = N_Integer_Literal
5743               or else (Nkind (Dcopy) = N_Real_Literal
5744                         and then not Vax_Float (Etype (Dcopy)))
5745               or else Nkind (Dcopy) = N_Character_Literal
5746               or else Nkind (Dcopy) = N_String_Literal
5747               or else Known_Null (Dcopy)
5748               or else (Nkind (Dcopy) = N_Attribute_Reference
5749                         and then
5750                        Attribute_Name (Dcopy) = Name_Null_Parameter)
5751             then
5752
5753                --  If there is no default function, we must still do a full
5754                --  analyze call on the default value, to ensure that all error
5755                --  checks are performed, e.g. those associated with static
5756                --  evaluation. Note: this branch will always be taken if the
5757                --  analyzer is turned off (but we still need the error checks).
5758
5759                --  Note: the setting of parent here is to meet the requirement
5760                --  that we can only analyze the expression while attached to
5761                --  the tree. Really the requirement is that the parent chain
5762                --  be set, we don't actually need to be in the tree.
5763
5764                Set_Parent (Dcopy, Declaration_Node (Formal));
5765                Analyze (Dcopy);
5766
5767                --  Default expressions are resolved with their own type if the
5768                --  context is generic, to avoid anomalies with private types.
5769
5770                if Ekind (Scope (E)) = E_Generic_Package then
5771                   Resolve (Dcopy);
5772                else
5773                   Resolve (Dcopy, Etype (Formal));
5774                end if;
5775
5776                --  If that resolved expression will raise constraint error,
5777                --  then flag the default value as raising constraint error.
5778                --  This allows a proper error message on the calls.
5779
5780                if Raises_Constraint_Error (Dcopy) then
5781                   Set_Raises_Constraint_Error (Default_Value (Formal));
5782                end if;
5783
5784             --  If the default is a parameterless call, we use the name of
5785             --  the called function directly, and there is no body to build.
5786
5787             elsif Nkind (Dcopy) = N_Function_Call
5788               and then No (Parameter_Associations (Dcopy))
5789             then
5790                null;
5791
5792             --  Else construct and analyze the body of a wrapper procedure
5793             --  that contains an object declaration to hold the expression.
5794             --  Given that this is done only to complete the analysis, it
5795             --  simpler to build a procedure than a function which might
5796             --  involve secondary stack expansion.
5797
5798             else
5799                Dnam := Make_Temporary (Loc, 'D');
5800
5801                Dbody :=
5802                  Make_Subprogram_Body (Loc,
5803                    Specification =>
5804                      Make_Procedure_Specification (Loc,
5805                        Defining_Unit_Name => Dnam),
5806
5807                    Declarations => New_List (
5808                      Make_Object_Declaration (Loc,
5809                        Defining_Identifier => Make_Temporary (Loc, 'T'),
5810                        Object_Definition   =>
5811                          New_Occurrence_Of (Etype (Formal), Loc),
5812                        Expression          => New_Copy_Tree (Dcopy))),
5813
5814                    Handled_Statement_Sequence =>
5815                      Make_Handled_Sequence_Of_Statements (Loc,
5816                        Statements => Empty_List));
5817
5818                Set_Scope (Dnam, Scope (E));
5819                Set_Assignment_OK (First (Declarations (Dbody)));
5820                Set_Is_Eliminated (Dnam);
5821                Insert_After (After, Dbody);
5822                Analyze (Dbody);
5823                After := Dbody;
5824             end if;
5825          end if;
5826
5827          Next_Formal (Formal);
5828       end loop;
5829    end Process_Default_Expressions;
5830
5831    ----------------------------------------
5832    -- Set_Component_Alignment_If_Not_Set --
5833    ----------------------------------------
5834
5835    procedure Set_Component_Alignment_If_Not_Set (Typ : Entity_Id) is
5836    begin
5837       --  Ignore if not base type, subtypes don't need anything
5838
5839       if Typ /= Base_Type (Typ) then
5840          return;
5841       end if;
5842
5843       --  Do not override existing representation
5844
5845       if Is_Packed (Typ) then
5846          return;
5847
5848       elsif Has_Specified_Layout (Typ) then
5849          return;
5850
5851       elsif Component_Alignment (Typ) /= Calign_Default then
5852          return;
5853
5854       else
5855          Set_Component_Alignment
5856            (Typ, Scope_Stack.Table
5857                   (Scope_Stack.Last).Component_Alignment_Default);
5858       end if;
5859    end Set_Component_Alignment_If_Not_Set;
5860
5861    ------------------
5862    -- Undelay_Type --
5863    ------------------
5864
5865    procedure Undelay_Type (T : Entity_Id) is
5866    begin
5867       Set_Has_Delayed_Freeze (T, False);
5868       Set_Freeze_Node (T, Empty);
5869
5870       --  Since we don't want T to have a Freeze_Node, we don't want its
5871       --  Full_View or Corresponding_Record_Type to have one either.
5872
5873       --  ??? Fundamentally, this whole handling is a kludge. What we really
5874       --  want is to be sure that for an Itype that's part of record R and is a
5875       --  subtype of type T, that it's frozen after the later of the freeze
5876       --  points of R and T. We have no way of doing that directly, so what we
5877       --  do is force most such Itypes to be frozen as part of freezing R via
5878       --  this procedure and only delay the ones that need to be delayed
5879       --  (mostly the designated types of access types that are defined as part
5880       --  of the record).
5881
5882       if Is_Private_Type (T)
5883         and then Present (Full_View (T))
5884         and then Is_Itype (Full_View (T))
5885         and then Is_Record_Type (Scope (Full_View (T)))
5886       then
5887          Undelay_Type (Full_View (T));
5888       end if;
5889
5890       if Is_Concurrent_Type (T)
5891         and then Present (Corresponding_Record_Type (T))
5892         and then Is_Itype (Corresponding_Record_Type (T))
5893         and then Is_Record_Type (Scope (Corresponding_Record_Type (T)))
5894       then
5895          Undelay_Type (Corresponding_Record_Type (T));
5896       end if;
5897    end Undelay_Type;
5898
5899    ------------------
5900    -- Warn_Overlay --
5901    ------------------
5902
5903    procedure Warn_Overlay
5904      (Expr : Node_Id;
5905       Typ  : Entity_Id;
5906       Nam  : Entity_Id)
5907    is
5908       Ent : constant Entity_Id := Entity (Nam);
5909       --  The object to which the address clause applies
5910
5911       Init : Node_Id;
5912       Old  : Entity_Id := Empty;
5913       Decl : Node_Id;
5914
5915    begin
5916       --  No warning if address clause overlay warnings are off
5917
5918       if not Address_Clause_Overlay_Warnings then
5919          return;
5920       end if;
5921
5922       --  No warning if there is an explicit initialization
5923
5924       Init := Original_Node (Expression (Declaration_Node (Ent)));
5925
5926       if Present (Init) and then Comes_From_Source (Init) then
5927          return;
5928       end if;
5929
5930       --  We only give the warning for non-imported entities of a type for
5931       --  which a non-null base init proc is defined, or for objects of access
5932       --  types with implicit null initialization, or when Normalize_Scalars
5933       --  applies and the type is scalar or a string type (the latter being
5934       --  tested for because predefined String types are initialized by inline
5935       --  code rather than by an init_proc). Note that we do not give the
5936       --  warning for Initialize_Scalars, since we suppressed initialization
5937       --  in this case. Also, do not warn if Suppress_Initialization is set.
5938
5939       if Present (Expr)
5940         and then not Is_Imported (Ent)
5941         and then not Initialization_Suppressed (Typ)
5942         and then (Has_Non_Null_Base_Init_Proc (Typ)
5943                    or else Is_Access_Type (Typ)
5944                    or else (Normalize_Scalars
5945                              and then (Is_Scalar_Type (Typ)
5946                                         or else Is_String_Type (Typ))))
5947       then
5948          if Nkind (Expr) = N_Attribute_Reference
5949            and then Is_Entity_Name (Prefix (Expr))
5950          then
5951             Old := Entity (Prefix (Expr));
5952
5953          elsif Is_Entity_Name (Expr)
5954            and then Ekind (Entity (Expr)) = E_Constant
5955          then
5956             Decl := Declaration_Node (Entity (Expr));
5957
5958             if Nkind (Decl) = N_Object_Declaration
5959               and then Present (Expression (Decl))
5960               and then Nkind (Expression (Decl)) = N_Attribute_Reference
5961               and then Is_Entity_Name (Prefix (Expression (Decl)))
5962             then
5963                Old := Entity (Prefix (Expression (Decl)));
5964
5965             elsif Nkind (Expr) = N_Function_Call then
5966                return;
5967             end if;
5968
5969          --  A function call (most likely to To_Address) is probably not an
5970          --  overlay, so skip warning. Ditto if the function call was inlined
5971          --  and transformed into an entity.
5972
5973          elsif Nkind (Original_Node (Expr)) = N_Function_Call then
5974             return;
5975          end if;
5976
5977          Decl := Next (Parent (Expr));
5978
5979          --  If a pragma Import follows, we assume that it is for the current
5980          --  target of the address clause, and skip the warning.
5981
5982          if Present (Decl)
5983            and then Nkind (Decl) = N_Pragma
5984            and then Pragma_Name (Decl) = Name_Import
5985          then
5986             return;
5987          end if;
5988
5989          if Present (Old) then
5990             Error_Msg_Node_2 := Old;
5991             Error_Msg_N
5992               ("default initialization of & may modify &?",
5993                Nam);
5994          else
5995             Error_Msg_N
5996               ("default initialization of & may modify overlaid storage?",
5997                Nam);
5998          end if;
5999
6000          --  Add friendly warning if initialization comes from a packed array
6001          --  component.
6002
6003          if Is_Record_Type (Typ)  then
6004             declare
6005                Comp : Entity_Id;
6006
6007             begin
6008                Comp := First_Component (Typ);
6009                while Present (Comp) loop
6010                   if Nkind (Parent (Comp)) = N_Component_Declaration
6011                     and then Present (Expression (Parent (Comp)))
6012                   then
6013                      exit;
6014                   elsif Is_Array_Type (Etype (Comp))
6015                      and then Present (Packed_Array_Type (Etype (Comp)))
6016                   then
6017                      Error_Msg_NE
6018                        ("\packed array component& " &
6019                         "will be initialized to zero?",
6020                         Nam, Comp);
6021                      exit;
6022                   else
6023                      Next_Component (Comp);
6024                   end if;
6025                end loop;
6026             end;
6027          end if;
6028
6029          Error_Msg_N
6030            ("\use pragma Import for & to " &
6031             "suppress initialization (RM B.1(24))?",
6032             Nam);
6033       end if;
6034    end Warn_Overlay;
6035
6036 end Freeze;