gcc/ada/a-coorma.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --           A D A . C O N T A I N E R S . O R D E R E D _ M A P S          --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  24 -- Boston, MA 02110-1301, USA.                                              --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- This unit was originally developed by Matthew J Heaney.                  --
  34 ------------------------------------------------------------------------------
  35
  36 private with Ada.Containers.Red_Black_Trees;
  37 private with Ada.Finalization;
  38 private with Ada.Streams;
  39
  40 generic
  41    type Key_Type is private;
  42    type Element_Type is private;
  43
  44    with function "<" (Left, Right : Key_Type) return Boolean is <>;
  45    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  46
  47 package Ada.Containers.Ordered_Maps is
  48    pragma Preelaborate;
  49    pragma Remote_Types;
  50
  51    function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  52
  53    type Map is tagged private;
  54    pragma Preelaborable_Initialization (Map);
  55
  56    type Cursor is private;
  57    pragma Preelaborable_Initialization (Cursor);
  58
  59    Empty_Map : constant Map;
  60
  61    No_Element : constant Cursor;
  62
  63    function "=" (Left, Right : Map) return Boolean;
  64
  65    function Length (Container : Map) return Count_Type;
  66
  67    function Is_Empty (Container : Map) return Boolean;
  68
  69    procedure Clear (Container : in out Map);
  70
  71    function Key (Position : Cursor) return Key_Type;
  72
  73    function Element (Position : Cursor) return Element_Type;
  74
  75    procedure Replace_Element
  76      (Container : in out Map;
  77       Position  : Cursor;
  78       New_Item  : Element_Type);
  79
  80    procedure Query_Element
  81      (Position : Cursor;
  82       Process  : not null access
  83                    procedure (Key : Key_Type; Element : Element_Type));
  84
  85    procedure Update_Element
  86      (Container : in out Map;
  87       Position  : Cursor;
  88       Process   : not null access
  89                    procedure (Key : Key_Type; Element : in out Element_Type));
  90
  91    procedure Move (Target : in out Map; Source : in out Map);
  92
  93    procedure Insert
  94      (Container : in out Map;
  95       Key       : Key_Type;
  96       New_Item  : Element_Type;
  97       Position  : out Cursor;
  98       Inserted  : out Boolean);
  99
 100    procedure Insert
 101      (Container : in out Map;
 102       Key       : Key_Type;
 103       Position  : out Cursor;
 104       Inserted  : out Boolean);
 105
 106    procedure Insert
 107      (Container : in out Map;
 108       Key       : Key_Type;
 109       New_Item  : Element_Type);
 110
 111    procedure Include
 112      (Container : in out Map;
 113       Key       : Key_Type;
 114       New_Item  : Element_Type);
 115
 116    procedure Replace
 117      (Container : in out Map;
 118       Key       : Key_Type;
 119       New_Item  : Element_Type);
 120
 121    procedure Exclude (Container : in out Map; Key : Key_Type);
 122
 123    procedure Delete (Container : in out Map; Key : Key_Type);
 124
 125    procedure Delete (Container : in out Map; Position : in out Cursor);
 126
 127    procedure Delete_First (Container : in out Map);
 128
 129    procedure Delete_Last (Container : in out Map);
 130
 131    function First (Container : Map) return Cursor;
 132
 133    function First_Element (Container : Map) return Element_Type;
 134
 135    function First_Key (Container : Map) return Key_Type;
 136
 137    function Last (Container : Map) return Cursor;
 138
 139    function Last_Element (Container : Map) return Element_Type;
 140
 141    function Last_Key (Container : Map) return Key_Type;
 142
 143    function Next (Position : Cursor) return Cursor;
 144
 145    procedure Next (Position : in out Cursor);
 146
 147    function Previous (Position : Cursor) return Cursor;
 148
 149    procedure Previous (Position : in out Cursor);
 150
 151    function Find (Container : Map; Key : Key_Type) return Cursor;
 152
 153    function Element (Container : Map; Key : Key_Type) return Element_Type;
 154
 155    function Floor (Container : Map; Key : Key_Type) return Cursor;
 156
 157    function Ceiling (Container : Map; Key : Key_Type) return Cursor;
 158
 159    function Contains (Container : Map; Key : Key_Type) return Boolean;
 160
 161    function Has_Element (Position : Cursor) return Boolean;
 162
 163    function "<" (Left, Right : Cursor) return Boolean;
 164
 165    function ">" (Left, Right : Cursor) return Boolean;
 166
 167    function "<" (Left : Cursor; Right : Key_Type) return Boolean;
 168
 169    function ">" (Left : Cursor; Right : Key_Type) return Boolean;
 170
 171    function "<" (Left : Key_Type; Right : Cursor) return Boolean;
 172
 173    function ">" (Left : Key_Type; Right : Cursor) return Boolean;
 174
 175    procedure Iterate
 176      (Container : Map;
 177       Process   : not null access procedure (Position : Cursor));
 178
 179    procedure Reverse_Iterate
 180      (Container : Map;
 181       Process   : not null access procedure (Position : Cursor));
 182
 183 private
 184
 185    pragma Inline (Next);
 186    pragma Inline (Previous);
 187
 188    type Node_Type;
 189    type Node_Access is access Node_Type;
 190
 191    type Node_Type is limited record
 192       Parent  : Node_Access;
 193       Left    : Node_Access;
 194       Right   : Node_Access;
 195       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 196       Key     : Key_Type;
 197       Element : Element_Type;
 198    end record;
 199
 200    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 201      (Node_Type,
 202       Node_Access);
 203
 204    type Map is new Ada.Finalization.Controlled with record
 205       Tree : Tree_Types.Tree_Type;
 206    end record;
 207
 208    overriding
 209    procedure Adjust (Container : in out Map);
 210
 211    overriding
 212    procedure Finalize (Container : in out Map) renames Clear;
 213
 214    use Red_Black_Trees;
 215    use Tree_Types;
 216    use Ada.Finalization;
 217    use Ada.Streams;
 218
 219    type Map_Access is access all Map;
 220    for Map_Access'Storage_Size use 0;
 221
 222    type Cursor is record
 223       Container : Map_Access;
 224       Node      : Node_Access;
 225    end record;
 226
 227    procedure Write
 228      (Stream : not null access Root_Stream_Type'Class;
 229       Item   : Cursor);
 230
 231    for Cursor'Write use Write;
 232
 233    procedure Read
 234      (Stream : not null access Root_Stream_Type'Class;
 235       Item   : out Cursor);
 236
 237    for Cursor'Read use Read;
 238
 239    No_Element : constant Cursor := Cursor'(null, null);
 240
 241    procedure Write
 242      (Stream    : not null access Root_Stream_Type'Class;
 243       Container : Map);
 244
 245    for Map'Write use Write;
 246
 247    procedure Read
 248      (Stream    : not null access Root_Stream_Type'Class;
 249       Container : out Map);
 250
 251    for Map'Read use Read;
 252
 253    Empty_Map : constant Map :=
 254                  (Controlled with Tree => (First  => null,
 255                                            Last   => null,
 256                                            Root   => null,
 257                                            Length => 0,
 258                                            Busy   => 0,
 259                                            Lock   => 0));
 260
 261 end Ada.Containers.Ordered_Maps;