OSDN Git Service

* configure.ac (*-*-dragonfly*, *-*-freebsd*, *-*-netbsd*,
[pf3gnuchains/gcc-fork.git] / configure.ac
1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
3 #   Free Software Foundation, Inc.
4 #
5 # This file is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License as published by
7 # the Free Software Foundation; either version 3 of the License, or
8 # (at your option) any later version.
9 #
10 # This program is distributed in the hope that it will be useful, but
11 # WITHOUT ANY WARRANTY; without even the implied warranty of
12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
13 # General Public License for more details.
14 #
15 # You should have received a copy of the GNU General Public License
16 # along with this program; see the file COPYING3.  If not see
17 # <http://www.gnu.org/licenses/>.
18
19 ##############################################################################
20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
21
22 m4_include(config/acx.m4)
23 m4_include(config/override.m4)
24 m4_include(config/proginstall.m4)
25 m4_include(config/elf.m4)
26 m4_include([libtool.m4])
27 m4_include([ltoptions.m4])
28 m4_include([ltsugar.m4])
29 m4_include([ltversion.m4])
30 m4_include([lt~obsolete.m4])
31 m4_include([config/cloog.m4])
32
33 AC_INIT(move-if-change)
34 AC_PREREQ(2.64)
35 AC_DISABLE_OPTION_CHECKING
36
37 progname=$0
38 # if PWD already has a value, it is probably wrong.
39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
40
41 # Export original configure arguments for use by sub-configures.
42 # Quote arguments with shell meta charatcers.
43 TOPLEVEL_CONFIGURE_ARGUMENTS=
44 set -- "$progname" "$@"
45 for ac_arg
46 do
47   case "$ac_arg" in
48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
50     # if the argument is of the form -foo=baz, quote the baz part only
51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
52   *) ;;
53   esac
54   # Add the quoted argument to the list.
55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
56 done
57 if test "$silent" = yes; then
58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
59 fi
60 # Remove the initial space we just introduced and, as these will be
61 # expanded by make, quote '$'.
62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
64
65 # Find the build, host, and target systems.
66 ACX_NONCANONICAL_BUILD
67 ACX_NONCANONICAL_HOST
68 ACX_NONCANONICAL_TARGET
69
70 dnl Autoconf 2.5x and later will set a default program prefix if
71 dnl --target was used, even if it was the same as --host.  Disable
72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
73 dnl to take effect.
74 test "$host_noncanonical" = "$target_noncanonical" &&
75   test "$program_prefix$program_suffix$program_transform_name" = \
76     NONENONEs,x,x, &&
77   program_transform_name=s,y,y,
78
79 AC_CANONICAL_SYSTEM
80 AC_ARG_PROGRAM
81
82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
84
85 # Get 'install' or 'install-sh' and its variants.
86 AC_PROG_INSTALL
87 ACX_PROG_LN
88 AC_PROG_LN_S
89 AC_PROG_SED
90 AC_PROG_AWK
91
92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
93
94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
95 # a relative path.
96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
97   INSTALL="${srcpwd}/install-sh -c"
98 fi
99
100 # Set srcdir to "." if that's what it is.
101 # This is important for multilib support.
102 pwd=`${PWDCMD-pwd}`
103 if test "${pwd}" = "${srcpwd}" ; then
104   srcdir=.
105 fi
106
107 topsrcdir=$srcpwd
108
109 extra_host_args=
110
111 ### To add a new directory to the tree, first choose whether it is a target
112 ### or a host dependent tool.  Then put it into the appropriate list
113 ### (library or tools, host or target), doing a dependency sort.
114
115 # Subdirs will be configured in the order listed in build_configdirs, 
116 # configdirs, or target_configdirs; see the serialization section below.
117
118 # Dependency sorting is only needed when *configuration* must be done in 
119 # a particular order.  In all cases a dependency should be specified in 
120 # the Makefile, whether or not it's implicitly specified here.
121
122 # Double entries in build_configdirs, configdirs, or target_configdirs may
123 # cause circular dependencies and break everything horribly.
124
125 # these library is used by various programs built for the build
126 # environment
127 #
128 build_libs="build-libiberty"
129
130 # these tools are built for the build environment
131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
132
133 # these libraries are used by various programs built for the host environment
134 #
135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
136
137 # these tools are built for the host environment
138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
139 # know that we are building the simulator.
140 # binutils, gas and ld appear in that order because it makes sense to run
141 # "make check" in that particular order.
142 # If --enable-gold is used, "gold" may replace "ld".
143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
144
145 # libgcj represents the runtime libraries only used by gcj.
146 libgcj="target-libffi \
147         target-zlib \
148         target-libjava"
149
150 # these libraries are built for the target environment, and are built after
151 # the host libraries and the host tools (which may be a cross compiler)
152 #
153 target_libraries="target-libgcc \
154                 target-libiberty \
155                 target-libgloss \
156                 target-newlib \
157                 target-libgomp \
158                 target-libstdc++-v3 \
159                 target-libmudflap \
160                 target-libssp \
161                 target-libquadmath \
162                 target-libgfortran \
163                 target-boehm-gc \
164                 ${libgcj} \
165                 target-libobjc \
166                 target-libada \
167                 target-libgo"
168
169 # these tools are built using the target libraries, and are intended to
170 # run only in the target environment
171 #
172 # note: any program that *uses* libraries that are in the "target_libraries"
173 # list belongs in this list.
174 #
175 target_tools="target-rda"
176
177 ################################################################################
178
179 ## All tools belong in one of the four categories, and are assigned above
180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
181 ## is important because configure will choke if they ever get through.
182 ## ${configdirs} is directories we build using the host tools.
183 ## ${target_configdirs} is directories we build using the target tools.
184 configdirs=`echo ${host_libs} ${host_tools}`
185 target_configdirs=`echo ${target_libraries} ${target_tools}`
186 build_configdirs=`echo ${build_libs} ${build_tools}`
187
188 m4_divert_text([PARSE_ARGS],
189 [case $srcdir in
190   *" "*)
191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
194     ;;
195 esac
196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
197 ])
198
199 ################################################################################
200
201 srcname="gnu development package"
202
203 # This gets set non-empty for some net releases of packages.
204 appdirs=""
205
206 # Define is_cross_compiler to save on calls to 'test'.
207 is_cross_compiler=
208 if test x"${host}" = x"${target}" ; then
209   is_cross_compiler=no
210 else
211   is_cross_compiler=yes
212 fi      
213
214 # Find the build and target subdir names.
215 GCC_TOPLEV_SUBDIRS
216 # Be sure to cover against remnants of an in-tree build.
217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
219 Use a pristine source tree when building in a separate tree])
220 fi
221
222 # Skipdirs are removed silently.
223 skipdirs=
224 # Noconfigdirs are removed loudly.
225 noconfigdirs=""
226
227 use_gnu_ld=
228 # Make sure we don't let GNU ld be added if we didn't want it.
229 if test x$with_gnu_ld = xno ; then
230   use_gnu_ld=no
231   noconfigdirs="$noconfigdirs ld gold"
232 fi
233
234 use_gnu_as=
235 # Make sure we don't let GNU as be added if we didn't want it.
236 if test x$with_gnu_as = xno ; then
237   use_gnu_as=no
238   noconfigdirs="$noconfigdirs gas"
239 fi
240
241 use_included_zlib=
242 # Make sure we don't let ZLIB be added if we didn't want it.
243 if test x$with_system_zlib = xyes ; then
244   use_included_zlib=no
245   noconfigdirs="$noconfigdirs zlib"
246 fi
247
248 # some tools are so dependent upon X11 that if we're not building with X, 
249 # it's not even worth trying to configure, much less build, that tool.
250
251 case ${with_x} in
252   yes | "") ;; # the default value for this tree is that X11 is available
253   no)
254     skipdirs="${skipdirs} tk itcl libgui"
255     # We won't be able to build gdbtk without X.
256     enable_gdbtk=no 
257     ;;
258   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
259 esac
260
261 # Some are only suitable for cross toolchains.
262 # Remove these if host=target.
263 cross_only="target-libgloss target-newlib target-opcodes"
264
265 case $is_cross_compiler in
266   no) skipdirs="${skipdirs} ${cross_only}" ;;
267 esac
268
269 # If both --with-headers and --with-libs are specified, default to
270 # --without-newlib.
271 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
272    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
273   if test x"${with_newlib}" = x ; then
274     with_newlib=no
275   fi
276 fi
277
278 # Recognize --with-newlib/--without-newlib.
279 case ${with_newlib} in
280   no) skipdirs="${skipdirs} target-newlib" ;;
281   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
282 esac
283
284 # Handle --enable-gold, --enable-ld.
285 # --disable-gold [--enable-ld]
286 #     Build only ld.  Default option.
287 # --enable-gold [--enable-ld]
288 #     Build both gold and ld.  Install gold as "ld.gold", install ld
289 #     as "ld.bfd" and "ld".
290 # --enable-gold=default [--enable-ld]
291 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
292 #     install ld as "ld.bfd".
293 # --enable-gold[=default] --disable-ld
294 #     Build only gold, which is then installed as both "ld.gold" and "ld".
295 # --enable-gold --enable-ld=default
296 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
297 #     and ld.bfd).
298 #     In other words, ld is default
299 # --enable-gold=default --enable-ld=default
300 #     Error.
301
302 default_ld=
303 AC_ARG_ENABLE(gold,
304 [AS_HELP_STRING([[--enable-gold[=ARG]]],
305                 [build gold @<:@ARG={default,yes,no}@:>@])],
306 ENABLE_GOLD=$enableval,
307 ENABLE_GOLD=no)
308 case "${ENABLE_GOLD}" in
309   yes|default)
310     # Check for ELF target.
311     is_elf=no
312     case "${target}" in
313       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
314       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
315       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
316       | *-*-solaris2* | *-*-nto*)
317         case "${target}" in
318           *-*-linux*aout* | *-*-linux*oldld*)
319             ;;
320           *)
321             is_elf=yes
322             ;;
323         esac
324     esac
325
326     if test "$is_elf" = "yes"; then
327       # Check for target supported by gold.
328       case "${target}" in
329         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
330           configdirs="$configdirs gold"
331           if test x${ENABLE_GOLD} = xdefault; then
332             default_ld=gold
333           fi
334           ENABLE_GOLD=yes
335           ;;
336       esac
337     fi
338     ;;
339   no)
340     ;;
341   *)
342     AC_MSG_ERROR([invalid --enable-gold argument])
343     ;;
344 esac
345
346 AC_ARG_ENABLE(ld,
347 [AS_HELP_STRING([[--enable-ld[=ARG]]],
348                 [build ld @<:@ARG={default,yes,no}@:>@])],
349 ENABLE_LD=$enableval,
350 ENABLE_LD=yes)
351
352 case "${ENABLE_LD}" in
353   default)
354     if test x${default_ld} != x; then
355       AC_MSG_ERROR([either gold or ld can be the default ld])
356     fi
357     ;;
358   yes)
359     ;;
360   no)
361     if test x${ENABLE_GOLD} != xyes; then
362       AC_MSG_WARN([neither ld nor gold are enabled])
363     fi
364     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
365     ;;
366   *)
367     AC_MSG_ERROR([invalid --enable-ld argument])
368     ;;
369 esac
370
371 # Configure extra directories which are host specific
372
373 case "${host}" in
374   *-cygwin*)
375     configdirs="$configdirs libtermcap" ;;
376 esac
377
378 # A target can indicate whether a language isn't supported for some reason.
379 # Only spaces may be used in this macro; not newlines or tabs.
380 unsupported_languages=
381
382 # Remove more programs from consideration, based on the host or 
383 # target this usually means that a port of the program doesn't
384 # exist yet.
385
386 case "${host}" in
387   i[[3456789]]86-*-msdosdjgpp*)
388     noconfigdirs="$noconfigdirs tcl tk itcl"
389     ;;
390 esac
391
392
393 AC_ARG_ENABLE(libquadmath,
394 AS_HELP_STRING([--disable-libquadmath],
395   [do not build libquadmath directory]),
396 ENABLE_LIBQUADMATH=$enableval,
397 ENABLE_LIBQUADMATH=yes)
398 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
399   noconfigdirs="$noconfigdirs target-libquadmath"
400 fi
401
402
403 AC_ARG_ENABLE(libquadmath-support,
404 AS_HELP_STRING([--disable-libquadmath-support],
405   [disable libquadmath support for Fortran]),
406 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
407 ENABLE_LIBQUADMATH_SUPPORT=yes)
408 enable_libquadmath_support=
409 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
410   enable_libquadmath_support=no
411 fi
412
413
414 AC_ARG_ENABLE(libada,
415 [AS_HELP_STRING([--enable-libada], [build libada directory])],
416 ENABLE_LIBADA=$enableval,
417 ENABLE_LIBADA=yes)
418 if test "${ENABLE_LIBADA}" != "yes" ; then
419   noconfigdirs="$noconfigdirs gnattools"
420 fi
421
422 AC_ARG_ENABLE(libssp,
423 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
424 ENABLE_LIBSSP=$enableval,
425 ENABLE_LIBSSP=yes)
426
427 # Save it here so that, even in case of --enable-libgcj, if the Java
428 # front-end isn't enabled, we still get libgcj disabled.
429 libgcj_saved=$libgcj
430 case $enable_libgcj in
431 yes)
432   # If we reset it here, it won't get added to noconfigdirs in the
433   # target-specific build rules, so it will be forcibly enabled
434   # (unless the Java language itself isn't enabled).
435   libgcj=
436   ;;
437 no)
438   # Make sure we get it printed in the list of not supported target libs.
439   # Don't disable libffi, though, other languages use it.
440   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
441   # Clear libgcj_saved so that even if java is enabled libffi won't be
442   # built.
443   libgcj_saved=
444   ;;
445 esac
446
447
448 # Disable libmudflap on some systems.
449 if test x$enable_libmudflap = x ; then
450     case "${target}" in
451     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
452         # Enable libmudflap by default in GNU and friends.
453         ;;
454     *-*-freebsd*)
455         # Enable libmudflap by default in FreeBSD.
456         ;;
457     *)
458         # Disable it by default everywhere else.
459         noconfigdirs="$noconfigdirs target-libmudflap"
460         ;;
461     esac
462 fi
463
464 # Disable libgomp on non POSIX hosted systems.
465 if test x$enable_libgomp = x ; then
466     # Enable libgomp by default on hosted POSIX systems.
467     case "${target}" in
468     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
469         ;;
470     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
471         ;;
472     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
473         ;;
474     *-*-darwin* | *-*-aix*)
475         ;;
476     *)
477         noconfigdirs="$noconfigdirs target-libgomp"
478         ;;
479     esac
480 fi
481
482 # Disable libssp for some systems.
483 case "${target}" in
484   avr-*-*)
485     # No hosted I/O support.
486     noconfigdirs="$noconfigdirs target-libssp"
487     ;;
488   powerpc-*-aix* | rs6000-*-aix*)
489     noconfigdirs="$noconfigdirs target-libssp"
490     ;;
491 esac
492
493 # Disable target libiberty for some systems.
494 case "${target}" in
495   *-*-kaos*)
496     # Remove unsupported stuff on all kaOS configurations.
497     skipdirs="target-libiberty"
498     ;;
499   *-*-netbsd*)
500     # Skip some stuff on all NetBSD configurations.
501     noconfigdirs="$noconfigdirs target-libiberty"
502     ;;
503   *-*-netware*)
504     noconfigdirs="$noconfigdirs target-libiberty"
505     ;;
506   *-*-rtems*)
507     skipdirs="${skipdirs} target-libiberty"
508     ;;
509   *-*-tpf*)
510     noconfigdirs="$noconfigdirs target-libiberty"
511     ;;
512   *-*-vxworks*)
513     noconfigdirs="$noconfigdirs target-libiberty"
514     ;;
515   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
516     noconfigdirs="$noconfigdirs target-libiberty"
517     ;;
518   arm*-*-symbianelf*)
519     noconfigdirs="$noconfigdirs target-libiberty"
520     ;;
521   avr-*-*)
522     noconfigdirs="$noconfigdirs target-libiberty"
523     ;;
524   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
525     noconfigdirs="$noconfigdirs target-libiberty"
526     ;;
527   picochip-*-*)
528     noconfigdirs="$noconfigdirs target-libiberty"
529     ;;
530   mips*-sde-elf*)
531     skipdirs="$skipdirs target-libiberty"
532     ;;
533   ip2k-*-*)
534     noconfigdirs="$noconfigdirs target-libiberty"
535     ;;
536 esac
537
538 # Disable libstdc++-v3 for some systems.
539 case "${target}" in
540   *-*-vxworks*)
541     # VxWorks uses the Dinkumware C++ library.
542     noconfigdirs="$noconfigdirs target-libstdc++-v3"
543     ;;
544   arm*-wince-pe*)
545     # the C++ libraries don't build on top of CE's C libraries
546     noconfigdirs="$noconfigdirs target-libstdc++-v3"
547     ;;
548   avr-*-*)
549     noconfigdirs="$noconfigdirs target-libstdc++-v3"
550     ;;
551 esac
552
553 # Disable Fortran for some systems.
554 case "${target}" in
555   mmix-*-*)
556     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
557     unsupported_languages="$unsupported_languages fortran"
558     ;;
559 esac
560
561 # Disable Java if libffi is not supported.
562 case "${target}" in
563   alpha*-*-*)
564     ;;
565   arm*-*-*)
566     ;;
567   cris-*-*)
568     ;;
569   frv-*-*)
570     ;;
571   hppa*-*-linux*)
572     ;;
573   hppa*-*-hpux*)
574     ;;
575   i?86-*-*)
576     ;;
577   ia64*-*-*)
578     ;;
579   m32r*-*-*)
580     ;;
581   m68k-*-*)
582     ;;
583   mips-sgi-irix6.* | mips*-*-rtems*)
584     ;;
585   mips*-*-linux*)
586     ;;
587   powerpc*-*-linux*)
588     ;;
589   powerpc-*-darwin*)
590     ;;
591   powerpc-*-aix* | rs6000-*-aix*)
592     ;;
593   powerpc-*-freebsd*)
594     ;;
595   powerpc64-*-freebsd*)
596     ;;
597   powerpc*-*-rtems*)
598     ;;
599   s390-*-* | s390x-*-*)
600     ;;
601   sh-*-* | sh[[34]]*-*-*)
602     ;;
603   sh64-*-* | sh5*-*-*)
604     ;;
605   sparc*-*-*)
606     ;;
607   x86_64-*-*)
608     ;;
609   *-*-*)
610     unsupported_languages="$unsupported_languages java"
611     ;;
612 esac
613
614 # Disable Java, libgcj or related libraries for some systems.
615 case "${target}" in
616   powerpc-*-darwin*)
617     ;;
618   i[[3456789]]86-*-darwin*)
619     ;;
620   x86_64-*-darwin[[912]]*)
621     ;;
622   *-*-darwin*)
623     noconfigdirs="$noconfigdirs ${libgcj}"
624     ;;
625   *-*-netware*)
626     noconfigdirs="$noconfigdirs ${libgcj}"
627     ;;
628   *-*-rtems*)
629     noconfigdirs="$noconfigdirs ${libgcj}"
630     ;;
631   *-*-tpf*)
632     noconfigdirs="$noconfigdirs ${libgcj}"
633     ;;
634   *-*-uclinux*)
635     noconfigdirs="$noconfigdirs ${libgcj}"
636     ;;
637   *-*-vxworks*)
638     noconfigdirs="$noconfigdirs ${libgcj}"
639     ;;
640   alpha*-*-*vms*)
641     noconfigdirs="$noconfigdirs ${libgcj}"
642     ;;
643   arm-wince-pe)
644     noconfigdirs="$noconfigdirs ${libgcj}"
645     ;;
646   arm*-*-symbianelf*)
647     noconfigdirs="$noconfigdirs ${libgcj}"
648     ;;
649   bfin-*-*)
650     noconfigdirs="$noconfigdirs target-boehm-gc"
651     ;;
652   cris-*-* | crisv32-*-*)
653     unsupported_languages="$unsupported_languages java"
654     case "${target}" in
655       *-*-linux*)
656         ;;
657       *) # See PR46792 regarding target-libffi.
658         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
659     esac
660     ;;
661   hppa*64*-*-linux*)
662     # In this case, it's because the hppa64-linux target is for
663     # the kernel only at this point and has no libc, and thus no
664     # headers, crt*.o, etc., all of which are needed by these.
665     unsupported_languages="$unsupported_languages java"
666     ;;
667   hppa*64*-*-hpux*)
668     noconfigdirs="$noconfigdirs ${libgcj}"
669     ;;
670   hppa*-hp-hpux11*)
671     ;;
672   hppa*-*-hpux*)
673     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
674     # build on HP-UX 10.20.
675     noconfigdirs="$noconfigdirs ${libgcj}"
676     ;;
677   ia64*-*-*vms*)
678     noconfigdirs="$noconfigdirs ${libgcj}"
679     ;;
680   i[[3456789]]86-w64-mingw*)
681     noconfigdirs="$noconfigdirs ${libgcj}"
682     ;;
683   i[[3456789]]86-*-mingw*)
684     noconfigdirs="$noconfigdirs ${libgcj}"
685     ;;
686   x86_64-*-mingw*)
687     noconfigdirs="$noconfigdirs ${libgcj}"
688     ;;
689   mmix-*-*)
690     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
691     ;;
692   powerpc-*-aix*)
693     # copied from rs6000-*-* entry
694     noconfigdirs="$noconfigdirs ${libgcj}"
695     ;;
696   rs6000-*-aix*)
697     noconfigdirs="$noconfigdirs ${libgcj}"
698     ;;
699   mips*-*-irix6*)
700     # Linking libjava exceeds command-line length limits on at least
701     # IRIX 6.2, but not on IRIX 6.5.
702     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
703     # <oldham@codesourcery.com>
704     noconfigdirs="$noconfigdirs ${libgcj}"
705     ;;
706   *-*-lynxos*)
707     noconfigdirs="$noconfigdirs ${libgcj}"
708     ;; 
709 esac
710
711 # Default libgloss CPU subdirectory.
712 libgloss_dir="$target_cpu"
713
714 case "${target}" in
715   *-*-chorusos)
716     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
717     ;;
718   powerpc-*-darwin*)
719     noconfigdirs="$noconfigdirs ld gas gdb gprof"
720     noconfigdirs="$noconfigdirs sim target-rda"
721     ;;
722   i[[3456789]]86-*-darwin*)
723     noconfigdirs="$noconfigdirs ld gprof"
724     noconfigdirs="$noconfigdirs sim target-rda"
725     ;;
726   x86_64-*-darwin[[912]]*)
727     noconfigdirs="$noconfigdirs ld gas gprof"
728     noconfigdirs="$noconfigdirs sim target-rda"
729     ;;
730   *-*-darwin*)
731     noconfigdirs="$noconfigdirs ld gas gdb gprof"
732     noconfigdirs="$noconfigdirs sim target-rda"
733     ;;
734   *-*-dragonfly*)
735     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
736     ;;
737   *-*-freebsd*)
738     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
739     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
740         && test -f /usr/local/include/gmp.h; then
741       with_gmp=/usr/local
742     fi
743     ;;
744   *-*-kaos*)
745     # Remove unsupported stuff on all kaOS configurations.
746     noconfigdirs="$noconfigdirs target-libgloss"
747     ;;
748   *-*-netbsd*)
749     # Skip some stuff on all NetBSD configurations.
750     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
751     ;;
752   *-*-netware*)
753     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
754     ;;
755   *-*-rtems*)
756     noconfigdirs="$noconfigdirs target-libgloss"
757     ;;
758     # The tpf target doesn't support gdb yet.
759   *-*-tpf*)
760     noconfigdirs="$noconfigdirs target-newlib target-libgloss gdb tcl tk libgui itcl"
761     ;;
762   *-*-uclinux*)
763     noconfigdirs="$noconfigdirs target-newlib target-libgloss target-rda"
764     ;;
765   *-*-vxworks*)
766     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
767     ;;
768   alpha*-dec-osf*)
769     # ld works, but does not support shared libraries.
770     # newlib is not 64 bit ready.
771     # gas doesn't generate exception information.
772     noconfigdirs="$noconfigdirs gas ld target-newlib target-libgloss"
773     ;;
774   alpha*-*-*vms*)
775     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
776     ;;
777   alpha*-*-linux*)
778     # newlib is not 64 bit ready
779     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
780     ;;
781   alpha*-*-*)
782     # newlib is not 64 bit ready
783     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
784     ;;
785   am33_2.0-*-linux*)
786     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
787     ;;
788   sh-*-linux*)
789     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
790     ;;    
791   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
792     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
793     noconfigdirs="$noconfigdirs target-newlib"
794     libgloss_dir=wince
795     ;;
796   arc-*-*)
797     noconfigdirs="$noconfigdirs target-libgloss"
798     ;;
799   arm-*-coff)
800     libgloss_dir=arm
801     ;;
802   arm-*-elf* | arm*-*-eabi* )
803     libgloss_dir=arm
804     ;;
805   arm*-*-linux-gnueabi)
806     case ${with_newlib} in
807       no) noconfigdirs="$noconfigdirs target-newlib target-libgloss"
808     esac
809     libgloss_dir=arm
810     ;;
811   arm*-*-symbianelf*)
812     libgloss_dir=arm
813     ;;
814   arm-*-pe*)
815     noconfigdirs="$noconfigdirs target-libgloss"
816     ;;
817   arm-*-riscix*)
818     noconfigdirs="$noconfigdirs ld target-libgloss"
819     ;;
820   avr-*-*)
821     ;;
822   bfin-*-*)
823     ;;
824   c4x-*-* | tic4x-*-*)
825     noconfigdirs="$noconfigdirs target-libgloss"
826     ;;
827   tic54x-*-*)
828     noconfigdirs="$noconfigdirs target-libgloss gdb"
829     ;;
830   cr16-*-*)
831     noconfigdirs="$noconfigdirs gdb"
832     ;;
833   cris-*-* | crisv32-*-*)
834     case "${target}" in
835       *-*-linux*)
836         noconfigdirs="$noconfigdirs target-newlib target-libgloss";;
837     esac
838     libgloss_dir=cris
839     ;;
840   d10v-*-*)
841     noconfigdirs="$noconfigdirs target-libgloss"
842     ;;
843   d30v-*-*)
844     noconfigdirs="$noconfigdirs gdb"
845     ;;
846   fr30-*-elf*)
847     noconfigdirs="$noconfigdirs gdb"
848     ;;
849   frv-*-*)
850     ;;
851   moxie-*-*)
852     noconfigdirs="$noconfigdirs gprof"
853     ;;
854   h8300*-*-*)
855     noconfigdirs="$noconfigdirs target-libgloss"
856     ;;
857   h8500-*-*)
858     noconfigdirs="$noconfigdirs target-libgloss"
859     ;;
860   hppa1.1-*-osf* | hppa1.1-*-bsd* )
861     ;;
862   hppa*64*-*-linux*)
863     ;;
864   hppa*-*-linux*)
865     ;;
866   hppa*-*-*elf* | \
867   hppa*-*-lites* | \
868   hppa*-*-openbsd* | \
869   hppa*64*-*-*)
870     ;;
871   hppa*-hp-hpux11*)
872     noconfigdirs="$noconfigdirs ld"
873     ;;
874   hppa*-*-pro*)
875     libgloss_dir=pa
876     ;;
877   hppa*-*-*)
878     noconfigdirs="$noconfigdirs ld"
879     ;;
880   i960-*-*)
881     noconfigdirs="$noconfigdirs gdb"
882     ;;
883   ia64*-*-elf*)
884     # No gdb support yet.
885     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
886     ;;
887   ia64*-**-hpux*)
888     # No ld support yet.
889     noconfigdirs="$noconfigdirs libgui itcl ld"
890     ;;
891   ia64*-*-*vms*)
892     # No gdb or ld support yet.
893     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
894     ;;
895   i[[3456789]]86-*-coff | i[[3456789]]86-*-elf)
896     libgloss_dir=i386
897     ;;
898   i[[3456789]]86-*-linux*)
899     # This section makes it possible to build newlib natively on linux.
900     # If we are using a cross compiler then don't configure newlib.
901     if test x${is_cross_compiler} != xno ; then
902       noconfigdirs="$noconfigdirs target-newlib"
903     fi
904     noconfigdirs="$noconfigdirs target-libgloss"
905     # If we are not using a cross compiler, do configure newlib.
906     # Note however, that newlib will only be configured in this situation
907     # if the --with-newlib option has been given, because otherwise
908     # 'target-newlib' will appear in skipdirs.
909     ;;
910   i[[3456789]]86-w64-mingw*)
911     noconfigdirs="$noconfigdirs target-libgloss target-newlib"
912     ;;
913   i[[3456789]]86-*-mingw*)
914     target_configdirs="$target_configdirs target-winsup"
915     noconfigdirs="$noconfigdirs target-libgloss target-newlib"
916     ;;
917   x86_64-*-mingw*)
918     noconfigdirs="$noconfigdirs target-libgloss target-newlib"
919     ;;
920   *-*-cygwin*)
921     target_configdirs="$target_configdirs target-libtermcap target-winsup"
922     noconfigdirs="$noconfigdirs target-libgloss"
923     # always build newlib if winsup directory is present.
924     if test -d "$srcdir/winsup/cygwin"; then
925       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
926     elif test -d "$srcdir/newlib"; then
927       echo "Warning: winsup/cygwin is missing so newlib can't be built."
928     fi
929     ;;
930   i[[3456789]]86-*-interix* )
931     ;;
932   i[[3456789]]86-*-pe)
933     noconfigdirs="$noconfigdirs target-libgloss"
934     ;;
935   i[[3456789]]86-*-sco3.2v5*)
936     # The linker does not yet know about weak symbols in COFF,
937     # and is not configured to handle mixed ELF and COFF.
938     noconfigdirs="$noconfigdirs ld target-libgloss"
939     ;;
940   i[[3456789]]86-*-sco*)
941     noconfigdirs="$noconfigdirs gprof target-libgloss"
942     ;;
943   i[[3456789]]86-*-solaris2*)
944     noconfigdirs="$noconfigdirs target-libgloss"
945     ;;
946   i[[3456789]]86-*-sysv4*)
947     noconfigdirs="$noconfigdirs target-libgloss"
948     ;;
949   i[[3456789]]86-*-beos*)
950     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
951     ;;
952   i[[3456789]]86-*-rdos*)
953     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
954     ;;
955   m32r-*-*)
956     ;;
957   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
958     libgloss_dir=m68hc11
959     ;;
960   m68k-*-elf*)
961     ;;
962   m68*-*-* | fido-*-*)
963     libgloss_dir=m68k
964     ;;
965   mmix-*-*)
966     noconfigdirs="$noconfigdirs gdb"
967     ;;
968   mt-*-*)
969     noconfigdirs="$noconfigdirs sim"
970     ;;
971   powerpc-*-aix*)
972     # copied from rs6000-*-* entry
973     noconfigdirs="$noconfigdirs gprof target-libgloss target-newlib"
974     ;;
975   powerpc*-*-winnt* | powerpc*-*-pe*)
976     target_configdirs="$target_configdirs target-winsup"
977     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
978     # always build newlib.
979     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
980     ;;
981     # This is temporary until we can link against shared libraries
982   powerpcle-*-solaris*)
983     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
984     libgloss_dir=rs6000
985     ;;
986   powerpc-*-beos*)
987     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
988     ;;
989   powerpc-*-eabi)
990     libgloss_dir=rs6000
991     ;;
992   powerpc-*-eabi* | powerpcle-*-eabi* | powerpc-*-rtems* )
993     libgloss_dir=rs6000
994     ;;
995   rs6000-*-lynxos*)
996     noconfigdirs="$noconfigdirs target-newlib gprof"
997     ;;
998   rs6000-*-aix*)
999     noconfigdirs="$noconfigdirs gprof target-libgloss target-newlib"
1000     ;;
1001   rs6000-*-*)
1002     noconfigdirs="$noconfigdirs gprof"
1003     ;;
1004   m68k-apollo-*)
1005     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1006     ;;
1007   microblaze*)
1008     noconfigdirs="$noconfigdirs gprof"
1009     ;;
1010   mips*-sde-elf*)
1011     if test x$with_newlib = xyes; then
1012       noconfigdirs="$noconfigdirs gprof"
1013     fi
1014     libgloss_dir=mips
1015     ;;
1016   mips*-*-irix5*)
1017     noconfigdirs="$noconfigdirs gprof target-libgloss"
1018     ;;
1019   mips*-*-irix6*)
1020     noconfigdirs="$noconfigdirs gprof target-libgloss"
1021     ;;
1022   mips*-*-bsd*)
1023     noconfigdirs="$noconfigdirs gprof target-libgloss"
1024     ;;
1025   mips*-*-linux*)
1026     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1027     ;;
1028   mips*-*-*)
1029     noconfigdirs="$noconfigdirs gprof"
1030     libgloss_dir=mips
1031     ;;
1032   sh-*-* | sh64-*-*)
1033     case "${target}" in
1034       sh*-*-elf)
1035          ;;
1036       *)
1037          noconfigdirs="$noconfigdirs target-libgloss" ;;
1038     esac
1039     ;;
1040   sparclet-*-aout* | sparc86x-*-*)
1041     libgloss_dir=sparc
1042     ;;
1043   sparc-*-elf*)
1044     ;;
1045   sparc64-*-elf*)
1046     libgloss_dir=sparc
1047     ;;
1048   sparclite-*-*)
1049     libgloss_dir=sparc
1050     ;;
1051   sparc-*-sunos4*)
1052     if test x${is_cross_compiler} != xno ; then
1053            noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1054     else
1055            use_gnu_ld=no
1056     fi
1057     ;;
1058   sparc-*-solaris* | sparc64-*-solaris* | sparcv9-*-solaris*)
1059     ;;
1060   tic6x-*-*)
1061     noconfigdirs="$noconfigdirs gdb sim"
1062     ;;
1063   v810-*-*)
1064     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1065     ;;
1066   vax-*-*)
1067     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1068     ;;
1069   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
1070     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1071     ;;
1072   *-*-lynxos*)
1073     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1074     ;; 
1075   *-*-*)
1076     ;;
1077 esac
1078
1079 # If we aren't building newlib, then don't build libgloss, since libgloss
1080 # depends upon some newlib header files.
1081 case "${noconfigdirs}" in
1082   *target-libgloss*) ;;
1083   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1084 esac
1085
1086 # Work in distributions that contain no compiler tools, like Autoconf.
1087 host_makefile_frag=/dev/null
1088 if test -d ${srcdir}/config ; then
1089 case "${host}" in
1090   i[[3456789]]86-*-msdosdjgpp*)
1091     host_makefile_frag="config/mh-djgpp"
1092     ;;
1093   *-cygwin*)
1094     ACX_CHECK_CYGWIN_CAT_WORKS
1095     host_makefile_frag="config/mh-cygwin"
1096     ;;
1097   *-mingw*)
1098     host_makefile_frag="config/mh-mingw"
1099     ;;
1100   *-interix*)
1101     host_makefile_frag="config/mh-interix"
1102     ;;
1103   hppa*-hp-hpux10*)
1104     host_makefile_frag="config/mh-pa-hpux10"
1105     ;;
1106   hppa*-hp-hpux*)
1107     host_makefile_frag="config/mh-pa"
1108     ;;
1109   hppa*-*)      
1110     host_makefile_frag="config/mh-pa"
1111     ;;
1112   *-*-darwin*)
1113     host_makefile_frag="config/mh-darwin"
1114     ;;
1115   powerpc-*-aix*)
1116     host_makefile_frag="config/mh-ppc-aix"
1117     ;;
1118   rs6000-*-aix*)
1119     host_makefile_frag="config/mh-ppc-aix"
1120     ;;
1121 esac
1122 fi
1123
1124 if test "${build}" != "${host}" ; then
1125   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1126   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1127   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1128   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1129   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1130   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1131   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1132   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1133   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1134   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1135   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1136   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1137   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1138 else
1139   AR_FOR_BUILD="\$(AR)"
1140   AS_FOR_BUILD="\$(AS)"
1141   CC_FOR_BUILD="\$(CC)"
1142   CXX_FOR_BUILD="\$(CXX)"
1143   GCJ_FOR_BUILD="\$(GCJ)"
1144   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1145   GOC_FOR_BUILD="\$(GOC)"
1146   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1147   LD_FOR_BUILD="\$(LD)"
1148   NM_FOR_BUILD="\$(NM)"
1149   RANLIB_FOR_BUILD="\$(RANLIB)"
1150   WINDRES_FOR_BUILD="\$(WINDRES)"
1151   WINDMC_FOR_BUILD="\$(WINDMC)"
1152 fi
1153
1154 AC_PROG_CC
1155 AC_PROG_CXX
1156
1157 # We must set the default linker to the linker used by gcc for the correct
1158 # operation of libtool.  If LD is not defined and we are using gcc, try to
1159 # set the LD default to the ld used by gcc.
1160 if test -z "$LD"; then
1161   if test "$GCC" = yes; then
1162     case $build in
1163     *-*-mingw*)
1164       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1165     *)
1166       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1167     esac
1168     case $gcc_prog_ld in
1169     # Accept absolute paths.
1170     [[\\/]* | [A-Za-z]:[\\/]*)]
1171       LD="$gcc_prog_ld" ;;
1172     esac
1173   fi
1174 fi
1175
1176 ACX_PROG_GNAT
1177 ACX_PROG_CMP_IGNORE_INITIAL
1178
1179 # See if we are building gcc with C++.
1180 AC_ARG_ENABLE(build-with-cxx,
1181 [AS_HELP_STRING([--enable-build-with-cxx],
1182                 [build with C++ compiler instead of C compiler])],
1183 ENABLE_BUILD_WITH_CXX=$enableval,
1184 ENABLE_BUILD_WITH_CXX=no)
1185
1186 # Used for setting $lt_cv_objdir
1187 _LT_CHECK_OBJDIR
1188
1189 # Check for GMP, MPFR and MPC
1190 gmplibs="-lmpc -lmpfr -lgmp"
1191 gmpinc=
1192 have_gmp=no
1193
1194 # Specify a location for mpc
1195 # check for this first so it ends up on the link line before mpfr.
1196 AC_ARG_WITH(mpc,
1197 [AS_HELP_STRING([--with-mpc=PATH],
1198                 [specify prefix directory for installed MPC package.
1199                  Equivalent to --with-mpc-include=PATH/include
1200                  plus --with-mpc-lib=PATH/lib])])
1201 AC_ARG_WITH(mpc-include,
1202 [AS_HELP_STRING([--with-mpc-include=PATH],
1203                 [specify directory for installed MPC include files])])
1204 AC_ARG_WITH(mpc-lib,
1205 [AS_HELP_STRING([--with-mpc-lib=PATH],
1206                 [specify directory for the installed MPC library])])
1207
1208 if test "x$with_mpc" != x; then
1209   gmplibs="-L$with_mpc/lib $gmplibs"
1210   gmpinc="-I$with_mpc/include $gmpinc"
1211 fi
1212 if test "x$with_mpc_include" != x; then
1213   gmpinc="-I$with_mpc_include $gmpinc"
1214 fi
1215 if test "x$with_mpc_lib" != x; then
1216   gmplibs="-L$with_mpc_lib $gmplibs"
1217 fi
1218 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1219   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1220   gmpinc='-I$$s/mpc/src '"$gmpinc"
1221   # Do not test the mpc version.  Assume that it is sufficient, since
1222   # it is in the source tree, and the library has not been built yet
1223   # but it would be included on the link line in the version check below
1224   # hence making the test fail.
1225   have_gmp=yes
1226 fi
1227
1228 # Specify a location for mpfr
1229 # check for this first so it ends up on the link line before gmp.
1230 AC_ARG_WITH(mpfr-dir,
1231 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1232 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1233 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1234
1235 AC_ARG_WITH(mpfr,
1236 [AS_HELP_STRING([--with-mpfr=PATH],
1237                 [specify prefix directory for installed MPFR package.
1238                  Equivalent to --with-mpfr-include=PATH/include
1239                  plus --with-mpfr-lib=PATH/lib])])
1240 AC_ARG_WITH(mpfr-include,
1241 [AS_HELP_STRING([--with-mpfr-include=PATH],
1242                 [specify directory for installed MPFR include files])])
1243 AC_ARG_WITH(mpfr-lib,
1244 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1245                 [specify directory for the installed MPFR library])])
1246
1247 if test "x$with_mpfr" != x; then
1248   gmplibs="-L$with_mpfr/lib $gmplibs"
1249   gmpinc="-I$with_mpfr/include $gmpinc"
1250 fi
1251 if test "x$with_mpfr_include" != x; then
1252   gmpinc="-I$with_mpfr_include $gmpinc"
1253 fi
1254 if test "x$with_mpfr_lib" != x; then
1255   gmplibs="-L$with_mpfr_lib $gmplibs"
1256 fi
1257 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1258   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1259   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1260   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1261   # Do not test the mpfr version.  Assume that it is sufficient, since
1262   # it is in the source tree, and the library has not been built yet
1263   # but it would be included on the link line in the version check below
1264   # hence making the test fail.
1265   have_gmp=yes
1266 fi
1267
1268 # Specify a location for gmp
1269 AC_ARG_WITH(gmp-dir,
1270 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1271 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1272 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1273
1274 AC_ARG_WITH(gmp,
1275 [AS_HELP_STRING([--with-gmp=PATH],
1276                 [specify prefix directory for the installed GMP package.
1277                  Equivalent to --with-gmp-include=PATH/include
1278                  plus --with-gmp-lib=PATH/lib])])
1279 AC_ARG_WITH(gmp-include,
1280 [AS_HELP_STRING([--with-gmp-include=PATH],
1281                 [specify directory for installed GMP include files])])
1282 AC_ARG_WITH(gmp-lib,
1283 [AS_HELP_STRING([--with-gmp-lib=PATH],
1284                 [specify directory for the installed GMP library])])
1285
1286
1287 if test "x$with_gmp" != x; then
1288   gmplibs="-L$with_gmp/lib $gmplibs"
1289   gmpinc="-I$with_gmp/include $gmpinc"
1290 fi
1291 if test "x$with_gmp_include" != x; then
1292   gmpinc="-I$with_gmp_include $gmpinc"
1293 fi
1294 if test "x$with_gmp_lib" != x; then
1295   gmplibs="-L$with_gmp_lib $gmplibs"
1296 fi
1297 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1298   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1299   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1300   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1301   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1302   # Do not test the gmp version.  Assume that it is sufficient, since
1303   # it is in the source tree, and the library has not been built yet
1304   # but it would be included on the link line in the version check below
1305   # hence making the test fail.
1306   have_gmp=yes
1307 fi
1308
1309 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1310   have_gmp=yes
1311   saved_CFLAGS="$CFLAGS"
1312   CFLAGS="$CFLAGS $gmpinc"
1313   # Check for the recommended and required versions of GMP.
1314   AC_MSG_CHECKING([for the correct version of gmp.h])
1315   AC_TRY_COMPILE([#include "gmp.h"],[
1316   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1317   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1318   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1319   choke me
1320   #endif
1321   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1322   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1323   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1324   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1325   choke me
1326   #endif
1327   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1328    [AC_MSG_RESULT([no]); have_gmp=no])
1329
1330   # If we have GMP, check the MPFR version.
1331   if test x"$have_gmp" = xyes; then
1332     # Check for the recommended and required versions of MPFR.
1333     AC_MSG_CHECKING([for the correct version of mpfr.h])
1334     AC_TRY_COMPILE([#include <gmp.h>
1335     #include <mpfr.h>],[
1336     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1337     choke me
1338     #endif
1339     ], [AC_TRY_COMPILE([#include <gmp.h>
1340     #include <mpfr.h>],[
1341     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1342     choke me
1343     #endif
1344     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1345      [AC_MSG_RESULT([no]); have_gmp=no])
1346   fi
1347
1348   # Check for the MPC header version.
1349   if test x"$have_gmp" = xyes ; then
1350     # Check for the recommended and required versions of MPC.
1351     AC_MSG_CHECKING([for the correct version of mpc.h])
1352     AC_TRY_COMPILE([#include <mpc.h>],[
1353     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1354     choke me
1355     #endif
1356     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1357     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1358     choke me
1359     #endif
1360     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1361      [AC_MSG_RESULT([no]); have_gmp=no])
1362   fi
1363
1364   # Now check the MPFR library.
1365   if test x"$have_gmp" = xyes; then
1366     saved_LIBS="$LIBS"
1367     LIBS="$LIBS $gmplibs"
1368     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1369     AC_TRY_LINK([#include <mpc.h>],[
1370     mpfr_t n;
1371     mpfr_t x;
1372     mpc_t c;
1373     int t;
1374     mpfr_init (n);
1375     mpfr_init (x);
1376     mpfr_atan2 (n, n, x, GMP_RNDN);
1377     mpfr_erfc (n, x, GMP_RNDN);
1378     mpfr_subnormalize (x, t, GMP_RNDN);
1379     mpfr_clear(n);
1380     mpfr_clear(x);
1381     mpc_init2 (c, 53);
1382     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1383     mpc_cosh (c, c, MPC_RNDNN);
1384     mpc_pow (c, c, c, MPC_RNDNN);
1385     mpc_acosh (c, c, MPC_RNDNN);
1386     mpc_clear (c);
1387     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1388     LIBS="$saved_LIBS"
1389   fi
1390
1391   CFLAGS="$saved_CFLAGS"
1392
1393 # The library versions listed in the error message below should match
1394 # the HARD-minimums enforced above.
1395   if test x$have_gmp != xyes; then
1396     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1397 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1398 their locations.  Source code for these libraries can be found at
1399 their respective hosting sites as well as at
1400 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1401 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1402 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1403 make sure that you have installed both the libraries and the header
1404 files.  They may be located in separate packages.])
1405   fi
1406 fi
1407
1408 # Flags needed for both GMP, MPFR and/or MPC.
1409 AC_SUBST(gmplibs)
1410 AC_SUBST(gmpinc)
1411 AC_SUBST(extra_mpfr_configure_flags)
1412 AC_SUBST(extra_mpc_gmp_configure_flags)
1413 AC_SUBST(extra_mpc_mpfr_configure_flags)
1414
1415 # Allow host libstdc++ to be specified for static linking with PPL.
1416 AC_ARG_WITH(host-libstdcxx,
1417 [AS_HELP_STRING([--with-host-libstdcxx=L],
1418                 [use linker arguments L to link with libstdc++
1419                  when linking with PPL])])
1420
1421 case $with_host_libstdcxx in
1422   no|yes)
1423     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1424     ;;
1425 esac
1426
1427 # Linker flags to use for stage1 or when not boostrapping.
1428 AC_ARG_WITH(stage1-ldflags,
1429 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1430 [if test "$withval" = "no" -o "$withval" = "yes"; then
1431    stage1_ldflags=
1432  else
1433    stage1_ldflags=$withval
1434  fi],
1435 [stage1_ldflags=])
1436 AC_SUBST(stage1_ldflags)
1437
1438 # Libraries to use for stage1 or when not bootstrapping.
1439 AC_ARG_WITH(stage1-libs,
1440 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1441 [if test "$withval" = "no" -o "$withval" = "yes"; then
1442    stage1_libs=
1443  else
1444    stage1_libs=$withval
1445  fi],
1446 [stage1_libs=$with_host_libstdcxx])
1447 AC_SUBST(stage1_libs)
1448
1449 # Libraries to use for stage2 and later builds.  This defaults to the
1450 # argument passed to --with-host-libstdcxx.
1451 AC_ARG_WITH(boot-libs,
1452 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1453 [if test "$withval" = "no" -o "$withval" = "yes"; then
1454    poststage1_libs=
1455  else
1456    poststage1_libs=$withval
1457  fi],
1458 [poststage1_libs=$with_host_libstdcxx])
1459 AC_SUBST(poststage1_libs)
1460
1461 # Linker flags to use for stage2 and later builds.
1462 AC_ARG_WITH(boot-ldflags,
1463 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1464                 [linker flags for stage2 and later])],
1465 [if test "$withval" = "no" -o "$withval" = "yes"; then
1466    poststage1_ldflags=
1467  else
1468    poststage1_ldflags=$withval
1469  fi],
1470 [poststage1_ldflags=
1471  # In stages 2 and 3, default to linking libstdc++ and libgcc
1472  # statically.  But if the user explicitly specified the libraries to
1473  # use, trust that they are doing what they want.
1474  if test "$poststage1_libs" = ""; then
1475    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1476  fi])
1477 AC_SUBST(poststage1_ldflags)
1478
1479 # Check for PPL
1480 ppllibs=
1481 pplinc=
1482 pwllib=
1483
1484 AC_ARG_WITH(ppl,
1485 [AS_HELP_STRING([--with-ppl=PATH],
1486                 [specify prefix directory for the installed PPL package.
1487                  Equivalent to --with-ppl-include=PATH/include
1488                  plus --with-ppl-lib=PATH/lib])])
1489 AC_ARG_WITH(ppl-include,
1490 [AS_HELP_STRING([--with-ppl-include=PATH],
1491                 [specify directory for installed PPL include files])])
1492 AC_ARG_WITH(ppl-lib,
1493 [AS_HELP_STRING([--with-ppl-lib=PATH],
1494                 [specify directory for the installed PPL library])])
1495
1496 AC_ARG_ENABLE(ppl-version-check,
1497 [AS_HELP_STRING([--disable-ppl-version-check],
1498                 [disable check for PPL version])])
1499
1500 case $with_ppl in
1501   yes | no | "")
1502     ;;
1503   *)
1504     ppllibs="-L$with_ppl/lib"
1505     pplinc="-I$with_ppl/include $pplinc"
1506     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1507       with_ppl=yes
1508     else
1509       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1510     fi
1511     ;;
1512 esac
1513
1514 if test x"$with_ppl_include" != x; then
1515   pplinc="-I$with_ppl_include $pplinc"
1516   with_ppl=yes
1517 fi
1518
1519 if test "x$with_ppl_lib" != x; then
1520   ppllibs="-L$with_ppl_lib"
1521   with_ppl=yes
1522 fi
1523
1524 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1525   if test x"$enable_watchdog" = xyes; then
1526     pwllib="-lpwl"
1527   fi
1528   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1529   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1530   enable_ppl_version_check=no
1531   with_ppl=yes
1532 fi
1533
1534 if test "x$with_ppl" != xno; then
1535   if test "x$pwllib" = x; then
1536     saved_LIBS="$LIBS"
1537     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1538     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1539     LIBS="$saved_LIBS"
1540   fi
1541
1542   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1543
1544   if test "$enable_ppl_version_check" != no; then
1545     saved_CFLAGS="$CFLAGS"
1546     CFLAGS="$CFLAGS $pplinc $gmpinc"
1547     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1548     AC_TRY_COMPILE([#include "ppl_c.h"],[
1549     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1550     choke me
1551     #endif
1552     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1553     CFLAGS="$saved_CFLAGS"
1554   fi
1555 fi
1556
1557 # Flags needed for PPL
1558 AC_SUBST(ppllibs)
1559 AC_SUBST(pplinc)
1560
1561
1562 # Check for CLOOG
1563
1564 dnl Provide configure switches and initialize clooginc & clooglibs
1565 dnl with user input.
1566 CLOOG_INIT_FLAGS
1567 if test "x$with_ppl" = "xno"; then
1568   dnl Only execute fail-action, if CLooG has been requested.
1569   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1570   if test "${graphite_requested}" = yes; then
1571     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1572   fi
1573   with_cloog=no
1574 fi
1575 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1576   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1577   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1578   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1579 fi
1580 if test "x$with_cloog" != "xno"; then
1581   dnl The minimal version of CLooG required for Graphite.
1582   dnl
1583   dnl If we use CLooG-Legacy, the provided version information is
1584   dnl ignored.
1585   CLOOG_CHECK_VERSION(0,16,1)
1586
1587   dnl Only execute fail-action, if CLooG has been requested.
1588   CLOOG_IF_FAILED([
1589     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1590 fi
1591
1592 # Check for LTO support.
1593 AC_ARG_ENABLE(lto,
1594 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1595 enable_lto=$enableval,
1596 enable_lto=yes; default_enable_lto=yes)
1597
1598 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1599   build_lto_plugin=yes
1600 ],[if test x"$default_enable_lto" = x"yes" ; then
1601     case $target in
1602       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1603       # On other non-ELF platforms, LTO has yet to be validated.
1604       *) enable_lto=no ;;
1605     esac
1606   else
1607   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1608   # It would also be nice to check the binutils support, but we don't
1609   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1610   # warn during gcc/ subconfigure; unless you're bootstrapping with
1611   # -flto it won't be needed until after installation anyway.
1612     case $target in
1613       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1614       *) if test x"$enable_lto" = x"yes"; then
1615         AC_MSG_ERROR([LTO support is not enabled for this target.])
1616         fi
1617       ;;
1618     esac
1619   fi
1620   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1621   # Build it unless LTO was explicitly disabled.
1622   case $target in
1623     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1624     *) ;;
1625   esac
1626 ])
1627
1628
1629 # By default, C is the only stage 1 language.
1630 stage1_languages=,c,
1631
1632 # Target libraries that we bootstrap.
1633 bootstrap_target_libs=,target-libgcc,
1634
1635 # Figure out what language subdirectories are present.
1636 # Look if the user specified --enable-languages="..."; if not, use
1637 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1638 # go away some day.
1639 # NB:  embedded tabs in this IF block -- do not untabify
1640 if test -d ${srcdir}/gcc; then
1641   if test x"${enable_languages+set}" != xset; then
1642     if test x"${LANGUAGES+set}" = xset; then
1643       enable_languages="${LANGUAGES}"
1644         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1645     else
1646       enable_languages=all
1647     fi
1648   else
1649     if test x"${enable_languages}" = x ||
1650        test x"${enable_languages}" = xyes;
1651        then
1652       echo configure.in: --enable-languages needs at least one language argument 1>&2
1653       exit 1
1654     fi
1655   fi
1656   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1657
1658   # 'f95' is the old name for the 'fortran' language. We issue a warning
1659   # and make the substitution.
1660   case ,${enable_languages}, in
1661     *,f95,*)
1662       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1663       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1664       ;;
1665   esac
1666
1667   # First scan to see if an enabled language requires some other language.
1668   # We assume that a given config-lang.in will list all the language
1669   # front ends it requires, even if some are required indirectly.
1670   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1671     case ${lang_frag} in
1672       ..) ;;
1673       # The odd quoting in the next line works around
1674       # an apparent bug in bash 1.12 on linux.
1675       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1676       *)
1677         # From the config-lang.in, get $language, $lang_requires, and
1678         # $lang_requires_boot_languages.
1679         language=
1680         lang_requires=
1681         lang_requires_boot_languages=
1682         . ${lang_frag}
1683         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1684           case ,${enable_languages}, in
1685             *,$other,*) ;;
1686             *,all,*) ;;
1687             *,$language,*)
1688               echo " \`$other' language required by \`$language'; enabling" 1>&2
1689               enable_languages="${enable_languages},${other}"
1690               ;;
1691           esac
1692         done
1693         for other in ${lang_requires_boot_languages} ; do
1694           if test "$other" != "c"; then
1695             case ,${enable_stage1_languages}, in
1696               *,$other,*) ;;
1697               *,all,*) ;;
1698               *)
1699                 case ,${enable_languages}, in
1700                   *,$language,*)
1701                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1702                     enable_stage1_languages="$enable_stage1_languages,${other}"
1703                     ;;
1704                 esac
1705                 ;;
1706             esac
1707           fi
1708         done
1709         ;;
1710     esac
1711   done
1712
1713   new_enable_languages=,c,
1714
1715   # If LTO is enabled, add the LTO front end.
1716   extra_host_libiberty_configure_flags=
1717   if test "$enable_lto" = "yes" ; then
1718     case ,${enable_languages}, in
1719       *,lto,*) ;;
1720       *) enable_languages="${enable_languages},lto" ;;
1721     esac
1722     if test "${build_lto_plugin}" = "yes" ; then
1723       configdirs="$configdirs lto-plugin"
1724       extra_host_libiberty_configure_flags=--enable-shared
1725     fi
1726   fi
1727   AC_SUBST(extra_host_libiberty_configure_flags)
1728
1729   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1730   potential_languages=,c,
1731
1732   enabled_target_libs=
1733   disabled_target_libs=
1734
1735   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1736     case ${lang_frag} in
1737       ..) ;;
1738       # The odd quoting in the next line works around
1739       # an apparent bug in bash 1.12 on linux.
1740       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1741       *)
1742         # From the config-lang.in, get $language, $target_libs, 
1743         # $lang_dirs, $boot_language, and $build_by_default
1744         language=
1745         target_libs=
1746         lang_dirs=
1747         subdir_requires=
1748         boot_language=no
1749         build_by_default=yes
1750         . ${lang_frag}
1751         if test x${language} = x; then
1752           echo "${lang_frag} doesn't set \$language." 1>&2
1753           exit 1
1754         fi
1755
1756         if test "$language" = "c++" \
1757            && test "$ENABLE_BUILD_WITH_CXX" = "yes"; then
1758           boot_language=yes
1759         fi
1760
1761         case ,${enable_languages}, in
1762           *,${language},*)
1763             # Language was explicitly selected; include it.
1764             add_this_lang=yes
1765             ;;
1766           *,all,*)
1767             # 'all' was selected, select it if it is a default language
1768             add_this_lang=${build_by_default}
1769             ;;
1770           *)
1771             add_this_lang=no
1772             ;;
1773         esac
1774
1775         # Disable languages that need other directories if these aren't available.
1776         for i in $subdir_requires; do
1777           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1778           case ,${enable_languages}, in
1779             *,${language},*)
1780               # Specifically requested language; tell them.
1781               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1782               ;;
1783             *)
1784               # Silently disable.
1785               add_this_lang=unsupported
1786               ;;
1787           esac
1788         done
1789
1790         # Disable Ada if no preexisting GNAT is available.
1791         case ,${enable_languages},:${language}:${have_gnat} in
1792           *,${language},*:ada:no)
1793             # Specifically requested language; tell them.
1794             AC_MSG_ERROR([GNAT is required to build $language])
1795             ;;
1796           *:ada:no)
1797             # Silently disable.
1798             add_this_lang=unsupported
1799             ;;
1800         esac
1801
1802         # Disable a language that is unsupported by the target.
1803         case " $unsupported_languages " in
1804           *" $language "*)
1805             add_this_lang=unsupported
1806             ;;
1807         esac
1808
1809         case $add_this_lang in
1810           unsupported)
1811             # Remove language-dependent dirs.
1812             disabled_target_libs="$disabled_target_libs $target_libs"
1813             noconfigdirs="$noconfigdirs $lang_dirs"
1814             ;;
1815           no)
1816             # Remove language-dependent dirs; still show language as supported.
1817             disabled_target_libs="$disabled_target_libs $target_libs"
1818             noconfigdirs="$noconfigdirs $lang_dirs"
1819             potential_languages="${potential_languages}${language},"
1820             ;;
1821           yes)
1822             new_enable_languages="${new_enable_languages}${language},"
1823             potential_languages="${potential_languages}${language},"
1824             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1825             enabled_target_libs="$enabled_target_libs $target_libs"
1826             case "${boot_language}:,$enable_stage1_languages," in
1827               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1828                 # Add to (comma-separated) list of stage 1 languages.
1829                 case ",$stage1_languages," in
1830                   *,$language,* | ,yes, | ,all,) ;;
1831                   *) stage1_languages="${stage1_languages}${language}," ;;
1832                 esac
1833                 # We need to bootstrap any supporting libraries.
1834                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1835                 ;;
1836             esac
1837             ;;
1838         esac
1839         ;;
1840     esac
1841   done
1842
1843   # Add target libraries which are only needed for disabled languages
1844   # to noconfigdirs.
1845   if test -n "$disabled_target_libs"; then
1846     for dir in $disabled_target_libs; do
1847       case " $enabled_target_libs " in
1848       *" ${dir} "*) ;;
1849       *) noconfigdirs="$noconfigdirs $dir" ;;
1850       esac
1851     done
1852   fi
1853
1854   AC_ARG_ENABLE(stage1-languages,
1855   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1856                   [choose additional languages to build during
1857                   stage1.  Mostly useful for compiler development])],
1858   [case ,${enable_stage1_languages}, in
1859     ,no,|,,)
1860       # Set it to something that will have no effect in the loop below
1861       enable_stage1_languages=c ;;
1862     ,yes,)
1863       enable_stage1_languages=`echo $new_enable_languages | \
1864         sed -e "s/^,//" -e "s/,$//" ` ;;
1865     *,all,*)
1866       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1867         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1868   esac
1869
1870   # Add "good" languages from enable_stage1_languages to stage1_languages,
1871   # while "bad" languages go in missing_languages.  Leave no duplicates.
1872   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1873     case $potential_languages in
1874       *,$i,*)
1875         case $stage1_languages in
1876           *,$i,*) ;;
1877           *) stage1_languages="$stage1_languages$i," ;;
1878         esac ;;
1879       *)
1880         case $missing_languages in
1881           *,$i,*) ;;
1882           *) missing_languages="$missing_languages$i," ;;
1883         esac ;;
1884      esac
1885   done])
1886
1887   # Remove leading/trailing commas that were added for simplicity
1888   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1889   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1890   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1891   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1892
1893   if test "x$missing_languages" != x; then
1894     AC_MSG_ERROR([
1895 The following requested languages could not be built: ${missing_languages}
1896 Supported languages are: ${potential_languages}])
1897   fi
1898   if test "x$new_enable_languages" != "x$enable_languages"; then
1899     echo The following languages will be built: ${new_enable_languages}
1900     enable_languages="$new_enable_languages"
1901   fi
1902
1903   AC_SUBST(stage1_languages)
1904   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1905 fi
1906
1907 # Handle --disable-<component> generically.
1908 for dir in $configdirs $build_configdirs $target_configdirs ; do
1909   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1910   varname=`echo $dirname | sed -e s/+/_/g`
1911   if eval test x\${enable_${varname}} "=" xno ; then
1912     noconfigdirs="$noconfigdirs $dir"
1913   fi
1914 done
1915
1916 # Check for Boehm's garbage collector
1917 AC_ARG_ENABLE(objc-gc,
1918 [AS_HELP_STRING([--enable-objc-gc],
1919                 [enable use of Boehm's garbage collector with the
1920                  GNU Objective-C runtime])],
1921 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1922   *,objc,*:*:yes:*target-boehm-gc*)
1923     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1924     ;;
1925 esac])
1926
1927 # Make sure we only build Boehm's garbage collector if required.
1928 case ,${enable_languages},:${enable_objc_gc} in
1929   *,objc,*:yes)
1930     # Keep target-boehm-gc if requested for Objective-C.
1931     ;;
1932   *)
1933     # Otherwise remove target-boehm-gc depending on target-libjava.
1934     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1935       noconfigdirs="$noconfigdirs target-boehm-gc"
1936     fi
1937     ;;
1938 esac
1939
1940 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1941 # $build_configdirs and $target_configdirs.
1942 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1943
1944 notsupp=""
1945 for dir in . $skipdirs $noconfigdirs ; do
1946   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1947   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1948     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1949     if test -r $srcdir/$dirname/configure ; then
1950       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1951         true
1952       else
1953         notsupp="$notsupp $dir"
1954       fi
1955     fi
1956   fi
1957   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1958     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1959     if test -r $srcdir/$dirname/configure ; then
1960       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1961         true
1962       else
1963         notsupp="$notsupp $dir"
1964       fi
1965     fi
1966   fi
1967   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1968     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1969     if test -r $srcdir/$dirname/configure ; then
1970       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1971         true
1972       else
1973         notsupp="$notsupp $dir"
1974       fi
1975     fi
1976   fi
1977 done
1978
1979 # Sometimes the tools are distributed with libiberty but with no other
1980 # libraries.  In that case, we don't want to build target-libiberty.
1981 # Don't let libgcc imply libiberty either.
1982 if test -n "${target_configdirs}" ; then
1983   libgcc=
1984   others=
1985   for i in `echo ${target_configdirs} | sed -e s/target-//g` ; do
1986     if test "$i" = "libgcc"; then
1987       libgcc=target-libgcc
1988     elif test "$i" != "libiberty" ; then
1989       if test -r $srcdir/$i/configure ; then
1990         others=yes;
1991         break;
1992       fi
1993     fi
1994   done
1995   if test -z "${others}" ; then
1996     target_configdirs=$libgcc
1997   fi
1998 fi
1999
2000 # Quietly strip out all directories which aren't configurable in this tree.
2001 # This relies on all configurable subdirectories being autoconfiscated, which
2002 # is now the case.
2003 build_configdirs_all="$build_configdirs"
2004 build_configdirs=
2005 for i in ${build_configdirs_all} ; do
2006   j=`echo $i | sed -e s/build-//g` 
2007   if test -f ${srcdir}/$j/configure ; then
2008     build_configdirs="${build_configdirs} $i"
2009   fi
2010 done
2011
2012 configdirs_all="$configdirs"
2013 configdirs=
2014 for i in ${configdirs_all} ; do
2015   if test -f ${srcdir}/$i/configure ; then
2016     configdirs="${configdirs} $i"
2017   fi
2018 done
2019
2020 target_configdirs_all="$target_configdirs"
2021 target_configdirs=
2022 for i in ${target_configdirs_all} ; do
2023   j=`echo $i | sed -e s/target-//g` 
2024   if test -f ${srcdir}/$j/configure ; then
2025     target_configdirs="${target_configdirs} $i"
2026   fi
2027 done
2028
2029 # Produce a warning message for the subdirs we can't configure.
2030 # This isn't especially interesting in the Cygnus tree, but in the individual
2031 # FSF releases, it's important to let people know when their machine isn't
2032 # supported by the one or two programs in a package.
2033
2034 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2035   # If $appdirs is non-empty, at least one of those directories must still
2036   # be configured, or we error out.  (E.g., if the gas release supports a
2037   # specified target in some subdirs but not the gas subdir, we shouldn't
2038   # pretend that all is well.)
2039   if test -n "$appdirs" ; then
2040     for dir in $appdirs ; do
2041       if test -r $dir/Makefile.in ; then
2042         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2043           appdirs=""
2044           break
2045         fi
2046         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2047           appdirs=""
2048           break
2049         fi
2050       fi
2051     done
2052     if test -n "$appdirs" ; then
2053       echo "*** This configuration is not supported by this package." 1>&2
2054       exit 1
2055     fi
2056   fi
2057   # Okay, some application will build, or we don't care to check.  Still
2058   # notify of subdirs not getting built.
2059   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2060   echo "    ${notsupp}" 1>&2
2061   echo "    (Any other directories should still work fine.)" 1>&2
2062 fi
2063
2064 case "$host" in
2065   *msdosdjgpp*)
2066     enable_gdbtk=no ;;
2067 esac
2068
2069 # To find our prefix, in gcc_cv_tool_prefix.
2070 ACX_TOOL_DIRS
2071
2072 copy_dirs=
2073
2074 AC_ARG_WITH([build-sysroot], 
2075   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2076                   [use sysroot as the system root during the build])],
2077   [if test x"$withval" != x ; then
2078      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2079    fi],
2080   [SYSROOT_CFLAGS_FOR_TARGET=])
2081 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2082
2083 AC_ARG_WITH([debug-prefix-map],
2084   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2085                   [map A to B, C to D ... in debug information])],
2086   [if test x"$withval" != x; then
2087      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2088      for debug_map in $withval; do
2089        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2090      done
2091    fi],
2092   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2093 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2094
2095 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2096 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2097 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2098 # We want to ensure that TARGET libraries (which we know are built with
2099 # gcc) are built with "-O2 -g", so include those options when setting
2100 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2101 if test "x$CFLAGS_FOR_TARGET" = x; then
2102   CFLAGS_FOR_TARGET=$CFLAGS
2103   case " $CFLAGS " in
2104     *" -O2 "*) ;;
2105     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2106   esac
2107   case " $CFLAGS " in
2108     *" -g "* | *" -g3 "*) ;;
2109     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2110   esac
2111 fi
2112 AC_SUBST(CFLAGS_FOR_TARGET)
2113
2114 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2115   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2116   case " $CXXFLAGS " in
2117     *" -O2 "*) ;;
2118     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2119   esac
2120   case " $CXXFLAGS " in
2121     *" -g "* | *" -g3 "*) ;;
2122     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2123   esac
2124 fi
2125 AC_SUBST(CXXFLAGS_FOR_TARGET)
2126
2127 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2128 # the named directory are copied to $(tooldir)/sys-include.
2129 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2130   if test x${is_cross_compiler} = xno ; then
2131     echo 1>&2 '***' --with-headers is only supported when cross compiling
2132     exit 1
2133   fi
2134   if test x"${with_headers}" != xyes ; then
2135     x=${gcc_cv_tool_prefix}
2136     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2137   fi
2138 fi
2139
2140 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2141 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2142 # are permitted.
2143 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2144   if test x${is_cross_compiler} = xno ; then
2145     echo 1>&2 '***' --with-libs is only supported when cross compiling
2146     exit 1
2147   fi
2148   if test x"${with_libs}" != xyes ; then
2149     # Copy the libraries in reverse order, so that files in the first named
2150     # library override files in subsequent libraries.
2151     x=${gcc_cv_tool_prefix}
2152     for l in ${with_libs}; do
2153       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2154     done
2155   fi
2156 fi
2157
2158 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2159 #
2160 # This is done by determining whether or not the appropriate directory
2161 # is available, and by checking whether or not specific configurations
2162 # have requested that this magic not happen.
2163
2164 # The command line options always override the explicit settings in 
2165 # configure.in, and the settings in configure.in override this magic.
2166 #
2167 # If the default for a toolchain is to use GNU as and ld, and you don't 
2168 # want to do that, then you should use the --without-gnu-as and
2169 # --without-gnu-ld options for the configure script.  Similarly, if
2170 # the default is to use the included zlib and you don't want to do that,
2171 # you should use the --with-system-zlib option for the configure script.
2172
2173 if test x${use_gnu_as} = x &&
2174    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2175   with_gnu_as=yes
2176   extra_host_args="$extra_host_args --with-gnu-as"
2177 fi
2178
2179 if test x${use_gnu_ld} = x &&
2180    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2181   with_gnu_ld=yes
2182   extra_host_args="$extra_host_args --with-gnu-ld"
2183 fi
2184
2185 if test x${use_included_zlib} = x &&
2186    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2187   :
2188 else
2189   with_system_zlib=yes
2190   extra_host_args="$extra_host_args --with-system-zlib"
2191 fi
2192
2193 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2194 # can detect this case.
2195
2196 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2197   with_newlib=yes
2198   extra_host_args="$extra_host_args --with-newlib"
2199 fi
2200
2201 # Handle ${copy_dirs}
2202 set fnord ${copy_dirs}
2203 shift
2204 while test $# != 0 ; do
2205   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2206     :
2207   else
2208     echo Copying $1 to $2
2209
2210     # Use the install script to create the directory and all required
2211     # parent directories.
2212     if test -d $2 ; then
2213       :
2214     else
2215       echo >config.temp
2216       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2217     fi
2218
2219     # Copy the directory, assuming we have tar.
2220     # FIXME: Should we use B in the second tar?  Not all systems support it.
2221     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2222
2223     # It is the responsibility of the user to correctly adjust all
2224     # symlinks.  If somebody can figure out how to handle them correctly
2225     # here, feel free to add the code.
2226
2227     echo $1 > $2/COPIED
2228   fi
2229   shift; shift
2230 done
2231
2232 # Determine a target-dependent exec_prefix that the installed
2233 # gcc will search in.  Keep this list sorted by triplet, with
2234 # the *-*-osname triplets last.
2235 md_exec_prefix=
2236 case "${target}" in
2237   i[[34567]]86-pc-msdosdjgpp*)
2238     md_exec_prefix=/dev/env/DJDIR/bin
2239     ;;
2240   *-*-hpux* | \
2241   *-*-nto-qnx* | \
2242   *-*-solaris2*)
2243     md_exec_prefix=/usr/ccs/bin
2244     ;;
2245 esac
2246
2247 extra_arflags_for_target=
2248 extra_nmflags_for_target=
2249 extra_ranlibflags_for_target=
2250 target_makefile_frag=/dev/null
2251 case "${target}" in
2252   spu-*-*)
2253     target_makefile_frag="config/mt-spu"
2254     ;;
2255   mips*-sde-elf*)
2256     target_makefile_frag="config/mt-sde"
2257     ;;
2258   mipsisa*-*-elfoabi*)
2259     target_makefile_frag="config/mt-mips-elfoabi"
2260     ;;
2261   mips*-*-*linux* | mips*-*-gnu*)
2262     target_makefile_frag="config/mt-mips-gnu"
2263     ;;
2264   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2265     target_makefile_frag="config/mt-gnu"
2266     ;;
2267   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2268     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm 
2269     # commands to handle both 32-bit and 64-bit objects.  These flags are
2270     # harmless if we're using GNU nm or ar.
2271     extra_arflags_for_target=" -X32_64"
2272     extra_nmflags_for_target=" -B -X32_64"
2273     ;;
2274   *-*-darwin[[3-9]]*)
2275     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2276     extra_ranlibflags_for_target=" -c"
2277     ;;
2278 esac
2279
2280 alphaieee_frag=/dev/null
2281 case $target in
2282   alpha*-*-*)
2283     # This just makes sure to use the -mieee option to build target libs.
2284     # This should probably be set individually by each library.
2285     alphaieee_frag="config/mt-alphaieee"
2286     ;;
2287 esac
2288
2289 # If --enable-target-optspace always use -Os instead of -O2 to build
2290 # the target libraries, similarly if it is not specified, use -Os
2291 # on selected platforms.
2292 ospace_frag=/dev/null
2293 case "${enable_target_optspace}:${target}" in
2294   yes:*)
2295     ospace_frag="config/mt-ospace"
2296     ;;
2297   :d30v-*)
2298     ospace_frag="config/mt-d30v"
2299     ;;
2300   :m32r-* | :d10v-* | :fr30-*)
2301     ospace_frag="config/mt-ospace"
2302     ;;
2303   no:* | :*)
2304     ;;
2305   *)
2306     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2307     ;;
2308 esac
2309
2310 # Default to using --with-stabs for certain targets.
2311 if test x${with_stabs} = x ; then
2312   case "${target}" in
2313   mips*-*-irix[[56]]*)
2314     ;;
2315   mips*-*-* | alpha*-*-osf*)
2316     with_stabs=yes;
2317     extra_host_args="${extra_host_args} --with-stabs"
2318     ;;
2319   esac
2320 fi
2321
2322 # hpux11 in 64bit mode has libraries in a weird place.  Arrange to find
2323 # them automatically.
2324 case "${host}" in
2325   hppa*64*-*-hpux11*)   
2326     extra_host_args="$extra_host_args -x-libraries=/usr/lib/pa20_64 -x-includes=/usr/X11R6/include"
2327     ;;
2328 esac
2329
2330 # Some systems (e.g., one of the i386-aix systems the gas testers are
2331 # using) don't handle "\$" correctly, so don't use it here.
2332 tooldir='${exec_prefix}'/${target_noncanonical}
2333 build_tooldir=${tooldir}
2334
2335 # Create a .gdbinit file which runs the one in srcdir
2336 # and tells GDB to look there for source files.
2337
2338 if test -r ${srcdir}/.gdbinit ; then
2339   case ${srcdir} in
2340     .) ;;
2341     *) cat > ./.gdbinit <<EOF
2342 # ${NO_EDIT}
2343 dir ${srcdir}
2344 dir .
2345 source ${srcdir}/.gdbinit
2346 EOF
2347     ;;
2348   esac
2349 fi
2350
2351 # Make sure that the compiler is able to generate an executable.  If it
2352 # can't, we are probably in trouble.  We don't care whether we can run the
2353 # executable--we might be using a cross compiler--we only care whether it
2354 # can be created.  At this point the main configure script has set CC.
2355 we_are_ok=no
2356 echo "int main () { return 0; }" > conftest.c
2357 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2358 if test $? = 0 ; then
2359   if test -s conftest || test -s conftest.exe ; then
2360     we_are_ok=yes
2361   fi
2362 fi 
2363 case $we_are_ok in
2364   no)
2365     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2366     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2367     rm -f conftest*
2368     exit 1
2369     ;;
2370 esac
2371 rm -f conftest*
2372
2373 # The Solaris /usr/ucb/cc compiler does not appear to work.
2374 case "${host}" in
2375   sparc-sun-solaris2*)
2376       CCBASE="`echo ${CC-cc} | sed 's/ .*$//'`"
2377       if test "`type $CCBASE | sed 's/^[[^/]]*//'`" = "/usr/ucb/cc" ; then
2378           could_use=
2379           test -d /opt/SUNWspro/bin && could_use="/opt/SUNWspro/bin"
2380           if test -d /opt/cygnus/bin ; then
2381               if test "$could_use" = "" ; then
2382                   could_use="/opt/cygnus/bin"
2383               else
2384                   could_use="$could_use or /opt/cygnus/bin"
2385               fi
2386           fi
2387         if test "$could_use" = "" ; then
2388             echo "Warning: compilation may fail because you're using"
2389             echo "/usr/ucb/cc.  You should change your PATH or CC "
2390             echo "variable and rerun configure."
2391         else
2392             echo "Warning: compilation may fail because you're using"
2393             echo "/usr/ucb/cc, when you should use the C compiler from"
2394             echo "$could_use.  You should change your"
2395             echo "PATH or CC variable and rerun configure."
2396         fi
2397       fi
2398   ;;
2399 esac
2400
2401 # Decide which environment variable is used to find dynamic libraries.
2402 case "${host}" in
2403   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2404   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2405   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2406   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2407 esac
2408
2409 # On systems where the dynamic library environment variable is PATH,
2410 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2411 # built executables to PATH.
2412 if test "$RPATH_ENVVAR" = PATH; then
2413   GCC_SHLIB_SUBDIR=/shlib
2414 else
2415   GCC_SHLIB_SUBDIR=
2416 fi
2417
2418 # Record target_configdirs and the configure arguments for target and
2419 # build configuration in Makefile.
2420 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2421 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2422
2423 # If we are building libgomp, bootstrap it.
2424 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2425   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2426 fi
2427
2428 # Determine whether gdb needs tk/tcl or not.
2429 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2430 # and in that case we want gdb to be built without tk.  Ugh!
2431 # In fact I believe gdb is the *only* package directly dependent on tk,
2432 # so we should be able to put the 'maybe's in unconditionally and
2433 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2434 # 100% sure that that's safe though.
2435
2436 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2437 case "$enable_gdbtk" in
2438   no)
2439     GDB_TK="" ;;
2440   yes)
2441     GDB_TK="${gdb_tk}" ;;
2442   *)
2443     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2444     # distro.  Eventually someone will fix this and move Insight, nee
2445     # gdbtk to a separate directory.
2446     if test -d ${srcdir}/gdb/gdbtk ; then
2447       GDB_TK="${gdb_tk}"
2448     else
2449       GDB_TK=""
2450     fi
2451     ;;
2452 esac
2453 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2454 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2455
2456 # Strip out unwanted targets.
2457
2458 # While at that, we remove Makefiles if we were started for recursive
2459 # configuration, so that the top-level Makefile reconfigures them,
2460 # like we used to do when configure itself was recursive.
2461
2462 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2463 # but now we're fixing up the Makefile ourselves with the additional
2464 # commands passed to AC_CONFIG_FILES.  Use separate variables
2465 # extrasub-{build,host,target} not because there is any reason to split
2466 # the substitutions up that way, but only to remain below the limit of
2467 # 99 commands in a script, for HP-UX sed.
2468 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2469
2470 AC_ARG_ENABLE([bootstrap],
2471 [AS_HELP_STRING([--enable-bootstrap],
2472                 [enable bootstrapping @<:@yes if native build@:>@])],,
2473 enable_bootstrap=default)
2474
2475 # Issue errors and warnings for invalid/strange bootstrap combinations.
2476 case "$configdirs" in
2477   *gcc*) have_compiler=yes ;;
2478   *) have_compiler=no ;;
2479 esac
2480
2481 case "$have_compiler:$host:$target:$enable_bootstrap" in
2482   *:*:*:no) ;;
2483
2484   # Default behavior.  Enable bootstrap if we have a compiler
2485   # and we are in a native configuration.
2486   yes:$build:$build:default)
2487     enable_bootstrap=yes ;;
2488
2489   *:*:*:default)
2490     enable_bootstrap=no ;;
2491
2492   # We have a compiler and we are in a native configuration, bootstrap is ok
2493   yes:$build:$build:yes)
2494     ;;
2495
2496   # Other configurations, but we have a compiler.  Assume the user knows
2497   # what he's doing.
2498   yes:*:*:yes)
2499     AC_MSG_WARN([trying to bootstrap a cross compiler])
2500     ;;
2501
2502   # No compiler: if they passed --enable-bootstrap explicitly, fail
2503   no:*:*:yes)
2504     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
2505
2506   # Fail if wrong command line
2507   *)
2508     AC_MSG_ERROR([invalid option for --enable-bootstrap])
2509     ;;
2510 esac
2511
2512 case ",$enable_languages,:$ENABLE_BUILD_WITH_CXX:$enable_bootstrap" in
2513   *,c++,*:yes:yes) ;;
2514   *:yes:yes)
2515     AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx requires c++ in --enable-languages])
2516     ;;
2517 esac
2518
2519 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2520   yes:yes:*\ gold\ *:*,c++,*) ;;
2521   yes:yes:*\ gold\ *:*)
2522     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2523     ;;
2524 esac
2525
2526 # Adjust the toplevel makefile according to whether bootstrap was selected.
2527 case $enable_bootstrap in
2528   yes)
2529     bootstrap_suffix=bootstrap
2530     BUILD_CONFIG=bootstrap-debug
2531     ;;
2532   no)
2533     bootstrap_suffix=no-bootstrap
2534     BUILD_CONFIG=
2535     ;;
2536 esac
2537
2538 AC_MSG_CHECKING(for default BUILD_CONFIG)
2539
2540 AC_ARG_WITH([build-config],
2541   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2542                   [use config/NAME.mk build configuration])],
2543   [case $with_build_config in
2544    yes) with_build_config= ;;
2545    no) with_build_config= BUILD_CONFIG= ;;
2546    esac])
2547
2548 if test "x${with_build_config}" != x; then
2549   BUILD_CONFIG=$with_build_config
2550 else
2551   case $BUILD_CONFIG in
2552   bootstrap-debug)
2553     if echo "int f (void) { return 0; }" > conftest.c &&
2554        ${CC} -c conftest.c &&
2555        mv conftest.o conftest.o.g0 &&
2556        ${CC} -c -g conftest.c &&
2557        mv conftest.o conftest.o.g &&
2558        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2559       :
2560     else
2561       BUILD_CONFIG=
2562     fi
2563     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2564     ;;
2565   esac
2566 fi
2567 AC_MSG_RESULT($BUILD_CONFIG)
2568 AC_SUBST(BUILD_CONFIG)
2569
2570 extrasub_build=
2571 for module in ${build_configdirs} ; do
2572   if test -z "${no_recursion}" \
2573      && test -f ${build_subdir}/${module}/Makefile; then
2574     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2575     rm -f ${build_subdir}/${module}/Makefile
2576   fi
2577   extrasub_build="$extrasub_build
2578 /^@if build-$module\$/d
2579 /^@endif build-$module\$/d
2580 /^@if build-$module-$bootstrap_suffix\$/d
2581 /^@endif build-$module-$bootstrap_suffix\$/d"
2582 done
2583 extrasub_host=
2584 for module in ${configdirs} ; do
2585   if test -z "${no_recursion}"; then
2586     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2587       if test -f ${file}; then
2588         echo 1>&2 "*** removing ${file} to force reconfigure"
2589         rm -f ${file}
2590       fi
2591     done
2592   fi
2593   extrasub_host="$extrasub_host
2594 /^@if $module\$/d
2595 /^@endif $module\$/d
2596 /^@if $module-$bootstrap_suffix\$/d
2597 /^@endif $module-$bootstrap_suffix\$/d"
2598 done
2599 extrasub_target=
2600 for module in ${target_configdirs} ; do
2601   if test -z "${no_recursion}" \
2602      && test -f ${target_subdir}/${module}/Makefile; then
2603     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2604     rm -f ${target_subdir}/${module}/Makefile
2605   fi
2606
2607   # We only bootstrap target libraries listed in bootstrap_target_libs.
2608   case $bootstrap_target_libs in
2609     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2610     *) target_bootstrap_suffix=no-bootstrap ;;
2611   esac
2612
2613   extrasub_target="$extrasub_target
2614 /^@if target-$module\$/d
2615 /^@endif target-$module\$/d
2616 /^@if target-$module-$target_bootstrap_suffix\$/d
2617 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2618 done
2619
2620 # Do the final fixup along with target modules.
2621 extrasub_target="$extrasub_target
2622 /^@if /,/^@endif /d"
2623
2624 # Create the serialization dependencies.  This uses a temporary file.
2625
2626 AC_ARG_ENABLE([serial-configure],
2627 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2628                 [force sequential configuration of
2629                  sub-packages for the host, target or build
2630                  machine, or all sub-packages])])
2631
2632 case ${enable_serial_configure} in
2633   yes)
2634     enable_serial_build_configure=yes
2635     enable_serial_host_configure=yes
2636     enable_serial_target_configure=yes
2637     ;;
2638 esac
2639
2640 # These force 'configure's to be done one at a time, to avoid problems
2641 # with contention over a shared config.cache.
2642 rm -f serdep.tmp
2643 echo '# serdep.tmp' > serdep.tmp
2644 olditem=
2645 test "x${enable_serial_build_configure}" = xyes &&
2646 for item in ${build_configdirs} ; do
2647   case ${olditem} in
2648     "") ;;
2649     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2650   esac
2651   olditem=${item}
2652 done
2653 olditem=
2654 test "x${enable_serial_host_configure}" = xyes &&
2655 for item in ${configdirs} ; do
2656   case ${olditem} in
2657     "") ;;
2658     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2659   esac
2660   olditem=${item}
2661 done
2662 olditem=
2663 test "x${enable_serial_target_configure}" = xyes &&
2664 for item in ${target_configdirs} ; do
2665   case ${olditem} in
2666     "") ;;
2667     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2668   esac
2669   olditem=${item}
2670 done
2671 serialization_dependencies=serdep.tmp
2672 AC_SUBST_FILE(serialization_dependencies)
2673
2674 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2675 # target, nonopt, and variable assignments.  These are the ones we
2676 # might not want to pass down to subconfigures.  The exception being
2677 # --cache-file=/dev/null, which is used to turn off the use of cache
2678 # files altogether, and which should be passed on to subconfigures.
2679 # Also strip program-prefix, program-suffix, and program-transform-name,
2680 # so that we can pass down a consistent program-transform-name.
2681 baseargs=
2682 tbaseargs=
2683 keep_next=no
2684 skip_next=no
2685 eval "set -- $ac_configure_args"
2686 for ac_arg
2687 do
2688   if test X"$skip_next" = X"yes"; then
2689     skip_next=no
2690     continue
2691   fi
2692   if test X"$keep_next" = X"yes"; then
2693     case $ac_arg in
2694       *\'*)
2695         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2696     esac
2697     baseargs="$baseargs '$ac_arg'"
2698     tbaseargs="$tbaseargs '$ac_arg'"
2699     keep_next=no
2700     continue
2701   fi
2702
2703   # Handle separated arguments.  Based on the logic generated by
2704   # autoconf 2.59.
2705   case $ac_arg in
2706     *=* | --config-cache | -C | -disable-* | --disable-* \
2707       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2708       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2709       | -with-* | --with-* | -without-* | --without-* | --x)
2710       separate_arg=no
2711       ;;
2712     -*)
2713       separate_arg=yes
2714       ;;
2715     *)
2716       separate_arg=no
2717       ;;
2718   esac
2719
2720   skip_targ=no
2721   case $ac_arg in
2722 changequote(,)
2723   --with-* | --without-*)
2724     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2725
2726     case $libopt in
2727     *[-_]include)
2728       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2729       ;;
2730     *[-_]lib)
2731       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2732       ;;
2733     *)
2734       lib=$libopt
2735       ;;
2736     esac
2737 changequote([,])
2738
2739     case $lib in
2740     mpc | mpfr | gmp | ppl | cloog)
2741       # If we're processing --with-$lib, --with-$lib-include or
2742       # --with-$lib-lib, for one of the libs above, and target is
2743       # different from host, don't pass the current argument to any
2744       # target library's configure.
2745       if test x$is_cross_compiler = xyes; then
2746         skip_targ=yes
2747       fi
2748       ;;
2749     esac
2750     ;;
2751   esac
2752
2753   case "$ac_arg" in
2754     --cache-file=/dev/null | \
2755     -cache-file=/dev/null )
2756       # Handled here to avoid the test to skip args below.
2757       baseargs="$baseargs '$ac_arg'"
2758       tbaseargs="$tbaseargs '$ac_arg'"
2759       # Assert: $separate_arg should always be no.
2760       keep_next=$separate_arg
2761       ;;
2762     --no*)
2763       continue
2764       ;;
2765     --c* | \
2766     --sr* | \
2767     --ho* | \
2768     --bu* | \
2769     --t* | \
2770     --program-* | \
2771     -cache_file* | \
2772     -srcdir* | \
2773     -host* | \
2774     -build* | \
2775     -target* | \
2776     -program-prefix* | \
2777     -program-suffix* | \
2778     -program-transform-name* )
2779       skip_next=$separate_arg
2780       continue
2781       ;;
2782     -*)
2783       # An option.  Add it.
2784       case $ac_arg in
2785         *\'*)
2786           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2787       esac
2788       baseargs="$baseargs '$ac_arg'"
2789       if test X"$skip_targ" = Xno; then
2790         tbaseargs="$tbaseargs '$ac_arg'"
2791       fi
2792       keep_next=$separate_arg
2793       ;;
2794     *)
2795       # Either a variable assignment, or a nonopt (triplet).  Don't
2796       # pass it down; let the Makefile handle this.
2797       continue
2798       ;;
2799   esac
2800 done
2801 # Remove the initial space we just introduced and, as these will be
2802 # expanded by make, quote '$'.
2803 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2804
2805 # Add in --program-transform-name, after --program-prefix and
2806 # --program-suffix have been applied to it.  Autoconf has already
2807 # doubled dollar signs and backslashes in program_transform_name; we want
2808 # the backslashes un-doubled, and then the entire thing wrapped in single
2809 # quotes, because this will be expanded first by make and then by the shell. 
2810 # Also, because we want to override the logic in subdir configure scripts to
2811 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2812 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2813 ${program_transform_name}
2814 EOF_SED
2815 gcc_transform_name=`cat conftestsed.out`
2816 rm -f conftestsed.out
2817 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2818 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2819 if test "$silent" = yes; then
2820   baseargs="$baseargs --silent"
2821   tbaseargs="$tbaseargs --silent"
2822 fi
2823 baseargs="$baseargs --disable-option-checking"
2824 tbaseargs="$tbaseargs --disable-option-checking"
2825
2826 # Record and document user additions to sub configure arguments.
2827 AC_ARG_VAR([build_configargs],
2828            [additional configure arguments for build directories])
2829 AC_ARG_VAR([host_configargs],
2830            [additional configure arguments for host directories])
2831 AC_ARG_VAR([target_configargs],
2832            [additional configure arguments for target directories])
2833
2834 # For the build-side libraries, we just need to pretend we're native,
2835 # and not use the same cache file.  Multilibs are neither needed nor
2836 # desired.
2837 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2838
2839 # For host modules, accept cache file option, or specification as blank.
2840 case "${cache_file}" in
2841 "") # empty
2842   cache_file_option="" ;;
2843 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2844   cache_file_option="--cache-file=${cache_file}" ;;
2845 *) # relative path
2846   cache_file_option="--cache-file=../${cache_file}" ;;
2847 esac
2848
2849 # Host dirs don't like to share a cache file either, horribly enough.
2850 # This seems to be due to autoconf 2.5x stupidity.
2851 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2852
2853 target_configargs="$target_configargs ${tbaseargs}"
2854
2855 # Passing a --with-cross-host argument lets the target libraries know
2856 # whether they are being built with a cross-compiler or being built
2857 # native.  However, it would be better to use other mechanisms to make the
2858 # sorts of decisions they want to make on this basis.  Please consider
2859 # this option to be deprecated.  FIXME.
2860 if test x${is_cross_compiler} = xyes ; then
2861   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2862 fi
2863
2864 # Default to --enable-multilib.
2865 if test x${enable_multilib} = x ; then
2866   target_configargs="--enable-multilib ${target_configargs}"
2867 fi
2868
2869 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2870 # changed from the earlier setting of with_newlib.
2871 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2872   target_configargs="--with-newlib ${target_configargs}"
2873 fi
2874
2875 # Different target subdirs use different values of certain variables
2876 # (notably CXX).  Worse, multilibs use *lots* of different values.
2877 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2878 # it doesn't automatically accept command-line overrides of them.
2879 # This means it's not safe for target subdirs to share a cache file,
2880 # which is disgusting, but there you have it.  Hopefully this can be
2881 # fixed in future.  It's still worthwhile to use a cache file for each
2882 # directory.  I think.
2883
2884 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2885 # We need to pass --target, as newer autoconf's requires consistency
2886 # for target_alias and gcc doesn't manage it consistently.
2887 target_configargs="--cache-file=./config.cache ${target_configargs}"
2888
2889 FLAGS_FOR_TARGET=
2890 case " $target_configdirs " in
2891  *" newlib "*)
2892   case " $target_configargs " in
2893   *" --with-newlib "*)
2894    case "$target" in
2895     *-cygwin*)
2896       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2897       ;;
2898    esac
2899
2900    # If we're not building GCC, don't discard standard headers.
2901    if test -d ${srcdir}/gcc; then
2902      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2903
2904      if test "${build}" != "${host}"; then
2905        # On Canadian crosses, CC_FOR_TARGET will have already been set
2906        # by `configure', so we won't have an opportunity to add -Bgcc/
2907        # to it.  This is right: we don't want to search that directory
2908        # for binaries, but we want the header files in there, so add
2909        # them explicitly.
2910        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2911
2912        # Someone might think of using the pre-installed headers on
2913        # Canadian crosses, in case the installed compiler is not fully
2914        # compatible with the compiler being built.  In this case, it
2915        # would be better to flag an error than risking having
2916        # incompatible object files being constructed.  We can't
2917        # guarantee that an error will be flagged, but let's hope the
2918        # compiler will do it, when presented with incompatible header
2919        # files.
2920      fi
2921    fi
2922
2923    case "${target}-${is_cross_compiler}" in
2924    i[[3456789]]86-*-linux*-no)
2925       # Here host == target, so we don't need to build gcc,
2926       # so we don't want to discard standard headers.
2927       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2928       ;;
2929    *)
2930       # If we're building newlib, use its generic headers last, but search
2931       # for any libc-related directories first (so make it the last -B
2932       # switch).
2933       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2934
2935       # If we're building libgloss, find the startup file, simulator library
2936       # and linker script.
2937       case " $target_configdirs " in
2938         *" libgloss "*)
2939         # Look for startup file, simulator library and maybe linker script.
2940         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2941         # Look for libnosys.a in case the target needs it.
2942         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2943         # Most targets have the linker script in the source directory.
2944         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2945         ;;
2946       esac
2947       ;;
2948    esac
2949    ;;
2950   esac
2951   ;;
2952 esac
2953
2954 case "$target" in
2955   x86_64-*mingw* | *-w64-mingw*)
2956   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2957   # however, use a symlink named 'mingw' in ${prefix} .
2958     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2959     ;;
2960   *-mingw*)
2961   # MinGW can't be handled as Cygwin above since it does not use newlib.
2962     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2963     ;;
2964 esac
2965
2966 # Allow the user to override the flags for
2967 # our build compiler if desired.
2968 if test x"${build}" = x"${host}" ; then
2969   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2970   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2971   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2972 fi
2973
2974 # On Canadian crosses, we'll be searching the right directories for
2975 # the previously-installed cross compiler, so don't bother to add
2976 # flags for directories within the install tree of the compiler
2977 # being built; programs in there won't even run.
2978 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2979   # Search for pre-installed headers if nothing else fits.
2980   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2981 fi
2982
2983 if test "x${use_gnu_ld}" = x &&
2984    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2985   # Arrange for us to find uninstalled linker scripts.
2986   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2987 fi
2988
2989 # Search for other target-specific linker scripts and such.
2990 case "${target}" in
2991   mep*)
2992     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2993     ;;
2994 esac
2995
2996 # Makefile fragments.
2997 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2998 do
2999   eval fragval=\$$frag
3000   if test $fragval != /dev/null; then
3001     eval $frag=${srcdir}/$fragval
3002   fi
3003 done
3004 AC_SUBST_FILE(host_makefile_frag)
3005 AC_SUBST_FILE(target_makefile_frag)
3006 AC_SUBST_FILE(alphaieee_frag)
3007 AC_SUBST_FILE(ospace_frag)
3008
3009 # Miscellanea: directories, flags, etc.
3010 AC_SUBST(RPATH_ENVVAR)
3011 AC_SUBST(GCC_SHLIB_SUBDIR)
3012 AC_SUBST(tooldir)
3013 AC_SUBST(build_tooldir)
3014 AC_SUBST(CONFIGURE_GDB_TK)
3015 AC_SUBST(GDB_TK)
3016 AC_SUBST(INSTALL_GDB_TK)
3017
3018 # Build module lists & subconfigure args.
3019 AC_SUBST(build_configargs)
3020 AC_SUBST(build_configdirs)
3021
3022 # Host module lists & subconfigure args.
3023 AC_SUBST(host_configargs)
3024 AC_SUBST(configdirs)
3025 AC_SUBST(target_configdirs)
3026
3027 # Target module lists & subconfigure args.
3028 AC_SUBST(target_configargs)
3029
3030
3031 # Build tools.
3032 AC_SUBST(AR_FOR_BUILD)
3033 AC_SUBST(AS_FOR_BUILD)
3034 AC_SUBST(CC_FOR_BUILD)
3035 AC_SUBST(CFLAGS_FOR_BUILD)
3036 AC_SUBST(CXXFLAGS_FOR_BUILD)
3037 AC_SUBST(CXX_FOR_BUILD)
3038 AC_SUBST(DLLTOOL_FOR_BUILD)
3039 AC_SUBST(GCJ_FOR_BUILD)
3040 AC_SUBST(GFORTRAN_FOR_BUILD)
3041 AC_SUBST(GOC_FOR_BUILD)
3042 AC_SUBST(LDFLAGS_FOR_BUILD)
3043 AC_SUBST(LD_FOR_BUILD)
3044 AC_SUBST(NM_FOR_BUILD)
3045 AC_SUBST(RANLIB_FOR_BUILD)
3046 AC_SUBST(WINDMC_FOR_BUILD)
3047 AC_SUBST(WINDRES_FOR_BUILD)
3048
3049 # Generate default definitions for YACC, M4, LEX and other programs that run
3050 # on the build machine.  These are used if the Makefile can't locate these
3051 # programs in objdir.
3052 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3053
3054 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3055 case " $build_configdirs " in
3056   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3057 esac
3058
3059 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3060 case " $build_configdirs " in
3061   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3062 esac
3063
3064 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3065 case " $build_configdirs " in
3066   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3067 esac
3068
3069 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3070 case " $build_configdirs " in
3071   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3072   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3073 esac
3074
3075 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3076 case " $build_configdirs " in
3077   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3078 esac
3079
3080 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3081 case " $build_configdirs " in
3082   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3083   *)
3084 changequote(,)
3085     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3086     # higher, else we use the "missing" dummy.
3087     if ${MAKEINFO} --version \
3088        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3089       :
3090     else
3091       MAKEINFO="$MISSING makeinfo"
3092     fi
3093     ;;
3094 changequote([,])
3095 esac
3096
3097 # FIXME: expect and dejagnu may become build tools?
3098
3099 AC_CHECK_PROGS(EXPECT, expect, expect)
3100 case " $configdirs " in
3101   *" expect "*)
3102     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3103     ;;
3104 esac
3105
3106 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3107 case " $configdirs " in
3108   *" dejagnu "*)
3109     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3110     ;;
3111 esac
3112
3113
3114 # Host tools.
3115 NCN_STRICT_CHECK_TOOLS(AR, ar)
3116 NCN_STRICT_CHECK_TOOLS(AS, as)
3117 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3118 NCN_STRICT_CHECK_TOOLS(LD, ld)
3119 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3120 NCN_STRICT_CHECK_TOOLS(NM, nm)
3121 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3122 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3123 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3124 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3125 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3126 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3127 AC_SUBST(CC)
3128 AC_SUBST(CXX)
3129 AC_SUBST(CFLAGS)
3130 AC_SUBST(CXXFLAGS)
3131
3132 # Target tools.
3133 AC_ARG_WITH([build-time-tools], 
3134   [AS_HELP_STRING([--with-build-time-tools=PATH],
3135                   [use given path to find target tools during the build])],
3136   [case x"$withval" in
3137      x/*) ;;
3138      *)
3139        with_build_time_tools=
3140        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3141        ;;
3142    esac],
3143   [with_build_time_tools=])
3144
3145 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3146 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3147 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3148 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3149 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3150 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3151
3152 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3153 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3154 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3155 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3156 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3157 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3158 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3159 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3160 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3161 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3162 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3163
3164 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3165
3166 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3167 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3168 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3169 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3170 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3171                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3172                 c++)
3173 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3174                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3175                 c++)
3176 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3177 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3178 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3179                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3180 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3181                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3182 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3183                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3184 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3185 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3186 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3187 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3188 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3189 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3190 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3191 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3192
3193 AC_SUBST(FLAGS_FOR_TARGET)
3194 AC_SUBST(RAW_CXX_FOR_TARGET)
3195
3196 # Certain tools may need extra flags.
3197 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3198 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3199 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3200
3201 # When building target libraries, except in a Canadian cross, we use
3202 # the same toolchain as the compiler we just built.
3203 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3204 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3205 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3206 if test $host = $build; then
3207   case " $configdirs " in
3208     *" gcc "*)
3209       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3210       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3211       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3212       ;;
3213   esac
3214 fi
3215
3216 AC_SUBST(COMPILER_AS_FOR_TARGET)
3217 AC_SUBST(COMPILER_LD_FOR_TARGET)
3218 AC_SUBST(COMPILER_NM_FOR_TARGET)
3219
3220 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3221 AC_ARG_ENABLE(maintainer-mode,
3222 [AS_HELP_STRING([--enable-maintainer-mode],
3223                 [enable make rules and dependencies not useful
3224                  (and sometimes confusing) to the casual installer])],
3225       USE_MAINTAINER_MODE=$enableval,
3226       USE_MAINTAINER_MODE=no)
3227 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3228 AC_SUBST(MAINTAINER_MODE_TRUE)
3229 AC_SUBST(MAINTAINER_MODE_FALSE)
3230 if test "$USE_MAINTAINER_MODE" = yes; then
3231   MAINTAINER_MODE_TRUE=
3232   MAINTAINER_MODE_FALSE='#'
3233 else
3234   MAINTAINER_MODE_TRUE='#'
3235   MAINTAINER_MODE_FALSE=
3236 fi      
3237 MAINT=$MAINTAINER_MODE_TRUE
3238 AC_SUBST(MAINT)dnl
3239
3240 # ---------------------
3241 # GCC bootstrap support
3242 # ---------------------
3243
3244 # Stage specific cflags for build.
3245 stage1_cflags="-g"
3246 case $build in
3247   vax-*-*)
3248     case ${GCC} in
3249       yes) stage1_cflags="-g -Wa,-J" ;;
3250       *) stage1_cflags="-g -J" ;;
3251     esac ;;
3252 esac
3253
3254 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3255 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3256   saved_CFLAGS="$CFLAGS"
3257
3258   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3259   CFLAGS="$CFLAGS -fkeep-inline-functions"
3260   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3261   AC_TRY_COMPILE([
3262 #if (__GNUC__ < 3) \
3263     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3264                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3265 #error http://gcc.gnu.org/PR29382
3266 #endif
3267     ],,
3268     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3269     [AC_MSG_RESULT([no])])
3270
3271   CFLAGS="$saved_CFLAGS"
3272 fi
3273
3274 AC_SUBST(stage1_cflags)
3275
3276 # Enable --enable-checking in stage1 of the compiler.
3277 AC_ARG_ENABLE(stage1-checking,
3278 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3279                 [choose additional checking for stage1 of the compiler])],
3280 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3281 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3282   stage1_checking=--enable-checking=yes,types
3283 else
3284   stage1_checking=--enable-checking=$enable_checking,types
3285 fi])
3286 AC_SUBST(stage1_checking)
3287
3288 # Enable -Werror in bootstrap stage2 and later.
3289 AC_ARG_ENABLE(werror,
3290 [AS_HELP_STRING([--enable-werror],
3291                 [enable -Werror in bootstrap stage2 and later])], [],
3292 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3293   enable_werror=yes
3294 else
3295   enable_werror=no
3296 fi])
3297 case ${enable_werror} in
3298   yes) stage2_werror_flag="--enable-werror-always" ;;
3299   *) stage2_werror_flag="" ;;
3300 esac
3301 AC_SUBST(stage2_werror_flag)
3302
3303 # Specify what files to not compare during bootstrap.
3304
3305 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3306 case "$target" in
3307   hppa*64*-*-hpux*) ;;
3308   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3309 esac
3310 case " $configdirs " in
3311 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3312 esac
3313 AC_SUBST(compare_exclusions)
3314
3315 AC_CONFIG_FILES([Makefile],
3316   [sed "$extrasub_build" Makefile |
3317    sed "$extrasub_host" |
3318    sed "$extrasub_target" > mf$$
3319    mv -f mf$$ Makefile],
3320   [extrasub_build="$extrasub_build"
3321    extrasub_host="$extrasub_host"
3322    extrasub_target="$extrasub_target"])
3323 AC_OUTPUT