OSDN Git Service

46296049f3153c40fed7498814a0fb566e0f2ca5
[pf3gnuchains/gcc-fork.git] / fixincludes / configure.ac
1 AC_PREREQ(2.59)
2
3 AC_INIT(fixincludes, [ ])
4 AC_CONFIG_SRCDIR(inclhack.def)
5 AC_CONFIG_AUX_DIR(..)
6 AC_CANONICAL_SYSTEM
7 AC_PROG_CC
8
9 # Determine the noncanonical target name, for directory use.
10 ACX_NONCANONICAL_TARGET
11
12 # Specify the local prefix
13 local_prefix=
14 AC_ARG_WITH(local-prefix,
15 [  --with-local-prefix=DIR specifies directory to put local include],
16 [case "${withval}" in
17 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
18 no)     ;;
19 *)      local_prefix=$with_local_prefix ;;
20 esac])
21
22 # Default local prefix if it is empty
23 if test x$local_prefix = x; then
24         local_prefix=/usr/local
25 fi
26
27 # Choose one or two-process fix methodology.  Systems that cannot handle
28 # bi-directional pipes must use the two process method.
29 #
30 AC_ARG_ENABLE([twoprocess],
31 [  --enable-twoprocess       Use a separate process to apply the fixes],
32 [if test "x$enable_twoprocess" = xyes; then
33         TARGET=twoprocess
34 else
35         TARGET=oneprocess
36 fi],
37 [case $host in
38         i?86-*-msdosdjgpp* | \
39         i?86-*-mingw32* | \
40         *-*-beos* )
41                 TARGET=twoprocess
42                 ;;
43
44         * )
45                 TARGET=oneprocess
46                 ;;
47 esac])
48 AC_SUBST(TARGET)
49
50 if test $TARGET = twoprocess; then
51         AC_DEFINE(SEPARATE_FIX_PROC, 1,
52                   [Define if testing and fixing are done by separate process])
53 fi
54
55 case $host in
56         vax-dec-bsd* )
57                 AC_DEFINE(exit, xexit, [Define to xexit if the host system does not support atexit])
58                 AC_DEFINE(atexit, xatexit, [Define to xatexit if the host system does not support atexit])
59                 ;;
60 esac
61
62 AC_DEFINE_UNQUOTED([EXE_EXT], "$ac_exeext",
63   [Defined to the executable file extension on the host system])
64
65 # Checks for header files.
66 AC_HEADER_STDC
67 AC_CHECK_HEADERS([stddef.h stdlib.h strings.h unistd.h fcntl.h sys/file.h \
68         sys/stat.h])
69 define(fixincludes_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
70   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
71   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
72   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
73   putchar_unlocked putc_unlocked)
74 AC_CHECK_FUNCS(fixincludes_UNLOCKED_FUNCS)
75 AC_CHECK_DECLS(m4_split(m4_normalize(abort errno fixincludes_UNLOCKED_FUNCS)))
76
77 # Checks for typedefs, structures, and compiler characteristics.
78 AC_C_CONST
79
80 # Checks for library functions.
81 gcc_AC_FUNC_MMAP_BLACKLIST
82
83 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
84 AC_ARG_ENABLE(maintainer-mode,
85 [  --enable-maintainer-mode enable make rules and dependencies not useful
86                           (and sometimes confusing) to the casual installer],
87       USE_MAINTAINER_MODE=$enableval,
88       USE_MAINTAINER_MODE=no)
89 AC_MSG_RESULT($USE_MAINTAINER_MODE)
90 if test "$USE_MAINTAINER_MODE" = yes; then
91   MAINT=
92 else
93   MAINT='#'
94 fi      
95 AC_SUBST(MAINT)
96
97 AC_CONFIG_HEADERS(config.h, [echo timestamp > stamp-h])
98 AC_CONFIG_FILES(Makefile mkheaders.almost:mkheaders.in)
99 AC_OUTPUT