boehm-gc/configure.in

   1 # Copyright (c) 1999-2001 by Red Hat, Inc. All rights reserved.
   2 #
   3 # THIS MATERIAL IS PROVIDED AS IS, WITH ABSOLUTELY NO WARRANTY EXPRESSED
   4 # OR IMPLIED.  ANY USE IS AT YOUR OWN RISK.
   5 #
   6 # Permission is hereby granted to use or copy this program
   7 # for any purpose,  provided the above notices are retained on all copies.
   8 # Permission to modify the code and to distribute modified code is granted,
   9 # provided the above notices are retained, and a notice that the code was
  10 # modified is included with the above copyright notice.
  11 #
  12 # Original author: Tom Tromey
  13
  14 dnl Process this file with autoconf to produce configure.
  15
  16 AC_INIT(gcj_mlc.c)
  17
  18 dnl Can't be done in GC_CONFIGURE because that confuses automake.
  19 AC_CONFIG_AUX_DIR(.)
  20
  21 GC_CONFIGURE(.)
  22
  23 AM_PROG_LIBTOOL
  24
  25 dnl We use these options to decide which functions to include.
  26 AC_ARG_WITH(target-subdir,
  27 [  --with-target-subdir=SUBDIR
  28                           configuring with a cross compiler])
  29 AC_ARG_WITH(cross-host,
  30 [  --with-cross-host=HOST  configuring with a cross compiler])
  31
  32 AM_MAINTAINER_MODE
  33 # automake wants to see AC_EXEEXT.  But we don't need it.  And having
  34 # it is actually a problem, because the compiler we're passed can't
  35 # necessarily do a full link.  So we fool automake here.
  36 if false; then
  37   # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
  38   # to nothing, so nothing would remain between `then' and `fi' if it
  39   # were not for the `:' below.
  40   :
  41   AC_EXEEXT
  42 fi
  43
  44 AC_MSG_CHECKING([for thread model used by GCC])
  45 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
  46 if test -z "$THREADS"; then
  47    THREADS=no
  48 fi
  49 AC_MSG_RESULT([$THREADS])
  50
  51 AC_ARG_ENABLE(parallel-mark,
  52 [  --enable-parallel-mark       parallelize marking and free list construction],
  53    [case "$THREADS" in
  54       no | none | single)
  55         AC_MSG_ERROR([Parallel mark requires --enable-threads=x spec])
  56         ;;
  57     esac]
  58 )
  59
  60 INCLUDES=-I${srcdir}/include
  61 THREADLIBS=
  62 case "$THREADS" in
  63  no | none | single)
  64     THREADS=none
  65     ;;
  66  posix | pthreads)
  67     THREADS=posix
  68     THREADLIBS=-lpthread
  69     case "$host" in
  70      x86-*-linux* | ia64-*-linux* | i586-*-linux* | i686-*-linux*)
  71         AC_DEFINE(GC_LINUX_THREADS)
  72         AC_DEFINE(_REENTRANT)
  73         if test "${enable_parallel_mark}"; then
  74           AC_DEFINE(PARALLEL_MARK)
  75         fi
  76         AC_DEFINE(THREAD_LOCAL_ALLOC)
  77         ;;
  78      *-*-linux*)
  79         AC_DEFINE(GC_LINUX_THREADS)
  80         AC_DEFINE(_REENTRANT)
  81         ;;
  82      *-*-hpux*)
  83         AC_MSG_WARN("Only HP/UX 11 threads are supported.")
  84         AC_DEFINE(GC_HPUX_THREADS)
  85         AC_DEFINE(_POSIX_C_SOURCE,199506L)
  86         if test "${enable_parallel_mark}" = yes; then
  87           AC_DEFINE(PARALLEL_MARK)
  88         fi
  89         AC_DEFINE(THREAD_LOCAL_ALLOC)
  90         THREADLIBS="-lpthread -lrt"
  91         ;;
  92      *-*-freebsd*)
  93         AC_MSG_WARN("FreeBSD does not yet fully support threads with Boehm GC.")
  94         AC_DEFINE(FREEBSD_THREADS)
  95         INCLUDES="$INCLUDES -pthread"
  96         THREADLIBS=-pthread
  97         ;;
  98      *-*-solaris*)
  99         AC_DEFINE(GC_SOLARIS_THREADS)
 100         AC_DEFINE(GC_SOLARIS_PTHREADS)
 101         ;;
 102      *-*-irix*)
 103         AC_DEFINE(GC_IRIX_THREADS)
 104         ;;
 105      *-*-cygwin*)
 106         THREADLIBS=
 107         ;;
 108     esac
 109     ;;
 110  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 111     AC_MSG_ERROR(thread package $THREADS not yet supported)
 112     ;;
 113  *)
 114     AC_MSG_ERROR($THREADS is an unknown thread package)
 115     ;;
 116 esac
 117 AC_SUBST(THREADLIBS)
 118
 119 AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
 120 AC_SUBST(EXTRA_TEST_LIBS)
 121
 122 target_all=libgcjgc.la
 123 AC_SUBST(target_all)
 124
 125 dnl If the target is an eCos system, use the appropriate eCos
 126 dnl I/O routines.
 127 dnl FIXME: this should not be a local option but a global target
 128 dnl system; at present there is no eCos target.
 129 TARGET_ECOS="no"
 130 AC_ARG_WITH(ecos,
 131 [  --with-ecos             enable runtime eCos target support],
 132 TARGET_ECOS="$with_ecos"
 133 )
 134
 135 addobjs=
 136 CXXINCLUDES=
 137 case "$TARGET_ECOS" in
 138    no)
 139       ;;
 140    *)
 141       AC_DEFINE(ECOS)
 142       CXXINCLUDES="-I${TARGET_ECOS}/include"
 143       addobjs="$addobjs ecos.lo"
 144       ;;
 145 esac
 146 AC_SUBST(CXX)
 147
 148 AC_SUBST(INCLUDES)
 149 AC_SUBST(CXXINCLUDES)
 150
 151 machdep=
 152 case "$host" in
 153  alpha*-*-*)
 154     machdep="alpha_mach_dep.lo"
 155     ;;
 156  mipstx39-*-elf*)
 157     machdep="mips_ultrix_mach_dep.lo"
 158     AC_DEFINE(STACKBASE, __stackbase)
 159     AC_DEFINE(DATASTART_IS_ETEXT)
 160     ;;
 161  mips-dec-ultrix*)
 162     machdep="mips_ultrix_mach-dep.lo"
 163     ;;
 164  mips-*-*)
 165     machdep="mips_sgi_mach_dep.lo"
 166     AC_DEFINE(NO_EXECUTE_PERMISSION)
 167     ;;
 168  sparc-sun-solaris2.3*)
 169     AC_DEFINE(SUNOS53_SHARED_LIB)
 170     ;;
 171 esac
 172 if test x"$machdep" = x; then
 173    machdep="mach_dep.lo"
 174 fi
 175 addobjs="$addobjs $machdep"
 176 AC_SUBST(addobjs)
 177
 178 dnl As of 4.13a2, the collector will not properly work on Solaris when
 179 dnl built with gcc and -O.  So we remove -O in the appropriate case.
 180 case "$host" in
 181  sparc-sun-solaris2*)
 182     if test "$GCC" = yes; then
 183        new_CFLAGS=
 184        for i in $CFLAGS; do
 185           case "$i" in
 186            -O*)
 187               ;;
 188            *)
 189               new_CFLAGS="$new_CFLAGS $i"
 190               ;;
 191           esac
 192        done
 193        CFLAGS="$new_CFLAGS"
 194     fi
 195     ;;
 196 esac
 197
 198 dnl We need to override the top-level CFLAGS.  This is how we do it.
 199 MY_CFLAGS="$CFLAGS"
 200 AC_SUBST(MY_CFLAGS)
 201
 202 dnl Include defines that have become de facto standard.
 203 dnl ALL_INTERIOR_POINTERS can be overridden in startup code.
 204 AC_DEFINE(SILENT)
 205 AC_DEFINE(NO_SIGNALS)
 206 AC_DEFINE(NO_EXECUTE_PERMISSION)
 207 AC_DEFINE(ALL_INTERIOR_POINTERS)
 208
 209 dnl By default, make the library as general as possible.
 210 AC_DEFINE(JAVA_FINALIZATION)
 211 AC_DEFINE(GC_GCJ_SUPPORT)
 212 AC_DEFINE(ATOMIC_UNCOLLECTABLE)
 213
 214 dnl This is something of a hack.  When cross-compiling we turn off
 215 dnl some functionality.  We also enable the "small" configuration.
 216 dnl These is only correct when targetting an embedded system.  FIXME.
 217 if test -n "${with_cross_host}"; then
 218    AC_DEFINE(NO_SIGSET)
 219    AC_DEFINE(NO_CLOCK)
 220    AC_DEFINE(SMALL_CONFIG)
 221    AC_DEFINE(NO_DEBUGGING)
 222 fi
 223
 224 AC_ARG_ENABLE(full-debug,
 225 [  --enable-full-debug  include full support for pointer backtracing etc.],
 226 [ if test "$enable_full_debug" = "yes"; then
 227     AC_MSG_WARN("Must define GC_DEBUG and use debug alloc. in clients.")
 228     AC_DEFINE(KEEP_BACK_PTRS)
 229     AC_DEFINE(DBG_HDRS_ALL)
 230     case $host in
 231       x86-*-linux* | i586-*-linux* | i686-*-linux* )
 232         AC_MSG_WARN("Client must not use -fomit-frame-pointer.")
 233         AC_DEFINE(SAVE_CALL_COUNT, 8)
 234       ;;
 235     esac ]
 236   fi)
 237
 238 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 239
 240 if test "${multilib}" = "yes"; then
 241   multilib_arg="--enable-multilib"
 242 else
 243   multilib_arg=
 244 fi
 245
 246 AC_OUTPUT(Makefile include/Makefile, [
 247 dnl Put all the -D options in a file.
 248 echo "$DEFS" > boehm-cflags
 249
 250 if test -n "$CONFIG_FILES"; then
 251   ac_file=Makefile . ${gc_basedir}/../config-ml.in
 252 fi],
 253 srcdir=${srcdir}
 254 host=${host}
 255 target=${target}
 256 with_multisubdir=${with_multisubdir}
 257 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 258 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 259 gc_basedir=${gc_basedir}
 260 CC="${CC}"
 261 DEFS="$DEFS"
 262 )