boehm-gc/configure.in

   1 dnl Process this file with autoconf to produce configure.
   2
   3 AC_INIT(gcj_mlc.c)
   4
   5 BOEHM_CONFIGURE(.)
   6
   7 AM_PROG_LIBTOOL
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                           configuring with a cross compiler])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 AM_MAINTAINER_MODE
  17 # automake wants to see AC_EXEEXT.  But we don't need it.  And having
  18 # it is actually a problem, because the compiler we're passed can't
  19 # necessarily do a full link.  So we fool automake here.
  20 if false; then
  21   # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
  22   # to nothing, so nothing would remain between `then' and `fi' if it
  23   # were not for the `:' below.
  24   :
  25   AC_EXEEXT
  26 fi
  27
  28 AC_MSG_CHECKING([for thread model used by GCC])
  29 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
  30 AC_MSG_RESULT([$THREADS])
  31
  32 INCLUDES=-I${srcdir}/include
  33 THREADLIBS=
  34 case "$THREADS" in
  35  no | none | single)
  36     THREADS=none
  37     ;;
  38  posix | pthreads)
  39     THREADS=posix
  40     THREADLIBS=-lpthread
  41     case "$host" in
  42      *-*-linux*)
  43         AC_DEFINE(LINUX_THREADS)
  44         AC_DEFINE(_REENTRANT)
  45         ;;
  46      *-*-freebsd*)
  47         AC_MSG_WARN("FreeBSD does not yet fully support threads with Boehm GC.")
  48         AC_DEFINE(FREEBSD_THREADS)
  49         INCLUDES="$INCLUDES -pthread"
  50         THREADLIBS=-pthread
  51         ;;
  52      *-*-solaris*)
  53         AC_DEFINE(SOLARIS_THREADS)
  54         AC_DEFINE(_SOLARIS_PTHREADS)
  55         ;;
  56      *-*-irix*)
  57         AC_DEFINE(IRIX_THREADS)
  58         ;;
  59      *-*-cygwin*)
  60         THREADLIBS=
  61         ;;
  62     esac
  63     ;;
  64  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
  65     AC_MSG_ERROR(thread package $THREADS not yet supported)
  66     ;;
  67  *)
  68     AC_MSG_ERROR($THREADS is an unknown thread package)
  69     ;;
  70 esac
  71 AC_SUBST(THREADLIBS)
  72
  73 AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
  74 AC_SUBST(EXTRA_TEST_LIBS)
  75
  76 AC_ARG_ENABLE(java-gc,
  77 changequote(<<,>>)dnl
  78 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
  79 changequote([,])
  80   GC=$enableval,
  81   GC=boehm)
  82 target_all=
  83 if test "$GC" = "boehm"; then
  84    target_all=libgcjgc.la
  85 fi
  86 AC_SUBST(target_all)
  87
  88 dnl If the target is an eCos system, use the appropriate eCos
  89 dnl I/O routines.
  90 dnl FIXME: this should not be a local option but a global target
  91 dnl system; at present there is no eCos target.
  92 TARGET_ECOS="no"
  93 AC_ARG_WITH(ecos,
  94 [  --with-ecos             enable runtime eCos target support],
  95 TARGET_ECOS="$with_ecos"
  96 )
  97
  98 addobjs=
  99 CXXINCLUDES=
 100 case "$TARGET_ECOS" in
 101    no)
 102       ;;
 103    *)
 104       AC_DEFINE(ECOS)
 105       CXXINCLUDES="-I${TARGET_ECOS}/include"
 106       addobjs="$addobjs ecos.lo"
 107       ;;
 108 esac
 109 AC_SUBST(CXX)
 110
 111 AC_SUBST(INCLUDES)
 112 AC_SUBST(CXXINCLUDES)
 113
 114 machdep=
 115 case "$host" in
 116  alpha*-*-*)
 117     machdep="alpha_mach_dep.lo"
 118     ;;
 119  mipstx39-*-elf*)
 120     machdep="mips_ultrix_mach_dep.lo"
 121     AC_DEFINE(STACKBASE, __stackbase)
 122     AC_DEFINE(DATASTART_IS_ETEXT)
 123     ;;
 124  mips-dec-ultrix*)
 125     machdep="mips_ultrix_mach-dep.lo"
 126     ;;
 127  mips-*-*)
 128     machdep="mips_sgi_mach_dep.lo"
 129     AC_DEFINE(NO_EXECUTE_PERMISSION)
 130     ;;
 131  sparc-sun-solaris2.3*)
 132     AC_DEFINE(SUNOS53_SHARED_LIB)
 133     ;;
 134 esac
 135 if test x"$machdep" = x; then
 136    machdep="mach_dep.lo"
 137 fi
 138 addobjs="$addobjs $machdep"
 139 AC_SUBST(addobjs)
 140
 141 dnl As of 4.13a2, the collector will not properly work on Solaris when
 142 dnl built with gcc and -O.  So we remove -O in the appropriate case.
 143 case "$host" in
 144  sparc-sun-solaris2*)
 145     if test "$GCC" = yes; then
 146        new_CFLAGS=
 147        for i in $CFLAGS; do
 148           case "$i" in
 149            -O*)
 150               ;;
 151            *)
 152               new_CFLAGS="$new_CFLAGS $i"
 153               ;;
 154           esac
 155        done
 156        CFLAGS="$new_CFLAGS"
 157     fi
 158     ;;
 159 esac
 160
 161 dnl We need to override the top-level CFLAGS.  This is how we do it.
 162 MY_CFLAGS="$CFLAGS"
 163 AC_SUBST(MY_CFLAGS)
 164
 165 dnl Define a few things to retarget the library towards
 166 dnl embedded Java.
 167 AC_DEFINE(SILENT)
 168 AC_DEFINE(NO_SIGNALS)
 169 AC_DEFINE(JAVA_FINALIZATION)
 170 AC_DEFINE(GC_GCJ_SUPPORT)
 171
 172 dnl This is something of a hack.  When cross-compiling we turn off
 173 dnl some functionality.  We also enable the "small" configuration.
 174 dnl These is only correct when targetting an embedded system.  FIXME.
 175 if test -n "${with_cross_host}"; then
 176    AC_DEFINE(NO_SIGSET)
 177    AC_DEFINE(NO_CLOCK)
 178    AC_DEFINE(SMALL_CONFIG)
 179    AC_DEFINE(NO_DEBUGGING)
 180 fi
 181
 182 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 183
 184 if test "${multilib}" = "yes"; then
 185   multilib_arg="--enable-multilib"
 186 else
 187   multilib_arg=
 188 fi
 189
 190 AC_OUTPUT(Makefile,
 191 [
 192 dnl Put all the -D options in a file.  These are required before
 193 dnl boehm-config.h can be included.  This is a huge hack brought
 194 dnl about by overall poor structuring of this entire library.
 195 echo "$DEFS" > boehm-cflags
 196
 197 if test -n "$CONFIG_FILES"; then
 198   ac_file=Makefile . ${boehm_gc_basedir}/../config-ml.in
 199 fi],
 200 srcdir=${srcdir}
 201 host=${host}
 202 target=${target}
 203 with_multisubdir=${with_multisubdir}
 204 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 205 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 206 boehm_gc_basedir=${boehm_gc_basedir}
 207 CC="${CC}"
 208 DEFS="$DEFS"
 209 )