OSDN Git Service

* configure.ac, config.h.in: use new autoconf macro, AC_CHECK_MEMBERS().
[lha/lha.git] / configure.in
1 dnl Process this file with autoconf to produce a configure script.
2 AC_INIT(src/lha.h)
3 AM_INIT_AUTOMAKE(lha, 1.14i-ac20020527a)
4 AM_CONFIG_HEADER(config.h)
5
6 AC_CANONICAL_HOST
7
8 AC_DEFINE_UNQUOTED(PLATFORM, "$ac_cv_host",
9                    [the type of system on which the package will run.])
10
11 dnl Checks for programs.
12 AC_PROG_CC
13 AC_PROG_GCC_TRADITIONAL
14 AC_PROG_INSTALL
15 AC_PROG_MAKE_SET
16 AC_MINIX
17 AM_C_PROTOTYPES
18 AC_EXEEXT
19 AC_OBJEXT
20
21 dnl Checks for libraries.
22
23 dnl Checks for header files.
24 AC_HEADER_DIRENT
25 AC_HEADER_STDC
26 AC_CHECK_HEADERS(fcntl.h limits.h sys/file.h sys/param.h sys/time.h)
27
28 dnl Checks for typedefs, structures, and compiler characteristics.
29 AC_C_CONST
30 AC_HEADER_TIME
31 AC_STRUCT_TM
32 AC_STRUCT_TIMEZONE
33
34 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_member_struct_tm_tm_gmtoff,
35 [AC_TRY_COMPILE([
36 #if TM_IN_SYS_TIME
37 #include <sys/time.h>
38 #else
39 #include <time.h>
40 #endif
41   ], [struct tm t; t.tm_gmtoff;],
42   ac_cv_member_struct_tm_tm_gmtoff=yes,
43   ac_cv_member_struct_tm_tm_gmtoff=no)
44 ])
45
46 if test "x$ac_cv_member_struct_tm_tm_gmtoff" = xyes; then
47   AC_DEFINE(HAVE_STRUCT_TM_TM_GMTOFF, 1,
48             [Define if your struct tm has tm_gmtoff])
49 fi
50
51 AC_CACHE_CHECK([for st_ino in struct stat], ac_cv_member_struct_stat_st_ino,
52 [AC_TRY_COMPILE([
53 #include <sys/types.h>
54 #include <sys/stat.h>
55   ], [struct stat s; s.st_ino;],
56   ac_cv_member_struct_stat_st_ino=yes,
57   ac_cv_member_struct_stat_st_ino=no)
58 ])
59
60 if test "x$ac_cv_member_struct_stat_st_ino" = xyes; then
61   AC_DEFINE(HAVE_STRUCT_STAT_ST_INO, 1,
62             [Define if your struct stat has st_ino])
63 fi
64
65 dnl Checks for library functions.
66 AC_TYPE_SIGNAL
67 AC_FUNC_FORK
68 AC_FUNC_UTIME_NULL
69 AC_CHECK_FUNCS(strchr strdup memcpy memset memmove)
70 AC_CHECK_FUNCS(mktime timelocal tzset ftime gettimeofday utime)
71 AC_CHECK_FUNCS(mkdir rmdir ftruncate lchown mkstemp)
72 AC_CHECK_FUNCS(strcasecmp link)
73
74 AC_SUBST(LIBOBJS)
75 if test $ac_header_dirent = no; then
76   LIBOBJS="$LIBOBJS lhdir.o"
77 fi
78
79 dnl support kanji code conversion
80 AC_SUBST(DEF_KCODE)
81 AC_ARG_ENABLE(text_conv,
82   [  --enable-text-conv      support text code convert from/to EUC [default=yes]],
83   , enable_text_conv=yes)
84
85 if test $enable_text_conv = yes; then
86   DEF_KCODE=-DEUC
87 fi
88
89 # force support -lh7-
90 AC_SUBST(SUPPORT_LZHUFF_METHOD)
91 SUPPORT_LZHUFF_METHOD=-DSUPPORT_LH7
92
93 dnl whether use the -lh567- method
94 AC_MSG_CHECKING(default archive method is )
95 AC_ARG_WITH(default_method,
96   [  --with-default-method=[567]  create the -lh[567]- archive default [default=5]],
97   [case $withval in
98    [567]) ;;
99    *) AC_MSG_ERROR(you should have specified 5, 6 or 7);;
100    esac],
101   with_default_method=5)
102
103 AC_MSG_RESULT(-lh$with_default_method-)
104 AC_DEFINE_UNQUOTED(DEFAULT_LZHUFF_METHOD, LZHUFF${with_default_method}_METHOD_NUM, [Define it to 5, 6 or 7 which you want to use -lhX- method, default])
105
106 dnl decide temporary path names
107 AC_MSG_CHECKING(template of the temporary file is )
108 AC_ARG_WITH(tmp_file,
109   [  --with-tmp-file=TEMPLATE temporary file template [default=/tmp/lhXXXXXX]],
110   [case $withval in
111    yes)  with_tmp_file=/tmp/lhXXXXXX ;;
112    no)   ;;
113    esac],
114   with_tmp_file=/tmp/lhXXXXXX)
115
116 AC_MSG_RESULT($with_tmp_file)
117 if test x"$with_tmp_file" != xno; then
118   AC_DEFINE_UNQUOTED(TMP_FILENAME_TEMPLATE, "$with_tmp_file",
119     [temporary file template for mktemp/mkstemp])
120 fi
121
122 dnl incremental indicator
123 AC_ARG_ENABLE(indicator,
124   [  --enable-indicator      need incremental indicator [default=yes]],
125   ,
126   # default
127   enable_indicator=yes)
128
129 if test "x$enable_indicator" = xyes; then
130   AC_DEFINE(NEED_INCREMENTAL_INDICATOR, 1, [Define you want to use the incremental indicator])
131 fi
132
133 dnl support multibyte filename
134 AC_ARG_ENABLE(multibyte-char,
135   [  --enable-multibyte-char support multibyte filename [default=yes]],
136   ,
137   # default
138   enable_multibyte_char=yes)
139
140 if test "x$enable_multibyte_char" = xyes; then
141   AC_DEFINE(MULTIBYTE_CHAR, 1, [Define you want to use multibyte filename])
142 fi
143
144 AC_OUTPUT([Makefile src/Makefile man/Makefile tests/Makefile tests/lha-test])