OSDN Git Service

* configure.ac (i[[3456789]]86-*-vsta, i[[3456789]]86-*-go32*,
[pf3gnuchains/gcc-fork.git] / configure.ac
1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
3 #   Free Software Foundation, Inc.
4 #
5 # This file is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License as published by
7 # the Free Software Foundation; either version 3 of the License, or
8 # (at your option) any later version.
9 #
10 # This program is distributed in the hope that it will be useful, but
11 # WITHOUT ANY WARRANTY; without even the implied warranty of
12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13 # General Public License for more details.
14 #
15 # You should have received a copy of the GNU General Public License
16 # along with this program; see the file COPYING3.  If not see
17 # <http://www.gnu.org/licenses/>.
18
19 ##############################################################################
20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
21
22 m4_include(config/acx.m4)
23 m4_include(config/override.m4)
24 m4_include(config/proginstall.m4)
25 m4_include(config/elf.m4)
26 m4_include([libtool.m4])
27 m4_include([ltoptions.m4])
28 m4_include([ltsugar.m4])
29 m4_include([ltversion.m4])
30 m4_include([lt~obsolete.m4])
31 m4_include([config/cloog.m4])
32
33 AC_INIT(move-if-change)
34 AC_PREREQ(2.64)
35 AC_DISABLE_OPTION_CHECKING
36
37 progname=$0
38 # if PWD already has a value, it is probably wrong.
39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
40
41 # Export original configure arguments for use by sub-configures.
42 # Quote arguments with shell meta charatcers.
43 TOPLEVEL_CONFIGURE_ARGUMENTS=
44 set -- "$progname" "$@"
45 for ac_arg
46 do
47   case "$ac_arg" in
48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
50     # if the argument is of the form -foo=baz, quote the baz part only
51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
52   *) ;;
53   esac
54   # Add the quoted argument to the list.
55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
56 done
57 if test "$silent" = yes; then
58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
59 fi
60 # Remove the initial space we just introduced and, as these will be
61 # expanded by make, quote '$'.
62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
64
65 # Find the build, host, and target systems.
66 ACX_NONCANONICAL_BUILD
67 ACX_NONCANONICAL_HOST
68 ACX_NONCANONICAL_TARGET
69
70 dnl Autoconf 2.5x and later will set a default program prefix if
71 dnl --target was used, even if it was the same as --host.  Disable
72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
73 dnl to take effect.
74 test "$host_noncanonical" = "$target_noncanonical" &&
75   test "$program_prefix$program_suffix$program_transform_name" = \
76     NONENONEs,x,x, &&
77   program_transform_name=s,y,y,
78
79 AC_CANONICAL_SYSTEM
80 AC_ARG_PROGRAM
81
82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
84
85 # Get 'install' or 'install-sh' and its variants.
86 AC_PROG_INSTALL
87 ACX_PROG_LN
88 AC_PROG_LN_S
89 AC_PROG_SED
90 AC_PROG_AWK
91
92 ### we might need to use some other shell than /bin/sh for running subshells
93 ### If we are on Windows, search for the shell.  This will permit people
94 ### to not have /bin/sh, but to be able to see /SOME/PATH/sh configure
95 ### without also having to set CONFIG_SHELL.  This code will work when
96 ### using bash, which sets OSTYPE.
97 case "${OSTYPE}" in
98 *win32*)
99   if test x${CONFIG_SHELL} = x ; then
100     if test ! -f /bin/sh ; then
101       if test x${SHELL} != x && test -f ${SHELL} ; then
102         CONFIG_SHELL=${SHELL}
103         export CONFIG_SHELL
104       else
105         for prog in sh sh.exe bash bash.exe; do
106           IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
107           for dir in $PATH; do
108             test -z "$dir" && dir=.
109             if test -f $dir/$prog; then
110               CONFIG_SHELL=$dir/$prog
111               export CONFIG_SHELL
112               break
113             fi
114           done
115           IFS="$save_ifs"
116           test -n "${CONFIG_SHELL}" && break
117         done
118       fi
119     fi
120   fi
121   ;;
122 esac
123
124 config_shell=${CONFIG_SHELL-/bin/sh}
125
126 moveifchange=${srcdir}/move-if-change
127
128 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
129
130 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
131 # a relative path.
132 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
133   INSTALL="${srcpwd}/install-sh -c"
134 fi
135
136 # Set srcdir to "." if that's what it is.
137 # This is important for multilib support.
138 pwd=`${PWDCMD-pwd}`
139 if test "${pwd}" = "${srcpwd}" ; then
140   srcdir=.
141 fi
142
143 topsrcdir=$srcpwd
144
145 extra_host_args=
146
147 ### To add a new directory to the tree, first choose whether it is a target
148 ### or a host dependent tool.  Then put it into the appropriate list
149 ### (library or tools, host or target), doing a dependency sort.
150
151 # Subdirs will be configured in the order listed in build_configdirs, 
152 # configdirs, or target_configdirs; see the serialization section below.
153
154 # Dependency sorting is only needed when *configuration* must be done in 
155 # a particular order.  In all cases a dependency should be specified in 
156 # the Makefile, whether or not it's implicitly specified here.
157
158 # Double entries in build_configdirs, configdirs, or target_configdirs may
159 # cause circular dependencies and break everything horribly.
160
161 # these library is used by various programs built for the build
162 # environment
163 #
164 build_libs="build-libiberty"
165
166 # these tools are built for the build environment
167 build_tools="build-texinfo build-byacc build-flex build-bison build-m4 build-fixincludes"
168
169 # these libraries are used by various programs built for the host environment
170 #
171 host_libs="intl mmalloc libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
172
173 # these tools are built for the host environment
174 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
175 # know that we are building the simulator.
176 # binutils, gas and ld appear in that order because it makes sense to run
177 # "make check" in that particular order.
178 # If --enable-gold is used, "gold" may replace "ld".
179 host_tools="texinfo byacc flex bison binutils gas ld fixincludes gcc cgen sid sim gdb make patch prms send-pr gprof etc expect dejagnu ash bash bzip2 m4 autoconf automake libtool diff rcs fileutils shellutils time textutils wdiff find uudecode hello tar gzip indent recode release sed utils guile perl gawk findutils gettext zip fastjar gnattools"
180
181 # libgcj represents the runtime libraries only used by gcj.
182 libgcj="target-libffi \
183         target-zlib \
184         target-qthreads \
185         target-libjava"
186
187 # these libraries are built for the target environment, and are built after
188 # the host libraries and the host tools (which may be a cross compiler)
189 #
190 target_libraries="target-libgcc \
191                 target-libiberty \
192                 target-libgloss \
193                 target-newlib \
194                 target-libgomp \
195                 target-libstdc++-v3 \
196                 target-libmudflap \
197                 target-libssp \
198                 target-libquadmath \
199                 target-libgfortran \
200                 target-boehm-gc \
201                 ${libgcj} \
202                 target-libobjc \
203                 target-libada \
204                 target-libgo"
205
206 # these tools are built using the target libraries, and are intended to
207 # run only in the target environment
208 #
209 # note: any program that *uses* libraries that are in the "target_libraries"
210 # list belongs in this list.  those programs are also very likely
211 # candidates for the "native_only" list which follows
212 #
213 target_tools="target-examples target-groff target-gperf target-rda"
214
215 ################################################################################
216
217 ## All tools belong in one of the four categories, and are assigned above
218 ## We assign ${configdirs} this way to remove all embedded newlines.  This
219 ## is important because configure will choke if they ever get through.
220 ## ${configdirs} is directories we build using the host tools.
221 ## ${target_configdirs} is directories we build using the target tools.
222 configdirs=`echo ${host_libs} ${host_tools}`
223 target_configdirs=`echo ${target_libraries} ${target_tools}`
224 build_configdirs=`echo ${build_libs} ${build_tools}`
225
226 m4_divert_text([PARSE_ARGS],
227 [case $srcdir in
228   *" "*)
229 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
230     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
231 m4_popdef([AS_MESSAGE_LOG_FD])dnl
232     ;;
233 esac
234 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
235 ])
236
237 ################################################################################
238
239 srcname="gnu development package"
240
241 # This gets set non-empty for some net releases of packages.
242 appdirs=""
243
244 # Define is_cross_compiler to save on calls to 'test'.
245 is_cross_compiler=
246 if test x"${host}" = x"${target}" ; then
247   is_cross_compiler=no
248 else
249   is_cross_compiler=yes
250 fi      
251
252 # Find the build and target subdir names.
253 GCC_TOPLEV_SUBDIRS
254 # Be sure to cover against remnants of an in-tree build.
255 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
256   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
257 Use a pristine source tree when building in a separate tree])
258 fi
259
260 # Skipdirs are removed silently.
261 skipdirs=
262 # Noconfigdirs are removed loudly.
263 noconfigdirs=""
264
265 use_gnu_ld=
266 # Make sure we don't let GNU ld be added if we didn't want it.
267 if test x$with_gnu_ld = xno ; then
268   use_gnu_ld=no
269   noconfigdirs="$noconfigdirs ld gold"
270 fi
271
272 use_gnu_as=
273 # Make sure we don't let GNU as be added if we didn't want it.
274 if test x$with_gnu_as = xno ; then
275   use_gnu_as=no
276   noconfigdirs="$noconfigdirs gas"
277 fi
278
279 use_included_zlib=
280 # Make sure we don't let ZLIB be added if we didn't want it.
281 if test x$with_system_zlib = xyes ; then
282   use_included_zlib=no
283   noconfigdirs="$noconfigdirs zlib"
284 fi
285
286 # some tools are so dependent upon X11 that if we're not building with X, 
287 # it's not even worth trying to configure, much less build, that tool.
288
289 case ${with_x} in
290   yes | "") ;; # the default value for this tree is that X11 is available
291   no)
292     skipdirs="${skipdirs} tk itcl libgui"
293     # We won't be able to build gdbtk without X.
294     enable_gdbtk=no 
295     ;;
296   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
297 esac
298
299 # Some tools are only suitable for building in a "native" situation.
300 # Remove these if host!=target.  
301 native_only="autoconf automake libtool fileutils find gawk gettext gzip hello indent m4 rcs recode sed shellutils tar textutils uudecode wdiff target-groff guile perl time ash bash bzip2 prms gnuserv target-gperf"
302
303 # Similarly, some are only suitable for cross toolchains.
304 # Remove these if host=target.
305 cross_only="target-libgloss target-newlib target-opcodes"
306
307 case $is_cross_compiler in
308   no) skipdirs="${skipdirs} ${cross_only}" ;;
309   yes) skipdirs="${skipdirs} ${native_only}" ;;
310 esac
311
312 # If both --with-headers and --with-libs are specified, default to
313 # --without-newlib.
314 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
315    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
316   if test x"${with_newlib}" = x ; then
317     with_newlib=no
318   fi
319 fi
320
321 # Recognize --with-newlib/--without-newlib.
322 case ${with_newlib} in
323   no) skipdirs="${skipdirs} target-newlib" ;;
324   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
325 esac
326
327 # Handle --enable-gold, --enable-ld.
328 # --disable-gold [--enable-ld]
329 #     Build only ld.  Default option.
330 # --enable-gold [--enable-ld]
331 #     Build both gold and ld.  Install gold as "ld.gold", install ld
332 #     as "ld.bfd" and "ld".
333 # --enable-gold=default [--enable-ld]
334 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
335 #     install ld as "ld.bfd".
336 # --enable-gold[=default] --disable-ld
337 #     Build only gold, which is then installed as both "ld.gold" and "ld".
338 # --enable-gold --enable-ld=default
339 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
340 #     and ld.bfd).
341 #     In other words, ld is default
342 # --enable-gold=default --enable-ld=default
343 #     Error.
344
345 default_ld=
346 AC_ARG_ENABLE(gold,
347 [AS_HELP_STRING([[--enable-gold[=ARG]]],
348                 [build gold @<:@ARG={default,yes,no}@:>@])],
349 ENABLE_GOLD=$enableval,
350 ENABLE_GOLD=no)
351 case "${ENABLE_GOLD}" in
352   yes|default)
353     # Check for ELF target.
354     is_elf=no
355     case "${target}" in
356       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
357       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
358       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-solaris2* | *-*-nto*)
359         case "${target}" in
360           *-*-linux*aout* | *-*-linux*oldld*)
361             ;;
362           *)
363             is_elf=yes
364             ;;
365         esac
366     esac
367
368     if test "$is_elf" = "yes"; then
369       # Check for target supported by gold.
370       case "${target}" in
371         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
372           configdirs="$configdirs gold"
373           if test x${ENABLE_GOLD} = xdefault; then
374             default_ld=gold
375           fi
376           ENABLE_GOLD=yes
377           ;;
378       esac
379     fi
380     ;;
381   no)
382     ;;
383   *)
384     AC_MSG_ERROR([invalid --enable-gold argument])
385     ;;
386 esac
387
388 AC_ARG_ENABLE(ld,
389 [AS_HELP_STRING([[--enable-ld[=ARG]]],
390                 [build ld @<:@ARG={default,yes,no}@:>@])],
391 ENABLE_LD=$enableval,
392 ENABLE_LD=yes)
393
394 case "${ENABLE_LD}" in
395   default)
396     if test x${default_ld} != x; then
397       AC_MSG_ERROR([either gold or ld can be the default ld])
398     fi
399     ;;
400   yes)
401     ;;
402   no)
403     if test x${ENABLE_GOLD} != xyes; then
404       AC_MSG_WARN([neither ld nor gold are enabled])
405     fi
406     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
407     ;;
408   *)
409     AC_MSG_ERROR([invalid --enable-ld argument])
410     ;;
411 esac
412
413 # Configure extra directories which are host specific
414
415 case "${host}" in
416   *-cygwin*)
417     configdirs="$configdirs libtermcap" ;;
418 esac
419
420 # A target can indicate whether a language isn't supported for some reason.
421 # Only spaces may be used in this macro; not newlines or tabs.
422 unsupported_languages=
423
424 # Remove more programs from consideration, based on the host or 
425 # target this usually means that a port of the program doesn't
426 # exist yet.
427
428 case "${host}" in
429   hppa*64*-*-*)
430     noconfigdirs="$noconfigdirs byacc"
431     ;;
432   i[[3456789]]86-*-msdosdjgpp*)
433     noconfigdirs="$noconfigdirs tcl tk expect dejagnu send-pr uudecode guile itcl gnuserv libffi"
434     ;;
435   x86_64-*-mingw*)
436     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
437     ;;
438   i[[3456789]]86-*-mingw32*)
439     # noconfigdirs="tcl tk expect dejagnu make texinfo bison patch flex byacc send-pr uudecode dejagnu diff guile perl itcl gnuserv"
440     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
441     ;;
442   *-*-cygwin*)
443     noconfigdirs="$noconfigdirs autoconf automake send-pr rcs guile perl"
444     ;;
445   *-*-netbsd*)
446     noconfigdirs="$noconfigdirs rcs"
447     ;;
448 esac
449
450
451 AC_ARG_ENABLE(libquadmath,
452 AS_HELP_STRING([--disable-libquadmath],
453   [do not build libquadmath directory]),
454 ENABLE_LIBQUADMATH=$enableval,
455 ENABLE_LIBQUADMATH=yes)
456 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
457   noconfigdirs="$noconfigdirs target-libquadmath"
458 fi
459
460
461 AC_ARG_ENABLE(libquadmath-support,
462 AS_HELP_STRING([--disable-libquadmath-support],
463   [disable libquadmath support for Fortran]),
464 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
465 ENABLE_LIBQUADMATH_SUPPORT=yes)
466 enable_libquadmath_support=
467 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
468   enable_libquadmath_support=no
469 fi
470
471
472 AC_ARG_ENABLE(libada,
473 [AS_HELP_STRING([--enable-libada], [build libada directory])],
474 ENABLE_LIBADA=$enableval,
475 ENABLE_LIBADA=yes)
476 if test "${ENABLE_LIBADA}" != "yes" ; then
477   noconfigdirs="$noconfigdirs gnattools"
478 fi
479
480 AC_ARG_ENABLE(libssp,
481 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
482 ENABLE_LIBSSP=$enableval,
483 ENABLE_LIBSSP=yes)
484
485 # Save it here so that, even in case of --enable-libgcj, if the Java
486 # front-end isn't enabled, we still get libgcj disabled.
487 libgcj_saved=$libgcj
488 case $enable_libgcj in
489 yes)
490   # If we reset it here, it won't get added to noconfigdirs in the
491   # target-specific build rules, so it will be forcibly enabled
492   # (unless the Java language itself isn't enabled).
493   libgcj=
494   ;;
495 no)
496   # Make sure we get it printed in the list of not supported target libs.
497   # Don't disable libffi, though, other languages use it.
498   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
499   # Clear libgcj_saved so that even if java is enabled libffi won't be
500   # built.
501   libgcj_saved=
502   ;;
503 esac
504
505
506 # Disable libmudflap on some systems.
507 if test x$enable_libmudflap = x ; then
508     case "${target}" in
509     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
510         # Enable libmudflap by default in GNU and friends.
511         ;;
512     *-*-freebsd*)
513         # Enable libmudflap by default in FreeBSD.
514         ;;
515     *)
516         # Disable it by default everywhere else.
517         noconfigdirs="$noconfigdirs target-libmudflap"
518         ;;
519     esac
520 fi
521
522 # Disable libgomp on non POSIX hosted systems.
523 if test x$enable_libgomp = x ; then
524     # Enable libgomp by default on hosted POSIX systems.
525     case "${target}" in
526     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
527         ;;
528     *-*-netbsd* | *-*-freebsd* | *-*-openbsd*)
529         ;;
530     *-*-solaris2* | *-*-sysv4* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
531         ;;
532     *-*-darwin* | *-*-aix*)
533         ;;
534     *)
535         noconfigdirs="$noconfigdirs target-libgomp"
536         ;;
537     esac
538 fi
539
540 # Default libgloss CPU subdirectory.
541 libgloss_dir="$target_cpu"
542
543 case "${target}" in
544   *-*-chorusos)
545     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
546     ;;
547   powerpc-*-darwin*)
548     noconfigdirs="$noconfigdirs ld gas gdb gprof"
549     noconfigdirs="$noconfigdirs sim target-rda"
550     ;;
551   i[[3456789]]86-*-darwin*)
552     noconfigdirs="$noconfigdirs ld gprof"
553     noconfigdirs="$noconfigdirs sim target-rda"
554     ;;
555   x86_64-*-darwin[[912]]*)
556     noconfigdirs="$noconfigdirs ld gas gprof"
557     noconfigdirs="$noconfigdirs sim target-rda"
558     ;;
559   *-*-darwin*)
560     noconfigdirs="$noconfigdirs ld gas gdb gprof"
561     noconfigdirs="$noconfigdirs sim target-rda"
562     noconfigdirs="$noconfigdirs ${libgcj}"
563     ;;
564   *-*-freebsd[[12]] | *-*-freebsd[[12]].* | *-*-freebsd*aout*)
565     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
566     ;;
567   *-*-freebsd*)
568     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
569     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
570         && test -f /usr/local/include/gmp.h; then
571       with_gmp=/usr/local
572     fi
573
574     # Skip some stuff that's unsupported on some FreeBSD configurations.
575     case "${target}" in
576       i*86-*-*) ;;
577       alpha*-*-*) ;;
578       x86_64-*-*) ;;
579       *)
580         noconfigdirs="$noconfigdirs ${libgcj}"
581         ;;
582     esac
583     ;;
584   *-*-kaos*)
585     # Remove unsupported stuff on all kaOS configurations.
586     skipdirs="target-libiberty ${libgcj} target-libstdc++-v3 target-librx"
587     skipdirs="$skipdirs target-libobjc target-examples target-groff target-gperf"
588     skipdirs="$skipdirs zlib fastjar target-libjava target-boehm-gc target-zlib"
589     noconfigdirs="$noconfigdirs target-libgloss"
590     ;;
591   *-*-netbsd*)
592     # Skip some stuff on all NetBSD configurations.
593     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss"
594
595     # Skip some stuff that's unsupported on some NetBSD configurations.
596     case "${target}" in
597       i*86-*-netbsdelf*) ;;
598       arm*-*-netbsdelf*) ;;
599       *)
600         noconfigdirs="$noconfigdirs ${libgcj}"
601         ;;
602     esac
603     ;;
604   *-*-netware*)
605     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss ${libgcj} target-libmudflap"
606     ;;
607   *-*-rtems*)
608     skipdirs="${skipdirs} target-libiberty"
609     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
610     ;;
611     # The tpf target doesn't support gdb yet.
612   *-*-tpf*)
613     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty ${libgcj} target-libmudflap gdb tcl tk libgui itcl"
614     ;;
615   *-*-uclinux*)
616     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-rda ${libgcj}"
617     ;;
618   *-*-vxworks*)
619     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty target-libstdc++-v3 ${libgcj}"
620     ;;
621   alpha*-dec-osf*)
622     # ld works, but does not support shared libraries.
623     # newlib is not 64 bit ready.  I'm not sure about fileutils.
624     # gas doesn't generate exception information.
625     noconfigdirs="$noconfigdirs gas ld fileutils target-newlib target-libgloss"
626     ;;
627   alpha*-*-*vms*)
628     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
629     ;;
630   alpha*-*-linux*)
631     # newlib is not 64 bit ready
632     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
633     ;;
634   alpha*-*-*)
635     # newlib is not 64 bit ready
636     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
637     ;;
638   am33_2.0-*-linux*)
639     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
640     ;;
641   sh-*-linux*)
642     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
643     ;;    
644   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
645     noconfigdirs="$noconfigdirs ${libgcj}"
646     noconfigdirs="$noconfigdirs target-examples"
647     noconfigdirs="$noconfigdirs target-libiberty texinfo send-pr"
648     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
649     noconfigdirs="$noconfigdirs expect dejagnu"
650     # the C++ libraries don't build on top of CE's C libraries
651     noconfigdirs="$noconfigdirs target-libstdc++-v3"
652     noconfigdirs="$noconfigdirs target-newlib"
653     case "${host}" in
654       *-*-cygwin*) ;; # keep gdb and readline
655       *) noconfigdirs="$noconfigdirs gdb readline"
656          ;;
657     esac
658     libgloss_dir=wince
659     ;;
660   arc-*-*)
661     noconfigdirs="$noconfigdirs target-libgloss"
662     ;;
663   arm-*-coff)
664     noconfigdirs="$noconfigdirs ${libgcj}"
665     libgloss_dir=arm
666     ;;
667   arm-*-elf* | arm*-*-eabi* )
668     noconfigdirs="$noconfigdirs target-libffi target-qthreads"
669     libgloss_dir=arm
670     ;;
671   arm*-*-linux-gnueabi)
672     noconfigdirs="$noconfigdirs target-qthreads"
673     case ${with_newlib} in
674       no) noconfigdirs="$noconfigdirs target-newlib target-libgloss"
675     esac
676     libgloss_dir=arm
677     ;;
678   arm*-*-symbianelf*)
679     noconfigdirs="$noconfigdirs ${libgcj} target-libiberty"
680     libgloss_dir=arm
681     ;;
682   arm-*-pe*)
683     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
684     ;;
685   arm-*-riscix*)
686     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
687     ;;
688   avr-*-*)
689     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj} target-libssp"
690     ;;
691   bfin-*-*)
692     unsupported_languages="$unsupported_languages java"
693     noconfigdirs="$noconfigdirs target-boehm-gc"
694     if test x${is_cross_compiler} != xno ; then
695       target_configdirs="${target_configdirs} target-bsp target-cygmon"
696     fi
697     ;;
698   c4x-*-* | tic4x-*-*)
699     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
700     ;;
701   c54x*-*-* | tic54x-*-*)
702     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj} gcc gdb newlib"
703     ;;
704   cr16-*-*)
705     noconfigdirs="$noconfigdirs ${libgcj} gdb"
706     ;;
707   cris-*-* | crisv32-*-*)
708     unsupported_languages="$unsupported_languages java"
709     case "${target}" in
710       *-*-aout)
711         unsupported_languages="$unsupported_languages fortran"
712         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
713       *-*-elf) # See PR46792 regarding target-libffi.
714         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
715       *-*-linux*)
716         noconfigdirs="$noconfigdirs target-newlib target-libgloss";;
717       *)
718         unsupported_languages="$unsupported_languages fortran"
719         noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss";;
720     esac
721     libgloss_dir=cris
722     ;;
723   d10v-*-*)
724     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
725     ;;
726   d30v-*-*)
727     noconfigdirs="$noconfigdirs ${libgcj} gdb"
728     ;;
729   fr30-*-elf*)
730     noconfigdirs="$noconfigdirs ${libgcj} gdb"
731     ;;
732   frv-*-*)
733     noconfigdirs="$noconfigdirs ${libgcj}"
734     ;;
735   moxie-*-*)
736     noconfigdirs="$noconfigdirs ${libgcj}"
737     noconfigdirs="$noconfigdirs gprof"
738     ;;
739   h8300*-*-*)
740     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
741     ;;
742   h8500-*-*)
743     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
744     ;;
745   hppa1.1-*-osf* | hppa1.1-*-bsd* )
746     ;;
747   hppa*64*-*-linux*)
748     # In this case, it's because the hppa64-linux target is for
749     # the kernel only at this point and has no libc, and thus no
750     # headers, crt*.o, etc., all of which are needed by these.
751     noconfigdirs="$noconfigdirs target-zlib"
752     ;;
753   hppa*-*-linux*)
754     ;;
755   hppa*-*-*elf* | \
756   hppa*-*-lites* | \
757   hppa*-*-openbsd* | \
758   hppa*64*-*-*)
759     noconfigdirs="$noconfigdirs ${libgcj}"
760     ;;
761   hppa*-hp-hpux11*)
762     noconfigdirs="$noconfigdirs ld shellutils"
763     ;;
764   hppa*-*-pro*)
765     libgloss_dir=pa
766     ;;
767   hppa*-*-*)
768     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
769     # build on HP-UX 10.20.
770     noconfigdirs="$noconfigdirs ld shellutils ${libgcj}"
771     ;;
772   i960-*-*)
773     noconfigdirs="$noconfigdirs ${libgcj} gdb"
774     ;;
775   ia64*-*-elf*)
776     # No gdb support yet.
777     noconfigdirs="$noconfigdirs readline mmalloc libgui itcl gdb"
778     ;;
779   ia64*-**-hpux*)
780     # No ld support yet.
781     noconfigdirs="$noconfigdirs ${libgcj} libgui itcl ld"
782     ;;
783   ia64*-*-*vms*)
784     # No gdb or ld support yet.
785     noconfigdirs="$noconfigdirs ${libgcj} tix readline mmalloc libgui itcl gdb ld"
786     ;;
787   i[[3456789]]86-*-coff | i[[3456789]]86-*-elf)
788     noconfigdirs="$noconfigdirs ${libgcj}"
789     libgloss_dir=i386
790     ;;
791   i[[3456789]]86-*-linux*)
792     # The GCC port for glibc1 has no MD_FALLBACK_FRAME_STATE_FOR, so let's
793     # not build java stuff by default.
794     case "${target}" in
795       *-*-*libc1*)
796         noconfigdirs="$noconfigdirs ${libgcj}";;
797     esac
798
799     # This section makes it possible to build newlib natively on linux.
800     # If we are using a cross compiler then don't configure newlib.
801     if test x${is_cross_compiler} != xno ; then
802       noconfigdirs="$noconfigdirs target-newlib"
803     fi
804     noconfigdirs="$noconfigdirs target-libgloss"
805     # If we are not using a cross compiler, do configure newlib.
806     # Note however, that newlib will only be configured in this situation
807     # if the --with-newlib option has been given, because otherwise
808     # 'target-newlib' will appear in skipdirs.
809     ;;
810   i[[3456789]]86-w64-mingw*)
811     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
812     ;;
813   i[[3456789]]86-*-mingw*)
814     target_configdirs="$target_configdirs target-winsup"
815     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
816     ;;
817   x86_64-*-mingw*)
818     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
819     ;;
820   *-*-cygwin*)
821     target_configdirs="$target_configdirs target-libtermcap target-winsup"
822     noconfigdirs="$noconfigdirs target-gperf target-libgloss"
823     # always build newlib if winsup directory is present.
824     if test -d "$srcdir/winsup/cygwin"; then
825       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
826     elif test -d "$srcdir/newlib"; then
827       echo "Warning: winsup/cygwin is missing so newlib can't be built."
828     fi
829     ;;
830   i[[3456789]]86-*-interix* )
831     ;;
832   i[[3456789]]86-*-pe)
833     noconfigdirs="$noconfigdirs target-libgloss"
834     ;;
835   i[[3456789]]86-*-sco3.2v5*)
836     # The linker does not yet know about weak symbols in COFF,
837     # and is not configured to handle mixed ELF and COFF.
838     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
839     ;;
840   i[[3456789]]86-*-sco*)
841     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
842     ;;
843   i[[3456789]]86-*-solaris2*)
844     noconfigdirs="$noconfigdirs target-libgloss"
845     ;;
846   i[[3456789]]86-*-sysv4*)
847     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
848     ;;
849   i[[3456789]]86-*-beos*)
850     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
851     ;;
852   i[[3456789]]86-*-rdos*)
853     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
854     ;;
855   m32r-*-*)
856     noconfigdirs="$noconfigdirs ${libgcj}"
857     ;;
858   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
859     noconfigdirs="$noconfigdirs target-libiberty"
860     libgloss_dir=m68hc11
861     ;;
862   m68k-*-elf*)
863     noconfigdirs="$noconfigdirs ${libgcj}"
864     ;;
865   m68k-*-coff*)
866     noconfigdirs="$noconfigdirs ${libgcj}"
867     ;;
868   m68*-*-* | fido-*-*)
869     libgloss_dir=m68k
870     ;;
871   mmix-*-*)
872     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc gdb libgloss"
873     unsupported_languages="$unsupported_languages fortran java"
874     ;;
875   mn10200-*-*)
876     noconfigdirs="$noconfigdirs ${libgcj}"
877     ;;
878   mn10300-*-*)
879     noconfigdirs="$noconfigdirs ${libgcj}"
880     ;;
881   mt-*-*)
882     noconfigdirs="$noconfigdirs sim"
883     ;;
884   picochip-*-*)
885     noconfigdirs="$noconfigdirs target-libiberty"
886     ;;
887   powerpc-*-aix*)
888     # copied from rs6000-*-* entry
889     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
890     ;;
891   powerpc*-*-winnt* | powerpc*-*-pe*)
892     target_configdirs="$target_configdirs target-winsup"
893     noconfigdirs="$noconfigdirs gdb tcl tk make expect target-libgloss itcl gnuserv ${libgcj}"
894     # always build newlib.
895     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
896     ;;
897     # This is temporary until we can link against shared libraries
898   powerpcle-*-solaris*)
899     noconfigdirs="$noconfigdirs gdb sim make tcl tk expect itcl gnuserv ${libgcj}"
900     libgloss_dir=rs6000
901     ;;
902   powerpc-*-beos*)
903     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
904     ;;
905   powerpc-*-eabi)
906     noconfigdirs="$noconfigdirs ${libgcj}"
907     libgloss_dir=rs6000
908     ;;
909   powerpc-*-eabi* | powerpcle-*-eabi* | powerpc-*-rtems* )
910     libgloss_dir=rs6000
911     ;;
912   rs6000-*-lynxos*)
913     noconfigdirs="$noconfigdirs target-newlib gprof ${libgcj}"
914     ;;
915   rs6000-*-aix*)
916     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
917     ;;
918   rs6000-*-*)
919     noconfigdirs="$noconfigdirs gprof ${libgcj}"
920     ;;
921   m68k-apollo-*)
922     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss ${libgcj}"
923     ;;
924   microblaze*)
925     noconfigdirs="$noconfigdirs gprof target-libssp ${libgcj}"
926     ;;
927   mips*-sde-elf*)
928     skipdirs="$skipdirs target-libiberty"
929     noconfigdirs="$noconfigdirs ${libgcj}"
930     if test x$with_newlib = xyes; then
931       noconfigdirs="$noconfigdirs gprof"
932     fi
933     libgloss_dir=mips
934     ;;
935   mips*-*-irix5*)
936     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
937     ;;
938   mips*-*-irix6*)
939     # Linking libjava exceeds command-line length limits on at least
940     # IRIX 6.2, but not on IRIX 6.5.
941     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
942     # <oldham@codesourcery.com>
943     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
944     ;;
945   mips*-*-bsd*)
946     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
947     ;;
948   mips*-*-linux*)
949     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
950     ;;
951   mips*-*-*)
952     noconfigdirs="$noconfigdirs gprof ${libgcj}"
953     libgloss_dir=mips
954     ;;
955   romp-*-*)
956     noconfigdirs="$noconfigdirs bfd binutils ld gas opcodes target-libgloss ${libgcj}"
957     ;;
958   sh-*-* | sh64-*-*)
959     case "${host}" in
960       i[[3456789]]86-*-msdosdjgpp*) ;; # don't add gprof back in
961       *) skipdirs=`echo " ${skipdirs} " | sed -e 's/ gprof / /'` ;;
962     esac
963     case "${target}" in
964       sh*-*-elf)
965          noconfigdirs="$noconfigdirs ${libgcj}" ;;
966       *)
967          noconfigdirs="$noconfigdirs target-libgloss ${libgcj}" ;;
968     esac
969     ;;
970   sparclet-*-aout* | sparc86x-*-*)
971     libgloss_dir=sparc
972     ;;
973   sparc-*-elf*)
974     noconfigdirs="$noconfigdirs ${libgcj}"
975     ;;
976   sparc64-*-elf*)
977     noconfigdirs="$noconfigdirs ${libgcj}"
978     libgloss_dir=sparc
979     ;;
980   sparclite-*-*)
981     noconfigdirs="$noconfigdirs ${libgcj}"
982     libgloss_dir=sparc
983     ;;
984   sparc-*-sunos4*)
985     noconfigdirs="$noconfigdirs ${libgcj}"
986     if test x${is_cross_compiler} != xno ; then
987            noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
988     else
989            use_gnu_ld=no
990     fi
991     ;;
992   sparc-*-solaris2.[[0-6]] | sparc-*-solaris2.[[0-6]].*)
993     noconfigdirs="$noconfigdirs ${libgcj}"
994     ;;
995   sparc-*-solaris* | sparc64-*-solaris* | sparcv9-*-solaris*)
996     ;;
997   tic6x-*-*)
998     noconfigdirs="$noconfigdirs gdb sim ${libgcj}"
999     ;;
1000   v810-*-*)
1001     noconfigdirs="$noconfigdirs bfd binutils gas gcc gdb ld target-libstdc++-v3 opcodes target-libgloss ${libgcj}"
1002     ;;
1003   v850*-*-*)
1004     noconfigdirs="$noconfigdirs ${libgcj}"
1005     ;;
1006   vax-*-vms)
1007     noconfigdirs="$noconfigdirs bfd binutils gdb ld target-newlib opcodes target-libgloss ${libgcj}"
1008     ;;
1009   vax-*-*)
1010     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1011     ;;
1012   xtensa*-*-*)
1013     noconfigdirs="$noconfigdirs ${libgcj}"
1014     ;;
1015   ip2k-*-*)
1016     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj}"
1017     ;;
1018   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1019     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1020     ;;
1021   *-*-lynxos*)
1022     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1023     ;; 
1024   *-*-*)
1025     noconfigdirs="$noconfigdirs ${libgcj}"
1026     ;;
1027 esac
1028
1029 # If we aren't building newlib, then don't build libgloss, since libgloss
1030 # depends upon some newlib header files.
1031 case "${noconfigdirs}" in
1032   *target-libgloss*) ;;
1033   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1034 esac
1035
1036 # Work in distributions that contain no compiler tools, like Autoconf.
1037 tentative_cc=""
1038 host_makefile_frag=/dev/null
1039 if test -d ${srcdir}/config ; then
1040 case "${host}" in
1041   i[[3456789]]86-*-solaris2*)
1042     host_makefile_frag="config/mh-sysv4"
1043     ;;
1044   i[[3456789]]86-*-msdosdjgpp*)
1045     host_makefile_frag="config/mh-djgpp"
1046     ;;
1047   *-cygwin*)
1048     ACX_CHECK_CYGWIN_CAT_WORKS
1049     host_makefile_frag="config/mh-cygwin"
1050     ;;
1051   *-mingw*)
1052     host_makefile_frag="config/mh-mingw"
1053     ;;
1054   *-interix*)
1055     host_makefile_frag="config/mh-interix"
1056     ;;
1057   *-*-solaris2*)
1058     host_makefile_frag="config/mh-solaris"
1059     ;;
1060   hppa*-hp-hpux10*)
1061     tentative_cc="cc -Wp,-H256000"
1062     host_makefile_frag="config/mh-pa-hpux10"
1063     ;;
1064   hppa*-hp-hpux*)
1065     tentative_cc="cc -Wp,-H256000"
1066     host_makefile_frag="config/mh-pa"
1067     ;;
1068   hppa*-*)      
1069     host_makefile_frag="config/mh-pa"
1070     ;;
1071   *-hp-hpux*)
1072     tentative_cc="cc -Wp,-H256000"
1073     ;;
1074   *-*-darwin*)
1075     host_makefile_frag="config/mh-darwin"
1076     ;;
1077   powerpc-*-aix*)
1078     host_makefile_frag="config/mh-ppc-aix"
1079     ;;
1080   rs6000-*-aix*)
1081     host_makefile_frag="config/mh-ppc-aix"
1082     ;;
1083   *-*-lynxos*)
1084     # /bin/cc is less than useful for our purposes.  Always use GCC
1085     tentative_cc="/bin/gcc"
1086     ;;
1087   # This is placed last to prevent interfering with the cases above.
1088   i[[3456789]]86-*-*)
1089     # Build the stage2 and stage3 compilers with -fomit-frame-pointer.
1090     host_makefile_frag="config/mh-x86omitfp"
1091     ;;
1092 esac
1093 fi
1094
1095 # If we aren't going to be using gcc, see if we can extract a definition
1096 # of CC from the fragment.
1097 # Actually, use the 'pre-extracted' version above.
1098 if test -z "${CC}" && test "${build}" = "${host}" ; then
1099   IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
1100   found=
1101   for dir in $PATH; do
1102     test -z "$dir" && dir=.
1103     if test -f $dir/gcc; then
1104       found=yes
1105       break
1106     fi
1107   done
1108   IFS="$save_ifs"
1109   if test -z "${found}" && test -n "${tentative_cc}" ; then
1110     CC=$tentative_cc
1111   fi
1112 fi
1113
1114 if test "${build}" != "${host}" ; then
1115   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1116   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1117   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1118   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1119   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1120   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1121   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1122   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1123   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1124   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1125   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1126   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1127   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1128 else
1129   AR_FOR_BUILD="\$(AR)"
1130   AS_FOR_BUILD="\$(AS)"
1131   CC_FOR_BUILD="\$(CC)"
1132   CXX_FOR_BUILD="\$(CXX)"
1133   GCJ_FOR_BUILD="\$(GCJ)"
1134   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1135   GOC_FOR_BUILD="\$(GOC)"
1136   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1137   LD_FOR_BUILD="\$(LD)"
1138   NM_FOR_BUILD="\$(NM)"
1139   RANLIB_FOR_BUILD="\$(RANLIB)"
1140   WINDRES_FOR_BUILD="\$(WINDRES)"
1141   WINDMC_FOR_BUILD="\$(WINDMC)"
1142 fi
1143
1144 AC_PROG_CC
1145 AC_PROG_CXX
1146
1147 # We must set the default linker to the linker used by gcc for the correct
1148 # operation of libtool.  If LD is not defined and we are using gcc, try to
1149 # set the LD default to the ld used by gcc.
1150 if test -z "$LD"; then
1151   if test "$GCC" = yes; then
1152     case $build in
1153     *-*-mingw*)
1154       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1155     *)
1156       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1157     esac
1158     case $gcc_prog_ld in
1159     # Accept absolute paths.
1160     [[\\/]* | [A-Za-z]:[\\/]*)]
1161       LD="$gcc_prog_ld" ;;
1162     esac
1163   fi
1164 fi
1165
1166 ACX_PROG_GNAT
1167 ACX_PROG_CMP_IGNORE_INITIAL
1168
1169 # See if we are building gcc with C++.
1170 AC_ARG_ENABLE(build-with-cxx,
1171 [AS_HELP_STRING([--enable-build-with-cxx],
1172                 [build with C++ compiler instead of C compiler])],
1173 ENABLE_BUILD_WITH_CXX=$enableval,
1174 ENABLE_BUILD_WITH_CXX=no)
1175
1176 # Used for setting $lt_cv_objdir
1177 _LT_CHECK_OBJDIR
1178
1179 # Check for GMP, MPFR and MPC
1180 gmplibs="-lmpc -lmpfr -lgmp"
1181 gmpinc=
1182 have_gmp=no
1183
1184 # Specify a location for mpc
1185 # check for this first so it ends up on the link line before mpfr.
1186 AC_ARG_WITH(mpc,
1187 [AS_HELP_STRING([--with-mpc=PATH],
1188                 [specify prefix directory for installed MPC package.
1189                  Equivalent to --with-mpc-include=PATH/include
1190                  plus --with-mpc-lib=PATH/lib])])
1191 AC_ARG_WITH(mpc-include,
1192 [AS_HELP_STRING([--with-mpc-include=PATH],
1193                 [specify directory for installed MPC include files])])
1194 AC_ARG_WITH(mpc-lib,
1195 [AS_HELP_STRING([--with-mpc-lib=PATH],
1196                 [specify directory for the installed MPC library])])
1197
1198 if test "x$with_mpc" != x; then
1199   gmplibs="-L$with_mpc/lib $gmplibs"
1200   gmpinc="-I$with_mpc/include $gmpinc"
1201 fi
1202 if test "x$with_mpc_include" != x; then
1203   gmpinc="-I$with_mpc_include $gmpinc"
1204 fi
1205 if test "x$with_mpc_lib" != x; then
1206   gmplibs="-L$with_mpc_lib $gmplibs"
1207 fi
1208 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1209   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1210   gmpinc='-I$$s/mpc/src '"$gmpinc"
1211   # Do not test the mpc version.  Assume that it is sufficient, since
1212   # it is in the source tree, and the library has not been built yet
1213   # but it would be included on the link line in the version check below
1214   # hence making the test fail.
1215   have_gmp=yes
1216 fi
1217
1218 # Specify a location for mpfr
1219 # check for this first so it ends up on the link line before gmp.
1220 AC_ARG_WITH(mpfr-dir,
1221 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1222 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1223 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1224
1225 AC_ARG_WITH(mpfr,
1226 [AS_HELP_STRING([--with-mpfr=PATH],
1227                 [specify prefix directory for installed MPFR package.
1228                  Equivalent to --with-mpfr-include=PATH/include
1229                  plus --with-mpfr-lib=PATH/lib])])
1230 AC_ARG_WITH(mpfr-include,
1231 [AS_HELP_STRING([--with-mpfr-include=PATH],
1232                 [specify directory for installed MPFR include files])])
1233 AC_ARG_WITH(mpfr-lib,
1234 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1235                 [specify directory for the installed MPFR library])])
1236
1237 if test "x$with_mpfr" != x; then
1238   gmplibs="-L$with_mpfr/lib $gmplibs"
1239   gmpinc="-I$with_mpfr/include $gmpinc"
1240 fi
1241 if test "x$with_mpfr_include" != x; then
1242   gmpinc="-I$with_mpfr_include $gmpinc"
1243 fi
1244 if test "x$with_mpfr_lib" != x; then
1245   gmplibs="-L$with_mpfr_lib $gmplibs"
1246 fi
1247 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1248   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1249   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1250   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1251   # Do not test the mpfr version.  Assume that it is sufficient, since
1252   # it is in the source tree, and the library has not been built yet
1253   # but it would be included on the link line in the version check below
1254   # hence making the test fail.
1255   have_gmp=yes
1256 fi
1257
1258 # Specify a location for gmp
1259 AC_ARG_WITH(gmp-dir,
1260 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1261 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1262 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1263
1264 AC_ARG_WITH(gmp,
1265 [AS_HELP_STRING([--with-gmp=PATH],
1266                 [specify prefix directory for the installed GMP package.
1267                  Equivalent to --with-gmp-include=PATH/include
1268                  plus --with-gmp-lib=PATH/lib])])
1269 AC_ARG_WITH(gmp-include,
1270 [AS_HELP_STRING([--with-gmp-include=PATH],
1271                 [specify directory for installed GMP include files])])
1272 AC_ARG_WITH(gmp-lib,
1273 [AS_HELP_STRING([--with-gmp-lib=PATH],
1274                 [specify directory for the installed GMP library])])
1275
1276
1277 if test "x$with_gmp" != x; then
1278   gmplibs="-L$with_gmp/lib $gmplibs"
1279   gmpinc="-I$with_gmp/include $gmpinc"
1280 fi
1281 if test "x$with_gmp_include" != x; then
1282   gmpinc="-I$with_gmp_include $gmpinc"
1283 fi
1284 if test "x$with_gmp_lib" != x; then
1285   gmplibs="-L$with_gmp_lib $gmplibs"
1286 fi
1287 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1288   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1289   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1290   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1291   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1292   # Do not test the gmp version.  Assume that it is sufficient, since
1293   # it is in the source tree, and the library has not been built yet
1294   # but it would be included on the link line in the version check below
1295   # hence making the test fail.
1296   have_gmp=yes
1297 fi
1298
1299 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1300   have_gmp=yes
1301   saved_CFLAGS="$CFLAGS"
1302   CFLAGS="$CFLAGS $gmpinc"
1303   # Check for the recommended and required versions of GMP.
1304   AC_MSG_CHECKING([for the correct version of gmp.h])
1305   AC_TRY_COMPILE([#include "gmp.h"],[
1306   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1307   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1308   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1309   choke me
1310   #endif
1311   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1312   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1313   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1314   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1315   choke me
1316   #endif
1317   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1318    [AC_MSG_RESULT([no]); have_gmp=no])
1319
1320   # If we have GMP, check the MPFR version.
1321   if test x"$have_gmp" = xyes; then
1322     # Check for the recommended and required versions of MPFR.
1323     AC_MSG_CHECKING([for the correct version of mpfr.h])
1324     AC_TRY_COMPILE([#include <gmp.h>
1325     #include <mpfr.h>],[
1326     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1327     choke me
1328     #endif
1329     ], [AC_TRY_COMPILE([#include <gmp.h>
1330     #include <mpfr.h>],[
1331     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1332     choke me
1333     #endif
1334     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1335      [AC_MSG_RESULT([no]); have_gmp=no])
1336   fi
1337
1338   # Check for the MPC header version.
1339   if test x"$have_gmp" = xyes ; then
1340     # Check for the recommended and required versions of MPC.
1341     AC_MSG_CHECKING([for the correct version of mpc.h])
1342     AC_TRY_COMPILE([#include <mpc.h>],[
1343     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1344     choke me
1345     #endif
1346     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1347     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1348     choke me
1349     #endif
1350     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1351      [AC_MSG_RESULT([no]); have_gmp=no])
1352   fi
1353
1354   # Now check the MPFR library.
1355   if test x"$have_gmp" = xyes; then
1356     saved_LIBS="$LIBS"
1357     LIBS="$LIBS $gmplibs"
1358     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1359     AC_TRY_LINK([#include <mpc.h>],[
1360     mpfr_t n;
1361     mpfr_t x;
1362     mpc_t c;
1363     int t;
1364     mpfr_init (n);
1365     mpfr_init (x);
1366     mpfr_atan2 (n, n, x, GMP_RNDN);
1367     mpfr_erfc (n, x, GMP_RNDN);
1368     mpfr_subnormalize (x, t, GMP_RNDN);
1369     mpfr_clear(n);
1370     mpfr_clear(x);
1371     mpc_init2 (c, 53);
1372     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1373     mpc_cosh (c, c, MPC_RNDNN);
1374     mpc_pow (c, c, c, MPC_RNDNN);
1375     mpc_acosh (c, c, MPC_RNDNN);
1376     mpc_clear (c);
1377     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1378     LIBS="$saved_LIBS"
1379   fi
1380
1381   CFLAGS="$saved_CFLAGS"
1382
1383 # The library versions listed in the error message below should match
1384 # the HARD-minimums enforced above.
1385   if test x$have_gmp != xyes; then
1386     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1387 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1388 their locations.  Source code for these libraries can be found at
1389 their respective hosting sites as well as at
1390 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1391 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1392 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1393 make sure that you have installed both the libraries and the header
1394 files.  They may be located in separate packages.])
1395   fi
1396 fi
1397
1398 # Flags needed for both GMP, MPFR and/or MPC.
1399 AC_SUBST(gmplibs)
1400 AC_SUBST(gmpinc)
1401 AC_SUBST(extra_mpfr_configure_flags)
1402 AC_SUBST(extra_mpc_gmp_configure_flags)
1403 AC_SUBST(extra_mpc_mpfr_configure_flags)
1404
1405 # Allow host libstdc++ to be specified for static linking with PPL.
1406 AC_ARG_WITH(host-libstdcxx,
1407 [AS_HELP_STRING([--with-host-libstdcxx=L],
1408                 [use linker arguments L to link with libstdc++
1409                  when linking with PPL])])
1410
1411 case $with_host_libstdcxx in
1412   no|yes)
1413     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1414     ;;
1415 esac
1416
1417 # Linker flags to use for stage1 or when not boostrapping.
1418 AC_ARG_WITH(stage1-ldflags,
1419 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1420 [if test "$withval" = "no" -o "$withval" = "yes"; then
1421    stage1_ldflags=
1422  else
1423    stage1_ldflags=$withval
1424  fi],
1425 [stage1_ldflags=])
1426 AC_SUBST(stage1_ldflags)
1427
1428 # Libraries to use for stage1 or when not bootstrapping.
1429 AC_ARG_WITH(stage1-libs,
1430 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1431 [if test "$withval" = "no" -o "$withval" = "yes"; then
1432    stage1_libs=
1433  else
1434    stage1_libs=$withval
1435  fi],
1436 [stage1_libs=$with_host_libstdcxx])
1437 AC_SUBST(stage1_libs)
1438
1439 # Libraries to use for stage2 and later builds.  This defaults to the
1440 # argument passed to --with-host-libstdcxx.
1441 AC_ARG_WITH(boot-libs,
1442 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1443 [if test "$withval" = "no" -o "$withval" = "yes"; then
1444    poststage1_libs=
1445  else
1446    poststage1_libs=$withval
1447  fi],
1448 [poststage1_libs=$with_host_libstdcxx])
1449 AC_SUBST(poststage1_libs)
1450
1451 # Linker flags to use for stage2 and later builds.
1452 AC_ARG_WITH(boot-ldflags,
1453 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1454                 [linker flags for stage2 and later])],
1455 [if test "$withval" = "no" -o "$withval" = "yes"; then
1456    poststage1_ldflags=
1457  else
1458    poststage1_ldflags=$withval
1459  fi],
1460 [poststage1_ldflags=
1461  # In stages 2 and 3, default to linking libstdc++ and libgcc
1462  # statically.  But if the user explicitly specified the libraries to
1463  # use, trust that they are doing what they want.
1464  if test "$poststage1_libs" = ""; then
1465    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1466  fi])
1467 AC_SUBST(poststage1_ldflags)
1468
1469 # Check for PPL
1470 ppllibs=
1471 pplinc=
1472 pwllib=
1473
1474 AC_ARG_WITH(ppl,
1475 [AS_HELP_STRING([--with-ppl=PATH],
1476                 [specify prefix directory for the installed PPL package.
1477                  Equivalent to --with-ppl-include=PATH/include
1478                  plus --with-ppl-lib=PATH/lib])])
1479 AC_ARG_WITH(ppl-include,
1480 [AS_HELP_STRING([--with-ppl-include=PATH],
1481                 [specify directory for installed PPL include files])])
1482 AC_ARG_WITH(ppl-lib,
1483 [AS_HELP_STRING([--with-ppl-lib=PATH],
1484                 [specify directory for the installed PPL library])])
1485
1486 AC_ARG_ENABLE(ppl-version-check,
1487 [AS_HELP_STRING([--disable-ppl-version-check],
1488                 [disable check for PPL version])])
1489
1490 case $with_ppl in
1491   yes | no | "")
1492     ;;
1493   *)
1494     ppllibs="-L$with_ppl/lib"
1495     pplinc="-I$with_ppl/include $pplinc"
1496     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1497       with_ppl=yes
1498     else
1499       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1500     fi
1501     ;;
1502 esac
1503
1504 if test x"$with_ppl_include" != x; then
1505   pplinc="-I$with_ppl_include $pplinc"
1506   with_ppl=yes
1507 fi
1508
1509 if test "x$with_ppl_lib" != x; then
1510   ppllibs="-L$with_ppl_lib"
1511   with_ppl=yes
1512 fi
1513
1514 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1515   if test x"$enable_watchdog" = xyes; then
1516     pwllib="-lpwl"
1517   fi
1518   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1519   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1520   enable_ppl_version_check=no
1521   with_ppl=yes
1522 fi
1523
1524 if test "x$with_ppl" != xno; then
1525   if test "x$pwllib" = x; then
1526     saved_LIBS="$LIBS"
1527     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1528     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1529     LIBS="$saved_LIBS"
1530   fi
1531
1532   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1533
1534   if test "$enable_ppl_version_check" != no; then
1535     saved_CFLAGS="$CFLAGS"
1536     CFLAGS="$CFLAGS $pplinc $gmpinc"
1537     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1538     AC_TRY_COMPILE([#include "ppl_c.h"],[
1539     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1540     choke me
1541     #endif
1542     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1543     CFLAGS="$saved_CFLAGS"
1544   fi
1545 fi
1546
1547 # Flags needed for PPL
1548 AC_SUBST(ppllibs)
1549 AC_SUBST(pplinc)
1550
1551
1552 # Check for CLOOG
1553
1554 dnl Provide configure switches and initialize clooginc & clooglibs
1555 dnl with user input.
1556 CLOOG_INIT_FLAGS
1557 if test "x$with_ppl" = "xno"; then
1558   dnl Only execute fail-action, if CLooG has been requested.
1559   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1560   if test "${graphite_requested}" = yes; then
1561     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1562   fi
1563   with_cloog=no
1564 fi
1565 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1566   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1567   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1568   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1569 fi
1570 if test "x$with_cloog" != "xno"; then
1571   dnl The minimal version of CLooG required for Graphite.
1572   dnl
1573   dnl If we use CLooG-Legacy, the provided version information is
1574   dnl ignored.
1575   CLOOG_CHECK_VERSION(0,16,1)
1576
1577   dnl Only execute fail-action, if CLooG has been requested.
1578   CLOOG_IF_FAILED([
1579     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1580 fi
1581
1582 # Check for LTO support.
1583 AC_ARG_ENABLE(lto,
1584 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1585 enable_lto=$enableval,
1586 enable_lto=yes; default_enable_lto=yes)
1587
1588 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1589   build_lto_plugin=yes
1590 ],[if test x"$default_enable_lto" = x"yes" ; then
1591     case $target in
1592       *-apple-darwin9 | *-cygwin* | *-mingw*) ;;
1593       # On other non-ELF platforms, LTO has yet to be validated.
1594       *) enable_lto=no ;;
1595     esac
1596   else
1597   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1598   # It would also be nice to check the binutils support, but we don't
1599   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1600   # warn during gcc/ subconfigure; unless you're bootstrapping with
1601   # -flto it won't be needed until after installation anyway.
1602     case $target in
1603       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1604       *) if test x"$enable_lto" = x"yes"; then
1605         AC_MSG_ERROR([LTO support is not enabled for this target.])
1606         fi
1607       ;;
1608     esac
1609   fi
1610   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1611   # Build it unless LTO was explicitly disabled.
1612   case $target in
1613     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1614     *) ;;
1615   esac
1616 ])
1617
1618
1619 # By default, C is the only stage 1 language.
1620 stage1_languages=,c,
1621
1622 # Target libraries that we bootstrap.
1623 bootstrap_target_libs=,target-libgcc,
1624
1625 # Figure out what language subdirectories are present.
1626 # Look if the user specified --enable-languages="..."; if not, use
1627 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1628 # go away some day.
1629 # NB:  embedded tabs in this IF block -- do not untabify
1630 if test -d ${srcdir}/gcc; then
1631   if test x"${enable_languages+set}" != xset; then
1632     if test x"${LANGUAGES+set}" = xset; then
1633       enable_languages="${LANGUAGES}"
1634         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1635     else
1636       enable_languages=all
1637     fi
1638   else
1639     if test x"${enable_languages}" = x ||
1640        test x"${enable_languages}" = xyes;
1641        then
1642       echo configure.in: --enable-languages needs at least one language argument 1>&2
1643       exit 1
1644     fi
1645   fi
1646   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1647
1648   # 'f95' is the old name for the 'fortran' language. We issue a warning
1649   # and make the substitution.
1650   case ,${enable_languages}, in
1651     *,f95,*)
1652       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1653       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1654       ;;
1655   esac
1656
1657   # First scan to see if an enabled language requires some other language.
1658   # We assume that a given config-lang.in will list all the language
1659   # front ends it requires, even if some are required indirectly.
1660   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1661     case ${lang_frag} in
1662       ..) ;;
1663       # The odd quoting in the next line works around
1664       # an apparent bug in bash 1.12 on linux.
1665       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1666       *)
1667         # From the config-lang.in, get $language, $lang_requires, and
1668         # $lang_requires_boot_languages.
1669         language=
1670         lang_requires=
1671         lang_requires_boot_languages=
1672         . ${lang_frag}
1673         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1674           case ,${enable_languages}, in
1675             *,$other,*) ;;
1676             *,all,*) ;;
1677             *,$language,*)
1678               echo " \`$other' language required by \`$language'; enabling" 1>&2
1679               enable_languages="${enable_languages},${other}"
1680               ;;
1681           esac
1682         done
1683         for other in ${lang_requires_boot_languages} ; do
1684           if test "$other" != "c"; then
1685             case ,${enable_stage1_languages}, in
1686               *,$other,*) ;;
1687               *,all,*) ;;
1688               *)
1689                 case ,${enable_languages}, in
1690                   *,$language,*)
1691                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1692                     enable_stage1_languages="$enable_stage1_languages,${other}"
1693                     ;;
1694                 esac
1695                 ;;
1696             esac
1697           fi
1698         done
1699         ;;
1700     esac
1701   done
1702
1703   new_enable_languages=,c,
1704
1705   # If LTO is enabled, add the LTO front end.
1706   extra_host_libiberty_configure_flags=
1707   if test "$enable_lto" = "yes" ; then
1708     case ,${enable_languages}, in
1709       *,lto,*) ;;
1710       *) enable_languages="${enable_languages},lto" ;;
1711     esac
1712     if test "${build_lto_plugin}" = "yes" ; then
1713       configdirs="$configdirs lto-plugin"
1714       extra_host_libiberty_configure_flags=--enable-shared
1715     fi
1716   fi
1717   AC_SUBST(extra_host_libiberty_configure_flags)
1718
1719   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1720   potential_languages=,c,
1721
1722   enabled_target_libs=
1723   disabled_target_libs=
1724
1725   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1726     case ${lang_frag} in
1727       ..) ;;
1728       # The odd quoting in the next line works around
1729       # an apparent bug in bash 1.12 on linux.
1730       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1731       *)
1732         # From the config-lang.in, get $language, $target_libs, 
1733         # $lang_dirs, $boot_language, and $build_by_default
1734         language=
1735         target_libs=
1736         lang_dirs=
1737         subdir_requires=
1738         boot_language=no
1739         build_by_default=yes
1740         . ${lang_frag}
1741         if test x${language} = x; then
1742           echo "${lang_frag} doesn't set \$language." 1>&2
1743           exit 1
1744         fi
1745
1746         if test "$language" = "c++" \
1747            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1748           boot_language=yes
1749         fi
1750
1751         case ,${enable_languages}, in
1752           *,${language},*)
1753             # Language was explicitly selected; include it.
1754             add_this_lang=yes
1755             ;;
1756           *,all,*)
1757             # 'all' was selected, select it if it is a default language
1758             add_this_lang=${build_by_default}
1759             ;;
1760           *)
1761             add_this_lang=no
1762             ;;
1763         esac
1764
1765         # Disable languages that need other directories if these aren't available.
1766         for i in $subdir_requires; do
1767           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1768           case ,${enable_languages}, in
1769             *,${language},*)
1770               # Specifically requested language; tell them.
1771               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1772               ;;
1773             *)
1774               # Silently disable.
1775               add_this_lang=unsupported
1776               ;;
1777           esac
1778         done
1779
1780         # Disable Ada if no preexisting GNAT is available.
1781         case ,${enable_languages},:${language}:${have_gnat} in
1782           *,${language},*:ada:no)
1783             # Specifically requested language; tell them.
1784             AC_MSG_ERROR([GNAT is required to build $language])
1785             ;;
1786           *:ada:no)
1787             # Silently disable.
1788             add_this_lang=unsupported
1789             ;;
1790         esac
1791
1792         # Disable a language that is unsupported by the target.
1793         case " $unsupported_languages " in
1794           *" $language "*)
1795             add_this_lang=unsupported
1796             ;;
1797         esac
1798
1799         case $add_this_lang in
1800           unsupported)
1801             # Remove language-dependent dirs.
1802             disabled_target_libs="$disabled_target_libs $target_libs"
1803             noconfigdirs="$noconfigdirs $lang_dirs"
1804             ;;
1805           no)
1806             # Remove language-dependent dirs; still show language as supported.
1807             disabled_target_libs="$disabled_target_libs $target_libs"
1808             noconfigdirs="$noconfigdirs $lang_dirs"
1809             potential_languages="${potential_languages}${language},"
1810             ;;
1811           yes)
1812             new_enable_languages="${new_enable_languages}${language},"
1813             potential_languages="${potential_languages}${language},"
1814             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1815             enabled_target_libs="$enabled_target_libs $target_libs"
1816             case "${boot_language}:,$enable_stage1_languages," in
1817               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1818                 # Add to (comma-separated) list of stage 1 languages.
1819                 case ",$stage1_languages," in
1820                   *,$language,* | ,yes, | ,all,) ;;
1821                   *) stage1_languages="${stage1_languages}${language}," ;;
1822                 esac
1823                 # We need to bootstrap any supporting libraries.
1824                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1825                 ;;
1826             esac
1827             ;;
1828         esac
1829         ;;
1830     esac
1831   done
1832
1833   # Add target libraries which are only needed for disabled languages
1834   # to noconfigdirs.
1835   if test -n "$disabled_target_libs"; then
1836     for dir in $disabled_target_libs; do
1837       case " $enabled_target_libs " in
1838       *" ${dir} "*) ;;
1839       *) noconfigdirs="$noconfigdirs $dir" ;;
1840       esac
1841     done
1842   fi
1843
1844   AC_ARG_ENABLE(stage1-languages,
1845   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1846                   [choose additional languages to build during
1847                   stage1.  Mostly useful for compiler development])],
1848   [case ,${enable_stage1_languages}, in
1849     ,no,|,,)
1850       # Set it to something that will have no effect in the loop below
1851       enable_stage1_languages=c ;;
1852     ,yes,)
1853       enable_stage1_languages=`echo $new_enable_languages | \
1854         sed -e "s/^,//" -e "s/,$//" ` ;;
1855     *,all,*)
1856       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1857         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1858   esac
1859
1860   # Add "good" languages from enable_stage1_languages to stage1_languages,
1861   # while "bad" languages go in missing_languages.  Leave no duplicates.
1862   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1863     case $potential_languages in
1864       *,$i,*)
1865         case $stage1_languages in
1866           *,$i,*) ;;
1867           *) stage1_languages="$stage1_languages$i," ;;
1868         esac ;;
1869       *)
1870         case $missing_languages in
1871           *,$i,*) ;;
1872           *) missing_languages="$missing_languages$i," ;;
1873         esac ;;
1874      esac
1875   done])
1876
1877   # Remove leading/trailing commas that were added for simplicity
1878   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1879   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1880   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1881   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1882
1883   if test "x$missing_languages" != x; then
1884     AC_MSG_ERROR([
1885 The following requested languages could not be built: ${missing_languages}
1886 Supported languages are: ${potential_languages}])
1887   fi
1888   if test "x$new_enable_languages" != "x$enable_languages"; then
1889     echo The following languages will be built: ${new_enable_languages}
1890     enable_languages="$new_enable_languages"
1891   fi
1892
1893   AC_SUBST(stage1_languages)
1894   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1895 fi
1896
1897 # Handle --disable-<component> generically.
1898 for dir in $configdirs $build_configdirs $target_configdirs ; do
1899   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1900   varname=`echo $dirname | sed -e s/+/_/g`
1901   if eval test x\${enable_${varname}} "=" xno ; then
1902     noconfigdirs="$noconfigdirs $dir"
1903   fi
1904 done
1905
1906 # Check for Boehm's garbage collector
1907 AC_ARG_ENABLE(objc-gc,
1908 [AS_HELP_STRING([--enable-objc-gc],
1909                 [enable use of Boehm's garbage collector with the
1910                  GNU Objective-C runtime])],
1911 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1912   *,objc,*:*:yes:*target-boehm-gc*)
1913     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1914     ;;
1915 esac])
1916
1917 # Make sure we only build Boehm's garbage collector if required.
1918 case ,${enable_languages},:${enable_objc_gc} in
1919   *,objc,*:yes)
1920     # Keep target-boehm-gc if requested for Objective-C.
1921     ;;
1922   *)
1923     # Otherwise remove target-boehm-gc depending on target-libjava.
1924     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1925       noconfigdirs="$noconfigdirs target-boehm-gc"
1926     fi
1927     ;;
1928 esac
1929
1930 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1931 # $build_configdirs and $target_configdirs.
1932 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1933
1934 notsupp=""
1935 for dir in . $skipdirs $noconfigdirs ; do
1936   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1937   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1938     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1939     if test -r $srcdir/$dirname/configure ; then
1940       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1941         true
1942       else
1943         notsupp="$notsupp $dir"
1944       fi
1945     fi
1946   fi
1947   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1948     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1949     if test -r $srcdir/$dirname/configure ; then
1950       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1951         true
1952       else
1953         notsupp="$notsupp $dir"
1954       fi
1955     fi
1956   fi
1957   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1958     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1959     if test -r $srcdir/$dirname/configure ; then
1960       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1961         true
1962       else
1963         notsupp="$notsupp $dir"
1964       fi
1965     fi
1966   fi
1967 done
1968
1969 # Sometimes the tools are distributed with libiberty but with no other
1970 # libraries.  In that case, we don't want to build target-libiberty.
1971 # Don't let libgcc imply libiberty either.
1972 if test -n "${target_configdirs}" ; then
1973   libgcc=
1974   others=
1975   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
1976     if test "$i" = "libgcc"; then
1977       libgcc=target-libgcc
1978     elif test "$i" != "libiberty" ; then
1979       if test -r $srcdir/$i/configure ; then
1980         others=yes;
1981         break;
1982       fi
1983     fi
1984   done
1985   if test -z "${others}" ; then
1986     target_configdirs=$libgcc
1987   fi
1988 fi
1989
1990 # Quietly strip out all directories which aren't configurable in this tree.
1991 # This relies on all configurable subdirectories being autoconfiscated, which
1992 # is now the case.
1993 build_configdirs_all="$build_configdirs"
1994 build_configdirs=
1995 for i in ${build_configdirs_all} ; do
1996   j=`echo $i | sed -e s/build-//g` 
1997   if test -f ${srcdir}/$j/configure ; then
1998     build_configdirs="${build_configdirs} $i"
1999   fi
2000 done
2001
2002 configdirs_all="$configdirs"
2003 configdirs=
2004 for i in ${configdirs_all} ; do
2005   if test -f ${srcdir}/$i/configure ; then
2006     configdirs="${configdirs} $i"
2007   fi
2008 done
2009
2010 target_configdirs_all="$target_configdirs"
2011 target_configdirs=
2012 for i in ${target_configdirs_all} ; do
2013   j=`echo $i | sed -e s/target-//g` 
2014   if test -f ${srcdir}/$j/configure ; then
2015     target_configdirs="${target_configdirs} $i"
2016   fi
2017 done
2018
2019 # Produce a warning message for the subdirs we can't configure.
2020 # This isn't especially interesting in the Cygnus tree, but in the individual
2021 # FSF releases, it's important to let people know when their machine isn't
2022 # supported by the one or two programs in a package.
2023
2024 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2025   # If $appdirs is non-empty, at least one of those directories must still
2026   # be configured, or we error out.  (E.g., if the gas release supports a
2027   # specified target in some subdirs but not the gas subdir, we shouldn't
2028   # pretend that all is well.)
2029   if test -n "$appdirs" ; then
2030     for dir in $appdirs ; do
2031       if test -r $dir/Makefile.in ; then
2032         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2033           appdirs=""
2034           break
2035         fi
2036         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2037           appdirs=""
2038           break
2039         fi
2040       fi
2041     done
2042     if test -n "$appdirs" ; then
2043       echo "*** This configuration is not supported by this package." 1>&2
2044       exit 1
2045     fi
2046   fi
2047   # Okay, some application will build, or we don't care to check.  Still
2048   # notify of subdirs not getting built.
2049   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2050   echo "    ${notsupp}" 1>&2
2051   echo "    (Any other directories should still work fine.)" 1>&2
2052 fi
2053
2054 case "$host" in
2055   *msdosdjgpp*)
2056     enable_gdbtk=no ;;
2057 esac
2058
2059 # To find our prefix, in gcc_cv_tool_prefix.
2060 ACX_TOOL_DIRS
2061
2062 copy_dirs=
2063
2064 AC_ARG_WITH([build-sysroot], 
2065   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2066                   [use sysroot as the system root during the build])],
2067   [if test x"$withval" != x ; then
2068      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2069    fi],
2070   [SYSROOT_CFLAGS_FOR_TARGET=])
2071 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2072
2073 AC_ARG_WITH([debug-prefix-map],
2074   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2075                   [map A to B, C to D ... in debug information])],
2076   [if test x"$withval" != x; then
2077      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2078      for debug_map in $withval; do
2079        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2080      done
2081    fi],
2082   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2083 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2084
2085 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2086 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2087 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2088 # We want to ensure that TARGET libraries (which we know are built with
2089 # gcc) are built with "-O2 -g", so include those options when setting
2090 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2091 if test "x$CFLAGS_FOR_TARGET" = x; then
2092   CFLAGS_FOR_TARGET=$CFLAGS
2093   case " $CFLAGS " in
2094     *" -O2 "*) ;;
2095     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2096   esac
2097   case " $CFLAGS " in
2098     *" -g "* | *" -g3 "*) ;;
2099     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2100   esac
2101 fi
2102 AC_SUBST(CFLAGS_FOR_TARGET)
2103
2104 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2105   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2106   case " $CXXFLAGS " in
2107     *" -O2 "*) ;;
2108     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2109   esac
2110   case " $CXXFLAGS " in
2111     *" -g "* | *" -g3 "*) ;;
2112     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2113   esac
2114 fi
2115 AC_SUBST(CXXFLAGS_FOR_TARGET)
2116
2117 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2118 # the named directory are copied to $(tooldir)/sys-include.
2119 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2120   if test x${is_cross_compiler} = xno ; then
2121     echo 1>&2 '***' --with-headers is only supported when cross compiling
2122     exit 1
2123   fi
2124   if test x"${with_headers}" != xyes ; then
2125     x=${gcc_cv_tool_prefix}
2126     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2127   fi
2128 fi
2129
2130 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2131 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2132 # are permitted.
2133 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2134   if test x${is_cross_compiler} = xno ; then
2135     echo 1>&2 '***' --with-libs is only supported when cross compiling
2136     exit 1
2137   fi
2138   if test x"${with_libs}" != xyes ; then
2139     # Copy the libraries in reverse order, so that files in the first named
2140     # library override files in subsequent libraries.
2141     x=${gcc_cv_tool_prefix}
2142     for l in ${with_libs}; do
2143       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2144     done
2145   fi
2146 fi
2147
2148 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2149 #
2150 # This is done by determining whether or not the appropriate directory
2151 # is available, and by checking whether or not specific configurations
2152 # have requested that this magic not happen.
2153
2154 # The command line options always override the explicit settings in 
2155 # configure.in, and the settings in configure.in override this magic.
2156 #
2157 # If the default for a toolchain is to use GNU as and ld, and you don't 
2158 # want to do that, then you should use the --without-gnu-as and
2159 # --without-gnu-ld options for the configure script.  Similarly, if
2160 # the default is to use the included zlib and you don't want to do that,
2161 # you should use the --with-system-zlib option for the configure script.
2162
2163 if test x${use_gnu_as} = x &&
2164    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2165   with_gnu_as=yes
2166   extra_host_args="$extra_host_args --with-gnu-as"
2167 fi
2168
2169 if test x${use_gnu_ld} = x &&
2170    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2171   with_gnu_ld=yes
2172   extra_host_args="$extra_host_args --with-gnu-ld"
2173 fi
2174
2175 if test x${use_included_zlib} = x &&
2176    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2177   :
2178 else
2179   with_system_zlib=yes
2180   extra_host_args="$extra_host_args --with-system-zlib"
2181 fi
2182
2183 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2184 # can detect this case.
2185
2186 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2187   with_newlib=yes
2188   extra_host_args="$extra_host_args --with-newlib"
2189 fi
2190
2191 # Handle ${copy_dirs}
2192 set fnord ${copy_dirs}
2193 shift
2194 while test $# != 0 ; do
2195   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2196     :
2197   else
2198     echo Copying $1 to $2
2199
2200     # Use the install script to create the directory and all required
2201     # parent directories.
2202     if test -d $2 ; then
2203       :
2204     else
2205       echo >config.temp
2206       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2207     fi
2208
2209     # Copy the directory, assuming we have tar.
2210     # FIXME: Should we use B in the second tar?  Not all systems support it.
2211     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2212
2213     # It is the responsibility of the user to correctly adjust all
2214     # symlinks.  If somebody can figure out how to handle them correctly
2215     # here, feel free to add the code.
2216
2217     echo $1 > $2/COPIED
2218   fi
2219   shift; shift
2220 done
2221
2222 # Determine a target-dependent exec_prefix that the installed
2223 # gcc will search in.  Keep this list sorted by triplet, with
2224 # the *-*-osname triplets last.
2225 md_exec_prefix=
2226 case "${target}" in
2227   alpha*-*-*vms*)
2228     md_exec_prefix=/gnu/lib/gcc-lib
2229     ;;
2230   i[[34567]]86-pc-msdosdjgpp*)
2231     md_exec_prefix=/dev/env/DJDIR/bin
2232     ;;
2233   i[[34567]]86-*-sco3.2v5*)
2234     if test $with_gnu_as = yes; then
2235       md_exec_prefix=/usr/gnu/bin
2236     else
2237       md_exec_prefix=/usr/ccs/bin/elf
2238     fi
2239     ;;
2240
2241   mn10300-*-* | \
2242   powerpc-*-chorusos* | \
2243   powerpc*-*-eabi* | \
2244   powerpc*-*-sysv* | \
2245   powerpc*-*-kaos* | \
2246   s390x-ibm-tpf*)
2247     md_exec_prefix=/usr/ccs/bin
2248     ;;
2249   sparc64-*-elf*)
2250     ;;
2251   v850*-*-*)
2252     md_exec_prefix=/usr/ccs/bin
2253     ;;
2254   xtensa*-*-elf*)
2255     ;;
2256
2257   *-*-beos* | \
2258   *-*-elf* | \
2259   *-*-hpux* | \
2260   *-*-netware* | \
2261   *-*-nto-qnx* | \
2262   *-*-rtems* | \
2263   *-*-solaris2* | \
2264   *-*-sysv[[45]]* | \
2265   *-*-vxworks* | \
2266   *-wrs-windiss)
2267     md_exec_prefix=/usr/ccs/bin
2268     ;;
2269 esac
2270
2271 extra_arflags_for_target=
2272 extra_nmflags_for_target=
2273 extra_ranlibflags_for_target=
2274 target_makefile_frag=/dev/null
2275 case "${target}" in
2276   mep*-*-*)
2277     target_makefile_frag="config/mt-mep"
2278     ;;
2279   spu-*-*)
2280     target_makefile_frag="config/mt-spu"
2281     ;;
2282   mips*-sde-elf*)
2283     target_makefile_frag="config/mt-sde"
2284     ;;
2285   mipsisa*-*-elfoabi*)
2286     target_makefile_frag="config/mt-mips-elfoabi"
2287     ;;
2288   mips*-*-*linux* | mips*-*-gnu*)
2289     target_makefile_frag="config/mt-mips-gnu"
2290     ;;
2291   *-*-netware*)
2292     target_makefile_frag="config/mt-netware"
2293     ;;
2294   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2295     target_makefile_frag="config/mt-gnu"
2296     ;;
2297   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2298     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm 
2299     # commands to handle both 32-bit and 64-bit objects.  These flags are
2300     # harmless if we're using GNU nm or ar.
2301     extra_arflags_for_target=" -X32_64"
2302     extra_nmflags_for_target=" -B -X32_64"
2303     ;;
2304   *-*-darwin[[3-9]]*)
2305     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2306     extra_ranlibflags_for_target=" -c"
2307     ;;
2308   mips*-*-pe | sh*-*-pe | *arm-wince-pe)
2309     target_makefile_frag="config/mt-wince"
2310     ;;
2311 esac
2312
2313 alphaieee_frag=/dev/null
2314 case $target in
2315   alpha*-*-*)
2316     # This just makes sure to use the -mieee option to build target libs.
2317     # This should probably be set individually by each library.
2318     alphaieee_frag="config/mt-alphaieee"
2319     ;;
2320 esac
2321
2322 # If --enable-target-optspace always use -Os instead of -O2 to build
2323 # the target libraries, similarly if it is not specified, use -Os
2324 # on selected platforms.
2325 ospace_frag=/dev/null
2326 case "${enable_target_optspace}:${target}" in
2327   yes:*)
2328     ospace_frag="config/mt-ospace"
2329     ;;
2330   :d30v-*)
2331     ospace_frag="config/mt-d30v"
2332     ;;
2333   :m32r-* | :d10v-* | :fr30-*)
2334     ospace_frag="config/mt-ospace"
2335     ;;
2336   no:* | :*)
2337     ;;
2338   *)
2339     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2340     ;;
2341 esac
2342
2343 # Default to using --with-stabs for certain targets.
2344 if test x${with_stabs} = x ; then
2345   case "${target}" in
2346   mips*-*-irix[[56]]*)
2347     ;;
2348   mips*-*-* | alpha*-*-osf*)
2349     with_stabs=yes;
2350     extra_host_args="${extra_host_args} --with-stabs"
2351     ;;
2352   esac
2353 fi
2354
2355 # hpux11 in 64bit mode has libraries in a weird place.  Arrange to find
2356 # them automatically.
2357 case "${host}" in
2358   hppa*64*-*-hpux11*)   
2359     extra_host_args="$extra_host_args -x-libraries=/usr/lib/pa20_64 -x-includes=/usr/X11R6/include"
2360     ;;
2361 esac
2362
2363 # Some systems (e.g., one of the i386-aix systems the gas testers are
2364 # using) don't handle "\$" correctly, so don't use it here.
2365 tooldir='${exec_prefix}'/${target_noncanonical}
2366 build_tooldir=${tooldir}
2367
2368 # Create a .gdbinit file which runs the one in srcdir
2369 # and tells GDB to look there for source files.
2370
2371 if test -r ${srcdir}/.gdbinit ; then
2372   case ${srcdir} in
2373     .) ;;
2374     *) cat > ./.gdbinit <<EOF
2375 # ${NO_EDIT}
2376 dir ${srcdir}
2377 dir .
2378 source ${srcdir}/.gdbinit
2379 EOF
2380     ;;
2381   esac
2382 fi
2383
2384 # Make sure that the compiler is able to generate an executable.  If it
2385 # can't, we are probably in trouble.  We don't care whether we can run the
2386 # executable--we might be using a cross compiler--we only care whether it
2387 # can be created.  At this point the main configure script has set CC.
2388 we_are_ok=no
2389 echo "int main () { return 0; }" > conftest.c
2390 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2391 if test $? = 0 ; then
2392   if test -s conftest || test -s conftest.exe ; then
2393     we_are_ok=yes
2394   fi
2395 fi 
2396 case $we_are_ok in
2397   no)
2398     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2399     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2400     rm -f conftest*
2401     exit 1
2402     ;;
2403 esac
2404 rm -f conftest*
2405
2406 # The Solaris /usr/ucb/cc compiler does not appear to work.
2407 case "${host}" in
2408   sparc-sun-solaris2*)
2409       CCBASE="`echo ${CC-cc} | sed 's/ .*$//'`"
2410       if test "`type $CCBASE | sed 's/^[[^/]]*//'`" = "/usr/ucb/cc" ; then
2411           could_use=
2412           test -d /opt/SUNWspro/bin && could_use="/opt/SUNWspro/bin"
2413           if test -d /opt/cygnus/bin ; then
2414               if test "$could_use" = "" ; then
2415                   could_use="/opt/cygnus/bin"
2416               else
2417                   could_use="$could_use or /opt/cygnus/bin"
2418               fi
2419           fi
2420         if test "$could_use" = "" ; then
2421             echo "Warning: compilation may fail because you're using"
2422             echo "/usr/ucb/cc.  You should change your PATH or CC "
2423             echo "variable and rerun configure."
2424         else
2425             echo "Warning: compilation may fail because you're using"
2426             echo "/usr/ucb/cc, when you should use the C compiler from"
2427             echo "$could_use.  You should change your"
2428             echo "PATH or CC variable and rerun configure."
2429         fi
2430       fi
2431   ;;
2432 esac
2433
2434 # Decide which environment variable is used to find dynamic libraries.
2435 case "${host}" in
2436   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2437   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2438   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2439   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2440 esac
2441
2442 # On systems where the dynamic library environment variable is PATH,
2443 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2444 # built executables to PATH.
2445 if test "$RPATH_ENVVAR" = PATH; then
2446   GCC_SHLIB_SUBDIR=/shlib
2447 else
2448   GCC_SHLIB_SUBDIR=
2449 fi
2450
2451 # Record target_configdirs and the configure arguments for target and
2452 # build configuration in Makefile.
2453 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2454 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2455
2456 # If we are building libgomp, bootstrap it.
2457 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2458   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2459 fi
2460
2461 # Determine whether gdb needs tk/tcl or not.
2462 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2463 # and in that case we want gdb to be built without tk.  Ugh!
2464 # In fact I believe gdb is the *only* package directly dependent on tk,
2465 # so we should be able to put the 'maybe's in unconditionally and
2466 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2467 # 100% sure that that's safe though.
2468
2469 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2470 case "$enable_gdbtk" in
2471   no)
2472     GDB_TK="" ;;
2473   yes)
2474     GDB_TK="${gdb_tk}" ;;
2475   *)
2476     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2477     # distro.  Eventually someone will fix this and move Insight, nee
2478     # gdbtk to a separate directory.
2479     if test -d ${srcdir}/gdb/gdbtk ; then
2480       GDB_TK="${gdb_tk}"
2481     else
2482       GDB_TK=""
2483     fi
2484     ;;
2485 esac
2486 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2487 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2488
2489 # Strip out unwanted targets.
2490
2491 # While at that, we remove Makefiles if we were started for recursive
2492 # configuration, so that the top-level Makefile reconfigures them,
2493 # like we used to do when configure itself was recursive.
2494
2495 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2496 # but now we're fixing up the Makefile ourselves with the additional
2497 # commands passed to AC_CONFIG_FILES.  Use separate variables
2498 # extrasub-{build,host,target} not because there is any reason to split
2499 # the substitutions up that way, but only to remain below the limit of
2500 # 99 commands in a script, for HP-UX sed.
2501 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2502
2503 AC_ARG_ENABLE([bootstrap],
2504 [AS_HELP_STRING([--enable-bootstrap],
2505                 [enable bootstrapping @<:@yes if native build@:>@])],,
2506 enable_bootstrap=default)
2507
2508 # Issue errors and warnings for invalid/strange bootstrap combinations.
2509 case "$configdirs" in
2510   *gcc*) have_compiler=yes ;;
2511   *) have_compiler=no ;;
2512 esac
2513
2514 case "$have_compiler:$host:$target:$enable_bootstrap" in
2515   *:*:*:no) ;;
2516
2517   # Default behavior.  Enable bootstrap if we have a compiler
2518   # and we are in a native configuration.
2519   yes:$build:$build:default)
2520     enable_bootstrap=yes ;;
2521
2522   *:*:*:default)
2523     enable_bootstrap=no ;;
2524
2525   # We have a compiler and we are in a native configuration, bootstrap is ok
2526   yes:$build:$build:yes)
2527     ;;
2528
2529   # Other configurations, but we have a compiler.  Assume the user knows
2530   # what he's doing.
2531   yes:*:*:yes)
2532     AC_MSG_WARN([trying to bootstrap a cross compiler])
2533     ;;
2534
2535   # No compiler: if they passed --enable-bootstrap explicitly, fail
2536   no:*:*:yes)
2537     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2538
2539   # Fail if wrong command line
2540   *)
2541     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2542     ;;
2543 esac
2544
2545 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2546   *,c++,*:yes:yes) ;;
2547   *:yes:yes)
2548     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2549     ;;
2550 esac
2551
2552 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2553   yes:yes:*\ gold\ *:*,c++,*) ;;
2554   yes:yes:*\ gold\ *:*)
2555     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2556     ;;
2557 esac
2558
2559 # Adjust the toplevel makefile according to whether bootstrap was selected.
2560 case $enable_bootstrap in
2561   yes)
2562     bootstrap_suffix=bootstrap
2563     BUILD_CONFIG=bootstrap-debug
2564     ;;
2565   no)
2566     bootstrap_suffix=no-bootstrap
2567     BUILD_CONFIG=
2568     ;;
2569 esac
2570
2571 AC_MSG_CHECKING(for default BUILD_CONFIG)
2572
2573 AC_ARG_WITH([build-config],
2574   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2575                   [use config/NAME.mk build configuration])],
2576   [case $with_build_config in
2577    yes) with_build_config= ;;
2578    no) with_build_config= BUILD_CONFIG= ;;
2579    esac])
2580
2581 if test "x${with_build_config}" != x; then
2582   BUILD_CONFIG=$with_build_config
2583 else
2584   case $BUILD_CONFIG in
2585   bootstrap-debug)
2586     if echo "int f (void) { return 0; }" > conftest.c &&
2587        ${CC} -c conftest.c &&
2588        mv conftest.o conftest.o.g0 &&
2589        ${CC} -c -g conftest.c &&
2590        mv conftest.o conftest.o.g &&
2591        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2592       :
2593     else
2594       BUILD_CONFIG=
2595     fi
2596     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2597     ;;
2598   esac
2599 fi
2600 AC_MSG_RESULT($BUILD_CONFIG)
2601 AC_SUBST(BUILD_CONFIG)
2602
2603 extrasub_build=
2604 for module in ${build_configdirs} ; do
2605   if test -z "${no_recursion}" \
2606      && test -f ${build_subdir}/${module}/Makefile; then
2607     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2608     rm -f ${build_subdir}/${module}/Makefile
2609   fi
2610   extrasub_build="$extrasub_build
2611 /^@if build-$module\$/d
2612 /^@endif build-$module\$/d
2613 /^@if build-$module-$bootstrap_suffix\$/d
2614 /^@endif build-$module-$bootstrap_suffix\$/d"
2615 done
2616 extrasub_host=
2617 for module in ${configdirs} ; do
2618   if test -z "${no_recursion}"; then
2619     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2620       if test -f ${file}; then
2621         echo 1>&2 "*** removing ${file} to force reconfigure"
2622         rm -f ${file}
2623       fi
2624     done
2625   fi
2626   extrasub_host="$extrasub_host
2627 /^@if $module\$/d
2628 /^@endif $module\$/d
2629 /^@if $module-$bootstrap_suffix\$/d
2630 /^@endif $module-$bootstrap_suffix\$/d"
2631 done
2632 extrasub_target=
2633 for module in ${target_configdirs} ; do
2634   if test -z "${no_recursion}" \
2635      && test -f ${target_subdir}/${module}/Makefile; then
2636     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2637     rm -f ${target_subdir}/${module}/Makefile
2638   fi
2639
2640   # We only bootstrap target libraries listed in bootstrap_target_libs.
2641   case $bootstrap_target_libs in
2642     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2643     *) target_bootstrap_suffix=no-bootstrap ;;
2644   esac
2645
2646   extrasub_target="$extrasub_target
2647 /^@if target-$module\$/d
2648 /^@endif target-$module\$/d
2649 /^@if target-$module-$target_bootstrap_suffix\$/d
2650 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2651 done
2652
2653 # Do the final fixup along with target modules.
2654 extrasub_target="$extrasub_target
2655 /^@if /,/^@endif /d"
2656
2657 # Create the serialization dependencies.  This uses a temporary file.
2658
2659 AC_ARG_ENABLE([serial-configure],
2660 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2661                 [force sequential configuration of
2662                  sub-packages for the host, target or build
2663                  machine, or all sub-packages])])
2664
2665 case ${enable_serial_configure} in
2666   yes)
2667     enable_serial_build_configure=yes
2668     enable_serial_host_configure=yes
2669     enable_serial_target_configure=yes
2670     ;;
2671 esac
2672
2673 # These force 'configure's to be done one at a time, to avoid problems
2674 # with contention over a shared config.cache.
2675 rm -f serdep.tmp
2676 echo '# serdep.tmp' > serdep.tmp
2677 olditem=
2678 test "x${enable_serial_build_configure}" = xyes &&
2679 for item in ${build_configdirs} ; do
2680   case ${olditem} in
2681     "") ;;
2682     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2683   esac
2684   olditem=${item}
2685 done
2686 olditem=
2687 test "x${enable_serial_host_configure}" = xyes &&
2688 for item in ${configdirs} ; do
2689   case ${olditem} in
2690     "") ;;
2691     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2692   esac
2693   olditem=${item}
2694 done
2695 olditem=
2696 test "x${enable_serial_target_configure}" = xyes &&
2697 for item in ${target_configdirs} ; do
2698   case ${olditem} in
2699     "") ;;
2700     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2701   esac
2702   olditem=${item}
2703 done
2704 serialization_dependencies=serdep.tmp
2705 AC_SUBST_FILE(serialization_dependencies)
2706
2707 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2708 # target, nonopt, and variable assignments.  These are the ones we
2709 # might not want to pass down to subconfigures.  The exception being
2710 # --cache-file=/dev/null, which is used to turn off the use of cache
2711 # files altogether, and which should be passed on to subconfigures.
2712 # Also strip program-prefix, program-suffix, and program-transform-name,
2713 # so that we can pass down a consistent program-transform-name.
2714 baseargs=
2715 tbaseargs=
2716 keep_next=no
2717 skip_next=no
2718 eval "set -- $ac_configure_args"
2719 for ac_arg
2720 do
2721   if test X"$skip_next" = X"yes"; then
2722     skip_next=no
2723     continue
2724   fi
2725   if test X"$keep_next" = X"yes"; then
2726     case $ac_arg in
2727       *\'*)
2728         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2729     esac
2730     baseargs="$baseargs '$ac_arg'"
2731     tbaseargs="$tbaseargs '$ac_arg'"
2732     keep_next=no
2733     continue
2734   fi
2735
2736   # Handle separated arguments.  Based on the logic generated by
2737   # autoconf 2.59.
2738   case $ac_arg in
2739     *=* | --config-cache | -C | -disable-* | --disable-* \
2740       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2741       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2742       | -with-* | --with-* | -without-* | --without-* | --x)
2743       separate_arg=no
2744       ;;
2745     -*)
2746       separate_arg=yes
2747       ;;
2748     *)
2749       separate_arg=no
2750       ;;
2751   esac
2752
2753   skip_targ=no
2754   case $ac_arg in
2755 changequote(,)
2756   --with-* | --without-*)
2757     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2758
2759     case $libopt in
2760     *[-_]include)
2761       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2762       ;;
2763     *[-_]lib)
2764       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2765       ;;
2766     *)
2767       lib=$libopt
2768       ;;
2769     esac
2770 changequote([,])
2771
2772     case $lib in
2773     mpc | mpfr | gmp | ppl | cloog)
2774       # If we're processing --with-$lib, --with-$lib-include or
2775       # --with-$lib-lib, for one of the libs above, and target is
2776       # different from host, don't pass the current argument to any
2777       # target library's configure.
2778       if test x$is_cross_compiler = xyes; then
2779         skip_targ=yes
2780       fi
2781       ;;
2782     esac
2783     ;;
2784   esac
2785
2786   case "$ac_arg" in
2787     --cache-file=/dev/null | \
2788     -cache-file=/dev/null )
2789       # Handled here to avoid the test to skip args below.
2790       baseargs="$baseargs '$ac_arg'"
2791       tbaseargs="$tbaseargs '$ac_arg'"
2792       # Assert: $separate_arg should always be no.
2793       keep_next=$separate_arg
2794       ;;
2795     --no*)
2796       continue
2797       ;;
2798     --c* | \
2799     --sr* | \
2800     --ho* | \
2801     --bu* | \
2802     --t* | \
2803     --program-* | \
2804     -cache_file* | \
2805     -srcdir* | \
2806     -host* | \
2807     -build* | \
2808     -target* | \
2809     -program-prefix* | \
2810     -program-suffix* | \
2811     -program-transform-name* )
2812       skip_next=$separate_arg
2813       continue
2814       ;;
2815     -*)
2816       # An option.  Add it.
2817       case $ac_arg in
2818         *\'*)
2819           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2820       esac
2821       baseargs="$baseargs '$ac_arg'"
2822       if test X"$skip_targ" = Xno; then
2823         tbaseargs="$tbaseargs '$ac_arg'"
2824       fi
2825       keep_next=$separate_arg
2826       ;;
2827     *)
2828       # Either a variable assignment, or a nonopt (triplet).  Don't
2829       # pass it down; let the Makefile handle this.
2830       continue
2831       ;;
2832   esac
2833 done
2834 # Remove the initial space we just introduced and, as these will be
2835 # expanded by make, quote '$'.
2836 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2837
2838 # Add in --program-transform-name, after --program-prefix and
2839 # --program-suffix have been applied to it.  Autoconf has already
2840 # doubled dollar signs and backslashes in program_transform_name; we want
2841 # the backslashes un-doubled, and then the entire thing wrapped in single
2842 # quotes, because this will be expanded first by make and then by the shell. 
2843 # Also, because we want to override the logic in subdir configure scripts to
2844 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2845 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2846 ${program_transform_name}
2847 EOF_SED
2848 gcc_transform_name=`cat conftestsed.out`
2849 rm -f conftestsed.out
2850 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2851 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2852 if test "$silent" = yes; then
2853   baseargs="$baseargs --silent"
2854   tbaseargs="$tbaseargs --silent"
2855 fi
2856 baseargs="$baseargs --disable-option-checking"
2857 tbaseargs="$tbaseargs --disable-option-checking"
2858
2859 # Record and document user additions to sub configure arguments.
2860 AC_ARG_VAR([build_configargs],
2861            [additional configure arguments for build directories])
2862 AC_ARG_VAR([host_configargs],
2863            [additional configure arguments for host directories])
2864 AC_ARG_VAR([target_configargs],
2865            [additional configure arguments for target directories])
2866
2867 # For the build-side libraries, we just need to pretend we're native,
2868 # and not use the same cache file.  Multilibs are neither needed nor
2869 # desired.
2870 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2871
2872 # For host modules, accept cache file option, or specification as blank.
2873 case "${cache_file}" in
2874 "") # empty
2875   cache_file_option="" ;;
2876 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2877   cache_file_option="--cache-file=${cache_file}" ;;
2878 *) # relative path
2879   cache_file_option="--cache-file=../${cache_file}" ;;
2880 esac
2881
2882 # Host dirs don't like to share a cache file either, horribly enough.
2883 # This seems to be due to autoconf 2.5x stupidity.
2884 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2885
2886 target_configargs="$target_configargs ${tbaseargs}"
2887
2888 # Passing a --with-cross-host argument lets the target libraries know
2889 # whether they are being built with a cross-compiler or being built
2890 # native.  However, it would be better to use other mechanisms to make the
2891 # sorts of decisions they want to make on this basis.  Please consider
2892 # this option to be deprecated.  FIXME.
2893 if test x${is_cross_compiler} = xyes ; then
2894   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2895 fi
2896
2897 # Default to --enable-multilib.
2898 if test x${enable_multilib} = x ; then
2899   target_configargs="--enable-multilib ${target_configargs}"
2900 fi
2901
2902 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2903 # changed from the earlier setting of with_newlib.
2904 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2905   target_configargs="--with-newlib ${target_configargs}"
2906 fi
2907
2908 # Different target subdirs use different values of certain variables
2909 # (notably CXX).  Worse, multilibs use *lots* of different values.
2910 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2911 # it doesn't automatically accept command-line overrides of them.
2912 # This means it's not safe for target subdirs to share a cache file,
2913 # which is disgusting, but there you have it.  Hopefully this can be
2914 # fixed in future.  It's still worthwhile to use a cache file for each
2915 # directory.  I think.
2916
2917 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2918 # We need to pass --target, as newer autoconf's requires consistency
2919 # for target_alias and gcc doesn't manage it consistently.
2920 target_configargs="--cache-file=./config.cache ${target_configargs}"
2921
2922 FLAGS_FOR_TARGET=
2923 case " $target_configdirs " in
2924  *" newlib "*)
2925   case " $target_configargs " in
2926   *" --with-newlib "*)
2927    case "$target" in
2928     *-cygwin*)
2929       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2930       ;;
2931    esac
2932
2933    # If we're not building GCC, don't discard standard headers.
2934    if test -d ${srcdir}/gcc; then
2935      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2936
2937      if test "${build}" != "${host}"; then
2938        # On Canadian crosses, CC_FOR_TARGET will have already been set
2939        # by `configure', so we won't have an opportunity to add -Bgcc/
2940        # to it.  This is right: we don't want to search that directory
2941        # for binaries, but we want the header files in there, so add
2942        # them explicitly.
2943        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2944
2945        # Someone might think of using the pre-installed headers on
2946        # Canadian crosses, in case the installed compiler is not fully
2947        # compatible with the compiler being built.  In this case, it
2948        # would be better to flag an error than risking having
2949        # incompatible object files being constructed.  We can't
2950        # guarantee that an error will be flagged, but let's hope the
2951        # compiler will do it, when presented with incompatible header
2952        # files.
2953      fi
2954    fi
2955
2956    case "${target}-${is_cross_compiler}" in
2957    i[[3456789]]86-*-linux*-no)
2958       # Here host == target, so we don't need to build gcc,
2959       # so we don't want to discard standard headers.
2960       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2961       ;;
2962    *)
2963       # If we're building newlib, use its generic headers last, but search
2964       # for any libc-related directories first (so make it the last -B
2965       # switch).
2966       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2967
2968       # If we're building libgloss, find the startup file, simulator library
2969       # and linker script.
2970       case " $target_configdirs " in
2971         *" libgloss "*)
2972         # Look for startup file, simulator library and maybe linker script.
2973         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2974         # Look for libnosys.a in case the target needs it.
2975         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2976         # Most targets have the linker script in the source directory.
2977         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2978         ;;
2979       esac
2980       ;;
2981    esac
2982    ;;
2983   esac
2984   ;;
2985 esac
2986
2987 case "$target" in
2988   x86_64-*mingw* | *-w64-mingw*)
2989   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2990   # however, use a symlink named 'mingw' in ${prefix} .
2991     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2992     ;;
2993   *-mingw*)
2994   # MinGW can't be handled as Cygwin above since it does not use newlib.
2995     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2996     ;;
2997 esac
2998
2999 # Allow the user to override the flags for
3000 # our build compiler if desired.
3001 if test x"${build}" = x"${host}" ; then
3002   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3003   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3004   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3005 fi
3006
3007 # On Canadian crosses, we'll be searching the right directories for
3008 # the previously-installed cross compiler, so don't bother to add
3009 # flags for directories within the install tree of the compiler
3010 # being built; programs in there won't even run.
3011 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3012   # Search for pre-installed headers if nothing else fits.
3013   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3014 fi
3015
3016 if test "x${use_gnu_ld}" = x &&
3017    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3018   # Arrange for us to find uninstalled linker scripts.
3019   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3020 fi
3021
3022 # Search for other target-specific linker scripts and such.
3023 case "${target}" in
3024   mep*)
3025     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3026     ;;
3027 esac
3028
3029 # Makefile fragments.
3030 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3031 do
3032   eval fragval=\$$frag
3033   if test $fragval != /dev/null; then
3034     eval $frag=${srcdir}/$fragval
3035   fi
3036 done
3037 AC_SUBST_FILE(host_makefile_frag)
3038 AC_SUBST_FILE(target_makefile_frag)
3039 AC_SUBST_FILE(alphaieee_frag)
3040 AC_SUBST_FILE(ospace_frag)
3041
3042 # Miscellanea: directories, flags, etc.
3043 AC_SUBST(RPATH_ENVVAR)
3044 AC_SUBST(GCC_SHLIB_SUBDIR)
3045 AC_SUBST(tooldir)
3046 AC_SUBST(build_tooldir)
3047 AC_SUBST(CONFIGURE_GDB_TK)
3048 AC_SUBST(GDB_TK)
3049 AC_SUBST(INSTALL_GDB_TK)
3050
3051 # Build module lists & subconfigure args.
3052 AC_SUBST(build_configargs)
3053 AC_SUBST(build_configdirs)
3054
3055 # Host module lists & subconfigure args.
3056 AC_SUBST(host_configargs)
3057 AC_SUBST(configdirs)
3058 AC_SUBST(target_configdirs)
3059
3060 # Target module lists & subconfigure args.
3061 AC_SUBST(target_configargs)
3062
3063
3064 # Build tools.
3065 AC_SUBST(AR_FOR_BUILD)
3066 AC_SUBST(AS_FOR_BUILD)
3067 AC_SUBST(CC_FOR_BUILD)
3068 AC_SUBST(CFLAGS_FOR_BUILD)
3069 AC_SUBST(CXXFLAGS_FOR_BUILD)
3070 AC_SUBST(CXX_FOR_BUILD)
3071 AC_SUBST(DLLTOOL_FOR_BUILD)
3072 AC_SUBST(GCJ_FOR_BUILD)
3073 AC_SUBST(GFORTRAN_FOR_BUILD)
3074 AC_SUBST(GOC_FOR_BUILD)
3075 AC_SUBST(LDFLAGS_FOR_BUILD)
3076 AC_SUBST(LD_FOR_BUILD)
3077 AC_SUBST(NM_FOR_BUILD)
3078 AC_SUBST(RANLIB_FOR_BUILD)
3079 AC_SUBST(WINDMC_FOR_BUILD)
3080 AC_SUBST(WINDRES_FOR_BUILD)
3081 AC_SUBST(config_shell)
3082
3083 # Generate default definitions for YACC, M4, LEX and other programs that run
3084 # on the build machine.  These are used if the Makefile can't locate these
3085 # programs in objdir.
3086 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3087
3088 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3089 case " $build_configdirs " in
3090   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3091   *" byacc "*) YACC='$$r/$(BUILD_SUBDIR)/byacc/byacc' ;;
3092 esac
3093
3094 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3095 case " $build_configdirs " in
3096   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3097 esac
3098
3099 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3100 case " $build_configdirs " in
3101   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3102 esac
3103
3104 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3105 case " $build_configdirs " in
3106   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3107   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3108 esac
3109
3110 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3111 case " $build_configdirs " in
3112   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3113 esac
3114
3115 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3116 case " $build_configdirs " in
3117   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3118   *)
3119 changequote(,)
3120     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3121     # higher, else we use the "missing" dummy.
3122     if ${MAKEINFO} --version \
3123        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3124       :
3125     else
3126       MAKEINFO="$MISSING makeinfo"
3127     fi
3128     ;;
3129 changequote([,])
3130 esac
3131
3132 # FIXME: expect and dejagnu may become build tools?
3133
3134 AC_CHECK_PROGS(EXPECT, expect, expect)
3135 case " $configdirs " in
3136   *" expect "*)
3137     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3138     ;;
3139 esac
3140
3141 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3142 case " $configdirs " in
3143   *" dejagnu "*)
3144     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3145     ;;
3146 esac
3147
3148
3149 # Host tools.
3150 NCN_STRICT_CHECK_TOOLS(AR, ar)
3151 NCN_STRICT_CHECK_TOOLS(AS, as)
3152 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3153 NCN_STRICT_CHECK_TOOLS(LD, ld)
3154 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3155 NCN_STRICT_CHECK_TOOLS(NM, nm)
3156 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3157 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3158 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3159 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3160 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3161 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3162 AC_SUBST(CC)
3163 AC_SUBST(CXX)
3164 AC_SUBST(CFLAGS)
3165 AC_SUBST(CXXFLAGS)
3166
3167 # Target tools.
3168 AC_ARG_WITH([build-time-tools], 
3169   [AS_HELP_STRING([--with-build-time-tools=PATH],
3170                   [use given path to find target tools during the build])],
3171   [case x"$withval" in
3172      x/*) ;;
3173      *)
3174        with_build_time_tools=
3175        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3176        ;;
3177    esac],
3178   [with_build_time_tools=])
3179
3180 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3181 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3182 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3183 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3184 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3185 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3186
3187 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3188 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3189 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3190 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3191 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3192 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3193 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3194 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3195 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3196 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3197 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3198
3199 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3200
3201 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3202 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3203 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3204 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3205 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3206                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3207                 c++)
3208 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3209                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3210                 c++)
3211 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3212 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3213 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3214                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3215 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3216                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3217 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3218                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3219 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3220 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3221 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3222 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3223 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3224 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3225 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3226 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3227
3228 AC_SUBST(FLAGS_FOR_TARGET)
3229 AC_SUBST(RAW_CXX_FOR_TARGET)
3230
3231 # Certain tools may need extra flags.
3232 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3233 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3234 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3235
3236 # When building target libraries, except in a Canadian cross, we use
3237 # the same toolchain as the compiler we just built.
3238 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3239 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3240 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3241 if test $host = $build; then
3242   case " $configdirs " in
3243     *" gcc "*)
3244       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3245       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3246       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3247       ;;
3248   esac
3249 fi
3250
3251 AC_SUBST(COMPILER_AS_FOR_TARGET)
3252 AC_SUBST(COMPILER_LD_FOR_TARGET)
3253 AC_SUBST(COMPILER_NM_FOR_TARGET)
3254
3255 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3256 AC_ARG_ENABLE(maintainer-mode,
3257 [AS_HELP_STRING([--enable-maintainer-mode],
3258                 [enable make rules and dependencies not useful
3259                  (and sometimes confusing) to the casual installer])],
3260       USE_MAINTAINER_MODE=$enableval,
3261       USE_MAINTAINER_MODE=no)
3262 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3263 AC_SUBST(MAINTAINER_MODE_TRUE)
3264 AC_SUBST(MAINTAINER_MODE_FALSE)
3265 if test "$USE_MAINTAINER_MODE" = yes; then
3266   MAINTAINER_MODE_TRUE=
3267   MAINTAINER_MODE_FALSE='#'
3268 else
3269   MAINTAINER_MODE_TRUE='#'
3270   MAINTAINER_MODE_FALSE=
3271 fi      
3272 MAINT=$MAINTAINER_MODE_TRUE
3273 AC_SUBST(MAINT)dnl
3274
3275 # ---------------------
3276 # GCC bootstrap support
3277 # ---------------------
3278
3279 # Stage specific cflags for build.
3280 stage1_cflags="-g"
3281 case $build in
3282   vax-*-*)
3283     case ${GCC} in
3284       yes) stage1_cflags="-g -Wa,-J" ;;
3285       *) stage1_cflags="-g -J" ;;
3286     esac ;;
3287 esac
3288
3289 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3290 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3291   saved_CFLAGS="$CFLAGS"
3292
3293   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3294   CFLAGS="$CFLAGS -fkeep-inline-functions"
3295   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3296   AC_TRY_COMPILE([
3297 #if (__GNUC__ < 3) \
3298     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3299                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3300 #error http://gcc.gnu.org/PR29382
3301 #endif
3302     ],,
3303     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3304     [AC_MSG_RESULT([no])])
3305
3306   CFLAGS="$saved_CFLAGS"
3307 fi
3308
3309 AC_SUBST(stage1_cflags)
3310
3311 # Enable --enable-checking in stage1 of the compiler.
3312 AC_ARG_ENABLE(stage1-checking,
3313 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3314                 [choose additional checking for stage1 of the compiler])],
3315 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3316 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3317   stage1_checking=--enable-checking=yes,types
3318 else
3319   stage1_checking=--enable-checking=$enable_checking,types
3320 fi])
3321 AC_SUBST(stage1_checking)
3322
3323 # Enable -Werror in bootstrap stage2 and later.
3324 AC_ARG_ENABLE(werror,
3325 [AS_HELP_STRING([--enable-werror],
3326                 [enable -Werror in bootstrap stage2 and later])], [],
3327 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3328   enable_werror=yes
3329 else
3330   enable_werror=no
3331 fi])
3332 case ${enable_werror} in
3333   yes) stage2_werror_flag="--enable-werror-always" ;;
3334   *) stage2_werror_flag="" ;;
3335 esac
3336 AC_SUBST(stage2_werror_flag)
3337
3338 # Specify what files to not compare during bootstrap.
3339
3340 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3341 case "$target" in
3342   hppa*64*-*-hpux*) ;;
3343   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3344 esac
3345 case " $configdirs " in
3346 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3347 esac
3348 AC_SUBST(compare_exclusions)
3349
3350 AC_CONFIG_FILES([Makefile],
3351   [sed "$extrasub_build" Makefile |
3352    sed "$extrasub_host" |
3353    sed "$extrasub_target" > mf$$
3354    mv -f mf$$ Makefile],
3355   [extrasub_build="$extrasub_build"
3356    extrasub_host="$extrasub_host"
3357    extrasub_target="$extrasub_target"])
3358 AC_OUTPUT