gcc/ada/a-cbprqu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                  ADA.CONTAINERS.BOUNDED_PRIORITY_QUEUES                  --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --            Copyright (C) 2011, Free Software Foundation, Inc.            --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 --                                                                          --
  31 -- This unit was originally developed by Matthew J Heaney.                  --
  32 ------------------------------------------------------------------------------
  33
  34 with System;
  35
  36 with Ada.Containers.Synchronized_Queue_Interfaces;
  37 with Ada.Containers.Bounded_Doubly_Linked_Lists;
  38
  39 generic
  40    with package Queue_Interfaces is
  41      new Ada.Containers.Synchronized_Queue_Interfaces (<>);
  42
  43    type Queue_Priority is private;
  44
  45    with function Get_Priority
  46      (Element : Queue_Interfaces.Element_Type) return Queue_Priority is <>;
  47
  48    with function Before
  49      (Left, Right : Queue_Priority) return Boolean is <>;
  50
  51    Default_Capacity : Count_Type;
  52    Default_Ceiling  : System.Any_Priority := System.Priority'Last;
  53
  54 package Ada.Containers.Bounded_Priority_Queues is
  55    pragma Preelaborate;
  56
  57    package Implementation is
  58
  59       --  All identifiers in this unit are implementation defined
  60
  61       pragma Implementation_Defined;
  62
  63       type List_Type (Capacity : Count_Type) is tagged limited private;
  64
  65       procedure Enqueue
  66         (List     : in out List_Type;
  67          New_Item : Queue_Interfaces.Element_Type);
  68
  69       procedure Dequeue
  70         (List    : in out List_Type;
  71          Element : out Queue_Interfaces.Element_Type);
  72
  73       procedure Dequeue
  74         (List     : in out List_Type;
  75          At_Least : Queue_Priority;
  76          Element  : in out Queue_Interfaces.Element_Type;
  77          Success  : out Boolean);
  78
  79       function First_Element
  80         (List : List_Type) return Queue_Interfaces.Element_Type;
  81
  82       function Length (List : List_Type) return Count_Type;
  83
  84       function Max_Length (List : List_Type) return Count_Type;
  85
  86    private
  87
  88       --  We need a better data structure here, such as a proper heap.  ???
  89
  90       package List_Types is new Bounded_Doubly_Linked_Lists
  91         (Element_Type => Queue_Interfaces.Element_Type,
  92          "="          => Queue_Interfaces."=");
  93
  94       type List_Type (Capacity : Count_Type) is tagged limited record
  95          Container  : List_Types.List (Capacity);
  96          Max_Length : Count_Type := 0;
  97       end record;
  98
  99    end Implementation;
 100
 101    protected type Queue
 102      (Capacity : Count_Type := Default_Capacity;
 103       Ceiling  : System.Any_Priority := Default_Ceiling)
 104      with Priority => Ceiling is new Queue_Interfaces.Queue with
 105
 106       overriding
 107       entry Enqueue (New_Item : Queue_Interfaces.Element_Type);
 108
 109       overriding
 110       entry Dequeue (Element : out Queue_Interfaces.Element_Type);
 111
 112       --  The priority queue operation Dequeue_Only_High_Priority had been a
 113       --  protected entry in early drafts of AI05-0159, but it was discovered
 114       --  that that operation as specified was not in fact implementable. The
 115       --  operation was changed from an entry to a protected procedure per the
 116       --  ARG meeting in Edinburgh (June 2011), with a different signature and
 117       --  semantics.
 118
 119       not overriding
 120       procedure Dequeue_Only_High_Priority
 121         (At_Least : Queue_Priority;
 122          Element  : in out Queue_Interfaces.Element_Type;
 123          Success  : out Boolean);
 124
 125       overriding
 126       function Current_Use return Count_Type;
 127
 128       overriding
 129       function Peak_Use return Count_Type;
 130
 131    private
 132
 133       List : Implementation.List_Type (Capacity);
 134
 135    end Queue;
 136
 137 end Ada.Containers.Bounded_Priority_Queues;