configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 144
 145 # libgcj represents the runtime libraries only used by gcj.
 146 libgcj="target-libffi \
 147         target-zlib \
 148         target-libjava"
 149
 150 # these libraries are built for the target environment, and are built after
 151 # the host libraries and the host tools (which may be a cross compiler)
 152 # Note that libiberty is not a target library.
 153 target_libraries="target-libgcc \
 154                 target-libgloss \
 155                 target-newlib \
 156                 target-libgomp \
 157                 target-libstdc++-v3 \
 158                 target-libmudflap \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-boehm-gc \
 163                 ${libgcj} \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 # Make sure we don't let ZLIB be added if we didn't want it.
 242 if test x$with_system_zlib = xyes ; then
 243   use_included_zlib=no
 244   noconfigdirs="$noconfigdirs zlib"
 245 fi
 246
 247 # some tools are so dependent upon X11 that if we're not building with X,
 248 # it's not even worth trying to configure, much less build, that tool.
 249
 250 case ${with_x} in
 251   yes | "") ;; # the default value for this tree is that X11 is available
 252   no)
 253     skipdirs="${skipdirs} tk itcl libgui"
 254     # We won't be able to build gdbtk without X.
 255     enable_gdbtk=no
 256     ;;
 257   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 258 esac
 259
 260 # Some are only suitable for cross toolchains.
 261 # Remove these if host=target.
 262 cross_only="target-libgloss target-newlib target-opcodes"
 263
 264 case $is_cross_compiler in
 265   no) skipdirs="${skipdirs} ${cross_only}" ;;
 266 esac
 267
 268 # If both --with-headers and --with-libs are specified, default to
 269 # --without-newlib.
 270 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 271    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 272   if test x"${with_newlib}" = x ; then
 273     with_newlib=no
 274   fi
 275 fi
 276
 277 # Recognize --with-newlib/--without-newlib.
 278 case ${with_newlib} in
 279   no) skipdirs="${skipdirs} target-newlib" ;;
 280   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 281 esac
 282
 283 # Handle --enable-gold, --enable-ld.
 284 # --disable-gold [--enable-ld]
 285 #     Build only ld.  Default option.
 286 # --enable-gold [--enable-ld]
 287 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 288 #     as "ld.bfd" and "ld".
 289 # --enable-gold=default [--enable-ld]
 290 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 291 #     install ld as "ld.bfd".
 292 # --enable-gold[=default] --disable-ld
 293 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 294 # --enable-gold --enable-ld=default
 295 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 296 #     and ld.bfd).
 297 #     In other words, ld is default
 298 # --enable-gold=default --enable-ld=default
 299 #     Error.
 300
 301 default_ld=
 302 AC_ARG_ENABLE(gold,
 303 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 304                 [build gold @<:@ARG={default,yes,no}@:>@])],
 305 ENABLE_GOLD=$enableval,
 306 ENABLE_GOLD=no)
 307 case "${ENABLE_GOLD}" in
 308   yes|default)
 309     # Check for ELF target.
 310     is_elf=no
 311     case "${target}" in
 312       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 313       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 314       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 315       | *-*-solaris2* | *-*-nto*)
 316         case "${target}" in
 317           *-*-linux*aout* | *-*-linux*oldld*)
 318             ;;
 319           *)
 320             is_elf=yes
 321             ;;
 322         esac
 323     esac
 324
 325     if test "$is_elf" = "yes"; then
 326       # Check for target supported by gold.
 327       case "${target}" in
 328         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 329           configdirs="$configdirs gold"
 330           if test x${ENABLE_GOLD} = xdefault; then
 331             default_ld=gold
 332           fi
 333           ENABLE_GOLD=yes
 334           ;;
 335       esac
 336     fi
 337     ;;
 338   no)
 339     ;;
 340   *)
 341     AC_MSG_ERROR([invalid --enable-gold argument])
 342     ;;
 343 esac
 344
 345 AC_ARG_ENABLE(ld,
 346 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 347                 [build ld @<:@ARG={default,yes,no}@:>@])],
 348 ENABLE_LD=$enableval,
 349 ENABLE_LD=yes)
 350
 351 case "${ENABLE_LD}" in
 352   default)
 353     if test x${default_ld} != x; then
 354       AC_MSG_ERROR([either gold or ld can be the default ld])
 355     fi
 356     ;;
 357   yes)
 358     ;;
 359   no)
 360     if test x${ENABLE_GOLD} != xyes; then
 361       AC_MSG_WARN([neither ld nor gold are enabled])
 362     fi
 363     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 364     ;;
 365   *)
 366     AC_MSG_ERROR([invalid --enable-ld argument])
 367     ;;
 368 esac
 369
 370 # Configure extra directories which are host specific
 371
 372 case "${host}" in
 373   *-cygwin*)
 374     configdirs="$configdirs libtermcap" ;;
 375 esac
 376
 377 # A target can indicate whether a language isn't supported for some reason.
 378 # Only spaces may be used in this macro; not newlines or tabs.
 379 unsupported_languages=
 380
 381 # Remove more programs from consideration, based on the host or
 382 # target this usually means that a port of the program doesn't
 383 # exist yet.
 384
 385 case "${host}" in
 386   i[[3456789]]86-*-msdosdjgpp*)
 387     noconfigdirs="$noconfigdirs tcl tk itcl"
 388     ;;
 389 esac
 390
 391
 392 AC_ARG_ENABLE(libquadmath,
 393 AS_HELP_STRING([--disable-libquadmath],
 394   [do not build libquadmath directory]),
 395 ENABLE_LIBQUADMATH=$enableval,
 396 ENABLE_LIBQUADMATH=yes)
 397 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 398   noconfigdirs="$noconfigdirs target-libquadmath"
 399 fi
 400
 401
 402 AC_ARG_ENABLE(libquadmath-support,
 403 AS_HELP_STRING([--disable-libquadmath-support],
 404   [disable libquadmath support for Fortran]),
 405 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 406 ENABLE_LIBQUADMATH_SUPPORT=yes)
 407 enable_libquadmath_support=
 408 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 409   enable_libquadmath_support=no
 410 fi
 411
 412
 413 AC_ARG_ENABLE(libada,
 414 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 415 ENABLE_LIBADA=$enableval,
 416 ENABLE_LIBADA=yes)
 417 if test "${ENABLE_LIBADA}" != "yes" ; then
 418   noconfigdirs="$noconfigdirs gnattools"
 419 fi
 420
 421 AC_ARG_ENABLE(libssp,
 422 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 423 ENABLE_LIBSSP=$enableval,
 424 ENABLE_LIBSSP=yes)
 425
 426 # Save it here so that, even in case of --enable-libgcj, if the Java
 427 # front-end isn't enabled, we still get libgcj disabled.
 428 libgcj_saved=$libgcj
 429 case $enable_libgcj in
 430 yes)
 431   # If we reset it here, it won't get added to noconfigdirs in the
 432   # target-specific build rules, so it will be forcibly enabled
 433   # (unless the Java language itself isn't enabled).
 434   libgcj=
 435   ;;
 436 no)
 437   # Make sure we get it printed in the list of not supported target libs.
 438   # Don't disable libffi, though, other languages use it.
 439   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 440   # Clear libgcj_saved so that even if java is enabled libffi won't be
 441   # built.
 442   libgcj_saved=
 443   ;;
 444 esac
 445
 446 AC_ARG_ENABLE(static-libjava,
 447 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 448                 [build static libjava @<:@default=no@:>@])],
 449 ENABLE_STATIC_LIBJAVA=$enableval,
 450 ENABLE_STATIC_LIBJAVA=no)
 451 enable_static_libjava=
 452 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 453   enable_static_libjava=yes
 454 fi
 455
 456 if test x$enable_static_libjava != xyes ; then
 457   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 458 fi
 459 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 460
 461 # Disable libmudflap on some systems.
 462 if test x$enable_libmudflap = x ; then
 463     case "${target}" in
 464     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 465         # Enable libmudflap by default in GNU and friends.
 466         ;;
 467     *-*-freebsd*)
 468         # Enable libmudflap by default in FreeBSD.
 469         ;;
 470     *)
 471         # Disable it by default everywhere else.
 472         noconfigdirs="$noconfigdirs target-libmudflap"
 473         ;;
 474     esac
 475 fi
 476
 477 # Disable libgomp on non POSIX hosted systems.
 478 if test x$enable_libgomp = x ; then
 479     # Enable libgomp by default on hosted POSIX systems.
 480     case "${target}" in
 481     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 482         ;;
 483     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 484         ;;
 485     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 486         ;;
 487     *-*-darwin* | *-*-aix*)
 488         ;;
 489     *)
 490         noconfigdirs="$noconfigdirs target-libgomp"
 491         ;;
 492     esac
 493 fi
 494
 495 # Disable libssp for some systems.
 496 case "${target}" in
 497   avr-*-*)
 498     # No hosted I/O support.
 499     noconfigdirs="$noconfigdirs target-libssp"
 500     ;;
 501   powerpc-*-aix* | rs6000-*-aix*)
 502     noconfigdirs="$noconfigdirs target-libssp"
 503     ;;
 504 esac
 505
 506 # Disable libstdc++-v3 for some systems.
 507 case "${target}" in
 508   *-*-vxworks*)
 509     # VxWorks uses the Dinkumware C++ library.
 510     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 511     ;;
 512   arm*-wince-pe*)
 513     # the C++ libraries don't build on top of CE's C libraries
 514     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 515     ;;
 516   avr-*-*)
 517     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 518     ;;
 519 esac
 520
 521 # Disable Fortran for some systems.
 522 case "${target}" in
 523   mmix-*-*)
 524     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 525     unsupported_languages="$unsupported_languages fortran"
 526     ;;
 527 esac
 528
 529 # Disable Java if libffi is not supported.
 530 case "${target}" in
 531   alpha*-*-*)
 532     ;;
 533   arm*-*-*)
 534     ;;
 535   cris-*-*)
 536     ;;
 537   frv-*-*)
 538     ;;
 539   hppa*-*-linux*)
 540     ;;
 541   hppa*-*-hpux*)
 542     ;;
 543   i?86-*-*)
 544     ;;
 545   ia64*-*-*)
 546     ;;
 547   m32r*-*-*)
 548     ;;
 549   m68k-*-*)
 550     ;;
 551   mips-sgi-irix6.* | mips*-*-rtems*)
 552     ;;
 553   mips*-*-linux*)
 554     ;;
 555   powerpc*-*-linux*)
 556     ;;
 557   powerpc-*-darwin*)
 558     ;;
 559   powerpc-*-aix* | rs6000-*-aix*)
 560     ;;
 561   powerpc-*-freebsd*)
 562     ;;
 563   powerpc64-*-freebsd*)
 564     ;;
 565   powerpc*-*-rtems*)
 566     ;;
 567   s390-*-* | s390x-*-*)
 568     ;;
 569   sh-*-* | sh[[34]]*-*-*)
 570     ;;
 571   sh64-*-* | sh5*-*-*)
 572     ;;
 573   sparc*-*-*)
 574     ;;
 575   x86_64-*-*)
 576     ;;
 577   *-*-*)
 578     unsupported_languages="$unsupported_languages java"
 579     ;;
 580 esac
 581
 582 # Disable Java, libgcj or related libraries for some systems.
 583 case "${target}" in
 584   powerpc-*-darwin*)
 585     ;;
 586   i[[3456789]]86-*-darwin*)
 587     ;;
 588   x86_64-*-darwin[[912]]*)
 589     ;;
 590   *-*-darwin*)
 591     noconfigdirs="$noconfigdirs ${libgcj}"
 592     ;;
 593   *-*-netware*)
 594     noconfigdirs="$noconfigdirs ${libgcj}"
 595     ;;
 596   *-*-rtems*)
 597     noconfigdirs="$noconfigdirs ${libgcj}"
 598     ;;
 599   *-*-tpf*)
 600     noconfigdirs="$noconfigdirs ${libgcj}"
 601     ;;
 602   *-*-uclinux*)
 603     noconfigdirs="$noconfigdirs ${libgcj}"
 604     ;;
 605   *-*-vxworks*)
 606     noconfigdirs="$noconfigdirs ${libgcj}"
 607     ;;
 608   alpha*-*-*vms*)
 609     noconfigdirs="$noconfigdirs ${libgcj}"
 610     ;;
 611   arm-wince-pe)
 612     noconfigdirs="$noconfigdirs ${libgcj}"
 613     ;;
 614   arm*-*-symbianelf*)
 615     noconfigdirs="$noconfigdirs ${libgcj}"
 616     ;;
 617   bfin-*-*)
 618     noconfigdirs="$noconfigdirs target-boehm-gc"
 619     ;;
 620   cris-*-* | crisv32-*-*)
 621     unsupported_languages="$unsupported_languages java"
 622     case "${target}" in
 623       *-*-linux*)
 624         ;;
 625       *) # See PR46792 regarding target-libffi.
 626         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 627     esac
 628     ;;
 629   hppa*64*-*-linux*)
 630     # In this case, it's because the hppa64-linux target is for
 631     # the kernel only at this point and has no libc, and thus no
 632     # headers, crt*.o, etc., all of which are needed by these.
 633     unsupported_languages="$unsupported_languages java"
 634     ;;
 635   hppa*64*-*-hpux*)
 636     noconfigdirs="$noconfigdirs ${libgcj}"
 637     ;;
 638   hppa*-hp-hpux11*)
 639     ;;
 640   hppa*-*-hpux*)
 641     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 642     # build on HP-UX 10.20.
 643     noconfigdirs="$noconfigdirs ${libgcj}"
 644     ;;
 645   ia64*-*-*vms*)
 646     noconfigdirs="$noconfigdirs ${libgcj}"
 647     ;;
 648   i[[3456789]]86-w64-mingw*)
 649     noconfigdirs="$noconfigdirs ${libgcj}"
 650     ;;
 651   i[[3456789]]86-*-mingw*)
 652     noconfigdirs="$noconfigdirs ${libgcj}"
 653     ;;
 654   x86_64-*-mingw*)
 655     noconfigdirs="$noconfigdirs ${libgcj}"
 656     ;;
 657   mmix-*-*)
 658     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 659     ;;
 660   powerpc-*-aix*)
 661     # copied from rs6000-*-* entry
 662     noconfigdirs="$noconfigdirs ${libgcj}"
 663     ;;
 664   rs6000-*-aix*)
 665     noconfigdirs="$noconfigdirs ${libgcj}"
 666     ;;
 667   mips*-*-irix6*)
 668     # Linking libjava exceeds command-line length limits on at least
 669     # IRIX 6.2, but not on IRIX 6.5.
 670     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 671     # <oldham@codesourcery.com>
 672     noconfigdirs="$noconfigdirs ${libgcj}"
 673     ;;
 674   *-*-lynxos*)
 675     noconfigdirs="$noconfigdirs ${libgcj}"
 676     ;;
 677 esac
 678
 679 # Default libgloss CPU subdirectory.
 680 libgloss_dir="$target_cpu"
 681
 682 case "${target}" in
 683   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 684     libgloss_dir=wince
 685     ;;
 686   arm*-*-*)
 687     libgloss_dir=arm
 688     ;;
 689   cris-*-* | crisv32-*-*)
 690     libgloss_dir=cris
 691     ;;
 692   hppa*-*-*)
 693     libgloss_dir=pa
 694     ;;
 695   i[[3456789]]86-*-*)
 696     libgloss_dir=i386
 697     ;;
 698   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 699     libgloss_dir=m68hc11
 700     ;;
 701   m68*-*-* | fido-*-*)
 702     libgloss_dir=m68k
 703     ;;
 704   mips*-*-*)
 705     libgloss_dir=mips
 706     ;;
 707   powerpc*-*-*)
 708     libgloss_dir=rs6000
 709     ;;
 710   sparc*-*-*)
 711     libgloss_dir=sparc
 712     ;;
 713 esac
 714
 715 # Disable newlib and libgloss for various target OSes.
 716 case "${target}" in
 717   alpha*-dec-osf*)
 718     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 719     ;;
 720   i[[3456789]]86-*-linux*)
 721     # This section makes it possible to build newlib natively on linux.
 722     # If we are using a cross compiler then don't configure newlib.
 723     if test x${is_cross_compiler} != xno ; then
 724       noconfigdirs="$noconfigdirs target-newlib"
 725     fi
 726     noconfigdirs="$noconfigdirs target-libgloss"
 727     # If we are not using a cross compiler, do configure newlib.
 728     # Note however, that newlib will only be configured in this situation
 729     # if the --with-newlib option has been given, because otherwise
 730     # 'target-newlib' will appear in skipdirs.
 731     ;;
 732   i[[3456789]]86-*-rdos*)
 733     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 734     ;;
 735   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 736     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 737     ;;
 738   sparc-*-sunos4*)
 739     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 740     ;;
 741   *-*-aix*)
 742     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 743     ;;
 744   *-*-beos*)
 745     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 746     ;;
 747   *-*-chorusos)
 748     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 749     ;;
 750   *-*-dragonfly*)
 751     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 752     ;;
 753   *-*-freebsd*)
 754     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 755     ;;
 756   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 757     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 758     ;;
 759   *-*-lynxos*)
 760     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 761     ;;
 762   *-*-mingw*)
 763     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 764     ;;
 765   *-*-netbsd*)
 766     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 767     ;;
 768   *-*-netware*)
 769     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 770     ;;
 771   *-*-tpf*)
 772     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 773     ;;
 774   *-*-uclinux*)
 775     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 776     ;;
 777   *-*-vxworks*)
 778     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 779     ;;
 780 esac
 781
 782 case "${target}" in
 783   *-*-chorusos)
 784     ;;
 785   powerpc-*-darwin*)
 786     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 787     noconfigdirs="$noconfigdirs sim target-rda"
 788     ;;
 789   i[[3456789]]86-*-darwin*)
 790     noconfigdirs="$noconfigdirs ld gprof"
 791     noconfigdirs="$noconfigdirs sim target-rda"
 792     ;;
 793   x86_64-*-darwin[[912]]*)
 794     noconfigdirs="$noconfigdirs ld gas gprof"
 795     noconfigdirs="$noconfigdirs sim target-rda"
 796     ;;
 797   *-*-darwin*)
 798     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 799     noconfigdirs="$noconfigdirs sim target-rda"
 800     ;;
 801   *-*-dragonfly*)
 802     ;;
 803   *-*-freebsd*)
 804     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 805         && test -f /usr/local/include/gmp.h; then
 806       with_gmp=/usr/local
 807     fi
 808     ;;
 809   *-*-kaos*)
 810     # Remove unsupported stuff on all kaOS configurations.
 811     noconfigdirs="$noconfigdirs target-libgloss"
 812     ;;
 813   *-*-netbsd*)
 814     ;;
 815   *-*-netware*)
 816     ;;
 817   *-*-rtems*)
 818     noconfigdirs="$noconfigdirs target-libgloss"
 819     ;;
 820     # The tpf target doesn't support gdb yet.
 821   *-*-tpf*)
 822     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 823     ;;
 824   *-*-uclinux*)
 825     noconfigdirs="$noconfigdirs target-rda"
 826     ;;
 827   *-*-vxworks*)
 828     ;;
 829   alpha*-dec-osf*)
 830     # ld works, but does not support shared libraries.
 831     # gas doesn't generate exception information.
 832     noconfigdirs="$noconfigdirs gas ld"
 833     ;;
 834   alpha*-*-*vms*)
 835     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 836     ;;
 837   alpha*-*-*)
 838     # newlib is not 64 bit ready
 839     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 840     ;;
 841   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 842     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 843     ;;
 844   arc-*-*)
 845     noconfigdirs="$noconfigdirs target-libgloss"
 846     ;;
 847   arm-*-pe*)
 848     noconfigdirs="$noconfigdirs target-libgloss"
 849     ;;
 850   arm-*-riscix*)
 851     noconfigdirs="$noconfigdirs ld target-libgloss"
 852     ;;
 853   c4x-*-* | tic4x-*-*)
 854     noconfigdirs="$noconfigdirs target-libgloss"
 855     ;;
 856   tic54x-*-*)
 857     noconfigdirs="$noconfigdirs target-libgloss gdb"
 858     ;;
 859   cr16-*-*)
 860     noconfigdirs="$noconfigdirs gdb"
 861     ;;
 862   d10v-*-*)
 863     noconfigdirs="$noconfigdirs target-libgloss"
 864     ;;
 865   d30v-*-*)
 866     noconfigdirs="$noconfigdirs gdb"
 867     ;;
 868   fr30-*-elf*)
 869     noconfigdirs="$noconfigdirs gdb"
 870     ;;
 871   moxie-*-*)
 872     noconfigdirs="$noconfigdirs gprof"
 873     ;;
 874   h8300*-*-*)
 875     noconfigdirs="$noconfigdirs target-libgloss"
 876     ;;
 877   h8500-*-*)
 878     noconfigdirs="$noconfigdirs target-libgloss"
 879     ;;
 880   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 881     ;;
 882   hppa*64*-*-linux*)
 883     ;;
 884   hppa*-*-linux*)
 885     ;;
 886   hppa*-*-*elf* | \
 887   hppa*-*-lites* | \
 888   hppa*-*-openbsd* | \
 889   hppa*64*-*-*)
 890     ;;
 891   hppa*-hp-hpux11*)
 892     noconfigdirs="$noconfigdirs ld"
 893     ;;
 894   hppa*-*-pro*)
 895     ;;
 896   hppa*-*-*)
 897     noconfigdirs="$noconfigdirs ld"
 898     ;;
 899   i960-*-*)
 900     noconfigdirs="$noconfigdirs gdb"
 901     ;;
 902   ia64*-*-elf*)
 903     # No gdb support yet.
 904     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 905     ;;
 906   ia64*-**-hpux*)
 907     # No ld support yet.
 908     noconfigdirs="$noconfigdirs libgui itcl ld"
 909     ;;
 910   ia64*-*-*vms*)
 911     # No gdb or ld support yet.
 912     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
 913     ;;
 914   i[[3456789]]86-w64-mingw*)
 915     ;;
 916   i[[3456789]]86-*-mingw*)
 917     target_configdirs="$target_configdirs target-winsup"
 918     ;;
 919   *-*-cygwin*)
 920     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 921     noconfigdirs="$noconfigdirs target-libgloss"
 922     # always build newlib if winsup directory is present.
 923     if test -d "$srcdir/winsup/cygwin"; then
 924       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 925     elif test -d "$srcdir/newlib"; then
 926       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 927     fi
 928     ;;
 929   i[[3456789]]86-*-pe)
 930     noconfigdirs="$noconfigdirs target-libgloss"
 931     ;;
 932   i[[3456789]]86-*-sco3.2v5*)
 933     # The linker does not yet know about weak symbols in COFF,
 934     # and is not configured to handle mixed ELF and COFF.
 935     noconfigdirs="$noconfigdirs ld target-libgloss"
 936     ;;
 937   i[[3456789]]86-*-sco*)
 938     noconfigdirs="$noconfigdirs gprof target-libgloss"
 939     ;;
 940   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 941     noconfigdirs="$noconfigdirs target-libgloss"
 942     ;;
 943   i[[3456789]]86-*-sysv4*)
 944     noconfigdirs="$noconfigdirs target-libgloss"
 945     ;;
 946   i[[3456789]]86-*-beos*)
 947     noconfigdirs="$noconfigdirs gdb"
 948     ;;
 949   i[[3456789]]86-*-rdos*)
 950     noconfigdirs="$noconfigdirs gdb"
 951     ;;
 952   mmix-*-*)
 953     noconfigdirs="$noconfigdirs gdb"
 954     ;;
 955   mt-*-*)
 956     noconfigdirs="$noconfigdirs sim"
 957     ;;
 958   powerpc-*-aix*)
 959     # copied from rs6000-*-* entry
 960     noconfigdirs="$noconfigdirs gprof"
 961     ;;
 962   powerpc*-*-winnt* | powerpc*-*-pe*)
 963     target_configdirs="$target_configdirs target-winsup"
 964     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
 965     # always build newlib.
 966     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 967     ;;
 968     # This is temporary until we can link against shared libraries
 969   powerpcle-*-solaris*)
 970     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
 971     ;;
 972   powerpc-*-beos*)
 973     noconfigdirs="$noconfigdirs gdb"
 974     ;;
 975   rs6000-*-lynxos*)
 976     noconfigdirs="$noconfigdirs gprof"
 977     ;;
 978   rs6000-*-aix*)
 979     noconfigdirs="$noconfigdirs gprof"
 980     ;;
 981   rs6000-*-*)
 982     noconfigdirs="$noconfigdirs gprof"
 983     ;;
 984   m68k-apollo-*)
 985     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
 986     ;;
 987   microblaze*)
 988     noconfigdirs="$noconfigdirs gprof"
 989     ;;
 990   mips*-sde-elf*)
 991     if test x$with_newlib = xyes; then
 992       noconfigdirs="$noconfigdirs gprof"
 993     fi
 994     ;;
 995   mips*-*-irix5*)
 996     noconfigdirs="$noconfigdirs gprof target-libgloss"
 997     ;;
 998   mips*-*-irix6*)
 999     noconfigdirs="$noconfigdirs gprof target-libgloss"
1000     ;;
1001   mips*-*-bsd*)
1002     noconfigdirs="$noconfigdirs gprof target-libgloss"
1003     ;;
1004   mips*-*-linux*)
1005     ;;
1006   mips*-*-*)
1007     noconfigdirs="$noconfigdirs gprof"
1008     ;;
1009   sh-*-* | sh64-*-*)
1010     case "${target}" in
1011       sh*-*-elf)
1012          ;;
1013       *)
1014          noconfigdirs="$noconfigdirs target-libgloss" ;;
1015     esac
1016     ;;
1017   sparc-*-sunos4*)
1018     if test x${is_cross_compiler} = xno ; then
1019            use_gnu_ld=no
1020     fi
1021     ;;
1022   tic6x-*-*)
1023     noconfigdirs="$noconfigdirs sim"
1024     ;;
1025   tilepro-*-* | tilegx-*-*)
1026     noconfigdirs="$noconfigdirs sim"
1027     ;;
1028   v810-*-*)
1029     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1030     ;;
1031   vax-*-*)
1032     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1033     ;;
1034 esac
1035
1036 # If we aren't building newlib, then don't build libgloss, since libgloss
1037 # depends upon some newlib header files.
1038 case "${noconfigdirs}" in
1039   *target-libgloss*) ;;
1040   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1041 esac
1042
1043 # Work in distributions that contain no compiler tools, like Autoconf.
1044 host_makefile_frag=/dev/null
1045 if test -d ${srcdir}/config ; then
1046 case "${host}" in
1047   i[[3456789]]86-*-msdosdjgpp*)
1048     host_makefile_frag="config/mh-djgpp"
1049     ;;
1050   *-cygwin*)
1051     ACX_CHECK_CYGWIN_CAT_WORKS
1052     host_makefile_frag="config/mh-cygwin"
1053     ;;
1054   *-mingw*)
1055     host_makefile_frag="config/mh-mingw"
1056     ;;
1057   *-interix*)
1058     host_makefile_frag="config/mh-interix"
1059     ;;
1060   hppa*-hp-hpux10*)
1061     host_makefile_frag="config/mh-pa-hpux10"
1062     ;;
1063   hppa*-hp-hpux*)
1064     host_makefile_frag="config/mh-pa"
1065     ;;
1066   hppa*-*)
1067     host_makefile_frag="config/mh-pa"
1068     ;;
1069   *-*-darwin*)
1070     host_makefile_frag="config/mh-darwin"
1071     ;;
1072   powerpc-*-aix*)
1073     host_makefile_frag="config/mh-ppc-aix"
1074     ;;
1075   rs6000-*-aix*)
1076     host_makefile_frag="config/mh-ppc-aix"
1077     ;;
1078 esac
1079 fi
1080
1081 if test "${build}" != "${host}" ; then
1082   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1083   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1084   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1085   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1086   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1087   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1088   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1089   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1090   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1091   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1092   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1093   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1094   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1095 else
1096   AR_FOR_BUILD="\$(AR)"
1097   AS_FOR_BUILD="\$(AS)"
1098   CC_FOR_BUILD="\$(CC)"
1099   CXX_FOR_BUILD="\$(CXX)"
1100   GCJ_FOR_BUILD="\$(GCJ)"
1101   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1102   GOC_FOR_BUILD="\$(GOC)"
1103   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1104   LD_FOR_BUILD="\$(LD)"
1105   NM_FOR_BUILD="\$(NM)"
1106   RANLIB_FOR_BUILD="\$(RANLIB)"
1107   WINDRES_FOR_BUILD="\$(WINDRES)"
1108   WINDMC_FOR_BUILD="\$(WINDMC)"
1109 fi
1110
1111 AC_PROG_CC
1112 AC_PROG_CXX
1113
1114 # We must set the default linker to the linker used by gcc for the correct
1115 # operation of libtool.  If LD is not defined and we are using gcc, try to
1116 # set the LD default to the ld used by gcc.
1117 if test -z "$LD"; then
1118   if test "$GCC" = yes; then
1119     case $build in
1120     *-*-mingw*)
1121       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1122     *)
1123       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1124     esac
1125     case $gcc_prog_ld in
1126     # Accept absolute paths.
1127     [[\\/]* | [A-Za-z]:[\\/]*)]
1128       LD="$gcc_prog_ld" ;;
1129     esac
1130   fi
1131 fi
1132
1133 ACX_PROG_GNAT
1134 ACX_PROG_CMP_IGNORE_INITIAL
1135
1136 AC_ARG_ENABLE([bootstrap],
1137 [AS_HELP_STRING([--enable-bootstrap],
1138                 [enable bootstrapping @<:@yes if native build@:>@])],,
1139 enable_bootstrap=default)
1140
1141 # Issue errors and warnings for invalid/strange bootstrap combinations.
1142 if test -r $srcdir/gcc/configure; then
1143   have_compiler=yes
1144 else
1145   have_compiler=no
1146 fi
1147
1148 case "$have_compiler:$host:$target:$enable_bootstrap" in
1149   *:*:*:no) ;;
1150
1151   # Default behavior.  Enable bootstrap if we have a compiler
1152   # and we are in a native configuration.
1153   yes:$build:$build:default)
1154     enable_bootstrap=yes ;;
1155
1156   *:*:*:default)
1157     enable_bootstrap=no ;;
1158
1159   # We have a compiler and we are in a native configuration, bootstrap is ok
1160   yes:$build:$build:yes)
1161     ;;
1162
1163   # Other configurations, but we have a compiler.  Assume the user knows
1164   # what he's doing.
1165   yes:*:*:yes)
1166     AC_MSG_WARN([trying to bootstrap a cross compiler])
1167     ;;
1168
1169   # No compiler: if they passed --enable-bootstrap explicitly, fail
1170   no:*:*:yes)
1171     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1172
1173   # Fail if wrong command line
1174   *)
1175     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1176     ;;
1177 esac
1178
1179 # See if we are building gcc with C++.
1180 AC_ARG_ENABLE(build-with-cxx,
1181 [AS_HELP_STRING([--enable-build-with-cxx],
1182                 [build with C++ compiler instead of C compiler])],
1183 ENABLE_BUILD_WITH_CXX=$enableval,
1184 ENABLE_BUILD_WITH_CXX=no)
1185
1186 # Build stage1 with C and build stages 2 and 3 with C++.
1187 AC_ARG_ENABLE(build-poststage1-with-cxx,
1188 [AS_HELP_STRING([--enable-build-poststage1-with-cxx],
1189                 [build stages 2 and 3 with C++, not C])],
1190 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=$enableval,
1191 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=yes)
1192
1193 # Used for setting $lt_cv_objdir
1194 _LT_CHECK_OBJDIR
1195
1196 # Check for GMP, MPFR and MPC
1197 gmplibs="-lmpc -lmpfr -lgmp"
1198 gmpinc=
1199 have_gmp=no
1200
1201 # Specify a location for mpc
1202 # check for this first so it ends up on the link line before mpfr.
1203 AC_ARG_WITH(mpc,
1204 [AS_HELP_STRING([--with-mpc=PATH],
1205                 [specify prefix directory for installed MPC package.
1206                  Equivalent to --with-mpc-include=PATH/include
1207                  plus --with-mpc-lib=PATH/lib])])
1208 AC_ARG_WITH(mpc-include,
1209 [AS_HELP_STRING([--with-mpc-include=PATH],
1210                 [specify directory for installed MPC include files])])
1211 AC_ARG_WITH(mpc-lib,
1212 [AS_HELP_STRING([--with-mpc-lib=PATH],
1213                 [specify directory for the installed MPC library])])
1214
1215 if test "x$with_mpc" != x; then
1216   gmplibs="-L$with_mpc/lib $gmplibs"
1217   gmpinc="-I$with_mpc/include $gmpinc"
1218 fi
1219 if test "x$with_mpc_include" != x; then
1220   gmpinc="-I$with_mpc_include $gmpinc"
1221 fi
1222 if test "x$with_mpc_lib" != x; then
1223   gmplibs="-L$with_mpc_lib $gmplibs"
1224 fi
1225 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1226   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1227   gmpinc='-I$$s/mpc/src '"$gmpinc"
1228   # Do not test the mpc version.  Assume that it is sufficient, since
1229   # it is in the source tree, and the library has not been built yet
1230   # but it would be included on the link line in the version check below
1231   # hence making the test fail.
1232   have_gmp=yes
1233 fi
1234
1235 # Specify a location for mpfr
1236 # check for this first so it ends up on the link line before gmp.
1237 AC_ARG_WITH(mpfr-dir,
1238 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1239 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1240 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1241
1242 AC_ARG_WITH(mpfr,
1243 [AS_HELP_STRING([--with-mpfr=PATH],
1244                 [specify prefix directory for installed MPFR package.
1245                  Equivalent to --with-mpfr-include=PATH/include
1246                  plus --with-mpfr-lib=PATH/lib])])
1247 AC_ARG_WITH(mpfr-include,
1248 [AS_HELP_STRING([--with-mpfr-include=PATH],
1249                 [specify directory for installed MPFR include files])])
1250 AC_ARG_WITH(mpfr-lib,
1251 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1252                 [specify directory for the installed MPFR library])])
1253
1254 if test "x$with_mpfr" != x; then
1255   gmplibs="-L$with_mpfr/lib $gmplibs"
1256   gmpinc="-I$with_mpfr/include $gmpinc"
1257 fi
1258 if test "x$with_mpfr_include" != x; then
1259   gmpinc="-I$with_mpfr_include $gmpinc"
1260 fi
1261 if test "x$with_mpfr_lib" != x; then
1262   gmplibs="-L$with_mpfr_lib $gmplibs"
1263 fi
1264 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1265   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs"
1266   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc"
1267   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir"
1268   # Do not test the mpfr version.  Assume that it is sufficient, since
1269   # it is in the source tree, and the library has not been built yet
1270   # but it would be included on the link line in the version check below
1271   # hence making the test fail.
1272   have_gmp=yes
1273 fi
1274
1275 # Specify a location for gmp
1276 AC_ARG_WITH(gmp-dir,
1277 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1278 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1279 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1280
1281 AC_ARG_WITH(gmp,
1282 [AS_HELP_STRING([--with-gmp=PATH],
1283                 [specify prefix directory for the installed GMP package.
1284                  Equivalent to --with-gmp-include=PATH/include
1285                  plus --with-gmp-lib=PATH/lib])])
1286 AC_ARG_WITH(gmp-include,
1287 [AS_HELP_STRING([--with-gmp-include=PATH],
1288                 [specify directory for installed GMP include files])])
1289 AC_ARG_WITH(gmp-lib,
1290 [AS_HELP_STRING([--with-gmp-lib=PATH],
1291                 [specify directory for the installed GMP library])])
1292
1293
1294 if test "x$with_gmp" != x; then
1295   gmplibs="-L$with_gmp/lib $gmplibs"
1296   gmpinc="-I$with_gmp/include $gmpinc"
1297 fi
1298 if test "x$with_gmp_include" != x; then
1299   gmpinc="-I$with_gmp_include $gmpinc"
1300 fi
1301 if test "x$with_gmp_lib" != x; then
1302   gmplibs="-L$with_gmp_lib $gmplibs"
1303 fi
1304 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1305   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1306   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1307   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1308   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1309   # Do not test the gmp version.  Assume that it is sufficient, since
1310   # it is in the source tree, and the library has not been built yet
1311   # but it would be included on the link line in the version check below
1312   # hence making the test fail.
1313   have_gmp=yes
1314 fi
1315
1316 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1317   have_gmp=yes
1318   saved_CFLAGS="$CFLAGS"
1319   CFLAGS="$CFLAGS $gmpinc"
1320   # Check for the recommended and required versions of GMP.
1321   AC_MSG_CHECKING([for the correct version of gmp.h])
1322   AC_TRY_COMPILE([#include "gmp.h"],[
1323   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1324   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1325   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1326   choke me
1327   #endif
1328   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1329   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1330   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1331   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1332   choke me
1333   #endif
1334   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1335    [AC_MSG_RESULT([no]); have_gmp=no])
1336
1337   # If we have GMP, check the MPFR version.
1338   if test x"$have_gmp" = xyes; then
1339     # Check for the recommended and required versions of MPFR.
1340     AC_MSG_CHECKING([for the correct version of mpfr.h])
1341     AC_TRY_COMPILE([#include <gmp.h>
1342     #include <mpfr.h>],[
1343     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1344     choke me
1345     #endif
1346     ], [AC_TRY_COMPILE([#include <gmp.h>
1347     #include <mpfr.h>],[
1348     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1349     choke me
1350     #endif
1351     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1352      [AC_MSG_RESULT([no]); have_gmp=no])
1353   fi
1354
1355   # Check for the MPC header version.
1356   if test x"$have_gmp" = xyes ; then
1357     # Check for the recommended and required versions of MPC.
1358     AC_MSG_CHECKING([for the correct version of mpc.h])
1359     AC_TRY_COMPILE([#include <mpc.h>],[
1360     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1361     choke me
1362     #endif
1363     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1364     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1365     choke me
1366     #endif
1367     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1368      [AC_MSG_RESULT([no]); have_gmp=no])
1369   fi
1370
1371   # Now check the MPFR library.
1372   if test x"$have_gmp" = xyes; then
1373     saved_LIBS="$LIBS"
1374     LIBS="$LIBS $gmplibs"
1375     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1376     AC_TRY_LINK([#include <mpc.h>],[
1377     mpfr_t n;
1378     mpfr_t x;
1379     mpc_t c;
1380     int t;
1381     mpfr_init (n);
1382     mpfr_init (x);
1383     mpfr_atan2 (n, n, x, GMP_RNDN);
1384     mpfr_erfc (n, x, GMP_RNDN);
1385     mpfr_subnormalize (x, t, GMP_RNDN);
1386     mpfr_clear(n);
1387     mpfr_clear(x);
1388     mpc_init2 (c, 53);
1389     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1390     mpc_cosh (c, c, MPC_RNDNN);
1391     mpc_pow (c, c, c, MPC_RNDNN);
1392     mpc_acosh (c, c, MPC_RNDNN);
1393     mpc_clear (c);
1394     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1395     LIBS="$saved_LIBS"
1396   fi
1397
1398   CFLAGS="$saved_CFLAGS"
1399
1400 # The library versions listed in the error message below should match
1401 # the HARD-minimums enforced above.
1402   if test x$have_gmp != xyes; then
1403     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1404 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1405 their locations.  Source code for these libraries can be found at
1406 their respective hosting sites as well as at
1407 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1408 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1409 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1410 make sure that you have installed both the libraries and the header
1411 files.  They may be located in separate packages.])
1412   fi
1413 fi
1414
1415 # Flags needed for both GMP, MPFR and/or MPC.
1416 AC_SUBST(gmplibs)
1417 AC_SUBST(gmpinc)
1418 AC_SUBST(extra_mpfr_configure_flags)
1419 AC_SUBST(extra_mpc_gmp_configure_flags)
1420 AC_SUBST(extra_mpc_mpfr_configure_flags)
1421
1422 # Allow host libstdc++ to be specified for static linking with PPL.
1423 AC_ARG_WITH(host-libstdcxx,
1424 [AS_HELP_STRING([--with-host-libstdcxx=L],
1425                 [use linker arguments L to link with libstdc++
1426                  when linking with PPL])])
1427
1428 case $with_host_libstdcxx in
1429   no|yes)
1430     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1431     ;;
1432 esac
1433
1434 # Linker flags to use for stage1 or when not boostrapping.
1435 AC_ARG_WITH(stage1-ldflags,
1436 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1437 [if test "$withval" = "no" -o "$withval" = "yes"; then
1438    stage1_ldflags=
1439  else
1440    stage1_ldflags=$withval
1441  fi],
1442 [stage1_ldflags=])
1443 AC_SUBST(stage1_ldflags)
1444
1445 # Libraries to use for stage1 or when not bootstrapping.
1446 AC_ARG_WITH(stage1-libs,
1447 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1448 [if test "$withval" = "no" -o "$withval" = "yes"; then
1449    stage1_libs=
1450  else
1451    stage1_libs=$withval
1452  fi],
1453 [stage1_libs=$with_host_libstdcxx])
1454 AC_SUBST(stage1_libs)
1455
1456 # Libraries to use for stage2 and later builds.  This defaults to the
1457 # argument passed to --with-host-libstdcxx.
1458 AC_ARG_WITH(boot-libs,
1459 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1460 [if test "$withval" = "no" -o "$withval" = "yes"; then
1461    poststage1_libs=
1462  else
1463    poststage1_libs=$withval
1464  fi],
1465 [poststage1_libs=$with_host_libstdcxx])
1466 AC_SUBST(poststage1_libs)
1467
1468 # Linker flags to use for stage2 and later builds.
1469 AC_ARG_WITH(boot-ldflags,
1470 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1471                 [linker flags for stage2 and later])],
1472 [if test "$withval" = "no" -o "$withval" = "yes"; then
1473    poststage1_ldflags=
1474  else
1475    poststage1_ldflags=$withval
1476  fi],
1477 [poststage1_ldflags=
1478  # In stages 2 and 3, default to linking libstdc++ and libgcc
1479  # statically.  But if the user explicitly specified the libraries to
1480  # use, trust that they are doing what they want.
1481  if test "$poststage1_libs" = ""; then
1482    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1483  fi])
1484 AC_SUBST(poststage1_ldflags)
1485
1486 # Check for PPL
1487 ppllibs=
1488 pplinc=
1489 pwllib=
1490
1491 AC_ARG_WITH(ppl,
1492 [AS_HELP_STRING([--with-ppl=PATH],
1493                 [specify prefix directory for the installed PPL package.
1494                  Equivalent to --with-ppl-include=PATH/include
1495                  plus --with-ppl-lib=PATH/lib])])
1496 AC_ARG_WITH(ppl-include,
1497 [AS_HELP_STRING([--with-ppl-include=PATH],
1498                 [specify directory for installed PPL include files])])
1499 AC_ARG_WITH(ppl-lib,
1500 [AS_HELP_STRING([--with-ppl-lib=PATH],
1501                 [specify directory for the installed PPL library])])
1502
1503 AC_ARG_ENABLE(ppl-version-check,
1504 [AS_HELP_STRING([--disable-ppl-version-check],
1505                 [disable check for PPL version])])
1506
1507 case $with_ppl in
1508   yes | no | "")
1509     ;;
1510   *)
1511     ppllibs="-L$with_ppl/lib"
1512     pplinc="-I$with_ppl/include $pplinc"
1513     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1514       with_ppl=yes
1515     else
1516       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1517     fi
1518     ;;
1519 esac
1520
1521 if test x"$with_ppl_include" != x; then
1522   pplinc="-I$with_ppl_include $pplinc"
1523   with_ppl=yes
1524 fi
1525
1526 if test "x$with_ppl_lib" != x; then
1527   ppllibs="-L$with_ppl_lib"
1528   with_ppl=yes
1529 fi
1530
1531 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1532   if test x"$enable_watchdog" = xyes; then
1533     pwllib="-lpwl"
1534   fi
1535   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1536   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1537   enable_ppl_version_check=no
1538   with_ppl=yes
1539 fi
1540
1541 if test "x$with_ppl" != xno; then
1542   if test "x$pwllib" = x; then
1543     saved_LIBS="$LIBS"
1544     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1545     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1546     LIBS="$saved_LIBS"
1547   fi
1548
1549   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1550
1551   if test "$enable_ppl_version_check" != no; then
1552     saved_CFLAGS="$CFLAGS"
1553     CFLAGS="$CFLAGS $pplinc $gmpinc"
1554     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1555     AC_TRY_COMPILE([#include "ppl_c.h"],[
1556     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1557     choke me
1558     #endif
1559     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1560     CFLAGS="$saved_CFLAGS"
1561   fi
1562 fi
1563
1564 # Flags needed for PPL
1565 AC_SUBST(ppllibs)
1566 AC_SUBST(pplinc)
1567
1568
1569 # Check for CLOOG
1570
1571 dnl Provide configure switches and initialize clooginc & clooglibs
1572 dnl with user input.
1573 CLOOG_INIT_FLAGS
1574 if test "x$with_ppl" = "xno"; then
1575   dnl Only execute fail-action, if CLooG has been requested.
1576   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1577   if test "${graphite_requested}" = yes; then
1578     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1579   fi
1580   with_cloog=no
1581 fi
1582 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1583   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1584   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1585   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1586 fi
1587 if test "x$with_cloog" != "xno"; then
1588   dnl The minimal version of CLooG required for Graphite.
1589   dnl
1590   dnl If we use CLooG-Legacy, the provided version information is
1591   dnl ignored.
1592   CLOOG_CHECK_VERSION(0,16,1)
1593
1594   dnl Only execute fail-action, if CLooG has been requested.
1595   CLOOG_IF_FAILED([
1596     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1597 fi
1598
1599 # Check for LTO support.
1600 AC_ARG_ENABLE(lto,
1601 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1602 enable_lto=$enableval,
1603 enable_lto=yes; default_enable_lto=yes)
1604
1605 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1606   build_lto_plugin=yes
1607 ],[if test x"$default_enable_lto" = x"yes" ; then
1608     case $target in
1609       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1610       # On other non-ELF platforms, LTO has yet to be validated.
1611       *) enable_lto=no ;;
1612     esac
1613   else
1614   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1615   # It would also be nice to check the binutils support, but we don't
1616   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1617   # warn during gcc/ subconfigure; unless you're bootstrapping with
1618   # -flto it won't be needed until after installation anyway.
1619     case $target in
1620       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1621       *) if test x"$enable_lto" = x"yes"; then
1622         AC_MSG_ERROR([LTO support is not enabled for this target.])
1623         fi
1624       ;;
1625     esac
1626   fi
1627   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1628   # Build it unless LTO was explicitly disabled.
1629   case $target in
1630     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1631     *) ;;
1632   esac
1633 ])
1634
1635
1636 # By default, C is the only stage 1 language.
1637 stage1_languages=,c,
1638
1639 # Target libraries that we bootstrap.
1640 bootstrap_target_libs=,target-libgcc,
1641
1642 # Figure out what language subdirectories are present.
1643 # Look if the user specified --enable-languages="..."; if not, use
1644 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1645 # go away some day.
1646 # NB:  embedded tabs in this IF block -- do not untabify
1647 if test -d ${srcdir}/gcc; then
1648   if test x"${enable_languages+set}" != xset; then
1649     if test x"${LANGUAGES+set}" = xset; then
1650       enable_languages="${LANGUAGES}"
1651         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1652     else
1653       enable_languages=all
1654     fi
1655   else
1656     if test x"${enable_languages}" = x ||
1657        test x"${enable_languages}" = xyes;
1658        then
1659       echo configure.in: --enable-languages needs at least one language argument 1>&2
1660       exit 1
1661     fi
1662   fi
1663   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1664
1665   # 'f95' is the old name for the 'fortran' language. We issue a warning
1666   # and make the substitution.
1667   case ,${enable_languages}, in
1668     *,f95,*)
1669       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1670       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1671       ;;
1672   esac
1673
1674   # If bootstrapping, then using --enable-build-with-cxx or
1675   # --enable-build-poststage1-with-cxx requires enabling C++.
1676   case ",$enable_languages,:,$ENABLE_BUILD_WITH_CXX,$ENABLE_BUILD_POSTSTAGE1_WITH_CXX,:$enable_bootstrap" in
1677     *,c++,*:*:*) ;;
1678     *:*,yes,*:yes)
1679       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1680         enable_languages="${enable_languages},c++"
1681       else
1682         AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx or --enable-build-poststage1-with-cxx requires c++ sources])
1683       fi
1684       ;;
1685   esac
1686
1687   # First scan to see if an enabled language requires some other language.
1688   # We assume that a given config-lang.in will list all the language
1689   # front ends it requires, even if some are required indirectly.
1690   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1691     case ${lang_frag} in
1692       ..) ;;
1693       # The odd quoting in the next line works around
1694       # an apparent bug in bash 1.12 on linux.
1695       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1696       *)
1697         # From the config-lang.in, get $language, $lang_requires, and
1698         # $lang_requires_boot_languages.
1699         language=
1700         lang_requires=
1701         lang_requires_boot_languages=
1702         . ${lang_frag}
1703         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1704           case ,${enable_languages}, in
1705             *,$other,*) ;;
1706             *,all,*) ;;
1707             *,$language,*)
1708               echo " \`$other' language required by \`$language'; enabling" 1>&2
1709               enable_languages="${enable_languages},${other}"
1710               ;;
1711           esac
1712         done
1713         for other in ${lang_requires_boot_languages} ; do
1714           if test "$other" != "c"; then
1715             case ,${enable_stage1_languages}, in
1716               *,$other,*) ;;
1717               *,all,*) ;;
1718               *)
1719                 case ,${enable_languages}, in
1720                   *,$language,*)
1721                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1722                     enable_stage1_languages="$enable_stage1_languages,${other}"
1723                     ;;
1724                 esac
1725                 ;;
1726             esac
1727           fi
1728         done
1729         ;;
1730     esac
1731   done
1732
1733   new_enable_languages=,c,
1734
1735   # If LTO is enabled, add the LTO front end.
1736   extra_host_libiberty_configure_flags=
1737   if test "$enable_lto" = "yes" ; then
1738     case ,${enable_languages}, in
1739       *,lto,*) ;;
1740       *) enable_languages="${enable_languages},lto" ;;
1741     esac
1742     if test "${build_lto_plugin}" = "yes" ; then
1743       configdirs="$configdirs lto-plugin"
1744       extra_host_libiberty_configure_flags=--enable-shared
1745     fi
1746   fi
1747   AC_SUBST(extra_host_libiberty_configure_flags)
1748
1749   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1750   potential_languages=,c,
1751
1752   enabled_target_libs=
1753   disabled_target_libs=
1754
1755   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1756     case ${lang_frag} in
1757       ..) ;;
1758       # The odd quoting in the next line works around
1759       # an apparent bug in bash 1.12 on linux.
1760       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1761       *)
1762         # From the config-lang.in, get $language, $target_libs,
1763         # $lang_dirs, $boot_language, and $build_by_default
1764         language=
1765         target_libs=
1766         lang_dirs=
1767         subdir_requires=
1768         boot_language=no
1769         build_by_default=yes
1770         . ${lang_frag}
1771         if test x${language} = x; then
1772           echo "${lang_frag} doesn't set \$language." 1>&2
1773           exit 1
1774         fi
1775
1776         if test "$language" = "c++"; then
1777           if test "$ENABLE_BUILD_WITH_CXX" = "yes" \
1778              || test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
1779             boot_language=yes
1780           fi
1781         fi
1782
1783         case ,${enable_languages}, in
1784           *,${language},*)
1785             # Language was explicitly selected; include it.
1786             add_this_lang=yes
1787             ;;
1788           *,all,*)
1789             # 'all' was selected, select it if it is a default language
1790             add_this_lang=${build_by_default}
1791             ;;
1792           *)
1793             add_this_lang=no
1794             ;;
1795         esac
1796
1797         # Disable languages that need other directories if these aren't available.
1798         for i in $subdir_requires; do
1799           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1800           case ,${enable_languages}, in
1801             *,${language},*)
1802               # Specifically requested language; tell them.
1803               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1804               ;;
1805             *)
1806               # Silently disable.
1807               add_this_lang=unsupported
1808               ;;
1809           esac
1810         done
1811
1812         # Disable Ada if no preexisting GNAT is available.
1813         case ,${enable_languages},:${language}:${have_gnat} in
1814           *,${language},*:ada:no)
1815             # Specifically requested language; tell them.
1816             AC_MSG_ERROR([GNAT is required to build $language])
1817             ;;
1818           *:ada:no)
1819             # Silently disable.
1820             add_this_lang=unsupported
1821             ;;
1822         esac
1823
1824         # Disable a language that is unsupported by the target.
1825         case " $unsupported_languages " in
1826           *" $language "*)
1827             add_this_lang=unsupported
1828             ;;
1829         esac
1830
1831         case $add_this_lang in
1832           unsupported)
1833             # Remove language-dependent dirs.
1834             disabled_target_libs="$disabled_target_libs $target_libs"
1835             noconfigdirs="$noconfigdirs $lang_dirs"
1836             ;;
1837           no)
1838             # Remove language-dependent dirs; still show language as supported.
1839             disabled_target_libs="$disabled_target_libs $target_libs"
1840             noconfigdirs="$noconfigdirs $lang_dirs"
1841             potential_languages="${potential_languages}${language},"
1842             ;;
1843           yes)
1844             new_enable_languages="${new_enable_languages}${language},"
1845             potential_languages="${potential_languages}${language},"
1846             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1847             enabled_target_libs="$enabled_target_libs $target_libs"
1848             case "${boot_language}:,$enable_stage1_languages," in
1849               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1850                 # Add to (comma-separated) list of stage 1 languages.
1851                 case ",$stage1_languages," in
1852                   *,$language,* | ,yes, | ,all,) ;;
1853                   *) stage1_languages="${stage1_languages}${language}," ;;
1854                 esac
1855                 # We need to bootstrap any supporting libraries.
1856                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1857                 ;;
1858             esac
1859             ;;
1860         esac
1861         ;;
1862     esac
1863   done
1864
1865   # Add target libraries which are only needed for disabled languages
1866   # to noconfigdirs.
1867   if test -n "$disabled_target_libs"; then
1868     for dir in $disabled_target_libs; do
1869       case " $enabled_target_libs " in
1870       *" ${dir} "*) ;;
1871       *) noconfigdirs="$noconfigdirs $dir" ;;
1872       esac
1873     done
1874   fi
1875
1876   AC_ARG_ENABLE(stage1-languages,
1877   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1878                   [choose additional languages to build during
1879                   stage1.  Mostly useful for compiler development])],
1880   [case ,${enable_stage1_languages}, in
1881     ,no,|,,)
1882       # Set it to something that will have no effect in the loop below
1883       enable_stage1_languages=c ;;
1884     ,yes,)
1885       enable_stage1_languages=`echo $new_enable_languages | \
1886         sed -e "s/^,//" -e "s/,$//" ` ;;
1887     *,all,*)
1888       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1889         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1890   esac
1891
1892   # Add "good" languages from enable_stage1_languages to stage1_languages,
1893   # while "bad" languages go in missing_languages.  Leave no duplicates.
1894   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1895     case $potential_languages in
1896       *,$i,*)
1897         case $stage1_languages in
1898           *,$i,*) ;;
1899           *) stage1_languages="$stage1_languages$i," ;;
1900         esac ;;
1901       *)
1902         case $missing_languages in
1903           *,$i,*) ;;
1904           *) missing_languages="$missing_languages$i," ;;
1905         esac ;;
1906      esac
1907   done])
1908
1909   # Remove leading/trailing commas that were added for simplicity
1910   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1911   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1912   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1913   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1914
1915   if test "x$missing_languages" != x; then
1916     AC_MSG_ERROR([
1917 The following requested languages could not be built: ${missing_languages}
1918 Supported languages are: ${potential_languages}])
1919   fi
1920   if test "x$new_enable_languages" != "x$enable_languages"; then
1921     echo The following languages will be built: ${new_enable_languages}
1922     enable_languages="$new_enable_languages"
1923   fi
1924
1925   AC_SUBST(stage1_languages)
1926   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1927 fi
1928
1929 # Handle --disable-<component> generically.
1930 for dir in $configdirs $build_configdirs $target_configdirs ; do
1931   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1932   varname=`echo $dirname | sed -e s/+/_/g`
1933   if eval test x\${enable_${varname}} "=" xno ; then
1934     noconfigdirs="$noconfigdirs $dir"
1935   fi
1936 done
1937
1938 # Check for Boehm's garbage collector
1939 AC_ARG_ENABLE(objc-gc,
1940 [AS_HELP_STRING([--enable-objc-gc],
1941                 [enable use of Boehm's garbage collector with the
1942                  GNU Objective-C runtime])],
1943 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1944   *,objc,*:*:yes:*target-boehm-gc*)
1945     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1946     ;;
1947 esac])
1948
1949 # Make sure we only build Boehm's garbage collector if required.
1950 case ,${enable_languages},:${enable_objc_gc} in
1951   *,objc,*:yes)
1952     # Keep target-boehm-gc if requested for Objective-C.
1953     ;;
1954   *)
1955     # Otherwise remove target-boehm-gc depending on target-libjava.
1956     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
1957       noconfigdirs="$noconfigdirs target-boehm-gc"
1958     fi
1959     ;;
1960 esac
1961
1962 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
1963 # $build_configdirs and $target_configdirs.
1964 # If we have the source for $noconfigdirs entries, add them to $notsupp.
1965
1966 notsupp=""
1967 for dir in . $skipdirs $noconfigdirs ; do
1968   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
1969   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1970     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
1971     if test -r $srcdir/$dirname/configure ; then
1972       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1973         true
1974       else
1975         notsupp="$notsupp $dir"
1976       fi
1977     fi
1978   fi
1979   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1980     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
1981     if test -r $srcdir/$dirname/configure ; then
1982       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1983         true
1984       else
1985         notsupp="$notsupp $dir"
1986       fi
1987     fi
1988   fi
1989   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1990     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
1991     if test -r $srcdir/$dirname/configure ; then
1992       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
1993         true
1994       else
1995         notsupp="$notsupp $dir"
1996       fi
1997     fi
1998   fi
1999 done
2000
2001 # Quietly strip out all directories which aren't configurable in this tree.
2002 # This relies on all configurable subdirectories being autoconfiscated, which
2003 # is now the case.
2004 build_configdirs_all="$build_configdirs"
2005 build_configdirs=
2006 for i in ${build_configdirs_all} ; do
2007   j=`echo $i | sed -e s/build-//g`
2008   if test -f ${srcdir}/$j/configure ; then
2009     build_configdirs="${build_configdirs} $i"
2010   fi
2011 done
2012
2013 configdirs_all="$configdirs"
2014 configdirs=
2015 for i in ${configdirs_all} ; do
2016   if test -f ${srcdir}/$i/configure ; then
2017     configdirs="${configdirs} $i"
2018   fi
2019 done
2020
2021 target_configdirs_all="$target_configdirs"
2022 target_configdirs=
2023 for i in ${target_configdirs_all} ; do
2024   j=`echo $i | sed -e s/target-//g`
2025   if test -f ${srcdir}/$j/configure ; then
2026     target_configdirs="${target_configdirs} $i"
2027   fi
2028 done
2029
2030 # Produce a warning message for the subdirs we can't configure.
2031 # This isn't especially interesting in the Cygnus tree, but in the individual
2032 # FSF releases, it's important to let people know when their machine isn't
2033 # supported by the one or two programs in a package.
2034
2035 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2036   # If $appdirs is non-empty, at least one of those directories must still
2037   # be configured, or we error out.  (E.g., if the gas release supports a
2038   # specified target in some subdirs but not the gas subdir, we shouldn't
2039   # pretend that all is well.)
2040   if test -n "$appdirs" ; then
2041     for dir in $appdirs ; do
2042       if test -r $dir/Makefile.in ; then
2043         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2044           appdirs=""
2045           break
2046         fi
2047         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2048           appdirs=""
2049           break
2050         fi
2051       fi
2052     done
2053     if test -n "$appdirs" ; then
2054       echo "*** This configuration is not supported by this package." 1>&2
2055       exit 1
2056     fi
2057   fi
2058   # Okay, some application will build, or we don't care to check.  Still
2059   # notify of subdirs not getting built.
2060   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2061   echo "    ${notsupp}" 1>&2
2062   echo "    (Any other directories should still work fine.)" 1>&2
2063 fi
2064
2065 case "$host" in
2066   *msdosdjgpp*)
2067     enable_gdbtk=no ;;
2068 esac
2069
2070 # To find our prefix, in gcc_cv_tool_prefix.
2071 ACX_TOOL_DIRS
2072
2073 copy_dirs=
2074
2075 AC_ARG_WITH([build-sysroot],
2076   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2077                   [use sysroot as the system root during the build])],
2078   [if test x"$withval" != x ; then
2079      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2080    fi],
2081   [SYSROOT_CFLAGS_FOR_TARGET=])
2082 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2083
2084 AC_ARG_WITH([debug-prefix-map],
2085   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2086                   [map A to B, C to D ... in debug information])],
2087   [if test x"$withval" != x; then
2088      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2089      for debug_map in $withval; do
2090        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2091      done
2092    fi],
2093   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2094 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2095
2096 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2097 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2098 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2099 # We want to ensure that TARGET libraries (which we know are built with
2100 # gcc) are built with "-O2 -g", so include those options when setting
2101 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2102 if test "x$CFLAGS_FOR_TARGET" = x; then
2103   CFLAGS_FOR_TARGET=$CFLAGS
2104   case " $CFLAGS " in
2105     *" -O2 "*) ;;
2106     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2107   esac
2108   case " $CFLAGS " in
2109     *" -g "* | *" -g3 "*) ;;
2110     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2111   esac
2112 fi
2113 AC_SUBST(CFLAGS_FOR_TARGET)
2114
2115 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2116   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2117   case " $CXXFLAGS " in
2118     *" -O2 "*) ;;
2119     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2120   esac
2121   case " $CXXFLAGS " in
2122     *" -g "* | *" -g3 "*) ;;
2123     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2124   esac
2125 fi
2126 AC_SUBST(CXXFLAGS_FOR_TARGET)
2127
2128 AC_SUBST(LDFLAGS_FOR_TARGET)
2129
2130 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2131 # the named directory are copied to $(tooldir)/sys-include.
2132 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2133   if test x${is_cross_compiler} = xno ; then
2134     echo 1>&2 '***' --with-headers is only supported when cross compiling
2135     exit 1
2136   fi
2137   if test x"${with_headers}" != xyes ; then
2138     x=${gcc_cv_tool_prefix}
2139     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2140   fi
2141 fi
2142
2143 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2144 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2145 # are permitted.
2146 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2147   if test x${is_cross_compiler} = xno ; then
2148     echo 1>&2 '***' --with-libs is only supported when cross compiling
2149     exit 1
2150   fi
2151   if test x"${with_libs}" != xyes ; then
2152     # Copy the libraries in reverse order, so that files in the first named
2153     # library override files in subsequent libraries.
2154     x=${gcc_cv_tool_prefix}
2155     for l in ${with_libs}; do
2156       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2157     done
2158   fi
2159 fi
2160
2161 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2162 #
2163 # This is done by determining whether or not the appropriate directory
2164 # is available, and by checking whether or not specific configurations
2165 # have requested that this magic not happen.
2166 #
2167 # The command line options always override the explicit settings in
2168 # configure.in, and the settings in configure.in override this magic.
2169 #
2170 # If the default for a toolchain is to use GNU as and ld, and you don't
2171 # want to do that, then you should use the --without-gnu-as and
2172 # --without-gnu-ld options for the configure script.  Similarly, if
2173 # the default is to use the included zlib and you don't want to do that,
2174 # you should use the --with-system-zlib option for the configure script.
2175
2176 if test x${use_gnu_as} = x &&
2177    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2178   with_gnu_as=yes
2179   extra_host_args="$extra_host_args --with-gnu-as"
2180 fi
2181
2182 if test x${use_gnu_ld} = x &&
2183    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2184   with_gnu_ld=yes
2185   extra_host_args="$extra_host_args --with-gnu-ld"
2186 fi
2187
2188 if test x${use_included_zlib} = x &&
2189    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2190   :
2191 else
2192   with_system_zlib=yes
2193   extra_host_args="$extra_host_args --with-system-zlib"
2194 fi
2195
2196 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2197 # can detect this case.
2198
2199 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2200   with_newlib=yes
2201   extra_host_args="$extra_host_args --with-newlib"
2202 fi
2203
2204 # Handle ${copy_dirs}
2205 set fnord ${copy_dirs}
2206 shift
2207 while test $# != 0 ; do
2208   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2209     :
2210   else
2211     echo Copying $1 to $2
2212
2213     # Use the install script to create the directory and all required
2214     # parent directories.
2215     if test -d $2 ; then
2216       :
2217     else
2218       echo >config.temp
2219       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2220     fi
2221
2222     # Copy the directory, assuming we have tar.
2223     # FIXME: Should we use B in the second tar?  Not all systems support it.
2224     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2225
2226     # It is the responsibility of the user to correctly adjust all
2227     # symlinks.  If somebody can figure out how to handle them correctly
2228     # here, feel free to add the code.
2229
2230     echo $1 > $2/COPIED
2231   fi
2232   shift; shift
2233 done
2234
2235 # Determine a target-dependent exec_prefix that the installed
2236 # gcc will search in.  Keep this list sorted by triplet, with
2237 # the *-*-osname triplets last.
2238 md_exec_prefix=
2239 case "${target}" in
2240   i[[34567]]86-pc-msdosdjgpp*)
2241     md_exec_prefix=/dev/env/DJDIR/bin
2242     ;;
2243   *-*-hpux* | \
2244   *-*-nto-qnx* | \
2245   *-*-solaris2*)
2246     md_exec_prefix=/usr/ccs/bin
2247     ;;
2248 esac
2249
2250 extra_arflags_for_target=
2251 extra_nmflags_for_target=
2252 extra_ranlibflags_for_target=
2253 target_makefile_frag=/dev/null
2254 case "${target}" in
2255   spu-*-*)
2256     target_makefile_frag="config/mt-spu"
2257     ;;
2258   mips*-sde-elf*)
2259     target_makefile_frag="config/mt-sde"
2260     ;;
2261   mipsisa*-*-elfoabi*)
2262     target_makefile_frag="config/mt-mips-elfoabi"
2263     ;;
2264   mips*-*-*linux* | mips*-*-gnu*)
2265     target_makefile_frag="config/mt-mips-gnu"
2266     ;;
2267   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2268     target_makefile_frag="config/mt-gnu"
2269     ;;
2270   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2271     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2272     # commands to handle both 32-bit and 64-bit objects.  These flags are
2273     # harmless if we're using GNU nm or ar.
2274     extra_arflags_for_target=" -X32_64"
2275     extra_nmflags_for_target=" -B -X32_64"
2276     ;;
2277   *-*-darwin[[3-9]]*)
2278     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2279     extra_ranlibflags_for_target=" -c"
2280     ;;
2281 esac
2282
2283 alphaieee_frag=/dev/null
2284 case $target in
2285   alpha*-*-*)
2286     # This just makes sure to use the -mieee option to build target libs.
2287     # This should probably be set individually by each library.
2288     alphaieee_frag="config/mt-alphaieee"
2289     ;;
2290 esac
2291
2292 # If --enable-target-optspace always use -Os instead of -O2 to build
2293 # the target libraries, similarly if it is not specified, use -Os
2294 # on selected platforms.
2295 ospace_frag=/dev/null
2296 case "${enable_target_optspace}:${target}" in
2297   yes:*)
2298     ospace_frag="config/mt-ospace"
2299     ;;
2300   :d30v-*)
2301     ospace_frag="config/mt-d30v"
2302     ;;
2303   :m32r-* | :d10v-* | :fr30-*)
2304     ospace_frag="config/mt-ospace"
2305     ;;
2306   no:* | :*)
2307     ;;
2308   *)
2309     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2310     ;;
2311 esac
2312
2313 # Default to using --with-stabs for certain targets.
2314 if test x${with_stabs} = x ; then
2315   case "${target}" in
2316   mips*-*-irix[[56]]*)
2317     ;;
2318   mips*-*-* | alpha*-*-osf*)
2319     with_stabs=yes;
2320     extra_host_args="${extra_host_args} --with-stabs"
2321     ;;
2322   esac
2323 fi
2324
2325 # Some systems (e.g., one of the i386-aix systems the gas testers are
2326 # using) don't handle "\$" correctly, so don't use it here.
2327 tooldir='${exec_prefix}'/${target_noncanonical}
2328 build_tooldir=${tooldir}
2329
2330 # Create a .gdbinit file which runs the one in srcdir
2331 # and tells GDB to look there for source files.
2332
2333 if test -r ${srcdir}/.gdbinit ; then
2334   case ${srcdir} in
2335     .) ;;
2336     *) cat > ./.gdbinit <<EOF
2337 # ${NO_EDIT}
2338 dir ${srcdir}
2339 dir .
2340 source ${srcdir}/.gdbinit
2341 EOF
2342     ;;
2343   esac
2344 fi
2345
2346 # Make sure that the compiler is able to generate an executable.  If it
2347 # can't, we are probably in trouble.  We don't care whether we can run the
2348 # executable--we might be using a cross compiler--we only care whether it
2349 # can be created.  At this point the main configure script has set CC.
2350 we_are_ok=no
2351 echo "int main () { return 0; }" > conftest.c
2352 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2353 if test $? = 0 ; then
2354   if test -s conftest || test -s conftest.exe ; then
2355     we_are_ok=yes
2356   fi
2357 fi
2358 case $we_are_ok in
2359   no)
2360     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2361     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2362     rm -f conftest*
2363     exit 1
2364     ;;
2365 esac
2366 rm -f conftest*
2367
2368 # Decide which environment variable is used to find dynamic libraries.
2369 case "${host}" in
2370   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2371   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2372   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2373   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2374 esac
2375
2376 # On systems where the dynamic library environment variable is PATH,
2377 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2378 # built executables to PATH.
2379 if test "$RPATH_ENVVAR" = PATH; then
2380   GCC_SHLIB_SUBDIR=/shlib
2381 else
2382   GCC_SHLIB_SUBDIR=
2383 fi
2384
2385 # Record target_configdirs and the configure arguments for target and
2386 # build configuration in Makefile.
2387 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2388 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2389
2390 # If we are building libgomp, bootstrap it.
2391 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2392   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2393 fi
2394
2395 # Determine whether gdb needs tk/tcl or not.
2396 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2397 # and in that case we want gdb to be built without tk.  Ugh!
2398 # In fact I believe gdb is the *only* package directly dependent on tk,
2399 # so we should be able to put the 'maybe's in unconditionally and
2400 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2401 # 100% sure that that's safe though.
2402
2403 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2404 case "$enable_gdbtk" in
2405   no)
2406     GDB_TK="" ;;
2407   yes)
2408     GDB_TK="${gdb_tk}" ;;
2409   *)
2410     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2411     # distro.  Eventually someone will fix this and move Insight, nee
2412     # gdbtk to a separate directory.
2413     if test -d ${srcdir}/gdb/gdbtk ; then
2414       GDB_TK="${gdb_tk}"
2415     else
2416       GDB_TK=""
2417     fi
2418     ;;
2419 esac
2420 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2421 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2422
2423 # Strip out unwanted targets.
2424
2425 # While at that, we remove Makefiles if we were started for recursive
2426 # configuration, so that the top-level Makefile reconfigures them,
2427 # like we used to do when configure itself was recursive.
2428
2429 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2430 # but now we're fixing up the Makefile ourselves with the additional
2431 # commands passed to AC_CONFIG_FILES.  Use separate variables
2432 # extrasub-{build,host,target} not because there is any reason to split
2433 # the substitutions up that way, but only to remain below the limit of
2434 # 99 commands in a script, for HP-UX sed.
2435 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2436
2437 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2438   yes:yes:*\ gold\ *:*,c++,*) ;;
2439   yes:yes:*\ gold\ *:*)
2440     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2441     ;;
2442 esac
2443
2444 # Adjust the toplevel makefile according to whether bootstrap was selected.
2445 case $enable_bootstrap in
2446   yes)
2447     bootstrap_suffix=bootstrap
2448     BUILD_CONFIG=bootstrap-debug
2449     ;;
2450   no)
2451     bootstrap_suffix=no-bootstrap
2452     BUILD_CONFIG=
2453     ;;
2454 esac
2455
2456 AC_MSG_CHECKING(for default BUILD_CONFIG)
2457
2458 AC_ARG_WITH([build-config],
2459   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2460                   [use config/NAME.mk build configuration])],
2461   [case $with_build_config in
2462    yes) with_build_config= ;;
2463    no) with_build_config= BUILD_CONFIG= ;;
2464    esac])
2465
2466 if test "x${with_build_config}" != x; then
2467   BUILD_CONFIG=$with_build_config
2468 else
2469   case $BUILD_CONFIG in
2470   bootstrap-debug)
2471     if echo "int f (void) { return 0; }" > conftest.c &&
2472        ${CC} -c conftest.c &&
2473        mv conftest.o conftest.o.g0 &&
2474        ${CC} -c -g conftest.c &&
2475        mv conftest.o conftest.o.g &&
2476        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2477       :
2478     else
2479       BUILD_CONFIG=
2480     fi
2481     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2482     ;;
2483   esac
2484 fi
2485 AC_MSG_RESULT($BUILD_CONFIG)
2486 AC_SUBST(BUILD_CONFIG)
2487
2488 extrasub_build=
2489 for module in ${build_configdirs} ; do
2490   if test -z "${no_recursion}" \
2491      && test -f ${build_subdir}/${module}/Makefile; then
2492     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2493     rm -f ${build_subdir}/${module}/Makefile
2494   fi
2495   extrasub_build="$extrasub_build
2496 /^@if build-$module\$/d
2497 /^@endif build-$module\$/d
2498 /^@if build-$module-$bootstrap_suffix\$/d
2499 /^@endif build-$module-$bootstrap_suffix\$/d"
2500 done
2501 extrasub_host=
2502 for module in ${configdirs} ; do
2503   if test -z "${no_recursion}"; then
2504     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2505       if test -f ${file}; then
2506         echo 1>&2 "*** removing ${file} to force reconfigure"
2507         rm -f ${file}
2508       fi
2509     done
2510   fi
2511   extrasub_host="$extrasub_host
2512 /^@if $module\$/d
2513 /^@endif $module\$/d
2514 /^@if $module-$bootstrap_suffix\$/d
2515 /^@endif $module-$bootstrap_suffix\$/d"
2516 done
2517 extrasub_target=
2518 for module in ${target_configdirs} ; do
2519   if test -z "${no_recursion}" \
2520      && test -f ${target_subdir}/${module}/Makefile; then
2521     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2522     rm -f ${target_subdir}/${module}/Makefile
2523   fi
2524
2525   # We only bootstrap target libraries listed in bootstrap_target_libs.
2526   case $bootstrap_target_libs in
2527     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2528     *) target_bootstrap_suffix=no-bootstrap ;;
2529   esac
2530
2531   extrasub_target="$extrasub_target
2532 /^@if target-$module\$/d
2533 /^@endif target-$module\$/d
2534 /^@if target-$module-$target_bootstrap_suffix\$/d
2535 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2536 done
2537
2538 # Do the final fixup along with target modules.
2539 extrasub_target="$extrasub_target
2540 /^@if /,/^@endif /d"
2541
2542 # Create the serialization dependencies.  This uses a temporary file.
2543
2544 AC_ARG_ENABLE([serial-configure],
2545 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2546                 [force sequential configuration of
2547                  sub-packages for the host, target or build
2548                  machine, or all sub-packages])])
2549
2550 case ${enable_serial_configure} in
2551   yes)
2552     enable_serial_build_configure=yes
2553     enable_serial_host_configure=yes
2554     enable_serial_target_configure=yes
2555     ;;
2556 esac
2557
2558 # These force 'configure's to be done one at a time, to avoid problems
2559 # with contention over a shared config.cache.
2560 rm -f serdep.tmp
2561 echo '# serdep.tmp' > serdep.tmp
2562 olditem=
2563 test "x${enable_serial_build_configure}" = xyes &&
2564 for item in ${build_configdirs} ; do
2565   case ${olditem} in
2566     "") ;;
2567     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2568   esac
2569   olditem=${item}
2570 done
2571 olditem=
2572 test "x${enable_serial_host_configure}" = xyes &&
2573 for item in ${configdirs} ; do
2574   case ${olditem} in
2575     "") ;;
2576     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2577   esac
2578   olditem=${item}
2579 done
2580 olditem=
2581 test "x${enable_serial_target_configure}" = xyes &&
2582 for item in ${target_configdirs} ; do
2583   case ${olditem} in
2584     "") ;;
2585     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2586   esac
2587   olditem=${item}
2588 done
2589 serialization_dependencies=serdep.tmp
2590 AC_SUBST_FILE(serialization_dependencies)
2591
2592 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2593 # target, nonopt, and variable assignments.  These are the ones we
2594 # might not want to pass down to subconfigures.  The exception being
2595 # --cache-file=/dev/null, which is used to turn off the use of cache
2596 # files altogether, and which should be passed on to subconfigures.
2597 # Also strip program-prefix, program-suffix, and program-transform-name,
2598 # so that we can pass down a consistent program-transform-name.
2599 baseargs=
2600 tbaseargs=
2601 keep_next=no
2602 skip_next=no
2603 eval "set -- $ac_configure_args"
2604 for ac_arg
2605 do
2606   if test X"$skip_next" = X"yes"; then
2607     skip_next=no
2608     continue
2609   fi
2610   if test X"$keep_next" = X"yes"; then
2611     case $ac_arg in
2612       *\'*)
2613         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2614     esac
2615     baseargs="$baseargs '$ac_arg'"
2616     tbaseargs="$tbaseargs '$ac_arg'"
2617     keep_next=no
2618     continue
2619   fi
2620
2621   # Handle separated arguments.  Based on the logic generated by
2622   # autoconf 2.59.
2623   case $ac_arg in
2624     *=* | --config-cache | -C | -disable-* | --disable-* \
2625       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2626       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2627       | -with-* | --with-* | -without-* | --without-* | --x)
2628       separate_arg=no
2629       ;;
2630     -*)
2631       separate_arg=yes
2632       ;;
2633     *)
2634       separate_arg=no
2635       ;;
2636   esac
2637
2638   skip_targ=no
2639   case $ac_arg in
2640 changequote(,)
2641   --with-* | --without-*)
2642     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2643
2644     case $libopt in
2645     *[-_]include)
2646       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2647       ;;
2648     *[-_]lib)
2649       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2650       ;;
2651     *)
2652       lib=$libopt
2653       ;;
2654     esac
2655 changequote([,])
2656
2657     case $lib in
2658     mpc | mpfr | gmp | ppl | cloog)
2659       # If we're processing --with-$lib, --with-$lib-include or
2660       # --with-$lib-lib, for one of the libs above, and target is
2661       # different from host, don't pass the current argument to any
2662       # target library's configure.
2663       if test x$is_cross_compiler = xyes; then
2664         skip_targ=yes
2665       fi
2666       ;;
2667     esac
2668     ;;
2669   esac
2670
2671   case "$ac_arg" in
2672     --cache-file=/dev/null | \
2673     -cache-file=/dev/null )
2674       # Handled here to avoid the test to skip args below.
2675       baseargs="$baseargs '$ac_arg'"
2676       tbaseargs="$tbaseargs '$ac_arg'"
2677       # Assert: $separate_arg should always be no.
2678       keep_next=$separate_arg
2679       ;;
2680     --no*)
2681       continue
2682       ;;
2683     --c* | \
2684     --sr* | \
2685     --ho* | \
2686     --bu* | \
2687     --t* | \
2688     --program-* | \
2689     -cache_file* | \
2690     -srcdir* | \
2691     -host* | \
2692     -build* | \
2693     -target* | \
2694     -program-prefix* | \
2695     -program-suffix* | \
2696     -program-transform-name* )
2697       skip_next=$separate_arg
2698       continue
2699       ;;
2700     -*)
2701       # An option.  Add it.
2702       case $ac_arg in
2703         *\'*)
2704           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2705       esac
2706       baseargs="$baseargs '$ac_arg'"
2707       if test X"$skip_targ" = Xno; then
2708         tbaseargs="$tbaseargs '$ac_arg'"
2709       fi
2710       keep_next=$separate_arg
2711       ;;
2712     *)
2713       # Either a variable assignment, or a nonopt (triplet).  Don't
2714       # pass it down; let the Makefile handle this.
2715       continue
2716       ;;
2717   esac
2718 done
2719 # Remove the initial space we just introduced and, as these will be
2720 # expanded by make, quote '$'.
2721 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2722
2723 # Add in --program-transform-name, after --program-prefix and
2724 # --program-suffix have been applied to it.  Autoconf has already
2725 # doubled dollar signs and backslashes in program_transform_name; we want
2726 # the backslashes un-doubled, and then the entire thing wrapped in single
2727 # quotes, because this will be expanded first by make and then by the shell.
2728 # Also, because we want to override the logic in subdir configure scripts to
2729 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2730 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2731 ${program_transform_name}
2732 EOF_SED
2733 gcc_transform_name=`cat conftestsed.out`
2734 rm -f conftestsed.out
2735 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2736 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2737 if test "$silent" = yes; then
2738   baseargs="$baseargs --silent"
2739   tbaseargs="$tbaseargs --silent"
2740 fi
2741 baseargs="$baseargs --disable-option-checking"
2742 tbaseargs="$tbaseargs --disable-option-checking"
2743
2744 # Record and document user additions to sub configure arguments.
2745 AC_ARG_VAR([build_configargs],
2746            [additional configure arguments for build directories])
2747 AC_ARG_VAR([host_configargs],
2748            [additional configure arguments for host directories])
2749 AC_ARG_VAR([target_configargs],
2750            [additional configure arguments for target directories])
2751
2752 # For the build-side libraries, we just need to pretend we're native,
2753 # and not use the same cache file.  Multilibs are neither needed nor
2754 # desired.
2755 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2756
2757 # For host modules, accept cache file option, or specification as blank.
2758 case "${cache_file}" in
2759 "") # empty
2760   cache_file_option="" ;;
2761 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2762   cache_file_option="--cache-file=${cache_file}" ;;
2763 *) # relative path
2764   cache_file_option="--cache-file=../${cache_file}" ;;
2765 esac
2766
2767 # Host dirs don't like to share a cache file either, horribly enough.
2768 # This seems to be due to autoconf 2.5x stupidity.
2769 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2770
2771 target_configargs="$target_configargs ${tbaseargs}"
2772
2773 # Passing a --with-cross-host argument lets the target libraries know
2774 # whether they are being built with a cross-compiler or being built
2775 # native.  However, it would be better to use other mechanisms to make the
2776 # sorts of decisions they want to make on this basis.  Please consider
2777 # this option to be deprecated.  FIXME.
2778 if test x${is_cross_compiler} = xyes ; then
2779   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2780 fi
2781
2782 # Default to --enable-multilib.
2783 if test x${enable_multilib} = x ; then
2784   target_configargs="--enable-multilib ${target_configargs}"
2785 fi
2786
2787 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2788 # changed from the earlier setting of with_newlib.
2789 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2790   target_configargs="--with-newlib ${target_configargs}"
2791 fi
2792
2793 # Different target subdirs use different values of certain variables
2794 # (notably CXX).  Worse, multilibs use *lots* of different values.
2795 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2796 # it doesn't automatically accept command-line overrides of them.
2797 # This means it's not safe for target subdirs to share a cache file,
2798 # which is disgusting, but there you have it.  Hopefully this can be
2799 # fixed in future.  It's still worthwhile to use a cache file for each
2800 # directory.  I think.
2801
2802 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2803 # We need to pass --target, as newer autoconf's requires consistency
2804 # for target_alias and gcc doesn't manage it consistently.
2805 target_configargs="--cache-file=./config.cache ${target_configargs}"
2806
2807 FLAGS_FOR_TARGET=
2808 case " $target_configdirs " in
2809  *" newlib "*)
2810   case " $target_configargs " in
2811   *" --with-newlib "*)
2812    case "$target" in
2813     *-cygwin*)
2814       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2815       ;;
2816    esac
2817
2818    # If we're not building GCC, don't discard standard headers.
2819    if test -d ${srcdir}/gcc; then
2820      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2821
2822      if test "${build}" != "${host}"; then
2823        # On Canadian crosses, CC_FOR_TARGET will have already been set
2824        # by `configure', so we won't have an opportunity to add -Bgcc/
2825        # to it.  This is right: we don't want to search that directory
2826        # for binaries, but we want the header files in there, so add
2827        # them explicitly.
2828        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2829
2830        # Someone might think of using the pre-installed headers on
2831        # Canadian crosses, in case the installed compiler is not fully
2832        # compatible with the compiler being built.  In this case, it
2833        # would be better to flag an error than risking having
2834        # incompatible object files being constructed.  We can't
2835        # guarantee that an error will be flagged, but let's hope the
2836        # compiler will do it, when presented with incompatible header
2837        # files.
2838      fi
2839    fi
2840
2841    case "${target}-${is_cross_compiler}" in
2842    i[[3456789]]86-*-linux*-no)
2843       # Here host == target, so we don't need to build gcc,
2844       # so we don't want to discard standard headers.
2845       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2846       ;;
2847    *)
2848       # If we're building newlib, use its generic headers last, but search
2849       # for any libc-related directories first (so make it the last -B
2850       # switch).
2851       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2852
2853       # If we're building libgloss, find the startup file, simulator library
2854       # and linker script.
2855       case " $target_configdirs " in
2856         *" libgloss "*)
2857         # Look for startup file, simulator library and maybe linker script.
2858         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2859         # Look for libnosys.a in case the target needs it.
2860         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2861         # Most targets have the linker script in the source directory.
2862         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2863         ;;
2864       esac
2865       ;;
2866    esac
2867    ;;
2868   esac
2869   ;;
2870 esac
2871
2872 case "$target" in
2873   x86_64-*mingw* | *-w64-mingw*)
2874   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2875   # however, use a symlink named 'mingw' in ${prefix} .
2876     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2877     ;;
2878   *-mingw*)
2879   # MinGW can't be handled as Cygwin above since it does not use newlib.
2880     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2881     ;;
2882 esac
2883
2884 # Allow the user to override the flags for
2885 # our build compiler if desired.
2886 if test x"${build}" = x"${host}" ; then
2887   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2888   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2889   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2890 fi
2891
2892 # On Canadian crosses, we'll be searching the right directories for
2893 # the previously-installed cross compiler, so don't bother to add
2894 # flags for directories within the install tree of the compiler
2895 # being built; programs in there won't even run.
2896 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2897   # Search for pre-installed headers if nothing else fits.
2898   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2899 fi
2900
2901 if test "x${use_gnu_ld}" = x &&
2902    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2903   # Arrange for us to find uninstalled linker scripts.
2904   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2905 fi
2906
2907 # Search for other target-specific linker scripts and such.
2908 case "${target}" in
2909   mep*)
2910     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2911     ;;
2912 esac
2913
2914 # Makefile fragments.
2915 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2916 do
2917   eval fragval=\$$frag
2918   if test $fragval != /dev/null; then
2919     eval $frag=${srcdir}/$fragval
2920   fi
2921 done
2922 AC_SUBST_FILE(host_makefile_frag)
2923 AC_SUBST_FILE(target_makefile_frag)
2924 AC_SUBST_FILE(alphaieee_frag)
2925 AC_SUBST_FILE(ospace_frag)
2926
2927 # Miscellanea: directories, flags, etc.
2928 AC_SUBST(RPATH_ENVVAR)
2929 AC_SUBST(GCC_SHLIB_SUBDIR)
2930 AC_SUBST(tooldir)
2931 AC_SUBST(build_tooldir)
2932 AC_SUBST(CONFIGURE_GDB_TK)
2933 AC_SUBST(GDB_TK)
2934 AC_SUBST(INSTALL_GDB_TK)
2935
2936 # Build module lists & subconfigure args.
2937 AC_SUBST(build_configargs)
2938 AC_SUBST(build_configdirs)
2939
2940 # Host module lists & subconfigure args.
2941 AC_SUBST(host_configargs)
2942 AC_SUBST(configdirs)
2943 AC_SUBST(target_configdirs)
2944
2945 # Target module lists & subconfigure args.
2946 AC_SUBST(target_configargs)
2947
2948
2949 # Build tools.
2950 AC_SUBST(AR_FOR_BUILD)
2951 AC_SUBST(AS_FOR_BUILD)
2952 AC_SUBST(CC_FOR_BUILD)
2953 AC_SUBST(CFLAGS_FOR_BUILD)
2954 AC_SUBST(CXXFLAGS_FOR_BUILD)
2955 AC_SUBST(CXX_FOR_BUILD)
2956 AC_SUBST(DLLTOOL_FOR_BUILD)
2957 AC_SUBST(GCJ_FOR_BUILD)
2958 AC_SUBST(GFORTRAN_FOR_BUILD)
2959 AC_SUBST(GOC_FOR_BUILD)
2960 AC_SUBST(LDFLAGS_FOR_BUILD)
2961 AC_SUBST(LD_FOR_BUILD)
2962 AC_SUBST(NM_FOR_BUILD)
2963 AC_SUBST(RANLIB_FOR_BUILD)
2964 AC_SUBST(WINDMC_FOR_BUILD)
2965 AC_SUBST(WINDRES_FOR_BUILD)
2966
2967 # Generate default definitions for YACC, M4, LEX and other programs that run
2968 # on the build machine.  These are used if the Makefile can't locate these
2969 # programs in objdir.
2970 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
2971
2972 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
2973 case " $build_configdirs " in
2974   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
2975 esac
2976
2977 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
2978 case " $build_configdirs " in
2979   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
2980 esac
2981
2982 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
2983 case " $build_configdirs " in
2984   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
2985 esac
2986
2987 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
2988 case " $build_configdirs " in
2989   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2990   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
2991 esac
2992
2993 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
2994 case " $build_configdirs " in
2995   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
2996 esac
2997
2998 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
2999 case " $build_configdirs " in
3000   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3001   *)
3002 changequote(,)
3003     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3004     # higher, else we use the "missing" dummy.
3005     if ${MAKEINFO} --version \
3006        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3007       :
3008     else
3009       MAKEINFO="$MISSING makeinfo"
3010     fi
3011     ;;
3012 changequote([,])
3013 esac
3014
3015 # FIXME: expect and dejagnu may become build tools?
3016
3017 AC_CHECK_PROGS(EXPECT, expect, expect)
3018 case " $configdirs " in
3019   *" expect "*)
3020     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3021     ;;
3022 esac
3023
3024 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3025 case " $configdirs " in
3026   *" dejagnu "*)
3027     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3028     ;;
3029 esac
3030
3031
3032 # Host tools.
3033 NCN_STRICT_CHECK_TOOLS(AR, ar)
3034 NCN_STRICT_CHECK_TOOLS(AS, as)
3035 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3036 NCN_STRICT_CHECK_TOOLS(LD, ld)
3037 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3038 NCN_STRICT_CHECK_TOOLS(NM, nm)
3039 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3040 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3041 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3042 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3043 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3044 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3045 AC_SUBST(CC)
3046 AC_SUBST(CXX)
3047 AC_SUBST(CFLAGS)
3048 AC_SUBST(CXXFLAGS)
3049
3050 # Target tools.
3051 AC_ARG_WITH([build-time-tools],
3052   [AS_HELP_STRING([--with-build-time-tools=PATH],
3053                   [use given path to find target tools during the build])],
3054   [case x"$withval" in
3055      x/*) ;;
3056      *)
3057        with_build_time_tools=
3058        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3059        ;;
3060    esac],
3061   [with_build_time_tools=])
3062
3063 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3064 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3065 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3066 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3067 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3068 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3069
3070 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3071 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3072 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3073 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3074 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3075 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3076 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3077 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3078 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3079 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3080 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3081
3082 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3083
3084 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3085 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3086 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3087 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3088 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3089                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3090                 c++)
3091 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3092                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3093                 c++)
3094 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3095 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3096 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3097                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3098 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3099                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3100 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3101                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3102 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3103 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3104 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3105 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3106 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3107 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3108 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3109 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3110
3111 AC_SUBST(FLAGS_FOR_TARGET)
3112 AC_SUBST(RAW_CXX_FOR_TARGET)
3113
3114 # Certain tools may need extra flags.
3115 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3116 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3117 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3118
3119 # When building target libraries, except in a Canadian cross, we use
3120 # the same toolchain as the compiler we just built.
3121 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3122 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3123 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3124 if test $host = $build; then
3125   case " $configdirs " in
3126     *" gcc "*)
3127       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3128       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3129       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3130       ;;
3131   esac
3132 fi
3133
3134 AC_SUBST(COMPILER_AS_FOR_TARGET)
3135 AC_SUBST(COMPILER_LD_FOR_TARGET)
3136 AC_SUBST(COMPILER_NM_FOR_TARGET)
3137
3138 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3139 AC_ARG_ENABLE(maintainer-mode,
3140 [AS_HELP_STRING([--enable-maintainer-mode],
3141                 [enable make rules and dependencies not useful
3142                  (and sometimes confusing) to the casual installer])],
3143       USE_MAINTAINER_MODE=$enableval,
3144       USE_MAINTAINER_MODE=no)
3145 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3146 AC_SUBST(MAINTAINER_MODE_TRUE)
3147 AC_SUBST(MAINTAINER_MODE_FALSE)
3148 if test "$USE_MAINTAINER_MODE" = yes; then
3149   MAINTAINER_MODE_TRUE=
3150   MAINTAINER_MODE_FALSE='#'
3151 else
3152   MAINTAINER_MODE_TRUE='#'
3153   MAINTAINER_MODE_FALSE=
3154 fi
3155 MAINT=$MAINTAINER_MODE_TRUE
3156 AC_SUBST(MAINT)dnl
3157
3158 # ---------------------
3159 # GCC bootstrap support
3160 # ---------------------
3161
3162 # Stage specific cflags for build.
3163 stage1_cflags="-g"
3164 case $build in
3165   vax-*-*)
3166     case ${GCC} in
3167       yes) stage1_cflags="-g -Wa,-J" ;;
3168       *) stage1_cflags="-g -J" ;;
3169     esac ;;
3170 esac
3171
3172 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3173 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3174   saved_CFLAGS="$CFLAGS"
3175
3176   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3177   CFLAGS="$CFLAGS -fkeep-inline-functions"
3178   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3179   AC_TRY_COMPILE([
3180 #if (__GNUC__ < 3) \
3181     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3182                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3183 #error http://gcc.gnu.org/PR29382
3184 #endif
3185     ],,
3186     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3187     [AC_MSG_RESULT([no])])
3188
3189   CFLAGS="$saved_CFLAGS"
3190 fi
3191
3192 AC_SUBST(stage1_cflags)
3193
3194 # Enable --enable-checking in stage1 of the compiler.
3195 AC_ARG_ENABLE(stage1-checking,
3196 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3197                 [choose additional checking for stage1 of the compiler])],
3198 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3199 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3200   stage1_checking=--enable-checking=yes,types
3201 else
3202   stage1_checking=--enable-checking=$enable_checking,types
3203 fi])
3204 AC_SUBST(stage1_checking)
3205
3206 # Enable -Werror in bootstrap stage2 and later.
3207 AC_ARG_ENABLE(werror,
3208 [AS_HELP_STRING([--enable-werror],
3209                 [enable -Werror in bootstrap stage2 and later])], [],
3210 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3211   enable_werror=yes
3212 else
3213   enable_werror=no
3214 fi])
3215 case ${enable_werror} in
3216   yes) stage2_werror_flag="--enable-werror-always" ;;
3217   *) stage2_werror_flag="" ;;
3218 esac
3219 AC_SUBST(stage2_werror_flag)
3220
3221 # If using ENABLE_BUILD_POSTSTAGE1_WITH_CXX, pass
3222 # --enable-build-with-cxx after stage1.
3223 if test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
3224   POSTSTAGE1_CONFIGURE_FLAGS=--enable-build-with-cxx
3225 else
3226   POSTSTAGE1_CONFIGURE_FLAGS=
3227 fi
3228 AC_SUBST(POSTSTAGE1_CONFIGURE_FLAGS)
3229
3230 # Specify what files to not compare during bootstrap.
3231
3232 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3233 case "$target" in
3234   hppa*64*-*-hpux*) ;;
3235   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3236 esac
3237 case " $configdirs " in
3238 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3239 esac
3240 AC_SUBST(compare_exclusions)
3241
3242 AC_CONFIG_FILES([Makefile],
3243   [sed "$extrasub_build" Makefile |
3244    sed "$extrasub_host" |
3245    sed "$extrasub_target" > mf$$
3246    mv -f mf$$ Makefile],
3247   [extrasub_build="$extrasub_build"
3248    extrasub_host="$extrasub_host"
3249    extrasub_target="$extrasub_target"])
3250 AC_OUTPUT