gcc/ada/exp_ch4.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              E X P _ C H 4                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Debug;    use Debug;
  29 with Einfo;    use Einfo;
  30 with Elists;   use Elists;
  31 with Errout;   use Errout;
  32 with Exp_Aggr; use Exp_Aggr;
  33 with Exp_Atag; use Exp_Atag;
  34 with Exp_Ch2;  use Exp_Ch2;
  35 with Exp_Ch3;  use Exp_Ch3;
  36 with Exp_Ch6;  use Exp_Ch6;
  37 with Exp_Ch7;  use Exp_Ch7;
  38 with Exp_Ch9;  use Exp_Ch9;
  39 with Exp_Disp; use Exp_Disp;
  40 with Exp_Fixd; use Exp_Fixd;
  41 with Exp_Intr; use Exp_Intr;
  42 with Exp_Pakd; use Exp_Pakd;
  43 with Exp_Tss;  use Exp_Tss;
  44 with Exp_Util; use Exp_Util;
  45 with Exp_VFpt; use Exp_VFpt;
  46 with Freeze;   use Freeze;
  47 with Inline;   use Inline;
  48 with Lib;      use Lib;
  49 with Namet;    use Namet;
  50 with Nlists;   use Nlists;
  51 with Nmake;    use Nmake;
  52 with Opt;      use Opt;
  53 with Par_SCO;  use Par_SCO;
  54 with Restrict; use Restrict;
  55 with Rident;   use Rident;
  56 with Rtsfind;  use Rtsfind;
  57 with Sem;      use Sem;
  58 with Sem_Aux;  use Sem_Aux;
  59 with Sem_Cat;  use Sem_Cat;
  60 with Sem_Ch3;  use Sem_Ch3;
  61 with Sem_Ch8;  use Sem_Ch8;
  62 with Sem_Ch13; use Sem_Ch13;
  63 with Sem_Eval; use Sem_Eval;
  64 with Sem_Res;  use Sem_Res;
  65 with Sem_Type; use Sem_Type;
  66 with Sem_Util; use Sem_Util;
  67 with Sem_Warn; use Sem_Warn;
  68 with Sinfo;    use Sinfo;
  69 with Snames;   use Snames;
  70 with Stand;    use Stand;
  71 with SCIL_LL;  use SCIL_LL;
  72 with Targparm; use Targparm;
  73 with Tbuild;   use Tbuild;
  74 with Ttypes;   use Ttypes;
  75 with Uintp;    use Uintp;
  76 with Urealp;   use Urealp;
  77 with Validsw;  use Validsw;
  78
  79 package body Exp_Ch4 is
  80
  81    -----------------------
  82    -- Local Subprograms --
  83    -----------------------
  84
  85    procedure Binary_Op_Validity_Checks (N : Node_Id);
  86    pragma Inline (Binary_Op_Validity_Checks);
  87    --  Performs validity checks for a binary operator
  88
  89    procedure Build_Boolean_Array_Proc_Call
  90      (N   : Node_Id;
  91       Op1 : Node_Id;
  92       Op2 : Node_Id);
  93    --  If a boolean array assignment can be done in place, build call to
  94    --  corresponding library procedure.
  95
  96    function Current_Anonymous_Master return Entity_Id;
  97    --  Return the entity of the heterogeneous finalization master belonging to
  98    --  the current unit (either function, package or procedure). This master
  99    --  services all anonymous access-to-controlled types. If the current unit
 100    --  does not have such master, create one.
 101
 102    procedure Displace_Allocator_Pointer (N : Node_Id);
 103    --  Ada 2005 (AI-251): Subsidiary procedure to Expand_N_Allocator and
 104    --  Expand_Allocator_Expression. Allocating class-wide interface objects
 105    --  this routine displaces the pointer to the allocated object to reference
 106    --  the component referencing the corresponding secondary dispatch table.
 107
 108    procedure Expand_Allocator_Expression (N : Node_Id);
 109    --  Subsidiary to Expand_N_Allocator, for the case when the expression
 110    --  is a qualified expression or an aggregate.
 111
 112    procedure Expand_Array_Comparison (N : Node_Id);
 113    --  This routine handles expansion of the comparison operators (N_Op_Lt,
 114    --  N_Op_Le, N_Op_Gt, N_Op_Ge) when operating on an array type. The basic
 115    --  code for these operators is similar, differing only in the details of
 116    --  the actual comparison call that is made. Special processing (call a
 117    --  run-time routine)
 118
 119    function Expand_Array_Equality
 120      (Nod    : Node_Id;
 121       Lhs    : Node_Id;
 122       Rhs    : Node_Id;
 123       Bodies : List_Id;
 124       Typ    : Entity_Id) return Node_Id;
 125    --  Expand an array equality into a call to a function implementing this
 126    --  equality, and a call to it. Loc is the location for the generated nodes.
 127    --  Lhs and Rhs are the array expressions to be compared. Bodies is a list
 128    --  on which to attach bodies of local functions that are created in the
 129    --  process. It is the responsibility of the caller to insert those bodies
 130    --  at the right place. Nod provides the Sloc value for the generated code.
 131    --  Normally the types used for the generated equality routine are taken
 132    --  from Lhs and Rhs. However, in some situations of generated code, the
 133    --  Etype fields of Lhs and Rhs are not set yet. In such cases, Typ supplies
 134    --  the type to be used for the formal parameters.
 135
 136    procedure Expand_Boolean_Operator (N : Node_Id);
 137    --  Common expansion processing for Boolean operators (And, Or, Xor) for the
 138    --  case of array type arguments.
 139
 140    procedure Expand_Short_Circuit_Operator (N : Node_Id);
 141    --  Common expansion processing for short-circuit boolean operators
 142
 143    function Expand_Composite_Equality
 144      (Nod    : Node_Id;
 145       Typ    : Entity_Id;
 146       Lhs    : Node_Id;
 147       Rhs    : Node_Id;
 148       Bodies : List_Id) return Node_Id;
 149    --  Local recursive function used to expand equality for nested composite
 150    --  types. Used by Expand_Record/Array_Equality, Bodies is a list on which
 151    --  to attach bodies of local functions that are created in the process.
 152    --  This is the responsibility of the caller to insert those bodies at the
 153    --  right place. Nod provides the Sloc value for generated code. Lhs and Rhs
 154    --  are the left and right sides for the comparison, and Typ is the type of
 155    --  the arrays to compare.
 156
 157    procedure Expand_Concatenate (Cnode : Node_Id; Opnds : List_Id);
 158    --  Routine to expand concatenation of a sequence of two or more operands
 159    --  (in the list Operands) and replace node Cnode with the result of the
 160    --  concatenation. The operands can be of any appropriate type, and can
 161    --  include both arrays and singleton elements.
 162
 163    procedure Fixup_Universal_Fixed_Operation (N : Node_Id);
 164    --  N is a N_Op_Divide or N_Op_Multiply node whose result is universal
 165    --  fixed. We do not have such a type at runtime, so the purpose of this
 166    --  routine is to find the real type by looking up the tree. We also
 167    --  determine if the operation must be rounded.
 168
 169    function Has_Inferable_Discriminants (N : Node_Id) return Boolean;
 170    --  Ada 2005 (AI-216): A view of an Unchecked_Union object has inferable
 171    --  discriminants if it has a constrained nominal type, unless the object
 172    --  is a component of an enclosing Unchecked_Union object that is subject
 173    --  to a per-object constraint and the enclosing object lacks inferable
 174    --  discriminants.
 175    --
 176    --  An expression of an Unchecked_Union type has inferable discriminants
 177    --  if it is either a name of an object with inferable discriminants or a
 178    --  qualified expression whose subtype mark denotes a constrained subtype.
 179
 180    procedure Insert_Dereference_Action (N : Node_Id);
 181    --  N is an expression whose type is an access. When the type of the
 182    --  associated storage pool is derived from Checked_Pool, generate a
 183    --  call to the 'Dereference' primitive operation.
 184
 185    function Make_Array_Comparison_Op
 186      (Typ : Entity_Id;
 187       Nod : Node_Id) return Node_Id;
 188    --  Comparisons between arrays are expanded in line. This function produces
 189    --  the body of the implementation of (a > b), where a and b are one-
 190    --  dimensional arrays of some discrete type. The original node is then
 191    --  expanded into the appropriate call to this function. Nod provides the
 192    --  Sloc value for the generated code.
 193
 194    function Make_Boolean_Array_Op
 195      (Typ : Entity_Id;
 196       N   : Node_Id) return Node_Id;
 197    --  Boolean operations on boolean arrays are expanded in line. This function
 198    --  produce the body for the node N, which is (a and b), (a or b), or (a xor
 199    --  b). It is used only the normal case and not the packed case. The type
 200    --  involved, Typ, is the Boolean array type, and the logical operations in
 201    --  the body are simple boolean operations. Note that Typ is always a
 202    --  constrained type (the caller has ensured this by using
 203    --  Convert_To_Actual_Subtype if necessary).
 204
 205    procedure Optimize_Length_Comparison (N : Node_Id);
 206    --  Given an expression, if it is of the form X'Length op N (or the other
 207    --  way round), where N is known at compile time to be 0 or 1, and X is a
 208    --  simple entity, and op is a comparison operator, optimizes it into a
 209    --  comparison of First and Last.
 210
 211    procedure Rewrite_Comparison (N : Node_Id);
 212    --  If N is the node for a comparison whose outcome can be determined at
 213    --  compile time, then the node N can be rewritten with True or False. If
 214    --  the outcome cannot be determined at compile time, the call has no
 215    --  effect. If N is a type conversion, then this processing is applied to
 216    --  its expression. If N is neither comparison nor a type conversion, the
 217    --  call has no effect.
 218
 219    procedure Tagged_Membership
 220      (N         : Node_Id;
 221       SCIL_Node : out Node_Id;
 222       Result    : out Node_Id);
 223    --  Construct the expression corresponding to the tagged membership test.
 224    --  Deals with a second operand being (or not) a class-wide type.
 225
 226    function Safe_In_Place_Array_Op
 227      (Lhs : Node_Id;
 228       Op1 : Node_Id;
 229       Op2 : Node_Id) return Boolean;
 230    --  In the context of an assignment, where the right-hand side is a boolean
 231    --  operation on arrays, check whether operation can be performed in place.
 232
 233    procedure Unary_Op_Validity_Checks (N : Node_Id);
 234    pragma Inline (Unary_Op_Validity_Checks);
 235    --  Performs validity checks for a unary operator
 236
 237    -------------------------------
 238    -- Binary_Op_Validity_Checks --
 239    -------------------------------
 240
 241    procedure Binary_Op_Validity_Checks (N : Node_Id) is
 242    begin
 243       if Validity_Checks_On and Validity_Check_Operands then
 244          Ensure_Valid (Left_Opnd (N));
 245          Ensure_Valid (Right_Opnd (N));
 246       end if;
 247    end Binary_Op_Validity_Checks;
 248
 249    ------------------------------------
 250    -- Build_Boolean_Array_Proc_Call --
 251    ------------------------------------
 252
 253    procedure Build_Boolean_Array_Proc_Call
 254      (N   : Node_Id;
 255       Op1 : Node_Id;
 256       Op2 : Node_Id)
 257    is
 258       Loc       : constant Source_Ptr := Sloc (N);
 259       Kind      : constant Node_Kind := Nkind (Expression (N));
 260       Target    : constant Node_Id   :=
 261                     Make_Attribute_Reference (Loc,
 262                       Prefix         => Name (N),
 263                       Attribute_Name => Name_Address);
 264
 265       Arg1      : Node_Id := Op1;
 266       Arg2      : Node_Id := Op2;
 267       Call_Node : Node_Id;
 268       Proc_Name : Entity_Id;
 269
 270    begin
 271       if Kind = N_Op_Not then
 272          if Nkind (Op1) in N_Binary_Op then
 273
 274             --  Use negated version of the binary operators
 275
 276             if Nkind (Op1) = N_Op_And then
 277                Proc_Name := RTE (RE_Vector_Nand);
 278
 279             elsif Nkind (Op1) = N_Op_Or then
 280                Proc_Name := RTE (RE_Vector_Nor);
 281
 282             else pragma Assert (Nkind (Op1) = N_Op_Xor);
 283                Proc_Name := RTE (RE_Vector_Xor);
 284             end if;
 285
 286             Call_Node :=
 287               Make_Procedure_Call_Statement (Loc,
 288                 Name => New_Occurrence_Of (Proc_Name, Loc),
 289
 290                 Parameter_Associations => New_List (
 291                   Target,
 292                   Make_Attribute_Reference (Loc,
 293                     Prefix => Left_Opnd (Op1),
 294                     Attribute_Name => Name_Address),
 295
 296                   Make_Attribute_Reference (Loc,
 297                     Prefix => Right_Opnd (Op1),
 298                     Attribute_Name => Name_Address),
 299
 300                   Make_Attribute_Reference (Loc,
 301                     Prefix => Left_Opnd (Op1),
 302                     Attribute_Name => Name_Length)));
 303
 304          else
 305             Proc_Name := RTE (RE_Vector_Not);
 306
 307             Call_Node :=
 308               Make_Procedure_Call_Statement (Loc,
 309                 Name => New_Occurrence_Of (Proc_Name, Loc),
 310                 Parameter_Associations => New_List (
 311                   Target,
 312
 313                   Make_Attribute_Reference (Loc,
 314                     Prefix => Op1,
 315                     Attribute_Name => Name_Address),
 316
 317                   Make_Attribute_Reference (Loc,
 318                     Prefix => Op1,
 319                      Attribute_Name => Name_Length)));
 320          end if;
 321
 322       else
 323          --  We use the following equivalences:
 324
 325          --   (not X) or  (not Y)  =  not (X and Y)  =  Nand (X, Y)
 326          --   (not X) and (not Y)  =  not (X or Y)   =  Nor  (X, Y)
 327          --   (not X) xor (not Y)  =  X xor Y
 328          --   X       xor (not Y)  =  not (X xor Y)  =  Nxor (X, Y)
 329
 330          if Nkind (Op1) = N_Op_Not then
 331             Arg1 := Right_Opnd (Op1);
 332             Arg2 := Right_Opnd (Op2);
 333             if Kind = N_Op_And then
 334                Proc_Name := RTE (RE_Vector_Nor);
 335             elsif Kind = N_Op_Or then
 336                Proc_Name := RTE (RE_Vector_Nand);
 337             else
 338                Proc_Name := RTE (RE_Vector_Xor);
 339             end if;
 340
 341          else
 342             if Kind = N_Op_And then
 343                Proc_Name := RTE (RE_Vector_And);
 344             elsif Kind = N_Op_Or then
 345                Proc_Name := RTE (RE_Vector_Or);
 346             elsif Nkind (Op2) = N_Op_Not then
 347                Proc_Name := RTE (RE_Vector_Nxor);
 348                Arg2 := Right_Opnd (Op2);
 349             else
 350                Proc_Name := RTE (RE_Vector_Xor);
 351             end if;
 352          end if;
 353
 354          Call_Node :=
 355            Make_Procedure_Call_Statement (Loc,
 356              Name => New_Occurrence_Of (Proc_Name, Loc),
 357              Parameter_Associations => New_List (
 358                Target,
 359                Make_Attribute_Reference (Loc,
 360                  Prefix         => Arg1,
 361                  Attribute_Name => Name_Address),
 362                Make_Attribute_Reference (Loc,
 363                  Prefix         => Arg2,
 364                  Attribute_Name => Name_Address),
 365                Make_Attribute_Reference (Loc,
 366                  Prefix         => Arg1,
 367                  Attribute_Name => Name_Length)));
 368       end if;
 369
 370       Rewrite (N, Call_Node);
 371       Analyze (N);
 372
 373    exception
 374       when RE_Not_Available =>
 375          return;
 376    end Build_Boolean_Array_Proc_Call;
 377
 378    ------------------------------
 379    -- Current_Anonymous_Master --
 380    ------------------------------
 381
 382    function Current_Anonymous_Master return Entity_Id is
 383       Decls     : List_Id;
 384       Loc       : Source_Ptr;
 385       Subp_Body : Node_Id;
 386       Unit_Decl : Node_Id;
 387       Unit_Id   : Entity_Id;
 388
 389    begin
 390       Unit_Id := Cunit_Entity (Current_Sem_Unit);
 391
 392       --  Find the entity of the current unit
 393
 394       if Ekind (Unit_Id) = E_Subprogram_Body then
 395
 396          --  When processing subprogram bodies, the proper scope is always that
 397          --  of the spec.
 398
 399          Subp_Body := Unit_Id;
 400          while Present (Subp_Body)
 401            and then Nkind (Subp_Body) /= N_Subprogram_Body
 402          loop
 403             Subp_Body := Parent (Subp_Body);
 404          end loop;
 405
 406          Unit_Id := Corresponding_Spec (Subp_Body);
 407       end if;
 408
 409       Loc := Sloc (Unit_Id);
 410       Unit_Decl := Unit (Cunit (Current_Sem_Unit));
 411
 412       --  Find the declarations list of the current unit
 413
 414       if Nkind (Unit_Decl) = N_Package_Declaration then
 415          Unit_Decl := Specification (Unit_Decl);
 416          Decls := Visible_Declarations (Unit_Decl);
 417
 418          if No (Decls) then
 419             Decls := New_List (Make_Null_Statement (Loc));
 420             Set_Visible_Declarations (Unit_Decl, Decls);
 421
 422          elsif Is_Empty_List (Decls) then
 423             Append_To (Decls, Make_Null_Statement (Loc));
 424          end if;
 425
 426       else
 427          Decls := Declarations (Unit_Decl);
 428
 429          if No (Decls) then
 430             Decls := New_List (Make_Null_Statement (Loc));
 431             Set_Declarations (Unit_Decl, Decls);
 432
 433          elsif Is_Empty_List (Decls) then
 434             Append_To (Decls, Make_Null_Statement (Loc));
 435          end if;
 436       end if;
 437
 438       --  The current unit has an existing anonymous master, traverse its
 439       --  declarations and locate the entity.
 440
 441       if Has_Anonymous_Master (Unit_Id) then
 442          declare
 443             Decl       : Node_Id;
 444             Fin_Mas_Id : Entity_Id;
 445
 446          begin
 447             Decl := First (Decls);
 448             while Present (Decl) loop
 449
 450                --  Look for the first variable in the declarations whole type
 451                --  is Finalization_Master.
 452
 453                if Nkind (Decl) = N_Object_Declaration then
 454                   Fin_Mas_Id := Defining_Identifier (Decl);
 455
 456                   if Ekind (Fin_Mas_Id) = E_Variable
 457                     and then Etype (Fin_Mas_Id) = RTE (RE_Finalization_Master)
 458                   then
 459                      return Fin_Mas_Id;
 460                   end if;
 461                end if;
 462
 463                Next (Decl);
 464             end loop;
 465
 466             --  The master was not found even though the unit was labeled as
 467             --  having one.
 468
 469             raise Program_Error;
 470          end;
 471
 472       --  Create a new anonymous master
 473
 474       else
 475          declare
 476             First_Decl : constant Node_Id := First (Decls);
 477             Action     : Node_Id;
 478             Fin_Mas_Id : Entity_Id;
 479
 480          begin
 481             --  Since the master and its associated initialization is inserted
 482             --  at top level, use the scope of the unit when analyzing.
 483
 484             Push_Scope (Unit_Id);
 485
 486             --  Create the finalization master
 487
 488             Fin_Mas_Id :=
 489               Make_Defining_Identifier (Loc,
 490                 Chars => New_External_Name (Chars (Unit_Id), "AM"));
 491
 492             --  Generate:
 493             --    <Fin_Mas_Id> : Finalization_Master;
 494
 495             Action :=
 496               Make_Object_Declaration (Loc,
 497                 Defining_Identifier => Fin_Mas_Id,
 498                 Object_Definition =>
 499                   New_Reference_To (RTE (RE_Finalization_Master), Loc));
 500
 501             Insert_Before_And_Analyze (First_Decl, Action);
 502
 503             --  Mark the unit to prevent the generation of multiple masters
 504
 505             Set_Has_Anonymous_Master (Unit_Id);
 506
 507             --  Do not set the base pool and mode of operation on .NET/JVM
 508             --  since those targets do not support pools and all VM masters
 509             --  are heterogeneous by default.
 510
 511             if VM_Target = No_VM then
 512
 513                --  Generate:
 514                --    Set_Base_Pool
 515                --      (<Fin_Mas_Id>, Global_Pool_Object'Unrestricted_Access);
 516
 517                Action :=
 518                  Make_Procedure_Call_Statement (Loc,
 519                    Name =>
 520                      New_Reference_To (RTE (RE_Set_Base_Pool), Loc),
 521
 522                    Parameter_Associations => New_List (
 523                      New_Reference_To (Fin_Mas_Id, Loc),
 524                      Make_Attribute_Reference (Loc,
 525                        Prefix =>
 526                          New_Reference_To (RTE (RE_Global_Pool_Object), Loc),
 527                        Attribute_Name => Name_Unrestricted_Access)));
 528
 529                Insert_Before_And_Analyze (First_Decl, Action);
 530
 531                --  Generate:
 532                --    Set_Is_Heterogeneous (<Fin_Mas_Id>);
 533
 534                Action :=
 535                  Make_Procedure_Call_Statement (Loc,
 536                    Name =>
 537                      New_Reference_To (RTE (RE_Set_Is_Heterogeneous), Loc),
 538                    Parameter_Associations => New_List (
 539                      New_Reference_To (Fin_Mas_Id, Loc)));
 540
 541                Insert_Before_And_Analyze (First_Decl, Action);
 542             end if;
 543
 544             --  Restore the original state of the scope stack
 545
 546             Pop_Scope;
 547
 548             return Fin_Mas_Id;
 549          end;
 550       end if;
 551    end Current_Anonymous_Master;
 552
 553    --------------------------------
 554    -- Displace_Allocator_Pointer --
 555    --------------------------------
 556
 557    procedure Displace_Allocator_Pointer (N : Node_Id) is
 558       Loc       : constant Source_Ptr := Sloc (N);
 559       Orig_Node : constant Node_Id := Original_Node (N);
 560       Dtyp      : Entity_Id;
 561       Etyp      : Entity_Id;
 562       PtrT      : Entity_Id;
 563
 564    begin
 565       --  Do nothing in case of VM targets: the virtual machine will handle
 566       --  interfaces directly.
 567
 568       if not Tagged_Type_Expansion then
 569          return;
 570       end if;
 571
 572       pragma Assert (Nkind (N) = N_Identifier
 573         and then Nkind (Orig_Node) = N_Allocator);
 574
 575       PtrT := Etype (Orig_Node);
 576       Dtyp := Available_View (Designated_Type (PtrT));
 577       Etyp := Etype (Expression (Orig_Node));
 578
 579       if Is_Class_Wide_Type (Dtyp)
 580         and then Is_Interface (Dtyp)
 581       then
 582          --  If the type of the allocator expression is not an interface type
 583          --  we can generate code to reference the record component containing
 584          --  the pointer to the secondary dispatch table.
 585
 586          if not Is_Interface (Etyp) then
 587             declare
 588                Saved_Typ : constant Entity_Id := Etype (Orig_Node);
 589
 590             begin
 591                --  1) Get access to the allocated object
 592
 593                Rewrite (N,
 594                  Make_Explicit_Dereference (Loc, Relocate_Node (N)));
 595                Set_Etype (N, Etyp);
 596                Set_Analyzed (N);
 597
 598                --  2) Add the conversion to displace the pointer to reference
 599                --     the secondary dispatch table.
 600
 601                Rewrite (N, Convert_To (Dtyp, Relocate_Node (N)));
 602                Analyze_And_Resolve (N, Dtyp);
 603
 604                --  3) The 'access to the secondary dispatch table will be used
 605                --     as the value returned by the allocator.
 606
 607                Rewrite (N,
 608                  Make_Attribute_Reference (Loc,
 609                    Prefix         => Relocate_Node (N),
 610                    Attribute_Name => Name_Access));
 611                Set_Etype (N, Saved_Typ);
 612                Set_Analyzed (N);
 613             end;
 614
 615          --  If the type of the allocator expression is an interface type we
 616          --  generate a run-time call to displace "this" to reference the
 617          --  component containing the pointer to the secondary dispatch table
 618          --  or else raise Constraint_Error if the actual object does not
 619          --  implement the target interface. This case corresponds with the
 620          --  following example:
 621
 622          --   function Op (Obj : Iface_1'Class) return access Iface_2'Class is
 623          --   begin
 624          --      return new Iface_2'Class'(Obj);
 625          --   end Op;
 626
 627          else
 628             Rewrite (N,
 629               Unchecked_Convert_To (PtrT,
 630                 Make_Function_Call (Loc,
 631                   Name => New_Reference_To (RTE (RE_Displace), Loc),
 632                   Parameter_Associations => New_List (
 633                     Unchecked_Convert_To (RTE (RE_Address),
 634                       Relocate_Node (N)),
 635
 636                     New_Occurrence_Of
 637                       (Elists.Node
 638                         (First_Elmt
 639                           (Access_Disp_Table (Etype (Base_Type (Dtyp))))),
 640                        Loc)))));
 641             Analyze_And_Resolve (N, PtrT);
 642          end if;
 643       end if;
 644    end Displace_Allocator_Pointer;
 645
 646    ---------------------------------
 647    -- Expand_Allocator_Expression --
 648    ---------------------------------
 649
 650    procedure Expand_Allocator_Expression (N : Node_Id) is
 651       Loc    : constant Source_Ptr := Sloc (N);
 652       Exp    : constant Node_Id    := Expression (Expression (N));
 653       PtrT   : constant Entity_Id  := Etype (N);
 654       DesigT : constant Entity_Id  := Designated_Type (PtrT);
 655
 656       procedure Apply_Accessibility_Check
 657         (Ref            : Node_Id;
 658          Built_In_Place : Boolean := False);
 659       --  Ada 2005 (AI-344): For an allocator with a class-wide designated
 660       --  type, generate an accessibility check to verify that the level of the
 661       --  type of the created object is not deeper than the level of the access
 662       --  type. If the type of the qualified expression is class- wide, then
 663       --  always generate the check (except in the case where it is known to be
 664       --  unnecessary, see comment below). Otherwise, only generate the check
 665       --  if the level of the qualified expression type is statically deeper
 666       --  than the access type.
 667       --
 668       --  Although the static accessibility will generally have been performed
 669       --  as a legality check, it won't have been done in cases where the
 670       --  allocator appears in generic body, so a run-time check is needed in
 671       --  general. One special case is when the access type is declared in the
 672       --  same scope as the class-wide allocator, in which case the check can
 673       --  never fail, so it need not be generated.
 674       --
 675       --  As an open issue, there seem to be cases where the static level
 676       --  associated with the class-wide object's underlying type is not
 677       --  sufficient to perform the proper accessibility check, such as for
 678       --  allocators in nested subprograms or accept statements initialized by
 679       --  class-wide formals when the actual originates outside at a deeper
 680       --  static level. The nested subprogram case might require passing
 681       --  accessibility levels along with class-wide parameters, and the task
 682       --  case seems to be an actual gap in the language rules that needs to
 683       --  be fixed by the ARG. ???
 684
 685       -------------------------------
 686       -- Apply_Accessibility_Check --
 687       -------------------------------
 688
 689       procedure Apply_Accessibility_Check
 690         (Ref            : Node_Id;
 691          Built_In_Place : Boolean := False)
 692       is
 693          New_Node : Node_Id;
 694
 695       begin
 696          if Ada_Version >= Ada_2005
 697            and then Is_Class_Wide_Type (DesigT)
 698            and then not Scope_Suppress (Accessibility_Check)
 699            and then
 700              (Type_Access_Level (Etype (Exp)) > Type_Access_Level (PtrT)
 701                or else
 702                  (Is_Class_Wide_Type (Etype (Exp))
 703                    and then Scope (PtrT) /= Current_Scope))
 704          then
 705             --  If the allocator was built in place Ref is already a reference
 706             --  to the access object initialized to the result of the allocator
 707             --  (see Exp_Ch6.Make_Build_In_Place_Call_In_Allocator). Otherwise
 708             --  it is the entity associated with the object containing the
 709             --  address of the allocated object.
 710
 711             if Built_In_Place then
 712                New_Node := New_Copy (Ref);
 713             else
 714                New_Node := New_Reference_To (Ref, Loc);
 715             end if;
 716
 717             New_Node :=
 718               Make_Attribute_Reference (Loc,
 719                 Prefix         => New_Node,
 720                 Attribute_Name => Name_Tag);
 721
 722             if Tagged_Type_Expansion then
 723                New_Node := Build_Get_Access_Level (Loc, New_Node);
 724
 725             elsif VM_Target /= No_VM then
 726                New_Node :=
 727                  Make_Function_Call (Loc,
 728                    Name => New_Reference_To (RTE (RE_Get_Access_Level), Loc),
 729                    Parameter_Associations => New_List (New_Node));
 730
 731             --  Cannot generate the runtime check
 732
 733             else
 734                return;
 735             end if;
 736
 737             Insert_Action (N,
 738               Make_Raise_Program_Error (Loc,
 739                 Condition =>
 740                   Make_Op_Gt (Loc,
 741                     Left_Opnd  => New_Node,
 742                     Right_Opnd =>
 743                       Make_Integer_Literal (Loc, Type_Access_Level (PtrT))),
 744                 Reason => PE_Accessibility_Check_Failed));
 745          end if;
 746       end Apply_Accessibility_Check;
 747
 748       --  Local variables
 749
 750       Aggr_In_Place : constant Boolean   := Is_Delayed_Aggregate (Exp);
 751       Indic         : constant Node_Id   := Subtype_Mark (Expression (N));
 752       T             : constant Entity_Id := Entity (Indic);
 753       Node          : Node_Id;
 754       Tag_Assign    : Node_Id;
 755       Temp          : Entity_Id;
 756       Temp_Decl     : Node_Id;
 757
 758       TagT : Entity_Id := Empty;
 759       --  Type used as source for tag assignment
 760
 761       TagR : Node_Id := Empty;
 762       --  Target reference for tag assignment
 763
 764    --  Start of processing for Expand_Allocator_Expression
 765
 766    begin
 767       --  In the case of an Ada 2012 allocator whose initial value comes from a
 768       --  function call, pass "the accessibility level determined by the point
 769       --  of call" (AI05-0234) to the function. Conceptually, this belongs in
 770       --  Expand_Call but it couldn't be done there (because the Etype of the
 771       --  allocator wasn't set then) so we generate the parameter here. See
 772       --  the Boolean variable Defer in (a block within) Expand_Call.
 773
 774       if Ada_Version >= Ada_2012 and then Nkind (Exp) = N_Function_Call then
 775          declare
 776             Subp : Entity_Id;
 777
 778          begin
 779             if Nkind (Name (Exp)) = N_Explicit_Dereference then
 780                Subp := Designated_Type (Etype (Prefix (Name (Exp))));
 781             else
 782                Subp := Entity (Name (Exp));
 783             end if;
 784
 785             Subp := Ultimate_Alias (Subp);
 786
 787             if Present (Extra_Accessibility_Of_Result (Subp)) then
 788                Add_Extra_Actual_To_Call
 789                  (Subprogram_Call => Exp,
 790                   Extra_Formal    => Extra_Accessibility_Of_Result (Subp),
 791                   Extra_Actual    => Dynamic_Accessibility_Level (PtrT));
 792             end if;
 793          end;
 794       end if;
 795
 796       --  Would be nice to comment the branches of this very long if ???
 797
 798       if Is_Tagged_Type (T) or else Needs_Finalization (T) then
 799          if Is_CPP_Constructor_Call (Exp) then
 800
 801             --  Generate:
 802             --    Pnnn : constant ptr_T := new (T);
 803             --    Init (Pnnn.all,...);
 804
 805             --  Allocate the object without an expression
 806
 807             Node := Relocate_Node (N);
 808             Set_Expression (Node, New_Reference_To (Etype (Exp), Loc));
 809
 810             --  Avoid its expansion to avoid generating a call to the default
 811             --  C++ constructor.
 812
 813             Set_Analyzed (Node);
 814
 815             Temp := Make_Temporary (Loc, 'P', N);
 816
 817             Temp_Decl :=
 818               Make_Object_Declaration (Loc,
 819                 Defining_Identifier => Temp,
 820                 Constant_Present    => True,
 821                 Object_Definition   => New_Reference_To (PtrT, Loc),
 822                 Expression          => Node);
 823             Insert_Action (N, Temp_Decl);
 824
 825             Apply_Accessibility_Check (Temp);
 826
 827             --  Locate the enclosing list and insert the C++ constructor call
 828
 829             declare
 830                P : Node_Id;
 831
 832             begin
 833                P := Parent (Node);
 834                while not Is_List_Member (P) loop
 835                   P := Parent (P);
 836                end loop;
 837
 838                Insert_List_After_And_Analyze (P,
 839                  Build_Initialization_Call (Loc,
 840                    Id_Ref          =>
 841                      Make_Explicit_Dereference (Loc,
 842                        Prefix => New_Reference_To (Temp, Loc)),
 843                    Typ             => Etype (Exp),
 844                    Constructor_Ref => Exp));
 845             end;
 846
 847             Rewrite (N, New_Reference_To (Temp, Loc));
 848             Analyze_And_Resolve (N, PtrT);
 849             return;
 850          end if;
 851
 852          --  Ada 2005 (AI-318-02): If the initialization expression is a call
 853          --  to a build-in-place function, then access to the allocated object
 854          --  must be passed to the function. Currently we limit such functions
 855          --  to those with constrained limited result subtypes, but eventually
 856          --  we plan to expand the allowed forms of functions that are treated
 857          --  as build-in-place.
 858
 859          if Ada_Version >= Ada_2005
 860            and then Is_Build_In_Place_Function_Call (Exp)
 861          then
 862             Make_Build_In_Place_Call_In_Allocator (N, Exp);
 863             Apply_Accessibility_Check (N, Built_In_Place => True);
 864             return;
 865          end if;
 866
 867          --  Actions inserted before:
 868          --    Temp : constant ptr_T := new T'(Expression);
 869          --    Temp._tag = T'tag;  --  when not class-wide
 870          --    [Deep_]Adjust (Temp.all);
 871
 872          --  We analyze by hand the new internal allocator to avoid any
 873          --  recursion and inappropriate call to Initialize
 874
 875          --  We don't want to remove side effects when the expression must be
 876          --  built in place. In the case of a build-in-place function call,
 877          --  that could lead to a duplication of the call, which was already
 878          --  substituted for the allocator.
 879
 880          if not Aggr_In_Place then
 881             Remove_Side_Effects (Exp);
 882          end if;
 883
 884          Temp := Make_Temporary (Loc, 'P', N);
 885
 886          --  For a class wide allocation generate the following code:
 887
 888          --    type Equiv_Record is record ... end record;
 889          --    implicit subtype CW is <Class_Wide_Subytpe>;
 890          --    temp : PtrT := new CW'(CW!(expr));
 891
 892          if Is_Class_Wide_Type (T) then
 893             Expand_Subtype_From_Expr (Empty, T, Indic, Exp);
 894
 895             --  Ada 2005 (AI-251): If the expression is a class-wide interface
 896             --  object we generate code to move up "this" to reference the
 897             --  base of the object before allocating the new object.
 898
 899             --  Note that Exp'Address is recursively expanded into a call
 900             --  to Base_Address (Exp.Tag)
 901
 902             if Is_Class_Wide_Type (Etype (Exp))
 903               and then Is_Interface (Etype (Exp))
 904               and then Tagged_Type_Expansion
 905             then
 906                Set_Expression
 907                  (Expression (N),
 908                   Unchecked_Convert_To (Entity (Indic),
 909                     Make_Explicit_Dereference (Loc,
 910                       Unchecked_Convert_To (RTE (RE_Tag_Ptr),
 911                         Make_Attribute_Reference (Loc,
 912                           Prefix         => Exp,
 913                           Attribute_Name => Name_Address)))));
 914             else
 915                Set_Expression
 916                  (Expression (N),
 917                   Unchecked_Convert_To (Entity (Indic), Exp));
 918             end if;
 919
 920             Analyze_And_Resolve (Expression (N), Entity (Indic));
 921          end if;
 922
 923          --  Processing for allocators returning non-interface types
 924
 925          if not Is_Interface (Directly_Designated_Type (PtrT)) then
 926             if Aggr_In_Place then
 927                Temp_Decl :=
 928                  Make_Object_Declaration (Loc,
 929                    Defining_Identifier => Temp,
 930                    Object_Definition   => New_Reference_To (PtrT, Loc),
 931                    Expression          =>
 932                      Make_Allocator (Loc,
 933                        Expression =>
 934                          New_Reference_To (Etype (Exp), Loc)));
 935
 936                --  Copy the Comes_From_Source flag for the allocator we just
 937                --  built, since logically this allocator is a replacement of
 938                --  the original allocator node. This is for proper handling of
 939                --  restriction No_Implicit_Heap_Allocations.
 940
 941                Set_Comes_From_Source
 942                  (Expression (Temp_Decl), Comes_From_Source (N));
 943
 944                Set_No_Initialization (Expression (Temp_Decl));
 945                Insert_Action (N, Temp_Decl);
 946
 947                Build_Allocate_Deallocate_Proc (Temp_Decl, True);
 948                Convert_Aggr_In_Allocator (N, Temp_Decl, Exp);
 949
 950                --  Attach the object to the associated finalization master.
 951                --  This is done manually on .NET/JVM since those compilers do
 952                --  no support pools and can't benefit from internally generated
 953                --  Allocate / Deallocate procedures.
 954
 955                if VM_Target /= No_VM
 956                  and then Is_Controlled (DesigT)
 957                  and then Present (Finalization_Master (PtrT))
 958                then
 959                   Insert_Action (N,
 960                     Make_Attach_Call (
 961                       Obj_Ref =>
 962                         New_Reference_To (Temp, Loc),
 963                       Ptr_Typ => PtrT));
 964                end if;
 965
 966             else
 967                Node := Relocate_Node (N);
 968                Set_Analyzed (Node);
 969
 970                Temp_Decl :=
 971                  Make_Object_Declaration (Loc,
 972                    Defining_Identifier => Temp,
 973                    Constant_Present    => True,
 974                    Object_Definition   => New_Reference_To (PtrT, Loc),
 975                    Expression          => Node);
 976
 977                Insert_Action (N, Temp_Decl);
 978                Build_Allocate_Deallocate_Proc (Temp_Decl, True);
 979
 980                --  Attach the object to the associated finalization master.
 981                --  This is done manually on .NET/JVM since those compilers do
 982                --  no support pools and can't benefit from internally generated
 983                --  Allocate / Deallocate procedures.
 984
 985                if VM_Target /= No_VM
 986                  and then Is_Controlled (DesigT)
 987                  and then Present (Finalization_Master (PtrT))
 988                then
 989                   Insert_Action (N,
 990                     Make_Attach_Call (
 991                       Obj_Ref =>
 992                         New_Reference_To (Temp, Loc),
 993                       Ptr_Typ => PtrT));
 994                end if;
 995             end if;
 996
 997          --  Ada 2005 (AI-251): Handle allocators whose designated type is an
 998          --  interface type. In this case we use the type of the qualified
 999          --  expression to allocate the object.
1000
1001          else
1002             declare
1003                Def_Id   : constant Entity_Id := Make_Temporary (Loc, 'T');
1004                New_Decl : Node_Id;
1005
1006             begin
1007                New_Decl :=
1008                  Make_Full_Type_Declaration (Loc,
1009                    Defining_Identifier => Def_Id,
1010                    Type_Definition =>
1011                      Make_Access_To_Object_Definition (Loc,
1012                        All_Present            => True,
1013                        Null_Exclusion_Present => False,
1014                        Constant_Present       => False,
1015                        Subtype_Indication     =>
1016                          New_Reference_To (Etype (Exp), Loc)));
1017
1018                Insert_Action (N, New_Decl);
1019
1020                --  Inherit the allocation-related attributes from the original
1021                --  access type.
1022
1023                Set_Finalization_Master (Def_Id, Finalization_Master (PtrT));
1024
1025                Set_Associated_Storage_Pool (Def_Id,
1026                  Associated_Storage_Pool (PtrT));
1027
1028                --  Declare the object using the previous type declaration
1029
1030                if Aggr_In_Place then
1031                   Temp_Decl :=
1032                     Make_Object_Declaration (Loc,
1033                       Defining_Identifier => Temp,
1034                       Object_Definition   => New_Reference_To (Def_Id, Loc),
1035                       Expression          =>
1036                         Make_Allocator (Loc,
1037                           New_Reference_To (Etype (Exp), Loc)));
1038
1039                   --  Copy the Comes_From_Source flag for the allocator we just
1040                   --  built, since logically this allocator is a replacement of
1041                   --  the original allocator node. This is for proper handling
1042                   --  of restriction No_Implicit_Heap_Allocations.
1043
1044                   Set_Comes_From_Source
1045                     (Expression (Temp_Decl), Comes_From_Source (N));
1046
1047                   Set_No_Initialization (Expression (Temp_Decl));
1048                   Insert_Action (N, Temp_Decl);
1049
1050                   Build_Allocate_Deallocate_Proc (Temp_Decl, True);
1051                   Convert_Aggr_In_Allocator (N, Temp_Decl, Exp);
1052
1053                else
1054                   Node := Relocate_Node (N);
1055                   Set_Analyzed (Node);
1056
1057                   Temp_Decl :=
1058                     Make_Object_Declaration (Loc,
1059                       Defining_Identifier => Temp,
1060                       Constant_Present    => True,
1061                       Object_Definition   => New_Reference_To (Def_Id, Loc),
1062                       Expression          => Node);
1063
1064                   Insert_Action (N, Temp_Decl);
1065                   Build_Allocate_Deallocate_Proc (Temp_Decl, True);
1066                end if;
1067
1068                --  Generate an additional object containing the address of the
1069                --  returned object. The type of this second object declaration
1070                --  is the correct type required for the common processing that
1071                --  is still performed by this subprogram. The displacement of
1072                --  this pointer to reference the component associated with the
1073                --  interface type will be done at the end of common processing.
1074
1075                New_Decl :=
1076                  Make_Object_Declaration (Loc,
1077                    Defining_Identifier => Make_Temporary (Loc, 'P'),
1078                    Object_Definition   => New_Reference_To (PtrT, Loc),
1079                    Expression          =>
1080                      Unchecked_Convert_To (PtrT,
1081                        New_Reference_To (Temp, Loc)));
1082
1083                Insert_Action (N, New_Decl);
1084
1085                Temp_Decl := New_Decl;
1086                Temp      := Defining_Identifier (New_Decl);
1087             end;
1088          end if;
1089
1090          Apply_Accessibility_Check (Temp);
1091
1092          --  Generate the tag assignment
1093
1094          --  Suppress the tag assignment when VM_Target because VM tags are
1095          --  represented implicitly in objects.
1096
1097          if not Tagged_Type_Expansion then
1098             null;
1099
1100          --  Ada 2005 (AI-251): Suppress the tag assignment with class-wide
1101          --  interface objects because in this case the tag does not change.
1102
1103          elsif Is_Interface (Directly_Designated_Type (Etype (N))) then
1104             pragma Assert (Is_Class_Wide_Type
1105                             (Directly_Designated_Type (Etype (N))));
1106             null;
1107
1108          elsif Is_Tagged_Type (T) and then not Is_Class_Wide_Type (T) then
1109             TagT := T;
1110             TagR := New_Reference_To (Temp, Loc);
1111
1112          elsif Is_Private_Type (T)
1113            and then Is_Tagged_Type (Underlying_Type (T))
1114          then
1115             TagT := Underlying_Type (T);
1116             TagR :=
1117               Unchecked_Convert_To (Underlying_Type (T),
1118                 Make_Explicit_Dereference (Loc,
1119                   Prefix => New_Reference_To (Temp, Loc)));
1120          end if;
1121
1122          if Present (TagT) then
1123             declare
1124                Full_T : constant Entity_Id := Underlying_Type (TagT);
1125             begin
1126                Tag_Assign :=
1127                  Make_Assignment_Statement (Loc,
1128                    Name =>
1129                      Make_Selected_Component (Loc,
1130                        Prefix => TagR,
1131                        Selector_Name =>
1132                          New_Reference_To (First_Tag_Component (Full_T), Loc)),
1133                    Expression =>
1134                      Unchecked_Convert_To (RTE (RE_Tag),
1135                        New_Reference_To
1136                          (Elists.Node
1137                            (First_Elmt (Access_Disp_Table (Full_T))), Loc)));
1138             end;
1139
1140             --  The previous assignment has to be done in any case
1141
1142             Set_Assignment_OK (Name (Tag_Assign));
1143             Insert_Action (N, Tag_Assign);
1144          end if;
1145
1146          if Needs_Finalization (DesigT)
1147             and then Needs_Finalization (T)
1148          then
1149             --  Generate an Adjust call if the object will be moved. In Ada
1150             --  2005, the object may be inherently limited, in which case
1151             --  there is no Adjust procedure, and the object is built in
1152             --  place. In Ada 95, the object can be limited but not
1153             --  inherently limited if this allocator came from a return
1154             --  statement (we're allocating the result on the secondary
1155             --  stack). In that case, the object will be moved, so we _do_
1156             --  want to Adjust.
1157
1158             if not Aggr_In_Place
1159               and then not Is_Immutably_Limited_Type (T)
1160             then
1161                Insert_Action (N,
1162                  Make_Adjust_Call (
1163                    Obj_Ref    =>
1164
1165                      --  An unchecked conversion is needed in the classwide
1166                      --  case because the designated type can be an ancestor
1167                      --  of the subtype mark of the allocator.
1168
1169                      Unchecked_Convert_To (T,
1170                        Make_Explicit_Dereference (Loc,
1171                          Prefix => New_Reference_To (Temp, Loc))),
1172                    Typ => T));
1173             end if;
1174
1175             --  Generate:
1176             --    Set_Finalize_Address (<PtrT>FM, <T>FD'Unrestricted_Access);
1177
1178             --  Do not generate this call in the following cases:
1179
1180             --    * .NET/JVM - these targets do not support address arithmetic
1181             --    and unchecked conversion, key elements of Finalize_Address.
1182
1183             --    * Alfa mode - the call is useless and results in unwanted
1184             --    expansion.
1185
1186             --    * CodePeer mode - TSS primitive Finalize_Address is not
1187             --    created in this mode.
1188
1189             if VM_Target = No_VM
1190               and then not Alfa_Mode
1191               and then not CodePeer_Mode
1192               and then Present (Finalization_Master (PtrT))
1193               and then Present (Temp_Decl)
1194               and then Nkind (Expression (Temp_Decl)) = N_Allocator
1195             then
1196                Insert_Action (N,
1197                  Make_Set_Finalize_Address_Call
1198                    (Loc     => Loc,
1199                     Typ     => T,
1200                     Ptr_Typ => PtrT));
1201             end if;
1202          end if;
1203
1204          Rewrite (N, New_Reference_To (Temp, Loc));
1205          Analyze_And_Resolve (N, PtrT);
1206
1207          --  Ada 2005 (AI-251): Displace the pointer to reference the record
1208          --  component containing the secondary dispatch table of the interface
1209          --  type.
1210
1211          if Is_Interface (Directly_Designated_Type (PtrT)) then
1212             Displace_Allocator_Pointer (N);
1213          end if;
1214
1215       elsif Aggr_In_Place then
1216          Temp := Make_Temporary (Loc, 'P', N);
1217          Temp_Decl :=
1218            Make_Object_Declaration (Loc,
1219              Defining_Identifier => Temp,
1220              Object_Definition   => New_Reference_To (PtrT, Loc),
1221              Expression          =>
1222                Make_Allocator (Loc,
1223                  Expression => New_Reference_To (Etype (Exp), Loc)));
1224
1225          --  Copy the Comes_From_Source flag for the allocator we just built,
1226          --  since logically this allocator is a replacement of the original
1227          --  allocator node. This is for proper handling of restriction
1228          --  No_Implicit_Heap_Allocations.
1229
1230          Set_Comes_From_Source
1231            (Expression (Temp_Decl), Comes_From_Source (N));
1232
1233          Set_No_Initialization (Expression (Temp_Decl));
1234          Insert_Action (N, Temp_Decl);
1235
1236          Build_Allocate_Deallocate_Proc (Temp_Decl, True);
1237          Convert_Aggr_In_Allocator (N, Temp_Decl, Exp);
1238
1239          --  Attach the object to the associated finalization master. Thisis
1240          --  done manually on .NET/JVM since those compilers do no support
1241          --  pools and cannot benefit from internally generated Allocate and
1242          --  Deallocate procedures.
1243
1244          if VM_Target /= No_VM
1245            and then Is_Controlled (DesigT)
1246            and then Present (Finalization_Master (PtrT))
1247          then
1248             Insert_Action (N,
1249               Make_Attach_Call
1250                 (Obj_Ref => New_Reference_To (Temp, Loc),
1251                  Ptr_Typ => PtrT));
1252          end if;
1253
1254          Rewrite (N, New_Reference_To (Temp, Loc));
1255          Analyze_And_Resolve (N, PtrT);
1256
1257       elsif Is_Access_Type (T)
1258         and then Can_Never_Be_Null (T)
1259       then
1260          Install_Null_Excluding_Check (Exp);
1261
1262       elsif Is_Access_Type (DesigT)
1263         and then Nkind (Exp) = N_Allocator
1264         and then Nkind (Expression (Exp)) /= N_Qualified_Expression
1265       then
1266          --  Apply constraint to designated subtype indication
1267
1268          Apply_Constraint_Check (Expression (Exp),
1269            Designated_Type (DesigT),
1270            No_Sliding => True);
1271
1272          if Nkind (Expression (Exp)) = N_Raise_Constraint_Error then
1273
1274             --  Propagate constraint_error to enclosing allocator
1275
1276             Rewrite (Exp, New_Copy (Expression (Exp)));
1277          end if;
1278
1279       else
1280          Build_Allocate_Deallocate_Proc (N, True);
1281
1282          --  If we have:
1283          --    type A is access T1;
1284          --    X : A := new T2'(...);
1285          --  T1 and T2 can be different subtypes, and we might need to check
1286          --  both constraints. First check against the type of the qualified
1287          --  expression.
1288
1289          Apply_Constraint_Check (Exp, T, No_Sliding => True);
1290
1291          if Do_Range_Check (Exp) then
1292             Set_Do_Range_Check (Exp, False);
1293             Generate_Range_Check (Exp, DesigT, CE_Range_Check_Failed);
1294          end if;
1295
1296          --  A check is also needed in cases where the designated subtype is
1297          --  constrained and differs from the subtype given in the qualified
1298          --  expression. Note that the check on the qualified expression does
1299          --  not allow sliding, but this check does (a relaxation from Ada 83).
1300
1301          if Is_Constrained (DesigT)
1302            and then not Subtypes_Statically_Match (T, DesigT)
1303          then
1304             Apply_Constraint_Check
1305               (Exp, DesigT, No_Sliding => False);
1306
1307             if Do_Range_Check (Exp) then
1308                Set_Do_Range_Check (Exp, False);
1309                Generate_Range_Check (Exp, DesigT, CE_Range_Check_Failed);
1310             end if;
1311          end if;
1312
1313          --  For an access to unconstrained packed array, GIGI needs to see an
1314          --  expression with a constrained subtype in order to compute the
1315          --  proper size for the allocator.
1316
1317          if Is_Array_Type (T)
1318            and then not Is_Constrained (T)
1319            and then Is_Packed (T)
1320          then
1321             declare
1322                ConstrT      : constant Entity_Id := Make_Temporary (Loc, 'A');
1323                Internal_Exp : constant Node_Id   := Relocate_Node (Exp);
1324             begin
1325                Insert_Action (Exp,
1326                  Make_Subtype_Declaration (Loc,
1327                    Defining_Identifier => ConstrT,
1328                    Subtype_Indication  =>
1329                      Make_Subtype_From_Expr (Internal_Exp, T)));
1330                Freeze_Itype (ConstrT, Exp);
1331                Rewrite (Exp, OK_Convert_To (ConstrT, Internal_Exp));
1332             end;
1333          end if;
1334
1335          --  Ada 2005 (AI-318-02): If the initialization expression is a call
1336          --  to a build-in-place function, then access to the allocated object
1337          --  must be passed to the function. Currently we limit such functions
1338          --  to those with constrained limited result subtypes, but eventually
1339          --  we plan to expand the allowed forms of functions that are treated
1340          --  as build-in-place.
1341
1342          if Ada_Version >= Ada_2005
1343            and then Is_Build_In_Place_Function_Call (Exp)
1344          then
1345             Make_Build_In_Place_Call_In_Allocator (N, Exp);
1346          end if;
1347       end if;
1348
1349    exception
1350       when RE_Not_Available =>
1351          return;
1352    end Expand_Allocator_Expression;
1353
1354    -----------------------------
1355    -- Expand_Array_Comparison --
1356    -----------------------------
1357
1358    --  Expansion is only required in the case of array types. For the unpacked
1359    --  case, an appropriate runtime routine is called. For packed cases, and
1360    --  also in some other cases where a runtime routine cannot be called, the
1361    --  form of the expansion is:
1362
1363    --     [body for greater_nn; boolean_expression]
1364
1365    --  The body is built by Make_Array_Comparison_Op, and the form of the
1366    --  Boolean expression depends on the operator involved.
1367
1368    procedure Expand_Array_Comparison (N : Node_Id) is
1369       Loc  : constant Source_Ptr := Sloc (N);
1370       Op1  : Node_Id             := Left_Opnd (N);
1371       Op2  : Node_Id             := Right_Opnd (N);
1372       Typ1 : constant Entity_Id  := Base_Type (Etype (Op1));
1373       Ctyp : constant Entity_Id  := Component_Type (Typ1);
1374
1375       Expr      : Node_Id;
1376       Func_Body : Node_Id;
1377       Func_Name : Entity_Id;
1378
1379       Comp : RE_Id;
1380
1381       Byte_Addressable : constant Boolean := System_Storage_Unit = Byte'Size;
1382       --  True for byte addressable target
1383
1384       function Length_Less_Than_4 (Opnd : Node_Id) return Boolean;
1385       --  Returns True if the length of the given operand is known to be less
1386       --  than 4. Returns False if this length is known to be four or greater
1387       --  or is not known at compile time.
1388
1389       ------------------------
1390       -- Length_Less_Than_4 --
1391       ------------------------
1392
1393       function Length_Less_Than_4 (Opnd : Node_Id) return Boolean is
1394          Otyp : constant Entity_Id := Etype (Opnd);
1395
1396       begin
1397          if Ekind (Otyp) = E_String_Literal_Subtype then
1398             return String_Literal_Length (Otyp) < 4;
1399
1400          else
1401             declare
1402                Ityp : constant Entity_Id := Etype (First_Index (Otyp));
1403                Lo   : constant Node_Id   := Type_Low_Bound (Ityp);
1404                Hi   : constant Node_Id   := Type_High_Bound (Ityp);
1405                Lov  : Uint;
1406                Hiv  : Uint;
1407
1408             begin
1409                if Compile_Time_Known_Value (Lo) then
1410                   Lov := Expr_Value (Lo);
1411                else
1412                   return False;
1413                end if;
1414
1415                if Compile_Time_Known_Value (Hi) then
1416                   Hiv := Expr_Value (Hi);
1417                else
1418                   return False;
1419                end if;
1420
1421                return Hiv < Lov + 3;
1422             end;
1423          end if;
1424       end Length_Less_Than_4;
1425
1426    --  Start of processing for Expand_Array_Comparison
1427
1428    begin
1429       --  Deal first with unpacked case, where we can call a runtime routine
1430       --  except that we avoid this for targets for which are not addressable
1431       --  by bytes, and for the JVM/CIL, since they do not support direct
1432       --  addressing of array components.
1433
1434       if not Is_Bit_Packed_Array (Typ1)
1435         and then Byte_Addressable
1436         and then VM_Target = No_VM
1437       then
1438          --  The call we generate is:
1439
1440          --  Compare_Array_xn[_Unaligned]
1441          --    (left'address, right'address, left'length, right'length) <op> 0
1442
1443          --  x = U for unsigned, S for signed
1444          --  n = 8,16,32,64 for component size
1445          --  Add _Unaligned if length < 4 and component size is 8.
1446          --  <op> is the standard comparison operator
1447
1448          if Component_Size (Typ1) = 8 then
1449             if Length_Less_Than_4 (Op1)
1450                  or else
1451                Length_Less_Than_4 (Op2)
1452             then
1453                if Is_Unsigned_Type (Ctyp) then
1454                   Comp := RE_Compare_Array_U8_Unaligned;
1455                else
1456                   Comp := RE_Compare_Array_S8_Unaligned;
1457                end if;
1458
1459             else
1460                if Is_Unsigned_Type (Ctyp) then
1461                   Comp := RE_Compare_Array_U8;
1462                else
1463                   Comp := RE_Compare_Array_S8;
1464                end if;
1465             end if;
1466
1467          elsif Component_Size (Typ1) = 16 then
1468             if Is_Unsigned_Type (Ctyp) then
1469                Comp := RE_Compare_Array_U16;
1470             else
1471                Comp := RE_Compare_Array_S16;
1472             end if;
1473
1474          elsif Component_Size (Typ1) = 32 then
1475             if Is_Unsigned_Type (Ctyp) then
1476                Comp := RE_Compare_Array_U32;
1477             else
1478                Comp := RE_Compare_Array_S32;
1479             end if;
1480
1481          else pragma Assert (Component_Size (Typ1) = 64);
1482             if Is_Unsigned_Type (Ctyp) then
1483                Comp := RE_Compare_Array_U64;
1484             else
1485                Comp := RE_Compare_Array_S64;
1486             end if;
1487          end if;
1488
1489          Remove_Side_Effects (Op1, Name_Req => True);
1490          Remove_Side_Effects (Op2, Name_Req => True);
1491
1492          Rewrite (Op1,
1493            Make_Function_Call (Sloc (Op1),
1494              Name => New_Occurrence_Of (RTE (Comp), Loc),
1495
1496              Parameter_Associations => New_List (
1497                Make_Attribute_Reference (Loc,
1498                  Prefix         => Relocate_Node (Op1),
1499                  Attribute_Name => Name_Address),
1500
1501                Make_Attribute_Reference (Loc,
1502                  Prefix         => Relocate_Node (Op2),
1503                  Attribute_Name => Name_Address),
1504
1505                Make_Attribute_Reference (Loc,
1506                  Prefix         => Relocate_Node (Op1),
1507                  Attribute_Name => Name_Length),
1508
1509                Make_Attribute_Reference (Loc,
1510                  Prefix         => Relocate_Node (Op2),
1511                  Attribute_Name => Name_Length))));
1512
1513          Rewrite (Op2,
1514            Make_Integer_Literal (Sloc (Op2),
1515              Intval => Uint_0));
1516
1517          Analyze_And_Resolve (Op1, Standard_Integer);
1518          Analyze_And_Resolve (Op2, Standard_Integer);
1519          return;
1520       end if;
1521
1522       --  Cases where we cannot make runtime call
1523
1524       --  For (a <= b) we convert to not (a > b)
1525
1526       if Chars (N) = Name_Op_Le then
1527          Rewrite (N,
1528            Make_Op_Not (Loc,
1529              Right_Opnd =>
1530                 Make_Op_Gt (Loc,
1531                  Left_Opnd  => Op1,
1532                  Right_Opnd => Op2)));
1533          Analyze_And_Resolve (N, Standard_Boolean);
1534          return;
1535
1536       --  For < the Boolean expression is
1537       --    greater__nn (op2, op1)
1538
1539       elsif Chars (N) = Name_Op_Lt then
1540          Func_Body := Make_Array_Comparison_Op (Typ1, N);
1541
1542          --  Switch operands
1543
1544          Op1 := Right_Opnd (N);
1545          Op2 := Left_Opnd  (N);
1546
1547       --  For (a >= b) we convert to not (a < b)
1548
1549       elsif Chars (N) = Name_Op_Ge then
1550          Rewrite (N,
1551            Make_Op_Not (Loc,
1552              Right_Opnd =>
1553                Make_Op_Lt (Loc,
1554                  Left_Opnd  => Op1,
1555                  Right_Opnd => Op2)));
1556          Analyze_And_Resolve (N, Standard_Boolean);
1557          return;
1558
1559       --  For > the Boolean expression is
1560       --    greater__nn (op1, op2)
1561
1562       else
1563          pragma Assert (Chars (N) = Name_Op_Gt);
1564          Func_Body := Make_Array_Comparison_Op (Typ1, N);
1565       end if;
1566
1567       Func_Name := Defining_Unit_Name (Specification (Func_Body));
1568       Expr :=
1569         Make_Function_Call (Loc,
1570           Name => New_Reference_To (Func_Name, Loc),
1571           Parameter_Associations => New_List (Op1, Op2));
1572
1573       Insert_Action (N, Func_Body);
1574       Rewrite (N, Expr);
1575       Analyze_And_Resolve (N, Standard_Boolean);
1576
1577    exception
1578       when RE_Not_Available =>
1579          return;
1580    end Expand_Array_Comparison;
1581
1582    ---------------------------
1583    -- Expand_Array_Equality --
1584    ---------------------------
1585
1586    --  Expand an equality function for multi-dimensional arrays. Here is an
1587    --  example of such a function for Nb_Dimension = 2
1588
1589    --  function Enn (A : atyp; B : btyp) return boolean is
1590    --  begin
1591    --     if (A'length (1) = 0 or else A'length (2) = 0)
1592    --          and then
1593    --        (B'length (1) = 0 or else B'length (2) = 0)
1594    --     then
1595    --        return True;    -- RM 4.5.2(22)
1596    --     end if;
1597
1598    --     if A'length (1) /= B'length (1)
1599    --               or else
1600    --           A'length (2) /= B'length (2)
1601    --     then
1602    --        return False;   -- RM 4.5.2(23)
1603    --     end if;
1604
1605    --     declare
1606    --        A1 : Index_T1 := A'first (1);
1607    --        B1 : Index_T1 := B'first (1);
1608    --     begin
1609    --        loop
1610    --           declare
1611    --              A2 : Index_T2 := A'first (2);
1612    --              B2 : Index_T2 := B'first (2);
1613    --           begin
1614    --              loop
1615    --                 if A (A1, A2) /= B (B1, B2) then
1616    --                    return False;
1617    --                 end if;
1618
1619    --                 exit when A2 = A'last (2);
1620    --                 A2 := Index_T2'succ (A2);
1621    --                 B2 := Index_T2'succ (B2);
1622    --              end loop;
1623    --           end;
1624
1625    --           exit when A1 = A'last (1);
1626    --           A1 := Index_T1'succ (A1);
1627    --           B1 := Index_T1'succ (B1);
1628    --        end loop;
1629    --     end;
1630
1631    --     return true;
1632    --  end Enn;
1633
1634    --  Note on the formal types used (atyp and btyp). If either of the arrays
1635    --  is of a private type, we use the underlying type, and do an unchecked
1636    --  conversion of the actual. If either of the arrays has a bound depending
1637    --  on a discriminant, then we use the base type since otherwise we have an
1638    --  escaped discriminant in the function.
1639
1640    --  If both arrays are constrained and have the same bounds, we can generate
1641    --  a loop with an explicit iteration scheme using a 'Range attribute over
1642    --  the first array.
1643
1644    function Expand_Array_Equality
1645      (Nod    : Node_Id;
1646       Lhs    : Node_Id;
1647       Rhs    : Node_Id;
1648       Bodies : List_Id;
1649       Typ    : Entity_Id) return Node_Id
1650    is
1651       Loc         : constant Source_Ptr := Sloc (Nod);
1652       Decls       : constant List_Id    := New_List;
1653       Index_List1 : constant List_Id    := New_List;
1654       Index_List2 : constant List_Id    := New_List;
1655
1656       Actuals   : List_Id;
1657       Formals   : List_Id;
1658       Func_Name : Entity_Id;
1659       Func_Body : Node_Id;
1660
1661       A : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uA);
1662       B : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uB);
1663
1664       Ltyp : Entity_Id;
1665       Rtyp : Entity_Id;
1666       --  The parameter types to be used for the formals
1667
1668       function Arr_Attr
1669         (Arr : Entity_Id;
1670          Nam : Name_Id;
1671          Num : Int) return Node_Id;
1672       --  This builds the attribute reference Arr'Nam (Expr)
1673
1674       function Component_Equality (Typ : Entity_Id) return Node_Id;
1675       --  Create one statement to compare corresponding components, designated
1676       --  by a full set of indexes.
1677
1678       function Get_Arg_Type (N : Node_Id) return Entity_Id;
1679       --  Given one of the arguments, computes the appropriate type to be used
1680       --  for that argument in the corresponding function formal
1681
1682       function Handle_One_Dimension
1683         (N     : Int;
1684          Index : Node_Id) return Node_Id;
1685       --  This procedure returns the following code
1686       --
1687       --    declare
1688       --       Bn : Index_T := B'First (N);
1689       --    begin
1690       --       loop
1691       --          xxx
1692       --          exit when An = A'Last (N);
1693       --          An := Index_T'Succ (An)
1694       --          Bn := Index_T'Succ (Bn)
1695       --       end loop;
1696       --    end;
1697       --
1698       --  If both indexes are constrained and identical, the procedure
1699       --  returns a simpler loop:
1700       --
1701       --      for An in A'Range (N) loop
1702       --         xxx
1703       --      end loop
1704       --
1705       --  N is the dimension for which we are generating a loop. Index is the
1706       --  N'th index node, whose Etype is Index_Type_n in the above code. The
1707       --  xxx statement is either the loop or declare for the next dimension
1708       --  or if this is the last dimension the comparison of corresponding
1709       --  components of the arrays.
1710       --
1711       --  The actual way the code works is to return the comparison of
1712       --  corresponding components for the N+1 call. That's neater!
1713
1714       function Test_Empty_Arrays return Node_Id;
1715       --  This function constructs the test for both arrays being empty
1716       --    (A'length (1) = 0 or else A'length (2) = 0 or else ...)
1717       --      and then
1718       --    (B'length (1) = 0 or else B'length (2) = 0 or else ...)
1719
1720       function Test_Lengths_Correspond return Node_Id;
1721       --  This function constructs the test for arrays having different lengths
1722       --  in at least one index position, in which case the resulting code is:
1723
1724       --     A'length (1) /= B'length (1)
1725       --       or else
1726       --     A'length (2) /= B'length (2)
1727       --       or else
1728       --       ...
1729
1730       --------------
1731       -- Arr_Attr --
1732       --------------
1733
1734       function Arr_Attr
1735         (Arr : Entity_Id;
1736          Nam : Name_Id;
1737          Num : Int) return Node_Id
1738       is
1739       begin
1740          return
1741            Make_Attribute_Reference (Loc,
1742             Attribute_Name => Nam,
1743             Prefix => New_Reference_To (Arr, Loc),
1744             Expressions => New_List (Make_Integer_Literal (Loc, Num)));
1745       end Arr_Attr;
1746
1747       ------------------------
1748       -- Component_Equality --
1749       ------------------------
1750
1751       function Component_Equality (Typ : Entity_Id) return Node_Id is
1752          Test : Node_Id;
1753          L, R : Node_Id;
1754
1755       begin
1756          --  if a(i1...) /= b(j1...) then return false; end if;
1757
1758          L :=
1759            Make_Indexed_Component (Loc,
1760              Prefix      => Make_Identifier (Loc, Chars (A)),
1761              Expressions => Index_List1);
1762
1763          R :=
1764            Make_Indexed_Component (Loc,
1765              Prefix      => Make_Identifier (Loc, Chars (B)),
1766              Expressions => Index_List2);
1767
1768          Test := Expand_Composite_Equality
1769                    (Nod, Component_Type (Typ), L, R, Decls);
1770
1771          --  If some (sub)component is an unchecked_union, the whole operation
1772          --  will raise program error.
1773
1774          if Nkind (Test) = N_Raise_Program_Error then
1775
1776             --  This node is going to be inserted at a location where a
1777             --  statement is expected: clear its Etype so analysis will set
1778             --  it to the expected Standard_Void_Type.
1779
1780             Set_Etype (Test, Empty);
1781             return Test;
1782
1783          else
1784             return
1785               Make_Implicit_If_Statement (Nod,
1786                 Condition => Make_Op_Not (Loc, Right_Opnd => Test),
1787                 Then_Statements => New_List (
1788                   Make_Simple_Return_Statement (Loc,
1789                     Expression => New_Occurrence_Of (Standard_False, Loc))));
1790          end if;
1791       end Component_Equality;
1792
1793       ------------------
1794       -- Get_Arg_Type --
1795       ------------------
1796
1797       function Get_Arg_Type (N : Node_Id) return Entity_Id is
1798          T : Entity_Id;
1799          X : Node_Id;
1800
1801       begin
1802          T := Etype (N);
1803
1804          if No (T) then
1805             return Typ;
1806
1807          else
1808             T := Underlying_Type (T);
1809
1810             X := First_Index (T);
1811             while Present (X) loop
1812                if Denotes_Discriminant (Type_Low_Bound (Etype (X)))
1813                  or else
1814                    Denotes_Discriminant (Type_High_Bound (Etype (X)))
1815                then
1816                   T := Base_Type (T);
1817                   exit;
1818                end if;
1819
1820                Next_Index (X);
1821             end loop;
1822
1823             return T;
1824          end if;
1825       end Get_Arg_Type;
1826
1827       --------------------------
1828       -- Handle_One_Dimension --
1829       ---------------------------
1830
1831       function Handle_One_Dimension
1832         (N     : Int;
1833          Index : Node_Id) return Node_Id
1834       is
1835          Need_Separate_Indexes : constant Boolean :=
1836                                    Ltyp /= Rtyp
1837                                      or else not Is_Constrained (Ltyp);
1838          --  If the index types are identical, and we are working with
1839          --  constrained types, then we can use the same index for both
1840          --  of the arrays.
1841
1842          An : constant Entity_Id := Make_Temporary (Loc, 'A');
1843
1844          Bn       : Entity_Id;
1845          Index_T  : Entity_Id;
1846          Stm_List : List_Id;
1847          Loop_Stm : Node_Id;
1848
1849       begin
1850          if N > Number_Dimensions (Ltyp) then
1851             return Component_Equality (Ltyp);
1852          end if;
1853
1854          --  Case where we generate a loop
1855
1856          Index_T := Base_Type (Etype (Index));
1857
1858          if Need_Separate_Indexes then
1859             Bn := Make_Temporary (Loc, 'B');
1860          else
1861             Bn := An;
1862          end if;
1863
1864          Append (New_Reference_To (An, Loc), Index_List1);
1865          Append (New_Reference_To (Bn, Loc), Index_List2);
1866
1867          Stm_List := New_List (
1868            Handle_One_Dimension (N + 1, Next_Index (Index)));
1869
1870          if Need_Separate_Indexes then
1871
1872             --  Generate guard for loop, followed by increments of indexes
1873
1874             Append_To (Stm_List,
1875                Make_Exit_Statement (Loc,
1876                  Condition =>
1877                    Make_Op_Eq (Loc,
1878                       Left_Opnd => New_Reference_To (An, Loc),
1879                       Right_Opnd => Arr_Attr (A, Name_Last, N))));
1880
1881             Append_To (Stm_List,
1882               Make_Assignment_Statement (Loc,
1883                 Name       => New_Reference_To (An, Loc),
1884                 Expression =>
1885                   Make_Attribute_Reference (Loc,
1886                     Prefix         => New_Reference_To (Index_T, Loc),
1887                     Attribute_Name => Name_Succ,
1888                     Expressions    => New_List (New_Reference_To (An, Loc)))));
1889
1890             Append_To (Stm_List,
1891               Make_Assignment_Statement (Loc,
1892                 Name       => New_Reference_To (Bn, Loc),
1893                 Expression =>
1894                   Make_Attribute_Reference (Loc,
1895                     Prefix         => New_Reference_To (Index_T, Loc),
1896                     Attribute_Name => Name_Succ,
1897                     Expressions    => New_List (New_Reference_To (Bn, Loc)))));
1898          end if;
1899
1900          --  If separate indexes, we need a declare block for An and Bn, and a
1901          --  loop without an iteration scheme.
1902
1903          if Need_Separate_Indexes then
1904             Loop_Stm :=
1905               Make_Implicit_Loop_Statement (Nod, Statements => Stm_List);
1906
1907             return
1908               Make_Block_Statement (Loc,
1909                 Declarations => New_List (
1910                   Make_Object_Declaration (Loc,
1911                     Defining_Identifier => An,
1912                     Object_Definition   => New_Reference_To (Index_T, Loc),
1913                     Expression          => Arr_Attr (A, Name_First, N)),
1914
1915                   Make_Object_Declaration (Loc,
1916                     Defining_Identifier => Bn,
1917                     Object_Definition   => New_Reference_To (Index_T, Loc),
1918                     Expression          => Arr_Attr (B, Name_First, N))),
1919
1920                 Handled_Statement_Sequence =>
1921                   Make_Handled_Sequence_Of_Statements (Loc,
1922                     Statements => New_List (Loop_Stm)));
1923
1924          --  If no separate indexes, return loop statement with explicit
1925          --  iteration scheme on its own
1926
1927          else
1928             Loop_Stm :=
1929               Make_Implicit_Loop_Statement (Nod,
1930                 Statements       => Stm_List,
1931                 Iteration_Scheme =>
1932                   Make_Iteration_Scheme (Loc,
1933                     Loop_Parameter_Specification =>
1934                       Make_Loop_Parameter_Specification (Loc,
1935                         Defining_Identifier         => An,
1936                         Discrete_Subtype_Definition =>
1937                           Arr_Attr (A, Name_Range, N))));
1938             return Loop_Stm;
1939          end if;
1940       end Handle_One_Dimension;
1941
1942       -----------------------
1943       -- Test_Empty_Arrays --
1944       -----------------------
1945
1946       function Test_Empty_Arrays return Node_Id is
1947          Alist : Node_Id;
1948          Blist : Node_Id;
1949
1950          Atest : Node_Id;
1951          Btest : Node_Id;
1952
1953       begin
1954          Alist := Empty;
1955          Blist := Empty;
1956          for J in 1 .. Number_Dimensions (Ltyp) loop
1957             Atest :=
1958               Make_Op_Eq (Loc,
1959                 Left_Opnd  => Arr_Attr (A, Name_Length, J),
1960                 Right_Opnd => Make_Integer_Literal (Loc, 0));
1961
1962             Btest :=
1963               Make_Op_Eq (Loc,
1964                 Left_Opnd  => Arr_Attr (B, Name_Length, J),
1965                 Right_Opnd => Make_Integer_Literal (Loc, 0));
1966
1967             if No (Alist) then
1968                Alist := Atest;
1969                Blist := Btest;
1970
1971             else
1972                Alist :=
1973                  Make_Or_Else (Loc,
1974                    Left_Opnd  => Relocate_Node (Alist),
1975                    Right_Opnd => Atest);
1976
1977                Blist :=
1978                  Make_Or_Else (Loc,
1979                    Left_Opnd  => Relocate_Node (Blist),
1980                    Right_Opnd => Btest);
1981             end if;
1982          end loop;
1983
1984          return
1985            Make_And_Then (Loc,
1986              Left_Opnd  => Alist,
1987              Right_Opnd => Blist);
1988       end Test_Empty_Arrays;
1989
1990       -----------------------------
1991       -- Test_Lengths_Correspond --
1992       -----------------------------
1993
1994       function Test_Lengths_Correspond return Node_Id is
1995          Result : Node_Id;
1996          Rtest  : Node_Id;
1997
1998       begin
1999          Result := Empty;
2000          for J in 1 .. Number_Dimensions (Ltyp) loop
2001             Rtest :=
2002               Make_Op_Ne (Loc,
2003                 Left_Opnd  => Arr_Attr (A, Name_Length, J),
2004                 Right_Opnd => Arr_Attr (B, Name_Length, J));
2005
2006             if No (Result) then
2007                Result := Rtest;
2008             else
2009                Result :=
2010                  Make_Or_Else (Loc,
2011                    Left_Opnd  => Relocate_Node (Result),
2012                    Right_Opnd => Rtest);
2013             end if;
2014          end loop;
2015
2016          return Result;
2017       end Test_Lengths_Correspond;
2018
2019    --  Start of processing for Expand_Array_Equality
2020
2021    begin
2022       Ltyp := Get_Arg_Type (Lhs);
2023       Rtyp := Get_Arg_Type (Rhs);
2024
2025       --  For now, if the argument types are not the same, go to the base type,
2026       --  since the code assumes that the formals have the same type. This is
2027       --  fixable in future ???
2028
2029       if Ltyp /= Rtyp then
2030          Ltyp := Base_Type (Ltyp);
2031          Rtyp := Base_Type (Rtyp);
2032          pragma Assert (Ltyp = Rtyp);
2033       end if;
2034
2035       --  Build list of formals for function
2036
2037       Formals := New_List (
2038         Make_Parameter_Specification (Loc,
2039           Defining_Identifier => A,
2040           Parameter_Type      => New_Reference_To (Ltyp, Loc)),
2041
2042         Make_Parameter_Specification (Loc,
2043           Defining_Identifier => B,
2044           Parameter_Type      => New_Reference_To (Rtyp, Loc)));
2045
2046       Func_Name := Make_Temporary (Loc, 'E');
2047
2048       --  Build statement sequence for function
2049
2050       Func_Body :=
2051         Make_Subprogram_Body (Loc,
2052           Specification =>
2053             Make_Function_Specification (Loc,
2054               Defining_Unit_Name       => Func_Name,
2055               Parameter_Specifications => Formals,
2056               Result_Definition => New_Reference_To (Standard_Boolean, Loc)),
2057
2058           Declarations =>  Decls,
2059
2060           Handled_Statement_Sequence =>
2061             Make_Handled_Sequence_Of_Statements (Loc,
2062               Statements => New_List (
2063
2064                 Make_Implicit_If_Statement (Nod,
2065                   Condition => Test_Empty_Arrays,
2066                   Then_Statements => New_List (
2067                     Make_Simple_Return_Statement (Loc,
2068                       Expression =>
2069                         New_Occurrence_Of (Standard_True, Loc)))),
2070
2071                 Make_Implicit_If_Statement (Nod,
2072                   Condition => Test_Lengths_Correspond,
2073                   Then_Statements => New_List (
2074                     Make_Simple_Return_Statement (Loc,
2075                       Expression =>
2076                         New_Occurrence_Of (Standard_False, Loc)))),
2077
2078                 Handle_One_Dimension (1, First_Index (Ltyp)),
2079
2080                 Make_Simple_Return_Statement (Loc,
2081                   Expression => New_Occurrence_Of (Standard_True, Loc)))));
2082
2083          Set_Has_Completion (Func_Name, True);
2084          Set_Is_Inlined (Func_Name);
2085
2086          --  If the array type is distinct from the type of the arguments, it
2087          --  is the full view of a private type. Apply an unchecked conversion
2088          --  to insure that analysis of the call succeeds.
2089
2090          declare
2091             L, R : Node_Id;
2092
2093          begin
2094             L := Lhs;
2095             R := Rhs;
2096
2097             if No (Etype (Lhs))
2098               or else Base_Type (Etype (Lhs)) /= Base_Type (Ltyp)
2099             then
2100                L := OK_Convert_To (Ltyp, Lhs);
2101             end if;
2102
2103             if No (Etype (Rhs))
2104               or else Base_Type (Etype (Rhs)) /= Base_Type (Rtyp)
2105             then
2106                R := OK_Convert_To (Rtyp, Rhs);
2107             end if;
2108
2109             Actuals := New_List (L, R);
2110          end;
2111
2112          Append_To (Bodies, Func_Body);
2113
2114          return
2115            Make_Function_Call (Loc,
2116              Name                   => New_Reference_To (Func_Name, Loc),
2117              Parameter_Associations => Actuals);
2118    end Expand_Array_Equality;
2119
2120    -----------------------------
2121    -- Expand_Boolean_Operator --
2122    -----------------------------
2123
2124    --  Note that we first get the actual subtypes of the operands, since we
2125    --  always want to deal with types that have bounds.
2126
2127    procedure Expand_Boolean_Operator (N : Node_Id) is
2128       Typ : constant Entity_Id  := Etype (N);
2129
2130    begin
2131       --  Special case of bit packed array where both operands are known to be
2132       --  properly aligned. In this case we use an efficient run time routine
2133       --  to carry out the operation (see System.Bit_Ops).
2134
2135       if Is_Bit_Packed_Array (Typ)
2136         and then not Is_Possibly_Unaligned_Object (Left_Opnd (N))
2137         and then not Is_Possibly_Unaligned_Object (Right_Opnd (N))
2138       then
2139          Expand_Packed_Boolean_Operator (N);
2140          return;
2141       end if;
2142
2143       --  For the normal non-packed case, the general expansion is to build
2144       --  function for carrying out the comparison (use Make_Boolean_Array_Op)
2145       --  and then inserting it into the tree. The original operator node is
2146       --  then rewritten as a call to this function. We also use this in the
2147       --  packed case if either operand is a possibly unaligned object.
2148
2149       declare
2150          Loc       : constant Source_Ptr := Sloc (N);
2151          L         : constant Node_Id    := Relocate_Node (Left_Opnd  (N));
2152          R         : constant Node_Id    := Relocate_Node (Right_Opnd (N));
2153          Func_Body : Node_Id;
2154          Func_Name : Entity_Id;
2155
2156       begin
2157          Convert_To_Actual_Subtype (L);
2158          Convert_To_Actual_Subtype (R);
2159          Ensure_Defined (Etype (L), N);
2160          Ensure_Defined (Etype (R), N);
2161          Apply_Length_Check (R, Etype (L));
2162
2163          if Nkind (N) = N_Op_Xor then
2164             Silly_Boolean_Array_Xor_Test (N, Etype (L));
2165          end if;
2166
2167          if Nkind (Parent (N)) = N_Assignment_Statement
2168            and then Safe_In_Place_Array_Op (Name (Parent (N)), L, R)
2169          then
2170             Build_Boolean_Array_Proc_Call (Parent (N), L, R);
2171
2172          elsif Nkind (Parent (N)) = N_Op_Not
2173            and then Nkind (N) = N_Op_And
2174            and then
2175              Safe_In_Place_Array_Op (Name (Parent (Parent (N))), L, R)
2176          then
2177             return;
2178          else
2179
2180             Func_Body := Make_Boolean_Array_Op (Etype (L), N);
2181             Func_Name := Defining_Unit_Name (Specification (Func_Body));
2182             Insert_Action (N, Func_Body);
2183
2184             --  Now rewrite the expression with a call
2185
2186             Rewrite (N,
2187               Make_Function_Call (Loc,
2188                 Name                   => New_Reference_To (Func_Name, Loc),
2189                 Parameter_Associations =>
2190                   New_List (
2191                     L,
2192                     Make_Type_Conversion
2193                       (Loc, New_Reference_To (Etype (L), Loc), R))));
2194
2195             Analyze_And_Resolve (N, Typ);
2196          end if;
2197       end;
2198    end Expand_Boolean_Operator;
2199
2200    -------------------------------
2201    -- Expand_Composite_Equality --
2202    -------------------------------
2203
2204    --  This function is only called for comparing internal fields of composite
2205    --  types when these fields are themselves composites. This is a special
2206    --  case because it is not possible to respect normal Ada visibility rules.
2207
2208    function Expand_Composite_Equality
2209      (Nod    : Node_Id;
2210       Typ    : Entity_Id;
2211       Lhs    : Node_Id;
2212       Rhs    : Node_Id;
2213       Bodies : List_Id) return Node_Id
2214    is
2215       Loc       : constant Source_Ptr := Sloc (Nod);
2216       Full_Type : Entity_Id;
2217       Prim      : Elmt_Id;
2218       Eq_Op     : Entity_Id;
2219
2220       function Find_Primitive_Eq return Node_Id;
2221       --  AI05-0123: Locate primitive equality for type if it exists, and
2222       --  build the corresponding call. If operation is abstract, replace
2223       --  call with an explicit raise. Return Empty if there is no primitive.
2224
2225       -----------------------
2226       -- Find_Primitive_Eq --
2227       -----------------------
2228
2229       function Find_Primitive_Eq return Node_Id is
2230          Prim_E : Elmt_Id;
2231          Prim   : Node_Id;
2232
2233       begin
2234          Prim_E := First_Elmt (Collect_Primitive_Operations (Typ));
2235          while Present (Prim_E) loop
2236             Prim := Node (Prim_E);
2237
2238             --  Locate primitive equality with the right signature
2239
2240             if Chars (Prim) = Name_Op_Eq
2241               and then Etype (First_Formal (Prim)) =
2242                        Etype (Next_Formal (First_Formal (Prim)))
2243               and then Etype (Prim) = Standard_Boolean
2244             then
2245                if Is_Abstract_Subprogram (Prim) then
2246                   return
2247                     Make_Raise_Program_Error (Loc,
2248                       Reason => PE_Explicit_Raise);
2249
2250                else
2251                   return
2252                     Make_Function_Call (Loc,
2253                       Name                   => New_Reference_To (Prim, Loc),
2254                       Parameter_Associations => New_List (Lhs, Rhs));
2255                end if;
2256             end if;
2257
2258             Next_Elmt (Prim_E);
2259          end loop;
2260
2261          --  If not found, predefined operation will be used
2262
2263          return Empty;
2264       end Find_Primitive_Eq;
2265
2266    --  Start of processing for Expand_Composite_Equality
2267
2268    begin
2269       if Is_Private_Type (Typ) then
2270          Full_Type := Underlying_Type (Typ);
2271       else
2272          Full_Type := Typ;
2273       end if;
2274
2275       --  Defense against malformed private types with no completion the error
2276       --  will be diagnosed later by check_completion
2277
2278       if No (Full_Type) then
2279          return New_Reference_To (Standard_False, Loc);
2280       end if;
2281
2282       Full_Type := Base_Type (Full_Type);
2283
2284       if Is_Array_Type (Full_Type) then
2285
2286          --  If the operand is an elementary type other than a floating-point
2287          --  type, then we can simply use the built-in block bitwise equality,
2288          --  since the predefined equality operators always apply and bitwise
2289          --  equality is fine for all these cases.
2290
2291          if Is_Elementary_Type (Component_Type (Full_Type))
2292            and then not Is_Floating_Point_Type (Component_Type (Full_Type))
2293          then
2294             return Make_Op_Eq (Loc, Left_Opnd => Lhs, Right_Opnd => Rhs);
2295
2296          --  For composite component types, and floating-point types, use the
2297          --  expansion. This deals with tagged component types (where we use
2298          --  the applicable equality routine) and floating-point, (where we
2299          --  need to worry about negative zeroes), and also the case of any
2300          --  composite type recursively containing such fields.
2301
2302          else
2303             return Expand_Array_Equality (Nod, Lhs, Rhs, Bodies, Full_Type);
2304          end if;
2305
2306       elsif Is_Tagged_Type (Full_Type) then
2307
2308          --  Call the primitive operation "=" of this type
2309
2310          if Is_Class_Wide_Type (Full_Type) then
2311             Full_Type := Root_Type (Full_Type);
2312          end if;
2313
2314          --  If this is derived from an untagged private type completed with a
2315          --  tagged type, it does not have a full view, so we use the primitive
2316          --  operations of the private type. This check should no longer be
2317          --  necessary when these types receive their full views ???
2318
2319          if Is_Private_Type (Typ)
2320            and then not Is_Tagged_Type (Typ)
2321            and then not Is_Controlled (Typ)
2322            and then Is_Derived_Type (Typ)
2323            and then No (Full_View (Typ))
2324          then
2325             Prim := First_Elmt (Collect_Primitive_Operations (Typ));
2326          else
2327             Prim := First_Elmt (Primitive_Operations (Full_Type));
2328          end if;
2329
2330          loop
2331             Eq_Op := Node (Prim);
2332             exit when Chars (Eq_Op) = Name_Op_Eq
2333               and then Etype (First_Formal (Eq_Op)) =
2334                        Etype (Next_Formal (First_Formal (Eq_Op)))
2335               and then Base_Type (Etype (Eq_Op)) = Standard_Boolean;
2336             Next_Elmt (Prim);
2337             pragma Assert (Present (Prim));
2338          end loop;
2339
2340          Eq_Op := Node (Prim);
2341
2342          return
2343            Make_Function_Call (Loc,
2344              Name => New_Reference_To (Eq_Op, Loc),
2345              Parameter_Associations =>
2346                New_List
2347                  (Unchecked_Convert_To (Etype (First_Formal (Eq_Op)), Lhs),
2348                   Unchecked_Convert_To (Etype (First_Formal (Eq_Op)), Rhs)));
2349
2350       elsif Is_Record_Type (Full_Type) then
2351          Eq_Op := TSS (Full_Type, TSS_Composite_Equality);
2352
2353          if Present (Eq_Op) then
2354             if Etype (First_Formal (Eq_Op)) /= Full_Type then
2355
2356                --  Inherited equality from parent type. Convert the actuals to
2357                --  match signature of operation.
2358
2359                declare
2360                   T : constant Entity_Id := Etype (First_Formal (Eq_Op));
2361
2362                begin
2363                   return
2364                     Make_Function_Call (Loc,
2365                       Name                  => New_Reference_To (Eq_Op, Loc),
2366                       Parameter_Associations => New_List (
2367                         OK_Convert_To (T, Lhs),
2368                         OK_Convert_To (T, Rhs)));
2369                end;
2370
2371             else
2372                --  Comparison between Unchecked_Union components
2373
2374                if Is_Unchecked_Union (Full_Type) then
2375                   declare
2376                      Lhs_Type      : Node_Id := Full_Type;
2377                      Rhs_Type      : Node_Id := Full_Type;
2378                      Lhs_Discr_Val : Node_Id;
2379                      Rhs_Discr_Val : Node_Id;
2380
2381                   begin
2382                      --  Lhs subtype
2383
2384                      if Nkind (Lhs) = N_Selected_Component then
2385                         Lhs_Type := Etype (Entity (Selector_Name (Lhs)));
2386                      end if;
2387
2388                      --  Rhs subtype
2389
2390                      if Nkind (Rhs) = N_Selected_Component then
2391                         Rhs_Type := Etype (Entity (Selector_Name (Rhs)));
2392                      end if;
2393
2394                      --  Lhs of the composite equality
2395
2396                      if Is_Constrained (Lhs_Type) then
2397
2398                         --  Since the enclosing record type can never be an
2399                         --  Unchecked_Union (this code is executed for records
2400                         --  that do not have variants), we may reference its
2401                         --  discriminant(s).
2402
2403                         if Nkind (Lhs) = N_Selected_Component
2404                           and then Has_Per_Object_Constraint (
2405                                      Entity (Selector_Name (Lhs)))
2406                         then
2407                            Lhs_Discr_Val :=
2408                              Make_Selected_Component (Loc,
2409                                Prefix        => Prefix (Lhs),
2410                                Selector_Name =>
2411                                  New_Copy
2412                                    (Get_Discriminant_Value
2413                                       (First_Discriminant (Lhs_Type),
2414                                        Lhs_Type,
2415                                        Stored_Constraint (Lhs_Type))));
2416
2417                         else
2418                            Lhs_Discr_Val :=
2419                              New_Copy
2420                                (Get_Discriminant_Value
2421                                   (First_Discriminant (Lhs_Type),
2422                                    Lhs_Type,
2423                                    Stored_Constraint (Lhs_Type)));
2424
2425                         end if;
2426                      else
2427                         --  It is not possible to infer the discriminant since
2428                         --  the subtype is not constrained.
2429
2430                         return
2431                           Make_Raise_Program_Error (Loc,
2432                             Reason => PE_Unchecked_Union_Restriction);
2433                      end if;
2434
2435                      --  Rhs of the composite equality
2436
2437                      if Is_Constrained (Rhs_Type) then
2438                         if Nkind (Rhs) = N_Selected_Component
2439                           and then Has_Per_Object_Constraint
2440                                      (Entity (Selector_Name (Rhs)))
2441                         then
2442                            Rhs_Discr_Val :=
2443                              Make_Selected_Component (Loc,
2444                                Prefix        => Prefix (Rhs),
2445                                Selector_Name =>
2446                                  New_Copy
2447                                    (Get_Discriminant_Value
2448                                       (First_Discriminant (Rhs_Type),
2449                                        Rhs_Type,
2450                                        Stored_Constraint (Rhs_Type))));
2451
2452                         else
2453                            Rhs_Discr_Val :=
2454                              New_Copy
2455                                (Get_Discriminant_Value
2456                                   (First_Discriminant (Rhs_Type),
2457                                    Rhs_Type,
2458                                    Stored_Constraint (Rhs_Type)));
2459
2460                         end if;
2461                      else
2462                         return
2463                           Make_Raise_Program_Error (Loc,
2464                             Reason => PE_Unchecked_Union_Restriction);
2465                      end if;
2466
2467                      --  Call the TSS equality function with the inferred
2468                      --  discriminant values.
2469
2470                      return
2471                        Make_Function_Call (Loc,
2472                          Name => New_Reference_To (Eq_Op, Loc),
2473                          Parameter_Associations => New_List (
2474                            Lhs,
2475                            Rhs,
2476                            Lhs_Discr_Val,
2477                            Rhs_Discr_Val));
2478                   end;
2479
2480                else
2481                   return
2482                     Make_Function_Call (Loc,
2483                       Name                   => New_Reference_To (Eq_Op, Loc),
2484                       Parameter_Associations => New_List (Lhs, Rhs));
2485                end if;
2486             end if;
2487
2488          elsif Ada_Version >= Ada_2012 then
2489
2490             --  if no TSS has been created for the type, check whether there is
2491             --  a primitive equality declared for it.
2492
2493             declare
2494                Ada_2012_Op : constant Node_Id := Find_Primitive_Eq;
2495
2496             begin
2497                if Present (Ada_2012_Op) then
2498                   return Ada_2012_Op;
2499                else
2500
2501                --  Use predefined equality if no user-defined primitive exists
2502
2503                   return Make_Op_Eq (Loc, Lhs, Rhs);
2504                end if;
2505             end;
2506
2507          else
2508             return Expand_Record_Equality (Nod, Full_Type, Lhs, Rhs, Bodies);
2509          end if;
2510
2511       else
2512          --  If not array or record type, it is predefined equality.
2513
2514          return Make_Op_Eq (Loc, Left_Opnd => Lhs, Right_Opnd => Rhs);
2515       end if;
2516    end Expand_Composite_Equality;
2517
2518    ------------------------
2519    -- Expand_Concatenate --
2520    ------------------------
2521
2522    procedure Expand_Concatenate (Cnode : Node_Id; Opnds : List_Id) is
2523       Loc : constant Source_Ptr := Sloc (Cnode);
2524
2525       Atyp : constant Entity_Id := Base_Type (Etype (Cnode));
2526       --  Result type of concatenation
2527
2528       Ctyp : constant Entity_Id := Base_Type (Component_Type (Etype (Cnode)));
2529       --  Component type. Elements of this component type can appear as one
2530       --  of the operands of concatenation as well as arrays.
2531
2532       Istyp : constant Entity_Id := Etype (First_Index (Atyp));
2533       --  Index subtype
2534
2535       Ityp : constant Entity_Id := Base_Type (Istyp);
2536       --  Index type. This is the base type of the index subtype, and is used
2537       --  for all computed bounds (which may be out of range of Istyp in the
2538       --  case of null ranges).
2539
2540       Artyp : Entity_Id;
2541       --  This is the type we use to do arithmetic to compute the bounds and
2542       --  lengths of operands. The choice of this type is a little subtle and
2543       --  is discussed in a separate section at the start of the body code.
2544
2545       Concatenation_Error : exception;
2546       --  Raised if concatenation is sure to raise a CE
2547
2548       Result_May_Be_Null : Boolean := True;
2549       --  Reset to False if at least one operand is encountered which is known
2550       --  at compile time to be non-null. Used for handling the special case
2551       --  of setting the high bound to the last operand high bound for a null
2552       --  result, thus ensuring a proper high bound in the super-flat case.
2553
2554       N : constant Nat := List_Length (Opnds);
2555       --  Number of concatenation operands including possibly null operands
2556
2557       NN : Nat := 0;
2558       --  Number of operands excluding any known to be null, except that the
2559       --  last operand is always retained, in case it provides the bounds for
2560       --  a null result.
2561
2562       Opnd : Node_Id;
2563       --  Current operand being processed in the loop through operands. After
2564       --  this loop is complete, always contains the last operand (which is not
2565       --  the same as Operands (NN), since null operands are skipped).
2566
2567       --  Arrays describing the operands, only the first NN entries of each
2568       --  array are set (NN < N when we exclude known null operands).
2569
2570       Is_Fixed_Length : array (1 .. N) of Boolean;
2571       --  True if length of corresponding operand known at compile time
2572
2573       Operands : array (1 .. N) of Node_Id;
2574       --  Set to the corresponding entry in the Opnds list (but note that null
2575       --  operands are excluded, so not all entries in the list are stored).
2576
2577       Fixed_Length : array (1 .. N) of Uint;
2578       --  Set to length of operand. Entries in this array are set only if the
2579       --  corresponding entry in Is_Fixed_Length is True.
2580
2581       Opnd_Low_Bound : array (1 .. N) of Node_Id;
2582       --  Set to lower bound of operand. Either an integer literal in the case
2583       --  where the bound is known at compile time, else actual lower bound.
2584       --  The operand low bound is of type Ityp.
2585
2586       Var_Length : array (1 .. N) of Entity_Id;
2587       --  Set to an entity of type Natural that contains the length of an
2588       --  operand whose length is not known at compile time. Entries in this
2589       --  array are set only if the corresponding entry in Is_Fixed_Length
2590       --  is False. The entity is of type Artyp.
2591
2592       Aggr_Length : array (0 .. N) of Node_Id;
2593       --  The J'th entry in an expression node that represents the total length
2594       --  of operands 1 through J. It is either an integer literal node, or a
2595       --  reference to a constant entity with the right value, so it is fine
2596       --  to just do a Copy_Node to get an appropriate copy. The extra zero'th
2597       --  entry always is set to zero. The length is of type Artyp.
2598
2599       Low_Bound : Node_Id;
2600       --  A tree node representing the low bound of the result (of type Ityp).
2601       --  This is either an integer literal node, or an identifier reference to
2602       --  a constant entity initialized to the appropriate value.
2603
2604       Last_Opnd_Low_Bound : Node_Id;
2605       --  A tree node representing the low bound of the last operand. This
2606       --  need only be set if the result could be null. It is used for the
2607       --  special case of setting the right low bound for a null result.
2608       --  This is of type Ityp.
2609
2610       Last_Opnd_High_Bound : Node_Id;
2611       --  A tree node representing the high bound of the last operand. This
2612       --  need only be set if the result could be null. It is used for the
2613       --  special case of setting the right high bound for a null result.
2614       --  This is of type Ityp.
2615
2616       High_Bound : Node_Id;
2617       --  A tree node representing the high bound of the result (of type Ityp)
2618
2619       Result : Node_Id;
2620       --  Result of the concatenation (of type Ityp)
2621
2622       Actions : constant List_Id := New_List;
2623       --  Collect actions to be inserted
2624
2625       Known_Non_Null_Operand_Seen : Boolean;
2626       --  Set True during generation of the assignments of operands into
2627       --  result once an operand known to be non-null has been seen.
2628
2629       function Make_Artyp_Literal (Val : Nat) return Node_Id;
2630       --  This function makes an N_Integer_Literal node that is returned in
2631       --  analyzed form with the type set to Artyp. Importantly this literal
2632       --  is not flagged as static, so that if we do computations with it that
2633       --  result in statically detected out of range conditions, we will not
2634       --  generate error messages but instead warning messages.
2635
2636       function To_Artyp (X : Node_Id) return Node_Id;
2637       --  Given a node of type Ityp, returns the corresponding value of type
2638       --  Artyp. For non-enumeration types, this is a plain integer conversion.
2639       --  For enum types, the Pos of the value is returned.
2640
2641       function To_Ityp (X : Node_Id) return Node_Id;
2642       --  The inverse function (uses Val in the case of enumeration types)
2643
2644       ------------------------
2645       -- Make_Artyp_Literal --
2646       ------------------------
2647
2648       function Make_Artyp_Literal (Val : Nat) return Node_Id is
2649          Result : constant Node_Id := Make_Integer_Literal (Loc, Val);
2650       begin
2651          Set_Etype (Result, Artyp);
2652          Set_Analyzed (Result, True);
2653          Set_Is_Static_Expression (Result, False);
2654          return Result;
2655       end Make_Artyp_Literal;
2656
2657       --------------
2658       -- To_Artyp --
2659       --------------
2660
2661       function To_Artyp (X : Node_Id) return Node_Id is
2662       begin
2663          if Ityp = Base_Type (Artyp) then
2664             return X;
2665
2666          elsif Is_Enumeration_Type (Ityp) then
2667             return
2668               Make_Attribute_Reference (Loc,
2669                 Prefix         => New_Occurrence_Of (Ityp, Loc),
2670                 Attribute_Name => Name_Pos,
2671                 Expressions    => New_List (X));
2672
2673          else
2674             return Convert_To (Artyp, X);
2675          end if;
2676       end To_Artyp;
2677
2678       -------------
2679       -- To_Ityp --
2680       -------------
2681
2682       function To_Ityp (X : Node_Id) return Node_Id is
2683       begin
2684          if Is_Enumeration_Type (Ityp) then
2685             return
2686               Make_Attribute_Reference (Loc,
2687                 Prefix         => New_Occurrence_Of (Ityp, Loc),
2688                 Attribute_Name => Name_Val,
2689                 Expressions    => New_List (X));
2690
2691          --  Case where we will do a type conversion
2692
2693          else
2694             if Ityp = Base_Type (Artyp) then
2695                return X;
2696             else
2697                return Convert_To (Ityp, X);
2698             end if;
2699          end if;
2700       end To_Ityp;
2701
2702       --  Local Declarations
2703
2704       Opnd_Typ : Entity_Id;
2705       Ent      : Entity_Id;
2706       Len      : Uint;
2707       J        : Nat;
2708       Clen     : Node_Id;
2709       Set      : Boolean;
2710
2711    --  Start of processing for Expand_Concatenate
2712
2713    begin
2714       --  Choose an appropriate computational type
2715
2716       --  We will be doing calculations of lengths and bounds in this routine
2717       --  and computing one from the other in some cases, e.g. getting the high
2718       --  bound by adding the length-1 to the low bound.
2719
2720       --  We can't just use the index type, or even its base type for this
2721       --  purpose for two reasons. First it might be an enumeration type which
2722       --  is not suitable for computations of any kind, and second it may
2723       --  simply not have enough range. For example if the index type is
2724       --  -128..+127 then lengths can be up to 256, which is out of range of
2725       --  the type.
2726
2727       --  For enumeration types, we can simply use Standard_Integer, this is
2728       --  sufficient since the actual number of enumeration literals cannot
2729       --  possibly exceed the range of integer (remember we will be doing the
2730       --  arithmetic with POS values, not representation values).
2731
2732       if Is_Enumeration_Type (Ityp) then
2733          Artyp := Standard_Integer;
2734
2735       --  If index type is Positive, we use the standard unsigned type, to give
2736       --  more room on the top of the range, obviating the need for an overflow
2737       --  check when creating the upper bound. This is needed to avoid junk
2738       --  overflow checks in the common case of String types.
2739
2740       --  ??? Disabled for now
2741
2742       --  elsif Istyp = Standard_Positive then
2743       --     Artyp := Standard_Unsigned;
2744
2745       --  For modular types, we use a 32-bit modular type for types whose size
2746       --  is in the range 1-31 bits. For 32-bit unsigned types, we use the
2747       --  identity type, and for larger unsigned types we use 64-bits.
2748
2749       elsif Is_Modular_Integer_Type (Ityp) then
2750          if RM_Size (Ityp) < RM_Size (Standard_Unsigned) then
2751             Artyp := Standard_Unsigned;
2752          elsif RM_Size (Ityp) = RM_Size (Standard_Unsigned) then
2753             Artyp := Ityp;
2754          else
2755             Artyp := RTE (RE_Long_Long_Unsigned);
2756          end if;
2757
2758       --  Similar treatment for signed types
2759
2760       else
2761          if RM_Size (Ityp) < RM_Size (Standard_Integer) then
2762             Artyp := Standard_Integer;
2763          elsif RM_Size (Ityp) = RM_Size (Standard_Integer) then
2764             Artyp := Ityp;
2765          else
2766             Artyp := Standard_Long_Long_Integer;
2767          end if;
2768       end if;
2769
2770       --  Supply dummy entry at start of length array
2771
2772       Aggr_Length (0) := Make_Artyp_Literal (0);
2773
2774       --  Go through operands setting up the above arrays
2775
2776       J := 1;
2777       while J <= N loop
2778          Opnd := Remove_Head (Opnds);
2779          Opnd_Typ := Etype (Opnd);
2780
2781          --  The parent got messed up when we put the operands in a list,
2782          --  so now put back the proper parent for the saved operand, that
2783          --  is to say the concatenation node, to make sure that each operand
2784          --  is seen as a subexpression, e.g. if actions must be inserted.
2785
2786          Set_Parent (Opnd, Cnode);
2787
2788          --  Set will be True when we have setup one entry in the array
2789
2790          Set := False;
2791
2792          --  Singleton element (or character literal) case
2793
2794          if Base_Type (Opnd_Typ) = Ctyp then
2795             NN := NN + 1;
2796             Operands (NN) := Opnd;
2797             Is_Fixed_Length (NN) := True;
2798             Fixed_Length (NN) := Uint_1;
2799             Result_May_Be_Null := False;
2800
2801             --  Set low bound of operand (no need to set Last_Opnd_High_Bound
2802             --  since we know that the result cannot be null).
2803
2804             Opnd_Low_Bound (NN) :=
2805               Make_Attribute_Reference (Loc,
2806                 Prefix         => New_Reference_To (Istyp, Loc),
2807                 Attribute_Name => Name_First);
2808
2809             Set := True;
2810
2811          --  String literal case (can only occur for strings of course)
2812
2813          elsif Nkind (Opnd) = N_String_Literal then
2814             Len := String_Literal_Length (Opnd_Typ);
2815
2816             if Len /= 0 then
2817                Result_May_Be_Null := False;
2818             end if;
2819
2820             --  Capture last operand low and high bound if result could be null
2821
2822             if J = N and then Result_May_Be_Null then
2823                Last_Opnd_Low_Bound :=
2824                  New_Copy_Tree (String_Literal_Low_Bound (Opnd_Typ));
2825
2826                Last_Opnd_High_Bound :=
2827                  Make_Op_Subtract (Loc,
2828                    Left_Opnd  =>
2829                      New_Copy_Tree (String_Literal_Low_Bound (Opnd_Typ)),
2830                    Right_Opnd => Make_Integer_Literal (Loc, 1));
2831             end if;
2832
2833             --  Skip null string literal
2834
2835             if J < N and then Len = 0 then
2836                goto Continue;
2837             end if;
2838
2839             NN := NN + 1;
2840             Operands (NN) := Opnd;
2841             Is_Fixed_Length (NN) := True;
2842
2843             --  Set length and bounds
2844
2845             Fixed_Length (NN) := Len;
2846
2847             Opnd_Low_Bound (NN) :=
2848               New_Copy_Tree (String_Literal_Low_Bound (Opnd_Typ));
2849
2850             Set := True;
2851
2852          --  All other cases
2853
2854          else
2855             --  Check constrained case with known bounds
2856
2857             if Is_Constrained (Opnd_Typ) then
2858                declare
2859                   Index    : constant Node_Id   := First_Index (Opnd_Typ);
2860                   Indx_Typ : constant Entity_Id := Etype (Index);
2861                   Lo       : constant Node_Id   := Type_Low_Bound  (Indx_Typ);
2862                   Hi       : constant Node_Id   := Type_High_Bound (Indx_Typ);
2863
2864                begin
2865                   --  Fixed length constrained array type with known at compile
2866                   --  time bounds is last case of fixed length operand.
2867
2868                   if Compile_Time_Known_Value (Lo)
2869                        and then
2870                      Compile_Time_Known_Value (Hi)
2871                   then
2872                      declare
2873                         Loval : constant Uint := Expr_Value (Lo);
2874                         Hival : constant Uint := Expr_Value (Hi);
2875                         Len   : constant Uint :=
2876                                   UI_Max (Hival - Loval + 1, Uint_0);
2877
2878                      begin
2879                         if Len > 0 then
2880                            Result_May_Be_Null := False;
2881                         end if;
2882
2883                         --  Capture last operand bounds if result could be null
2884
2885                         if J = N and then Result_May_Be_Null then
2886                            Last_Opnd_Low_Bound :=
2887                              Convert_To (Ityp,
2888                                Make_Integer_Literal (Loc, Expr_Value (Lo)));
2889
2890                            Last_Opnd_High_Bound :=
2891                              Convert_To (Ityp,
2892                                Make_Integer_Literal (Loc, Expr_Value (Hi)));
2893                         end if;
2894
2895                         --  Exclude null length case unless last operand
2896
2897                         if J < N and then Len = 0 then
2898                            goto Continue;
2899                         end if;
2900
2901                         NN := NN + 1;
2902                         Operands (NN) := Opnd;
2903                         Is_Fixed_Length (NN) := True;
2904                         Fixed_Length (NN)    := Len;
2905
2906                         Opnd_Low_Bound (NN) :=
2907                           To_Ityp
2908                             (Make_Integer_Literal (Loc, Expr_Value (Lo)));
2909                         Set := True;
2910                      end;
2911                   end if;
2912                end;
2913             end if;
2914
2915             --  All cases where the length is not known at compile time, or the
2916             --  special case of an operand which is known to be null but has a
2917             --  lower bound other than 1 or is other than a string type.
2918
2919             if not Set then
2920                NN := NN + 1;
2921
2922                --  Capture operand bounds
2923
2924                Opnd_Low_Bound (NN) :=
2925                  Make_Attribute_Reference (Loc,
2926                    Prefix         =>
2927                      Duplicate_Subexpr (Opnd, Name_Req => True),
2928                    Attribute_Name => Name_First);
2929
2930                --  Capture last operand bounds if result could be null
2931
2932                if J = N and Result_May_Be_Null then
2933                   Last_Opnd_Low_Bound :=
2934                     Convert_To (Ityp,
2935                       Make_Attribute_Reference (Loc,
2936                         Prefix         =>
2937                           Duplicate_Subexpr (Opnd, Name_Req => True),
2938                         Attribute_Name => Name_First));
2939
2940                   Last_Opnd_High_Bound :=
2941                     Convert_To (Ityp,
2942                       Make_Attribute_Reference (Loc,
2943                         Prefix         =>
2944                           Duplicate_Subexpr (Opnd, Name_Req => True),
2945                         Attribute_Name => Name_Last));
2946                end if;
2947
2948                --  Capture length of operand in entity
2949
2950                Operands (NN) := Opnd;
2951                Is_Fixed_Length (NN) := False;
2952
2953                Var_Length (NN) := Make_Temporary (Loc, 'L');
2954
2955                Append_To (Actions,
2956                  Make_Object_Declaration (Loc,
2957                    Defining_Identifier => Var_Length (NN),
2958                    Constant_Present    => True,
2959                    Object_Definition   => New_Occurrence_Of (Artyp, Loc),
2960                    Expression          =>
2961                      Make_Attribute_Reference (Loc,
2962                        Prefix         =>
2963                          Duplicate_Subexpr (Opnd, Name_Req => True),
2964                        Attribute_Name => Name_Length)));
2965             end if;
2966          end if;
2967
2968          --  Set next entry in aggregate length array
2969
2970          --  For first entry, make either integer literal for fixed length
2971          --  or a reference to the saved length for variable length.
2972
2973          if NN = 1 then
2974             if Is_Fixed_Length (1) then
2975                Aggr_Length (1) := Make_Integer_Literal (Loc, Fixed_Length (1));
2976             else
2977                Aggr_Length (1) := New_Reference_To (Var_Length (1), Loc);
2978             end if;
2979
2980          --  If entry is fixed length and only fixed lengths so far, make
2981          --  appropriate new integer literal adding new length.
2982
2983          elsif Is_Fixed_Length (NN)
2984            and then Nkind (Aggr_Length (NN - 1)) = N_Integer_Literal
2985          then
2986             Aggr_Length (NN) :=
2987               Make_Integer_Literal (Loc,
2988                 Intval => Fixed_Length (NN) + Intval (Aggr_Length (NN - 1)));
2989
2990          --  All other cases, construct an addition node for the length and
2991          --  create an entity initialized to this length.
2992
2993          else
2994             Ent := Make_Temporary (Loc, 'L');
2995
2996             if Is_Fixed_Length (NN) then
2997                Clen := Make_Integer_Literal (Loc, Fixed_Length (NN));
2998             else
2999                Clen := New_Reference_To (Var_Length (NN), Loc);
3000             end if;
3001
3002             Append_To (Actions,
3003               Make_Object_Declaration (Loc,
3004                 Defining_Identifier => Ent,
3005                 Constant_Present    => True,
3006                 Object_Definition   => New_Occurrence_Of (Artyp, Loc),
3007                 Expression          =>
3008                   Make_Op_Add (Loc,
3009                     Left_Opnd  => New_Copy (Aggr_Length (NN - 1)),
3010                     Right_Opnd => Clen)));
3011
3012             Aggr_Length (NN) := Make_Identifier (Loc, Chars => Chars (Ent));
3013          end if;
3014
3015       <<Continue>>
3016          J := J + 1;
3017       end loop;
3018
3019       --  If we have only skipped null operands, return the last operand
3020
3021       if NN = 0 then
3022          Result := Opnd;
3023          goto Done;
3024       end if;
3025
3026       --  If we have only one non-null operand, return it and we are done.
3027       --  There is one case in which this cannot be done, and that is when
3028       --  the sole operand is of the element type, in which case it must be
3029       --  converted to an array, and the easiest way of doing that is to go
3030       --  through the normal general circuit.
3031
3032       if NN = 1
3033         and then Base_Type (Etype (Operands (1))) /= Ctyp
3034       then
3035          Result := Operands (1);
3036          goto Done;
3037       end if;
3038
3039       --  Cases where we have a real concatenation
3040
3041       --  Next step is to find the low bound for the result array that we
3042       --  will allocate. The rules for this are in (RM 4.5.6(5-7)).
3043
3044       --  If the ultimate ancestor of the index subtype is a constrained array
3045       --  definition, then the lower bound is that of the index subtype as
3046       --  specified by (RM 4.5.3(6)).
3047
3048       --  The right test here is to go to the root type, and then the ultimate
3049       --  ancestor is the first subtype of this root type.
3050
3051       if Is_Constrained (First_Subtype (Root_Type (Atyp))) then
3052          Low_Bound :=
3053            Make_Attribute_Reference (Loc,
3054              Prefix         =>
3055                New_Occurrence_Of (First_Subtype (Root_Type (Atyp)), Loc),
3056              Attribute_Name => Name_First);
3057
3058       --  If the first operand in the list has known length we know that
3059       --  the lower bound of the result is the lower bound of this operand.
3060
3061       elsif Is_Fixed_Length (1) then
3062          Low_Bound := Opnd_Low_Bound (1);
3063
3064       --  OK, we don't know the lower bound, we have to build a horrible
3065       --  expression actions node of the form
3066
3067       --     if Cond1'Length /= 0 then
3068       --        Opnd1 low bound
3069       --     else
3070       --        if Opnd2'Length /= 0 then
3071       --          Opnd2 low bound
3072       --        else
3073       --           ...
3074
3075       --  The nesting ends either when we hit an operand whose length is known
3076       --  at compile time, or on reaching the last operand, whose low bound we
3077       --  take unconditionally whether or not it is null. It's easiest to do
3078       --  this with a recursive procedure:
3079
3080       else
3081          declare
3082             function Get_Known_Bound (J : Nat) return Node_Id;
3083             --  Returns the lower bound determined by operands J .. NN
3084
3085             ---------------------
3086             -- Get_Known_Bound --
3087             ---------------------
3088
3089             function Get_Known_Bound (J : Nat) return Node_Id is
3090             begin
3091                if Is_Fixed_Length (J) or else J = NN then
3092                   return New_Copy (Opnd_Low_Bound (J));
3093
3094                else
3095                   return
3096                     Make_Conditional_Expression (Loc,
3097                       Expressions => New_List (
3098
3099                         Make_Op_Ne (Loc,
3100                           Left_Opnd  => New_Reference_To (Var_Length (J), Loc),
3101                           Right_Opnd => Make_Integer_Literal (Loc, 0)),
3102
3103                         New_Copy (Opnd_Low_Bound (J)),
3104                         Get_Known_Bound (J + 1)));
3105                end if;
3106             end Get_Known_Bound;
3107
3108          begin
3109             Ent := Make_Temporary (Loc, 'L');
3110
3111             Append_To (Actions,
3112               Make_Object_Declaration (Loc,
3113                 Defining_Identifier => Ent,
3114                 Constant_Present    => True,
3115                 Object_Definition   => New_Occurrence_Of (Ityp, Loc),
3116                 Expression          => Get_Known_Bound (1)));
3117
3118             Low_Bound := New_Reference_To (Ent, Loc);
3119          end;
3120       end if;
3121
3122       --  Now we can safely compute the upper bound, normally
3123       --  Low_Bound + Length - 1.
3124
3125       High_Bound :=
3126         To_Ityp (
3127           Make_Op_Add (Loc,
3128             Left_Opnd  => To_Artyp (New_Copy (Low_Bound)),
3129             Right_Opnd =>
3130               Make_Op_Subtract (Loc,
3131                 Left_Opnd  => New_Copy (Aggr_Length (NN)),
3132                 Right_Opnd => Make_Artyp_Literal (1))));
3133
3134       --  Note that calculation of the high bound may cause overflow in some
3135       --  very weird cases, so in the general case we need an overflow check on
3136       --  the high bound. We can avoid this for the common case of string types
3137       --  and other types whose index is Positive, since we chose a wider range
3138       --  for the arithmetic type.
3139
3140       if Istyp /= Standard_Positive then
3141          Activate_Overflow_Check (High_Bound);
3142       end if;
3143
3144       --  Handle the exceptional case where the result is null, in which case
3145       --  case the bounds come from the last operand (so that we get the proper
3146       --  bounds if the last operand is super-flat).
3147
3148       if Result_May_Be_Null then
3149          Low_Bound :=
3150            Make_Conditional_Expression (Loc,
3151              Expressions => New_List (
3152                Make_Op_Eq (Loc,
3153                  Left_Opnd  => New_Copy (Aggr_Length (NN)),
3154                  Right_Opnd => Make_Artyp_Literal (0)),
3155                Last_Opnd_Low_Bound,
3156                Low_Bound));
3157
3158          High_Bound :=
3159            Make_Conditional_Expression (Loc,
3160              Expressions => New_List (
3161                Make_Op_Eq (Loc,
3162                  Left_Opnd  => New_Copy (Aggr_Length (NN)),
3163                  Right_Opnd => Make_Artyp_Literal (0)),
3164                Last_Opnd_High_Bound,
3165                High_Bound));
3166       end if;
3167
3168       --  Here is where we insert the saved up actions
3169
3170       Insert_Actions (Cnode, Actions, Suppress => All_Checks);
3171
3172       --  Now we construct an array object with appropriate bounds. We mark
3173       --  the target as internal to prevent useless initialization when
3174       --  Initialize_Scalars is enabled. Also since this is the actual result
3175       --  entity, we make sure we have debug information for the result.
3176
3177       Ent := Make_Temporary (Loc, 'S');
3178       Set_Is_Internal (Ent);
3179       Set_Needs_Debug_Info (Ent);
3180
3181       --  If the bound is statically known to be out of range, we do not want
3182       --  to abort, we want a warning and a runtime constraint error. Note that
3183       --  we have arranged that the result will not be treated as a static
3184       --  constant, so we won't get an illegality during this insertion.
3185
3186       Insert_Action (Cnode,
3187         Make_Object_Declaration (Loc,
3188           Defining_Identifier => Ent,
3189           Object_Definition   =>
3190             Make_Subtype_Indication (Loc,
3191               Subtype_Mark => New_Occurrence_Of (Atyp, Loc),
3192               Constraint   =>
3193                 Make_Index_Or_Discriminant_Constraint (Loc,
3194                   Constraints => New_List (
3195                     Make_Range (Loc,
3196                       Low_Bound  => Low_Bound,
3197                       High_Bound => High_Bound))))),
3198         Suppress => All_Checks);
3199
3200       --  If the result of the concatenation appears as the initializing
3201       --  expression of an object declaration, we can just rename the
3202       --  result, rather than copying it.
3203
3204       Set_OK_To_Rename (Ent);
3205
3206       --  Catch the static out of range case now
3207
3208       if Raises_Constraint_Error (High_Bound) then
3209          raise Concatenation_Error;
3210       end if;
3211
3212       --  Now we will generate the assignments to do the actual concatenation
3213
3214       --  There is one case in which we will not do this, namely when all the
3215       --  following conditions are met:
3216
3217       --    The result type is Standard.String
3218
3219       --    There are nine or fewer retained (non-null) operands
3220
3221       --    The optimization level is -O0
3222
3223       --    The corresponding System.Concat_n.Str_Concat_n routine is
3224       --    available in the run time.
3225
3226       --    The debug flag gnatd.c is not set
3227
3228       --  If all these conditions are met then we generate a call to the
3229       --  relevant concatenation routine. The purpose of this is to avoid
3230       --  undesirable code bloat at -O0.
3231
3232       if Atyp = Standard_String
3233         and then NN in 2 .. 9
3234         and then (Opt.Optimization_Level = 0 or else Debug_Flag_Dot_CC)
3235         and then not Debug_Flag_Dot_C
3236       then
3237          declare
3238             RR : constant array (Nat range 2 .. 9) of RE_Id :=
3239                    (RE_Str_Concat_2,
3240                     RE_Str_Concat_3,
3241                     RE_Str_Concat_4,
3242                     RE_Str_Concat_5,
3243                     RE_Str_Concat_6,
3244                     RE_Str_Concat_7,
3245                     RE_Str_Concat_8,
3246                     RE_Str_Concat_9);
3247
3248          begin
3249             if RTE_Available (RR (NN)) then
3250                declare
3251                   Opnds : constant List_Id :=
3252                             New_List (New_Occurrence_Of (Ent, Loc));
3253
3254                begin
3255                   for J in 1 .. NN loop
3256                      if Is_List_Member (Operands (J)) then
3257                         Remove (Operands (J));
3258                      end if;
3259
3260                      if Base_Type (Etype (Operands (J))) = Ctyp then
3261                         Append_To (Opnds,
3262                           Make_Aggregate (Loc,
3263                             Component_Associations => New_List (
3264                               Make_Component_Association (Loc,
3265                                 Choices => New_List (
3266                                   Make_Integer_Literal (Loc, 1)),
3267                                 Expression => Operands (J)))));
3268
3269                      else
3270                         Append_To (Opnds, Operands (J));
3271                      end if;
3272                   end loop;
3273
3274                   Insert_Action (Cnode,
3275                     Make_Procedure_Call_Statement (Loc,
3276                       Name => New_Reference_To (RTE (RR (NN)), Loc),
3277                       Parameter_Associations => Opnds));
3278
3279                   Result := New_Reference_To (Ent, Loc);
3280                   goto Done;
3281                end;
3282             end if;
3283          end;
3284       end if;
3285
3286       --  Not special case so generate the assignments
3287
3288       Known_Non_Null_Operand_Seen := False;
3289
3290       for J in 1 .. NN loop
3291          declare
3292             Lo : constant Node_Id :=
3293                    Make_Op_Add (Loc,
3294                      Left_Opnd  => To_Artyp (New_Copy (Low_Bound)),
3295                      Right_Opnd => Aggr_Length (J - 1));
3296
3297             Hi : constant Node_Id :=
3298                    Make_Op_Add (Loc,
3299                      Left_Opnd  => To_Artyp (New_Copy (Low_Bound)),
3300                      Right_Opnd =>
3301                        Make_Op_Subtract (Loc,
3302                          Left_Opnd  => Aggr_Length (J),
3303                          Right_Opnd => Make_Artyp_Literal (1)));
3304
3305          begin
3306             --  Singleton case, simple assignment
3307
3308             if Base_Type (Etype (Operands (J))) = Ctyp then
3309                Known_Non_Null_Operand_Seen := True;
3310                Insert_Action (Cnode,
3311                  Make_Assignment_Statement (Loc,
3312                    Name       =>
3313                      Make_Indexed_Component (Loc,
3314                        Prefix      => New_Occurrence_Of (Ent, Loc),
3315                        Expressions => New_List (To_Ityp (Lo))),
3316                    Expression => Operands (J)),
3317                  Suppress => All_Checks);
3318
3319             --  Array case, slice assignment, skipped when argument is fixed
3320             --  length and known to be null.
3321
3322             elsif (not Is_Fixed_Length (J)) or else (Fixed_Length (J) > 0) then
3323                declare
3324                   Assign : Node_Id :=
3325                              Make_Assignment_Statement (Loc,
3326                                Name       =>
3327                                  Make_Slice (Loc,
3328                                    Prefix         =>
3329                                      New_Occurrence_Of (Ent, Loc),
3330                                    Discrete_Range =>
3331                                      Make_Range (Loc,
3332                                        Low_Bound  => To_Ityp (Lo),
3333                                        High_Bound => To_Ityp (Hi))),
3334                                Expression => Operands (J));
3335                begin
3336                   if Is_Fixed_Length (J) then
3337                      Known_Non_Null_Operand_Seen := True;
3338
3339                   elsif not Known_Non_Null_Operand_Seen then
3340
3341                      --  Here if operand length is not statically known and no
3342                      --  operand known to be non-null has been processed yet.
3343                      --  If operand length is 0, we do not need to perform the
3344                      --  assignment, and we must avoid the evaluation of the
3345                      --  high bound of the slice, since it may underflow if the
3346                      --  low bound is Ityp'First.
3347
3348                      Assign :=
3349                        Make_Implicit_If_Statement (Cnode,
3350                          Condition       =>
3351                            Make_Op_Ne (Loc,
3352                              Left_Opnd  =>
3353                                New_Occurrence_Of (Var_Length (J), Loc),
3354                              Right_Opnd => Make_Integer_Literal (Loc, 0)),
3355                          Then_Statements => New_List (Assign));
3356                   end if;
3357
3358                   Insert_Action (Cnode, Assign, Suppress => All_Checks);
3359                end;
3360             end if;
3361          end;
3362       end loop;
3363
3364       --  Finally we build the result, which is a reference to the array object
3365
3366       Result := New_Reference_To (Ent, Loc);
3367
3368    <<Done>>
3369       Rewrite (Cnode, Result);
3370       Analyze_And_Resolve (Cnode, Atyp);
3371
3372    exception
3373       when Concatenation_Error =>
3374
3375          --  Kill warning generated for the declaration of the static out of
3376          --  range high bound, and instead generate a Constraint_Error with
3377          --  an appropriate specific message.
3378
3379          Kill_Dead_Code (Declaration_Node (Entity (High_Bound)));
3380          Apply_Compile_Time_Constraint_Error
3381            (N      => Cnode,
3382             Msg    => "concatenation result upper bound out of range?",
3383             Reason => CE_Range_Check_Failed);
3384          --  Set_Etype (Cnode, Atyp);
3385    end Expand_Concatenate;
3386
3387    ------------------------
3388    -- Expand_N_Allocator --
3389    ------------------------
3390
3391    procedure Expand_N_Allocator (N : Node_Id) is
3392       PtrT  : constant Entity_Id  := Etype (N);
3393       Dtyp  : constant Entity_Id  := Available_View (Designated_Type (PtrT));
3394       Etyp  : constant Entity_Id  := Etype (Expression (N));
3395       Loc   : constant Source_Ptr := Sloc (N);
3396       Desig : Entity_Id;
3397       Nod   : Node_Id;
3398       Pool  : Entity_Id;
3399       Temp  : Entity_Id;
3400
3401       procedure Rewrite_Coextension (N : Node_Id);
3402       --  Static coextensions have the same lifetime as the entity they
3403       --  constrain. Such occurrences can be rewritten as aliased objects
3404       --  and their unrestricted access used instead of the coextension.
3405
3406       function Size_In_Storage_Elements (E : Entity_Id) return Node_Id;
3407       --  Given a constrained array type E, returns a node representing the
3408       --  code to compute the size in storage elements for the given type.
3409       --  This is done without using the attribute (which malfunctions for
3410       --  large sizes ???)
3411
3412       -------------------------
3413       -- Rewrite_Coextension --
3414       -------------------------
3415
3416       procedure Rewrite_Coextension (N : Node_Id) is
3417          Temp_Id    : constant Node_Id := Make_Temporary (Loc, 'C');
3418          Temp_Decl  : Node_Id;
3419          Insert_Nod : Node_Id;
3420
3421       begin
3422          --  Generate:
3423          --    Cnn : aliased Etyp;
3424
3425          Temp_Decl :=
3426            Make_Object_Declaration (Loc,
3427              Defining_Identifier => Temp_Id,
3428              Aliased_Present     => True,
3429              Object_Definition   => New_Occurrence_Of (Etyp, Loc));
3430
3431          if Nkind (Expression (N)) = N_Qualified_Expression then
3432             Set_Expression (Temp_Decl, Expression (Expression (N)));
3433          end if;
3434
3435          --  Find the proper insertion node for the declaration
3436
3437          Insert_Nod := Parent (N);
3438          while Present (Insert_Nod) loop
3439             exit when
3440               Nkind (Insert_Nod) in N_Statement_Other_Than_Procedure_Call
3441                 or else Nkind (Insert_Nod) = N_Procedure_Call_Statement
3442                 or else Nkind (Insert_Nod) in N_Declaration;
3443
3444             Insert_Nod := Parent (Insert_Nod);
3445          end loop;
3446
3447          Insert_Before (Insert_Nod, Temp_Decl);
3448          Analyze (Temp_Decl);
3449
3450          Rewrite (N,
3451            Make_Attribute_Reference (Loc,
3452              Prefix         => New_Occurrence_Of (Temp_Id, Loc),
3453              Attribute_Name => Name_Unrestricted_Access));
3454
3455          Analyze_And_Resolve (N, PtrT);
3456       end Rewrite_Coextension;
3457
3458       ------------------------------
3459       -- Size_In_Storage_Elements --
3460       ------------------------------
3461
3462       function Size_In_Storage_Elements (E : Entity_Id) return Node_Id is
3463       begin
3464          --  Logically this just returns E'Max_Size_In_Storage_Elements.
3465          --  However, the reason for the existence of this function is
3466          --  to construct a test for sizes too large, which means near the
3467          --  32-bit limit on a 32-bit machine, and precisely the trouble
3468          --  is that we get overflows when sizes are greater than 2**31.
3469
3470          --  So what we end up doing for array types is to use the expression:
3471
3472          --    number-of-elements * component_type'Max_Size_In_Storage_Elements
3473
3474          --  which avoids this problem. All this is a bit bogus, but it does
3475          --  mean we catch common cases of trying to allocate arrays that
3476          --  are too large, and which in the absence of a check results in
3477          --  undetected chaos ???
3478
3479          declare
3480             Len : Node_Id;
3481             Res : Node_Id;
3482
3483          begin
3484             for J in 1 .. Number_Dimensions (E) loop
3485                Len :=
3486                  Make_Attribute_Reference (Loc,
3487                    Prefix         => New_Occurrence_Of (E, Loc),
3488                    Attribute_Name => Name_Length,
3489                    Expressions    => New_List (Make_Integer_Literal (Loc, J)));
3490
3491                if J = 1 then
3492                   Res := Len;
3493
3494                else
3495                   Res :=
3496                     Make_Op_Multiply (Loc,
3497                       Left_Opnd  => Res,
3498                       Right_Opnd => Len);
3499                end if;
3500             end loop;
3501
3502             return
3503               Make_Op_Multiply (Loc,
3504                 Left_Opnd  => Len,
3505                 Right_Opnd =>
3506                   Make_Attribute_Reference (Loc,
3507                     Prefix => New_Occurrence_Of (Component_Type (E), Loc),
3508                     Attribute_Name => Name_Max_Size_In_Storage_Elements));
3509          end;
3510       end Size_In_Storage_Elements;
3511
3512    --  Start of processing for Expand_N_Allocator
3513
3514    begin
3515       --  RM E.2.3(22). We enforce that the expected type of an allocator
3516       --  shall not be a remote access-to-class-wide-limited-private type
3517
3518       --  Why is this being done at expansion time, seems clearly wrong ???
3519
3520       Validate_Remote_Access_To_Class_Wide_Type (N);
3521
3522       --  Processing for anonymous access-to-controlled types. These access
3523       --  types receive a special finalization master which appears in the
3524       --  declarations of the enclosing semantic unit. This expansion is done
3525       --  now to ensure that any additional types generated by this routine
3526       --  or Expand_Allocator_Expression inherit the proper type attributes.
3527
3528       if Ekind (PtrT) = E_Anonymous_Access_Type
3529         and then Needs_Finalization (Dtyp)
3530       then
3531          --  Anonymous access-to-controlled types allocate on the global pool.
3532          --  Do not set this attribute on .NET/JVM since those targets do not
3533          --  support pools.
3534
3535          if No (Associated_Storage_Pool (PtrT))
3536            and then VM_Target = No_VM
3537          then
3538             Set_Associated_Storage_Pool
3539               (PtrT, Get_Global_Pool_For_Access_Type (PtrT));
3540          end if;
3541
3542          --  The finalization master must be inserted and analyzed as part of
3543          --  the current semantic unit. This form of expansion is not carried
3544          --  out in Alfa mode because it is useless. Note that the master is
3545          --  updated when analysis changes current units.
3546
3547          if not Alfa_Mode then
3548             Set_Finalization_Master (PtrT, Current_Anonymous_Master);
3549          end if;
3550       end if;
3551
3552       --  Set the storage pool and find the appropriate version of Allocate to
3553       --  call. Do not overwrite the storage pool if it is already set, which
3554       --  can happen for build-in-place function returns (see
3555       --  Exp_Ch4.Expand_N_Extended_Return_Statement).
3556
3557       if No (Storage_Pool (N)) then
3558          Pool := Associated_Storage_Pool (Root_Type (PtrT));
3559
3560          if Present (Pool) then
3561             Set_Storage_Pool (N, Pool);
3562
3563             if Is_RTE (Pool, RE_SS_Pool) then
3564                if VM_Target = No_VM then
3565                   Set_Procedure_To_Call (N, RTE (RE_SS_Allocate));
3566                end if;
3567
3568             elsif Is_Class_Wide_Type (Etype (Pool)) then
3569                Set_Procedure_To_Call (N, RTE (RE_Allocate_Any));
3570
3571             else
3572                Set_Procedure_To_Call (N,
3573                  Find_Prim_Op (Etype (Pool), Name_Allocate));
3574             end if;
3575          end if;
3576       end if;
3577
3578       --  Under certain circumstances we can replace an allocator by an access
3579       --  to statically allocated storage. The conditions, as noted in AARM
3580       --  3.10 (10c) are as follows:
3581
3582       --    Size and initial value is known at compile time
3583       --    Access type is access-to-constant
3584
3585       --  The allocator is not part of a constraint on a record component,
3586       --  because in that case the inserted actions are delayed until the
3587       --  record declaration is fully analyzed, which is too late for the
3588       --  analysis of the rewritten allocator.
3589
3590       if Is_Access_Constant (PtrT)
3591         and then Nkind (Expression (N)) = N_Qualified_Expression
3592         and then Compile_Time_Known_Value (Expression (Expression (N)))
3593         and then Size_Known_At_Compile_Time
3594                    (Etype (Expression (Expression (N))))
3595         and then not Is_Record_Type (Current_Scope)
3596       then
3597          --  Here we can do the optimization. For the allocator
3598
3599          --    new x'(y)
3600
3601          --  We insert an object declaration
3602
3603          --    Tnn : aliased x := y;
3604
3605          --  and replace the allocator by Tnn'Unrestricted_Access. Tnn is
3606          --  marked as requiring static allocation.
3607
3608          Temp  := Make_Temporary (Loc, 'T', Expression (Expression (N)));
3609          Desig := Subtype_Mark (Expression (N));
3610
3611          --  If context is constrained, use constrained subtype directly,
3612          --  so that the constant is not labelled as having a nominally
3613          --  unconstrained subtype.
3614
3615          if Entity (Desig) = Base_Type (Dtyp) then
3616             Desig := New_Occurrence_Of (Dtyp, Loc);
3617          end if;
3618
3619          Insert_Action (N,
3620            Make_Object_Declaration (Loc,
3621              Defining_Identifier => Temp,
3622              Aliased_Present     => True,
3623              Constant_Present    => Is_Access_Constant (PtrT),
3624              Object_Definition   => Desig,
3625              Expression          => Expression (Expression (N))));
3626
3627          Rewrite (N,
3628            Make_Attribute_Reference (Loc,
3629              Prefix         => New_Occurrence_Of (Temp, Loc),
3630              Attribute_Name => Name_Unrestricted_Access));
3631
3632          Analyze_And_Resolve (N, PtrT);
3633
3634          --  We set the variable as statically allocated, since we don't want
3635          --  it going on the stack of the current procedure!
3636
3637          Set_Is_Statically_Allocated (Temp);
3638          return;
3639       end if;
3640
3641       --  Same if the allocator is an access discriminant for a local object:
3642       --  instead of an allocator we create a local value and constrain the
3643       --  enclosing object with the corresponding access attribute.
3644
3645       if Is_Static_Coextension (N) then
3646          Rewrite_Coextension (N);
3647          return;
3648       end if;
3649
3650       --  Check for size too large, we do this because the back end misses
3651       --  proper checks here and can generate rubbish allocation calls when
3652       --  we are near the limit. We only do this for the 32-bit address case
3653       --  since that is from a practical point of view where we see a problem.
3654
3655       if System_Address_Size = 32
3656         and then not Storage_Checks_Suppressed (PtrT)
3657         and then not Storage_Checks_Suppressed (Dtyp)
3658         and then not Storage_Checks_Suppressed (Etyp)
3659       then
3660          --  The check we want to generate should look like
3661
3662          --  if Etyp'Max_Size_In_Storage_Elements > 3.5 gigabytes then
3663          --    raise Storage_Error;
3664          --  end if;
3665
3666          --  where 3.5 gigabytes is a constant large enough to accommodate any
3667          --  reasonable request for. But we can't do it this way because at
3668          --  least at the moment we don't compute this attribute right, and
3669          --  can silently give wrong results when the result gets large. Since
3670          --  this is all about large results, that's bad, so instead we only
3671          --  apply the check for constrained arrays, and manually compute the
3672          --  value of the attribute ???
3673
3674          if Is_Array_Type (Etyp) and then Is_Constrained (Etyp) then
3675             Insert_Action (N,
3676               Make_Raise_Storage_Error (Loc,
3677                 Condition =>
3678                   Make_Op_Gt (Loc,
3679                     Left_Opnd  => Size_In_Storage_Elements (Etyp),
3680                     Right_Opnd =>
3681                       Make_Integer_Literal (Loc, Uint_7 * (Uint_2 ** 29))),
3682                 Reason    => SE_Object_Too_Large));
3683          end if;
3684       end if;
3685
3686       --  Handle case of qualified expression (other than optimization above)
3687       --  First apply constraint checks, because the bounds or discriminants
3688       --  in the aggregate might not match the subtype mark in the allocator.
3689
3690       if Nkind (Expression (N)) = N_Qualified_Expression then
3691          Apply_Constraint_Check
3692            (Expression (Expression (N)), Etype (Expression (N)));
3693
3694          Expand_Allocator_Expression (N);
3695          return;
3696       end if;
3697
3698       --  If the allocator is for a type which requires initialization, and
3699       --  there is no initial value (i.e. operand is a subtype indication
3700       --  rather than a qualified expression), then we must generate a call to
3701       --  the initialization routine using an expressions action node:
3702
3703       --     [Pnnn : constant ptr_T := new (T); Init (Pnnn.all,...); Pnnn]
3704
3705       --  Here ptr_T is the pointer type for the allocator, and T is the
3706       --  subtype of the allocator. A special case arises if the designated
3707       --  type of the access type is a task or contains tasks. In this case
3708       --  the call to Init (Temp.all ...) is replaced by code that ensures
3709       --  that tasks get activated (see Exp_Ch9.Build_Task_Allocate_Block
3710       --  for details). In addition, if the type T is a task T, then the
3711       --  first argument to Init must be converted to the task record type.
3712
3713       declare
3714          T         : constant Entity_Id := Entity (Expression (N));
3715          Args      : List_Id;
3716          Decls     : List_Id;
3717          Decl      : Node_Id;
3718          Discr     : Elmt_Id;
3719          Init      : Entity_Id;
3720          Init_Arg1 : Node_Id;
3721          Temp_Decl : Node_Id;
3722          Temp_Type : Entity_Id;
3723
3724       begin
3725          if No_Initialization (N) then
3726
3727             --  Even though this might be a simple allocation, create a custom
3728             --  Allocate if the context requires it. Since .NET/JVM compilers
3729             --  do not support pools, this step is skipped.
3730
3731             if VM_Target = No_VM
3732               and then Present (Finalization_Master (PtrT))
3733             then
3734                Build_Allocate_Deallocate_Proc
3735                  (N           => N,
3736                   Is_Allocate => True);
3737             end if;
3738
3739          --  Case of no initialization procedure present
3740
3741          elsif not Has_Non_Null_Base_Init_Proc (T) then
3742
3743             --  Case of simple initialization required
3744
3745             if Needs_Simple_Initialization (T) then
3746                Check_Restriction (No_Default_Initialization, N);
3747                Rewrite (Expression (N),
3748                  Make_Qualified_Expression (Loc,
3749                    Subtype_Mark => New_Occurrence_Of (T, Loc),
3750                    Expression   => Get_Simple_Init_Val (T, N)));
3751
3752                Analyze_And_Resolve (Expression (Expression (N)), T);
3753                Analyze_And_Resolve (Expression (N), T);
3754                Set_Paren_Count     (Expression (Expression (N)), 1);
3755                Expand_N_Allocator  (N);
3756
3757             --  No initialization required
3758
3759             else
3760                null;
3761             end if;
3762
3763          --  Case of initialization procedure present, must be called
3764
3765          else
3766             Check_Restriction (No_Default_Initialization, N);
3767
3768             if not Restriction_Active (No_Default_Initialization) then
3769                Init := Base_Init_Proc (T);
3770                Nod  := N;
3771                Temp := Make_Temporary (Loc, 'P');
3772
3773                --  Construct argument list for the initialization routine call
3774
3775                Init_Arg1 :=
3776                  Make_Explicit_Dereference (Loc,
3777                    Prefix =>
3778                      New_Reference_To (Temp, Loc));
3779
3780                Set_Assignment_OK (Init_Arg1);
3781                Temp_Type := PtrT;
3782
3783                --  The initialization procedure expects a specific type. if the
3784                --  context is access to class wide, indicate that the object
3785                --  being allocated has the right specific type.
3786
3787                if Is_Class_Wide_Type (Dtyp) then
3788                   Init_Arg1 := Unchecked_Convert_To (T, Init_Arg1);
3789                end if;
3790
3791                --  If designated type is a concurrent type or if it is private
3792                --  type whose definition is a concurrent type, the first
3793                --  argument in the Init routine has to be unchecked conversion
3794                --  to the corresponding record type. If the designated type is
3795                --  a derived type, also convert the argument to its root type.
3796
3797                if Is_Concurrent_Type (T) then
3798                   Init_Arg1 :=
3799                     Unchecked_Convert_To (
3800                       Corresponding_Record_Type (T), Init_Arg1);
3801
3802                elsif Is_Private_Type (T)
3803                  and then Present (Full_View (T))
3804                  and then Is_Concurrent_Type (Full_View (T))
3805                then
3806                   Init_Arg1 :=
3807                     Unchecked_Convert_To
3808                       (Corresponding_Record_Type (Full_View (T)), Init_Arg1);
3809
3810                elsif Etype (First_Formal (Init)) /= Base_Type (T) then
3811                   declare
3812                      Ftyp : constant Entity_Id := Etype (First_Formal (Init));
3813
3814                   begin
3815                      Init_Arg1 := OK_Convert_To (Etype (Ftyp), Init_Arg1);
3816                      Set_Etype (Init_Arg1, Ftyp);
3817                   end;
3818                end if;
3819
3820                Args := New_List (Init_Arg1);
3821
3822                --  For the task case, pass the Master_Id of the access type as
3823                --  the value of the _Master parameter, and _Chain as the value
3824                --  of the _Chain parameter (_Chain will be defined as part of
3825                --  the generated code for the allocator).
3826
3827                --  In Ada 2005, the context may be a function that returns an
3828                --  anonymous access type. In that case the Master_Id has been
3829                --  created when expanding the function declaration.
3830
3831                if Has_Task (T) then
3832                   if No (Master_Id (Base_Type (PtrT))) then
3833
3834                      --  The designated type was an incomplete type, and the
3835                      --  access type did not get expanded. Salvage it now.
3836
3837                      if not Restriction_Active (No_Task_Hierarchy) then
3838                         pragma Assert (Present (Parent (Base_Type (PtrT))));
3839                         Expand_N_Full_Type_Declaration
3840                           (Parent (Base_Type (PtrT)));
3841                      end if;
3842                   end if;
3843
3844                   --  If the context of the allocator is a declaration or an
3845                   --  assignment, we can generate a meaningful image for it,
3846                   --  even though subsequent assignments might remove the
3847                   --  connection between task and entity. We build this image
3848                   --  when the left-hand side is a simple variable, a simple
3849                   --  indexed assignment or a simple selected component.
3850
3851                   if Nkind (Parent (N)) = N_Assignment_Statement then
3852                      declare
3853                         Nam : constant Node_Id := Name (Parent (N));
3854
3855                      begin
3856                         if Is_Entity_Name (Nam) then
3857                            Decls :=
3858                              Build_Task_Image_Decls
3859                                (Loc,
3860                                 New_Occurrence_Of
3861                                   (Entity (Nam), Sloc (Nam)), T);
3862
3863                         elsif Nkind_In (Nam, N_Indexed_Component,
3864                                              N_Selected_Component)
3865                           and then Is_Entity_Name (Prefix (Nam))
3866                         then
3867                            Decls :=
3868                              Build_Task_Image_Decls
3869                                (Loc, Nam, Etype (Prefix (Nam)));
3870                         else
3871                            Decls := Build_Task_Image_Decls (Loc, T, T);
3872                         end if;
3873                      end;
3874
3875                   elsif Nkind (Parent (N)) = N_Object_Declaration then
3876                      Decls :=
3877                        Build_Task_Image_Decls
3878                          (Loc, Defining_Identifier (Parent (N)), T);
3879
3880                   else
3881                      Decls := Build_Task_Image_Decls (Loc, T, T);
3882                   end if;
3883
3884                   if Restriction_Active (No_Task_Hierarchy) then
3885                      Append_To (Args,
3886                        New_Occurrence_Of (RTE (RE_Library_Task_Level), Loc));
3887                   else
3888                      Append_To (Args,
3889                        New_Reference_To
3890                          (Master_Id (Base_Type (Root_Type (PtrT))), Loc));
3891                   end if;
3892
3893                   Append_To (Args, Make_Identifier (Loc, Name_uChain));
3894
3895                   Decl := Last (Decls);
3896                   Append_To (Args,
3897                     New_Occurrence_Of (Defining_Identifier (Decl), Loc));
3898
3899                --  Has_Task is false, Decls not used
3900
3901                else
3902                   Decls := No_List;
3903                end if;
3904
3905                --  Add discriminants if discriminated type
3906
3907                declare
3908                   Dis : Boolean := False;
3909                   Typ : Entity_Id;
3910
3911                begin
3912                   if Has_Discriminants (T) then
3913                      Dis := True;
3914                      Typ := T;
3915
3916                   elsif Is_Private_Type (T)
3917                     and then Present (Full_View (T))
3918                     and then Has_Discriminants (Full_View (T))
3919                   then
3920                      Dis := True;
3921                      Typ := Full_View (T);
3922                   end if;
3923
3924                   if Dis then
3925
3926                      --  If the allocated object will be constrained by the
3927                      --  default values for discriminants, then build a subtype
3928                      --  with those defaults, and change the allocated subtype
3929                      --  to that. Note that this happens in fewer cases in Ada
3930                      --  2005 (AI-363).
3931
3932                      if not Is_Constrained (Typ)
3933                        and then Present (Discriminant_Default_Value
3934                                           (First_Discriminant (Typ)))
3935                        and then (Ada_Version < Ada_2005
3936                                   or else not
3937                                     Effectively_Has_Constrained_Partial_View
3938                                       (Typ  => Typ,
3939                                        Scop => Current_Scope))
3940                      then
3941                         Typ := Build_Default_Subtype (Typ, N);
3942                         Set_Expression (N, New_Reference_To (Typ, Loc));
3943                      end if;
3944
3945                      Discr := First_Elmt (Discriminant_Constraint (Typ));
3946                      while Present (Discr) loop
3947                         Nod := Node (Discr);
3948                         Append (New_Copy_Tree (Node (Discr)), Args);
3949
3950                         --  AI-416: when the discriminant constraint is an
3951                         --  anonymous access type make sure an accessibility
3952                         --  check is inserted if necessary (3.10.2(22.q/2))
3953
3954                         if Ada_Version >= Ada_2005
3955                           and then
3956                             Ekind (Etype (Nod)) = E_Anonymous_Access_Type
3957                         then
3958                            Apply_Accessibility_Check
3959                              (Nod, Typ, Insert_Node => Nod);
3960                         end if;
3961
3962                         Next_Elmt (Discr);
3963                      end loop;
3964                   end if;
3965                end;
3966
3967                --  We set the allocator as analyzed so that when we analyze the
3968                --  expression actions node, we do not get an unwanted recursive
3969                --  expansion of the allocator expression.
3970
3971                Set_Analyzed (N, True);
3972                Nod := Relocate_Node (N);
3973
3974                --  Here is the transformation:
3975                --    input:  new Ctrl_Typ
3976                --    output: Temp : constant Ctrl_Typ_Ptr := new Ctrl_Typ;
3977                --            Ctrl_TypIP (Temp.all, ...);
3978                --            [Deep_]Initialize (Temp.all);
3979
3980                --  Here Ctrl_Typ_Ptr is the pointer type for the allocator, and
3981                --  is the subtype of the allocator.
3982
3983                Temp_Decl :=
3984                  Make_Object_Declaration (Loc,
3985                    Defining_Identifier => Temp,
3986                    Constant_Present    => True,
3987                    Object_Definition   => New_Reference_To (Temp_Type, Loc),
3988                    Expression          => Nod);
3989
3990                Set_Assignment_OK (Temp_Decl);
3991                Insert_Action (N, Temp_Decl, Suppress => All_Checks);
3992
3993                Build_Allocate_Deallocate_Proc (Temp_Decl, True);
3994
3995                --  If the designated type is a task type or contains tasks,
3996                --  create block to activate created tasks, and insert
3997                --  declaration for Task_Image variable ahead of call.
3998
3999                if Has_Task (T) then
4000                   declare
4001                      L   : constant List_Id := New_List;
4002                      Blk : Node_Id;
4003                   begin
4004                      Build_Task_Allocate_Block (L, Nod, Args);
4005                      Blk := Last (L);
4006                      Insert_List_Before (First (Declarations (Blk)), Decls);
4007                      Insert_Actions (N, L);
4008                   end;
4009
4010                else
4011                   Insert_Action (N,
4012                     Make_Procedure_Call_Statement (Loc,
4013                       Name                   => New_Reference_To (Init, Loc),
4014                       Parameter_Associations => Args));
4015                end if;
4016
4017                if Needs_Finalization (T) then
4018
4019                   --  Generate:
4020                   --    [Deep_]Initialize (Init_Arg1);
4021
4022                   Insert_Action (N,
4023                     Make_Init_Call
4024                       (Obj_Ref => New_Copy_Tree (Init_Arg1),
4025                        Typ     => T));
4026
4027                   if Present (Finalization_Master (PtrT)) then
4028
4029                      --  Special processing for .NET/JVM, the allocated object
4030                      --  is attached to the finalization master. Generate:
4031
4032                      --    Attach (<PtrT>FM, Root_Controlled_Ptr (Init_Arg1));
4033
4034                      --  Types derived from [Limited_]Controlled are the only
4035                      --  ones considered since they have fields Prev and Next.
4036
4037                      if VM_Target /= No_VM then
4038                         if Is_Controlled (T) then
4039                            Insert_Action (N,
4040                              Make_Attach_Call
4041                                (Obj_Ref => New_Copy_Tree (Init_Arg1),
4042                                 Ptr_Typ => PtrT));
4043                         end if;
4044
4045                      --  Default case, generate:
4046
4047                      --    Set_Finalize_Address
4048                      --      (<PtrT>FM, <T>FD'Unrestricted_Access);
4049
4050                      --  Do not generate this call in the following cases:
4051                      --
4052                      --    * Alfa mode - the call is useless and results in
4053                      --    unwanted expansion.
4054                      --
4055                      --    * CodePeer mode - TSS primitive Finalize_Address is
4056                      --    not created in this mode.
4057
4058                      elsif not Alfa_Mode
4059                        and then not CodePeer_Mode
4060                      then
4061                         Insert_Action (N,
4062                           Make_Set_Finalize_Address_Call
4063                             (Loc     => Loc,
4064                              Typ     => T,
4065                              Ptr_Typ => PtrT));
4066                      end if;
4067                   end if;
4068                end if;
4069
4070                Rewrite (N, New_Reference_To (Temp, Loc));
4071                Analyze_And_Resolve (N, PtrT);
4072             end if;
4073          end if;
4074       end;
4075
4076       --  Ada 2005 (AI-251): If the allocator is for a class-wide interface
4077       --  object that has been rewritten as a reference, we displace "this"
4078       --  to reference properly its secondary dispatch table.
4079
4080       if Nkind (N) = N_Identifier
4081         and then Is_Interface (Dtyp)
4082       then
4083          Displace_Allocator_Pointer (N);
4084       end if;
4085
4086    exception
4087       when RE_Not_Available =>
4088          return;
4089    end Expand_N_Allocator;
4090
4091    -----------------------
4092    -- Expand_N_And_Then --
4093    -----------------------
4094
4095    procedure Expand_N_And_Then (N : Node_Id)
4096      renames Expand_Short_Circuit_Operator;
4097
4098    ------------------------------
4099    -- Expand_N_Case_Expression --
4100    ------------------------------
4101
4102    procedure Expand_N_Case_Expression (N : Node_Id) is
4103       Loc     : constant Source_Ptr := Sloc (N);
4104       Typ     : constant Entity_Id  := Etype (N);
4105       Cstmt   : Node_Id;
4106       Tnn     : Entity_Id;
4107       Pnn     : Entity_Id;
4108       Actions : List_Id;
4109       Ttyp    : Entity_Id;
4110       Alt     : Node_Id;
4111       Fexp    : Node_Id;
4112
4113    begin
4114       --  We expand
4115
4116       --    case X is when A => AX, when B => BX ...
4117
4118       --  to
4119
4120       --    do
4121       --       Tnn : typ;
4122       --       case X is
4123       --          when A =>
4124       --             Tnn := AX;
4125       --          when B =>
4126       --             Tnn := BX;
4127       --          ...
4128       --       end case;
4129       --    in Tnn end;
4130
4131       --  However, this expansion is wrong for limited types, and also
4132       --  wrong for unconstrained types (since the bounds may not be the
4133       --  same in all branches). Furthermore it involves an extra copy
4134       --  for large objects. So we take care of this by using the following
4135       --  modified expansion for non-scalar types:
4136
4137       --    do
4138       --       type Pnn is access all typ;
4139       --       Tnn : Pnn;
4140       --       case X is
4141       --          when A =>
4142       --             T := AX'Unrestricted_Access;
4143       --          when B =>
4144       --             T := BX'Unrestricted_Access;
4145       --          ...
4146       --       end case;
4147       --    in Tnn.all end;
4148
4149       Cstmt :=
4150         Make_Case_Statement (Loc,
4151           Expression   => Expression (N),
4152           Alternatives => New_List);
4153
4154       Actions := New_List;
4155
4156       --  Scalar case
4157
4158       if Is_Scalar_Type (Typ) then
4159          Ttyp := Typ;
4160
4161       else
4162          Pnn := Make_Temporary (Loc, 'P');
4163          Append_To (Actions,
4164            Make_Full_Type_Declaration (Loc,
4165              Defining_Identifier => Pnn,
4166              Type_Definition =>
4167                Make_Access_To_Object_Definition (Loc,
4168                  All_Present => True,
4169                  Subtype_Indication =>
4170                    New_Reference_To (Typ, Loc))));
4171          Ttyp := Pnn;
4172       end if;
4173
4174       Tnn := Make_Temporary (Loc, 'T');
4175       Append_To (Actions,
4176         Make_Object_Declaration (Loc,
4177           Defining_Identifier => Tnn,
4178           Object_Definition   => New_Occurrence_Of (Ttyp, Loc)));
4179
4180       --  Now process the alternatives
4181
4182       Alt := First (Alternatives (N));
4183       while Present (Alt) loop
4184          declare
4185             Aexp  : Node_Id             := Expression (Alt);
4186             Aloc  : constant Source_Ptr := Sloc (Aexp);
4187             Stats : List_Id;
4188
4189          begin
4190             --  As described above, take Unrestricted_Access for case of non-
4191             --  scalar types, to avoid big copies, and special cases.
4192
4193             if not Is_Scalar_Type (Typ) then
4194                Aexp :=
4195                  Make_Attribute_Reference (Aloc,
4196                    Prefix         => Relocate_Node (Aexp),
4197                    Attribute_Name => Name_Unrestricted_Access);
4198             end if;
4199
4200             Stats := New_List (
4201               Make_Assignment_Statement (Aloc,
4202                 Name       => New_Occurrence_Of (Tnn, Loc),
4203                 Expression => Aexp));
4204
4205             --  Propagate declarations inserted in the node by Insert_Actions
4206             --  (for example, temporaries generated to remove side effects).
4207             --  These actions must remain attached to the alternative, given
4208             --  that they are generated by the corresponding expression.
4209
4210             if Present (Sinfo.Actions (Alt)) then
4211                Prepend_List (Sinfo.Actions (Alt), Stats);
4212             end if;
4213
4214             Append_To
4215               (Alternatives (Cstmt),
4216                Make_Case_Statement_Alternative (Sloc (Alt),
4217                  Discrete_Choices => Discrete_Choices (Alt),
4218                  Statements       => Stats));
4219          end;
4220
4221          Next (Alt);
4222       end loop;
4223
4224       Append_To (Actions, Cstmt);
4225
4226       --  Construct and return final expression with actions
4227
4228       if Is_Scalar_Type (Typ) then
4229          Fexp := New_Occurrence_Of (Tnn, Loc);
4230       else
4231          Fexp :=
4232            Make_Explicit_Dereference (Loc,
4233              Prefix => New_Occurrence_Of (Tnn, Loc));
4234       end if;
4235
4236       Rewrite (N,
4237         Make_Expression_With_Actions (Loc,
4238           Expression => Fexp,
4239           Actions    => Actions));
4240
4241       Analyze_And_Resolve (N, Typ);
4242    end Expand_N_Case_Expression;
4243
4244    -------------------------------------
4245    -- Expand_N_Conditional_Expression --
4246    -------------------------------------
4247
4248    --  Deal with limited types and expression actions
4249
4250    procedure Expand_N_Conditional_Expression (N : Node_Id) is
4251       Loc    : constant Source_Ptr := Sloc (N);
4252       Cond   : constant Node_Id    := First (Expressions (N));
4253       Thenx  : constant Node_Id    := Next (Cond);
4254       Elsex  : constant Node_Id    := Next (Thenx);
4255       Typ    : constant Entity_Id  := Etype (N);
4256
4257       Cnn     : Entity_Id;
4258       Decl    : Node_Id;
4259       New_If  : Node_Id;
4260       New_N   : Node_Id;
4261       P_Decl  : Node_Id;
4262       Expr    : Node_Id;
4263       Actions : List_Id;
4264
4265    begin
4266       --  Fold at compile time if condition known. We have already folded
4267       --  static conditional expressions, but it is possible to fold any
4268       --  case in which the condition is known at compile time, even though
4269       --  the result is non-static.
4270
4271       --  Note that we don't do the fold of such cases in Sem_Elab because
4272       --  it can cause infinite loops with the expander adding a conditional
4273       --  expression, and Sem_Elab circuitry removing it repeatedly.
4274
4275       if Compile_Time_Known_Value (Cond) then
4276          if Is_True (Expr_Value (Cond)) then
4277             Expr := Thenx;
4278             Actions := Then_Actions (N);
4279          else
4280             Expr := Elsex;
4281             Actions := Else_Actions (N);
4282          end if;
4283
4284          Remove (Expr);
4285
4286          if Present (Actions) then
4287
4288             --  If we are not allowed to use Expression_With_Actions, just skip
4289             --  the optimization, it is not critical for correctness.
4290
4291             if not Use_Expression_With_Actions then
4292                goto Skip_Optimization;
4293             end if;
4294
4295             Rewrite (N,
4296               Make_Expression_With_Actions (Loc,
4297                 Expression => Relocate_Node (Expr),
4298                 Actions    => Actions));
4299             Analyze_And_Resolve (N, Typ);
4300
4301          else
4302             Rewrite (N, Relocate_Node (Expr));
4303          end if;
4304
4305          --  Note that the result is never static (legitimate cases of static
4306          --  conditional expressions were folded in Sem_Eval).
4307
4308          Set_Is_Static_Expression (N, False);
4309          return;
4310       end if;
4311
4312       <<Skip_Optimization>>
4313
4314       --  If the type is limited or unconstrained, we expand as follows to
4315       --  avoid any possibility of improper copies.
4316
4317       --  Note: it may be possible to avoid this special processing if the
4318       --  back end uses its own mechanisms for handling by-reference types ???
4319
4320       --      type Ptr is access all Typ;
4321       --      Cnn : Ptr;
4322       --      if cond then
4323       --         <<then actions>>
4324       --         Cnn := then-expr'Unrestricted_Access;
4325       --      else
4326       --         <<else actions>>
4327       --         Cnn := else-expr'Unrestricted_Access;
4328       --      end if;
4329
4330       --  and replace the conditional expression by a reference to Cnn.all.
4331
4332       --  This special case can be skipped if the back end handles limited
4333       --  types properly and ensures that no incorrect copies are made.
4334
4335       if Is_By_Reference_Type (Typ)
4336         and then not Back_End_Handles_Limited_Types
4337       then
4338          Cnn := Make_Temporary (Loc, 'C', N);
4339
4340          P_Decl :=
4341            Make_Full_Type_Declaration (Loc,
4342              Defining_Identifier =>
4343                Make_Temporary (Loc, 'A'),
4344              Type_Definition =>
4345                Make_Access_To_Object_Definition (Loc,
4346                  All_Present        => True,
4347                  Subtype_Indication => New_Reference_To (Typ, Loc)));
4348
4349          Insert_Action (N, P_Decl);
4350
4351          Decl :=
4352             Make_Object_Declaration (Loc,
4353               Defining_Identifier => Cnn,
4354               Object_Definition   =>
4355                    New_Occurrence_Of (Defining_Identifier (P_Decl), Loc));
4356
4357          New_If :=
4358            Make_Implicit_If_Statement (N,
4359              Condition => Relocate_Node (Cond),
4360
4361              Then_Statements => New_List (
4362                Make_Assignment_Statement (Sloc (Thenx),
4363                  Name       => New_Occurrence_Of (Cnn, Sloc (Thenx)),
4364                  Expression =>
4365                    Make_Attribute_Reference (Loc,
4366                      Attribute_Name => Name_Unrestricted_Access,
4367                      Prefix         =>  Relocate_Node (Thenx)))),
4368
4369              Else_Statements => New_List (
4370                Make_Assignment_Statement (Sloc (Elsex),
4371                  Name       => New_Occurrence_Of (Cnn, Sloc (Elsex)),
4372                  Expression =>
4373                    Make_Attribute_Reference (Loc,
4374                      Attribute_Name => Name_Unrestricted_Access,
4375                      Prefix         => Relocate_Node (Elsex)))));
4376
4377          New_N :=
4378            Make_Explicit_Dereference (Loc,
4379              Prefix => New_Occurrence_Of (Cnn, Loc));
4380
4381       --  For other types, we only need to expand if there are other actions
4382       --  associated with either branch.
4383
4384       elsif Present (Then_Actions (N)) or else Present (Else_Actions (N)) then
4385
4386          --  We have two approaches to handling this. If we are allowed to use
4387          --  N_Expression_With_Actions, then we can just wrap the actions into
4388          --  the appropriate expression.
4389
4390          if Use_Expression_With_Actions then
4391             if Present (Then_Actions (N)) then
4392                Rewrite (Thenx,
4393                  Make_Expression_With_Actions (Sloc (Thenx),
4394                    Actions    => Then_Actions (N),
4395                    Expression => Relocate_Node (Thenx)));
4396                Set_Then_Actions (N, No_List);
4397                Analyze_And_Resolve (Thenx, Typ);
4398             end if;
4399
4400             if Present (Else_Actions (N)) then
4401                Rewrite (Elsex,
4402                  Make_Expression_With_Actions (Sloc (Elsex),
4403                    Actions    => Else_Actions (N),
4404                    Expression => Relocate_Node (Elsex)));
4405                Set_Else_Actions (N, No_List);
4406                Analyze_And_Resolve (Elsex, Typ);
4407             end if;
4408
4409             return;
4410
4411             --  if we can't use N_Expression_With_Actions nodes, then we insert
4412             --  the following sequence of actions (using Insert_Actions):
4413
4414             --      Cnn : typ;
4415             --      if cond then
4416             --         <<then actions>>
4417             --         Cnn := then-expr;
4418             --      else
4419             --         <<else actions>>
4420             --         Cnn := else-expr
4421             --      end if;
4422
4423             --  and replace the conditional expression by a reference to Cnn
4424
4425          else
4426             Cnn := Make_Temporary (Loc, 'C', N);
4427
4428             Decl :=
4429               Make_Object_Declaration (Loc,
4430                 Defining_Identifier => Cnn,
4431                 Object_Definition   => New_Occurrence_Of (Typ, Loc));
4432
4433             New_If :=
4434               Make_Implicit_If_Statement (N,
4435                 Condition       => Relocate_Node (Cond),
4436
4437                 Then_Statements => New_List (
4438                   Make_Assignment_Statement (Sloc (Thenx),
4439                     Name       => New_Occurrence_Of (Cnn, Sloc (Thenx)),
4440                     Expression => Relocate_Node (Thenx))),
4441
4442                 Else_Statements => New_List (
4443                   Make_Assignment_Statement (Sloc (Elsex),
4444                     Name       => New_Occurrence_Of (Cnn, Sloc (Elsex)),
4445                     Expression => Relocate_Node (Elsex))));
4446
4447             Set_Assignment_OK (Name (First (Then_Statements (New_If))));
4448             Set_Assignment_OK (Name (First (Else_Statements (New_If))));
4449
4450             New_N := New_Occurrence_Of (Cnn, Loc);
4451          end if;
4452
4453          --  If no actions then no expansion needed, gigi will handle it using
4454          --  the same approach as a C conditional expression.
4455
4456       else
4457          return;
4458       end if;
4459
4460       --  Fall through here for either the limited expansion, or the case of
4461       --  inserting actions for non-limited types. In both these cases, we must
4462       --  move the SLOC of the parent If statement to the newly created one and
4463       --  change it to the SLOC of the expression which, after expansion, will
4464       --  correspond to what is being evaluated.
4465
4466       if Present (Parent (N))
4467         and then Nkind (Parent (N)) = N_If_Statement
4468       then
4469          Set_Sloc (New_If, Sloc (Parent (N)));
4470          Set_Sloc (Parent (N), Loc);
4471       end if;
4472
4473       --  Make sure Then_Actions and Else_Actions are appropriately moved
4474       --  to the new if statement.
4475
4476       if Present (Then_Actions (N)) then
4477          Insert_List_Before
4478            (First (Then_Statements (New_If)), Then_Actions (N));
4479       end if;
4480
4481       if Present (Else_Actions (N)) then
4482          Insert_List_Before
4483            (First (Else_Statements (New_If)), Else_Actions (N));
4484       end if;
4485
4486       Insert_Action (N, Decl);
4487       Insert_Action (N, New_If);
4488       Rewrite (N, New_N);
4489       Analyze_And_Resolve (N, Typ);
4490    end Expand_N_Conditional_Expression;
4491
4492    -----------------------------------
4493    -- Expand_N_Explicit_Dereference --
4494    -----------------------------------
4495
4496    procedure Expand_N_Explicit_Dereference (N : Node_Id) is
4497    begin
4498       --  Insert explicit dereference call for the checked storage pool case
4499
4500       Insert_Dereference_Action (Prefix (N));
4501
4502       --  If the type is an Atomic type for which Atomic_Sync is enabled, then
4503       --  we set the atomic sync flag.
4504
4505       if Is_Atomic (Etype (N))
4506         and then not Atomic_Synchronization_Disabled (Etype (N))
4507       then
4508          Activate_Atomic_Synchronization (N);
4509       end if;
4510    end Expand_N_Explicit_Dereference;
4511
4512    --------------------------------------
4513    -- Expand_N_Expression_With_Actions --
4514    --------------------------------------
4515
4516    procedure Expand_N_Expression_With_Actions (N : Node_Id) is
4517
4518       procedure Process_Transient_Object (Decl : Node_Id);
4519       --  Given the declaration of a controlled transient declared inside the
4520       --  Actions list of an Expression_With_Actions, generate all necessary
4521       --  types and hooks in order to properly finalize the transient. This
4522       --  mechanism works in conjunction with Build_Finalizer.
4523
4524       ------------------------------
4525       -- Process_Transient_Object --
4526       ------------------------------
4527
4528       procedure Process_Transient_Object (Decl : Node_Id) is
4529
4530          function Find_Insertion_Node return Node_Id;
4531          --  Complex conditions in if statements may be converted into nested
4532          --  EWAs. In this case, any generated code must be inserted before the
4533          --  if statement to ensure proper visibility of the hook objects. This
4534          --  routine returns the top most short circuit operator or the parent
4535          --  of the EWA if no nesting was detected.
4536
4537          -------------------------
4538          -- Find_Insertion_Node --
4539          -------------------------
4540
4541          function Find_Insertion_Node return Node_Id is
4542             Par : Node_Id;
4543
4544          begin
4545             --  Climb up the branches of a complex condition
4546
4547             Par := N;
4548             while Nkind_In (Parent (Par), N_And_Then, N_Op_Not, N_Or_Else) loop
4549                Par := Parent (Par);
4550             end loop;
4551
4552             return Par;
4553          end Find_Insertion_Node;
4554
4555          --  Local variables
4556
4557          Ins_Node  : constant Node_Id    := Find_Insertion_Node;
4558          Loc       : constant Source_Ptr := Sloc (Decl);
4559          Obj_Id    : constant Entity_Id  := Defining_Identifier (Decl);
4560          Obj_Typ   : constant Entity_Id  := Etype (Obj_Id);
4561          Desig_Typ : Entity_Id;
4562          Expr      : Node_Id;
4563          Ptr_Decl  : Node_Id;
4564          Ptr_Id    : Entity_Id;
4565          Temp_Decl : Node_Id;
4566          Temp_Id   : Node_Id;
4567
4568       --  Start of processing for Process_Transient_Object
4569
4570       begin
4571          --  Step 1: Create the access type which provides a reference to the
4572          --  transient object.
4573
4574          if Is_Access_Type (Obj_Typ) then
4575             Desig_Typ := Directly_Designated_Type (Obj_Typ);
4576          else
4577             Desig_Typ := Obj_Typ;
4578          end if;
4579
4580          --  Generate:
4581          --    Ann : access [all] <Desig_Typ>;
4582
4583          Ptr_Id := Make_Temporary (Loc, 'A');
4584
4585          Ptr_Decl :=
4586            Make_Full_Type_Declaration (Loc,
4587              Defining_Identifier => Ptr_Id,
4588              Type_Definition     =>
4589                Make_Access_To_Object_Definition (Loc,
4590                  All_Present        =>
4591                    Ekind (Obj_Typ) = E_General_Access_Type,
4592                  Subtype_Indication => New_Reference_To (Desig_Typ, Loc)));
4593
4594          Insert_Action (Ins_Node, Ptr_Decl);
4595          Analyze (Ptr_Decl);
4596
4597          --  Step 2: Create a temporary which acts as a hook to the transient
4598          --  object. Generate:
4599
4600          --    Temp : Ptr_Id := null;
4601
4602          Temp_Id := Make_Temporary (Loc, 'T');
4603
4604          Temp_Decl :=
4605            Make_Object_Declaration (Loc,
4606              Defining_Identifier => Temp_Id,
4607              Object_Definition   => New_Reference_To (Ptr_Id, Loc));
4608
4609          Insert_Action (Ins_Node, Temp_Decl);
4610          Analyze (Temp_Decl);
4611
4612          --  Mark this temporary as created for the purposes of exporting the
4613          --  transient declaration out of the Actions list. This signals the
4614          --  machinery in Build_Finalizer to recognize this special case.
4615
4616          Set_Return_Flag_Or_Transient_Decl (Temp_Id, Decl);
4617
4618          --  Step 3: Hook the transient object to the temporary
4619
4620          if Is_Access_Type (Obj_Typ) then
4621             Expr := Convert_To (Ptr_Id, New_Reference_To (Obj_Id, Loc));
4622          else
4623             Expr :=
4624               Make_Attribute_Reference (Loc,
4625                 Prefix         => New_Reference_To (Obj_Id, Loc),
4626                 Attribute_Name => Name_Unrestricted_Access);
4627          end if;
4628
4629          --  Generate:
4630          --    Temp := Ptr_Id (Obj_Id);
4631          --      <or>
4632          --    Temp := Obj_Id'Unrestricted_Access;
4633
4634          Insert_After_And_Analyze (Decl,
4635            Make_Assignment_Statement (Loc,
4636              Name       => New_Reference_To (Temp_Id, Loc),
4637              Expression => Expr));
4638       end Process_Transient_Object;
4639
4640       --  Local variables
4641
4642       Decl : Node_Id;
4643
4644    --  Start of processing for Expand_N_Expression_With_Actions
4645
4646    begin
4647       Decl := First (Actions (N));
4648       while Present (Decl) loop
4649          if Nkind (Decl) = N_Object_Declaration
4650            and then Is_Finalizable_Transient (Decl, N)
4651          then
4652             Process_Transient_Object (Decl);
4653          end if;
4654
4655          Next (Decl);
4656       end loop;
4657    end Expand_N_Expression_With_Actions;
4658
4659    -----------------
4660    -- Expand_N_In --
4661    -----------------
4662
4663    procedure Expand_N_In (N : Node_Id) is
4664       Loc    : constant Source_Ptr := Sloc (N);
4665       Restyp : constant Entity_Id  := Etype (N);
4666       Lop    : constant Node_Id    := Left_Opnd (N);
4667       Rop    : constant Node_Id    := Right_Opnd (N);
4668       Static : constant Boolean    := Is_OK_Static_Expression (N);
4669
4670       Ltyp  : Entity_Id;
4671       Rtyp  : Entity_Id;
4672
4673       procedure Substitute_Valid_Check;
4674       --  Replaces node N by Lop'Valid. This is done when we have an explicit
4675       --  test for the left operand being in range of its subtype.
4676
4677       ----------------------------
4678       -- Substitute_Valid_Check --
4679       ----------------------------
4680
4681       procedure Substitute_Valid_Check is
4682       begin
4683          Rewrite (N,
4684            Make_Attribute_Reference (Loc,
4685              Prefix         => Relocate_Node (Lop),
4686              Attribute_Name => Name_Valid));
4687
4688          Analyze_And_Resolve (N, Restyp);
4689
4690          Error_Msg_N ("?explicit membership test may be optimized away", N);
4691          Error_Msg_N -- CODEFIX
4692            ("\?use ''Valid attribute instead", N);
4693          return;
4694       end Substitute_Valid_Check;
4695
4696    --  Start of processing for Expand_N_In
4697
4698    begin
4699       --  If set membership case, expand with separate procedure
4700
4701       if Present (Alternatives (N)) then
4702          Expand_Set_Membership (N);
4703          return;
4704       end if;
4705
4706       --  Not set membership, proceed with expansion
4707
4708       Ltyp := Etype (Left_Opnd  (N));
4709       Rtyp := Etype (Right_Opnd (N));
4710
4711       --  Check case of explicit test for an expression in range of its
4712       --  subtype. This is suspicious usage and we replace it with a 'Valid
4713       --  test and give a warning. For floating point types however, this is a
4714       --  standard way to check for finite numbers, and using 'Valid would
4715       --  typically be a pessimization. Also skip this test for predicated
4716       --  types, since it is perfectly reasonable to check if a value meets
4717       --  its predicate.
4718
4719       if Is_Scalar_Type (Ltyp)
4720         and then not Is_Floating_Point_Type (Ltyp)
4721         and then Nkind (Rop) in N_Has_Entity
4722         and then Ltyp = Entity (Rop)
4723         and then Comes_From_Source (N)
4724         and then VM_Target = No_VM
4725         and then not (Is_Discrete_Type (Ltyp)
4726                        and then Present (Predicate_Function (Ltyp)))
4727       then
4728          Substitute_Valid_Check;
4729          return;
4730       end if;
4731
4732       --  Do validity check on operands
4733
4734       if Validity_Checks_On and Validity_Check_Operands then
4735          Ensure_Valid (Left_Opnd (N));
4736          Validity_Check_Range (Right_Opnd (N));
4737       end if;
4738
4739       --  Case of explicit range
4740
4741       if Nkind (Rop) = N_Range then
4742          declare
4743             Lo : constant Node_Id := Low_Bound (Rop);
4744             Hi : constant Node_Id := High_Bound (Rop);
4745
4746             Lo_Orig : constant Node_Id := Original_Node (Lo);
4747             Hi_Orig : constant Node_Id := Original_Node (Hi);
4748
4749             Lcheck : Compare_Result;
4750             Ucheck : Compare_Result;
4751
4752             Warn1 : constant Boolean :=
4753                       Constant_Condition_Warnings
4754                         and then Comes_From_Source (N)
4755                         and then not In_Instance;
4756             --  This must be true for any of the optimization warnings, we
4757             --  clearly want to give them only for source with the flag on. We
4758             --  also skip these warnings in an instance since it may be the
4759             --  case that different instantiations have different ranges.
4760
4761             Warn2 : constant Boolean :=
4762                       Warn1
4763                         and then Nkind (Original_Node (Rop)) = N_Range
4764                         and then Is_Integer_Type (Etype (Lo));
4765             --  For the case where only one bound warning is elided, we also
4766             --  insist on an explicit range and an integer type. The reason is
4767             --  that the use of enumeration ranges including an end point is
4768             --  common, as is the use of a subtype name, one of whose bounds is
4769             --  the same as the type of the expression.
4770
4771          begin
4772             --  If test is explicit x'First .. x'Last, replace by valid check
4773
4774             --  Could use some individual comments for this complex test ???
4775
4776             if Is_Scalar_Type (Ltyp)
4777               and then Nkind (Lo_Orig) = N_Attribute_Reference
4778               and then Attribute_Name (Lo_Orig) = Name_First
4779               and then Nkind (Prefix (Lo_Orig)) in N_Has_Entity
4780               and then Entity (Prefix (Lo_Orig)) = Ltyp
4781               and then Nkind (Hi_Orig) = N_Attribute_Reference
4782               and then Attribute_Name (Hi_Orig) = Name_Last
4783               and then Nkind (Prefix (Hi_Orig)) in N_Has_Entity
4784               and then Entity (Prefix (Hi_Orig)) = Ltyp
4785               and then Comes_From_Source (N)
4786               and then VM_Target = No_VM
4787             then
4788                Substitute_Valid_Check;
4789                goto Leave;
4790             end if;
4791
4792             --  If bounds of type are known at compile time, and the end points
4793             --  are known at compile time and identical, this is another case
4794             --  for substituting a valid test. We only do this for discrete
4795             --  types, since it won't arise in practice for float types.
4796
4797             if Comes_From_Source (N)
4798               and then Is_Discrete_Type (Ltyp)
4799               and then Compile_Time_Known_Value (Type_High_Bound (Ltyp))
4800               and then Compile_Time_Known_Value (Type_Low_Bound  (Ltyp))
4801               and then Compile_Time_Known_Value (Lo)
4802               and then Compile_Time_Known_Value (Hi)
4803               and then Expr_Value (Type_High_Bound (Ltyp)) = Expr_Value (Hi)
4804               and then Expr_Value (Type_Low_Bound  (Ltyp)) = Expr_Value (Lo)
4805
4806                --  Kill warnings in instances, since they may be cases where we
4807                --  have a test in the generic that makes sense with some types
4808                --  and not with other types.
4809
4810               and then not In_Instance
4811             then
4812                Substitute_Valid_Check;
4813                goto Leave;
4814             end if;
4815
4816             --  If we have an explicit range, do a bit of optimization based on
4817             --  range analysis (we may be able to kill one or both checks).
4818
4819             Lcheck := Compile_Time_Compare (Lop, Lo, Assume_Valid => False);
4820             Ucheck := Compile_Time_Compare (Lop, Hi, Assume_Valid => False);
4821
4822             --  If either check is known to fail, replace result by False since
4823             --  the other check does not matter. Preserve the static flag for
4824             --  legality checks, because we are constant-folding beyond RM 4.9.
4825
4826             if Lcheck = LT or else Ucheck = GT then
4827                if Warn1 then
4828                   Error_Msg_N ("?range test optimized away", N);
4829                   Error_Msg_N ("\?value is known to be out of range", N);
4830                end if;
4831
4832                Rewrite (N, New_Reference_To (Standard_False, Loc));
4833                Analyze_And_Resolve (N, Restyp);
4834                Set_Is_Static_Expression (N, Static);
4835                goto Leave;
4836
4837             --  If both checks are known to succeed, replace result by True,
4838             --  since we know we are in range.
4839
4840             elsif Lcheck in Compare_GE and then Ucheck in Compare_LE then
4841                if Warn1 then
4842                   Error_Msg_N ("?range test optimized away", N);
4843                   Error_Msg_N ("\?value is known to be in range", N);
4844                end if;
4845
4846                Rewrite (N, New_Reference_To (Standard_True, Loc));
4847                Analyze_And_Resolve (N, Restyp);
4848                Set_Is_Static_Expression (N, Static);
4849                goto Leave;
4850
4851             --  If lower bound check succeeds and upper bound check is not
4852             --  known to succeed or fail, then replace the range check with
4853             --  a comparison against the upper bound.
4854
4855             elsif Lcheck in Compare_GE then
4856                if Warn2 and then not In_Instance then
4857                   Error_Msg_N ("?lower bound test optimized away", Lo);
4858                   Error_Msg_N ("\?value is known to be in range", Lo);
4859                end if;
4860
4861                Rewrite (N,
4862                  Make_Op_Le (Loc,
4863                    Left_Opnd  => Lop,
4864                    Right_Opnd => High_Bound (Rop)));
4865                Analyze_And_Resolve (N, Restyp);
4866                goto Leave;
4867
4868             --  If upper bound check succeeds and lower bound check is not
4869             --  known to succeed or fail, then replace the range check with
4870             --  a comparison against the lower bound.
4871
4872             elsif Ucheck in Compare_LE then
4873                if Warn2 and then not In_Instance then
4874                   Error_Msg_N ("?upper bound test optimized away", Hi);
4875                   Error_Msg_N ("\?value is known to be in range", Hi);
4876                end if;
4877
4878                Rewrite (N,
4879                  Make_Op_Ge (Loc,
4880                    Left_Opnd  => Lop,
4881                    Right_Opnd => Low_Bound (Rop)));
4882                Analyze_And_Resolve (N, Restyp);
4883                goto Leave;
4884             end if;
4885
4886             --  We couldn't optimize away the range check, but there is one
4887             --  more issue. If we are checking constant conditionals, then we
4888             --  see if we can determine the outcome assuming everything is
4889             --  valid, and if so give an appropriate warning.
4890
4891             if Warn1 and then not Assume_No_Invalid_Values then
4892                Lcheck := Compile_Time_Compare (Lop, Lo, Assume_Valid => True);
4893                Ucheck := Compile_Time_Compare (Lop, Hi, Assume_Valid => True);
4894
4895                --  Result is out of range for valid value
4896
4897                if Lcheck = LT or else Ucheck = GT then
4898                   Error_Msg_N
4899                     ("?value can only be in range if it is invalid", N);
4900
4901                --  Result is in range for valid value
4902
4903                elsif Lcheck in Compare_GE and then Ucheck in Compare_LE then
4904                   Error_Msg_N
4905                     ("?value can only be out of range if it is invalid", N);
4906
4907                --  Lower bound check succeeds if value is valid
4908
4909                elsif Warn2 and then Lcheck in Compare_GE then
4910                   Error_Msg_N
4911                     ("?lower bound check only fails if it is invalid", Lo);
4912
4913                --  Upper bound  check succeeds if value is valid
4914
4915                elsif Warn2 and then Ucheck in Compare_LE then
4916                   Error_Msg_N
4917                     ("?upper bound check only fails for invalid values", Hi);
4918                end if;
4919             end if;
4920          end;
4921
4922          --  For all other cases of an explicit range, nothing to be done
4923
4924          goto Leave;
4925
4926       --  Here right operand is a subtype mark
4927
4928       else
4929          declare
4930             Typ       : Entity_Id        := Etype (Rop);
4931             Is_Acc    : constant Boolean := Is_Access_Type (Typ);
4932             Cond      : Node_Id          := Empty;
4933             New_N     : Node_Id;
4934             Obj       : Node_Id          := Lop;
4935             SCIL_Node : Node_Id;
4936
4937          begin
4938             Remove_Side_Effects (Obj);
4939
4940             --  For tagged type, do tagged membership operation
4941
4942             if Is_Tagged_Type (Typ) then
4943
4944                --  No expansion will be performed when VM_Target, as the VM
4945                --  back-ends will handle the membership tests directly (tags
4946                --  are not explicitly represented in Java objects, so the
4947                --  normal tagged membership expansion is not what we want).
4948
4949                if Tagged_Type_Expansion then
4950                   Tagged_Membership (N, SCIL_Node, New_N);
4951                   Rewrite (N, New_N);
4952                   Analyze_And_Resolve (N, Restyp);
4953
4954                   --  Update decoration of relocated node referenced by the
4955                   --  SCIL node.
4956
4957                   if Generate_SCIL and then Present (SCIL_Node) then
4958                      Set_SCIL_Node (N, SCIL_Node);
4959                   end if;
4960                end if;
4961
4962                goto Leave;
4963
4964             --  If type is scalar type, rewrite as x in t'First .. t'Last.
4965             --  This reason we do this is that the bounds may have the wrong
4966             --  type if they come from the original type definition. Also this
4967             --  way we get all the processing above for an explicit range.
4968
4969                --  Don't do this for predicated types, since in this case we
4970                --  want to check the predicate!
4971
4972             elsif Is_Scalar_Type (Typ) then
4973                if No (Predicate_Function (Typ)) then
4974                   Rewrite (Rop,
4975                     Make_Range (Loc,
4976                       Low_Bound =>
4977                         Make_Attribute_Reference (Loc,
4978                           Attribute_Name => Name_First,
4979                           Prefix => New_Reference_To (Typ, Loc)),
4980
4981                       High_Bound =>
4982                         Make_Attribute_Reference (Loc,
4983                           Attribute_Name => Name_Last,
4984                           Prefix => New_Reference_To (Typ, Loc))));
4985                   Analyze_And_Resolve (N, Restyp);
4986                end if;
4987
4988                goto Leave;
4989
4990             --  Ada 2005 (AI-216): Program_Error is raised when evaluating
4991             --  a membership test if the subtype mark denotes a constrained
4992             --  Unchecked_Union subtype and the expression lacks inferable
4993             --  discriminants.
4994
4995             elsif Is_Unchecked_Union (Base_Type (Typ))
4996               and then Is_Constrained (Typ)
4997               and then not Has_Inferable_Discriminants (Lop)
4998             then
4999                Insert_Action (N,
5000                  Make_Raise_Program_Error (Loc,
5001                    Reason => PE_Unchecked_Union_Restriction));
5002
5003                --  Prevent Gigi from generating incorrect code by rewriting the
5004                --  test as False.
5005
5006                Rewrite (N, New_Occurrence_Of (Standard_False, Loc));
5007                goto Leave;
5008             end if;
5009
5010             --  Here we have a non-scalar type
5011
5012             if Is_Acc then
5013                Typ := Designated_Type (Typ);
5014             end if;
5015
5016             if not Is_Constrained (Typ) then
5017                Rewrite (N, New_Reference_To (Standard_True, Loc));
5018                Analyze_And_Resolve (N, Restyp);
5019
5020             --  For the constrained array case, we have to check the subscripts
5021             --  for an exact match if the lengths are non-zero (the lengths
5022             --  must match in any case).
5023
5024             elsif Is_Array_Type (Typ) then
5025                Check_Subscripts : declare
5026                   function Build_Attribute_Reference
5027                     (E   : Node_Id;
5028                      Nam : Name_Id;
5029                      Dim : Nat) return Node_Id;
5030                   --  Build attribute reference E'Nam (Dim)
5031
5032                   -------------------------------
5033                   -- Build_Attribute_Reference --
5034                   -------------------------------
5035
5036                   function Build_Attribute_Reference
5037                     (E   : Node_Id;
5038                      Nam : Name_Id;
5039                      Dim : Nat) return Node_Id
5040                   is
5041                   begin
5042                      return
5043                        Make_Attribute_Reference (Loc,
5044                          Prefix         => E,
5045                          Attribute_Name => Nam,
5046                          Expressions    => New_List (
5047                            Make_Integer_Literal (Loc, Dim)));
5048                   end Build_Attribute_Reference;
5049
5050                --  Start of processing for Check_Subscripts
5051
5052                begin
5053                   for J in 1 .. Number_Dimensions (Typ) loop
5054                      Evolve_And_Then (Cond,
5055                        Make_Op_Eq (Loc,
5056                          Left_Opnd  =>
5057                            Build_Attribute_Reference
5058                              (Duplicate_Subexpr_No_Checks (Obj),
5059                               Name_First, J),
5060                          Right_Opnd =>
5061                            Build_Attribute_Reference
5062                              (New_Occurrence_Of (Typ, Loc), Name_First, J)));
5063
5064                      Evolve_And_Then (Cond,
5065                        Make_Op_Eq (Loc,
5066                          Left_Opnd  =>
5067                            Build_Attribute_Reference
5068                              (Duplicate_Subexpr_No_Checks (Obj),
5069                               Name_Last, J),
5070                          Right_Opnd =>
5071                            Build_Attribute_Reference
5072                              (New_Occurrence_Of (Typ, Loc), Name_Last, J)));
5073                   end loop;
5074
5075                   if Is_Acc then
5076                      Cond :=
5077                        Make_Or_Else (Loc,
5078                          Left_Opnd =>
5079                            Make_Op_Eq (Loc,
5080                              Left_Opnd  => Obj,
5081                              Right_Opnd => Make_Null (Loc)),
5082                          Right_Opnd => Cond);
5083                   end if;
5084
5085                   Rewrite (N, Cond);
5086                   Analyze_And_Resolve (N, Restyp);
5087                end Check_Subscripts;
5088
5089             --  These are the cases where constraint checks may be required,
5090             --  e.g. records with possible discriminants
5091
5092             else
5093                --  Expand the test into a series of discriminant comparisons.
5094                --  The expression that is built is the negation of the one that
5095                --  is used for checking discriminant constraints.
5096
5097                Obj := Relocate_Node (Left_Opnd (N));
5098
5099                if Has_Discriminants (Typ) then
5100                   Cond := Make_Op_Not (Loc,
5101                     Right_Opnd => Build_Discriminant_Checks (Obj, Typ));
5102
5103                   if Is_Acc then
5104                      Cond := Make_Or_Else (Loc,
5105                        Left_Opnd =>
5106                          Make_Op_Eq (Loc,
5107                            Left_Opnd  => Obj,
5108                            Right_Opnd => Make_Null (Loc)),
5109                        Right_Opnd => Cond);
5110                   end if;
5111
5112                else
5113                   Cond := New_Occurrence_Of (Standard_True, Loc);
5114                end if;
5115
5116                Rewrite (N, Cond);
5117                Analyze_And_Resolve (N, Restyp);
5118             end if;
5119
5120             --  Ada 2012 (AI05-0149): Handle membership tests applied to an
5121             --  expression of an anonymous access type. This can involve an
5122             --  accessibility test and a tagged type membership test in the
5123             --  case of tagged designated types.
5124
5125             if Ada_Version >= Ada_2012
5126               and then Is_Acc
5127               and then Ekind (Ltyp) = E_Anonymous_Access_Type
5128             then
5129                declare
5130                   Expr_Entity : Entity_Id := Empty;
5131                   New_N       : Node_Id;
5132                   Param_Level : Node_Id;
5133                   Type_Level  : Node_Id;
5134
5135                begin
5136                   if Is_Entity_Name (Lop) then
5137                      Expr_Entity := Param_Entity (Lop);
5138
5139                      if not Present (Expr_Entity) then
5140                         Expr_Entity := Entity (Lop);
5141                      end if;
5142                   end if;
5143
5144                   --  If a conversion of the anonymous access value to the
5145                   --  tested type would be illegal, then the result is False.
5146
5147                   if not Valid_Conversion
5148                            (Lop, Rtyp, Lop, Report_Errs => False)
5149                   then
5150                      Rewrite (N, New_Occurrence_Of (Standard_False, Loc));
5151                      Analyze_And_Resolve (N, Restyp);
5152
5153                   --  Apply an accessibility check if the access object has an
5154                   --  associated access level and when the level of the type is
5155                   --  less deep than the level of the access parameter. This
5156                   --  only occur for access parameters and stand-alone objects
5157                   --  of an anonymous access type.
5158
5159                   else
5160                      if Present (Expr_Entity)
5161                        and then
5162                          Present
5163                            (Effective_Extra_Accessibility (Expr_Entity))
5164                        and then UI_Gt (Object_Access_Level (Lop),
5165                                        Type_Access_Level (Rtyp))
5166                      then
5167                         Param_Level :=
5168                           New_Occurrence_Of
5169                             (Effective_Extra_Accessibility (Expr_Entity), Loc);
5170
5171                         Type_Level :=
5172                           Make_Integer_Literal (Loc, Type_Access_Level (Rtyp));
5173
5174                         --  Return True only if the accessibility level of the
5175                         --  expression entity is not deeper than the level of
5176                         --  the tested access type.
5177
5178                         Rewrite (N,
5179                           Make_And_Then (Loc,
5180                             Left_Opnd  => Relocate_Node (N),
5181                             Right_Opnd => Make_Op_Le (Loc,
5182                                             Left_Opnd  => Param_Level,
5183                                             Right_Opnd => Type_Level)));
5184
5185                         Analyze_And_Resolve (N);
5186                      end if;
5187
5188                      --  If the designated type is tagged, do tagged membership
5189                      --  operation.
5190
5191                      --  *** NOTE: we have to check not null before doing the
5192                      --  tagged membership test (but maybe that can be done
5193                      --  inside Tagged_Membership?).
5194
5195                      if Is_Tagged_Type (Typ) then
5196                         Rewrite (N,
5197                           Make_And_Then (Loc,
5198                             Left_Opnd  => Relocate_Node (N),
5199                             Right_Opnd =>
5200                               Make_Op_Ne (Loc,
5201                                 Left_Opnd  => Obj,
5202                                 Right_Opnd => Make_Null (Loc))));
5203
5204                         --  No expansion will be performed when VM_Target, as
5205                         --  the VM back-ends will handle the membership tests
5206                         --  directly (tags are not explicitly represented in
5207                         --  Java objects, so the normal tagged membership
5208                         --  expansion is not what we want).
5209
5210                         if Tagged_Type_Expansion then
5211
5212                            --  Note that we have to pass Original_Node, because
5213                            --  the membership test might already have been
5214                            --  rewritten by earlier parts of membership test.
5215
5216                            Tagged_Membership
5217                              (Original_Node (N), SCIL_Node, New_N);
5218
5219                            --  Update decoration of relocated node referenced
5220                            --  by the SCIL node.
5221
5222                            if Generate_SCIL and then Present (SCIL_Node) then
5223                               Set_SCIL_Node (New_N, SCIL_Node);
5224                            end if;
5225
5226                            Rewrite (N,
5227                              Make_And_Then (Loc,
5228                                Left_Opnd  => Relocate_Node (N),
5229                                Right_Opnd => New_N));
5230
5231                            Analyze_And_Resolve (N, Restyp);
5232                         end if;
5233                      end if;
5234                   end if;
5235                end;
5236             end if;
5237          end;
5238       end if;
5239
5240    --  At this point, we have done the processing required for the basic
5241    --  membership test, but not yet dealt with the predicate.
5242
5243    <<Leave>>
5244
5245       --  If a predicate is present, then we do the predicate test, but we
5246       --  most certainly want to omit this if we are within the predicate
5247       --  function itself, since otherwise we have an infinite recursion!
5248
5249       declare
5250          PFunc : constant Entity_Id := Predicate_Function (Rtyp);
5251
5252       begin
5253          if Present (PFunc)
5254            and then Current_Scope /= PFunc
5255          then
5256             Rewrite (N,
5257               Make_And_Then (Loc,
5258                 Left_Opnd  => Relocate_Node (N),
5259                 Right_Opnd => Make_Predicate_Call (Rtyp, Lop)));
5260
5261             --  Analyze new expression, mark left operand as analyzed to
5262             --  avoid infinite recursion adding predicate calls. Similarly,
5263             --  suppress further range checks on the call.
5264
5265             Set_Analyzed (Left_Opnd (N));
5266             Analyze_And_Resolve (N, Standard_Boolean, Suppress => All_Checks);
5267
5268             --  All done, skip attempt at compile time determination of result
5269
5270             return;
5271          end if;
5272       end;
5273    end Expand_N_In;
5274
5275    --------------------------------
5276    -- Expand_N_Indexed_Component --
5277    --------------------------------
5278
5279    procedure Expand_N_Indexed_Component (N : Node_Id) is
5280       Loc : constant Source_Ptr := Sloc (N);
5281       Typ : constant Entity_Id  := Etype (N);
5282       P   : constant Node_Id    := Prefix (N);
5283       T   : constant Entity_Id  := Etype (P);
5284       Atp : Entity_Id;
5285
5286    begin
5287       --  A special optimization, if we have an indexed component that is
5288       --  selecting from a slice, then we can eliminate the slice, since, for
5289       --  example, x (i .. j)(k) is identical to x(k). The only difference is
5290       --  the range check required by the slice. The range check for the slice
5291       --  itself has already been generated. The range check for the
5292       --  subscripting operation is ensured by converting the subject to
5293       --  the subtype of the slice.
5294
5295       --  This optimization not only generates better code, avoiding slice
5296       --  messing especially in the packed case, but more importantly bypasses
5297       --  some problems in handling this peculiar case, for example, the issue
5298       --  of dealing specially with object renamings.
5299
5300       if Nkind (P) = N_Slice then
5301          Rewrite (N,
5302            Make_Indexed_Component (Loc,
5303              Prefix => Prefix (P),
5304              Expressions => New_List (
5305                Convert_To
5306                  (Etype (First_Index (Etype (P))),
5307                   First (Expressions (N))))));
5308          Analyze_And_Resolve (N, Typ);
5309          return;
5310       end if;
5311
5312       --  Ada 2005 (AI-318-02): If the prefix is a call to a build-in-place
5313       --  function, then additional actuals must be passed.
5314
5315       if Ada_Version >= Ada_2005
5316         and then Is_Build_In_Place_Function_Call (P)
5317       then
5318          Make_Build_In_Place_Call_In_Anonymous_Context (P);
5319       end if;
5320
5321       --  If the prefix is an access type, then we unconditionally rewrite if
5322       --  as an explicit dereference. This simplifies processing for several
5323       --  cases, including packed array cases and certain cases in which checks
5324       --  must be generated. We used to try to do this only when it was
5325       --  necessary, but it cleans up the code to do it all the time.
5326
5327       if Is_Access_Type (T) then
5328          Insert_Explicit_Dereference (P);
5329          Analyze_And_Resolve (P, Designated_Type (T));
5330          Atp := Designated_Type (T);
5331       else
5332          Atp := T;
5333       end if;
5334
5335       --  Generate index and validity checks
5336
5337       Generate_Index_Checks (N);
5338
5339       if Validity_Checks_On and then Validity_Check_Subscripts then
5340          Apply_Subscript_Validity_Checks (N);
5341       end if;
5342
5343       --  If selecting from an array with atomic components, and atomic sync
5344       --  is not suppressed for this array type, set atomic sync flag.
5345
5346       if (Has_Atomic_Components (Atp)
5347            and then not Atomic_Synchronization_Disabled (Atp))
5348         or else (Is_Atomic (Typ)
5349                   and then not Atomic_Synchronization_Disabled (Typ))
5350       then
5351          Activate_Atomic_Synchronization (N);
5352       end if;
5353
5354       --  All done for the non-packed case
5355
5356       if not Is_Packed (Etype (Prefix (N))) then
5357          return;
5358       end if;
5359
5360       --  For packed arrays that are not bit-packed (i.e. the case of an array
5361       --  with one or more index types with a non-contiguous enumeration type),
5362       --  we can always use the normal packed element get circuit.
5363
5364       if not Is_Bit_Packed_Array (Etype (Prefix (N))) then
5365          Expand_Packed_Element_Reference (N);
5366          return;
5367       end if;
5368
5369       --  For a reference to a component of a bit packed array, we have to
5370       --  convert it to a reference to the corresponding Packed_Array_Type.
5371       --  We only want to do this for simple references, and not for:
5372
5373       --    Left side of assignment, or prefix of left side of assignment, or
5374       --    prefix of the prefix, to handle packed arrays of packed arrays,
5375       --      This case is handled in Exp_Ch5.Expand_N_Assignment_Statement
5376
5377       --    Renaming objects in renaming associations
5378       --      This case is handled when a use of the renamed variable occurs
5379
5380       --    Actual parameters for a procedure call
5381       --      This case is handled in Exp_Ch6.Expand_Actuals
5382
5383       --    The second expression in a 'Read attribute reference
5384
5385       --    The prefix of an address or bit or size attribute reference
5386
5387       --  The following circuit detects these exceptions
5388
5389       declare
5390          Child : Node_Id := N;
5391          Parnt : Node_Id := Parent (N);
5392
5393       begin
5394          loop
5395             if Nkind (Parnt) = N_Unchecked_Expression then
5396                null;
5397
5398             elsif Nkind_In (Parnt, N_Object_Renaming_Declaration,
5399                                    N_Procedure_Call_Statement)
5400               or else (Nkind (Parnt) = N_Parameter_Association
5401                         and then
5402                           Nkind (Parent (Parnt)) =  N_Procedure_Call_Statement)
5403             then
5404                return;
5405
5406             elsif Nkind (Parnt) = N_Attribute_Reference
5407               and then (Attribute_Name (Parnt) = Name_Address
5408                          or else
5409                         Attribute_Name (Parnt) = Name_Bit
5410                          or else
5411                         Attribute_Name (Parnt) = Name_Size)
5412               and then Prefix (Parnt) = Child
5413             then
5414                return;
5415
5416             elsif Nkind (Parnt) = N_Assignment_Statement
5417               and then Name (Parnt) = Child
5418             then
5419                return;
5420
5421             --  If the expression is an index of an indexed component, it must
5422             --  be expanded regardless of context.
5423
5424             elsif Nkind (Parnt) = N_Indexed_Component
5425               and then Child /= Prefix (Parnt)
5426             then
5427                Expand_Packed_Element_Reference (N);
5428                return;
5429
5430             elsif Nkind (Parent (Parnt)) = N_Assignment_Statement
5431               and then Name (Parent (Parnt)) = Parnt
5432             then
5433                return;
5434
5435             elsif Nkind (Parnt) = N_Attribute_Reference
5436               and then Attribute_Name (Parnt) = Name_Read
5437               and then Next (First (Expressions (Parnt))) = Child
5438             then
5439                return;
5440
5441             elsif Nkind_In (Parnt, N_Indexed_Component, N_Selected_Component)
5442                and then Prefix (Parnt) = Child
5443             then
5444                null;
5445
5446             else
5447                Expand_Packed_Element_Reference (N);
5448                return;
5449             end if;
5450
5451             --  Keep looking up tree for unchecked expression, or if we are the
5452             --  prefix of a possible assignment left side.
5453
5454             Child := Parnt;
5455             Parnt := Parent (Child);
5456          end loop;
5457       end;
5458    end Expand_N_Indexed_Component;
5459
5460    ---------------------
5461    -- Expand_N_Not_In --
5462    ---------------------
5463
5464    --  Replace a not in b by not (a in b) so that the expansions for (a in b)
5465    --  can be done. This avoids needing to duplicate this expansion code.
5466
5467    procedure Expand_N_Not_In (N : Node_Id) is
5468       Loc : constant Source_Ptr := Sloc (N);
5469       Typ : constant Entity_Id  := Etype (N);
5470       Cfs : constant Boolean    := Comes_From_Source (N);
5471
5472    begin
5473       Rewrite (N,
5474         Make_Op_Not (Loc,
5475           Right_Opnd =>
5476             Make_In (Loc,
5477               Left_Opnd  => Left_Opnd (N),
5478               Right_Opnd => Right_Opnd (N))));
5479
5480       --  If this is a set membership, preserve list of alternatives
5481
5482       Set_Alternatives (Right_Opnd (N), Alternatives (Original_Node (N)));
5483
5484       --  We want this to appear as coming from source if original does (see
5485       --  transformations in Expand_N_In).
5486
5487       Set_Comes_From_Source (N, Cfs);
5488       Set_Comes_From_Source (Right_Opnd (N), Cfs);
5489
5490       --  Now analyze transformed node
5491
5492       Analyze_And_Resolve (N, Typ);
5493    end Expand_N_Not_In;
5494
5495    -------------------
5496    -- Expand_N_Null --
5497    -------------------
5498
5499    --  The only replacement required is for the case of a null of a type that
5500    --  is an access to protected subprogram, or a subtype thereof. We represent
5501    --  such access values as a record, and so we must replace the occurrence of
5502    --  null by the equivalent record (with a null address and a null pointer in
5503    --  it), so that the backend creates the proper value.
5504
5505    procedure Expand_N_Null (N : Node_Id) is
5506       Loc : constant Source_Ptr := Sloc (N);
5507       Typ : constant Entity_Id  := Base_Type (Etype (N));
5508       Agg : Node_Id;
5509
5510    begin
5511       if Is_Access_Protected_Subprogram_Type (Typ) then
5512          Agg :=
5513            Make_Aggregate (Loc,
5514              Expressions => New_List (
5515                New_Occurrence_Of (RTE (RE_Null_Address), Loc),
5516                Make_Null (Loc)));
5517
5518          Rewrite (N, Agg);
5519          Analyze_And_Resolve (N, Equivalent_Type (Typ));
5520
5521          --  For subsequent semantic analysis, the node must retain its type.
5522          --  Gigi in any case replaces this type by the corresponding record
5523          --  type before processing the node.
5524
5525          Set_Etype (N, Typ);
5526       end if;
5527
5528    exception
5529       when RE_Not_Available =>
5530          return;
5531    end Expand_N_Null;
5532
5533    ---------------------
5534    -- Expand_N_Op_Abs --
5535    ---------------------
5536
5537    procedure Expand_N_Op_Abs (N : Node_Id) is
5538       Loc  : constant Source_Ptr := Sloc (N);
5539       Expr : constant Node_Id := Right_Opnd (N);
5540
5541    begin
5542       Unary_Op_Validity_Checks (N);
5543
5544       --  Deal with software overflow checking
5545
5546       if not Backend_Overflow_Checks_On_Target
5547          and then Is_Signed_Integer_Type (Etype (N))
5548          and then Do_Overflow_Check (N)
5549       then
5550          --  The only case to worry about is when the argument is equal to the
5551          --  largest negative number, so what we do is to insert the check:
5552
5553          --     [constraint_error when Expr = typ'Base'First]
5554
5555          --  with the usual Duplicate_Subexpr use coding for expr
5556
5557          Insert_Action (N,
5558            Make_Raise_Constraint_Error (Loc,
5559              Condition =>
5560                Make_Op_Eq (Loc,
5561                  Left_Opnd  => Duplicate_Subexpr (Expr),
5562                  Right_Opnd =>
5563                    Make_Attribute_Reference (Loc,
5564                      Prefix =>
5565                        New_Occurrence_Of (Base_Type (Etype (Expr)), Loc),
5566                      Attribute_Name => Name_First)),
5567              Reason => CE_Overflow_Check_Failed));
5568       end if;
5569
5570       --  Vax floating-point types case
5571
5572       if Vax_Float (Etype (N)) then
5573          Expand_Vax_Arith (N);
5574       end if;
5575    end Expand_N_Op_Abs;
5576
5577    ---------------------
5578    -- Expand_N_Op_Add --
5579    ---------------------
5580
5581    procedure Expand_N_Op_Add (N : Node_Id) is
5582       Typ : constant Entity_Id := Etype (N);
5583
5584    begin
5585       Binary_Op_Validity_Checks (N);
5586
5587       --  N + 0 = 0 + N = N for integer types
5588
5589       if Is_Integer_Type (Typ) then
5590          if Compile_Time_Known_Value (Right_Opnd (N))
5591            and then Expr_Value (Right_Opnd (N)) = Uint_0
5592          then
5593             Rewrite (N, Left_Opnd (N));
5594             return;
5595
5596          elsif Compile_Time_Known_Value (Left_Opnd (N))
5597            and then Expr_Value (Left_Opnd (N)) = Uint_0
5598          then
5599             Rewrite (N, Right_Opnd (N));
5600             return;
5601          end if;
5602       end if;
5603
5604       --  Arithmetic overflow checks for signed integer/fixed point types
5605
5606       if Is_Signed_Integer_Type (Typ)
5607         or else Is_Fixed_Point_Type (Typ)
5608       then
5609          Apply_Arithmetic_Overflow_Check (N);
5610          return;
5611
5612       --  Vax floating-point types case
5613
5614       elsif Vax_Float (Typ) then
5615          Expand_Vax_Arith (N);
5616       end if;
5617    end Expand_N_Op_Add;
5618
5619    ---------------------
5620    -- Expand_N_Op_And --
5621    ---------------------
5622
5623    procedure Expand_N_Op_And (N : Node_Id) is
5624       Typ : constant Entity_Id := Etype (N);
5625
5626    begin
5627       Binary_Op_Validity_Checks (N);
5628
5629       if Is_Array_Type (Etype (N)) then
5630          Expand_Boolean_Operator (N);
5631
5632       elsif Is_Boolean_Type (Etype (N)) then
5633          Adjust_Condition (Left_Opnd (N));
5634          Adjust_Condition (Right_Opnd (N));
5635          Set_Etype (N, Standard_Boolean);
5636          Adjust_Result_Type (N, Typ);
5637
5638       elsif Is_Intrinsic_Subprogram (Entity (N)) then
5639          Expand_Intrinsic_Call (N, Entity (N));
5640
5641       end if;
5642    end Expand_N_Op_And;
5643
5644    ------------------------
5645    -- Expand_N_Op_Concat --
5646    ------------------------
5647
5648    procedure Expand_N_Op_Concat (N : Node_Id) is
5649       Opnds : List_Id;
5650       --  List of operands to be concatenated
5651
5652       Cnode : Node_Id;
5653       --  Node which is to be replaced by the result of concatenating the nodes
5654       --  in the list Opnds.
5655
5656    begin
5657       --  Ensure validity of both operands
5658
5659       Binary_Op_Validity_Checks (N);
5660
5661       --  If we are the left operand of a concatenation higher up the tree,
5662       --  then do nothing for now, since we want to deal with a series of
5663       --  concatenations as a unit.
5664
5665       if Nkind (Parent (N)) = N_Op_Concat
5666         and then N = Left_Opnd (Parent (N))
5667       then
5668          return;
5669       end if;
5670
5671       --  We get here with a concatenation whose left operand may be a
5672       --  concatenation itself with a consistent type. We need to process
5673       --  these concatenation operands from left to right, which means
5674       --  from the deepest node in the tree to the highest node.
5675
5676       Cnode := N;
5677       while Nkind (Left_Opnd (Cnode)) = N_Op_Concat loop
5678          Cnode := Left_Opnd (Cnode);
5679       end loop;
5680
5681       --  Now Cnode is the deepest concatenation, and its parents are the
5682       --  concatenation nodes above, so now we process bottom up, doing the
5683       --  operations. We gather a string that is as long as possible up to five
5684       --  operands.
5685
5686       --  The outer loop runs more than once if more than one concatenation
5687       --  type is involved.
5688
5689       Outer : loop
5690          Opnds := New_List (Left_Opnd (Cnode), Right_Opnd (Cnode));
5691          Set_Parent (Opnds, N);
5692
5693          --  The inner loop gathers concatenation operands
5694
5695          Inner : while Cnode /= N
5696                    and then Base_Type (Etype (Cnode)) =
5697                             Base_Type (Etype (Parent (Cnode)))
5698          loop
5699             Cnode := Parent (Cnode);
5700             Append (Right_Opnd (Cnode), Opnds);
5701          end loop Inner;
5702
5703          Expand_Concatenate (Cnode, Opnds);
5704
5705          exit Outer when Cnode = N;
5706          Cnode := Parent (Cnode);
5707       end loop Outer;
5708    end Expand_N_Op_Concat;
5709
5710    ------------------------
5711    -- Expand_N_Op_Divide --
5712    ------------------------
5713
5714    procedure Expand_N_Op_Divide (N : Node_Id) is
5715       Loc   : constant Source_Ptr := Sloc (N);
5716       Lopnd : constant Node_Id    := Left_Opnd (N);
5717       Ropnd : constant Node_Id    := Right_Opnd (N);
5718       Ltyp  : constant Entity_Id  := Etype (Lopnd);
5719       Rtyp  : constant Entity_Id  := Etype (Ropnd);
5720       Typ   : Entity_Id           := Etype (N);
5721       Rknow : constant Boolean    := Is_Integer_Type (Typ)
5722                                        and then
5723                                          Compile_Time_Known_Value (Ropnd);
5724       Rval  : Uint;
5725
5726    begin
5727       Binary_Op_Validity_Checks (N);
5728
5729       if Rknow then
5730          Rval := Expr_Value (Ropnd);
5731       end if;
5732
5733       --  N / 1 = N for integer types
5734
5735       if Rknow and then Rval = Uint_1 then
5736          Rewrite (N, Lopnd);
5737          return;
5738       end if;
5739
5740       --  Convert x / 2 ** y to Shift_Right (x, y). Note that the fact that
5741       --  Is_Power_Of_2_For_Shift is set means that we know that our left
5742       --  operand is an unsigned integer, as required for this to work.
5743
5744       if Nkind (Ropnd) = N_Op_Expon
5745         and then Is_Power_Of_2_For_Shift (Ropnd)
5746
5747       --  We cannot do this transformation in configurable run time mode if we
5748       --  have 64-bit integers and long shifts are not available.
5749
5750         and then
5751           (Esize (Ltyp) <= 32
5752              or else Support_Long_Shifts_On_Target)
5753       then
5754          Rewrite (N,
5755            Make_Op_Shift_Right (Loc,
5756              Left_Opnd  => Lopnd,
5757              Right_Opnd =>
5758                Convert_To (Standard_Natural, Right_Opnd (Ropnd))));
5759          Analyze_And_Resolve (N, Typ);
5760          return;
5761       end if;
5762
5763       --  Do required fixup of universal fixed operation
5764
5765       if Typ = Universal_Fixed then
5766          Fixup_Universal_Fixed_Operation (N);
5767          Typ := Etype (N);
5768       end if;
5769
5770       --  Divisions with fixed-point results
5771
5772       if Is_Fixed_Point_Type (Typ) then
5773
5774          --  No special processing if Treat_Fixed_As_Integer is set, since
5775          --  from a semantic point of view such operations are simply integer
5776          --  operations and will be treated that way.
5777
5778          if not Treat_Fixed_As_Integer (N) then
5779             if Is_Integer_Type (Rtyp) then
5780                Expand_Divide_Fixed_By_Integer_Giving_Fixed (N);
5781             else
5782                Expand_Divide_Fixed_By_Fixed_Giving_Fixed (N);
5783             end if;
5784          end if;
5785
5786       --  Other cases of division of fixed-point operands. Again we exclude the
5787       --  case where Treat_Fixed_As_Integer is set.
5788
5789       elsif (Is_Fixed_Point_Type (Ltyp) or else
5790              Is_Fixed_Point_Type (Rtyp))
5791         and then not Treat_Fixed_As_Integer (N)
5792       then
5793          if Is_Integer_Type (Typ) then
5794             Expand_Divide_Fixed_By_Fixed_Giving_Integer (N);
5795          else
5796             pragma Assert (Is_Floating_Point_Type (Typ));
5797             Expand_Divide_Fixed_By_Fixed_Giving_Float (N);
5798          end if;
5799
5800       --  Mixed-mode operations can appear in a non-static universal context,
5801       --  in which case the integer argument must be converted explicitly.
5802
5803       elsif Typ = Universal_Real
5804         and then Is_Integer_Type (Rtyp)
5805       then
5806          Rewrite (Ropnd,
5807            Convert_To (Universal_Real, Relocate_Node (Ropnd)));
5808
5809          Analyze_And_Resolve (Ropnd, Universal_Real);
5810
5811       elsif Typ = Universal_Real
5812         and then Is_Integer_Type (Ltyp)
5813       then
5814          Rewrite (Lopnd,
5815            Convert_To (Universal_Real, Relocate_Node (Lopnd)));
5816
5817          Analyze_And_Resolve (Lopnd, Universal_Real);
5818
5819       --  Non-fixed point cases, do integer zero divide and overflow checks
5820
5821       elsif Is_Integer_Type (Typ) then
5822          Apply_Divide_Check (N);
5823
5824       --  Deal with Vax_Float
5825
5826       elsif Vax_Float (Typ) then
5827          Expand_Vax_Arith (N);
5828          return;
5829       end if;
5830    end Expand_N_Op_Divide;
5831
5832    --------------------
5833    -- Expand_N_Op_Eq --
5834    --------------------
5835
5836    procedure Expand_N_Op_Eq (N : Node_Id) is
5837       Loc    : constant Source_Ptr := Sloc (N);
5838       Typ    : constant Entity_Id  := Etype (N);
5839       Lhs    : constant Node_Id    := Left_Opnd (N);
5840       Rhs    : constant Node_Id    := Right_Opnd (N);
5841       Bodies : constant List_Id    := New_List;
5842       A_Typ  : constant Entity_Id  := Etype (Lhs);
5843
5844       Typl    : Entity_Id := A_Typ;
5845       Op_Name : Entity_Id;
5846       Prim    : Elmt_Id;
5847
5848       procedure Build_Equality_Call (Eq : Entity_Id);
5849       --  If a constructed equality exists for the type or for its parent,
5850       --  build and analyze call, adding conversions if the operation is
5851       --  inherited.
5852
5853       function Has_Unconstrained_UU_Component (Typ : Node_Id) return Boolean;
5854       --  Determines whether a type has a subcomponent of an unconstrained
5855       --  Unchecked_Union subtype. Typ is a record type.
5856
5857       -------------------------
5858       -- Build_Equality_Call --
5859       -------------------------
5860
5861       procedure Build_Equality_Call (Eq : Entity_Id) is
5862          Op_Type : constant Entity_Id := Etype (First_Formal (Eq));
5863          L_Exp   : Node_Id := Relocate_Node (Lhs);
5864          R_Exp   : Node_Id := Relocate_Node (Rhs);
5865
5866       begin
5867          if Base_Type (Op_Type) /= Base_Type (A_Typ)
5868            and then not Is_Class_Wide_Type (A_Typ)
5869          then
5870             L_Exp := OK_Convert_To (Op_Type, L_Exp);
5871             R_Exp := OK_Convert_To (Op_Type, R_Exp);
5872          end if;
5873
5874          --  If we have an Unchecked_Union, we need to add the inferred
5875          --  discriminant values as actuals in the function call. At this
5876          --  point, the expansion has determined that both operands have
5877          --  inferable discriminants.
5878
5879          if Is_Unchecked_Union (Op_Type) then
5880             declare
5881                Lhs_Type      : constant Node_Id := Etype (L_Exp);
5882                Rhs_Type      : constant Node_Id := Etype (R_Exp);
5883                Lhs_Discr_Val : Node_Id;
5884                Rhs_Discr_Val : Node_Id;
5885
5886             begin
5887                --  Per-object constrained selected components require special
5888                --  attention. If the enclosing scope of the component is an
5889                --  Unchecked_Union, we cannot reference its discriminants
5890                --  directly. This is why we use the two extra parameters of
5891                --  the equality function of the enclosing Unchecked_Union.
5892
5893                --  type UU_Type (Discr : Integer := 0) is
5894                --     . . .
5895                --  end record;
5896                --  pragma Unchecked_Union (UU_Type);
5897
5898                --  1. Unchecked_Union enclosing record:
5899
5900                --     type Enclosing_UU_Type (Discr : Integer := 0) is record
5901                --        . . .
5902                --        Comp : UU_Type (Discr);
5903                --        . . .
5904                --     end Enclosing_UU_Type;
5905                --     pragma Unchecked_Union (Enclosing_UU_Type);
5906
5907                --     Obj1 : Enclosing_UU_Type;
5908                --     Obj2 : Enclosing_UU_Type (1);
5909
5910                --     [. . .] Obj1 = Obj2 [. . .]
5911
5912                --     Generated code:
5913
5914                --     if not (uu_typeEQ (obj1.comp, obj2.comp, a, b)) then
5915
5916                --  A and B are the formal parameters of the equality function
5917                --  of Enclosing_UU_Type. The function always has two extra
5918                --  formals to capture the inferred discriminant values.
5919
5920                --  2. Non-Unchecked_Union enclosing record:
5921
5922                --     type
5923                --       Enclosing_Non_UU_Type (Discr : Integer := 0)
5924                --     is record
5925                --        . . .
5926                --        Comp : UU_Type (Discr);
5927                --        . . .
5928                --     end Enclosing_Non_UU_Type;
5929
5930                --     Obj1 : Enclosing_Non_UU_Type;
5931                --     Obj2 : Enclosing_Non_UU_Type (1);
5932
5933                --     ...  Obj1 = Obj2 ...
5934
5935                --     Generated code:
5936
5937                --     if not (uu_typeEQ (obj1.comp, obj2.comp,
5938                --                        obj1.discr, obj2.discr)) then
5939
5940                --  In this case we can directly reference the discriminants of
5941                --  the enclosing record.
5942
5943                --  Lhs of equality
5944
5945                if Nkind (Lhs) = N_Selected_Component
5946                  and then Has_Per_Object_Constraint
5947                             (Entity (Selector_Name (Lhs)))
5948                then
5949                   --  Enclosing record is an Unchecked_Union, use formal A
5950
5951                   if Is_Unchecked_Union
5952                        (Scope (Entity (Selector_Name (Lhs))))
5953                   then
5954                      Lhs_Discr_Val := Make_Identifier (Loc, Name_A);
5955
5956                   --  Enclosing record is of a non-Unchecked_Union type, it is
5957                   --  possible to reference the discriminant.
5958
5959                   else
5960                      Lhs_Discr_Val :=
5961                        Make_Selected_Component (Loc,
5962                          Prefix => Prefix (Lhs),
5963                          Selector_Name =>
5964                            New_Copy
5965                              (Get_Discriminant_Value
5966                                 (First_Discriminant (Lhs_Type),
5967                                  Lhs_Type,
5968                                  Stored_Constraint (Lhs_Type))));
5969                   end if;
5970
5971                --  Comment needed here ???
5972
5973                else
5974                   --  Infer the discriminant value
5975
5976                   Lhs_Discr_Val :=
5977                     New_Copy
5978                       (Get_Discriminant_Value
5979                          (First_Discriminant (Lhs_Type),
5980                           Lhs_Type,
5981                           Stored_Constraint (Lhs_Type)));
5982                end if;
5983
5984                --  Rhs of equality
5985
5986                if Nkind (Rhs) = N_Selected_Component
5987                  and then Has_Per_Object_Constraint
5988                             (Entity (Selector_Name (Rhs)))
5989                then
5990                   if Is_Unchecked_Union
5991                        (Scope (Entity (Selector_Name (Rhs))))
5992                   then
5993                      Rhs_Discr_Val := Make_Identifier (Loc, Name_B);
5994
5995                   else
5996                      Rhs_Discr_Val :=
5997                        Make_Selected_Component (Loc,
5998                          Prefix => Prefix (Rhs),
5999                          Selector_Name =>
6000                            New_Copy (Get_Discriminant_Value (
6001                              First_Discriminant (Rhs_Type),
6002                              Rhs_Type,
6003                              Stored_Constraint (Rhs_Type))));
6004
6005                   end if;
6006                else
6007                   Rhs_Discr_Val :=
6008                     New_Copy (Get_Discriminant_Value (
6009                       First_Discriminant (Rhs_Type),
6010                       Rhs_Type,
6011                       Stored_Constraint (Rhs_Type)));
6012
6013                end if;
6014
6015                Rewrite (N,
6016                  Make_Function_Call (Loc,
6017                    Name => New_Reference_To (Eq, Loc),
6018                    Parameter_Associations => New_List (
6019                      L_Exp,
6020                      R_Exp,
6021                      Lhs_Discr_Val,
6022                      Rhs_Discr_Val)));
6023             end;
6024
6025          --  Normal case, not an unchecked union
6026
6027          else
6028             Rewrite (N,
6029               Make_Function_Call (Loc,
6030                 Name => New_Reference_To (Eq, Loc),
6031                 Parameter_Associations => New_List (L_Exp, R_Exp)));
6032          end if;
6033
6034          Analyze_And_Resolve (N, Standard_Boolean, Suppress => All_Checks);
6035       end Build_Equality_Call;
6036
6037       ------------------------------------
6038       -- Has_Unconstrained_UU_Component --
6039       ------------------------------------
6040
6041       function Has_Unconstrained_UU_Component
6042         (Typ : Node_Id) return Boolean
6043       is
6044          Tdef  : constant Node_Id :=
6045                    Type_Definition (Declaration_Node (Base_Type (Typ)));
6046          Clist : Node_Id;
6047          Vpart : Node_Id;
6048
6049          function Component_Is_Unconstrained_UU
6050            (Comp : Node_Id) return Boolean;
6051          --  Determines whether the subtype of the component is an
6052          --  unconstrained Unchecked_Union.
6053
6054          function Variant_Is_Unconstrained_UU
6055            (Variant : Node_Id) return Boolean;
6056          --  Determines whether a component of the variant has an unconstrained
6057          --  Unchecked_Union subtype.
6058
6059          -----------------------------------
6060          -- Component_Is_Unconstrained_UU --
6061          -----------------------------------
6062
6063          function Component_Is_Unconstrained_UU
6064            (Comp : Node_Id) return Boolean
6065          is
6066          begin
6067             if Nkind (Comp) /= N_Component_Declaration then
6068                return False;
6069             end if;
6070
6071             declare
6072                Sindic : constant Node_Id :=
6073                           Subtype_Indication (Component_Definition (Comp));
6074
6075             begin
6076                --  Unconstrained nominal type. In the case of a constraint
6077                --  present, the node kind would have been N_Subtype_Indication.
6078
6079                if Nkind (Sindic) = N_Identifier then
6080                   return Is_Unchecked_Union (Base_Type (Etype (Sindic)));
6081                end if;
6082
6083                return False;
6084             end;
6085          end Component_Is_Unconstrained_UU;
6086
6087          ---------------------------------
6088          -- Variant_Is_Unconstrained_UU --
6089          ---------------------------------
6090
6091          function Variant_Is_Unconstrained_UU
6092            (Variant : Node_Id) return Boolean
6093          is
6094             Clist : constant Node_Id := Component_List (Variant);
6095
6096          begin
6097             if Is_Empty_List (Component_Items (Clist)) then
6098                return False;
6099             end if;
6100
6101             --  We only need to test one component
6102
6103             declare
6104                Comp : Node_Id := First (Component_Items (Clist));
6105
6106             begin
6107                while Present (Comp) loop
6108                   if Component_Is_Unconstrained_UU (Comp) then
6109                      return True;
6110                   end if;
6111
6112                   Next (Comp);
6113                end loop;
6114             end;
6115
6116             --  None of the components withing the variant were of
6117             --  unconstrained Unchecked_Union type.
6118
6119             return False;
6120          end Variant_Is_Unconstrained_UU;
6121
6122       --  Start of processing for Has_Unconstrained_UU_Component
6123
6124       begin
6125          if Null_Present (Tdef) then
6126             return False;
6127          end if;
6128
6129          Clist := Component_List (Tdef);
6130          Vpart := Variant_Part (Clist);
6131
6132          --  Inspect available components
6133
6134          if Present (Component_Items (Clist)) then
6135             declare
6136                Comp : Node_Id := First (Component_Items (Clist));
6137
6138             begin
6139                while Present (Comp) loop
6140
6141                   --  One component is sufficient
6142
6143                   if Component_Is_Unconstrained_UU (Comp) then
6144                      return True;
6145                   end if;
6146
6147                   Next (Comp);
6148                end loop;
6149             end;
6150          end if;
6151
6152          --  Inspect available components withing variants
6153
6154          if Present (Vpart) then
6155             declare
6156                Variant : Node_Id := First (Variants (Vpart));
6157
6158             begin
6159                while Present (Variant) loop
6160
6161                   --  One component within a variant is sufficient
6162
6163                   if Variant_Is_Unconstrained_UU (Variant) then
6164                      return True;
6165                   end if;
6166
6167                   Next (Variant);
6168                end loop;
6169             end;
6170          end if;
6171
6172          --  Neither the available components, nor the components inside the
6173          --  variant parts were of an unconstrained Unchecked_Union subtype.
6174
6175          return False;
6176       end Has_Unconstrained_UU_Component;
6177
6178    --  Start of processing for Expand_N_Op_Eq
6179
6180    begin
6181       Binary_Op_Validity_Checks (N);
6182
6183       if Ekind (Typl) = E_Private_Type then
6184          Typl := Underlying_Type (Typl);
6185       elsif Ekind (Typl) = E_Private_Subtype then
6186          Typl := Underlying_Type (Base_Type (Typl));
6187       else
6188          null;
6189       end if;
6190
6191       --  It may happen in error situations that the underlying type is not
6192       --  set. The error will be detected later, here we just defend the
6193       --  expander code.
6194
6195       if No (Typl) then
6196          return;
6197       end if;
6198
6199       Typl := Base_Type (Typl);
6200
6201       --  Boolean types (requiring handling of non-standard case)
6202
6203       if Is_Boolean_Type (Typl) then
6204          Adjust_Condition (Left_Opnd (N));
6205          Adjust_Condition (Right_Opnd (N));
6206          Set_Etype (N, Standard_Boolean);
6207          Adjust_Result_Type (N, Typ);
6208
6209       --  Array types
6210
6211       elsif Is_Array_Type (Typl) then
6212
6213          --  If we are doing full validity checking, and it is possible for the
6214          --  array elements to be invalid then expand out array comparisons to
6215          --  make sure that we check the array elements.
6216
6217          if Validity_Check_Operands
6218            and then not Is_Known_Valid (Component_Type (Typl))
6219          then
6220             declare
6221                Save_Force_Validity_Checks : constant Boolean :=
6222                                               Force_Validity_Checks;
6223             begin
6224                Force_Validity_Checks := True;
6225                Rewrite (N,
6226                  Expand_Array_Equality
6227                   (N,
6228                    Relocate_Node (Lhs),
6229                    Relocate_Node (Rhs),
6230                    Bodies,
6231                    Typl));
6232                Insert_Actions (N, Bodies);
6233                Analyze_And_Resolve (N, Standard_Boolean);
6234                Force_Validity_Checks := Save_Force_Validity_Checks;
6235             end;
6236
6237          --  Packed case where both operands are known aligned
6238
6239          elsif Is_Bit_Packed_Array (Typl)
6240            and then not Is_Possibly_Unaligned_Object (Lhs)
6241            and then not Is_Possibly_Unaligned_Object (Rhs)
6242          then
6243             Expand_Packed_Eq (N);
6244
6245          --  Where the component type is elementary we can use a block bit
6246          --  comparison (if supported on the target) exception in the case
6247          --  of floating-point (negative zero issues require element by
6248          --  element comparison), and atomic types (where we must be sure
6249          --  to load elements independently) and possibly unaligned arrays.
6250
6251          elsif Is_Elementary_Type (Component_Type (Typl))
6252            and then not Is_Floating_Point_Type (Component_Type (Typl))
6253            and then not Is_Atomic (Component_Type (Typl))
6254            and then not Is_Possibly_Unaligned_Object (Lhs)
6255            and then not Is_Possibly_Unaligned_Object (Rhs)
6256            and then Support_Composite_Compare_On_Target
6257          then
6258             null;
6259
6260          --  For composite and floating-point cases, expand equality loop to
6261          --  make sure of using proper comparisons for tagged types, and
6262          --  correctly handling the floating-point case.
6263
6264          else
6265             Rewrite (N,
6266               Expand_Array_Equality
6267                 (N,
6268                  Relocate_Node (Lhs),
6269                  Relocate_Node (Rhs),
6270                  Bodies,
6271                  Typl));
6272             Insert_Actions      (N, Bodies,           Suppress => All_Checks);
6273             Analyze_And_Resolve (N, Standard_Boolean, Suppress => All_Checks);
6274          end if;
6275
6276       --  Record Types
6277
6278       elsif Is_Record_Type (Typl) then
6279
6280          --  For tagged types, use the primitive "="
6281
6282          if Is_Tagged_Type (Typl) then
6283
6284             --  No need to do anything else compiling under restriction
6285             --  No_Dispatching_Calls. During the semantic analysis we
6286             --  already notified such violation.
6287
6288             if Restriction_Active (No_Dispatching_Calls) then
6289                return;
6290             end if;
6291
6292             --  If this is derived from an untagged private type completed with
6293             --  a tagged type, it does not have a full view, so we use the
6294             --  primitive operations of the private type. This check should no
6295             --  longer be necessary when these types get their full views???
6296
6297             if Is_Private_Type (A_Typ)
6298               and then not Is_Tagged_Type (A_Typ)
6299               and then Is_Derived_Type (A_Typ)
6300               and then No (Full_View (A_Typ))
6301             then
6302                --  Search for equality operation, checking that the operands
6303                --  have the same type. Note that we must find a matching entry,
6304                --  or something is very wrong!
6305
6306                Prim := First_Elmt (Collect_Primitive_Operations (A_Typ));
6307
6308                while Present (Prim) loop
6309                   exit when Chars (Node (Prim)) = Name_Op_Eq
6310                     and then Etype (First_Formal (Node (Prim))) =
6311                              Etype (Next_Formal (First_Formal (Node (Prim))))
6312                     and then
6313                       Base_Type (Etype (Node (Prim))) = Standard_Boolean;
6314
6315                   Next_Elmt (Prim);
6316                end loop;
6317
6318                pragma Assert (Present (Prim));
6319                Op_Name := Node (Prim);
6320
6321             --  Find the type's predefined equality or an overriding
6322             --  user- defined equality. The reason for not simply calling
6323             --  Find_Prim_Op here is that there may be a user-defined
6324             --  overloaded equality op that precedes the equality that we want,
6325             --  so we have to explicitly search (e.g., there could be an
6326             --  equality with two different parameter types).
6327
6328             else
6329                if Is_Class_Wide_Type (Typl) then
6330                   Typl := Root_Type (Typl);
6331                end if;
6332
6333                Prim := First_Elmt (Primitive_Operations (Typl));
6334                while Present (Prim) loop
6335                   exit when Chars (Node (Prim)) = Name_Op_Eq
6336                     and then Etype (First_Formal (Node (Prim))) =
6337                              Etype (Next_Formal (First_Formal (Node (Prim))))
6338                     and then
6339                       Base_Type (Etype (Node (Prim))) = Standard_Boolean;
6340
6341                   Next_Elmt (Prim);
6342                end loop;
6343
6344                pragma Assert (Present (Prim));
6345                Op_Name := Node (Prim);
6346             end if;
6347
6348             Build_Equality_Call (Op_Name);
6349
6350          --  Ada 2005 (AI-216): Program_Error is raised when evaluating the
6351          --  predefined equality operator for a type which has a subcomponent
6352          --  of an Unchecked_Union type whose nominal subtype is unconstrained.
6353
6354          elsif Has_Unconstrained_UU_Component (Typl) then
6355             Insert_Action (N,
6356               Make_Raise_Program_Error (Loc,
6357                 Reason => PE_Unchecked_Union_Restriction));
6358
6359             --  Prevent Gigi from generating incorrect code by rewriting the
6360             --  equality as a standard False.
6361
6362             Rewrite (N,
6363               New_Occurrence_Of (Standard_False, Loc));
6364
6365          elsif Is_Unchecked_Union (Typl) then
6366
6367             --  If we can infer the discriminants of the operands, we make a
6368             --  call to the TSS equality function.
6369
6370             if Has_Inferable_Discriminants (Lhs)
6371                  and then
6372                Has_Inferable_Discriminants (Rhs)
6373             then
6374                Build_Equality_Call
6375                  (TSS (Root_Type (Typl), TSS_Composite_Equality));
6376
6377             else
6378                --  Ada 2005 (AI-216): Program_Error is raised when evaluating
6379                --  the predefined equality operator for an Unchecked_Union type
6380                --  if either of the operands lack inferable discriminants.
6381
6382                Insert_Action (N,
6383                  Make_Raise_Program_Error (Loc,
6384                    Reason => PE_Unchecked_Union_Restriction));
6385
6386                --  Prevent Gigi from generating incorrect code by rewriting
6387                --  the equality as a standard False.
6388
6389                Rewrite (N,
6390                  New_Occurrence_Of (Standard_False, Loc));
6391
6392             end if;
6393
6394          --  If a type support function is present (for complex cases), use it
6395
6396          elsif Present (TSS (Root_Type (Typl), TSS_Composite_Equality)) then
6397             Build_Equality_Call
6398               (TSS (Root_Type (Typl), TSS_Composite_Equality));
6399
6400          --  Otherwise expand the component by component equality. Note that
6401          --  we never use block-bit comparisons for records, because of the
6402          --  problems with gaps. The backend will often be able to recombine
6403          --  the separate comparisons that we generate here.
6404
6405          else
6406             Remove_Side_Effects (Lhs);
6407             Remove_Side_Effects (Rhs);
6408             Rewrite (N,
6409               Expand_Record_Equality (N, Typl, Lhs, Rhs, Bodies));
6410
6411             Insert_Actions      (N, Bodies,           Suppress => All_Checks);
6412             Analyze_And_Resolve (N, Standard_Boolean, Suppress => All_Checks);
6413          end if;
6414       end if;
6415
6416       --  Test if result is known at compile time
6417
6418       Rewrite_Comparison (N);
6419
6420       --  If we still have comparison for Vax_Float, process it
6421
6422       if Vax_Float (Typl) and then Nkind (N) in N_Op_Compare  then
6423          Expand_Vax_Comparison (N);
6424          return;
6425       end if;
6426
6427       Optimize_Length_Comparison (N);
6428    end Expand_N_Op_Eq;
6429
6430    -----------------------
6431    -- Expand_N_Op_Expon --
6432    -----------------------
6433
6434    procedure Expand_N_Op_Expon (N : Node_Id) is
6435       Loc    : constant Source_Ptr := Sloc (N);
6436       Typ    : constant Entity_Id  := Etype (N);
6437       Rtyp   : constant Entity_Id  := Root_Type (Typ);
6438       Base   : constant Node_Id    := Relocate_Node (Left_Opnd (N));
6439       Bastyp : constant Node_Id    := Etype (Base);
6440       Exp    : constant Node_Id    := Relocate_Node (Right_Opnd (N));
6441       Exptyp : constant Entity_Id  := Etype (Exp);
6442       Ovflo  : constant Boolean    := Do_Overflow_Check (N);
6443       Expv   : Uint;
6444       Xnode  : Node_Id;
6445       Temp   : Node_Id;
6446       Rent   : RE_Id;
6447       Ent    : Entity_Id;
6448       Etyp   : Entity_Id;
6449
6450    begin
6451       Binary_Op_Validity_Checks (N);
6452
6453       --  CodePeer and GNATprove want to see the unexpanded N_Op_Expon node
6454
6455       if CodePeer_Mode or Alfa_Mode then
6456          return;
6457       end if;
6458
6459       --  If either operand is of a private type, then we have the use of an
6460       --  intrinsic operator, and we get rid of the privateness, by using root
6461       --  types of underlying types for the actual operation. Otherwise the
6462       --  private types will cause trouble if we expand multiplications or
6463       --  shifts etc. We also do this transformation if the result type is
6464       --  different from the base type.
6465
6466       if Is_Private_Type (Etype (Base))
6467         or else Is_Private_Type (Typ)
6468         or else Is_Private_Type (Exptyp)
6469         or else Rtyp /= Root_Type (Bastyp)
6470       then
6471          declare
6472             Bt : constant Entity_Id := Root_Type (Underlying_Type (Bastyp));
6473             Et : constant Entity_Id := Root_Type (Underlying_Type (Exptyp));
6474
6475          begin
6476             Rewrite (N,
6477               Unchecked_Convert_To (Typ,
6478                 Make_Op_Expon (Loc,
6479                   Left_Opnd  => Unchecked_Convert_To (Bt, Base),
6480                   Right_Opnd => Unchecked_Convert_To (Et, Exp))));
6481             Analyze_And_Resolve (N, Typ);
6482             return;
6483          end;
6484       end if;
6485
6486       --  Test for case of known right argument
6487
6488       if Compile_Time_Known_Value (Exp) then
6489          Expv := Expr_Value (Exp);
6490
6491          --  We only fold small non-negative exponents. You might think we
6492          --  could fold small negative exponents for the real case, but we
6493          --  can't because we are required to raise Constraint_Error for
6494          --  the case of 0.0 ** (negative) even if Machine_Overflows = False.
6495          --  See ACVC test C4A012B.
6496
6497          if Expv >= 0 and then Expv <= 4 then
6498
6499             --  X ** 0 = 1 (or 1.0)
6500
6501             if Expv = 0 then
6502
6503                --  Call Remove_Side_Effects to ensure that any side effects
6504                --  in the ignored left operand (in particular function calls
6505                --  to user defined functions) are properly executed.
6506
6507                Remove_Side_Effects (Base);
6508
6509                if Ekind (Typ) in Integer_Kind then
6510                   Xnode := Make_Integer_Literal (Loc, Intval => 1);
6511                else
6512                   Xnode := Make_Real_Literal (Loc, Ureal_1);
6513                end if;
6514
6515             --  X ** 1 = X
6516
6517             elsif Expv = 1 then
6518                Xnode := Base;
6519
6520             --  X ** 2 = X * X
6521
6522             elsif Expv = 2 then
6523                Xnode :=
6524                  Make_Op_Multiply (Loc,
6525                    Left_Opnd  => Duplicate_Subexpr (Base),
6526                    Right_Opnd => Duplicate_Subexpr_No_Checks (Base));
6527
6528             --  X ** 3 = X * X * X
6529
6530             elsif Expv = 3 then
6531                Xnode :=
6532                  Make_Op_Multiply (Loc,
6533                    Left_Opnd =>
6534                      Make_Op_Multiply (Loc,
6535                        Left_Opnd  => Duplicate_Subexpr (Base),
6536                        Right_Opnd => Duplicate_Subexpr_No_Checks (Base)),
6537                    Right_Opnd  => Duplicate_Subexpr_No_Checks (Base));
6538
6539             --  X ** 4  ->
6540             --    En : constant base'type := base * base;
6541             --    ...
6542             --    En * En
6543
6544             else -- Expv = 4
6545                Temp := Make_Temporary (Loc, 'E', Base);
6546
6547                Insert_Actions (N, New_List (
6548                  Make_Object_Declaration (Loc,
6549                    Defining_Identifier => Temp,
6550                    Constant_Present    => True,
6551                    Object_Definition   => New_Reference_To (Typ, Loc),
6552                    Expression =>
6553                      Make_Op_Multiply (Loc,
6554                        Left_Opnd  => Duplicate_Subexpr (Base),
6555                        Right_Opnd => Duplicate_Subexpr_No_Checks (Base)))));
6556
6557                Xnode :=
6558                  Make_Op_Multiply (Loc,
6559                    Left_Opnd  => New_Reference_To (Temp, Loc),
6560                    Right_Opnd => New_Reference_To (Temp, Loc));
6561             end if;
6562
6563             Rewrite (N, Xnode);
6564             Analyze_And_Resolve (N, Typ);
6565             return;
6566          end if;
6567       end if;
6568
6569       --  Case of (2 ** expression) appearing as an argument of an integer
6570       --  multiplication, or as the right argument of a division of a non-
6571       --  negative integer. In such cases we leave the node untouched, setting
6572       --  the flag Is_Natural_Power_Of_2_for_Shift set, then the expansion
6573       --  of the higher level node converts it into a shift.
6574
6575       --  Another case is 2 ** N in any other context. We simply convert
6576       --  this to 1 * 2 ** N, and then the above transformation applies.
6577
6578       --  Note: this transformation is not applicable for a modular type with
6579       --  a non-binary modulus in the multiplication case, since we get a wrong
6580       --  result if the shift causes an overflow before the modular reduction.
6581
6582       if Nkind (Base) = N_Integer_Literal
6583         and then Intval (Base) = 2
6584         and then Is_Integer_Type (Root_Type (Exptyp))
6585         and then Esize (Root_Type (Exptyp)) <= Esize (Standard_Integer)
6586         and then Is_Unsigned_Type (Exptyp)
6587         and then not Ovflo
6588       then
6589          --  First the multiply and divide cases
6590
6591          if Nkind_In (Parent (N), N_Op_Divide, N_Op_Multiply) then
6592             declare
6593                P : constant Node_Id := Parent (N);
6594                L : constant Node_Id := Left_Opnd (P);
6595                R : constant Node_Id := Right_Opnd (P);
6596
6597             begin
6598                if (Nkind (P) = N_Op_Multiply
6599                    and then not Non_Binary_Modulus (Typ)
6600                    and then
6601                      ((Is_Integer_Type (Etype (L)) and then R = N)
6602                          or else
6603                       (Is_Integer_Type (Etype (R)) and then L = N))
6604                    and then not Do_Overflow_Check (P))
6605                  or else
6606                   (Nkind (P) = N_Op_Divide
6607                      and then Is_Integer_Type (Etype (L))
6608                      and then Is_Unsigned_Type (Etype (L))
6609                      and then R = N
6610                      and then not Do_Overflow_Check (P))
6611                then
6612                   Set_Is_Power_Of_2_For_Shift (N);
6613                   return;
6614                end if;
6615             end;
6616
6617          --  Now the other cases
6618
6619          elsif not Non_Binary_Modulus (Typ) then
6620             Rewrite (N,
6621               Make_Op_Multiply (Loc,
6622                 Left_Opnd  => Make_Integer_Literal (Loc, 1),
6623                 Right_Opnd => Relocate_Node (N)));
6624             Analyze_And_Resolve (N, Typ);
6625             return;
6626          end if;
6627       end if;
6628
6629       --  Fall through if exponentiation must be done using a runtime routine
6630
6631       --  First deal with modular case
6632
6633       if Is_Modular_Integer_Type (Rtyp) then
6634
6635          --  Non-binary case, we call the special exponentiation routine for
6636          --  the non-binary case, converting the argument to Long_Long_Integer
6637          --  and passing the modulus value. Then the result is converted back
6638          --  to the base type.
6639
6640          if Non_Binary_Modulus (Rtyp) then
6641             Rewrite (N,
6642               Convert_To (Typ,
6643                 Make_Function_Call (Loc,
6644                   Name => New_Reference_To (RTE (RE_Exp_Modular), Loc),
6645                   Parameter_Associations => New_List (
6646                     Convert_To (Standard_Integer, Base),
6647                     Make_Integer_Literal (Loc, Modulus (Rtyp)),
6648                     Exp))));
6649
6650          --  Binary case, in this case, we call one of two routines, either the
6651          --  unsigned integer case, or the unsigned long long integer case,
6652          --  with a final "and" operation to do the required mod.
6653
6654          else
6655             if UI_To_Int (Esize (Rtyp)) <= Standard_Integer_Size then
6656                Ent := RTE (RE_Exp_Unsigned);
6657             else
6658                Ent := RTE (RE_Exp_Long_Long_Unsigned);
6659             end if;
6660
6661             Rewrite (N,
6662               Convert_To (Typ,
6663                 Make_Op_And (Loc,
6664                   Left_Opnd =>
6665                     Make_Function_Call (Loc,
6666                       Name => New_Reference_To (Ent, Loc),
6667                       Parameter_Associations => New_List (
6668                         Convert_To (Etype (First_Formal (Ent)), Base),
6669                         Exp)),
6670                    Right_Opnd =>
6671                      Make_Integer_Literal (Loc, Modulus (Rtyp) - 1))));
6672
6673          end if;
6674
6675          --  Common exit point for modular type case
6676
6677          Analyze_And_Resolve (N, Typ);
6678          return;
6679
6680       --  Signed integer cases, done using either Integer or Long_Long_Integer.
6681       --  It is not worth having routines for Short_[Short_]Integer, since for
6682       --  most machines it would not help, and it would generate more code that
6683       --  might need certification when a certified run time is required.
6684
6685       --  In the integer cases, we have two routines, one for when overflow
6686       --  checks are required, and one when they are not required, since there
6687       --  is a real gain in omitting checks on many machines.
6688
6689       elsif Rtyp = Base_Type (Standard_Long_Long_Integer)
6690         or else (Rtyp = Base_Type (Standard_Long_Integer)
6691                    and then
6692                      Esize (Standard_Long_Integer) > Esize (Standard_Integer))
6693         or else (Rtyp = Universal_Integer)
6694       then
6695          Etyp := Standard_Long_Long_Integer;
6696
6697          if Ovflo then
6698             Rent := RE_Exp_Long_Long_Integer;
6699          else
6700             Rent := RE_Exn_Long_Long_Integer;
6701          end if;
6702
6703       elsif Is_Signed_Integer_Type (Rtyp) then
6704          Etyp := Standard_Integer;
6705
6706          if Ovflo then
6707             Rent := RE_Exp_Integer;
6708          else
6709             Rent := RE_Exn_Integer;
6710          end if;
6711
6712       --  Floating-point cases, always done using Long_Long_Float. We do not
6713       --  need separate routines for the overflow case here, since in the case
6714       --  of floating-point, we generate infinities anyway as a rule (either
6715       --  that or we automatically trap overflow), and if there is an infinity
6716       --  generated and a range check is required, the check will fail anyway.
6717
6718       else
6719          pragma Assert (Is_Floating_Point_Type (Rtyp));
6720          Etyp := Standard_Long_Long_Float;
6721          Rent := RE_Exn_Long_Long_Float;
6722       end if;
6723
6724       --  Common processing for integer cases and floating-point cases.
6725       --  If we are in the right type, we can call runtime routine directly
6726
6727       if Typ = Etyp
6728         and then Rtyp /= Universal_Integer
6729         and then Rtyp /= Universal_Real
6730       then
6731          Rewrite (N,
6732            Make_Function_Call (Loc,
6733              Name => New_Reference_To (RTE (Rent), Loc),
6734              Parameter_Associations => New_List (Base, Exp)));
6735
6736       --  Otherwise we have to introduce conversions (conversions are also
6737       --  required in the universal cases, since the runtime routine is
6738       --  typed using one of the standard types).
6739
6740       else
6741          Rewrite (N,
6742            Convert_To (Typ,
6743              Make_Function_Call (Loc,
6744                Name => New_Reference_To (RTE (Rent), Loc),
6745                Parameter_Associations => New_List (
6746                  Convert_To (Etyp, Base),
6747                  Exp))));
6748       end if;
6749
6750       Analyze_And_Resolve (N, Typ);
6751       return;
6752
6753    exception
6754       when RE_Not_Available =>
6755          return;
6756    end Expand_N_Op_Expon;
6757
6758    --------------------
6759    -- Expand_N_Op_Ge --
6760    --------------------
6761
6762    procedure Expand_N_Op_Ge (N : Node_Id) is
6763       Typ  : constant Entity_Id := Etype (N);
6764       Op1  : constant Node_Id   := Left_Opnd (N);
6765       Op2  : constant Node_Id   := Right_Opnd (N);
6766       Typ1 : constant Entity_Id := Base_Type (Etype (Op1));
6767
6768    begin
6769       Binary_Op_Validity_Checks (N);
6770
6771       if Is_Array_Type (Typ1) then
6772          Expand_Array_Comparison (N);
6773          return;
6774       end if;
6775
6776       if Is_Boolean_Type (Typ1) then
6777          Adjust_Condition (Op1);
6778          Adjust_Condition (Op2);
6779          Set_Etype (N, Standard_Boolean);
6780          Adjust_Result_Type (N, Typ);
6781       end if;
6782
6783       Rewrite_Comparison (N);
6784
6785       --  If we still have comparison, and Vax_Float type, process it
6786
6787       if Vax_Float (Typ1) and then Nkind (N) in N_Op_Compare then
6788          Expand_Vax_Comparison (N);
6789          return;
6790       end if;
6791
6792       Optimize_Length_Comparison (N);
6793    end Expand_N_Op_Ge;
6794
6795    --------------------
6796    -- Expand_N_Op_Gt --
6797    --------------------
6798
6799    procedure Expand_N_Op_Gt (N : Node_Id) is
6800       Typ  : constant Entity_Id := Etype (N);
6801       Op1  : constant Node_Id   := Left_Opnd (N);
6802       Op2  : constant Node_Id   := Right_Opnd (N);
6803       Typ1 : constant Entity_Id := Base_Type (Etype (Op1));
6804
6805    begin
6806       Binary_Op_Validity_Checks (N);
6807
6808       if Is_Array_Type (Typ1) then
6809          Expand_Array_Comparison (N);
6810          return;
6811       end if;
6812
6813       if Is_Boolean_Type (Typ1) then
6814          Adjust_Condition (Op1);
6815          Adjust_Condition (Op2);
6816          Set_Etype (N, Standard_Boolean);
6817          Adjust_Result_Type (N, Typ);
6818       end if;
6819
6820       Rewrite_Comparison (N);
6821
6822       --  If we still have comparison, and Vax_Float type, process it
6823
6824       if Vax_Float (Typ1) and then Nkind (N) in N_Op_Compare then
6825          Expand_Vax_Comparison (N);
6826          return;
6827       end if;
6828
6829       Optimize_Length_Comparison (N);
6830    end Expand_N_Op_Gt;
6831
6832    --------------------
6833    -- Expand_N_Op_Le --
6834    --------------------
6835
6836    procedure Expand_N_Op_Le (N : Node_Id) is
6837       Typ  : constant Entity_Id := Etype (N);
6838       Op1  : constant Node_Id   := Left_Opnd (N);
6839       Op2  : constant Node_Id   := Right_Opnd (N);
6840       Typ1 : constant Entity_Id := Base_Type (Etype (Op1));
6841
6842    begin
6843       Binary_Op_Validity_Checks (N);
6844
6845       if Is_Array_Type (Typ1) then
6846          Expand_Array_Comparison (N);
6847          return;
6848       end if;
6849
6850       if Is_Boolean_Type (Typ1) then
6851          Adjust_Condition (Op1);
6852          Adjust_Condition (Op2);
6853          Set_Etype (N, Standard_Boolean);
6854          Adjust_Result_Type (N, Typ);
6855       end if;
6856
6857       Rewrite_Comparison (N);
6858
6859       --  If we still have comparison, and Vax_Float type, process it
6860
6861       if Vax_Float (Typ1) and then Nkind (N) in N_Op_Compare then
6862          Expand_Vax_Comparison (N);
6863          return;
6864       end if;
6865
6866       Optimize_Length_Comparison (N);
6867    end Expand_N_Op_Le;
6868
6869    --------------------
6870    -- Expand_N_Op_Lt --
6871    --------------------
6872
6873    procedure Expand_N_Op_Lt (N : Node_Id) is
6874       Typ  : constant Entity_Id := Etype (N);
6875       Op1  : constant Node_Id   := Left_Opnd (N);
6876       Op2  : constant Node_Id   := Right_Opnd (N);
6877       Typ1 : constant Entity_Id := Base_Type (Etype (Op1));
6878
6879    begin
6880       Binary_Op_Validity_Checks (N);
6881
6882       if Is_Array_Type (Typ1) then
6883          Expand_Array_Comparison (N);
6884          return;
6885       end if;
6886
6887       if Is_Boolean_Type (Typ1) then
6888          Adjust_Condition (Op1);
6889          Adjust_Condition (Op2);
6890          Set_Etype (N, Standard_Boolean);
6891          Adjust_Result_Type (N, Typ);
6892       end if;
6893
6894       Rewrite_Comparison (N);
6895
6896       --  If we still have comparison, and Vax_Float type, process it
6897
6898       if Vax_Float (Typ1) and then Nkind (N) in N_Op_Compare then
6899          Expand_Vax_Comparison (N);
6900          return;
6901       end if;
6902
6903       Optimize_Length_Comparison (N);
6904    end Expand_N_Op_Lt;
6905
6906    -----------------------
6907    -- Expand_N_Op_Minus --
6908    -----------------------
6909
6910    procedure Expand_N_Op_Minus (N : Node_Id) is
6911       Loc : constant Source_Ptr := Sloc (N);
6912       Typ : constant Entity_Id  := Etype (N);
6913
6914    begin
6915       Unary_Op_Validity_Checks (N);
6916
6917       if not Backend_Overflow_Checks_On_Target
6918          and then Is_Signed_Integer_Type (Etype (N))
6919          and then Do_Overflow_Check (N)
6920       then
6921          --  Software overflow checking expands -expr into (0 - expr)
6922
6923          Rewrite (N,
6924            Make_Op_Subtract (Loc,
6925              Left_Opnd  => Make_Integer_Literal (Loc, 0),
6926              Right_Opnd => Right_Opnd (N)));
6927
6928          Analyze_And_Resolve (N, Typ);
6929
6930       --  Vax floating-point types case
6931
6932       elsif Vax_Float (Etype (N)) then
6933          Expand_Vax_Arith (N);
6934       end if;
6935    end Expand_N_Op_Minus;
6936
6937    ---------------------
6938    -- Expand_N_Op_Mod --
6939    ---------------------
6940
6941    procedure Expand_N_Op_Mod (N : Node_Id) is
6942       Loc   : constant Source_Ptr := Sloc (N);
6943       Typ   : constant Entity_Id  := Etype (N);
6944       Left  : constant Node_Id    := Left_Opnd (N);
6945       Right : constant Node_Id    := Right_Opnd (N);
6946       DOC   : constant Boolean    := Do_Overflow_Check (N);
6947       DDC   : constant Boolean    := Do_Division_Check (N);
6948
6949       LLB : Uint;
6950       Llo : Uint;
6951       Lhi : Uint;
6952       LOK : Boolean;
6953       Rlo : Uint;
6954       Rhi : Uint;
6955       ROK : Boolean;
6956
6957       pragma Warnings (Off, Lhi);
6958
6959    begin
6960       Binary_Op_Validity_Checks (N);
6961
6962       Determine_Range (Right, ROK, Rlo, Rhi, Assume_Valid => True);
6963       Determine_Range (Left,  LOK, Llo, Lhi, Assume_Valid => True);
6964
6965       --  Convert mod to rem if operands are known non-negative. We do this
6966       --  since it is quite likely that this will improve the quality of code,
6967       --  (the operation now corresponds to the hardware remainder), and it
6968       --  does not seem likely that it could be harmful.
6969
6970       if LOK and then Llo >= 0
6971            and then
6972          ROK and then Rlo >= 0
6973       then
6974          Rewrite (N,
6975            Make_Op_Rem (Sloc (N),
6976              Left_Opnd  => Left_Opnd (N),
6977              Right_Opnd => Right_Opnd (N)));
6978
6979          --  Instead of reanalyzing the node we do the analysis manually. This
6980          --  avoids anomalies when the replacement is done in an instance and
6981          --  is epsilon more efficient.
6982
6983          Set_Entity            (N, Standard_Entity (S_Op_Rem));
6984          Set_Etype             (N, Typ);
6985          Set_Do_Overflow_Check (N, DOC);
6986          Set_Do_Division_Check (N, DDC);
6987          Expand_N_Op_Rem (N);
6988          Set_Analyzed (N);
6989
6990       --  Otherwise, normal mod processing
6991
6992       else
6993          if Is_Integer_Type (Etype (N)) then
6994             Apply_Divide_Check (N);
6995          end if;
6996
6997          --  Apply optimization x mod 1 = 0. We don't really need that with
6998          --  gcc, but it is useful with other back ends (e.g. AAMP), and is
6999          --  certainly harmless.
7000
7001          if Is_Integer_Type (Etype (N))
7002            and then Compile_Time_Known_Value (Right)
7003            and then Expr_Value (Right) = Uint_1
7004          then
7005             --  Call Remove_Side_Effects to ensure that any side effects in
7006             --  the ignored left operand (in particular function calls to
7007             --  user defined functions) are properly executed.
7008
7009             Remove_Side_Effects (Left);
7010
7011             Rewrite (N, Make_Integer_Literal (Loc, 0));
7012             Analyze_And_Resolve (N, Typ);
7013             return;
7014          end if;
7015
7016          --  Deal with annoying case of largest negative number remainder
7017          --  minus one. Gigi does not handle this case correctly, because
7018          --  it generates a divide instruction which may trap in this case.
7019
7020          --  In fact the check is quite easy, if the right operand is -1, then
7021          --  the mod value is always 0, and we can just ignore the left operand
7022          --  completely in this case.
7023
7024          --  The operand type may be private (e.g. in the expansion of an
7025          --  intrinsic operation) so we must use the underlying type to get the
7026          --  bounds, and convert the literals explicitly.
7027
7028          LLB :=
7029            Expr_Value
7030              (Type_Low_Bound (Base_Type (Underlying_Type (Etype (Left)))));
7031
7032          if ((not ROK) or else (Rlo <= (-1) and then (-1) <= Rhi))
7033            and then
7034             ((not LOK) or else (Llo = LLB))
7035          then
7036             Rewrite (N,
7037               Make_Conditional_Expression (Loc,
7038                 Expressions => New_List (
7039                   Make_Op_Eq (Loc,
7040                     Left_Opnd => Duplicate_Subexpr (Right),
7041                     Right_Opnd =>
7042                       Unchecked_Convert_To (Typ,
7043                         Make_Integer_Literal (Loc, -1))),
7044                   Unchecked_Convert_To (Typ,
7045                     Make_Integer_Literal (Loc, Uint_0)),
7046                   Relocate_Node (N))));
7047
7048             Set_Analyzed (Next (Next (First (Expressions (N)))));
7049             Analyze_And_Resolve (N, Typ);
7050          end if;
7051       end if;
7052    end Expand_N_Op_Mod;
7053
7054    --------------------------
7055    -- Expand_N_Op_Multiply --
7056    --------------------------
7057
7058    procedure Expand_N_Op_Multiply (N : Node_Id) is
7059       Loc : constant Source_Ptr := Sloc (N);
7060       Lop : constant Node_Id    := Left_Opnd (N);
7061       Rop : constant Node_Id    := Right_Opnd (N);
7062
7063       Lp2 : constant Boolean :=
7064               Nkind (Lop) = N_Op_Expon
7065                 and then Is_Power_Of_2_For_Shift (Lop);
7066
7067       Rp2 : constant Boolean :=
7068               Nkind (Rop) = N_Op_Expon
7069                 and then Is_Power_Of_2_For_Shift (Rop);
7070
7071       Ltyp : constant Entity_Id  := Etype (Lop);
7072       Rtyp : constant Entity_Id  := Etype (Rop);
7073       Typ  : Entity_Id           := Etype (N);
7074
7075    begin
7076       Binary_Op_Validity_Checks (N);
7077
7078       --  Special optimizations for integer types
7079
7080       if Is_Integer_Type (Typ) then
7081
7082          --  N * 0 = 0 for integer types
7083
7084          if Compile_Time_Known_Value (Rop)
7085            and then Expr_Value (Rop) = Uint_0
7086          then
7087             --  Call Remove_Side_Effects to ensure that any side effects in
7088             --  the ignored left operand (in particular function calls to
7089             --  user defined functions) are properly executed.
7090
7091             Remove_Side_Effects (Lop);
7092
7093             Rewrite (N, Make_Integer_Literal (Loc, Uint_0));
7094             Analyze_And_Resolve (N, Typ);
7095             return;
7096          end if;
7097
7098          --  Similar handling for 0 * N = 0
7099
7100          if Compile_Time_Known_Value (Lop)
7101            and then Expr_Value (Lop) = Uint_0
7102          then
7103             Remove_Side_Effects (Rop);
7104             Rewrite (N, Make_Integer_Literal (Loc, Uint_0));
7105             Analyze_And_Resolve (N, Typ);
7106             return;
7107          end if;
7108
7109          --  N * 1 = 1 * N = N for integer types
7110
7111          --  This optimisation is not done if we are going to
7112          --  rewrite the product 1 * 2 ** N to a shift.
7113
7114          if Compile_Time_Known_Value (Rop)
7115            and then Expr_Value (Rop) = Uint_1
7116            and then not Lp2
7117          then
7118             Rewrite (N, Lop);
7119             return;
7120
7121          elsif Compile_Time_Known_Value (Lop)
7122            and then Expr_Value (Lop) = Uint_1
7123            and then not Rp2
7124          then
7125             Rewrite (N, Rop);
7126             return;
7127          end if;
7128       end if;
7129
7130       --  Convert x * 2 ** y to Shift_Left (x, y). Note that the fact that
7131       --  Is_Power_Of_2_For_Shift is set means that we know that our left
7132       --  operand is an integer, as required for this to work.
7133
7134       if Rp2 then
7135          if Lp2 then
7136
7137             --  Convert 2 ** A * 2 ** B into  2 ** (A + B)
7138
7139             Rewrite (N,
7140               Make_Op_Expon (Loc,
7141                 Left_Opnd => Make_Integer_Literal (Loc, 2),
7142                 Right_Opnd =>
7143                   Make_Op_Add (Loc,
7144                     Left_Opnd  => Right_Opnd (Lop),
7145                     Right_Opnd => Right_Opnd (Rop))));
7146             Analyze_And_Resolve (N, Typ);
7147             return;
7148
7149          else
7150             Rewrite (N,
7151               Make_Op_Shift_Left (Loc,
7152                 Left_Opnd  => Lop,
7153                 Right_Opnd =>
7154                   Convert_To (Standard_Natural, Right_Opnd (Rop))));
7155             Analyze_And_Resolve (N, Typ);
7156             return;
7157          end if;
7158
7159       --  Same processing for the operands the other way round
7160
7161       elsif Lp2 then
7162          Rewrite (N,
7163            Make_Op_Shift_Left (Loc,
7164              Left_Opnd  => Rop,
7165              Right_Opnd =>
7166                Convert_To (Standard_Natural, Right_Opnd (Lop))));
7167          Analyze_And_Resolve (N, Typ);
7168          return;
7169       end if;
7170
7171       --  Do required fixup of universal fixed operation
7172
7173       if Typ = Universal_Fixed then
7174          Fixup_Universal_Fixed_Operation (N);
7175          Typ := Etype (N);
7176       end if;
7177
7178       --  Multiplications with fixed-point results
7179
7180       if Is_Fixed_Point_Type (Typ) then
7181
7182          --  No special processing if Treat_Fixed_As_Integer is set, since from
7183          --  a semantic point of view such operations are simply integer
7184          --  operations and will be treated that way.
7185
7186          if not Treat_Fixed_As_Integer (N) then
7187
7188             --  Case of fixed * integer => fixed
7189
7190             if Is_Integer_Type (Rtyp) then
7191                Expand_Multiply_Fixed_By_Integer_Giving_Fixed (N);
7192
7193             --  Case of integer * fixed => fixed
7194
7195             elsif Is_Integer_Type (Ltyp) then
7196                Expand_Multiply_Integer_By_Fixed_Giving_Fixed (N);
7197
7198             --  Case of fixed * fixed => fixed
7199
7200             else
7201                Expand_Multiply_Fixed_By_Fixed_Giving_Fixed (N);
7202             end if;
7203          end if;
7204
7205       --  Other cases of multiplication of fixed-point operands. Again we
7206       --  exclude the cases where Treat_Fixed_As_Integer flag is set.
7207
7208       elsif (Is_Fixed_Point_Type (Ltyp) or else Is_Fixed_Point_Type (Rtyp))
7209         and then not Treat_Fixed_As_Integer (N)
7210       then
7211          if Is_Integer_Type (Typ) then
7212             Expand_Multiply_Fixed_By_Fixed_Giving_Integer (N);
7213          else
7214             pragma Assert (Is_Floating_Point_Type (Typ));
7215             Expand_Multiply_Fixed_By_Fixed_Giving_Float (N);
7216          end if;
7217
7218       --  Mixed-mode operations can appear in a non-static universal context,
7219       --  in which case the integer argument must be converted explicitly.
7220
7221       elsif Typ = Universal_Real
7222         and then Is_Integer_Type (Rtyp)
7223       then
7224          Rewrite (Rop, Convert_To (Universal_Real, Relocate_Node (Rop)));
7225
7226          Analyze_And_Resolve (Rop, Universal_Real);
7227
7228       elsif Typ = Universal_Real
7229         and then Is_Integer_Type (Ltyp)
7230       then
7231          Rewrite (Lop, Convert_To (Universal_Real, Relocate_Node (Lop)));
7232
7233          Analyze_And_Resolve (Lop, Universal_Real);
7234
7235       --  Non-fixed point cases, check software overflow checking required
7236
7237       elsif Is_Signed_Integer_Type (Etype (N)) then
7238          Apply_Arithmetic_Overflow_Check (N);
7239
7240       --  Deal with VAX float case
7241
7242       elsif Vax_Float (Typ) then
7243          Expand_Vax_Arith (N);
7244          return;
7245       end if;
7246    end Expand_N_Op_Multiply;
7247
7248    --------------------
7249    -- Expand_N_Op_Ne --
7250    --------------------
7251
7252    procedure Expand_N_Op_Ne (N : Node_Id) is
7253       Typ : constant Entity_Id := Etype (Left_Opnd (N));
7254
7255    begin
7256       --  Case of elementary type with standard operator
7257
7258       if Is_Elementary_Type (Typ)
7259         and then Sloc (Entity (N)) = Standard_Location
7260       then
7261          Binary_Op_Validity_Checks (N);
7262
7263          --  Boolean types (requiring handling of non-standard case)
7264
7265          if Is_Boolean_Type (Typ) then
7266             Adjust_Condition (Left_Opnd (N));
7267             Adjust_Condition (Right_Opnd (N));
7268             Set_Etype (N, Standard_Boolean);
7269             Adjust_Result_Type (N, Typ);
7270          end if;
7271
7272          Rewrite_Comparison (N);
7273
7274          --  If we still have comparison for Vax_Float, process it
7275
7276          if Vax_Float (Typ) and then Nkind (N) in N_Op_Compare  then
7277             Expand_Vax_Comparison (N);
7278             return;
7279          end if;
7280
7281       --  For all cases other than elementary types, we rewrite node as the
7282       --  negation of an equality operation, and reanalyze. The equality to be
7283       --  used is defined in the same scope and has the same signature. This
7284       --  signature must be set explicitly since in an instance it may not have
7285       --  the same visibility as in the generic unit. This avoids duplicating
7286       --  or factoring the complex code for record/array equality tests etc.
7287
7288       else
7289          declare
7290             Loc : constant Source_Ptr := Sloc (N);
7291             Neg : Node_Id;
7292             Ne  : constant Entity_Id := Entity (N);
7293
7294          begin
7295             Binary_Op_Validity_Checks (N);
7296
7297             Neg :=
7298               Make_Op_Not (Loc,
7299                 Right_Opnd =>
7300                   Make_Op_Eq (Loc,
7301                     Left_Opnd =>  Left_Opnd (N),
7302                     Right_Opnd => Right_Opnd (N)));
7303             Set_Paren_Count (Right_Opnd (Neg), 1);
7304
7305             if Scope (Ne) /= Standard_Standard then
7306                Set_Entity (Right_Opnd (Neg), Corresponding_Equality (Ne));
7307             end if;
7308
7309             --  For navigation purposes, we want to treat the inequality as an
7310             --  implicit reference to the corresponding equality. Preserve the
7311             --  Comes_From_ source flag to generate proper Xref entries.
7312
7313             Preserve_Comes_From_Source (Neg, N);
7314             Preserve_Comes_From_Source (Right_Opnd (Neg), N);
7315             Rewrite (N, Neg);
7316             Analyze_And_Resolve (N, Standard_Boolean);
7317          end;
7318       end if;
7319
7320       Optimize_Length_Comparison (N);
7321    end Expand_N_Op_Ne;
7322
7323    ---------------------
7324    -- Expand_N_Op_Not --
7325    ---------------------
7326
7327    --  If the argument is other than a Boolean array type, there is no special
7328    --  expansion required, except for VMS operations on signed integers.
7329
7330    --  For the packed case, we call the special routine in Exp_Pakd, except
7331    --  that if the component size is greater than one, we use the standard
7332    --  routine generating a gruesome loop (it is so peculiar to have packed
7333    --  arrays with non-standard Boolean representations anyway, so it does not
7334    --  matter that we do not handle this case efficiently).
7335
7336    --  For the unpacked case (and for the special packed case where we have non
7337    --  standard Booleans, as discussed above), we generate and insert into the
7338    --  tree the following function definition:
7339
7340    --     function Nnnn (A : arr) is
7341    --       B : arr;
7342    --     begin
7343    --       for J in a'range loop
7344    --          B (J) := not A (J);
7345    --       end loop;
7346    --       return B;
7347    --     end Nnnn;
7348
7349    --  Here arr is the actual subtype of the parameter (and hence always
7350    --  constrained). Then we replace the not with a call to this function.
7351
7352    procedure Expand_N_Op_Not (N : Node_Id) is
7353       Loc  : constant Source_Ptr := Sloc (N);
7354       Typ  : constant Entity_Id  := Etype (N);
7355       Opnd : Node_Id;
7356       Arr  : Entity_Id;
7357       A    : Entity_Id;
7358       B    : Entity_Id;
7359       J    : Entity_Id;
7360       A_J  : Node_Id;
7361       B_J  : Node_Id;
7362
7363       Func_Name      : Entity_Id;
7364       Loop_Statement : Node_Id;
7365
7366    begin
7367       Unary_Op_Validity_Checks (N);
7368
7369       --  For boolean operand, deal with non-standard booleans
7370
7371       if Is_Boolean_Type (Typ) then
7372          Adjust_Condition (Right_Opnd (N));
7373          Set_Etype (N, Standard_Boolean);
7374          Adjust_Result_Type (N, Typ);
7375          return;
7376       end if;
7377
7378       --  For the VMS "not" on signed integer types, use conversion to and from
7379       --  a predefined modular type.
7380
7381       if Is_VMS_Operator (Entity (N)) then
7382          declare
7383             Rtyp : Entity_Id;
7384             Utyp : Entity_Id;
7385
7386          begin
7387             --  If this is a derived type, retrieve original VMS type so that
7388             --  the proper sized type is used for intermediate values.
7389
7390             if Is_Derived_Type (Typ) then
7391                Rtyp := First_Subtype (Etype (Typ));
7392             else
7393                Rtyp := Typ;
7394             end if;
7395
7396             --  The proper unsigned type must have a size compatible with the
7397             --  operand, to prevent misalignment.
7398
7399             if RM_Size (Rtyp) <= 8 then
7400                Utyp := RTE (RE_Unsigned_8);
7401
7402             elsif RM_Size (Rtyp) <= 16 then
7403                Utyp := RTE (RE_Unsigned_16);
7404
7405             elsif RM_Size (Rtyp) = RM_Size (Standard_Unsigned) then
7406                Utyp := RTE (RE_Unsigned_32);
7407
7408             else
7409                Utyp := RTE (RE_Long_Long_Unsigned);
7410             end if;
7411
7412             Rewrite (N,
7413               Unchecked_Convert_To (Typ,
7414                 Make_Op_Not (Loc,
7415                   Unchecked_Convert_To (Utyp, Right_Opnd (N)))));
7416             Analyze_And_Resolve (N, Typ);
7417             return;
7418          end;
7419       end if;
7420
7421       --  Only array types need any other processing
7422
7423       if not Is_Array_Type (Typ) then
7424          return;
7425       end if;
7426
7427       --  Case of array operand. If bit packed with a component size of 1,
7428       --  handle it in Exp_Pakd if the operand is known to be aligned.
7429
7430       if Is_Bit_Packed_Array (Typ)
7431         and then Component_Size (Typ) = 1
7432         and then not Is_Possibly_Unaligned_Object (Right_Opnd (N))
7433       then
7434          Expand_Packed_Not (N);
7435          return;
7436       end if;
7437
7438       --  Case of array operand which is not bit-packed. If the context is
7439       --  a safe assignment, call in-place operation, If context is a larger
7440       --  boolean expression in the context of a safe assignment, expansion is
7441       --  done by enclosing operation.
7442
7443       Opnd := Relocate_Node (Right_Opnd (N));
7444       Convert_To_Actual_Subtype (Opnd);
7445       Arr := Etype (Opnd);
7446       Ensure_Defined (Arr, N);
7447       Silly_Boolean_Array_Not_Test (N, Arr);
7448
7449       if Nkind (Parent (N)) = N_Assignment_Statement then
7450          if Safe_In_Place_Array_Op (Name (Parent (N)), N, Empty) then
7451             Build_Boolean_Array_Proc_Call (Parent (N), Opnd, Empty);
7452             return;
7453
7454          --  Special case the negation of a binary operation
7455
7456          elsif Nkind_In (Opnd, N_Op_And, N_Op_Or, N_Op_Xor)
7457            and then Safe_In_Place_Array_Op
7458                       (Name (Parent (N)), Left_Opnd (Opnd), Right_Opnd (Opnd))
7459          then
7460             Build_Boolean_Array_Proc_Call (Parent (N), Opnd, Empty);
7461             return;
7462          end if;
7463
7464       elsif Nkind (Parent (N)) in N_Binary_Op
7465         and then Nkind (Parent (Parent (N))) = N_Assignment_Statement
7466       then
7467          declare
7468             Op1 : constant Node_Id := Left_Opnd  (Parent (N));
7469             Op2 : constant Node_Id := Right_Opnd (Parent (N));
7470             Lhs : constant Node_Id := Name (Parent (Parent (N)));
7471
7472          begin
7473             if Safe_In_Place_Array_Op (Lhs, Op1, Op2) then
7474
7475                --  (not A) op (not B) can be reduced to a single call
7476
7477                if N = Op1 and then Nkind (Op2) = N_Op_Not then
7478                   return;
7479
7480                elsif N = Op2 and then Nkind (Op1) = N_Op_Not then
7481                   return;
7482
7483                --  A xor (not B) can also be special-cased
7484
7485                elsif N = Op2 and then Nkind (Parent (N)) = N_Op_Xor then
7486                   return;
7487                end if;
7488             end if;
7489          end;
7490       end if;
7491
7492       A := Make_Defining_Identifier (Loc, Name_uA);
7493       B := Make_Defining_Identifier (Loc, Name_uB);
7494       J := Make_Defining_Identifier (Loc, Name_uJ);
7495
7496       A_J :=
7497         Make_Indexed_Component (Loc,
7498           Prefix      => New_Reference_To (A, Loc),
7499           Expressions => New_List (New_Reference_To (J, Loc)));
7500
7501       B_J :=
7502         Make_Indexed_Component (Loc,
7503           Prefix      => New_Reference_To (B, Loc),
7504           Expressions => New_List (New_Reference_To (J, Loc)));
7505
7506       Loop_Statement :=
7507         Make_Implicit_Loop_Statement (N,
7508           Identifier => Empty,
7509
7510           Iteration_Scheme =>
7511             Make_Iteration_Scheme (Loc,
7512               Loop_Parameter_Specification =>
7513                 Make_Loop_Parameter_Specification (Loc,
7514                   Defining_Identifier         => J,
7515                   Discrete_Subtype_Definition =>
7516                     Make_Attribute_Reference (Loc,
7517                       Prefix         => Make_Identifier (Loc, Chars (A)),
7518                       Attribute_Name => Name_Range))),
7519
7520           Statements => New_List (
7521             Make_Assignment_Statement (Loc,
7522               Name       => B_J,
7523               Expression => Make_Op_Not (Loc, A_J))));
7524
7525       Func_Name := Make_Temporary (Loc, 'N');
7526       Set_Is_Inlined (Func_Name);
7527
7528       Insert_Action (N,
7529         Make_Subprogram_Body (Loc,
7530           Specification =>
7531             Make_Function_Specification (Loc,
7532               Defining_Unit_Name => Func_Name,
7533               Parameter_Specifications => New_List (
7534                 Make_Parameter_Specification (Loc,
7535                   Defining_Identifier => A,
7536                   Parameter_Type      => New_Reference_To (Typ, Loc))),
7537               Result_Definition => New_Reference_To (Typ, Loc)),
7538
7539           Declarations => New_List (
7540             Make_Object_Declaration (Loc,
7541               Defining_Identifier => B,
7542               Object_Definition   => New_Reference_To (Arr, Loc))),
7543
7544           Handled_Statement_Sequence =>
7545             Make_Handled_Sequence_Of_Statements (Loc,
7546               Statements => New_List (
7547                 Loop_Statement,
7548                 Make_Simple_Return_Statement (Loc,
7549                   Expression => Make_Identifier (Loc, Chars (B)))))));
7550
7551       Rewrite (N,
7552         Make_Function_Call (Loc,
7553           Name                   => New_Reference_To (Func_Name, Loc),
7554           Parameter_Associations => New_List (Opnd)));
7555
7556       Analyze_And_Resolve (N, Typ);
7557    end Expand_N_Op_Not;
7558
7559    --------------------
7560    -- Expand_N_Op_Or --
7561    --------------------
7562
7563    procedure Expand_N_Op_Or (N : Node_Id) is
7564       Typ : constant Entity_Id := Etype (N);
7565
7566    begin
7567       Binary_Op_Validity_Checks (N);
7568
7569       if Is_Array_Type (Etype (N)) then
7570          Expand_Boolean_Operator (N);
7571
7572       elsif Is_Boolean_Type (Etype (N)) then
7573          Adjust_Condition (Left_Opnd (N));
7574          Adjust_Condition (Right_Opnd (N));
7575          Set_Etype (N, Standard_Boolean);
7576          Adjust_Result_Type (N, Typ);
7577
7578       elsif Is_Intrinsic_Subprogram (Entity (N)) then
7579          Expand_Intrinsic_Call (N, Entity (N));
7580
7581       end if;
7582    end Expand_N_Op_Or;
7583
7584    ----------------------
7585    -- Expand_N_Op_Plus --
7586    ----------------------
7587
7588    procedure Expand_N_Op_Plus (N : Node_Id) is
7589    begin
7590       Unary_Op_Validity_Checks (N);
7591    end Expand_N_Op_Plus;
7592
7593    ---------------------
7594    -- Expand_N_Op_Rem --
7595    ---------------------
7596
7597    procedure Expand_N_Op_Rem (N : Node_Id) is
7598       Loc : constant Source_Ptr := Sloc (N);
7599       Typ : constant Entity_Id  := Etype (N);
7600
7601       Left  : constant Node_Id := Left_Opnd (N);
7602       Right : constant Node_Id := Right_Opnd (N);
7603
7604       Lo : Uint;
7605       Hi : Uint;
7606       OK : Boolean;
7607
7608       Lneg : Boolean;
7609       Rneg : Boolean;
7610       --  Set if corresponding operand can be negative
7611
7612       pragma Unreferenced (Hi);
7613
7614    begin
7615       Binary_Op_Validity_Checks (N);
7616
7617       if Is_Integer_Type (Etype (N)) then
7618          Apply_Divide_Check (N);
7619       end if;
7620
7621       --  Apply optimization x rem 1 = 0. We don't really need that with gcc,
7622       --  but it is useful with other back ends (e.g. AAMP), and is certainly
7623       --  harmless.
7624
7625       if Is_Integer_Type (Etype (N))
7626         and then Compile_Time_Known_Value (Right)
7627         and then Expr_Value (Right) = Uint_1
7628       then
7629          --  Call Remove_Side_Effects to ensure that any side effects in the
7630          --  ignored left operand (in particular function calls to user defined
7631          --  functions) are properly executed.
7632
7633          Remove_Side_Effects (Left);
7634
7635          Rewrite (N, Make_Integer_Literal (Loc, 0));
7636          Analyze_And_Resolve (N, Typ);
7637          return;
7638       end if;
7639
7640       --  Deal with annoying case of largest negative number remainder minus
7641       --  one. Gigi does not handle this case correctly, because it generates
7642       --  a divide instruction which may trap in this case.
7643
7644       --  In fact the check is quite easy, if the right operand is -1, then
7645       --  the remainder is always 0, and we can just ignore the left operand
7646       --  completely in this case.
7647
7648       Determine_Range (Right, OK, Lo, Hi, Assume_Valid => True);
7649       Lneg := (not OK) or else Lo < 0;
7650
7651       Determine_Range (Left,  OK, Lo, Hi, Assume_Valid => True);
7652       Rneg := (not OK) or else Lo < 0;
7653
7654       --  We won't mess with trying to find out if the left operand can really
7655       --  be the largest negative number (that's a pain in the case of private
7656       --  types and this is really marginal). We will just assume that we need
7657       --  the test if the left operand can be negative at all.
7658
7659       if Lneg and Rneg then
7660          Rewrite (N,
7661            Make_Conditional_Expression (Loc,
7662              Expressions => New_List (
7663                Make_Op_Eq (Loc,
7664                  Left_Opnd  => Duplicate_Subexpr (Right),
7665                  Right_Opnd =>
7666                    Unchecked_Convert_To (Typ, Make_Integer_Literal (Loc, -1))),
7667
7668                Unchecked_Convert_To (Typ,
7669                  Make_Integer_Literal (Loc, Uint_0)),
7670
7671                Relocate_Node (N))));
7672
7673          Set_Analyzed (Next (Next (First (Expressions (N)))));
7674          Analyze_And_Resolve (N, Typ);
7675       end if;
7676    end Expand_N_Op_Rem;
7677
7678    -----------------------------
7679    -- Expand_N_Op_Rotate_Left --
7680    -----------------------------
7681
7682    procedure Expand_N_Op_Rotate_Left (N : Node_Id) is
7683    begin
7684       Binary_Op_Validity_Checks (N);
7685    end Expand_N_Op_Rotate_Left;
7686
7687    ------------------------------
7688    -- Expand_N_Op_Rotate_Right --
7689    ------------------------------
7690
7691    procedure Expand_N_Op_Rotate_Right (N : Node_Id) is
7692    begin
7693       Binary_Op_Validity_Checks (N);
7694    end Expand_N_Op_Rotate_Right;
7695
7696    ----------------------------
7697    -- Expand_N_Op_Shift_Left --
7698    ----------------------------
7699
7700    procedure Expand_N_Op_Shift_Left (N : Node_Id) is
7701    begin
7702       Binary_Op_Validity_Checks (N);
7703    end Expand_N_Op_Shift_Left;
7704
7705    -----------------------------
7706    -- Expand_N_Op_Shift_Right --
7707    -----------------------------
7708
7709    procedure Expand_N_Op_Shift_Right (N : Node_Id) is
7710    begin
7711       Binary_Op_Validity_Checks (N);
7712    end Expand_N_Op_Shift_Right;
7713
7714    ----------------------------------------
7715    -- Expand_N_Op_Shift_Right_Arithmetic --
7716    ----------------------------------------
7717
7718    procedure Expand_N_Op_Shift_Right_Arithmetic (N : Node_Id) is
7719    begin
7720       Binary_Op_Validity_Checks (N);
7721    end Expand_N_Op_Shift_Right_Arithmetic;
7722
7723    --------------------------
7724    -- Expand_N_Op_Subtract --
7725    --------------------------
7726
7727    procedure Expand_N_Op_Subtract (N : Node_Id) is
7728       Typ : constant Entity_Id := Etype (N);
7729
7730    begin
7731       Binary_Op_Validity_Checks (N);
7732
7733       --  N - 0 = N for integer types
7734
7735       if Is_Integer_Type (Typ)
7736         and then Compile_Time_Known_Value (Right_Opnd (N))
7737         and then Expr_Value (Right_Opnd (N)) = 0
7738       then
7739          Rewrite (N, Left_Opnd (N));
7740          return;
7741       end if;
7742
7743       --  Arithmetic overflow checks for signed integer/fixed point types
7744
7745       if Is_Signed_Integer_Type (Typ)
7746            or else
7747          Is_Fixed_Point_Type (Typ)
7748       then
7749          Apply_Arithmetic_Overflow_Check (N);
7750
7751       --  VAX floating-point types case
7752
7753       elsif Vax_Float (Typ) then
7754          Expand_Vax_Arith (N);
7755       end if;
7756    end Expand_N_Op_Subtract;
7757
7758    ---------------------
7759    -- Expand_N_Op_Xor --
7760    ---------------------
7761
7762    procedure Expand_N_Op_Xor (N : Node_Id) is
7763       Typ : constant Entity_Id := Etype (N);
7764
7765    begin
7766       Binary_Op_Validity_Checks (N);
7767
7768       if Is_Array_Type (Etype (N)) then
7769          Expand_Boolean_Operator (N);
7770
7771       elsif Is_Boolean_Type (Etype (N)) then
7772          Adjust_Condition (Left_Opnd (N));
7773          Adjust_Condition (Right_Opnd (N));
7774          Set_Etype (N, Standard_Boolean);
7775          Adjust_Result_Type (N, Typ);
7776
7777       elsif Is_Intrinsic_Subprogram (Entity (N)) then
7778          Expand_Intrinsic_Call (N, Entity (N));
7779
7780       end if;
7781    end Expand_N_Op_Xor;
7782
7783    ----------------------
7784    -- Expand_N_Or_Else --
7785    ----------------------
7786
7787    procedure Expand_N_Or_Else (N : Node_Id)
7788      renames Expand_Short_Circuit_Operator;
7789
7790    -----------------------------------
7791    -- Expand_N_Qualified_Expression --
7792    -----------------------------------
7793
7794    procedure Expand_N_Qualified_Expression (N : Node_Id) is
7795       Operand     : constant Node_Id   := Expression (N);
7796       Target_Type : constant Entity_Id := Entity (Subtype_Mark (N));
7797
7798    begin
7799       --  Do validity check if validity checking operands
7800
7801       if Validity_Checks_On
7802         and then Validity_Check_Operands
7803       then
7804          Ensure_Valid (Operand);
7805       end if;
7806
7807       --  Apply possible constraint check
7808
7809       Apply_Constraint_Check (Operand, Target_Type, No_Sliding => True);
7810
7811       if Do_Range_Check (Operand) then
7812          Set_Do_Range_Check (Operand, False);
7813          Generate_Range_Check (Operand, Target_Type, CE_Range_Check_Failed);
7814       end if;
7815    end Expand_N_Qualified_Expression;
7816
7817    ------------------------------------
7818    -- Expand_N_Quantified_Expression --
7819    ------------------------------------
7820
7821    --  We expand:
7822
7823    --    for all X in range => Cond
7824
7825    --  into:
7826
7827    --        T := True;
7828    --        for X in range loop
7829    --           if not Cond then
7830    --              T := False;
7831    --              exit;
7832    --           end if;
7833    --        end loop;
7834
7835    --  Conversely, an existentially quantified expression:
7836
7837    --    for some X in range => Cond
7838
7839    --  becomes:
7840
7841    --        T := False;
7842    --        for X in range loop
7843    --           if Cond then
7844    --              T := True;
7845    --              exit;
7846    --           end if;
7847    --        end loop;
7848
7849    --  In both cases, the iteration may be over a container in which case it is
7850    --  given by an iterator specification, not a loop parameter specification.
7851
7852    procedure Expand_N_Quantified_Expression (N : Node_Id) is
7853       Loc          : constant Source_Ptr := Sloc (N);
7854       Is_Universal : constant Boolean := All_Present (N);
7855       Actions      : constant List_Id := New_List;
7856       Tnn          : constant Entity_Id := Make_Temporary (Loc, 'T', N);
7857       Cond         : Node_Id;
7858       Decl         : Node_Id;
7859       I_Scheme     : Node_Id;
7860       Test         : Node_Id;
7861
7862    begin
7863       Decl :=
7864         Make_Object_Declaration (Loc,
7865           Defining_Identifier => Tnn,
7866           Object_Definition   => New_Occurrence_Of (Standard_Boolean, Loc),
7867           Expression          =>
7868             New_Occurrence_Of (Boolean_Literals (Is_Universal), Loc));
7869       Append_To (Actions, Decl);
7870
7871       Cond := Relocate_Node (Condition (N));
7872
7873       --  Reset flag analyzed in the condition to force its analysis. Required
7874       --  since the previous analysis was done with expansion disabled (see
7875       --  Resolve_Quantified_Expression) and hence checks were not inserted
7876       --  and record comparisons have not been expanded.
7877
7878       Reset_Analyzed_Flags (Cond);
7879
7880       if Is_Universal then
7881          Cond := Make_Op_Not (Loc, Cond);
7882       end if;
7883
7884       Test :=
7885         Make_Implicit_If_Statement (N,
7886           Condition       => Cond,
7887           Then_Statements => New_List (
7888             Make_Assignment_Statement (Loc,
7889               Name       => New_Occurrence_Of (Tnn, Loc),
7890               Expression =>
7891                 New_Occurrence_Of (Boolean_Literals (not Is_Universal), Loc)),
7892             Make_Exit_Statement (Loc)));
7893
7894       if Present (Loop_Parameter_Specification (N)) then
7895          I_Scheme :=
7896            Make_Iteration_Scheme (Loc,
7897               Loop_Parameter_Specification =>
7898                 Loop_Parameter_Specification (N));
7899       else
7900          I_Scheme :=
7901            Make_Iteration_Scheme (Loc,
7902              Iterator_Specification => Iterator_Specification (N));
7903       end if;
7904
7905       Append_To (Actions,
7906         Make_Loop_Statement (Loc,
7907           Iteration_Scheme => I_Scheme,
7908           Statements       => New_List (Test),
7909           End_Label        => Empty));
7910
7911       Rewrite (N,
7912         Make_Expression_With_Actions (Loc,
7913           Expression => New_Occurrence_Of (Tnn, Loc),
7914           Actions    => Actions));
7915
7916       Analyze_And_Resolve (N, Standard_Boolean);
7917    end Expand_N_Quantified_Expression;
7918
7919    ---------------------------------
7920    -- Expand_N_Selected_Component --
7921    ---------------------------------
7922
7923    procedure Expand_N_Selected_Component (N : Node_Id) is
7924       Loc   : constant Source_Ptr := Sloc (N);
7925       Par   : constant Node_Id    := Parent (N);
7926       P     : constant Node_Id    := Prefix (N);
7927       Ptyp  : Entity_Id           := Underlying_Type (Etype (P));
7928       Disc  : Entity_Id;
7929       New_N : Node_Id;
7930       Dcon  : Elmt_Id;
7931       Dval  : Node_Id;
7932
7933       function In_Left_Hand_Side (Comp : Node_Id) return Boolean;
7934       --  Gigi needs a temporary for prefixes that depend on a discriminant,
7935       --  unless the context of an assignment can provide size information.
7936       --  Don't we have a general routine that does this???
7937
7938       function Is_Subtype_Declaration return Boolean;
7939       --  The replacement of a discriminant reference by its value is required
7940       --  if this is part of the initialization of an temporary generated by a
7941       --  change of representation. This shows up as the construction of a
7942       --  discriminant constraint for a subtype declared at the same point as
7943       --  the entity in the prefix of the selected component. We recognize this
7944       --  case when the context of the reference is:
7945       --    subtype ST is T(Obj.D);
7946       --  where the entity for Obj comes from source, and ST has the same sloc.
7947
7948       -----------------------
7949       -- In_Left_Hand_Side --
7950       -----------------------
7951
7952       function In_Left_Hand_Side (Comp : Node_Id) return Boolean is
7953       begin
7954          return (Nkind (Parent (Comp)) = N_Assignment_Statement
7955                   and then Comp = Name (Parent (Comp)))
7956            or else (Present (Parent (Comp))
7957                      and then Nkind (Parent (Comp)) in N_Subexpr
7958                      and then In_Left_Hand_Side (Parent (Comp)));
7959       end In_Left_Hand_Side;
7960
7961       -----------------------------
7962       --  Is_Subtype_Declaration --
7963       -----------------------------
7964
7965       function Is_Subtype_Declaration return Boolean is
7966          Par : constant Node_Id := Parent (N);
7967       begin
7968          return
7969            Nkind (Par) = N_Index_Or_Discriminant_Constraint
7970              and then Nkind (Parent (Parent (Par))) = N_Subtype_Declaration
7971              and then Comes_From_Source (Entity (Prefix (N)))
7972              and then Sloc (Par) = Sloc (Entity (Prefix (N)));
7973       end Is_Subtype_Declaration;
7974
7975    --  Start of processing for Expand_N_Selected_Component
7976
7977    begin
7978       --  Insert explicit dereference if required
7979
7980       if Is_Access_Type (Ptyp) then
7981
7982          --  First set prefix type to proper access type, in case it currently
7983          --  has a private (non-access) view of this type.
7984
7985          Set_Etype (P, Ptyp);
7986
7987          Insert_Explicit_Dereference (P);
7988          Analyze_And_Resolve (P, Designated_Type (Ptyp));
7989
7990          if Ekind (Etype (P)) = E_Private_Subtype
7991            and then Is_For_Access_Subtype (Etype (P))
7992          then
7993             Set_Etype (P, Base_Type (Etype (P)));
7994          end if;
7995
7996          Ptyp := Etype (P);
7997       end if;
7998
7999       --  Deal with discriminant check required
8000
8001       if Do_Discriminant_Check (N) then
8002
8003          --  Present the discriminant checking function to the backend, so that
8004          --  it can inline the call to the function.
8005
8006          Add_Inlined_Body
8007            (Discriminant_Checking_Func
8008              (Original_Record_Component (Entity (Selector_Name (N)))));
8009
8010          --  Now reset the flag and generate the call
8011
8012          Set_Do_Discriminant_Check (N, False);
8013          Generate_Discriminant_Check (N);
8014       end if;
8015
8016       --  Ada 2005 (AI-318-02): If the prefix is a call to a build-in-place
8017       --  function, then additional actuals must be passed.
8018
8019       if Ada_Version >= Ada_2005
8020         and then Is_Build_In_Place_Function_Call (P)
8021       then
8022          Make_Build_In_Place_Call_In_Anonymous_Context (P);
8023       end if;
8024
8025       --  Gigi cannot handle unchecked conversions that are the prefix of a
8026       --  selected component with discriminants. This must be checked during
8027       --  expansion, because during analysis the type of the selector is not
8028       --  known at the point the prefix is analyzed. If the conversion is the
8029       --  target of an assignment, then we cannot force the evaluation.
8030
8031       if Nkind (Prefix (N)) = N_Unchecked_Type_Conversion
8032         and then Has_Discriminants (Etype (N))
8033         and then not In_Left_Hand_Side (N)
8034       then
8035          Force_Evaluation (Prefix (N));
8036       end if;
8037
8038       --  Remaining processing applies only if selector is a discriminant
8039
8040       if Ekind (Entity (Selector_Name (N))) = E_Discriminant then
8041
8042          --  If the selector is a discriminant of a constrained record type,
8043          --  we may be able to rewrite the expression with the actual value
8044          --  of the discriminant, a useful optimization in some cases.
8045
8046          if Is_Record_Type (Ptyp)
8047            and then Has_Discriminants (Ptyp)
8048            and then Is_Constrained (Ptyp)
8049          then
8050             --  Do this optimization for discrete types only, and not for
8051             --  access types (access discriminants get us into trouble!)
8052
8053             if not Is_Discrete_Type (Etype (N)) then
8054                null;
8055
8056             --  Don't do this on the left hand of an assignment statement.
8057             --  Normally one would think that references like this would not
8058             --  occur, but they do in generated code, and mean that we really
8059             --  do want to assign the discriminant!
8060
8061             elsif Nkind (Par) = N_Assignment_Statement
8062               and then Name (Par) = N
8063             then
8064                null;
8065
8066             --  Don't do this optimization for the prefix of an attribute or
8067             --  the name of an object renaming declaration since these are
8068             --  contexts where we do not want the value anyway.
8069
8070             elsif (Nkind (Par) = N_Attribute_Reference
8071                      and then Prefix (Par) = N)
8072               or else Is_Renamed_Object (N)
8073             then
8074                null;
8075
8076             --  Don't do this optimization if we are within the code for a
8077             --  discriminant check, since the whole point of such a check may
8078             --  be to verify the condition on which the code below depends!
8079
8080             elsif Is_In_Discriminant_Check (N) then
8081                null;
8082
8083             --  Green light to see if we can do the optimization. There is
8084             --  still one condition that inhibits the optimization below but
8085             --  now is the time to check the particular discriminant.
8086
8087             else
8088                --  Loop through discriminants to find the matching discriminant
8089                --  constraint to see if we can copy it.
8090
8091                Disc := First_Discriminant (Ptyp);
8092                Dcon := First_Elmt (Discriminant_Constraint (Ptyp));
8093                Discr_Loop : while Present (Dcon) loop
8094                   Dval := Node (Dcon);
8095
8096                   --  Check if this is the matching discriminant and if the
8097                   --  discriminant value is simple enough to make sense to
8098                   --  copy. We don't want to copy complex expressions, and
8099                   --  indeed to do so can cause trouble (before we put in
8100                   --  this guard, a discriminant expression containing an
8101                   --  AND THEN was copied, causing problems for coverage
8102                   --  analysis tools).
8103
8104                   --  However, if the reference is part of the initialization
8105                   --  code generated for an object declaration, we must use
8106                   --  the discriminant value from the subtype constraint,
8107                   --  because the selected component may be a reference to the
8108                   --  object being initialized, whose discriminant is not yet
8109                   --  set. This only happens in complex cases involving changes
8110                   --  or representation.
8111
8112                   if Disc = Entity (Selector_Name (N))
8113                     and then (Is_Entity_Name (Dval)
8114                                or else Compile_Time_Known_Value (Dval)
8115                                or else Is_Subtype_Declaration)
8116                   then
8117                      --  Here we have the matching discriminant. Check for
8118                      --  the case of a discriminant of a component that is
8119                      --  constrained by an outer discriminant, which cannot
8120                      --  be optimized away.
8121
8122                      if Denotes_Discriminant
8123                           (Dval, Check_Concurrent => True)
8124                      then
8125                         exit Discr_Loop;
8126
8127                      elsif Nkind (Original_Node (Dval)) = N_Selected_Component
8128                        and then
8129                          Denotes_Discriminant
8130                            (Selector_Name (Original_Node (Dval)), True)
8131                      then
8132                         exit Discr_Loop;
8133
8134                      --  Do not retrieve value if constraint is not static. It
8135                      --  is generally not useful, and the constraint may be a
8136                      --  rewritten outer discriminant in which case it is in
8137                      --  fact incorrect.
8138
8139                      elsif Is_Entity_Name (Dval)
8140                        and then Nkind (Parent (Entity (Dval))) =
8141                                                       N_Object_Declaration
8142                        and then Present (Expression (Parent (Entity (Dval))))
8143                        and then
8144                          not Is_Static_Expression
8145                            (Expression (Parent (Entity (Dval))))
8146                      then
8147                         exit Discr_Loop;
8148
8149                      --  In the context of a case statement, the expression may
8150                      --  have the base type of the discriminant, and we need to
8151                      --  preserve the constraint to avoid spurious errors on
8152                      --  missing cases.
8153
8154                      elsif Nkind (Parent (N)) = N_Case_Statement
8155                        and then Etype (Dval) /= Etype (Disc)
8156                      then
8157                         Rewrite (N,
8158                           Make_Qualified_Expression (Loc,
8159                             Subtype_Mark =>
8160                               New_Occurrence_Of (Etype (Disc), Loc),
8161                             Expression   =>
8162                               New_Copy_Tree (Dval)));
8163                         Analyze_And_Resolve (N, Etype (Disc));
8164
8165                         --  In case that comes out as a static expression,
8166                         --  reset it (a selected component is never static).
8167
8168                         Set_Is_Static_Expression (N, False);
8169                         return;
8170
8171                      --  Otherwise we can just copy the constraint, but the
8172                      --  result is certainly not static! In some cases the
8173                      --  discriminant constraint has been analyzed in the
8174                      --  context of the original subtype indication, but for
8175                      --  itypes the constraint might not have been analyzed
8176                      --  yet, and this must be done now.
8177
8178                      else
8179                         Rewrite (N, New_Copy_Tree (Dval));
8180                         Analyze_And_Resolve (N);
8181                         Set_Is_Static_Expression (N, False);
8182                         return;
8183                      end if;
8184                   end if;
8185
8186                   Next_Elmt (Dcon);
8187                   Next_Discriminant (Disc);
8188                end loop Discr_Loop;
8189
8190                --  Note: the above loop should always find a matching
8191                --  discriminant, but if it does not, we just missed an
8192                --  optimization due to some glitch (perhaps a previous
8193                --  error), so ignore.
8194
8195             end if;
8196          end if;
8197
8198          --  The only remaining processing is in the case of a discriminant of
8199          --  a concurrent object, where we rewrite the prefix to denote the
8200          --  corresponding record type. If the type is derived and has renamed
8201          --  discriminants, use corresponding discriminant, which is the one
8202          --  that appears in the corresponding record.
8203
8204          if not Is_Concurrent_Type (Ptyp) then
8205             return;
8206          end if;
8207
8208          Disc := Entity (Selector_Name (N));
8209
8210          if Is_Derived_Type (Ptyp)
8211            and then Present (Corresponding_Discriminant (Disc))
8212          then
8213             Disc := Corresponding_Discriminant (Disc);
8214          end if;
8215
8216          New_N :=
8217            Make_Selected_Component (Loc,
8218              Prefix =>
8219                Unchecked_Convert_To (Corresponding_Record_Type (Ptyp),
8220                  New_Copy_Tree (P)),
8221              Selector_Name => Make_Identifier (Loc, Chars (Disc)));
8222
8223          Rewrite (N, New_N);
8224          Analyze (N);
8225       end if;
8226
8227       --  Set Atomic_Sync_Required if necessary for atomic component
8228
8229       if Nkind (N) = N_Selected_Component then
8230          declare
8231             E   : constant Entity_Id := Entity (Selector_Name (N));
8232             Set : Boolean;
8233
8234          begin
8235             --  If component is atomic, but type is not, setting depends on
8236             --  disable/enable state for the component.
8237
8238             if Is_Atomic (E) and then not Is_Atomic (Etype (E)) then
8239                Set := not Atomic_Synchronization_Disabled (E);
8240
8241             --  If component is not atomic, but its type is atomic, setting
8242             --  depends on disable/enable state for the type.
8243
8244             elsif not Is_Atomic (E) and then Is_Atomic (Etype (E)) then
8245                Set := not Atomic_Synchronization_Disabled (Etype (E));
8246
8247             --  If both component and type are atomic, we disable if either
8248             --  component or its type have sync disabled.
8249
8250             elsif Is_Atomic (E) and then Is_Atomic (Etype (E)) then
8251                Set := (not Atomic_Synchronization_Disabled (E))
8252                         and then
8253                       (not Atomic_Synchronization_Disabled (Etype (E)));
8254
8255             else
8256                Set := False;
8257             end if;
8258
8259             --  Set flag if required
8260
8261             if Set then
8262                Activate_Atomic_Synchronization (N);
8263             end if;
8264          end;
8265       end if;
8266    end Expand_N_Selected_Component;
8267
8268    --------------------
8269    -- Expand_N_Slice --
8270    --------------------
8271
8272    procedure Expand_N_Slice (N : Node_Id) is
8273       Loc  : constant Source_Ptr := Sloc (N);
8274       Typ  : constant Entity_Id  := Etype (N);
8275       Pfx  : constant Node_Id    := Prefix (N);
8276       Ptp  : Entity_Id           := Etype (Pfx);
8277
8278       function Is_Procedure_Actual (N : Node_Id) return Boolean;
8279       --  Check whether the argument is an actual for a procedure call, in
8280       --  which case the expansion of a bit-packed slice is deferred until the
8281       --  call itself is expanded. The reason this is required is that we might
8282       --  have an IN OUT or OUT parameter, and the copy out is essential, and
8283       --  that copy out would be missed if we created a temporary here in
8284       --  Expand_N_Slice. Note that we don't bother to test specifically for an
8285       --  IN OUT or OUT mode parameter, since it is a bit tricky to do, and it
8286       --  is harmless to defer expansion in the IN case, since the call
8287       --  processing will still generate the appropriate copy in operation,
8288       --  which will take care of the slice.
8289
8290       procedure Make_Temporary_For_Slice;
8291       --  Create a named variable for the value of the slice, in cases where
8292       --  the back-end cannot handle it properly, e.g. when packed types or
8293       --  unaligned slices are involved.
8294
8295       -------------------------
8296       -- Is_Procedure_Actual --
8297       -------------------------
8298
8299       function Is_Procedure_Actual (N : Node_Id) return Boolean is
8300          Par : Node_Id := Parent (N);
8301
8302       begin
8303          loop
8304             --  If our parent is a procedure call we can return
8305
8306             if Nkind (Par) = N_Procedure_Call_Statement then
8307                return True;
8308
8309             --  If our parent is a type conversion, keep climbing the tree,
8310             --  since a type conversion can be a procedure actual. Also keep
8311             --  climbing if parameter association or a qualified expression,
8312             --  since these are additional cases that do can appear on
8313             --  procedure actuals.
8314
8315             elsif Nkind_In (Par, N_Type_Conversion,
8316                                  N_Parameter_Association,
8317                                  N_Qualified_Expression)
8318             then
8319                Par := Parent (Par);
8320
8321                --  Any other case is not what we are looking for
8322
8323             else
8324                return False;
8325             end if;
8326          end loop;
8327       end Is_Procedure_Actual;
8328
8329       ------------------------------
8330       -- Make_Temporary_For_Slice --
8331       ------------------------------
8332
8333       procedure Make_Temporary_For_Slice is
8334          Decl : Node_Id;
8335          Ent  : constant Entity_Id := Make_Temporary (Loc, 'T', N);
8336
8337       begin
8338          Decl :=
8339            Make_Object_Declaration (Loc,
8340              Defining_Identifier => Ent,
8341              Object_Definition   => New_Occurrence_Of (Typ, Loc));
8342
8343          Set_No_Initialization (Decl);
8344
8345          Insert_Actions (N, New_List (
8346            Decl,
8347            Make_Assignment_Statement (Loc,
8348              Name => New_Occurrence_Of (Ent, Loc),
8349              Expression => Relocate_Node (N))));
8350
8351          Rewrite (N, New_Occurrence_Of (Ent, Loc));
8352          Analyze_And_Resolve (N, Typ);
8353       end Make_Temporary_For_Slice;
8354
8355    --  Start of processing for Expand_N_Slice
8356
8357    begin
8358       --  Special handling for access types
8359
8360       if Is_Access_Type (Ptp) then
8361
8362          Ptp := Designated_Type (Ptp);
8363
8364          Rewrite (Pfx,
8365            Make_Explicit_Dereference (Sloc (N),
8366             Prefix => Relocate_Node (Pfx)));
8367
8368          Analyze_And_Resolve (Pfx, Ptp);
8369       end if;
8370
8371       --  Ada 2005 (AI-318-02): If the prefix is a call to a build-in-place
8372       --  function, then additional actuals must be passed.
8373
8374       if Ada_Version >= Ada_2005
8375         and then Is_Build_In_Place_Function_Call (Pfx)
8376       then
8377          Make_Build_In_Place_Call_In_Anonymous_Context (Pfx);
8378       end if;
8379
8380       --  The remaining case to be handled is packed slices. We can leave
8381       --  packed slices as they are in the following situations:
8382
8383       --    1. Right or left side of an assignment (we can handle this
8384       --       situation correctly in the assignment statement expansion).
8385
8386       --    2. Prefix of indexed component (the slide is optimized away in this
8387       --       case, see the start of Expand_N_Slice.)
8388
8389       --    3. Object renaming declaration, since we want the name of the
8390       --       slice, not the value.
8391
8392       --    4. Argument to procedure call, since copy-in/copy-out handling may
8393       --       be required, and this is handled in the expansion of call
8394       --       itself.
8395
8396       --    5. Prefix of an address attribute (this is an error which is caught
8397       --       elsewhere, and the expansion would interfere with generating the
8398       --       error message).
8399
8400       if not Is_Packed (Typ) then
8401
8402          --  Apply transformation for actuals of a function call, where
8403          --  Expand_Actuals is not used.
8404
8405          if Nkind (Parent (N)) = N_Function_Call
8406            and then Is_Possibly_Unaligned_Slice (N)
8407          then
8408             Make_Temporary_For_Slice;
8409          end if;
8410
8411       elsif Nkind (Parent (N)) = N_Assignment_Statement
8412         or else (Nkind (Parent (Parent (N))) = N_Assignment_Statement
8413                    and then Parent (N) = Name (Parent (Parent (N))))
8414       then
8415          return;
8416
8417       elsif Nkind (Parent (N)) = N_Indexed_Component
8418         or else Is_Renamed_Object (N)
8419         or else Is_Procedure_Actual (N)
8420       then
8421          return;
8422
8423       elsif Nkind (Parent (N)) = N_Attribute_Reference
8424         and then Attribute_Name (Parent (N)) = Name_Address
8425       then
8426          return;
8427
8428       else
8429          Make_Temporary_For_Slice;
8430       end if;
8431    end Expand_N_Slice;
8432
8433    ------------------------------
8434    -- Expand_N_Type_Conversion --
8435    ------------------------------
8436
8437    procedure Expand_N_Type_Conversion (N : Node_Id) is
8438       Loc          : constant Source_Ptr := Sloc (N);
8439       Operand      : constant Node_Id    := Expression (N);
8440       Target_Type  : constant Entity_Id  := Etype (N);
8441       Operand_Type : Entity_Id           := Etype (Operand);
8442
8443       procedure Handle_Changed_Representation;
8444       --  This is called in the case of record and array type conversions to
8445       --  see if there is a change of representation to be handled. Change of
8446       --  representation is actually handled at the assignment statement level,
8447       --  and what this procedure does is rewrite node N conversion as an
8448       --  assignment to temporary. If there is no change of representation,
8449       --  then the conversion node is unchanged.
8450
8451       procedure Raise_Accessibility_Error;
8452       --  Called when we know that an accessibility check will fail. Rewrites
8453       --  node N to an appropriate raise statement and outputs warning msgs.
8454       --  The Etype of the raise node is set to Target_Type.
8455
8456       procedure Real_Range_Check;
8457       --  Handles generation of range check for real target value
8458
8459       function Has_Extra_Accessibility (Id : Entity_Id) return Boolean;
8460       --  True iff Present (Effective_Extra_Accessibility (Id)) successfully
8461       --  evaluates to True.
8462
8463       -----------------------------------
8464       -- Handle_Changed_Representation --
8465       -----------------------------------
8466
8467       procedure Handle_Changed_Representation is
8468          Temp : Entity_Id;
8469          Decl : Node_Id;
8470          Odef : Node_Id;
8471          Disc : Node_Id;
8472          N_Ix : Node_Id;
8473          Cons : List_Id;
8474
8475       begin
8476          --  Nothing else to do if no change of representation
8477
8478          if Same_Representation (Operand_Type, Target_Type) then
8479             return;
8480
8481          --  The real change of representation work is done by the assignment
8482          --  statement processing. So if this type conversion is appearing as
8483          --  the expression of an assignment statement, nothing needs to be
8484          --  done to the conversion.
8485
8486          elsif Nkind (Parent (N)) = N_Assignment_Statement then
8487             return;
8488
8489          --  Otherwise we need to generate a temporary variable, and do the
8490          --  change of representation assignment into that temporary variable.
8491          --  The conversion is then replaced by a reference to this variable.
8492
8493          else
8494             Cons := No_List;
8495
8496             --  If type is unconstrained we have to add a constraint, copied
8497             --  from the actual value of the left hand side.
8498
8499             if not Is_Constrained (Target_Type) then
8500                if Has_Discriminants (Operand_Type) then
8501                   Disc := First_Discriminant (Operand_Type);
8502
8503                   if Disc /= First_Stored_Discriminant (Operand_Type) then
8504                      Disc := First_Stored_Discriminant (Operand_Type);
8505                   end if;
8506
8507                   Cons := New_List;
8508                   while Present (Disc) loop
8509                      Append_To (Cons,
8510                        Make_Selected_Component (Loc,
8511                          Prefix        =>
8512                            Duplicate_Subexpr_Move_Checks (Operand),
8513                          Selector_Name =>
8514                            Make_Identifier (Loc, Chars (Disc))));
8515                      Next_Discriminant (Disc);
8516                   end loop;
8517
8518                elsif Is_Array_Type (Operand_Type) then
8519                   N_Ix := First_Index (Target_Type);
8520                   Cons := New_List;
8521
8522                   for J in 1 .. Number_Dimensions (Operand_Type) loop
8523
8524                      --  We convert the bounds explicitly. We use an unchecked
8525                      --  conversion because bounds checks are done elsewhere.
8526
8527                      Append_To (Cons,
8528                        Make_Range (Loc,
8529                          Low_Bound =>
8530                            Unchecked_Convert_To (Etype (N_Ix),
8531                              Make_Attribute_Reference (Loc,
8532                                Prefix =>
8533                                  Duplicate_Subexpr_No_Checks
8534                                    (Operand, Name_Req => True),
8535                                Attribute_Name => Name_First,
8536                                Expressions    => New_List (
8537                                  Make_Integer_Literal (Loc, J)))),
8538
8539                          High_Bound =>
8540                            Unchecked_Convert_To (Etype (N_Ix),
8541                              Make_Attribute_Reference (Loc,
8542                                Prefix =>
8543                                  Duplicate_Subexpr_No_Checks
8544                                    (Operand, Name_Req => True),
8545                                Attribute_Name => Name_Last,
8546                                Expressions    => New_List (
8547                                  Make_Integer_Literal (Loc, J))))));
8548
8549                      Next_Index (N_Ix);
8550                   end loop;
8551                end if;
8552             end if;
8553
8554             Odef := New_Occurrence_Of (Target_Type, Loc);
8555
8556             if Present (Cons) then
8557                Odef :=
8558                  Make_Subtype_Indication (Loc,
8559                    Subtype_Mark => Odef,
8560                    Constraint =>
8561                      Make_Index_Or_Discriminant_Constraint (Loc,
8562                        Constraints => Cons));
8563             end if;
8564
8565             Temp := Make_Temporary (Loc, 'C');
8566             Decl :=
8567               Make_Object_Declaration (Loc,
8568                 Defining_Identifier => Temp,
8569                 Object_Definition   => Odef);
8570
8571             Set_No_Initialization (Decl, True);
8572
8573             --  Insert required actions. It is essential to suppress checks
8574             --  since we have suppressed default initialization, which means
8575             --  that the variable we create may have no discriminants.
8576
8577             Insert_Actions (N,
8578               New_List (
8579                 Decl,
8580                 Make_Assignment_Statement (Loc,
8581                   Name => New_Occurrence_Of (Temp, Loc),
8582                   Expression => Relocate_Node (N))),
8583                 Suppress => All_Checks);
8584
8585             Rewrite (N, New_Occurrence_Of (Temp, Loc));
8586             return;
8587          end if;
8588       end Handle_Changed_Representation;
8589
8590       -------------------------------
8591       -- Raise_Accessibility_Error --
8592       -------------------------------
8593
8594       procedure Raise_Accessibility_Error is
8595       begin
8596          Rewrite (N,
8597            Make_Raise_Program_Error (Sloc (N),
8598              Reason => PE_Accessibility_Check_Failed));
8599          Set_Etype (N, Target_Type);
8600
8601          Error_Msg_N ("?accessibility check failure", N);
8602          Error_Msg_NE
8603            ("\?& will be raised at run time", N, Standard_Program_Error);
8604       end Raise_Accessibility_Error;
8605
8606       ----------------------
8607       -- Real_Range_Check --
8608       ----------------------
8609
8610       --  Case of conversions to floating-point or fixed-point. If range checks
8611       --  are enabled and the target type has a range constraint, we convert:
8612
8613       --     typ (x)
8614
8615       --       to
8616
8617       --     Tnn : typ'Base := typ'Base (x);
8618       --     [constraint_error when Tnn < typ'First or else Tnn > typ'Last]
8619       --     Tnn
8620
8621       --  This is necessary when there is a conversion of integer to float or
8622       --  to fixed-point to ensure that the correct checks are made. It is not
8623       --  necessary for float to float where it is enough to simply set the
8624       --  Do_Range_Check flag.
8625
8626       procedure Real_Range_Check is
8627          Btyp : constant Entity_Id := Base_Type (Target_Type);
8628          Lo   : constant Node_Id   := Type_Low_Bound  (Target_Type);
8629          Hi   : constant Node_Id   := Type_High_Bound (Target_Type);
8630          Xtyp : constant Entity_Id := Etype (Operand);
8631          Conv : Node_Id;
8632          Tnn  : Entity_Id;
8633
8634       begin
8635          --  Nothing to do if conversion was rewritten
8636
8637          if Nkind (N) /= N_Type_Conversion then
8638             return;
8639          end if;
8640
8641          --  Nothing to do if range checks suppressed, or target has the same
8642          --  range as the base type (or is the base type).
8643
8644          if Range_Checks_Suppressed (Target_Type)
8645            or else (Lo = Type_Low_Bound (Btyp)
8646                       and then
8647                     Hi = Type_High_Bound (Btyp))
8648          then
8649             return;
8650          end if;
8651
8652          --  Nothing to do if expression is an entity on which checks have been
8653          --  suppressed.
8654
8655          if Is_Entity_Name (Operand)
8656            and then Range_Checks_Suppressed (Entity (Operand))
8657          then
8658             return;
8659          end if;
8660
8661          --  Nothing to do if bounds are all static and we can tell that the
8662          --  expression is within the bounds of the target. Note that if the
8663          --  operand is of an unconstrained floating-point type, then we do
8664          --  not trust it to be in range (might be infinite)
8665
8666          declare
8667             S_Lo : constant Node_Id := Type_Low_Bound (Xtyp);
8668             S_Hi : constant Node_Id := Type_High_Bound (Xtyp);
8669
8670          begin
8671             if (not Is_Floating_Point_Type (Xtyp)
8672                  or else Is_Constrained (Xtyp))
8673               and then Compile_Time_Known_Value (S_Lo)
8674               and then Compile_Time_Known_Value (S_Hi)
8675               and then Compile_Time_Known_Value (Hi)
8676               and then Compile_Time_Known_Value (Lo)
8677             then
8678                declare
8679                   D_Lov : constant Ureal := Expr_Value_R (Lo);
8680                   D_Hiv : constant Ureal := Expr_Value_R (Hi);
8681                   S_Lov : Ureal;
8682                   S_Hiv : Ureal;
8683
8684                begin
8685                   if Is_Real_Type (Xtyp) then
8686                      S_Lov := Expr_Value_R (S_Lo);
8687                      S_Hiv := Expr_Value_R (S_Hi);
8688                   else
8689                      S_Lov := UR_From_Uint (Expr_Value (S_Lo));
8690                      S_Hiv := UR_From_Uint (Expr_Value (S_Hi));
8691                   end if;
8692
8693                   if D_Hiv > D_Lov
8694                     and then S_Lov >= D_Lov
8695                     and then S_Hiv <= D_Hiv
8696                   then
8697                      Set_Do_Range_Check (Operand, False);
8698                      return;
8699                   end if;
8700                end;
8701             end if;
8702          end;
8703
8704          --  For float to float conversions, we are done
8705
8706          if Is_Floating_Point_Type (Xtyp)
8707               and then
8708             Is_Floating_Point_Type (Btyp)
8709          then
8710             return;
8711          end if;
8712
8713          --  Otherwise rewrite the conversion as described above
8714
8715          Conv := Relocate_Node (N);
8716          Rewrite (Subtype_Mark (Conv), New_Occurrence_Of (Btyp, Loc));
8717          Set_Etype (Conv, Btyp);
8718
8719          --  Enable overflow except for case of integer to float conversions,
8720          --  where it is never required, since we can never have overflow in
8721          --  this case.
8722
8723          if not Is_Integer_Type (Etype (Operand)) then
8724             Enable_Overflow_Check (Conv);
8725          end if;
8726
8727          Tnn := Make_Temporary (Loc, 'T', Conv);
8728
8729          Insert_Actions (N, New_List (
8730            Make_Object_Declaration (Loc,
8731              Defining_Identifier => Tnn,
8732              Object_Definition   => New_Occurrence_Of (Btyp, Loc),
8733              Constant_Present    => True,
8734              Expression          => Conv),
8735
8736            Make_Raise_Constraint_Error (Loc,
8737              Condition =>
8738               Make_Or_Else (Loc,
8739                 Left_Opnd =>
8740                   Make_Op_Lt (Loc,
8741                     Left_Opnd  => New_Occurrence_Of (Tnn, Loc),
8742                     Right_Opnd =>
8743                       Make_Attribute_Reference (Loc,
8744                         Attribute_Name => Name_First,
8745                         Prefix =>
8746                           New_Occurrence_Of (Target_Type, Loc))),
8747
8748                 Right_Opnd =>
8749                   Make_Op_Gt (Loc,
8750                     Left_Opnd  => New_Occurrence_Of (Tnn, Loc),
8751                     Right_Opnd =>
8752                       Make_Attribute_Reference (Loc,
8753                         Attribute_Name => Name_Last,
8754                         Prefix =>
8755                           New_Occurrence_Of (Target_Type, Loc)))),
8756              Reason => CE_Range_Check_Failed)));
8757
8758          Rewrite (N, New_Occurrence_Of (Tnn, Loc));
8759          Analyze_And_Resolve (N, Btyp);
8760       end Real_Range_Check;
8761
8762       -----------------------------
8763       -- Has_Extra_Accessibility --
8764       -----------------------------
8765
8766       --  Returns true for a formal of an anonymous access type or for
8767       --  an Ada 2012-style stand-alone object of an anonymous access type.
8768
8769       function Has_Extra_Accessibility (Id : Entity_Id) return Boolean is
8770       begin
8771          if Is_Formal (Id) or else Ekind_In (Id, E_Constant, E_Variable) then
8772             return Present (Effective_Extra_Accessibility (Id));
8773          else
8774             return False;
8775          end if;
8776       end Has_Extra_Accessibility;
8777
8778    --  Start of processing for Expand_N_Type_Conversion
8779
8780    begin
8781       --  Nothing at all to do if conversion is to the identical type so remove
8782       --  the conversion completely, it is useless, except that it may carry
8783       --  an Assignment_OK attribute, which must be propagated to the operand.
8784
8785       if Operand_Type = Target_Type then
8786          if Assignment_OK (N) then
8787             Set_Assignment_OK (Operand);
8788          end if;
8789
8790          Rewrite (N, Relocate_Node (Operand));
8791          goto Done;
8792       end if;
8793
8794       --  Nothing to do if this is the second argument of read. This is a
8795       --  "backwards" conversion that will be handled by the specialized code
8796       --  in attribute processing.
8797
8798       if Nkind (Parent (N)) = N_Attribute_Reference
8799         and then Attribute_Name (Parent (N)) = Name_Read
8800         and then Next (First (Expressions (Parent (N)))) = N
8801       then
8802          goto Done;
8803       end if;
8804
8805       --  Check for case of converting to a type that has an invariant
8806       --  associated with it. This required an invariant check. We convert
8807
8808       --    typ (expr)
8809
8810       --  into
8811
8812       --    do invariant_check (typ (expr)) in typ (expr);
8813
8814       --  using Duplicate_Subexpr to avoid multiple side effects
8815
8816       --  Note: the Comes_From_Source check, and then the resetting of this
8817       --  flag prevents what would otherwise be an infinite recursion.
8818
8819       if Has_Invariants (Target_Type)
8820         and then Present (Invariant_Procedure (Target_Type))
8821         and then Comes_From_Source (N)
8822       then
8823          Set_Comes_From_Source (N, False);
8824          Rewrite (N,
8825            Make_Expression_With_Actions (Loc,
8826              Actions    => New_List (
8827                Make_Invariant_Call (Duplicate_Subexpr (N))),
8828              Expression => Duplicate_Subexpr_No_Checks (N)));
8829          Analyze_And_Resolve (N, Target_Type);
8830          goto Done;
8831       end if;
8832
8833       --  Here if we may need to expand conversion
8834
8835       --  If the operand of the type conversion is an arithmetic operation on
8836       --  signed integers, and the based type of the signed integer type in
8837       --  question is smaller than Standard.Integer, we promote both of the
8838       --  operands to type Integer.
8839
8840       --  For example, if we have
8841
8842       --     target-type (opnd1 + opnd2)
8843
8844       --  and opnd1 and opnd2 are of type short integer, then we rewrite
8845       --  this as:
8846
8847       --     target-type (integer(opnd1) + integer(opnd2))
8848
8849       --  We do this because we are always allowed to compute in a larger type
8850       --  if we do the right thing with the result, and in this case we are
8851       --  going to do a conversion which will do an appropriate check to make
8852       --  sure that things are in range of the target type in any case. This
8853       --  avoids some unnecessary intermediate overflows.
8854
8855       --  We might consider a similar transformation in the case where the
8856       --  target is a real type or a 64-bit integer type, and the operand
8857       --  is an arithmetic operation using a 32-bit integer type. However,
8858       --  we do not bother with this case, because it could cause significant
8859       --  inefficiencies on 32-bit machines. On a 64-bit machine it would be
8860       --  much cheaper, but we don't want different behavior on 32-bit and
8861       --  64-bit machines. Note that the exclusion of the 64-bit case also
8862       --  handles the configurable run-time cases where 64-bit arithmetic
8863       --  may simply be unavailable.
8864
8865       --  Note: this circuit is partially redundant with respect to the circuit
8866       --  in Checks.Apply_Arithmetic_Overflow_Check, but we catch more cases in
8867       --  the processing here. Also we still need the Checks circuit, since we
8868       --  have to be sure not to generate junk overflow checks in the first
8869       --  place, since it would be trick to remove them here!
8870
8871       if Integer_Promotion_Possible (N) then
8872
8873          --  All conditions met, go ahead with transformation
8874
8875          declare
8876             Opnd : Node_Id;
8877             L, R : Node_Id;
8878
8879          begin
8880             R :=
8881               Make_Type_Conversion (Loc,
8882                 Subtype_Mark => New_Reference_To (Standard_Integer, Loc),
8883                 Expression   => Relocate_Node (Right_Opnd (Operand)));
8884
8885             Opnd := New_Op_Node (Nkind (Operand), Loc);
8886             Set_Right_Opnd (Opnd, R);
8887
8888             if Nkind (Operand) in N_Binary_Op then
8889                L :=
8890                  Make_Type_Conversion (Loc,
8891                    Subtype_Mark => New_Reference_To (Standard_Integer, Loc),
8892                    Expression   => Relocate_Node (Left_Opnd (Operand)));
8893
8894                Set_Left_Opnd  (Opnd, L);
8895             end if;
8896
8897             Rewrite (N,
8898               Make_Type_Conversion (Loc,
8899                 Subtype_Mark => Relocate_Node (Subtype_Mark (N)),
8900                 Expression   => Opnd));
8901
8902             Analyze_And_Resolve (N, Target_Type);
8903             goto Done;
8904          end;
8905       end if;
8906
8907       --  Do validity check if validity checking operands
8908
8909       if Validity_Checks_On
8910         and then Validity_Check_Operands
8911       then
8912          Ensure_Valid (Operand);
8913       end if;
8914
8915       --  Special case of converting from non-standard boolean type
8916
8917       if Is_Boolean_Type (Operand_Type)
8918         and then (Nonzero_Is_True (Operand_Type))
8919       then
8920          Adjust_Condition (Operand);
8921          Set_Etype (Operand, Standard_Boolean);
8922          Operand_Type := Standard_Boolean;
8923       end if;
8924
8925       --  Case of converting to an access type
8926
8927       if Is_Access_Type (Target_Type) then
8928
8929          --  Apply an accessibility check when the conversion operand is an
8930          --  access parameter (or a renaming thereof), unless conversion was
8931          --  expanded from an Unchecked_ or Unrestricted_Access attribute.
8932          --  Note that other checks may still need to be applied below (such
8933          --  as tagged type checks).
8934
8935          if Is_Entity_Name (Operand)
8936            and then Has_Extra_Accessibility (Entity (Operand))
8937            and then Ekind (Etype (Operand)) = E_Anonymous_Access_Type
8938            and then (Nkind (Original_Node (N)) /= N_Attribute_Reference
8939                       or else Attribute_Name (Original_Node (N)) = Name_Access)
8940          then
8941             Apply_Accessibility_Check
8942               (Operand, Target_Type, Insert_Node => Operand);
8943
8944          --  If the level of the operand type is statically deeper than the
8945          --  level of the target type, then force Program_Error. Note that this
8946          --  can only occur for cases where the attribute is within the body of
8947          --  an instantiation (otherwise the conversion will already have been
8948          --  rejected as illegal). Note: warnings are issued by the analyzer
8949          --  for the instance cases.
8950
8951          elsif In_Instance_Body
8952            and then Type_Access_Level (Operand_Type) >
8953                     Type_Access_Level (Target_Type)
8954          then
8955             Raise_Accessibility_Error;
8956
8957          --  When the operand is a selected access discriminant the check needs
8958          --  to be made against the level of the object denoted by the prefix
8959          --  of the selected name. Force Program_Error for this case as well
8960          --  (this accessibility violation can only happen if within the body
8961          --  of an instantiation).
8962
8963          elsif In_Instance_Body
8964            and then Ekind (Operand_Type) = E_Anonymous_Access_Type
8965            and then Nkind (Operand) = N_Selected_Component
8966            and then Object_Access_Level (Operand) >
8967                       Type_Access_Level (Target_Type)
8968          then
8969             Raise_Accessibility_Error;
8970             goto Done;
8971          end if;
8972       end if;
8973
8974       --  Case of conversions of tagged types and access to tagged types
8975
8976       --  When needed, that is to say when the expression is class-wide, Add
8977       --  runtime a tag check for (strict) downward conversion by using the
8978       --  membership test, generating:
8979
8980       --      [constraint_error when Operand not in Target_Type'Class]
8981
8982       --  or in the access type case
8983
8984       --      [constraint_error
8985       --        when Operand /= null
8986       --          and then Operand.all not in
8987       --            Designated_Type (Target_Type)'Class]
8988
8989       if (Is_Access_Type (Target_Type)
8990            and then Is_Tagged_Type (Designated_Type (Target_Type)))
8991         or else Is_Tagged_Type (Target_Type)
8992       then
8993          --  Do not do any expansion in the access type case if the parent is a
8994          --  renaming, since this is an error situation which will be caught by
8995          --  Sem_Ch8, and the expansion can interfere with this error check.
8996
8997          if Is_Access_Type (Target_Type) and then Is_Renamed_Object (N) then
8998             goto Done;
8999          end if;
9000
9001          --  Otherwise, proceed with processing tagged conversion
9002
9003          Tagged_Conversion : declare
9004             Actual_Op_Typ   : Entity_Id;
9005             Actual_Targ_Typ : Entity_Id;
9006             Make_Conversion : Boolean := False;
9007             Root_Op_Typ     : Entity_Id;
9008
9009             procedure Make_Tag_Check (Targ_Typ : Entity_Id);
9010             --  Create a membership check to test whether Operand is a member
9011             --  of Targ_Typ. If the original Target_Type is an access, include
9012             --  a test for null value. The check is inserted at N.
9013
9014             --------------------
9015             -- Make_Tag_Check --
9016             --------------------
9017
9018             procedure Make_Tag_Check (Targ_Typ : Entity_Id) is
9019                Cond : Node_Id;
9020
9021             begin
9022                --  Generate:
9023                --    [Constraint_Error
9024                --       when Operand /= null
9025                --         and then Operand.all not in Targ_Typ]
9026
9027                if Is_Access_Type (Target_Type) then
9028                   Cond :=
9029                     Make_And_Then (Loc,
9030                       Left_Opnd =>
9031                         Make_Op_Ne (Loc,
9032                           Left_Opnd  => Duplicate_Subexpr_No_Checks (Operand),
9033                           Right_Opnd => Make_Null (Loc)),
9034
9035                       Right_Opnd =>
9036                         Make_Not_In (Loc,
9037                           Left_Opnd  =>
9038                             Make_Explicit_Dereference (Loc,
9039                               Prefix => Duplicate_Subexpr_No_Checks (Operand)),
9040                           Right_Opnd => New_Reference_To (Targ_Typ, Loc)));
9041
9042                --  Generate:
9043                --    [Constraint_Error when Operand not in Targ_Typ]
9044
9045                else
9046                   Cond :=
9047                     Make_Not_In (Loc,
9048                       Left_Opnd  => Duplicate_Subexpr_No_Checks (Operand),
9049                       Right_Opnd => New_Reference_To (Targ_Typ, Loc));
9050                end if;
9051
9052                Insert_Action (N,
9053                  Make_Raise_Constraint_Error (Loc,
9054                    Condition => Cond,
9055                    Reason    => CE_Tag_Check_Failed));
9056             end Make_Tag_Check;
9057
9058          --  Start of processing for Tagged_Conversion
9059
9060          begin
9061             --  Handle entities from the limited view
9062
9063             if Is_Access_Type (Operand_Type) then
9064                Actual_Op_Typ :=
9065                  Available_View (Designated_Type (Operand_Type));
9066             else
9067                Actual_Op_Typ := Operand_Type;
9068             end if;
9069
9070             if Is_Access_Type (Target_Type) then
9071                Actual_Targ_Typ :=
9072                  Available_View (Designated_Type (Target_Type));
9073             else
9074                Actual_Targ_Typ := Target_Type;
9075             end if;
9076
9077             Root_Op_Typ := Root_Type (Actual_Op_Typ);
9078
9079             --  Ada 2005 (AI-251): Handle interface type conversion
9080
9081             if Is_Interface (Actual_Op_Typ) then
9082                Expand_Interface_Conversion (N, Is_Static => False);
9083                goto Done;
9084             end if;
9085
9086             if not Tag_Checks_Suppressed (Actual_Targ_Typ) then
9087
9088                --  Create a runtime tag check for a downward class-wide type
9089                --  conversion.
9090
9091                if Is_Class_Wide_Type (Actual_Op_Typ)
9092                  and then Actual_Op_Typ /= Actual_Targ_Typ
9093                  and then Root_Op_Typ /= Actual_Targ_Typ
9094                  and then Is_Ancestor (Root_Op_Typ, Actual_Targ_Typ,
9095                                        Use_Full_View => True)
9096                then
9097                   Make_Tag_Check (Class_Wide_Type (Actual_Targ_Typ));
9098                   Make_Conversion := True;
9099                end if;
9100
9101                --  AI05-0073: If the result subtype of the function is defined
9102                --  by an access_definition designating a specific tagged type
9103                --  T, a check is made that the result value is null or the tag
9104                --  of the object designated by the result value identifies T.
9105                --  Constraint_Error is raised if this check fails.
9106
9107                if Nkind (Parent (N)) = Sinfo.N_Return_Statement then
9108                   declare
9109                      Func     : Entity_Id;
9110                      Func_Typ : Entity_Id;
9111
9112                   begin
9113                      --  Climb scope stack looking for the enclosing function
9114
9115                      Func := Current_Scope;
9116                      while Present (Func)
9117                        and then Ekind (Func) /= E_Function
9118                      loop
9119                         Func := Scope (Func);
9120                      end loop;
9121
9122                      --  The function's return subtype must be defined using
9123                      --  an access definition.
9124
9125                      if Nkind (Result_Definition (Parent (Func))) =
9126                           N_Access_Definition
9127                      then
9128                         Func_Typ := Directly_Designated_Type (Etype (Func));
9129
9130                         --  The return subtype denotes a specific tagged type,
9131                         --  in other words, a non class-wide type.
9132
9133                         if Is_Tagged_Type (Func_Typ)
9134                           and then not Is_Class_Wide_Type (Func_Typ)
9135                         then
9136                            Make_Tag_Check (Actual_Targ_Typ);
9137                            Make_Conversion := True;
9138                         end if;
9139                      end if;
9140                   end;
9141                end if;
9142
9143                --  We have generated a tag check for either a class-wide type
9144                --  conversion or for AI05-0073.
9145
9146                if Make_Conversion then
9147                   declare
9148                      Conv : Node_Id;
9149                   begin
9150                      Conv :=
9151                        Make_Unchecked_Type_Conversion (Loc,
9152                          Subtype_Mark => New_Occurrence_Of (Target_Type, Loc),
9153                          Expression   => Relocate_Node (Expression (N)));
9154                      Rewrite (N, Conv);
9155                      Analyze_And_Resolve (N, Target_Type);
9156                   end;
9157                end if;
9158             end if;
9159          end Tagged_Conversion;
9160
9161       --  Case of other access type conversions
9162
9163       elsif Is_Access_Type (Target_Type) then
9164          Apply_Constraint_Check (Operand, Target_Type);
9165
9166       --  Case of conversions from a fixed-point type
9167
9168       --  These conversions require special expansion and processing, found in
9169       --  the Exp_Fixd package. We ignore cases where Conversion_OK is set,
9170       --  since from a semantic point of view, these are simple integer
9171       --  conversions, which do not need further processing.
9172
9173       elsif Is_Fixed_Point_Type (Operand_Type)
9174         and then not Conversion_OK (N)
9175       then
9176          --  We should never see universal fixed at this case, since the
9177          --  expansion of the constituent divide or multiply should have
9178          --  eliminated the explicit mention of universal fixed.
9179
9180          pragma Assert (Operand_Type /= Universal_Fixed);
9181
9182          --  Check for special case of the conversion to universal real that
9183          --  occurs as a result of the use of a round attribute. In this case,
9184          --  the real type for the conversion is taken from the target type of
9185          --  the Round attribute and the result must be marked as rounded.
9186
9187          if Target_Type = Universal_Real
9188            and then Nkind (Parent (N)) = N_Attribute_Reference
9189            and then Attribute_Name (Parent (N)) = Name_Round
9190          then
9191             Set_Rounded_Result (N);
9192             Set_Etype (N, Etype (Parent (N)));
9193          end if;
9194
9195          --  Otherwise do correct fixed-conversion, but skip these if the
9196          --  Conversion_OK flag is set, because from a semantic point of view
9197          --  these are simple integer conversions needing no further processing
9198          --  (the backend will simply treat them as integers).
9199
9200          if not Conversion_OK (N) then
9201             if Is_Fixed_Point_Type (Etype (N)) then
9202                Expand_Convert_Fixed_To_Fixed (N);
9203                Real_Range_Check;
9204
9205             elsif Is_Integer_Type (Etype (N)) then
9206                Expand_Convert_Fixed_To_Integer (N);
9207
9208             else
9209                pragma Assert (Is_Floating_Point_Type (Etype (N)));
9210                Expand_Convert_Fixed_To_Float (N);
9211                Real_Range_Check;
9212             end if;
9213          end if;
9214
9215       --  Case of conversions to a fixed-point type
9216
9217       --  These conversions require special expansion and processing, found in
9218       --  the Exp_Fixd package. Again, ignore cases where Conversion_OK is set,
9219       --  since from a semantic point of view, these are simple integer
9220       --  conversions, which do not need further processing.
9221
9222       elsif Is_Fixed_Point_Type (Target_Type)
9223         and then not Conversion_OK (N)
9224       then
9225          if Is_Integer_Type (Operand_Type) then
9226             Expand_Convert_Integer_To_Fixed (N);
9227             Real_Range_Check;
9228          else
9229             pragma Assert (Is_Floating_Point_Type (Operand_Type));
9230             Expand_Convert_Float_To_Fixed (N);
9231             Real_Range_Check;
9232          end if;
9233
9234       --  Case of float-to-integer conversions
9235
9236       --  We also handle float-to-fixed conversions with Conversion_OK set
9237       --  since semantically the fixed-point target is treated as though it
9238       --  were an integer in such cases.
9239
9240       elsif Is_Floating_Point_Type (Operand_Type)
9241         and then
9242           (Is_Integer_Type (Target_Type)
9243             or else
9244           (Is_Fixed_Point_Type (Target_Type) and then Conversion_OK (N)))
9245       then
9246          --  One more check here, gcc is still not able to do conversions of
9247          --  this type with proper overflow checking, and so gigi is doing an
9248          --  approximation of what is required by doing floating-point compares
9249          --  with the end-point. But that can lose precision in some cases, and
9250          --  give a wrong result. Converting the operand to Universal_Real is
9251          --  helpful, but still does not catch all cases with 64-bit integers
9252          --  on targets with only 64-bit floats.
9253
9254          --  The above comment seems obsoleted by Apply_Float_Conversion_Check
9255          --  Can this code be removed ???
9256
9257          if Do_Range_Check (Operand) then
9258             Rewrite (Operand,
9259               Make_Type_Conversion (Loc,
9260                 Subtype_Mark =>
9261                   New_Occurrence_Of (Universal_Real, Loc),
9262                 Expression =>
9263                   Relocate_Node (Operand)));
9264
9265             Set_Etype (Operand, Universal_Real);
9266             Enable_Range_Check (Operand);
9267             Set_Do_Range_Check (Expression (Operand), False);
9268          end if;
9269
9270       --  Case of array conversions
9271
9272       --  Expansion of array conversions, add required length/range checks but
9273       --  only do this if there is no change of representation. For handling of
9274       --  this case, see Handle_Changed_Representation.
9275
9276       elsif Is_Array_Type (Target_Type) then
9277          if Is_Constrained (Target_Type) then
9278             Apply_Length_Check (Operand, Target_Type);
9279          else
9280             Apply_Range_Check (Operand, Target_Type);
9281          end if;
9282
9283          Handle_Changed_Representation;
9284
9285       --  Case of conversions of discriminated types
9286
9287       --  Add required discriminant checks if target is constrained. Again this
9288       --  change is skipped if we have a change of representation.
9289
9290       elsif Has_Discriminants (Target_Type)
9291         and then Is_Constrained (Target_Type)
9292       then
9293          Apply_Discriminant_Check (Operand, Target_Type);
9294          Handle_Changed_Representation;
9295
9296       --  Case of all other record conversions. The only processing required
9297       --  is to check for a change of representation requiring the special
9298       --  assignment processing.
9299
9300       elsif Is_Record_Type (Target_Type) then
9301
9302          --  Ada 2005 (AI-216): Program_Error is raised when converting from
9303          --  a derived Unchecked_Union type to an unconstrained type that is
9304          --  not Unchecked_Union if the operand lacks inferable discriminants.
9305
9306          if Is_Derived_Type (Operand_Type)
9307            and then Is_Unchecked_Union (Base_Type (Operand_Type))
9308            and then not Is_Constrained (Target_Type)
9309            and then not Is_Unchecked_Union (Base_Type (Target_Type))
9310            and then not Has_Inferable_Discriminants (Operand)
9311          then
9312             --  To prevent Gigi from generating illegal code, we generate a
9313             --  Program_Error node, but we give it the target type of the
9314             --  conversion.
9315
9316             declare
9317                PE : constant Node_Id := Make_Raise_Program_Error (Loc,
9318                       Reason => PE_Unchecked_Union_Restriction);
9319
9320             begin
9321                Set_Etype (PE, Target_Type);
9322                Rewrite (N, PE);
9323
9324             end;
9325          else
9326             Handle_Changed_Representation;
9327          end if;
9328
9329       --  Case of conversions of enumeration types
9330
9331       elsif Is_Enumeration_Type (Target_Type) then
9332
9333          --  Special processing is required if there is a change of
9334          --  representation (from enumeration representation clauses).
9335
9336          if not Same_Representation (Target_Type, Operand_Type) then
9337
9338             --  Convert: x(y) to x'val (ytyp'val (y))
9339
9340             Rewrite (N,
9341                Make_Attribute_Reference (Loc,
9342                  Prefix => New_Occurrence_Of (Target_Type, Loc),
9343                  Attribute_Name => Name_Val,
9344                  Expressions => New_List (
9345                    Make_Attribute_Reference (Loc,
9346                      Prefix => New_Occurrence_Of (Operand_Type, Loc),
9347                      Attribute_Name => Name_Pos,
9348                      Expressions => New_List (Operand)))));
9349
9350             Analyze_And_Resolve (N, Target_Type);
9351          end if;
9352
9353       --  Case of conversions to floating-point
9354
9355       elsif Is_Floating_Point_Type (Target_Type) then
9356          Real_Range_Check;
9357       end if;
9358
9359       --  At this stage, either the conversion node has been transformed into
9360       --  some other equivalent expression, or left as a conversion that can be
9361       --  handled by Gigi, in the following cases:
9362
9363       --    Conversions with no change of representation or type
9364
9365       --    Numeric conversions involving integer, floating- and fixed-point
9366       --    values. Fixed-point values are allowed only if Conversion_OK is
9367       --    set, i.e. if the fixed-point values are to be treated as integers.
9368
9369       --  No other conversions should be passed to Gigi
9370
9371       --  Check: are these rules stated in sinfo??? if so, why restate here???
9372
9373       --  The only remaining step is to generate a range check if we still have
9374       --  a type conversion at this stage and Do_Range_Check is set. For now we
9375       --  do this only for conversions of discrete types.
9376
9377       if Nkind (N) = N_Type_Conversion
9378         and then Is_Discrete_Type (Etype (N))
9379       then
9380          declare
9381             Expr : constant Node_Id := Expression (N);
9382             Ftyp : Entity_Id;
9383             Ityp : Entity_Id;
9384
9385          begin
9386             if Do_Range_Check (Expr)
9387               and then Is_Discrete_Type (Etype (Expr))
9388             then
9389                Set_Do_Range_Check (Expr, False);
9390
9391                --  Before we do a range check, we have to deal with treating a
9392                --  fixed-point operand as an integer. The way we do this is
9393                --  simply to do an unchecked conversion to an appropriate
9394                --  integer type large enough to hold the result.
9395
9396                --  This code is not active yet, because we are only dealing
9397                --  with discrete types so far ???
9398
9399                if Nkind (Expr) in N_Has_Treat_Fixed_As_Integer
9400                  and then Treat_Fixed_As_Integer (Expr)
9401                then
9402                   Ftyp := Base_Type (Etype (Expr));
9403
9404                   if Esize (Ftyp) >= Esize (Standard_Integer) then
9405                      Ityp := Standard_Long_Long_Integer;
9406                   else
9407                      Ityp := Standard_Integer;
9408                   end if;
9409
9410                   Rewrite (Expr, Unchecked_Convert_To (Ityp, Expr));
9411                end if;
9412
9413                --  Reset overflow flag, since the range check will include
9414                --  dealing with possible overflow, and generate the check. If
9415                --  Address is either a source type or target type, suppress
9416                --  range check to avoid typing anomalies when it is a visible
9417                --  integer type.
9418
9419                Set_Do_Overflow_Check (N, False);
9420                if not Is_Descendent_Of_Address (Etype (Expr))
9421                  and then not Is_Descendent_Of_Address (Target_Type)
9422                then
9423                   Generate_Range_Check
9424                     (Expr, Target_Type, CE_Range_Check_Failed);
9425                end if;
9426             end if;
9427          end;
9428       end if;
9429
9430       --  Final step, if the result is a type conversion involving Vax_Float
9431       --  types, then it is subject for further special processing.
9432
9433       if Nkind (N) = N_Type_Conversion
9434         and then (Vax_Float (Operand_Type) or else Vax_Float (Target_Type))
9435       then
9436          Expand_Vax_Conversion (N);
9437          goto Done;
9438       end if;
9439
9440       --  Here at end of processing
9441
9442    <<Done>>
9443       --  Apply predicate check if required. Note that we can't just call
9444       --  Apply_Predicate_Check here, because the type looks right after
9445       --  the conversion and it would omit the check. The Comes_From_Source
9446       --  guard is necessary to prevent infinite recursions when we generate
9447       --  internal conversions for the purpose of checking predicates.
9448
9449       if Present (Predicate_Function (Target_Type))
9450         and then Target_Type /= Operand_Type
9451         and then Comes_From_Source (N)
9452       then
9453          declare
9454             New_Expr : constant Node_Id := Duplicate_Subexpr (N);
9455
9456          begin
9457             --  Avoid infinite recursion on the subsequent expansion of
9458             --  of the copy of the original type conversion.
9459
9460             Set_Comes_From_Source (New_Expr, False);
9461             Insert_Action (N, Make_Predicate_Check (Target_Type, New_Expr));
9462          end;
9463       end if;
9464    end Expand_N_Type_Conversion;
9465
9466    -----------------------------------
9467    -- Expand_N_Unchecked_Expression --
9468    -----------------------------------
9469
9470    --  Remove the unchecked expression node from the tree. Its job was simply
9471    --  to make sure that its constituent expression was handled with checks
9472    --  off, and now that that is done, we can remove it from the tree, and
9473    --  indeed must, since Gigi does not expect to see these nodes.
9474
9475    procedure Expand_N_Unchecked_Expression (N : Node_Id) is
9476       Exp : constant Node_Id := Expression (N);
9477    begin
9478       Set_Assignment_OK (Exp, Assignment_OK (N) or else Assignment_OK (Exp));
9479       Rewrite (N, Exp);
9480    end Expand_N_Unchecked_Expression;
9481
9482    ----------------------------------------
9483    -- Expand_N_Unchecked_Type_Conversion --
9484    ----------------------------------------
9485
9486    --  If this cannot be handled by Gigi and we haven't already made a
9487    --  temporary for it, do it now.
9488
9489    procedure Expand_N_Unchecked_Type_Conversion (N : Node_Id) is
9490       Target_Type  : constant Entity_Id := Etype (N);
9491       Operand      : constant Node_Id   := Expression (N);
9492       Operand_Type : constant Entity_Id := Etype (Operand);
9493
9494    begin
9495       --  Nothing at all to do if conversion is to the identical type so remove
9496       --  the conversion completely, it is useless, except that it may carry
9497       --  an Assignment_OK indication which must be propagated to the operand.
9498
9499       if Operand_Type = Target_Type then
9500
9501          --  Code duplicates Expand_N_Unchecked_Expression above, factor???
9502
9503          if Assignment_OK (N) then
9504             Set_Assignment_OK (Operand);
9505          end if;
9506
9507          Rewrite (N, Relocate_Node (Operand));
9508          return;
9509       end if;
9510
9511       --  If we have a conversion of a compile time known value to a target
9512       --  type and the value is in range of the target type, then we can simply
9513       --  replace the construct by an integer literal of the correct type. We
9514       --  only apply this to integer types being converted. Possibly it may
9515       --  apply in other cases, but it is too much trouble to worry about.
9516
9517       --  Note that we do not do this transformation if the Kill_Range_Check
9518       --  flag is set, since then the value may be outside the expected range.
9519       --  This happens in the Normalize_Scalars case.
9520
9521       --  We also skip this if either the target or operand type is biased
9522       --  because in this case, the unchecked conversion is supposed to
9523       --  preserve the bit pattern, not the integer value.
9524
9525       if Is_Integer_Type (Target_Type)
9526         and then not Has_Biased_Representation (Target_Type)
9527         and then Is_Integer_Type (Operand_Type)
9528         and then not Has_Biased_Representation (Operand_Type)
9529         and then Compile_Time_Known_Value (Operand)
9530         and then not Kill_Range_Check (N)
9531       then
9532          declare
9533             Val : constant Uint := Expr_Value (Operand);
9534
9535          begin
9536             if Compile_Time_Known_Value (Type_Low_Bound (Target_Type))
9537                  and then
9538                Compile_Time_Known_Value (Type_High_Bound (Target_Type))
9539                  and then
9540                Val >= Expr_Value (Type_Low_Bound (Target_Type))
9541                  and then
9542                Val <= Expr_Value (Type_High_Bound (Target_Type))
9543             then
9544                Rewrite (N, Make_Integer_Literal (Sloc (N), Val));
9545
9546                --  If Address is the target type, just set the type to avoid a
9547                --  spurious type error on the literal when Address is a visible
9548                --  integer type.
9549
9550                if Is_Descendent_Of_Address (Target_Type) then
9551                   Set_Etype (N, Target_Type);
9552                else
9553                   Analyze_And_Resolve (N, Target_Type);
9554                end if;
9555
9556                return;
9557             end if;
9558          end;
9559       end if;
9560
9561       --  Nothing to do if conversion is safe
9562
9563       if Safe_Unchecked_Type_Conversion (N) then
9564          return;
9565       end if;
9566
9567       --  Otherwise force evaluation unless Assignment_OK flag is set (this
9568       --  flag indicates ??? -- more comments needed here)
9569
9570       if Assignment_OK (N) then
9571          null;
9572       else
9573          Force_Evaluation (N);
9574       end if;
9575    end Expand_N_Unchecked_Type_Conversion;
9576
9577    ----------------------------
9578    -- Expand_Record_Equality --
9579    ----------------------------
9580
9581    --  For non-variant records, Equality is expanded when needed into:
9582
9583    --      and then Lhs.Discr1 = Rhs.Discr1
9584    --      and then ...
9585    --      and then Lhs.Discrn = Rhs.Discrn
9586    --      and then Lhs.Cmp1 = Rhs.Cmp1
9587    --      and then ...
9588    --      and then Lhs.Cmpn = Rhs.Cmpn
9589
9590    --  The expression is folded by the back-end for adjacent fields. This
9591    --  function is called for tagged record in only one occasion: for imple-
9592    --  menting predefined primitive equality (see Predefined_Primitives_Bodies)
9593    --  otherwise the primitive "=" is used directly.
9594
9595    function Expand_Record_Equality
9596      (Nod    : Node_Id;
9597       Typ    : Entity_Id;
9598       Lhs    : Node_Id;
9599       Rhs    : Node_Id;
9600       Bodies : List_Id) return Node_Id
9601    is
9602       Loc : constant Source_Ptr := Sloc (Nod);
9603
9604       Result : Node_Id;
9605       C      : Entity_Id;
9606
9607       First_Time : Boolean := True;
9608
9609       function Suitable_Element (C : Entity_Id) return Entity_Id;
9610       --  Return the first field to compare beginning with C, skipping the
9611       --  inherited components.
9612
9613       ----------------------
9614       -- Suitable_Element --
9615       ----------------------
9616
9617       function Suitable_Element (C : Entity_Id) return Entity_Id is
9618       begin
9619          if No (C) then
9620             return Empty;
9621
9622          elsif Ekind (C) /= E_Discriminant
9623            and then Ekind (C) /= E_Component
9624          then
9625             return Suitable_Element (Next_Entity (C));
9626
9627          elsif Is_Tagged_Type (Typ)
9628            and then C /= Original_Record_Component (C)
9629          then
9630             return Suitable_Element (Next_Entity (C));
9631
9632          elsif Chars (C) = Name_uTag then
9633             return Suitable_Element (Next_Entity (C));
9634
9635          --  The .NET/JVM version of type Root_Controlled contains two fields
9636          --  which should not be considered part of the object. To achieve
9637          --  proper equiality between two controlled objects on .NET/JVM, skip
9638          --  field _parent whenever it is of type Root_Controlled.
9639
9640          elsif Chars (C) = Name_uParent
9641            and then VM_Target /= No_VM
9642            and then Etype (C) = RTE (RE_Root_Controlled)
9643          then
9644             return Suitable_Element (Next_Entity (C));
9645
9646          elsif Is_Interface (Etype (C)) then
9647             return Suitable_Element (Next_Entity (C));
9648
9649          else
9650             return C;
9651          end if;
9652       end Suitable_Element;
9653
9654    --  Start of processing for Expand_Record_Equality
9655
9656    begin
9657       --  Generates the following code: (assuming that Typ has one Discr and
9658       --  component C2 is also a record)
9659
9660       --   True
9661       --     and then Lhs.Discr1 = Rhs.Discr1
9662       --     and then Lhs.C1 = Rhs.C1
9663       --     and then Lhs.C2.C1=Rhs.C2.C1 and then ... Lhs.C2.Cn=Rhs.C2.Cn
9664       --     and then ...
9665       --     and then Lhs.Cmpn = Rhs.Cmpn
9666
9667       Result := New_Reference_To (Standard_True, Loc);
9668       C := Suitable_Element (First_Entity (Typ));
9669       while Present (C) loop
9670          declare
9671             New_Lhs : Node_Id;
9672             New_Rhs : Node_Id;
9673             Check   : Node_Id;
9674
9675          begin
9676             if First_Time then
9677                First_Time := False;
9678                New_Lhs := Lhs;
9679                New_Rhs := Rhs;
9680             else
9681                New_Lhs := New_Copy_Tree (Lhs);
9682                New_Rhs := New_Copy_Tree (Rhs);
9683             end if;
9684
9685             Check :=
9686               Expand_Composite_Equality (Nod, Etype (C),
9687                Lhs =>
9688                  Make_Selected_Component (Loc,
9689                    Prefix => New_Lhs,
9690                    Selector_Name => New_Reference_To (C, Loc)),
9691                Rhs =>
9692                  Make_Selected_Component (Loc,
9693                    Prefix => New_Rhs,
9694                    Selector_Name => New_Reference_To (C, Loc)),
9695                Bodies => Bodies);
9696
9697             --  If some (sub)component is an unchecked_union, the whole
9698             --  operation will raise program error.
9699
9700             if Nkind (Check) = N_Raise_Program_Error then
9701                Result := Check;
9702                Set_Etype (Result, Standard_Boolean);
9703                exit;
9704             else
9705                Result :=
9706                  Make_And_Then (Loc,
9707                    Left_Opnd  => Result,
9708                    Right_Opnd => Check);
9709             end if;
9710          end;
9711
9712          C := Suitable_Element (Next_Entity (C));
9713       end loop;
9714
9715       return Result;
9716    end Expand_Record_Equality;
9717
9718    ---------------------------
9719    -- Expand_Set_Membership --
9720    ---------------------------
9721
9722    procedure Expand_Set_Membership (N : Node_Id) is
9723       Lop : constant Node_Id := Left_Opnd (N);
9724       Alt : Node_Id;
9725       Res : Node_Id;
9726
9727       function Make_Cond (Alt : Node_Id) return Node_Id;
9728       --  If the alternative is a subtype mark, create a simple membership
9729       --  test. Otherwise create an equality test for it.
9730
9731       ---------------
9732       -- Make_Cond --
9733       ---------------
9734
9735       function Make_Cond (Alt : Node_Id) return Node_Id is
9736          Cond : Node_Id;
9737          L    : constant Node_Id := New_Copy (Lop);
9738          R    : constant Node_Id := Relocate_Node (Alt);
9739
9740       begin
9741          if (Is_Entity_Name (Alt) and then Is_Type (Entity (Alt)))
9742            or else Nkind (Alt) = N_Range
9743          then
9744             Cond :=
9745               Make_In (Sloc (Alt),
9746                 Left_Opnd  => L,
9747                 Right_Opnd => R);
9748          else
9749             Cond :=
9750               Make_Op_Eq (Sloc (Alt),
9751                 Left_Opnd  => L,
9752                 Right_Opnd => R);
9753          end if;
9754
9755          return Cond;
9756       end Make_Cond;
9757
9758    --  Start of processing for Expand_Set_Membership
9759
9760    begin
9761       Remove_Side_Effects (Lop);
9762
9763       Alt := Last (Alternatives (N));
9764       Res := Make_Cond (Alt);
9765
9766       Prev (Alt);
9767       while Present (Alt) loop
9768          Res :=
9769            Make_Or_Else (Sloc (Alt),
9770              Left_Opnd  => Make_Cond (Alt),
9771              Right_Opnd => Res);
9772          Prev (Alt);
9773       end loop;
9774
9775       Rewrite (N, Res);
9776       Analyze_And_Resolve (N, Standard_Boolean);
9777    end Expand_Set_Membership;
9778
9779    -----------------------------------
9780    -- Expand_Short_Circuit_Operator --
9781    -----------------------------------
9782
9783    --  Deal with special expansion if actions are present for the right operand
9784    --  and deal with optimizing case of arguments being True or False. We also
9785    --  deal with the special case of non-standard boolean values.
9786
9787    procedure Expand_Short_Circuit_Operator (N : Node_Id) is
9788       Loc     : constant Source_Ptr := Sloc (N);
9789       Typ     : constant Entity_Id  := Etype (N);
9790       Left    : constant Node_Id    := Left_Opnd (N);
9791       Right   : constant Node_Id    := Right_Opnd (N);
9792       LocR    : constant Source_Ptr := Sloc (Right);
9793       Actlist : List_Id;
9794
9795       Shortcut_Value : constant Boolean := Nkind (N) = N_Or_Else;
9796       Shortcut_Ent   : constant Entity_Id := Boolean_Literals (Shortcut_Value);
9797       --  If Left = Shortcut_Value then Right need not be evaluated
9798
9799       function Make_Test_Expr (Opnd : Node_Id) return Node_Id;
9800       --  For Opnd a boolean expression, return a Boolean expression equivalent
9801       --  to Opnd /= Shortcut_Value.
9802
9803       --------------------
9804       -- Make_Test_Expr --
9805       --------------------
9806
9807       function Make_Test_Expr (Opnd : Node_Id) return Node_Id is
9808       begin
9809          if Shortcut_Value then
9810             return Make_Op_Not (Sloc (Opnd), Opnd);
9811          else
9812             return Opnd;
9813          end if;
9814       end Make_Test_Expr;
9815
9816       Op_Var : Entity_Id;
9817       --  Entity for a temporary variable holding the value of the operator,
9818       --  used for expansion in the case where actions are present.
9819
9820    --  Start of processing for Expand_Short_Circuit_Operator
9821
9822    begin
9823       --  Deal with non-standard booleans
9824
9825       if Is_Boolean_Type (Typ) then
9826          Adjust_Condition (Left);
9827          Adjust_Condition (Right);
9828          Set_Etype (N, Standard_Boolean);
9829       end if;
9830
9831       --  Check for cases where left argument is known to be True or False
9832
9833       if Compile_Time_Known_Value (Left) then
9834
9835          --  Mark SCO for left condition as compile time known
9836
9837          if Generate_SCO and then Comes_From_Source (Left) then
9838             Set_SCO_Condition (Left, Expr_Value_E (Left) = Standard_True);
9839          end if;
9840
9841          --  Rewrite True AND THEN Right / False OR ELSE Right to Right.
9842          --  Any actions associated with Right will be executed unconditionally
9843          --  and can thus be inserted into the tree unconditionally.
9844
9845          if Expr_Value_E (Left) /= Shortcut_Ent then
9846             if Present (Actions (N)) then
9847                Insert_Actions (N, Actions (N));
9848             end if;
9849
9850             Rewrite (N, Right);
9851
9852          --  Rewrite False AND THEN Right / True OR ELSE Right to Left.
9853          --  In this case we can forget the actions associated with Right,
9854          --  since they will never be executed.
9855
9856          else
9857             Kill_Dead_Code (Right);
9858             Kill_Dead_Code (Actions (N));
9859             Rewrite (N, New_Occurrence_Of (Shortcut_Ent, Loc));
9860          end if;
9861
9862          Adjust_Result_Type (N, Typ);
9863          return;
9864       end if;
9865
9866       --  If Actions are present for the right operand, we have to do some
9867       --  special processing. We can't just let these actions filter back into
9868       --  code preceding the short circuit (which is what would have happened
9869       --  if we had not trapped them in the short-circuit form), since they
9870       --  must only be executed if the right operand of the short circuit is
9871       --  executed and not otherwise.
9872
9873       --  the temporary variable C.
9874
9875       if Present (Actions (N)) then
9876          Actlist := Actions (N);
9877
9878          --  The old approach is to expand:
9879
9880          --     left AND THEN right
9881
9882          --  into
9883
9884          --     C : Boolean := False;
9885          --     IF left THEN
9886          --        Actions;
9887          --        IF right THEN
9888          --           C := True;
9889          --        END IF;
9890          --     END IF;
9891
9892          --  and finally rewrite the operator into a reference to C. Similarly
9893          --  for left OR ELSE right, with negated values. Note that this
9894          --  rewrite causes some difficulties for coverage analysis because
9895          --  of the introduction of the new variable C, which obscures the
9896          --  structure of the test.
9897
9898          --  We use this "old approach" if use of N_Expression_With_Actions
9899          --  is False (see description in Opt of when this is or is not set).
9900
9901          if not Use_Expression_With_Actions then
9902             Op_Var := Make_Temporary (Loc, 'C', Related_Node => N);
9903
9904             Insert_Action (N,
9905               Make_Object_Declaration (Loc,
9906                 Defining_Identifier =>
9907                   Op_Var,
9908                 Object_Definition   =>
9909                   New_Occurrence_Of (Standard_Boolean, Loc),
9910                 Expression          =>
9911                   New_Occurrence_Of (Shortcut_Ent, Loc)));
9912
9913             Append_To (Actlist,
9914               Make_Implicit_If_Statement (Right,
9915                 Condition       => Make_Test_Expr (Right),
9916                 Then_Statements => New_List (
9917                   Make_Assignment_Statement (LocR,
9918                     Name       => New_Occurrence_Of (Op_Var, LocR),
9919                     Expression =>
9920                       New_Occurrence_Of
9921                         (Boolean_Literals (not Shortcut_Value), LocR)))));
9922
9923             Insert_Action (N,
9924               Make_Implicit_If_Statement (Left,
9925                 Condition       => Make_Test_Expr (Left),
9926                 Then_Statements => Actlist));
9927
9928             Rewrite (N, New_Occurrence_Of (Op_Var, Loc));
9929             Analyze_And_Resolve (N, Standard_Boolean);
9930
9931          --  The new approach, activated for now by the use of debug flag
9932          --  -gnatd.X is to use the new Expression_With_Actions node for the
9933          --  right operand of the short-circuit form. This should solve the
9934          --  traceability problems for coverage analysis.
9935
9936          else
9937             Rewrite (Right,
9938               Make_Expression_With_Actions (LocR,
9939                 Expression => Relocate_Node (Right),
9940                 Actions    => Actlist));
9941             Set_Actions (N, No_List);
9942             Analyze_And_Resolve (Right, Standard_Boolean);
9943          end if;
9944
9945          Adjust_Result_Type (N, Typ);
9946          return;
9947       end if;
9948
9949       --  No actions present, check for cases of right argument True/False
9950
9951       if Compile_Time_Known_Value (Right) then
9952
9953          --  Mark SCO for left condition as compile time known
9954
9955          if Generate_SCO and then Comes_From_Source (Right) then
9956             Set_SCO_Condition (Right, Expr_Value_E (Right) = Standard_True);
9957          end if;
9958
9959          --  Change (Left and then True), (Left or else False) to Left.
9960          --  Note that we know there are no actions associated with the right
9961          --  operand, since we just checked for this case above.
9962
9963          if Expr_Value_E (Right) /= Shortcut_Ent then
9964             Rewrite (N, Left);
9965
9966          --  Change (Left and then False), (Left or else True) to Right,
9967          --  making sure to preserve any side effects associated with the Left
9968          --  operand.
9969
9970          else
9971             Remove_Side_Effects (Left);
9972             Rewrite (N, New_Occurrence_Of (Shortcut_Ent, Loc));
9973          end if;
9974       end if;
9975
9976       Adjust_Result_Type (N, Typ);
9977    end Expand_Short_Circuit_Operator;
9978
9979    -------------------------------------
9980    -- Fixup_Universal_Fixed_Operation --
9981    -------------------------------------
9982
9983    procedure Fixup_Universal_Fixed_Operation (N : Node_Id) is
9984       Conv : constant Node_Id := Parent (N);
9985
9986    begin
9987       --  We must have a type conversion immediately above us
9988
9989       pragma Assert (Nkind (Conv) = N_Type_Conversion);
9990
9991       --  Normally the type conversion gives our target type. The exception
9992       --  occurs in the case of the Round attribute, where the conversion
9993       --  will be to universal real, and our real type comes from the Round
9994       --  attribute (as well as an indication that we must round the result)
9995
9996       if Nkind (Parent (Conv)) = N_Attribute_Reference
9997         and then Attribute_Name (Parent (Conv)) = Name_Round
9998       then
9999          Set_Etype (N, Etype (Parent (Conv)));
10000          Set_Rounded_Result (N);
10001
10002       --  Normal case where type comes from conversion above us
10003
10004       else
10005          Set_Etype (N, Etype (Conv));
10006       end if;
10007    end Fixup_Universal_Fixed_Operation;
10008
10009    ---------------------------------
10010    -- Has_Inferable_Discriminants --
10011    ---------------------------------
10012
10013    function Has_Inferable_Discriminants (N : Node_Id) return Boolean is
10014
10015       function Prefix_Is_Formal_Parameter (N : Node_Id) return Boolean;
10016       --  Determines whether the left-most prefix of a selected component is a
10017       --  formal parameter in a subprogram. Assumes N is a selected component.
10018
10019       --------------------------------
10020       -- Prefix_Is_Formal_Parameter --
10021       --------------------------------
10022
10023       function Prefix_Is_Formal_Parameter (N : Node_Id) return Boolean is
10024          Sel_Comp : Node_Id := N;
10025
10026       begin
10027          --  Move to the left-most prefix by climbing up the tree
10028
10029          while Present (Parent (Sel_Comp))
10030            and then Nkind (Parent (Sel_Comp)) = N_Selected_Component
10031          loop
10032             Sel_Comp := Parent (Sel_Comp);
10033          end loop;
10034
10035          return Ekind (Entity (Prefix (Sel_Comp))) in Formal_Kind;
10036       end Prefix_Is_Formal_Parameter;
10037
10038    --  Start of processing for Has_Inferable_Discriminants
10039
10040    begin
10041       --  For identifiers and indexed components, it is sufficient to have a
10042       --  constrained Unchecked_Union nominal subtype.
10043
10044       if Nkind_In (N, N_Identifier, N_Indexed_Component) then
10045          return Is_Unchecked_Union (Base_Type (Etype (N)))
10046                   and then
10047                 Is_Constrained (Etype (N));
10048
10049       --  For selected components, the subtype of the selector must be a
10050       --  constrained Unchecked_Union. If the component is subject to a
10051       --  per-object constraint, then the enclosing object must have inferable
10052       --  discriminants.
10053
10054       elsif Nkind (N) = N_Selected_Component then
10055          if Has_Per_Object_Constraint (Entity (Selector_Name (N))) then
10056
10057             --  A small hack. If we have a per-object constrained selected
10058             --  component of a formal parameter, return True since we do not
10059             --  know the actual parameter association yet.
10060
10061             if Prefix_Is_Formal_Parameter (N) then
10062                return True;
10063             end if;
10064
10065             --  Otherwise, check the enclosing object and the selector
10066
10067             return Has_Inferable_Discriminants (Prefix (N))
10068                      and then
10069                    Has_Inferable_Discriminants (Selector_Name (N));
10070          end if;
10071
10072          --  The call to Has_Inferable_Discriminants will determine whether
10073          --  the selector has a constrained Unchecked_Union nominal type.
10074
10075          return Has_Inferable_Discriminants (Selector_Name (N));
10076
10077       --  A qualified expression has inferable discriminants if its subtype
10078       --  mark is a constrained Unchecked_Union subtype.
10079
10080       elsif Nkind (N) = N_Qualified_Expression then
10081          return Is_Unchecked_Union (Subtype_Mark (N))
10082                   and then
10083                 Is_Constrained (Subtype_Mark (N));
10084
10085       end if;
10086
10087       return False;
10088    end Has_Inferable_Discriminants;
10089
10090    -------------------------------
10091    -- Insert_Dereference_Action --
10092    -------------------------------
10093
10094    procedure Insert_Dereference_Action (N : Node_Id) is
10095       Loc  : constant Source_Ptr := Sloc (N);
10096       Typ  : constant Entity_Id  := Etype (N);
10097       Pool : constant Entity_Id  := Associated_Storage_Pool (Typ);
10098       Pnod : constant Node_Id    := Parent (N);
10099
10100       function Is_Checked_Storage_Pool (P : Entity_Id) return Boolean;
10101       --  Return true if type of P is derived from Checked_Pool;
10102
10103       -----------------------------
10104       -- Is_Checked_Storage_Pool --
10105       -----------------------------
10106
10107       function Is_Checked_Storage_Pool (P : Entity_Id) return Boolean is
10108          T : Entity_Id;
10109
10110       begin
10111          if No (P) then
10112             return False;
10113          end if;
10114
10115          T := Etype (P);
10116          while T /= Etype (T) loop
10117             if Is_RTE (T, RE_Checked_Pool) then
10118                return True;
10119             else
10120                T := Etype (T);
10121             end if;
10122          end loop;
10123
10124          return False;
10125       end Is_Checked_Storage_Pool;
10126
10127    --  Start of processing for Insert_Dereference_Action
10128
10129    begin
10130       pragma Assert (Nkind (Pnod) = N_Explicit_Dereference);
10131
10132       if not (Is_Checked_Storage_Pool (Pool)
10133               and then Comes_From_Source (Original_Node (Pnod)))
10134       then
10135          return;
10136       end if;
10137
10138       Insert_Action (N,
10139         Make_Procedure_Call_Statement (Loc,
10140           Name => New_Reference_To (
10141             Find_Prim_Op (Etype (Pool), Name_Dereference), Loc),
10142
10143           Parameter_Associations => New_List (
10144
10145             --  Pool
10146
10147              New_Reference_To (Pool, Loc),
10148
10149             --  Storage_Address. We use the attribute Pool_Address, which uses
10150             --  the pointer itself to find the address of the object, and which
10151             --  handles unconstrained arrays properly by computing the address
10152             --  of the template. i.e. the correct address of the corresponding
10153             --  allocation.
10154
10155              Make_Attribute_Reference (Loc,
10156                Prefix         => Duplicate_Subexpr_Move_Checks (N),
10157                Attribute_Name => Name_Pool_Address),
10158
10159             --  Size_In_Storage_Elements
10160
10161              Make_Op_Divide (Loc,
10162                Left_Opnd  =>
10163                 Make_Attribute_Reference (Loc,
10164                   Prefix         =>
10165                     Make_Explicit_Dereference (Loc,
10166                       Duplicate_Subexpr_Move_Checks (N)),
10167                   Attribute_Name => Name_Size),
10168                Right_Opnd =>
10169                  Make_Integer_Literal (Loc, System_Storage_Unit)),
10170
10171             --  Alignment
10172
10173              Make_Attribute_Reference (Loc,
10174                Prefix         =>
10175                  Make_Explicit_Dereference (Loc,
10176                    Duplicate_Subexpr_Move_Checks (N)),
10177                Attribute_Name => Name_Alignment))));
10178
10179    exception
10180       when RE_Not_Available =>
10181          return;
10182    end Insert_Dereference_Action;
10183
10184    --------------------------------
10185    -- Integer_Promotion_Possible --
10186    --------------------------------
10187
10188    function Integer_Promotion_Possible (N : Node_Id) return Boolean is
10189       Operand           : constant Node_Id   := Expression (N);
10190       Operand_Type      : constant Entity_Id := Etype (Operand);
10191       Root_Operand_Type : constant Entity_Id := Root_Type (Operand_Type);
10192
10193    begin
10194       pragma Assert (Nkind (N) = N_Type_Conversion);
10195
10196       return
10197
10198            --  We only do the transformation for source constructs. We assume
10199            --  that the expander knows what it is doing when it generates code.
10200
10201            Comes_From_Source (N)
10202
10203            --  If the operand type is Short_Integer or Short_Short_Integer,
10204            --  then we will promote to Integer, which is available on all
10205            --  targets, and is sufficient to ensure no intermediate overflow.
10206            --  Furthermore it is likely to be as efficient or more efficient
10207            --  than using the smaller type for the computation so we do this
10208            --  unconditionally.
10209
10210            and then
10211              (Root_Operand_Type = Base_Type (Standard_Short_Integer)
10212                or else
10213               Root_Operand_Type = Base_Type (Standard_Short_Short_Integer))
10214
10215            --  Test for interesting operation, which includes addition,
10216            --  division, exponentiation, multiplication, subtraction, absolute
10217            --  value and unary negation. Unary "+" is omitted since it is a
10218            --  no-op and thus can't overflow.
10219
10220            and then Nkind_In (Operand, N_Op_Abs,
10221                                        N_Op_Add,
10222                                        N_Op_Divide,
10223                                        N_Op_Expon,
10224                                        N_Op_Minus,
10225                                        N_Op_Multiply,
10226                                        N_Op_Subtract);
10227    end Integer_Promotion_Possible;
10228
10229    ------------------------------
10230    -- Make_Array_Comparison_Op --
10231    ------------------------------
10232
10233    --  This is a hand-coded expansion of the following generic function:
10234
10235    --  generic
10236    --    type elem is  (<>);
10237    --    type index is (<>);
10238    --    type a is array (index range <>) of elem;
10239
10240    --  function Gnnn (X : a; Y: a) return boolean is
10241    --    J : index := Y'first;
10242
10243    --  begin
10244    --    if X'length = 0 then
10245    --       return false;
10246
10247    --    elsif Y'length = 0 then
10248    --       return true;
10249
10250    --    else
10251    --      for I in X'range loop
10252    --        if X (I) = Y (J) then
10253    --          if J = Y'last then
10254    --            exit;
10255    --          else
10256    --            J := index'succ (J);
10257    --          end if;
10258
10259    --        else
10260    --           return X (I) > Y (J);
10261    --        end if;
10262    --      end loop;
10263
10264    --      return X'length > Y'length;
10265    --    end if;
10266    --  end Gnnn;
10267
10268    --  Note that since we are essentially doing this expansion by hand, we
10269    --  do not need to generate an actual or formal generic part, just the
10270    --  instantiated function itself.
10271
10272    function Make_Array_Comparison_Op
10273      (Typ : Entity_Id;
10274       Nod : Node_Id) return Node_Id
10275    is
10276       Loc : constant Source_Ptr := Sloc (Nod);
10277
10278       X : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uX);
10279       Y : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uY);
10280       I : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uI);
10281       J : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uJ);
10282
10283       Index : constant Entity_Id := Base_Type (Etype (First_Index (Typ)));
10284
10285       Loop_Statement : Node_Id;
10286       Loop_Body      : Node_Id;
10287       If_Stat        : Node_Id;
10288       Inner_If       : Node_Id;
10289       Final_Expr     : Node_Id;
10290       Func_Body      : Node_Id;
10291       Func_Name      : Entity_Id;
10292       Formals        : List_Id;
10293       Length1        : Node_Id;
10294       Length2        : Node_Id;
10295
10296    begin
10297       --  if J = Y'last then
10298       --     exit;
10299       --  else
10300       --     J := index'succ (J);
10301       --  end if;
10302
10303       Inner_If :=
10304         Make_Implicit_If_Statement (Nod,
10305           Condition =>
10306             Make_Op_Eq (Loc,
10307               Left_Opnd => New_Reference_To (J, Loc),
10308               Right_Opnd =>
10309                 Make_Attribute_Reference (Loc,
10310                   Prefix => New_Reference_To (Y, Loc),
10311                   Attribute_Name => Name_Last)),
10312
10313           Then_Statements => New_List (
10314                 Make_Exit_Statement (Loc)),
10315
10316           Else_Statements =>
10317             New_List (
10318               Make_Assignment_Statement (Loc,
10319                 Name => New_Reference_To (J, Loc),
10320                 Expression =>
10321                   Make_Attribute_Reference (Loc,
10322                     Prefix => New_Reference_To (Index, Loc),
10323                     Attribute_Name => Name_Succ,
10324                     Expressions => New_List (New_Reference_To (J, Loc))))));
10325
10326       --  if X (I) = Y (J) then
10327       --     if ... end if;
10328       --  else
10329       --     return X (I) > Y (J);
10330       --  end if;
10331
10332       Loop_Body :=
10333         Make_Implicit_If_Statement (Nod,
10334           Condition =>
10335             Make_Op_Eq (Loc,
10336               Left_Opnd =>
10337                 Make_Indexed_Component (Loc,
10338                   Prefix      => New_Reference_To (X, Loc),
10339                   Expressions => New_List (New_Reference_To (I, Loc))),
10340
10341               Right_Opnd =>
10342                 Make_Indexed_Component (Loc,
10343                   Prefix      => New_Reference_To (Y, Loc),
10344                   Expressions => New_List (New_Reference_To (J, Loc)))),
10345
10346           Then_Statements => New_List (Inner_If),
10347
10348           Else_Statements => New_List (
10349             Make_Simple_Return_Statement (Loc,
10350               Expression =>
10351                 Make_Op_Gt (Loc,
10352                   Left_Opnd =>
10353                     Make_Indexed_Component (Loc,
10354                       Prefix      => New_Reference_To (X, Loc),
10355                       Expressions => New_List (New_Reference_To (I, Loc))),
10356
10357                   Right_Opnd =>
10358                     Make_Indexed_Component (Loc,
10359                       Prefix      => New_Reference_To (Y, Loc),
10360                       Expressions => New_List (
10361                         New_Reference_To (J, Loc)))))));
10362
10363       --  for I in X'range loop
10364       --     if ... end if;
10365       --  end loop;
10366
10367       Loop_Statement :=
10368         Make_Implicit_Loop_Statement (Nod,
10369           Identifier => Empty,
10370
10371           Iteration_Scheme =>
10372             Make_Iteration_Scheme (Loc,
10373               Loop_Parameter_Specification =>
10374                 Make_Loop_Parameter_Specification (Loc,
10375                   Defining_Identifier => I,
10376                   Discrete_Subtype_Definition =>
10377                     Make_Attribute_Reference (Loc,
10378                       Prefix => New_Reference_To (X, Loc),
10379                       Attribute_Name => Name_Range))),
10380
10381           Statements => New_List (Loop_Body));
10382
10383       --    if X'length = 0 then
10384       --       return false;
10385       --    elsif Y'length = 0 then
10386       --       return true;
10387       --    else
10388       --      for ... loop ... end loop;
10389       --      return X'length > Y'length;
10390       --    end if;
10391
10392       Length1 :=
10393         Make_Attribute_Reference (Loc,
10394           Prefix => New_Reference_To (X, Loc),
10395           Attribute_Name => Name_Length);
10396
10397       Length2 :=
10398         Make_Attribute_Reference (Loc,
10399           Prefix => New_Reference_To (Y, Loc),
10400           Attribute_Name => Name_Length);
10401
10402       Final_Expr :=
10403         Make_Op_Gt (Loc,
10404           Left_Opnd  => Length1,
10405           Right_Opnd => Length2);
10406
10407       If_Stat :=
10408         Make_Implicit_If_Statement (Nod,
10409           Condition =>
10410             Make_Op_Eq (Loc,
10411               Left_Opnd =>
10412                 Make_Attribute_Reference (Loc,
10413                   Prefix => New_Reference_To (X, Loc),
10414                   Attribute_Name => Name_Length),
10415               Right_Opnd =>
10416                 Make_Integer_Literal (Loc, 0)),
10417
10418           Then_Statements =>
10419             New_List (
10420               Make_Simple_Return_Statement (Loc,
10421                 Expression => New_Reference_To (Standard_False, Loc))),
10422
10423           Elsif_Parts => New_List (
10424             Make_Elsif_Part (Loc,
10425               Condition =>
10426                 Make_Op_Eq (Loc,
10427                   Left_Opnd =>
10428                     Make_Attribute_Reference (Loc,
10429                       Prefix => New_Reference_To (Y, Loc),
10430                       Attribute_Name => Name_Length),
10431                   Right_Opnd =>
10432                     Make_Integer_Literal (Loc, 0)),
10433
10434               Then_Statements =>
10435                 New_List (
10436                   Make_Simple_Return_Statement (Loc,
10437                      Expression => New_Reference_To (Standard_True, Loc))))),
10438
10439           Else_Statements => New_List (
10440             Loop_Statement,
10441             Make_Simple_Return_Statement (Loc,
10442               Expression => Final_Expr)));
10443
10444       --  (X : a; Y: a)
10445
10446       Formals := New_List (
10447         Make_Parameter_Specification (Loc,
10448           Defining_Identifier => X,
10449           Parameter_Type      => New_Reference_To (Typ, Loc)),
10450
10451         Make_Parameter_Specification (Loc,
10452           Defining_Identifier => Y,
10453           Parameter_Type      => New_Reference_To (Typ, Loc)));
10454
10455       --  function Gnnn (...) return boolean is
10456       --    J : index := Y'first;
10457       --  begin
10458       --    if ... end if;
10459       --  end Gnnn;
10460
10461       Func_Name := Make_Temporary (Loc, 'G');
10462
10463       Func_Body :=
10464         Make_Subprogram_Body (Loc,
10465           Specification =>
10466             Make_Function_Specification (Loc,
10467               Defining_Unit_Name       => Func_Name,
10468               Parameter_Specifications => Formals,
10469               Result_Definition => New_Reference_To (Standard_Boolean, Loc)),
10470
10471           Declarations => New_List (
10472             Make_Object_Declaration (Loc,
10473               Defining_Identifier => J,
10474               Object_Definition   => New_Reference_To (Index, Loc),
10475               Expression =>
10476                 Make_Attribute_Reference (Loc,
10477                   Prefix => New_Reference_To (Y, Loc),
10478                   Attribute_Name => Name_First))),
10479
10480           Handled_Statement_Sequence =>
10481             Make_Handled_Sequence_Of_Statements (Loc,
10482               Statements => New_List (If_Stat)));
10483
10484       return Func_Body;
10485    end Make_Array_Comparison_Op;
10486
10487    ---------------------------
10488    -- Make_Boolean_Array_Op --
10489    ---------------------------
10490
10491    --  For logical operations on boolean arrays, expand in line the following,
10492    --  replacing 'and' with 'or' or 'xor' where needed:
10493
10494    --    function Annn (A : typ; B: typ) return typ is
10495    --       C : typ;
10496    --    begin
10497    --       for J in A'range loop
10498    --          C (J) := A (J) op B (J);
10499    --       end loop;
10500    --       return C;
10501    --    end Annn;
10502
10503    --  Here typ is the boolean array type
10504
10505    function Make_Boolean_Array_Op
10506      (Typ : Entity_Id;
10507       N   : Node_Id) return Node_Id
10508    is
10509       Loc : constant Source_Ptr := Sloc (N);
10510
10511       A : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uA);
10512       B : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uB);
10513       C : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uC);
10514       J : constant Entity_Id := Make_Defining_Identifier (Loc, Name_uJ);
10515
10516       A_J : Node_Id;
10517       B_J : Node_Id;
10518       C_J : Node_Id;
10519       Op  : Node_Id;
10520
10521       Formals        : List_Id;
10522       Func_Name      : Entity_Id;
10523       Func_Body      : Node_Id;
10524       Loop_Statement : Node_Id;
10525
10526    begin
10527       A_J :=
10528         Make_Indexed_Component (Loc,
10529           Prefix      => New_Reference_To (A, Loc),
10530           Expressions => New_List (New_Reference_To (J, Loc)));
10531
10532       B_J :=
10533         Make_Indexed_Component (Loc,
10534           Prefix      => New_Reference_To (B, Loc),
10535           Expressions => New_List (New_Reference_To (J, Loc)));
10536
10537       C_J :=
10538         Make_Indexed_Component (Loc,
10539           Prefix      => New_Reference_To (C, Loc),
10540           Expressions => New_List (New_Reference_To (J, Loc)));
10541
10542       if Nkind (N) = N_Op_And then
10543          Op :=
10544            Make_Op_And (Loc,
10545              Left_Opnd  => A_J,
10546              Right_Opnd => B_J);
10547
10548       elsif Nkind (N) = N_Op_Or then
10549          Op :=
10550            Make_Op_Or (Loc,
10551              Left_Opnd  => A_J,
10552              Right_Opnd => B_J);
10553
10554       else
10555          Op :=
10556            Make_Op_Xor (Loc,
10557              Left_Opnd  => A_J,
10558              Right_Opnd => B_J);
10559       end if;
10560
10561       Loop_Statement :=
10562         Make_Implicit_Loop_Statement (N,
10563           Identifier => Empty,
10564
10565           Iteration_Scheme =>
10566             Make_Iteration_Scheme (Loc,
10567               Loop_Parameter_Specification =>
10568                 Make_Loop_Parameter_Specification (Loc,
10569                   Defining_Identifier => J,
10570                   Discrete_Subtype_Definition =>
10571                     Make_Attribute_Reference (Loc,
10572                       Prefix => New_Reference_To (A, Loc),
10573                       Attribute_Name => Name_Range))),
10574
10575           Statements => New_List (
10576             Make_Assignment_Statement (Loc,
10577               Name       => C_J,
10578               Expression => Op)));
10579
10580       Formals := New_List (
10581         Make_Parameter_Specification (Loc,
10582           Defining_Identifier => A,
10583           Parameter_Type      => New_Reference_To (Typ, Loc)),
10584
10585         Make_Parameter_Specification (Loc,
10586           Defining_Identifier => B,
10587           Parameter_Type      => New_Reference_To (Typ, Loc)));
10588
10589       Func_Name := Make_Temporary (Loc, 'A');
10590       Set_Is_Inlined (Func_Name);
10591
10592       Func_Body :=
10593         Make_Subprogram_Body (Loc,
10594           Specification =>
10595             Make_Function_Specification (Loc,
10596               Defining_Unit_Name       => Func_Name,
10597               Parameter_Specifications => Formals,
10598               Result_Definition        => New_Reference_To (Typ, Loc)),
10599
10600           Declarations => New_List (
10601             Make_Object_Declaration (Loc,
10602               Defining_Identifier => C,
10603               Object_Definition   => New_Reference_To (Typ, Loc))),
10604
10605           Handled_Statement_Sequence =>
10606             Make_Handled_Sequence_Of_Statements (Loc,
10607               Statements => New_List (
10608                 Loop_Statement,
10609                 Make_Simple_Return_Statement (Loc,
10610                   Expression => New_Reference_To (C, Loc)))));
10611
10612       return Func_Body;
10613    end Make_Boolean_Array_Op;
10614
10615    --------------------------------
10616    -- Optimize_Length_Comparison --
10617    --------------------------------
10618
10619    procedure Optimize_Length_Comparison (N : Node_Id) is
10620       Loc    : constant Source_Ptr := Sloc (N);
10621       Typ    : constant Entity_Id  := Etype (N);
10622       Result : Node_Id;
10623
10624       Left  : Node_Id;
10625       Right : Node_Id;
10626       --  First and Last attribute reference nodes, which end up as left and
10627       --  right operands of the optimized result.
10628
10629       Is_Zero : Boolean;
10630       --  True for comparison operand of zero
10631
10632       Comp : Node_Id;
10633       --  Comparison operand, set only if Is_Zero is false
10634
10635       Ent : Entity_Id;
10636       --  Entity whose length is being compared
10637
10638       Index : Node_Id;
10639       --  Integer_Literal node for length attribute expression, or Empty
10640       --  if there is no such expression present.
10641
10642       Ityp  : Entity_Id;
10643       --  Type of array index to which 'Length is applied
10644
10645       Op : Node_Kind := Nkind (N);
10646       --  Kind of comparison operator, gets flipped if operands backwards
10647
10648       function Is_Optimizable (N : Node_Id) return Boolean;
10649       --  Tests N to see if it is an optimizable comparison value (defined as
10650       --  constant zero or one, or something else where the value is known to
10651       --  be positive and in the range of 32-bits, and where the corresponding
10652       --  Length value is also known to be 32-bits. If result is true, sets
10653       --  Is_Zero, Ityp, and Comp accordingly.
10654
10655       function Is_Entity_Length (N : Node_Id) return Boolean;
10656       --  Tests if N is a length attribute applied to a simple entity. If so,
10657       --  returns True, and sets Ent to the entity, and Index to the integer
10658       --  literal provided as an attribute expression, or to Empty if none.
10659       --  Also returns True if the expression is a generated type conversion
10660       --  whose expression is of the desired form. This latter case arises
10661       --  when Apply_Universal_Integer_Attribute_Check installs a conversion
10662       --  to check for being in range, which is not needed in this context.
10663       --  Returns False if neither condition holds.
10664
10665       function Prepare_64 (N : Node_Id) return Node_Id;
10666       --  Given a discrete expression, returns a Long_Long_Integer typed
10667       --  expression representing the underlying value of the expression.
10668       --  This is done with an unchecked conversion to the result type. We
10669       --  use unchecked conversion to handle the enumeration type case.
10670
10671       ----------------------
10672       -- Is_Entity_Length --
10673       ----------------------
10674
10675       function Is_Entity_Length (N : Node_Id) return Boolean is
10676       begin
10677          if Nkind (N) = N_Attribute_Reference
10678            and then Attribute_Name (N) = Name_Length
10679            and then Is_Entity_Name (Prefix (N))
10680          then
10681             Ent := Entity (Prefix (N));
10682
10683             if Present (Expressions (N)) then
10684                Index := First (Expressions (N));
10685             else
10686                Index := Empty;
10687             end if;
10688
10689             return True;
10690
10691          elsif Nkind (N) = N_Type_Conversion
10692            and then not Comes_From_Source (N)
10693          then
10694             return Is_Entity_Length (Expression (N));
10695
10696          else
10697             return False;
10698          end if;
10699       end Is_Entity_Length;
10700
10701       --------------------
10702       -- Is_Optimizable --
10703       --------------------
10704
10705       function Is_Optimizable (N : Node_Id) return Boolean is
10706          Val  : Uint;
10707          OK   : Boolean;
10708          Lo   : Uint;
10709          Hi   : Uint;
10710          Indx : Node_Id;
10711
10712       begin
10713          if Compile_Time_Known_Value (N) then
10714             Val := Expr_Value (N);
10715
10716             if Val = Uint_0 then
10717                Is_Zero := True;
10718                Comp    := Empty;
10719                return True;
10720
10721             elsif Val = Uint_1 then
10722                Is_Zero := False;
10723                Comp    := Empty;
10724                return True;
10725             end if;
10726          end if;
10727
10728          --  Here we have to make sure of being within 32-bits
10729
10730          Determine_Range (N, OK, Lo, Hi, Assume_Valid => True);
10731
10732          if not OK
10733            or else Lo < Uint_1
10734            or else Hi > UI_From_Int (Int'Last)
10735          then
10736             return False;
10737          end if;
10738
10739          --  Comparison value was within range, so now we must check the index
10740          --  value to make sure it is also within 32-bits.
10741
10742          Indx := First_Index (Etype (Ent));
10743
10744          if Present (Index) then
10745             for J in 2 .. UI_To_Int (Intval (Index)) loop
10746                Next_Index (Indx);
10747             end loop;
10748          end if;
10749
10750          Ityp := Etype (Indx);
10751
10752          if Esize (Ityp) > 32 then
10753             return False;
10754          end if;
10755
10756          Is_Zero := False;
10757          Comp := N;
10758          return True;
10759       end Is_Optimizable;
10760
10761       ----------------
10762       -- Prepare_64 --
10763       ----------------
10764
10765       function Prepare_64 (N : Node_Id) return Node_Id is
10766       begin
10767          return Unchecked_Convert_To (Standard_Long_Long_Integer, N);
10768       end Prepare_64;
10769
10770    --  Start of processing for Optimize_Length_Comparison
10771
10772    begin
10773       --  Nothing to do if not a comparison
10774
10775       if Op not in N_Op_Compare then
10776          return;
10777       end if;
10778
10779       --  Nothing to do if special -gnatd.P debug flag set
10780
10781       if Debug_Flag_Dot_PP then
10782          return;
10783       end if;
10784
10785       --  Ent'Length op 0/1
10786
10787       if Is_Entity_Length (Left_Opnd (N))
10788         and then Is_Optimizable (Right_Opnd (N))
10789       then
10790          null;
10791
10792       --  0/1 op Ent'Length
10793
10794       elsif Is_Entity_Length (Right_Opnd (N))
10795         and then Is_Optimizable (Left_Opnd (N))
10796       then
10797          --  Flip comparison to opposite sense
10798
10799          case Op is
10800             when N_Op_Lt => Op := N_Op_Gt;
10801             when N_Op_Le => Op := N_Op_Ge;
10802             when N_Op_Gt => Op := N_Op_Lt;
10803             when N_Op_Ge => Op := N_Op_Le;
10804             when others  => null;
10805          end case;
10806
10807       --  Else optimization not possible
10808
10809       else
10810          return;
10811       end if;
10812
10813       --  Fall through if we will do the optimization
10814
10815       --  Cases to handle:
10816
10817       --    X'Length = 0  => X'First > X'Last
10818       --    X'Length = 1  => X'First = X'Last
10819       --    X'Length = n  => X'First + (n - 1) = X'Last
10820
10821       --    X'Length /= 0 => X'First <= X'Last
10822       --    X'Length /= 1 => X'First /= X'Last
10823       --    X'Length /= n => X'First + (n - 1) /= X'Last
10824
10825       --    X'Length >= 0 => always true, warn
10826       --    X'Length >= 1 => X'First <= X'Last
10827       --    X'Length >= n => X'First + (n - 1) <= X'Last
10828
10829       --    X'Length > 0  => X'First <= X'Last
10830       --    X'Length > 1  => X'First < X'Last
10831       --    X'Length > n  => X'First + (n - 1) < X'Last
10832
10833       --    X'Length <= 0 => X'First > X'Last (warn, could be =)
10834       --    X'Length <= 1 => X'First >= X'Last
10835       --    X'Length <= n => X'First + (n - 1) >= X'Last
10836
10837       --    X'Length < 0  => always false (warn)
10838       --    X'Length < 1  => X'First > X'Last
10839       --    X'Length < n  => X'First + (n - 1) > X'Last
10840
10841       --  Note: for the cases of n (not constant 0,1), we require that the
10842       --  corresponding index type be integer or shorter (i.e. not 64-bit),
10843       --  and the same for the comparison value. Then we do the comparison
10844       --  using 64-bit arithmetic (actually long long integer), so that we
10845       --  cannot have overflow intefering with the result.
10846
10847       --  First deal with warning cases
10848
10849       if Is_Zero then
10850          case Op is
10851
10852             --  X'Length >= 0
10853
10854             when N_Op_Ge =>
10855                Rewrite (N,
10856                  Convert_To (Typ, New_Occurrence_Of (Standard_True, Loc)));
10857                Analyze_And_Resolve (N, Typ);
10858                Warn_On_Known_Condition (N);
10859                return;
10860
10861             --  X'Length < 0
10862
10863             when N_Op_Lt =>
10864                Rewrite (N,
10865                  Convert_To (Typ, New_Occurrence_Of (Standard_False, Loc)));
10866                Analyze_And_Resolve (N, Typ);
10867                Warn_On_Known_Condition (N);
10868                return;
10869
10870             when N_Op_Le =>
10871                if Constant_Condition_Warnings
10872                  and then Comes_From_Source (Original_Node (N))
10873                then
10874                   Error_Msg_N ("could replace by ""'=""?", N);
10875                end if;
10876
10877                Op := N_Op_Eq;
10878
10879             when others =>
10880                null;
10881          end case;
10882       end if;
10883
10884       --  Build the First reference we will use
10885
10886       Left :=
10887         Make_Attribute_Reference (Loc,
10888           Prefix         => New_Occurrence_Of (Ent, Loc),
10889           Attribute_Name => Name_First);
10890
10891       if Present (Index) then
10892          Set_Expressions (Left, New_List (New_Copy (Index)));
10893       end if;
10894
10895       --  If general value case, then do the addition of (n - 1), and
10896       --  also add the needed conversions to type Long_Long_Integer.
10897
10898       if Present (Comp) then
10899          Left :=
10900            Make_Op_Add (Loc,
10901              Left_Opnd  => Prepare_64 (Left),
10902              Right_Opnd =>
10903                Make_Op_Subtract (Loc,
10904                  Left_Opnd  => Prepare_64 (Comp),
10905                  Right_Opnd => Make_Integer_Literal (Loc, 1)));
10906       end if;
10907
10908       --  Build the Last reference we will use
10909
10910       Right :=
10911         Make_Attribute_Reference (Loc,
10912           Prefix         => New_Occurrence_Of (Ent, Loc),
10913           Attribute_Name => Name_Last);
10914
10915       if Present (Index) then
10916          Set_Expressions (Right, New_List (New_Copy (Index)));
10917       end if;
10918
10919       --  If general operand, convert Last reference to Long_Long_Integer
10920
10921       if Present (Comp) then
10922          Right := Prepare_64 (Right);
10923       end if;
10924
10925       --  Check for cases to optimize
10926
10927       --  X'Length = 0  => X'First > X'Last
10928       --  X'Length < 1  => X'First > X'Last
10929       --  X'Length < n  => X'First + (n - 1) > X'Last
10930
10931       if (Is_Zero and then Op = N_Op_Eq)
10932         or else (not Is_Zero and then Op = N_Op_Lt)
10933       then
10934          Result :=
10935            Make_Op_Gt (Loc,
10936              Left_Opnd  => Left,
10937              Right_Opnd => Right);
10938
10939       --  X'Length = 1  => X'First = X'Last
10940       --  X'Length = n  => X'First + (n - 1) = X'Last
10941
10942       elsif not Is_Zero and then Op = N_Op_Eq then
10943          Result :=
10944            Make_Op_Eq (Loc,
10945              Left_Opnd  => Left,
10946              Right_Opnd => Right);
10947
10948       --  X'Length /= 0 => X'First <= X'Last
10949       --  X'Length > 0  => X'First <= X'Last
10950
10951       elsif Is_Zero and (Op = N_Op_Ne or else Op = N_Op_Gt) then
10952          Result :=
10953            Make_Op_Le (Loc,
10954              Left_Opnd  => Left,
10955              Right_Opnd => Right);
10956
10957       --  X'Length /= 1 => X'First /= X'Last
10958       --  X'Length /= n => X'First + (n - 1) /= X'Last
10959
10960       elsif not Is_Zero and then Op = N_Op_Ne then
10961          Result :=
10962            Make_Op_Ne (Loc,
10963              Left_Opnd  => Left,
10964              Right_Opnd => Right);
10965
10966       --  X'Length >= 1 => X'First <= X'Last
10967       --  X'Length >= n => X'First + (n - 1) <= X'Last
10968
10969       elsif not Is_Zero and then Op = N_Op_Ge then
10970          Result :=
10971            Make_Op_Le (Loc,
10972              Left_Opnd  => Left,
10973                        Right_Opnd => Right);
10974
10975       --  X'Length > 1  => X'First < X'Last
10976       --  X'Length > n  => X'First + (n = 1) < X'Last
10977
10978       elsif not Is_Zero and then Op = N_Op_Gt then
10979          Result :=
10980            Make_Op_Lt (Loc,
10981              Left_Opnd  => Left,
10982              Right_Opnd => Right);
10983
10984       --  X'Length <= 1 => X'First >= X'Last
10985       --  X'Length <= n => X'First + (n - 1) >= X'Last
10986
10987       elsif not Is_Zero and then Op = N_Op_Le then
10988          Result :=
10989            Make_Op_Ge (Loc,
10990              Left_Opnd  => Left,
10991              Right_Opnd => Right);
10992
10993       --  Should not happen at this stage
10994
10995       else
10996          raise Program_Error;
10997       end if;
10998
10999       --  Rewrite and finish up
11000
11001       Rewrite (N, Result);
11002       Analyze_And_Resolve (N, Typ);
11003       return;
11004    end Optimize_Length_Comparison;
11005
11006    ------------------------
11007    -- Rewrite_Comparison --
11008    ------------------------
11009
11010    procedure Rewrite_Comparison (N : Node_Id) is
11011       Warning_Generated : Boolean := False;
11012       --  Set to True if first pass with Assume_Valid generates a warning in
11013       --  which case we skip the second pass to avoid warning overloaded.
11014
11015       Result : Node_Id;
11016       --  Set to Standard_True or Standard_False
11017
11018    begin
11019       if Nkind (N) = N_Type_Conversion then
11020          Rewrite_Comparison (Expression (N));
11021          return;
11022
11023       elsif Nkind (N) not in N_Op_Compare then
11024          return;
11025       end if;
11026
11027       --  Now start looking at the comparison in detail. We potentially go
11028       --  through this loop twice. The first time, Assume_Valid is set False
11029       --  in the call to Compile_Time_Compare. If this call results in a
11030       --  clear result of always True or Always False, that's decisive and
11031       --  we are done. Otherwise we repeat the processing with Assume_Valid
11032       --  set to True to generate additional warnings. We can skip that step
11033       --  if Constant_Condition_Warnings is False.
11034
11035       for AV in False .. True loop
11036          declare
11037             Typ : constant Entity_Id := Etype (N);
11038             Op1 : constant Node_Id   := Left_Opnd (N);
11039             Op2 : constant Node_Id   := Right_Opnd (N);
11040
11041             Res : constant Compare_Result :=
11042                     Compile_Time_Compare (Op1, Op2, Assume_Valid => AV);
11043             --  Res indicates if compare outcome can be compile time determined
11044
11045             True_Result  : Boolean;
11046             False_Result : Boolean;
11047
11048          begin
11049             case N_Op_Compare (Nkind (N)) is
11050             when N_Op_Eq =>
11051                True_Result  := Res = EQ;
11052                False_Result := Res = LT or else Res = GT or else Res = NE;
11053
11054             when N_Op_Ge =>
11055                True_Result  := Res in Compare_GE;
11056                False_Result := Res = LT;
11057
11058                if Res = LE
11059                  and then Constant_Condition_Warnings
11060                  and then Comes_From_Source (Original_Node (N))
11061                  and then Nkind (Original_Node (N)) = N_Op_Ge
11062                  and then not In_Instance
11063                  and then Is_Integer_Type (Etype (Left_Opnd (N)))
11064                  and then not Has_Warnings_Off (Etype (Left_Opnd (N)))
11065                then
11066                   Error_Msg_N
11067                     ("can never be greater than, could replace by ""'=""?", N);
11068                   Warning_Generated := True;
11069                end if;
11070
11071             when N_Op_Gt =>
11072                True_Result  := Res = GT;
11073                False_Result := Res in Compare_LE;
11074
11075             when N_Op_Lt =>
11076                True_Result  := Res = LT;
11077                False_Result := Res in Compare_GE;
11078
11079             when N_Op_Le =>
11080                True_Result  := Res in Compare_LE;
11081                False_Result := Res = GT;
11082
11083                if Res = GE
11084                  and then Constant_Condition_Warnings
11085                  and then Comes_From_Source (Original_Node (N))
11086                  and then Nkind (Original_Node (N)) = N_Op_Le
11087                  and then not In_Instance
11088                  and then Is_Integer_Type (Etype (Left_Opnd (N)))
11089                  and then not Has_Warnings_Off (Etype (Left_Opnd (N)))
11090                then
11091                   Error_Msg_N
11092                     ("can never be less than, could replace by ""'=""?", N);
11093                   Warning_Generated := True;
11094                end if;
11095
11096             when N_Op_Ne =>
11097                True_Result  := Res = NE or else Res = GT or else Res = LT;
11098                False_Result := Res = EQ;
11099             end case;
11100
11101             --  If this is the first iteration, then we actually convert the
11102             --  comparison into True or False, if the result is certain.
11103
11104             if AV = False then
11105                if True_Result or False_Result then
11106                   if True_Result then
11107                      Result := Standard_True;
11108                   else
11109                      Result := Standard_False;
11110                   end if;
11111
11112                   Rewrite (N,
11113                     Convert_To (Typ,
11114                       New_Occurrence_Of (Result, Sloc (N))));
11115                   Analyze_And_Resolve (N, Typ);
11116                   Warn_On_Known_Condition (N);
11117                   return;
11118                end if;
11119
11120             --  If this is the second iteration (AV = True), and the original
11121             --  node comes from source and we are not in an instance, then give
11122             --  a warning if we know result would be True or False. Note: we
11123             --  know Constant_Condition_Warnings is set if we get here.
11124
11125             elsif Comes_From_Source (Original_Node (N))
11126               and then not In_Instance
11127             then
11128                if True_Result then
11129                   Error_Msg_N
11130                     ("condition can only be False if invalid values present?",
11131                      N);
11132                elsif False_Result then
11133                   Error_Msg_N
11134                     ("condition can only be True if invalid values present?",
11135                      N);
11136                end if;
11137             end if;
11138          end;
11139
11140          --  Skip second iteration if not warning on constant conditions or
11141          --  if the first iteration already generated a warning of some kind or
11142          --  if we are in any case assuming all values are valid (so that the
11143          --  first iteration took care of the valid case).
11144
11145          exit when not Constant_Condition_Warnings;
11146          exit when Warning_Generated;
11147          exit when Assume_No_Invalid_Values;
11148       end loop;
11149    end Rewrite_Comparison;
11150
11151    ----------------------------
11152    -- Safe_In_Place_Array_Op --
11153    ----------------------------
11154
11155    function Safe_In_Place_Array_Op
11156      (Lhs : Node_Id;
11157       Op1 : Node_Id;
11158       Op2 : Node_Id) return Boolean
11159    is
11160       Target : Entity_Id;
11161
11162       function Is_Safe_Operand (Op : Node_Id) return Boolean;
11163       --  Operand is safe if it cannot overlap part of the target of the
11164       --  operation. If the operand and the target are identical, the operand
11165       --  is safe. The operand can be empty in the case of negation.
11166
11167       function Is_Unaliased (N : Node_Id) return Boolean;
11168       --  Check that N is a stand-alone entity
11169
11170       ------------------
11171       -- Is_Unaliased --
11172       ------------------
11173
11174       function Is_Unaliased (N : Node_Id) return Boolean is
11175       begin
11176          return
11177            Is_Entity_Name (N)
11178              and then No (Address_Clause (Entity (N)))
11179              and then No (Renamed_Object (Entity (N)));
11180       end Is_Unaliased;
11181
11182       ---------------------
11183       -- Is_Safe_Operand --
11184       ---------------------
11185
11186       function Is_Safe_Operand (Op : Node_Id) return Boolean is
11187       begin
11188          if No (Op) then
11189             return True;
11190
11191          elsif Is_Entity_Name (Op) then
11192             return Is_Unaliased (Op);
11193
11194          elsif Nkind_In (Op, N_Indexed_Component, N_Selected_Component) then
11195             return Is_Unaliased (Prefix (Op));
11196
11197          elsif Nkind (Op) = N_Slice then
11198             return
11199               Is_Unaliased (Prefix (Op))
11200                 and then Entity (Prefix (Op)) /= Target;
11201
11202          elsif Nkind (Op) = N_Op_Not then
11203             return Is_Safe_Operand (Right_Opnd (Op));
11204
11205          else
11206             return False;
11207          end if;
11208       end Is_Safe_Operand;
11209
11210    --  Start of processing for Is_Safe_In_Place_Array_Op
11211
11212    begin
11213       --  Skip this processing if the component size is different from system
11214       --  storage unit (since at least for NOT this would cause problems).
11215
11216       if Component_Size (Etype (Lhs)) /= System_Storage_Unit then
11217          return False;
11218
11219       --  Cannot do in place stuff on VM_Target since cannot pass addresses
11220
11221       elsif VM_Target /= No_VM then
11222          return False;
11223
11224       --  Cannot do in place stuff if non-standard Boolean representation
11225
11226       elsif Has_Non_Standard_Rep (Component_Type (Etype (Lhs))) then
11227          return False;
11228
11229       elsif not Is_Unaliased (Lhs) then
11230          return False;
11231
11232       else
11233          Target := Entity (Lhs);
11234          return Is_Safe_Operand (Op1) and then Is_Safe_Operand (Op2);
11235       end if;
11236    end Safe_In_Place_Array_Op;
11237
11238    -----------------------
11239    -- Tagged_Membership --
11240    -----------------------
11241
11242    --  There are two different cases to consider depending on whether the right
11243    --  operand is a class-wide type or not. If not we just compare the actual
11244    --  tag of the left expr to the target type tag:
11245    --
11246    --     Left_Expr.Tag = Right_Type'Tag;
11247    --
11248    --  If it is a class-wide type we use the RT function CW_Membership which is
11249    --  usually implemented by looking in the ancestor tables contained in the
11250    --  dispatch table pointed by Left_Expr.Tag for Typ'Tag
11251
11252    --  Ada 2005 (AI-251): If it is a class-wide interface type we use the RT
11253    --  function IW_Membership which is usually implemented by looking in the
11254    --  table of abstract interface types plus the ancestor table contained in
11255    --  the dispatch table pointed by Left_Expr.Tag for Typ'Tag
11256
11257    procedure Tagged_Membership
11258      (N         : Node_Id;
11259       SCIL_Node : out Node_Id;
11260       Result    : out Node_Id)
11261    is
11262       Left  : constant Node_Id    := Left_Opnd  (N);
11263       Right : constant Node_Id    := Right_Opnd (N);
11264       Loc   : constant Source_Ptr := Sloc (N);
11265
11266       Full_R_Typ : Entity_Id;
11267       Left_Type  : Entity_Id;
11268       New_Node   : Node_Id;
11269       Right_Type : Entity_Id;
11270       Obj_Tag    : Node_Id;
11271
11272    begin
11273       SCIL_Node := Empty;
11274
11275       --  Handle entities from the limited view
11276
11277       Left_Type  := Available_View (Etype (Left));
11278       Right_Type := Available_View (Etype (Right));
11279
11280       --  In the case where the type is an access type, the test is applied
11281       --  using the designated types (needed in Ada 2012 for implicit anonymous
11282       --  access conversions, for AI05-0149).
11283
11284       if Is_Access_Type (Right_Type) then
11285          Left_Type  := Designated_Type (Left_Type);
11286          Right_Type := Designated_Type (Right_Type);
11287       end if;
11288
11289       if Is_Class_Wide_Type (Left_Type) then
11290          Left_Type := Root_Type (Left_Type);
11291       end if;
11292
11293       if Is_Class_Wide_Type (Right_Type) then
11294          Full_R_Typ := Underlying_Type (Root_Type (Right_Type));
11295       else
11296          Full_R_Typ := Underlying_Type (Right_Type);
11297       end if;
11298
11299       Obj_Tag :=
11300         Make_Selected_Component (Loc,
11301           Prefix        => Relocate_Node (Left),
11302           Selector_Name =>
11303             New_Reference_To (First_Tag_Component (Left_Type), Loc));
11304
11305       if Is_Class_Wide_Type (Right_Type) then
11306
11307          --  No need to issue a run-time check if we statically know that the
11308          --  result of this membership test is always true. For example,
11309          --  considering the following declarations:
11310
11311          --    type Iface is interface;
11312          --    type T     is tagged null record;
11313          --    type DT    is new T and Iface with null record;
11314
11315          --    Obj1 : T;
11316          --    Obj2 : DT;
11317
11318          --  These membership tests are always true:
11319
11320          --    Obj1 in T'Class
11321          --    Obj2 in T'Class;
11322          --    Obj2 in Iface'Class;
11323
11324          --  We do not need to handle cases where the membership is illegal.
11325          --  For example:
11326
11327          --    Obj1 in DT'Class;     --  Compile time error
11328          --    Obj1 in Iface'Class;  --  Compile time error
11329
11330          if not Is_Class_Wide_Type (Left_Type)
11331            and then (Is_Ancestor (Etype (Right_Type), Left_Type,
11332                                   Use_Full_View => True)
11333                        or else (Is_Interface (Etype (Right_Type))
11334                                  and then Interface_Present_In_Ancestor
11335                                            (Typ   => Left_Type,
11336                                             Iface => Etype (Right_Type))))
11337          then
11338             Result := New_Reference_To (Standard_True, Loc);
11339             return;
11340          end if;
11341
11342          --  Ada 2005 (AI-251): Class-wide applied to interfaces
11343
11344          if Is_Interface (Etype (Class_Wide_Type (Right_Type)))
11345
11346             --   Support to: "Iface_CW_Typ in Typ'Class"
11347
11348            or else Is_Interface (Left_Type)
11349          then
11350             --  Issue error if IW_Membership operation not available in a
11351             --  configurable run time setting.
11352
11353             if not RTE_Available (RE_IW_Membership) then
11354                Error_Msg_CRT
11355                  ("dynamic membership test on interface types", N);
11356                Result := Empty;
11357                return;
11358             end if;
11359
11360             Result :=
11361               Make_Function_Call (Loc,
11362                  Name => New_Occurrence_Of (RTE (RE_IW_Membership), Loc),
11363                  Parameter_Associations => New_List (
11364                    Make_Attribute_Reference (Loc,
11365                      Prefix => Obj_Tag,
11366                      Attribute_Name => Name_Address),
11367                    New_Reference_To (
11368                      Node (First_Elmt (Access_Disp_Table (Full_R_Typ))),
11369                      Loc)));
11370
11371          --  Ada 95: Normal case
11372
11373          else
11374             Build_CW_Membership (Loc,
11375               Obj_Tag_Node => Obj_Tag,
11376               Typ_Tag_Node =>
11377                  New_Reference_To (
11378                    Node (First_Elmt (Access_Disp_Table (Full_R_Typ))),  Loc),
11379               Related_Nod => N,
11380               New_Node    => New_Node);
11381
11382             --  Generate the SCIL node for this class-wide membership test.
11383             --  Done here because the previous call to Build_CW_Membership
11384             --  relocates Obj_Tag.
11385
11386             if Generate_SCIL then
11387                SCIL_Node := Make_SCIL_Membership_Test (Sloc (N));
11388                Set_SCIL_Entity (SCIL_Node, Etype (Right_Type));
11389                Set_SCIL_Tag_Value (SCIL_Node, Obj_Tag);
11390             end if;
11391
11392             Result := New_Node;
11393          end if;
11394
11395       --  Right_Type is not a class-wide type
11396
11397       else
11398          --  No need to check the tag of the object if Right_Typ is abstract
11399
11400          if Is_Abstract_Type (Right_Type) then
11401             Result := New_Reference_To (Standard_False, Loc);
11402
11403          else
11404             Result :=
11405               Make_Op_Eq (Loc,
11406                 Left_Opnd  => Obj_Tag,
11407                 Right_Opnd =>
11408                   New_Reference_To
11409                     (Node (First_Elmt (Access_Disp_Table (Full_R_Typ))), Loc));
11410          end if;
11411       end if;
11412    end Tagged_Membership;
11413
11414    ------------------------------
11415    -- Unary_Op_Validity_Checks --
11416    ------------------------------
11417
11418    procedure Unary_Op_Validity_Checks (N : Node_Id) is
11419    begin
11420       if Validity_Checks_On and Validity_Check_Operands then
11421          Ensure_Valid (Right_Opnd (N));
11422       end if;
11423    end Unary_Op_Validity_Checks;
11424
11425 end Exp_Ch4;