OSDN Git Service

4cace763fa4152e45945010cb412294e9e0d5f6a
[pf3gnuchains/gcc-fork.git] / config / dfp.m4
1 dnl @synopsis GCC_AC_ENABLE_DECIMAL_FLOAT([target triplet])
2 dnl
3 dnl Enable C extension for decimal float if target supports it.
4 dnl
5 dnl @author Andreas Krebbel  <Andreas.Krebbel@de.ibm.com>
6
7 AC_DEFUN([GCC_AC_ENABLE_DECIMAL_FLOAT],
8 [
9 AC_ARG_ENABLE(decimal-float,
10 [  --enable-decimal-float={no,yes,bid,dpd}
11                         enable decimal float extension to C.  Selecting 'bid'
12                         or 'dpd' choses which decimal floating point format
13                         to use],
14 [
15   case $enable_decimal_float in
16     yes | no | bid | dpd) ;;
17     *) AC_MSG_ERROR(['$enable_decimal_float' is an invalid value for --enable-decimal-float.
18 Valid choices are 'yes', 'bid', 'dpd', and 'no'.]) ;;
19   esac
20 ],
21 [
22   case $1 in
23     powerpc*-*-linux* | i?86*-*-linux* | x86_64*-*-linux* | s390*-*-linux*)
24       enable_decimal_float=yes
25       ;;
26     *)
27       AC_MSG_WARN(decimal float is not supported for this target, ignored)
28       enable_decimal_float=no
29       ;;
30   esac
31 ])
32
33 # x86's use BID format instead of DPD
34 case x$enable_decimal_float in
35   xyes)
36     case $1 in
37       i?86*-*-* | x86_64*-*-*)
38         enable_decimal_float=bid
39         ;;
40       *)
41         enable_decimal_float=dpd
42         ;;
43     esac
44     ;;
45   xno)
46     # ENABLE_DECIMAL_FLOAT is set to 0. But we have to have proper
47     # dependency on libdecnumber.
48     enable_decimal_float=dpd
49     ;;
50 esac
51 AC_SUBST(enable_decimal_float)
52
53 ])