configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation,
   3 #   Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25
  26 AC_INIT(move-if-change)
  27 AC_PREREQ(2.59)
  28
  29 progname=$0
  30 # if PWD already has a value, it is probably wrong.
  31 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  32
  33 # Export original configure arguments for use by sub-configures.
  34 # Quote arguments with shell meta charatcers.
  35 TOPLEVEL_CONFIGURE_ARGUMENTS=
  36 set -- "$progname" "$@"
  37 for ac_arg
  38 do
  39   case "$ac_arg" in
  40   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  41     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  42     # if the argument is of the form -foo=baz, quote the baz part only
  43     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  44   *) ;;
  45   esac
  46   # Add the quoted argument to the list.
  47   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  48 done
  49 if test "$silent" = yes; then
  50   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  51 fi
  52 # Remove the initial space we just introduced and, as these will be
  53 # expanded by make, quote '$'.
  54 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  55 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  56
  57 # Find the build, host, and target systems.
  58 ACX_NONCANONICAL_BUILD
  59 ACX_NONCANONICAL_HOST
  60 ACX_NONCANONICAL_TARGET
  61
  62 dnl Autoconf 2.5x and later will set a default program prefix if
  63 dnl --target was used, even if it was the same as --host.  Disable
  64 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  65 dnl to take effect.
  66 test "$host_noncanonical" = "$target_noncanonical" &&
  67   test "$program_prefix$program_suffix$program_transform_name" = \
  68     NONENONEs,x,x, &&
  69   program_transform_name=s,y,y,
  70
  71 AC_CANONICAL_SYSTEM
  72 AC_ARG_PROGRAM
  73
  74 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  75 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  76
  77 # Get 'install' or 'install-sh' and its variants.
  78 AC_PROG_INSTALL
  79 ACX_PROG_LN
  80 AC_PROG_LN_S
  81
  82 ### we might need to use some other shell than /bin/sh for running subshells
  83 ### If we are on Windows, search for the shell.  This will permit people
  84 ### to not have /bin/sh, but to be able to see /SOME/PATH/sh configure
  85 ### without also having to set CONFIG_SHELL.  This code will work when
  86 ### using bash, which sets OSTYPE.
  87 case "${OSTYPE}" in
  88 *win32*)
  89   if test x${CONFIG_SHELL} = x ; then
  90     if test ! -f /bin/sh ; then
  91       if test x${SHELL} != x && test -f ${SHELL} ; then
  92         CONFIG_SHELL=${SHELL}
  93         export CONFIG_SHELL
  94       else
  95         for prog in sh sh.exe bash bash.exe; do
  96           IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
  97           for dir in $PATH; do
  98             test -z "$dir" && dir=.
  99             if test -f $dir/$prog; then
 100               CONFIG_SHELL=$dir/$prog
 101               export CONFIG_SHELL
 102               break
 103             fi
 104           done
 105           IFS="$save_ifs"
 106           test -n "${CONFIG_SHELL}" && break
 107         done
 108       fi
 109     fi
 110   fi
 111   ;;
 112 esac
 113
 114 config_shell=${CONFIG_SHELL-/bin/sh}
 115
 116 moveifchange=${srcdir}/move-if-change
 117
 118 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
 119
 120 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
 121 # a relative path.
 122 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 123   INSTALL="${srcpwd}/install-sh -c"
 124 fi
 125
 126 # Set srcdir to "." if that's what it is.
 127 # This is important for multilib support.
 128 pwd=`${PWDCMD-pwd}`
 129 if test "${pwd}" = "${srcpwd}" ; then
 130   srcdir=.
 131 fi
 132
 133 topsrcdir=$srcpwd
 134
 135 extra_host_args=
 136
 137 ### To add a new directory to the tree, first choose whether it is a target
 138 ### or a host dependent tool.  Then put it into the appropriate list
 139 ### (library or tools, host or target), doing a dependency sort.
 140
 141 # Subdirs will be configured in the order listed in build_configdirs,
 142 # configdirs, or target_configdirs; see the serialization section below.
 143
 144 # Dependency sorting is only needed when *configuration* must be done in
 145 # a particular order.  In all cases a dependency should be specified in
 146 # the Makefile, whether or not it's implicitly specified here.
 147
 148 # Double entries in build_configdirs, configdirs, or target_configdirs may
 149 # cause circular dependencies and break everything horribly.
 150
 151 # these library is used by various programs built for the build
 152 # environment
 153 #
 154 build_libs="build-libiberty"
 155
 156 # these tools are built for the build environment
 157 build_tools="build-texinfo build-byacc build-flex build-bison build-m4 build-fixincludes"
 158
 159 # these libraries are used by various programs built for the host environment
 160 #
 161 host_libs="intl mmalloc libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr ppl cloog"
 162
 163 # these tools are built for the host environment
 164 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 165 # know that we are building the simulator.
 166 # binutils, gas and ld appear in that order because it makes sense to run
 167 # "make check" in that particular order.
 168 # If --enable-gold is used, "gold" will replace "ld".
 169 host_tools="texinfo byacc flex bison binutils gas ld fixincludes gcc sid sim gdb make patch prms send-pr gprof etc expect dejagnu ash bash bzip2 m4 autoconf automake libtool diff rcs fileutils shellutils time textutils wdiff find uudecode hello tar gzip indent recode release sed utils guile perl gawk findutils gettext zip fastjar gnattools"
 170
 171 # libgcj represents the runtime libraries only used by gcj.
 172 libgcj="target-libffi \
 173         target-zlib \
 174         target-qthreads \
 175         target-libjava"
 176
 177 # these libraries are built for the target environment, and are built after
 178 # the host libraries and the host tools (which may be a cross compiler)
 179 #
 180 target_libraries="target-libgcc \
 181                 target-libiberty \
 182                 target-libgloss \
 183                 target-newlib \
 184                 target-libgomp \
 185                 target-libstdc++-v3 \
 186                 target-libmudflap \
 187                 target-libssp \
 188                 target-libgfortran \
 189                 target-boehm-gc \
 190                 ${libgcj} \
 191                 target-libobjc \
 192                 target-libada"
 193
 194 # these tools are built using the target libraries, and are intended to
 195 # run only in the target environment
 196 #
 197 # note: any program that *uses* libraries that are in the "target_libraries"
 198 # list belongs in this list.  those programs are also very likely
 199 # candidates for the "native_only" list which follows
 200 #
 201 target_tools="target-examples target-groff target-gperf target-rda"
 202
 203 ################################################################################
 204
 205 ## All tools belong in one of the four categories, and are assigned above
 206 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 207 ## is important because configure will choke if they ever get through.
 208 ## ${configdirs} is directories we build using the host tools.
 209 ## ${target_configdirs} is directories we build using the target tools.
 210 configdirs=`echo ${host_libs} ${host_tools}`
 211 target_configdirs=`echo ${target_libraries} ${target_tools}`
 212 build_configdirs=`echo ${build_libs} ${build_tools}`
 213
 214 m4_divert_text([PARSE_ARGS],
 215 [ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 216 ])
 217
 218 ################################################################################
 219
 220 srcname="gnu development package"
 221
 222 # This gets set non-empty for some net releases of packages.
 223 appdirs=""
 224
 225 # Define is_cross_compiler to save on calls to 'test'.
 226 is_cross_compiler=
 227 if test x"${host}" = x"${target}" ; then
 228   is_cross_compiler=no
 229 else
 230   is_cross_compiler=yes
 231 fi
 232
 233 # Find the build and target subdir names.
 234 GCC_TOPLEV_SUBDIRS
 235
 236 # Skipdirs are removed silently.
 237 skipdirs=
 238 # Noconfigdirs are removed loudly.
 239 noconfigdirs=""
 240
 241 use_gnu_ld=
 242 # Make sure we don't let GNU ld be added if we didn't want it.
 243 if test x$with_gnu_ld = xno ; then
 244   use_gnu_ld=no
 245   noconfigdirs="$noconfigdirs ld gold"
 246 fi
 247
 248 use_gnu_as=
 249 # Make sure we don't let GNU as be added if we didn't want it.
 250 if test x$with_gnu_as = xno ; then
 251   use_gnu_as=no
 252   noconfigdirs="$noconfigdirs gas"
 253 fi
 254
 255 # some tools are so dependent upon X11 that if we're not building with X,
 256 # it's not even worth trying to configure, much less build, that tool.
 257
 258 case ${with_x} in
 259   yes | "") ;; # the default value for this tree is that X11 is available
 260   no)
 261     skipdirs="${skipdirs} tk itcl libgui"
 262     # We won't be able to build gdbtk without X.
 263     enable_gdbtk=no
 264     ;;
 265   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 266 esac
 267
 268 # Some tools are only suitable for building in a "native" situation.
 269 # Remove these if host!=target.
 270 native_only="autoconf automake libtool fileutils find gawk gettext gzip hello indent m4 rcs recode sed shellutils tar textutils uudecode wdiff target-groff guile perl time ash bash bzip2 prms gnuserv target-gperf"
 271
 272 # Similarly, some are only suitable for cross toolchains.
 273 # Remove these if host=target.
 274 cross_only="target-libgloss target-newlib target-opcodes"
 275
 276 case $is_cross_compiler in
 277   no) skipdirs="${skipdirs} ${cross_only}" ;;
 278   yes) skipdirs="${skipdirs} ${native_only}" ;;
 279 esac
 280
 281 # If both --with-headers and --with-libs are specified, default to
 282 # --without-newlib.
 283 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 284    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 285   if test x"${with_newlib}" = x ; then
 286     with_newlib=no
 287   fi
 288 fi
 289
 290 # Recognize --with-newlib/--without-newlib.
 291 case ${with_newlib} in
 292   no) skipdirs="${skipdirs} target-newlib" ;;
 293   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 294 esac
 295
 296 # Handle --enable-gold.
 297
 298 AC_ARG_ENABLE(gold,
 299 [  --enable-gold           use gold instead of ld],
 300 ENABLE_GOLD=$enableval,
 301 ENABLE_GOLD=no)
 302 if test "${ENABLE_GOLD}" = "yes"; then
 303   # Check for ELF target.
 304   is_elf=no
 305   case "${target}" in
 306     *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 307     | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 308     | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-solaris2*)
 309       case "${target}" in
 310         *-*-linux*aout* | *-*-linux*oldld*)
 311           ;;
 312         *)
 313           is_elf=yes
 314           ;;
 315       esac
 316   esac
 317
 318   if test "$is_elf" = "yes"; then
 319     # Check for target supported by gold.
 320     case "${target}" in
 321       i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-*)
 322         configdirs="`echo " ${configdirs} " | sed -e 's/ ld / gold /'`"
 323         ;;
 324     esac
 325   fi
 326 fi
 327
 328 # Configure extra directories which are host specific
 329
 330 case "${host}" in
 331   *-cygwin*)
 332     configdirs="$configdirs libtermcap" ;;
 333 esac
 334
 335 # A target can indicate whether a language isn't supported for some reason.
 336 # Only spaces may be used in this macro; not newlines or tabs.
 337 unsupported_languages=
 338
 339 # Remove more programs from consideration, based on the host or
 340 # target this usually means that a port of the program doesn't
 341 # exist yet.
 342
 343 case "${host}" in
 344   hppa*64*-*-*)
 345     noconfigdirs="$noconfigdirs byacc"
 346     ;;
 347   i[[3456789]]86-*-vsta)
 348     noconfigdirs="$noconfigdirs tcl expect dejagnu make texinfo bison patch flex byacc send-pr gprof uudecode dejagnu diff guile perl itcl gnuserv gettext"
 349     ;;
 350   i[[3456789]]86-*-go32* | i[[3456789]]86-*-msdosdjgpp*)
 351     noconfigdirs="$noconfigdirs tcl tk expect dejagnu send-pr uudecode guile itcl gnuserv libffi"
 352     ;;
 353   x86_64-*-mingw*)
 354     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 355     ;;
 356   i[[3456789]]86-*-mingw32*)
 357     # noconfigdirs="tcl tk expect dejagnu make texinfo bison patch flex byacc send-pr uudecode dejagnu diff guile perl itcl gnuserv"
 358     noconfigdirs="$noconfigdirs expect dejagnu autoconf automake send-pr rcs guile perl texinfo libtool newlib"
 359     ;;
 360   i[[3456789]]86-*-beos*)
 361     noconfigdirs="$noconfigdirs tk itcl libgui gdb"
 362     ;;
 363   *-*-cygwin*)
 364     noconfigdirs="$noconfigdirs autoconf automake send-pr rcs guile perl"
 365     ;;
 366   *-*-netbsd*)
 367     noconfigdirs="$noconfigdirs rcs"
 368     ;;
 369   ppc*-*-pe)
 370     noconfigdirs="$noconfigdirs patch diff make tk tcl expect dejagnu autoconf automake texinfo bison send-pr gprof rcs guile perl itcl gnuserv"
 371     ;;
 372   powerpc-*-beos*)
 373     noconfigdirs="$noconfigdirs tk itcl libgui gdb dejagnu readline"
 374     ;;
 375 esac
 376
 377
 378 AC_ARG_ENABLE(libada,
 379 [  --enable-libada         build libada directory],
 380 ENABLE_LIBADA=$enableval,
 381 ENABLE_LIBADA=yes)
 382 if test "${ENABLE_LIBADA}" != "yes" ; then
 383   noconfigdirs="$noconfigdirs gnattools"
 384 fi
 385
 386 AC_ARG_ENABLE(libssp,
 387 [  --enable-libssp         build libssp directory],
 388 ENABLE_LIBSSP=$enableval,
 389 ENABLE_LIBSSP=yes)
 390
 391 # Save it here so that, even in case of --enable-libgcj, if the Java
 392 # front-end isn't enabled, we still get libgcj disabled.
 393 libgcj_saved=$libgcj
 394 case $enable_libgcj in
 395 yes)
 396   # If we reset it here, it won't get added to noconfigdirs in the
 397   # target-specific build rules, so it will be forcibly enabled
 398   # (unless the Java language itself isn't enabled).
 399   libgcj=
 400   ;;
 401 no)
 402   # Make sure we get it printed in the list of not supported target libs.
 403   noconfigdirs="$noconfigdirs ${libgcj}"
 404   ;;
 405 esac
 406
 407
 408 # Disable libmudflap on some systems.
 409 if test x$enable_libmudflap = x ; then
 410     case "${target}" in
 411     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux*)
 412         # Enable libmudflap by default in GNU and friends.
 413         ;;
 414     *-*-freebsd*)
 415         # Enable libmudflap by default in FreeBSD.
 416         ;;
 417     *)
 418         # Disable it by default everywhere else.
 419         noconfigdirs="$noconfigdirs target-libmudflap"
 420         ;;
 421     esac
 422 fi
 423
 424 # Disable libgomp on non POSIX hosted systems.
 425 if test x$enable_libgomp = x ; then
 426     # Enable libgomp by default on hosted POSIX systems.
 427     case "${target}" in
 428     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu)
 429         ;;
 430     *-*-netbsd* | *-*-freebsd* | *-*-openbsd*)
 431         ;;
 432     *-*-solaris2* | *-*-sysv4* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 433         ;;
 434     *-*-darwin* | *-*-aix*)
 435         ;;
 436     *)
 437         noconfigdirs="$noconfigdirs target-libgomp"
 438         ;;
 439     esac
 440 fi
 441
 442 # Default libgloss CPU subdirectory.
 443 libgloss_dir="$target_cpu"
 444
 445 case "${target}" in
 446   *-*-chorusos)
 447     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 448     ;;
 449   powerpc-*-darwin* | i[[3456789]]86-*-darwin* | x86_64-*-darwin9*)
 450     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 451     noconfigdirs="$noconfigdirs sim target-rda"
 452     ;;
 453   *-*-darwin*)
 454     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 455     noconfigdirs="$noconfigdirs sim target-rda"
 456     noconfigdirs="$noconfigdirs ${libgcj}"
 457     ;;
 458   *-*-freebsd[[12]] | *-*-freebsd[[12]].* | *-*-freebsd*aout*)
 459     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 460     ;;
 461   *-*-freebsd*)
 462     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 463     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 464         && test -f /usr/local/include/gmp.h; then
 465       with_gmp=/usr/local
 466     fi
 467
 468     # Skip some stuff that's unsupported on some FreeBSD configurations.
 469     case "${target}" in
 470       i*86-*-*) ;;
 471       alpha*-*-*) ;;
 472       *)
 473         noconfigdirs="$noconfigdirs ${libgcj}"
 474         ;;
 475     esac
 476     ;;
 477   *-*-kaos*)
 478     # Remove unsupported stuff on all kaOS configurations.
 479     skipdirs="target-libiberty ${libgcj} target-libstdc++-v3 target-librx"
 480     skipdirs="$skipdirs target-libobjc target-examples target-groff target-gperf"
 481     skipdirs="$skipdirs zlib fastjar target-libjava target-boehm-gc target-zlib"
 482     noconfigdirs="$noconfigdirs target-libgloss"
 483     ;;
 484   *-*-netbsd*)
 485     # Skip some stuff on all NetBSD configurations.
 486     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss"
 487
 488     # Skip some stuff that's unsupported on some NetBSD configurations.
 489     case "${target}" in
 490       i*86-*-netbsdelf*) ;;
 491       arm*-*-netbsdelf*) ;;
 492       *)
 493         noconfigdirs="$noconfigdirs ${libgcj}"
 494         ;;
 495     esac
 496     ;;
 497   *-*-netware*)
 498     noconfigdirs="$noconfigdirs target-newlib target-libiberty target-libgloss ${libgcj} target-libmudflap"
 499     ;;
 500   *-*-rtems*)
 501     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 502     ;;
 503     # The tpf target doesn't support gdb yet.
 504   *-*-tpf*)
 505     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty ${libgcj} target-libmudflap gdb tcl tk libgui itcl"
 506     ;;
 507   *-*-uclinux*)
 508     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-rda ${libgcj}"
 509     ;;
 510   *-*-vxworks*)
 511     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-libiberty target-libstdc++-v3 ${libgcj}"
 512     ;;
 513   alpha*-dec-osf*)
 514     # ld works, but does not support shared libraries.
 515     # newlib is not 64 bit ready.  I'm not sure about fileutils.
 516     # gas doesn't generate exception information.
 517     noconfigdirs="$noconfigdirs gas ld fileutils target-newlib target-libgloss"
 518     ;;
 519   alpha*-*-*vms*)
 520     noconfigdirs="$noconfigdirs gdb ld target-newlib target-libgloss ${libgcj}"
 521     ;;
 522   alpha*-*-linux*)
 523     # newlib is not 64 bit ready
 524     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 525     ;;
 526   alpha*-*-*)
 527     # newlib is not 64 bit ready
 528     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 529     ;;
 530   am33_2.0-*-linux*)
 531     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 532     ;;
 533   sh-*-linux*)
 534     noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss"
 535     ;;
 536   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 537     noconfigdirs="$noconfigdirs ${libgcj}"
 538     noconfigdirs="$noconfigdirs target-examples"
 539     noconfigdirs="$noconfigdirs target-libiberty texinfo send-pr"
 540     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 541     noconfigdirs="$noconfigdirs expect dejagnu"
 542     # the C++ libraries don't build on top of CE's C libraries
 543     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 544     noconfigdirs="$noconfigdirs target-newlib"
 545     case "${host}" in
 546       *-*-cygwin*) ;; # keep gdb and readline
 547       *) noconfigdirs="$noconfigdirs gdb readline"
 548          ;;
 549     esac
 550     libgloss_dir=wince
 551     ;;
 552   arc-*-*)
 553     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 554     ;;
 555   arm-semi-aof )
 556     ;;
 557   arm-*-coff | strongarm-*-coff | xscale-*-coff)
 558     noconfigdirs="$noconfigdirs ${libgcj}"
 559     libgloss_dir=arm
 560     ;;
 561   arm-*-elf* | strongarm-*-elf* | xscale-*-elf* | arm*-*-eabi* )
 562     noconfigdirs="$noconfigdirs target-libffi target-qthreads"
 563     libgloss_dir=arm
 564     ;;
 565   arm*-*-linux-gnueabi)
 566     noconfigdirs="$noconfigdirs target-qthreads"
 567     case ${with_newlib} in
 568       no) noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 569     esac
 570     libgloss_dir=arm
 571     ;;
 572   arm*-*-symbianelf*)
 573     noconfigdirs="$noconfigdirs ${libgcj} target-libiberty"
 574     libgloss_dir=arm
 575     ;;
 576   arm-*-pe*)
 577     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 578     ;;
 579   thumb-*-coff)
 580     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 581     ;;
 582   thumb-*-elf)
 583     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 584     ;;
 585   thumb-*-pe)
 586     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 587     ;;
 588   arm-*-riscix*)
 589     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 590     ;;
 591   avr-*-*)
 592     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj} target-libssp"
 593     ;;
 594   bfin-*-*)
 595     noconfigdirs="$noconfigdirs gdb"
 596     if test x${is_cross_compiler} != xno ; then
 597       target_configdirs="${target_configdirs} target-bsp target-cygmon"
 598     fi
 599     ;;
 600   c4x-*-* | tic4x-*-*)
 601     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 602     ;;
 603   c54x*-*-* | tic54x-*-*)
 604     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj} gcc gdb newlib"
 605     ;;
 606   cr16-*-*)
 607     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 608     ;;
 609   cris-*-* | crisv32-*-*)
 610     unsupported_languages="$unsupported_languages java"
 611     case "${target}" in
 612       *-*-aout)
 613         unsupported_languages="$unsupported_languages fortran"
 614         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 615       *-*-elf)
 616         noconfigdirs="$noconfigdirs target-boehm-gc";;
 617       *-*-linux*)
 618         noconfigdirs="$noconfigdirs target-newlib target-libgloss";;
 619       *)
 620         unsupported_languages="$unsupported_languages fortran"
 621         noconfigdirs="$noconfigdirs ${libgcj} target-newlib target-libgloss";;
 622     esac
 623     libgloss_dir=cris
 624     ;;
 625   crx-*-*)
 626     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-mudflap ${libgcj}"
 627     ;;
 628   d10v-*-*)
 629     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 630     ;;
 631   d30v-*-*)
 632     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 633     ;;
 634   ep9312-*-elf | ep9312-*-coff)
 635     libgloss_dir=arm
 636     ;;
 637   fr30-*-elf*)
 638     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 639     ;;
 640   frv-*-*)
 641     noconfigdirs="$noconfigdirs ${libgcj}"
 642     ;;
 643   h8300*-*-*)
 644     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 645     ;;
 646   h8500-*-*)
 647     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 648     ;;
 649   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 650     ;;
 651   hppa*64*-*-linux* | parisc*64*-*-linux*)
 652     # In this case, it's because the hppa64-linux target is for
 653     # the kernel only at this point and has no libc, and thus no
 654     # headers, crt*.o, etc., all of which are needed by these.
 655     noconfigdirs="$noconfigdirs target-zlib"
 656     ;;
 657   parisc*-*-linux* | hppa*-*-linux*)
 658     ;;
 659   hppa*-*-*elf* | \
 660   hppa*-*-lites* | \
 661   hppa*-*-openbsd* | \
 662   hppa*64*-*-*)
 663     noconfigdirs="$noconfigdirs ${libgcj}"
 664     ;;
 665   hppa*-hp-hpux11*)
 666     noconfigdirs="$noconfigdirs ld shellutils"
 667     ;;
 668   hppa*-*-pro*)
 669     libgloss_dir=pa
 670     ;;
 671   hppa*-*-*)
 672     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 673     # build on HP-UX 10.20.
 674     noconfigdirs="$noconfigdirs ld shellutils ${libgcj}"
 675     ;;
 676   i960-*-*)
 677     noconfigdirs="$noconfigdirs ${libgcj} gdb"
 678     ;;
 679   ia64*-*-elf*)
 680     # No gdb support yet.
 681     noconfigdirs="$noconfigdirs readline mmalloc libgui itcl gdb"
 682     ;;
 683   ia64*-**-hpux*)
 684     # No gdb or ld support yet.
 685     noconfigdirs="$noconfigdirs ${libgcj} readline mmalloc libgui itcl gdb ld"
 686     ;;
 687   i370-*-opened*)
 688     ;;
 689   i[[3456789]]86-*-coff | i[[3456789]]86-*-elf)
 690     noconfigdirs="$noconfigdirs ${libgcj}"
 691     libgloss_dir=i386
 692     ;;
 693   i[[3456789]]86-*-linux*)
 694     # The GCC port for glibc1 has no MD_FALLBACK_FRAME_STATE_FOR, so let's
 695     # not build java stuff by default.
 696     case "${target}" in
 697       *-*-*libc1*)
 698         noconfigdirs="$noconfigdirs ${libgcj}";;
 699     esac
 700
 701     # This section makes it possible to build newlib natively on linux.
 702     # If we are using a cross compiler then don't configure newlib.
 703     if test x${is_cross_compiler} != xno ; then
 704       noconfigdirs="$noconfigdirs target-newlib"
 705     fi
 706     noconfigdirs="$noconfigdirs target-libgloss"
 707     # If we are not using a cross compiler, do configure newlib.
 708     # Note however, that newlib will only be configured in this situation
 709     # if the --with-newlib option has been given, because otherwise
 710     # 'target-newlib' will appear in skipdirs.
 711     ;;
 712   i[[3456789]]86-*-mingw32*)
 713     target_configdirs="$target_configdirs target-winsup"
 714     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 715     ;;
 716   x86_64-*-mingw*)
 717     target_configdirs="$target_configdirs target-winsup"
 718     noconfigdirs="$noconfigdirs expect target-libgloss target-newlib ${libgcj}"
 719     ;;
 720   *-*-cygwin*)
 721     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 722     noconfigdirs="$noconfigdirs target-gperf target-libgloss ${libgcj}"
 723     # always build newlib if winsup directory is present.
 724     if test -d "$srcdir/winsup/cygwin"; then
 725       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 726     elif test -d "$srcdir/newlib"; then
 727       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 728     fi
 729     ;;
 730   i[[3456789]]86-moss-msdos | i[[3456789]]86-*-moss* | \
 731   i[[3456789]]86-*-uwin* | i[[3456789]]86-*-interix* )
 732     ;;
 733   i[[3456789]]86-*-pe)
 734     noconfigdirs="$noconfigdirs target-libstdc++-v3 target-libgloss ${libgcj}"
 735     ;;
 736   i[[3456789]]86-*-sco3.2v5*)
 737     # The linker does not yet know about weak symbols in COFF,
 738     # and is not configured to handle mixed ELF and COFF.
 739     noconfigdirs="$noconfigdirs ld target-libgloss ${libgcj}"
 740     ;;
 741   i[[3456789]]86-*-sco*)
 742     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 743     ;;
 744   i[[3456789]]86-*-solaris2*)
 745     noconfigdirs="$noconfigdirs target-libgloss"
 746     ;;
 747   i[[3456789]]86-*-sysv4*)
 748     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 749     ;;
 750   i[[3456789]]86-*-beos*)
 751     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 752     ;;
 753   i[[3456789]]86-*-rdos*)
 754     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 755     ;;
 756   m32r-*-*)
 757     noconfigdirs="$noconfigdirs ${libgcj}"
 758     ;;
 759   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 760     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj}"
 761     libgloss_dir=m68hc11
 762     ;;
 763   m68k-*-elf*)
 764     noconfigdirs="$noconfigdirs ${libgcj}"
 765     ;;
 766   m68k-*-coff*)
 767     noconfigdirs="$noconfigdirs ${libgcj}"
 768     ;;
 769   m68*-*-* | fido-*-*)
 770     libgloss_dir=m68k
 771     ;;
 772   mcore-*-pe*)
 773   # The EPOC C++ environment does not support exceptions or rtti,
 774   # and so building libstdc++-v3 tends not to always work.
 775     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 776     ;;
 777   mmix-*-*)
 778     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc gdb libgloss"
 779     unsupported_languages="$unsupported_languages fortran java"
 780     ;;
 781   mn10200-*-*)
 782     noconfigdirs="$noconfigdirs ${libgcj}"
 783     ;;
 784   mn10300-*-*)
 785     noconfigdirs="$noconfigdirs ${libgcj}"
 786     ;;
 787   mt-*-*)
 788     noconfigdirs="$noconfigdirs sim"
 789     ;;
 790   powerpc-*-aix*)
 791     # copied from rs6000-*-* entry
 792     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp ${libgcj}"
 793     ;;
 794   powerpc*-*-winnt* | powerpc*-*-pe* | ppc*-*-pe)
 795     target_configdirs="$target_configdirs target-winsup"
 796     noconfigdirs="$noconfigdirs gdb tcl tk make expect target-libgloss itcl gnuserv ${libgcj}"
 797     # always build newlib.
 798     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 799     ;;
 800     # This is temporary until we can link against shared libraries
 801   powerpcle-*-solaris*)
 802     noconfigdirs="$noconfigdirs gdb sim make tcl tk expect itcl gnuserv ${libgcj}"
 803     libgloss_dir=rs6000
 804     ;;
 805   powerpc-*-beos*)
 806     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss ${libgcj}"
 807     ;;
 808   powerpc-*-eabi)
 809     noconfigdirs="$noconfigdirs ${libgcj}"
 810     libgloss_dir=rs6000
 811     ;;
 812   powerpc-*-eabi* | powerpcle-*-eabi* | powerpc-*-rtems* )
 813     libgloss_dir=rs6000
 814     ;;
 815   rs6000-*-lynxos*)
 816     noconfigdirs="$noconfigdirs target-newlib gprof ${libgcj}"
 817     ;;
 818   rs6000-*-aix*)
 819     noconfigdirs="$noconfigdirs gprof target-libgloss target-libssp ${libgcj}"
 820     ;;
 821   rs6000-*-*)
 822     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 823     ;;
 824   m68k-apollo-*)
 825     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss ${libgcj}"
 826     ;;
 827   mips*-sde-elf*)
 828     skipdirs="$skipdirs target-libiberty"
 829     noconfigdirs="$noconfigdirs ${libgcj}"
 830     if test x$with_newlib = xyes; then
 831       noconfigdirs="$noconfigdirs gprof"
 832     fi
 833     libgloss_dir=mips
 834     ;;
 835   mips*-*-irix5*)
 836     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 837     ;;
 838   mips*-*-irix6*)
 839     # Linking libjava exceeds command-line length limits on at least
 840     # IRIX 6.2, but not on IRIX 6.5.
 841     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 842     # <oldham@codesourcery.com>
 843     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 844     ;;
 845   mips*-*-bsd*)
 846     noconfigdirs="$noconfigdirs gprof target-libgloss ${libgcj}"
 847     ;;
 848   mips*-*-linux*)
 849     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 850     ;;
 851   mips*-*-*)
 852     noconfigdirs="$noconfigdirs gprof ${libgcj}"
 853     libgloss_dir=mips
 854     ;;
 855   romp-*-*)
 856     noconfigdirs="$noconfigdirs bfd binutils ld gas opcodes target-libgloss ${libgcj}"
 857     ;;
 858   sh-*-* | sh64-*-*)
 859     case "${host}" in
 860       i[[3456789]]86-*-vsta) ;; # don't add gprof back in
 861       i[[3456789]]86-*-go32*) ;; # don't add gprof back in
 862       i[[3456789]]86-*-msdosdjgpp*) ;; # don't add gprof back in
 863       *) skipdirs=`echo " ${skipdirs} " | sed -e 's/ gprof / /'` ;;
 864     esac
 865     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 866     ;;
 867   sparclet-*-aout* | sparc86x-*-*)
 868     libgloss_dir=sparc
 869     ;;
 870   sparc-*-elf*)
 871     noconfigdirs="$noconfigdirs ${libgcj}"
 872     ;;
 873   sparc64-*-elf*)
 874     noconfigdirs="$noconfigdirs ${libgcj}"
 875     libgloss_dir=sparc
 876     ;;
 877   sparclite-*-*)
 878     noconfigdirs="$noconfigdirs ${libgcj}"
 879     libgloss_dir=sparc
 880     ;;
 881   sparc-*-sunos4*)
 882     noconfigdirs="$noconfigdirs ${libgcj}"
 883     if test x${is_cross_compiler} != xno ; then
 884            noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 885     else
 886            use_gnu_ld=no
 887     fi
 888     ;;
 889   sparc-*-solaris2.[[0-6]] | sparc-*-solaris2.[[0-6]].*)
 890     noconfigdirs="$noconfigdirs ${libgcj}"
 891     ;;
 892   sparc-*-solaris* | sparc64-*-solaris* | sparcv9-*-solaris*)
 893     ;;
 894   spu-*-*)
 895     skipdirs="target-libssp"
 896     ;;
 897   v810-*-*)
 898     noconfigdirs="$noconfigdirs bfd binutils gas gcc gdb ld target-libstdc++-v3 opcodes target-libgloss ${libgcj}"
 899     ;;
 900   v850-*-*)
 901     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 902     ;;
 903   v850e-*-*)
 904     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 905     ;;
 906   v850ea-*-*)
 907     noconfigdirs="$noconfigdirs target-libgloss ${libgcj}"
 908     ;;
 909   vax-*-vms)
 910     noconfigdirs="$noconfigdirs bfd binutils gdb ld target-newlib opcodes target-libgloss ${libgcj}"
 911     ;;
 912   vax-*-*)
 913     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 914     ;;
 915   xtensa*-*-*)
 916     noconfigdirs="$noconfigdirs ${libgcj}"
 917     ;;
 918   ip2k-*-*)
 919     noconfigdirs="$noconfigdirs target-libiberty target-libstdc++-v3 ${libgcj}"
 920     ;;
 921   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu)
 922     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 923     ;;
 924   *-*-lynxos*)
 925     noconfigdirs="$noconfigdirs target-newlib target-libgloss ${libgcj}"
 926     ;;
 927   *-*-*)
 928     noconfigdirs="$noconfigdirs ${libgcj}"
 929     ;;
 930 esac
 931
 932 # If we aren't building newlib, then don't build libgloss, since libgloss
 933 # depends upon some newlib header files.
 934 case "${noconfigdirs}" in
 935   *target-libgloss*) ;;
 936   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
 937 esac
 938
 939 # Work in distributions that contain no compiler tools, like Autoconf.
 940 tentative_cc=""
 941 host_makefile_frag=/dev/null
 942 if test -d ${srcdir}/config ; then
 943 case "${host}" in
 944   m68k-hp-hpux*)
 945     # Avoid "too much defining" errors from HPUX compiler.
 946     tentative_cc="cc -Wp,-H256000"
 947     # If "ar" in $PATH is GNU ar, the symbol table may need rebuilding.
 948     # If it's HP/UX ar, this should be harmless.
 949     RANLIB="ar ts"
 950     ;;
 951   m68k-apollo-sysv*)
 952     tentative_cc="cc -A ansi -A runtype,any -A systype,any -U__STDC__ -DUSG"
 953     ;;
 954   m68k-apollo-bsd*)
 955     #None of the Apollo compilers can compile gas or binutils.  The preprocessor
 956     # chokes on bfd, the compiler won't let you assign integers to enums, and
 957     # other problems.  Defining CC to gcc is a questionable way to say "don't use
 958     # the apollo compiler" (the preferred version of GCC could be called cc,
 959     # or whatever), but I'm not sure leaving CC as cc is any better...
 960     #CC=cc -A ansi -A runtype,any -A systype,any -U__STDC__ -DNO_STDARG
 961     # Used to have BISON=yacc.
 962     tentative_cc=gcc
 963     ;;
 964   m88k-dg-dgux*)
 965     tentative_cc="gcc -Wall -ansi -D__using_DGUX"
 966     ;;
 967   m88k-harris-cxux*)
 968     # Under CX/UX, we want to tell the compiler to use ANSI mode.
 969     tentative_cc="cc -Xa"
 970     host_makefile_frag="config/mh-cxux"
 971     ;;
 972   m88k-motorola-sysv*)
 973     ;;
 974   mips*-dec-ultrix*)
 975     tentative_cc="cc -Wf,-XNg1000"
 976     host_makefile_frag="config/mh-decstation"
 977     ;;
 978   mips*-nec-sysv4*)
 979     # The C compiler on NEC MIPS SVR4 needs bigger tables.
 980     tentative_cc="cc -ZXNd=5000 -ZXNg=1000"
 981     host_makefile_frag="config/mh-necv4"
 982     ;;
 983   mips*-sgi-irix4*)
 984     # Tell compiler to use K&R C.  We can't compile under the SGI Ansi
 985     # environment.  Also bump switch table size so that cp-parse will
 986     # compile.  Bump string length limit so linker builds.
 987     tentative_cc="cc -cckr -Wf,-XNg1500 -Wf,-XNk1000 -Wf,-XNh2000 -Wf,-XNl8192"
 988     ;;
 989   mips*-*-sysv4*)
 990     host_makefile_frag="config/mh-sysv4"
 991     ;;
 992   mips*-*-sysv*)
 993     # This is for a MIPS running RISC/os 4.52C.
 994
 995     # This is needed for GDB, but needs to be in the top-level make because
 996     # if a library is compiled with the bsd headers and gets linked with the
 997     # sysv system libraries all hell can break loose (e.g. a jmp_buf might be
 998     # a different size).
 999     # ptrace(2) apparently has problems in the BSD environment.  No workaround is
1000     # known except to select the sysv environment.  Could we use /proc instead?
1001     # These "sysv environments" and "bsd environments" often end up being a pain.
1002     #
1003     # This is not part of CFLAGS because perhaps not all C compilers have this
1004     # option.
1005     tentative_cc="cc -systype sysv"
1006     ;;
1007   i370-ibm-opened*)
1008     tentative_cc="c89"
1009     ;;
1010   i[[3456789]]86-*-sysv5*)
1011     host_makefile_frag="config/mh-sysv5"
1012     ;;
1013   i[[3456789]]86-*-dgux*)
1014     tentative_cc="gcc -Wall -ansi -D__using_DGUX"
1015     host_makefile_frag="config/mh-dgux386"
1016     ;;
1017   i[[3456789]]86-ncr-sysv4.3*)
1018     # The MetaWare compiler will generate a copyright message unless you
1019     # turn it off by adding the -Hnocopyr flag.
1020     tentative_cc="cc -Hnocopyr"
1021     ;;
1022   i[[3456789]]86-ncr-sysv4*)
1023     # for an NCR 3000 (i486/SVR4) system.
1024     # The NCR 3000 ships with a MetaWare compiler installed as /bin/cc.
1025     # This compiler not only emits obnoxious copyright messages every time
1026     # you run it, but it chokes and dies on a whole bunch of GNU source
1027     # files.  Default to using the AT&T compiler installed in /usr/ccs/ATT/cc.
1028     tentative_cc="/usr/ccs/ATT/cc"
1029     host_makefile_frag="config/mh-ncr3000"
1030     ;;
1031   i[[3456789]]86-*-sco3.2v5*)
1032     ;;
1033   i[[3456789]]86-*-sco*)
1034     # The native C compiler botches some simple uses of const.  Unfortunately,
1035     # it doesn't defined anything like "__sco__" for us to test for in ansidecl.h.
1036     tentative_cc="cc -Dconst="
1037     host_makefile_frag="config/mh-sco"
1038     ;;
1039   i[[3456789]]86-*-udk*)
1040     host_makefile_frag="config/mh-sysv5"
1041     ;;
1042   i[[3456789]]86-*-solaris2*)
1043     host_makefile_frag="config/mh-sysv4"
1044     ;;
1045   i[[3456789]]86-*-msdosdjgpp*)
1046     host_makefile_frag="config/mh-djgpp"
1047     ;;
1048   *-cygwin*)
1049     ACX_CHECK_CYGWIN_CAT_WORKS
1050     host_makefile_frag="config/mh-cygwin"
1051     ;;
1052   *-mingw*)
1053     host_makefile_frag="config/mh-mingw"
1054     ;;
1055   *-interix*)
1056     host_makefile_frag="config/mh-interix"
1057     ;;
1058   vax-*-ultrix2*)
1059     # The old BSD pcc isn't up to compiling parts of gdb so use gcc
1060     tentative_cc=gcc
1061     ;;
1062   *-*-solaris2*)
1063     host_makefile_frag="config/mh-solaris"
1064     ;;
1065   m68k-sun-sunos*)
1066     # Sun's C compiler needs the -J flag to be able to compile cp-parse.c
1067     # without overflowing the jump tables (-J says to use a 32 bit table)
1068     tentative_cc="cc -J"
1069     ;;
1070   hppa*-hp-hpux10*)
1071     tentative_cc="cc -Wp,-H256000"
1072     host_makefile_frag="config/mh-pa-hpux10"
1073     ;;
1074   hppa*-hp-hpux* | hppa*-*-hiux*)
1075     tentative_cc="cc -Wp,-H256000"
1076     host_makefile_frag="config/mh-pa"
1077     ;;
1078   hppa*-*)
1079     host_makefile_frag="config/mh-pa"
1080     ;;
1081   *-hp-hpux* | *-*-hiux*)
1082     tentative_cc="cc -Wp,-H256000"
1083     ;;
1084   rs6000-*-lynxos*)
1085     # /bin/cc is less than useful for our purposes.  Always use GCC
1086     tentative_cc="/usr/cygnus/progressive/bin/gcc"
1087     host_makefile_frag="config/mh-lynxrs6k"
1088     ;;
1089   powerpc-*-darwin*)
1090     host_makefile_frag="config/mh-ppc-darwin"
1091     ;;
1092   powerpc-*-aix*)
1093     host_makefile_frag="config/mh-ppc-aix"
1094     ;;
1095   rs6000-*-aix*)
1096     host_makefile_frag="config/mh-ppc-aix"
1097     ;;
1098   *-*-lynxos*)
1099     # /bin/cc is less than useful for our purposes.  Always use GCC
1100     tentative_cc="/bin/gcc"
1101     ;;
1102   *-*-sysv4*)
1103     host_makefile_frag="config/mh-sysv4"
1104     ;;
1105   # This is placed last to prevent interfering with the cases above.
1106   i[[3456789]]86-*-*)
1107     # Build the stage2 and stage3 compilers with -fomit-frame-pointer.
1108     host_makefile_frag="config/mh-x86omitfp"
1109     ;;
1110 esac
1111 fi
1112
1113 # If we aren't going to be using gcc, see if we can extract a definition
1114 # of CC from the fragment.
1115 # Actually, use the 'pre-extracted' version above.
1116 if test -z "${CC}" && test "${build}" = "${host}" ; then
1117   IFS="${IFS=   }"; save_ifs="$IFS"; IFS="${IFS}:"
1118   found=
1119   for dir in $PATH; do
1120     test -z "$dir" && dir=.
1121     if test -f $dir/gcc; then
1122       found=yes
1123       break
1124     fi
1125   done
1126   IFS="$save_ifs"
1127   if test -z "${found}" && test -n "${tentative_cc}" ; then
1128     CC=$tentative_cc
1129   fi
1130 fi
1131
1132 if test "${build}" != "${host}" ; then
1133   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1134   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1135   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1136   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1137   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1138   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1139   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1140   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1141   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1142   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1143   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1144   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1145 else
1146   AR_FOR_BUILD="\$(AR)"
1147   AS_FOR_BUILD="\$(AS)"
1148   CC_FOR_BUILD="\$(CC)"
1149   CXX_FOR_BUILD="\$(CXX)"
1150   GCJ_FOR_BUILD="\$(GCJ)"
1151   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1152   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1153   LD_FOR_BUILD="\$(LD)"
1154   NM_FOR_BUILD="\$(NM)"
1155   RANLIB_FOR_BUILD="\$(RANLIB)"
1156   WINDRES_FOR_BUILD="\$(WINDRES)"
1157   WINDMC_FOR_BUILD="\$(WINDMC)"
1158 fi
1159
1160 AC_PROG_CC
1161 AC_PROG_CXX
1162
1163 # We must set the default linker to the linker used by gcc for the correct
1164 # operation of libtool.  If LD is not defined and we are using gcc, try to
1165 # set the LD default to the ld used by gcc.
1166 if test -z "$LD"; then
1167   if test "$GCC" = yes; then
1168     case $build in
1169     *-*-mingw*)
1170       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1171     *)
1172       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1173     esac
1174     case $gcc_prog_ld in
1175     # Accept absolute paths.
1176     [[\\/]* | [A-Za-z]:[\\/]*)]
1177       LD="$gcc_prog_ld" ;;
1178     esac
1179   fi
1180 fi
1181
1182 ACX_PROG_GNAT
1183 ACX_PROG_CMP_IGNORE_INITIAL
1184
1185 # Check for GMP and MPFR
1186 gmplibs="-lmpfr -lgmp"
1187 gmpinc=
1188 have_gmp=no
1189
1190 # Specify a location for mpfr
1191 # check for this first so it ends up on the link line before gmp.
1192 AC_ARG_WITH(mpfr-dir, [  --with-mpfr-dir=PATH    this option has been REMOVED],
1193   AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1194 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH]))
1195
1196 AC_ARG_WITH(mpfr, [  --with-mpfr=PATH        specify prefix directory for installed MPFR package.
1197                           Equivalent to --with-mpfr-include=PATH/include
1198                           plus --with-mpfr-lib=PATH/lib])
1199 AC_ARG_WITH(mpfr_include, [  --with-mpfr-include=PATH
1200                           specify directory for installed MPFR include files])
1201 AC_ARG_WITH(mpfr_lib, [  --with-mpfr-lib=PATH    specify directory for the installed MPFR library])
1202
1203 if test "x$with_mpfr" != x; then
1204   gmplibs="-L$with_mpfr/lib $gmplibs"
1205   gmpinc="-I$with_mpfr/include"
1206 fi
1207 if test "x$with_mpfr_include" != x; then
1208   gmpinc="-I$with_mpfr_include"
1209 fi
1210 if test "x$with_mpfr_lib" != x; then
1211   gmplibs="-L$with_mpfr_lib $gmplibs"
1212 fi
1213 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1214   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/.libs -L$$r/$(HOST_SUBDIR)/mpfr/_libs '"$gmplibs"
1215   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1216   # Do not test the mpfr version.  Assume that it is sufficient, since
1217   # it is in the source tree, and the library has not been built yet
1218   # but it would be included on the link line in the version check below
1219   # hence making the test fail.
1220   have_gmp=yes
1221 fi
1222
1223 # Specify a location for gmp
1224 AC_ARG_WITH(gmp-dir, [  --with-gmp-dir=PATH     this option has been REMOVED],
1225   AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1226 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH]))
1227
1228 AC_ARG_WITH(gmp, [  --with-gmp=PATH         specify prefix directory for the installed GMP package.
1229                           Equivalent to --with-gmp-include=PATH/include
1230                           plus --with-gmp-lib=PATH/lib])
1231 AC_ARG_WITH(gmp_include, [  --with-gmp-include=PATH specify directory for installed GMP include files])
1232 AC_ARG_WITH(gmp_lib, [  --with-gmp-lib=PATH     specify directory for the installed GMP library])
1233
1234
1235 if test "x$with_gmp" != x; then
1236   gmplibs="-L$with_gmp/lib $gmplibs"
1237   gmpinc="-I$with_gmp/include $gmpinc"
1238 fi
1239 if test "x$with_gmp_include" != x; then
1240   gmpinc="-I$with_gmp_include $gmpinc"
1241 fi
1242 if test "x$with_gmp_lib" != x; then
1243   gmplibs="-L$with_gmp_lib $gmplibs"
1244 fi
1245 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1246   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/.libs -L$$r/$(HOST_SUBDIR)/gmp/_libs '"$gmplibs"
1247   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1248   # Do not test the gmp version.  Assume that it is sufficient, since
1249   # it is in the source tree, and the library has not been built yet
1250   # but it would be included on the link line in the version check below
1251   # hence making the test fail.
1252   have_gmp=yes
1253 fi
1254
1255 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1256   have_gmp=yes
1257   saved_CFLAGS="$CFLAGS"
1258   CFLAGS="$CFLAGS $gmpinc"
1259   # Check GMP actually works
1260   AC_MSG_CHECKING([for correct version of gmp.h])
1261   AC_TRY_COMPILE([#include "gmp.h"],[
1262   #if __GNU_MP_VERSION < 4 || (__GNU_MP_VERSION == 4 && __GNU_MP_VERSION_MINOR < 1)
1263   choke me
1264   #endif
1265   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1266
1267   if test x"$have_gmp" = xyes; then
1268     saved_LIBS="$LIBS"
1269     LIBS="$LIBS $gmplibs"
1270     dnl MPFR 2.3.0 is acceptable, but MPFR 2.3.2 is better.
1271     AC_MSG_CHECKING([for correct version of mpfr.h])
1272     AC_TRY_LINK([#include <gmp.h>
1273     #include <mpfr.h>],[
1274     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,0)
1275     choke me
1276     #endif
1277     mpfr_t n;
1278     mpfr_t x;
1279     int t;
1280     mpfr_init (n);
1281     mpfr_init (x);
1282     mpfr_atan2 (n, n, x, GMP_RNDN);
1283     mpfr_erfc (n, x, GMP_RNDN);
1284     mpfr_subnormalize (x, t, GMP_RNDN);
1285     ], [AC_TRY_LINK([#include <gmp.h>
1286     #include <mpfr.h>],[
1287     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,2)
1288     choke me
1289     #endif
1290     mpfr_t n; mpfr_init(n);
1291     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1292      [AC_MSG_RESULT([no]); have_gmp=no])
1293       LIBS="$saved_LIBS"
1294   fi
1295   CFLAGS="$saved_CFLAGS"
1296
1297   if test x$have_gmp != xyes; then
1298     AC_MSG_ERROR([Building GCC requires GMP 4.1+ and MPFR 2.3.2+.
1299 Try the --with-gmp and/or --with-mpfr options to specify their locations.
1300 Copies of these libraries' source code can be found at their respective
1301 hosting sites as well as at ftp://gcc.gnu.org/pub/gcc/infrastructure/.
1302 See also http://gcc.gnu.org/install/prerequisites.html for additional info.
1303 If you obtained GMP and/or MPFR from a vendor distribution package, make
1304 sure that you have installed both the libraries and the header files.
1305 They may be located in separate packages.])
1306   fi
1307 fi
1308
1309 # Flags needed for both GMP and/or MPFR
1310 AC_SUBST(gmplibs)
1311 AC_SUBST(gmpinc)
1312
1313
1314 # Check for PPL
1315 ppl_major_version=0
1316 ppl_minor_version=10
1317 ppllibs=
1318 pplinc=
1319
1320 AC_ARG_WITH(ppl, [  --with-ppl=PATH         Specify prefix directory for the installed PPL package
1321                           Equivalent to --with-ppl-include=PATH/include
1322                           plus --with-ppl-lib=PATH/lib])
1323 AC_ARG_WITH(ppl_include, [  --with-ppl-include=PATH Specify directory for installed PPL include files])
1324 AC_ARG_WITH(ppl_lib, [  --with-ppl-lib=PATH     Specify the directory for the installed PPL library])
1325
1326 if test "x$with_ppl" != x; then
1327   ppllibs="-L$with_ppl/lib -lppl_c -lppl -lgmpxx"
1328   pplinc="-I$with_ppl/include $pplinc"
1329   LIBS="$ppllibs $LIBS"
1330 fi
1331 if test "x$with_ppl_include" != x; then
1332   pplinc="-I$with_ppl_include $pplinc"
1333 fi
1334 if test "x$with_ppl_lib" != x; then
1335   ppllibs="-L$with_ppl_lib -lppl_c -lppl -lgmpxx"
1336   LIBS="$ppllibs $LIBS"
1337 fi
1338 if test "x$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1339   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/.libs -L$$r/$(HOST_SUBDIR)/ppl/_libs -lppl_c -lppl -lgmpxx '
1340   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/include -I$$s/ppl/include '
1341   LIBS="$ppllibs $LIBS"
1342 fi
1343
1344 AC_ARG_ENABLE(ppl-version-check,
1345 [  --disable-ppl-version-check    disable check for PPL version],
1346 ENABLE_PPL_CHECK=$enableval,
1347 ENABLE_PPL_CHECK=yes)
1348
1349 if test "${ENABLE_PPL_CHECK}" = "yes"; then
1350   saved_CFLAGS="$CFLAGS"
1351   CFLAGS="$CFLAGS $pplinc $gmpinc"
1352   AC_MSG_CHECKING([for version $ppl_major_version.$ppl_minor_version of PPL])
1353   AC_TRY_COMPILE([#include "ppl_c.h"],[
1354   #if PPL_VERSION_MAJOR != $ppl_major_version || PPL_VERSION_MINOR != $ppl_minor_version
1355   choke me
1356   #endif
1357   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ])
1358   CFLAGS="$saved_CFLAGS"
1359 fi
1360
1361 # Flags needed for PPL
1362 AC_SUBST(ppllibs)
1363 AC_SUBST(pplinc)
1364
1365
1366 # Check for CLOOG
1367 clooglibs=" -lcloog "
1368 clooginc=" -DCLOOG_PPL_BACKEND "
1369
1370 AC_ARG_WITH(cloog, [  --with-cloog=PATH       Specify prefix directory for the installed CLooG-PPL package
1371                           Equivalent to --with-cloog-include=PATH/include
1372                           plus --with-cloog-lib=PATH/lib])
1373 AC_ARG_WITH(cloog_include, [  --with-cloog-include=PATH Specify directory for installed CLooG include files])
1374 AC_ARG_WITH(cloog_lib, [  --with-cloog-lib=PATH   Specify the directory for the installed CLooG library])
1375 AC_ARG_WITH(cloog-polylib, [  --with-cloog-polylib=PATH Specify prefix directory for the installed CLooG-PolyLib package])
1376
1377 if test "x$with_cloog" != x; then
1378   clooglibs="-L$with_cloog/lib -lcloog"
1379   clooginc="-I$with_cloog/include -DCLOOG_PPL_BACKEND "
1380   LIBS="$clooglibs $LIBS"
1381 fi
1382 if test "x$with_cloog_polylib" != x; then
1383   clooglibs="-L$with_cloog/lib -lcloog"
1384   clooginc="-I$with_cloog/include "
1385   LIBS="$clooglibs $LIBS"
1386 fi
1387 if test "x$with_cloog_include" != x; then
1388   clooginc="-I$with_cloog_include -DCLOOG_PPL_BACKEND "
1389 fi
1390 if test "x$with_cloog_lib" != x; then
1391   clooglibs="-L$with_cloog_lib -lcloog"
1392   LIBS="$clooglibs $LIBS"
1393 fi
1394 if test "x$with_cloog$with_cloog_include$with_cloog_lib" = x && test -d ${srcdir}/cloog; then
1395   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/.libs -L$$r/$(HOST_SUBDIR)/cloog/_libs -lcloog '
1396   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include -DCLOOG_PPL_BACKEND '
1397   LIBS="$clooglibs $LIBS"
1398 fi
1399
1400 AC_ARG_ENABLE(cloog-version-check,
1401 [  --disable-cloog-version-check  disable check for CLooG version],
1402 ENABLE_CLOOG_CHECK=$enableval,
1403 ENABLE_CLOOG_CHECK=yes)
1404
1405 if test "${ENABLE_CLOOG_CHECK}" = "yes"; then
1406   saved_CFLAGS="$CFLAGS"
1407   CFLAGS="$CFLAGS $clooginc $gmpinc $pplinc"
1408   AC_MSG_CHECKING([for correct version of CLooG])
1409   AC_TRY_COMPILE([#include "cloog/cloog.h"],[
1410   #if CLOOG_VERSION_MAJOR != 0 || CLOOG_VERSION_MINOR != 15
1411   choke me
1412   #endif
1413   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); clooglibs= ; clooginc= ])
1414   CFLAGS="$saved_CFLAGS"
1415 fi
1416
1417 # Flags needed for CLOOG
1418 AC_SUBST(clooglibs)
1419 AC_SUBST(clooginc)
1420
1421
1422 # By default, C is the only stage 1 language.
1423 stage1_languages=,c,
1424
1425 # Figure out what language subdirectories are present.
1426 # Look if the user specified --enable-languages="..."; if not, use
1427 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1428 # go away some day.
1429 # NB:  embedded tabs in this IF block -- do not untabify
1430 if test -d ${srcdir}/gcc; then
1431   if test x"${enable_languages+set}" != xset; then
1432     if test x"${LANGUAGES+set}" = xset; then
1433       enable_languages="${LANGUAGES}"
1434         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1435     else
1436       enable_languages=all
1437     fi
1438   else
1439     if test x"${enable_languages}" = x ||
1440        test x"${enable_languages}" = xyes;
1441        then
1442       echo configure.in: --enable-languages needs at least one language argument 1>&2
1443       exit 1
1444     fi
1445   fi
1446   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1447
1448   # 'f95' is the old name for the 'fortran' language. We issue a warning
1449   # and make the substitution.
1450   case ,${enable_languages}, in
1451     *,f95,*)
1452       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1453       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1454       ;;
1455   esac
1456
1457   # First scan to see if an enabled language requires some other language.
1458   # We assume that a given config-lang.in will list all the language
1459   # front ends it requires, even if some are required indirectly.
1460   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1461     case ${lang_frag} in
1462       ..) ;;
1463       # The odd quoting in the next line works around
1464       # an apparent bug in bash 1.12 on linux.
1465       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1466       *)
1467         # From the config-lang.in, get $language, $lang_requires
1468         language=
1469         lang_requires=
1470         . ${lang_frag}
1471         for other in ${lang_requires} ; do
1472           case ,${enable_languages}, in
1473             *,$other,*) ;;
1474             *,all,*) ;;
1475             *,$language,*)
1476               echo " \`$other' language required by \`$language'; enabling" 1>&2
1477               enable_languages="${enable_languages},${other}"
1478               ;;
1479           esac
1480         done
1481         ;;
1482     esac
1483   done
1484
1485   new_enable_languages=,c,
1486   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1487   potential_languages=,c,
1488
1489   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1490     case ${lang_frag} in
1491       ..) ;;
1492       # The odd quoting in the next line works around
1493       # an apparent bug in bash 1.12 on linux.
1494       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1495       *)
1496         # From the config-lang.in, get $language, $target_libs,
1497         # $lang_dirs, $boot_language, and $build_by_default
1498         language=
1499         target_libs=
1500         lang_dirs=
1501         subdir_requires=
1502         boot_language=no
1503         build_by_default=yes
1504         . ${lang_frag}
1505         if test x${language} = x; then
1506           echo "${lang_frag} doesn't set \$language." 1>&2
1507           exit 1
1508         fi
1509
1510         case ,${enable_languages}, in
1511           *,${language},*)
1512             # Language was explicitly selected; include it.
1513             add_this_lang=yes
1514             ;;
1515           *,all,*)
1516             # 'all' was selected, select it if it is a default language
1517             add_this_lang=${build_by_default}
1518             ;;
1519           *)
1520             add_this_lang=no
1521             ;;
1522         esac
1523
1524         # Disable languages that need other directories if these aren't available.
1525         for i in $subdir_requires; do
1526           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1527           case ,${enable_languages}, in
1528             *,${language},*)
1529               # Specifically requested language; tell them.
1530               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1531               ;;
1532             *)
1533               # Silently disable.
1534               add_this_lang=unsupported
1535               ;;
1536           esac
1537         done
1538
1539         # Disable Ada if no preexisting GNAT is available.
1540         case ,${enable_languages},:${language}:${have_gnat} in
1541           *,${language},*:ada:no)
1542             # Specifically requested language; tell them.
1543             AC_MSG_ERROR([GNAT is required to build $language])
1544             ;;
1545           *:ada:no)
1546             # Silently disable.
1547             add_this_lang=unsupported
1548             ;;
1549         esac
1550
1551         # Disable a language that is unsupported by the target.
1552         case " $unsupported_languages " in
1553           *" $language "*)
1554             add_this_lang=unsupported
1555             ;;
1556         esac
1557
1558         case $add_this_lang in
1559           unsupported)
1560             # Remove language-dependent dirs.
1561             eval noconfigdirs='"$noconfigdirs "'\"$target_libs $lang_dirs\"
1562             ;;
1563           no)
1564             # Remove language-dependent dirs; still show language as supported.
1565             eval noconfigdirs='"$noconfigdirs "'\"$target_libs $lang_dirs\"
1566             potential_languages="${potential_languages}${language},"
1567             ;;
1568           yes)
1569             new_enable_languages="${new_enable_languages}${language},"
1570             potential_languages="${potential_languages}${language},"
1571             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1572             case ${boot_language} in
1573               yes)
1574                 # Add to (comma-separated) list of stage 1 languages.
1575                 stage1_languages="${stage1_languages}${language},"
1576                 ;;
1577             esac
1578             ;;
1579         esac
1580         ;;
1581     esac
1582   done
1583
1584   AC_ARG_ENABLE(stage1-languages,
1585 [  --enable-stage1-languages@<:@=all@:>@   choose additional languages to build during
1586                           stage1.  Mostly useful for compiler development.],
1587   [case ,${enable_stage1_languages}, in
1588     ,no,|,,)
1589       # Set it to something that will have no effect in the loop below
1590       enable_stage1_languages=c ;;
1591     ,yes,)
1592       enable_stage1_languages=`echo $new_enable_languages | \
1593         sed -e "s/^,//" -e "s/,$//" ` ;;
1594     *,all,*)
1595       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1596         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1597   esac
1598
1599   # Add "good" languages from enable_stage1_languages to stage1_languages,
1600   # while "bad" languages go in missing_languages.  Leave no duplicates.
1601   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1602     case $potential_languages in
1603       *,$i,*)
1604         case $stage1_languages in
1605           *,$i,*) ;;
1606           *) stage1_languages="$stage1_languages$i," ;;
1607         esac ;;
1608       *)
1609         case $missing_languages in
1610           *,$i,*) ;;
1611           *) missing_languages="$missing_languages$i," ;;
1612         esac ;;
1613      esac
1614   done])
1615
1616   # Remove leading/trailing commas that were added for simplicity
1617   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1618   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1619   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1620   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1621
1622   if test "x$missing_languages" != x; then
1623     AC_MSG_ERROR([
1624 The following requested languages could not be built: ${missing_languages}
1625 Supported languages are: ${potential_languages}])
1626   fi
1627   if test "x$new_enable_languages" != "x$enable_languages"; then
1628     echo The following languages will be built: ${new_enable_languages}
1629     enable_languages="$new_enable_languages"
1630   fi
1631
1632   AC_SUBST(stage1_languages)
1633   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1634 fi
1635
1636 # Handle --disable-<component> generically.
1637 for dir in $configdirs $build_configdirs $target_configdirs ; do
1638   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1639   varname=`echo $dirname | sed -e s/+/_/g`
1640   if eval test x\${enable_${varname}} "=" xno ; then
1641     noconfigdirs="$noconfigdirs $dir"
1642   fi
1643 done
1644
1645 # Check for Boehm's garbage collector
1646 AC_ARG_ENABLE(objc-gc,
1647 [  --enable-objc-gc        enable use of Boehm's garbage collector with the
1648                           GNU Objective-C runtime],
1649 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1650   *,objc,*:*:yes:*target-boehm-gc*)
1651     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1652     ;;
1653 esac])
1654
1655 # Make sure we only build Boehm's garbage collector if required.
1656 case ,${enable_languages},:${enable_objc_gc} in
1657   *,objc,*:yes)
1658     # Keep target-boehm-gc if requested for Objective-C.
1659     ;;
1660   *)
1661     # Otherwise remove target-boehm-gc depending on target-libjava.
1662     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1663       noconfigdirs="$noconfigdirs target-boehm-gc"
1664     fi
1665     ;;
1666 esac
1667
1668 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1669 # $build_configdirs and $target_configdirs.
1670 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1671
1672 notsupp=""
1673 for dir in . $skipdirs $noconfigdirs ; do
1674   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1675   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1676     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1677     if test -r $srcdir/$dirname/configure ; then
1678       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1679         true
1680       else
1681         notsupp="$notsupp $dir"
1682       fi
1683     fi
1684   fi
1685   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1686     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1687     if test -r $srcdir/$dirname/configure ; then
1688       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1689         true
1690       else
1691         notsupp="$notsupp $dir"
1692       fi
1693     fi
1694   fi
1695   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1696     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1697     if test -r $srcdir/$dirname/configure ; then
1698       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1699         true
1700       else
1701         notsupp="$notsupp $dir"
1702       fi
1703     fi
1704   fi
1705 done
1706
1707 # Sometimes the tools are distributed with libiberty but with no other
1708 # libraries.  In that case, we don't want to build target-libiberty.
1709 # Don't let libgcc imply libiberty either.
1710 if test -n "${target_configdirs}" ; then
1711   libgcc=
1712   others=
1713   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
1714     if test "$i" = "libgcc"; then
1715       libgcc=target-libgcc
1716     elif test "$i" != "libiberty" ; then
1717       if test -r $srcdir/$i/configure ; then
1718         others=yes;
1719         break;
1720       fi
1721     fi
1722   done
1723   if test -z "${others}" ; then
1724     target_configdirs=$libgcc
1725   fi
1726 fi
1727
1728 # Quietly strip out all directories which aren't configurable in this tree.
1729 # This relies on all configurable subdirectories being autoconfiscated, which
1730 # is now the case.
1731 build_configdirs_all="$build_configdirs"
1732 build_configdirs=
1733 for i in ${build_configdirs_all} ; do
1734   j=`echo $i | sed -e s/build-//g`
1735   if test -f ${srcdir}/$j/configure ; then
1736     build_configdirs="${build_configdirs} $i"
1737   fi
1738 done
1739
1740 configdirs_all="$configdirs"
1741 configdirs=
1742 for i in ${configdirs_all} ; do
1743   if test -f ${srcdir}/$i/configure ; then
1744     configdirs="${configdirs} $i"
1745   fi
1746 done
1747
1748 target_configdirs_all="$target_configdirs"
1749 target_configdirs=
1750 for i in ${target_configdirs_all} ; do
1751   j=`echo $i | sed -e s/target-//g`
1752   if test -f ${srcdir}/$j/configure ; then
1753     target_configdirs="${target_configdirs} $i"
1754   fi
1755 done
1756
1757 # Produce a warning message for the subdirs we can't configure.
1758 # This isn't especially interesting in the Cygnus tree, but in the individual
1759 # FSF releases, it's important to let people know when their machine isn't
1760 # supported by the one or two programs in a package.
1761
1762 if test -n "${notsupp}" && test -z "${norecursion}" ; then
1763   # If $appdirs is non-empty, at least one of those directories must still
1764   # be configured, or we error out.  (E.g., if the gas release supports a
1765   # specified target in some subdirs but not the gas subdir, we shouldn't
1766   # pretend that all is well.)
1767   if test -n "$appdirs" ; then
1768     for dir in $appdirs ; do
1769       if test -r $dir/Makefile.in ; then
1770         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1771           appdirs=""
1772           break
1773         fi
1774         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
1775           appdirs=""
1776           break
1777         fi
1778       fi
1779     done
1780     if test -n "$appdirs" ; then
1781       echo "*** This configuration is not supported by this package." 1>&2
1782       exit 1
1783     fi
1784   fi
1785   # Okay, some application will build, or we don't care to check.  Still
1786   # notify of subdirs not getting built.
1787   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
1788   echo "    ${notsupp}" 1>&2
1789   echo "    (Any other directories should still work fine.)" 1>&2
1790 fi
1791
1792 case "$host" in
1793   *msdosdjgpp*)
1794     enable_gdbtk=no ;;
1795 esac
1796
1797 # To find our prefix, in gcc_cv_tool_prefix.
1798 ACX_TOOL_DIRS
1799
1800 copy_dirs=
1801
1802 AC_ARG_WITH([build-sysroot],
1803   [  --with-build-sysroot=SYSROOT
1804                           use sysroot as the system root during the build],
1805   [if test x"$withval" != x ; then
1806      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
1807    fi],
1808   [SYSROOT_CFLAGS_FOR_TARGET=])
1809 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
1810
1811 AC_ARG_WITH([debug-prefix-map],
1812   [  --with-debug-prefix-map='A=B C=D ...'
1813                              map A to B, C to D ... in debug information],
1814   [if test x"$withval" != x; then
1815      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
1816      for debug_map in $withval; do
1817        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
1818      done
1819    fi],
1820   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
1821 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
1822
1823 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
1824 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
1825 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
1826 # We want to ensure that TARGET libraries (which we know are built with
1827 # gcc) are built with "-O2 -g", so include those options when setting
1828 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
1829 if test "x$CFLAGS_FOR_TARGET" = x; then
1830   CFLAGS_FOR_TARGET=$CFLAGS
1831   case " $CFLAGS " in
1832     *" -O2 "*) ;;
1833     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
1834   esac
1835   case " $CFLAGS " in
1836     *" -g "* | *" -g3 "*) ;;
1837     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
1838   esac
1839 fi
1840 AC_SUBST(CFLAGS_FOR_TARGET)
1841
1842 if test "x$CXXFLAGS_FOR_TARGET" = x; then
1843   CXXFLAGS_FOR_TARGET=$CXXFLAGS
1844   case " $CXXFLAGS " in
1845     *" -O2 "*) ;;
1846     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
1847   esac
1848   case " $CXXFLAGS " in
1849     *" -g "* | *" -g3 "*) ;;
1850     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
1851   esac
1852 fi
1853 AC_SUBST(CXXFLAGS_FOR_TARGET)
1854
1855 # Other target tools.
1856 CPPFLAGS_FOR_TARGET=${CPPFLAGS_FOR_TARGET-${CPPFLAGS}}
1857 AC_SUBST(CPPFLAGS_FOR_TARGET)
1858 LDFLAGS_FOR_TARGET=${LDFLAGS_FOR_TARGET-${LDFLAGS}}
1859 AC_SUBST(LDFLAGS_FOR_TARGET)
1860
1861 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
1862 # the named directory are copied to $(tooldir)/sys-include.
1863 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
1864   if test x${is_cross_compiler} = xno ; then
1865     echo 1>&2 '***' --with-headers is only supported when cross compiling
1866     exit 1
1867   fi
1868   if test x"${with_headers}" != xyes ; then
1869     x=${gcc_cv_tool_prefix}
1870     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
1871   fi
1872 fi
1873
1874 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
1875 # the name directories are copied to $(tooldir)/lib.  Multiple directories
1876 # are permitted.
1877 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
1878   if test x${is_cross_compiler} = xno ; then
1879     echo 1>&2 '***' --with-libs is only supported when cross compiling
1880     exit 1
1881   fi
1882   if test x"${with_libs}" != xyes ; then
1883     # Copy the libraries in reverse order, so that files in the first named
1884     # library override files in subsequent libraries.
1885     x=${gcc_cv_tool_prefix}
1886     for l in ${with_libs}; do
1887       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
1888     done
1889   fi
1890 fi
1891
1892 # Set with_gnu_as and with_gnu_ld as appropriate.
1893 #
1894 # This is done by determining whether or not the appropriate directory
1895 # is available, and by checking whether or not specific configurations
1896 # have requested that this magic not happen.
1897 #
1898 # The command line options always override the explicit settings in
1899 # configure.in, and the settings in configure.in override this magic.
1900 #
1901 # If the default for a toolchain is to use GNU as and ld, and you don't
1902 # want to do that, then you should use the --without-gnu-as and
1903 # --without-gnu-ld options for the configure script.
1904
1905 if test x${use_gnu_as} = x &&
1906    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
1907   with_gnu_as=yes
1908   extra_host_args="$extra_host_args --with-gnu-as"
1909 fi
1910
1911 if test x${use_gnu_ld} = x &&
1912    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
1913   with_gnu_ld=yes
1914   extra_host_args="$extra_host_args --with-gnu-ld"
1915 fi
1916
1917 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
1918 # can detect this case.
1919
1920 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
1921   with_newlib=yes
1922   extra_host_args="$extra_host_args --with-newlib"
1923 fi
1924
1925 # Handle ${copy_dirs}
1926 set fnord ${copy_dirs}
1927 shift
1928 while test $# != 0 ; do
1929   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
1930     :
1931   else
1932     echo Copying $1 to $2
1933
1934     # Use the install script to create the directory and all required
1935     # parent directories.
1936     if test -d $2 ; then
1937       :
1938     else
1939       echo >config.temp
1940       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
1941     fi
1942
1943     # Copy the directory, assuming we have tar.
1944     # FIXME: Should we use B in the second tar?  Not all systems support it.
1945     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
1946
1947     # It is the responsibility of the user to correctly adjust all
1948     # symlinks.  If somebody can figure out how to handle them correctly
1949     # here, feel free to add the code.
1950
1951     echo $1 > $2/COPIED
1952   fi
1953   shift; shift
1954 done
1955
1956 # Determine a target-dependent exec_prefix that the installed
1957 # gcc will search in.  Keep this list sorted by triplet, with
1958 # the *-*-osname triplets last.
1959 md_exec_prefix=
1960 case "${target}" in
1961   alpha*-*-*vms*)
1962     md_exec_prefix=/gnu/lib/gcc-lib
1963     ;;
1964   i[[34567]]86-pc-msdosdjgpp*)
1965     md_exec_prefix=/dev/env/DJDIR/bin
1966     ;;
1967   i[[34567]]86-*-sco3.2v5*)
1968     if test $with_gnu_as = yes; then
1969       md_exec_prefix=/usr/gnu/bin
1970     else
1971       md_exec_prefix=/usr/ccs/bin/elf
1972     fi
1973     ;;
1974
1975   mn10300-*-* | \
1976   powerpc-*-chorusos* | \
1977   powerpc*-*-eabi* | \
1978   powerpc*-*-sysv* | \
1979   powerpc*-*-kaos* | \
1980   s390x-ibm-tpf*)
1981     md_exec_prefix=/usr/ccs/bin
1982     ;;
1983   sparc64-*-elf*)
1984     ;;
1985   v850*-*-*)
1986     md_exec_prefix=/usr/ccs/bin
1987     ;;
1988   xtensa*-*-elf*)
1989     ;;
1990
1991   *-*-beos* | \
1992   *-*-elf* | \
1993   *-*-hpux* | \
1994   *-*-netware* | \
1995   *-*-nto-qnx* | \
1996   *-*-rtems* | \
1997   *-*-solaris2* | \
1998   *-*-sysv[[45]]* | \
1999   *-*-vxworks* | \
2000   *-wrs-windiss)
2001     md_exec_prefix=/usr/ccs/bin
2002     ;;
2003 esac
2004
2005 extra_arflags_for_target=
2006 extra_nmflags_for_target=
2007 extra_ranlibflags_for_target=
2008 target_makefile_frag=/dev/null
2009 case "${target}" in
2010   mep*-*-*)
2011     target_makefile_frag="config/mt-mep"
2012     ;;
2013   spu-*-*)
2014     target_makefile_frag="config/mt-spu"
2015     ;;
2016   mips*-sde-elf*)
2017     target_makefile_frag="config/mt-sde"
2018     ;;
2019   mipsisa*-*-elfoabi*)
2020     target_makefile_frag="config/mt-mips-elfoabi"
2021     ;;
2022   mips*-*-*linux* | mips*-*-gnu*)
2023     target_makefile_frag="config/mt-mips-gnu"
2024     ;;
2025   *-*-netware*)
2026     target_makefile_frag="config/mt-netware"
2027     ;;
2028   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu)
2029     target_makefile_frag="config/mt-gnu"
2030     ;;
2031   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2032     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2033     # commands to handle both 32-bit and 64-bit objects.  These flags are
2034     # harmless if we're using GNU nm or ar.
2035     extra_arflags_for_target=" -X32_64"
2036     extra_nmflags_for_target=" -B -X32_64"
2037     ;;
2038   *-*-darwin*)
2039     # ranlib from Darwin requires the -c flag to look at common symbols.
2040     extra_ranlibflags_for_target=" -c"
2041     ;;
2042   mips*-*-pe | sh*-*-pe | *arm-wince-pe)
2043     target_makefile_frag="config/mt-wince"
2044     ;;
2045 esac
2046
2047 alphaieee_frag=/dev/null
2048 case $target in
2049   alpha*-*-*)
2050     # This just makes sure to use the -mieee option to build target libs.
2051     # This should probably be set individually by each library.
2052     alphaieee_frag="config/mt-alphaieee"
2053     ;;
2054 esac
2055
2056 # If --enable-target-optspace always use -Os instead of -O2 to build
2057 # the target libraries, similarly if it is not specified, use -Os
2058 # on selected platforms.
2059 ospace_frag=/dev/null
2060 case "${enable_target_optspace}:${target}" in
2061   yes:*)
2062     ospace_frag="config/mt-ospace"
2063     ;;
2064   :d30v-*)
2065     ospace_frag="config/mt-d30v"
2066     ;;
2067   :m32r-* | :d10v-* | :fr30-*)
2068     ospace_frag="config/mt-ospace"
2069     ;;
2070   no:* | :*)
2071     ;;
2072   *)
2073     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2074     ;;
2075 esac
2076
2077 # Default to using --with-stabs for certain targets.
2078 if test x${with_stabs} = x ; then
2079   case "${target}" in
2080   mips*-*-irix[[56]]*)
2081     ;;
2082   mips*-*-* | alpha*-*-osf*)
2083     with_stabs=yes;
2084     extra_host_args="${extra_host_args} --with-stabs"
2085     ;;
2086   esac
2087 fi
2088
2089 # hpux11 in 64bit mode has libraries in a weird place.  Arrange to find
2090 # them automatically.
2091 case "${host}" in
2092   hppa*64*-*-hpux11*)
2093     extra_host_args="$extra_host_args -x-libraries=/usr/lib/pa20_64 -x-includes=/usr/X11R6/include"
2094     ;;
2095 esac
2096
2097 # Some systems (e.g., one of the i386-aix systems the gas testers are
2098 # using) don't handle "\$" correctly, so don't use it here.
2099 tooldir='${exec_prefix}'/${target_noncanonical}
2100 build_tooldir=${tooldir}
2101
2102 # Create a .gdbinit file which runs the one in srcdir
2103 # and tells GDB to look there for source files.
2104
2105 if test -r ${srcdir}/.gdbinit ; then
2106   case ${srcdir} in
2107     .) ;;
2108     *) cat > ./.gdbinit <<EOF
2109 # ${NO_EDIT}
2110 dir ${srcdir}
2111 dir .
2112 source ${srcdir}/.gdbinit
2113 EOF
2114     ;;
2115   esac
2116 fi
2117
2118 # Make sure that the compiler is able to generate an executable.  If it
2119 # can't, we are probably in trouble.  We don't care whether we can run the
2120 # executable--we might be using a cross compiler--we only care whether it
2121 # can be created.  At this point the main configure script has set CC.
2122 we_are_ok=no
2123 echo "int main () { return 0; }" > conftest.c
2124 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2125 if test $? = 0 ; then
2126   if test -s conftest || test -s conftest.exe ; then
2127     we_are_ok=yes
2128   fi
2129 fi
2130 case $we_are_ok in
2131   no)
2132     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2133     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2134     rm -f conftest*
2135     exit 1
2136     ;;
2137 esac
2138 rm -f conftest*
2139
2140 # The Solaris /usr/ucb/cc compiler does not appear to work.
2141 case "${host}" in
2142   sparc-sun-solaris2*)
2143       CCBASE="`echo ${CC-cc} | sed 's/ .*$//'`"
2144       if test "`type $CCBASE | sed 's/^[[^/]]*//'`" = "/usr/ucb/cc" ; then
2145           could_use=
2146           test -d /opt/SUNWspro/bin && could_use="/opt/SUNWspro/bin"
2147           if test -d /opt/cygnus/bin ; then
2148               if test "$could_use" = "" ; then
2149                   could_use="/opt/cygnus/bin"
2150               else
2151                   could_use="$could_use or /opt/cygnus/bin"
2152               fi
2153           fi
2154         if test "$could_use" = "" ; then
2155             echo "Warning: compilation may fail because you're using"
2156             echo "/usr/ucb/cc.  You should change your PATH or CC "
2157             echo "variable and rerun configure."
2158         else
2159             echo "Warning: compilation may fail because you're using"
2160             echo "/usr/ucb/cc, when you should use the C compiler from"
2161             echo "$could_use.  You should change your"
2162             echo "PATH or CC variable and rerun configure."
2163         fi
2164       fi
2165   ;;
2166 esac
2167
2168 # Decide which environment variable is used to find dynamic libraries.
2169 case "${host}" in
2170   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2171   *-*-darwin* | *-*-rhapsody* ) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2172   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2173   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2174 esac
2175
2176 # On systems where the dynamic library environment variable is PATH,
2177 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2178 # built executables to PATH.
2179 if test "$RPATH_ENVVAR" = PATH; then
2180   GCC_SHLIB_SUBDIR=/shlib
2181 else
2182   GCC_SHLIB_SUBDIR=
2183 fi
2184
2185 # Record target_configdirs and the configure arguments for target and
2186 # build configuration in Makefile.
2187 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2188 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2189
2190 # Determine whether gdb needs tk/tcl or not.
2191 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2192 # and in that case we want gdb to be built without tk.  Ugh!
2193 # In fact I believe gdb is the *only* package directly dependent on tk,
2194 # so we should be able to put the 'maybe's in unconditionally and
2195 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2196 # 100% sure that that's safe though.
2197
2198 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2199 case "$enable_gdbtk" in
2200   no)
2201     GDB_TK="" ;;
2202   yes)
2203     GDB_TK="${gdb_tk}" ;;
2204   *)
2205     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2206     # distro.  Eventually someone will fix this and move Insight, nee
2207     # gdbtk to a separate directory.
2208     if test -d ${srcdir}/gdb/gdbtk ; then
2209       GDB_TK="${gdb_tk}"
2210     else
2211       GDB_TK=""
2212     fi
2213     ;;
2214 esac
2215 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2216 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2217
2218 # Strip out unwanted targets.
2219
2220 # While at that, we remove Makefiles if we were started for recursive
2221 # configuration, so that the top-level Makefile reconfigures them,
2222 # like we used to do when configure itself was recursive.
2223
2224 # Loop over modules.  $extrasub must be used with care, limiting as
2225 # much as possible the usage of range addresses.  That's because autoconf
2226 # splits the sed script to overcome limits in the number of commands,
2227 # and relying on carefully-timed sed passes may turn out to be very hard
2228 # to maintain later.  In this particular case, you just have to be careful
2229 # not to nest @if/@endif pairs, because configure will not warn you at all.
2230
2231 AC_ARG_ENABLE([bootstrap],
2232 [  --enable-bootstrap      enable bootstrapping @<:@yes if native build@:>@],,
2233 enable_bootstrap=default)
2234
2235 # Issue errors and warnings for invalid/strange bootstrap combinations.
2236 case "$configdirs" in
2237   *gcc*) have_compiler=yes ;;
2238   *) have_compiler=no ;;
2239 esac
2240
2241 case "$have_compiler:$host:$target:$enable_bootstrap" in
2242   *:*:*:no) ;;
2243
2244   # Default behavior.  Enable bootstrap if we have a compiler
2245   # and we are in a native configuration.
2246   yes:$build:$build:default)
2247     enable_bootstrap=yes ;;
2248
2249   *:*:*:default)
2250     enable_bootstrap=no ;;
2251
2252   # We have a compiler and we are in a native configuration, bootstrap is ok
2253   yes:$build:$build:yes)
2254     ;;
2255
2256   # Other configurations, but we have a compiler.  Assume the user knows
2257   # what he's doing.
2258   yes:*:*:yes)
2259     AC_MSG_WARN([trying to bootstrap a cross compiler])
2260     ;;
2261
2262   # No compiler: if they passed --enable-bootstrap explicitly, fail
2263   no:*:*:yes)
2264     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2265
2266   # Fail if wrong command line
2267   *)
2268     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2269     ;;
2270 esac
2271
2272 # Adjust the toplevel makefile according to whether bootstrap was selected.
2273 case "$enable_bootstrap" in
2274   yes)
2275     bootstrap_suffix=bootstrap ;;
2276   no)
2277     bootstrap_suffix=no-bootstrap ;;
2278 esac
2279
2280 for module in ${build_configdirs} ; do
2281   if test -z "${no_recursion}" \
2282      && test -f ${build_subdir}/${module}/Makefile; then
2283     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2284     rm -f ${build_subdir}/${module}/Makefile
2285   fi
2286   extrasub="$extrasub
2287 /^@if build-$module\$/d
2288 /^@endif build-$module\$/d
2289 /^@if build-$module-$bootstrap_suffix\$/d
2290 /^@endif build-$module-$bootstrap_suffix\$/d"
2291 done
2292 for module in ${configdirs} ; do
2293   if test -z "${no_recursion}"; then
2294     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2295       if test -f ${file}; then
2296         echo 1>&2 "*** removing ${file} to force reconfigure"
2297         rm -f ${file}
2298       fi
2299     done
2300   fi
2301   extrasub="$extrasub
2302 /^@if $module\$/d
2303 /^@endif $module\$/d
2304 /^@if $module-$bootstrap_suffix\$/d
2305 /^@endif $module-$bootstrap_suffix\$/d"
2306 done
2307 for module in ${target_configdirs} ; do
2308   if test -z "${no_recursion}" \
2309      && test -f ${target_subdir}/${module}/Makefile; then
2310     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2311     rm -f ${target_subdir}/${module}/Makefile
2312   fi
2313   extrasub="$extrasub
2314 /^@if target-$module\$/d
2315 /^@endif target-$module\$/d
2316 /^@if target-$module-$bootstrap_suffix\$/d
2317 /^@endif target-$module-$bootstrap_suffix\$/d"
2318 done
2319
2320 extrasub="$extrasub
2321 /^@if /,/^@endif /d"
2322
2323 # Create the serialization dependencies.  This uses a temporary file.
2324
2325 AC_ARG_ENABLE([serial-configure],
2326 [  --enable-serial-@<:@{host,target,build}-@:>@configure
2327                           force sequential configuration of
2328                           sub-packages for the host, target or build
2329                           machine, or all sub-packages])
2330
2331 case ${enable_serial_configure} in
2332   yes)
2333     enable_serial_build_configure=yes
2334     enable_serial_host_configure=yes
2335     enable_serial_target_configure=yes
2336     ;;
2337 esac
2338
2339 # These force 'configure's to be done one at a time, to avoid problems
2340 # with contention over a shared config.cache.
2341 rm -f serdep.tmp
2342 echo '# serdep.tmp' > serdep.tmp
2343 olditem=
2344 test "x${enable_serial_build_configure}" = xyes &&
2345 for item in ${build_configdirs} ; do
2346   case ${olditem} in
2347     "") ;;
2348     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2349   esac
2350   olditem=${item}
2351 done
2352 olditem=
2353 test "x${enable_serial_host_configure}" = xyes &&
2354 for item in ${configdirs} ; do
2355   case ${olditem} in
2356     "") ;;
2357     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2358   esac
2359   olditem=${item}
2360 done
2361 olditem=
2362 test "x${enable_serial_target_configure}" = xyes &&
2363 for item in ${target_configdirs} ; do
2364   case ${olditem} in
2365     "") ;;
2366     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2367   esac
2368   olditem=${item}
2369 done
2370 serialization_dependencies=serdep.tmp
2371 AC_SUBST_FILE(serialization_dependencies)
2372
2373 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2374 # target, nonopt, and variable assignments.  These are the ones we
2375 # might not want to pass down to subconfigures.  Also strip
2376 # program-prefix, program-suffix, and program-transform-name, so that
2377 # we can pass down a consistent program-transform-name.
2378 baseargs=
2379 keep_next=no
2380 skip_next=no
2381 eval "set -- $ac_configure_args"
2382 for ac_arg
2383 do
2384   if test X"$skip_next" = X"yes"; then
2385     skip_next=no
2386     continue
2387   fi
2388   if test X"$keep_next" = X"yes"; then
2389     case $ac_arg in
2390       *\'*)
2391         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2392     esac
2393     baseargs="$baseargs '$ac_arg'"
2394     keep_next=no
2395     continue
2396   fi
2397
2398   # Handle separated arguments.  Based on the logic generated by
2399   # autoconf 2.59.
2400   case $ac_arg in
2401     *=* | --config-cache | -C | -disable-* | --disable-* \
2402       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2403       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2404       | -with-* | --with-* | -without-* | --without-* | --x)
2405       separate_arg=no
2406       ;;
2407     -*)
2408       separate_arg=yes
2409       ;;
2410     *)
2411       separate_arg=no
2412       ;;
2413   esac
2414
2415   case "$ac_arg" in
2416     --no*)
2417       continue
2418       ;;
2419     --c* | \
2420     --sr* | \
2421     --ho* | \
2422     --bu* | \
2423     --t* | \
2424     --program-* | \
2425     -cache_file* | \
2426     -srcdir* | \
2427     -host* | \
2428     -build* | \
2429     -target* | \
2430     -program-prefix* | \
2431     -program-suffix* | \
2432     -program-transform-name* )
2433       skip_next=$separate_arg
2434       continue
2435       ;;
2436     -*)
2437       # An option.  Add it.
2438       case $ac_arg in
2439         *\'*)
2440           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2441       esac
2442       baseargs="$baseargs '$ac_arg'"
2443       keep_next=$separate_arg
2444       ;;
2445     *)
2446       # Either a variable assignment, or a nonopt (triplet).  Don't
2447       # pass it down; let the Makefile handle this.
2448       continue
2449       ;;
2450   esac
2451 done
2452 # Remove the initial space we just introduced and, as these will be
2453 # expanded by make, quote '$'.
2454 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2455
2456 # Add in --program-transform-name, after --program-prefix and
2457 # --program-suffix have been applied to it.  Autoconf has already
2458 # doubled dollar signs and backslashes in program_transform_name; we want
2459 # the backslashes un-doubled, and then the entire thing wrapped in single
2460 # quotes, because this will be expanded first by make and then by the shell.
2461 # Also, because we want to override the logic in subdir configure scripts to
2462 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2463 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2464 ${program_transform_name}
2465 EOF_SED
2466 gcc_transform_name=`cat conftestsed.out`
2467 rm -f conftestsed.out
2468 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2469 if test "$silent" = yes; then
2470   baseargs="$baseargs --silent"
2471 fi
2472
2473 # For the build-side libraries, we just need to pretend we're native,
2474 # and not use the same cache file.  Multilibs are neither needed nor
2475 # desired.
2476 build_configargs="--cache-file=../config.cache ${baseargs}"
2477
2478 # For host modules, accept cache file option, or specification as blank.
2479 case "${cache_file}" in
2480 "") # empty
2481   cache_file_option="" ;;
2482 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2483   cache_file_option="--cache-file=${cache_file}" ;;
2484 *) # relative path
2485   cache_file_option="--cache-file=../${cache_file}" ;;
2486 esac
2487
2488 # Host dirs don't like to share a cache file either, horribly enough.
2489 # This seems to be due to autoconf 2.5x stupidity.
2490 host_configargs="--cache-file=./config.cache ${extra_host_args} ${baseargs}"
2491
2492 target_configargs=${baseargs}
2493
2494 # Passing a --with-cross-host argument lets the target libraries know
2495 # whether they are being built with a cross-compiler or being built
2496 # native.  However, it would be better to use other mechanisms to make the
2497 # sorts of decisions they want to make on this basis.  Please consider
2498 # this option to be deprecated.  FIXME.
2499 if test x${is_cross_compiler} = xyes ; then
2500   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2501 fi
2502
2503 # Default to --enable-multilib.
2504 if test x${enable_multilib} = x ; then
2505   target_configargs="--enable-multilib ${target_configargs}"
2506 fi
2507
2508 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2509 # changed from the earlier setting of with_newlib.
2510 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2511   target_configargs="--with-newlib ${target_configargs}"
2512 fi
2513
2514 # Different target subdirs use different values of certain variables
2515 # (notably CXX).  Worse, multilibs use *lots* of different values.
2516 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2517 # it doesn't automatically accept command-line overrides of them.
2518 # This means it's not safe for target subdirs to share a cache file,
2519 # which is disgusting, but there you have it.  Hopefully this can be
2520 # fixed in future.  It's still worthwhile to use a cache file for each
2521 # directory.  I think.
2522
2523 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2524 # We need to pass --target, as newer autoconf's requires consistency
2525 # for target_alias and gcc doesn't manage it consistently.
2526 target_configargs="--cache-file=./config.cache ${target_configargs}"
2527
2528 FLAGS_FOR_TARGET=
2529 case " $target_configdirs " in
2530  *" newlib "*)
2531   case " $target_configargs " in
2532   *" --with-newlib "*)
2533    case "$target" in
2534    *-cygwin*)
2535      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include' ;;
2536    esac
2537
2538    # If we're not building GCC, don't discard standard headers.
2539    if test -d ${srcdir}/gcc; then
2540      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2541
2542      if test "${build}" != "${host}"; then
2543        # On Canadian crosses, CC_FOR_TARGET will have already been set
2544        # by `configure', so we won't have an opportunity to add -Bgcc/
2545        # to it.  This is right: we don't want to search that directory
2546        # for binaries, but we want the header files in there, so add
2547        # them explicitly.
2548        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include'
2549
2550        # Someone might think of using the pre-installed headers on
2551        # Canadian crosses, in case the installed compiler is not fully
2552        # compatible with the compiler being built.  In this case, it
2553        # would be better to flag an error than risking having
2554        # incompatible object files being constructed.  We can't
2555        # guarantee that an error will be flagged, but let's hope the
2556        # compiler will do it, when presented with incompatible header
2557        # files.
2558      fi
2559    fi
2560
2561    case "${target}-${is_cross_compiler}" in
2562    i[[3456789]]86-*-linux*-no)
2563       # Here host == target, so we don't need to build gcc,
2564       # so we don't want to discard standard headers.
2565       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2566       ;;
2567    *)
2568       # If we're building newlib, use its generic headers last, but search
2569       # for any libc-related directories first (so make it the last -B
2570       # switch).
2571       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2572
2573       # If we're building libgloss, find the startup file, simulator library
2574       # and linker script.
2575       case " $target_configdirs " in
2576         *" libgloss "*)
2577         # Look for startup file, simulator library and maybe linker script.
2578         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2579         # Look for libnosys.a in case the target needs it.
2580         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2581         # Most targets have the linker script in the source directory.
2582         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2583         ;;
2584       esac
2585       ;;
2586    esac
2587    ;;
2588   esac
2589   ;;
2590 esac
2591 case "$target" in
2592 *-mingw*)
2593   # Can't be handled as Cygwin above since Mingw does not use newlib.
2594   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include' ;;
2595 esac
2596
2597 # Allow the user to override the flags for
2598 # our build compiler if desired.
2599 if test x"${build}" = x"${host}" ; then
2600   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2601   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
2602   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2603   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2604 fi
2605
2606 # On Canadian crosses, we'll be searching the right directories for
2607 # the previously-installed cross compiler, so don't bother to add
2608 # flags for directories within the install tree of the compiler
2609 # being built; programs in there won't even run.
2610 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2611   # Search for pre-installed headers if nothing else fits.
2612   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2613 fi
2614
2615 if test "x${use_gnu_ld}" = x &&
2616    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2617   # Arrange for us to find uninstalled linker scripts.
2618   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2619 fi
2620
2621 # Search for other target-specific linker scripts and such.
2622 case "${target}" in
2623   mep*)
2624     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2625     ;;
2626 esac
2627
2628 # Makefile fragments.
2629 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2630 do
2631   eval fragval=\$$frag
2632   if test $fragval != /dev/null; then
2633     eval $frag=${srcdir}/$fragval
2634   fi
2635 done
2636 AC_SUBST_FILE(host_makefile_frag)
2637 AC_SUBST_FILE(target_makefile_frag)
2638 AC_SUBST_FILE(alphaieee_frag)
2639 AC_SUBST_FILE(ospace_frag)
2640
2641 # Miscellanea: directories, flags, etc.
2642 AC_SUBST(RPATH_ENVVAR)
2643 AC_SUBST(GCC_SHLIB_SUBDIR)
2644 AC_SUBST(tooldir)
2645 AC_SUBST(build_tooldir)
2646 AC_SUBST(CONFIGURE_GDB_TK)
2647 AC_SUBST(GDB_TK)
2648 AC_SUBST(INSTALL_GDB_TK)
2649
2650 # Build module lists & subconfigure args.
2651 AC_SUBST(build_configargs)
2652 AC_SUBST(build_configdirs)
2653
2654 # Host module lists & subconfigure args.
2655 AC_SUBST(host_configargs)
2656 AC_SUBST(configdirs)
2657
2658 # Target module lists & subconfigure args.
2659 AC_SUBST(target_configargs)
2660
2661
2662 # Build tools.
2663 AC_SUBST(AR_FOR_BUILD)
2664 AC_SUBST(AS_FOR_BUILD)
2665 AC_SUBST(CC_FOR_BUILD)
2666 AC_SUBST(CFLAGS_FOR_BUILD)
2667 AC_SUBST(CPPFLAGS_FOR_BUILD)
2668 AC_SUBST(CXXFLAGS_FOR_BUILD)
2669 AC_SUBST(CXX_FOR_BUILD)
2670 AC_SUBST(DLLTOOL_FOR_BUILD)
2671 AC_SUBST(GCJ_FOR_BUILD)
2672 AC_SUBST(GFORTRAN_FOR_BUILD)
2673 AC_SUBST(LDFLAGS_FOR_BUILD)
2674 AC_SUBST(LD_FOR_BUILD)
2675 AC_SUBST(NM_FOR_BUILD)
2676 AC_SUBST(RANLIB_FOR_BUILD)
2677 AC_SUBST(WINDMC_FOR_BUILD)
2678 AC_SUBST(WINDRES_FOR_BUILD)
2679 AC_SUBST(config_shell)
2680
2681 # Generate default definitions for YACC, M4, LEX and other programs that run
2682 # on the build machine.  These are used if the Makefile can't locate these
2683 # programs in objdir.
2684 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2685
2686 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2687 case " $build_configdirs " in
2688   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2689   *" byacc "*) YACC='$$r/$(BUILD_SUBDIR)/byacc/byacc' ;;
2690 esac
2691
2692 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2693 case " $build_configdirs " in
2694   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2695 esac
2696
2697 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
2698 case " $build_configdirs " in
2699   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
2700 esac
2701
2702 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
2703 case " $build_configdirs " in
2704   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2705   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
2706 esac
2707
2708 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
2709 case " $build_configdirs " in
2710   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2711 esac
2712
2713 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
2714 case " $build_configdirs " in
2715   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
2716   *)
2717 changequote(,)
2718     # For an installed makeinfo, we require it to be from texinfo 4.6 or
2719     # higher, else we use the "missing" dummy.
2720     if ${MAKEINFO} --version \
2721        | egrep 'texinfo[^0-9]*(4\.([6-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
2722       :
2723     else
2724       MAKEINFO="$MISSING makeinfo"
2725     fi
2726     ;;
2727 changequote([,])
2728 esac
2729
2730 # FIXME: expect and dejagnu may become build tools?
2731
2732 AC_CHECK_PROGS(EXPECT, expect, expect)
2733 case " $configdirs " in
2734   *" expect "*)
2735     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
2736     ;;
2737 esac
2738
2739 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
2740 case " $configdirs " in
2741   *" dejagnu "*)
2742     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
2743     ;;
2744 esac
2745
2746
2747 # Host tools.
2748 NCN_STRICT_CHECK_TOOLS(AR, ar)
2749 NCN_STRICT_CHECK_TOOLS(AS, as)
2750 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
2751 NCN_STRICT_CHECK_TOOLS(LD, ld)
2752 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
2753 NCN_STRICT_CHECK_TOOLS(NM, nm)
2754 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, :)
2755 NCN_STRICT_CHECK_TOOLS(STRIP, strip, :)
2756 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
2757 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
2758 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
2759 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
2760 AC_SUBST(CC)
2761 AC_SUBST(CXX)
2762 AC_SUBST(CFLAGS)
2763 AC_SUBST(CXXFLAGS)
2764
2765 # Target tools.
2766 AC_ARG_WITH([build-time-tools],
2767   [  --with-build-time-tools=PATH
2768                           use given path to find target tools during the build],
2769   [case x"$withval" in
2770      x/*) ;;
2771      *)
2772        with_build_time_tools=
2773        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
2774        ;;
2775    esac],
2776   [with_build_time_tools=])
2777
2778 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
2779 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
2780 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
2781 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
2782 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
2783
2784 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
2785 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
2786 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
2787 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
2788 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
2789 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
2790 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
2791 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib, :)
2792 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
2793 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
2794 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
2795
2796 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
2797
2798 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
2799 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
2800 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
2801 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
2802                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `test ! -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags || $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
2803                 c++)
2804 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
2805                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
2806                 c++)
2807 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
2808 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
2809 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
2810                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
2811 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
2812                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
2813 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
2814 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
2815 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
2816 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
2817 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
2818 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip])
2819 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
2820 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
2821
2822 AC_SUBST(FLAGS_FOR_TARGET)
2823 AC_SUBST(RAW_CXX_FOR_TARGET)
2824
2825 # Certain tools may need extra flags.
2826 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
2827 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
2828 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
2829
2830 # When building target libraries, except in a Canadian cross, we use
2831 # the same toolchain as the compiler we just built.
2832 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
2833 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
2834 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
2835 if test $host = $build; then
2836   case " $configdirs " in
2837     *" gcc "*)
2838       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
2839       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
2840       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
2841       ;;
2842   esac
2843 fi
2844
2845 AC_SUBST(COMPILER_AS_FOR_TARGET)
2846 AC_SUBST(COMPILER_LD_FOR_TARGET)
2847 AC_SUBST(COMPILER_NM_FOR_TARGET)
2848
2849 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2850 AC_ARG_ENABLE(maintainer-mode,
2851 [  --enable-maintainer-mode enable make rules and dependencies not useful
2852                           (and sometimes confusing) to the casual installer],
2853       USE_MAINTAINER_MODE=$enableval,
2854       USE_MAINTAINER_MODE=no)
2855 AC_MSG_RESULT($USE_MAINTAINER_MODE)
2856 AC_SUBST(MAINTAINER_MODE_TRUE)
2857 AC_SUBST(MAINTAINER_MODE_FALSE)
2858 if test "$USE_MAINTAINER_MODE" = yes; then
2859   MAINTAINER_MODE_TRUE=
2860   MAINTAINER_MODE_FALSE='#'
2861 else
2862   MAINTAINER_MODE_TRUE='#'
2863   MAINTAINER_MODE_FALSE=
2864 fi
2865 MAINT=$MAINTAINER_MODE_TRUE
2866 AC_SUBST(MAINT)dnl
2867
2868 # ---------------------
2869 # GCC bootstrap support
2870 # ---------------------
2871
2872 # Stage specific cflags for build.
2873 stage1_cflags="-g"
2874 case $build in
2875   vax-*-*)
2876     case ${GCC} in
2877       yes) stage1_cflags="-g -Wa,-J" ;;
2878       *) stage1_cflags="-g -J" ;;
2879     esac ;;
2880 esac
2881
2882 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
2883 if test "$GCC" = yes; then
2884   saved_CFLAGS="$CFLAGS"
2885
2886   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
2887   CFLAGS="$CFLAGS -fkeep-inline-functions"
2888   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
2889   AC_TRY_COMPILE([
2890 #if (__GNUC__ < 3) \
2891     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
2892                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
2893 #error http://gcc.gnu.org/PR29382
2894 #endif
2895     ],,
2896     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
2897     [AC_MSG_RESULT([no])])
2898
2899   CFLAGS="$saved_CFLAGS"
2900 fi
2901
2902 AC_SUBST(stage1_cflags)
2903
2904 # Enable --enable-checking in stage1 of the compiler.
2905 AC_ARG_ENABLE(stage1-checking,
2906 [  --enable-stage1-checking@<:@=all@:>@   choose additional checking for stage1
2907                           of the compiler],
2908 [stage1_checking=--enable-checking=${enable_stage1_checking}],
2909 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
2910   stage1_checking=--enable-checking=yes,types
2911 else
2912   stage1_checking=--enable-checking=$enable_checking,types
2913 fi])
2914 AC_SUBST(stage1_checking)
2915
2916 # Enable -Werror in bootstrap stage2 and later.
2917 AC_ARG_ENABLE(werror,
2918 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
2919 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
2920   enable_werror=yes
2921 else
2922   enable_werror=no
2923 fi])
2924 case ${enable_werror} in
2925   yes) stage2_werror_flag="--enable-werror-always" ;;
2926   *) stage2_werror_flag="" ;;
2927 esac
2928 AC_SUBST(stage2_werror_flag)
2929
2930 # Flags needed to enable html installing and building
2931 AC_ARG_WITH(datarootdir,
2932 [  --with-datarootdir      use datarootdir as the data root directory.],
2933 [datarootdir="\${prefix}/${withval}"],
2934 [datarootdir="\${prefix}/share"])
2935
2936 AC_ARG_WITH(docdir,
2937 [  --with-docdir           install documentation in this directory.],
2938 [docdir="\${prefix}/${withval}"],
2939 [docdir="\${datarootdir}/doc"])
2940
2941 AC_ARG_WITH(pdfdir,
2942 [  --with-pdfdir           install pdf in this directory.],
2943 [pdfdir="\${prefix}/${withval}"],
2944 [pdfdir="\${docdir}"])
2945
2946 AC_ARG_WITH(htmldir,
2947 [  --with-htmldir          install html in this directory.],
2948 [htmldir="\${prefix}/${withval}"],
2949 [htmldir="\${docdir}"])
2950
2951 AC_SUBST(datarootdir)
2952 AC_SUBST(docdir)
2953 AC_SUBST(pdfdir)
2954 AC_SUBST(htmldir)
2955
2956 AC_OUTPUT(Makefile)