OSDN Git Service

eae042a3d0a3183967f6f50e77d6beb01eb4d8d4
[lha/lha.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_INIT(src/lha.h)
3 AM_INIT_AUTOMAKE(lha, 1.14i-ac20020527a)
4 AM_CONFIG_HEADER(config.h)
5
6 AC_CANONICAL_HOST
7
8 AC_DEFINE_UNQUOTED(PLATFORM, "$ac_cv_host",
9                    [the type of system on which the package will run.])
10
11 dnl Checks for programs.
12 AC_PROG_CC
13 AC_PROG_GCC_TRADITIONAL
14 AC_PROG_INSTALL
15 AC_PROG_MAKE_SET
16 AC_MINIX
17 AM_C_PROTOTYPES
18 AC_EXEEXT
19 AC_OBJEXT
20
21 dnl Checks for libraries.
22
23 dnl Checks for header files.
24 AC_HEADER_DIRENT
25 AC_HEADER_STDC
26 AC_CHECK_HEADERS(fcntl.h limits.h sys/file.h sys/param.h sys/time.h)
27 AC_CHECK_HEADERS(pwd.h grp.h)
28
29 dnl Checks for typedefs, structures, and compiler characteristics.
30 AC_C_CONST
31 AC_HEADER_TIME
32 AC_STRUCT_TM
33 AC_STRUCT_TIMEZONE
34
35 AC_CHECK_TYPE(uid_t, int)
36 AC_CHECK_TYPE(gid_t, int)
37 AC_DEFINE(HAVE_UID_T, 1, [dummy macro])
38 AC_DEFINE(HAVE_GID_T, 1, [dummy macro])
39
40 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_member_struct_tm_tm_gmtoff,
41 [AC_TRY_COMPILE([
42 #if TM_IN_SYS_TIME
43 #include <sys/time.h>
44 #else
45 #include <time.h>
46 #endif
47   ], [struct tm t; t.tm_gmtoff;],
48   ac_cv_member_struct_tm_tm_gmtoff=yes,
49   ac_cv_member_struct_tm_tm_gmtoff=no)
50 ])
51
52 if test "x$ac_cv_member_struct_tm_tm_gmtoff" = xyes; then
53   AC_DEFINE(HAVE_STRUCT_TM_TM_GMTOFF, 1,
54             [Define if your struct tm has tm_gmtoff])
55 fi
56
57 AC_CACHE_CHECK([for st_ino in struct stat], ac_cv_member_struct_stat_st_ino,
58 [AC_TRY_COMPILE([
59 #include <sys/types.h>
60 #include <sys/stat.h>
61   ], [struct stat s; s.st_ino;],
62   ac_cv_member_struct_stat_st_ino=yes,
63   ac_cv_member_struct_stat_st_ino=no)
64 ])
65
66 if test "x$ac_cv_member_struct_stat_st_ino" = xyes; then
67   AC_DEFINE(HAVE_STRUCT_STAT_ST_INO, 1,
68             [Define if your struct stat has st_ino])
69 fi
70
71 dnl Checks for library functions.
72 AC_TYPE_SIGNAL
73 AC_FUNC_FORK
74 AC_FUNC_UTIME_NULL
75 AC_CHECK_FUNCS(strchr strdup memcpy memset memmove)
76 AC_CHECK_FUNCS(mktime timelocal tzset ftime gettimeofday utime)
77 AC_CHECK_FUNCS(mkdir rmdir ftruncate lchown mkstemp)
78 AC_CHECK_FUNCS(strcasecmp link)
79 AC_CHECK_FUNCS(getpwuid getgrgid getpwnam getgrnam)
80
81 AC_SUBST(LIBOBJS)
82 if test $ac_header_dirent = no; then
83   LIBOBJS="$LIBOBJS lhdir.o"
84 fi
85
86 dnl support kanji code conversion
87 AC_SUBST(DEF_KCODE)
88 AC_ARG_ENABLE(text_conv,
89   [  --enable-text-conv      support text code convert from/to EUC [default=yes]],
90   , enable_text_conv=yes)
91
92 if test $enable_text_conv = yes; then
93   DEF_KCODE=-DEUC
94 fi
95
96 # force support -lh7-
97 AC_SUBST(SUPPORT_LZHUFF_METHOD)
98 SUPPORT_LZHUFF_METHOD=-DSUPPORT_LH7
99
100 dnl whether use the -lh567- method
101 AC_MSG_CHECKING(default archive method is )
102 AC_ARG_WITH(default_method,
103   [  --with-default-method=[567]  create the -lh[567]- archive default [default=5]],
104   [case $withval in
105    [567]) ;;
106    *) AC_MSG_ERROR(you should have specified 5, 6 or 7);;
107    esac],
108   with_default_method=5)
109
110 AC_MSG_RESULT(-lh$with_default_method-)
111 AC_DEFINE_UNQUOTED(DEFAULT_LZHUFF_METHOD, LZHUFF${with_default_method}_METHOD_NUM, [Define it to 5, 6 or 7 which you want to use -lhX- method, default])
112
113 dnl decide temporary path names
114 AC_MSG_CHECKING(template of the temporary file is )
115 AC_ARG_WITH(tmp_file,
116   [  --with-tmp-file=TEMPLATE temporary file template [default=/tmp/lhXXXXXX]],
117   [case $withval in
118    yes)  with_tmp_file=/tmp/lhXXXXXX ;;
119    no)   ;;
120    esac],
121   with_tmp_file=/tmp/lhXXXXXX)
122
123 AC_MSG_RESULT($with_tmp_file)
124 if test x"$with_tmp_file" != xno; then
125   AC_DEFINE_UNQUOTED(TMP_FILENAME_TEMPLATE, "$with_tmp_file",
126     [temporary file template for mktemp/mkstemp])
127 fi
128
129 dnl incremental indicator
130 AC_ARG_ENABLE(indicator,
131   [  --enable-indicator      need incremental indicator [default=yes]],
132   ,
133   # default
134   enable_indicator=yes)
135
136 if test "x$enable_indicator" = xyes; then
137   AC_DEFINE(NEED_INCREMENTAL_INDICATOR, 1, [Define you want to use the incremental indicator])
138 fi
139
140 dnl support multibyte filename
141 AC_ARG_ENABLE(multibyte-char,
142   [  --enable-multibyte-char support multibyte filename [default=yes]],
143   ,
144   # default
145   enable_multibyte_char=yes)
146
147 if test "x$enable_multibyte_char" = xyes; then
148   AC_DEFINE(MULTIBYTE_CHAR, 1, [Define you want to use multibyte filename])
149 fi
150
151 AC_OUTPUT([Makefile src/Makefile man/Makefile tests/Makefile tests/lha-test])