OSDN Git Service

ce6b7250c7023adcb269510f3dee5ffa3c4eeaf6
[pf3gnuchains/gcc-fork.git] / boehm-gc / configure.in
1 # Copyright (c) 1999-2001 by Red Hat, Inc. All rights reserved.
2
3 # THIS MATERIAL IS PROVIDED AS IS, WITH ABSOLUTELY NO WARRANTY EXPRESSED
4 # OR IMPLIED.  ANY USE IS AT YOUR OWN RISK.
5
6 # Permission is hereby granted to use or copy this program
7 # for any purpose,  provided the above notices are retained on all copies.
8 # Permission to modify the code and to distribute modified code is granted,
9 # provided the above notices are retained, and a notice that the code was
10 # modified is included with the above copyright notice.
11 #
12 # Original author: Tom Tromey
13
14 dnl Process this file with autoconf to produce configure.
15
16 AC_INIT(gcj_mlc.c)
17
18 dnl Can't be done in GC_CONFIGURE because that confuses automake. 
19 AC_CONFIG_AUX_DIR(.)
20
21 GC_CONFIGURE(.)
22
23 AM_PROG_LIBTOOL
24
25 dnl We use these options to decide which functions to include.
26 AC_ARG_WITH(target-subdir,
27 [  --with-target-subdir=SUBDIR
28                           configuring with a cross compiler])
29 AC_ARG_WITH(cross-host,
30 [  --with-cross-host=HOST  configuring with a cross compiler])
31
32 AM_MAINTAINER_MODE
33 # automake wants to see AC_EXEEXT.  But we don't need it.  And having
34 # it is actually a problem, because the compiler we're passed can't
35 # necessarily do a full link.  So we fool automake here.
36 if false; then
37   # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
38   # to nothing, so nothing would remain between `then' and `fi' if it
39   # were not for the `:' below.
40   :
41   AC_EXEEXT
42 fi
43
44 AC_MSG_CHECKING([for thread model used by GCC])
45 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
46 if test -z "$THREADS"; then
47    THREADS=no
48 fi
49 AC_MSG_RESULT([$THREADS])
50
51 AC_ARG_ENABLE(parallel-mark,
52 [  --enable-parallel-mark       parallelize marking and free list construction],
53    [case "$THREADS" in
54       no | none | single)
55         AC_MSG_ERROR([Parallel mark requires --enable-threads=x spec])
56         ;;
57     esac]
58 )
59
60 INCLUDES=-I${srcdir}/include
61 THREADLIBS=
62 case "$THREADS" in
63  no | none | single)
64     THREADS=none
65     ;;
66  posix | pthreads)
67     THREADS=posix
68     THREADLIBS=-lpthread
69     case "$host" in
70      x86-*-linux* | ia64-*-linux* | i586-*-linux* | i686-*-linux*)
71         AC_DEFINE(GC_LINUX_THREADS)
72         AC_DEFINE(_REENTRANT)
73         if test "${enable_parallel_mark}"; then
74           AC_DEFINE(PARALLEL_MARK)
75         fi
76         AC_DEFINE(THREAD_LOCAL_ALLOC)
77         ;;
78      *-*-linux*)
79         AC_DEFINE(GC_LINUX_THREADS)
80         AC_DEFINE(_REENTRANT)
81         ;;
82      *-*-hpux*)
83         AC_MSG_WARN("Only HP/UX 11 threads are supported.")
84         AC_DEFINE(GC_HPUX_THREADS)
85         AC_DEFINE(_POSIX_C_SOURCE,199506L)
86         if test "${enable_parallel_mark}" = yes; then
87           AC_DEFINE(PARALLEL_MARK)
88         fi
89         AC_DEFINE(THREAD_LOCAL_ALLOC)
90         THREADLIBS="-lpthread -lrt"
91         ;;
92      *-*-freebsd*)
93         AC_MSG_WARN("FreeBSD does not yet fully support threads with Boehm GC.")
94         AC_DEFINE(GC_FREEBSD_THREADS)
95         INCLUDES="$INCLUDES -pthread"
96         THREADLIBS=-pthread
97         ;;
98      *-*-solaris*)
99         AC_DEFINE(GC_SOLARIS_THREADS)
100         AC_DEFINE(GC_SOLARIS_PTHREADS)
101         ;;
102      *-*-irix*)
103         AC_DEFINE(GC_IRIX_THREADS)
104         ;;
105      *-*-cygwin*)
106         THREADLIBS=
107         ;;
108     esac
109     ;;
110  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
111     AC_MSG_ERROR(thread package $THREADS not yet supported)
112     ;;
113  *)
114     AC_MSG_ERROR($THREADS is an unknown thread package)
115     ;;
116 esac
117 AC_SUBST(THREADLIBS)
118
119 AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
120 AC_SUBST(EXTRA_TEST_LIBS)
121
122 target_all=libgcjgc.la
123 AC_SUBST(target_all)
124
125 dnl If the target is an eCos system, use the appropriate eCos
126 dnl I/O routines.
127 dnl FIXME: this should not be a local option but a global target
128 dnl system; at present there is no eCos target.
129 TARGET_ECOS="no"
130 AC_ARG_WITH(ecos,
131 [  --with-ecos             enable runtime eCos target support],
132 TARGET_ECOS="$with_ecos"
133 )
134
135 addobjs=
136 CXXINCLUDES=
137 case "$TARGET_ECOS" in
138    no)
139       ;;
140    *)
141       AC_DEFINE(ECOS)
142       CXXINCLUDES="-I${TARGET_ECOS}/include"
143       addobjs="$addobjs ecos.lo"
144       ;;
145 esac
146 AC_SUBST(CXX)
147
148 AC_SUBST(INCLUDES)
149 AC_SUBST(CXXINCLUDES)
150
151 machdep=
152 case "$host" in
153  alpha*-*-*)
154     machdep="alpha_mach_dep.lo"
155     ;;
156  alpha-*-openbsd*)
157     if test x"${ac_cv_lib_dl_dlopen}" != xyes ; then
158        AC_MSG_WARN(OpenBSD/Alpha without dlopen(). Shared library support is disabled)
159        AM_DISABLE_SHARED
160     fi
161     ;;
162  i?86-*-solaris2.[[89]]*)
163     AC_DEFINE(SOLARIS25_PROC_VDB_BUG_FIXED)
164     ;;
165  mipstx39-*-elf*)
166     machdep="mips_ultrix_mach_dep.lo"
167     AC_DEFINE(STACKBASE, __stackbase)
168     AC_DEFINE(DATASTART_IS_ETEXT)
169     ;;
170  mips-dec-ultrix*)
171     machdep="mips_ultrix_mach-dep.lo"
172     ;;
173  mips-*-*)
174     machdep="mips_sgi_mach_dep.lo"
175     AC_DEFINE(NO_EXECUTE_PERMISSION)
176     ;;
177  sparc-sun-solaris2.3*)
178     AC_DEFINE(SUNOS53_SHARED_LIB)
179     ;;
180  ia64-*-hpux*)
181     machdep="mach_dep.lo ia64_save_regs_in_stack.lo"
182     ;;
183 esac
184 if test x"$machdep" = x; then
185    machdep="mach_dep.lo"
186 fi
187 addobjs="$addobjs $machdep"
188 AC_SUBST(addobjs)
189
190 dnl As of 4.13a2, the collector will not properly work on Solaris when
191 dnl built with gcc and -O.  So we remove -O in the appropriate case.
192 case "$host" in
193  sparc-sun-solaris2*)
194     if test "$GCC" = yes; then
195        new_CFLAGS=
196        for i in $CFLAGS; do
197           case "$i" in
198            -O*)
199               ;;
200            *)
201               new_CFLAGS="$new_CFLAGS $i"
202               ;;
203           esac
204        done
205        CFLAGS="$new_CFLAGS"
206     fi
207     ;;
208 esac
209
210 dnl We need to override the top-level CFLAGS.  This is how we do it.
211 MY_CFLAGS="$CFLAGS"
212 AC_SUBST(MY_CFLAGS)
213
214 dnl Include defines that have become de facto standard.
215 dnl ALL_INTERIOR_POINTERS can be overridden in startup code.
216 AC_DEFINE(SILENT)
217 AC_DEFINE(NO_SIGNALS)
218 AC_DEFINE(NO_EXECUTE_PERMISSION)
219 AC_DEFINE(ALL_INTERIOR_POINTERS)
220
221 dnl By default, make the library as general as possible.
222 AC_DEFINE(JAVA_FINALIZATION)
223 AC_DEFINE(GC_GCJ_SUPPORT)
224 AC_DEFINE(ATOMIC_UNCOLLECTABLE)
225
226 dnl This is something of a hack.  When cross-compiling we turn off
227 dnl some functionality.  We also enable the "small" configuration.
228 dnl These is only correct when targetting an embedded system.  FIXME.
229 if test -n "${with_cross_host}"; then
230    AC_DEFINE(NO_SIGSET)
231    AC_DEFINE(NO_CLOCK)
232    AC_DEFINE(SMALL_CONFIG)
233    AC_DEFINE(NO_DEBUGGING)
234 fi
235
236 AC_ARG_ENABLE(full-debug,
237 [  --enable-full-debug  include full support for pointer backtracing etc.],
238 [ if test "$enable_full_debug" = "yes"; then
239     AC_MSG_WARN("Must define GC_DEBUG and use debug alloc. in clients.")
240     AC_DEFINE(KEEP_BACK_PTRS)
241     AC_DEFINE(DBG_HDRS_ALL)
242     case $host in
243       x86-*-linux* | i586-*-linux* | i686-*-linux* )
244         AC_MSG_WARN("Client must not use -fomit-frame-pointer.")
245         AC_DEFINE(SAVE_CALL_COUNT, 8)
246       ;;
247     esac ]
248   fi)
249
250 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
251
252 if test "${multilib}" = "yes"; then
253   multilib_arg="--enable-multilib"
254 else
255   multilib_arg=
256 fi
257
258 AC_OUTPUT(Makefile include/Makefile, [
259 dnl Put all the -D options in a file.
260 echo "$DEFS" > boehm-cflags
261
262 if test -n "$CONFIG_FILES"; then
263   ac_file=Makefile . ${gc_basedir}/../config-ml.in
264 fi],
265 srcdir=${srcdir}
266 host=${host}
267 target=${target}
268 with_multisubdir=${with_multisubdir}
269 ac_configure_args="${multilib_arg} ${ac_configure_args}"
270 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
271 gc_basedir=${gc_basedir}
272 CC="${CC}"
273 DEFS="$DEFS"
274 )