configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 ### we might need to use some other shell than /bin/sh for running subshells
  93 ### If we are on Windows, search for the shell.  This will permit people
  94 ### to not have /bin/sh, but to be able to see /SOME/PATH/sh configure
  95 ### without also having to set CONFIG_SHELL.  This code will work when
  96 ### using bash, which sets OSTYPE.
  97 case "${OSTYPE}" in
  98 *win32*)
  99   if test x${CONFIG_SHELL} = x ; then
 100     if test ! -f /bin/sh ; then
 101       if test x${SHELL} != x && test -f ${SHELL} ; then
 102         CONFIG_SHELL=${SHELL}
 103         export CONFIG_SHELL
 104       else
 105         for prog in sh sh.exe bash bash.exe; do
 106           IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
 107           for dir in $PATH; do
 108             test -z "$dir" && dir=.
 109             if test -f $dir/$prog; then
 110               CONFIG_SHELL=$dir/$prog
 111               export CONFIG_SHELL
 112               break
 113             fi
 114           done
 115           IFS="$save_ifs"
 116           test -n "${CONFIG_SHELL}" && break
 117         done
 118       fi
 119     fi
 120   fi
 121   ;;
 122 esac
 123
 124 config_shell=${CONFIG_SHELL-/bin/sh}
 125
 126 moveifchange=${srcdir}/move-if-change
 127
 128 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
 129
 130 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
 131 # a relative path.
 132 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 133   INSTALL="${srcpwd}/install-sh -c"
 134 fi
 135
 136 # Set srcdir to "." if that's what it is.
 137 # This is important for multilib support.
 138 pwd=`${PWDCMD-pwd}`
 139 if test "${pwd}" = "${srcpwd}" ; then
 140   srcdir=.
 141 fi
 142
 143 topsrcdir=$srcpwd
 144
 145 extra_host_args=
 146
 147 ### To add a new directory to the tree, first choose whether it is a target
 148 ### or a host dependent tool.  Then put it into the appropriate list
 149 ### (library or tools, host or target), doing a dependency sort.
 150
 151 # Subdirs will be configured in the order listed in build_configdirs,
 152 # configdirs, or target_configdirs; see the serialization section below.
 153
 154 # Dependency sorting is only needed when *configuration* must be done in
 155 # a particular order.  In all cases a dependency should be specified in
 156 # the Makefile, whether or not it's implicitly specified here.
 157
 158 # Double entries in build_configdirs, configdirs, or target_configdirs may
 159 # cause circular dependencies and break everything horribly.
 160
 161 # these library is used by various programs built for the build
 162 # environment
 163 #
 164 build_libs="build-libiberty"
 165
 166 # these tools are built for the build environment
 167 build_tools="build-texinfo build-byacc build-flex build-bison build-m4 build-fixincludes"
 168
 169 # these libraries are used by various programs built for the host environment
 170 #
 171 host_libs="intl mmalloc libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 172
 173 # these tools are built for the host environment
 174 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 175 # know that we are building the simulator.
 176 # binutils, gas and ld appear in that order because it makes sense to run
 177 # "make check" in that particular order.
 178 # If --enable-gold is used, "gold" may replace "ld".
 179 host_tools="texinfo byacc flex bison binutils gas ld fixincludes gcc cgen sid sim gdb make patch prms send-pr gprof etc expect dejagnu ash bash bzip2 m4 autoconf automake libtool diff rcs fileutils shellutils time textutils wdiff find uudecode hello tar gzip indent recode release sed utils guile perl gawk findutils gettext zip fastjar gnattools"
 180
 181 # libgcj represents the runtime libraries only used by gcj.
 182 libgcj="target-libffi \
 183         target-zlib \
 184         target-qthreads \
 185         target-libjava"
 186
 187 # these libraries are built for the target environment, and are built after
 188 # the host libraries and the host tools (which may be a cross compiler)
 189 #
 190 target_libraries="target-libgcc \
 191                 target-libiberty \
 192                 target-libgloss \
 193                 target-newlib \
 194                 target-libgomp \
 195                 target-libstdc++-v3 \
 196                 target-libmudflap \
 197                 target-libssp \
 198                 target-libquadmath \
 199                 target-libgfortran \
 200                 target-boehm-gc \
 201                 ${libgcj} \
 202                 target-libobjc \
 203                 target-libada \
 204                 target-libgo"
 205
 206 # these tools are built using the target libraries, and are intended to
 207 # run only in the target environment
 208 #
 209 # note: any program that *uses* libraries that are in the "target_libraries"
 210 # list belongs in this list.  those programs are also very likely
 211 # candidates for the "native_only" list which follows
 212 #
 213 target_tools="target-examples target-groff target-gperf target-rda"
 214
 215 ################################################################################
 216
 217 ## All tools belong in one of the four categories, and are assigned above
 218 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 219 ## is important because configure will choke if they ever get through.
 220 ## ${configdirs} is directories we build using the host tools.
 221 ## ${target_configdirs} is directories we build using the target tools.
 222 configdirs=`echo ${host_libs} ${host_tools}`
 223 target_configdirs=`echo ${target_libraries} ${target_tools}`
 224 build_configdirs=`echo ${build_libs} ${build_tools}`
 225
 226 m4_divert_text([PARSE_ARGS],
 227 [case $srcdir in
 228   *" "*)
 229 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 230     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 231 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 232     ;;
 233 esac
 234 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 235 ])
 236
 237 ################################################################################
 238
 239 srcname="gnu development package"
 240
 241 # This gets set non-empty for some net releases of packages.
 242 appdirs=""
 243
 244 # Define is_cross_compiler to save on calls to 'test'.
 245 is_cross_compiler=
 246 if test x"${host}" = x"${target}" ; then
 247   is_cross_compiler=no
 248 else
 249   is_cross_compiler=yes
 250 fi
 251
 252 # Find the build and target subdir names.
 253 GCC_TOPLEV_SUBDIRS
 254 # Be sure to cover against remnants of an in-tree build.
 255 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 256   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 257 Use a pristine source tree when building in a separate tree])
 258 fi
 259
 260 # Skipdirs are removed silently.
 261 skipdirs=
 262 # Noconfigdirs are removed loudly.
 263 noconfigdirs=""
 264
 265 use_gnu_ld=
 266 # Make sure we don't let GNU ld be added if we didn't want it.
 267 if test x$with_gnu_ld = xno ; then
 268   use_gnu_ld=no
 269   noconfigdirs="$noconfigdirs ld gold"
 270 fi
 271
 272 use_gnu_as=
 273 # Make sure we don't let GNU as be added if we didn't want it.
 274 if test x$with_gnu_as = xno ; then
 275   use_gnu_as=no
 276   noconfigdirs="$noconfigdirs gas"
 277 fi
 278
 279 use_included_zlib=
 280 # Make sure we don't let ZLIB be added if we didn't want it.
 281 if test x$with_system_zlib = xyes ; then
 282   use_included_zlib=no
 283   noconfigdirs="$noconfigdirs zlib"
 284 fi
 285
 286 # some tools are so dependent upon X11 that if we're not building with X,
 287 # it's not even worth trying to configure, much less build, that tool.
 288
 289 case ${with_x} in
 290   yes | "") ;; # the default value for this tree is that X11 is available
 291   no)
 292     skipdirs="${skipdirs} tk itcl libgui"
 293     # We won't be able to build gdbtk without X.
 294     enable_gdbtk=no
 295     ;;
 296   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 297 esac
 298
 299 # Some tools are only suitable for building in a "native" situation.
 300 # Remove these if host!=target.
 301 native_only="autoconf automake libtool fileutils find gawk gettext gzip hello indent m4 rcs recode sed shellutils tar textutils uudecode wdiff target-groff guile perl time ash bash bzip2 prms gnuserv target-gperf"
 302
 303 # Similarly, some are only suitable for cross toolchains.
 304 # Remove these if host=target.
 305 cross_only="target-libgloss target-newlib target-opcodes"
 306
 307 case $is_cross_compiler in
 308   no) skipdirs="${skipdirs} ${cross_only}" ;;
 309   yes) skipdirs="${skipdirs} ${native_only}" ;;
 310 esac
 311
 312 # If both --with-headers and --with-libs are specified, default to
 313 # --without-newlib.
 314 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 315    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 316   if test x"${with_newlib}" = x ; then
 317     with_newlib=no
 318   fi
 319 fi
 320
 321 # Recognize --with-newlib/--without-newlib.
 322 case ${with_newlib} in
 323   no) skipdirs="${skipdirs} target-newlib" ;;
 324   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 325 esac
 326
 327 # Handle --enable-gold, --enable-ld.
 328 # --disable-gold [--enable-ld]
 329 #     Build only ld.  Default option.
 330 # --enable-gold [--enable-ld]
 331 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 332 #     as "ld.bfd" and "ld".
 333 # --enable-gold=default [--enable-ld]
 334 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 335 #     install ld as "ld.bfd".
 336 # --enable-gold[=default] --disable-ld
 337 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 338 # --enable-gold --enable-ld=default
 339 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 340 #     and ld.bfd).
 341 #     In other words, ld is default
 342 # --enable-gold=default --enable-ld=default
 343 #     Error.
 344
 345 default_ld=
 346 AC_ARG_ENABLE(gold,
 347 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 348                 [build gold @<:@ARG={default,yes,no}@:>@])],
 349 ENABLE_GOLD=$enableval,
 350 ENABLE_GOLD=no)
 351 case "${ENABLE_GOLD}" in
 352   yes|default)
 353     # Check for ELF target.
 354     is_elf=no
 355     case "${target}" in
 356       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 357       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 358       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-solaris2* | *-*-nto*)
 359         case "${target}" in
 360           *-*-linux*aout* | *-*-linux*oldld*)
 361             ;;
 362           *)
 363             is_elf=yes
 364             ;;
 365         esac
 366     esac
 367
 368     if test "$is_elf" = "yes"; then
 369       # Check for target supported by gold.
 370       case "${target}" in
 371         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 372           configdirs="$configdirs gold"
 373           if test x${ENABLE_GOLD} = xdefault; then
 374             default_ld=gold
 375           fi
 376           ENABLE_GOLD=yes
 377           ;;
 378       esac
 379     fi
 380     ;;
 381   no)
 382     ;;
 383   *)
 384     AC_MSG_ERROR([invalid --enable-gold argument])
 385     ;;
 386 esac
 387
 388 AC_ARG_ENABLE(ld,
 389 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 390                 [build ld @<:@ARG={default,yes,no}@:>@])],
 391 ENABLE_LD=$enableval,
 392 ENABLE_LD=yes)
 393
 394 case "${ENABLE_LD}" in
 395   default)
 396     if test x${default_ld} != x; then
 397       AC_MSG_ERROR([either gold or ld can be the default ld])
 398     fi
 399     ;;
 400   yes)
 401     ;;
 402   no)
 403     if test x${ENABLE_GOLD} != xyes; then
 404       AC_MSG_WARN([neither ld nor gold are enabled])
 405     fi
 406     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 407     ;;
 408   *)
 409     AC_MSG_ERROR([invalid --enable-ld argument])
 410     ;;
 411 esac
 412
 413 # Configure extra directories which are host specific
 414
 415 case "${host}" in
 416   *-cygwin*)
 417     configdirs="$configdirs libtermcap" ;;
 418 esac
 419
 420 # A target can indicate whether a language isn't supported for some reason.
 421 # Only spaces may be used in this macro; not newlines or tabs.
 422 unsupported_languages=
 423
 424 # Remove more programs from consideration, based on the host or
 425 # target this usually means that a port of the program doesn't
 426 # exist yet.
 427
 428 case "${host}" in
 429   hppa*64*-*-*)
 430     noconfigdirs="$noconfigdirs byacc"
 431     ;;
 432   i[[3456789]]86-*-vsta)
 433     noconfigdirs="$noconfigdirs tcl expect dejagnu make texinfo bison patch flex byacc send-pr gprof uudecode dejagnu diff guile perl itcl gnuserv gettext"
 434     ;;
 435   i[[3456789]]86-*-go32* | i[[3456789]]86-*-msdosdjgpp*)
 436     noconfigdirs="$noconfigdirs tcl tk expect dejagnu send-pr uudecode guile itcl gnuserv libffi"
 437     ;;
 438   x86_64-*-mingw*)
 439     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 440     ;;
 441   i[[3456789]]86-*-mingw32*)
 442     # noconfigdirs="tcl tk expect dejagnu make texinfo bison patch flex byacc send-pr uudecode dejagnu diff guile perl itcl gnuserv"
 443     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 444     ;;
 445   i[[3456789]]86-*-beos*)
 446     noconfigdirs="$noconfigdirs tk itcl libgui gdb"
 447     ;;
 448   *-*-cygwin*)
 449     noconfigdirs="$noconfigdirs autoconf automake send-pr rcs guile perl"
 450     ;;
 451   *-*-netbsd*)
 452     noconfigdirs="$noconfigdirs rcs"
 453     ;;
 454   ppc*-*-pe)
 455     noconfigdirs="$noconfigdirs patch diff make tk tcl expect dejagnu autoconf automake texinfo bison send-pr gprof rcs guile perl itcl gnuserv"
 456     ;;
 457   powerpc-*-beos*)
 458     noconfigdirs="$noconfigdirs tk itcl libgui gdb dejagnu readline"
 459     ;;
 460 esac
 461
 462
 463 AC_ARG_ENABLE(libquadmath,
 464 AS_HELP_STRING([--disable-libquadmath],
 465   [do not build libquadmath directory]),
 466 ENABLE_LIBQUADMATH=$enableval,
 467 ENABLE_LIBQUADMATH=yes)
 468 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 469   noconfigdirs="$noconfigdirs target-libquadmath"
 470 fi
 471
 472
 473 AC_ARG_ENABLE(libquadmath-support,
 474 AS_HELP_STRING([--disable-libquadmath-support],
 475   [disable libquadmath support for Fortran]),
 476 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 477 ENABLE_LIBQUADMATH_SUPPORT=yes)
 478 enable_libquadmath_support=
 479 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 480   enable_libquadmath_support=no
 481 fi
 482
 483
 484 AC_ARG_ENABLE(libada,
 485 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 486 ENABLE_LIBADA=$enableval,
 487 ENABLE_LIBADA=yes)
 488 if test "${ENABLE_LIBADA}" != "yes" ; then
 489   noconfigdirs="$noconfigdirs gnattools"
 490 fi
 491
 492 AC_ARG_ENABLE(libssp,
 493 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 494 ENABLE_LIBSSP=$enableval,
 495 ENABLE_LIBSSP=yes)
 496
 497 # Save it here so that, even in case of --enable-libgcj, if the Java
 498 # front-end isn't enabled, we still get libgcj disabled.
 499 libgcj_saved=$libgcj
 500 case $enable_libgcj in
 501 yes)
 502   # If we reset it here, it won't get added to noconfigdirs in the
 503   # target-specific build rules, so it will be forcibly enabled
 504   # (unless the Java language itself isn't enabled).
 505   libgcj=
 506   ;;
 507 no)
 508   # Make sure we get it printed in the list of not supported target libs.
 509   # Don't disable libffi, though, other languages use it.
 510   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 511   # Clear libgcj_saved so that even if java is enabled libffi won't be
 512   # built.
 513   libgcj_saved=
 514   ;;
 515 esac
 516
 517
 518 # Disable libmudflap on some systems.
 519 if test x$enable_libmudflap = x ; then
 520     case "${target}" in
 521     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 522         # Enable libmudflap by default in GNU and friends.
 523         ;;
 524     *-*-freebsd*)
 525         # Enable libmudflap by default in FreeBSD.
 526         ;;
 527     *)
 528         # Disable it by default everywhere else.
 529         noconfigdirs="$noconfigdirs target-libmudflap"
 530         ;;
 531     esac
 532 fi
 533
 534 # Disable libgomp on non POSIX hosted systems.
 535 if test x$enable_libgomp = x ; then
 536     # Enable libgomp by default on hosted POSIX systems.
 537     case "${target}" in
 538     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 539         ;;
 540     *-*-netbsd* | *-*-freebsd* | *-*-openbsd*)
 541         ;;
 542     *-*-solaris2* | *-*-sysv4* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 543         ;;
 544     *-*-darwin* | *-*-aix*)
 545         ;;
 546     *)
 547         noconfigdirs="$noconfigdirs target-libgomp"
 548         ;;
 549     esac
 550 fi
 551
 552 # Default libgloss CPU subdirectory.
 553 libgloss_dir="$target_cpu"
 554
 555 case "${target}" in
 556   *-*-chorusos)
 557     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 558     ;;
 559   powerpc-*-darwin*)
 560     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 561     noconfigdirs="$noconfigdirs sim target-rda"
 562     ;;
 563   i[[3456789]]86-*-darwin*)
 564     noconfigdirs="$noconfigdirs ld gprof"
 565     noconfigdirs="$noconfigdirs sim target-rda"
 566     ;;
 567   x86_64-*-darwin[[912]]*)
 568     noconfigdirs="$noconfigdirs ld gas gprof"
 569     noconfigdirs="$noconfigdirs sim target-rda"
 570     ;;
 571   *-*-darwin*)
 572     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 573     noconfigdirs="$noconfigdirs sim target-rda"
 574     noconfigdirs="$noconfigdirs ${libgcj}"
 575     ;;
 576   *-*-freebsd[[12]] | *-*-freebsd[[12]].* | *-*-freebsd*aout*)
 577     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 578     ;;
 579   *-*-freebsd*)
 580     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 581     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 582         && test -f /usr/local/include/gmp.h; then
 583       with_gmp=/usr/local
 584     fi
 585
 586     # Skip some stuff that's unsupported on some FreeBSD configurations.
 587     case "${target}" in
 588       i*86-*-*) ;;
 589       alpha*-*-*) ;;
 590       x86_64-*-*) ;;
 591       *)
 592         noconfigdirs="$noconfigdirs ${libgcj}"
 593         ;;
 594     esac
 595     ;;
 596   *-*-kaos*)
 597     # Remove unsupported stuff on all kaOS configurations.
 598     skipdirs="target-libiberty ${libgcj} target-libstdc++-v3 target-librx"
 599     skipdirs="$skipdirs target-libobjc target-examples target-groff target-gperf"
 600     skipdirs="$skipdirs zlib fastjar target-libjava target-boehm-gc target-zlib"
 601     noconfigdirs="$noconfigdirs target-libgloss"
 602     ;;
 603   *-*-netbsd*)
 604     # Skip some stuff on all NetBSD configurations.
 605     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss"
 606
 607     # Skip some stuff that's unsupported on some NetBSD configurations.
 608     case "${target}" in
 609       i*86-*-netbsdelf*) ;;
 610       arm*-*-netbsdelf*) ;;
 611       *)
 612         noconfigdirs="$noconfigdirs ${libgcj}"
 613         ;;
 614     esac
 615     ;;
 616   *-*-netware*)
 617     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss ${libgcj} target-libmudflap"
 618     ;;
 619   *-*-rtems*)
 620     skipdirs="${skipdirs} target-libiberty"
 621     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 622     ;;
 623     # The tpf target doesn't support gdb yet.
 624   *-*-tpf*)
 625     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty ${libgcj} target-libmudflap gdb tcl tk libgui itcl"
 626     ;;
 627   *-*-uclinux*)
 628     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-rda ${libgcj}"
 629     ;;
 630   *-*-vxworks*)
 631     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty target-libstdc++-v3 ${libgcj}"
 632     ;;
 633   alpha*-dec-osf*)
 634     # ld works, but does not support shared libraries.
 635     # newlib is not 64 bit ready.  I'm not sure about fileutils.
 636     # gas doesn't generate exception information.
 637     noconfigdirs="$noconfigdirs gas ld fileutils target-newlib target-libgloss"
 638     ;;
 639   alpha*-*-*vms*)
 640     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 641     ;;
 642   alpha*-*-linux*)
 643     # newlib is not 64 bit ready
 644     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 645     ;;
 646   alpha*-*-*)
 647     # newlib is not 64 bit ready
 648     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 649     ;;
 650   am33_2.0-*-linux*)
 651     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 652     ;;
 653   sh-*-linux*)
 654     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 655     ;;
 656   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 657     noconfigdirs="$noconfigdirs ${libgcj}"
 658     noconfigdirs="$noconfigdirs target-examples"
 659     noconfigdirs="$noconfigdirs target-libiberty texinfo send-pr"
 660     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 661     noconfigdirs="$noconfigdirs expect dejagnu"
 662     # the C++ libraries don't build on top of CE's C libraries
 663     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 664     noconfigdirs="$noconfigdirs target-newlib"
 665     case "${host}" in
 666       *-*-cygwin*) ;; # keep gdb and readline
 667       *) noconfigdirs="$noconfigdirs gdb readline"
 668          ;;
 669     esac
 670     libgloss_dir=wince
 671     ;;
 672   arc-*-*)
 673     noconfigdirs="$noconfigdirs target-libgloss"
 674     ;;
 675   arm-semi-aof )
 676     ;;
 677   arm-*-coff | strongarm-*-coff | xscale-*-coff)
 678     noconfigdirs="$noconfigdirs ${libgcj}"
 679     libgloss_dir=arm
 680     ;;
 681   arm-*-elf* | strongarm-*-elf* | xscale-*-elf* | arm*-*-eabi* )
 682     noconfigdirs="$noconfigdirs target-libffi target-qthreads"
 683     libgloss_dir=arm
 684     ;;
 685   arm*-*-linux-gnueabi)
 686     noconfigdirs="$noconfigdirs target-qthreads"
 687     case ${with_newlib} in
 688       no) noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 689     esac
 690     libgloss_dir=arm
 691     ;;
 692   arm*-*-symbianelf*)
 693     noconfigdirs="$noconfigdirs ${libgcj} target-libiberty"
 694     libgloss_dir=arm
 695     ;;
 696   arm-*-pe*)
 697     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 698     ;;
 699   thumb-*-coff)
 700     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 701     ;;
 702   thumb-*-elf)
 703     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 704     ;;
 705   thumb-*-pe)
 706     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 707     ;;
 708   arm-*-riscix*)
 709     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 710     ;;
 711   avr-*-*)
 712     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj} target-libssp"
 713     ;;
 714   bfin-*-*)
 715     unsupported_languages="$unsupported_languages java"
 716     noconfigdirs="$noconfigdirs target-boehm-gc"
 717     if test x${is_cross_compiler} != xno ; then
 718       target_configdirs="${target_configdirs} target-bsp target-cygmon"
 719     fi
 720     ;;
 721   c4x-*-* | tic4x-*-*)
 722     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 723     ;;
 724   c54x*-*-* | tic54x-*-*)
 725     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj} gcc gdb newlib"
 726     ;;
 727   cr16-*-*)
 728     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 729     ;;
 730   cris-*-* | crisv32-*-*)
 731     unsupported_languages="$unsupported_languages java"
 732     case "${target}" in
 733       *-*-aout)
 734         unsupported_languages="$unsupported_languages fortran"
 735         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 736       *-*-elf) # See PR46792 regarding target-libffi.
 737         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 738       *-*-linux*)
 739         noconfigdirs="$noconfigdirs target-newlib target-libgloss";;
 740       *)
 741         unsupported_languages="$unsupported_languages fortran"
 742         noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss";;
 743     esac
 744     libgloss_dir=cris
 745     ;;
 746   crx-*-*)
 747     ;;
 748   d10v-*-*)
 749     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 750     ;;
 751   d30v-*-*)
 752     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 753     ;;
 754   ep9312-*-elf | ep9312-*-coff)
 755     libgloss_dir=arm
 756     ;;
 757   fr30-*-elf*)
 758     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 759     ;;
 760   frv-*-*)
 761     noconfigdirs="$noconfigdirs ${libgcj}"
 762     ;;
 763   moxie-*-*)
 764     noconfigdirs="$noconfigdirs ${libgcj}"
 765     noconfigdirs="$noconfigdirs gprof"
 766     ;;
 767   h8300*-*-*)
 768     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 769     ;;
 770   h8500-*-*)
 771     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 772     ;;
 773   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 774     ;;
 775   hppa*64*-*-linux* | parisc*64*-*-linux*)
 776     # In this case, it's because the hppa64-linux target is for
 777     # the kernel only at this point and has no libc, and thus no
 778     # headers, crt*.o, etc., all of which are needed by these.
 779     noconfigdirs="$noconfigdirs target-zlib"
 780     ;;
 781   parisc*-*-linux* | hppa*-*-linux*)
 782     ;;
 783   hppa*-*-*elf* | \
 784   hppa*-*-lites* | \
 785   hppa*-*-openbsd* | \
 786   hppa*64*-*-*)
 787     noconfigdirs="$noconfigdirs ${libgcj}"
 788     ;;
 789   hppa*-hp-hpux11*)
 790     noconfigdirs="$noconfigdirs ld shellutils"
 791     ;;
 792   hppa*-*-pro*)
 793     libgloss_dir=pa
 794     ;;
 795   hppa*-*-*)
 796     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 797     # build on HP-UX 10.20.
 798     noconfigdirs="$noconfigdirs ld shellutils ${libgcj}"
 799     ;;
 800   i960-*-*)
 801     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 802     ;;
 803   ia64*-*-elf*)
 804     # No gdb support yet.
 805     noconfigdirs="$noconfigdirs readline mmalloc libgui itcl gdb"
 806     ;;
 807   ia64*-**-hpux*)
 808     # No ld support yet.
 809     noconfigdirs="$noconfigdirs ${libgcj} libgui itcl ld"
 810     ;;
 811   ia64*-*-*vms*)
 812     # No gdb or ld support yet.
 813     noconfigdirs="$noconfigdirs ${libgcj} tix readline mmalloc libgui itcl gdb ld"
 814     ;;
 815   i370-*-opened*)
 816     ;;
 817   i[[3456789]]86-*-coff | i[[3456789]]86-*-elf)
 818     noconfigdirs="$noconfigdirs ${libgcj}"
 819     libgloss_dir=i386
 820     ;;
 821   i[[3456789]]86-*-linux*)
 822     # The GCC port for glibc1 has no MD_FALLBACK_FRAME_STATE_FOR, so let's
 823     # not build java stuff by default.
 824     case "${target}" in
 825       *-*-*libc1*)
 826         noconfigdirs="$noconfigdirs ${libgcj}";;
 827     esac
 828
 829     # This section makes it possible to build newlib natively on linux.
 830     # If we are using a cross compiler then don't configure newlib.
 831     if test x${is_cross_compiler} != xno ; then
 832       noconfigdirs="$noconfigdirs target-newlib"
 833     fi
 834     noconfigdirs="$noconfigdirs target-libgloss"
 835     # If we are not using a cross compiler, do configure newlib.
 836     # Note however, that newlib will only be configured in this situation
 837     # if the --with-newlib option has been given, because otherwise
 838     # 'target-newlib' will appear in skipdirs.
 839     ;;
 840   i[[3456789]]86-w64-mingw*)
 841     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 842     ;;
 843   i[[3456789]]86-*-mingw*)
 844     target_configdirs="$target_configdirs target-winsup"
 845     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 846     ;;
 847   x86_64-*-mingw*)
 848     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 849     ;;
 850   *-*-cygwin*)
 851     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 852     noconfigdirs="$noconfigdirs target-gperf target-libgloss"
 853     # always build newlib if winsup directory is present.
 854     if test -d "$srcdir/winsup/cygwin"; then
 855       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 856     elif test -d "$srcdir/newlib"; then
 857       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 858     fi
 859     ;;
 860   i[[3456789]]86-moss-msdos | i[[3456789]]86-*-moss* | \
 861   i[[3456789]]86-*-uwin* | i[[3456789]]86-*-interix* )
 862     ;;
 863   i[[3456789]]86-*-pe)
 864     noconfigdirs="$noconfigdirs target-libgloss"
 865     ;;
 866   i[[3456789]]86-*-sco3.2v5*)
 867     # The linker does not yet know about weak symbols in COFF,
 868     # and is not configured to handle mixed ELF and COFF.
 869     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 870     ;;
 871   i[[3456789]]86-*-sco*)
 872     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 873     ;;
 874   i[[3456789]]86-*-solaris2*)
 875     noconfigdirs="$noconfigdirs target-libgloss"
 876     ;;
 877   i[[3456789]]86-*-sysv4*)
 878     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 879     ;;
 880   i[[3456789]]86-*-beos*)
 881     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 882     ;;
 883   i[[3456789]]86-*-rdos*)
 884     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 885     ;;
 886   m32r-*-*)
 887     noconfigdirs="$noconfigdirs ${libgcj}"
 888     ;;
 889   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 890     noconfigdirs="$noconfigdirs target-libiberty"
 891     libgloss_dir=m68hc11
 892     ;;
 893   m68k-*-elf*)
 894     noconfigdirs="$noconfigdirs ${libgcj}"
 895     ;;
 896   m68k-*-coff*)
 897     noconfigdirs="$noconfigdirs ${libgcj}"
 898     ;;
 899   m68*-*-* | fido-*-*)
 900     libgloss_dir=m68k
 901     ;;
 902   mcore-*-pe*)
 903     ;;
 904   mmix-*-*)
 905     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc gdb libgloss"
 906     unsupported_languages="$unsupported_languages fortran java"
 907     ;;
 908   mn10200-*-*)
 909     noconfigdirs="$noconfigdirs ${libgcj}"
 910     ;;
 911   mn10300-*-*)
 912     noconfigdirs="$noconfigdirs ${libgcj}"
 913     ;;
 914   mt-*-*)
 915     noconfigdirs="$noconfigdirs sim"
 916     ;;
 917   picochip-*-*)
 918     noconfigdirs="$noconfigdirs target-libiberty"
 919     ;;
 920   powerpc-*-aix*)
 921     # copied from rs6000-*-* entry
 922     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
 923     ;;
 924   powerpc*-*-winnt* | powerpc*-*-pe* | ppc*-*-pe)
 925     target_configdirs="$target_configdirs target-winsup"
 926     noconfigdirs="$noconfigdirs gdb tcl tk make expect target-libgloss itcl gnuserv ${libgcj}"
 927     # always build newlib.
 928     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 929     ;;
 930     # This is temporary until we can link against shared libraries
 931   powerpcle-*-solaris*)
 932     noconfigdirs="$noconfigdirs gdb sim make tcl tk expect itcl gnuserv ${libgcj}"
 933     libgloss_dir=rs6000
 934     ;;
 935   powerpc-*-beos*)
 936     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 937     ;;
 938   powerpc-*-eabi)
 939     noconfigdirs="$noconfigdirs ${libgcj}"
 940     libgloss_dir=rs6000
 941     ;;
 942   powerpc-*-eabi* | powerpcle-*-eabi* | powerpc-*-rtems* )
 943     libgloss_dir=rs6000
 944     ;;
 945   rs6000-*-lynxos*)
 946     noconfigdirs="$noconfigdirs target-newlib gprof ${libgcj}"
 947     ;;
 948   rs6000-*-aix*)
 949     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp target-newlib ${libgcj}"
 950     ;;
 951   rs6000-*-*)
 952     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 953     ;;
 954   m68k-apollo-*)
 955     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss ${libgcj}"
 956     ;;
 957   microblaze*)
 958     noconfigdirs="$noconfigdirs gprof target-libssp ${libgcj}"
 959     ;;
 960   mips*-sde-elf*)
 961     skipdirs="$skipdirs target-libiberty"
 962     noconfigdirs="$noconfigdirs ${libgcj}"
 963     if test x$with_newlib = xyes; then
 964       noconfigdirs="$noconfigdirs gprof"
 965     fi
 966     libgloss_dir=mips
 967     ;;
 968   mips*-*-irix5*)
 969     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 970     ;;
 971   mips*-*-irix6*)
 972     # Linking libjava exceeds command-line length limits on at least
 973     # IRIX 6.2, but not on IRIX 6.5.
 974     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 975     # <oldham@codesourcery.com>
 976     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 977     ;;
 978   mips*-*-bsd*)
 979     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 980     ;;
 981   mips*-*-linux*)
 982     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 983     ;;
 984   mips*-*-*)
 985     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 986     libgloss_dir=mips
 987     ;;
 988   romp-*-*)
 989     noconfigdirs="$noconfigdirs bfd binutils ld gas opcodes target-libgloss ${libgcj}"
 990     ;;
 991   sh-*-* | sh64-*-*)
 992     case "${host}" in
 993       i[[3456789]]86-*-vsta) ;; # don't add gprof back in
 994       i[[3456789]]86-*-go32*) ;; # don't add gprof back in
 995       i[[3456789]]86-*-msdosdjgpp*) ;; # don't add gprof back in
 996       *) skipdirs=`echo " ${skipdirs} " | sed -e 's/ gprof / /'` ;;
 997     esac
 998     case "${target}" in
 999       sh*-*-elf)
1000          noconfigdirs="$noconfigdirs ${libgcj}" ;;
1001       *)
1002          noconfigdirs="$noconfigdirs target-libgloss ${libgcj}" ;;
1003     esac
1004     ;;
1005   sparclet-*-aout* | sparc86x-*-*)
1006     libgloss_dir=sparc
1007     ;;
1008   sparc-*-elf*)
1009     noconfigdirs="$noconfigdirs ${libgcj}"
1010     ;;
1011   sparc64-*-elf*)
1012     noconfigdirs="$noconfigdirs ${libgcj}"
1013     libgloss_dir=sparc
1014     ;;
1015   sparclite-*-*)
1016     noconfigdirs="$noconfigdirs ${libgcj}"
1017     libgloss_dir=sparc
1018     ;;
1019   sparc-*-sunos4*)
1020     noconfigdirs="$noconfigdirs ${libgcj}"
1021     if test x${is_cross_compiler} != xno ; then
1022            noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1023     else
1024            use_gnu_ld=no
1025     fi
1026     ;;
1027   sparc-*-solaris2.[[0-6]] | sparc-*-solaris2.[[0-6]].*)
1028     noconfigdirs="$noconfigdirs ${libgcj}"
1029     ;;
1030   sparc-*-solaris* | sparc64-*-solaris* | sparcv9-*-solaris*)
1031     ;;
1032   tic6x-*-*)
1033     noconfigdirs="$noconfigdirs gdb sim ${libgcj}"
1034     ;;
1035   v810-*-*)
1036     noconfigdirs="$noconfigdirs bfd binutils gas gcc gdb ld target-libstdc++-v3 opcodes target-libgloss ${libgcj}"
1037     ;;
1038   v850*-*-*)
1039     noconfigdirs="$noconfigdirs ${libgcj}"
1040     ;;
1041   vax-*-vms)
1042     noconfigdirs="$noconfigdirs bfd binutils gdb ld target-newlib opcodes target-libgloss ${libgcj}"
1043     ;;
1044   vax-*-*)
1045     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1046     ;;
1047   xtensa*-*-*)
1048     noconfigdirs="$noconfigdirs ${libgcj}"
1049     ;;
1050   ip2k-*-*)
1051     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj}"
1052     ;;
1053   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1054     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1055     ;;
1056   *-*-lynxos*)
1057     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
1058     ;;
1059   *-*-*)
1060     noconfigdirs="$noconfigdirs ${libgcj}"
1061     ;;
1062 esac
1063
1064 # If we aren't building newlib, then don't build libgloss, since libgloss
1065 # depends upon some newlib header files.
1066 case "${noconfigdirs}" in
1067   *target-libgloss*) ;;
1068   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1069 esac
1070
1071 # Work in distributions that contain no compiler tools, like Autoconf.
1072 tentative_cc=""
1073 host_makefile_frag=/dev/null
1074 if test -d ${srcdir}/config ; then
1075 case "${host}" in
1076   m68k-hp-hpux*)
1077     # Avoid "too much defining" errors from HPUX compiler.
1078     tentative_cc="cc -Wp,-H256000"
1079     # If "ar" in $PATH is GNU ar, the symbol table may need rebuilding.
1080     # If it's HP/UX ar, this should be harmless.
1081     RANLIB="ar ts"
1082     ;;
1083   m68k-apollo-sysv*)
1084     tentative_cc="cc -A ansi -A runtype,any -A systype,any -U__STDC__ -DUSG"
1085     ;;
1086   m68k-apollo-bsd*)
1087     #None of the Apollo compilers can compile gas or binutils.  The preprocessor
1088     # chokes on bfd, the compiler won't let you assign integers to enums, and
1089     # other problems.  Defining CC to gcc is a questionable way to say "don't use
1090     # the apollo compiler" (the preferred version of GCC could be called cc,
1091     # or whatever), but I'm not sure leaving CC as cc is any better...
1092     #CC=cc -A ansi -A runtype,any -A systype,any -U__STDC__ -DNO_STDARG
1093     # Used to have BISON=yacc.
1094     tentative_cc=gcc
1095     ;;
1096   m88k-dg-dgux*)
1097     tentative_cc="gcc -Wall -ansi -D__using_DGUX"
1098     ;;
1099   m88k-harris-cxux*)
1100     # Under CX/UX, we want to tell the compiler to use ANSI mode.
1101     tentative_cc="cc -Xa"
1102     host_makefile_frag="config/mh-cxux"
1103     ;;
1104   m88k-motorola-sysv*)
1105     ;;
1106   mips*-dec-ultrix*)
1107     tentative_cc="cc -Wf,-XNg1000"
1108     host_makefile_frag="config/mh-decstation"
1109     ;;
1110   mips*-nec-sysv4*)
1111     # The C compiler on NEC MIPS SVR4 needs bigger tables.
1112     tentative_cc="cc -ZXNd=5000 -ZXNg=1000"
1113     host_makefile_frag="config/mh-necv4"
1114     ;;
1115   mips*-sgi-irix4*)
1116     # Tell compiler to use K&R C.  We can't compile under the SGI Ansi
1117     # environment.  Also bump switch table size so that cp-parse will
1118     # compile.  Bump string length limit so linker builds.
1119     tentative_cc="cc -cckr -Wf,-XNg1500 -Wf,-XNk1000 -Wf,-XNh2000 -Wf,-XNl8192"
1120     ;;
1121   mips*-*-sysv4*)
1122     host_makefile_frag="config/mh-sysv4"
1123     ;;
1124   mips*-*-sysv*)
1125     # This is for a MIPS running RISC/os 4.52C.
1126
1127     # This is needed for GDB, but needs to be in the top-level make because
1128     # if a library is compiled with the bsd headers and gets linked with the
1129     # sysv system libraries all hell can break loose (e.g. a jmp_buf might be
1130     # a different size).
1131     # ptrace(2) apparently has problems in the BSD environment.  No workaround is
1132     # known except to select the sysv environment.  Could we use /proc instead?
1133     # These "sysv environments" and "bsd environments" often end up being a pain.
1134     #
1135     # This is not part of CFLAGS because perhaps not all C compilers have this
1136     # option.
1137     tentative_cc="cc -systype sysv"
1138     ;;
1139   i370-ibm-opened*)
1140     tentative_cc="c89"
1141     ;;
1142   i[[3456789]]86-*-sysv5*)
1143     host_makefile_frag="config/mh-sysv5"
1144     ;;
1145   i[[3456789]]86-*-dgux*)
1146     tentative_cc="gcc -Wall -ansi -D__using_DGUX"
1147     host_makefile_frag="config/mh-dgux386"
1148     ;;
1149   i[[3456789]]86-ncr-sysv4.3*)
1150     # The MetaWare compiler will generate a copyright message unless you
1151     # turn it off by adding the -Hnocopyr flag.
1152     tentative_cc="cc -Hnocopyr"
1153     ;;
1154   i[[3456789]]86-ncr-sysv4*)
1155     # for an NCR 3000 (i486/SVR4) system.
1156     # The NCR 3000 ships with a MetaWare compiler installed as /bin/cc.
1157     # This compiler not only emits obnoxious copyright messages every time
1158     # you run it, but it chokes and dies on a whole bunch of GNU source
1159     # files.  Default to using the AT&T compiler installed in /usr/ccs/ATT/cc.
1160     tentative_cc="/usr/ccs/ATT/cc"
1161     host_makefile_frag="config/mh-ncr3000"
1162     ;;
1163   i[[3456789]]86-*-sco3.2v5*)
1164     ;;
1165   i[[3456789]]86-*-sco*)
1166     # The native C compiler botches some simple uses of const.  Unfortunately,
1167     # it doesn't defined anything like "__sco__" for us to test for in ansidecl.h.
1168     tentative_cc="cc -Dconst="
1169     host_makefile_frag="config/mh-sco"
1170     ;;
1171   i[[3456789]]86-*-udk*)
1172     host_makefile_frag="config/mh-sysv5"
1173     ;;
1174   i[[3456789]]86-*-solaris2*)
1175     host_makefile_frag="config/mh-sysv4"
1176     ;;
1177   i[[3456789]]86-*-msdosdjgpp*)
1178     host_makefile_frag="config/mh-djgpp"
1179     ;;
1180   *-cygwin*)
1181     ACX_CHECK_CYGWIN_CAT_WORKS
1182     host_makefile_frag="config/mh-cygwin"
1183     ;;
1184   *-mingw*)
1185     host_makefile_frag="config/mh-mingw"
1186     ;;
1187   *-interix*)
1188     host_makefile_frag="config/mh-interix"
1189     ;;
1190   vax-*-ultrix2*)
1191     # The old BSD pcc isn't up to compiling parts of gdb so use gcc
1192     tentative_cc=gcc
1193     ;;
1194   *-*-solaris2*)
1195     host_makefile_frag="config/mh-solaris"
1196     ;;
1197   m68k-sun-sunos*)
1198     # Sun's C compiler needs the -J flag to be able to compile cp-parse.c
1199     # without overflowing the jump tables (-J says to use a 32 bit table)
1200     tentative_cc="cc -J"
1201     ;;
1202   hppa*-hp-hpux10*)
1203     tentative_cc="cc -Wp,-H256000"
1204     host_makefile_frag="config/mh-pa-hpux10"
1205     ;;
1206   hppa*-hp-hpux* | hppa*-*-hiux*)
1207     tentative_cc="cc -Wp,-H256000"
1208     host_makefile_frag="config/mh-pa"
1209     ;;
1210   hppa*-*)
1211     host_makefile_frag="config/mh-pa"
1212     ;;
1213   *-hp-hpux* | *-*-hiux*)
1214     tentative_cc="cc -Wp,-H256000"
1215     ;;
1216   rs6000-*-lynxos*)
1217     # /bin/cc is less than useful for our purposes.  Always use GCC
1218     tentative_cc="/usr/cygnus/progressive/bin/gcc"
1219     host_makefile_frag="config/mh-lynxrs6k"
1220     ;;
1221   *-*-darwin*)
1222     host_makefile_frag="config/mh-darwin"
1223     ;;
1224   powerpc-*-aix*)
1225     host_makefile_frag="config/mh-ppc-aix"
1226     ;;
1227   rs6000-*-aix*)
1228     host_makefile_frag="config/mh-ppc-aix"
1229     ;;
1230   *-*-lynxos*)
1231     # /bin/cc is less than useful for our purposes.  Always use GCC
1232     tentative_cc="/bin/gcc"
1233     ;;
1234   *-*-sysv4*)
1235     host_makefile_frag="config/mh-sysv4"
1236     ;;
1237   # This is placed last to prevent interfering with the cases above.
1238   i[[3456789]]86-*-*)
1239     # Build the stage2 and stage3 compilers with -fomit-frame-pointer.
1240     host_makefile_frag="config/mh-x86omitfp"
1241     ;;
1242 esac
1243 fi
1244
1245 # If we aren't going to be using gcc, see if we can extract a definition
1246 # of CC from the fragment.
1247 # Actually, use the 'pre-extracted' version above.
1248 if test -z "${CC}" && test "${build}" = "${host}" ; then
1249   IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
1250   found=
1251   for dir in $PATH; do
1252     test -z "$dir" && dir=.
1253     if test -f $dir/gcc; then
1254       found=yes
1255       break
1256     fi
1257   done
1258   IFS="$save_ifs"
1259   if test -z "${found}" && test -n "${tentative_cc}" ; then
1260     CC=$tentative_cc
1261   fi
1262 fi
1263
1264 if test "${build}" != "${host}" ; then
1265   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1266   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1267   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1268   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1269   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1270   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1271   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1272   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1273   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1274   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1275   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1276   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1277   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1278 else
1279   AR_FOR_BUILD="\$(AR)"
1280   AS_FOR_BUILD="\$(AS)"
1281   CC_FOR_BUILD="\$(CC)"
1282   CXX_FOR_BUILD="\$(CXX)"
1283   GCJ_FOR_BUILD="\$(GCJ)"
1284   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1285   GOC_FOR_BUILD="\$(GOC)"
1286   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1287   LD_FOR_BUILD="\$(LD)"
1288   NM_FOR_BUILD="\$(NM)"
1289   RANLIB_FOR_BUILD="\$(RANLIB)"
1290   WINDRES_FOR_BUILD="\$(WINDRES)"
1291   WINDMC_FOR_BUILD="\$(WINDMC)"
1292 fi
1293
1294 AC_PROG_CC
1295 AC_PROG_CXX
1296
1297 # We must set the default linker to the linker used by gcc for the correct
1298 # operation of libtool.  If LD is not defined and we are using gcc, try to
1299 # set the LD default to the ld used by gcc.
1300 if test -z "$LD"; then
1301   if test "$GCC" = yes; then
1302     case $build in
1303     *-*-mingw*)
1304       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1305     *)
1306       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1307     esac
1308     case $gcc_prog_ld in
1309     # Accept absolute paths.
1310     [[\\/]* | [A-Za-z]:[\\/]*)]
1311       LD="$gcc_prog_ld" ;;
1312     esac
1313   fi
1314 fi
1315
1316 ACX_PROG_GNAT
1317 ACX_PROG_CMP_IGNORE_INITIAL
1318
1319 # See if we are building gcc with C++.
1320 AC_ARG_ENABLE(build-with-cxx,
1321 [AS_HELP_STRING([--enable-build-with-cxx],
1322                 [build with C++ compiler instead of C compiler])],
1323 ENABLE_BUILD_WITH_CXX=$enableval,
1324 ENABLE_BUILD_WITH_CXX=no)
1325
1326 # Used for setting $lt_cv_objdir
1327 _LT_CHECK_OBJDIR
1328
1329 # Check for GMP, MPFR and MPC
1330 gmplibs="-lmpc -lmpfr -lgmp"
1331 gmpinc=
1332 have_gmp=no
1333
1334 # Specify a location for mpc
1335 # check for this first so it ends up on the link line before mpfr.
1336 AC_ARG_WITH(mpc,
1337 [AS_HELP_STRING([--with-mpc=PATH],
1338                 [specify prefix directory for installed MPC package.
1339                  Equivalent to --with-mpc-include=PATH/include
1340                  plus --with-mpc-lib=PATH/lib])])
1341 AC_ARG_WITH(mpc-include,
1342 [AS_HELP_STRING([--with-mpc-include=PATH],
1343                 [specify directory for installed MPC include files])])
1344 AC_ARG_WITH(mpc-lib,
1345 [AS_HELP_STRING([--with-mpc-lib=PATH],
1346                 [specify directory for the installed MPC library])])
1347
1348 if test "x$with_mpc" != x; then
1349   gmplibs="-L$with_mpc/lib $gmplibs"
1350   gmpinc="-I$with_mpc/include $gmpinc"
1351 fi
1352 if test "x$with_mpc_include" != x; then
1353   gmpinc="-I$with_mpc_include $gmpinc"
1354 fi
1355 if test "x$with_mpc_lib" != x; then
1356   gmplibs="-L$with_mpc_lib $gmplibs"
1357 fi
1358 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1359   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1360   gmpinc='-I$$s/mpc/src '"$gmpinc"
1361   # Do not test the mpc version.  Assume that it is sufficient, since
1362   # it is in the source tree, and the library has not been built yet
1363   # but it would be included on the link line in the version check below
1364   # hence making the test fail.
1365   have_gmp=yes
1366 fi
1367
1368 # Specify a location for mpfr
1369 # check for this first so it ends up on the link line before gmp.
1370 AC_ARG_WITH(mpfr-dir,
1371 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1372 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1373 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1374
1375 AC_ARG_WITH(mpfr,
1376 [AS_HELP_STRING([--with-mpfr=PATH],
1377                 [specify prefix directory for installed MPFR package.
1378                  Equivalent to --with-mpfr-include=PATH/include
1379                  plus --with-mpfr-lib=PATH/lib])])
1380 AC_ARG_WITH(mpfr-include,
1381 [AS_HELP_STRING([--with-mpfr-include=PATH],
1382                 [specify directory for installed MPFR include files])])
1383 AC_ARG_WITH(mpfr-lib,
1384 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1385                 [specify directory for the installed MPFR library])])
1386
1387 if test "x$with_mpfr" != x; then
1388   gmplibs="-L$with_mpfr/lib $gmplibs"
1389   gmpinc="-I$with_mpfr/include $gmpinc"
1390 fi
1391 if test "x$with_mpfr_include" != x; then
1392   gmpinc="-I$with_mpfr_include $gmpinc"
1393 fi
1394 if test "x$with_mpfr_lib" != x; then
1395   gmplibs="-L$with_mpfr_lib $gmplibs"
1396 fi
1397 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1398   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1399   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1400   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1401   # Do not test the mpfr version.  Assume that it is sufficient, since
1402   # it is in the source tree, and the library has not been built yet
1403   # but it would be included on the link line in the version check below
1404   # hence making the test fail.
1405   have_gmp=yes
1406 fi
1407
1408 # Specify a location for gmp
1409 AC_ARG_WITH(gmp-dir,
1410 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1411 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1412 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1413
1414 AC_ARG_WITH(gmp,
1415 [AS_HELP_STRING([--with-gmp=PATH],
1416                 [specify prefix directory for the installed GMP package.
1417                  Equivalent to --with-gmp-include=PATH/include
1418                  plus --with-gmp-lib=PATH/lib])])
1419 AC_ARG_WITH(gmp-include,
1420 [AS_HELP_STRING([--with-gmp-include=PATH],
1421                 [specify directory for installed GMP include files])])
1422 AC_ARG_WITH(gmp-lib,
1423 [AS_HELP_STRING([--with-gmp-lib=PATH],
1424                 [specify directory for the installed GMP library])])
1425
1426
1427 if test "x$with_gmp" != x; then
1428   gmplibs="-L$with_gmp/lib $gmplibs"
1429   gmpinc="-I$with_gmp/include $gmpinc"
1430 fi
1431 if test "x$with_gmp_include" != x; then
1432   gmpinc="-I$with_gmp_include $gmpinc"
1433 fi
1434 if test "x$with_gmp_lib" != x; then
1435   gmplibs="-L$with_gmp_lib $gmplibs"
1436 fi
1437 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1438   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1439   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1440   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1441   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1442   # Do not test the gmp version.  Assume that it is sufficient, since
1443   # it is in the source tree, and the library has not been built yet
1444   # but it would be included on the link line in the version check below
1445   # hence making the test fail.
1446   have_gmp=yes
1447 fi
1448
1449 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1450   have_gmp=yes
1451   saved_CFLAGS="$CFLAGS"
1452   CFLAGS="$CFLAGS $gmpinc"
1453   # Check for the recommended and required versions of GMP.
1454   AC_MSG_CHECKING([for the correct version of gmp.h])
1455   AC_TRY_COMPILE([#include "gmp.h"],[
1456   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1457   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1458   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1459   choke me
1460   #endif
1461   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1462   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1463   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1464   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1465   choke me
1466   #endif
1467   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1468    [AC_MSG_RESULT([no]); have_gmp=no])
1469
1470   # If we have GMP, check the MPFR version.
1471   if test x"$have_gmp" = xyes; then
1472     # Check for the recommended and required versions of MPFR.
1473     AC_MSG_CHECKING([for the correct version of mpfr.h])
1474     AC_TRY_COMPILE([#include <gmp.h>
1475     #include <mpfr.h>],[
1476     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1477     choke me
1478     #endif
1479     ], [AC_TRY_COMPILE([#include <gmp.h>
1480     #include <mpfr.h>],[
1481     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1482     choke me
1483     #endif
1484     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1485      [AC_MSG_RESULT([no]); have_gmp=no])
1486   fi
1487
1488   # Check for the MPC header version.
1489   if test x"$have_gmp" = xyes ; then
1490     # Check for the recommended and required versions of MPC.
1491     AC_MSG_CHECKING([for the correct version of mpc.h])
1492     AC_TRY_COMPILE([#include <mpc.h>],[
1493     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1494     choke me
1495     #endif
1496     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1497     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1498     choke me
1499     #endif
1500     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1501      [AC_MSG_RESULT([no]); have_gmp=no])
1502   fi
1503
1504   # Now check the MPFR library.
1505   if test x"$have_gmp" = xyes; then
1506     saved_LIBS="$LIBS"
1507     LIBS="$LIBS $gmplibs"
1508     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1509     AC_TRY_LINK([#include <mpc.h>],[
1510     mpfr_t n;
1511     mpfr_t x;
1512     mpc_t c;
1513     int t;
1514     mpfr_init (n);
1515     mpfr_init (x);
1516     mpfr_atan2 (n, n, x, GMP_RNDN);
1517     mpfr_erfc (n, x, GMP_RNDN);
1518     mpfr_subnormalize (x, t, GMP_RNDN);
1519     mpfr_clear(n);
1520     mpfr_clear(x);
1521     mpc_init2 (c, 53);
1522     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1523     mpc_cosh (c, c, MPC_RNDNN);
1524     mpc_pow (c, c, c, MPC_RNDNN);
1525     mpc_acosh (c, c, MPC_RNDNN);
1526     mpc_clear (c);
1527     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1528     LIBS="$saved_LIBS"
1529   fi
1530
1531   CFLAGS="$saved_CFLAGS"
1532
1533 # The library versions listed in the error message below should match
1534 # the HARD-minimums enforced above.
1535   if test x$have_gmp != xyes; then
1536     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1537 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1538 their locations.  Source code for these libraries can be found at
1539 their respective hosting sites as well as at
1540 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1541 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1542 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1543 make sure that you have installed both the libraries and the header
1544 files.  They may be located in separate packages.])
1545   fi
1546 fi
1547
1548 # Flags needed for both GMP, MPFR and/or MPC.
1549 AC_SUBST(gmplibs)
1550 AC_SUBST(gmpinc)
1551 AC_SUBST(extra_mpfr_configure_flags)
1552 AC_SUBST(extra_mpc_gmp_configure_flags)
1553 AC_SUBST(extra_mpc_mpfr_configure_flags)
1554
1555 # Allow host libstdc++ to be specified for static linking with PPL.
1556 AC_ARG_WITH(host-libstdcxx,
1557 [AS_HELP_STRING([--with-host-libstdcxx=L],
1558                 [use linker arguments L to link with libstdc++
1559                  when linking with PPL])])
1560
1561 case $with_host_libstdcxx in
1562   no|yes)
1563     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1564     ;;
1565 esac
1566
1567 # Linker flags to use for stage1 or when not boostrapping.
1568 AC_ARG_WITH(stage1-ldflags,
1569 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1570 [if test "$withval" = "no" -o "$withval" = "yes"; then
1571    stage1_ldflags=
1572  else
1573    stage1_ldflags=$withval
1574  fi],
1575 [stage1_ldflags=])
1576 AC_SUBST(stage1_ldflags)
1577
1578 # Libraries to use for stage1 or when not bootstrapping.
1579 AC_ARG_WITH(stage1-libs,
1580 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1581 [if test "$withval" = "no" -o "$withval" = "yes"; then
1582    stage1_libs=
1583  else
1584    stage1_libs=$withval
1585  fi],
1586 [stage1_libs=$with_host_libstdcxx])
1587 AC_SUBST(stage1_libs)
1588
1589 # Libraries to use for stage2 and later builds.  This defaults to the
1590 # argument passed to --with-host-libstdcxx.
1591 AC_ARG_WITH(boot-libs,
1592 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1593 [if test "$withval" = "no" -o "$withval" = "yes"; then
1594    poststage1_libs=
1595  else
1596    poststage1_libs=$withval
1597  fi],
1598 [poststage1_libs=$with_host_libstdcxx])
1599 AC_SUBST(poststage1_libs)
1600
1601 # Linker flags to use for stage2 and later builds.
1602 AC_ARG_WITH(boot-ldflags,
1603 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1604                 [linker flags for stage2 and later])],
1605 [if test "$withval" = "no" -o "$withval" = "yes"; then
1606    poststage1_ldflags=
1607  else
1608    poststage1_ldflags=$withval
1609  fi],
1610 [poststage1_ldflags=
1611  # In stages 2 and 3, default to linking libstdc++ and libgcc
1612  # statically.  But if the user explicitly specified the libraries to
1613  # use, trust that they are doing what they want.
1614  if test "$poststage1_libs" = ""; then
1615    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1616  fi])
1617 AC_SUBST(poststage1_ldflags)
1618
1619 # Check for PPL
1620 ppllibs=
1621 pplinc=
1622 pwllib=
1623
1624 AC_ARG_WITH(ppl,
1625 [AS_HELP_STRING([--with-ppl=PATH],
1626                 [specify prefix directory for the installed PPL package.
1627                  Equivalent to --with-ppl-include=PATH/include
1628                  plus --with-ppl-lib=PATH/lib])])
1629 AC_ARG_WITH(ppl-include,
1630 [AS_HELP_STRING([--with-ppl-include=PATH],
1631                 [specify directory for installed PPL include files])])
1632 AC_ARG_WITH(ppl-lib,
1633 [AS_HELP_STRING([--with-ppl-lib=PATH],
1634                 [specify directory for the installed PPL library])])
1635
1636 AC_ARG_ENABLE(ppl-version-check,
1637 [AS_HELP_STRING([--disable-ppl-version-check],
1638                 [disable check for PPL version])])
1639
1640 case $with_ppl in
1641   yes | no | "")
1642     ;;
1643   *)
1644     ppllibs="-L$with_ppl/lib"
1645     pplinc="-I$with_ppl/include $pplinc"
1646     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1647       with_ppl=yes
1648     else
1649       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1650     fi
1651     ;;
1652 esac
1653
1654 if test x"$with_ppl_include" != x; then
1655   pplinc="-I$with_ppl_include $pplinc"
1656   with_ppl=yes
1657 fi
1658
1659 if test "x$with_ppl_lib" != x; then
1660   ppllibs="-L$with_ppl_lib"
1661   with_ppl=yes
1662 fi
1663
1664 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1665   if test x"$enable_watchdog" = xyes; then
1666     pwllib="-lpwl"
1667   fi
1668   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1669   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1670   enable_ppl_version_check=no
1671   with_ppl=yes
1672 fi
1673
1674 if test "x$with_ppl" != xno; then
1675   if test "x$pwllib" = x; then
1676     saved_LIBS="$LIBS"
1677     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1678     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1679     LIBS="$saved_LIBS"
1680   fi
1681
1682   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1683
1684   if test "$enable_ppl_version_check" != no; then
1685     saved_CFLAGS="$CFLAGS"
1686     CFLAGS="$CFLAGS $pplinc $gmpinc"
1687     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1688     AC_TRY_COMPILE([#include "ppl_c.h"],[
1689     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1690     choke me
1691     #endif
1692     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1693     CFLAGS="$saved_CFLAGS"
1694   fi
1695 fi
1696
1697 # Flags needed for PPL
1698 AC_SUBST(ppllibs)
1699 AC_SUBST(pplinc)
1700
1701
1702 # Check for CLOOG
1703
1704 dnl Provide configure switches and initialize clooginc & clooglibs
1705 dnl with user input.
1706 CLOOG_INIT_FLAGS
1707 if test "x$with_ppl" = "xno"; then
1708   dnl Only execute fail-action, if CLooG has been requested.
1709   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1710   if test "${graphite_requested}" = yes; then
1711     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1712   fi
1713   with_cloog=no
1714 fi
1715 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1716   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1717   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1718   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1719 fi
1720 if test "x$with_cloog" != "xno"; then
1721   dnl The minimal version of CLooG required for Graphite.
1722   dnl
1723   dnl If we use CLooG-Legacy, the provided version information is
1724   dnl ignored.
1725   CLOOG_CHECK_VERSION(0,16,1)
1726
1727   dnl Only execute fail-action, if CLooG has been requested.
1728   CLOOG_IF_FAILED([
1729     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1730 fi
1731
1732 # Check for LTO support.
1733 AC_ARG_ENABLE(lto,
1734 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1735 enable_lto=$enableval,
1736 enable_lto=yes; default_enable_lto=yes)
1737
1738 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1739   build_lto_plugin=yes
1740 ],[if test x"$default_enable_lto" = x"yes" ; then
1741     case $target in
1742       *-apple-darwin9 | *-cygwin* | *-mingw*) ;;
1743       # On other non-ELF platforms, LTO has yet to be validated.
1744       *) enable_lto=no ;;
1745     esac
1746   else
1747   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1748   # It would also be nice to check the binutils support, but we don't
1749   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1750   # warn during gcc/ subconfigure; unless you're bootstrapping with
1751   # -flto it won't be needed until after installation anyway.
1752     case $target in
1753       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1754       *) if test x"$enable_lto" = x"yes"; then
1755         AC_MSG_ERROR([LTO support is not enabled for this target.])
1756         fi
1757       ;;
1758     esac
1759   fi
1760   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1761   # Build it unless LTO was explicitly disabled.
1762   case $target in
1763     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1764     *) ;;
1765   esac
1766 ])
1767
1768
1769 # By default, C is the only stage 1 language.
1770 stage1_languages=,c,
1771
1772 # Target libraries that we bootstrap.
1773 bootstrap_target_libs=,target-libgcc,
1774
1775 # Figure out what language subdirectories are present.
1776 # Look if the user specified --enable-languages="..."; if not, use
1777 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1778 # go away some day.
1779 # NB:  embedded tabs in this IF block -- do not untabify
1780 if test -d ${srcdir}/gcc; then
1781   if test x"${enable_languages+set}" != xset; then
1782     if test x"${LANGUAGES+set}" = xset; then
1783       enable_languages="${LANGUAGES}"
1784         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1785     else
1786       enable_languages=all
1787     fi
1788   else
1789     if test x"${enable_languages}" = x ||
1790        test x"${enable_languages}" = xyes;
1791        then
1792       echo configure.in: --enable-languages needs at least one language argument 1>&2
1793       exit 1
1794     fi
1795   fi
1796   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1797
1798   # 'f95' is the old name for the 'fortran' language. We issue a warning
1799   # and make the substitution.
1800   case ,${enable_languages}, in
1801     *,f95,*)
1802       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1803       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1804       ;;
1805   esac
1806
1807   # First scan to see if an enabled language requires some other language.
1808   # We assume that a given config-lang.in will list all the language
1809   # front ends it requires, even if some are required indirectly.
1810   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1811     case ${lang_frag} in
1812       ..) ;;
1813       # The odd quoting in the next line works around
1814       # an apparent bug in bash 1.12 on linux.
1815       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1816       *)
1817         # From the config-lang.in, get $language, $lang_requires, and
1818         # $lang_requires_boot_languages.
1819         language=
1820         lang_requires=
1821         lang_requires_boot_languages=
1822         . ${lang_frag}
1823         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1824           case ,${enable_languages}, in
1825             *,$other,*) ;;
1826             *,all,*) ;;
1827             *,$language,*)
1828               echo " \`$other' language required by \`$language'; enabling" 1>&2
1829               enable_languages="${enable_languages},${other}"
1830               ;;
1831           esac
1832         done
1833         for other in ${lang_requires_boot_languages} ; do
1834           if test "$other" != "c"; then
1835             case ,${enable_stage1_languages}, in
1836               *,$other,*) ;;
1837               *,all,*) ;;
1838               *)
1839                 case ,${enable_languages}, in
1840                   *,$language,*)
1841                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1842                     enable_stage1_languages="$enable_stage1_languages,${other}"
1843                     ;;
1844                 esac
1845                 ;;
1846             esac
1847           fi
1848         done
1849         ;;
1850     esac
1851   done
1852
1853   new_enable_languages=,c,
1854
1855   # If LTO is enabled, add the LTO front end.
1856   extra_host_libiberty_configure_flags=
1857   if test "$enable_lto" = "yes" ; then
1858     case ,${enable_languages}, in
1859       *,lto,*) ;;
1860       *) enable_languages="${enable_languages},lto" ;;
1861     esac
1862     if test "${build_lto_plugin}" = "yes" ; then
1863       configdirs="$configdirs lto-plugin"
1864       extra_host_libiberty_configure_flags=--enable-shared
1865     fi
1866   fi
1867   AC_SUBST(extra_host_libiberty_configure_flags)
1868
1869   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1870   potential_languages=,c,
1871
1872   enabled_target_libs=
1873   disabled_target_libs=
1874
1875   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1876     case ${lang_frag} in
1877       ..) ;;
1878       # The odd quoting in the next line works around
1879       # an apparent bug in bash 1.12 on linux.
1880       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1881       *)
1882         # From the config-lang.in, get $language, $target_libs,
1883         # $lang_dirs, $boot_language, and $build_by_default
1884         language=
1885         target_libs=
1886         lang_dirs=
1887         subdir_requires=
1888         boot_language=no
1889         build_by_default=yes
1890         . ${lang_frag}
1891         if test x${language} = x; then
1892           echo "${lang_frag} doesn't set \$language." 1>&2
1893           exit 1
1894         fi
1895
1896         if test "$language" = "c++" \
1897            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1898           boot_language=yes
1899         fi
1900
1901         case ,${enable_languages}, in
1902           *,${language},*)
1903             # Language was explicitly selected; include it.
1904             add_this_lang=yes
1905             ;;
1906           *,all,*)
1907             # 'all' was selected, select it if it is a default language
1908             add_this_lang=${build_by_default}
1909             ;;
1910           *)
1911             add_this_lang=no
1912             ;;
1913         esac
1914
1915         # Disable languages that need other directories if these aren't available.
1916         for i in $subdir_requires; do
1917           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1918           case ,${enable_languages}, in
1919             *,${language},*)
1920               # Specifically requested language; tell them.
1921               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1922               ;;
1923             *)
1924               # Silently disable.
1925               add_this_lang=unsupported
1926               ;;
1927           esac
1928         done
1929
1930         # Disable Ada if no preexisting GNAT is available.
1931         case ,${enable_languages},:${language}:${have_gnat} in
1932           *,${language},*:ada:no)
1933             # Specifically requested language; tell them.
1934             AC_MSG_ERROR([GNAT is required to build $language])
1935             ;;
1936           *:ada:no)
1937             # Silently disable.
1938             add_this_lang=unsupported
1939             ;;
1940         esac
1941
1942         # Disable a language that is unsupported by the target.
1943         case " $unsupported_languages " in
1944           *" $language "*)
1945             add_this_lang=unsupported
1946             ;;
1947         esac
1948
1949         case $add_this_lang in
1950           unsupported)
1951             # Remove language-dependent dirs.
1952             disabled_target_libs="$disabled_target_libs $target_libs"
1953             noconfigdirs="$noconfigdirs $lang_dirs"
1954             ;;
1955           no)
1956             # Remove language-dependent dirs; still show language as supported.
1957             disabled_target_libs="$disabled_target_libs $target_libs"
1958             noconfigdirs="$noconfigdirs $lang_dirs"
1959             potential_languages="${potential_languages}${language},"
1960             ;;
1961           yes)
1962             new_enable_languages="${new_enable_languages}${language},"
1963             potential_languages="${potential_languages}${language},"
1964             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1965             enabled_target_libs="$enabled_target_libs $target_libs"
1966             case "${boot_language}:,$enable_stage1_languages," in
1967               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1968                 # Add to (comma-separated) list of stage 1 languages.
1969                 case ",$stage1_languages," in
1970                   *,$language,* | ,yes, | ,all,) ;;
1971                   *) stage1_languages="${stage1_languages}${language}," ;;
1972                 esac
1973                 # We need to bootstrap any supporting libraries.
1974                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1975                 ;;
1976             esac
1977             ;;
1978         esac
1979         ;;
1980     esac
1981   done
1982
1983   # Add target libraries which are only needed for disabled languages
1984   # to noconfigdirs.
1985   if test -n "$disabled_target_libs"; then
1986     for dir in $disabled_target_libs; do
1987       case " $enabled_target_libs " in
1988       *" ${dir} "*) ;;
1989       *) noconfigdirs="$noconfigdirs $dir" ;;
1990       esac
1991     done
1992   fi
1993
1994   AC_ARG_ENABLE(stage1-languages,
1995   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1996                   [choose additional languages to build during
1997                   stage1.  Mostly useful for compiler development])],
1998   [case ,${enable_stage1_languages}, in
1999     ,no,|,,)
2000       # Set it to something that will have no effect in the loop below
2001       enable_stage1_languages=c ;;
2002     ,yes,)
2003       enable_stage1_languages=`echo $new_enable_languages | \
2004         sed -e "s/^,//" -e "s/,$//" ` ;;
2005     *,all,*)
2006       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2007         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2008   esac
2009
2010   # Add "good" languages from enable_stage1_languages to stage1_languages,
2011   # while "bad" languages go in missing_languages.  Leave no duplicates.
2012   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2013     case $potential_languages in
2014       *,$i,*)
2015         case $stage1_languages in
2016           *,$i,*) ;;
2017           *) stage1_languages="$stage1_languages$i," ;;
2018         esac ;;
2019       *)
2020         case $missing_languages in
2021           *,$i,*) ;;
2022           *) missing_languages="$missing_languages$i," ;;
2023         esac ;;
2024      esac
2025   done])
2026
2027   # Remove leading/trailing commas that were added for simplicity
2028   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2029   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2030   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2031   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2032
2033   if test "x$missing_languages" != x; then
2034     AC_MSG_ERROR([
2035 The following requested languages could not be built: ${missing_languages}
2036 Supported languages are: ${potential_languages}])
2037   fi
2038   if test "x$new_enable_languages" != "x$enable_languages"; then
2039     echo The following languages will be built: ${new_enable_languages}
2040     enable_languages="$new_enable_languages"
2041   fi
2042
2043   AC_SUBST(stage1_languages)
2044   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2045 fi
2046
2047 # Handle --disable-<component> generically.
2048 for dir in $configdirs $build_configdirs $target_configdirs ; do
2049   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2050   varname=`echo $dirname | sed -e s/+/_/g`
2051   if eval test x\${enable_${varname}} "=" xno ; then
2052     noconfigdirs="$noconfigdirs $dir"
2053   fi
2054 done
2055
2056 # Check for Boehm's garbage collector
2057 AC_ARG_ENABLE(objc-gc,
2058 [AS_HELP_STRING([--enable-objc-gc],
2059                 [enable use of Boehm's garbage collector with the
2060                  GNU Objective-C runtime])],
2061 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
2062   *,objc,*:*:yes:*target-boehm-gc*)
2063     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
2064     ;;
2065 esac])
2066
2067 # Make sure we only build Boehm's garbage collector if required.
2068 case ,${enable_languages},:${enable_objc_gc} in
2069   *,objc,*:yes)
2070     # Keep target-boehm-gc if requested for Objective-C.
2071     ;;
2072   *)
2073     # Otherwise remove target-boehm-gc depending on target-libjava.
2074     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
2075       noconfigdirs="$noconfigdirs target-boehm-gc"
2076     fi
2077     ;;
2078 esac
2079
2080 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2081 # $build_configdirs and $target_configdirs.
2082 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2083
2084 notsupp=""
2085 for dir in . $skipdirs $noconfigdirs ; do
2086   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2087   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2088     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2089     if test -r $srcdir/$dirname/configure ; then
2090       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2091         true
2092       else
2093         notsupp="$notsupp $dir"
2094       fi
2095     fi
2096   fi
2097   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2098     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2099     if test -r $srcdir/$dirname/configure ; then
2100       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2101         true
2102       else
2103         notsupp="$notsupp $dir"
2104       fi
2105     fi
2106   fi
2107   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2108     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2109     if test -r $srcdir/$dirname/configure ; then
2110       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2111         true
2112       else
2113         notsupp="$notsupp $dir"
2114       fi
2115     fi
2116   fi
2117 done
2118
2119 # Sometimes the tools are distributed with libiberty but with no other
2120 # libraries.  In that case, we don't want to build target-libiberty.
2121 # Don't let libgcc imply libiberty either.
2122 if test -n "${target_configdirs}" ; then
2123   libgcc=
2124   others=
2125   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
2126     if test "$i" = "libgcc"; then
2127       libgcc=target-libgcc
2128     elif test "$i" != "libiberty" ; then
2129       if test -r $srcdir/$i/configure ; then
2130         others=yes;
2131         break;
2132       fi
2133     fi
2134   done
2135   if test -z "${others}" ; then
2136     target_configdirs=$libgcc
2137   fi
2138 fi
2139
2140 # Quietly strip out all directories which aren't configurable in this tree.
2141 # This relies on all configurable subdirectories being autoconfiscated, which
2142 # is now the case.
2143 build_configdirs_all="$build_configdirs"
2144 build_configdirs=
2145 for i in ${build_configdirs_all} ; do
2146   j=`echo $i | sed -e s/build-//g`
2147   if test -f ${srcdir}/$j/configure ; then
2148     build_configdirs="${build_configdirs} $i"
2149   fi
2150 done
2151
2152 configdirs_all="$configdirs"
2153 configdirs=
2154 for i in ${configdirs_all} ; do
2155   if test -f ${srcdir}/$i/configure ; then
2156     configdirs="${configdirs} $i"
2157   fi
2158 done
2159
2160 target_configdirs_all="$target_configdirs"
2161 target_configdirs=
2162 for i in ${target_configdirs_all} ; do
2163   j=`echo $i | sed -e s/target-//g`
2164   if test -f ${srcdir}/$j/configure ; then
2165     target_configdirs="${target_configdirs} $i"
2166   fi
2167 done
2168
2169 # Produce a warning message for the subdirs we can't configure.
2170 # This isn't especially interesting in the Cygnus tree, but in the individual
2171 # FSF releases, it's important to let people know when their machine isn't
2172 # supported by the one or two programs in a package.
2173
2174 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2175   # If $appdirs is non-empty, at least one of those directories must still
2176   # be configured, or we error out.  (E.g., if the gas release supports a
2177   # specified target in some subdirs but not the gas subdir, we shouldn't
2178   # pretend that all is well.)
2179   if test -n "$appdirs" ; then
2180     for dir in $appdirs ; do
2181       if test -r $dir/Makefile.in ; then
2182         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2183           appdirs=""
2184           break
2185         fi
2186         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2187           appdirs=""
2188           break
2189         fi
2190       fi
2191     done
2192     if test -n "$appdirs" ; then
2193       echo "*** This configuration is not supported by this package." 1>&2
2194       exit 1
2195     fi
2196   fi
2197   # Okay, some application will build, or we don't care to check.  Still
2198   # notify of subdirs not getting built.
2199   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2200   echo "    ${notsupp}" 1>&2
2201   echo "    (Any other directories should still work fine.)" 1>&2
2202 fi
2203
2204 case "$host" in
2205   *msdosdjgpp*)
2206     enable_gdbtk=no ;;
2207 esac
2208
2209 # To find our prefix, in gcc_cv_tool_prefix.
2210 ACX_TOOL_DIRS
2211
2212 copy_dirs=
2213
2214 AC_ARG_WITH([build-sysroot],
2215   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2216                   [use sysroot as the system root during the build])],
2217   [if test x"$withval" != x ; then
2218      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2219    fi],
2220   [SYSROOT_CFLAGS_FOR_TARGET=])
2221 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2222
2223 AC_ARG_WITH([debug-prefix-map],
2224   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2225                   [map A to B, C to D ... in debug information])],
2226   [if test x"$withval" != x; then
2227      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2228      for debug_map in $withval; do
2229        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2230      done
2231    fi],
2232   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2233 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2234
2235 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2236 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2237 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2238 # We want to ensure that TARGET libraries (which we know are built with
2239 # gcc) are built with "-O2 -g", so include those options when setting
2240 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2241 if test "x$CFLAGS_FOR_TARGET" = x; then
2242   CFLAGS_FOR_TARGET=$CFLAGS
2243   case " $CFLAGS " in
2244     *" -O2 "*) ;;
2245     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2246   esac
2247   case " $CFLAGS " in
2248     *" -g "* | *" -g3 "*) ;;
2249     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2250   esac
2251 fi
2252 AC_SUBST(CFLAGS_FOR_TARGET)
2253
2254 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2255   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2256   case " $CXXFLAGS " in
2257     *" -O2 "*) ;;
2258     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2259   esac
2260   case " $CXXFLAGS " in
2261     *" -g "* | *" -g3 "*) ;;
2262     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2263   esac
2264 fi
2265 AC_SUBST(CXXFLAGS_FOR_TARGET)
2266
2267 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2268 # the named directory are copied to $(tooldir)/sys-include.
2269 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2270   if test x${is_cross_compiler} = xno ; then
2271     echo 1>&2 '***' --with-headers is only supported when cross compiling
2272     exit 1
2273   fi
2274   if test x"${with_headers}" != xyes ; then
2275     x=${gcc_cv_tool_prefix}
2276     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2277   fi
2278 fi
2279
2280 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2281 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2282 # are permitted.
2283 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2284   if test x${is_cross_compiler} = xno ; then
2285     echo 1>&2 '***' --with-libs is only supported when cross compiling
2286     exit 1
2287   fi
2288   if test x"${with_libs}" != xyes ; then
2289     # Copy the libraries in reverse order, so that files in the first named
2290     # library override files in subsequent libraries.
2291     x=${gcc_cv_tool_prefix}
2292     for l in ${with_libs}; do
2293       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2294     done
2295   fi
2296 fi
2297
2298 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2299 #
2300 # This is done by determining whether or not the appropriate directory
2301 # is available, and by checking whether or not specific configurations
2302 # have requested that this magic not happen.
2303 #
2304 # The command line options always override the explicit settings in
2305 # configure.in, and the settings in configure.in override this magic.
2306 #
2307 # If the default for a toolchain is to use GNU as and ld, and you don't
2308 # want to do that, then you should use the --without-gnu-as and
2309 # --without-gnu-ld options for the configure script.  Similarly, if
2310 # the default is to use the included zlib and you don't want to do that,
2311 # you should use the --with-system-zlib option for the configure script.
2312
2313 if test x${use_gnu_as} = x &&
2314    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2315   with_gnu_as=yes
2316   extra_host_args="$extra_host_args --with-gnu-as"
2317 fi
2318
2319 if test x${use_gnu_ld} = x &&
2320    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2321   with_gnu_ld=yes
2322   extra_host_args="$extra_host_args --with-gnu-ld"
2323 fi
2324
2325 if test x${use_included_zlib} = x &&
2326    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2327   :
2328 else
2329   with_system_zlib=yes
2330   extra_host_args="$extra_host_args --with-system-zlib"
2331 fi
2332
2333 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2334 # can detect this case.
2335
2336 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2337   with_newlib=yes
2338   extra_host_args="$extra_host_args --with-newlib"
2339 fi
2340
2341 # Handle ${copy_dirs}
2342 set fnord ${copy_dirs}
2343 shift
2344 while test $# != 0 ; do
2345   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2346     :
2347   else
2348     echo Copying $1 to $2
2349
2350     # Use the install script to create the directory and all required
2351     # parent directories.
2352     if test -d $2 ; then
2353       :
2354     else
2355       echo >config.temp
2356       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2357     fi
2358
2359     # Copy the directory, assuming we have tar.
2360     # FIXME: Should we use B in the second tar?  Not all systems support it.
2361     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2362
2363     # It is the responsibility of the user to correctly adjust all
2364     # symlinks.  If somebody can figure out how to handle them correctly
2365     # here, feel free to add the code.
2366
2367     echo $1 > $2/COPIED
2368   fi
2369   shift; shift
2370 done
2371
2372 # Determine a target-dependent exec_prefix that the installed
2373 # gcc will search in.  Keep this list sorted by triplet, with
2374 # the *-*-osname triplets last.
2375 md_exec_prefix=
2376 case "${target}" in
2377   alpha*-*-*vms*)
2378     md_exec_prefix=/gnu/lib/gcc-lib
2379     ;;
2380   i[[34567]]86-pc-msdosdjgpp*)
2381     md_exec_prefix=/dev/env/DJDIR/bin
2382     ;;
2383   i[[34567]]86-*-sco3.2v5*)
2384     if test $with_gnu_as = yes; then
2385       md_exec_prefix=/usr/gnu/bin
2386     else
2387       md_exec_prefix=/usr/ccs/bin/elf
2388     fi
2389     ;;
2390
2391   mn10300-*-* | \
2392   powerpc-*-chorusos* | \
2393   powerpc*-*-eabi* | \
2394   powerpc*-*-sysv* | \
2395   powerpc*-*-kaos* | \
2396   s390x-ibm-tpf*)
2397     md_exec_prefix=/usr/ccs/bin
2398     ;;
2399   sparc64-*-elf*)
2400     ;;
2401   v850*-*-*)
2402     md_exec_prefix=/usr/ccs/bin
2403     ;;
2404   xtensa*-*-elf*)
2405     ;;
2406
2407   *-*-beos* | \
2408   *-*-elf* | \
2409   *-*-hpux* | \
2410   *-*-netware* | \
2411   *-*-nto-qnx* | \
2412   *-*-rtems* | \
2413   *-*-solaris2* | \
2414   *-*-sysv[[45]]* | \
2415   *-*-vxworks* | \
2416   *-wrs-windiss)
2417     md_exec_prefix=/usr/ccs/bin
2418     ;;
2419 esac
2420
2421 extra_arflags_for_target=
2422 extra_nmflags_for_target=
2423 extra_ranlibflags_for_target=
2424 target_makefile_frag=/dev/null
2425 case "${target}" in
2426   mep*-*-*)
2427     target_makefile_frag="config/mt-mep"
2428     ;;
2429   spu-*-*)
2430     target_makefile_frag="config/mt-spu"
2431     ;;
2432   mips*-sde-elf*)
2433     target_makefile_frag="config/mt-sde"
2434     ;;
2435   mipsisa*-*-elfoabi*)
2436     target_makefile_frag="config/mt-mips-elfoabi"
2437     ;;
2438   mips*-*-*linux* | mips*-*-gnu*)
2439     target_makefile_frag="config/mt-mips-gnu"
2440     ;;
2441   *-*-netware*)
2442     target_makefile_frag="config/mt-netware"
2443     ;;
2444   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2445     target_makefile_frag="config/mt-gnu"
2446     ;;
2447   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2448     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2449     # commands to handle both 32-bit and 64-bit objects.  These flags are
2450     # harmless if we're using GNU nm or ar.
2451     extra_arflags_for_target=" -X32_64"
2452     extra_nmflags_for_target=" -B -X32_64"
2453     ;;
2454   *-*-darwin[[3-9]]*)
2455     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2456     extra_ranlibflags_for_target=" -c"
2457     ;;
2458   mips*-*-pe | sh*-*-pe | *arm-wince-pe)
2459     target_makefile_frag="config/mt-wince"
2460     ;;
2461 esac
2462
2463 alphaieee_frag=/dev/null
2464 case $target in
2465   alpha*-*-*)
2466     # This just makes sure to use the -mieee option to build target libs.
2467     # This should probably be set individually by each library.
2468     alphaieee_frag="config/mt-alphaieee"
2469     ;;
2470 esac
2471
2472 # If --enable-target-optspace always use -Os instead of -O2 to build
2473 # the target libraries, similarly if it is not specified, use -Os
2474 # on selected platforms.
2475 ospace_frag=/dev/null
2476 case "${enable_target_optspace}:${target}" in
2477   yes:*)
2478     ospace_frag="config/mt-ospace"
2479     ;;
2480   :d30v-*)
2481     ospace_frag="config/mt-d30v"
2482     ;;
2483   :m32r-* | :d10v-* | :fr30-*)
2484     ospace_frag="config/mt-ospace"
2485     ;;
2486   no:* | :*)
2487     ;;
2488   *)
2489     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2490     ;;
2491 esac
2492
2493 # Default to using --with-stabs for certain targets.
2494 if test x${with_stabs} = x ; then
2495   case "${target}" in
2496   mips*-*-irix[[56]]*)
2497     ;;
2498   mips*-*-* | alpha*-*-osf*)
2499     with_stabs=yes;
2500     extra_host_args="${extra_host_args} --with-stabs"
2501     ;;
2502   esac
2503 fi
2504
2505 # hpux11 in 64bit mode has libraries in a weird place.  Arrange to find
2506 # them automatically.
2507 case "${host}" in
2508   hppa*64*-*-hpux11*)
2509     extra_host_args="$extra_host_args -x-libraries=/usr/lib/pa20_64 -x-includes=/usr/X11R6/include"
2510     ;;
2511 esac
2512
2513 # Some systems (e.g., one of the i386-aix systems the gas testers are
2514 # using) don't handle "\$" correctly, so don't use it here.
2515 tooldir='${exec_prefix}'/${target_noncanonical}
2516 build_tooldir=${tooldir}
2517
2518 # Create a .gdbinit file which runs the one in srcdir
2519 # and tells GDB to look there for source files.
2520
2521 if test -r ${srcdir}/.gdbinit ; then
2522   case ${srcdir} in
2523     .) ;;
2524     *) cat > ./.gdbinit <<EOF
2525 # ${NO_EDIT}
2526 dir ${srcdir}
2527 dir .
2528 source ${srcdir}/.gdbinit
2529 EOF
2530     ;;
2531   esac
2532 fi
2533
2534 # Make sure that the compiler is able to generate an executable.  If it
2535 # can't, we are probably in trouble.  We don't care whether we can run the
2536 # executable--we might be using a cross compiler--we only care whether it
2537 # can be created.  At this point the main configure script has set CC.
2538 we_are_ok=no
2539 echo "int main () { return 0; }" > conftest.c
2540 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2541 if test $? = 0 ; then
2542   if test -s conftest || test -s conftest.exe ; then
2543     we_are_ok=yes
2544   fi
2545 fi
2546 case $we_are_ok in
2547   no)
2548     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2549     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2550     rm -f conftest*
2551     exit 1
2552     ;;
2553 esac
2554 rm -f conftest*
2555
2556 # The Solaris /usr/ucb/cc compiler does not appear to work.
2557 case "${host}" in
2558   sparc-sun-solaris2*)
2559       CCBASE="`echo ${CC-cc} | sed 's/ .*$//'`"
2560       if test "`type $CCBASE | sed 's/^[[^/]]*//'`" = "/usr/ucb/cc" ; then
2561           could_use=
2562           test -d /opt/SUNWspro/bin && could_use="/opt/SUNWspro/bin"
2563           if test -d /opt/cygnus/bin ; then
2564               if test "$could_use" = "" ; then
2565                   could_use="/opt/cygnus/bin"
2566               else
2567                   could_use="$could_use or /opt/cygnus/bin"
2568               fi
2569           fi
2570         if test "$could_use" = "" ; then
2571             echo "Warning: compilation may fail because you're using"
2572             echo "/usr/ucb/cc.  You should change your PATH or CC "
2573             echo "variable and rerun configure."
2574         else
2575             echo "Warning: compilation may fail because you're using"
2576             echo "/usr/ucb/cc, when you should use the C compiler from"
2577             echo "$could_use.  You should change your"
2578             echo "PATH or CC variable and rerun configure."
2579         fi
2580       fi
2581   ;;
2582 esac
2583
2584 # Decide which environment variable is used to find dynamic libraries.
2585 case "${host}" in
2586   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2587   *-*-darwin* | *-*-rhapsody* ) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2588   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2589   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2590 esac
2591
2592 # On systems where the dynamic library environment variable is PATH,
2593 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2594 # built executables to PATH.
2595 if test "$RPATH_ENVVAR" = PATH; then
2596   GCC_SHLIB_SUBDIR=/shlib
2597 else
2598   GCC_SHLIB_SUBDIR=
2599 fi
2600
2601 # Record target_configdirs and the configure arguments for target and
2602 # build configuration in Makefile.
2603 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2604 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2605
2606 # If we are building libgomp, bootstrap it.
2607 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2608   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2609 fi
2610
2611 # Determine whether gdb needs tk/tcl or not.
2612 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2613 # and in that case we want gdb to be built without tk.  Ugh!
2614 # In fact I believe gdb is the *only* package directly dependent on tk,
2615 # so we should be able to put the 'maybe's in unconditionally and
2616 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2617 # 100% sure that that's safe though.
2618
2619 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2620 case "$enable_gdbtk" in
2621   no)
2622     GDB_TK="" ;;
2623   yes)
2624     GDB_TK="${gdb_tk}" ;;
2625   *)
2626     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2627     # distro.  Eventually someone will fix this and move Insight, nee
2628     # gdbtk to a separate directory.
2629     if test -d ${srcdir}/gdb/gdbtk ; then
2630       GDB_TK="${gdb_tk}"
2631     else
2632       GDB_TK=""
2633     fi
2634     ;;
2635 esac
2636 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2637 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2638
2639 # Strip out unwanted targets.
2640
2641 # While at that, we remove Makefiles if we were started for recursive
2642 # configuration, so that the top-level Makefile reconfigures them,
2643 # like we used to do when configure itself was recursive.
2644
2645 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2646 # but now we're fixing up the Makefile ourselves with the additional
2647 # commands passed to AC_CONFIG_FILES.  Use separate variables
2648 # extrasub-{build,host,target} not because there is any reason to split
2649 # the substitutions up that way, but only to remain below the limit of
2650 # 99 commands in a script, for HP-UX sed.
2651 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2652
2653 AC_ARG_ENABLE([bootstrap],
2654 [AS_HELP_STRING([--enable-bootstrap],
2655                 [enable bootstrapping @<:@yes if native build@:>@])],,
2656 enable_bootstrap=default)
2657
2658 # Issue errors and warnings for invalid/strange bootstrap combinations.
2659 case "$configdirs" in
2660   *gcc*) have_compiler=yes ;;
2661   *) have_compiler=no ;;
2662 esac
2663
2664 case "$have_compiler:$host:$target:$enable_bootstrap" in
2665   *:*:*:no) ;;
2666
2667   # Default behavior.  Enable bootstrap if we have a compiler
2668   # and we are in a native configuration.
2669   yes:$build:$build:default)
2670     enable_bootstrap=yes ;;
2671
2672   *:*:*:default)
2673     enable_bootstrap=no ;;
2674
2675   # We have a compiler and we are in a native configuration, bootstrap is ok
2676   yes:$build:$build:yes)
2677     ;;
2678
2679   # Other configurations, but we have a compiler.  Assume the user knows
2680   # what he's doing.
2681   yes:*:*:yes)
2682     AC_MSG_WARN([trying to bootstrap a cross compiler])
2683     ;;
2684
2685   # No compiler: if they passed --enable-bootstrap explicitly, fail
2686   no:*:*:yes)
2687     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2688
2689   # Fail if wrong command line
2690   *)
2691     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2692     ;;
2693 esac
2694
2695 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2696   *,c++,*:yes:yes) ;;
2697   *:yes:yes)
2698     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2699     ;;
2700 esac
2701
2702 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2703   yes:yes:*\ gold\ *:*,c++,*) ;;
2704   yes:yes:*\ gold\ *:*)
2705     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2706     ;;
2707 esac
2708
2709 # Adjust the toplevel makefile according to whether bootstrap was selected.
2710 case $enable_bootstrap in
2711   yes)
2712     bootstrap_suffix=bootstrap
2713     BUILD_CONFIG=bootstrap-debug
2714     ;;
2715   no)
2716     bootstrap_suffix=no-bootstrap
2717     BUILD_CONFIG=
2718     ;;
2719 esac
2720
2721 AC_MSG_CHECKING(for default BUILD_CONFIG)
2722
2723 AC_ARG_WITH([build-config],
2724   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2725                   [use config/NAME.mk build configuration])],
2726   [case $with_build_config in
2727    yes) with_build_config= ;;
2728    no) with_build_config= BUILD_CONFIG= ;;
2729    esac])
2730
2731 if test "x${with_build_config}" != x; then
2732   BUILD_CONFIG=$with_build_config
2733 else
2734   case $BUILD_CONFIG in
2735   bootstrap-debug)
2736     if echo "int f (void) { return 0; }" > conftest.c &&
2737        ${CC} -c conftest.c &&
2738        mv conftest.o conftest.o.g0 &&
2739        ${CC} -c -g conftest.c &&
2740        mv conftest.o conftest.o.g &&
2741        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2742       :
2743     else
2744       BUILD_CONFIG=
2745     fi
2746     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2747     ;;
2748   esac
2749 fi
2750 AC_MSG_RESULT($BUILD_CONFIG)
2751 AC_SUBST(BUILD_CONFIG)
2752
2753 extrasub_build=
2754 for module in ${build_configdirs} ; do
2755   if test -z "${no_recursion}" \
2756      && test -f ${build_subdir}/${module}/Makefile; then
2757     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2758     rm -f ${build_subdir}/${module}/Makefile
2759   fi
2760   extrasub_build="$extrasub_build
2761 /^@if build-$module\$/d
2762 /^@endif build-$module\$/d
2763 /^@if build-$module-$bootstrap_suffix\$/d
2764 /^@endif build-$module-$bootstrap_suffix\$/d"
2765 done
2766 extrasub_host=
2767 for module in ${configdirs} ; do
2768   if test -z "${no_recursion}"; then
2769     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2770       if test -f ${file}; then
2771         echo 1>&2 "*** removing ${file} to force reconfigure"
2772         rm -f ${file}
2773       fi
2774     done
2775   fi
2776   extrasub_host="$extrasub_host
2777 /^@if $module\$/d
2778 /^@endif $module\$/d
2779 /^@if $module-$bootstrap_suffix\$/d
2780 /^@endif $module-$bootstrap_suffix\$/d"
2781 done
2782 extrasub_target=
2783 for module in ${target_configdirs} ; do
2784   if test -z "${no_recursion}" \
2785      && test -f ${target_subdir}/${module}/Makefile; then
2786     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2787     rm -f ${target_subdir}/${module}/Makefile
2788   fi
2789
2790   # We only bootstrap target libraries listed in bootstrap_target_libs.
2791   case $bootstrap_target_libs in
2792     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2793     *) target_bootstrap_suffix=no-bootstrap ;;
2794   esac
2795
2796   extrasub_target="$extrasub_target
2797 /^@if target-$module\$/d
2798 /^@endif target-$module\$/d
2799 /^@if target-$module-$target_bootstrap_suffix\$/d
2800 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2801 done
2802
2803 # Do the final fixup along with target modules.
2804 extrasub_target="$extrasub_target
2805 /^@if /,/^@endif /d"
2806
2807 # Create the serialization dependencies.  This uses a temporary file.
2808
2809 AC_ARG_ENABLE([serial-configure],
2810 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2811                 [force sequential configuration of
2812                  sub-packages for the host, target or build
2813                  machine, or all sub-packages])])
2814
2815 case ${enable_serial_configure} in
2816   yes)
2817     enable_serial_build_configure=yes
2818     enable_serial_host_configure=yes
2819     enable_serial_target_configure=yes
2820     ;;
2821 esac
2822
2823 # These force 'configure's to be done one at a time, to avoid problems
2824 # with contention over a shared config.cache.
2825 rm -f serdep.tmp
2826 echo '# serdep.tmp' > serdep.tmp
2827 olditem=
2828 test "x${enable_serial_build_configure}" = xyes &&
2829 for item in ${build_configdirs} ; do
2830   case ${olditem} in
2831     "") ;;
2832     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2833   esac
2834   olditem=${item}
2835 done
2836 olditem=
2837 test "x${enable_serial_host_configure}" = xyes &&
2838 for item in ${configdirs} ; do
2839   case ${olditem} in
2840     "") ;;
2841     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2842   esac
2843   olditem=${item}
2844 done
2845 olditem=
2846 test "x${enable_serial_target_configure}" = xyes &&
2847 for item in ${target_configdirs} ; do
2848   case ${olditem} in
2849     "") ;;
2850     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2851   esac
2852   olditem=${item}
2853 done
2854 serialization_dependencies=serdep.tmp
2855 AC_SUBST_FILE(serialization_dependencies)
2856
2857 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2858 # target, nonopt, and variable assignments.  These are the ones we
2859 # might not want to pass down to subconfigures.  The exception being
2860 # --cache-file=/dev/null, which is used to turn off the use of cache
2861 # files altogether, and which should be passed on to subconfigures.
2862 # Also strip program-prefix, program-suffix, and program-transform-name,
2863 # so that we can pass down a consistent program-transform-name.
2864 baseargs=
2865 tbaseargs=
2866 keep_next=no
2867 skip_next=no
2868 eval "set -- $ac_configure_args"
2869 for ac_arg
2870 do
2871   if test X"$skip_next" = X"yes"; then
2872     skip_next=no
2873     continue
2874   fi
2875   if test X"$keep_next" = X"yes"; then
2876     case $ac_arg in
2877       *\'*)
2878         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2879     esac
2880     baseargs="$baseargs '$ac_arg'"
2881     tbaseargs="$tbaseargs '$ac_arg'"
2882     keep_next=no
2883     continue
2884   fi
2885
2886   # Handle separated arguments.  Based on the logic generated by
2887   # autoconf 2.59.
2888   case $ac_arg in
2889     *=* | --config-cache | -C | -disable-* | --disable-* \
2890       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2891       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2892       | -with-* | --with-* | -without-* | --without-* | --x)
2893       separate_arg=no
2894       ;;
2895     -*)
2896       separate_arg=yes
2897       ;;
2898     *)
2899       separate_arg=no
2900       ;;
2901   esac
2902
2903   skip_targ=no
2904   case $ac_arg in
2905 changequote(,)
2906   --with-* | --without-*)
2907     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2908
2909     case $libopt in
2910     *[-_]include)
2911       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2912       ;;
2913     *[-_]lib)
2914       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2915       ;;
2916     *)
2917       lib=$libopt
2918       ;;
2919     esac
2920 changequote([,])
2921
2922     case $lib in
2923     mpc | mpfr | gmp | ppl | cloog)
2924       # If we're processing --with-$lib, --with-$lib-include or
2925       # --with-$lib-lib, for one of the libs above, and target is
2926       # different from host, don't pass the current argument to any
2927       # target library's configure.
2928       if test x$is_cross_compiler = xyes; then
2929         skip_targ=yes
2930       fi
2931       ;;
2932     esac
2933     ;;
2934   esac
2935
2936   case "$ac_arg" in
2937     --cache-file=/dev/null | \
2938     -cache-file=/dev/null )
2939       # Handled here to avoid the test to skip args below.
2940       baseargs="$baseargs '$ac_arg'"
2941       tbaseargs="$tbaseargs '$ac_arg'"
2942       # Assert: $separate_arg should always be no.
2943       keep_next=$separate_arg
2944       ;;
2945     --no*)
2946       continue
2947       ;;
2948     --c* | \
2949     --sr* | \
2950     --ho* | \
2951     --bu* | \
2952     --t* | \
2953     --program-* | \
2954     -cache_file* | \
2955     -srcdir* | \
2956     -host* | \
2957     -build* | \
2958     -target* | \
2959     -program-prefix* | \
2960     -program-suffix* | \
2961     -program-transform-name* )
2962       skip_next=$separate_arg
2963       continue
2964       ;;
2965     -*)
2966       # An option.  Add it.
2967       case $ac_arg in
2968         *\'*)
2969           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2970       esac
2971       baseargs="$baseargs '$ac_arg'"
2972       if test X"$skip_targ" = Xno; then
2973         tbaseargs="$tbaseargs '$ac_arg'"
2974       fi
2975       keep_next=$separate_arg
2976       ;;
2977     *)
2978       # Either a variable assignment, or a nonopt (triplet).  Don't
2979       # pass it down; let the Makefile handle this.
2980       continue
2981       ;;
2982   esac
2983 done
2984 # Remove the initial space we just introduced and, as these will be
2985 # expanded by make, quote '$'.
2986 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2987
2988 # Add in --program-transform-name, after --program-prefix and
2989 # --program-suffix have been applied to it.  Autoconf has already
2990 # doubled dollar signs and backslashes in program_transform_name; we want
2991 # the backslashes un-doubled, and then the entire thing wrapped in single
2992 # quotes, because this will be expanded first by make and then by the shell.
2993 # Also, because we want to override the logic in subdir configure scripts to
2994 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2995 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2996 ${program_transform_name}
2997 EOF_SED
2998 gcc_transform_name=`cat conftestsed.out`
2999 rm -f conftestsed.out
3000 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3001 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3002 if test "$silent" = yes; then
3003   baseargs="$baseargs --silent"
3004   tbaseargs="$tbaseargs --silent"
3005 fi
3006 baseargs="$baseargs --disable-option-checking"
3007 tbaseargs="$tbaseargs --disable-option-checking"
3008
3009 # Record and document user additions to sub configure arguments.
3010 AC_ARG_VAR([build_configargs],
3011            [additional configure arguments for build directories])
3012 AC_ARG_VAR([host_configargs],
3013            [additional configure arguments for host directories])
3014 AC_ARG_VAR([target_configargs],
3015            [additional configure arguments for target directories])
3016
3017 # For the build-side libraries, we just need to pretend we're native,
3018 # and not use the same cache file.  Multilibs are neither needed nor
3019 # desired.
3020 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
3021
3022 # For host modules, accept cache file option, or specification as blank.
3023 case "${cache_file}" in
3024 "") # empty
3025   cache_file_option="" ;;
3026 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3027   cache_file_option="--cache-file=${cache_file}" ;;
3028 *) # relative path
3029   cache_file_option="--cache-file=../${cache_file}" ;;
3030 esac
3031
3032 # Host dirs don't like to share a cache file either, horribly enough.
3033 # This seems to be due to autoconf 2.5x stupidity.
3034 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3035
3036 target_configargs="$target_configargs ${tbaseargs}"
3037
3038 # Passing a --with-cross-host argument lets the target libraries know
3039 # whether they are being built with a cross-compiler or being built
3040 # native.  However, it would be better to use other mechanisms to make the
3041 # sorts of decisions they want to make on this basis.  Please consider
3042 # this option to be deprecated.  FIXME.
3043 if test x${is_cross_compiler} = xyes ; then
3044   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3045 fi
3046
3047 # Default to --enable-multilib.
3048 if test x${enable_multilib} = x ; then
3049   target_configargs="--enable-multilib ${target_configargs}"
3050 fi
3051
3052 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3053 # changed from the earlier setting of with_newlib.
3054 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3055   target_configargs="--with-newlib ${target_configargs}"
3056 fi
3057
3058 # Different target subdirs use different values of certain variables
3059 # (notably CXX).  Worse, multilibs use *lots* of different values.
3060 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3061 # it doesn't automatically accept command-line overrides of them.
3062 # This means it's not safe for target subdirs to share a cache file,
3063 # which is disgusting, but there you have it.  Hopefully this can be
3064 # fixed in future.  It's still worthwhile to use a cache file for each
3065 # directory.  I think.
3066
3067 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3068 # We need to pass --target, as newer autoconf's requires consistency
3069 # for target_alias and gcc doesn't manage it consistently.
3070 target_configargs="--cache-file=./config.cache ${target_configargs}"
3071
3072 FLAGS_FOR_TARGET=
3073 case " $target_configdirs " in
3074  *" newlib "*)
3075   case " $target_configargs " in
3076   *" --with-newlib "*)
3077    case "$target" in
3078     *-cygwin*)
3079       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
3080       ;;
3081    esac
3082
3083    # If we're not building GCC, don't discard standard headers.
3084    if test -d ${srcdir}/gcc; then
3085      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3086
3087      if test "${build}" != "${host}"; then
3088        # On Canadian crosses, CC_FOR_TARGET will have already been set
3089        # by `configure', so we won't have an opportunity to add -Bgcc/
3090        # to it.  This is right: we don't want to search that directory
3091        # for binaries, but we want the header files in there, so add
3092        # them explicitly.
3093        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3094
3095        # Someone might think of using the pre-installed headers on
3096        # Canadian crosses, in case the installed compiler is not fully
3097        # compatible with the compiler being built.  In this case, it
3098        # would be better to flag an error than risking having
3099        # incompatible object files being constructed.  We can't
3100        # guarantee that an error will be flagged, but let's hope the
3101        # compiler will do it, when presented with incompatible header
3102        # files.
3103      fi
3104    fi
3105
3106    case "${target}-${is_cross_compiler}" in
3107    i[[3456789]]86-*-linux*-no)
3108       # Here host == target, so we don't need to build gcc,
3109       # so we don't want to discard standard headers.
3110       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3111       ;;
3112    *)
3113       # If we're building newlib, use its generic headers last, but search
3114       # for any libc-related directories first (so make it the last -B
3115       # switch).
3116       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3117
3118       # If we're building libgloss, find the startup file, simulator library
3119       # and linker script.
3120       case " $target_configdirs " in
3121         *" libgloss "*)
3122         # Look for startup file, simulator library and maybe linker script.
3123         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3124         # Look for libnosys.a in case the target needs it.
3125         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3126         # Most targets have the linker script in the source directory.
3127         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3128         ;;
3129       esac
3130       ;;
3131    esac
3132    ;;
3133   esac
3134   ;;
3135 esac
3136
3137 case "$target" in
3138   x86_64-*mingw* | *-w64-mingw*)
3139   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3140   # however, use a symlink named 'mingw' in ${prefix} .
3141     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3142     ;;
3143   *-mingw*)
3144   # MinGW can't be handled as Cygwin above since it does not use newlib.
3145     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3146     ;;
3147 esac
3148
3149 # Allow the user to override the flags for
3150 # our build compiler if desired.
3151 if test x"${build}" = x"${host}" ; then
3152   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3153   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3154   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3155 fi
3156
3157 # On Canadian crosses, we'll be searching the right directories for
3158 # the previously-installed cross compiler, so don't bother to add
3159 # flags for directories within the install tree of the compiler
3160 # being built; programs in there won't even run.
3161 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3162   # Search for pre-installed headers if nothing else fits.
3163   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3164 fi
3165
3166 if test "x${use_gnu_ld}" = x &&
3167    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3168   # Arrange for us to find uninstalled linker scripts.
3169   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3170 fi
3171
3172 # Search for other target-specific linker scripts and such.
3173 case "${target}" in
3174   mep*)
3175     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3176     ;;
3177 esac
3178
3179 # Makefile fragments.
3180 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3181 do
3182   eval fragval=\$$frag
3183   if test $fragval != /dev/null; then
3184     eval $frag=${srcdir}/$fragval
3185   fi
3186 done
3187 AC_SUBST_FILE(host_makefile_frag)
3188 AC_SUBST_FILE(target_makefile_frag)
3189 AC_SUBST_FILE(alphaieee_frag)
3190 AC_SUBST_FILE(ospace_frag)
3191
3192 # Miscellanea: directories, flags, etc.
3193 AC_SUBST(RPATH_ENVVAR)
3194 AC_SUBST(GCC_SHLIB_SUBDIR)
3195 AC_SUBST(tooldir)
3196 AC_SUBST(build_tooldir)
3197 AC_SUBST(CONFIGURE_GDB_TK)
3198 AC_SUBST(GDB_TK)
3199 AC_SUBST(INSTALL_GDB_TK)
3200
3201 # Build module lists & subconfigure args.
3202 AC_SUBST(build_configargs)
3203 AC_SUBST(build_configdirs)
3204
3205 # Host module lists & subconfigure args.
3206 AC_SUBST(host_configargs)
3207 AC_SUBST(configdirs)
3208 AC_SUBST(target_configdirs)
3209
3210 # Target module lists & subconfigure args.
3211 AC_SUBST(target_configargs)
3212
3213
3214 # Build tools.
3215 AC_SUBST(AR_FOR_BUILD)
3216 AC_SUBST(AS_FOR_BUILD)
3217 AC_SUBST(CC_FOR_BUILD)
3218 AC_SUBST(CFLAGS_FOR_BUILD)
3219 AC_SUBST(CXXFLAGS_FOR_BUILD)
3220 AC_SUBST(CXX_FOR_BUILD)
3221 AC_SUBST(DLLTOOL_FOR_BUILD)
3222 AC_SUBST(GCJ_FOR_BUILD)
3223 AC_SUBST(GFORTRAN_FOR_BUILD)
3224 AC_SUBST(GOC_FOR_BUILD)
3225 AC_SUBST(LDFLAGS_FOR_BUILD)
3226 AC_SUBST(LD_FOR_BUILD)
3227 AC_SUBST(NM_FOR_BUILD)
3228 AC_SUBST(RANLIB_FOR_BUILD)
3229 AC_SUBST(WINDMC_FOR_BUILD)
3230 AC_SUBST(WINDRES_FOR_BUILD)
3231 AC_SUBST(config_shell)
3232
3233 # Generate default definitions for YACC, M4, LEX and other programs that run
3234 # on the build machine.  These are used if the Makefile can't locate these
3235 # programs in objdir.
3236 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3237
3238 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3239 case " $build_configdirs " in
3240   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3241   *" byacc "*) YACC='$$r/$(BUILD_SUBDIR)/byacc/byacc' ;;
3242 esac
3243
3244 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3245 case " $build_configdirs " in
3246   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3247 esac
3248
3249 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3250 case " $build_configdirs " in
3251   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3252 esac
3253
3254 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3255 case " $build_configdirs " in
3256   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3257   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3258 esac
3259
3260 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3261 case " $build_configdirs " in
3262   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3263 esac
3264
3265 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3266 case " $build_configdirs " in
3267   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3268   *)
3269 changequote(,)
3270     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3271     # higher, else we use the "missing" dummy.
3272     if ${MAKEINFO} --version \
3273        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3274       :
3275     else
3276       MAKEINFO="$MISSING makeinfo"
3277     fi
3278     ;;
3279 changequote([,])
3280 esac
3281
3282 # FIXME: expect and dejagnu may become build tools?
3283
3284 AC_CHECK_PROGS(EXPECT, expect, expect)
3285 case " $configdirs " in
3286   *" expect "*)
3287     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3288     ;;
3289 esac
3290
3291 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3292 case " $configdirs " in
3293   *" dejagnu "*)
3294     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3295     ;;
3296 esac
3297
3298
3299 # Host tools.
3300 NCN_STRICT_CHECK_TOOLS(AR, ar)
3301 NCN_STRICT_CHECK_TOOLS(AS, as)
3302 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3303 NCN_STRICT_CHECK_TOOLS(LD, ld)
3304 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3305 NCN_STRICT_CHECK_TOOLS(NM, nm)
3306 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3307 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3308 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3309 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3310 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3311 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3312 AC_SUBST(CC)
3313 AC_SUBST(CXX)
3314 AC_SUBST(CFLAGS)
3315 AC_SUBST(CXXFLAGS)
3316
3317 # Target tools.
3318 AC_ARG_WITH([build-time-tools],
3319   [AS_HELP_STRING([--with-build-time-tools=PATH],
3320                   [use given path to find target tools during the build])],
3321   [case x"$withval" in
3322      x/*) ;;
3323      *)
3324        with_build_time_tools=
3325        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3326        ;;
3327    esac],
3328   [with_build_time_tools=])
3329
3330 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3331 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3332 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3333 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3334 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3335 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3336
3337 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3338 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3339 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3340 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3341 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3342 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3343 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3344 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3345 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3346 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3347 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3348
3349 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3350
3351 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3352 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3353 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3354 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3355 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3356                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3357                 c++)
3358 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3359                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3360                 c++)
3361 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3362 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3363 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3364                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3365 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3366                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3367 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3368                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3369 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3370 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3371 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3372 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3373 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3374 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3375 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3376 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3377
3378 AC_SUBST(FLAGS_FOR_TARGET)
3379 AC_SUBST(RAW_CXX_FOR_TARGET)
3380
3381 # Certain tools may need extra flags.
3382 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3383 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3384 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3385
3386 # When building target libraries, except in a Canadian cross, we use
3387 # the same toolchain as the compiler we just built.
3388 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3389 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3390 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3391 if test $host = $build; then
3392   case " $configdirs " in
3393     *" gcc "*)
3394       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3395       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3396       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3397       ;;
3398   esac
3399 fi
3400
3401 AC_SUBST(COMPILER_AS_FOR_TARGET)
3402 AC_SUBST(COMPILER_LD_FOR_TARGET)
3403 AC_SUBST(COMPILER_NM_FOR_TARGET)
3404
3405 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3406 AC_ARG_ENABLE(maintainer-mode,
3407 [AS_HELP_STRING([--enable-maintainer-mode],
3408                 [enable make rules and dependencies not useful
3409                  (and sometimes confusing) to the casual installer])],
3410       USE_MAINTAINER_MODE=$enableval,
3411       USE_MAINTAINER_MODE=no)
3412 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3413 AC_SUBST(MAINTAINER_MODE_TRUE)
3414 AC_SUBST(MAINTAINER_MODE_FALSE)
3415 if test "$USE_MAINTAINER_MODE" = yes; then
3416   MAINTAINER_MODE_TRUE=
3417   MAINTAINER_MODE_FALSE='#'
3418 else
3419   MAINTAINER_MODE_TRUE='#'
3420   MAINTAINER_MODE_FALSE=
3421 fi
3422 MAINT=$MAINTAINER_MODE_TRUE
3423 AC_SUBST(MAINT)dnl
3424
3425 # ---------------------
3426 # GCC bootstrap support
3427 # ---------------------
3428
3429 # Stage specific cflags for build.
3430 stage1_cflags="-g"
3431 case $build in
3432   vax-*-*)
3433     case ${GCC} in
3434       yes) stage1_cflags="-g -Wa,-J" ;;
3435       *) stage1_cflags="-g -J" ;;
3436     esac ;;
3437 esac
3438
3439 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3440 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3441   saved_CFLAGS="$CFLAGS"
3442
3443   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3444   CFLAGS="$CFLAGS -fkeep-inline-functions"
3445   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3446   AC_TRY_COMPILE([
3447 #if (__GNUC__ < 3) \
3448     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3449                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3450 #error http://gcc.gnu.org/PR29382
3451 #endif
3452     ],,
3453     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3454     [AC_MSG_RESULT([no])])
3455
3456   CFLAGS="$saved_CFLAGS"
3457 fi
3458
3459 AC_SUBST(stage1_cflags)
3460
3461 # Enable --enable-checking in stage1 of the compiler.
3462 AC_ARG_ENABLE(stage1-checking,
3463 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3464                 [choose additional checking for stage1 of the compiler])],
3465 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3466 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3467   stage1_checking=--enable-checking=yes,types
3468 else
3469   stage1_checking=--enable-checking=$enable_checking,types
3470 fi])
3471 AC_SUBST(stage1_checking)
3472
3473 # Enable -Werror in bootstrap stage2 and later.
3474 AC_ARG_ENABLE(werror,
3475 [AS_HELP_STRING([--enable-werror],
3476                 [enable -Werror in bootstrap stage2 and later])], [],
3477 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3478   enable_werror=yes
3479 else
3480   enable_werror=no
3481 fi])
3482 case ${enable_werror} in
3483   yes) stage2_werror_flag="--enable-werror-always" ;;
3484   *) stage2_werror_flag="" ;;
3485 esac
3486 AC_SUBST(stage2_werror_flag)
3487
3488 # Specify what files to not compare during bootstrap.
3489
3490 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3491 case "$target" in
3492   hppa*64*-*-hpux*) ;;
3493   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3494 esac
3495 case " $configdirs " in
3496 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3497 esac
3498 AC_SUBST(compare_exclusions)
3499
3500 AC_CONFIG_FILES([Makefile],
3501   [sed "$extrasub_build" Makefile |
3502    sed "$extrasub_host" |
3503    sed "$extrasub_target" > mf$$
3504    mv -f mf$$ Makefile],
3505   [extrasub_build="$extrasub_build"
3506    extrasub_host="$extrasub_host"
3507    extrasub_target="$extrasub_target"])
3508 AC_OUTPUT