OSDN Git Service

Fix a bug: Could not extract 2G over files.
[lha/lha.git] / configure.ac
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT([LHa for UNIX], 1.14i-ac20070904, arai@users.sourceforge.jp, lha)
3 AC_CANONICAL_HOST
4 AC_CANONICAL_TARGET
5 AM_INIT_AUTOMAKE
6 AM_CONFIG_HEADER(config.h)
7
8 AC_DEFINE_UNQUOTED(PLATFORM, "$ac_cv_host",
9                    [the type of system on which the package will run.])
10
11 # Checks for programs.
12 AC_PROG_CC
13 AC_PROG_GCC_TRADITIONAL
14 AC_PROG_INSTALL
15 AC_PROG_MAKE_SET
16 AC_MINIX
17 AM_C_PROTOTYPES
18 AC_SYS_LARGEFILE
19 AC_CHECK_PROGS(sh_for_lha_test, [zsh bash ksh pdksh], [sh])
20
21 # Checks for libraries.
22 AC_SEARCH_LIBS(opendir, [mingwex])
23 AC_CHECK_LIB(applefile, af_open)
24
25 # Checks for header files.
26 AC_HEADER_DIRENT
27 AC_HEADER_STDC
28 AC_CHECK_HEADERS(fcntl.h limits.h sys/file.h sys/param.h sys/time.h)
29 AC_CHECK_HEADERS(pwd.h grp.h utime.h inttypes.h stdint.h fnmatch.h)
30
31 # Checks for typedefs, structures, and compiler characteristics.
32 AC_C_CONST
33 AC_HEADER_TIME
34 AC_STRUCT_TM
35 AC_STRUCT_TIMEZONE
36
37 AC_CHECK_SIZEOF(long)
38 AC_CHECK_SIZEOF(off_t)
39 AC_CHECK_TYPES([uid_t, gid_t, long long, uint64_t, ssize_t])
40 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct stat.st_ino],,,
41 [
42 #if HAVE_SYS_TYPES_H
43 # include <sys/types.h>
44 #endif
45 #if HAVE_SYS_STAT_H
46 # include <sys/stat.h>
47 #endif
48 #if TIME_WITH_SYS_TIME
49 # include <sys/time.h>
50 # include <time.h>
51 #else
52 # if HAVE_SYS_TIME_H
53 #  include <sys/time.h>
54 # else
55 #  include <time.h>
56 # endif
57 #endif
58 ])
59
60 # Checks for library functions.
61 AC_TYPE_SIGNAL
62 AC_FUNC_UTIME_NULL
63 AC_FUNC_FNMATCH
64 AC_FUNC_FSEEKO
65 AC_CHECK_FUNCS(strchr strdup memcpy memset memmove strcasecmp)
66 AC_CHECK_FUNCS(mktime timelocal tzset ftime gettimeofday utime)
67 AC_CHECK_FUNCS(ftruncate chsize lchown mkstemp ftello)
68 AC_CHECK_FUNCS(getpwuid getgrgid getpwnam getgrnam)
69 AC_CHECK_FUNCS(iconv basename)
70 AC_REPLACE_FUNCS(vsnprintf fnmatch)
71
72 if test $ac_header_dirent = no; then
73   AC_LIBOBJ(lhdir)
74 fi
75
76 AC_CHECK_DECLS([basename])
77
78 # checking whether 8 bit clean or not
79 AC_CACHE_CHECK([whether strchr()/strrchr() is 8bit clean],
80   [lha_cv_func_strchr_8bit_clean],
81   AC_TRY_RUN([
82 #if STDC_HEADERS
83 # include <string.h>
84 #else
85 # if !HAVE_STRCHR
86 #  define strchr index
87 #  define strrchr rindex
88 # endif
89 char *strchr (), *strrchr ();
90 #endif
91
92 main()
93 {
94   char *s = "\377";
95   if (strchr(s, 0xff) != s) exit(1);
96   if (strchr(s, '\377') != s) exit(1);
97   if (strrchr(s, 0xff) != s) exit(1);
98   if (strrchr(s, '\377') != s) exit(1);
99   exit(0); /* ok */
100 }
101 ], lha_cv_func_strchr_8bit_clean=yes,
102    lha_cv_func_strchr_8bit_clean=no,
103    lha_cv_func_strchr_8bit_clean=no))
104
105 if test x$lha_cv_func_strchr_8bit_clean = xyes; then
106   AC_DEFINE(STRCHR_8BIT_CLEAN, 1,
107             [Define to 1 if strchr()/strrchr() works correctly.])
108 fi
109
110 # checking whether the 2nd argument of gettimeofday() is effective or not.
111 # note that this timezone argument is obsolete.
112 AC_CACHE_CHECK([whether the 2nd argument of gettimeofday() is effective],
113   [lha_cv_func_gettimeofday_2nd_arg],
114   AC_TRY_RUN([
115 #if TIME_WITH_SYS_TIME
116 # include <sys/time.h>
117 # include <time.h>
118 #else
119 # if HAVE_SYS_TIME_H
120 #  include <sys/time.h>
121 # else
122 #  include <time.h>
123 # endif
124 #endif
125
126 main()
127 {
128     struct timeval tv;
129     struct timezone tz;
130
131     tz.tz_minuteswest = -1;
132     if (gettimeofday(&tv, &tz) == -1)
133         exit(1);
134
135     if (tz.tz_minuteswest == -1)
136         exit(1);        /* the timezone information is no given */
137
138     exit(0);
139 }], lha_cv_func_gettimeofday_2nd_arg=yes,
140    lha_cv_func_gettimeofday_2nd_arg=no,
141    lha_cv_func_gettimeofday_2nd_arg=no))
142
143 if test x$lha_cv_func_gettimeofday_2nd_arg = xyes; then
144   AC_DEFINE(GETTIMEOFDAY_HAS_2ND_ARG, 1,
145             [Define to 1 if the 2nd argument of gettimeofday() is effective.])
146 fi
147
148 # support kanji code conversion
149 AC_SUBST(DEF_KCODE)
150 AC_MSG_CHECKING(kanji code conversion on text file)
151 AC_ARG_ENABLE(text-conv,
152   AC_HELP_STRING([--enable-text-conv],
153                  [support text code convert from/to EUC [[default=yes]]]),
154   , enable_text_conv=yes)
155
156 AC_MSG_RESULT($enable_text_conv)
157 if test $enable_text_conv = yes; then
158   DEF_KCODE=-DEUC
159 fi
160
161 # force support -lh7-
162 AC_SUBST(SUPPORT_LZHUFF_METHOD)
163 SUPPORT_LZHUFF_METHOD=-DSUPPORT_LH7
164
165 # whether use the -lh567- method
166 AC_MSG_CHECKING(default archive method)
167 AC_ARG_WITH(default-method,
168   AC_HELP_STRING([--with-default-method=[[567]]],
169                  [create the -lh[[567]]- archive default [[default=5]]]),
170   [case $withval in
171    [567]) ;;
172    *) AC_MSG_ERROR(you should have specified 5, 6 or 7);;
173    esac],
174   with_default_method=5)
175 AC_MSG_RESULT(-lh$with_default_method-)
176 AC_DEFINE_UNQUOTED(DEFAULT_LZHUFF_METHOD, LZHUFF${with_default_method}_METHOD_NUM, [Define it to 5, 6 or 7 which you want to use -lhX- method, default])
177
178 # decide temporary path names
179 AC_MSG_CHECKING(template of the temporary file)
180 AC_ARG_WITH(tmp-file,
181   AC_HELP_STRING([--with-tmp-file=TEMPLATE],
182                  [temporary file template [[default=/tmp/lhXXXXXX]]]),
183   [case $withval in
184    yes)  with_tmp_file=/tmp/lhXXXXXX ;;
185    no)   ;;
186    esac],
187   with_tmp_file=/tmp/lhXXXXXX)
188
189 AC_MSG_RESULT($with_tmp_file)
190 if test x"$with_tmp_file" != xno; then
191   AC_DEFINE_UNQUOTED(TMP_FILENAME_TEMPLATE, "$with_tmp_file",
192     [temporary file template for mktemp/mkstemp])
193 fi
194
195 # incremental indicator
196 AC_MSG_CHECKING(whether incremental indicator is needed)
197 AC_ARG_ENABLE(indicator,
198   AC_HELP_STRING([--enable-indicator],
199                  [need incremental indicator [[default=yes]]]),
200   ,
201   # default
202   enable_indicator=yes)
203
204 AC_MSG_RESULT($enable_indicator)
205 if test "x$enable_indicator" = xyes; then
206   AC_DEFINE(NEED_INCREMENTAL_INDICATOR, 1,
207             [Define to 1 if you want to use the incremental indicator])
208 fi
209
210 # support multibyte filename
211 AC_MSG_CHECKING(kanji code of filename)
212 AC_ARG_ENABLE(multibyte-filename,
213   AC_HELP_STRING([--enable-multibyte-filename],
214                  [support multibyte filename. specify kanji code (euc, sjis, utf8 or auto) [[default=auto]]]),,
215   # default
216   enable_multibyte_filename=auto)
217
218 case $enable_multibyte_filename in
219 auto|yes)
220   AC_EGREP_CPP(SJIS,[
221 #if defined(__CYGWIN__) || defined(__MINGW32__) || defined(__hpux)
222 SJIS
223 #endif], enable_multibyte_filename=CODE_SJIS,
224   AC_EGREP_CPP(UTF8,[
225 #if defined(__APPLE__)  /* for Mac OS X */
226 UTF8
227 #endif], enable_multibyte_filename=CODE_UTF8,
228          enable_multibyte_filename=CODE_EUC));;
229 sjis)    enable_multibyte_filename=CODE_SJIS;;
230 euc)     enable_multibyte_filename=CODE_EUC;;
231 utf8)    enable_multibyte_filename=CODE_UTF8;;
232 no)      ;;
233 *)       AC_MSG_ERROR([you should specify auto, sjis or euc as your system filename code.]);;
234 esac
235
236 AC_MSG_RESULT($enable_multibyte_filename)
237 if test x$enable_multibyte_filename != xno; then
238   AC_DEFINE_UNQUOTED(MULTIBYTE_FILENAME, $enable_multibyte_filename,
239       [Define to CODE_EUC or CODE_SJIS if you want to use multibyte filename])
240
241   case $target_os in
242   darwin*)
243         # for multibyte filename
244         LDFLAGS="$LDFLAGS -framework CoreFoundation"
245         ;;
246   esac
247 fi
248
249 # make user/group name extented header
250 AC_MSG_CHECKING(whether user/group name extended header is needed)
251 AC_ARG_ENABLE(user-name-header,
252   AC_HELP_STRING([--enable-user-name-header],
253                  [make user/group name extended header [[default=no]]]),
254   ,
255   # default
256   enable_user_name_header=no)
257
258 AC_MSG_RESULT($enable_user_name_header)
259 if test "x$enable_user_name_header" = xyes; then
260   AC_DEFINE(INCLUDE_OWNER_NAME_IN_HEADER, 1,
261             [Define to 1 if you want to use the user/group name extened header])
262 fi
263
264 # backup old archive file
265 AC_MSG_CHECKING(whether backup file for old archive is left)
266 AC_ARG_ENABLE(backup-archive,
267   AC_HELP_STRING([--enable-backup-archive],
268                  [backup old archive [[default=no]]]),
269   ,
270   # default
271   enable_backup_archive=no)
272
273 AC_MSG_RESULT($enable_backup_archive)
274 if test "x$enable_backup_archive" = xyes; then
275   AC_DEFINE(BACKUP_OLD_ARCHIVE, 1,
276             [Define to 1 if you want to leave an old archive])
277 fi
278
279 case $host_os in 
280 *msdosdjgpp*)
281 CFLAGS="$CFLAGS -DNOT_COMPATIBLE_MODE"
282 ;;
283 esac
284
285 AC_CONFIG_FILES([Makefile src/Makefile man/Makefile olddoc/Makefile])
286 AC_CONFIG_FILES([tests/Makefile tests/lha-test])
287 AC_OUTPUT