configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libgloss \
 155                 target-newlib \
 156                 target-libgomp \
 157                 target-libitm \
 158                 target-libstdc++-v3 \
 159                 target-libmudflap \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-boehm-gc \
 164                 ${libgcj} \
 165                 target-libobjc \
 166                 target-libada \
 167                 target-libgo"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 # Make sure we don't let ZLIB be added if we didn't want it.
 243 if test x$with_system_zlib = xyes ; then
 244   use_included_zlib=no
 245   noconfigdirs="$noconfigdirs zlib"
 246 fi
 247
 248 # some tools are so dependent upon X11 that if we're not building with X,
 249 # it's not even worth trying to configure, much less build, that tool.
 250
 251 case ${with_x} in
 252   yes | "") ;; # the default value for this tree is that X11 is available
 253   no)
 254     skipdirs="${skipdirs} tk itcl libgui"
 255     # We won't be able to build gdbtk without X.
 256     enable_gdbtk=no
 257     ;;
 258   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 259 esac
 260
 261 # Some are only suitable for cross toolchains.
 262 # Remove these if host=target.
 263 cross_only="target-libgloss target-newlib target-opcodes"
 264
 265 case $is_cross_compiler in
 266   no) skipdirs="${skipdirs} ${cross_only}" ;;
 267 esac
 268
 269 # If both --with-headers and --with-libs are specified, default to
 270 # --without-newlib.
 271 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 272    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 273   if test x"${with_newlib}" = x ; then
 274     with_newlib=no
 275   fi
 276 fi
 277
 278 # Recognize --with-newlib/--without-newlib.
 279 case ${with_newlib} in
 280   no) skipdirs="${skipdirs} target-newlib" ;;
 281   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 282 esac
 283
 284 # Handle --enable-gold, --enable-ld.
 285 # --disable-gold [--enable-ld]
 286 #     Build only ld.  Default option.
 287 # --enable-gold [--enable-ld]
 288 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 289 #     as "ld.bfd" and "ld".
 290 # --enable-gold=default [--enable-ld]
 291 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 292 #     install ld as "ld.bfd".
 293 # --enable-gold[=default] --disable-ld
 294 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 295 # --enable-gold --enable-ld=default
 296 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 297 #     and ld.bfd).
 298 #     In other words, ld is default
 299 # --enable-gold=default --enable-ld=default
 300 #     Error.
 301
 302 default_ld=
 303 AC_ARG_ENABLE(gold,
 304 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 305                 [build gold @<:@ARG={default,yes,no}@:>@])],
 306 ENABLE_GOLD=$enableval,
 307 ENABLE_GOLD=no)
 308 case "${ENABLE_GOLD}" in
 309   yes|default)
 310     # Check for ELF target.
 311     is_elf=no
 312     case "${target}" in
 313       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 314       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 315       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 316       | *-*-solaris2* | *-*-nto*)
 317         case "${target}" in
 318           *-*-linux*aout* | *-*-linux*oldld*)
 319             ;;
 320           *)
 321             is_elf=yes
 322             ;;
 323         esac
 324     esac
 325
 326     if test "$is_elf" = "yes"; then
 327       # Check for target supported by gold.
 328       case "${target}" in
 329         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 330           configdirs="$configdirs gold"
 331           if test x${ENABLE_GOLD} = xdefault; then
 332             default_ld=gold
 333           fi
 334           ENABLE_GOLD=yes
 335           ;;
 336       esac
 337     fi
 338     ;;
 339   no)
 340     ;;
 341   *)
 342     AC_MSG_ERROR([invalid --enable-gold argument])
 343     ;;
 344 esac
 345
 346 AC_ARG_ENABLE(ld,
 347 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 348                 [build ld @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_LD=$enableval,
 350 ENABLE_LD=yes)
 351
 352 case "${ENABLE_LD}" in
 353   default)
 354     if test x${default_ld} != x; then
 355       AC_MSG_ERROR([either gold or ld can be the default ld])
 356     fi
 357     ;;
 358   yes)
 359     ;;
 360   no)
 361     if test x${ENABLE_GOLD} != xyes; then
 362       AC_MSG_WARN([neither ld nor gold are enabled])
 363     fi
 364     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 365     ;;
 366   *)
 367     AC_MSG_ERROR([invalid --enable-ld argument])
 368     ;;
 369 esac
 370
 371 # Configure extra directories which are host specific
 372
 373 case "${host}" in
 374   *-cygwin*)
 375     configdirs="$configdirs libtermcap" ;;
 376 esac
 377
 378 # A target can indicate whether a language isn't supported for some reason.
 379 # Only spaces may be used in this macro; not newlines or tabs.
 380 unsupported_languages=
 381
 382 # Remove more programs from consideration, based on the host or
 383 # target this usually means that a port of the program doesn't
 384 # exist yet.
 385
 386 case "${host}" in
 387   i[[3456789]]86-*-msdosdjgpp*)
 388     noconfigdirs="$noconfigdirs tcl tk itcl"
 389     ;;
 390 esac
 391
 392
 393 AC_ARG_ENABLE(libquadmath,
 394 AS_HELP_STRING([--disable-libquadmath],
 395   [do not build libquadmath directory]),
 396 ENABLE_LIBQUADMATH=$enableval,
 397 ENABLE_LIBQUADMATH=yes)
 398 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 399   noconfigdirs="$noconfigdirs target-libquadmath"
 400 fi
 401
 402
 403 AC_ARG_ENABLE(libquadmath-support,
 404 AS_HELP_STRING([--disable-libquadmath-support],
 405   [disable libquadmath support for Fortran]),
 406 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 407 ENABLE_LIBQUADMATH_SUPPORT=yes)
 408 enable_libquadmath_support=
 409 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 410   enable_libquadmath_support=no
 411 fi
 412
 413
 414 AC_ARG_ENABLE(libada,
 415 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 416 ENABLE_LIBADA=$enableval,
 417 ENABLE_LIBADA=yes)
 418 if test "${ENABLE_LIBADA}" != "yes" ; then
 419   noconfigdirs="$noconfigdirs gnattools"
 420 fi
 421
 422 AC_ARG_ENABLE(libssp,
 423 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 424 ENABLE_LIBSSP=$enableval,
 425 ENABLE_LIBSSP=yes)
 426
 427 # Save it here so that, even in case of --enable-libgcj, if the Java
 428 # front-end isn't enabled, we still get libgcj disabled.
 429 libgcj_saved=$libgcj
 430 case $enable_libgcj in
 431 yes)
 432   # If we reset it here, it won't get added to noconfigdirs in the
 433   # target-specific build rules, so it will be forcibly enabled
 434   # (unless the Java language itself isn't enabled).
 435   libgcj=
 436   ;;
 437 no)
 438   # Make sure we get it printed in the list of not supported target libs.
 439   # Don't disable libffi, though, other languages use it.
 440   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 441   # Clear libgcj_saved so that even if java is enabled libffi won't be
 442   # built.
 443   libgcj_saved=
 444   ;;
 445 esac
 446
 447 AC_ARG_ENABLE(static-libjava,
 448 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 449                 [build static libjava @<:@default=no@:>@])],
 450 ENABLE_STATIC_LIBJAVA=$enableval,
 451 ENABLE_STATIC_LIBJAVA=no)
 452 enable_static_libjava=
 453 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 454   enable_static_libjava=yes
 455 fi
 456
 457 if test x$enable_static_libjava != xyes ; then
 458   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 459 fi
 460 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 461
 462 # Disable libmudflap on some systems.
 463 if test x$enable_libmudflap = x ; then
 464     case "${target}" in
 465     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 466         # Enable libmudflap by default in GNU and friends.
 467         ;;
 468     *-*-freebsd*)
 469         # Enable libmudflap by default in FreeBSD.
 470         ;;
 471     *)
 472         # Disable it by default everywhere else.
 473         noconfigdirs="$noconfigdirs target-libmudflap"
 474         ;;
 475     esac
 476 fi
 477
 478 # Disable libgomp on non POSIX hosted systems.
 479 if test x$enable_libgomp = x ; then
 480     # Enable libgomp by default on hosted POSIX systems.
 481     case "${target}" in
 482     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 483         ;;
 484     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 485         ;;
 486     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 487         ;;
 488     *-*-darwin* | *-*-aix*)
 489         ;;
 490     *)
 491         noconfigdirs="$noconfigdirs target-libgomp"
 492         ;;
 493     esac
 494 fi
 495
 496 # Disable libitm on non POSIX hosted systems.
 497 if test x$enable_libitm = x ; then
 498     # Enable libitm by default on hosted POSIX systems.
 499     case "${target}" in
 500     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu)
 501         ;;
 502     *-*-netbsd* | *-*-freebsd* | *-*-openbsd*)
 503         ;;
 504     *-*-solaris2* | *-*-sysv4* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 505         ;;
 506     *-*-darwin* | *-*-aix*)
 507         ;;
 508     *)
 509         noconfigdirs="$noconfigdirs target-libitm"
 510         ;;
 511     esac
 512 fi
 513
 514 # Disable libssp for some systems.
 515 case "${target}" in
 516   avr-*-*)
 517     # No hosted I/O support.
 518     noconfigdirs="$noconfigdirs target-libssp"
 519     ;;
 520   powerpc-*-aix* | rs6000-*-aix*)
 521     noconfigdirs="$noconfigdirs target-libssp"
 522     ;;
 523 esac
 524
 525 # Disable libstdc++-v3 for some systems.
 526 case "${target}" in
 527   *-*-vxworks*)
 528     # VxWorks uses the Dinkumware C++ library.
 529     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 530     ;;
 531   arm*-wince-pe*)
 532     # the C++ libraries don't build on top of CE's C libraries
 533     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 534     ;;
 535   avr-*-*)
 536     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 537     ;;
 538 esac
 539
 540 # Disable Fortran for some systems.
 541 case "${target}" in
 542   mmix-*-*)
 543     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 544     unsupported_languages="$unsupported_languages fortran"
 545     ;;
 546 esac
 547
 548 # Disable Java if libffi is not supported.
 549 case "${target}" in
 550   alpha*-*-*)
 551     ;;
 552   arm*-*-*)
 553     ;;
 554   cris-*-*)
 555     ;;
 556   frv-*-*)
 557     ;;
 558   hppa*-*-linux*)
 559     ;;
 560   hppa*-*-hpux*)
 561     ;;
 562   i?86-*-*)
 563     ;;
 564   ia64*-*-*)
 565     ;;
 566   m32r*-*-*)
 567     ;;
 568   m68k-*-*)
 569     ;;
 570   mips-sgi-irix6.* | mips*-*-rtems*)
 571     ;;
 572   mips*-*-linux*)
 573     ;;
 574   powerpc*-*-linux*)
 575     ;;
 576   powerpc-*-darwin*)
 577     ;;
 578   powerpc-*-aix* | rs6000-*-aix*)
 579     ;;
 580   powerpc-*-freebsd*)
 581     ;;
 582   powerpc64-*-freebsd*)
 583     ;;
 584   powerpc*-*-rtems*)
 585     ;;
 586   s390-*-* | s390x-*-*)
 587     ;;
 588   sh-*-* | sh[[34]]*-*-*)
 589     ;;
 590   sh64-*-* | sh5*-*-*)
 591     ;;
 592   sparc*-*-*)
 593     ;;
 594   x86_64-*-*)
 595     ;;
 596   *-*-*)
 597     unsupported_languages="$unsupported_languages java"
 598     ;;
 599 esac
 600
 601 # Disable Java, libgcj or related libraries for some systems.
 602 case "${target}" in
 603   powerpc-*-darwin*)
 604     ;;
 605   i[[3456789]]86-*-darwin*)
 606     ;;
 607   x86_64-*-darwin[[912]]*)
 608     ;;
 609   *-*-darwin*)
 610     noconfigdirs="$noconfigdirs ${libgcj}"
 611     ;;
 612   *-*-netware*)
 613     noconfigdirs="$noconfigdirs ${libgcj}"
 614     ;;
 615   *-*-rtems*)
 616     noconfigdirs="$noconfigdirs ${libgcj}"
 617     ;;
 618   *-*-tpf*)
 619     noconfigdirs="$noconfigdirs ${libgcj}"
 620     ;;
 621   *-*-uclinux*)
 622     noconfigdirs="$noconfigdirs ${libgcj}"
 623     ;;
 624   *-*-vxworks*)
 625     noconfigdirs="$noconfigdirs ${libgcj}"
 626     ;;
 627   alpha*-*-*vms*)
 628     noconfigdirs="$noconfigdirs ${libgcj}"
 629     ;;
 630   arm-wince-pe)
 631     noconfigdirs="$noconfigdirs ${libgcj}"
 632     ;;
 633   arm*-*-symbianelf*)
 634     noconfigdirs="$noconfigdirs ${libgcj}"
 635     ;;
 636   bfin-*-*)
 637     noconfigdirs="$noconfigdirs target-boehm-gc"
 638     ;;
 639   cris-*-* | crisv32-*-*)
 640     unsupported_languages="$unsupported_languages java"
 641     case "${target}" in
 642       *-*-linux*)
 643         ;;
 644       *) # See PR46792 regarding target-libffi.
 645         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 646     esac
 647     ;;
 648   hppa*64*-*-linux*)
 649     # In this case, it's because the hppa64-linux target is for
 650     # the kernel only at this point and has no libc, and thus no
 651     # headers, crt*.o, etc., all of which are needed by these.
 652     unsupported_languages="$unsupported_languages java"
 653     ;;
 654   hppa*64*-*-hpux*)
 655     noconfigdirs="$noconfigdirs ${libgcj}"
 656     ;;
 657   hppa*-hp-hpux11*)
 658     ;;
 659   hppa*-*-hpux*)
 660     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 661     # build on HP-UX 10.20.
 662     noconfigdirs="$noconfigdirs ${libgcj}"
 663     ;;
 664   ia64*-*-*vms*)
 665     noconfigdirs="$noconfigdirs ${libgcj}"
 666     ;;
 667   i[[3456789]]86-w64-mingw*)
 668     noconfigdirs="$noconfigdirs ${libgcj}"
 669     ;;
 670   i[[3456789]]86-*-mingw*)
 671     noconfigdirs="$noconfigdirs ${libgcj}"
 672     ;;
 673   x86_64-*-mingw*)
 674     noconfigdirs="$noconfigdirs ${libgcj}"
 675     ;;
 676   mmix-*-*)
 677     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 678     ;;
 679   powerpc-*-aix*)
 680     # copied from rs6000-*-* entry
 681     noconfigdirs="$noconfigdirs ${libgcj}"
 682     ;;
 683   rs6000-*-aix*)
 684     noconfigdirs="$noconfigdirs ${libgcj}"
 685     ;;
 686   mips*-*-irix6*)
 687     # Linking libjava exceeds command-line length limits on at least
 688     # IRIX 6.2, but not on IRIX 6.5.
 689     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 690     # <oldham@codesourcery.com>
 691     noconfigdirs="$noconfigdirs ${libgcj}"
 692     ;;
 693   *-*-lynxos*)
 694     noconfigdirs="$noconfigdirs ${libgcj}"
 695     ;;
 696 esac
 697
 698 # Default libgloss CPU subdirectory.
 699 libgloss_dir="$target_cpu"
 700
 701 case "${target}" in
 702   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 703     libgloss_dir=wince
 704     ;;
 705   arm*-*-*)
 706     libgloss_dir=arm
 707     ;;
 708   cris-*-* | crisv32-*-*)
 709     libgloss_dir=cris
 710     ;;
 711   hppa*-*-*)
 712     libgloss_dir=pa
 713     ;;
 714   i[[3456789]]86-*-*)
 715     libgloss_dir=i386
 716     ;;
 717   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 718     libgloss_dir=m68hc11
 719     ;;
 720   m68*-*-* | fido-*-*)
 721     libgloss_dir=m68k
 722     ;;
 723   mips*-*-*)
 724     libgloss_dir=mips
 725     ;;
 726   powerpc*-*-*)
 727     libgloss_dir=rs6000
 728     ;;
 729   sparc*-*-*)
 730     libgloss_dir=sparc
 731     ;;
 732 esac
 733
 734 # Disable newlib and libgloss for various target OSes.
 735 case "${target}" in
 736   alpha*-dec-osf*)
 737     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 738     ;;
 739   i[[3456789]]86-*-linux*)
 740     # This section makes it possible to build newlib natively on linux.
 741     # If we are using a cross compiler then don't configure newlib.
 742     if test x${is_cross_compiler} != xno ; then
 743       noconfigdirs="$noconfigdirs target-newlib"
 744     fi
 745     noconfigdirs="$noconfigdirs target-libgloss"
 746     # If we are not using a cross compiler, do configure newlib.
 747     # Note however, that newlib will only be configured in this situation
 748     # if the --with-newlib option has been given, because otherwise
 749     # 'target-newlib' will appear in skipdirs.
 750     ;;
 751   i[[3456789]]86-*-rdos*)
 752     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 753     ;;
 754   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 755     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 756     ;;
 757   sparc-*-sunos4*)
 758     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 759     ;;
 760   *-*-aix*)
 761     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 762     ;;
 763   *-*-beos*)
 764     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 765     ;;
 766   *-*-chorusos)
 767     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 768     ;;
 769   *-*-dragonfly*)
 770     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 771     ;;
 772   *-*-freebsd*)
 773     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 774     ;;
 775   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 776     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 777     ;;
 778   *-*-lynxos*)
 779     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 780     ;;
 781   *-*-mingw*)
 782     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 783     ;;
 784   *-*-netbsd*)
 785     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 786     ;;
 787   *-*-netware*)
 788     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 789     ;;
 790   *-*-tpf*)
 791     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 792     ;;
 793   *-*-uclinux*)
 794     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 795     ;;
 796   *-*-vxworks*)
 797     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 798     ;;
 799 esac
 800
 801 case "${target}" in
 802   *-*-chorusos)
 803     ;;
 804   powerpc-*-darwin*)
 805     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 806     noconfigdirs="$noconfigdirs sim target-rda"
 807     ;;
 808   i[[3456789]]86-*-darwin*)
 809     noconfigdirs="$noconfigdirs ld gprof"
 810     noconfigdirs="$noconfigdirs sim target-rda"
 811     ;;
 812   x86_64-*-darwin[[912]]*)
 813     noconfigdirs="$noconfigdirs ld gas gprof"
 814     noconfigdirs="$noconfigdirs sim target-rda"
 815     ;;
 816   *-*-darwin*)
 817     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 818     noconfigdirs="$noconfigdirs sim target-rda"
 819     ;;
 820   *-*-dragonfly*)
 821     ;;
 822   *-*-freebsd*)
 823     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 824         && test -f /usr/local/include/gmp.h; then
 825       with_gmp=/usr/local
 826     fi
 827     ;;
 828   *-*-kaos*)
 829     # Remove unsupported stuff on all kaOS configurations.
 830     noconfigdirs="$noconfigdirs target-libgloss"
 831     ;;
 832   *-*-netbsd*)
 833     ;;
 834   *-*-netware*)
 835     ;;
 836   *-*-rtems*)
 837     noconfigdirs="$noconfigdirs target-libgloss"
 838     ;;
 839     # The tpf target doesn't support gdb yet.
 840   *-*-tpf*)
 841     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 842     ;;
 843   *-*-uclinux*)
 844     noconfigdirs="$noconfigdirs target-rda"
 845     ;;
 846   *-*-vxworks*)
 847     ;;
 848   alpha*-dec-osf*)
 849     # ld works, but does not support shared libraries.
 850     # gas doesn't generate exception information.
 851     noconfigdirs="$noconfigdirs gas ld"
 852     ;;
 853   alpha*-*-*vms*)
 854     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 855     ;;
 856   alpha*-*-*)
 857     # newlib is not 64 bit ready
 858     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 859     ;;
 860   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 861     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 862     ;;
 863   arc-*-*)
 864     noconfigdirs="$noconfigdirs target-libgloss"
 865     ;;
 866   arm-*-pe*)
 867     noconfigdirs="$noconfigdirs target-libgloss"
 868     ;;
 869   arm-*-riscix*)
 870     noconfigdirs="$noconfigdirs ld target-libgloss"
 871     ;;
 872   c4x-*-* | tic4x-*-*)
 873     noconfigdirs="$noconfigdirs target-libgloss"
 874     ;;
 875   tic54x-*-*)
 876     noconfigdirs="$noconfigdirs target-libgloss gdb"
 877     ;;
 878   cr16-*-*)
 879     noconfigdirs="$noconfigdirs gdb"
 880     ;;
 881   d10v-*-*)
 882     noconfigdirs="$noconfigdirs target-libgloss"
 883     ;;
 884   d30v-*-*)
 885     noconfigdirs="$noconfigdirs gdb"
 886     ;;
 887   fr30-*-elf*)
 888     noconfigdirs="$noconfigdirs gdb"
 889     ;;
 890   moxie-*-*)
 891     noconfigdirs="$noconfigdirs gprof"
 892     ;;
 893   h8300*-*-*)
 894     noconfigdirs="$noconfigdirs target-libgloss"
 895     ;;
 896   h8500-*-*)
 897     noconfigdirs="$noconfigdirs target-libgloss"
 898     ;;
 899   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 900     ;;
 901   hppa*64*-*-linux*)
 902     ;;
 903   hppa*-*-linux*)
 904     ;;
 905   hppa*-*-*elf* | \
 906   hppa*-*-lites* | \
 907   hppa*-*-openbsd* | \
 908   hppa*64*-*-*)
 909     ;;
 910   hppa*-hp-hpux11*)
 911     noconfigdirs="$noconfigdirs ld"
 912     ;;
 913   hppa*-*-pro*)
 914     ;;
 915   hppa*-*-*)
 916     noconfigdirs="$noconfigdirs ld"
 917     ;;
 918   i960-*-*)
 919     noconfigdirs="$noconfigdirs gdb"
 920     ;;
 921   ia64*-*-elf*)
 922     # No gdb support yet.
 923     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 924     ;;
 925   ia64*-**-hpux*)
 926     # No ld support yet.
 927     noconfigdirs="$noconfigdirs libgui itcl ld"
 928     ;;
 929   ia64*-*-*vms*)
 930     # No gdb or ld support yet.
 931     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
 932     ;;
 933   i[[3456789]]86-w64-mingw*)
 934     ;;
 935   i[[3456789]]86-*-mingw*)
 936     target_configdirs="$target_configdirs target-winsup"
 937     ;;
 938   *-*-cygwin*)
 939     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 940     noconfigdirs="$noconfigdirs target-libgloss"
 941     # always build newlib if winsup directory is present.
 942     if test -d "$srcdir/winsup/cygwin"; then
 943       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 944     elif test -d "$srcdir/newlib"; then
 945       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 946     fi
 947     ;;
 948   i[[3456789]]86-*-pe)
 949     noconfigdirs="$noconfigdirs target-libgloss"
 950     ;;
 951   i[[3456789]]86-*-sco3.2v5*)
 952     # The linker does not yet know about weak symbols in COFF,
 953     # and is not configured to handle mixed ELF and COFF.
 954     noconfigdirs="$noconfigdirs ld target-libgloss"
 955     ;;
 956   i[[3456789]]86-*-sco*)
 957     noconfigdirs="$noconfigdirs gprof target-libgloss"
 958     ;;
 959   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 960     noconfigdirs="$noconfigdirs target-libgloss"
 961     ;;
 962   i[[3456789]]86-*-sysv4*)
 963     noconfigdirs="$noconfigdirs target-libgloss"
 964     ;;
 965   i[[3456789]]86-*-beos*)
 966     noconfigdirs="$noconfigdirs gdb"
 967     ;;
 968   i[[3456789]]86-*-rdos*)
 969     noconfigdirs="$noconfigdirs gdb"
 970     ;;
 971   mmix-*-*)
 972     noconfigdirs="$noconfigdirs gdb"
 973     ;;
 974   mt-*-*)
 975     noconfigdirs="$noconfigdirs sim"
 976     ;;
 977   powerpc-*-aix*)
 978     # copied from rs6000-*-* entry
 979     noconfigdirs="$noconfigdirs gprof"
 980     ;;
 981   powerpc*-*-winnt* | powerpc*-*-pe*)
 982     target_configdirs="$target_configdirs target-winsup"
 983     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 984     # always build newlib.
 985     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 986     ;;
 987     # This is temporary until we can link against shared libraries
 988   powerpcle-*-solaris*)
 989     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
 990     ;;
 991   powerpc-*-beos*)
 992     noconfigdirs="$noconfigdirs gdb"
 993     ;;
 994   rs6000-*-lynxos*)
 995     noconfigdirs="$noconfigdirs gprof"
 996     ;;
 997   rs6000-*-aix*)
 998     noconfigdirs="$noconfigdirs gprof"
 999     ;;
1000   rs6000-*-*)
1001     noconfigdirs="$noconfigdirs gprof"
1002     ;;
1003   m68k-apollo-*)
1004     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1005     ;;
1006   microblaze*)
1007     noconfigdirs="$noconfigdirs gprof"
1008     ;;
1009   mips*-sde-elf*)
1010     if test x$with_newlib = xyes; then
1011       noconfigdirs="$noconfigdirs gprof"
1012     fi
1013     ;;
1014   mips*-*-irix5*)
1015     noconfigdirs="$noconfigdirs gprof target-libgloss"
1016     ;;
1017   mips*-*-irix6*)
1018     noconfigdirs="$noconfigdirs gprof target-libgloss"
1019     ;;
1020   mips*-*-bsd*)
1021     noconfigdirs="$noconfigdirs gprof target-libgloss"
1022     ;;
1023   mips*-*-linux*)
1024     ;;
1025   mips*-*-*)
1026     noconfigdirs="$noconfigdirs gprof"
1027     ;;
1028   sh-*-* | sh64-*-*)
1029     case "${target}" in
1030       sh*-*-elf)
1031          ;;
1032       *)
1033          noconfigdirs="$noconfigdirs target-libgloss" ;;
1034     esac
1035     ;;
1036   sparc-*-sunos4*)
1037     if test x${is_cross_compiler} = xno ; then
1038            use_gnu_ld=no
1039     fi
1040     ;;
1041   tic6x-*-*)
1042     noconfigdirs="$noconfigdirs sim"
1043     ;;
1044   tilepro-*-* | tilegx-*-*)
1045     noconfigdirs="$noconfigdirs sim"
1046     ;;
1047   v810-*-*)
1048     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1049     ;;
1050   vax-*-*)
1051     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1052     ;;
1053 esac
1054
1055 # If we aren't building newlib, then don't build libgloss, since libgloss
1056 # depends upon some newlib header files.
1057 case "${noconfigdirs}" in
1058   *target-libgloss*) ;;
1059   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1060 esac
1061
1062 # Work in distributions that contain no compiler tools, like Autoconf.
1063 host_makefile_frag=/dev/null
1064 if test -d ${srcdir}/config ; then
1065 case "${host}" in
1066   i[[3456789]]86-*-msdosdjgpp*)
1067     host_makefile_frag="config/mh-djgpp"
1068     ;;
1069   *-cygwin*)
1070     ACX_CHECK_CYGWIN_CAT_WORKS
1071     host_makefile_frag="config/mh-cygwin"
1072     ;;
1073   *-mingw*)
1074     host_makefile_frag="config/mh-mingw"
1075     ;;
1076   *-interix*)
1077     host_makefile_frag="config/mh-interix"
1078     ;;
1079   hppa*-hp-hpux10*)
1080     host_makefile_frag="config/mh-pa-hpux10"
1081     ;;
1082   hppa*-hp-hpux*)
1083     host_makefile_frag="config/mh-pa"
1084     ;;
1085   hppa*-*)
1086     host_makefile_frag="config/mh-pa"
1087     ;;
1088   *-*-darwin*)
1089     host_makefile_frag="config/mh-darwin"
1090     ;;
1091   powerpc-*-aix*)
1092     host_makefile_frag="config/mh-ppc-aix"
1093     ;;
1094   rs6000-*-aix*)
1095     host_makefile_frag="config/mh-ppc-aix"
1096     ;;
1097 esac
1098 fi
1099
1100 if test "${build}" != "${host}" ; then
1101   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1102   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1103   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1104   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1105   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1106   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1107   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1108   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1109   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1110   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1111   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1112   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1113   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1114 else
1115   AR_FOR_BUILD="\$(AR)"
1116   AS_FOR_BUILD="\$(AS)"
1117   CC_FOR_BUILD="\$(CC)"
1118   CXX_FOR_BUILD="\$(CXX)"
1119   GCJ_FOR_BUILD="\$(GCJ)"
1120   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1121   GOC_FOR_BUILD="\$(GOC)"
1122   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1123   LD_FOR_BUILD="\$(LD)"
1124   NM_FOR_BUILD="\$(NM)"
1125   RANLIB_FOR_BUILD="\$(RANLIB)"
1126   WINDRES_FOR_BUILD="\$(WINDRES)"
1127   WINDMC_FOR_BUILD="\$(WINDMC)"
1128 fi
1129
1130 AC_PROG_CC
1131 AC_PROG_CXX
1132
1133 # We must set the default linker to the linker used by gcc for the correct
1134 # operation of libtool.  If LD is not defined and we are using gcc, try to
1135 # set the LD default to the ld used by gcc.
1136 if test -z "$LD"; then
1137   if test "$GCC" = yes; then
1138     case $build in
1139     *-*-mingw*)
1140       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1141     *)
1142       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1143     esac
1144     case $gcc_prog_ld in
1145     # Accept absolute paths.
1146     [[\\/]* | [A-Za-z]:[\\/]*)]
1147       LD="$gcc_prog_ld" ;;
1148     esac
1149   fi
1150 fi
1151
1152 ACX_PROG_GNAT
1153 ACX_PROG_CMP_IGNORE_INITIAL
1154
1155 AC_ARG_ENABLE([bootstrap],
1156 [AS_HELP_STRING([--enable-bootstrap],
1157                 [enable bootstrapping @<:@yes if native build@:>@])],,
1158 enable_bootstrap=default)
1159
1160 # Issue errors and warnings for invalid/strange bootstrap combinations.
1161 if test -r $srcdir/gcc/configure; then
1162   have_compiler=yes
1163 else
1164   have_compiler=no
1165 fi
1166
1167 case "$have_compiler:$host:$target:$enable_bootstrap" in
1168   *:*:*:no) ;;
1169
1170   # Default behavior.  Enable bootstrap if we have a compiler
1171   # and we are in a native configuration.
1172   yes:$build:$build:default)
1173     enable_bootstrap=yes ;;
1174
1175   *:*:*:default)
1176     enable_bootstrap=no ;;
1177
1178   # We have a compiler and we are in a native configuration, bootstrap is ok
1179   yes:$build:$build:yes)
1180     ;;
1181
1182   # Other configurations, but we have a compiler.  Assume the user knows
1183   # what he's doing.
1184   yes:*:*:yes)
1185     AC_MSG_WARN([trying to bootstrap a cross compiler])
1186     ;;
1187
1188   # No compiler: if they passed --enable-bootstrap explicitly, fail
1189   no:*:*:yes)
1190     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1191
1192   # Fail if wrong command line
1193   *)
1194     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1195     ;;
1196 esac
1197
1198 # See if we are building gcc with C++.
1199 AC_ARG_ENABLE(build-with-cxx,
1200 [AS_HELP_STRING([--enable-build-with-cxx],
1201                 [build with C++ compiler instead of C compiler])],
1202 ENABLE_BUILD_WITH_CXX=$enableval,
1203 ENABLE_BUILD_WITH_CXX=no)
1204
1205 # Build stage1 with C and build stages 2 and 3 with C++.
1206 AC_ARG_ENABLE(build-poststage1-with-cxx,
1207 [AS_HELP_STRING([--enable-build-poststage1-with-cxx],
1208                 [build stages 2 and 3 with C++, not C])],
1209 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=$enableval,
1210 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=yes)
1211
1212 # Used for setting $lt_cv_objdir
1213 _LT_CHECK_OBJDIR
1214
1215 # Check for GMP, MPFR and MPC
1216 gmplibs="-lmpc -lmpfr -lgmp"
1217 gmpinc=
1218 have_gmp=no
1219
1220 # Specify a location for mpc
1221 # check for this first so it ends up on the link line before mpfr.
1222 AC_ARG_WITH(mpc,
1223 [AS_HELP_STRING([--with-mpc=PATH],
1224                 [specify prefix directory for installed MPC package.
1225                  Equivalent to --with-mpc-include=PATH/include
1226                  plus --with-mpc-lib=PATH/lib])])
1227 AC_ARG_WITH(mpc-include,
1228 [AS_HELP_STRING([--with-mpc-include=PATH],
1229                 [specify directory for installed MPC include files])])
1230 AC_ARG_WITH(mpc-lib,
1231 [AS_HELP_STRING([--with-mpc-lib=PATH],
1232                 [specify directory for the installed MPC library])])
1233
1234 if test "x$with_mpc" != x; then
1235   gmplibs="-L$with_mpc/lib $gmplibs"
1236   gmpinc="-I$with_mpc/include $gmpinc"
1237 fi
1238 if test "x$with_mpc_include" != x; then
1239   gmpinc="-I$with_mpc_include $gmpinc"
1240 fi
1241 if test "x$with_mpc_lib" != x; then
1242   gmplibs="-L$with_mpc_lib $gmplibs"
1243 fi
1244 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1245   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1246   gmpinc='-I$$s/mpc/src '"$gmpinc"
1247   # Do not test the mpc version.  Assume that it is sufficient, since
1248   # it is in the source tree, and the library has not been built yet
1249   # but it would be included on the link line in the version check below
1250   # hence making the test fail.
1251   have_gmp=yes
1252 fi
1253
1254 # Specify a location for mpfr
1255 # check for this first so it ends up on the link line before gmp.
1256 AC_ARG_WITH(mpfr-dir,
1257 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1258 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1259 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1260
1261 AC_ARG_WITH(mpfr,
1262 [AS_HELP_STRING([--with-mpfr=PATH],
1263                 [specify prefix directory for installed MPFR package.
1264                  Equivalent to --with-mpfr-include=PATH/include
1265                  plus --with-mpfr-lib=PATH/lib])])
1266 AC_ARG_WITH(mpfr-include,
1267 [AS_HELP_STRING([--with-mpfr-include=PATH],
1268                 [specify directory for installed MPFR include files])])
1269 AC_ARG_WITH(mpfr-lib,
1270 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1271                 [specify directory for the installed MPFR library])])
1272
1273 if test "x$with_mpfr" != x; then
1274   gmplibs="-L$with_mpfr/lib $gmplibs"
1275   gmpinc="-I$with_mpfr/include $gmpinc"
1276 fi
1277 if test "x$with_mpfr_include" != x; then
1278   gmpinc="-I$with_mpfr_include $gmpinc"
1279 fi
1280 if test "x$with_mpfr_lib" != x; then
1281   gmplibs="-L$with_mpfr_lib $gmplibs"
1282 fi
1283 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1284   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1285   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1286   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1287   # Do not test the mpfr version.  Assume that it is sufficient, since
1288   # it is in the source tree, and the library has not been built yet
1289   # but it would be included on the link line in the version check below
1290   # hence making the test fail.
1291   have_gmp=yes
1292 fi
1293
1294 # Specify a location for gmp
1295 AC_ARG_WITH(gmp-dir,
1296 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1297 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1298 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1299
1300 AC_ARG_WITH(gmp,
1301 [AS_HELP_STRING([--with-gmp=PATH],
1302                 [specify prefix directory for the installed GMP package.
1303                  Equivalent to --with-gmp-include=PATH/include
1304                  plus --with-gmp-lib=PATH/lib])])
1305 AC_ARG_WITH(gmp-include,
1306 [AS_HELP_STRING([--with-gmp-include=PATH],
1307                 [specify directory for installed GMP include files])])
1308 AC_ARG_WITH(gmp-lib,
1309 [AS_HELP_STRING([--with-gmp-lib=PATH],
1310                 [specify directory for the installed GMP library])])
1311
1312
1313 if test "x$with_gmp" != x; then
1314   gmplibs="-L$with_gmp/lib $gmplibs"
1315   gmpinc="-I$with_gmp/include $gmpinc"
1316 fi
1317 if test "x$with_gmp_include" != x; then
1318   gmpinc="-I$with_gmp_include $gmpinc"
1319 fi
1320 if test "x$with_gmp_lib" != x; then
1321   gmplibs="-L$with_gmp_lib $gmplibs"
1322 fi
1323 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1324   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1325   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1326   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1327   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1328   # Do not test the gmp version.  Assume that it is sufficient, since
1329   # it is in the source tree, and the library has not been built yet
1330   # but it would be included on the link line in the version check below
1331   # hence making the test fail.
1332   have_gmp=yes
1333 fi
1334
1335 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1336   have_gmp=yes
1337   saved_CFLAGS="$CFLAGS"
1338   CFLAGS="$CFLAGS $gmpinc"
1339   # Check for the recommended and required versions of GMP.
1340   AC_MSG_CHECKING([for the correct version of gmp.h])
1341   AC_TRY_COMPILE([#include "gmp.h"],[
1342   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1343   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1344   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1345   choke me
1346   #endif
1347   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1348   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1349   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1350   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1351   choke me
1352   #endif
1353   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1354    [AC_MSG_RESULT([no]); have_gmp=no])
1355
1356   # If we have GMP, check the MPFR version.
1357   if test x"$have_gmp" = xyes; then
1358     # Check for the recommended and required versions of MPFR.
1359     AC_MSG_CHECKING([for the correct version of mpfr.h])
1360     AC_TRY_COMPILE([#include <gmp.h>
1361     #include <mpfr.h>],[
1362     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1363     choke me
1364     #endif
1365     ], [AC_TRY_COMPILE([#include <gmp.h>
1366     #include <mpfr.h>],[
1367     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1368     choke me
1369     #endif
1370     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1371      [AC_MSG_RESULT([no]); have_gmp=no])
1372   fi
1373
1374   # Check for the MPC header version.
1375   if test x"$have_gmp" = xyes ; then
1376     # Check for the recommended and required versions of MPC.
1377     AC_MSG_CHECKING([for the correct version of mpc.h])
1378     AC_TRY_COMPILE([#include <mpc.h>],[
1379     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1380     choke me
1381     #endif
1382     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1383     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1384     choke me
1385     #endif
1386     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1387      [AC_MSG_RESULT([no]); have_gmp=no])
1388   fi
1389
1390   # Now check the MPFR library.
1391   if test x"$have_gmp" = xyes; then
1392     saved_LIBS="$LIBS"
1393     LIBS="$LIBS $gmplibs"
1394     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1395     AC_TRY_LINK([#include <mpc.h>],[
1396     mpfr_t n;
1397     mpfr_t x;
1398     mpc_t c;
1399     int t;
1400     mpfr_init (n);
1401     mpfr_init (x);
1402     mpfr_atan2 (n, n, x, GMP_RNDN);
1403     mpfr_erfc (n, x, GMP_RNDN);
1404     mpfr_subnormalize (x, t, GMP_RNDN);
1405     mpfr_clear(n);
1406     mpfr_clear(x);
1407     mpc_init2 (c, 53);
1408     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1409     mpc_cosh (c, c, MPC_RNDNN);
1410     mpc_pow (c, c, c, MPC_RNDNN);
1411     mpc_acosh (c, c, MPC_RNDNN);
1412     mpc_clear (c);
1413     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1414     LIBS="$saved_LIBS"
1415   fi
1416
1417   CFLAGS="$saved_CFLAGS"
1418
1419 # The library versions listed in the error message below should match
1420 # the HARD-minimums enforced above.
1421   if test x$have_gmp != xyes; then
1422     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1423 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1424 their locations.  Source code for these libraries can be found at
1425 their respective hosting sites as well as at
1426 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1427 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1428 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1429 make sure that you have installed both the libraries and the header
1430 files.  They may be located in separate packages.])
1431   fi
1432 fi
1433
1434 # Flags needed for both GMP, MPFR and/or MPC.
1435 AC_SUBST(gmplibs)
1436 AC_SUBST(gmpinc)
1437 AC_SUBST(extra_mpfr_configure_flags)
1438 AC_SUBST(extra_mpc_gmp_configure_flags)
1439 AC_SUBST(extra_mpc_mpfr_configure_flags)
1440
1441 # Allow host libstdc++ to be specified for static linking with PPL.
1442 AC_ARG_WITH(host-libstdcxx,
1443 [AS_HELP_STRING([--with-host-libstdcxx=L],
1444                 [use linker arguments L to link with libstdc++
1445                  when linking with PPL])])
1446
1447 case $with_host_libstdcxx in
1448   no|yes)
1449     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1450     ;;
1451 esac
1452
1453 # Linker flags to use for stage1 or when not boostrapping.
1454 AC_ARG_WITH(stage1-ldflags,
1455 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1456 [if test "$withval" = "no" -o "$withval" = "yes"; then
1457    stage1_ldflags=
1458  else
1459    stage1_ldflags=$withval
1460  fi],
1461 [stage1_ldflags=])
1462 AC_SUBST(stage1_ldflags)
1463
1464 # Libraries to use for stage1 or when not bootstrapping.
1465 AC_ARG_WITH(stage1-libs,
1466 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1467 [if test "$withval" = "no" -o "$withval" = "yes"; then
1468    stage1_libs=
1469  else
1470    stage1_libs=$withval
1471  fi],
1472 [stage1_libs=$with_host_libstdcxx])
1473 AC_SUBST(stage1_libs)
1474
1475 # Libraries to use for stage2 and later builds.  This defaults to the
1476 # argument passed to --with-host-libstdcxx.
1477 AC_ARG_WITH(boot-libs,
1478 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1479 [if test "$withval" = "no" -o "$withval" = "yes"; then
1480    poststage1_libs=
1481  else
1482    poststage1_libs=$withval
1483  fi],
1484 [poststage1_libs=$with_host_libstdcxx])
1485 AC_SUBST(poststage1_libs)
1486
1487 # Linker flags to use for stage2 and later builds.
1488 AC_ARG_WITH(boot-ldflags,
1489 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1490                 [linker flags for stage2 and later])],
1491 [if test "$withval" = "no" -o "$withval" = "yes"; then
1492    poststage1_ldflags=
1493  else
1494    poststage1_ldflags=$withval
1495  fi],
1496 [poststage1_ldflags=
1497  # In stages 2 and 3, default to linking libstdc++ and libgcc
1498  # statically.  But if the user explicitly specified the libraries to
1499  # use, trust that they are doing what they want.
1500  if test "$poststage1_libs" = ""; then
1501    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1502  fi])
1503 AC_SUBST(poststage1_ldflags)
1504
1505 # Check for PPL
1506 ppllibs=
1507 pplinc=
1508 pwllib=
1509
1510 AC_ARG_WITH(ppl,
1511 [AS_HELP_STRING([--with-ppl=PATH],
1512                 [specify prefix directory for the installed PPL package.
1513                  Equivalent to --with-ppl-include=PATH/include
1514                  plus --with-ppl-lib=PATH/lib])])
1515 AC_ARG_WITH(ppl-include,
1516 [AS_HELP_STRING([--with-ppl-include=PATH],
1517                 [specify directory for installed PPL include files])])
1518 AC_ARG_WITH(ppl-lib,
1519 [AS_HELP_STRING([--with-ppl-lib=PATH],
1520                 [specify directory for the installed PPL library])])
1521
1522 AC_ARG_ENABLE(ppl-version-check,
1523 [AS_HELP_STRING([--disable-ppl-version-check],
1524                 [disable check for PPL version])])
1525
1526 case $with_ppl in
1527   yes | no | "")
1528     ;;
1529   *)
1530     ppllibs="-L$with_ppl/lib"
1531     pplinc="-I$with_ppl/include $pplinc"
1532     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1533       with_ppl=yes
1534     else
1535       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1536     fi
1537     ;;
1538 esac
1539
1540 if test x"$with_ppl_include" != x; then
1541   pplinc="-I$with_ppl_include $pplinc"
1542   with_ppl=yes
1543 fi
1544
1545 if test "x$with_ppl_lib" != x; then
1546   ppllibs="-L$with_ppl_lib"
1547   with_ppl=yes
1548 fi
1549
1550 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1551   if test x"$enable_watchdog" = xyes; then
1552     pwllib="-lpwl"
1553   fi
1554   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1555   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1556   enable_ppl_version_check=no
1557   with_ppl=yes
1558 fi
1559
1560 if test "x$with_ppl" != xno; then
1561   if test "x$pwllib" = x; then
1562     saved_LIBS="$LIBS"
1563     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1564     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1565     LIBS="$saved_LIBS"
1566   fi
1567
1568   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1569
1570   if test "$enable_ppl_version_check" != no; then
1571     saved_CFLAGS="$CFLAGS"
1572     CFLAGS="$CFLAGS $pplinc $gmpinc"
1573     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1574     AC_TRY_COMPILE([#include "ppl_c.h"],[
1575     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1576     choke me
1577     #endif
1578     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1579     CFLAGS="$saved_CFLAGS"
1580   fi
1581 fi
1582
1583 # Flags needed for PPL
1584 AC_SUBST(ppllibs)
1585 AC_SUBST(pplinc)
1586
1587
1588 # Check for CLOOG
1589
1590 dnl Provide configure switches and initialize clooginc & clooglibs
1591 dnl with user input.
1592 CLOOG_INIT_FLAGS
1593 if test "x$with_ppl" = "xno"; then
1594   dnl Only execute fail-action, if CLooG has been requested.
1595   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1596   if test "${graphite_requested}" = yes; then
1597     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1598   fi
1599   with_cloog=no
1600 fi
1601 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1602   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1603   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1604   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1605 fi
1606 if test "x$with_cloog" != "xno"; then
1607   dnl The minimal version of CLooG required for Graphite.
1608   dnl
1609   dnl If we use CLooG-Legacy, the provided version information is
1610   dnl ignored.
1611   CLOOG_CHECK_VERSION(0,16,1)
1612
1613   dnl Only execute fail-action, if CLooG has been requested.
1614   CLOOG_IF_FAILED([
1615     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1616 fi
1617
1618 # Check for LTO support.
1619 AC_ARG_ENABLE(lto,
1620 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1621 enable_lto=$enableval,
1622 enable_lto=yes; default_enable_lto=yes)
1623
1624 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1625   build_lto_plugin=yes
1626 ],[if test x"$default_enable_lto" = x"yes" ; then
1627     case $target in
1628       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1629       # On other non-ELF platforms, LTO has yet to be validated.
1630       *) enable_lto=no ;;
1631     esac
1632   else
1633   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1634   # It would also be nice to check the binutils support, but we don't
1635   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1636   # warn during gcc/ subconfigure; unless you're bootstrapping with
1637   # -flto it won't be needed until after installation anyway.
1638     case $target in
1639       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1640       *) if test x"$enable_lto" = x"yes"; then
1641         AC_MSG_ERROR([LTO support is not enabled for this target.])
1642         fi
1643       ;;
1644     esac
1645   fi
1646   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1647   # Build it unless LTO was explicitly disabled.
1648   case $target in
1649     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1650     *) ;;
1651   esac
1652 ])
1653
1654
1655 # By default, C is the only stage 1 language.
1656 stage1_languages=,c,
1657
1658 # Target libraries that we bootstrap.
1659 bootstrap_target_libs=,target-libgcc,
1660
1661 # Figure out what language subdirectories are present.
1662 # Look if the user specified --enable-languages="..."; if not, use
1663 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1664 # go away some day.
1665 # NB:  embedded tabs in this IF block -- do not untabify
1666 if test -d ${srcdir}/gcc; then
1667   if test x"${enable_languages+set}" != xset; then
1668     if test x"${LANGUAGES+set}" = xset; then
1669       enable_languages="${LANGUAGES}"
1670         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1671     else
1672       enable_languages=all
1673     fi
1674   else
1675     if test x"${enable_languages}" = x ||
1676        test x"${enable_languages}" = xyes;
1677        then
1678       echo configure.in: --enable-languages needs at least one language argument 1>&2
1679       exit 1
1680     fi
1681   fi
1682   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1683
1684   # 'f95' is the old name for the 'fortran' language. We issue a warning
1685   # and make the substitution.
1686   case ,${enable_languages}, in
1687     *,f95,*)
1688       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1689       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1690       ;;
1691   esac
1692
1693   # If bootstrapping, then using --enable-build-with-cxx or
1694   # --enable-build-poststage1-with-cxx requires enabling C++.
1695   case ",$enable_languages,:,$ENABLE_BUILD_WITH_CXX,$ENABLE_BUILD_POSTSTAGE1_WITH_CXX,:$enable_bootstrap" in
1696     *,c++,*:*:*) ;;
1697     *:*,yes,*:yes)
1698       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1699         enable_languages="${enable_languages},c++"
1700       else
1701         AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx or --enable-build-poststage1-with-cxx requires c++ sources])
1702       fi
1703       ;;
1704   esac
1705
1706   # First scan to see if an enabled language requires some other language.
1707   # We assume that a given config-lang.in will list all the language
1708   # front ends it requires, even if some are required indirectly.
1709   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1710     case ${lang_frag} in
1711       ..) ;;
1712       # The odd quoting in the next line works around
1713       # an apparent bug in bash 1.12 on linux.
1714       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1715       *)
1716         # From the config-lang.in, get $language, $lang_requires, and
1717         # $lang_requires_boot_languages.
1718         language=
1719         lang_requires=
1720         lang_requires_boot_languages=
1721         . ${lang_frag}
1722         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1723           case ,${enable_languages}, in
1724             *,$other,*) ;;
1725             *,all,*) ;;
1726             *,$language,*)
1727               echo " \`$other' language required by \`$language'; enabling" 1>&2
1728               enable_languages="${enable_languages},${other}"
1729               ;;
1730           esac
1731         done
1732         for other in ${lang_requires_boot_languages} ; do
1733           if test "$other" != "c"; then
1734             case ,${enable_stage1_languages}, in
1735               *,$other,*) ;;
1736               *,all,*) ;;
1737               *)
1738                 case ,${enable_languages}, in
1739                   *,$language,*)
1740                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1741                     enable_stage1_languages="$enable_stage1_languages,${other}"
1742                     ;;
1743                 esac
1744                 ;;
1745             esac
1746           fi
1747         done
1748         ;;
1749     esac
1750   done
1751
1752   new_enable_languages=,c,
1753
1754   # If LTO is enabled, add the LTO front end.
1755   extra_host_libiberty_configure_flags=
1756   if test "$enable_lto" = "yes" ; then
1757     case ,${enable_languages}, in
1758       *,lto,*) ;;
1759       *) enable_languages="${enable_languages},lto" ;;
1760     esac
1761     if test "${build_lto_plugin}" = "yes" ; then
1762       configdirs="$configdirs lto-plugin"
1763       extra_host_libiberty_configure_flags=--enable-shared
1764     fi
1765   fi
1766   AC_SUBST(extra_host_libiberty_configure_flags)
1767
1768   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1769   potential_languages=,c,
1770
1771   enabled_target_libs=
1772   disabled_target_libs=
1773
1774   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1775     case ${lang_frag} in
1776       ..) ;;
1777       # The odd quoting in the next line works around
1778       # an apparent bug in bash 1.12 on linux.
1779       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1780       *)
1781         # From the config-lang.in, get $language, $target_libs,
1782         # $lang_dirs, $boot_language, and $build_by_default
1783         language=
1784         target_libs=
1785         lang_dirs=
1786         subdir_requires=
1787         boot_language=no
1788         build_by_default=yes
1789         . ${lang_frag}
1790         if test x${language} = x; then
1791           echo "${lang_frag} doesn't set \$language." 1>&2
1792           exit 1
1793         fi
1794
1795         if test "$language" = "c++"; then
1796           if test "$ENABLE_BUILD_WITH_CXX" = "yes" \
1797              || test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
1798             boot_language=yes
1799           fi
1800         fi
1801
1802         case ,${enable_languages}, in
1803           *,${language},*)
1804             # Language was explicitly selected; include it.
1805             add_this_lang=yes
1806             ;;
1807           *,all,*)
1808             # 'all' was selected, select it if it is a default language
1809             add_this_lang=${build_by_default}
1810             ;;
1811           *)
1812             add_this_lang=no
1813             ;;
1814         esac
1815
1816         # Disable languages that need other directories if these aren't available.
1817         for i in $subdir_requires; do
1818           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1819           case ,${enable_languages}, in
1820             *,${language},*)
1821               # Specifically requested language; tell them.
1822               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1823               ;;
1824             *)
1825               # Silently disable.
1826               add_this_lang=unsupported
1827               ;;
1828           esac
1829         done
1830
1831         # Disable Ada if no preexisting GNAT is available.
1832         case ,${enable_languages},:${language}:${have_gnat} in
1833           *,${language},*:ada:no)
1834             # Specifically requested language; tell them.
1835             AC_MSG_ERROR([GNAT is required to build $language])
1836             ;;
1837           *:ada:no)
1838             # Silently disable.
1839             add_this_lang=unsupported
1840             ;;
1841         esac
1842
1843         # Disable a language that is unsupported by the target.
1844         case " $unsupported_languages " in
1845           *" $language "*)
1846             add_this_lang=unsupported
1847             ;;
1848         esac
1849
1850         case $add_this_lang in
1851           unsupported)
1852             # Remove language-dependent dirs.
1853             disabled_target_libs="$disabled_target_libs $target_libs"
1854             noconfigdirs="$noconfigdirs $lang_dirs"
1855             ;;
1856           no)
1857             # Remove language-dependent dirs; still show language as supported.
1858             disabled_target_libs="$disabled_target_libs $target_libs"
1859             noconfigdirs="$noconfigdirs $lang_dirs"
1860             potential_languages="${potential_languages}${language},"
1861             ;;
1862           yes)
1863             new_enable_languages="${new_enable_languages}${language},"
1864             potential_languages="${potential_languages}${language},"
1865             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1866             enabled_target_libs="$enabled_target_libs $target_libs"
1867             case "${boot_language}:,$enable_stage1_languages," in
1868               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1869                 # Add to (comma-separated) list of stage 1 languages.
1870                 case ",$stage1_languages," in
1871                   *,$language,* | ,yes, | ,all,) ;;
1872                   *) stage1_languages="${stage1_languages}${language}," ;;
1873                 esac
1874                 # We need to bootstrap any supporting libraries.
1875                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1876                 ;;
1877             esac
1878             ;;
1879         esac
1880         ;;
1881     esac
1882   done
1883
1884   # Add target libraries which are only needed for disabled languages
1885   # to noconfigdirs.
1886   if test -n "$disabled_target_libs"; then
1887     for dir in $disabled_target_libs; do
1888       case " $enabled_target_libs " in
1889       *" ${dir} "*) ;;
1890       *) noconfigdirs="$noconfigdirs $dir" ;;
1891       esac
1892     done
1893   fi
1894
1895   AC_ARG_ENABLE(stage1-languages,
1896   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1897                   [choose additional languages to build during
1898                   stage1.  Mostly useful for compiler development])],
1899   [case ,${enable_stage1_languages}, in
1900     ,no,|,,)
1901       # Set it to something that will have no effect in the loop below
1902       enable_stage1_languages=c ;;
1903     ,yes,)
1904       enable_stage1_languages=`echo $new_enable_languages | \
1905         sed -e "s/^,//" -e "s/,$//" ` ;;
1906     *,all,*)
1907       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1908         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1909   esac
1910
1911   # Add "good" languages from enable_stage1_languages to stage1_languages,
1912   # while "bad" languages go in missing_languages.  Leave no duplicates.
1913   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1914     case $potential_languages in
1915       *,$i,*)
1916         case $stage1_languages in
1917           *,$i,*) ;;
1918           *) stage1_languages="$stage1_languages$i," ;;
1919         esac ;;
1920       *)
1921         case $missing_languages in
1922           *,$i,*) ;;
1923           *) missing_languages="$missing_languages$i," ;;
1924         esac ;;
1925      esac
1926   done])
1927
1928   # Remove leading/trailing commas that were added for simplicity
1929   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1930   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1931   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1932   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1933
1934   if test "x$missing_languages" != x; then
1935     AC_MSG_ERROR([
1936 The following requested languages could not be built: ${missing_languages}
1937 Supported languages are: ${potential_languages}])
1938   fi
1939   if test "x$new_enable_languages" != "x$enable_languages"; then
1940     echo The following languages will be built: ${new_enable_languages}
1941     enable_languages="$new_enable_languages"
1942   fi
1943
1944   AC_SUBST(stage1_languages)
1945   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1946 fi
1947
1948 # Handle --disable-<component> generically.
1949 for dir in $configdirs $build_configdirs $target_configdirs ; do
1950   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1951   varname=`echo $dirname | sed -e s/+/_/g`
1952   if eval test x\${enable_${varname}} "=" xno ; then
1953     noconfigdirs="$noconfigdirs $dir"
1954   fi
1955 done
1956
1957 # Check for Boehm's garbage collector
1958 AC_ARG_ENABLE(objc-gc,
1959 [AS_HELP_STRING([--enable-objc-gc],
1960                 [enable use of Boehm's garbage collector with the
1961                  GNU Objective-C runtime])],
1962 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1963   *,objc,*:*:yes:*target-boehm-gc*)
1964     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1965     ;;
1966 esac])
1967
1968 # Make sure we only build Boehm's garbage collector if required.
1969 case ,${enable_languages},:${enable_objc_gc} in
1970   *,objc,*:yes)
1971     # Keep target-boehm-gc if requested for Objective-C.
1972     ;;
1973   *)
1974     # Otherwise remove target-boehm-gc depending on target-libjava.
1975     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1976       noconfigdirs="$noconfigdirs target-boehm-gc"
1977     fi
1978     ;;
1979 esac
1980
1981 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1982 # $build_configdirs and $target_configdirs.
1983 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1984
1985 notsupp=""
1986 for dir in . $skipdirs $noconfigdirs ; do
1987   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1988   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1989     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1990     if test -r $srcdir/$dirname/configure ; then
1991       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1992         true
1993       else
1994         notsupp="$notsupp $dir"
1995       fi
1996     fi
1997   fi
1998   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1999     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2000     if test -r $srcdir/$dirname/configure ; then
2001       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2002         true
2003       else
2004         notsupp="$notsupp $dir"
2005       fi
2006     fi
2007   fi
2008   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2009     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2010     if test -r $srcdir/$dirname/configure ; then
2011       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2012         true
2013       else
2014         notsupp="$notsupp $dir"
2015       fi
2016     fi
2017   fi
2018 done
2019
2020 # Quietly strip out all directories which aren't configurable in this tree.
2021 # This relies on all configurable subdirectories being autoconfiscated, which
2022 # is now the case.
2023 build_configdirs_all="$build_configdirs"
2024 build_configdirs=
2025 for i in ${build_configdirs_all} ; do
2026   j=`echo $i | sed -e s/build-//g`
2027   if test -f ${srcdir}/$j/configure ; then
2028     build_configdirs="${build_configdirs} $i"
2029   fi
2030 done
2031
2032 configdirs_all="$configdirs"
2033 configdirs=
2034 for i in ${configdirs_all} ; do
2035   if test -f ${srcdir}/$i/configure ; then
2036     configdirs="${configdirs} $i"
2037   fi
2038 done
2039
2040 target_configdirs_all="$target_configdirs"
2041 target_configdirs=
2042 for i in ${target_configdirs_all} ; do
2043   j=`echo $i | sed -e s/target-//g`
2044   if test -f ${srcdir}/$j/configure ; then
2045     target_configdirs="${target_configdirs} $i"
2046   fi
2047 done
2048
2049 # Produce a warning message for the subdirs we can't configure.
2050 # This isn't especially interesting in the Cygnus tree, but in the individual
2051 # FSF releases, it's important to let people know when their machine isn't
2052 # supported by the one or two programs in a package.
2053
2054 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2055   # If $appdirs is non-empty, at least one of those directories must still
2056   # be configured, or we error out.  (E.g., if the gas release supports a
2057   # specified target in some subdirs but not the gas subdir, we shouldn't
2058   # pretend that all is well.)
2059   if test -n "$appdirs" ; then
2060     for dir in $appdirs ; do
2061       if test -r $dir/Makefile.in ; then
2062         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2063           appdirs=""
2064           break
2065         fi
2066         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2067           appdirs=""
2068           break
2069         fi
2070       fi
2071     done
2072     if test -n "$appdirs" ; then
2073       echo "*** This configuration is not supported by this package." 1>&2
2074       exit 1
2075     fi
2076   fi
2077   # Okay, some application will build, or we don't care to check.  Still
2078   # notify of subdirs not getting built.
2079   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2080   echo "    ${notsupp}" 1>&2
2081   echo "    (Any other directories should still work fine.)" 1>&2
2082 fi
2083
2084 case "$host" in
2085   *msdosdjgpp*)
2086     enable_gdbtk=no ;;
2087 esac
2088
2089 # To find our prefix, in gcc_cv_tool_prefix.
2090 ACX_TOOL_DIRS
2091
2092 copy_dirs=
2093
2094 AC_ARG_WITH([build-sysroot],
2095   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2096                   [use sysroot as the system root during the build])],
2097   [if test x"$withval" != x ; then
2098      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2099    fi],
2100   [SYSROOT_CFLAGS_FOR_TARGET=])
2101 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2102
2103 AC_ARG_WITH([debug-prefix-map],
2104   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2105                   [map A to B, C to D ... in debug information])],
2106   [if test x"$withval" != x; then
2107      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2108      for debug_map in $withval; do
2109        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2110      done
2111    fi],
2112   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2113 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2114
2115 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2116 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2117 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2118 # We want to ensure that TARGET libraries (which we know are built with
2119 # gcc) are built with "-O2 -g", so include those options when setting
2120 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2121 if test "x$CFLAGS_FOR_TARGET" = x; then
2122   CFLAGS_FOR_TARGET=$CFLAGS
2123   case " $CFLAGS " in
2124     *" -O2 "*) ;;
2125     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2126   esac
2127   case " $CFLAGS " in
2128     *" -g "* | *" -g3 "*) ;;
2129     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2130   esac
2131 fi
2132 AC_SUBST(CFLAGS_FOR_TARGET)
2133
2134 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2135   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2136   case " $CXXFLAGS " in
2137     *" -O2 "*) ;;
2138     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2139   esac
2140   case " $CXXFLAGS " in
2141     *" -g "* | *" -g3 "*) ;;
2142     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2143   esac
2144 fi
2145 AC_SUBST(CXXFLAGS_FOR_TARGET)
2146
2147 AC_SUBST(LDFLAGS_FOR_TARGET)
2148
2149 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2150 # the named directory are copied to $(tooldir)/sys-include.
2151 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2152   if test x${is_cross_compiler} = xno ; then
2153     echo 1>&2 '***' --with-headers is only supported when cross compiling
2154     exit 1
2155   fi
2156   if test x"${with_headers}" != xyes ; then
2157     x=${gcc_cv_tool_prefix}
2158     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2159   fi
2160 fi
2161
2162 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2163 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2164 # are permitted.
2165 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2166   if test x${is_cross_compiler} = xno ; then
2167     echo 1>&2 '***' --with-libs is only supported when cross compiling
2168     exit 1
2169   fi
2170   if test x"${with_libs}" != xyes ; then
2171     # Copy the libraries in reverse order, so that files in the first named
2172     # library override files in subsequent libraries.
2173     x=${gcc_cv_tool_prefix}
2174     for l in ${with_libs}; do
2175       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2176     done
2177   fi
2178 fi
2179
2180 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2181 #
2182 # This is done by determining whether or not the appropriate directory
2183 # is available, and by checking whether or not specific configurations
2184 # have requested that this magic not happen.
2185 #
2186 # The command line options always override the explicit settings in
2187 # configure.in, and the settings in configure.in override this magic.
2188 #
2189 # If the default for a toolchain is to use GNU as and ld, and you don't
2190 # want to do that, then you should use the --without-gnu-as and
2191 # --without-gnu-ld options for the configure script.  Similarly, if
2192 # the default is to use the included zlib and you don't want to do that,
2193 # you should use the --with-system-zlib option for the configure script.
2194
2195 if test x${use_gnu_as} = x &&
2196    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2197   with_gnu_as=yes
2198   extra_host_args="$extra_host_args --with-gnu-as"
2199 fi
2200
2201 if test x${use_gnu_ld} = x &&
2202    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2203   with_gnu_ld=yes
2204   extra_host_args="$extra_host_args --with-gnu-ld"
2205 fi
2206
2207 if test x${use_included_zlib} = x &&
2208    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2209   :
2210 else
2211   with_system_zlib=yes
2212   extra_host_args="$extra_host_args --with-system-zlib"
2213 fi
2214
2215 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2216 # can detect this case.
2217
2218 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2219   with_newlib=yes
2220   extra_host_args="$extra_host_args --with-newlib"
2221 fi
2222
2223 # Handle ${copy_dirs}
2224 set fnord ${copy_dirs}
2225 shift
2226 while test $# != 0 ; do
2227   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2228     :
2229   else
2230     echo Copying $1 to $2
2231
2232     # Use the install script to create the directory and all required
2233     # parent directories.
2234     if test -d $2 ; then
2235       :
2236     else
2237       echo >config.temp
2238       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2239     fi
2240
2241     # Copy the directory, assuming we have tar.
2242     # FIXME: Should we use B in the second tar?  Not all systems support it.
2243     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2244
2245     # It is the responsibility of the user to correctly adjust all
2246     # symlinks.  If somebody can figure out how to handle them correctly
2247     # here, feel free to add the code.
2248
2249     echo $1 > $2/COPIED
2250   fi
2251   shift; shift
2252 done
2253
2254 # Determine a target-dependent exec_prefix that the installed
2255 # gcc will search in.  Keep this list sorted by triplet, with
2256 # the *-*-osname triplets last.
2257 md_exec_prefix=
2258 case "${target}" in
2259   i[[34567]]86-pc-msdosdjgpp*)
2260     md_exec_prefix=/dev/env/DJDIR/bin
2261     ;;
2262   *-*-hpux* | \
2263   *-*-nto-qnx* | \
2264   *-*-solaris2*)
2265     md_exec_prefix=/usr/ccs/bin
2266     ;;
2267 esac
2268
2269 extra_arflags_for_target=
2270 extra_nmflags_for_target=
2271 extra_ranlibflags_for_target=
2272 target_makefile_frag=/dev/null
2273 case "${target}" in
2274   spu-*-*)
2275     target_makefile_frag="config/mt-spu"
2276     ;;
2277   mips*-sde-elf*)
2278     target_makefile_frag="config/mt-sde"
2279     ;;
2280   mipsisa*-*-elfoabi*)
2281     target_makefile_frag="config/mt-mips-elfoabi"
2282     ;;
2283   mips*-*-*linux* | mips*-*-gnu*)
2284     target_makefile_frag="config/mt-mips-gnu"
2285     ;;
2286   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2287     target_makefile_frag="config/mt-gnu"
2288     ;;
2289   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2290     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2291     # commands to handle both 32-bit and 64-bit objects.  These flags are
2292     # harmless if we're using GNU nm or ar.
2293     extra_arflags_for_target=" -X32_64"
2294     extra_nmflags_for_target=" -B -X32_64"
2295     ;;
2296   *-*-darwin[[3-9]]*)
2297     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2298     extra_ranlibflags_for_target=" -c"
2299     ;;
2300 esac
2301
2302 alphaieee_frag=/dev/null
2303 case $target in
2304   alpha*-*-*)
2305     # This just makes sure to use the -mieee option to build target libs.
2306     # This should probably be set individually by each library.
2307     alphaieee_frag="config/mt-alphaieee"
2308     ;;
2309 esac
2310
2311 # If --enable-target-optspace always use -Os instead of -O2 to build
2312 # the target libraries, similarly if it is not specified, use -Os
2313 # on selected platforms.
2314 ospace_frag=/dev/null
2315 case "${enable_target_optspace}:${target}" in
2316   yes:*)
2317     ospace_frag="config/mt-ospace"
2318     ;;
2319   :d30v-*)
2320     ospace_frag="config/mt-d30v"
2321     ;;
2322   :m32r-* | :d10v-* | :fr30-*)
2323     ospace_frag="config/mt-ospace"
2324     ;;
2325   no:* | :*)
2326     ;;
2327   *)
2328     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2329     ;;
2330 esac
2331
2332 # Default to using --with-stabs for certain targets.
2333 if test x${with_stabs} = x ; then
2334   case "${target}" in
2335   mips*-*-irix[[56]]*)
2336     ;;
2337   mips*-*-* | alpha*-*-osf*)
2338     with_stabs=yes;
2339     extra_host_args="${extra_host_args} --with-stabs"
2340     ;;
2341   esac
2342 fi
2343
2344 # Some systems (e.g., one of the i386-aix systems the gas testers are
2345 # using) don't handle "\$" correctly, so don't use it here.
2346 tooldir='${exec_prefix}'/${target_noncanonical}
2347 build_tooldir=${tooldir}
2348
2349 # Create a .gdbinit file which runs the one in srcdir
2350 # and tells GDB to look there for source files.
2351
2352 if test -r ${srcdir}/.gdbinit ; then
2353   case ${srcdir} in
2354     .) ;;
2355     *) cat > ./.gdbinit <<EOF
2356 # ${NO_EDIT}
2357 dir ${srcdir}
2358 dir .
2359 source ${srcdir}/.gdbinit
2360 EOF
2361     ;;
2362   esac
2363 fi
2364
2365 # Make sure that the compiler is able to generate an executable.  If it
2366 # can't, we are probably in trouble.  We don't care whether we can run the
2367 # executable--we might be using a cross compiler--we only care whether it
2368 # can be created.  At this point the main configure script has set CC.
2369 we_are_ok=no
2370 echo "int main () { return 0; }" > conftest.c
2371 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2372 if test $? = 0 ; then
2373   if test -s conftest || test -s conftest.exe ; then
2374     we_are_ok=yes
2375   fi
2376 fi
2377 case $we_are_ok in
2378   no)
2379     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2380     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2381     rm -f conftest*
2382     exit 1
2383     ;;
2384 esac
2385 rm -f conftest*
2386
2387 # Decide which environment variable is used to find dynamic libraries.
2388 case "${host}" in
2389   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2390   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2391   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2392   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2393 esac
2394
2395 # On systems where the dynamic library environment variable is PATH,
2396 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2397 # built executables to PATH.
2398 if test "$RPATH_ENVVAR" = PATH; then
2399   GCC_SHLIB_SUBDIR=/shlib
2400 else
2401   GCC_SHLIB_SUBDIR=
2402 fi
2403
2404 # Record target_configdirs and the configure arguments for target and
2405 # build configuration in Makefile.
2406 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2407 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2408
2409 # If we are building libgomp, bootstrap it.
2410 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2411   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2412 fi
2413
2414 # Determine whether gdb needs tk/tcl or not.
2415 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2416 # and in that case we want gdb to be built without tk.  Ugh!
2417 # In fact I believe gdb is the *only* package directly dependent on tk,
2418 # so we should be able to put the 'maybe's in unconditionally and
2419 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2420 # 100% sure that that's safe though.
2421
2422 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2423 case "$enable_gdbtk" in
2424   no)
2425     GDB_TK="" ;;
2426   yes)
2427     GDB_TK="${gdb_tk}" ;;
2428   *)
2429     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2430     # distro.  Eventually someone will fix this and move Insight, nee
2431     # gdbtk to a separate directory.
2432     if test -d ${srcdir}/gdb/gdbtk ; then
2433       GDB_TK="${gdb_tk}"
2434     else
2435       GDB_TK=""
2436     fi
2437     ;;
2438 esac
2439 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2440 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2441
2442 # Strip out unwanted targets.
2443
2444 # While at that, we remove Makefiles if we were started for recursive
2445 # configuration, so that the top-level Makefile reconfigures them,
2446 # like we used to do when configure itself was recursive.
2447
2448 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2449 # but now we're fixing up the Makefile ourselves with the additional
2450 # commands passed to AC_CONFIG_FILES.  Use separate variables
2451 # extrasub-{build,host,target} not because there is any reason to split
2452 # the substitutions up that way, but only to remain below the limit of
2453 # 99 commands in a script, for HP-UX sed.
2454 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2455
2456 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2457   yes:yes:*\ gold\ *:*,c++,*) ;;
2458   yes:yes:*\ gold\ *:*)
2459     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2460     ;;
2461 esac
2462
2463 # Adjust the toplevel makefile according to whether bootstrap was selected.
2464 case $enable_bootstrap in
2465   yes)
2466     bootstrap_suffix=bootstrap
2467     BUILD_CONFIG=bootstrap-debug
2468     ;;
2469   no)
2470     bootstrap_suffix=no-bootstrap
2471     BUILD_CONFIG=
2472     ;;
2473 esac
2474
2475 AC_MSG_CHECKING(for default BUILD_CONFIG)
2476
2477 AC_ARG_WITH([build-config],
2478   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2479                   [use config/NAME.mk build configuration])],
2480   [case $with_build_config in
2481    yes) with_build_config= ;;
2482    no) with_build_config= BUILD_CONFIG= ;;
2483    esac])
2484
2485 if test "x${with_build_config}" != x; then
2486   BUILD_CONFIG=$with_build_config
2487 else
2488   case $BUILD_CONFIG in
2489   bootstrap-debug)
2490     if echo "int f (void) { return 0; }" > conftest.c &&
2491        ${CC} -c conftest.c &&
2492        mv conftest.o conftest.o.g0 &&
2493        ${CC} -c -g conftest.c &&
2494        mv conftest.o conftest.o.g &&
2495        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2496       :
2497     else
2498       BUILD_CONFIG=
2499     fi
2500     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2501     ;;
2502   esac
2503 fi
2504 AC_MSG_RESULT($BUILD_CONFIG)
2505 AC_SUBST(BUILD_CONFIG)
2506
2507 extrasub_build=
2508 for module in ${build_configdirs} ; do
2509   if test -z "${no_recursion}" \
2510      && test -f ${build_subdir}/${module}/Makefile; then
2511     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2512     rm -f ${build_subdir}/${module}/Makefile
2513   fi
2514   extrasub_build="$extrasub_build
2515 /^@if build-$module\$/d
2516 /^@endif build-$module\$/d
2517 /^@if build-$module-$bootstrap_suffix\$/d
2518 /^@endif build-$module-$bootstrap_suffix\$/d"
2519 done
2520 extrasub_host=
2521 for module in ${configdirs} ; do
2522   if test -z "${no_recursion}"; then
2523     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2524       if test -f ${file}; then
2525         echo 1>&2 "*** removing ${file} to force reconfigure"
2526         rm -f ${file}
2527       fi
2528     done
2529   fi
2530   extrasub_host="$extrasub_host
2531 /^@if $module\$/d
2532 /^@endif $module\$/d
2533 /^@if $module-$bootstrap_suffix\$/d
2534 /^@endif $module-$bootstrap_suffix\$/d"
2535 done
2536 extrasub_target=
2537 for module in ${target_configdirs} ; do
2538   if test -z "${no_recursion}" \
2539      && test -f ${target_subdir}/${module}/Makefile; then
2540     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2541     rm -f ${target_subdir}/${module}/Makefile
2542   fi
2543
2544   # We only bootstrap target libraries listed in bootstrap_target_libs.
2545   case $bootstrap_target_libs in
2546     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2547     *) target_bootstrap_suffix=no-bootstrap ;;
2548   esac
2549
2550   extrasub_target="$extrasub_target
2551 /^@if target-$module\$/d
2552 /^@endif target-$module\$/d
2553 /^@if target-$module-$target_bootstrap_suffix\$/d
2554 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2555 done
2556
2557 # Do the final fixup along with target modules.
2558 extrasub_target="$extrasub_target
2559 /^@if /,/^@endif /d"
2560
2561 # Create the serialization dependencies.  This uses a temporary file.
2562
2563 AC_ARG_ENABLE([serial-configure],
2564 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2565                 [force sequential configuration of
2566                  sub-packages for the host, target or build
2567                  machine, or all sub-packages])])
2568
2569 case ${enable_serial_configure} in
2570   yes)
2571     enable_serial_build_configure=yes
2572     enable_serial_host_configure=yes
2573     enable_serial_target_configure=yes
2574     ;;
2575 esac
2576
2577 # These force 'configure's to be done one at a time, to avoid problems
2578 # with contention over a shared config.cache.
2579 rm -f serdep.tmp
2580 echo '# serdep.tmp' > serdep.tmp
2581 olditem=
2582 test "x${enable_serial_build_configure}" = xyes &&
2583 for item in ${build_configdirs} ; do
2584   case ${olditem} in
2585     "") ;;
2586     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2587   esac
2588   olditem=${item}
2589 done
2590 olditem=
2591 test "x${enable_serial_host_configure}" = xyes &&
2592 for item in ${configdirs} ; do
2593   case ${olditem} in
2594     "") ;;
2595     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2596   esac
2597   olditem=${item}
2598 done
2599 olditem=
2600 test "x${enable_serial_target_configure}" = xyes &&
2601 for item in ${target_configdirs} ; do
2602   case ${olditem} in
2603     "") ;;
2604     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2605   esac
2606   olditem=${item}
2607 done
2608 serialization_dependencies=serdep.tmp
2609 AC_SUBST_FILE(serialization_dependencies)
2610
2611 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2612 # target, nonopt, and variable assignments.  These are the ones we
2613 # might not want to pass down to subconfigures.  The exception being
2614 # --cache-file=/dev/null, which is used to turn off the use of cache
2615 # files altogether, and which should be passed on to subconfigures.
2616 # Also strip program-prefix, program-suffix, and program-transform-name,
2617 # so that we can pass down a consistent program-transform-name.
2618 baseargs=
2619 tbaseargs=
2620 keep_next=no
2621 skip_next=no
2622 eval "set -- $ac_configure_args"
2623 for ac_arg
2624 do
2625   if test X"$skip_next" = X"yes"; then
2626     skip_next=no
2627     continue
2628   fi
2629   if test X"$keep_next" = X"yes"; then
2630     case $ac_arg in
2631       *\'*)
2632         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2633     esac
2634     baseargs="$baseargs '$ac_arg'"
2635     tbaseargs="$tbaseargs '$ac_arg'"
2636     keep_next=no
2637     continue
2638   fi
2639
2640   # Handle separated arguments.  Based on the logic generated by
2641   # autoconf 2.59.
2642   case $ac_arg in
2643     *=* | --config-cache | -C | -disable-* | --disable-* \
2644       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2645       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2646       | -with-* | --with-* | -without-* | --without-* | --x)
2647       separate_arg=no
2648       ;;
2649     -*)
2650       separate_arg=yes
2651       ;;
2652     *)
2653       separate_arg=no
2654       ;;
2655   esac
2656
2657   skip_targ=no
2658   case $ac_arg in
2659 changequote(,)
2660   --with-* | --without-*)
2661     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2662
2663     case $libopt in
2664     *[-_]include)
2665       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2666       ;;
2667     *[-_]lib)
2668       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2669       ;;
2670     *)
2671       lib=$libopt
2672       ;;
2673     esac
2674 changequote([,])
2675
2676     case $lib in
2677     mpc | mpfr | gmp | ppl | cloog)
2678       # If we're processing --with-$lib, --with-$lib-include or
2679       # --with-$lib-lib, for one of the libs above, and target is
2680       # different from host, don't pass the current argument to any
2681       # target library's configure.
2682       if test x$is_cross_compiler = xyes; then
2683         skip_targ=yes
2684       fi
2685       ;;
2686     esac
2687     ;;
2688   esac
2689
2690   case "$ac_arg" in
2691     --cache-file=/dev/null | \
2692     -cache-file=/dev/null )
2693       # Handled here to avoid the test to skip args below.
2694       baseargs="$baseargs '$ac_arg'"
2695       tbaseargs="$tbaseargs '$ac_arg'"
2696       # Assert: $separate_arg should always be no.
2697       keep_next=$separate_arg
2698       ;;
2699     --no*)
2700       continue
2701       ;;
2702     --c* | \
2703     --sr* | \
2704     --ho* | \
2705     --bu* | \
2706     --t* | \
2707     --program-* | \
2708     -cache_file* | \
2709     -srcdir* | \
2710     -host* | \
2711     -build* | \
2712     -target* | \
2713     -program-prefix* | \
2714     -program-suffix* | \
2715     -program-transform-name* )
2716       skip_next=$separate_arg
2717       continue
2718       ;;
2719     -*)
2720       # An option.  Add it.
2721       case $ac_arg in
2722         *\'*)
2723           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2724       esac
2725       baseargs="$baseargs '$ac_arg'"
2726       if test X"$skip_targ" = Xno; then
2727         tbaseargs="$tbaseargs '$ac_arg'"
2728       fi
2729       keep_next=$separate_arg
2730       ;;
2731     *)
2732       # Either a variable assignment, or a nonopt (triplet).  Don't
2733       # pass it down; let the Makefile handle this.
2734       continue
2735       ;;
2736   esac
2737 done
2738 # Remove the initial space we just introduced and, as these will be
2739 # expanded by make, quote '$'.
2740 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2741
2742 # Add in --program-transform-name, after --program-prefix and
2743 # --program-suffix have been applied to it.  Autoconf has already
2744 # doubled dollar signs and backslashes in program_transform_name; we want
2745 # the backslashes un-doubled, and then the entire thing wrapped in single
2746 # quotes, because this will be expanded first by make and then by the shell.
2747 # Also, because we want to override the logic in subdir configure scripts to
2748 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2749 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2750 ${program_transform_name}
2751 EOF_SED
2752 gcc_transform_name=`cat conftestsed.out`
2753 rm -f conftestsed.out
2754 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2755 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2756 if test "$silent" = yes; then
2757   baseargs="$baseargs --silent"
2758   tbaseargs="$tbaseargs --silent"
2759 fi
2760 baseargs="$baseargs --disable-option-checking"
2761 tbaseargs="$tbaseargs --disable-option-checking"
2762
2763 # Record and document user additions to sub configure arguments.
2764 AC_ARG_VAR([build_configargs],
2765            [additional configure arguments for build directories])
2766 AC_ARG_VAR([host_configargs],
2767            [additional configure arguments for host directories])
2768 AC_ARG_VAR([target_configargs],
2769            [additional configure arguments for target directories])
2770
2771 # For the build-side libraries, we just need to pretend we're native,
2772 # and not use the same cache file.  Multilibs are neither needed nor
2773 # desired.
2774 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2775
2776 # For host modules, accept cache file option, or specification as blank.
2777 case "${cache_file}" in
2778 "") # empty
2779   cache_file_option="" ;;
2780 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2781   cache_file_option="--cache-file=${cache_file}" ;;
2782 *) # relative path
2783   cache_file_option="--cache-file=../${cache_file}" ;;
2784 esac
2785
2786 # Host dirs don't like to share a cache file either, horribly enough.
2787 # This seems to be due to autoconf 2.5x stupidity.
2788 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2789
2790 target_configargs="$target_configargs ${tbaseargs}"
2791
2792 # Passing a --with-cross-host argument lets the target libraries know
2793 # whether they are being built with a cross-compiler or being built
2794 # native.  However, it would be better to use other mechanisms to make the
2795 # sorts of decisions they want to make on this basis.  Please consider
2796 # this option to be deprecated.  FIXME.
2797 if test x${is_cross_compiler} = xyes ; then
2798   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2799 fi
2800
2801 # Default to --enable-multilib.
2802 if test x${enable_multilib} = x ; then
2803   target_configargs="--enable-multilib ${target_configargs}"
2804 fi
2805
2806 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2807 # changed from the earlier setting of with_newlib.
2808 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2809   target_configargs="--with-newlib ${target_configargs}"
2810 fi
2811
2812 # Different target subdirs use different values of certain variables
2813 # (notably CXX).  Worse, multilibs use *lots* of different values.
2814 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2815 # it doesn't automatically accept command-line overrides of them.
2816 # This means it's not safe for target subdirs to share a cache file,
2817 # which is disgusting, but there you have it.  Hopefully this can be
2818 # fixed in future.  It's still worthwhile to use a cache file for each
2819 # directory.  I think.
2820
2821 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2822 # We need to pass --target, as newer autoconf's requires consistency
2823 # for target_alias and gcc doesn't manage it consistently.
2824 target_configargs="--cache-file=./config.cache ${target_configargs}"
2825
2826 FLAGS_FOR_TARGET=
2827 case " $target_configdirs " in
2828  *" newlib "*)
2829   case " $target_configargs " in
2830   *" --with-newlib "*)
2831    case "$target" in
2832     *-cygwin*)
2833       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2834       ;;
2835    esac
2836
2837    # If we're not building GCC, don't discard standard headers.
2838    if test -d ${srcdir}/gcc; then
2839      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2840
2841      if test "${build}" != "${host}"; then
2842        # On Canadian crosses, CC_FOR_TARGET will have already been set
2843        # by `configure', so we won't have an opportunity to add -Bgcc/
2844        # to it.  This is right: we don't want to search that directory
2845        # for binaries, but we want the header files in there, so add
2846        # them explicitly.
2847        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2848
2849        # Someone might think of using the pre-installed headers on
2850        # Canadian crosses, in case the installed compiler is not fully
2851        # compatible with the compiler being built.  In this case, it
2852        # would be better to flag an error than risking having
2853        # incompatible object files being constructed.  We can't
2854        # guarantee that an error will be flagged, but let's hope the
2855        # compiler will do it, when presented with incompatible header
2856        # files.
2857      fi
2858    fi
2859
2860    case "${target}-${is_cross_compiler}" in
2861    i[[3456789]]86-*-linux*-no)
2862       # Here host == target, so we don't need to build gcc,
2863       # so we don't want to discard standard headers.
2864       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2865       ;;
2866    *)
2867       # If we're building newlib, use its generic headers last, but search
2868       # for any libc-related directories first (so make it the last -B
2869       # switch).
2870       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2871
2872       # If we're building libgloss, find the startup file, simulator library
2873       # and linker script.
2874       case " $target_configdirs " in
2875         *" libgloss "*)
2876         # Look for startup file, simulator library and maybe linker script.
2877         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2878         # Look for libnosys.a in case the target needs it.
2879         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2880         # Most targets have the linker script in the source directory.
2881         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2882         ;;
2883       esac
2884       ;;
2885    esac
2886    ;;
2887   esac
2888   ;;
2889 esac
2890
2891 case "$target" in
2892   x86_64-*mingw* | *-w64-mingw*)
2893   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2894   # however, use a symlink named 'mingw' in ${prefix} .
2895     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2896     ;;
2897   *-mingw*)
2898   # MinGW can't be handled as Cygwin above since it does not use newlib.
2899     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2900     ;;
2901 esac
2902
2903 # Allow the user to override the flags for
2904 # our build compiler if desired.
2905 if test x"${build}" = x"${host}" ; then
2906   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2907   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2908   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2909 fi
2910
2911 # On Canadian crosses, we'll be searching the right directories for
2912 # the previously-installed cross compiler, so don't bother to add
2913 # flags for directories within the install tree of the compiler
2914 # being built; programs in there won't even run.
2915 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2916   # Search for pre-installed headers if nothing else fits.
2917   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2918 fi
2919
2920 if test "x${use_gnu_ld}" = x &&
2921    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2922   # Arrange for us to find uninstalled linker scripts.
2923   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2924 fi
2925
2926 # Search for other target-specific linker scripts and such.
2927 case "${target}" in
2928   mep*)
2929     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2930     ;;
2931 esac
2932
2933 # Makefile fragments.
2934 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2935 do
2936   eval fragval=\$$frag
2937   if test $fragval != /dev/null; then
2938     eval $frag=${srcdir}/$fragval
2939   fi
2940 done
2941 AC_SUBST_FILE(host_makefile_frag)
2942 AC_SUBST_FILE(target_makefile_frag)
2943 AC_SUBST_FILE(alphaieee_frag)
2944 AC_SUBST_FILE(ospace_frag)
2945
2946 # Miscellanea: directories, flags, etc.
2947 AC_SUBST(RPATH_ENVVAR)
2948 AC_SUBST(GCC_SHLIB_SUBDIR)
2949 AC_SUBST(tooldir)
2950 AC_SUBST(build_tooldir)
2951 AC_SUBST(CONFIGURE_GDB_TK)
2952 AC_SUBST(GDB_TK)
2953 AC_SUBST(INSTALL_GDB_TK)
2954
2955 # Build module lists & subconfigure args.
2956 AC_SUBST(build_configargs)
2957 AC_SUBST(build_configdirs)
2958
2959 # Host module lists & subconfigure args.
2960 AC_SUBST(host_configargs)
2961 AC_SUBST(configdirs)
2962 AC_SUBST(target_configdirs)
2963
2964 # Target module lists & subconfigure args.
2965 AC_SUBST(target_configargs)
2966
2967
2968 # Build tools.
2969 AC_SUBST(AR_FOR_BUILD)
2970 AC_SUBST(AS_FOR_BUILD)
2971 AC_SUBST(CC_FOR_BUILD)
2972 AC_SUBST(CFLAGS_FOR_BUILD)
2973 AC_SUBST(CXXFLAGS_FOR_BUILD)
2974 AC_SUBST(CXX_FOR_BUILD)
2975 AC_SUBST(DLLTOOL_FOR_BUILD)
2976 AC_SUBST(GCJ_FOR_BUILD)
2977 AC_SUBST(GFORTRAN_FOR_BUILD)
2978 AC_SUBST(GOC_FOR_BUILD)
2979 AC_SUBST(LDFLAGS_FOR_BUILD)
2980 AC_SUBST(LD_FOR_BUILD)
2981 AC_SUBST(NM_FOR_BUILD)
2982 AC_SUBST(RANLIB_FOR_BUILD)
2983 AC_SUBST(WINDMC_FOR_BUILD)
2984 AC_SUBST(WINDRES_FOR_BUILD)
2985
2986 # Generate default definitions for YACC, M4, LEX and other programs that run
2987 # on the build machine.  These are used if the Makefile can't locate these
2988 # programs in objdir.
2989 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2990
2991 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2992 case " $build_configdirs " in
2993   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2994 esac
2995
2996 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2997 case " $build_configdirs " in
2998   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2999 esac
3000
3001 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3002 case " $build_configdirs " in
3003   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3004 esac
3005
3006 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3007 case " $build_configdirs " in
3008   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3009   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3010 esac
3011
3012 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3013 case " $build_configdirs " in
3014   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3015 esac
3016
3017 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3018 case " $build_configdirs " in
3019   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3020   *)
3021 changequote(,)
3022     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3023     # higher, else we use the "missing" dummy.
3024     if ${MAKEINFO} --version \
3025        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3026       :
3027     else
3028       MAKEINFO="$MISSING makeinfo"
3029     fi
3030     ;;
3031 changequote([,])
3032 esac
3033
3034 # FIXME: expect and dejagnu may become build tools?
3035
3036 AC_CHECK_PROGS(EXPECT, expect, expect)
3037 case " $configdirs " in
3038   *" expect "*)
3039     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3040     ;;
3041 esac
3042
3043 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3044 case " $configdirs " in
3045   *" dejagnu "*)
3046     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3047     ;;
3048 esac
3049
3050
3051 # Host tools.
3052 NCN_STRICT_CHECK_TOOLS(AR, ar)
3053 NCN_STRICT_CHECK_TOOLS(AS, as)
3054 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3055 NCN_STRICT_CHECK_TOOLS(LD, ld)
3056 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3057 NCN_STRICT_CHECK_TOOLS(NM, nm)
3058 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3059 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3060 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3061 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3062 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3063 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3064 AC_SUBST(CC)
3065 AC_SUBST(CXX)
3066 AC_SUBST(CFLAGS)
3067 AC_SUBST(CXXFLAGS)
3068
3069 # Target tools.
3070 AC_ARG_WITH([build-time-tools],
3071   [AS_HELP_STRING([--with-build-time-tools=PATH],
3072                   [use given path to find target tools during the build])],
3073   [case x"$withval" in
3074      x/*) ;;
3075      *)
3076        with_build_time_tools=
3077        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3078        ;;
3079    esac],
3080   [with_build_time_tools=])
3081
3082 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3083 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3084 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3085 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3086 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3087 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3088
3089 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3090 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3091 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3092 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3093 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3094 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3095 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3096 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3097 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3098 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3099 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3100
3101 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3102
3103 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3104 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3105 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3106 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3107 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3108                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3109                 c++)
3110 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3111                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3112                 c++)
3113 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3114 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3115 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3116                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3117 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3118                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3119 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3120                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3121 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3122 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3123 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3124 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3125 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3126 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3127 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3128 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3129
3130 AC_SUBST(FLAGS_FOR_TARGET)
3131 AC_SUBST(RAW_CXX_FOR_TARGET)
3132
3133 # Certain tools may need extra flags.
3134 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3135 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3136 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3137
3138 # When building target libraries, except in a Canadian cross, we use
3139 # the same toolchain as the compiler we just built.
3140 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3141 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3142 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3143 if test $host = $build; then
3144   case " $configdirs " in
3145     *" gcc "*)
3146       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3147       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3148       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3149       ;;
3150   esac
3151 fi
3152
3153 AC_SUBST(COMPILER_AS_FOR_TARGET)
3154 AC_SUBST(COMPILER_LD_FOR_TARGET)
3155 AC_SUBST(COMPILER_NM_FOR_TARGET)
3156
3157 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3158 AC_ARG_ENABLE(maintainer-mode,
3159 [AS_HELP_STRING([--enable-maintainer-mode],
3160                 [enable make rules and dependencies not useful
3161                  (and sometimes confusing) to the casual installer])],
3162       USE_MAINTAINER_MODE=$enableval,
3163       USE_MAINTAINER_MODE=no)
3164 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3165 AC_SUBST(MAINTAINER_MODE_TRUE)
3166 AC_SUBST(MAINTAINER_MODE_FALSE)
3167 if test "$USE_MAINTAINER_MODE" = yes; then
3168   MAINTAINER_MODE_TRUE=
3169   MAINTAINER_MODE_FALSE='#'
3170 else
3171   MAINTAINER_MODE_TRUE='#'
3172   MAINTAINER_MODE_FALSE=
3173 fi
3174 MAINT=$MAINTAINER_MODE_TRUE
3175 AC_SUBST(MAINT)dnl
3176
3177 # ---------------------
3178 # GCC bootstrap support
3179 # ---------------------
3180
3181 # Stage specific cflags for build.
3182 stage1_cflags="-g"
3183 case $build in
3184   vax-*-*)
3185     case ${GCC} in
3186       yes) stage1_cflags="-g -Wa,-J" ;;
3187       *) stage1_cflags="-g -J" ;;
3188     esac ;;
3189 esac
3190
3191 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3192 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3193   saved_CFLAGS="$CFLAGS"
3194
3195   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3196   CFLAGS="$CFLAGS -fkeep-inline-functions"
3197   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3198   AC_TRY_COMPILE([
3199 #if (__GNUC__ < 3) \
3200     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3201                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3202 #error http://gcc.gnu.org/PR29382
3203 #endif
3204     ],,
3205     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3206     [AC_MSG_RESULT([no])])
3207
3208   CFLAGS="$saved_CFLAGS"
3209 fi
3210
3211 AC_SUBST(stage1_cflags)
3212
3213 # Enable --enable-checking in stage1 of the compiler.
3214 AC_ARG_ENABLE(stage1-checking,
3215 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3216                 [choose additional checking for stage1 of the compiler])],
3217 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3218 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3219   stage1_checking=--enable-checking=yes,types
3220 else
3221   stage1_checking=--enable-checking=$enable_checking,types
3222 fi])
3223 AC_SUBST(stage1_checking)
3224
3225 # Enable -Werror in bootstrap stage2 and later.
3226 AC_ARG_ENABLE(werror,
3227 [AS_HELP_STRING([--enable-werror],
3228                 [enable -Werror in bootstrap stage2 and later])], [],
3229 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3230   enable_werror=yes
3231 else
3232   enable_werror=no
3233 fi])
3234 case ${enable_werror} in
3235   yes) stage2_werror_flag="--enable-werror-always" ;;
3236   *) stage2_werror_flag="" ;;
3237 esac
3238 AC_SUBST(stage2_werror_flag)
3239
3240 # If using ENABLE_BUILD_POSTSTAGE1_WITH_CXX, pass
3241 # --enable-build-with-cxx after stage1.
3242 if test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
3243   POSTSTAGE1_CONFIGURE_FLAGS=--enable-build-with-cxx
3244 else
3245   POSTSTAGE1_CONFIGURE_FLAGS=
3246 fi
3247 AC_SUBST(POSTSTAGE1_CONFIGURE_FLAGS)
3248
3249 # Specify what files to not compare during bootstrap.
3250
3251 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3252 case "$target" in
3253   hppa*64*-*-hpux*) ;;
3254   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3255 esac
3256 case " $configdirs " in
3257 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3258 esac
3259 AC_SUBST(compare_exclusions)
3260
3261 AC_CONFIG_FILES([Makefile],
3262   [sed "$extrasub_build" Makefile |
3263    sed "$extrasub_host" |
3264    sed "$extrasub_target" > mf$$
3265    mv -f mf$$ Makefile],
3266   [extrasub_build="$extrasub_build"
3267    extrasub_host="$extrasub_host"
3268    extrasub_target="$extrasub_target"])
3269 AC_OUTPUT