OSDN Git Service

2c90026297efc31ce3ca8193cad692ae4a0e8c5e
[lha/lha.git] / configure.ac
1 dnl Process this file with autoconf to produce a configure script.
2 AC_INIT(lha, 1.14i-ac20020527a, jca02266@nifty.ne.jp)
3 AC_CANONICAL_TARGET
4 AM_INIT_AUTOMAKE
5 AM_CONFIG_HEADER(config.h)
6
7 AC_DEFINE_UNQUOTED(PLATFORM, "$ac_cv_host",
8                    [the type of system on which the package will run.])
9
10 dnl Checks for programs.
11 AC_PROG_CC
12 AC_PROG_GCC_TRADITIONAL
13 AC_PROG_INSTALL
14 AC_PROG_MAKE_SET
15 AC_MINIX
16 AM_C_PROTOTYPES
17
18 dnl Checks for libraries.
19
20 dnl Checks for header files.
21 AC_HEADER_DIRENT
22 AC_HEADER_STDC
23 AC_CHECK_HEADERS(fcntl.h limits.h sys/file.h sys/param.h sys/time.h)
24 AC_CHECK_HEADERS(pwd.h grp.h)
25
26 dnl Checks for typedefs, structures, and compiler characteristics.
27 AC_C_CONST
28 AC_HEADER_TIME
29 AC_STRUCT_TM
30 AC_STRUCT_TIMEZONE
31
32 AC_CHECK_TYPES([uid_t, gid_t])
33 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct stat.st_ino],,,
34 [
35 #if HAVE_SYS_TYPES_H
36 # include <sys/types.h>
37 #endif
38 #if HAVE_SYS_STAT_H
39 # include <sys/stat.h>
40 #endif
41 #if TIME_WITH_SYS_TIME
42 # include <sys/time.h>
43 # include <time.h>
44 #else
45 # if HAVE_SYS_TIME_H
46 #  include <sys/time.h>
47 # else
48 #  include <time.h>
49 # endif
50 #endif
51 ])
52
53 dnl Checks for library functions.
54 AC_TYPE_SIGNAL
55 AC_FUNC_FORK
56 AC_FUNC_UTIME_NULL
57 AC_CHECK_FUNCS(strchr strdup memcpy memset memmove)
58 AC_CHECK_FUNCS(mktime timelocal tzset ftime gettimeofday utime)
59 AC_CHECK_FUNCS(mkdir rmdir ftruncate lchown mkstemp)
60 AC_CHECK_FUNCS(strcasecmp link)
61 AC_CHECK_FUNCS(getpwuid getgrgid getpwnam getgrnam)
62
63 if test $ac_header_dirent = no; then
64   AC_LIBOBJ(lhdir)
65 fi
66
67 dnl support kanji code conversion
68 AC_SUBST(DEF_KCODE)
69 AC_ARG_ENABLE(text_conv,
70   AC_HELP_STRING([--enable-text-conv],
71                  [support text code convert from/to EUC [[default=yes]]]),
72   , enable_text_conv=yes)
73
74 if test $enable_text_conv = yes; then
75   DEF_KCODE=-DEUC
76 fi
77
78 # force support -lh7-
79 AC_SUBST(SUPPORT_LZHUFF_METHOD)
80 SUPPORT_LZHUFF_METHOD=-DSUPPORT_LH7
81
82 dnl whether use the -lh567- method
83 AC_MSG_CHECKING(default archive method is )
84 AC_ARG_WITH(default_method,
85   AC_HELP_STRING([--with-default-method=[[567]]],
86                  [create the -lh[[567]]- archive default [[default=5]]]),
87   [case $withval in
88    [567]) ;;
89    *) AC_MSG_ERROR(you should have specified 5, 6 or 7);;
90    esac],
91   with_default_method=5)
92
93 AC_MSG_RESULT(-lh$with_default_method-)
94 AC_DEFINE_UNQUOTED(DEFAULT_LZHUFF_METHOD, LZHUFF${with_default_method}_METHOD_NUM, [Define it to 5, 6 or 7 which you want to use -lhX- method, default])
95
96 dnl decide temporary path names
97 AC_MSG_CHECKING(template of the temporary file is )
98 AC_ARG_WITH(tmp_file,
99   AC_HELP_STRING([--with-tmp-file=TEMPLATE],
100                  [temporary file template [[default=/tmp/lhXXXXXX]]]),
101   [case $withval in
102    yes)  with_tmp_file=/tmp/lhXXXXXX ;;
103    no)   ;;
104    esac],
105   with_tmp_file=/tmp/lhXXXXXX)
106
107 AC_MSG_RESULT($with_tmp_file)
108 if test x"$with_tmp_file" != xno; then
109   AC_DEFINE_UNQUOTED(TMP_FILENAME_TEMPLATE, "$with_tmp_file",
110     [temporary file template for mktemp/mkstemp])
111 fi
112
113 dnl incremental indicator
114 AC_ARG_ENABLE(indicator,
115   AC_HELP_STRING([--enable-indicator],
116                  [need incremental indicator [[default=yes]]]),
117   ,
118   # default
119   enable_indicator=yes)
120
121 if test "x$enable_indicator" = xyes; then
122   AC_DEFINE(NEED_INCREMENTAL_INDICATOR, 1, [Define you want to use the incremental indicator])
123 fi
124
125 dnl support multibyte filename
126 AC_ARG_ENABLE(multibyte-char,
127   AC_HELP_STRING([--enable-multibyte-char],
128                  [support multibyte filename [[default=yes]]]),
129   ,
130   # default
131   enable_multibyte_char=yes)
132
133 if test "x$enable_multibyte_char" = xyes; then
134   AC_DEFINE(MULTIBYTE_CHAR, 1, [Define you want to use multibyte filename])
135 fi
136
137 AC_CONFIG_FILES([Makefile src/Makefile man/Makefile])
138 AC_CONFIG_FILES([tests/Makefile tests/lha-test])
139 AC_OUTPUT