boehm-gc/configure.in

   1 # Copyright (c) 1999, 2000, 2001, 2002, 2003 by Red Hat, Inc. All rights reserved.
   2 #
   3 # THIS MATERIAL IS PROVIDED AS IS, WITH ABSOLUTELY NO WARRANTY EXPRESSED
   4 # OR IMPLIED.  ANY USE IS AT YOUR OWN RISK.
   5 #
   6 # Permission is hereby granted to use or copy this program
   7 # for any purpose,  provided the above notices are retained on all copies.
   8 # Permission to modify the code and to distribute modified code is granted,
   9 # provided the above notices are retained, and a notice that the code was
  10 # modified is included with the above copyright notice.
  11 #
  12 # Original author: Tom Tromey
  13
  14 dnl Process this file with autoconf to produce configure.
  15
  16 AC_INIT(gcj_mlc.c)
  17
  18 # This works around the fact that libtool configuration may change LD
  19 # for this particular configuration, but some shells, instead of
  20 # keeping the changes in LD private, export them just because LD is
  21 # exported.
  22 ORIGINAL_LD_FOR_MULTILIBS=$LD
  23
  24 dnl Can't be done in GC_CONFIGURE because that confuses automake.
  25 AC_CONFIG_AUX_DIR(.)
  26
  27 GC_CONFIGURE(.)
  28
  29 AM_PROG_LIBTOOL
  30
  31 dnl We use these options to decide which functions to include.
  32 AC_ARG_WITH(target-subdir,
  33 [  --with-target-subdir=SUBDIR
  34                           configuring with a cross compiler])
  35 AC_ARG_WITH(cross-host,
  36 [  --with-cross-host=HOST  configuring with a cross compiler])
  37
  38 AM_MAINTAINER_MODE
  39 # automake wants to see AC_EXEEXT.  But we don't need it.  And having
  40 # it is actually a problem, because the compiler we're passed can't
  41 # necessarily do a full link.  So we fool automake here.
  42 if false; then
  43   # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
  44   # to nothing, so nothing would remain between `then' and `fi' if it
  45   # were not for the `:' below.
  46   :
  47   AC_EXEEXT
  48 fi
  49
  50 AC_MSG_CHECKING([for thread model used by GCC])
  51 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
  52 if test -z "$THREADS"; then
  53    THREADS=no
  54 fi
  55 AC_MSG_RESULT([$THREADS])
  56
  57 AC_ARG_ENABLE(parallel-mark,
  58 [  --enable-parallel-mark       parallelize marking and free list construction],
  59    [case "$THREADS" in
  60       no | none | single)
  61         AC_MSG_ERROR([Parallel mark requires --enable-threads=x spec])
  62         ;;
  63     esac]
  64 )
  65
  66 INCLUDES=-I${srcdir}/include
  67 THREADLIBS=
  68 case "$THREADS" in
  69  no | none | single)
  70     THREADS=none
  71     ;;
  72  posix | pthreads)
  73     THREADS=posix
  74     THREADLIBS=-lpthread
  75     case "$host" in
  76      x86-*-linux* | ia64-*-linux* | i586-*-linux* | i686-*-linux* | x86_64-*-linux* )
  77         AC_DEFINE(GC_LINUX_THREADS)
  78         AC_DEFINE(_REENTRANT)
  79         if test "${enable_parallel_mark}"; then
  80           AC_DEFINE(PARALLEL_MARK)
  81         fi
  82         AC_DEFINE(THREAD_LOCAL_ALLOC)
  83         ;;
  84      *-*-linux*)
  85         AC_DEFINE(GC_LINUX_THREADS)
  86         AC_DEFINE(_REENTRANT)
  87         ;;
  88      *-*-hpux*)
  89         AC_MSG_WARN("Only HP/UX 11 threads are supported.")
  90         AC_DEFINE(GC_HPUX_THREADS)
  91         AC_DEFINE(_POSIX_C_SOURCE,199506L)
  92         if test "${enable_parallel_mark}" = yes; then
  93           AC_DEFINE(PARALLEL_MARK)
  94         fi
  95         AC_DEFINE(THREAD_LOCAL_ALLOC)
  96         THREADLIBS="-lpthread -lrt"
  97         ;;
  98      *-*-freebsd*)
  99         AC_MSG_WARN("FreeBSD does not yet fully support threads with Boehm GC.")
 100         AC_DEFINE(GC_FREEBSD_THREADS)
 101         INCLUDES="$INCLUDES -pthread"
 102         THREADLIBS=-pthread
 103         ;;
 104      *-*-solaris*)
 105         AC_DEFINE(GC_SOLARIS_THREADS)
 106         AC_DEFINE(GC_SOLARIS_PTHREADS)
 107         ;;
 108      *-*-irix*)
 109         AC_DEFINE(GC_IRIX_THREADS)
 110         ;;
 111      *-*-cygwin*)
 112         THREADLIBS=
 113         ;;
 114     esac
 115     ;;
 116  win32)
 117     AC_DEFINE(GC_WIN32_THREADS)
 118     AC_DEFINE(NO_GETENV)
 119     ;;
 120  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 121     AC_MSG_ERROR(thread package $THREADS not yet supported)
 122     ;;
 123  *)
 124     AC_MSG_ERROR($THREADS is an unknown thread package)
 125     ;;
 126 esac
 127 AC_SUBST(THREADLIBS)
 128
 129 AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
 130 AC_SUBST(EXTRA_TEST_LIBS)
 131
 132 target_all=libgcjgc.la
 133 AC_SUBST(target_all)
 134 AC_SUBST(target_alias)
 135
 136 dnl If the target is an eCos system, use the appropriate eCos
 137 dnl I/O routines.
 138 dnl FIXME: this should not be a local option but a global target
 139 dnl system; at present there is no eCos target.
 140 TARGET_ECOS="no"
 141 AC_ARG_WITH(ecos,
 142 [  --with-ecos             enable runtime eCos target support],
 143 TARGET_ECOS="$with_ecos"
 144 )
 145
 146 addobjs=
 147 CXXINCLUDES=
 148 case "$TARGET_ECOS" in
 149    no)
 150       ;;
 151    *)
 152       AC_DEFINE(ECOS)
 153       CXXINCLUDES="-I${TARGET_ECOS}/include"
 154       addobjs="$addobjs ecos.lo"
 155       ;;
 156 esac
 157 AC_SUBST(CXX)
 158
 159 AC_SUBST(INCLUDES)
 160 AC_SUBST(CXXINCLUDES)
 161
 162 machdep=
 163 case "$host" in
 164  alpha*-*-openbsd*)
 165     machdep="alpha_mach_dep.lo"
 166     if test x"${ac_cv_lib_dl_dlopen}" != xyes ; then
 167        AC_MSG_WARN(OpenBSD/Alpha without dlopen(). Shared library support is disabled)
 168        AM_DISABLE_SHARED
 169     fi
 170     ;;
 171  alpha*-*-*)
 172     machdep="alpha_mach_dep.lo"
 173     ;;
 174  i?86-*-solaris2.[[89]]*)
 175     AC_DEFINE(SOLARIS25_PROC_VDB_BUG_FIXED)
 176     ;;
 177  mipstx39-*-elf*)
 178     machdep="mips_ultrix_mach_dep.lo"
 179     AC_DEFINE(STACKBASE, __stackbase)
 180     AC_DEFINE(DATASTART_IS_ETEXT)
 181     ;;
 182  mips-dec-ultrix*)
 183     machdep="mips_ultrix_mach-dep.lo"
 184     ;;
 185  mips*-*-linux*)
 186     ;;
 187  mips-*-*)
 188     machdep="mips_sgi_mach_dep.lo"
 189     AC_DEFINE(NO_EXECUTE_PERMISSION)
 190     ;;
 191  sparc-sun-solaris2.3*)
 192     machdep="sparc_mach_dep.lo"
 193     AC_DEFINE(SUNOS53_SHARED_LIB)
 194     ;;
 195  sparc-sun-solaris2.*)
 196     machdep="sparc_mach_dep.lo"
 197     ;;
 198  ia64-*-*)
 199     machdep="mach_dep.lo ia64_save_regs_in_stack.lo"
 200     ;;
 201 esac
 202 if test x"$machdep" = x; then
 203    machdep="mach_dep.lo"
 204 fi
 205 addobjs="$addobjs $machdep"
 206 AC_SUBST(addobjs)
 207
 208 dnl As of 4.13a2, the collector will not properly work on Solaris when
 209 dnl built with gcc and -O.  So we remove -O in the appropriate case.
 210 case "$host" in
 211  sparc-sun-solaris2*)
 212     if test "$GCC" = yes; then
 213        new_CFLAGS=
 214        for i in $CFLAGS; do
 215           case "$i" in
 216            -O*)
 217               ;;
 218            *)
 219               new_CFLAGS="$new_CFLAGS $i"
 220               ;;
 221           esac
 222        done
 223        CFLAGS="$new_CFLAGS"
 224     fi
 225     ;;
 226 esac
 227
 228 dnl We need to override the top-level CFLAGS.  This is how we do it.
 229 MY_CFLAGS="$CFLAGS"
 230 AC_SUBST(MY_CFLAGS)
 231
 232 dnl Include defines that have become de facto standard.
 233 dnl ALL_INTERIOR_POINTERS can be overridden in startup code.
 234 AC_DEFINE(SILENT)
 235 AC_DEFINE(NO_SIGNALS)
 236 AC_DEFINE(NO_EXECUTE_PERMISSION)
 237 AC_DEFINE(ALL_INTERIOR_POINTERS)
 238
 239 dnl By default, make the library as general as possible.
 240 AC_DEFINE(JAVA_FINALIZATION)
 241 AC_DEFINE(GC_GCJ_SUPPORT)
 242 AC_DEFINE(ATOMIC_UNCOLLECTABLE)
 243
 244 dnl This is something of a hack.  When cross-compiling we turn off
 245 dnl some functionality. These is only correct when targetting an
 246 dnl embedded system.  FIXME.
 247 if test -n "${with_cross_host}"; then
 248    AC_DEFINE(NO_SIGSET)
 249    AC_DEFINE(NO_DEBUGGING)
 250 fi
 251
 252 AC_ARG_ENABLE(full-debug,
 253 [  --enable-full-debug  include full support for pointer backtracing etc.],
 254 [ if test "$enable_full_debug" = "yes"; then
 255     AC_MSG_WARN("Must define GC_DEBUG and use debug alloc. in clients.")
 256     AC_DEFINE(KEEP_BACK_PTRS)
 257     AC_DEFINE(DBG_HDRS_ALL)
 258     case $host in
 259       ia64-*-linux* )
 260         AC_DEFINE(MAKE_BACK_GRAPH)
 261       ;;
 262       x86-*-linux* | i586-*-linux* | i686-*-linux* | x86_64-*-linux* )
 263         AC_DEFINE(MAKE_BACK_GRAPH)
 264         AC_MSG_WARN("Client must not use -fomit-frame-pointer.")
 265         AC_DEFINE(SAVE_CALL_COUNT, 8)
 266       ;;
 267     esac ]
 268   fi)
 269
 270 if test -n "$with_cross_host" &&
 271    test x"$with_cross_host" != x"no"; then
 272   toolexecdir='$(exec_prefix)/$(target_alias)'
 273   toolexeclibdir='$(toolexecdir)/lib'
 274 else
 275   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 276   toolexeclibdir='$(libdir)'
 277 fi
 278 toolexeclibdir=$toolexeclibdir/`$CC -print-multi-os-directory`
 279 AC_SUBST(toolexecdir)
 280 AC_SUBST(toolexeclibdir)
 281
 282 if test "${multilib}" = "yes"; then
 283   multilib_arg="--enable-multilib"
 284 else
 285   multilib_arg=
 286 fi
 287
 288 AC_OUTPUT(Makefile include/Makefile, [
 289 dnl Put all the -D options in a file.
 290 echo "$DEFS" > boehm-cflags
 291
 292 if test -n "$CONFIG_FILES"; then
 293   LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 294   ac_file=Makefile . ${gc_basedir}/../config-ml.in
 295 fi],
 296 srcdir=${srcdir}
 297 host=${host}
 298 target=${target}
 299 with_multisubdir=${with_multisubdir}
 300 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 301 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 302 gc_basedir=${gc_basedir}
 303 CC="${CC}"
 304 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 305 DEFS="$DEFS"
 306 )