configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libgloss \
 155                 target-newlib \
 156                 target-libgomp \
 157                 target-libstdc++-v3 \
 158                 target-libmudflap \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-boehm-gc \
 163                 ${libgcj} \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 # Make sure we don't let ZLIB be added if we didn't want it.
 242 if test x$with_system_zlib = xyes ; then
 243   use_included_zlib=no
 244   noconfigdirs="$noconfigdirs zlib"
 245 fi
 246
 247 # some tools are so dependent upon X11 that if we're not building with X,
 248 # it's not even worth trying to configure, much less build, that tool.
 249
 250 case ${with_x} in
 251   yes | "") ;; # the default value for this tree is that X11 is available
 252   no)
 253     skipdirs="${skipdirs} tk itcl libgui"
 254     # We won't be able to build gdbtk without X.
 255     enable_gdbtk=no
 256     ;;
 257   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 258 esac
 259
 260 # Some are only suitable for cross toolchains.
 261 # Remove these if host=target.
 262 cross_only="target-libgloss target-newlib target-opcodes"
 263
 264 case $is_cross_compiler in
 265   no) skipdirs="${skipdirs} ${cross_only}" ;;
 266 esac
 267
 268 # If both --with-headers and --with-libs are specified, default to
 269 # --without-newlib.
 270 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 271    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 272   if test x"${with_newlib}" = x ; then
 273     with_newlib=no
 274   fi
 275 fi
 276
 277 # Recognize --with-newlib/--without-newlib.
 278 case ${with_newlib} in
 279   no) skipdirs="${skipdirs} target-newlib" ;;
 280   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 281 esac
 282
 283 # Handle --enable-gold, --enable-ld.
 284 # --disable-gold [--enable-ld]
 285 #     Build only ld.  Default option.
 286 # --enable-gold [--enable-ld]
 287 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 288 #     as "ld.bfd" and "ld".
 289 # --enable-gold=default [--enable-ld]
 290 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 291 #     install ld as "ld.bfd".
 292 # --enable-gold[=default] --disable-ld
 293 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 294 # --enable-gold --enable-ld=default
 295 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 296 #     and ld.bfd).
 297 #     In other words, ld is default
 298 # --enable-gold=default --enable-ld=default
 299 #     Error.
 300
 301 default_ld=
 302 AC_ARG_ENABLE(gold,
 303 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 304                 [build gold @<:@ARG={default,yes,no}@:>@])],
 305 ENABLE_GOLD=$enableval,
 306 ENABLE_GOLD=no)
 307 case "${ENABLE_GOLD}" in
 308   yes|default)
 309     # Check for ELF target.
 310     is_elf=no
 311     case "${target}" in
 312       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 313       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 314       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 315       | *-*-solaris2* | *-*-nto*)
 316         case "${target}" in
 317           *-*-linux*aout* | *-*-linux*oldld*)
 318             ;;
 319           *)
 320             is_elf=yes
 321             ;;
 322         esac
 323     esac
 324
 325     if test "$is_elf" = "yes"; then
 326       # Check for target supported by gold.
 327       case "${target}" in
 328         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 329           configdirs="$configdirs gold"
 330           if test x${ENABLE_GOLD} = xdefault; then
 331             default_ld=gold
 332           fi
 333           ENABLE_GOLD=yes
 334           ;;
 335       esac
 336     fi
 337     ;;
 338   no)
 339     ;;
 340   *)
 341     AC_MSG_ERROR([invalid --enable-gold argument])
 342     ;;
 343 esac
 344
 345 AC_ARG_ENABLE(ld,
 346 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 347                 [build ld @<:@ARG={default,yes,no}@:>@])],
 348 ENABLE_LD=$enableval,
 349 ENABLE_LD=yes)
 350
 351 case "${ENABLE_LD}" in
 352   default)
 353     if test x${default_ld} != x; then
 354       AC_MSG_ERROR([either gold or ld can be the default ld])
 355     fi
 356     ;;
 357   yes)
 358     ;;
 359   no)
 360     if test x${ENABLE_GOLD} != xyes; then
 361       AC_MSG_WARN([neither ld nor gold are enabled])
 362     fi
 363     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 364     ;;
 365   *)
 366     AC_MSG_ERROR([invalid --enable-ld argument])
 367     ;;
 368 esac
 369
 370 # Configure extra directories which are host specific
 371
 372 case "${host}" in
 373   *-cygwin*)
 374     configdirs="$configdirs libtermcap" ;;
 375 esac
 376
 377 # A target can indicate whether a language isn't supported for some reason.
 378 # Only spaces may be used in this macro; not newlines or tabs.
 379 unsupported_languages=
 380
 381 # Remove more programs from consideration, based on the host or
 382 # target this usually means that a port of the program doesn't
 383 # exist yet.
 384
 385 case "${host}" in
 386   i[[3456789]]86-*-msdosdjgpp*)
 387     noconfigdirs="$noconfigdirs tcl tk itcl"
 388     ;;
 389 esac
 390
 391
 392 AC_ARG_ENABLE(libquadmath,
 393 AS_HELP_STRING([--disable-libquadmath],
 394   [do not build libquadmath directory]),
 395 ENABLE_LIBQUADMATH=$enableval,
 396 ENABLE_LIBQUADMATH=yes)
 397 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 398   noconfigdirs="$noconfigdirs target-libquadmath"
 399 fi
 400
 401
 402 AC_ARG_ENABLE(libquadmath-support,
 403 AS_HELP_STRING([--disable-libquadmath-support],
 404   [disable libquadmath support for Fortran]),
 405 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 406 ENABLE_LIBQUADMATH_SUPPORT=yes)
 407 enable_libquadmath_support=
 408 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 409   enable_libquadmath_support=no
 410 fi
 411
 412
 413 AC_ARG_ENABLE(libada,
 414 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 415 ENABLE_LIBADA=$enableval,
 416 ENABLE_LIBADA=yes)
 417 if test "${ENABLE_LIBADA}" != "yes" ; then
 418   noconfigdirs="$noconfigdirs gnattools"
 419 fi
 420
 421 AC_ARG_ENABLE(libssp,
 422 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 423 ENABLE_LIBSSP=$enableval,
 424 ENABLE_LIBSSP=yes)
 425
 426 # Save it here so that, even in case of --enable-libgcj, if the Java
 427 # front-end isn't enabled, we still get libgcj disabled.
 428 libgcj_saved=$libgcj
 429 case $enable_libgcj in
 430 yes)
 431   # If we reset it here, it won't get added to noconfigdirs in the
 432   # target-specific build rules, so it will be forcibly enabled
 433   # (unless the Java language itself isn't enabled).
 434   libgcj=
 435   ;;
 436 no)
 437   # Make sure we get it printed in the list of not supported target libs.
 438   # Don't disable libffi, though, other languages use it.
 439   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 440   # Clear libgcj_saved so that even if java is enabled libffi won't be
 441   # built.
 442   libgcj_saved=
 443   ;;
 444 esac
 445
 446 AC_ARG_ENABLE(static-libjava,
 447 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 448                 [build static libjava @<:@default=no@:>@])],
 449 ENABLE_STATIC_LIBJAVA=$enableval,
 450 ENABLE_STATIC_LIBJAVA=no)
 451 enable_static_libjava=
 452 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 453   enable_static_libjava=yes
 454 fi
 455
 456 if test x$enable_static_libjava != xyes ; then
 457   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 458 fi
 459 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 460
 461 # Disable libmudflap on some systems.
 462 if test x$enable_libmudflap = x ; then
 463     case "${target}" in
 464     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 465         # Enable libmudflap by default in GNU and friends.
 466         ;;
 467     *-*-freebsd*)
 468         # Enable libmudflap by default in FreeBSD.
 469         ;;
 470     *)
 471         # Disable it by default everywhere else.
 472         noconfigdirs="$noconfigdirs target-libmudflap"
 473         ;;
 474     esac
 475 fi
 476
 477 # Disable libgomp on non POSIX hosted systems.
 478 if test x$enable_libgomp = x ; then
 479     # Enable libgomp by default on hosted POSIX systems.
 480     case "${target}" in
 481     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 482         ;;
 483     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 484         ;;
 485     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 486         ;;
 487     *-*-darwin* | *-*-aix*)
 488         ;;
 489     *)
 490         noconfigdirs="$noconfigdirs target-libgomp"
 491         ;;
 492     esac
 493 fi
 494
 495 # Disable libssp for some systems.
 496 case "${target}" in
 497   avr-*-*)
 498     # No hosted I/O support.
 499     noconfigdirs="$noconfigdirs target-libssp"
 500     ;;
 501   powerpc-*-aix* | rs6000-*-aix*)
 502     noconfigdirs="$noconfigdirs target-libssp"
 503     ;;
 504 esac
 505
 506 # Disable libstdc++-v3 for some systems.
 507 case "${target}" in
 508   *-*-vxworks*)
 509     # VxWorks uses the Dinkumware C++ library.
 510     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 511     ;;
 512   arm*-wince-pe*)
 513     # the C++ libraries don't build on top of CE's C libraries
 514     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 515     ;;
 516   avr-*-*)
 517     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 518     ;;
 519 esac
 520
 521 # Disable Fortran for some systems.
 522 case "${target}" in
 523   mmix-*-*)
 524     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 525     unsupported_languages="$unsupported_languages fortran"
 526     ;;
 527 esac
 528
 529 # Disable Java if libffi is not supported.
 530 case "${target}" in
 531   alpha*-*-*)
 532     ;;
 533   arm*-*-*)
 534     ;;
 535   cris-*-*)
 536     ;;
 537   frv-*-*)
 538     ;;
 539   hppa*-*-linux*)
 540     ;;
 541   hppa*-*-hpux*)
 542     ;;
 543   i?86-*-*)
 544     ;;
 545   ia64*-*-*)
 546     ;;
 547   m32r*-*-*)
 548     ;;
 549   m68k-*-*)
 550     ;;
 551   mips-sgi-irix6.* | mips*-*-rtems*)
 552     ;;
 553   mips*-*-linux*)
 554     ;;
 555   powerpc*-*-linux*)
 556     ;;
 557   powerpc-*-darwin*)
 558     ;;
 559   powerpc-*-aix* | rs6000-*-aix*)
 560     ;;
 561   powerpc-*-freebsd*)
 562     ;;
 563   powerpc64-*-freebsd*)
 564     ;;
 565   powerpc*-*-rtems*)
 566     ;;
 567   s390-*-* | s390x-*-*)
 568     ;;
 569   sh-*-* | sh[[34]]*-*-*)
 570     ;;
 571   sh64-*-* | sh5*-*-*)
 572     ;;
 573   sparc*-*-*)
 574     ;;
 575   x86_64-*-*)
 576     ;;
 577   *-*-*)
 578     unsupported_languages="$unsupported_languages java"
 579     ;;
 580 esac
 581
 582 # Disable Java, libgcj or related libraries for some systems.
 583 case "${target}" in
 584   powerpc-*-darwin*)
 585     ;;
 586   i[[3456789]]86-*-darwin*)
 587     ;;
 588   x86_64-*-darwin[[912]]*)
 589     ;;
 590   *-*-darwin*)
 591     noconfigdirs="$noconfigdirs ${libgcj}"
 592     ;;
 593   *-*-netware*)
 594     noconfigdirs="$noconfigdirs ${libgcj}"
 595     ;;
 596   *-*-rtems*)
 597     noconfigdirs="$noconfigdirs ${libgcj}"
 598     ;;
 599   *-*-tpf*)
 600     noconfigdirs="$noconfigdirs ${libgcj}"
 601     ;;
 602   *-*-uclinux*)
 603     noconfigdirs="$noconfigdirs ${libgcj}"
 604     ;;
 605   *-*-vxworks*)
 606     noconfigdirs="$noconfigdirs ${libgcj}"
 607     ;;
 608   alpha*-*-*vms*)
 609     noconfigdirs="$noconfigdirs ${libgcj}"
 610     ;;
 611   arm-wince-pe)
 612     noconfigdirs="$noconfigdirs ${libgcj}"
 613     ;;
 614   arm*-*-symbianelf*)
 615     noconfigdirs="$noconfigdirs ${libgcj}"
 616     ;;
 617   bfin-*-*)
 618     noconfigdirs="$noconfigdirs target-boehm-gc"
 619     ;;
 620   cris-*-* | crisv32-*-*)
 621     unsupported_languages="$unsupported_languages java"
 622     case "${target}" in
 623       *-*-linux*)
 624         ;;
 625       *) # See PR46792 regarding target-libffi.
 626         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 627     esac
 628     ;;
 629   hppa*64*-*-linux*)
 630     # In this case, it's because the hppa64-linux target is for
 631     # the kernel only at this point and has no libc, and thus no
 632     # headers, crt*.o, etc., all of which are needed by these.
 633     unsupported_languages="$unsupported_languages java"
 634     ;;
 635   hppa*64*-*-hpux*)
 636     noconfigdirs="$noconfigdirs ${libgcj}"
 637     ;;
 638   hppa*-hp-hpux11*)
 639     ;;
 640   hppa*-*-hpux*)
 641     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 642     # build on HP-UX 10.20.
 643     noconfigdirs="$noconfigdirs ${libgcj}"
 644     ;;
 645   ia64*-*-*vms*)
 646     noconfigdirs="$noconfigdirs ${libgcj}"
 647     ;;
 648   i[[3456789]]86-w64-mingw*)
 649     noconfigdirs="$noconfigdirs ${libgcj}"
 650     ;;
 651   i[[3456789]]86-*-mingw*)
 652     noconfigdirs="$noconfigdirs ${libgcj}"
 653     ;;
 654   x86_64-*-mingw*)
 655     noconfigdirs="$noconfigdirs ${libgcj}"
 656     ;;
 657   mmix-*-*)
 658     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 659     ;;
 660   powerpc-*-aix*)
 661     # copied from rs6000-*-* entry
 662     noconfigdirs="$noconfigdirs ${libgcj}"
 663     ;;
 664   rs6000-*-aix*)
 665     noconfigdirs="$noconfigdirs ${libgcj}"
 666     ;;
 667   mips*-*-irix6*)
 668     # Linking libjava exceeds command-line length limits on at least
 669     # IRIX 6.2, but not on IRIX 6.5.
 670     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 671     # <oldham@codesourcery.com>
 672     noconfigdirs="$noconfigdirs ${libgcj}"
 673     ;;
 674   *-*-lynxos*)
 675     noconfigdirs="$noconfigdirs ${libgcj}"
 676     ;;
 677 esac
 678
 679 # Default libgloss CPU subdirectory.
 680 libgloss_dir="$target_cpu"
 681
 682 case "${target}" in
 683   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 684     libgloss_dir=wince
 685     ;;
 686   arm*-*-*)
 687     libgloss_dir=arm
 688     ;;
 689   cris-*-* | crisv32-*-*)
 690     libgloss_dir=cris
 691     ;;
 692   hppa*-*-*)
 693     libgloss_dir=pa
 694     ;;
 695   i[[3456789]]86-*-*)
 696     libgloss_dir=i386
 697     ;;
 698   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 699     libgloss_dir=m68hc11
 700     ;;
 701   m68*-*-* | fido-*-*)
 702     libgloss_dir=m68k
 703     ;;
 704   mips*-*-*)
 705     libgloss_dir=mips
 706     ;;
 707   powerpc*-*-*)
 708     libgloss_dir=rs6000
 709     ;;
 710   sparc*-*-*)
 711     libgloss_dir=sparc
 712     ;;
 713 esac
 714
 715 # Disable newlib and libgloss for various target OSes.
 716 case "${target}" in
 717   alpha*-dec-osf*)
 718     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 719     ;;
 720   i[[3456789]]86-*-linux*)
 721     # This section makes it possible to build newlib natively on linux.
 722     # If we are using a cross compiler then don't configure newlib.
 723     if test x${is_cross_compiler} != xno ; then
 724       noconfigdirs="$noconfigdirs target-newlib"
 725     fi
 726     noconfigdirs="$noconfigdirs target-libgloss"
 727     # If we are not using a cross compiler, do configure newlib.
 728     # Note however, that newlib will only be configured in this situation
 729     # if the --with-newlib option has been given, because otherwise
 730     # 'target-newlib' will appear in skipdirs.
 731     ;;
 732   i[[3456789]]86-*-rdos*)
 733     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 734     ;;
 735   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 736     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 737     ;;
 738   sparc-*-sunos4*)
 739     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 740     ;;
 741   *-*-aix*)
 742     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 743     ;;
 744   *-*-beos*)
 745     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 746     ;;
 747   *-*-chorusos)
 748     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 749     ;;
 750   *-*-dragonfly*)
 751     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 752     ;;
 753   *-*-freebsd*)
 754     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 755     ;;
 756   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 757     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 758     ;;
 759   *-*-lynxos*)
 760     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 761     ;;
 762   *-*-mingw*)
 763     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 764     ;;
 765   *-*-netbsd*)
 766     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 767     ;;
 768   *-*-netware*)
 769     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 770     ;;
 771   *-*-tpf*)
 772     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 773     ;;
 774   *-*-uclinux*)
 775     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 776     ;;
 777   *-*-vxworks*)
 778     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 779     ;;
 780 esac
 781
 782 case "${target}" in
 783   *-*-chorusos)
 784     ;;
 785   powerpc-*-darwin*)
 786     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 787     noconfigdirs="$noconfigdirs sim target-rda"
 788     ;;
 789   i[[3456789]]86-*-darwin*)
 790     noconfigdirs="$noconfigdirs ld gprof"
 791     noconfigdirs="$noconfigdirs sim target-rda"
 792     ;;
 793   x86_64-*-darwin[[912]]*)
 794     noconfigdirs="$noconfigdirs ld gas gprof"
 795     noconfigdirs="$noconfigdirs sim target-rda"
 796     ;;
 797   *-*-darwin*)
 798     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 799     noconfigdirs="$noconfigdirs sim target-rda"
 800     ;;
 801   *-*-dragonfly*)
 802     ;;
 803   *-*-freebsd*)
 804     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 805         && test -f /usr/local/include/gmp.h; then
 806       with_gmp=/usr/local
 807     fi
 808     ;;
 809   *-*-kaos*)
 810     # Remove unsupported stuff on all kaOS configurations.
 811     noconfigdirs="$noconfigdirs target-libgloss"
 812     ;;
 813   *-*-netbsd*)
 814     ;;
 815   *-*-netware*)
 816     ;;
 817   *-*-rtems*)
 818     noconfigdirs="$noconfigdirs target-libgloss"
 819     ;;
 820     # The tpf target doesn't support gdb yet.
 821   *-*-tpf*)
 822     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 823     ;;
 824   *-*-uclinux*)
 825     noconfigdirs="$noconfigdirs target-rda"
 826     ;;
 827   *-*-vxworks*)
 828     ;;
 829   alpha*-dec-osf*)
 830     # ld works, but does not support shared libraries.
 831     # gas doesn't generate exception information.
 832     noconfigdirs="$noconfigdirs gas ld"
 833     ;;
 834   alpha*-*-*vms*)
 835     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 836     ;;
 837   alpha*-*-*)
 838     # newlib is not 64 bit ready
 839     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 840     ;;
 841   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 842     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 843     ;;
 844   arc-*-*)
 845     noconfigdirs="$noconfigdirs target-libgloss"
 846     ;;
 847   arm-*-pe*)
 848     noconfigdirs="$noconfigdirs target-libgloss"
 849     ;;
 850   arm-*-riscix*)
 851     noconfigdirs="$noconfigdirs ld target-libgloss"
 852     ;;
 853   c4x-*-* | tic4x-*-*)
 854     noconfigdirs="$noconfigdirs target-libgloss"
 855     ;;
 856   tic54x-*-*)
 857     noconfigdirs="$noconfigdirs target-libgloss gdb"
 858     ;;
 859   cr16-*-*)
 860     noconfigdirs="$noconfigdirs gdb"
 861     ;;
 862   d10v-*-*)
 863     noconfigdirs="$noconfigdirs target-libgloss"
 864     ;;
 865   d30v-*-*)
 866     noconfigdirs="$noconfigdirs gdb"
 867     ;;
 868   fr30-*-elf*)
 869     noconfigdirs="$noconfigdirs gdb"
 870     ;;
 871   moxie-*-*)
 872     noconfigdirs="$noconfigdirs gprof"
 873     ;;
 874   h8300*-*-*)
 875     noconfigdirs="$noconfigdirs target-libgloss"
 876     ;;
 877   h8500-*-*)
 878     noconfigdirs="$noconfigdirs target-libgloss"
 879     ;;
 880   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 881     ;;
 882   hppa*64*-*-linux*)
 883     ;;
 884   hppa*-*-linux*)
 885     ;;
 886   hppa*-*-*elf* | \
 887   hppa*-*-lites* | \
 888   hppa*-*-openbsd* | \
 889   hppa*64*-*-*)
 890     ;;
 891   hppa*-hp-hpux11*)
 892     noconfigdirs="$noconfigdirs ld"
 893     ;;
 894   hppa*-*-pro*)
 895     ;;
 896   hppa*-*-*)
 897     noconfigdirs="$noconfigdirs ld"
 898     ;;
 899   i960-*-*)
 900     noconfigdirs="$noconfigdirs gdb"
 901     ;;
 902   ia64*-*-elf*)
 903     # No gdb support yet.
 904     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 905     ;;
 906   ia64*-**-hpux*)
 907     # No ld support yet.
 908     noconfigdirs="$noconfigdirs libgui itcl ld"
 909     ;;
 910   ia64*-*-*vms*)
 911     # No gdb or ld support yet.
 912     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
 913     ;;
 914   i[[3456789]]86-w64-mingw*)
 915     ;;
 916   i[[3456789]]86-*-mingw*)
 917     target_configdirs="$target_configdirs target-winsup"
 918     ;;
 919   *-*-cygwin*)
 920     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 921     noconfigdirs="$noconfigdirs target-libgloss"
 922     # always build newlib if winsup directory is present.
 923     if test -d "$srcdir/winsup/cygwin"; then
 924       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 925     elif test -d "$srcdir/newlib"; then
 926       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 927     fi
 928     ;;
 929   i[[3456789]]86-*-pe)
 930     noconfigdirs="$noconfigdirs target-libgloss"
 931     ;;
 932   i[[3456789]]86-*-sco3.2v5*)
 933     # The linker does not yet know about weak symbols in COFF,
 934     # and is not configured to handle mixed ELF and COFF.
 935     noconfigdirs="$noconfigdirs ld target-libgloss"
 936     ;;
 937   i[[3456789]]86-*-sco*)
 938     noconfigdirs="$noconfigdirs gprof target-libgloss"
 939     ;;
 940   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 941     noconfigdirs="$noconfigdirs target-libgloss"
 942     ;;
 943   i[[3456789]]86-*-sysv4*)
 944     noconfigdirs="$noconfigdirs target-libgloss"
 945     ;;
 946   i[[3456789]]86-*-beos*)
 947     noconfigdirs="$noconfigdirs gdb"
 948     ;;
 949   i[[3456789]]86-*-rdos*)
 950     noconfigdirs="$noconfigdirs gdb"
 951     ;;
 952   mmix-*-*)
 953     noconfigdirs="$noconfigdirs gdb"
 954     ;;
 955   mt-*-*)
 956     noconfigdirs="$noconfigdirs sim"
 957     ;;
 958   powerpc-*-aix*)
 959     # copied from rs6000-*-* entry
 960     noconfigdirs="$noconfigdirs gprof"
 961     ;;
 962   powerpc*-*-winnt* | powerpc*-*-pe*)
 963     target_configdirs="$target_configdirs target-winsup"
 964     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 965     # always build newlib.
 966     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 967     ;;
 968     # This is temporary until we can link against shared libraries
 969   powerpcle-*-solaris*)
 970     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
 971     ;;
 972   powerpc-*-beos*)
 973     noconfigdirs="$noconfigdirs gdb"
 974     ;;
 975   rs6000-*-lynxos*)
 976     noconfigdirs="$noconfigdirs gprof"
 977     ;;
 978   rs6000-*-aix*)
 979     noconfigdirs="$noconfigdirs gprof"
 980     ;;
 981   rs6000-*-*)
 982     noconfigdirs="$noconfigdirs gprof"
 983     ;;
 984   m68k-apollo-*)
 985     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
 986     ;;
 987   microblaze*)
 988     noconfigdirs="$noconfigdirs gprof"
 989     ;;
 990   mips*-sde-elf*)
 991     if test x$with_newlib = xyes; then
 992       noconfigdirs="$noconfigdirs gprof"
 993     fi
 994     ;;
 995   mips*-*-irix5*)
 996     noconfigdirs="$noconfigdirs gprof target-libgloss"
 997     ;;
 998   mips*-*-irix6*)
 999     noconfigdirs="$noconfigdirs gprof target-libgloss"
1000     ;;
1001   mips*-*-bsd*)
1002     noconfigdirs="$noconfigdirs gprof target-libgloss"
1003     ;;
1004   mips*-*-linux*)
1005     ;;
1006   mips*-*-*)
1007     noconfigdirs="$noconfigdirs gprof"
1008     ;;
1009   sh-*-* | sh64-*-*)
1010     case "${target}" in
1011       sh*-*-elf)
1012          ;;
1013       *)
1014          noconfigdirs="$noconfigdirs target-libgloss" ;;
1015     esac
1016     ;;
1017   sparc-*-sunos4*)
1018     if test x${is_cross_compiler} = xno ; then
1019            use_gnu_ld=no
1020     fi
1021     ;;
1022   tic6x-*-*)
1023     noconfigdirs="$noconfigdirs gdb sim"
1024     ;;
1025   tilepro-*-* | tilegx-*-*)
1026     noconfigdirs="$noconfigdirs sim"
1027     ;;
1028   v810-*-*)
1029     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1030     ;;
1031   vax-*-*)
1032     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1033     ;;
1034 esac
1035
1036 # If we aren't building newlib, then don't build libgloss, since libgloss
1037 # depends upon some newlib header files.
1038 case "${noconfigdirs}" in
1039   *target-libgloss*) ;;
1040   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1041 esac
1042
1043 # Work in distributions that contain no compiler tools, like Autoconf.
1044 host_makefile_frag=/dev/null
1045 if test -d ${srcdir}/config ; then
1046 case "${host}" in
1047   i[[3456789]]86-*-msdosdjgpp*)
1048     host_makefile_frag="config/mh-djgpp"
1049     ;;
1050   *-cygwin*)
1051     ACX_CHECK_CYGWIN_CAT_WORKS
1052     host_makefile_frag="config/mh-cygwin"
1053     ;;
1054   *-mingw*)
1055     host_makefile_frag="config/mh-mingw"
1056     ;;
1057   *-interix*)
1058     host_makefile_frag="config/mh-interix"
1059     ;;
1060   hppa*-hp-hpux10*)
1061     host_makefile_frag="config/mh-pa-hpux10"
1062     ;;
1063   hppa*-hp-hpux*)
1064     host_makefile_frag="config/mh-pa"
1065     ;;
1066   hppa*-*)
1067     host_makefile_frag="config/mh-pa"
1068     ;;
1069   *-*-darwin*)
1070     host_makefile_frag="config/mh-darwin"
1071     ;;
1072   powerpc-*-aix*)
1073     host_makefile_frag="config/mh-ppc-aix"
1074     ;;
1075   rs6000-*-aix*)
1076     host_makefile_frag="config/mh-ppc-aix"
1077     ;;
1078 esac
1079 fi
1080
1081 if test "${build}" != "${host}" ; then
1082   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1083   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1084   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1085   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1086   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1087   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1088   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1089   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1090   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1091   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1092   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1093   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1094   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1095 else
1096   AR_FOR_BUILD="\$(AR)"
1097   AS_FOR_BUILD="\$(AS)"
1098   CC_FOR_BUILD="\$(CC)"
1099   CXX_FOR_BUILD="\$(CXX)"
1100   GCJ_FOR_BUILD="\$(GCJ)"
1101   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1102   GOC_FOR_BUILD="\$(GOC)"
1103   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1104   LD_FOR_BUILD="\$(LD)"
1105   NM_FOR_BUILD="\$(NM)"
1106   RANLIB_FOR_BUILD="\$(RANLIB)"
1107   WINDRES_FOR_BUILD="\$(WINDRES)"
1108   WINDMC_FOR_BUILD="\$(WINDMC)"
1109 fi
1110
1111 AC_PROG_CC
1112 AC_PROG_CXX
1113
1114 # We must set the default linker to the linker used by gcc for the correct
1115 # operation of libtool.  If LD is not defined and we are using gcc, try to
1116 # set the LD default to the ld used by gcc.
1117 if test -z "$LD"; then
1118   if test "$GCC" = yes; then
1119     case $build in
1120     *-*-mingw*)
1121       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1122     *)
1123       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1124     esac
1125     case $gcc_prog_ld in
1126     # Accept absolute paths.
1127     [[\\/]* | [A-Za-z]:[\\/]*)]
1128       LD="$gcc_prog_ld" ;;
1129     esac
1130   fi
1131 fi
1132
1133 ACX_PROG_GNAT
1134 ACX_PROG_CMP_IGNORE_INITIAL
1135
1136 # See if we are building gcc with C++.
1137 AC_ARG_ENABLE(build-with-cxx,
1138 [AS_HELP_STRING([--enable-build-with-cxx],
1139                 [build with C++ compiler instead of C compiler])],
1140 ENABLE_BUILD_WITH_CXX=$enableval,
1141 ENABLE_BUILD_WITH_CXX=no)
1142
1143 # Used for setting $lt_cv_objdir
1144 _LT_CHECK_OBJDIR
1145
1146 # Check for GMP, MPFR and MPC
1147 gmplibs="-lmpc -lmpfr -lgmp"
1148 gmpinc=
1149 have_gmp=no
1150
1151 # Specify a location for mpc
1152 # check for this first so it ends up on the link line before mpfr.
1153 AC_ARG_WITH(mpc,
1154 [AS_HELP_STRING([--with-mpc=PATH],
1155                 [specify prefix directory for installed MPC package.
1156                  Equivalent to --with-mpc-include=PATH/include
1157                  plus --with-mpc-lib=PATH/lib])])
1158 AC_ARG_WITH(mpc-include,
1159 [AS_HELP_STRING([--with-mpc-include=PATH],
1160                 [specify directory for installed MPC include files])])
1161 AC_ARG_WITH(mpc-lib,
1162 [AS_HELP_STRING([--with-mpc-lib=PATH],
1163                 [specify directory for the installed MPC library])])
1164
1165 if test "x$with_mpc" != x; then
1166   gmplibs="-L$with_mpc/lib $gmplibs"
1167   gmpinc="-I$with_mpc/include $gmpinc"
1168 fi
1169 if test "x$with_mpc_include" != x; then
1170   gmpinc="-I$with_mpc_include $gmpinc"
1171 fi
1172 if test "x$with_mpc_lib" != x; then
1173   gmplibs="-L$with_mpc_lib $gmplibs"
1174 fi
1175 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1176   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1177   gmpinc='-I$$s/mpc/src '"$gmpinc"
1178   # Do not test the mpc version.  Assume that it is sufficient, since
1179   # it is in the source tree, and the library has not been built yet
1180   # but it would be included on the link line in the version check below
1181   # hence making the test fail.
1182   have_gmp=yes
1183 fi
1184
1185 # Specify a location for mpfr
1186 # check for this first so it ends up on the link line before gmp.
1187 AC_ARG_WITH(mpfr-dir,
1188 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1189 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1190 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1191
1192 AC_ARG_WITH(mpfr,
1193 [AS_HELP_STRING([--with-mpfr=PATH],
1194                 [specify prefix directory for installed MPFR package.
1195                  Equivalent to --with-mpfr-include=PATH/include
1196                  plus --with-mpfr-lib=PATH/lib])])
1197 AC_ARG_WITH(mpfr-include,
1198 [AS_HELP_STRING([--with-mpfr-include=PATH],
1199                 [specify directory for installed MPFR include files])])
1200 AC_ARG_WITH(mpfr-lib,
1201 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1202                 [specify directory for the installed MPFR library])])
1203
1204 if test "x$with_mpfr" != x; then
1205   gmplibs="-L$with_mpfr/lib $gmplibs"
1206   gmpinc="-I$with_mpfr/include $gmpinc"
1207 fi
1208 if test "x$with_mpfr_include" != x; then
1209   gmpinc="-I$with_mpfr_include $gmpinc"
1210 fi
1211 if test "x$with_mpfr_lib" != x; then
1212   gmplibs="-L$with_mpfr_lib $gmplibs"
1213 fi
1214 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1215   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1216   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1217   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1218   # Do not test the mpfr version.  Assume that it is sufficient, since
1219   # it is in the source tree, and the library has not been built yet
1220   # but it would be included on the link line in the version check below
1221   # hence making the test fail.
1222   have_gmp=yes
1223 fi
1224
1225 # Specify a location for gmp
1226 AC_ARG_WITH(gmp-dir,
1227 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1228 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1229 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1230
1231 AC_ARG_WITH(gmp,
1232 [AS_HELP_STRING([--with-gmp=PATH],
1233                 [specify prefix directory for the installed GMP package.
1234                  Equivalent to --with-gmp-include=PATH/include
1235                  plus --with-gmp-lib=PATH/lib])])
1236 AC_ARG_WITH(gmp-include,
1237 [AS_HELP_STRING([--with-gmp-include=PATH],
1238                 [specify directory for installed GMP include files])])
1239 AC_ARG_WITH(gmp-lib,
1240 [AS_HELP_STRING([--with-gmp-lib=PATH],
1241                 [specify directory for the installed GMP library])])
1242
1243
1244 if test "x$with_gmp" != x; then
1245   gmplibs="-L$with_gmp/lib $gmplibs"
1246   gmpinc="-I$with_gmp/include $gmpinc"
1247 fi
1248 if test "x$with_gmp_include" != x; then
1249   gmpinc="-I$with_gmp_include $gmpinc"
1250 fi
1251 if test "x$with_gmp_lib" != x; then
1252   gmplibs="-L$with_gmp_lib $gmplibs"
1253 fi
1254 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1255   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1256   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1257   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1258   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1259   # Do not test the gmp version.  Assume that it is sufficient, since
1260   # it is in the source tree, and the library has not been built yet
1261   # but it would be included on the link line in the version check below
1262   # hence making the test fail.
1263   have_gmp=yes
1264 fi
1265
1266 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1267   have_gmp=yes
1268   saved_CFLAGS="$CFLAGS"
1269   CFLAGS="$CFLAGS $gmpinc"
1270   # Check for the recommended and required versions of GMP.
1271   AC_MSG_CHECKING([for the correct version of gmp.h])
1272   AC_TRY_COMPILE([#include "gmp.h"],[
1273   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1274   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1275   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1276   choke me
1277   #endif
1278   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1279   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1280   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1281   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1282   choke me
1283   #endif
1284   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1285    [AC_MSG_RESULT([no]); have_gmp=no])
1286
1287   # If we have GMP, check the MPFR version.
1288   if test x"$have_gmp" = xyes; then
1289     # Check for the recommended and required versions of MPFR.
1290     AC_MSG_CHECKING([for the correct version of mpfr.h])
1291     AC_TRY_COMPILE([#include <gmp.h>
1292     #include <mpfr.h>],[
1293     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1294     choke me
1295     #endif
1296     ], [AC_TRY_COMPILE([#include <gmp.h>
1297     #include <mpfr.h>],[
1298     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1299     choke me
1300     #endif
1301     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1302      [AC_MSG_RESULT([no]); have_gmp=no])
1303   fi
1304
1305   # Check for the MPC header version.
1306   if test x"$have_gmp" = xyes ; then
1307     # Check for the recommended and required versions of MPC.
1308     AC_MSG_CHECKING([for the correct version of mpc.h])
1309     AC_TRY_COMPILE([#include <mpc.h>],[
1310     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1311     choke me
1312     #endif
1313     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1314     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1315     choke me
1316     #endif
1317     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1318      [AC_MSG_RESULT([no]); have_gmp=no])
1319   fi
1320
1321   # Now check the MPFR library.
1322   if test x"$have_gmp" = xyes; then
1323     saved_LIBS="$LIBS"
1324     LIBS="$LIBS $gmplibs"
1325     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1326     AC_TRY_LINK([#include <mpc.h>],[
1327     mpfr_t n;
1328     mpfr_t x;
1329     mpc_t c;
1330     int t;
1331     mpfr_init (n);
1332     mpfr_init (x);
1333     mpfr_atan2 (n, n, x, GMP_RNDN);
1334     mpfr_erfc (n, x, GMP_RNDN);
1335     mpfr_subnormalize (x, t, GMP_RNDN);
1336     mpfr_clear(n);
1337     mpfr_clear(x);
1338     mpc_init2 (c, 53);
1339     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1340     mpc_cosh (c, c, MPC_RNDNN);
1341     mpc_pow (c, c, c, MPC_RNDNN);
1342     mpc_acosh (c, c, MPC_RNDNN);
1343     mpc_clear (c);
1344     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1345     LIBS="$saved_LIBS"
1346   fi
1347
1348   CFLAGS="$saved_CFLAGS"
1349
1350 # The library versions listed in the error message below should match
1351 # the HARD-minimums enforced above.
1352   if test x$have_gmp != xyes; then
1353     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1354 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1355 their locations.  Source code for these libraries can be found at
1356 their respective hosting sites as well as at
1357 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1358 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1359 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1360 make sure that you have installed both the libraries and the header
1361 files.  They may be located in separate packages.])
1362   fi
1363 fi
1364
1365 # Flags needed for both GMP, MPFR and/or MPC.
1366 AC_SUBST(gmplibs)
1367 AC_SUBST(gmpinc)
1368 AC_SUBST(extra_mpfr_configure_flags)
1369 AC_SUBST(extra_mpc_gmp_configure_flags)
1370 AC_SUBST(extra_mpc_mpfr_configure_flags)
1371
1372 # Allow host libstdc++ to be specified for static linking with PPL.
1373 AC_ARG_WITH(host-libstdcxx,
1374 [AS_HELP_STRING([--with-host-libstdcxx=L],
1375                 [use linker arguments L to link with libstdc++
1376                  when linking with PPL])])
1377
1378 case $with_host_libstdcxx in
1379   no|yes)
1380     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1381     ;;
1382 esac
1383
1384 # Linker flags to use for stage1 or when not boostrapping.
1385 AC_ARG_WITH(stage1-ldflags,
1386 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1387 [if test "$withval" = "no" -o "$withval" = "yes"; then
1388    stage1_ldflags=
1389  else
1390    stage1_ldflags=$withval
1391  fi],
1392 [stage1_ldflags=])
1393 AC_SUBST(stage1_ldflags)
1394
1395 # Libraries to use for stage1 or when not bootstrapping.
1396 AC_ARG_WITH(stage1-libs,
1397 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1398 [if test "$withval" = "no" -o "$withval" = "yes"; then
1399    stage1_libs=
1400  else
1401    stage1_libs=$withval
1402  fi],
1403 [stage1_libs=$with_host_libstdcxx])
1404 AC_SUBST(stage1_libs)
1405
1406 # Libraries to use for stage2 and later builds.  This defaults to the
1407 # argument passed to --with-host-libstdcxx.
1408 AC_ARG_WITH(boot-libs,
1409 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1410 [if test "$withval" = "no" -o "$withval" = "yes"; then
1411    poststage1_libs=
1412  else
1413    poststage1_libs=$withval
1414  fi],
1415 [poststage1_libs=$with_host_libstdcxx])
1416 AC_SUBST(poststage1_libs)
1417
1418 # Linker flags to use for stage2 and later builds.
1419 AC_ARG_WITH(boot-ldflags,
1420 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1421                 [linker flags for stage2 and later])],
1422 [if test "$withval" = "no" -o "$withval" = "yes"; then
1423    poststage1_ldflags=
1424  else
1425    poststage1_ldflags=$withval
1426  fi],
1427 [poststage1_ldflags=
1428  # In stages 2 and 3, default to linking libstdc++ and libgcc
1429  # statically.  But if the user explicitly specified the libraries to
1430  # use, trust that they are doing what they want.
1431  if test "$poststage1_libs" = ""; then
1432    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1433  fi])
1434 AC_SUBST(poststage1_ldflags)
1435
1436 # Check for PPL
1437 ppllibs=
1438 pplinc=
1439 pwllib=
1440
1441 AC_ARG_WITH(ppl,
1442 [AS_HELP_STRING([--with-ppl=PATH],
1443                 [specify prefix directory for the installed PPL package.
1444                  Equivalent to --with-ppl-include=PATH/include
1445                  plus --with-ppl-lib=PATH/lib])])
1446 AC_ARG_WITH(ppl-include,
1447 [AS_HELP_STRING([--with-ppl-include=PATH],
1448                 [specify directory for installed PPL include files])])
1449 AC_ARG_WITH(ppl-lib,
1450 [AS_HELP_STRING([--with-ppl-lib=PATH],
1451                 [specify directory for the installed PPL library])])
1452
1453 AC_ARG_ENABLE(ppl-version-check,
1454 [AS_HELP_STRING([--disable-ppl-version-check],
1455                 [disable check for PPL version])])
1456
1457 case $with_ppl in
1458   yes | no | "")
1459     ;;
1460   *)
1461     ppllibs="-L$with_ppl/lib"
1462     pplinc="-I$with_ppl/include $pplinc"
1463     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1464       with_ppl=yes
1465     else
1466       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1467     fi
1468     ;;
1469 esac
1470
1471 if test x"$with_ppl_include" != x; then
1472   pplinc="-I$with_ppl_include $pplinc"
1473   with_ppl=yes
1474 fi
1475
1476 if test "x$with_ppl_lib" != x; then
1477   ppllibs="-L$with_ppl_lib"
1478   with_ppl=yes
1479 fi
1480
1481 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1482   if test x"$enable_watchdog" = xyes; then
1483     pwllib="-lpwl"
1484   fi
1485   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1486   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1487   enable_ppl_version_check=no
1488   with_ppl=yes
1489 fi
1490
1491 if test "x$with_ppl" != xno; then
1492   if test "x$pwllib" = x; then
1493     saved_LIBS="$LIBS"
1494     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1495     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1496     LIBS="$saved_LIBS"
1497   fi
1498
1499   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1500
1501   if test "$enable_ppl_version_check" != no; then
1502     saved_CFLAGS="$CFLAGS"
1503     CFLAGS="$CFLAGS $pplinc $gmpinc"
1504     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1505     AC_TRY_COMPILE([#include "ppl_c.h"],[
1506     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1507     choke me
1508     #endif
1509     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1510     CFLAGS="$saved_CFLAGS"
1511   fi
1512 fi
1513
1514 # Flags needed for PPL
1515 AC_SUBST(ppllibs)
1516 AC_SUBST(pplinc)
1517
1518
1519 # Check for CLOOG
1520
1521 dnl Provide configure switches and initialize clooginc & clooglibs
1522 dnl with user input.
1523 CLOOG_INIT_FLAGS
1524 if test "x$with_ppl" = "xno"; then
1525   dnl Only execute fail-action, if CLooG has been requested.
1526   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1527   if test "${graphite_requested}" = yes; then
1528     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1529   fi
1530   with_cloog=no
1531 fi
1532 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1533   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1534   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1535   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1536 fi
1537 if test "x$with_cloog" != "xno"; then
1538   dnl The minimal version of CLooG required for Graphite.
1539   dnl
1540   dnl If we use CLooG-Legacy, the provided version information is
1541   dnl ignored.
1542   CLOOG_CHECK_VERSION(0,16,1)
1543
1544   dnl Only execute fail-action, if CLooG has been requested.
1545   CLOOG_IF_FAILED([
1546     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1547 fi
1548
1549 # Check for LTO support.
1550 AC_ARG_ENABLE(lto,
1551 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1552 enable_lto=$enableval,
1553 enable_lto=yes; default_enable_lto=yes)
1554
1555 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1556   build_lto_plugin=yes
1557 ],[if test x"$default_enable_lto" = x"yes" ; then
1558     case $target in
1559       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1560       # On other non-ELF platforms, LTO has yet to be validated.
1561       *) enable_lto=no ;;
1562     esac
1563   else
1564   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1565   # It would also be nice to check the binutils support, but we don't
1566   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1567   # warn during gcc/ subconfigure; unless you're bootstrapping with
1568   # -flto it won't be needed until after installation anyway.
1569     case $target in
1570       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1571       *) if test x"$enable_lto" = x"yes"; then
1572         AC_MSG_ERROR([LTO support is not enabled for this target.])
1573         fi
1574       ;;
1575     esac
1576   fi
1577   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1578   # Build it unless LTO was explicitly disabled.
1579   case $target in
1580     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1581     *) ;;
1582   esac
1583 ])
1584
1585
1586 # By default, C is the only stage 1 language.
1587 stage1_languages=,c,
1588
1589 # Target libraries that we bootstrap.
1590 bootstrap_target_libs=,target-libgcc,
1591
1592 # Figure out what language subdirectories are present.
1593 # Look if the user specified --enable-languages="..."; if not, use
1594 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1595 # go away some day.
1596 # NB:  embedded tabs in this IF block -- do not untabify
1597 if test -d ${srcdir}/gcc; then
1598   if test x"${enable_languages+set}" != xset; then
1599     if test x"${LANGUAGES+set}" = xset; then
1600       enable_languages="${LANGUAGES}"
1601         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1602     else
1603       enable_languages=all
1604     fi
1605   else
1606     if test x"${enable_languages}" = x ||
1607        test x"${enable_languages}" = xyes;
1608        then
1609       echo configure.in: --enable-languages needs at least one language argument 1>&2
1610       exit 1
1611     fi
1612   fi
1613   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1614
1615   # 'f95' is the old name for the 'fortran' language. We issue a warning
1616   # and make the substitution.
1617   case ,${enable_languages}, in
1618     *,f95,*)
1619       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1620       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1621       ;;
1622   esac
1623
1624   # First scan to see if an enabled language requires some other language.
1625   # We assume that a given config-lang.in will list all the language
1626   # front ends it requires, even if some are required indirectly.
1627   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1628     case ${lang_frag} in
1629       ..) ;;
1630       # The odd quoting in the next line works around
1631       # an apparent bug in bash 1.12 on linux.
1632       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1633       *)
1634         # From the config-lang.in, get $language, $lang_requires, and
1635         # $lang_requires_boot_languages.
1636         language=
1637         lang_requires=
1638         lang_requires_boot_languages=
1639         . ${lang_frag}
1640         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1641           case ,${enable_languages}, in
1642             *,$other,*) ;;
1643             *,all,*) ;;
1644             *,$language,*)
1645               echo " \`$other' language required by \`$language'; enabling" 1>&2
1646               enable_languages="${enable_languages},${other}"
1647               ;;
1648           esac
1649         done
1650         for other in ${lang_requires_boot_languages} ; do
1651           if test "$other" != "c"; then
1652             case ,${enable_stage1_languages}, in
1653               *,$other,*) ;;
1654               *,all,*) ;;
1655               *)
1656                 case ,${enable_languages}, in
1657                   *,$language,*)
1658                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1659                     enable_stage1_languages="$enable_stage1_languages,${other}"
1660                     ;;
1661                 esac
1662                 ;;
1663             esac
1664           fi
1665         done
1666         ;;
1667     esac
1668   done
1669
1670   new_enable_languages=,c,
1671
1672   # If LTO is enabled, add the LTO front end.
1673   extra_host_libiberty_configure_flags=
1674   if test "$enable_lto" = "yes" ; then
1675     case ,${enable_languages}, in
1676       *,lto,*) ;;
1677       *) enable_languages="${enable_languages},lto" ;;
1678     esac
1679     if test "${build_lto_plugin}" = "yes" ; then
1680       configdirs="$configdirs lto-plugin"
1681       extra_host_libiberty_configure_flags=--enable-shared
1682     fi
1683   fi
1684   AC_SUBST(extra_host_libiberty_configure_flags)
1685
1686   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1687   potential_languages=,c,
1688
1689   enabled_target_libs=
1690   disabled_target_libs=
1691
1692   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1693     case ${lang_frag} in
1694       ..) ;;
1695       # The odd quoting in the next line works around
1696       # an apparent bug in bash 1.12 on linux.
1697       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1698       *)
1699         # From the config-lang.in, get $language, $target_libs,
1700         # $lang_dirs, $boot_language, and $build_by_default
1701         language=
1702         target_libs=
1703         lang_dirs=
1704         subdir_requires=
1705         boot_language=no
1706         build_by_default=yes
1707         . ${lang_frag}
1708         if test x${language} = x; then
1709           echo "${lang_frag} doesn't set \$language." 1>&2
1710           exit 1
1711         fi
1712
1713         if test "$language" = "c++" \
1714            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1715           boot_language=yes
1716         fi
1717
1718         case ,${enable_languages}, in
1719           *,${language},*)
1720             # Language was explicitly selected; include it.
1721             add_this_lang=yes
1722             ;;
1723           *,all,*)
1724             # 'all' was selected, select it if it is a default language
1725             add_this_lang=${build_by_default}
1726             ;;
1727           *)
1728             add_this_lang=no
1729             ;;
1730         esac
1731
1732         # Disable languages that need other directories if these aren't available.
1733         for i in $subdir_requires; do
1734           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1735           case ,${enable_languages}, in
1736             *,${language},*)
1737               # Specifically requested language; tell them.
1738               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1739               ;;
1740             *)
1741               # Silently disable.
1742               add_this_lang=unsupported
1743               ;;
1744           esac
1745         done
1746
1747         # Disable Ada if no preexisting GNAT is available.
1748         case ,${enable_languages},:${language}:${have_gnat} in
1749           *,${language},*:ada:no)
1750             # Specifically requested language; tell them.
1751             AC_MSG_ERROR([GNAT is required to build $language])
1752             ;;
1753           *:ada:no)
1754             # Silently disable.
1755             add_this_lang=unsupported
1756             ;;
1757         esac
1758
1759         # Disable a language that is unsupported by the target.
1760         case " $unsupported_languages " in
1761           *" $language "*)
1762             add_this_lang=unsupported
1763             ;;
1764         esac
1765
1766         case $add_this_lang in
1767           unsupported)
1768             # Remove language-dependent dirs.
1769             disabled_target_libs="$disabled_target_libs $target_libs"
1770             noconfigdirs="$noconfigdirs $lang_dirs"
1771             ;;
1772           no)
1773             # Remove language-dependent dirs; still show language as supported.
1774             disabled_target_libs="$disabled_target_libs $target_libs"
1775             noconfigdirs="$noconfigdirs $lang_dirs"
1776             potential_languages="${potential_languages}${language},"
1777             ;;
1778           yes)
1779             new_enable_languages="${new_enable_languages}${language},"
1780             potential_languages="${potential_languages}${language},"
1781             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1782             enabled_target_libs="$enabled_target_libs $target_libs"
1783             case "${boot_language}:,$enable_stage1_languages," in
1784               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1785                 # Add to (comma-separated) list of stage 1 languages.
1786                 case ",$stage1_languages," in
1787                   *,$language,* | ,yes, | ,all,) ;;
1788                   *) stage1_languages="${stage1_languages}${language}," ;;
1789                 esac
1790                 # We need to bootstrap any supporting libraries.
1791                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1792                 ;;
1793             esac
1794             ;;
1795         esac
1796         ;;
1797     esac
1798   done
1799
1800   # Add target libraries which are only needed for disabled languages
1801   # to noconfigdirs.
1802   if test -n "$disabled_target_libs"; then
1803     for dir in $disabled_target_libs; do
1804       case " $enabled_target_libs " in
1805       *" ${dir} "*) ;;
1806       *) noconfigdirs="$noconfigdirs $dir" ;;
1807       esac
1808     done
1809   fi
1810
1811   AC_ARG_ENABLE(stage1-languages,
1812   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1813                   [choose additional languages to build during
1814                   stage1.  Mostly useful for compiler development])],
1815   [case ,${enable_stage1_languages}, in
1816     ,no,|,,)
1817       # Set it to something that will have no effect in the loop below
1818       enable_stage1_languages=c ;;
1819     ,yes,)
1820       enable_stage1_languages=`echo $new_enable_languages | \
1821         sed -e "s/^,//" -e "s/,$//" ` ;;
1822     *,all,*)
1823       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1824         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1825   esac
1826
1827   # Add "good" languages from enable_stage1_languages to stage1_languages,
1828   # while "bad" languages go in missing_languages.  Leave no duplicates.
1829   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1830     case $potential_languages in
1831       *,$i,*)
1832         case $stage1_languages in
1833           *,$i,*) ;;
1834           *) stage1_languages="$stage1_languages$i," ;;
1835         esac ;;
1836       *)
1837         case $missing_languages in
1838           *,$i,*) ;;
1839           *) missing_languages="$missing_languages$i," ;;
1840         esac ;;
1841      esac
1842   done])
1843
1844   # Remove leading/trailing commas that were added for simplicity
1845   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1846   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1847   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1848   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1849
1850   if test "x$missing_languages" != x; then
1851     AC_MSG_ERROR([
1852 The following requested languages could not be built: ${missing_languages}
1853 Supported languages are: ${potential_languages}])
1854   fi
1855   if test "x$new_enable_languages" != "x$enable_languages"; then
1856     echo The following languages will be built: ${new_enable_languages}
1857     enable_languages="$new_enable_languages"
1858   fi
1859
1860   AC_SUBST(stage1_languages)
1861   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1862 fi
1863
1864 # Handle --disable-<component> generically.
1865 for dir in $configdirs $build_configdirs $target_configdirs ; do
1866   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1867   varname=`echo $dirname | sed -e s/+/_/g`
1868   if eval test x\${enable_${varname}} "=" xno ; then
1869     noconfigdirs="$noconfigdirs $dir"
1870   fi
1871 done
1872
1873 # Check for Boehm's garbage collector
1874 AC_ARG_ENABLE(objc-gc,
1875 [AS_HELP_STRING([--enable-objc-gc],
1876                 [enable use of Boehm's garbage collector with the
1877                  GNU Objective-C runtime])],
1878 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1879   *,objc,*:*:yes:*target-boehm-gc*)
1880     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1881     ;;
1882 esac])
1883
1884 # Make sure we only build Boehm's garbage collector if required.
1885 case ,${enable_languages},:${enable_objc_gc} in
1886   *,objc,*:yes)
1887     # Keep target-boehm-gc if requested for Objective-C.
1888     ;;
1889   *)
1890     # Otherwise remove target-boehm-gc depending on target-libjava.
1891     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1892       noconfigdirs="$noconfigdirs target-boehm-gc"
1893     fi
1894     ;;
1895 esac
1896
1897 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1898 # $build_configdirs and $target_configdirs.
1899 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1900
1901 notsupp=""
1902 for dir in . $skipdirs $noconfigdirs ; do
1903   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1904   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1905     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1906     if test -r $srcdir/$dirname/configure ; then
1907       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1908         true
1909       else
1910         notsupp="$notsupp $dir"
1911       fi
1912     fi
1913   fi
1914   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1915     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1916     if test -r $srcdir/$dirname/configure ; then
1917       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1918         true
1919       else
1920         notsupp="$notsupp $dir"
1921       fi
1922     fi
1923   fi
1924   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1925     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1926     if test -r $srcdir/$dirname/configure ; then
1927       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1928         true
1929       else
1930         notsupp="$notsupp $dir"
1931       fi
1932     fi
1933   fi
1934 done
1935
1936 # Quietly strip out all directories which aren't configurable in this tree.
1937 # This relies on all configurable subdirectories being autoconfiscated, which
1938 # is now the case.
1939 build_configdirs_all="$build_configdirs"
1940 build_configdirs=
1941 for i in ${build_configdirs_all} ; do
1942   j=`echo $i | sed -e s/build-//g`
1943   if test -f ${srcdir}/$j/configure ; then
1944     build_configdirs="${build_configdirs} $i"
1945   fi
1946 done
1947
1948 configdirs_all="$configdirs"
1949 configdirs=
1950 for i in ${configdirs_all} ; do
1951   if test -f ${srcdir}/$i/configure ; then
1952     configdirs="${configdirs} $i"
1953   fi
1954 done
1955
1956 target_configdirs_all="$target_configdirs"
1957 target_configdirs=
1958 for i in ${target_configdirs_all} ; do
1959   j=`echo $i | sed -e s/target-//g`
1960   if test -f ${srcdir}/$j/configure ; then
1961     target_configdirs="${target_configdirs} $i"
1962   fi
1963 done
1964
1965 # Produce a warning message for the subdirs we can't configure.
1966 # This isn't especially interesting in the Cygnus tree, but in the individual
1967 # FSF releases, it's important to let people know when their machine isn't
1968 # supported by the one or two programs in a package.
1969
1970 if test -n "${notsupp}" && test -z "${norecursion}" ; then
1971   # If $appdirs is non-empty, at least one of those directories must still
1972   # be configured, or we error out.  (E.g., if the gas release supports a
1973   # specified target in some subdirs but not the gas subdir, we shouldn't
1974   # pretend that all is well.)
1975   if test -n "$appdirs" ; then
1976     for dir in $appdirs ; do
1977       if test -r $dir/Makefile.in ; then
1978         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1979           appdirs=""
1980           break
1981         fi
1982         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
1983           appdirs=""
1984           break
1985         fi
1986       fi
1987     done
1988     if test -n "$appdirs" ; then
1989       echo "*** This configuration is not supported by this package." 1>&2
1990       exit 1
1991     fi
1992   fi
1993   # Okay, some application will build, or we don't care to check.  Still
1994   # notify of subdirs not getting built.
1995   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
1996   echo "    ${notsupp}" 1>&2
1997   echo "    (Any other directories should still work fine.)" 1>&2
1998 fi
1999
2000 case "$host" in
2001   *msdosdjgpp*)
2002     enable_gdbtk=no ;;
2003 esac
2004
2005 # To find our prefix, in gcc_cv_tool_prefix.
2006 ACX_TOOL_DIRS
2007
2008 copy_dirs=
2009
2010 AC_ARG_WITH([build-sysroot],
2011   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2012                   [use sysroot as the system root during the build])],
2013   [if test x"$withval" != x ; then
2014      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2015    fi],
2016   [SYSROOT_CFLAGS_FOR_TARGET=])
2017 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2018
2019 AC_ARG_WITH([debug-prefix-map],
2020   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2021                   [map A to B, C to D ... in debug information])],
2022   [if test x"$withval" != x; then
2023      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2024      for debug_map in $withval; do
2025        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2026      done
2027    fi],
2028   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2029 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2030
2031 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2032 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2033 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2034 # We want to ensure that TARGET libraries (which we know are built with
2035 # gcc) are built with "-O2 -g", so include those options when setting
2036 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2037 if test "x$CFLAGS_FOR_TARGET" = x; then
2038   CFLAGS_FOR_TARGET=$CFLAGS
2039   case " $CFLAGS " in
2040     *" -O2 "*) ;;
2041     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2042   esac
2043   case " $CFLAGS " in
2044     *" -g "* | *" -g3 "*) ;;
2045     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2046   esac
2047 fi
2048 AC_SUBST(CFLAGS_FOR_TARGET)
2049
2050 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2051   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2052   case " $CXXFLAGS " in
2053     *" -O2 "*) ;;
2054     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2055   esac
2056   case " $CXXFLAGS " in
2057     *" -g "* | *" -g3 "*) ;;
2058     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2059   esac
2060 fi
2061 AC_SUBST(CXXFLAGS_FOR_TARGET)
2062
2063 AC_SUBST(LDFLAGS_FOR_TARGET)
2064
2065 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2066 # the named directory are copied to $(tooldir)/sys-include.
2067 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2068   if test x${is_cross_compiler} = xno ; then
2069     echo 1>&2 '***' --with-headers is only supported when cross compiling
2070     exit 1
2071   fi
2072   if test x"${with_headers}" != xyes ; then
2073     x=${gcc_cv_tool_prefix}
2074     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2075   fi
2076 fi
2077
2078 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2079 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2080 # are permitted.
2081 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2082   if test x${is_cross_compiler} = xno ; then
2083     echo 1>&2 '***' --with-libs is only supported when cross compiling
2084     exit 1
2085   fi
2086   if test x"${with_libs}" != xyes ; then
2087     # Copy the libraries in reverse order, so that files in the first named
2088     # library override files in subsequent libraries.
2089     x=${gcc_cv_tool_prefix}
2090     for l in ${with_libs}; do
2091       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2092     done
2093   fi
2094 fi
2095
2096 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2097 #
2098 # This is done by determining whether or not the appropriate directory
2099 # is available, and by checking whether or not specific configurations
2100 # have requested that this magic not happen.
2101 #
2102 # The command line options always override the explicit settings in
2103 # configure.in, and the settings in configure.in override this magic.
2104 #
2105 # If the default for a toolchain is to use GNU as and ld, and you don't
2106 # want to do that, then you should use the --without-gnu-as and
2107 # --without-gnu-ld options for the configure script.  Similarly, if
2108 # the default is to use the included zlib and you don't want to do that,
2109 # you should use the --with-system-zlib option for the configure script.
2110
2111 if test x${use_gnu_as} = x &&
2112    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2113   with_gnu_as=yes
2114   extra_host_args="$extra_host_args --with-gnu-as"
2115 fi
2116
2117 if test x${use_gnu_ld} = x &&
2118    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2119   with_gnu_ld=yes
2120   extra_host_args="$extra_host_args --with-gnu-ld"
2121 fi
2122
2123 if test x${use_included_zlib} = x &&
2124    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2125   :
2126 else
2127   with_system_zlib=yes
2128   extra_host_args="$extra_host_args --with-system-zlib"
2129 fi
2130
2131 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2132 # can detect this case.
2133
2134 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2135   with_newlib=yes
2136   extra_host_args="$extra_host_args --with-newlib"
2137 fi
2138
2139 # Handle ${copy_dirs}
2140 set fnord ${copy_dirs}
2141 shift
2142 while test $# != 0 ; do
2143   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2144     :
2145   else
2146     echo Copying $1 to $2
2147
2148     # Use the install script to create the directory and all required
2149     # parent directories.
2150     if test -d $2 ; then
2151       :
2152     else
2153       echo >config.temp
2154       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2155     fi
2156
2157     # Copy the directory, assuming we have tar.
2158     # FIXME: Should we use B in the second tar?  Not all systems support it.
2159     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2160
2161     # It is the responsibility of the user to correctly adjust all
2162     # symlinks.  If somebody can figure out how to handle them correctly
2163     # here, feel free to add the code.
2164
2165     echo $1 > $2/COPIED
2166   fi
2167   shift; shift
2168 done
2169
2170 # Determine a target-dependent exec_prefix that the installed
2171 # gcc will search in.  Keep this list sorted by triplet, with
2172 # the *-*-osname triplets last.
2173 md_exec_prefix=
2174 case "${target}" in
2175   i[[34567]]86-pc-msdosdjgpp*)
2176     md_exec_prefix=/dev/env/DJDIR/bin
2177     ;;
2178   *-*-hpux* | \
2179   *-*-nto-qnx* | \
2180   *-*-solaris2*)
2181     md_exec_prefix=/usr/ccs/bin
2182     ;;
2183 esac
2184
2185 extra_arflags_for_target=
2186 extra_nmflags_for_target=
2187 extra_ranlibflags_for_target=
2188 target_makefile_frag=/dev/null
2189 case "${target}" in
2190   spu-*-*)
2191     target_makefile_frag="config/mt-spu"
2192     ;;
2193   mips*-sde-elf*)
2194     target_makefile_frag="config/mt-sde"
2195     ;;
2196   mipsisa*-*-elfoabi*)
2197     target_makefile_frag="config/mt-mips-elfoabi"
2198     ;;
2199   mips*-*-*linux* | mips*-*-gnu*)
2200     target_makefile_frag="config/mt-mips-gnu"
2201     ;;
2202   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2203     target_makefile_frag="config/mt-gnu"
2204     ;;
2205   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2206     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2207     # commands to handle both 32-bit and 64-bit objects.  These flags are
2208     # harmless if we're using GNU nm or ar.
2209     extra_arflags_for_target=" -X32_64"
2210     extra_nmflags_for_target=" -B -X32_64"
2211     ;;
2212   *-*-darwin[[3-9]]*)
2213     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2214     extra_ranlibflags_for_target=" -c"
2215     ;;
2216 esac
2217
2218 alphaieee_frag=/dev/null
2219 case $target in
2220   alpha*-*-*)
2221     # This just makes sure to use the -mieee option to build target libs.
2222     # This should probably be set individually by each library.
2223     alphaieee_frag="config/mt-alphaieee"
2224     ;;
2225 esac
2226
2227 # If --enable-target-optspace always use -Os instead of -O2 to build
2228 # the target libraries, similarly if it is not specified, use -Os
2229 # on selected platforms.
2230 ospace_frag=/dev/null
2231 case "${enable_target_optspace}:${target}" in
2232   yes:*)
2233     ospace_frag="config/mt-ospace"
2234     ;;
2235   :d30v-*)
2236     ospace_frag="config/mt-d30v"
2237     ;;
2238   :m32r-* | :d10v-* | :fr30-*)
2239     ospace_frag="config/mt-ospace"
2240     ;;
2241   no:* | :*)
2242     ;;
2243   *)
2244     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2245     ;;
2246 esac
2247
2248 # Default to using --with-stabs for certain targets.
2249 if test x${with_stabs} = x ; then
2250   case "${target}" in
2251   mips*-*-irix[[56]]*)
2252     ;;
2253   mips*-*-* | alpha*-*-osf*)
2254     with_stabs=yes;
2255     extra_host_args="${extra_host_args} --with-stabs"
2256     ;;
2257   esac
2258 fi
2259
2260 # Some systems (e.g., one of the i386-aix systems the gas testers are
2261 # using) don't handle "\$" correctly, so don't use it here.
2262 tooldir='${exec_prefix}'/${target_noncanonical}
2263 build_tooldir=${tooldir}
2264
2265 # Create a .gdbinit file which runs the one in srcdir
2266 # and tells GDB to look there for source files.
2267
2268 if test -r ${srcdir}/.gdbinit ; then
2269   case ${srcdir} in
2270     .) ;;
2271     *) cat > ./.gdbinit <<EOF
2272 # ${NO_EDIT}
2273 dir ${srcdir}
2274 dir .
2275 source ${srcdir}/.gdbinit
2276 EOF
2277     ;;
2278   esac
2279 fi
2280
2281 # Make sure that the compiler is able to generate an executable.  If it
2282 # can't, we are probably in trouble.  We don't care whether we can run the
2283 # executable--we might be using a cross compiler--we only care whether it
2284 # can be created.  At this point the main configure script has set CC.
2285 we_are_ok=no
2286 echo "int main () { return 0; }" > conftest.c
2287 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2288 if test $? = 0 ; then
2289   if test -s conftest || test -s conftest.exe ; then
2290     we_are_ok=yes
2291   fi
2292 fi
2293 case $we_are_ok in
2294   no)
2295     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2296     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2297     rm -f conftest*
2298     exit 1
2299     ;;
2300 esac
2301 rm -f conftest*
2302
2303 # Decide which environment variable is used to find dynamic libraries.
2304 case "${host}" in
2305   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2306   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2307   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2308   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2309 esac
2310
2311 # On systems where the dynamic library environment variable is PATH,
2312 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2313 # built executables to PATH.
2314 if test "$RPATH_ENVVAR" = PATH; then
2315   GCC_SHLIB_SUBDIR=/shlib
2316 else
2317   GCC_SHLIB_SUBDIR=
2318 fi
2319
2320 # Record target_configdirs and the configure arguments for target and
2321 # build configuration in Makefile.
2322 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2323 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2324
2325 # If we are building libgomp, bootstrap it.
2326 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2327   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2328 fi
2329
2330 # Determine whether gdb needs tk/tcl or not.
2331 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2332 # and in that case we want gdb to be built without tk.  Ugh!
2333 # In fact I believe gdb is the *only* package directly dependent on tk,
2334 # so we should be able to put the 'maybe's in unconditionally and
2335 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2336 # 100% sure that that's safe though.
2337
2338 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2339 case "$enable_gdbtk" in
2340   no)
2341     GDB_TK="" ;;
2342   yes)
2343     GDB_TK="${gdb_tk}" ;;
2344   *)
2345     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2346     # distro.  Eventually someone will fix this and move Insight, nee
2347     # gdbtk to a separate directory.
2348     if test -d ${srcdir}/gdb/gdbtk ; then
2349       GDB_TK="${gdb_tk}"
2350     else
2351       GDB_TK=""
2352     fi
2353     ;;
2354 esac
2355 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2356 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2357
2358 # Strip out unwanted targets.
2359
2360 # While at that, we remove Makefiles if we were started for recursive
2361 # configuration, so that the top-level Makefile reconfigures them,
2362 # like we used to do when configure itself was recursive.
2363
2364 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2365 # but now we're fixing up the Makefile ourselves with the additional
2366 # commands passed to AC_CONFIG_FILES.  Use separate variables
2367 # extrasub-{build,host,target} not because there is any reason to split
2368 # the substitutions up that way, but only to remain below the limit of
2369 # 99 commands in a script, for HP-UX sed.
2370 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2371
2372 AC_ARG_ENABLE([bootstrap],
2373 [AS_HELP_STRING([--enable-bootstrap],
2374                 [enable bootstrapping @<:@yes if native build@:>@])],,
2375 enable_bootstrap=default)
2376
2377 # Issue errors and warnings for invalid/strange bootstrap combinations.
2378 case "$configdirs" in
2379   *gcc*) have_compiler=yes ;;
2380   *) have_compiler=no ;;
2381 esac
2382
2383 case "$have_compiler:$host:$target:$enable_bootstrap" in
2384   *:*:*:no) ;;
2385
2386   # Default behavior.  Enable bootstrap if we have a compiler
2387   # and we are in a native configuration.
2388   yes:$build:$build:default)
2389     enable_bootstrap=yes ;;
2390
2391   *:*:*:default)
2392     enable_bootstrap=no ;;
2393
2394   # We have a compiler and we are in a native configuration, bootstrap is ok
2395   yes:$build:$build:yes)
2396     ;;
2397
2398   # Other configurations, but we have a compiler.  Assume the user knows
2399   # what he's doing.
2400   yes:*:*:yes)
2401     AC_MSG_WARN([trying to bootstrap a cross compiler])
2402     ;;
2403
2404   # No compiler: if they passed --enable-bootstrap explicitly, fail
2405   no:*:*:yes)
2406     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2407
2408   # Fail if wrong command line
2409   *)
2410     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2411     ;;
2412 esac
2413
2414 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2415   *,c++,*:yes:yes) ;;
2416   *:yes:yes)
2417     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2418     ;;
2419 esac
2420
2421 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2422   yes:yes:*\ gold\ *:*,c++,*) ;;
2423   yes:yes:*\ gold\ *:*)
2424     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2425     ;;
2426 esac
2427
2428 # Adjust the toplevel makefile according to whether bootstrap was selected.
2429 case $enable_bootstrap in
2430   yes)
2431     bootstrap_suffix=bootstrap
2432     BUILD_CONFIG=bootstrap-debug
2433     ;;
2434   no)
2435     bootstrap_suffix=no-bootstrap
2436     BUILD_CONFIG=
2437     ;;
2438 esac
2439
2440 AC_MSG_CHECKING(for default BUILD_CONFIG)
2441
2442 AC_ARG_WITH([build-config],
2443   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2444                   [use config/NAME.mk build configuration])],
2445   [case $with_build_config in
2446    yes) with_build_config= ;;
2447    no) with_build_config= BUILD_CONFIG= ;;
2448    esac])
2449
2450 if test "x${with_build_config}" != x; then
2451   BUILD_CONFIG=$with_build_config
2452 else
2453   case $BUILD_CONFIG in
2454   bootstrap-debug)
2455     if echo "int f (void) { return 0; }" > conftest.c &&
2456        ${CC} -c conftest.c &&
2457        mv conftest.o conftest.o.g0 &&
2458        ${CC} -c -g conftest.c &&
2459        mv conftest.o conftest.o.g &&
2460        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2461       :
2462     else
2463       BUILD_CONFIG=
2464     fi
2465     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2466     ;;
2467   esac
2468 fi
2469 AC_MSG_RESULT($BUILD_CONFIG)
2470 AC_SUBST(BUILD_CONFIG)
2471
2472 extrasub_build=
2473 for module in ${build_configdirs} ; do
2474   if test -z "${no_recursion}" \
2475      && test -f ${build_subdir}/${module}/Makefile; then
2476     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2477     rm -f ${build_subdir}/${module}/Makefile
2478   fi
2479   extrasub_build="$extrasub_build
2480 /^@if build-$module\$/d
2481 /^@endif build-$module\$/d
2482 /^@if build-$module-$bootstrap_suffix\$/d
2483 /^@endif build-$module-$bootstrap_suffix\$/d"
2484 done
2485 extrasub_host=
2486 for module in ${configdirs} ; do
2487   if test -z "${no_recursion}"; then
2488     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2489       if test -f ${file}; then
2490         echo 1>&2 "*** removing ${file} to force reconfigure"
2491         rm -f ${file}
2492       fi
2493     done
2494   fi
2495   extrasub_host="$extrasub_host
2496 /^@if $module\$/d
2497 /^@endif $module\$/d
2498 /^@if $module-$bootstrap_suffix\$/d
2499 /^@endif $module-$bootstrap_suffix\$/d"
2500 done
2501 extrasub_target=
2502 for module in ${target_configdirs} ; do
2503   if test -z "${no_recursion}" \
2504      && test -f ${target_subdir}/${module}/Makefile; then
2505     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2506     rm -f ${target_subdir}/${module}/Makefile
2507   fi
2508
2509   # We only bootstrap target libraries listed in bootstrap_target_libs.
2510   case $bootstrap_target_libs in
2511     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2512     *) target_bootstrap_suffix=no-bootstrap ;;
2513   esac
2514
2515   extrasub_target="$extrasub_target
2516 /^@if target-$module\$/d
2517 /^@endif target-$module\$/d
2518 /^@if target-$module-$target_bootstrap_suffix\$/d
2519 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2520 done
2521
2522 # Do the final fixup along with target modules.
2523 extrasub_target="$extrasub_target
2524 /^@if /,/^@endif /d"
2525
2526 # Create the serialization dependencies.  This uses a temporary file.
2527
2528 AC_ARG_ENABLE([serial-configure],
2529 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2530                 [force sequential configuration of
2531                  sub-packages for the host, target or build
2532                  machine, or all sub-packages])])
2533
2534 case ${enable_serial_configure} in
2535   yes)
2536     enable_serial_build_configure=yes
2537     enable_serial_host_configure=yes
2538     enable_serial_target_configure=yes
2539     ;;
2540 esac
2541
2542 # These force 'configure's to be done one at a time, to avoid problems
2543 # with contention over a shared config.cache.
2544 rm -f serdep.tmp
2545 echo '# serdep.tmp' > serdep.tmp
2546 olditem=
2547 test "x${enable_serial_build_configure}" = xyes &&
2548 for item in ${build_configdirs} ; do
2549   case ${olditem} in
2550     "") ;;
2551     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2552   esac
2553   olditem=${item}
2554 done
2555 olditem=
2556 test "x${enable_serial_host_configure}" = xyes &&
2557 for item in ${configdirs} ; do
2558   case ${olditem} in
2559     "") ;;
2560     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2561   esac
2562   olditem=${item}
2563 done
2564 olditem=
2565 test "x${enable_serial_target_configure}" = xyes &&
2566 for item in ${target_configdirs} ; do
2567   case ${olditem} in
2568     "") ;;
2569     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2570   esac
2571   olditem=${item}
2572 done
2573 serialization_dependencies=serdep.tmp
2574 AC_SUBST_FILE(serialization_dependencies)
2575
2576 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2577 # target, nonopt, and variable assignments.  These are the ones we
2578 # might not want to pass down to subconfigures.  The exception being
2579 # --cache-file=/dev/null, which is used to turn off the use of cache
2580 # files altogether, and which should be passed on to subconfigures.
2581 # Also strip program-prefix, program-suffix, and program-transform-name,
2582 # so that we can pass down a consistent program-transform-name.
2583 baseargs=
2584 tbaseargs=
2585 keep_next=no
2586 skip_next=no
2587 eval "set -- $ac_configure_args"
2588 for ac_arg
2589 do
2590   if test X"$skip_next" = X"yes"; then
2591     skip_next=no
2592     continue
2593   fi
2594   if test X"$keep_next" = X"yes"; then
2595     case $ac_arg in
2596       *\'*)
2597         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2598     esac
2599     baseargs="$baseargs '$ac_arg'"
2600     tbaseargs="$tbaseargs '$ac_arg'"
2601     keep_next=no
2602     continue
2603   fi
2604
2605   # Handle separated arguments.  Based on the logic generated by
2606   # autoconf 2.59.
2607   case $ac_arg in
2608     *=* | --config-cache | -C | -disable-* | --disable-* \
2609       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2610       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2611       | -with-* | --with-* | -without-* | --without-* | --x)
2612       separate_arg=no
2613       ;;
2614     -*)
2615       separate_arg=yes
2616       ;;
2617     *)
2618       separate_arg=no
2619       ;;
2620   esac
2621
2622   skip_targ=no
2623   case $ac_arg in
2624 changequote(,)
2625   --with-* | --without-*)
2626     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2627
2628     case $libopt in
2629     *[-_]include)
2630       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2631       ;;
2632     *[-_]lib)
2633       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2634       ;;
2635     *)
2636       lib=$libopt
2637       ;;
2638     esac
2639 changequote([,])
2640
2641     case $lib in
2642     mpc | mpfr | gmp | ppl | cloog)
2643       # If we're processing --with-$lib, --with-$lib-include or
2644       # --with-$lib-lib, for one of the libs above, and target is
2645       # different from host, don't pass the current argument to any
2646       # target library's configure.
2647       if test x$is_cross_compiler = xyes; then
2648         skip_targ=yes
2649       fi
2650       ;;
2651     esac
2652     ;;
2653   esac
2654
2655   case "$ac_arg" in
2656     --cache-file=/dev/null | \
2657     -cache-file=/dev/null )
2658       # Handled here to avoid the test to skip args below.
2659       baseargs="$baseargs '$ac_arg'"
2660       tbaseargs="$tbaseargs '$ac_arg'"
2661       # Assert: $separate_arg should always be no.
2662       keep_next=$separate_arg
2663       ;;
2664     --no*)
2665       continue
2666       ;;
2667     --c* | \
2668     --sr* | \
2669     --ho* | \
2670     --bu* | \
2671     --t* | \
2672     --program-* | \
2673     -cache_file* | \
2674     -srcdir* | \
2675     -host* | \
2676     -build* | \
2677     -target* | \
2678     -program-prefix* | \
2679     -program-suffix* | \
2680     -program-transform-name* )
2681       skip_next=$separate_arg
2682       continue
2683       ;;
2684     -*)
2685       # An option.  Add it.
2686       case $ac_arg in
2687         *\'*)
2688           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2689       esac
2690       baseargs="$baseargs '$ac_arg'"
2691       if test X"$skip_targ" = Xno; then
2692         tbaseargs="$tbaseargs '$ac_arg'"
2693       fi
2694       keep_next=$separate_arg
2695       ;;
2696     *)
2697       # Either a variable assignment, or a nonopt (triplet).  Don't
2698       # pass it down; let the Makefile handle this.
2699       continue
2700       ;;
2701   esac
2702 done
2703 # Remove the initial space we just introduced and, as these will be
2704 # expanded by make, quote '$'.
2705 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2706
2707 # Add in --program-transform-name, after --program-prefix and
2708 # --program-suffix have been applied to it.  Autoconf has already
2709 # doubled dollar signs and backslashes in program_transform_name; we want
2710 # the backslashes un-doubled, and then the entire thing wrapped in single
2711 # quotes, because this will be expanded first by make and then by the shell.
2712 # Also, because we want to override the logic in subdir configure scripts to
2713 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2714 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2715 ${program_transform_name}
2716 EOF_SED
2717 gcc_transform_name=`cat conftestsed.out`
2718 rm -f conftestsed.out
2719 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2720 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2721 if test "$silent" = yes; then
2722   baseargs="$baseargs --silent"
2723   tbaseargs="$tbaseargs --silent"
2724 fi
2725 baseargs="$baseargs --disable-option-checking"
2726 tbaseargs="$tbaseargs --disable-option-checking"
2727
2728 # Record and document user additions to sub configure arguments.
2729 AC_ARG_VAR([build_configargs],
2730            [additional configure arguments for build directories])
2731 AC_ARG_VAR([host_configargs],
2732            [additional configure arguments for host directories])
2733 AC_ARG_VAR([target_configargs],
2734            [additional configure arguments for target directories])
2735
2736 # For the build-side libraries, we just need to pretend we're native,
2737 # and not use the same cache file.  Multilibs are neither needed nor
2738 # desired.
2739 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2740
2741 # For host modules, accept cache file option, or specification as blank.
2742 case "${cache_file}" in
2743 "") # empty
2744   cache_file_option="" ;;
2745 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2746   cache_file_option="--cache-file=${cache_file}" ;;
2747 *) # relative path
2748   cache_file_option="--cache-file=../${cache_file}" ;;
2749 esac
2750
2751 # Host dirs don't like to share a cache file either, horribly enough.
2752 # This seems to be due to autoconf 2.5x stupidity.
2753 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2754
2755 target_configargs="$target_configargs ${tbaseargs}"
2756
2757 # Passing a --with-cross-host argument lets the target libraries know
2758 # whether they are being built with a cross-compiler or being built
2759 # native.  However, it would be better to use other mechanisms to make the
2760 # sorts of decisions they want to make on this basis.  Please consider
2761 # this option to be deprecated.  FIXME.
2762 if test x${is_cross_compiler} = xyes ; then
2763   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2764 fi
2765
2766 # Default to --enable-multilib.
2767 if test x${enable_multilib} = x ; then
2768   target_configargs="--enable-multilib ${target_configargs}"
2769 fi
2770
2771 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2772 # changed from the earlier setting of with_newlib.
2773 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2774   target_configargs="--with-newlib ${target_configargs}"
2775 fi
2776
2777 # Different target subdirs use different values of certain variables
2778 # (notably CXX).  Worse, multilibs use *lots* of different values.
2779 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2780 # it doesn't automatically accept command-line overrides of them.
2781 # This means it's not safe for target subdirs to share a cache file,
2782 # which is disgusting, but there you have it.  Hopefully this can be
2783 # fixed in future.  It's still worthwhile to use a cache file for each
2784 # directory.  I think.
2785
2786 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2787 # We need to pass --target, as newer autoconf's requires consistency
2788 # for target_alias and gcc doesn't manage it consistently.
2789 target_configargs="--cache-file=./config.cache ${target_configargs}"
2790
2791 FLAGS_FOR_TARGET=
2792 case " $target_configdirs " in
2793  *" newlib "*)
2794   case " $target_configargs " in
2795   *" --with-newlib "*)
2796    case "$target" in
2797     *-cygwin*)
2798       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2799       ;;
2800    esac
2801
2802    # If we're not building GCC, don't discard standard headers.
2803    if test -d ${srcdir}/gcc; then
2804      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2805
2806      if test "${build}" != "${host}"; then
2807        # On Canadian crosses, CC_FOR_TARGET will have already been set
2808        # by `configure', so we won't have an opportunity to add -Bgcc/
2809        # to it.  This is right: we don't want to search that directory
2810        # for binaries, but we want the header files in there, so add
2811        # them explicitly.
2812        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2813
2814        # Someone might think of using the pre-installed headers on
2815        # Canadian crosses, in case the installed compiler is not fully
2816        # compatible with the compiler being built.  In this case, it
2817        # would be better to flag an error than risking having
2818        # incompatible object files being constructed.  We can't
2819        # guarantee that an error will be flagged, but let's hope the
2820        # compiler will do it, when presented with incompatible header
2821        # files.
2822      fi
2823    fi
2824
2825    case "${target}-${is_cross_compiler}" in
2826    i[[3456789]]86-*-linux*-no)
2827       # Here host == target, so we don't need to build gcc,
2828       # so we don't want to discard standard headers.
2829       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2830       ;;
2831    *)
2832       # If we're building newlib, use its generic headers last, but search
2833       # for any libc-related directories first (so make it the last -B
2834       # switch).
2835       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2836
2837       # If we're building libgloss, find the startup file, simulator library
2838       # and linker script.
2839       case " $target_configdirs " in
2840         *" libgloss "*)
2841         # Look for startup file, simulator library and maybe linker script.
2842         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2843         # Look for libnosys.a in case the target needs it.
2844         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2845         # Most targets have the linker script in the source directory.
2846         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2847         ;;
2848       esac
2849       ;;
2850    esac
2851    ;;
2852   esac
2853   ;;
2854 esac
2855
2856 case "$target" in
2857   x86_64-*mingw* | *-w64-mingw*)
2858   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2859   # however, use a symlink named 'mingw' in ${prefix} .
2860     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2861     ;;
2862   *-mingw*)
2863   # MinGW can't be handled as Cygwin above since it does not use newlib.
2864     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2865     ;;
2866 esac
2867
2868 # Allow the user to override the flags for
2869 # our build compiler if desired.
2870 if test x"${build}" = x"${host}" ; then
2871   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2872   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2873   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2874 fi
2875
2876 # On Canadian crosses, we'll be searching the right directories for
2877 # the previously-installed cross compiler, so don't bother to add
2878 # flags for directories within the install tree of the compiler
2879 # being built; programs in there won't even run.
2880 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2881   # Search for pre-installed headers if nothing else fits.
2882   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2883 fi
2884
2885 if test "x${use_gnu_ld}" = x &&
2886    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2887   # Arrange for us to find uninstalled linker scripts.
2888   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2889 fi
2890
2891 # Search for other target-specific linker scripts and such.
2892 case "${target}" in
2893   mep*)
2894     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2895     ;;
2896 esac
2897
2898 # Makefile fragments.
2899 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2900 do
2901   eval fragval=\$$frag
2902   if test $fragval != /dev/null; then
2903     eval $frag=${srcdir}/$fragval
2904   fi
2905 done
2906 AC_SUBST_FILE(host_makefile_frag)
2907 AC_SUBST_FILE(target_makefile_frag)
2908 AC_SUBST_FILE(alphaieee_frag)
2909 AC_SUBST_FILE(ospace_frag)
2910
2911 # Miscellanea: directories, flags, etc.
2912 AC_SUBST(RPATH_ENVVAR)
2913 AC_SUBST(GCC_SHLIB_SUBDIR)
2914 AC_SUBST(tooldir)
2915 AC_SUBST(build_tooldir)
2916 AC_SUBST(CONFIGURE_GDB_TK)
2917 AC_SUBST(GDB_TK)
2918 AC_SUBST(INSTALL_GDB_TK)
2919
2920 # Build module lists & subconfigure args.
2921 AC_SUBST(build_configargs)
2922 AC_SUBST(build_configdirs)
2923
2924 # Host module lists & subconfigure args.
2925 AC_SUBST(host_configargs)
2926 AC_SUBST(configdirs)
2927 AC_SUBST(target_configdirs)
2928
2929 # Target module lists & subconfigure args.
2930 AC_SUBST(target_configargs)
2931
2932
2933 # Build tools.
2934 AC_SUBST(AR_FOR_BUILD)
2935 AC_SUBST(AS_FOR_BUILD)
2936 AC_SUBST(CC_FOR_BUILD)
2937 AC_SUBST(CFLAGS_FOR_BUILD)
2938 AC_SUBST(CXXFLAGS_FOR_BUILD)
2939 AC_SUBST(CXX_FOR_BUILD)
2940 AC_SUBST(DLLTOOL_FOR_BUILD)
2941 AC_SUBST(GCJ_FOR_BUILD)
2942 AC_SUBST(GFORTRAN_FOR_BUILD)
2943 AC_SUBST(GOC_FOR_BUILD)
2944 AC_SUBST(LDFLAGS_FOR_BUILD)
2945 AC_SUBST(LD_FOR_BUILD)
2946 AC_SUBST(NM_FOR_BUILD)
2947 AC_SUBST(RANLIB_FOR_BUILD)
2948 AC_SUBST(WINDMC_FOR_BUILD)
2949 AC_SUBST(WINDRES_FOR_BUILD)
2950
2951 # Generate default definitions for YACC, M4, LEX and other programs that run
2952 # on the build machine.  These are used if the Makefile can't locate these
2953 # programs in objdir.
2954 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2955
2956 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2957 case " $build_configdirs " in
2958   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2959 esac
2960
2961 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2962 case " $build_configdirs " in
2963   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2964 esac
2965
2966 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
2967 case " $build_configdirs " in
2968   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
2969 esac
2970
2971 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
2972 case " $build_configdirs " in
2973   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2974   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
2975 esac
2976
2977 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
2978 case " $build_configdirs " in
2979   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2980 esac
2981
2982 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
2983 case " $build_configdirs " in
2984   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
2985   *)
2986 changequote(,)
2987     # For an installed makeinfo, we require it to be from texinfo 4.7 or
2988     # higher, else we use the "missing" dummy.
2989     if ${MAKEINFO} --version \
2990        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
2991       :
2992     else
2993       MAKEINFO="$MISSING makeinfo"
2994     fi
2995     ;;
2996 changequote([,])
2997 esac
2998
2999 # FIXME: expect and dejagnu may become build tools?
3000
3001 AC_CHECK_PROGS(EXPECT, expect, expect)
3002 case " $configdirs " in
3003   *" expect "*)
3004     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3005     ;;
3006 esac
3007
3008 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3009 case " $configdirs " in
3010   *" dejagnu "*)
3011     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3012     ;;
3013 esac
3014
3015
3016 # Host tools.
3017 NCN_STRICT_CHECK_TOOLS(AR, ar)
3018 NCN_STRICT_CHECK_TOOLS(AS, as)
3019 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3020 NCN_STRICT_CHECK_TOOLS(LD, ld)
3021 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3022 NCN_STRICT_CHECK_TOOLS(NM, nm)
3023 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3024 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3025 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3026 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3027 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3028 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3029 AC_SUBST(CC)
3030 AC_SUBST(CXX)
3031 AC_SUBST(CFLAGS)
3032 AC_SUBST(CXXFLAGS)
3033
3034 # Target tools.
3035 AC_ARG_WITH([build-time-tools],
3036   [AS_HELP_STRING([--with-build-time-tools=PATH],
3037                   [use given path to find target tools during the build])],
3038   [case x"$withval" in
3039      x/*) ;;
3040      *)
3041        with_build_time_tools=
3042        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3043        ;;
3044    esac],
3045   [with_build_time_tools=])
3046
3047 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3048 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3049 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3050 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3051 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3052 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3053
3054 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3055 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3056 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3057 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3058 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3059 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3060 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3061 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3062 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3063 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3064 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3065
3066 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3067
3068 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3069 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3070 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3071 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3072 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3073                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3074                 c++)
3075 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3076                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3077                 c++)
3078 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3079 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3080 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3081                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3082 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3083                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3084 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3085                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3086 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3087 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3088 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3089 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3090 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3091 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3092 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3093 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3094
3095 AC_SUBST(FLAGS_FOR_TARGET)
3096 AC_SUBST(RAW_CXX_FOR_TARGET)
3097
3098 # Certain tools may need extra flags.
3099 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3100 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3101 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3102
3103 # When building target libraries, except in a Canadian cross, we use
3104 # the same toolchain as the compiler we just built.
3105 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3106 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3107 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3108 if test $host = $build; then
3109   case " $configdirs " in
3110     *" gcc "*)
3111       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3112       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3113       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3114       ;;
3115   esac
3116 fi
3117
3118 AC_SUBST(COMPILER_AS_FOR_TARGET)
3119 AC_SUBST(COMPILER_LD_FOR_TARGET)
3120 AC_SUBST(COMPILER_NM_FOR_TARGET)
3121
3122 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3123 AC_ARG_ENABLE(maintainer-mode,
3124 [AS_HELP_STRING([--enable-maintainer-mode],
3125                 [enable make rules and dependencies not useful
3126                  (and sometimes confusing) to the casual installer])],
3127       USE_MAINTAINER_MODE=$enableval,
3128       USE_MAINTAINER_MODE=no)
3129 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3130 AC_SUBST(MAINTAINER_MODE_TRUE)
3131 AC_SUBST(MAINTAINER_MODE_FALSE)
3132 if test "$USE_MAINTAINER_MODE" = yes; then
3133   MAINTAINER_MODE_TRUE=
3134   MAINTAINER_MODE_FALSE='#'
3135 else
3136   MAINTAINER_MODE_TRUE='#'
3137   MAINTAINER_MODE_FALSE=
3138 fi
3139 MAINT=$MAINTAINER_MODE_TRUE
3140 AC_SUBST(MAINT)dnl
3141
3142 # ---------------------
3143 # GCC bootstrap support
3144 # ---------------------
3145
3146 # Stage specific cflags for build.
3147 stage1_cflags="-g"
3148 case $build in
3149   vax-*-*)
3150     case ${GCC} in
3151       yes) stage1_cflags="-g -Wa,-J" ;;
3152       *) stage1_cflags="-g -J" ;;
3153     esac ;;
3154 esac
3155
3156 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3157 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3158   saved_CFLAGS="$CFLAGS"
3159
3160   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3161   CFLAGS="$CFLAGS -fkeep-inline-functions"
3162   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3163   AC_TRY_COMPILE([
3164 #if (__GNUC__ < 3) \
3165     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3166                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3167 #error http://gcc.gnu.org/PR29382
3168 #endif
3169     ],,
3170     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3171     [AC_MSG_RESULT([no])])
3172
3173   CFLAGS="$saved_CFLAGS"
3174 fi
3175
3176 AC_SUBST(stage1_cflags)
3177
3178 # Enable --enable-checking in stage1 of the compiler.
3179 AC_ARG_ENABLE(stage1-checking,
3180 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3181                 [choose additional checking for stage1 of the compiler])],
3182 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3183 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3184   stage1_checking=--enable-checking=yes,types
3185 else
3186   stage1_checking=--enable-checking=$enable_checking,types
3187 fi])
3188 AC_SUBST(stage1_checking)
3189
3190 # Enable -Werror in bootstrap stage2 and later.
3191 AC_ARG_ENABLE(werror,
3192 [AS_HELP_STRING([--enable-werror],
3193                 [enable -Werror in bootstrap stage2 and later])], [],
3194 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3195   enable_werror=yes
3196 else
3197   enable_werror=no
3198 fi])
3199 case ${enable_werror} in
3200   yes) stage2_werror_flag="--enable-werror-always" ;;
3201   *) stage2_werror_flag="" ;;
3202 esac
3203 AC_SUBST(stage2_werror_flag)
3204
3205 # Specify what files to not compare during bootstrap.
3206
3207 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3208 case "$target" in
3209   hppa*64*-*-hpux*) ;;
3210   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3211 esac
3212 case " $configdirs " in
3213 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3214 esac
3215 AC_SUBST(compare_exclusions)
3216
3217 AC_CONFIG_FILES([Makefile],
3218   [sed "$extrasub_build" Makefile |
3219    sed "$extrasub_host" |
3220    sed "$extrasub_target" > mf$$
3221    mv -f mf$$ Makefile],
3222   [extrasub_build="$extrasub_build"
3223    extrasub_host="$extrasub_host"
3224    extrasub_target="$extrasub_target"])
3225 AC_OUTPUT